b5236548152043c5ec29997a791f5a51fa3f56cb
1# git-gui blame viewer
2# Copyright (C) 2006, 2007 Shawn Pearce
3class blame {
5image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
7# Persistant data (survives loads)
9#
10field history {}; # viewer history: {commit path}
11field header ; # array commit,key -> header field
12# Tk UI control paths
14#
15field w ; # top window in this viewer
16field w_back ; # our back button
17field w_path ; # label showing the current file path
18field w_columns ; # list of all column widgets in the viewer
19field w_line ; # text column: all line numbers
20field w_amov ; # text column: annotations + move tracking
21field w_asim ; # text column: annotations (simple computation)
22field w_file ; # text column: actual file data
23field w_cviewer ; # pane showing commit message
24field status ; # text variable bound to status bar
25field old_height ; # last known height of $w.file_pane
26# Tk UI colors
28#
29variable active_color #c0edc5
30variable group_colors {
31 #d6d6d6
32 #e1e1e1
33 #ececec
34}
35# Current blame data; cleared/reset on each load
37#
38field commit ; # input commit to blame
39field path ; # input filename to view in $commit
40field current_fd {} ; # background process running
42field highlight_line -1 ; # current line selected
43field highlight_column {} ; # current commit column selected
44field highlight_commit {} ; # sha1 of commit selected
45field total_lines 0 ; # total length of file
47field blame_lines 0 ; # number of lines computed
48field amov_data ; # list of {commit origfile origline}
49field asim_data ; # list of {commit origfile origline}
50field r_commit ; # commit currently being parsed
52field r_orig_line ; # original line number
53field r_final_line ; # final line number
54field r_line_count ; # lines in this region
55field tooltip_wm {} ; # Current tooltip toplevel, if open
57field tooltip_t {} ; # Text widget in $tooltip_wm
58field tooltip_timer {} ; # Current timer event for our tooltip
59field tooltip_commit {} ; # Commit(s) in tooltip
60constructor new {i_commit i_path} {
62 global cursor_ptr
63 variable active_color
64 variable group_colors
65 set commit $i_commit
67 set path $i_path
68 make_toplevel top w
70 wm title $top "[appname] ([reponame]): File Viewer"
71 frame $w.header -background gold
73 label $w.header.commit_l \
74 -text {Commit:} \
75 -background gold \
76 -anchor w \
77 -justify left
78 set w_back $w.header.commit_b
79 label $w_back \
80 -image ::blame::img_back_arrow \
81 -borderwidth 0 \
82 -relief flat \
83 -state disabled \
84 -background gold \
85 -activebackground gold
86 bind $w_back <Button-1> "
87 if {\[$w_back cget -state\] eq {normal}} {
88 [cb _history_menu]
89 }
90 "
91 label $w.header.commit \
92 -textvariable @commit \
93 -background gold \
94 -anchor w \
95 -justify left
96 label $w.header.path_l \
97 -text {File:} \
98 -background gold \
99 -anchor w \
100 -justify left
101 set w_path $w.header.path
102 label $w_path \
103 -background gold \
104 -anchor w \
105 -justify left
106 pack $w.header.commit_l -side left
107 pack $w_back -side left
108 pack $w.header.commit -side left
109 pack $w_path -fill x -side right
110 pack $w.header.path_l -side right
111 panedwindow $w.file_pane -orient vertical
113 frame $w.file_pane.out
114 frame $w.file_pane.cm
115 $w.file_pane add $w.file_pane.out \
116 -sticky nsew \
117 -minsize 100 \
118 -height 100 \
119 -width 100
120 $w.file_pane add $w.file_pane.cm \
121 -sticky nsew \
122 -minsize 25 \
123 -height 25 \
124 -width 100
125 set w_line $w.file_pane.out.linenumber_t
127 text $w_line \
128 -takefocus 0 \
129 -highlightthickness 0 \
130 -padx 0 -pady 0 \
131 -background white -borderwidth 0 \
132 -state disabled \
133 -wrap none \
134 -height 40 \
135 -width 6 \
136 -font font_diff
137 $w_line tag conf linenumber -justify right -rmargin 5
138 set w_amov $w.file_pane.out.amove_t
140 text $w_amov \
141 -takefocus 0 \
142 -highlightthickness 0 \
143 -padx 0 -pady 0 \
144 -background white -borderwidth 0 \
145 -state disabled \
146 -wrap none \
147 -height 40 \
148 -width 5 \
149 -font font_diff
150 $w_amov tag conf author_abbr -justify right -rmargin 5
151 $w_amov tag conf curr_commit
152 $w_amov tag conf prior_commit -foreground blue -underline 1
153 $w_amov tag bind prior_commit \
154 <Button-1> \
155 "[cb _load_commit $w_amov @amov_data @%x,%y];break"
156 set w_asim $w.file_pane.out.asimple_t
158 text $w_asim \
159 -takefocus 0 \
160 -highlightthickness 0 \
161 -padx 0 -pady 0 \
162 -background white -borderwidth 0 \
163 -state disabled \
164 -wrap none \
165 -height 40 \
166 -width 4 \
167 -font font_diff
168 $w_asim tag conf author_abbr -justify right
169 $w_asim tag conf curr_commit
170 $w_asim tag conf prior_commit -foreground blue -underline 1
171 $w_asim tag bind prior_commit \
172 <Button-1> \
173 "[cb _load_commit $w_asim @asim_data @%x,%y];break"
174 set w_file $w.file_pane.out.file_t
176 text $w_file \
177 -takefocus 0 \
178 -highlightthickness 0 \
179 -padx 0 -pady 0 \
180 -background white -borderwidth 0 \
181 -state disabled \
182 -wrap none \
183 -height 40 \
184 -width 80 \
185 -xscrollcommand [list $w.file_pane.out.sbx set] \
186 -font font_diff
187 set w_columns [list $w_amov $w_asim $w_line $w_file]
189 scrollbar $w.file_pane.out.sbx \
191 -orient h \
192 -command [list $w_file xview]
193 scrollbar $w.file_pane.out.sby \
194 -orient v \
195 -command [list scrollbar2many $w_columns yview]
196 eval grid $w_columns $w.file_pane.out.sby -sticky nsew
197 grid conf \
198 $w.file_pane.out.sbx \
199 -column [expr {[llength $w_columns] - 1}] \
200 -sticky we
201 grid columnconfigure \
202 $w.file_pane.out \
203 [expr {[llength $w_columns] - 1}] \
204 -weight 1
205 grid rowconfigure $w.file_pane.out 0 -weight 1
206 set w_cviewer $w.file_pane.cm.t
208 text $w_cviewer \
209 -background white -borderwidth 0 \
210 -state disabled \
211 -wrap none \
212 -height 10 \
213 -width 80 \
214 -xscrollcommand [list $w.file_pane.cm.sbx set] \
215 -yscrollcommand [list $w.file_pane.cm.sby set] \
216 -font font_diff
217 $w_cviewer tag conf still_loading \
218 -font font_uiitalic \
219 -justify center
220 $w_cviewer tag conf header_key \
221 -tabs {3c} \
222 -background $active_color \
223 -font font_uibold
224 $w_cviewer tag conf header_val \
225 -background $active_color \
226 -font font_ui
227 $w_cviewer tag raise sel
228 scrollbar $w.file_pane.cm.sbx \
229 -orient h \
230 -command [list $w_cviewer xview]
231 scrollbar $w.file_pane.cm.sby \
232 -orient v \
233 -command [list $w_cviewer yview]
234 pack $w.file_pane.cm.sby -side right -fill y
235 pack $w.file_pane.cm.sbx -side bottom -fill x
236 pack $w_cviewer -expand 1 -fill both
237 frame $w.status \
239 -borderwidth 1 \
240 -relief sunken
241 label $w.status.l \
242 -textvariable @status \
243 -anchor w \
244 -justify left
245 pack $w.status.l -side left
246 menu $w.ctxm -tearoff 0
248 $w.ctxm add command \
249 -label "Copy Commit" \
250 -command [cb _copycommit]
251 foreach i $w_columns {
253 for {set g 0} {$g < [llength $group_colors]} {incr g} {
254 $i tag conf color$g -background [lindex $group_colors $g]
255 }
256 $i conf -cursor $cursor_ptr
258 $i conf -yscrollcommand [list many2scrollbar \
259 $w_columns yview $w.file_pane.out.sby]
260 bind $i <Button-1> "
261 [cb _hide_tooltip]
262 [cb _click $i @%x,%y]
263 focus $i
264 "
265 bind $i <Any-Motion> [cb _show_tooltip $i @%x,%y]
266 bind $i <Any-Enter> [cb _hide_tooltip]
267 bind $i <Any-Leave> [cb _hide_tooltip]
268 bind_button3 $i "
269 [cb _hide_tooltip]
270 set cursorX %x
271 set cursorY %y
272 set cursorW %W
273 tk_popup $w.ctxm %X %Y
274 "
275 bind $i <Shift-Tab> "[list focus $w_cviewer];break"
276 bind $i <Tab> "[list focus $w_cviewer];break"
277 }
278 foreach i [concat $w_columns $w_cviewer] {
280 bind $i <Key-Up> {catch {%W yview scroll -1 units};break}
281 bind $i <Key-Down> {catch {%W yview scroll 1 units};break}
282 bind $i <Key-Left> {catch {%W xview scroll -1 units};break}
283 bind $i <Key-Right> {catch {%W xview scroll 1 units};break}
284 bind $i <Key-k> {catch {%W yview scroll -1 units};break}
285 bind $i <Key-j> {catch {%W yview scroll 1 units};break}
286 bind $i <Key-h> {catch {%W xview scroll -1 units};break}
287 bind $i <Key-l> {catch {%W xview scroll 1 units};break}
288 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
289 bind $i <Control-Key-f> {catch {%W yview scroll 1 pages};break}
290 }
291 bind $w_cviewer <Shift-Tab> "[list focus $w_file];break"
293 bind $w_cviewer <Tab> "[list focus $w_file];break"
294 bind $w_cviewer <Button-1> [list focus $w_cviewer]
295 bind $w_file <Visibility> [list focus $w_file]
296 grid configure $w.header -sticky ew
298 grid configure $w.file_pane -sticky nsew
299 grid configure $w.status -sticky ew
300 grid columnconfigure $top 0 -weight 1
301 grid rowconfigure $top 0 -weight 0
302 grid rowconfigure $top 1 -weight 1
303 grid rowconfigure $top 2 -weight 0
304 set req_w [winfo reqwidth $top]
306 set req_h [winfo reqheight $top]
307 if {$req_w < 600} {set req_w 600}
308 if {$req_h < 400} {set req_h 400}
309 set g "${req_w}x${req_h}"
310 wm geometry $top $g
311 update
312 set old_height [winfo height $w.file_pane]
314 $w.file_pane sash place 0 \
315 [lindex [$w.file_pane sash coord 0] 0] \
316 [expr {int($old_height * 0.70)}]
317 bind $w.file_pane <Configure> \
318 "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
319 _load $this {}
321}
322method _load {jump} {
324 variable group_colors
325 _hide_tooltip $this
327 if {$total_lines != 0 || $current_fd ne {}} {
329 if {$current_fd ne {}} {
330 catch {close $current_fd}
331 set current_fd {}
332 }
333 foreach i $w_columns {
335 $i conf -state normal
336 $i delete 0.0 end
337 foreach g [$i tag names] {
338 if {[regexp {^g[0-9a-f]{40}$} $g]} {
339 $i tag delete $g
340 }
341 }
342 $i conf -state disabled
343 }
344 $w_cviewer conf -state normal
346 $w_cviewer delete 0.0 end
347 $w_cviewer conf -state disabled
348 set highlight_line -1
350 set highlight_column {}
351 set highlight_commit {}
352 set total_lines 0
353 }
354 if {[winfo exists $w.status.c]} {
356 $w.status.c coords bar 0 0 0 20
357 } else {
358 canvas $w.status.c \
359 -width 100 \
360 -height [expr {int([winfo reqheight $w.status.l] * 0.6)}] \
361 -borderwidth 1 \
362 -relief groove \
363 -highlightt 0
364 $w.status.c create rectangle 0 0 0 20 -tags bar -fill navy
365 pack $w.status.c -side right
366 }
367 if {$history eq {}} {
369 $w_back conf -state disabled
370 } else {
371 $w_back conf -state normal
372 }
373 # Index 0 is always empty. There is never line 0 as
375 # we use only 1 based lines, as that matches both with
376 # git-blame output and with Tk's text widget.
377 #
378 set amov_data [list [list]]
379 set asim_data [list [list]]
380 set status "Loading $commit:[escape_path $path]..."
382 $w_path conf -text [escape_path $path]
383 if {$commit eq {}} {
384 set fd [open $path r]
385 } else {
386 set cmd [list git cat-file blob "$commit:$path"]
387 set fd [open "| $cmd" r]
388 }
389 fconfigure $fd -blocking 0 -translation lf -encoding binary
390 fileevent $fd readable [cb _read_file $fd $jump]
391 set current_fd $fd
392}
393method _history_menu {} {
395 set m $w.backmenu
396 if {[winfo exists $m]} {
397 $m delete 0 end
398 } else {
399 menu $m -tearoff 0
400 }
401 for {set i [expr {[llength $history] - 1}]
403 } {$i >= 0} {incr i -1} {
404 set e [lindex $history $i]
405 set c [lindex $e 0]
406 set f [lindex $e 1]
407 if {[regexp {^[0-9a-f]{40}$} $c]} {
409 set t [string range $c 0 8]...
410 } elseif {$c eq {}} {
411 set t {Working Directory}
412 } else {
413 set t $c
414 }
415 if {![catch {set summary $header($c,summary)}]} {
416 append t " $summary"
417 if {[string length $t] > 70} {
418 set t [string range $t 0 66]...
419 }
420 }
421 $m add command -label $t -command [cb _goback $i]
423 }
424 set X [winfo rootx $w_back]
425 set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
426 tk_popup $m $X $Y
427}
428method _goback {i} {
430 set dat [lindex $history $i]
431 set history [lrange $history 0 [expr {$i - 1}]]
432 set commit [lindex $dat 0]
433 set path [lindex $dat 1]
434 _load $this [lrange $dat 2 5]
435}
436method _read_file {fd jump} {
438 if {$fd ne $current_fd} {
439 catch {close $fd}
440 return
441 }
442 foreach i $w_columns {$i conf -state normal}
444 while {[gets $fd line] >= 0} {
445 regsub "\r\$" $line {} line
446 incr total_lines
447 lappend amov_data {}
448 lappend asim_data {}
449 if {$total_lines > 1} {
451 foreach i $w_columns {$i insert end "\n"}
452 }
453 $w_line insert end "$total_lines" linenumber
455 $w_file insert end "$line"
456 }
457 set ln_wc [expr {[string length $total_lines] + 2}]
459 if {[$w_line cget -width] < $ln_wc} {
460 $w_line conf -width $ln_wc
461 }
462 foreach i $w_columns {$i conf -state disabled}
464 if {[eof $fd]} {
466 close $fd
467 # If we don't force Tk to update the widgets *right now*
469 # none of our jump commands will cause a change in the UI.
470 #
471 update
472 if {[llength $jump] == 1} {
474 set highlight_line [lindex $jump 0]
475 $w_file see "$highlight_line.0"
476 } elseif {[llength $jump] == 4} {
477 set highlight_column [lindex $jump 0]
478 set highlight_line [lindex $jump 1]
479 $w_file xview moveto [lindex $jump 2]
480 $w_file yview moveto [lindex $jump 3]
481 }
482 _exec_blame $this $w_asim @asim_data \
484 [list] \
485 { copy/move tracking}
486 }
487} ifdeleted { catch {close $fd} }
488method _exec_blame {cur_w cur_d options cur_s} {
490 set cmd [list]
491 if {![is_Windows] || [is_Cygwin]} {
492 lappend cmd nice
493 }
494 lappend cmd git blame
495 set cmd [concat $cmd $options]
496 lappend cmd --incremental
497 if {$commit eq {}} {
498 lappend cmd --contents $path
499 } else {
500 lappend cmd $commit
501 }
502 lappend cmd -- $path
503 set fd [open "| $cmd" r]
504 fconfigure $fd -blocking 0 -translation lf -encoding binary
505 fileevent $fd readable [cb _read_blame $fd $cur_w $cur_d $cur_s]
506 set current_fd $fd
507 set blame_lines 0
508 _status $this $cur_s
509}
510method _read_blame {fd cur_w cur_d cur_s} {
512 upvar #0 $cur_d line_data
513 variable group_colors
514 if {$fd ne $current_fd} {
516 catch {close $fd}
517 return
518 }
519 $cur_w conf -state normal
521 while {[gets $fd line] >= 0} {
522 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
523 cmit original_line final_line line_count]} {
524 set r_commit $cmit
525 set r_orig_line $original_line
526 set r_final_line $final_line
527 set r_line_count $line_count
528 } elseif {[string match {filename *} $line]} {
529 set file [string range $line 9 end]
530 set n $r_line_count
531 set lno $r_final_line
532 set oln $r_orig_line
533 set cmit $r_commit
534 if {[regexp {^0{40}$} $cmit]} {
536 set commit_abbr work
537 set commit_type curr_commit
538 } elseif {$cmit eq $commit} {
539 set commit_abbr this
540 set commit_type curr_commit
541 } else {
542 set commit_type prior_commit
543 set commit_abbr [string range $cmit 0 3]
544 }
545 set author_abbr {}
547 set a_name {}
548 catch {set a_name $header($cmit,author)}
549 while {$a_name ne {}} {
550 if {![regexp {^([[:upper:]])} $a_name _a]} break
551 append author_abbr $_a
552 unset _a
553 if {![regsub \
554 {^[[:upper:]][^\s]*\s+} \
555 $a_name {} a_name ]} break
556 }
557 if {$author_abbr eq {}} {
558 set author_abbr { |}
559 } else {
560 set author_abbr [string range $author_abbr 0 3]
561 }
562 unset a_name
563 set first_lno $lno
565 while {
566 $first_lno > 1
567 && $cmit eq [lindex $line_data [expr {$first_lno - 1}] 0]
568 && $file eq [lindex $line_data [expr {$first_lno - 1}] 1]
569 } {
570 incr first_lno -1
571 }
572 set color {}
574 if {$first_lno < $lno} {
575 foreach g [$w_file tag names $first_lno.0] {
576 if {[regexp {^color[0-9]+$} $g]} {
577 set color $g
578 break
579 }
580 }
581 } else {
582 set i [lsort [concat \
583 [$w_file tag names "[expr {$first_lno - 1}].0"] \
584 [$w_file tag names "[expr {$lno + $n}].0"] \
585 ]]
586 for {set g 0} {$g < [llength $group_colors]} {incr g} {
587 if {[lsearch -sorted -exact $i color$g] == -1} {
588 set color color$g
589 break
590 }
591 }
592 }
593 if {$color eq {}} {
594 set color color0
595 }
596 while {$n > 0} {
598 set lno_e "$lno.0 lineend + 1c"
599 if {[lindex $line_data $lno] ne {}} {
600 set g [lindex $line_data $lno 0]
601 foreach i $w_columns {
602 $i tag remove g$g $lno.0 $lno_e
603 }
604 }
605 lset line_data $lno [list $cmit $file $oln]
606 $cur_w delete $lno.0 "$lno.0 lineend"
608 if {$lno == $first_lno} {
609 $cur_w insert $lno.0 $commit_abbr $commit_type
610 } elseif {$lno == [expr {$first_lno + 1}]} {
611 $cur_w insert $lno.0 $author_abbr author_abbr
612 } else {
613 $cur_w insert $lno.0 { |}
614 }
615 foreach i $w_columns {
617 if {$cur_w eq $w_amov} {
618 for {set g 0} \
619 {$g < [llength $group_colors]} \
620 {incr g} {
621 $i tag remove color$g $lno.0 $lno_e
622 }
623 $i tag add $color $lno.0 $lno_e
624 }
625 $i tag add g$cmit $lno.0 $lno_e
626 }
627 if {$highlight_column eq $cur_w} {
629 if {$highlight_line == -1
630 && [lindex [$w_file yview] 0] == 0} {
631 $w_file see $lno.0
632 set highlight_line $lno
633 }
634 if {$highlight_line == $lno} {
635 _showcommit $this $cur_w $lno
636 }
637 }
638 incr n -1
640 incr lno
641 incr oln
642 incr blame_lines
643 }
644 while {
646 $cmit eq [lindex $line_data $lno 0]
647 && $file eq [lindex $line_data $lno 1]
648 } {
649 $cur_w delete $lno.0 "$lno.0 lineend"
650 if {$lno == $first_lno} {
652 $cur_w insert $lno.0 $commit_abbr $commit_type
653 } elseif {$lno == [expr {$first_lno + 1}]} {
654 $cur_w insert $lno.0 $author_abbr author_abbr
655 } else {
656 $cur_w insert $lno.0 { |}
657 }
658 if {$cur_w eq $w_amov} {
660 foreach i $w_columns {
661 for {set g 0} \
662 {$g < [llength $group_colors]} \
663 {incr g} {
664 $i tag remove color$g $lno.0 $lno_e
665 }
666 $i tag add $color $lno.0 $lno_e
667 }
668 }
669 incr lno
671 }
672 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
674 set header($r_commit,$key) $data
675 }
676 }
677 $cur_w conf -state disabled
678 if {[eof $fd]} {
680 close $fd
681 if {$cur_w eq $w_asim} {
682 _exec_blame $this $w_amov @amov_data \
683 [list -M -C -C] \
684 { original location}
685 } else {
686 set current_fd {}
687 set status {Annotation complete.}
688 destroy $w.status.c
689 }
690 } else {
691 _status $this $cur_s
692 }
693} ifdeleted { catch {close $fd} }
694method _status {cur_s} {
696 set have $blame_lines
697 set total $total_lines
698 set pdone 0
699 if {$total} {set pdone [expr {100 * $have / $total}]}
700 set status [format \
702 "Loading%s annotations... %i of %i lines annotated (%2i%%)" \
703 $cur_s $have $total $pdone]
704 $w.status.c coords bar 0 0 $pdone 20
705}
706method _click {cur_w pos} {
708 set lno [lindex [split [$cur_w index $pos] .] 0]
709 _showcommit $this $cur_w $lno
710}
711method _load_commit {cur_w cur_d pos} {
713 upvar #0 $cur_d line_data
714 set lno [lindex [split [$cur_w index $pos] .] 0]
715 set dat [lindex $line_data $lno]
716 if {$dat ne {}} {
717 lappend history [list \
718 $commit $path \
719 $highlight_column \
720 $highlight_line \
721 [lindex [$w_file xview] 0] \
722 [lindex [$w_file yview] 0] \
723 ]
724 set commit [lindex $dat 0]
725 set path [lindex $dat 1]
726 _load $this [list [lindex $dat 2]]
727 }
728}
729method _showcommit {cur_w lno} {
731 global repo_config
732 variable active_color
733 if {$highlight_commit ne {}} {
735 foreach i $w_columns {
736 $i tag conf g$highlight_commit -background {}
737 $i tag lower g$highlight_commit
738 }
739 }
740 if {$cur_w eq $w_asim} {
742 set dat [lindex $asim_data $lno]
743 set highlight_column $w_asim
744 } else {
745 set dat [lindex $amov_data $lno]
746 set highlight_column $w_amov
747 }
748 $w_cviewer conf -state normal
750 $w_cviewer delete 0.0 end
751 if {$dat eq {}} {
753 set cmit {}
754 $w_cviewer insert end "Loading annotation..." still_loading
755 } else {
756 set cmit [lindex $dat 0]
757 set file [lindex $dat 1]
758 foreach i $w_columns {
760 $i tag conf g$cmit -background $active_color
761 $i tag raise g$cmit
762 }
763 set author_name {}
765 set author_email {}
766 set author_time {}
767 catch {set author_name $header($cmit,author)}
768 catch {set author_email $header($cmit,author-mail)}
769 catch {set author_time [clock format \
770 $header($cmit,author-time) \
771 -format {%Y-%m-%d %H:%M:%S}
772 ]}
773 set committer_name {}
775 set committer_email {}
776 set committer_time {}
777 catch {set committer_name $header($cmit,committer)}
778 catch {set committer_email $header($cmit,committer-mail)}
779 catch {set committer_time [clock format \
780 $header($cmit,committer-time) \
781 -format {%Y-%m-%d %H:%M:%S}
782 ]}
783 if {[catch {set msg $header($cmit,message)}]} {
785 set msg {}
786 catch {
787 set fd [open "| git cat-file commit $cmit" r]
788 fconfigure $fd -encoding binary -translation lf
789 if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
790 set enc utf-8
791 }
792 while {[gets $fd line] > 0} {
793 if {[string match {encoding *} $line]} {
794 set enc [string tolower [string range $line 9 end]]
795 }
796 }
797 set msg [encoding convertfrom $enc [read $fd]]
798 set msg [string trim $msg]
799 close $fd
800 set author_name [encoding convertfrom $enc $author_name]
802 set committer_name [encoding convertfrom $enc $committer_name]
803 set header($cmit,author) $author_name
805 set header($cmit,committer) $committer_name
806 }
807 set header($cmit,message) $msg
808 }
809 $w_cviewer insert end "commit $cmit\n" header_key
811 $w_cviewer insert end "Author:\t" header_key
812 $w_cviewer insert end "$author_name $author_email" header_val
813 $w_cviewer insert end " $author_time\n" header_val
814 $w_cviewer insert end "Committer:\t" header_key
816 $w_cviewer insert end "$committer_name $committer_email" header_val
817 $w_cviewer insert end " $committer_time\n" header_val
818 if {$file ne $path} {
820 $w_cviewer insert end "Original File:\t" header_key
821 $w_cviewer insert end "[escape_path $file]\n" header_val
822 }
823 $w_cviewer insert end "\n$msg"
825 }
826 $w_cviewer conf -state disabled
827 set highlight_line $lno
829 set highlight_commit $cmit
830 if {[lsearch -exact $tooltip_commit $highlight_commit] != -1} {
832 _hide_tooltip $this
833 }
834}
835method _copycommit {} {
837 set pos @$::cursorX,$::cursorY
838 set lno [lindex [split [$::cursorW index $pos] .] 0]
839 set dat [lindex $amov_data $lno]
840 if {$dat ne {}} {
841 clipboard clear
842 clipboard append \
843 -format STRING \
844 -type STRING \
845 -- [lindex $dat 0]
846 }
847}
848method _show_tooltip {cur_w pos} {
850 if {$tooltip_wm ne {}} {
851 _open_tooltip $this $cur_w
852 } elseif {$tooltip_timer eq {}} {
853 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
854 }
855}
856method _open_tooltip {cur_w} {
858 set tooltip_timer {}
859 set pos_x [winfo pointerx $cur_w]
860 set pos_y [winfo pointery $cur_w]
861 if {[winfo containing $pos_x $pos_y] ne $cur_w} {
862 _hide_tooltip $this
863 return
864 }
865 if {$tooltip_wm ne "$cur_w.tooltip"} {
867 _hide_tooltip $this
868 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
870 wm overrideredirect $tooltip_wm 1
871 wm transient $tooltip_wm [winfo toplevel $cur_w]
872 set tooltip_t $tooltip_wm.label
873 text $tooltip_t \
874 -takefocus 0 \
875 -highlightthickness 0 \
876 -relief flat \
877 -borderwidth 0 \
878 -wrap none \
879 -background lightyellow \
880 -foreground black
881 $tooltip_t tag conf section_header -font font_uibold
882 pack $tooltip_t
883 } else {
884 $tooltip_t conf -state normal
885 $tooltip_t delete 0.0 end
886 }
887 set pos @[join [list \
889 [expr {$pos_x - [winfo rootx $cur_w]}] \
890 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
891 set lno [lindex [split [$cur_w index $pos] .] 0]
892 if {$cur_w eq $w_amov} {
893 set dat [lindex $amov_data $lno]
894 set org {}
895 } else {
896 set dat [lindex $asim_data $lno]
897 set org [lindex $amov_data $lno]
898 }
899 set cmit [lindex $dat 0]
901 set tooltip_commit [list $cmit]
902 set author_name {}
904 set summary {}
905 set author_time {}
906 catch {set author_name $header($cmit,author)}
907 catch {set summary $header($cmit,summary)}
908 catch {set author_time [clock format \
909 $header($cmit,author-time) \
910 -format {%Y-%m-%d %H:%M:%S}
911 ]}
912 $tooltip_t insert end "commit $cmit\n"
914 $tooltip_t insert end "$author_name $author_time\n"
915 $tooltip_t insert end "$summary"
916 if {$org ne {} && [lindex $org 0] ne $cmit} {
918 set save [$tooltip_t get 0.0 end]
919 $tooltip_t delete 0.0 end
920 set cmit [lindex $org 0]
922 set file [lindex $org 1]
923 lappend tooltip_commit $cmit
924 set author_name {}
926 set summary {}
927 set author_time {}
928 catch {set author_name $header($cmit,author)}
929 catch {set summary $header($cmit,summary)}
930 catch {set author_time [clock format \
931 $header($cmit,author-time) \
932 -format {%Y-%m-%d %H:%M:%S}
933 ]}
934 $tooltip_t insert end "Originally By:\n" section_header
936 $tooltip_t insert end "commit $cmit\n"
937 $tooltip_t insert end "$author_name $author_time\n"
938 $tooltip_t insert end "$summary\n"
939 if {$file ne $path} {
941 $tooltip_t insert end "In File: " section_header
942 $tooltip_t insert end "$file\n"
943 }
944 $tooltip_t insert end "\n"
946 $tooltip_t insert end "Copied Or Moved Here By:\n" section_header
947 $tooltip_t insert end $save
948 }
949 $tooltip_t conf -state disabled
951 _position_tooltip $this
952}
953method _position_tooltip {} {
955 set max_h [lindex [split [$tooltip_t index end] .] 0]
956 set max_w 0
957 for {set i 1} {$i <= $max_h} {incr i} {
958 set c [lindex [split [$tooltip_t index "$i.0 lineend"] .] 1]
959 if {$c > $max_w} {set max_w $c}
960 }
961 $tooltip_t conf -width $max_w -height $max_h
962 set req_w [winfo reqwidth $tooltip_t]
964 set req_h [winfo reqheight $tooltip_t]
965 set pos_x [expr {[winfo pointerx .] + 5}]
966 set pos_y [expr {[winfo pointery .] + 10}]
967 set g "${req_w}x${req_h}"
969 if {$pos_x >= 0} {append g +}
970 append g $pos_x
971 if {$pos_y >= 0} {append g +}
972 append g $pos_y
973 wm geometry $tooltip_wm $g
975 raise $tooltip_wm
976}
977method _hide_tooltip {} {
979 if {$tooltip_wm ne {}} {
980 destroy $tooltip_wm
981 set tooltip_wm {}
982 set tooltip_commit {}
983 }
984 if {$tooltip_timer ne {}} {
985 after cancel $tooltip_timer
986 set tooltip_timer {}
987 }
988}
989method _resize {new_height} {
991 set diff [expr {$new_height - $old_height}]
992 if {$diff == 0} return
993 set my [expr {[winfo height $w.file_pane] - 25}]
995 set o [$w.file_pane sash coord 0]
996 set ox [lindex $o 0]
997 set oy [expr {[lindex $o 1] + $diff}]
998 if {$oy < 0} {set oy 0}
999 if {$oy > $my} {set oy $my}
1000 $w.file_pane sash place 0 $ox $oy
1001 set old_height $new_height
1003}
1004}