4730c2b1ea9adbb4d90e817842541225ee23d45b
1# git-gui blame viewer
2# Copyright (C) 2006, 2007 Shawn Pearce
3class blame {
5field commit ; # input commit to blame
7field path ; # input filename to view in $commit
8field w
10field w_line
11field w_cgrp
12field w_load
13field w_file
14field w_cmit
15field status
16field highlight_line -1 ; # current line selected
18field highlight_commit {} ; # sha1 of commit selected
19field total_lines 0 ; # total length of file
21field blame_lines 0 ; # number of lines computed
22field commit_count 0 ; # number of commits in $commit_list
23field commit_list {} ; # list of commit sha1 in receipt order
24field order ; # array commit -> receipt order
25field header ; # array commit,key -> header field
26field line_commit ; # array line -> sha1 commit
27field line_file ; # array line -> file name
28field r_commit ; # commit currently being parsed
30field r_orig_line ; # original line number
31field r_final_line ; # final line number
32field r_line_count ; # lines in this region
33field tooltip_wm {} ; # Current tooltip toplevel, if open
35field tooltip_timer {} ; # Current timer event for our tooltip
36field tooltip_commit {} ; # Commit in tooltip
37field tooltip_text {} ; # Text in current tooltip
38variable active_color #98e1a0
40variable group_colors {
41 #cbcbcb
42 #e1e1e1
43}
44constructor new {i_commit i_path} {
46 variable active_color
47 global cursor_ptr
48 set commit $i_commit
50 set path $i_path
51 make_toplevel top w
53 wm title $top "[appname] ([reponame]): File Viewer"
54 set status "Loading $commit:$path..."
55 label $w.path -text "$commit:$path" \
57 -anchor w \
58 -justify left \
59 -borderwidth 1 \
60 -relief sunken \
61 -font font_uibold
62 pack $w.path -side top -fill x
63 frame $w.out
65 set w_load $w.out.loaded_t
66 text $w_load \
67 -background white -borderwidth 0 \
68 -state disabled \
69 -wrap none \
70 -height 40 \
71 -width 1 \
72 -font font_diff
73 $w_load tag conf annotated -background grey
74 set w_line $w.out.linenumber_t
76 text $w_line \
77 -background white -borderwidth 0 \
78 -state disabled \
79 -wrap none \
80 -height 40 \
81 -width 5 \
82 -font font_diff
83 $w_line tag conf linenumber -justify right
84 set w_cgrp $w.out.commit_t
86 text $w_cgrp \
87 -background white -borderwidth 0 \
88 -state disabled \
89 -wrap none \
90 -height 40 \
91 -width 4 \
92 -font font_diff
93 set w_file $w.out.file_t
95 text $w_file \
96 -background white -borderwidth 0 \
97 -state disabled \
98 -wrap none \
99 -height 40 \
100 -width 80 \
101 -xscrollcommand [list $w.out.sbx set] \
102 -font font_diff
103 scrollbar $w.out.sbx -orient h -command [list $w_file xview]
105 scrollbar $w.out.sby -orient v \
106 -command [list scrollbar2many [list \
107 $w_load \
108 $w_line \
109 $w_cgrp \
110 $w_file \
111 ] yview]
112 grid \
113 $w_cgrp \
114 $w_line \
115 $w_load \
116 $w_file \
117 $w.out.sby \
118 -sticky nsew
119 grid conf $w.out.sbx -column 3 -sticky we
120 grid columnconfigure $w.out 3 -weight 1
121 grid rowconfigure $w.out 0 -weight 1
122 pack $w.out -fill both -expand 1
123 label $w.status \
125 -textvariable @status \
126 -anchor w \
127 -justify left \
128 -borderwidth 1 \
129 -relief sunken
130 pack $w.status -side bottom -fill x
131 frame $w.cm
133 set w_cmit $w.cm.t
134 text $w_cmit \
135 -background white -borderwidth 0 \
136 -state disabled \
137 -wrap none \
138 -height 10 \
139 -width 80 \
140 -xscrollcommand [list $w.cm.sbx set] \
141 -yscrollcommand [list $w.cm.sby set] \
142 -font font_diff
143 $w_cmit tag conf header_key \
144 -tabs {3c} \
145 -background $active_color \
146 -font font_uibold
147 $w_cmit tag conf header_val \
148 -background $active_color \
149 -font font_ui
150 $w_cmit tag raise sel
151 scrollbar $w.cm.sbx -orient h -command [list $w_cmit xview]
152 scrollbar $w.cm.sby -orient v -command [list $w_cmit yview]
153 pack $w.cm.sby -side right -fill y
154 pack $w.cm.sbx -side bottom -fill x
155 pack $w_cmit -expand 1 -fill both
156 pack $w.cm -side bottom -fill x
157 menu $w.ctxm -tearoff 0
159 $w.ctxm add command \
160 -label "Copy Commit" \
161 -command [cb _copycommit]
162 foreach i [list \
164 $w_cgrp \
165 $w_load \
166 $w_line \
167 $w_file] {
168 $i conf -cursor $cursor_ptr
169 $i conf -yscrollcommand \
170 [list many2scrollbar [list \
171 $w_cgrp \
172 $w_load \
173 $w_line \
174 $w_file \
175 ] yview $w.out.sby]
176 bind $i <Button-1> "
177 [cb _hide_tooltip]
178 [cb _click $i @%x,%y]
179 focus $i
180 "
181 bind $i <Any-Motion> [cb _show_tooltip $i @%x,%y]
182 bind $i <Any-Enter> [cb _hide_tooltip]
183 bind $i <Any-Leave> [cb _hide_tooltip]
184 bind_button3 $i "
185 [cb _hide_tooltip]
186 set cursorX %x
187 set cursorY %y
188 set cursorW %W
189 tk_popup $w.ctxm %X %Y
190 "
191 }
192 foreach i [list \
194 $w_cgrp \
195 $w_load \
196 $w_line \
197 $w_file \
198 $w_cmit] {
199 bind $i <Key-Up> {catch {%W yview scroll -1 units};break}
200 bind $i <Key-Down> {catch {%W yview scroll 1 units};break}
201 bind $i <Key-Left> {catch {%W xview scroll -1 units};break}
202 bind $i <Key-Right> {catch {%W xview scroll 1 units};break}
203 bind $i <Key-k> {catch {%W yview scroll -1 units};break}
204 bind $i <Key-j> {catch {%W yview scroll 1 units};break}
205 bind $i <Key-h> {catch {%W xview scroll -1 units};break}
206 bind $i <Key-l> {catch {%W xview scroll 1 units};break}
207 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
208 bind $i <Control-Key-f> {catch {%W yview scroll 1 pages};break}
209 }
210 bind $w_cmit <Button-1> [list focus $w_cmit]
212 bind $top <Visibility> [list focus $top]
213 bind $top <Destroy> [list delete_this $this]
214 if {$commit eq {}} {
216 set fd [open $path r]
217 } else {
218 set cmd [list git cat-file blob "$commit:$path"]
219 set fd [open "| $cmd" r]
220 }
221 fconfigure $fd -blocking 0 -translation lf -encoding binary
222 fileevent $fd readable [cb _read_file $fd]
223}
224method _read_file {fd} {
226 $w_load conf -state normal
227 $w_cgrp conf -state normal
228 $w_line conf -state normal
229 $w_file conf -state normal
230 while {[gets $fd line] >= 0} {
231 regsub "\r\$" $line {} line
232 incr total_lines
233 if {$total_lines > 1} {
235 $w_load insert end "\n"
236 $w_cgrp insert end "\n"
237 $w_line insert end "\n"
238 $w_file insert end "\n"
239 }
240 $w_line insert end "$total_lines" linenumber
242 $w_file insert end "$line"
243 }
244 $w_load conf -state disabled
245 $w_cgrp conf -state disabled
246 $w_line conf -state disabled
247 $w_file conf -state disabled
248 if {[eof $fd]} {
250 close $fd
251 _status $this
252 set cmd [list git blame -M -C --incremental]
253 if {$commit eq {}} {
254 lappend cmd --contents $path
255 } else {
256 lappend cmd $commit
257 }
258 lappend cmd -- $path
259 set fd [open "| $cmd" r]
260 fconfigure $fd -blocking 0 -translation lf -encoding binary
261 fileevent $fd readable [cb _read_blame $fd]
262 }
263} ifdeleted { catch {close $fd} }
264method _read_blame {fd} {
266 variable group_colors
267 $w_cgrp conf -state normal
269 while {[gets $fd line] >= 0} {
270 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
271 cmit original_line final_line line_count]} {
272 set r_commit $cmit
273 set r_orig_line $original_line
274 set r_final_line $final_line
275 set r_line_count $line_count
276 if {[catch {set g $order($cmit)}]} {
278 set bg [lindex $group_colors 0]
279 set group_colors [lrange $group_colors 1 end]
280 lappend group_colors $bg
281 $w_cgrp tag conf g$cmit -background $bg
283 $w_line tag conf g$cmit -background $bg
284 $w_file tag conf g$cmit -background $bg
285 set order($cmit) $commit_count
287 incr commit_count
288 lappend commit_list $cmit
289 }
290 } elseif {[string match {filename *} $line]} {
291 set file [string range $line 9 end]
292 set n $r_line_count
293 set lno $r_final_line
294 set cmit $r_commit
295 if {[regexp {^0{40}$} $cmit]} {
297 set abbr work
298 } else {
299 set abbr [string range $cmit 0 4]
300 }
301 if {![catch {set ncmit $line_commit([expr {$lno - 1}])}]} {
303 if {$ncmit eq $cmit} {
304 set abbr |
305 }
306 }
307 while {$n > 0} {
309 set lno_e "$lno.0 lineend + 1c"
310 if {[catch {set g g$line_commit($lno)}]} {
311 $w_load tag add annotated $lno.0 $lno_e
312 } else {
313 $w_cgrp tag remove g$g $lno.0 $lno_e
314 $w_line tag remove g$g $lno.0 $lno_e
315 $w_file tag remove g$g $lno.0 $lno_e
316 $w_cgrp tag remove a$g $lno.0 $lno_e
318 $w_line tag remove a$g $lno.0 $lno_e
319 $w_file tag remove a$g $lno.0 $lno_e
320 }
321 set line_commit($lno) $cmit
323 set line_file($lno) $file
324 $w_cgrp delete $lno.0 "$lno.0 lineend"
326 $w_cgrp insert $lno.0 $abbr
327 set abbr |
328 $w_cgrp tag add g$cmit $lno.0 $lno_e
330 $w_line tag add g$cmit $lno.0 $lno_e
331 $w_file tag add g$cmit $lno.0 $lno_e
332 $w_cgrp tag add a$cmit $lno.0 $lno_e
334 $w_line tag add a$cmit $lno.0 $lno_e
335 $w_file tag add a$cmit $lno.0 $lno_e
336 if {$highlight_line == -1} {
338 if {[lindex [$w_file yview] 0] == 0} {
339 $w_file see $lno.0
340 _showcommit $this $lno
341 }
342 } elseif {$highlight_line == $lno} {
343 _showcommit $this $lno
344 }
345 incr n -1
347 incr lno
348 incr blame_lines
349 }
350 if {![catch {set ncmit $line_commit($lno)}]} {
352 if {$ncmit eq $cmit} {
353 $w_cgrp delete $lno.0 "$lno.0 lineend + 1c"
354 $w_cgrp insert $lno.0 "|\n"
355 }
356 }
357 set hc $highlight_commit
359 if {$hc ne {}
360 && [expr {$order($hc) + 1}] == $order($cmit)} {
361 _showcommit $this $highlight_line
362 }
363 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
364 set header($r_commit,$key) $data
365 }
366 }
367 $w_cgrp conf -state disabled
368 if {[eof $fd]} {
370 close $fd
371 set status {Annotation complete.}
372 } else {
373 _status $this
374 }
375} ifdeleted { catch {close $fd} }
376method _status {} {
378 set have $blame_lines
379 set total $total_lines
380 set pdone 0
381 if {$total} {set pdone [expr {100 * $have / $total}]}
382 set status [format \
384 "Loading annotations... %i of %i lines annotated (%2i%%)" \
385 $have $total $pdone]
386}
387method _click {cur_w pos} {
389 set lno [lindex [split [$cur_w index $pos] .] 0]
390 if {$lno eq {}} return
391 _showcommit $this $lno
392}
393method _showcommit {lno} {
395 global repo_config
396 variable active_color
397 if {$highlight_commit ne {}} {
399 set cmit $highlight_commit
400 $w_cgrp tag conf a$cmit -background {}
401 $w_line tag conf a$cmit -background {}
402 $w_file tag conf a$cmit -background {}
403 }
404 $w_cmit conf -state normal
406 $w_cmit delete 0.0 end
407 if {[catch {set cmit $line_commit($lno)}]} {
408 set cmit {}
409 $w_cmit insert end "Loading annotation..."
410 } else {
411 $w_cgrp tag conf a$cmit -background $active_color
412 $w_line tag conf a$cmit -background $active_color
413 $w_file tag conf a$cmit -background $active_color
414 set author_name {}
416 set author_email {}
417 set author_time {}
418 catch {set author_name $header($cmit,author)}
419 catch {set author_email $header($cmit,author-mail)}
420 catch {set author_time [clock format \
421 $header($cmit,author-time) \
422 -format {%Y-%m-%d %H:%M:%S}
423 ]}
424 set committer_name {}
426 set committer_email {}
427 set committer_time {}
428 catch {set committer_name $header($cmit,committer)}
429 catch {set committer_email $header($cmit,committer-mail)}
430 catch {set committer_time [clock format \
431 $header($cmit,committer-time) \
432 -format {%Y-%m-%d %H:%M:%S}
433 ]}
434 if {[catch {set msg $header($cmit,message)}]} {
436 set msg {}
437 catch {
438 set fd [open "| git cat-file commit $cmit" r]
439 fconfigure $fd -encoding binary -translation lf
440 if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
441 set enc utf-8
442 }
443 while {[gets $fd line] > 0} {
444 if {[string match {encoding *} $line]} {
445 set enc [string tolower [string range $line 9 end]]
446 }
447 }
448 set msg [encoding convertfrom $enc [read $fd]]
449 set msg [string trim $msg]
450 close $fd
451 set author_name [encoding convertfrom $enc $author_name]
453 set committer_name [encoding convertfrom $enc $committer_name]
454 set header($cmit,author) $author_name
456 set header($cmit,committer) $committer_name
457 }
458 set header($cmit,message) $msg
459 }
460 $w_cmit insert end "commit $cmit\n" header_key
462 $w_cmit insert end "Author:\t" header_key
463 $w_cmit insert end "$author_name $author_email" header_val
464 $w_cmit insert end "$author_time\n" header_val
465 $w_cmit insert end "Committer:\t" header_key
467 $w_cmit insert end "$committer_name $committer_email" header_val
468 $w_cmit insert end "$committer_time\n" header_val
469 if {$line_file($lno) ne $path} {
471 $w_cmit insert end "Original File:\t" header_key
472 $w_cmit insert end "[escape_path $line_file($lno)]\n" header_val
473 }
474 $w_cmit insert end "\n$msg"
476 }
477 $w_cmit conf -state disabled
478 set highlight_line $lno
480 set highlight_commit $cmit
481 if {$highlight_commit eq $tooltip_commit} {
483 _hide_tooltip $this
484 }
485}
486method _copycommit {} {
488 set pos @$::cursorX,$::cursorY
489 set lno [lindex [split [$::cursorW index $pos] .] 0]
490 if {![catch {set commit $line_commit($lno)}]} {
491 clipboard clear
492 clipboard append \
493 -format STRING \
494 -type STRING \
495 -- $commit
496 }
497}
498method _show_tooltip {cur_w pos} {
500 set lno [lindex [split [$cur_w index $pos] .] 0]
501 if {[catch {set cmit $line_commit($lno)}]} {
502 _hide_tooltip $this
503 return
504 }
505 if {$cmit eq $highlight_commit} {
507 _hide_tooltip $this
508 return
509 }
510 if {$cmit eq $tooltip_commit} {
512 _position_tooltip $this
513 } elseif {$tooltip_wm ne {}} {
514 _open_tooltip $this $cur_w
515 } elseif {$tooltip_timer eq {}} {
516 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
517 }
518}
519method _open_tooltip {cur_w} {
521 set tooltip_timer {}
522 set pos_x [winfo pointerx $cur_w]
523 set pos_y [winfo pointery $cur_w]
524 if {[winfo containing $pos_x $pos_y] ne $cur_w} {
525 _hide_tooltip $this
526 return
527 }
528 set pos @[join [list \
530 [expr {$pos_x - [winfo rootx $cur_w]}] \
531 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
532 set lno [lindex [split [$cur_w index $pos] .] 0]
533 set cmit $line_commit($lno)
534 set author_name {}
536 set author_email {}
537 set author_time {}
538 catch {set author_name $header($cmit,author)}
539 catch {set author_email $header($cmit,author-mail)}
540 catch {set author_time [clock format \
541 $header($cmit,author-time) \
542 -format {%Y-%m-%d %H:%M:%S}
543 ]}
544 set committer_name {}
546 set committer_email {}
547 set committer_time {}
548 catch {set committer_name $header($cmit,committer)}
549 catch {set committer_email $header($cmit,committer-mail)}
550 catch {set committer_time [clock format \
551 $header($cmit,committer-time) \
552 -format {%Y-%m-%d %H:%M:%S}
553 ]}
554 set summary {}
556 catch {set summary $header($cmit,summary)}
557 set tooltip_commit $cmit
559 set tooltip_text "commit $cmit
560$author_name $author_email $author_time
561$summary"
562 if {$tooltip_wm ne "$cur_w.tooltip"} {
564 _hide_tooltip $this
565 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
567 wm overrideredirect $tooltip_wm 1
568 wm transient $tooltip_wm [winfo toplevel $cur_w]
569 pack [label $tooltip_wm.label \
570 -background lightyellow \
571 -foreground black \
572 -textvariable @tooltip_text \
573 -justify left]
574 }
575 _position_tooltip $this
576}
577method _position_tooltip {} {
579 set req_w [winfo reqwidth $tooltip_wm.label]
580 set req_h [winfo reqheight $tooltip_wm.label]
581 set pos_x [expr {[winfo pointerx .] + 5}]
582 set pos_y [expr {[winfo pointery .] + 10}]
583 set g "${req_w}x${req_h}"
585 if {$pos_x >= 0} {append g +}
586 append g $pos_x
587 if {$pos_y >= 0} {append g +}
588 append g $pos_y
589 wm geometry $tooltip_wm $g
591 raise $tooltip_wm
592}
593method _hide_tooltip {} {
595 if {$tooltip_wm ne {}} {
596 destroy $tooltip_wm
597 set tooltip_wm {}
598 set tooltip_commit {}
599 }
600 if {$tooltip_timer ne {}} {
601 after cancel $tooltip_timer
602 set tooltip_timer {}
603 }
604}
605}