dae6ca6831a3ed13e7cc97cdce661ed0f1ce5386
1# git-gui diff viewer
2# Copyright (C) 2006, 2007 Shawn Pearce
3proc clear_diff {} {
5 global ui_diff current_diff_path current_diff_header
6 global ui_index ui_workdir
7 $ui_diff conf -state normal
9 $ui_diff delete 0.0 end
10 $ui_diff conf -state disabled
11 set current_diff_path {}
13 set current_diff_header {}
14 $ui_index tag remove in_diff 0.0 end
16 $ui_workdir tag remove in_diff 0.0 end
17}
18proc reshow_diff {{after {}}} {
20 global file_states file_lists
21 global current_diff_path current_diff_side
22 global ui_diff
23 set p $current_diff_path
25 if {$p eq {}} {
26 # No diff is being shown.
27 } elseif {$current_diff_side eq {}} {
28 clear_diff
29 } elseif {[catch {set s $file_states($p)}]
30 || [lsearch -sorted -exact $file_lists($current_diff_side) $p] == -1} {
31 if {[find_next_diff $current_diff_side $p {} {[^O]}]} {
33 next_diff $after
34 } else {
35 clear_diff
36 }
37 } else {
38 set save_pos [lindex [$ui_diff yview] 0]
39 show_diff $p $current_diff_side {} $save_pos $after
40 }
41}
42proc force_diff_encoding {enc} {
44 global current_diff_path
45
46 if {$current_diff_path ne {}} {
47 force_path_encoding $current_diff_path $enc
48 reshow_diff
49 }
50}
51proc handle_empty_diff {} {
53 global current_diff_path file_states file_lists
54 global diff_empty_count
55 set path $current_diff_path
57 set s $file_states($path)
58 if {[lindex $s 0] ne {_M} || [has_textconv $path]} return
59 # Prevent infinite rescan loops
61 incr diff_empty_count
62 if {$diff_empty_count > 1} return
63 info_popup [mc "No differences detected.
65%s has no changes.
67The modification date of this file was updated by another application, but the content within the file was not changed.
69A rescan will be automatically started to find other files which may have the same state." [short_path $path]]
71 clear_diff
73 display_file $path __
74 rescan ui_ready 0
75}
76proc show_diff {path w {lno {}} {scroll_pos {}} {callback {}}} {
78 global file_states file_lists
79 global is_3way_diff is_conflict_diff diff_active repo_config
80 global ui_diff ui_index ui_workdir
81 global current_diff_path current_diff_side current_diff_header
82 global current_diff_queue
83 if {$diff_active || ![lock_index read]} return
85 clear_diff
87 if {$lno == {}} {
88 set lno [lsearch -sorted -exact $file_lists($w) $path]
89 if {$lno >= 0} {
90 incr lno
91 }
92 }
93 if {$lno >= 1} {
94 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
95 $w see $lno.0
96 }
97 set s $file_states($path)
99 set m [lindex $s 0]
100 set is_conflict_diff 0
101 set current_diff_path $path
102 set current_diff_side $w
103 set current_diff_queue {}
104 ui_status [mc "Loading diff of %s..." [escape_path $path]]
105 set cont_info [list $scroll_pos $callback]
107 if {[string first {U} $m] >= 0} {
109 merge_load_stages $path [list show_unmerged_diff $cont_info]
110 } elseif {$m eq {_O}} {
111 show_other_diff $path $w $m $cont_info
112 } else {
113 start_show_diff $cont_info
114 }
115}
116proc show_unmerged_diff {cont_info} {
118 global current_diff_path current_diff_side
119 global merge_stages ui_diff is_conflict_diff
120 global current_diff_queue
121 if {$merge_stages(2) eq {}} {
123 set is_conflict_diff 1
124 lappend current_diff_queue \
125 [list [mc "LOCAL: deleted\nREMOTE:\n"] d= \
126 [list ":1:$current_diff_path" ":3:$current_diff_path"]]
127 } elseif {$merge_stages(3) eq {}} {
128 set is_conflict_diff 1
129 lappend current_diff_queue \
130 [list [mc "REMOTE: deleted\nLOCAL:\n"] d= \
131 [list ":1:$current_diff_path" ":2:$current_diff_path"]]
132 } elseif {[lindex $merge_stages(1) 0] eq {120000}
133 || [lindex $merge_stages(2) 0] eq {120000}
134 || [lindex $merge_stages(3) 0] eq {120000}} {
135 set is_conflict_diff 1
136 lappend current_diff_queue \
137 [list [mc "LOCAL:\n"] d= \
138 [list ":1:$current_diff_path" ":2:$current_diff_path"]]
139 lappend current_diff_queue \
140 [list [mc "REMOTE:\n"] d= \
141 [list ":1:$current_diff_path" ":3:$current_diff_path"]]
142 } else {
143 start_show_diff $cont_info
144 return
145 }
146 advance_diff_queue $cont_info
148}
149proc advance_diff_queue {cont_info} {
151 global current_diff_queue ui_diff
152 set item [lindex $current_diff_queue 0]
154 set current_diff_queue [lrange $current_diff_queue 1 end]
155 $ui_diff conf -state normal
157 $ui_diff insert end [lindex $item 0] [lindex $item 1]
158 $ui_diff conf -state disabled
159 start_show_diff $cont_info [lindex $item 2]
161}
162proc show_other_diff {path w m cont_info} {
164 global file_states file_lists
165 global is_3way_diff diff_active repo_config
166 global ui_diff ui_index ui_workdir
167 global current_diff_path current_diff_side current_diff_header
168 # - Git won't give us the diff, there's nothing to compare to!
170 #
171 if {$m eq {_O}} {
172 set max_sz 100000
173 set type unknown
174 if {[catch {
175 set type [file type $path]
176 switch -- $type {
177 directory {
178 set type submodule
179 set content {}
180 set sz 0
181 }
182 link {
183 set content [file readlink $path]
184 set sz [string length $content]
185 }
186 file {
187 set fd [open $path r]
188 fconfigure $fd \
189 -eofchar {} \
190 -encoding [get_path_encoding $path]
191 set content [read $fd $max_sz]
192 close $fd
193 set sz [file size $path]
194 }
195 default {
196 error "'$type' not supported"
197 }
198 }
199 } err ]} {
200 set diff_active 0
201 unlock_index
202 ui_status [mc "Unable to display %s" [escape_path $path]]
203 error_popup [strcat [mc "Error loading file:"] "\n\n$err"]
204 return
205 }
206 $ui_diff conf -state normal
207 if {$type eq {submodule}} {
208 $ui_diff insert end [append \
209 "* " \
210 [mc "Git Repository (subproject)"] \
211 "\n"] d_info
212 } elseif {![catch {set type [exec file $path]}]} {
213 set n [string length $path]
214 if {[string equal -length $n $path $type]} {
215 set type [string range $type $n end]
216 regsub {^:?\s*} $type {} type
217 }
218 $ui_diff insert end "* $type\n" d_info
219 }
220 if {[string first "\0" $content] != -1} {
221 $ui_diff insert end \
222 [mc "* Binary file (not showing content)."] \
223 d_info
224 } else {
225 if {$sz > $max_sz} {
226 $ui_diff insert end [mc \
227"* Untracked file is %d bytes.
228* Showing only first %d bytes.
229" $sz $max_sz] d_info
230 }
231 $ui_diff insert end $content
232 if {$sz > $max_sz} {
233 $ui_diff insert end [mc "
234* Untracked file clipped here by %s.
235* To see the entire file, use an external editor.
236" [appname]] d_info
237 }
238 }
239 $ui_diff conf -state disabled
240 set diff_active 0
241 unlock_index
242 set scroll_pos [lindex $cont_info 0]
243 if {$scroll_pos ne {}} {
244 update
245 $ui_diff yview moveto $scroll_pos
246 }
247 ui_ready
248 set callback [lindex $cont_info 1]
249 if {$callback ne {}} {
250 eval $callback
251 }
252 return
253 }
254}
255proc get_conflict_marker_size {path} {
257 set size 7
258 catch {
259 set fd_rc [eval [list git_read check-attr "conflict-marker-size" -- $path]]
260 set ret [gets $fd_rc line]
261 close $fd_rc
262 if {$ret > 0} {
263 regexp {.*: conflict-marker-size: (\d+)$} $line line size
264 }
265 }
266 return $size
267}
268proc start_show_diff {cont_info {add_opts {}}} {
270 global file_states file_lists
271 global is_3way_diff is_submodule_diff diff_active repo_config
272 global ui_diff ui_index ui_workdir
273 global current_diff_path current_diff_side current_diff_header
274 set path $current_diff_path
276 set w $current_diff_side
277 set s $file_states($path)
279 set m [lindex $s 0]
280 set is_3way_diff 0
281 set is_submodule_diff 0
282 set diff_active 1
283 set current_diff_header {}
284 set conflict_size [get_conflict_marker_size $path]
285 set cmd [list]
287 if {$w eq $ui_index} {
288 lappend cmd diff-index
289 lappend cmd --cached
290 } elseif {$w eq $ui_workdir} {
291 if {[string first {U} $m] >= 0} {
292 lappend cmd diff
293 } else {
294 lappend cmd diff-files
295 }
296 }
297 if {![is_config_false gui.textconv] && [git-version >= 1.6.1]} {
298 lappend cmd --textconv
299 }
300 if {[string match {160000 *} [lindex $s 2]]
302 || [string match {160000 *} [lindex $s 3]]} {
303 set is_submodule_diff 1
304 if {[git-version >= "1.6.6"]} {
306 lappend cmd --submodule
307 }
308 }
309 lappend cmd -p
311 lappend cmd --color
312 if {$repo_config(gui.diffcontext) >= 1} {
313 lappend cmd "-U$repo_config(gui.diffcontext)"
314 }
315 if {$w eq $ui_index} {
316 lappend cmd [PARENT]
317 }
318 if {$add_opts ne {}} {
319 eval lappend cmd $add_opts
320 } else {
321 lappend cmd --
322 lappend cmd $path
323 }
324 if {$is_submodule_diff && [git-version < "1.6.6"]} {
326 if {$w eq $ui_index} {
327 set cmd [list submodule summary --cached -- $path]
328 } else {
329 set cmd [list submodule summary --files -- $path]
330 }
331 }
332 if {[catch {set fd [eval git_read --nice $cmd]} err]} {
334 set diff_active 0
335 unlock_index
336 ui_status [mc "Unable to display %s" [escape_path $path]]
337 error_popup [strcat [mc "Error loading diff:"] "\n\n$err"]
338 return
339 }
340 set ::current_diff_inheader 1
342 fconfigure $fd \
343 -blocking 0 \
344 -encoding [get_path_encoding $path] \
345 -translation lf
346 fileevent $fd readable [list read_diff $fd $conflict_size $cont_info]
347}
348proc parse_color_line {line} {
350 set start 0
351 set result ""
352 set markup [list]
353 set regexp {\033\[((?:\d+;)*\d+)?m}
354 set need_reset 0
355 while {[regexp -indices -start $start $regexp $line match code]} {
356 foreach {begin end} $match break
357 append result [string range $line $start [expr {$begin - 1}]]
358 set pos [string length $result]
359 set col [eval [linsert $code 0 string range $line]]
360 set start [incr end]
361 if {$col eq "0" || $col eq ""} {
362 if {!$need_reset} continue
363 set need_reset 0
364 } else {
365 set need_reset 1
366 }
367 lappend markup $pos $col
368 }
369 append result [string range $line $start end]
370 if {[llength $markup] < 4} {set markup {}}
371 return [list $result $markup]
372}
373proc read_diff {fd conflict_size cont_info} {
375 global ui_diff diff_active is_submodule_diff
376 global is_3way_diff is_conflict_diff current_diff_header
377 global current_diff_queue
378 global diff_empty_count
379 $ui_diff conf -state normal
381 while {[gets $fd line] >= 0} {
382 foreach {line markup} [parse_color_line $line] break
383 set line [string map {\033 ^} $line]
384 # -- Check for start of diff header.
386 if { [string match {diff --git *} $line]
387 || [string match {diff --cc *} $line]
388 || [string match {diff --combined *} $line]} {
389 set ::current_diff_inheader 1
390 }
391 # -- Check for end of diff header (any hunk line will do this).
393 #
394 if {[regexp {^@@+ } $line]} {set ::current_diff_inheader 0}
395 if {$::current_diff_inheader} {
397 append current_diff_header $line "\n"
398 # -- Cleanup uninteresting diff header lines.
400 #
401 if { [string match {diff --git *} $line]
402 || [string match {diff --cc *} $line]
403 || [string match {diff --combined *} $line]
404 || [string match {--- *} $line]
405 || [string match {+++ *} $line]} {
406 continue
407 }
408 }
409 if {[string match {index *} $line]} continue
411 if {$line eq {deleted file mode 120000}} {
412 set line "deleted symlink"
413 }
414 # -- Automatically detect if this is a 3 way diff.
416 #
417 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
418 if {[string match {mode *} $line]
420 || [string match {new file *} $line]
421 || [regexp {^(old|new) mode *} $line]
422 || [string match {deleted file *} $line]
423 || [string match {deleted symlink} $line]
424 || [string match {Binary files * and * differ} $line]
425 || $line eq {\ No newline at end of file}
426 || [regexp {^\* Unmerged path } $line]} {
427 set tags {}
428 } elseif {$is_3way_diff} {
429 set op [string range $line 0 1]
430 switch -- $op {
431 { } {set tags {}}
432 {@@} {set tags d_@}
433 { +} {set tags d_s+}
434 { -} {set tags d_s-}
435 {+ } {set tags d_+s}
436 {- } {set tags d_-s}
437 {--} {set tags d_--}
438 {++} {
439 set regexp [string map [list %conflict_size $conflict_size]\
440 {^\+\+([<>=]){%conflict_size}(?: |$)}]
441 if {[regexp $regexp $line _g op]} {
442 set is_conflict_diff 1
443 set line [string replace $line 0 1 { }]
444 set tags d$op
445 } else {
446 set tags d_++
447 }
448 }
449 default {
450 puts "error: Unhandled 3 way diff marker: {$op}"
451 set tags {}
452 }
453 }
454 } elseif {$is_submodule_diff} {
455 if {$line == ""} continue
456 if {[regexp {^Submodule } $line]} {
457 set tags d_info
458 } elseif {[regexp {^\* } $line]} {
459 set line [string replace $line 0 1 {Submodule }]
460 set tags d_info
461 } else {
462 set op [string range $line 0 2]
463 switch -- $op {
464 { <} {set tags d_-}
465 { >} {set tags d_+}
466 { W} {set tags {}}
467 default {
468 puts "error: Unhandled submodule diff marker: {$op}"
469 set tags {}
470 }
471 }
472 }
473 } else {
474 set op [string index $line 0]
475 switch -- $op {
476 { } {set tags {}}
477 {@} {set tags d_@}
478 {-} {set tags d_-}
479 {+} {
480 set regexp [string map [list %conflict_size $conflict_size]\
481 {^\+([<>=]){%conflict_size}(?: |$)}]
482 if {[regexp $regexp $line _g op]} {
483 set is_conflict_diff 1
484 set tags d$op
485 } else {
486 set tags d_+
487 }
488 }
489 default {
490 puts "error: Unhandled 2 way diff marker: {$op}"
491 set tags {}
492 }
493 }
494 }
495 set mark [$ui_diff index "end - 1 line linestart"]
496 $ui_diff insert end $line $tags
497 if {[string index $line end] eq "\r"} {
498 $ui_diff tag add d_cr {end - 2c}
499 }
500 $ui_diff insert end "\n" $tags
501 foreach {posbegin colbegin posend colend} $markup {
503 set prefix clr
504 foreach style [split $colbegin ";"] {
505 if {$style eq "7"} {append prefix i; continue}
506 if {$style < 30 || $style > 47} {continue}
507 set a "$mark linestart + $posbegin chars"
508 set b "$mark linestart + $posend chars"
509 catch {$ui_diff tag add $prefix$style $a $b}
510 }
511 }
512 }
513 $ui_diff conf -state disabled
514 if {[eof $fd]} {
516 close $fd
517 if {$current_diff_queue ne {}} {
519 advance_diff_queue $cont_info
520 return
521 }
522 set diff_active 0
524 unlock_index
525 set scroll_pos [lindex $cont_info 0]
526 if {$scroll_pos ne {}} {
527 update
528 $ui_diff yview moveto $scroll_pos
529 }
530 ui_ready
531 if {[$ui_diff index end] eq {2.0}} {
533 handle_empty_diff
534 } else {
535 set diff_empty_count 0
536 }
537 set callback [lindex $cont_info 1]
539 if {$callback ne {}} {
540 eval $callback
541 }
542 }
543}
544proc apply_hunk {x y} {
546 global current_diff_path current_diff_header current_diff_side
547 global ui_diff ui_index file_states
548 if {$current_diff_path eq {} || $current_diff_header eq {}} return
550 if {![lock_index apply_hunk]} return
551 set apply_cmd {apply --cached --whitespace=nowarn}
553 set mi [lindex $file_states($current_diff_path) 0]
554 if {$current_diff_side eq $ui_index} {
555 set failed_msg [mc "Failed to unstage selected hunk."]
556 lappend apply_cmd --reverse
557 if {[string index $mi 0] ne {M}} {
558 unlock_index
559 return
560 }
561 } else {
562 set failed_msg [mc "Failed to stage selected hunk."]
563 if {[string index $mi 1] ne {M}} {
564 unlock_index
565 return
566 }
567 }
568 set s_lno [lindex [split [$ui_diff index @$x,$y] .] 0]
570 set s_lno [$ui_diff search -backwards -regexp ^@@ $s_lno.0 0.0]
571 if {$s_lno eq {}} {
572 unlock_index
573 return
574 }
575 set e_lno [$ui_diff search -forwards -regexp ^@@ "$s_lno + 1 lines" end]
577 if {$e_lno eq {}} {
578 set e_lno end
579 }
580 if {[catch {
582 set enc [get_path_encoding $current_diff_path]
583 set p [eval git_write $apply_cmd]
584 fconfigure $p -translation binary -encoding $enc
585 puts -nonewline $p $current_diff_header
586 puts -nonewline $p [$ui_diff get $s_lno $e_lno]
587 close $p} err]} {
588 error_popup [append $failed_msg "\n\n$err"]
589 unlock_index
590 return
591 }
592 $ui_diff conf -state normal
594 $ui_diff delete $s_lno $e_lno
595 $ui_diff conf -state disabled
596 if {[$ui_diff get 1.0 end] eq "\n"} {
598 set o _
599 } else {
600 set o ?
601 }
602 if {$current_diff_side eq $ui_index} {
604 set mi ${o}M
605 } elseif {[string index $mi 0] eq {_}} {
606 set mi M$o
607 } else {
608 set mi ?$o
609 }
610 unlock_index
611 display_file $current_diff_path $mi
612 # This should trigger shift to the next changed file
613 if {$o eq {_}} {
614 reshow_diff
615 }
616}
617proc apply_range_or_line {x y} {
619 global current_diff_path current_diff_header current_diff_side
620 global ui_diff ui_index file_states
621 set selected [$ui_diff tag nextrange sel 0.0]
623 if {$selected == {}} {
625 set first [$ui_diff index "@$x,$y"]
626 set last $first
627 } else {
628 set first [lindex $selected 0]
629 set last [lindex $selected 1]
630 }
631 set first_l [$ui_diff index "$first linestart"]
633 set last_l [$ui_diff index "$last lineend"]
634 if {$current_diff_path eq {} || $current_diff_header eq {}} return
636 if {![lock_index apply_hunk]} return
637 set apply_cmd {apply --cached --whitespace=nowarn}
639 set mi [lindex $file_states($current_diff_path) 0]
640 if {$current_diff_side eq $ui_index} {
641 set failed_msg [mc "Failed to unstage selected line."]
642 set to_context {+}
643 lappend apply_cmd --reverse
644 if {[string index $mi 0] ne {M}} {
645 unlock_index
646 return
647 }
648 } else {
649 set failed_msg [mc "Failed to stage selected line."]
650 set to_context {-}
651 if {[string index $mi 1] ne {M}} {
652 unlock_index
653 return
654 }
655 }
656 set wholepatch {}
658 while {$first_l < $last_l} {
660 set i_l [$ui_diff search -backwards -regexp ^@@ $first_l 0.0]
661 if {$i_l eq {}} {
662 # If there's not a @@ above, then the selected range
663 # must have come before the first_l @@
664 set i_l [$ui_diff search -regexp ^@@ $first_l $last_l]
665 }
666 if {$i_l eq {}} {
667 unlock_index
668 return
669 }
670 # $i_l is now at the beginning of a line
671 # pick start line number from hunk header
673 set hh [$ui_diff get $i_l "$i_l + 1 lines"]
674 set hh [lindex [split $hh ,] 0]
675 set hln [lindex [split $hh -] 1]
676 # There is a special situation to take care of. Consider this
678 # hunk:
679 #
680 # @@ -10,4 +10,4 @@
681 # context before
682 # -old 1
683 # -old 2
684 # +new 1
685 # +new 2
686 # context after
687 #
688 # We used to keep the context lines in the order they appear in
689 # the hunk. But then it is not possible to correctly stage only
690 # "-old 1" and "+new 1" - it would result in this staged text:
691 #
692 # context before
693 # old 2
694 # new 1
695 # context after
696 #
697 # (By symmetry it is not possible to *un*stage "old 2" and "new
698 # 2".)
699 #
700 # We resolve the problem by introducing an asymmetry, namely,
701 # when a "+" line is *staged*, it is moved in front of the
702 # context lines that are generated from the "-" lines that are
703 # immediately before the "+" block. That is, we construct this
704 # patch:
705 #
706 # @@ -10,4 +10,5 @@
707 # context before
708 # +new 1
709 # old 1
710 # old 2
711 # context after
712 #
713 # But we do *not* treat "-" lines that are *un*staged in a
714 # special way.
715 #
716 # With this asymmetry it is possible to stage the change "old
717 # 1" -> "new 1" directly, and to stage the change "old 2" ->
718 # "new 2" by first staging the entire hunk and then unstaging
719 # the change "old 1" -> "new 1".
720 #
721 # Applying multiple lines adds complexity to the special
722 # situation. The pre_context must be moved after the entire
723 # first block of consecutive staged "+" lines, so that
724 # staging both additions gives the following patch:
725 #
726 # @@ -10,4 +10,6 @@
727 # context before
728 # +new 1
729 # +new 2
730 # old 1
731 # old 2
732 # context after
733 # This is non-empty if and only if we are _staging_ changes;
735 # then it accumulates the consecutive "-" lines (after
736 # converting them to context lines) in order to be moved after
737 # "+" change lines.
738 set pre_context {}
739 set n 0
741 set m 0
742 set i_l [$ui_diff index "$i_l + 1 lines"]
743 set patch {}
744 while {[$ui_diff compare $i_l < "end - 1 chars"] &&
745 [$ui_diff get $i_l "$i_l + 2 chars"] ne {@@}} {
746 set next_l [$ui_diff index "$i_l + 1 lines"]
747 set c1 [$ui_diff get $i_l]
748 if {[$ui_diff compare $first_l <= $i_l] &&
749 [$ui_diff compare $i_l < $last_l] &&
750 ($c1 eq {-} || $c1 eq {+})} {
751 # a line to stage/unstage
752 set ln [$ui_diff get $i_l $next_l]
753 if {$c1 eq {-}} {
754 set n [expr $n+1]
755 set patch "$patch$pre_context$ln"
756 set pre_context {}
757 } else {
758 set m [expr $m+1]
759 set patch "$patch$ln"
760 }
761 } elseif {$c1 ne {-} && $c1 ne {+}} {
762 # context line
763 set ln [$ui_diff get $i_l $next_l]
764 set patch "$patch$pre_context$ln"
765 set n [expr $n+1]
766 set m [expr $m+1]
767 set pre_context {}
768 } elseif {$c1 eq $to_context} {
769 # turn change line into context line
770 set ln [$ui_diff get "$i_l + 1 chars" $next_l]
771 if {$c1 eq {-}} {
772 set pre_context "$pre_context $ln"
773 } else {
774 set patch "$patch $ln"
775 }
776 set n [expr $n+1]
777 set m [expr $m+1]
778 } else {
779 # a change in the opposite direction of
780 # to_context which is outside the range of
781 # lines to apply.
782 set patch "$patch$pre_context"
783 set pre_context {}
784 }
785 set i_l $next_l
786 }
787 set patch "$patch$pre_context"
788 set wholepatch "$wholepatch@@ -$hln,$n +$hln,$m @@\n$patch"
789 set first_l [$ui_diff index "$next_l + 1 lines"]
790 }
791 if {[catch {
793 set enc [get_path_encoding $current_diff_path]
794 set p [eval git_write $apply_cmd]
795 fconfigure $p -translation binary -encoding $enc
796 puts -nonewline $p $current_diff_header
797 puts -nonewline $p $wholepatch
798 close $p} err]} {
799 error_popup [append $failed_msg "\n\n$err"]
800 }
801 unlock_index
803}