Andrew's git / gitweb.git / configure.ac
?
configure.acon commit configure: reorganize flow of argument checks (08df6a3)
   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_ERROR([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  47                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  48        fi; \
  49fi; \
  50]) # GIT_CONF_APPEND_PATH
  51#
  52# GIT_PARSE_WITH(PACKAGE)
  53# -----------------------
  54# For use in AC_ARG_WITH action-if-found, for packages default ON.
  55# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  56# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  57# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  58AC_DEFUN([GIT_PARSE_WITH],
  59[PACKAGE=m4_toupper($1); \
  60if test "$withval" = "no"; then \
  61        m4_toupper(NO_$1)=YesPlease; \
  62elif test "$withval" = "yes"; then \
  63        m4_toupper(NO_$1)=; \
  64else \
  65        m4_toupper(NO_$1)=; \
  66        m4_toupper($1)DIR=$withval; \
  67        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  68        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  69fi \
  70])# GIT_PARSE_WITH
  71
  72dnl
  73dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
  74dnl -----------------------------------------
  75dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
  76dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
  77dnl -Wall), it does not work.  By looking for function definition in
  78dnl libraries, this problem can be worked around.
  79AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
  80  AC_SEARCH_LIBS([$1],,
  81  [$2],[$3])
  82],[$3])])
  83## Site configuration related to programs (before tests)
  84## --with-PACKAGE[=ARG] and --without-PACKAGE
  85#
  86# Set lib to alternative name of lib directory (e.g. lib64)
  87AC_ARG_WITH([lib],
  88 [AS_HELP_STRING([--with-lib=ARG],
  89                 [ARG specifies alternative name for lib directory])],
  90 [if test "$withval" = "no" || test "$withval" = "yes"; then \
  91        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
  92else \
  93        lib=$withval; \
  94        AC_MSG_NOTICE([Setting lib to '$lib']); \
  95        GIT_CONF_APPEND_LINE(lib=$withval); \
  96fi; \
  97],[])
  98
  99if test -z "$lib"; then
 100   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 101   lib=lib
 102fi
 103
 104## Site configuration (override autodetection)
 105## --with-PACKAGE[=ARG] and --without-PACKAGE
 106AC_MSG_NOTICE([CHECKS for site configuration])
 107#
 108# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 109# tests.  These tests take up a significant amount of the total test time
 110# but are not needed unless you plan to talk to SVN repos.
 111#
 112# Define MOZILLA_SHA1 environment variable when running make to make use of
 113# a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 114# on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 115# choice) has very fast version optimized for i586.
 116#
 117# Define PPC_SHA1 environment variable when running make to make use of
 118# a bundled SHA1 routine optimized for PowerPC.
 119#
 120# Define ARM_SHA1 environment variable when running make to make use of
 121# a bundled SHA1 routine optimized for ARM.
 122#
 123# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 124# This also implies MOZILLA_SHA1.
 125#
 126# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 127# /foo/bar/include and /foo/bar/lib directories.
 128AC_ARG_WITH(openssl,
 129AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 130AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 131GIT_PARSE_WITH(openssl))
 132#
 133# Define NO_CURL if you do not have curl installed.  git-http-pull and
 134# git-http-push are not built, and you cannot use http:// and https://
 135# transports.
 136#
 137# Define CURLDIR=/foo/bar if your curl header and library files are in
 138# /foo/bar/include and /foo/bar/lib directories.
 139AC_ARG_WITH(curl,
 140AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 141AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 142GIT_PARSE_WITH(curl))
 143#
 144# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 145# not built, and you cannot push using http:// and https:// transports.
 146#
 147# Define EXPATDIR=/foo/bar if your expat header and library files are in
 148# /foo/bar/include and /foo/bar/lib directories.
 149AC_ARG_WITH(expat,
 150AS_HELP_STRING([--with-expat],
 151[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 152AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 153GIT_PARSE_WITH(expat))
 154#
 155# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 156# installed in /sw, but don't want GIT to link against any libraries
 157# installed there.  If defined you may specify your own (or Fink's)
 158# include directories and library directories by defining CFLAGS
 159# and LDFLAGS appropriately.
 160#
 161# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 162# have DarwinPorts installed in /opt/local, but don't want GIT to
 163# link against any libraries installed there.  If defined you may
 164# specify your own (or DarwinPort's) include directories and
 165# library directories by defining CFLAGS and LDFLAGS appropriately.
 166#
 167# Define NO_MMAP if you want to avoid mmap.
 168#
 169# Define NO_ICONV if your libc does not properly support iconv.
 170AC_ARG_WITH(iconv,
 171AS_HELP_STRING([--without-iconv],
 172[if your architecture doesn't properly support iconv])
 173AS_HELP_STRING([--with-iconv=PATH],
 174[PATH is prefix for libiconv library and headers])
 175AS_HELP_STRING([],
 176[used only if you need linking with libiconv]),
 177GIT_PARSE_WITH(iconv))
 178
 179## --enable-FEATURE[=ARG] and --disable-FEATURE
 180#
 181# Define USE_NSEC below if you want git to care about sub-second file mtimes
 182# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 183# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 184# randomly break unless your underlying filesystem supports those sub-second
 185# times (my ext3 doesn't).
 186#
 187# Define USE_STDEV below if you want git to care about the underlying device
 188# change being considered an inode change from the update-index perspective.
 189
 190#
 191# Define SHELL_PATH to provide path to shell.
 192GIT_ARG_SET_PATH(shell)
 193#
 194# Define PERL_PATH to provide path to Perl.
 195GIT_ARG_SET_PATH(perl)
 196#
 197# Define ZLIB_PATH to provide path to zlib.
 198GIT_ARG_SET_PATH(zlib)
 199#
 200# Declare the with-tcltk/without-tcltk options.
 201AC_ARG_WITH(tcltk,
 202AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 203AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 204AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 205AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 206GIT_PARSE_WITH(tcltk))
 207#
 208
 209
 210## Checks for programs.
 211AC_MSG_NOTICE([CHECKS for programs])
 212#
 213AC_PROG_CC([cc gcc])
 214# which switch to pass runtime path to dynamic libraries to the linker
 215AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 216   SAVE_LDFLAGS="${LDFLAGS}"
 217   LDFLAGS="${SAVE_LDFLAGS} -R /"
 218   AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 219   LDFLAGS="${SAVE_LDFLAGS}"
 220])
 221if test "$git_cv_ld_dashr" = "yes"; then
 222   AC_SUBST(CC_LD_DYNPATH, [-R])
 223else
 224   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 225      SAVE_LDFLAGS="${LDFLAGS}"
 226      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 227      AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 228      LDFLAGS="${SAVE_LDFLAGS}"
 229   ])
 230   if test "$git_cv_ld_wl_rpath" = "yes"; then
 231      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 232   else
 233      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 234         SAVE_LDFLAGS="${LDFLAGS}"
 235         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 236         AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 237         LDFLAGS="${SAVE_LDFLAGS}"
 238      ])
 239      if test "$git_cv_ld_rpath" = "yes"; then
 240         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 241      else
 242         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 243      fi
 244   fi
 245fi
 246#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 247AC_CHECK_TOOLS(AR, [gar ar], :)
 248AC_CHECK_PROGS(TAR, [gtar tar])
 249# TCLTK_PATH will be set to some value if we want Tcl/Tk
 250# or will be empty otherwise.
 251if test -z "$NO_TCLTK"; then
 252  if test "$with_tcltk" = ""; then
 253  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 254    TCLTK_PATH=wish
 255    AC_SUBST(TCLTK_PATH)
 256  elif test "$with_tcltk" = "yes"; then
 257  # Tcl/Tk check requested.
 258    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 259  else
 260    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 261    TCLTK_PATH="$with_tcltk"
 262    AC_SUBST(TCLTK_PATH)
 263  fi
 264fi
 265AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 266if test -n "$ASCIIDOC"; then
 267        AC_MSG_CHECKING([for asciidoc version])
 268        asciidoc_version=`$ASCIIDOC --version 2>&1`
 269        case "${asciidoc_version}" in
 270        asciidoc' '8*)
 271                ASCIIDOC8=YesPlease
 272                AC_MSG_RESULT([${asciidoc_version} > 7])
 273                ;;
 274        asciidoc' '7*)
 275                ASCIIDOC8=
 276                AC_MSG_RESULT([${asciidoc_version}])
 277                ;;
 278        *)
 279                ASCIIDOC8=
 280                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 281                ;;
 282        esac
 283fi
 284AC_SUBST(ASCIIDOC8)
 285
 286
 287## Checks for libraries.
 288AC_MSG_NOTICE([CHECKS for libraries])
 289#
 290# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 291# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 292AC_CHECK_LIB([crypto], [SHA1_Init],
 293[NEEDS_SSL_WITH_CRYPTO=],
 294[AC_CHECK_LIB([ssl], [SHA1_Init],
 295 [NEEDS_SSL_WITH_CRYPTO=YesPlease
 296  NEEDS_SSL_WITH_CRYPTO=],
 297 [NO_OPENSSL=YesPlease])])
 298AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 299AC_SUBST(NO_OPENSSL)
 300#
 301# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 302# git-http-push are not built, and you cannot use http:// and https://
 303# transports.
 304AC_CHECK_LIB([curl], [curl_global_init],
 305[NO_CURL=],
 306[NO_CURL=YesPlease])
 307AC_SUBST(NO_CURL)
 308#
 309# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 310# not built, and you cannot push using http:// and https:// transports.
 311AC_CHECK_LIB([expat], [XML_ParserCreate],
 312[NO_EXPAT=],
 313[NO_EXPAT=YesPlease])
 314AC_SUBST(NO_EXPAT)
 315#
 316# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 317# some Solaris installations).
 318# Define NO_ICONV if neither libc nor libiconv support iconv.
 319AC_DEFUN([ICONVTEST_SRC], [
 320#include <iconv.h>
 321
 322int main(void)
 323{
 324        iconv_open("", "");
 325        return 0;
 326}
 327])
 328AC_MSG_CHECKING([for iconv in -lc])
 329AC_LINK_IFELSE(ICONVTEST_SRC,
 330        [AC_MSG_RESULT([yes])
 331        NEEDS_LIBICONV=],
 332        [AC_MSG_RESULT([no])
 333        old_LIBS="$LIBS"
 334        LIBS="$LIBS -liconv"
 335        AC_MSG_CHECKING([for iconv in -liconv])
 336        AC_LINK_IFELSE(ICONVTEST_SRC,
 337                [AC_MSG_RESULT([yes])
 338                NEEDS_LIBICONV=YesPlease],
 339                [AC_MSG_RESULT([no])
 340                NO_ICONV=YesPlease])
 341        LIBS="$old_LIBS"])
 342AC_SUBST(NEEDS_LIBICONV)
 343AC_SUBST(NO_ICONV)
 344test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 345#
 346# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 347AC_DEFUN([ZLIBTEST_SRC], [
 348#include <zlib.h>
 349
 350int main(void)
 351{
 352        deflateBound(0, 0);
 353        return 0;
 354}
 355])
 356AC_MSG_CHECKING([for deflateBound in -lz])
 357old_LIBS="$LIBS"
 358LIBS="$LIBS -lz"
 359AC_LINK_IFELSE(ZLIBTEST_SRC,
 360        [AC_MSG_RESULT([yes])],
 361        [AC_MSG_RESULT([no])
 362        NO_DEFLATE_BOUND=yes])
 363LIBS="$old_LIBS"
 364AC_SUBST(NO_DEFLATE_BOUND)
 365#
 366# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 367# Patrick Mauritz).
 368AC_CHECK_LIB([c], [socket],
 369[NEEDS_SOCKET=],
 370[NEEDS_SOCKET=YesPlease])
 371AC_SUBST(NEEDS_SOCKET)
 372test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 373
 374
 375## Checks for header files.
 376AC_MSG_NOTICE([CHECKS for header files])
 377#
 378# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 379AC_CHECK_HEADER([sys/select.h],
 380[NO_SYS_SELECT_H=],
 381[NO_SYS_SELECT_H=UnfortunatelyYes])
 382AC_SUBST(NO_SYS_SELECT_H)
 383#
 384# Define OLD_ICONV if your library has an old iconv(), where the second
 385# (input buffer pointer) parameter is declared with type (const char **).
 386AC_DEFUN([OLDICONVTEST_SRC], [[
 387#include <iconv.h>
 388
 389extern size_t iconv(iconv_t cd,
 390                    char **inbuf, size_t *inbytesleft,
 391                    char **outbuf, size_t *outbytesleft);
 392
 393int main(void)
 394{
 395        return 0;
 396}
 397]])
 398AC_MSG_CHECKING([for old iconv()])
 399AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 400        [AC_MSG_RESULT([no])],
 401        [AC_MSG_RESULT([yes])
 402        OLD_ICONV=UnfortunatelyYes])
 403AC_SUBST(OLD_ICONV)
 404
 405
 406## Checks for typedefs, structures, and compiler characteristics.
 407AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 408#
 409# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 410AC_CHECK_MEMBER(struct dirent.d_ino,
 411[NO_D_INO_IN_DIRENT=],
 412[NO_D_INO_IN_DIRENT=YesPlease],
 413[#include <dirent.h>])
 414AC_SUBST(NO_D_INO_IN_DIRENT)
 415#
 416# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 417# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 418AC_CHECK_MEMBER(struct dirent.d_type,
 419[NO_D_TYPE_IN_DIRENT=],
 420[NO_D_TYPE_IN_DIRENT=YesPlease],
 421[#include <dirent.h>])
 422AC_SUBST(NO_D_TYPE_IN_DIRENT)
 423#
 424# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 425# sockaddr_storage.
 426AC_CHECK_TYPE(struct sockaddr_storage,
 427[NO_SOCKADDR_STORAGE=],
 428[NO_SOCKADDR_STORAGE=YesPlease],[
 429#include <sys/types.h>
 430#include <sys/socket.h>
 431])
 432AC_SUBST(NO_SOCKADDR_STORAGE)
 433#
 434# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 435AC_CHECK_TYPE([struct addrinfo],[
 436 GIT_CHECK_FUNC([getaddrinfo],
 437  [NO_IPV6=],
 438  [NO_IPV6=YesPlease])
 439],[NO_IPV6=YesPlease],[
 440#include <sys/types.h>
 441#include <sys/socket.h>
 442#include <netdb.h>
 443])
 444AC_SUBST(NO_IPV6)
 445#
 446# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 447# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 448# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 449# some C compilers supported these specifiers prior to C99 as an extension.
 450AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 451 [ac_cv_c_c99_format],
 452[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 453AC_RUN_IFELSE(
 454        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 455                [[char buf[64];
 456                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 457                  return 1;
 458                else if (strcmp(buf, "12345"))
 459                  return 2;]])],
 460        [ac_cv_c_c99_format=yes],
 461        [ac_cv_c_c99_format=no])
 462])
 463if test $ac_cv_c_c99_format = no; then
 464        NO_C99_FORMAT=YesPlease
 465else
 466        NO_C99_FORMAT=
 467fi
 468AC_SUBST(NO_C99_FORMAT)
 469#
 470# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 471# when attempting to read from an fopen'ed directory.
 472AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 473 [ac_cv_fread_reads_directories],
 474[
 475AC_RUN_IFELSE(
 476        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 477                [[char c;
 478                FILE *f = fopen(".", "r");
 479                return f && fread(&c, 1, 1, f)]])],
 480        [ac_cv_fread_reads_directories=no],
 481        [ac_cv_fread_reads_directories=yes])
 482])
 483if test $ac_cv_fread_reads_directories = yes; then
 484        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 485else
 486        FREAD_READS_DIRECTORIES=
 487fi
 488AC_SUBST(FREAD_READS_DIRECTORIES)
 489#
 490# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 491# or vsnprintf() return -1 instead of number of characters which would
 492# have been written to the final string if enough space had been available.
 493AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 494 [ac_cv_snprintf_returns_bogus],
 495[
 496AC_RUN_IFELSE(
 497        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 498                #include "stdarg.h"
 499
 500                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 501                {
 502                  int ret;
 503                  va_list ap;
 504                  va_start(ap, format);
 505                  ret = vsnprintf(str, maxsize, format, ap);
 506                  va_end(ap);
 507                  return ret;
 508                }],
 509                [[char buf[6];
 510                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 511                      || strcmp(buf, "12")) return 1;
 512                  if (snprintf(buf, 3, "%s", "12345") != 5
 513                      || strcmp(buf, "12")) return 1]])],
 514        [ac_cv_snprintf_returns_bogus=no],
 515        [ac_cv_snprintf_returns_bogus=yes])
 516])
 517if test $ac_cv_snprintf_returns_bogus = yes; then
 518        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 519else
 520        SNPRINTF_RETURNS_BOGUS=
 521fi
 522AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 523
 524
 525## Checks for library functions.
 526## (in default C library and libraries checked by AC_CHECK_LIB)
 527AC_MSG_NOTICE([CHECKS for library functions])
 528#
 529# Define NO_STRCASESTR if you don't have strcasestr.
 530GIT_CHECK_FUNC(strcasestr,
 531[NO_STRCASESTR=],
 532[NO_STRCASESTR=YesPlease])
 533AC_SUBST(NO_STRCASESTR)
 534#
 535# Define NO_MEMMEM if you don't have memmem.
 536GIT_CHECK_FUNC(memmem,
 537[NO_MEMMEM=],
 538[NO_MEMMEM=YesPlease])
 539AC_SUBST(NO_MEMMEM)
 540#
 541# Define NO_STRLCPY if you don't have strlcpy.
 542GIT_CHECK_FUNC(strlcpy,
 543[NO_STRLCPY=],
 544[NO_STRLCPY=YesPlease])
 545AC_SUBST(NO_STRLCPY)
 546#
 547# Define NO_UINTMAX_T if your platform does not have uintmax_t
 548AC_CHECK_TYPE(uintmax_t,
 549[NO_UINTMAX_T=],
 550[NO_UINTMAX_T=YesPlease],[
 551#include <inttypes.h>
 552])
 553AC_SUBST(NO_UINTMAX_T)
 554#
 555# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 556GIT_CHECK_FUNC(strtoumax,
 557[NO_STRTOUMAX=],
 558[NO_STRTOUMAX=YesPlease])
 559AC_SUBST(NO_STRTOUMAX)
 560#
 561# Define NO_SETENV if you don't have setenv in the C library.
 562GIT_CHECK_FUNC(setenv,
 563[NO_SETENV=],
 564[NO_SETENV=YesPlease])
 565AC_SUBST(NO_SETENV)
 566#
 567# Define NO_UNSETENV if you don't have unsetenv in the C library.
 568GIT_CHECK_FUNC(unsetenv,
 569[NO_UNSETENV=],
 570[NO_UNSETENV=YesPlease])
 571AC_SUBST(NO_UNSETENV)
 572#
 573# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 574GIT_CHECK_FUNC(mkdtemp,
 575[NO_MKDTEMP=],
 576[NO_MKDTEMP=YesPlease])
 577AC_SUBST(NO_MKDTEMP)
 578#
 579# Define NO_MMAP if you want to avoid mmap.
 580#
 581# Define NO_ICONV if your libc does not properly support iconv.
 582
 583
 584## Other checks.
 585# Define USE_PIC if you need the main git objects to be built with -fPIC
 586# in order to build and link perl/Git.so.  x86-64 seems to need this.
 587#
 588# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 589# Enable it on Windows.  By default, symrefs are still used.
 590#
 591# Define NO_PTHREADS if we do not have pthreads
 592#
 593# Define PTHREAD_LIBS to the linker flag used for Pthread support and define
 594# THREADED_DELTA_SEARCH if Pthreads are available.
 595AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 596  [[#include <pthread.h>]],
 597  [[pthread_mutex_t test_mutex;]]
 598)])
 599${CC} -pthread conftest.c -o conftest.o > /dev/null 2>&1
 600if test $? -eq 0;then
 601 PTHREAD_LIBS="-pthread"
 602 THREADED_DELTA_SEARCH=YesPlease
 603else
 604 ${CC} -lpthread conftest.c -o conftest.o > /dev/null 2>&1
 605 if test $? -eq 0;then
 606  PTHREAD_LIBS="-lpthread"
 607  THREADED_DELTA_SEARCH=YesPlease
 608 else
 609  NO_PTHREADS=UnfortunatelyYes
 610 fi
 611fi
 612AC_SUBST(PTHREAD_LIBS)
 613AC_SUBST(NO_PTHREADS)
 614AC_SUBST(THREADED_DELTA_SEARCH)
 615
 616## Output files
 617AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 618AC_OUTPUT
 619
 620
 621## Cleanup
 622rm -f "${config_append}"