bc81e29b4399a1fcb7d651d247528162229b4eda
1# git-gui blame viewer
2# Copyright (C) 2006, 2007 Shawn Pearce
3class blame {
5image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
7# Persistant data (survives loads)
9#
10field history {}; # viewer history: {commit path}
11field header ; # array commit,key -> header field
12# Tk UI control paths
14#
15field w ; # top window in this viewer
16field w_back ; # our back button
17field w_path ; # label showing the current file path
18field w_columns ; # list of all column widgets in the viewer
19field w_line ; # text column: all line numbers
20field w_amov ; # text column: annotations + move tracking
21field w_asim ; # text column: annotations (simple computation)
22field w_file ; # text column: actual file data
23field w_cviewer ; # pane showing commit message
24field finder ; # find mini-dialog frame
25field gotoline ; # line goto mini-dialog frame
26field status ; # status mega-widget instance
27field old_height ; # last known height of $w.file_pane
28# Tk UI colors
31#
32variable active_color #c0edc5
33variable group_colors {
34 #d6d6d6
35 #e1e1e1
36 #ececec
37}
38# Current blame data; cleared/reset on each load
40#
41field commit ; # input commit to blame
42field path ; # input filename to view in $commit
43field current_fd {} ; # background process running
45field highlight_line -1 ; # current line selected
46field highlight_column {} ; # current commit column selected
47field highlight_commit {} ; # sha1 of commit selected
48field total_lines 0 ; # total length of file
50field blame_lines 0 ; # number of lines computed
51field amov_data ; # list of {commit origfile origline}
52field asim_data ; # list of {commit origfile origline}
53field r_commit ; # commit currently being parsed
55field r_orig_line ; # original line number
56field r_final_line ; # final line number
57field r_line_count ; # lines in this region
58field tooltip_wm {} ; # Current tooltip toplevel, if open
60field tooltip_t {} ; # Text widget in $tooltip_wm
61field tooltip_timer {} ; # Current timer event for our tooltip
62field tooltip_commit {} ; # Commit(s) in tooltip
63constructor new {i_commit i_path i_jump} {
65 global cursor_ptr M1B M1T have_tk85 use_ttk NS
66 variable active_color
67 variable group_colors
68 set commit $i_commit
70 set path $i_path
71 make_toplevel top w
73 wm title $top [append "[appname] ([reponame]): " [mc "File Viewer"]]
74 set font_w [font measure font_diff "0"]
76 gold_frame $w.header
78 tlabel $w.header.commit_l \
79 -text [mc "Commit:"] \
80 -background gold \
81 -foreground black \
82 -anchor w \
83 -justify left
84 set w_back $w.header.commit_b
85 tlabel $w_back \
86 -image ::blame::img_back_arrow \
87 -borderwidth 0 \
88 -relief flat \
89 -state disabled \
90 -background gold \
91 -foreground black \
92 -activebackground gold
93 bind $w_back <Button-1> "
94 if {\[$w_back cget -state\] eq {normal}} {
95 [cb _history_menu]
96 }
97 "
98 tlabel $w.header.commit \
99 -textvariable @commit \
100 -background gold \
101 -foreground black \
102 -anchor w \
103 -justify left
104 tlabel $w.header.path_l \
105 -text [mc "File:"] \
106 -background gold \
107 -foreground black \
108 -anchor w \
109 -justify left
110 set w_path $w.header.path
111 tlabel $w_path \
112 -background gold \
113 -foreground black \
114 -anchor w \
115 -justify left
116 pack $w.header.commit_l -side left
117 pack $w_back -side left
118 pack $w.header.commit -side left
119 pack $w_path -fill x -side right
120 pack $w.header.path_l -side right
121 panedwindow $w.file_pane -orient vertical -borderwidth 0 -sashwidth 3
123 frame $w.file_pane.out -relief flat -borderwidth 1
124 frame $w.file_pane.cm -relief sunken -borderwidth 1
125 $w.file_pane add $w.file_pane.out \
126 -sticky nsew \
127 -minsize 100 \
128 -height 100 \
129 -width 100
130 $w.file_pane add $w.file_pane.cm \
131 -sticky nsew \
132 -minsize 25 \
133 -height 25 \
134 -width 100
135 set w_line $w.file_pane.out.linenumber_t
137 text $w_line \
138 -takefocus 0 \
139 -highlightthickness 0 \
140 -padx 0 -pady 0 \
141 -background white \
142 -foreground black \
143 -borderwidth 0 \
144 -state disabled \
145 -wrap none \
146 -height 40 \
147 -width 6 \
148 -font font_diff
149 $w_line tag conf linenumber -justify right -rmargin 5
150 set w_amov $w.file_pane.out.amove_t
152 text $w_amov \
153 -takefocus 0 \
154 -highlightthickness 0 \
155 -padx 0 -pady 0 \
156 -background white \
157 -foreground black \
158 -borderwidth 0 \
159 -state disabled \
160 -wrap none \
161 -height 40 \
162 -width 5 \
163 -font font_diff
164 $w_amov tag conf author_abbr -justify right -rmargin 5
165 $w_amov tag conf curr_commit
166 $w_amov tag conf prior_commit -foreground blue -underline 1
167 $w_amov tag bind prior_commit \
168 <Button-1> \
169 "[cb _load_commit $w_amov @amov_data @%x,%y];break"
170 set w_asim $w.file_pane.out.asimple_t
172 text $w_asim \
173 -takefocus 0 \
174 -highlightthickness 0 \
175 -padx 0 -pady 0 \
176 -background white \
177 -foreground black \
178 -borderwidth 0 \
179 -state disabled \
180 -wrap none \
181 -height 40 \
182 -width 4 \
183 -font font_diff
184 $w_asim tag conf author_abbr -justify right
185 $w_asim tag conf curr_commit
186 $w_asim tag conf prior_commit -foreground blue -underline 1
187 $w_asim tag bind prior_commit \
188 <Button-1> \
189 "[cb _load_commit $w_asim @asim_data @%x,%y];break"
190 set w_file $w.file_pane.out.file_t
192 text $w_file \
193 -takefocus 0 \
194 -highlightthickness 0 \
195 -padx 0 -pady 0 \
196 -background white \
197 -foreground black \
198 -borderwidth 0 \
199 -state disabled \
200 -wrap none \
201 -height 40 \
202 -width 80 \
203 -xscrollcommand [list $w.file_pane.out.sbx set] \
204 -font font_diff
205 if {$have_tk85} {
206 $w_file configure -inactiveselectbackground darkblue
207 }
208 $w_file tag conf found \
209 -background yellow
210 set w_columns [list $w_amov $w_asim $w_line $w_file]
212 ${NS}::scrollbar $w.file_pane.out.sbx \
214 -orient h \
215 -command [list $w_file xview]
216 ${NS}::scrollbar $w.file_pane.out.sby \
217 -orient v \
218 -command [list scrollbar2many $w_columns yview]
219 eval grid $w_columns $w.file_pane.out.sby -sticky nsew
220 grid conf \
221 $w.file_pane.out.sbx \
222 -column [expr {[llength $w_columns] - 1}] \
223 -sticky we
224 grid columnconfigure \
225 $w.file_pane.out \
226 [expr {[llength $w_columns] - 1}] \
227 -weight 1
228 grid rowconfigure $w.file_pane.out 0 -weight 1
229 set finder [::searchbar::new \
231 $w.file_pane.out.ff $w_file \
232 -column [expr {[llength $w_columns] - 1}] \
233 ]
234 set gotoline [::linebar::new \
236 $w.file_pane.out.lf $w_file \
237 -column [expr {[llength $w_columns] - 1}] \
238 ]
239 set w_cviewer $w.file_pane.cm.t
241 text $w_cviewer \
242 -background white \
243 -foreground black \
244 -borderwidth 0 \
245 -state disabled \
246 -wrap none \
247 -height 10 \
248 -width 80 \
249 -xscrollcommand [list $w.file_pane.cm.sbx set] \
250 -yscrollcommand [list $w.file_pane.cm.sby set] \
251 -font font_diff
252 $w_cviewer tag conf still_loading \
253 -font font_uiitalic \
254 -justify center
255 $w_cviewer tag conf header_key \
256 -tabs {3c} \
257 -background $active_color \
258 -font font_uibold
259 $w_cviewer tag conf header_val \
260 -background $active_color \
261 -font font_ui
262 $w_cviewer tag raise sel
263 ${NS}::scrollbar $w.file_pane.cm.sbx \
264 -orient h \
265 -command [list $w_cviewer xview]
266 ${NS}::scrollbar $w.file_pane.cm.sby \
267 -orient v \
268 -command [list $w_cviewer yview]
269 pack $w.file_pane.cm.sby -side right -fill y
270 pack $w.file_pane.cm.sbx -side bottom -fill x
271 pack $w_cviewer -expand 1 -fill both
272 set status [::status_bar::new $w.status]
274 menu $w.ctxm -tearoff 0
276 $w.ctxm add command \
277 -label [mc "Copy Commit"] \
278 -command [cb _copycommit]
279 $w.ctxm add separator
280 $w.ctxm add command \
281 -label [mc "Find Text..."] \
282 -accelerator F7 \
283 -command [list searchbar::show $finder]
284 $w.ctxm add command \
285 -label [mc "Goto Line..."] \
286 -accelerator "Ctrl-G" \
287 -command [list linebar::show $gotoline]
288 menu $w.ctxm.enc
289 build_encoding_menu $w.ctxm.enc [cb _setencoding]
290 $w.ctxm add cascade \
291 -label [mc "Encoding"] \
292 -menu $w.ctxm.enc
293 $w.ctxm add command \
294 -label [mc "Do Full Copy Detection"] \
295 -command [cb _fullcopyblame]
296 $w.ctxm add separator
297 $w.ctxm add command \
298 -label [mc "Show History Context"] \
299 -command [cb _gitkcommit]
300 $w.ctxm add command \
301 -label [mc "Blame Parent Commit"] \
302 -command [cb _blameparent]
303 foreach i $w_columns {
305 for {set g 0} {$g < [llength $group_colors]} {incr g} {
306 $i tag conf color$g -background [lindex $group_colors $g]
307 }
308 if {$i eq $w_file} {
310 $w_file tag raise found
311 }
312 $i tag raise sel
313 $i conf -cursor $cursor_ptr
315 $i conf -yscrollcommand \
316 "[list ::searchbar::scrolled $finder]
317 [list many2scrollbar $w_columns yview $w.file_pane.out.sby]"
318 bind $i <Button-1> "
319 [cb _hide_tooltip]
320 [cb _click $i @%x,%y]
321 focus $i
322 "
323 bind $i <Any-Motion> [cb _show_tooltip $i @%x,%y]
324 bind $i <Any-Enter> [cb _hide_tooltip]
325 bind $i <Any-Leave> [cb _hide_tooltip]
326 bind_button3 $i "
327 [cb _hide_tooltip]
328 set cursorX %x
329 set cursorY %y
330 set cursorW %W
331 tk_popup $w.ctxm %X %Y
332 "
333 bind $i <Shift-Tab> "[list focus $w_cviewer];break"
334 bind $i <Tab> "[cb _focus_search $w_cviewer];break"
335 }
336 foreach i [concat $w_columns $w_cviewer] {
338 bind $i <Key-Up> {catch {%W yview scroll -1 units};break}
339 bind $i <Key-Down> {catch {%W yview scroll 1 units};break}
340 bind $i <Key-Left> {catch {%W xview scroll -1 units};break}
341 bind $i <Key-Right> {catch {%W xview scroll 1 units};break}
342 bind $i <Key-k> {catch {%W yview scroll -1 units};break}
343 bind $i <Key-j> {catch {%W yview scroll 1 units};break}
344 bind $i <Key-h> {catch {%W xview scroll -1 units};break}
345 bind $i <Key-l> {catch {%W xview scroll 1 units};break}
346 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
347 bind $i <Control-Key-f> {catch {%W yview scroll 1 pages};break}
348 }
349 bind $w_cviewer <Shift-Tab> "[cb _focus_search $w_file];break"
351 bind $w_cviewer <Tab> "[list focus $w_file];break"
352 bind $w_cviewer <Button-1> [list focus $w_cviewer]
353 bind $w_file <Visibility> [cb _focus_search $w_file]
354 bind $top <F7> [list searchbar::show $finder]
355 bind $top <Key-slash> [list searchbar::show $finder]
356 bind $top <Control-Key-s> [list searchbar::show $finder]
357 bind $top <Escape> [list searchbar::hide $finder]
358 bind $top <F3> [list searchbar::find_next $finder]
359 bind $top <Key-n> [list searchbar::find_next $finder]
360 bind $top <Shift-F3> [list searchbar::find_prev $finder]
361 bind $top <Shift-Key-n> [list searchbar::find_prev $finder]
362 bind $top <Control-Key-g> [list linebar::show $gotoline]
363 catch { bind $top <Shift-Key-XF86_Switch_VT_3> [list searchbar::find_prev $finder] }
364 grid configure $w.header -sticky ew
366 grid configure $w.file_pane -sticky nsew
367 grid configure $w.status -sticky ew
368 grid columnconfigure $top 0 -weight 1
369 grid rowconfigure $top 0 -weight 0
370 grid rowconfigure $top 1 -weight 1
371 grid rowconfigure $top 2 -weight 0
372 set req_w [winfo reqwidth $top]
374 set req_h [winfo reqheight $top]
375 set scr_w [expr {[winfo screenwidth $top] - 40}]
376 set scr_h [expr {[winfo screenheight $top] - 120}]
377 set opt_w [expr {$font_w * (80 + 5*3 + 3)}]
378 if {$req_w < $opt_w} {set req_w $opt_w}
379 if {$req_w > $scr_w} {set req_w $scr_w}
380 set opt_h [expr {$req_w*4/3}]
381 if {$req_h < $scr_h} {set req_h $scr_h}
382 if {$req_h > $opt_h} {set req_h $opt_h}
383 set g "${req_w}x${req_h}"
384 wm geometry $top $g
385 update
386 set old_height [winfo height $w.file_pane]
388 $w.file_pane sash place 0 \
389 [lindex [$w.file_pane sash coord 0] 0] \
390 [expr {int($old_height * 0.80)}]
391 bind $w.file_pane <Configure> \
392 "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
393 wm protocol $top WM_DELETE_WINDOW "destroy $top"
395 bind $top <Destroy> [cb _handle_destroy %W]
396 _load $this $i_jump
398}
399method _focus_search {win} {
401 if {[searchbar::visible $finder]} {
402 focus [searchbar::editor $finder]
403 } else {
404 focus $win
405 }
406}
407method _handle_destroy {win} {
409 if {$win eq $w} {
410 _kill $this
411 delete_this
412 }
413}
414method _kill {} {
416 if {$current_fd ne {}} {
417 kill_file_process $current_fd
418 catch {close $current_fd}
419 set current_fd {}
420 }
421}
422method _load {jump} {
424 variable group_colors
425 _hide_tooltip $this
427 if {$total_lines != 0 || $current_fd ne {}} {
429 _kill $this
430 foreach i $w_columns {
432 $i conf -state normal
433 $i delete 0.0 end
434 foreach g [$i tag names] {
435 if {[regexp {^g[0-9a-f]{40}$} $g]} {
436 $i tag delete $g
437 }
438 }
439 $i conf -state disabled
440 }
441 $w_cviewer conf -state normal
443 $w_cviewer delete 0.0 end
444 $w_cviewer conf -state disabled
445 set highlight_line -1
447 set highlight_column {}
448 set highlight_commit {}
449 set total_lines 0
450 }
451 if {$history eq {}} {
453 $w_back conf -state disabled
454 } else {
455 $w_back conf -state normal
456 }
457 # Index 0 is always empty. There is never line 0 as
459 # we use only 1 based lines, as that matches both with
460 # git-blame output and with Tk's text widget.
461 #
462 set amov_data [list [list]]
463 set asim_data [list [list]]
464 $status show [mc "Reading %s..." "$commit:[escape_path $path]"]
466 $w_path conf -text [escape_path $path]
467 set do_textconv 0
469 if {![is_config_false gui.textconv] && [git-version >= 1.7.2]} {
470 set filter [gitattr $path diff set]
471 set textconv [get_config [join [list diff $filter textconv] .]]
472 if {$filter ne {set} && $textconv ne {}} {
473 set do_textconv 1
474 }
475 }
476 if {$commit eq {}} {
477 if {$do_textconv ne 0} {
478 # Run textconv with sh -c "..." to allow it to
479 # contain command + arguments. On windows, just
480 # call the filter command.
481 if {![file executable [shellpath]]} {
482 set fd [open |[linsert $textconv end $path] r]
483 } else {
484 set fd [open |[list [shellpath] -c "$textconv \"\$0\"" $path] r]
485 }
486 } else {
487 set fd [open $path r]
488 }
489 fconfigure $fd -eofchar {}
490 } else {
491 if {$do_textconv ne 0} {
492 set fd [git_read cat-file --textconv "$commit:$path"]
493 } else {
494 set fd [git_read cat-file blob "$commit:$path"]
495 }
496 }
497 fconfigure $fd \
498 -blocking 0 \
499 -translation lf \
500 -encoding [get_path_encoding $path]
501 fileevent $fd readable [cb _read_file $fd $jump]
502 set current_fd $fd
503}
504method _history_menu {} {
506 set m $w.backmenu
507 if {[winfo exists $m]} {
508 $m delete 0 end
509 } else {
510 menu $m -tearoff 0
511 }
512 for {set i [expr {[llength $history] - 1}]
514 } {$i >= 0} {incr i -1} {
515 set e [lindex $history $i]
516 set c [lindex $e 0]
517 set f [lindex $e 1]
518 if {[regexp {^[0-9a-f]{40}$} $c]} {
520 set t [string range $c 0 8]...
521 } elseif {$c eq {}} {
522 set t {Working Directory}
523 } else {
524 set t $c
525 }
526 if {![catch {set summary $header($c,summary)}]} {
527 append t " $summary"
528 if {[string length $t] > 70} {
529 set t [string range $t 0 66]...
530 }
531 }
532 $m add command -label $t -command [cb _goback $i]
534 }
535 set X [winfo rootx $w_back]
536 set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
537 tk_popup $m $X $Y
538}
539method _goback {i} {
541 set dat [lindex $history $i]
542 set history [lrange $history 0 [expr {$i - 1}]]
543 set commit [lindex $dat 0]
544 set path [lindex $dat 1]
545 _load $this [lrange $dat 2 5]
546}
547method _read_file {fd jump} {
549 if {$fd ne $current_fd} {
550 catch {close $fd}
551 return
552 }
553 foreach i $w_columns {$i conf -state normal}
555 while {[gets $fd line] >= 0} {
556 regsub "\r\$" $line {} line
557 incr total_lines
558 lappend amov_data {}
559 lappend asim_data {}
560 if {$total_lines > 1} {
562 foreach i $w_columns {$i insert end "\n"}
563 }
564 $w_line insert end "$total_lines" linenumber
566 $w_file insert end "$line"
567 }
568 set ln_wc [expr {[string length $total_lines] + 2}]
570 if {[$w_line cget -width] < $ln_wc} {
571 $w_line conf -width $ln_wc
572 }
573 foreach i $w_columns {$i conf -state disabled}
575 if {[eof $fd]} {
577 close $fd
578 # If we don't force Tk to update the widgets *right now*
580 # none of our jump commands will cause a change in the UI.
581 #
582 update
583 if {[llength $jump] == 1} {
585 set highlight_line [lindex $jump 0]
586 $w_file see "$highlight_line.0"
587 } elseif {[llength $jump] == 4} {
588 set highlight_column [lindex $jump 0]
589 set highlight_line [lindex $jump 1]
590 $w_file xview moveto [lindex $jump 2]
591 $w_file yview moveto [lindex $jump 3]
592 }
593 _exec_blame $this $w_asim @asim_data \
595 [list] \
596 [mc "Loading copy/move tracking annotations..."]
597 }
598} ifdeleted { catch {close $fd} }
599method _exec_blame {cur_w cur_d options cur_s} {
601 lappend options --incremental --encoding=utf-8
602 if {$commit eq {}} {
603 lappend options --contents $path
604 } else {
605 lappend options $commit
606 }
607 lappend options -- $path
608 set fd [eval git_read --nice blame $options]
609 fconfigure $fd -blocking 0 -translation lf -encoding utf-8
610 fileevent $fd readable [cb _read_blame $fd $cur_w $cur_d]
611 set current_fd $fd
612 set blame_lines 0
613 $status start \
615 $cur_s \
616 [mc "lines annotated"]
617}
618method _read_blame {fd cur_w cur_d} {
620 upvar #0 $cur_d line_data
621 variable group_colors
622 if {$fd ne $current_fd} {
624 catch {close $fd}
625 return
626 }
627 $cur_w conf -state normal
629 while {[gets $fd line] >= 0} {
630 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
631 cmit original_line final_line line_count]} {
632 set r_commit $cmit
633 set r_orig_line $original_line
634 set r_final_line $final_line
635 set r_line_count $line_count
636 } elseif {[string match {filename *} $line]} {
637 set file [string range $line 9 end]
638 set n $r_line_count
639 set lno $r_final_line
640 set oln $r_orig_line
641 set cmit $r_commit
642 if {[regexp {^0{40}$} $cmit]} {
644 set commit_abbr work
645 set commit_type curr_commit
646 } elseif {$cmit eq $commit} {
647 set commit_abbr this
648 set commit_type curr_commit
649 } else {
650 set commit_type prior_commit
651 set commit_abbr [string range $cmit 0 3]
652 }
653 set author_abbr {}
655 set a_name {}
656 catch {set a_name $header($cmit,author)}
657 while {$a_name ne {}} {
658 if {$author_abbr ne {}
659 && [string index $a_name 0] eq {'}} {
660 regsub {^'[^']+'\s+} $a_name {} a_name
661 }
662 if {![regexp {^([[:upper:]])} $a_name _a]} break
663 append author_abbr $_a
664 unset _a
665 if {![regsub \
666 {^[[:upper:]][^\s]*\s+} \
667 $a_name {} a_name ]} break
668 }
669 if {$author_abbr eq {}} {
670 set author_abbr { |}
671 } else {
672 set author_abbr [string range $author_abbr 0 3]
673 }
674 unset a_name
675 set first_lno $lno
677 while {
678 $first_lno > 1
679 && $cmit eq [lindex $line_data [expr {$first_lno - 1}] 0]
680 && $file eq [lindex $line_data [expr {$first_lno - 1}] 1]
681 } {
682 incr first_lno -1
683 }
684 set color {}
686 if {$first_lno < $lno} {
687 foreach g [$w_file tag names $first_lno.0] {
688 if {[regexp {^color[0-9]+$} $g]} {
689 set color $g
690 break
691 }
692 }
693 } else {
694 set i [lsort [concat \
695 [$w_file tag names "[expr {$first_lno - 1}].0"] \
696 [$w_file tag names "[expr {$lno + $n}].0"] \
697 ]]
698 for {set g 0} {$g < [llength $group_colors]} {incr g} {
699 if {[lsearch -sorted -exact $i color$g] == -1} {
700 set color color$g
701 break
702 }
703 }
704 }
705 if {$color eq {}} {
706 set color color0
707 }
708 while {$n > 0} {
710 set lno_e "$lno.0 lineend + 1c"
711 if {[lindex $line_data $lno] ne {}} {
712 set g [lindex $line_data $lno 0]
713 foreach i $w_columns {
714 $i tag remove g$g $lno.0 $lno_e
715 }
716 }
717 lset line_data $lno [list $cmit $file $oln]
718 $cur_w delete $lno.0 "$lno.0 lineend"
720 if {$lno == $first_lno} {
721 $cur_w insert $lno.0 $commit_abbr $commit_type
722 } elseif {$lno == [expr {$first_lno + 1}]} {
723 $cur_w insert $lno.0 $author_abbr author_abbr
724 } else {
725 $cur_w insert $lno.0 { |}
726 }
727 foreach i $w_columns {
729 if {$cur_w eq $w_amov} {
730 for {set g 0} \
731 {$g < [llength $group_colors]} \
732 {incr g} {
733 $i tag remove color$g $lno.0 $lno_e
734 }
735 $i tag add $color $lno.0 $lno_e
736 }
737 $i tag add g$cmit $lno.0 $lno_e
738 }
739 if {$highlight_column eq $cur_w} {
741 if {$highlight_line == -1
742 && [lindex [$w_file yview] 0] == 0} {
743 $w_file see $lno.0
744 set highlight_line $lno
745 }
746 if {$highlight_line == $lno} {
747 _showcommit $this $cur_w $lno
748 }
749 }
750 incr n -1
752 incr lno
753 incr oln
754 incr blame_lines
755 }
756 while {
758 $cmit eq [lindex $line_data $lno 0]
759 && $file eq [lindex $line_data $lno 1]
760 } {
761 $cur_w delete $lno.0 "$lno.0 lineend"
762 if {$lno == $first_lno} {
764 $cur_w insert $lno.0 $commit_abbr $commit_type
765 } elseif {$lno == [expr {$first_lno + 1}]} {
766 $cur_w insert $lno.0 $author_abbr author_abbr
767 } else {
768 $cur_w insert $lno.0 { |}
769 }
770 if {$cur_w eq $w_amov} {
772 foreach i $w_columns {
773 for {set g 0} \
774 {$g < [llength $group_colors]} \
775 {incr g} {
776 $i tag remove color$g $lno.0 $lno_e
777 }
778 $i tag add $color $lno.0 $lno_e
779 }
780 }
781 incr lno
783 }
784 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
786 set header($r_commit,$key) $data
787 }
788 }
789 $cur_w conf -state disabled
790 if {[eof $fd]} {
792 close $fd
793 if {$cur_w eq $w_asim} {
794 # Switches for original location detection
795 set threshold [get_config gui.copyblamethreshold]
796 set original_options [list "-C$threshold"]
797 if {![is_config_true gui.fastcopyblame]} {
799 # thorough copy search; insert before the threshold
800 set original_options [linsert $original_options 0 -C]
801 }
802 if {[git-version >= 1.5.3]} {
803 lappend original_options -w ; # ignore indentation changes
804 }
805 _exec_blame $this $w_amov @amov_data \
807 $original_options \
808 [mc "Loading original location annotations..."]
809 } else {
810 set current_fd {}
811 $status stop [mc "Annotation complete."]
812 }
813 } else {
814 $status update $blame_lines $total_lines
815 }
816} ifdeleted { catch {close $fd} }
817method _find_commit_bound {data_list start_idx delta} {
819 upvar #0 $data_list line_data
820 set pos $start_idx
821 set limit [expr {[llength $line_data] - 1}]
822 set base_commit [lindex $line_data $pos 0]
823 while {$pos > 0 && $pos < $limit} {
825 set new_pos [expr {$pos + $delta}]
826 if {[lindex $line_data $new_pos 0] ne $base_commit} {
827 return $pos
828 }
829 set pos $new_pos
831 }
832 return $pos
834}
835method _fullcopyblame {} {
837 if {$current_fd ne {}} {
838 tk_messageBox \
839 -icon error \
840 -type ok \
841 -title [mc "Busy"] \
842 -message [mc "Annotation process is already running."]
843 return
845 }
846 # Switches for original location detection
848 set threshold [get_config gui.copyblamethreshold]
849 set original_options [list -C -C "-C$threshold"]
850 if {[git-version >= 1.5.3]} {
852 lappend original_options -w ; # ignore indentation changes
853 }
854 # Find the line range
856 set pos @$::cursorX,$::cursorY
857 set lno [lindex [split [$::cursorW index $pos] .] 0]
858 set min_amov_lno [_find_commit_bound $this @amov_data $lno -1]
859 set max_amov_lno [_find_commit_bound $this @amov_data $lno 1]
860 set min_asim_lno [_find_commit_bound $this @asim_data $lno -1]
861 set max_asim_lno [_find_commit_bound $this @asim_data $lno 1]
862 if {$min_asim_lno < $min_amov_lno} {
864 set min_amov_lno $min_asim_lno
865 }
866 if {$max_asim_lno > $max_amov_lno} {
868 set max_amov_lno $max_asim_lno
869 }
870 lappend original_options -L "$min_amov_lno,$max_amov_lno"
872 # Clear lines
874 for {set i $min_amov_lno} {$i <= $max_amov_lno} {incr i} {
875 lset amov_data $i [list ]
876 }
877 # Start the back-end process
879 _exec_blame $this $w_amov @amov_data \
880 $original_options \
881 [mc "Running thorough copy detection..."]
882}
883method _click {cur_w pos} {
885 set lno [lindex [split [$cur_w index $pos] .] 0]
886 _showcommit $this $cur_w $lno
887}
888method _setencoding {enc} {
890 force_path_encoding $path $enc
891 _load $this [list \
892 $highlight_column \
893 $highlight_line \
894 [lindex [$w_file xview] 0] \
895 [lindex [$w_file yview] 0] \
896 ]
897}
898method _load_commit {cur_w cur_d pos} {
900 upvar #0 $cur_d line_data
901 set lno [lindex [split [$cur_w index $pos] .] 0]
902 set dat [lindex $line_data $lno]
903 if {$dat ne {}} {
904 _load_new_commit $this \
905 [lindex $dat 0] \
906 [lindex $dat 1] \
907 [list [lindex $dat 2]]
908 }
909}
910method _load_new_commit {new_commit new_path jump} {
912 lappend history [list \
913 $commit $path \
914 $highlight_column \
915 $highlight_line \
916 [lindex [$w_file xview] 0] \
917 [lindex [$w_file yview] 0] \
918 ]
919 set commit $new_commit
921 set path $new_path
922 _load $this $jump
923}
924method _showcommit {cur_w lno} {
926 global repo_config
927 variable active_color
928 if {$highlight_commit ne {}} {
930 foreach i $w_columns {
931 $i tag conf g$highlight_commit -background {}
932 $i tag lower g$highlight_commit
933 }
934 }
935 if {$cur_w eq $w_asim} {
937 set dat [lindex $asim_data $lno]
938 set highlight_column $w_asim
939 } else {
940 set dat [lindex $amov_data $lno]
941 set highlight_column $w_amov
942 }
943 $w_cviewer conf -state normal
945 $w_cviewer delete 0.0 end
946 if {$dat eq {}} {
948 set cmit {}
949 $w_cviewer insert end [mc "Loading annotation..."] still_loading
950 } else {
951 set cmit [lindex $dat 0]
952 set file [lindex $dat 1]
953 foreach i $w_columns {
955 $i tag conf g$cmit -background $active_color
956 $i tag raise g$cmit
957 if {$i eq $w_file} {
958 $w_file tag raise found
959 }
960 $i tag raise sel
961 }
962 set author_name {}
964 set author_email {}
965 set author_time {}
966 catch {set author_name $header($cmit,author)}
967 catch {set author_email $header($cmit,author-mail)}
968 catch {set author_time [format_date $header($cmit,author-time)]}
969 set committer_name {}
971 set committer_email {}
972 set committer_time {}
973 catch {set committer_name $header($cmit,committer)}
974 catch {set committer_email $header($cmit,committer-mail)}
975 catch {set committer_time [format_date $header($cmit,committer-time)]}
976 if {[catch {set msg $header($cmit,message)}]} {
978 set msg {}
979 catch {
980 set fd [git_read cat-file commit $cmit]
981 fconfigure $fd -encoding binary -translation lf
982 # By default commits are assumed to be in utf-8
983 set enc utf-8
984 while {[gets $fd line] > 0} {
985 if {[string match {encoding *} $line]} {
986 set enc [string tolower [string range $line 9 end]]
987 }
988 }
989 set msg [read $fd]
990 close $fd
991 set enc [tcl_encoding $enc]
993 if {$enc ne {}} {
994 set msg [encoding convertfrom $enc $msg]
995 }
996 set msg [string trim $msg]
997 }
998 set header($cmit,message) $msg
999 }
1000 $w_cviewer insert end "commit $cmit\n" header_key
1002 $w_cviewer insert end [strcat [mc "Author:"] "\t"] header_key
1003 $w_cviewer insert end "$author_name $author_email" header_val
1004 $w_cviewer insert end " $author_time\n" header_val
1005 $w_cviewer insert end [strcat [mc "Committer:"] "\t"] header_key
1007 $w_cviewer insert end "$committer_name $committer_email" header_val
1008 $w_cviewer insert end " $committer_time\n" header_val
1009 if {$file ne $path} {
1011 $w_cviewer insert end [strcat [mc "Original File:"] "\t"] header_key
1012 $w_cviewer insert end "[escape_path $file]\n" header_val
1013 }
1014 $w_cviewer insert end "\n$msg"
1016 }
1017 $w_cviewer conf -state disabled
1018 set highlight_line $lno
1020 set highlight_commit $cmit
1021 if {[lsearch -exact $tooltip_commit $highlight_commit] != -1} {
1023 _hide_tooltip $this
1024 }
1025}
1026method _get_click_amov_info {} {
1028 set pos @$::cursorX,$::cursorY
1029 set lno [lindex [split [$::cursorW index $pos] .] 0]
1030 return [lindex $amov_data $lno]
1031}
1032method _copycommit {} {
1034 set dat [_get_click_amov_info $this]
1035 if {$dat ne {}} {
1036 clipboard clear
1037 clipboard append \
1038 -format STRING \
1039 -type STRING \
1040 -- [lindex $dat 0]
1041 }
1042}
1043method _format_offset_date {base offset} {
1045 set exval [expr {$base + $offset*24*60*60}]
1046 return [clock format $exval -format {%Y-%m-%d}]
1047}
1048method _gitkcommit {} {
1050 global nullid
1051 set dat [_get_click_amov_info $this]
1053 if {$dat ne {}} {
1054 set cmit [lindex $dat 0]
1055 # If the line belongs to the working copy, use HEAD instead
1057 if {$cmit eq $nullid} {
1058 if {[catch {set cmit [git rev-parse --verify HEAD]} err]} {
1059 error_popup [strcat [mc "Cannot find HEAD commit:"] "\n\n$err"]
1060 return;
1061 }
1062 }
1063 set radius [get_config gui.blamehistoryctx]
1065 set cmdline [list --select-commit=$cmit]
1066 if {$radius > 0} {
1068 set author_time {}
1069 set committer_time {}
1070 catch {set author_time $header($cmit,author-time)}
1072 catch {set committer_time $header($cmit,committer-time)}
1073 if {$committer_time eq {}} {
1075 set committer_time $author_time
1076 }
1077 set after_time [_format_offset_date $this $committer_time [expr {-$radius}]]
1079 set before_time [_format_offset_date $this $committer_time $radius]
1080 lappend cmdline --after=$after_time --before=$before_time
1082 }
1083 lappend cmdline $cmit
1085 set base_rev "HEAD"
1087 if {$commit ne {}} {
1088 set base_rev $commit
1089 }
1090 if {$base_rev ne $cmit} {
1092 lappend cmdline $base_rev
1093 }
1094 do_gitk $cmdline
1096 }
1097}
1098method _blameparent {} {
1100 global nullid
1101 set dat [_get_click_amov_info $this]
1103 if {$dat ne {}} {
1104 set cmit [lindex $dat 0]
1105 set new_path [lindex $dat 1]
1106 # Allow using Blame Parent on lines modified in the working copy
1108 if {$cmit eq $nullid} {
1109 set parent_ref "HEAD"
1110 } else {
1111 set parent_ref "$cmit^"
1112 }
1113 if {[catch {set cparent [git rev-parse --verify $parent_ref]} err]} {
1114 error_popup [strcat [mc "Cannot find parent commit:"] "\n\n$err"]
1115 return;
1116 }
1117 _kill $this
1119 # Generate a diff between the commit and its parent,
1121 # and use the hunks to update the line number.
1122 # Request zero context to simplify calculations.
1123 if {$cmit eq $nullid} {
1124 set diffcmd [list diff-index --unified=0 $cparent -- $new_path]
1125 } else {
1126 set diffcmd [list diff-tree --unified=0 $cparent $cmit -- $new_path]
1127 }
1128 if {[catch {set fd [eval git_read $diffcmd]} err]} {
1129 $status stop [mc "Unable to display parent"]
1130 error_popup [strcat [mc "Error loading diff:"] "\n\n$err"]
1131 return
1132 }
1133 set r_orig_line [lindex $dat 2]
1135 fconfigure $fd \
1137 -blocking 0 \
1138 -encoding binary \
1139 -translation binary
1140 fileevent $fd readable [cb _read_diff_load_commit \
1141 $fd $cparent $new_path $r_orig_line]
1142 set current_fd $fd
1143 }
1144}
1145method _read_diff_load_commit {fd cparent new_path tline} {
1147 if {$fd ne $current_fd} {
1148 catch {close $fd}
1149 return
1150 }
1151 while {[gets $fd line] >= 0} {
1153 if {[regexp {^@@ -(\d+)(,(\d+))? \+(\d+)(,(\d+))? @@} $line line \
1154 old_line osz old_size new_line nsz new_size]} {
1155 if {$osz eq {}} { set old_size 1 }
1157 if {$nsz eq {}} { set new_size 1 }
1158 if {$new_line <= $tline} {
1160 if {[expr {$new_line + $new_size}] > $tline} {
1161 # Target line within the hunk
1162 set line_shift [expr {
1163 ($new_size-$old_size)*($tline-$new_line)/$new_size
1164 }]
1165 } else {
1166 set line_shift [expr {$new_size-$old_size}]
1167 }
1168 set r_orig_line [expr {$r_orig_line - $line_shift}]
1170 }
1171 }
1172 }
1173 if {[eof $fd]} {
1175 close $fd;
1176 set current_fd {}
1177 _load_new_commit $this \
1179 $cparent \
1180 $new_path \
1181 [list $r_orig_line]
1182 }
1183} ifdeleted { catch {close $fd} }
1184method _show_tooltip {cur_w pos} {
1186 if {$tooltip_wm ne {}} {
1187 _open_tooltip $this $cur_w
1188 } elseif {$tooltip_timer eq {}} {
1189 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
1190 }
1191}
1192method _open_tooltip {cur_w} {
1194 set tooltip_timer {}
1195 set pos_x [winfo pointerx $cur_w]
1196 set pos_y [winfo pointery $cur_w]
1197 if {[winfo containing $pos_x $pos_y] ne $cur_w} {
1198 _hide_tooltip $this
1199 return
1200 }
1201 if {$tooltip_wm ne "$cur_w.tooltip"} {
1203 _hide_tooltip $this
1204 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
1206 wm overrideredirect $tooltip_wm 1
1207 wm transient $tooltip_wm [winfo toplevel $cur_w]
1208 set tooltip_t $tooltip_wm.label
1209 text $tooltip_t \
1210 -takefocus 0 \
1211 -highlightthickness 0 \
1212 -relief flat \
1213 -borderwidth 0 \
1214 -wrap none \
1215 -background lightyellow \
1216 -foreground black
1217 $tooltip_t tag conf section_header -font font_uibold
1218 pack $tooltip_t
1219 } else {
1220 $tooltip_t conf -state normal
1221 $tooltip_t delete 0.0 end
1222 }
1223 set pos @[join [list \
1225 [expr {$pos_x - [winfo rootx $cur_w]}] \
1226 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
1227 set lno [lindex [split [$cur_w index $pos] .] 0]
1228 if {$cur_w eq $w_amov} {
1229 set dat [lindex $amov_data $lno]
1230 set org {}
1231 } else {
1232 set dat [lindex $asim_data $lno]
1233 set org [lindex $amov_data $lno]
1234 }
1235 if {$dat eq {}} {
1237 _hide_tooltip $this
1238 return
1239 }
1240 set cmit [lindex $dat 0]
1242 set tooltip_commit [list $cmit]
1243 set author_name {}
1245 set summary {}
1246 set author_time {}
1247 catch {set author_name $header($cmit,author)}
1248 catch {set summary $header($cmit,summary)}
1249 catch {set author_time [format_date $header($cmit,author-time)]}
1250 $tooltip_t insert end "commit $cmit\n"
1252 $tooltip_t insert end "$author_name $author_time\n"
1253 $tooltip_t insert end "$summary"
1254 if {$org ne {} && [lindex $org 0] ne $cmit} {
1256 set save [$tooltip_t get 0.0 end]
1257 $tooltip_t delete 0.0 end
1258 set cmit [lindex $org 0]
1260 set file [lindex $org 1]
1261 lappend tooltip_commit $cmit
1262 set author_name {}
1264 set summary {}
1265 set author_time {}
1266 catch {set author_name $header($cmit,author)}
1267 catch {set summary $header($cmit,summary)}
1268 catch {set author_time [format_date $header($cmit,author-time)]}
1269 $tooltip_t insert end [strcat [mc "Originally By:"] "\n"] section_header
1271 $tooltip_t insert end "commit $cmit\n"
1272 $tooltip_t insert end "$author_name $author_time\n"
1273 $tooltip_t insert end "$summary\n"
1274 if {$file ne $path} {
1276 $tooltip_t insert end [strcat [mc "In File:"] " "] section_header
1277 $tooltip_t insert end "$file\n"
1278 }
1279 $tooltip_t insert end "\n"
1281 $tooltip_t insert end [strcat [mc "Copied Or Moved Here By:"] "\n"] section_header
1282 $tooltip_t insert end $save
1283 }
1284 $tooltip_t conf -state disabled
1286 _position_tooltip $this
1287 # On MacOS raising a window causes it to acquire focus.
1289 # Tk 8.5 on MacOS seems to properly support wm transient,
1290 # so we can safely counter the effect there.
1291 if {$::have_tk85 && [is_MacOSX]} {
1292 update
1293 if {$w eq {}} {
1294 raise .
1295 } else {
1296 raise $w
1297 }
1298 }
1299}
1300method _position_tooltip {} {
1302 set max_h [lindex [split [$tooltip_t index end] .] 0]
1303 set max_w 0
1304 for {set i 1} {$i <= $max_h} {incr i} {
1305 set c [lindex [split [$tooltip_t index "$i.0 lineend"] .] 1]
1306 if {$c > $max_w} {set max_w $c}
1307 }
1308 $tooltip_t conf -width $max_w -height $max_h
1309 set req_w [winfo reqwidth $tooltip_t]
1311 set req_h [winfo reqheight $tooltip_t]
1312 set pos_x [expr {[winfo pointerx .] + 5}]
1313 set pos_y [expr {[winfo pointery .] + 10}]
1314 set g "${req_w}x${req_h}"
1316 if {[tk windowingsystem] eq "win32" || $pos_x >= 0} {append g +}
1317 append g $pos_x
1318 if {[tk windowingsystem] eq "win32" || $pos_y >= 0} {append g +}
1319 append g $pos_y
1320 wm geometry $tooltip_wm $g
1322 if {![is_MacOSX]} {
1323 raise $tooltip_wm
1324 }
1325}
1326method _hide_tooltip {} {
1328 if {$tooltip_wm ne {}} {
1329 destroy $tooltip_wm
1330 set tooltip_wm {}
1331 set tooltip_commit {}
1332 }
1333 if {$tooltip_timer ne {}} {
1334 after cancel $tooltip_timer
1335 set tooltip_timer {}
1336 }
1337}
1338method _resize {new_height} {
1340 set diff [expr {$new_height - $old_height}]
1341 if {$diff == 0} return
1342 set my [expr {[winfo height $w.file_pane] - 25}]
1344 set o [$w.file_pane sash coord 0]
1345 set ox [lindex $o 0]
1346 set oy [expr {[lindex $o 1] + $diff}]
1347 if {$oy < 0} {set oy 0}
1348 if {$oy > $my} {set oy $my}
1349 $w.file_pane sash place 0 $ox $oy
1350 set old_height $new_height
1352}
1353}