Andrew's git - gitweb.git/blob

   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_ERROR([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46        fi; \
  47fi; \
  48]) # GIT_CONF_APPEND_PATH
  49#
  50# GIT_PARSE_WITH(PACKAGE)
  51# -----------------------
  52# For use in AC_ARG_WITH action-if-found, for packages default ON.
  53# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56AC_DEFUN([GIT_PARSE_WITH],
  57[PACKAGE=m4_toupper($1); \
  58if test "$withval" = "no"; then \
  59        m4_toupper(NO_$1)=YesPlease; \
  60elif test "$withval" = "yes"; then \
  61        m4_toupper(NO_$1)=; \
  62else \
  63        m4_toupper(NO_$1)=; \
  64        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65fi \
  66])# GIT_PARSE_WITH
  67
  68
  69## Site configuration related to programs (before tests)
  70## --with-PACKAGE[=ARG] and --without-PACKAGE
  71#
  72# Set lib to alternative name of lib directory (e.g. lib64)
  73AC_ARG_WITH([lib],
  74 [AS_HELP_STRING([--with-lib=ARG],
  75                 [ARG specifies alternative name for lib directory])],
  76 [if test "$withval" = "no" || test "$withval" = "yes"; then \
  77        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
  78else \
  79        GIT_CONF_APPEND_LINE(lib=$withval); \
  80fi; \
  81],[])
  82#
  83# Define SHELL_PATH to provide path to shell.
  84GIT_ARG_SET_PATH(shell)
  85#
  86# Define PERL_PATH to provide path to Perl.
  87GIT_ARG_SET_PATH(perl)
  88#
  89# Define ZLIB_PATH to provide path to zlib.
  90GIT_ARG_SET_PATH(zlib)
  91#
  92# Declare the with-tcltk/without-tcltk options.
  93AC_ARG_WITH(tcltk,
  94AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
  95AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
  96AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
  97AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
  98GIT_PARSE_WITH(tcltk))
  99#
 100
 101
 102## Checks for programs.
 103AC_MSG_NOTICE([CHECKS for programs])
 104#
 105AC_PROG_CC([cc gcc])
 106#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 107AC_CHECK_TOOLS(AR, [gar ar], :)
 108AC_CHECK_PROGS(TAR, [gtar tar])
 109# TCLTK_PATH will be set to some value if we want Tcl/Tk
 110# or will be empty otherwise.
 111if test -z "$NO_TCLTK"; then
 112  if test "$with_tcltk" = ""; then
 113  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 114    TCLTK_PATH=wish
 115    AC_SUBST(TCLTK_PATH)
 116  elif test "$with_tcltk" = "yes"; then
 117  # Tcl/Tk check requested.
 118    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 119  else
 120    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 121    TCLTK_PATH="$with_tcltk"
 122    AC_SUBST(TCLTK_PATH)
 123  fi
 124fi
 125
 126## Checks for libraries.
 127AC_MSG_NOTICE([CHECKS for libraries])
 128#
 129# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 130# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 131AC_CHECK_LIB([crypto], [SHA1_Init],
 132[NEEDS_SSL_WITH_CRYPTO=],
 133[AC_CHECK_LIB([ssl], [SHA1_Init],
 134 [NEEDS_SSL_WITH_CRYPTO=YesPlease
 135  NEEDS_SSL_WITH_CRYPTO=],
 136 [NO_OPENSSL=YesPlease])])
 137AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 138AC_SUBST(NO_OPENSSL)
 139#
 140# Define NO_CURL if you do not have curl installed.  git-http-pull and
 141# git-http-push are not built, and you cannot use http:// and https://
 142# transports.
 143AC_CHECK_LIB([curl], [curl_global_init],
 144[NO_CURL=],
 145[NO_CURL=YesPlease])
 146AC_SUBST(NO_CURL)
 147#
 148# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 149# not built, and you cannot push using http:// and https:// transports.
 150AC_CHECK_LIB([expat], [XML_ParserCreate],
 151[NO_EXPAT=],
 152[NO_EXPAT=YesPlease])
 153AC_SUBST(NO_EXPAT)
 154#
 155# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 156# some Solaris installations).
 157# Define NO_ICONV if neither libc nor libiconv support iconv.
 158AC_DEFUN([ICONVTEST_SRC], [
 159#include <iconv.h>
 160
 161int main(void)
 162{
 163        iconv_open("", "");
 164        return 0;
 165}
 166])
 167AC_MSG_CHECKING([for iconv in -lc])
 168AC_LINK_IFELSE(ICONVTEST_SRC,
 169        [AC_MSG_RESULT([yes])
 170        NEEDS_LIBICONV=],
 171        [AC_MSG_RESULT([no])
 172        old_LIBS="$LIBS"
 173        LIBS="$LIBS -liconv"
 174        AC_MSG_CHECKING([for iconv in -liconv])
 175        AC_LINK_IFELSE(ICONVTEST_SRC,
 176                [AC_MSG_RESULT([yes])
 177                NEEDS_LIBICONV=YesPlease],
 178                [AC_MSG_RESULT([no])
 179                NO_ICONV=YesPlease])
 180        LIBS="$old_LIBS"])
 181AC_SUBST(NEEDS_LIBICONV)
 182AC_SUBST(NO_ICONV)
 183test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 184#
 185# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 186AC_DEFUN([ZLIBTEST_SRC], [
 187#include <zlib.h>
 188
 189int main(void)
 190{
 191        deflateBound(0, 0);
 192        return 0;
 193}
 194])
 195AC_MSG_CHECKING([for deflateBound in -lz])
 196old_LIBS="$LIBS"
 197LIBS="$LIBS -lz"
 198AC_LINK_IFELSE(ZLIBTEST_SRC,
 199        [AC_MSG_RESULT([yes])],
 200        [AC_MSG_RESULT([no])
 201        NO_DEFLATE_BOUND=yes])
 202LIBS="$old_LIBS"
 203AC_SUBST(NO_DEFLATE_BOUND)
 204#
 205# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 206# Patrick Mauritz).
 207AC_CHECK_LIB([c], [socket],
 208[NEEDS_SOCKET=],
 209[NEEDS_SOCKET=YesPlease])
 210AC_SUBST(NEEDS_SOCKET)
 211test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 212
 213
 214## Checks for header files.
 215
 216
 217## Checks for typedefs, structures, and compiler characteristics.
 218AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 219#
 220# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 221AC_CHECK_MEMBER(struct dirent.d_ino,
 222[NO_D_INO_IN_DIRENT=],
 223[NO_D_INO_IN_DIRENT=YesPlease],
 224[#include <dirent.h>])
 225AC_SUBST(NO_D_INO_IN_DIRENT)
 226#
 227# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 228# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 229AC_CHECK_MEMBER(struct dirent.d_type,
 230[NO_D_TYPE_IN_DIRENT=],
 231[NO_D_TYPE_IN_DIRENT=YesPlease],
 232[#include <dirent.h>])
 233AC_SUBST(NO_D_TYPE_IN_DIRENT)
 234#
 235# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 236# sockaddr_storage.
 237AC_CHECK_TYPE(struct sockaddr_storage,
 238[NO_SOCKADDR_STORAGE=],
 239[NO_SOCKADDR_STORAGE=YesPlease],[
 240#include <sys/types.h>
 241#include <sys/socket.h>
 242])
 243AC_SUBST(NO_SOCKADDR_STORAGE)
 244#
 245# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 246AC_CHECK_TYPE([struct addrinfo],[
 247 AC_CHECK_FUNC([getaddrinfo],
 248  [NO_IPV6=],
 249  [NO_IPV6=YesPlease])
 250],[NO_IPV6=YesPlease],[
 251#include <sys/types.h>
 252#include <sys/socket.h>
 253#include <netdb.h>
 254])
 255AC_SUBST(NO_IPV6)
 256#
 257# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 258# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 259# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 260# some C compilers supported these specifiers prior to C99 as an extension.
 261AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 262 [ac_cv_c_c99_format],
 263[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 264AC_RUN_IFELSE(
 265        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 266                [[char buf[64];
 267                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 268                  return 1;
 269                else if (strcmp(buf, "12345"))
 270                  return 2;]])],
 271        [ac_cv_c_c99_format=yes],
 272        [ac_cv_c_c99_format=no])
 273])
 274if test $ac_cv_c_c99_format = no; then
 275        NO_C99_FORMAT=YesPlease
 276else
 277        NO_C99_FORMAT=
 278fi
 279AC_SUBST(NO_C99_FORMAT)
 280
 281
 282## Checks for library functions.
 283## (in default C library and libraries checked by AC_CHECK_LIB)
 284AC_MSG_NOTICE([CHECKS for library functions])
 285#
 286# Define NO_STRCASESTR if you don't have strcasestr.
 287AC_CHECK_FUNC(strcasestr,
 288[NO_STRCASESTR=],
 289[NO_STRCASESTR=YesPlease])
 290AC_SUBST(NO_STRCASESTR)
 291#
 292# Define NO_STRLCPY if you don't have strlcpy.
 293AC_CHECK_FUNC(strlcpy,
 294[NO_STRLCPY=],
 295[NO_STRLCPY=YesPlease])
 296AC_SUBST(NO_STRLCPY)
 297#
 298# Define NO_SETENV if you don't have setenv in the C library.
 299AC_CHECK_FUNC(setenv,
 300[NO_SETENV=],
 301[NO_SETENV=YesPlease])
 302AC_SUBST(NO_SETENV)
 303#
 304# Define NO_MMAP if you want to avoid mmap.
 305#
 306# Define NO_ICONV if your libc does not properly support iconv.
 307
 308
 309## Other checks.
 310# Define USE_PIC if you need the main git objects to be built with -fPIC
 311# in order to build and link perl/Git.so.  x86-64 seems to need this.
 312#
 313# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 314# Enable it on Windows.  By default, symrefs are still used.
 315
 316## Site configuration (override autodetection)
 317## --with-PACKAGE[=ARG] and --without-PACKAGE
 318AC_MSG_NOTICE([CHECKS for site configuration])
 319#
 320# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 321# tests.  These tests take up a significant amount of the total test time
 322# but are not needed unless you plan to talk to SVN repos.
 323#
 324# Define MOZILLA_SHA1 environment variable when running make to make use of
 325# a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 326# on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 327# choice) has very fast version optimized for i586.
 328#
 329# Define PPC_SHA1 environment variable when running make to make use of
 330# a bundled SHA1 routine optimized for PowerPC.
 331#
 332# Define ARM_SHA1 environment variable when running make to make use of
 333# a bundled SHA1 routine optimized for ARM.
 334#
 335# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 336# This also implies MOZILLA_SHA1.
 337#
 338# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 339# /foo/bar/include and /foo/bar/lib directories.
 340AC_ARG_WITH(openssl,
 341AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 342AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 343GIT_PARSE_WITH(openssl))
 344#
 345# Define NO_CURL if you do not have curl installed.  git-http-pull and
 346# git-http-push are not built, and you cannot use http:// and https://
 347# transports.
 348#
 349# Define CURLDIR=/foo/bar if your curl header and library files are in
 350# /foo/bar/include and /foo/bar/lib directories.
 351AC_ARG_WITH(curl,
 352AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 353AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 354GIT_PARSE_WITH(curl))
 355#
 356# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 357# not built, and you cannot push using http:// and https:// transports.
 358#
 359# Define EXPATDIR=/foo/bar if your expat header and library files are in
 360# /foo/bar/include and /foo/bar/lib directories.
 361AC_ARG_WITH(expat,
 362AS_HELP_STRING([--with-expat],
 363[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 364AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 365GIT_PARSE_WITH(expat))
 366#
 367# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 368# installed in /sw, but don't want GIT to link against any libraries
 369# installed there.  If defined you may specify your own (or Fink's)
 370# include directories and library directories by defining CFLAGS
 371# and LDFLAGS appropriately.
 372#
 373# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 374# have DarwinPorts installed in /opt/local, but don't want GIT to
 375# link against any libraries installed there.  If defined you may
 376# specify your own (or DarwinPort's) include directories and
 377# library directories by defining CFLAGS and LDFLAGS appropriately.
 378#
 379# Define NO_MMAP if you want to avoid mmap.
 380#
 381# Define NO_ICONV if your libc does not properly support iconv.
 382AC_ARG_WITH(iconv,
 383AS_HELP_STRING([--without-iconv],
 384[if your architecture doesn't properly support iconv])
 385AS_HELP_STRING([--with-iconv=PATH],
 386[PATH is prefix for libiconv library and headers])
 387AS_HELP_STRING([],
 388[used only if you need linking with libiconv]),
 389GIT_PARSE_WITH(iconv))
 390
 391## --enable-FEATURE[=ARG] and --disable-FEATURE
 392#
 393# Define USE_NSEC below if you want git to care about sub-second file mtimes
 394# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 395# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 396# randomly break unless your underlying filesystem supports those sub-second
 397# times (my ext3 doesn't).
 398#
 399# Define USE_STDEV below if you want git to care about the underlying device
 400# change being considered an inode change from the update-cache perspective.
 401
 402
 403## Output files
 404AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 405AC_OUTPUT
 406
 407
 408## Cleanup
 409rm -f "${config_append}"