Andrew's git - gitweb.git/blob

   1#!/bin/sh
   2# Tcl ignores the next line -*- tcl -*- \
   3 if test "z$*" = zversion \
   4 || test "z$*" = z--version; \
   5 then \
   6        echo 'git-gui version @@GITGUI_VERSION@@'; \
   7        exit; \
   8 fi; \
   9 argv0=$0; \
  10 exec wish "$argv0" -- "$@"
  11
  12set appvers {@@GITGUI_VERSION@@}
  13set copyright [encoding convertfrom utf-8 {
  14Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16This program is free software; you can redistribute it and/or modify
  17it under the terms of the GNU General Public License as published by
  18the Free Software Foundation; either version 2 of the License, or
  19(at your option) any later version.
  20
  21This program is distributed in the hope that it will be useful,
  22but WITHOUT ANY WARRANTY; without even the implied warranty of
  23MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24GNU General Public License for more details.
  25
  26You should have received a copy of the GNU General Public License
  27along with this program; if not, write to the Free Software
  28Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30######################################################################
  31##
  32## Tcl/Tk sanity check
  33
  34if {[catch {package require Tcl 8.4} err]
  35 || [catch {package require Tk  8.4} err]
  36} {
  37        catch {wm withdraw .}
  38        tk_messageBox \
  39                -icon error \
  40                -type ok \
  41                -title [mc "git-gui: fatal error"] \
  42                -message $err
  43        exit 1
  44}
  45
  46catch {rename send {}} ; # What an evil concept...
  47
  48######################################################################
  49##
  50## locate our library
  51
  52set oguilib {@@GITGUI_LIBDIR@@}
  53set oguirel {@@GITGUI_RELATIVE@@}
  54if {$oguirel eq {1}} {
  55        set oguilib [file dirname [file normalize $argv0]]
  56        if {[file tail $oguilib] eq {git-core}} {
  57                set oguilib [file dirname $oguilib]
  58        }
  59        set oguilib [file dirname $oguilib]
  60        set oguilib [file join $oguilib share git-gui lib]
  61        set oguimsg [file join $oguilib msgs]
  62} elseif {[string match @@* $oguirel]} {
  63        set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64        set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65} else {
  66        set oguimsg [file join $oguilib msgs]
  67}
  68unset oguirel
  69
  70######################################################################
  71##
  72## enable verbose loading?
  73
  74if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75        unset _verbose
  76        rename auto_load real__auto_load
  77        proc auto_load {name args} {
  78                puts stderr "auto_load $name"
  79                return [uplevel 1 real__auto_load $name $args]
  80        }
  81        rename source real__source
  82        proc source {name} {
  83                puts stderr "source    $name"
  84                uplevel 1 real__source $name
  85        }
  86}
  87
  88######################################################################
  89##
  90## Internationalization (i18n) through msgcat and gettext. See
  91## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93package require msgcat
  94
  95proc _mc_trim {fmt} {
  96        set cmk [string first @@ $fmt]
  97        if {$cmk > 0} {
  98                return [string range $fmt 0 [expr {$cmk - 1}]]
  99        }
 100        return $fmt
 101}
 102
 103proc mc {en_fmt args} {
 104        set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105        if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107        }
 108        return $msg
 109}
 110
 111proc strcat {args} {
 112        return [join $args {}]
 113}
 114
 115::msgcat::mcload $oguimsg
 116unset oguimsg
 117
 118######################################################################
 119##
 120## read only globals
 121
 122set _appname {Git Gui}
 123set _gitdir {}
 124set _gitexec {}
 125set _githtmldir {}
 126set _reponame {}
 127set _iscygwin {}
 128set _search_path {}
 129
 130set _trace [lsearch -exact $argv --trace]
 131if {$_trace >= 0} {
 132        set argv [lreplace $argv $_trace $_trace]
 133        set _trace 1
 134} else {
 135        set _trace 0
 136}
 137
 138proc appname {} {
 139        global _appname
 140        return $_appname
 141}
 142
 143proc gitdir {args} {
 144        global _gitdir
 145        if {$args eq {}} {
 146                return $_gitdir
 147        }
 148        return [eval [list file join $_gitdir] $args]
 149}
 150
 151proc gitexec {args} {
 152        global _gitexec
 153        if {$_gitexec eq {}} {
 154                if {[catch {set _gitexec [git --exec-path]} err]} {
 155                        error "Git not installed?\n\n$err"
 156                }
 157                if {[is_Cygwin]} {
 158                        set _gitexec [exec cygpath \
 159                                --windows \
 160                                --absolute \
 161                                $_gitexec]
 162                } else {
 163                        set _gitexec [file normalize $_gitexec]
 164                }
 165        }
 166        if {$args eq {}} {
 167                return $_gitexec
 168        }
 169        return [eval [list file join $_gitexec] $args]
 170}
 171
 172proc githtmldir {args} {
 173        global _githtmldir
 174        if {$_githtmldir eq {}} {
 175                if {[catch {set _githtmldir [git --html-path]}]} {
 176                        # Git not installed or option not yet supported
 177                        return {}
 178                }
 179                if {[is_Cygwin]} {
 180                        set _githtmldir [exec cygpath \
 181                                --windows \
 182                                --absolute \
 183                                $_githtmldir]
 184                } else {
 185                        set _githtmldir [file normalize $_githtmldir]
 186                }
 187        }
 188        if {$args eq {}} {
 189                return $_githtmldir
 190        }
 191        return [eval [list file join $_githtmldir] $args]
 192}
 193
 194proc reponame {} {
 195        return $::_reponame
 196}
 197
 198proc is_MacOSX {} {
 199        if {[tk windowingsystem] eq {aqua}} {
 200                return 1
 201        }
 202        return 0
 203}
 204
 205proc is_Windows {} {
 206        if {$::tcl_platform(platform) eq {windows}} {
 207                return 1
 208        }
 209        return 0
 210}
 211
 212proc is_Cygwin {} {
 213        global _iscygwin
 214        if {$_iscygwin eq {}} {
 215                if {$::tcl_platform(platform) eq {windows}} {
 216                        if {[catch {set p [exec cygpath --windir]} err]} {
 217                                set _iscygwin 0
 218                        } else {
 219                                set _iscygwin 1
 220                        }
 221                } else {
 222                        set _iscygwin 0
 223                }
 224        }
 225        return $_iscygwin
 226}
 227
 228proc is_enabled {option} {
 229        global enabled_options
 230        if {[catch {set on $enabled_options($option)}]} {return 0}
 231        return $on
 232}
 233
 234proc enable_option {option} {
 235        global enabled_options
 236        set enabled_options($option) 1
 237}
 238
 239proc disable_option {option} {
 240        global enabled_options
 241        set enabled_options($option) 0
 242}
 243
 244######################################################################
 245##
 246## config
 247
 248proc is_many_config {name} {
 249        switch -glob -- $name {
 250        gui.recentrepo -
 251        remote.*.fetch -
 252        remote.*.push
 253                {return 1}
 254        *
 255                {return 0}
 256        }
 257}
 258
 259proc is_config_true {name} {
 260        global repo_config
 261        if {[catch {set v $repo_config($name)}]} {
 262                return 0
 263        } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 264                return 1
 265        } else {
 266                return 0
 267        }
 268}
 269
 270proc get_config {name} {
 271        global repo_config
 272        if {[catch {set v $repo_config($name)}]} {
 273                return {}
 274        } else {
 275                return $v
 276        }
 277}
 278
 279######################################################################
 280##
 281## handy utils
 282
 283proc _trace_exec {cmd} {
 284        if {!$::_trace} return
 285        set d {}
 286        foreach v $cmd {
 287                if {$d ne {}} {
 288                        append d { }
 289                }
 290                if {[regexp {[ \t\r\n'"$?*]} $v]} {
 291                        set v [sq $v]
 292                }
 293                append d $v
 294        }
 295        puts stderr $d
 296}
 297
 298proc _git_cmd {name} {
 299        global _git_cmd_path
 300
 301        if {[catch {set v $_git_cmd_path($name)}]} {
 302                switch -- $name {
 303                  version   -
 304                --version   -
 305                --exec-path { return [list $::_git $name] }
 306                }
 307
 308                set p [gitexec git-$name$::_search_exe]
 309                if {[file exists $p]} {
 310                        set v [list $p]
 311                } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 312                        # Try to determine what sort of magic will make
 313                        # git-$name go and do its thing, because native
 314                        # Tcl on Windows doesn't know it.
 315                        #
 316                        set p [gitexec git-$name]
 317                        set f [open $p r]
 318                        set s [gets $f]
 319                        close $f
 320
 321                        switch -glob -- [lindex $s 0] {
 322                        #!*sh     { set i sh     }
 323                        #!*perl   { set i perl   }
 324                        #!*python { set i python }
 325                        default   { error "git-$name is not supported: $s" }
 326                        }
 327
 328                        upvar #0 _$i interp
 329                        if {![info exists interp]} {
 330                                set interp [_which $i]
 331                        }
 332                        if {$interp eq {}} {
 333                                error "git-$name requires $i (not in PATH)"
 334                        }
 335                        set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 336                } else {
 337                        # Assume it is builtin to git somehow and we
 338                        # aren't actually able to see a file for it.
 339                        #
 340                        set v [list $::_git $name]
 341                }
 342                set _git_cmd_path($name) $v
 343        }
 344        return $v
 345}
 346
 347proc _which {what args} {
 348        global env _search_exe _search_path
 349
 350        if {$_search_path eq {}} {
 351                if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 352                        set _search_path [split [exec cygpath \
 353                                --windows \
 354                                --path \
 355                                --absolute \
 356                                $env(PATH)] {;}]
 357                        set _search_exe .exe
 358                } elseif {[is_Windows]} {
 359                        set gitguidir [file dirname [info script]]
 360                        regsub -all ";" $gitguidir "\\;" gitguidir
 361                        set env(PATH) "$gitguidir;$env(PATH)"
 362                        set _search_path [split $env(PATH) {;}]
 363                        set _search_exe .exe
 364                } else {
 365                        set _search_path [split $env(PATH) :]
 366                        set _search_exe {}
 367                }
 368        }
 369
 370        if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 371                set suffix {}
 372        } else {
 373                set suffix $_search_exe
 374        }
 375
 376        foreach p $_search_path {
 377                set p [file join $p $what$suffix]
 378                if {[file exists $p]} {
 379                        return [file normalize $p]
 380                }
 381        }
 382        return {}
 383}
 384
 385proc _lappend_nice {cmd_var} {
 386        global _nice
 387        upvar $cmd_var cmd
 388
 389        if {![info exists _nice]} {
 390                set _nice [_which nice]
 391        }
 392        if {$_nice ne {}} {
 393                lappend cmd $_nice
 394        }
 395}
 396
 397proc git {args} {
 398        set opt [list]
 399
 400        while {1} {
 401                switch -- [lindex $args 0] {
 402                --nice {
 403                        _lappend_nice opt
 404                }
 405
 406                default {
 407                        break
 408                }
 409
 410                }
 411
 412                set args [lrange $args 1 end]
 413        }
 414
 415        set cmdp [_git_cmd [lindex $args 0]]
 416        set args [lrange $args 1 end]
 417
 418        _trace_exec [concat $opt $cmdp $args]
 419        set result [eval exec $opt $cmdp $args]
 420        if {$::_trace} {
 421                puts stderr "< $result"
 422        }
 423        return $result
 424}
 425
 426proc _open_stdout_stderr {cmd} {
 427        _trace_exec $cmd
 428        if {[catch {
 429                        set fd [open [concat [list | ] $cmd] r]
 430                } err]} {
 431                if {   [lindex $cmd end] eq {2>@1}
 432                    && $err eq {can not find channel named "1"}
 433                        } {
 434                        # Older versions of Tcl 8.4 don't have this 2>@1 IO
 435                        # redirect operator.  Fallback to |& cat for those.
 436                        # The command was not actually started, so its safe
 437                        # to try to start it a second time.
 438                        #
 439                        set fd [open [concat \
 440                                [list | ] \
 441                                [lrange $cmd 0 end-1] \
 442                                [list |& cat] \
 443                                ] r]
 444                } else {
 445                        error $err
 446                }
 447        }
 448        fconfigure $fd -eofchar {}
 449        return $fd
 450}
 451
 452proc git_read {args} {
 453        set opt [list]
 454
 455        while {1} {
 456                switch -- [lindex $args 0] {
 457                --nice {
 458                        _lappend_nice opt
 459                }
 460
 461                --stderr {
 462                        lappend args 2>@1
 463                }
 464
 465                default {
 466                        break
 467                }
 468
 469                }
 470
 471                set args [lrange $args 1 end]
 472        }
 473
 474        set cmdp [_git_cmd [lindex $args 0]]
 475        set args [lrange $args 1 end]
 476
 477        return [_open_stdout_stderr [concat $opt $cmdp $args]]
 478}
 479
 480proc git_write {args} {
 481        set opt [list]
 482
 483        while {1} {
 484                switch -- [lindex $args 0] {
 485                --nice {
 486                        _lappend_nice opt
 487                }
 488
 489                default {
 490                        break
 491                }
 492
 493                }
 494
 495                set args [lrange $args 1 end]
 496        }
 497
 498        set cmdp [_git_cmd [lindex $args 0]]
 499        set args [lrange $args 1 end]
 500
 501        _trace_exec [concat $opt $cmdp $args]
 502        return [open [concat [list | ] $opt $cmdp $args] w]
 503}
 504
 505proc githook_read {hook_name args} {
 506        set pchook [gitdir hooks $hook_name]
 507        lappend args 2>@1
 508
 509        # On Windows [file executable] might lie so we need to ask
 510        # the shell if the hook is executable.  Yes that's annoying.
 511        #
 512        if {[is_Windows]} {
 513                upvar #0 _sh interp
 514                if {![info exists interp]} {
 515                        set interp [_which sh]
 516                }
 517                if {$interp eq {}} {
 518                        error "hook execution requires sh (not in PATH)"
 519                }
 520
 521                set scr {if test -x "$1";then exec "$@";fi}
 522                set sh_c [list $interp -c $scr $interp $pchook]
 523                return [_open_stdout_stderr [concat $sh_c $args]]
 524        }
 525
 526        if {[file executable $pchook]} {
 527                return [_open_stdout_stderr [concat [list $pchook] $args]]
 528        }
 529
 530        return {}
 531}
 532
 533proc kill_file_process {fd} {
 534        set process [pid $fd]
 535
 536        catch {
 537                if {[is_Windows]} {
 538                        # Use a Cygwin-specific flag to allow killing
 539                        # native Windows processes
 540                        exec kill -f $process
 541                } else {
 542                        exec kill $process
 543                }
 544        }
 545}
 546
 547proc gitattr {path attr default} {
 548        if {[catch {set r [git check-attr $attr -- $path]}]} {
 549                set r unspecified
 550        } else {
 551                set r [join [lrange [split $r :] 2 end] :]
 552                regsub {^ } $r {} r
 553        }
 554        if {$r eq {unspecified}} {
 555                return $default
 556        }
 557        return $r
 558}
 559
 560proc sq {value} {
 561        regsub -all ' $value "'\\''" value
 562        return "'$value'"
 563}
 564
 565proc load_current_branch {} {
 566        global current_branch is_detached
 567
 568        set fd [open [gitdir HEAD] r]
 569        if {[gets $fd ref] < 1} {
 570                set ref {}
 571        }
 572        close $fd
 573
 574        set pfx {ref: refs/heads/}
 575        set len [string length $pfx]
 576        if {[string equal -length $len $pfx $ref]} {
 577                # We're on a branch.  It might not exist.  But
 578                # HEAD looks good enough to be a branch.
 579                #
 580                set current_branch [string range $ref $len end]
 581                set is_detached 0
 582        } else {
 583                # Assume this is a detached head.
 584                #
 585                set current_branch HEAD
 586                set is_detached 1
 587        }
 588}
 589
 590auto_load tk_optionMenu
 591rename tk_optionMenu real__tkOptionMenu
 592proc tk_optionMenu {w varName args} {
 593        set m [eval real__tkOptionMenu $w $varName $args]
 594        $m configure -font font_ui
 595        $w configure -font font_ui
 596        return $m
 597}
 598
 599proc rmsel_tag {text} {
 600        $text tag conf sel \
 601                -background [$text cget -background] \
 602                -foreground [$text cget -foreground] \
 603                -borderwidth 0
 604        $text tag conf in_sel -background lightgray
 605        bind $text <Motion> break
 606        return $text
 607}
 608
 609set root_exists 0
 610bind . <Visibility> {
 611        bind . <Visibility> {}
 612        set root_exists 1
 613}
 614
 615if {[is_Windows]} {
 616        wm iconbitmap . -default $oguilib/git-gui.ico
 617        set ::tk::AlwaysShowSelection 1
 618
 619        # Spoof an X11 display for SSH
 620        if {![info exists env(DISPLAY)]} {
 621                set env(DISPLAY) :9999
 622        }
 623} else {
 624        catch {
 625                image create photo gitlogo -width 16 -height 16
 626
 627                gitlogo put #33CC33 -to  7  0  9  2
 628                gitlogo put #33CC33 -to  4  2 12  4
 629                gitlogo put #33CC33 -to  7  4  9  6
 630                gitlogo put #CC3333 -to  4  6 12  8
 631                gitlogo put gray26  -to  4  9  6 10
 632                gitlogo put gray26  -to  3 10  6 12
 633                gitlogo put gray26  -to  8  9 13 11
 634                gitlogo put gray26  -to  8 11 10 12
 635                gitlogo put gray26  -to 11 11 13 14
 636                gitlogo put gray26  -to  3 12  5 14
 637                gitlogo put gray26  -to  5 13
 638                gitlogo put gray26  -to 10 13
 639                gitlogo put gray26  -to  4 14 12 15
 640                gitlogo put gray26  -to  5 15 11 16
 641                gitlogo redither
 642
 643                wm iconphoto . -default gitlogo
 644        }
 645}
 646
 647######################################################################
 648##
 649## config defaults
 650
 651set cursor_ptr arrow
 652font create font_diff -family Courier -size 10
 653font create font_ui
 654catch {
 655        label .dummy
 656        eval font configure font_ui [font actual [.dummy cget -font]]
 657        destroy .dummy
 658}
 659
 660font create font_uiitalic
 661font create font_uibold
 662font create font_diffbold
 663font create font_diffitalic
 664
 665foreach class {Button Checkbutton Entry Label
 666                Labelframe Listbox Message
 667                Radiobutton Spinbox Text} {
 668        option add *$class.font font_ui
 669}
 670if {![is_MacOSX]} {
 671        option add *Menu.font font_ui
 672}
 673unset class
 674
 675if {[is_Windows] || [is_MacOSX]} {
 676        option add *Menu.tearOff 0
 677}
 678
 679if {[is_MacOSX]} {
 680        set M1B M1
 681        set M1T Cmd
 682} else {
 683        set M1B Control
 684        set M1T Ctrl
 685}
 686
 687proc bind_button3 {w cmd} {
 688        bind $w <Any-Button-3> $cmd
 689        if {[is_MacOSX]} {
 690                # Mac OS X sends Button-2 on right click through three-button mouse,
 691                # or through trackpad right-clicking (two-finger touch + click).
 692                bind $w <Any-Button-2> $cmd
 693                bind $w <Control-Button-1> $cmd
 694        }
 695}
 696
 697proc apply_config {} {
 698        global repo_config font_descs
 699
 700        foreach option $font_descs {
 701                set name [lindex $option 0]
 702                set font [lindex $option 1]
 703                if {[catch {
 704                        set need_weight 1
 705                        foreach {cn cv} $repo_config(gui.$name) {
 706                                if {$cn eq {-weight}} {
 707                                        set need_weight 0
 708                                }
 709                                font configure $font $cn $cv
 710                        }
 711                        if {$need_weight} {
 712                                font configure $font -weight normal
 713                        }
 714                        } err]} {
 715                        error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 716                }
 717                foreach {cn cv} [font configure $font] {
 718                        font configure ${font}bold $cn $cv
 719                        font configure ${font}italic $cn $cv
 720                }
 721                font configure ${font}bold -weight bold
 722                font configure ${font}italic -slant italic
 723        }
 724}
 725
 726set default_config(branch.autosetupmerge) true
 727set default_config(merge.tool) {}
 728set default_config(mergetool.keepbackup) true
 729set default_config(merge.diffstat) true
 730set default_config(merge.summary) false
 731set default_config(merge.verbosity) 2
 732set default_config(user.name) {}
 733set default_config(user.email) {}
 734
 735set default_config(gui.encoding) [encoding system]
 736set default_config(gui.matchtrackingbranch) false
 737set default_config(gui.pruneduringfetch) false
 738set default_config(gui.trustmtime) false
 739set default_config(gui.fastcopyblame) false
 740set default_config(gui.copyblamethreshold) 40
 741set default_config(gui.blamehistoryctx) 7
 742set default_config(gui.diffcontext) 5
 743set default_config(gui.commitmsgwidth) 75
 744set default_config(gui.newbranchtemplate) {}
 745set default_config(gui.spellingdictionary) {}
 746set default_config(gui.fontui) [font configure font_ui]
 747set default_config(gui.fontdiff) [font configure font_diff]
 748# TODO: this option should be added to the git-config documentation
 749set default_config(gui.maxfilesdisplayed) 5000
 750set font_descs {
 751        {fontui   font_ui   {mc "Main Font"}}
 752        {fontdiff font_diff {mc "Diff/Console Font"}}
 753}
 754
 755######################################################################
 756##
 757## find git
 758
 759set _git  [_which git]
 760if {$_git eq {}} {
 761        catch {wm withdraw .}
 762        tk_messageBox \
 763                -icon error \
 764                -type ok \
 765                -title [mc "git-gui: fatal error"] \
 766                -message [mc "Cannot find git in PATH."]
 767        exit 1
 768}
 769
 770######################################################################
 771##
 772## version check
 773
 774if {[catch {set _git_version [git --version]} err]} {
 775        catch {wm withdraw .}
 776        tk_messageBox \
 777                -icon error \
 778                -type ok \
 779                -title [mc "git-gui: fatal error"] \
 780                -message "Cannot determine Git version:
 781
 782$err
 783
 784[appname] requires Git 1.5.0 or later."
 785        exit 1
 786}
 787if {![regsub {^git version } $_git_version {} _git_version]} {
 788        catch {wm withdraw .}
 789        tk_messageBox \
 790                -icon error \
 791                -type ok \
 792                -title [mc "git-gui: fatal error"] \
 793                -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 794        exit 1
 795}
 796
 797set _real_git_version $_git_version
 798regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 799regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 800regsub {\.[a-zA-Z]+\.?[0-9]+$} $_git_version {} _git_version
 801regsub {\.GIT$} $_git_version {} _git_version
 802regsub {\.[a-zA-Z]+\.?[0-9]+$} $_git_version {} _git_version
 803
 804if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 805        catch {wm withdraw .}
 806        if {[tk_messageBox \
 807                -icon warning \
 808                -type yesno \
 809                -default no \
 810                -title "[appname]: warning" \
 811                 -message [mc "Git version cannot be determined.
 812
 813%s claims it is version '%s'.
 814
 815%s requires at least Git 1.5.0 or later.
 816
 817Assume '%s' is version 1.5.0?
 818" $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 819                set _git_version 1.5.0
 820        } else {
 821                exit 1
 822        }
 823}
 824unset _real_git_version
 825
 826proc git-version {args} {
 827        global _git_version
 828
 829        switch [llength $args] {
 830        0 {
 831                return $_git_version
 832        }
 833
 834        2 {
 835                set op [lindex $args 0]
 836                set vr [lindex $args 1]
 837                set cm [package vcompare $_git_version $vr]
 838                return [expr $cm $op 0]
 839        }
 840
 841        4 {
 842                set type [lindex $args 0]
 843                set name [lindex $args 1]
 844                set parm [lindex $args 2]
 845                set body [lindex $args 3]
 846
 847                if {($type ne {proc} && $type ne {method})} {
 848                        error "Invalid arguments to git-version"
 849                }
 850                if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 851                        error "Last arm of $type $name must be default"
 852                }
 853
 854                foreach {op vr cb} [lrange $body 0 end-2] {
 855                        if {[git-version $op $vr]} {
 856                                return [uplevel [list $type $name $parm $cb]]
 857                        }
 858                }
 859
 860                return [uplevel [list $type $name $parm [lindex $body end]]]
 861        }
 862
 863        default {
 864                error "git-version >= x"
 865        }
 866
 867        }
 868}
 869
 870if {[git-version < 1.5]} {
 871        catch {wm withdraw .}
 872        tk_messageBox \
 873                -icon error \
 874                -type ok \
 875                -title [mc "git-gui: fatal error"] \
 876                -message "[appname] requires Git 1.5.0 or later.
 877
 878You are using [git-version]:
 879
 880[git --version]"
 881        exit 1
 882}
 883
 884######################################################################
 885##
 886## configure our library
 887
 888set idx [file join $oguilib tclIndex]
 889if {[catch {set fd [open $idx r]} err]} {
 890        catch {wm withdraw .}
 891        tk_messageBox \
 892                -icon error \
 893                -type ok \
 894                -title [mc "git-gui: fatal error"] \
 895                -message $err
 896        exit 1
 897}
 898if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 899        set idx [list]
 900        while {[gets $fd n] >= 0} {
 901                if {$n ne {} && ![string match #* $n]} {
 902                        lappend idx $n
 903                }
 904        }
 905} else {
 906        set idx {}
 907}
 908close $fd
 909
 910if {$idx ne {}} {
 911        set loaded [list]
 912        foreach p $idx {
 913                if {[lsearch -exact $loaded $p] >= 0} continue
 914                source [file join $oguilib $p]
 915                lappend loaded $p
 916        }
 917        unset loaded p
 918} else {
 919        set auto_path [concat [list $oguilib] $auto_path]
 920}
 921unset -nocomplain idx fd
 922
 923######################################################################
 924##
 925## config file parsing
 926
 927git-version proc _parse_config {arr_name args} {
 928        >= 1.5.3 {
 929                upvar $arr_name arr
 930                array unset arr
 931                set buf {}
 932                catch {
 933                        set fd_rc [eval \
 934                                [list git_read config] \
 935                                $args \
 936                                [list --null --list]]
 937                        fconfigure $fd_rc -translation binary
 938                        set buf [read $fd_rc]
 939                        close $fd_rc
 940                }
 941                foreach line [split $buf "\0"] {
 942                        if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 943                                if {[is_many_config $name]} {
 944                                        lappend arr($name) $value
 945                                } else {
 946                                        set arr($name) $value
 947                                }
 948                        }
 949                }
 950        }
 951        default {
 952                upvar $arr_name arr
 953                array unset arr
 954                catch {
 955                        set fd_rc [eval [list git_read config --list] $args]
 956                        while {[gets $fd_rc line] >= 0} {
 957                                if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 958                                        if {[is_many_config $name]} {
 959                                                lappend arr($name) $value
 960                                        } else {
 961                                                set arr($name) $value
 962                                        }
 963                                }
 964                        }
 965                        close $fd_rc
 966                }
 967        }
 968}
 969
 970proc load_config {include_global} {
 971        global repo_config global_config system_config default_config
 972
 973        if {$include_global} {
 974                _parse_config system_config --system
 975                _parse_config global_config --global
 976        }
 977        _parse_config repo_config
 978
 979        foreach name [array names default_config] {
 980                if {[catch {set v $system_config($name)}]} {
 981                        set system_config($name) $default_config($name)
 982                }
 983        }
 984        foreach name [array names system_config] {
 985                if {[catch {set v $global_config($name)}]} {
 986                        set global_config($name) $system_config($name)
 987                }
 988                if {[catch {set v $repo_config($name)}]} {
 989                        set repo_config($name) $system_config($name)
 990                }
 991        }
 992}
 993
 994######################################################################
 995##
 996## feature option selection
 997
 998if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 999        unset _junk
1000} else {
1001        set subcommand gui
1002}
1003if {$subcommand eq {gui.sh}} {
1004        set subcommand gui
1005}
1006if {$subcommand eq {gui} && [llength $argv] > 0} {
1007        set subcommand [lindex $argv 0]
1008        set argv [lrange $argv 1 end]
1009}
1010
1011enable_option multicommit
1012enable_option branch
1013enable_option transport
1014disable_option bare
1015
1016switch -- $subcommand {
1017browser -
1018blame {
1019        enable_option bare
1020
1021        disable_option multicommit
1022        disable_option branch
1023        disable_option transport
1024}
1025citool {
1026        enable_option singlecommit
1027        enable_option retcode
1028
1029        disable_option multicommit
1030        disable_option branch
1031        disable_option transport
1032
1033        while {[llength $argv] > 0} {
1034                set a [lindex $argv 0]
1035                switch -- $a {
1036                --amend {
1037                        enable_option initialamend
1038                }
1039                --nocommit {
1040                        enable_option nocommit
1041                        enable_option nocommitmsg
1042                }
1043                --commitmsg {
1044                        disable_option nocommitmsg
1045                }
1046                default {
1047                        break
1048                }
1049                }
1050
1051                set argv [lrange $argv 1 end]
1052        }
1053}
1054}
1055
1056######################################################################
1057##
1058## execution environment
1059
1060set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1061
1062# Suggest our implementation of askpass, if none is set
1063if {![info exists env(SSH_ASKPASS)]} {
1064        set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1065}
1066
1067######################################################################
1068##
1069## repository setup
1070
1071set picked 0
1072if {[catch {
1073                set _gitdir $env(GIT_DIR)
1074                set _prefix {}
1075                }]
1076        && [catch {
1077                set _gitdir [git rev-parse --git-dir]
1078                set _prefix [git rev-parse --show-prefix]
1079        } err]} {
1080        load_config 1
1081        apply_config
1082        choose_repository::pick
1083        set picked 1
1084}
1085if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1086        catch {set _gitdir [exec cygpath --windows $_gitdir]}
1087}
1088if {![file isdirectory $_gitdir]} {
1089        catch {wm withdraw .}
1090        error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1091        exit 1
1092}
1093if {$_prefix ne {}} {
1094        regsub -all {[^/]+/} $_prefix ../ cdup
1095        if {[catch {cd $cdup} err]} {
1096                catch {wm withdraw .}
1097                error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1098                exit 1
1099        }
1100        unset cdup
1101} elseif {![is_enabled bare]} {
1102        if {[lindex [file split $_gitdir] end] ne {.git}} {
1103                catch {wm withdraw .}
1104                error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
1105                exit 1
1106        }
1107        if {[catch {cd [file dirname $_gitdir]} err]} {
1108                catch {wm withdraw .}
1109                error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
1110                exit 1
1111        }
1112}
1113set _reponame [file split [file normalize $_gitdir]]
1114if {[lindex $_reponame end] eq {.git}} {
1115        set _reponame [lindex $_reponame end-1]
1116} else {
1117        set _reponame [lindex $_reponame end]
1118}
1119
1120######################################################################
1121##
1122## global init
1123
1124set current_diff_path {}
1125set current_diff_side {}
1126set diff_actions [list]
1127
1128set HEAD {}
1129set PARENT {}
1130set MERGE_HEAD [list]
1131set commit_type {}
1132set empty_tree {}
1133set current_branch {}
1134set is_detached 0
1135set current_diff_path {}
1136set is_3way_diff 0
1137set is_conflict_diff 0
1138set selected_commit_type new
1139set diff_empty_count 0
1140
1141set nullid "0000000000000000000000000000000000000000"
1142set nullid2 "0000000000000000000000000000000000000001"
1143
1144######################################################################
1145##
1146## task management
1147
1148set rescan_active 0
1149set diff_active 0
1150set last_clicked {}
1151
1152set disable_on_lock [list]
1153set index_lock_type none
1154
1155proc lock_index {type} {
1156        global index_lock_type disable_on_lock
1157
1158        if {$index_lock_type eq {none}} {
1159                set index_lock_type $type
1160                foreach w $disable_on_lock {
1161                        uplevel #0 $w disabled
1162                }
1163                return 1
1164        } elseif {$index_lock_type eq "begin-$type"} {
1165                set index_lock_type $type
1166                return 1
1167        }
1168        return 0
1169}
1170
1171proc unlock_index {} {
1172        global index_lock_type disable_on_lock
1173
1174        set index_lock_type none
1175        foreach w $disable_on_lock {
1176                uplevel #0 $w normal
1177        }
1178}
1179
1180######################################################################
1181##
1182## status
1183
1184proc repository_state {ctvar hdvar mhvar} {
1185        global current_branch
1186        upvar $ctvar ct $hdvar hd $mhvar mh
1187
1188        set mh [list]
1189
1190        load_current_branch
1191        if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1192                set hd {}
1193                set ct initial
1194                return
1195        }
1196
1197        set merge_head [gitdir MERGE_HEAD]
1198        if {[file exists $merge_head]} {
1199                set ct merge
1200                set fd_mh [open $merge_head r]
1201                while {[gets $fd_mh line] >= 0} {
1202                        lappend mh $line
1203                }
1204                close $fd_mh
1205                return
1206        }
1207
1208        set ct normal
1209}
1210
1211proc PARENT {} {
1212        global PARENT empty_tree
1213
1214        set p [lindex $PARENT 0]
1215        if {$p ne {}} {
1216                return $p
1217        }
1218        if {$empty_tree eq {}} {
1219                set empty_tree [git mktree << {}]
1220        }
1221        return $empty_tree
1222}
1223
1224proc force_amend {} {
1225        global selected_commit_type
1226        global HEAD PARENT MERGE_HEAD commit_type
1227
1228        repository_state newType newHEAD newMERGE_HEAD
1229        set HEAD $newHEAD
1230        set PARENT $newHEAD
1231        set MERGE_HEAD $newMERGE_HEAD
1232        set commit_type $newType
1233
1234        set selected_commit_type amend
1235        do_select_commit_type
1236}
1237
1238proc rescan {after {honor_trustmtime 1}} {
1239        global HEAD PARENT MERGE_HEAD commit_type
1240        global ui_index ui_workdir ui_comm
1241        global rescan_active file_states
1242        global repo_config
1243
1244        if {$rescan_active > 0 || ![lock_index read]} return
1245
1246        repository_state newType newHEAD newMERGE_HEAD
1247        if {[string match amend* $commit_type]
1248                && $newType eq {normal}
1249                && $newHEAD eq $HEAD} {
1250        } else {
1251                set HEAD $newHEAD
1252                set PARENT $newHEAD
1253                set MERGE_HEAD $newMERGE_HEAD
1254                set commit_type $newType
1255        }
1256
1257        array unset file_states
1258
1259        if {!$::GITGUI_BCK_exists &&
1260                (![$ui_comm edit modified]
1261                || [string trim [$ui_comm get 0.0 end]] eq {})} {
1262                if {[string match amend* $commit_type]} {
1263                } elseif {[load_message GITGUI_MSG]} {
1264                } elseif {[run_prepare_commit_msg_hook]} {
1265                } elseif {[load_message MERGE_MSG]} {
1266                } elseif {[load_message SQUASH_MSG]} {
1267                }
1268                $ui_comm edit reset
1269                $ui_comm edit modified false
1270        }
1271
1272        if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1273                rescan_stage2 {} $after
1274        } else {
1275                set rescan_active 1
1276                ui_status [mc "Refreshing file status..."]
1277                set fd_rf [git_read update-index \
1278                        -q \
1279                        --unmerged \
1280                        --ignore-missing \
1281                        --refresh \
1282                        ]
1283                fconfigure $fd_rf -blocking 0 -translation binary
1284                fileevent $fd_rf readable \
1285                        [list rescan_stage2 $fd_rf $after]
1286        }
1287}
1288
1289if {[is_Cygwin]} {
1290        set is_git_info_exclude {}
1291        proc have_info_exclude {} {
1292                global is_git_info_exclude
1293
1294                if {$is_git_info_exclude eq {}} {
1295                        if {[catch {exec test -f [gitdir info exclude]}]} {
1296                                set is_git_info_exclude 0
1297                        } else {
1298                                set is_git_info_exclude 1
1299                        }
1300                }
1301                return $is_git_info_exclude
1302        }
1303} else {
1304        proc have_info_exclude {} {
1305                return [file readable [gitdir info exclude]]
1306        }
1307}
1308
1309proc rescan_stage2 {fd after} {
1310        global rescan_active buf_rdi buf_rdf buf_rlo
1311
1312        if {$fd ne {}} {
1313                read $fd
1314                if {![eof $fd]} return
1315                close $fd
1316        }
1317
1318        set ls_others [list --exclude-per-directory=.gitignore]
1319        if {[have_info_exclude]} {
1320                lappend ls_others "--exclude-from=[gitdir info exclude]"
1321        }
1322        set user_exclude [get_config core.excludesfile]
1323        if {$user_exclude ne {} && [file readable $user_exclude]} {
1324                lappend ls_others "--exclude-from=$user_exclude"
1325        }
1326
1327        set buf_rdi {}
1328        set buf_rdf {}
1329        set buf_rlo {}
1330
1331        set rescan_active 3
1332        ui_status [mc "Scanning for modified files ..."]
1333        set fd_di [git_read diff-index --cached -z [PARENT]]
1334        set fd_df [git_read diff-files -z]
1335        set fd_lo [eval git_read ls-files --others -z $ls_others]
1336
1337        fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1338        fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1339        fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1340        fileevent $fd_di readable [list read_diff_index $fd_di $after]
1341        fileevent $fd_df readable [list read_diff_files $fd_df $after]
1342        fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1343}
1344
1345proc load_message {file} {
1346        global ui_comm
1347
1348        set f [gitdir $file]
1349        if {[file isfile $f]} {
1350                if {[catch {set fd [open $f r]}]} {
1351                        return 0
1352                }
1353                fconfigure $fd -eofchar {}
1354                set content [string trim [read $fd]]
1355                close $fd
1356                regsub -all -line {[ \r\t]+$} $content {} content
1357                $ui_comm delete 0.0 end
1358                $ui_comm insert end $content
1359                return 1
1360        }
1361        return 0
1362}
1363
1364proc run_prepare_commit_msg_hook {} {
1365        global pch_error
1366
1367        # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1368        # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1369        # empty file but existant file.
1370
1371        set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1372
1373        if {[file isfile [gitdir MERGE_MSG]]} {
1374                set pcm_source "merge"
1375                set fd_mm [open [gitdir MERGE_MSG] r]
1376                puts -nonewline $fd_pcm [read $fd_mm]
1377                close $fd_mm
1378        } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1379                set pcm_source "squash"
1380                set fd_sm [open [gitdir SQUASH_MSG] r]
1381                puts -nonewline $fd_pcm [read $fd_sm]
1382                close $fd_sm
1383        } else {
1384                set pcm_source ""
1385        }
1386
1387        close $fd_pcm
1388
1389        set fd_ph [githook_read prepare-commit-msg \
1390                        [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1391        if {$fd_ph eq {}} {
1392                catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1393                return 0;
1394        }
1395
1396        ui_status [mc "Calling prepare-commit-msg hook..."]
1397        set pch_error {}
1398
1399        fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1400        fileevent $fd_ph readable \
1401                [list prepare_commit_msg_hook_wait $fd_ph]
1402
1403        return 1;
1404}
1405
1406proc prepare_commit_msg_hook_wait {fd_ph} {
1407        global pch_error
1408
1409        append pch_error [read $fd_ph]
1410        fconfigure $fd_ph -blocking 1
1411        if {[eof $fd_ph]} {
1412                if {[catch {close $fd_ph}]} {
1413                        ui_status [mc "Commit declined by prepare-commit-msg hook."]
1414                        hook_failed_popup prepare-commit-msg $pch_error
1415                        catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1416                        exit 1
1417                } else {
1418                        load_message PREPARE_COMMIT_MSG
1419                }
1420                set pch_error {}
1421                catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1422                return
1423        }
1424        fconfigure $fd_ph -blocking 0
1425        catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1426}
1427
1428proc read_diff_index {fd after} {
1429        global buf_rdi
1430
1431        append buf_rdi [read $fd]
1432        set c 0
1433        set n [string length $buf_rdi]
1434        while {$c < $n} {
1435                set z1 [string first "\0" $buf_rdi $c]
1436                if {$z1 == -1} break
1437                incr z1
1438                set z2 [string first "\0" $buf_rdi $z1]
1439                if {$z2 == -1} break
1440
1441                incr c
1442                set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1443                set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1444                merge_state \
1445                        [encoding convertfrom $p] \
1446                        [lindex $i 4]? \
1447                        [list [lindex $i 0] [lindex $i 2]] \
1448                        [list]
1449                set c $z2
1450                incr c
1451        }
1452        if {$c < $n} {
1453                set buf_rdi [string range $buf_rdi $c end]
1454        } else {
1455                set buf_rdi {}
1456        }
1457
1458        rescan_done $fd buf_rdi $after
1459}
1460
1461proc read_diff_files {fd after} {
1462        global buf_rdf
1463
1464        append buf_rdf [read $fd]
1465        set c 0
1466        set n [string length $buf_rdf]
1467        while {$c < $n} {
1468                set z1 [string first "\0" $buf_rdf $c]
1469                if {$z1 == -1} break
1470                incr z1
1471                set z2 [string first "\0" $buf_rdf $z1]
1472                if {$z2 == -1} break
1473
1474                incr c
1475                set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1476                set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1477                merge_state \
1478                        [encoding convertfrom $p] \
1479                        ?[lindex $i 4] \
1480                        [list] \
1481                        [list [lindex $i 0] [lindex $i 2]]
1482                set c $z2
1483                incr c
1484        }
1485        if {$c < $n} {
1486                set buf_rdf [string range $buf_rdf $c end]
1487        } else {
1488                set buf_rdf {}
1489        }
1490
1491        rescan_done $fd buf_rdf $after
1492}
1493
1494proc read_ls_others {fd after} {
1495        global buf_rlo
1496
1497        append buf_rlo [read $fd]
1498        set pck [split $buf_rlo "\0"]
1499        set buf_rlo [lindex $pck end]
1500        foreach p [lrange $pck 0 end-1] {
1501                set p [encoding convertfrom $p]
1502                if {[string index $p end] eq {/}} {
1503                        set p [string range $p 0 end-1]
1504                }
1505                merge_state $p ?O
1506        }
1507        rescan_done $fd buf_rlo $after
1508}
1509
1510proc rescan_done {fd buf after} {
1511        global rescan_active current_diff_path
1512        global file_states repo_config
1513        upvar $buf to_clear
1514
1515        if {![eof $fd]} return
1516        set to_clear {}
1517        close $fd
1518        if {[incr rescan_active -1] > 0} return
1519
1520        prune_selection
1521        unlock_index
1522        display_all_files
1523        if {$current_diff_path ne {}} { reshow_diff $after }
1524        if {$current_diff_path eq {}} { select_first_diff $after }
1525}
1526
1527proc prune_selection {} {
1528        global file_states selected_paths
1529
1530        foreach path [array names selected_paths] {
1531                if {[catch {set still_here $file_states($path)}]} {
1532                        unset selected_paths($path)
1533                }
1534        }
1535}
1536
1537######################################################################
1538##
1539## ui helpers
1540
1541proc mapicon {w state path} {
1542        global all_icons
1543
1544        if {[catch {set r $all_icons($state$w)}]} {
1545                puts "error: no icon for $w state={$state} $path"
1546                return file_plain
1547        }
1548        return $r
1549}
1550
1551proc mapdesc {state path} {
1552        global all_descs
1553
1554        if {[catch {set r $all_descs($state)}]} {
1555                puts "error: no desc for state={$state} $path"
1556                return $state
1557        }
1558        return $r
1559}
1560
1561proc ui_status {msg} {
1562        global main_status
1563        if {[info exists main_status]} {
1564                $main_status show $msg
1565        }
1566}
1567
1568proc ui_ready {{test {}}} {
1569        global main_status
1570        if {[info exists main_status]} {
1571                $main_status show [mc "Ready."] $test
1572        }
1573}
1574
1575proc escape_path {path} {
1576        regsub -all {\\} $path "\\\\" path
1577        regsub -all "\n" $path "\\n" path
1578        return $path
1579}
1580
1581proc short_path {path} {
1582        return [escape_path [lindex [file split $path] end]]
1583}
1584
1585set next_icon_id 0
1586set null_sha1 [string repeat 0 40]
1587
1588proc merge_state {path new_state {head_info {}} {index_info {}}} {
1589        global file_states next_icon_id null_sha1
1590
1591        set s0 [string index $new_state 0]
1592        set s1 [string index $new_state 1]
1593
1594        if {[catch {set info $file_states($path)}]} {
1595                set state __
1596                set icon n[incr next_icon_id]
1597        } else {
1598                set state [lindex $info 0]
1599                set icon [lindex $info 1]
1600                if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1601                if {$index_info eq {}} {set index_info [lindex $info 3]}
1602        }
1603
1604        if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1605        elseif {$s0 eq {_}} {set s0 _}
1606
1607        if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1608        elseif {$s1 eq {_}} {set s1 _}
1609
1610        if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1611                set head_info [list 0 $null_sha1]
1612        } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1613                && $head_info eq {}} {
1614                set head_info $index_info
1615        }
1616
1617        set file_states($path) [list $s0$s1 $icon \
1618                $head_info $index_info \
1619                ]
1620        return $state
1621}
1622
1623proc display_file_helper {w path icon_name old_m new_m} {
1624        global file_lists
1625
1626        if {$new_m eq {_}} {
1627                set lno [lsearch -sorted -exact $file_lists($w) $path]
1628                if {$lno >= 0} {
1629                        set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1630                        incr lno
1631                        $w conf -state normal
1632                        $w delete $lno.0 [expr {$lno + 1}].0
1633                        $w conf -state disabled
1634                }
1635        } elseif {$old_m eq {_} && $new_m ne {_}} {
1636                lappend file_lists($w) $path
1637                set file_lists($w) [lsort -unique $file_lists($w)]
1638                set lno [lsearch -sorted -exact $file_lists($w) $path]
1639                incr lno
1640                $w conf -state normal
1641                $w image create $lno.0 \
1642                        -align center -padx 5 -pady 1 \
1643                        -name $icon_name \
1644                        -image [mapicon $w $new_m $path]
1645                $w insert $lno.1 "[escape_path $path]\n"
1646                $w conf -state disabled
1647        } elseif {$old_m ne $new_m} {
1648                $w conf -state normal
1649                $w image conf $icon_name -image [mapicon $w $new_m $path]
1650                $w conf -state disabled
1651        }
1652}
1653
1654proc display_file {path state} {
1655        global file_states selected_paths
1656        global ui_index ui_workdir
1657
1658        set old_m [merge_state $path $state]
1659        set s $file_states($path)
1660        set new_m [lindex $s 0]
1661        set icon_name [lindex $s 1]
1662
1663        set o [string index $old_m 0]
1664        set n [string index $new_m 0]
1665        if {$o eq {U}} {
1666                set o _
1667        }
1668        if {$n eq {U}} {
1669                set n _
1670        }
1671        display_file_helper     $ui_index $path $icon_name $o $n
1672
1673        if {[string index $old_m 0] eq {U}} {
1674                set o U
1675        } else {
1676                set o [string index $old_m 1]
1677        }
1678        if {[string index $new_m 0] eq {U}} {
1679                set n U
1680        } else {
1681                set n [string index $new_m 1]
1682        }
1683        display_file_helper     $ui_workdir $path $icon_name $o $n
1684
1685        if {$new_m eq {__}} {
1686                unset file_states($path)
1687                catch {unset selected_paths($path)}
1688        }
1689}
1690
1691proc display_all_files_helper {w path icon_name m} {
1692        global file_lists
1693
1694        lappend file_lists($w) $path
1695        set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1696        $w image create end \
1697                -align center -padx 5 -pady 1 \
1698                -name $icon_name \
1699                -image [mapicon $w $m $path]
1700        $w insert end "[escape_path $path]\n"
1701}
1702
1703set files_warning 0
1704proc display_all_files {} {
1705        global ui_index ui_workdir
1706        global file_states file_lists
1707        global last_clicked
1708        global files_warning
1709
1710        $ui_index conf -state normal
1711        $ui_workdir conf -state normal
1712
1713        $ui_index delete 0.0 end
1714        $ui_workdir delete 0.0 end
1715        set last_clicked {}
1716
1717        set file_lists($ui_index) [list]
1718        set file_lists($ui_workdir) [list]
1719
1720        set to_display [lsort [array names file_states]]
1721        set display_limit [get_config gui.maxfilesdisplayed]
1722        if {[llength $to_display] > $display_limit} {
1723                if {!$files_warning} {
1724                        # do not repeatedly warn:
1725                        set files_warning 1
1726                        info_popup [mc "Displaying only %s of %s files." \
1727                                $display_limit [llength $to_display]]
1728                }
1729                set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1730        }
1731        foreach path $to_display {
1732                set s $file_states($path)
1733                set m [lindex $s 0]
1734                set icon_name [lindex $s 1]
1735
1736                set s [string index $m 0]
1737                if {$s ne {U} && $s ne {_}} {
1738                        display_all_files_helper $ui_index $path \
1739                                $icon_name $s
1740                }
1741
1742                if {[string index $m 0] eq {U}} {
1743                        set s U
1744                } else {
1745                        set s [string index $m 1]
1746                }
1747                if {$s ne {_}} {
1748                        display_all_files_helper $ui_workdir $path \
1749                                $icon_name $s
1750                }
1751        }
1752
1753        $ui_index conf -state disabled
1754        $ui_workdir conf -state disabled
1755}
1756
1757######################################################################
1758##
1759## icons
1760
1761set filemask {
1762#define mask_width 14
1763#define mask_height 15
1764static unsigned char mask_bits[] = {
1765   0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1766   0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1767   0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1768}
1769
1770image create bitmap file_plain -background white -foreground black -data {
1771#define plain_width 14
1772#define plain_height 15
1773static unsigned char plain_bits[] = {
1774   0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1775   0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1776   0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1777} -maskdata $filemask
1778
1779image create bitmap file_mod -background white -foreground blue -data {
1780#define mod_width 14
1781#define mod_height 15
1782static unsigned char mod_bits[] = {
1783   0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1784   0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1785   0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1786} -maskdata $filemask
1787
1788image create bitmap file_fulltick -background white -foreground "#007000" -data {
1789#define file_fulltick_width 14
1790#define file_fulltick_height 15
1791static unsigned char file_fulltick_bits[] = {
1792   0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1793   0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1794   0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1795} -maskdata $filemask
1796
1797image create bitmap file_parttick -background white -foreground "#005050" -data {
1798#define parttick_width 14
1799#define parttick_height 15
1800static unsigned char parttick_bits[] = {
1801   0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1802   0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1803   0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1804} -maskdata $filemask
1805
1806image create bitmap file_question -background white -foreground black -data {
1807#define file_question_width 14
1808#define file_question_height 15
1809static unsigned char file_question_bits[] = {
1810   0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1811   0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1812   0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1813} -maskdata $filemask
1814
1815image create bitmap file_removed -background white -foreground red -data {
1816#define file_removed_width 14
1817#define file_removed_height 15
1818static unsigned char file_removed_bits[] = {
1819   0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1820   0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1821   0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1822} -maskdata $filemask
1823
1824image create bitmap file_merge -background white -foreground blue -data {
1825#define file_merge_width 14
1826#define file_merge_height 15
1827static unsigned char file_merge_bits[] = {
1828   0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1829   0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1830   0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1831} -maskdata $filemask
1832
1833image create bitmap file_statechange -background white -foreground green -data {
1834#define file_merge_width 14
1835#define file_merge_height 15
1836static unsigned char file_statechange_bits[] = {
1837   0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1838   0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1839   0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1840} -maskdata $filemask
1841
1842set ui_index .vpane.files.index.list
1843set ui_workdir .vpane.files.workdir.list
1844
1845set all_icons(_$ui_index)   file_plain
1846set all_icons(A$ui_index)   file_fulltick
1847set all_icons(M$ui_index)   file_fulltick
1848set all_icons(D$ui_index)   file_removed
1849set all_icons(U$ui_index)   file_merge
1850set all_icons(T$ui_index)   file_statechange
1851
1852set all_icons(_$ui_workdir) file_plain
1853set all_icons(M$ui_workdir) file_mod
1854set all_icons(D$ui_workdir) file_question
1855set all_icons(U$ui_workdir) file_merge
1856set all_icons(O$ui_workdir) file_plain
1857set all_icons(T$ui_workdir) file_statechange
1858
1859set max_status_desc 0
1860foreach i {
1861                {__ {mc "Unmodified"}}
1862
1863                {_M {mc "Modified, not staged"}}
1864                {M_ {mc "Staged for commit"}}
1865                {MM {mc "Portions staged for commit"}}
1866                {MD {mc "Staged for commit, missing"}}
1867
1868                {_T {mc "File type changed, not staged"}}
1869                {T_ {mc "File type changed, staged"}}
1870
1871                {_O {mc "Untracked, not staged"}}
1872                {A_ {mc "Staged for commit"}}
1873                {AM {mc "Portions staged for commit"}}
1874                {AD {mc "Staged for commit, missing"}}
1875
1876                {_D {mc "Missing"}}
1877                {D_ {mc "Staged for removal"}}
1878                {DO {mc "Staged for removal, still present"}}
1879
1880                {_U {mc "Requires merge resolution"}}
1881                {U_ {mc "Requires merge resolution"}}
1882                {UU {mc "Requires merge resolution"}}
1883                {UM {mc "Requires merge resolution"}}
1884                {UD {mc "Requires merge resolution"}}
1885                {UT {mc "Requires merge resolution"}}
1886        } {
1887        set text [eval [lindex $i 1]]
1888        if {$max_status_desc < [string length $text]} {
1889                set max_status_desc [string length $text]
1890        }
1891        set all_descs([lindex $i 0]) $text
1892}
1893unset i
1894
1895######################################################################
1896##
1897## util
1898
1899proc scrollbar2many {list mode args} {
1900        foreach w $list {eval $w $mode $args}
1901}
1902
1903proc many2scrollbar {list mode sb top bottom} {
1904        $sb set $top $bottom
1905        foreach w $list {$w $mode moveto $top}
1906}
1907
1908proc incr_font_size {font {amt 1}} {
1909        set sz [font configure $font -size]
1910        incr sz $amt
1911        font configure $font -size $sz
1912        font configure ${font}bold -size $sz
1913        font configure ${font}italic -size $sz
1914}
1915
1916######################################################################
1917##
1918## ui commands
1919
1920set starting_gitk_msg [mc "Starting gitk... please wait..."]
1921
1922proc do_gitk {revs} {
1923        # -- Always start gitk through whatever we were loaded with.  This
1924        #    lets us bypass using shell process on Windows systems.
1925        #
1926        set exe [_which gitk -script]
1927        set cmd [list [info nameofexecutable] $exe]
1928        if {$exe eq {}} {
1929                error_popup [mc "Couldn't find gitk in PATH"]
1930        } else {
1931                global env
1932
1933                if {[info exists env(GIT_DIR)]} {
1934                        set old_GIT_DIR $env(GIT_DIR)
1935                } else {
1936                        set old_GIT_DIR {}
1937                }
1938
1939                set pwd [pwd]
1940                cd [file dirname [gitdir]]
1941                set env(GIT_DIR) [file tail [gitdir]]
1942
1943                eval exec $cmd $revs &
1944
1945                if {$old_GIT_DIR eq {}} {
1946                        unset env(GIT_DIR)
1947                } else {
1948                        set env(GIT_DIR) $old_GIT_DIR
1949                }
1950                cd $pwd
1951
1952                ui_status $::starting_gitk_msg
1953                after 10000 {
1954                        ui_ready $starting_gitk_msg
1955                }
1956        }
1957}
1958
1959proc do_explore {} {
1960        set explorer {}
1961        if {[is_Cygwin] || [is_Windows]} {
1962                set explorer "explorer.exe"
1963        } elseif {[is_MacOSX]} {
1964                set explorer "open"
1965        } else {
1966                # freedesktop.org-conforming system is our best shot
1967                set explorer "xdg-open"
1968        }
1969        eval exec $explorer [list [file nativename [file dirname [gitdir]]]] &
1970}
1971
1972set is_quitting 0
1973set ret_code    1
1974
1975proc terminate_me {win} {
1976        global ret_code
1977        if {$win ne {.}} return
1978        exit $ret_code
1979}
1980
1981proc do_quit {{rc {1}}} {
1982        global ui_comm is_quitting repo_config commit_type
1983        global GITGUI_BCK_exists GITGUI_BCK_i
1984        global ui_comm_spell
1985        global ret_code
1986
1987        if {$is_quitting} return
1988        set is_quitting 1
1989
1990        if {[winfo exists $ui_comm]} {
1991                # -- Stash our current commit buffer.
1992                #
1993                set save [gitdir GITGUI_MSG]
1994                if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1995                        file rename -force [gitdir GITGUI_BCK] $save
1996                        set GITGUI_BCK_exists 0
1997                } else {
1998                        set msg [string trim [$ui_comm get 0.0 end]]
1999                        regsub -all -line {[ \r\t]+$} $msg {} msg
2000                        if {(![string match amend* $commit_type]
2001                                || [$ui_comm edit modified])
2002                                && $msg ne {}} {
2003                                catch {
2004                                        set fd [open $save w]
2005                                        puts -nonewline $fd $msg
2006                                        close $fd
2007                                }
2008                        } else {
2009                                catch {file delete $save}
2010                        }
2011                }
2012
2013                # -- Cancel our spellchecker if its running.
2014                #
2015                if {[info exists ui_comm_spell]} {
2016                        $ui_comm_spell stop
2017                }
2018
2019                # -- Remove our editor backup, its not needed.
2020                #
2021                after cancel $GITGUI_BCK_i
2022                if {$GITGUI_BCK_exists} {
2023                        catch {file delete [gitdir GITGUI_BCK]}
2024                }
2025
2026                # -- Stash our current window geometry into this repository.
2027                #
2028                set cfg_geometry [list]
2029                lappend cfg_geometry [wm geometry .]
2030                lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2031                lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2032                if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2033                        set rc_geometry {}
2034                }
2035                if {$cfg_geometry ne $rc_geometry} {
2036                        catch {git config gui.geometry $cfg_geometry}
2037                }
2038        }
2039
2040        set ret_code $rc
2041        destroy .
2042}
2043
2044proc do_rescan {} {
2045        rescan ui_ready
2046}
2047
2048proc ui_do_rescan {} {
2049        rescan {force_first_diff ui_ready}
2050}
2051
2052proc do_commit {} {
2053        commit_tree
2054}
2055
2056proc next_diff {{after {}}} {
2057        global next_diff_p next_diff_w next_diff_i
2058        show_diff $next_diff_p $next_diff_w {} {} $after
2059}
2060
2061proc find_anchor_pos {lst name} {
2062        set lid [lsearch -sorted -exact $lst $name]
2063
2064        if {$lid == -1} {
2065                set lid 0
2066                foreach lname $lst {
2067                        if {$lname >= $name} break
2068                        incr lid
2069                }
2070        }
2071
2072        return $lid
2073}
2074
2075proc find_file_from {flist idx delta path mmask} {
2076        global file_states
2077
2078        set len [llength $flist]
2079        while {$idx >= 0 && $idx < $len} {
2080                set name [lindex $flist $idx]
2081
2082                if {$name ne $path && [info exists file_states($name)]} {
2083                        set state [lindex $file_states($name) 0]
2084
2085                        if {$mmask eq {} || [regexp $mmask $state]} {
2086                                return $idx
2087                        }
2088                }
2089
2090                incr idx $delta
2091        }
2092
2093        return {}
2094}
2095
2096proc find_next_diff {w path {lno {}} {mmask {}}} {
2097        global next_diff_p next_diff_w next_diff_i
2098        global file_lists ui_index ui_workdir
2099
2100        set flist $file_lists($w)
2101        if {$lno eq {}} {
2102                set lno [find_anchor_pos $flist $path]
2103        } else {
2104                incr lno -1
2105        }
2106
2107        if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2108                if {$w eq $ui_index} {
2109                        set mmask "^$mmask"
2110                } else {
2111                        set mmask "$mmask\$"
2112                }
2113        }
2114
2115        set idx [find_file_from $flist $lno 1 $path $mmask]
2116        if {$idx eq {}} {
2117                incr lno -1
2118                set idx [find_file_from $flist $lno -1 $path $mmask]
2119        }
2120
2121        if {$idx ne {}} {
2122                set next_diff_w $w
2123                set next_diff_p [lindex $flist $idx]
2124                set next_diff_i [expr {$idx+1}]
2125                return 1
2126        } else {
2127                return 0
2128        }
2129}
2130
2131proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2132        global current_diff_path
2133
2134        if {$path ne $current_diff_path} {
2135                return {}
2136        } elseif {[find_next_diff $w $path $lno $mmask]} {
2137                return {next_diff;}
2138        } else {
2139                return {reshow_diff;}
2140        }
2141}
2142
2143proc select_first_diff {after} {
2144        global ui_workdir
2145
2146        if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2147            [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2148                next_diff $after
2149        } else {
2150                uplevel #0 $after
2151        }
2152}
2153
2154proc force_first_diff {after} {
2155        global ui_workdir current_diff_path file_states
2156
2157        if {[info exists file_states($current_diff_path)]} {
2158                set state [lindex $file_states($current_diff_path) 0]
2159        } else {
2160                set state {OO}
2161        }
2162
2163        set reselect 0
2164        if {[string first {U} $state] >= 0} {
2165                # Already a conflict, do nothing
2166        } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2167                set reselect 1
2168        } elseif {[string index $state 1] ne {O}} {
2169                # Already a diff & no conflicts, do nothing
2170        } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2171                set reselect 1
2172        }
2173
2174        if {$reselect} {
2175                next_diff $after
2176        } else {
2177                uplevel #0 $after
2178        }
2179}
2180
2181proc toggle_or_diff {w x y} {
2182        global file_states file_lists current_diff_path ui_index ui_workdir
2183        global last_clicked selected_paths
2184
2185        set pos [split [$w index @$x,$y] .]
2186        set lno [lindex $pos 0]
2187        set col [lindex $pos 1]
2188        set path [lindex $file_lists($w) [expr {$lno - 1}]]
2189        if {$path eq {}} {
2190                set last_clicked {}
2191                return
2192        }
2193
2194        set last_clicked [list $w $lno]
2195        array unset selected_paths
2196        $ui_index tag remove in_sel 0.0 end
2197        $ui_workdir tag remove in_sel 0.0 end
2198
2199        # Determine the state of the file
2200        if {[info exists file_states($path)]} {
2201                set state [lindex $file_states($path) 0]
2202        } else {
2203                set state {__}
2204        }
2205
2206        # Restage the file, or simply show the diff
2207        if {$col == 0 && $y > 1} {
2208                # Conflicts need special handling
2209                if {[string first {U} $state] >= 0} {
2210                        # $w must always be $ui_workdir, but...
2211                        if {$w ne $ui_workdir} { set lno {} }
2212                        merge_stage_workdir $path $lno
2213                        return
2214                }
2215
2216                if {[string index $state 1] eq {O}} {
2217                        set mmask {}
2218                } else {
2219                        set mmask {[^O]}
2220                }
2221
2222                set after [next_diff_after_action $w $path $lno $mmask]
2223
2224                if {$w eq $ui_index} {
2225                        update_indexinfo \
2226                                "Unstaging [short_path $path] from commit" \
2227                                [list $path] \
2228                                [concat $after [list ui_ready]]
2229                } elseif {$w eq $ui_workdir} {
2230                        update_index \
2231                                "Adding [short_path $path]" \
2232                                [list $path] \
2233                                [concat $after [list ui_ready]]
2234                }
2235        } else {
2236                show_diff $path $w $lno
2237        }
2238}
2239
2240proc add_one_to_selection {w x y} {
2241        global file_lists last_clicked selected_paths
2242
2243        set lno [lindex [split [$w index @$x,$y] .] 0]
2244        set path [lindex $file_lists($w) [expr {$lno - 1}]]
2245        if {$path eq {}} {
2246                set last_clicked {}
2247                return
2248        }
2249
2250        if {$last_clicked ne {}
2251                && [lindex $last_clicked 0] ne $w} {
2252                array unset selected_paths
2253                [lindex $last_clicked 0] tag remove in_sel 0.0 end
2254        }
2255
2256        set last_clicked [list $w $lno]
2257        if {[catch {set in_sel $selected_paths($path)}]} {
2258                set in_sel 0
2259        }
2260        if {$in_sel} {
2261                unset selected_paths($path)
2262                $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2263        } else {
2264                set selected_paths($path) 1
2265                $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2266        }
2267}
2268
2269proc add_range_to_selection {w x y} {
2270        global file_lists last_clicked selected_paths
2271
2272        if {[lindex $last_clicked 0] ne $w} {
2273                toggle_or_diff $w $x $y
2274                return
2275        }
2276
2277        set lno [lindex [split [$w index @$x,$y] .] 0]
2278        set lc [lindex $last_clicked 1]
2279        if {$lc < $lno} {
2280                set begin $lc
2281                set end $lno
2282        } else {
2283                set begin $lno
2284                set end $lc
2285        }
2286
2287        foreach path [lrange $file_lists($w) \
2288                [expr {$begin - 1}] \
2289                [expr {$end - 1}]] {
2290                set selected_paths($path) 1
2291        }
2292        $w tag add in_sel $begin.0 [expr {$end + 1}].0
2293}
2294
2295proc show_more_context {} {
2296        global repo_config
2297        if {$repo_config(gui.diffcontext) < 99} {
2298                incr repo_config(gui.diffcontext)
2299                reshow_diff
2300        }
2301}
2302
2303proc show_less_context {} {
2304        global repo_config
2305        if {$repo_config(gui.diffcontext) > 1} {
2306                incr repo_config(gui.diffcontext) -1
2307                reshow_diff
2308        }
2309}
2310
2311######################################################################
2312##
2313## ui construction
2314
2315load_config 0
2316apply_config
2317set ui_comm {}
2318
2319# -- Menu Bar
2320#
2321menu .mbar -tearoff 0
2322if {[is_MacOSX]} {
2323        # -- Apple Menu (Mac OS X only)
2324        #
2325        .mbar add cascade -label Apple -menu .mbar.apple
2326        menu .mbar.apple
2327}
2328.mbar add cascade -label [mc Repository] -menu .mbar.repository
2329.mbar add cascade -label [mc Edit] -menu .mbar.edit
2330if {[is_enabled branch]} {
2331        .mbar add cascade -label [mc Branch] -menu .mbar.branch
2332}
2333if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2334        .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2335}
2336if {[is_enabled transport]} {
2337        .mbar add cascade -label [mc Merge] -menu .mbar.merge
2338        .mbar add cascade -label [mc Remote] -menu .mbar.remote
2339}
2340if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2341        .mbar add cascade -label [mc Tools] -menu .mbar.tools
2342}
2343
2344# -- Repository Menu
2345#
2346menu .mbar.repository
2347
2348.mbar.repository add command \
2349        -label [mc "Explore Working Copy"] \
2350        -command {do_explore}
2351.mbar.repository add separator
2352
2353.mbar.repository add command \
2354        -label [mc "Browse Current Branch's Files"] \
2355        -command {browser::new $current_branch}
2356set ui_browse_current [.mbar.repository index last]
2357.mbar.repository add command \
2358        -label [mc "Browse Branch Files..."] \
2359        -command browser_open::dialog
2360.mbar.repository add separator
2361
2362.mbar.repository add command \
2363        -label [mc "Visualize Current Branch's History"] \
2364        -command {do_gitk $current_branch}
2365set ui_visualize_current [.mbar.repository index last]
2366.mbar.repository add command \
2367        -label [mc "Visualize All Branch History"] \
2368        -command {do_gitk --all}
2369.mbar.repository add separator
2370
2371proc current_branch_write {args} {
2372        global current_branch
2373        .mbar.repository entryconf $::ui_browse_current \
2374                -label [mc "Browse %s's Files" $current_branch]
2375        .mbar.repository entryconf $::ui_visualize_current \
2376                -label [mc "Visualize %s's History" $current_branch]
2377}
2378trace add variable current_branch write current_branch_write
2379
2380if {[is_enabled multicommit]} {
2381        .mbar.repository add command -label [mc "Database Statistics"] \
2382                -command do_stats
2383
2384        .mbar.repository add command -label [mc "Compress Database"] \
2385                -command do_gc
2386
2387        .mbar.repository add command -label [mc "Verify Database"] \
2388                -command do_fsck_objects
2389
2390        .mbar.repository add separator
2391
2392        if {[is_Cygwin]} {
2393                .mbar.repository add command \
2394                        -label [mc "Create Desktop Icon"] \
2395                        -command do_cygwin_shortcut
2396        } elseif {[is_Windows]} {
2397                .mbar.repository add command \
2398                        -label [mc "Create Desktop Icon"] \
2399                        -command do_windows_shortcut
2400        } elseif {[is_MacOSX]} {
2401                .mbar.repository add command \
2402                        -label [mc "Create Desktop Icon"] \
2403                        -command do_macosx_app
2404        }
2405}
2406
2407if {[is_MacOSX]} {
2408        proc ::tk::mac::Quit {args} { do_quit }
2409} else {
2410        .mbar.repository add command -label [mc Quit] \
2411                -command do_quit \
2412                -accelerator $M1T-Q
2413}
2414
2415# -- Edit Menu
2416#
2417menu .mbar.edit
2418.mbar.edit add command -label [mc Undo] \
2419        -command {catch {[focus] edit undo}} \
2420        -accelerator $M1T-Z
2421.mbar.edit add command -label [mc Redo] \
2422        -command {catch {[focus] edit redo}} \
2423        -accelerator $M1T-Y
2424.mbar.edit add separator
2425.mbar.edit add command -label [mc Cut] \
2426        -command {catch {tk_textCut [focus]}} \
2427        -accelerator $M1T-X
2428.mbar.edit add command -label [mc Copy] \
2429        -command {catch {tk_textCopy [focus]}} \
2430        -accelerator $M1T-C
2431.mbar.edit add command -label [mc Paste] \
2432        -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2433        -accelerator $M1T-V
2434.mbar.edit add command -label [mc Delete] \
2435        -command {catch {[focus] delete sel.first sel.last}} \
2436        -accelerator Del
2437.mbar.edit add separator
2438.mbar.edit add command -label [mc "Select All"] \
2439        -command {catch {[focus] tag add sel 0.0 end}} \
2440        -accelerator $M1T-A
2441
2442# -- Branch Menu
2443#
2444if {[is_enabled branch]} {
2445        menu .mbar.branch
2446
2447        .mbar.branch add command -label [mc "Create..."] \
2448                -command branch_create::dialog \
2449                -accelerator $M1T-N
2450        lappend disable_on_lock [list .mbar.branch entryconf \
2451                [.mbar.branch index last] -state]
2452
2453        .mbar.branch add command -label [mc "Checkout..."] \
2454                -command branch_checkout::dialog \
2455                -accelerator $M1T-O
2456        lappend disable_on_lock [list .mbar.branch entryconf \
2457                [.mbar.branch index last] -state]
2458
2459        .mbar.branch add command -label [mc "Rename..."] \
2460                -command branch_rename::dialog
2461        lappend disable_on_lock [list .mbar.branch entryconf \
2462                [.mbar.branch index last] -state]
2463
2464        .mbar.branch add command -label [mc "Delete..."] \
2465                -command branch_delete::dialog
2466        lappend disable_on_lock [list .mbar.branch entryconf \
2467                [.mbar.branch index last] -state]
2468
2469        .mbar.branch add command -label [mc "Reset..."] \
2470                -command merge::reset_hard
2471        lappend disable_on_lock [list .mbar.branch entryconf \
2472                [.mbar.branch index last] -state]
2473}
2474
2475# -- Commit Menu
2476#
2477proc commit_btn_caption {} {
2478        if {[is_enabled nocommit]} {
2479                return [mc "Done"]
2480        } else {
2481                return [mc Commit@@verb]
2482        }
2483}
2484
2485if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2486        menu .mbar.commit
2487
2488        if {![is_enabled nocommit]} {
2489                .mbar.commit add radiobutton \
2490                        -label [mc "New Commit"] \
2491                        -command do_select_commit_type \
2492                        -variable selected_commit_type \
2493                        -value new
2494                lappend disable_on_lock \
2495                        [list .mbar.commit entryconf [.mbar.commit index last] -state]
2496
2497                .mbar.commit add radiobutton \
2498                        -label [mc "Amend Last Commit"] \
2499                        -command do_select_commit_type \
2500                        -variable selected_commit_type \
2501                        -value amend
2502                lappend disable_on_lock \
2503                        [list .mbar.commit entryconf [.mbar.commit index last] -state]
2504
2505                .mbar.commit add separator
2506        }
2507
2508        .mbar.commit add command -label [mc Rescan] \
2509                -command ui_do_rescan \
2510                -accelerator F5
2511        lappend disable_on_lock \
2512                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2513
2514        .mbar.commit add command -label [mc "Stage To Commit"] \
2515                -command do_add_selection \
2516                -accelerator $M1T-T
2517        lappend disable_on_lock \
2518                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2519
2520        .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2521                -command do_add_all \
2522                -accelerator $M1T-I
2523        lappend disable_on_lock \
2524                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2525
2526        .mbar.commit add command -label [mc "Unstage From Commit"] \
2527                -command do_unstage_selection
2528        lappend disable_on_lock \
2529                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2530
2531        .mbar.commit add command -label [mc "Revert Changes"] \
2532                -command do_revert_selection
2533        lappend disable_on_lock \
2534                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2535
2536        .mbar.commit add separator
2537
2538        .mbar.commit add command -label [mc "Show Less Context"] \
2539                -command show_less_context \
2540                -accelerator $M1T-\-
2541
2542        .mbar.commit add command -label [mc "Show More Context"] \
2543                -command show_more_context \
2544                -accelerator $M1T-=
2545
2546        .mbar.commit add separator
2547
2548        if {![is_enabled nocommitmsg]} {
2549                .mbar.commit add command -label [mc "Sign Off"] \
2550                        -command do_signoff \
2551                        -accelerator $M1T-S
2552        }
2553
2554        .mbar.commit add command -label [commit_btn_caption] \
2555                -command do_commit \
2556                -accelerator $M1T-Return
2557        lappend disable_on_lock \
2558                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2559}
2560
2561# -- Merge Menu
2562#
2563if {[is_enabled branch]} {
2564        menu .mbar.merge
2565        .mbar.merge add command -label [mc "Local Merge..."] \
2566                -command merge::dialog \
2567                -accelerator $M1T-M
2568        lappend disable_on_lock \
2569                [list .mbar.merge entryconf [.mbar.merge index last] -state]
2570        .mbar.merge add command -label [mc "Abort Merge..."] \
2571                -command merge::reset_hard
2572        lappend disable_on_lock \
2573                [list .mbar.merge entryconf [.mbar.merge index last] -state]
2574}
2575
2576# -- Transport Menu
2577#
2578if {[is_enabled transport]} {
2579        menu .mbar.remote
2580
2581        .mbar.remote add command \
2582                -label [mc "Add..."] \
2583                -command remote_add::dialog \
2584                -accelerator $M1T-A
2585        .mbar.remote add command \
2586                -label [mc "Push..."] \
2587                -command do_push_anywhere \
2588                -accelerator $M1T-P
2589        .mbar.remote add command \
2590                -label [mc "Delete Branch..."] \
2591                -command remote_branch_delete::dialog
2592}
2593
2594if {[is_MacOSX]} {
2595        proc ::tk::mac::ShowPreferences {} {do_options}
2596} else {
2597        # -- Edit Menu
2598        #
2599        .mbar.edit add separator
2600        .mbar.edit add command -label [mc "Options..."] \
2601                -command do_options
2602}
2603
2604# -- Tools Menu
2605#
2606if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2607        set tools_menubar .mbar.tools
2608        menu $tools_menubar
2609        $tools_menubar add separator
2610        $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2611        $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2612        set tools_tailcnt 3
2613        if {[array names repo_config guitool.*.cmd] ne {}} {
2614                tools_populate_all
2615        }
2616}
2617
2618# -- Help Menu
2619#
2620.mbar add cascade -label [mc Help] -menu .mbar.help
2621menu .mbar.help
2622
2623if {[is_MacOSX]} {
2624        .mbar.apple add command -label [mc "About %s" [appname]] \
2625                -command do_about
2626        .mbar.apple add separator
2627} else {
2628        .mbar.help add command -label [mc "About %s" [appname]] \
2629                -command do_about
2630}
2631. configure -menu .mbar
2632
2633set doc_path [githtmldir]
2634if {$doc_path ne {}} {
2635        set doc_path [file join $doc_path index.html]
2636
2637        if {[is_Cygwin]} {
2638                set doc_path [exec cygpath --mixed $doc_path]
2639        }
2640}
2641
2642if {[file isfile $doc_path]} {
2643        set doc_url "file:$doc_path"
2644} else {
2645        set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2646}
2647
2648proc start_browser {url} {
2649        git "web--browse" $url
2650}
2651
2652.mbar.help add command -label [mc "Online Documentation"] \
2653        -command [list start_browser $doc_url]
2654
2655.mbar.help add command -label [mc "Show SSH Key"] \
2656        -command do_ssh_key
2657
2658unset doc_path doc_url
2659
2660# -- Standard bindings
2661#
2662wm protocol . WM_DELETE_WINDOW do_quit
2663bind all <$M1B-Key-q> do_quit
2664bind all <$M1B-Key-Q> do_quit
2665bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2666bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2667
2668set subcommand_args {}
2669proc usage {} {
2670        puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2671        exit 1
2672}
2673
2674proc normalize_relpath {path} {
2675        set elements {}
2676        foreach item [file split $path] {
2677                if {$item eq {.}} continue
2678                if {$item eq {..} && [llength $elements] > 0
2679                    && [lindex $elements end] ne {..}} {
2680                        set elements [lrange $elements 0 end-1]
2681                        continue
2682                }
2683                lappend elements $item
2684        }
2685        return [eval file join $elements]
2686}
2687
2688# -- Not a normal commit type invocation?  Do that instead!
2689#
2690switch -- $subcommand {
2691browser -
2692blame {
2693        if {$subcommand eq "blame"} {
2694                set subcommand_args {[--line=<num>] rev? path}
2695        } else {
2696                set subcommand_args {rev? path}
2697        }
2698        if {$argv eq {}} usage
2699        set head {}
2700        set path {}
2701        set jump_spec {}
2702        set is_path 0
2703        foreach a $argv {
2704                if {$is_path || [file exists $_prefix$a]} {
2705                        if {$path ne {}} usage
2706                        set path [normalize_relpath $_prefix$a]
2707                        break
2708                } elseif {$a eq {--}} {
2709                        if {$path ne {}} {
2710                                if {$head ne {}} usage
2711                                set head $path
2712                                set path {}
2713                        }
2714                        set is_path 1
2715                } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2716                        if {$jump_spec ne {} || $head ne {}} usage
2717                        set jump_spec [list $lnum]
2718                } elseif {$head eq {}} {
2719                        if {$head ne {}} usage
2720                        set head $a
2721                        set is_path 1
2722                } else {
2723                        usage
2724                }
2725        }
2726        unset is_path
2727
2728        if {$head ne {} && $path eq {}} {
2729                set path [normalize_relpath $_prefix$head]
2730                set head {}
2731        }
2732
2733        if {$head eq {}} {
2734                load_current_branch
2735        } else {
2736                if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2737                        if {[catch {
2738                                        set head [git rev-parse --verify $head]
2739                                } err]} {
2740                                puts stderr $err
2741                                exit 1
2742                        }
2743                }
2744                set current_branch $head
2745        }
2746
2747        switch -- $subcommand {
2748        browser {
2749                if {$jump_spec ne {}} usage
2750                if {$head eq {}} {
2751                        if {$path ne {} && [file isdirectory $path]} {
2752                                set head $current_branch
2753                        } else {
2754                                set head $path
2755                                set path {}
2756                        }
2757                }
2758                browser::new $head $path
2759        }
2760        blame   {
2761                if {$head eq {} && ![file exists $path]} {
2762                        puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2763                        exit 1
2764                }
2765                blame::new $head $path $jump_spec
2766        }
2767        }
2768        return
2769}
2770citool -
2771gui {
2772        if {[llength $argv] != 0} {
2773                puts -nonewline stderr "usage: $argv0"
2774                if {$subcommand ne {gui}
2775                        && [file tail $argv0] ne "git-$subcommand"} {
2776                        puts -nonewline stderr " $subcommand"
2777                }
2778                puts stderr {}
2779                exit 1
2780        }
2781        # fall through to setup UI for commits
2782}
2783default {
2784        puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2785        exit 1
2786}
2787}
2788
2789# -- Branch Control
2790#
2791frame .branch \
2792        -borderwidth 1 \
2793        -relief sunken
2794label .branch.l1 \
2795        -text [mc "Current Branch:"] \
2796        -anchor w \
2797        -justify left
2798label .branch.cb \
2799        -textvariable current_branch \
2800        -anchor w \
2801        -justify left
2802pack .branch.l1 -side left
2803pack .branch.cb -side left -fill x
2804pack .branch -side top -fill x
2805
2806# -- Main Window Layout
2807#
2808panedwindow .vpane -orient horizontal
2809panedwindow .vpane.files -orient vertical
2810.vpane add .vpane.files -sticky nsew -height 100 -width 200
2811pack .vpane -anchor n -side top -fill both -expand 1
2812
2813# -- Index File List
2814#
2815frame .vpane.files.index -height 100 -width 200
2816label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2817        -background lightgreen -foreground black
2818text $ui_index -background white -foreground black \
2819        -borderwidth 0 \
2820        -width 20 -height 10 \
2821        -wrap none \
2822        -cursor $cursor_ptr \
2823        -xscrollcommand {.vpane.files.index.sx set} \
2824        -yscrollcommand {.vpane.files.index.sy set} \
2825        -state disabled
2826scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2827scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2828pack .vpane.files.index.title -side top -fill x
2829pack .vpane.files.index.sx -side bottom -fill x
2830pack .vpane.files.index.sy -side right -fill y
2831pack $ui_index -side left -fill both -expand 1
2832
2833# -- Working Directory File List
2834#
2835frame .vpane.files.workdir -height 100 -width 200
2836label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2837        -background lightsalmon -foreground black
2838text $ui_workdir -background white -foreground black \
2839        -borderwidth 0 \
2840        -width 20 -height 10 \
2841        -wrap none \
2842        -cursor $cursor_ptr \
2843        -xscrollcommand {.vpane.files.workdir.sx set} \
2844        -yscrollcommand {.vpane.files.workdir.sy set} \
2845        -state disabled
2846scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2847scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2848pack .vpane.files.workdir.title -side top -fill x
2849pack .vpane.files.workdir.sx -side bottom -fill x
2850pack .vpane.files.workdir.sy -side right -fill y
2851pack $ui_workdir -side left -fill both -expand 1
2852
2853.vpane.files add .vpane.files.workdir -sticky nsew
2854.vpane.files add .vpane.files.index -sticky nsew
2855
2856foreach i [list $ui_index $ui_workdir] {
2857        rmsel_tag $i
2858        $i tag conf in_diff -background [$i tag cget in_sel -background]
2859}
2860unset i
2861
2862# -- Diff and Commit Area
2863#
2864frame .vpane.lower -height 300 -width 400
2865frame .vpane.lower.commarea
2866frame .vpane.lower.diff -relief sunken -borderwidth 1
2867pack .vpane.lower.diff -fill both -expand 1
2868pack .vpane.lower.commarea -side bottom -fill x
2869.vpane add .vpane.lower -sticky nsew
2870
2871# -- Commit Area Buttons
2872#
2873frame .vpane.lower.commarea.buttons
2874label .vpane.lower.commarea.buttons.l -text {} \
2875        -anchor w \
2876        -justify left
2877pack .vpane.lower.commarea.buttons.l -side top -fill x
2878pack .vpane.lower.commarea.buttons -side left -fill y
2879
2880button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2881        -command ui_do_rescan
2882pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2883lappend disable_on_lock \
2884        {.vpane.lower.commarea.buttons.rescan conf -state}
2885
2886button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2887        -command do_add_all
2888pack .vpane.lower.commarea.buttons.incall -side top -fill x
2889lappend disable_on_lock \
2890        {.vpane.lower.commarea.buttons.incall conf -state}
2891
2892if {![is_enabled nocommitmsg]} {
2893        button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2894                -command do_signoff
2895        pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2896}
2897
2898button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
2899        -command do_commit
2900pack .vpane.lower.commarea.buttons.commit -side top -fill x
2901lappend disable_on_lock \
2902        {.vpane.lower.commarea.buttons.commit conf -state}
2903
2904if {![is_enabled nocommit]} {
2905        button .vpane.lower.commarea.buttons.push -text [mc Push] \
2906                -command do_push_anywhere
2907        pack .vpane.lower.commarea.buttons.push -side top -fill x
2908}
2909
2910# -- Commit Message Buffer
2911#
2912frame .vpane.lower.commarea.buffer
2913frame .vpane.lower.commarea.buffer.header
2914set ui_comm .vpane.lower.commarea.buffer.t
2915set ui_coml .vpane.lower.commarea.buffer.header.l
2916
2917if {![is_enabled nocommit]} {
2918        radiobutton .vpane.lower.commarea.buffer.header.new \
2919                -text [mc "New Commit"] \
2920                -command do_select_commit_type \
2921                -variable selected_commit_type \
2922                -value new
2923        lappend disable_on_lock \
2924                [list .vpane.lower.commarea.buffer.header.new conf -state]
2925        radiobutton .vpane.lower.commarea.buffer.header.amend \
2926                -text [mc "Amend Last Commit"] \
2927                -command do_select_commit_type \
2928                -variable selected_commit_type \
2929                -value amend
2930        lappend disable_on_lock \
2931                [list .vpane.lower.commarea.buffer.header.amend conf -state]
2932}
2933
2934label $ui_coml \
2935        -anchor w \
2936        -justify left
2937proc trace_commit_type {varname args} {
2938        global ui_coml commit_type
2939        switch -glob -- $commit_type {
2940        initial       {set txt [mc "Initial Commit Message:"]}
2941        amend         {set txt [mc "Amended Commit Message:"]}
2942        amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2943        amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2944        merge         {set txt [mc "Merge Commit Message:"]}
2945        *             {set txt [mc "Commit Message:"]}
2946        }
2947        $ui_coml conf -text $txt
2948}
2949trace add variable commit_type write trace_commit_type
2950pack $ui_coml -side left -fill x
2951
2952if {![is_enabled nocommit]} {
2953        pack .vpane.lower.commarea.buffer.header.amend -side right
2954        pack .vpane.lower.commarea.buffer.header.new -side right
2955}
2956
2957text $ui_comm -background white -foreground black \
2958        -borderwidth 1 \
2959        -undo true \
2960        -maxundo 20 \
2961        -autoseparators true \
2962        -relief sunken \
2963        -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2964        -font font_diff \
2965        -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2966scrollbar .vpane.lower.commarea.buffer.sby \
2967        -command [list $ui_comm yview]
2968pack .vpane.lower.commarea.buffer.header -side top -fill x
2969pack .vpane.lower.commarea.buffer.sby -side right -fill y
2970pack $ui_comm -side left -fill y
2971pack .vpane.lower.commarea.buffer -side left -fill y
2972
2973# -- Commit Message Buffer Context Menu
2974#
2975set ctxm .vpane.lower.commarea.buffer.ctxm
2976menu $ctxm -tearoff 0
2977$ctxm add command \
2978        -label [mc Cut] \
2979        -command {tk_textCut $ui_comm}
2980$ctxm add command \
2981        -label [mc Copy] \
2982        -command {tk_textCopy $ui_comm}
2983$ctxm add command \
2984        -label [mc Paste] \
2985        -command {tk_textPaste $ui_comm}
2986$ctxm add command \
2987        -label [mc Delete] \
2988        -command {catch {$ui_comm delete sel.first sel.last}}
2989$ctxm add separator
2990$ctxm add command \
2991        -label [mc "Select All"] \
2992        -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2993$ctxm add command \
2994        -label [mc "Copy All"] \
2995        -command {
2996                $ui_comm tag add sel 0.0 end
2997                tk_textCopy $ui_comm
2998                $ui_comm tag remove sel 0.0 end
2999        }
3000$ctxm add separator
3001$ctxm add command \
3002        -label [mc "Sign Off"] \
3003        -command do_signoff
3004set ui_comm_ctxm $ctxm
3005
3006# -- Diff Header
3007#
3008proc trace_current_diff_path {varname args} {
3009        global current_diff_path diff_actions file_states
3010        if {$current_diff_path eq {}} {
3011                set s {}
3012                set f {}
3013                set p {}
3014                set o disabled
3015        } else {
3016                set p $current_diff_path
3017                set s [mapdesc [lindex $file_states($p) 0] $p]
3018                set f [mc "File:"]
3019                set p [escape_path $p]
3020                set o normal
3021        }
3022
3023        .vpane.lower.diff.header.status configure -text $s
3024        .vpane.lower.diff.header.file configure -text $f
3025        .vpane.lower.diff.header.path configure -text $p
3026        foreach w $diff_actions {
3027                uplevel #0 $w $o
3028        }
3029}
3030trace add variable current_diff_path write trace_current_diff_path
3031
3032frame .vpane.lower.diff.header -background gold
3033label .vpane.lower.diff.header.status \
3034        -background gold \
3035        -foreground black \
3036        -width $max_status_desc \
3037        -anchor w \
3038        -justify left
3039label .vpane.lower.diff.header.file \
3040        -background gold \
3041        -foreground black \
3042        -anchor w \
3043        -justify left
3044label .vpane.lower.diff.header.path \
3045        -background gold \
3046        -foreground black \
3047        -anchor w \
3048        -justify left
3049pack .vpane.lower.diff.header.status -side left
3050pack .vpane.lower.diff.header.file -side left
3051pack .vpane.lower.diff.header.path -fill x
3052set ctxm .vpane.lower.diff.header.ctxm
3053menu $ctxm -tearoff 0
3054$ctxm add command \
3055        -label [mc Copy] \
3056        -command {
3057                clipboard clear
3058                clipboard append \
3059                        -format STRING \
3060                        -type STRING \
3061                        -- $current_diff_path
3062        }
3063lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3064bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3065
3066# -- Diff Body
3067#
3068frame .vpane.lower.diff.body
3069set ui_diff .vpane.lower.diff.body.t
3070text $ui_diff -background white -foreground black \
3071        -borderwidth 0 \
3072        -width 80 -height 15 -wrap none \
3073        -font font_diff \
3074        -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3075        -yscrollcommand {.vpane.lower.diff.body.sby set} \
3076        -state disabled
3077scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3078        -command [list $ui_diff xview]
3079scrollbar .vpane.lower.diff.body.sby -orient vertical \
3080        -command [list $ui_diff yview]
3081pack .vpane.lower.diff.body.sbx -side bottom -fill x
3082pack .vpane.lower.diff.body.sby -side right -fill y
3083pack $ui_diff -side left -fill both -expand 1
3084pack .vpane.lower.diff.header -side top -fill x
3085pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3086
3087$ui_diff tag conf d_cr -elide true
3088$ui_diff tag conf d_@ -foreground blue -font font_diffbold
3089$ui_diff tag conf d_+ -foreground {#00a000}
3090$ui_diff tag conf d_- -foreground red
3091
3092$ui_diff tag conf d_++ -foreground {#00a000}
3093$ui_diff tag conf d_-- -foreground red
3094$ui_diff tag conf d_+s \
3095        -foreground {#00a000} \
3096        -background {#e2effa}
3097$ui_diff tag conf d_-s \
3098        -foreground red \
3099        -background {#e2effa}
3100$ui_diff tag conf d_s+ \
3101        -foreground {#00a000} \
3102        -background ivory1
3103$ui_diff tag conf d_s- \
3104        -foreground red \
3105        -background ivory1
3106
3107$ui_diff tag conf d<<<<<<< \
3108        -foreground orange \
3109        -font font_diffbold
3110$ui_diff tag conf d======= \
3111        -foreground orange \
3112        -font font_diffbold
3113$ui_diff tag conf d>>>>>>> \
3114        -foreground orange \
3115        -font font_diffbold
3116
3117$ui_diff tag raise sel
3118
3119# -- Diff Body Context Menu
3120#
3121
3122proc create_common_diff_popup {ctxm} {
3123        $ctxm add command \
3124                -label [mc "Show Less Context"] \
3125                -command show_less_context
3126        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3127        $ctxm add command \
3128                -label [mc "Show More Context"] \
3129                -command show_more_context
3130        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3131        $ctxm add separator
3132        $ctxm add command \
3133                -label [mc Refresh] \
3134                -command reshow_diff
3135        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3136        $ctxm add command \
3137                -label [mc Copy] \
3138                -command {tk_textCopy $ui_diff}
3139        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3140        $ctxm add command \
3141                -label [mc "Select All"] \
3142                -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3143        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3144        $ctxm add command \
3145                -label [mc "Copy All"] \
3146                -command {
3147                        $ui_diff tag add sel 0.0 end
3148                        tk_textCopy $ui_diff
3149                        $ui_diff tag remove sel 0.0 end
3150                }
3151        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3152        $ctxm add separator
3153        $ctxm add command \
3154                -label [mc "Decrease Font Size"] \
3155                -command {incr_font_size font_diff -1}
3156        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3157        $ctxm add command \
3158                -label [mc "Increase Font Size"] \
3159                -command {incr_font_size font_diff 1}
3160        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3161        $ctxm add separator
3162        set emenu $ctxm.enc
3163        menu $emenu
3164        build_encoding_menu $emenu [list force_diff_encoding]
3165        $ctxm add cascade \
3166                -label [mc "Encoding"] \
3167                -menu $emenu
3168        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3169        $ctxm add separator
3170        $ctxm add command -label [mc "Options..."] \
3171                -command do_options
3172}
3173
3174set ctxm .vpane.lower.diff.body.ctxm
3175menu $ctxm -tearoff 0
3176$ctxm add command \
3177        -label [mc "Apply/Reverse Hunk"] \
3178        -command {apply_hunk $cursorX $cursorY}
3179set ui_diff_applyhunk [$ctxm index last]
3180lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3181$ctxm add command \
3182        -label [mc "Apply/Reverse Line"] \
3183        -command {apply_line $cursorX $cursorY; do_rescan}
3184set ui_diff_applyline [$ctxm index last]
3185lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3186$ctxm add separator
3187create_common_diff_popup $ctxm
3188
3189set ctxmmg .vpane.lower.diff.body.ctxmmg
3190menu $ctxmmg -tearoff 0
3191$ctxmmg add command \
3192        -label [mc "Run Merge Tool"] \
3193        -command {merge_resolve_tool}
3194lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3195$ctxmmg add separator
3196$ctxmmg add command \
3197        -label [mc "Use Remote Version"] \
3198        -command {merge_resolve_one 3}
3199lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3200$ctxmmg add command \
3201        -label [mc "Use Local Version"] \
3202        -command {merge_resolve_one 2}
3203lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3204$ctxmmg add command \
3205        -label [mc "Revert To Base"] \
3206        -command {merge_resolve_one 1}
3207lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3208$ctxmmg add separator
3209create_common_diff_popup $ctxmmg
3210
3211proc popup_diff_menu {ctxm ctxmmg x y X Y} {
3212        global current_diff_path file_states
3213        set ::cursorX $x
3214        set ::cursorY $y
3215        if {[info exists file_states($current_diff_path)]} {
3216                set state [lindex $file_states($current_diff_path) 0]
3217        } else {
3218                set state {__}
3219        }
3220        if {[string first {U} $state] >= 0} {
3221                tk_popup $ctxmmg $X $Y
3222        } else {
3223                if {$::ui_index eq $::current_diff_side} {
3224                        set l [mc "Unstage Hunk From Commit"]
3225                        set t [mc "Unstage Line From Commit"]
3226                } else {
3227                        set l [mc "Stage Hunk For Commit"]
3228                        set t [mc "Stage Line For Commit"]
3229                }
3230                if {$::is_3way_diff || $::is_submodule_diff
3231                        || $current_diff_path eq {}
3232                        || {__} eq $state
3233                        || {_O} eq $state
3234                        || {_T} eq $state
3235                        || {T_} eq $state} {
3236                        set s disabled
3237                } else {
3238                        set s normal
3239                }
3240                $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3241                $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3242                tk_popup $ctxm $X $Y
3243        }
3244}
3245bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
3246
3247# -- Status Bar
3248#
3249set main_status [::status_bar::new .status]
3250pack .status -anchor w -side bottom -fill x
3251$main_status show [mc "Initializing..."]
3252
3253# -- Load geometry
3254#
3255catch {
3256set gm $repo_config(gui.geometry)
3257wm geometry . [lindex $gm 0]
3258.vpane sash place 0 \
3259        [lindex $gm 1] \
3260        [lindex [.vpane sash coord 0] 1]
3261.vpane.files sash place 0 \
3262        [lindex [.vpane.files sash coord 0] 0] \
3263        [lindex $gm 2]
3264unset gm
3265}
3266
3267# -- Key Bindings
3268#
3269bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3270bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3271bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3272bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3273bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3274bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3275bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3276bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3277bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3278bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3279bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3280bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3281bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3282bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3283bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3284bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3285bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3286bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3287
3288bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3289bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3290bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3291bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3292bind $ui_diff <$M1B-Key-v> {break}
3293bind $ui_diff <$M1B-Key-V> {break}
3294bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3295bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3296bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3297bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3298bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3299bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3300bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3301bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3302bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3303bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3304bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3305bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3306bind $ui_diff <Button-1>   {focus %W}
3307
3308if {[is_enabled branch]} {
3309        bind . <$M1B-Key-n> branch_create::dialog
3310        bind . <$M1B-Key-N> branch_create::dialog
3311        bind . <$M1B-Key-o> branch_checkout::dialog
3312        bind . <$M1B-Key-O> branch_checkout::dialog
3313        bind . <$M1B-Key-m> merge::dialog
3314        bind . <$M1B-Key-M> merge::dialog
3315}
3316if {[is_enabled transport]} {
3317        bind . <$M1B-Key-p> do_push_anywhere
3318        bind . <$M1B-Key-P> do_push_anywhere
3319}
3320
3321bind .   <Key-F5>     ui_do_rescan
3322bind .   <$M1B-Key-r> ui_do_rescan
3323bind .   <$M1B-Key-R> ui_do_rescan
3324bind .   <$M1B-Key-s> do_signoff
3325bind .   <$M1B-Key-S> do_signoff
3326bind .   <$M1B-Key-t> do_add_selection
3327bind .   <$M1B-Key-T> do_add_selection
3328bind .   <$M1B-Key-i> do_add_all
3329bind .   <$M1B-Key-I> do_add_all
3330bind .   <$M1B-Key-minus> {show_less_context;break}
3331bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3332bind .   <$M1B-Key-equal> {show_more_context;break}
3333bind .   <$M1B-Key-plus> {show_more_context;break}
3334bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3335bind .   <$M1B-Key-Return> do_commit
3336foreach i [list $ui_index $ui_workdir] {
3337        bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3338        bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3339        bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3340}
3341unset i
3342
3343set file_lists($ui_index) [list]
3344set file_lists($ui_workdir) [list]
3345
3346wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
3347focus -force $ui_comm
3348
3349# -- Warn the user about environmental problems.  Cygwin's Tcl
3350#    does *not* pass its env array onto any processes it spawns.
3351#    This means that git processes get none of our environment.
3352#
3353if {[is_Cygwin]} {
3354        set ignored_env 0
3355        set suggest_user {}
3356        set msg [mc "Possible environment issues exist.
3357
3358The following environment variables are probably
3359going to be ignored by any Git subprocess run
3360by %s:
3361
3362" [appname]]
3363        foreach name [array names env] {
3364                switch -regexp -- $name {
3365                {^GIT_INDEX_FILE$} -
3366                {^GIT_OBJECT_DIRECTORY$} -
3367                {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3368                {^GIT_DIFF_OPTS$} -
3369                {^GIT_EXTERNAL_DIFF$} -
3370                {^GIT_PAGER$} -
3371                {^GIT_TRACE$} -
3372                {^GIT_CONFIG$} -
3373                {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3374                        append msg " - $name\n"
3375                        incr ignored_env
3376                }
3377                {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3378                        append msg " - $name\n"
3379                        incr ignored_env
3380                        set suggest_user $name
3381                }
3382                }
3383        }
3384        if {$ignored_env > 0} {
3385                append msg [mc "
3386This is due to a known issue with the
3387Tcl binary distributed by Cygwin."]
3388
3389                if {$suggest_user ne {}} {
3390                        append msg [mc "
3391
3392A good replacement for %s
3393is placing values for the user.name and
3394user.email settings into your personal
3395~/.gitconfig file.
3396" $suggest_user]
3397                }
3398                warn_popup $msg
3399        }
3400        unset ignored_env msg suggest_user name
3401}
3402
3403# -- Only initialize complex UI if we are going to stay running.
3404#
3405if {[is_enabled transport]} {
3406        load_all_remotes
3407
3408        set n [.mbar.remote index end]
3409        populate_remotes_menu
3410        set n [expr {[.mbar.remote index end] - $n}]
3411        if {$n > 0} {
3412                if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3413                .mbar.remote insert $n separator
3414        }
3415        unset n
3416}
3417
3418if {[winfo exists $ui_comm]} {
3419        set GITGUI_BCK_exists [load_message GITGUI_BCK]
3420
3421        # -- If both our backup and message files exist use the
3422        #    newer of the two files to initialize the buffer.
3423        #
3424        if {$GITGUI_BCK_exists} {
3425                set m [gitdir GITGUI_MSG]
3426                if {[file isfile $m]} {
3427                        if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3428                                catch {file delete [gitdir GITGUI_MSG]}
3429                        } else {
3430                                $ui_comm delete 0.0 end
3431                                $ui_comm edit reset
3432                                $ui_comm edit modified false
3433                                catch {file delete [gitdir GITGUI_BCK]}
3434                                set GITGUI_BCK_exists 0
3435                        }
3436                }
3437                unset m
3438        }
3439
3440        proc backup_commit_buffer {} {
3441                global ui_comm GITGUI_BCK_exists
3442
3443                set m [$ui_comm edit modified]
3444                if {$m || $GITGUI_BCK_exists} {
3445                        set msg [string trim [$ui_comm get 0.0 end]]
3446                        regsub -all -line {[ \r\t]+$} $msg {} msg
3447
3448                        if {$msg eq {}} {
3449                                if {$GITGUI_BCK_exists} {
3450                                        catch {file delete [gitdir GITGUI_BCK]}
3451                                        set GITGUI_BCK_exists 0
3452                                }
3453                        } elseif {$m} {
3454                                catch {
3455                                        set fd [open [gitdir GITGUI_BCK] w]
3456                                        puts -nonewline $fd $msg
3457                                        close $fd
3458                                        set GITGUI_BCK_exists 1
3459                                }
3460                        }
3461
3462                        $ui_comm edit modified false
3463                }
3464
3465                set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3466        }
3467
3468        backup_commit_buffer
3469
3470        # -- If the user has aspell available we can drive it
3471        #    in pipe mode to spellcheck the commit message.
3472        #
3473        set spell_cmd [list |]
3474        set spell_dict [get_config gui.spellingdictionary]
3475        lappend spell_cmd aspell
3476        if {$spell_dict ne {}} {
3477                lappend spell_cmd --master=$spell_dict
3478        }
3479        lappend spell_cmd --mode=none
3480        lappend spell_cmd --encoding=utf-8
3481        lappend spell_cmd pipe
3482        if {$spell_dict eq {none}
3483         || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3484                bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3485        } else {
3486                set ui_comm_spell [spellcheck::init \
3487                        $spell_fd \
3488                        $ui_comm \
3489                        $ui_comm_ctxm \
3490                ]
3491        }
3492        unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3493}
3494
3495lock_index begin-read
3496if {![winfo ismapped .]} {
3497        wm deiconify .
3498}
3499after 1 {
3500        if {[is_enabled initialamend]} {
3501                force_amend
3502        } else {
3503                do_rescan
3504        }
3505
3506        if {[is_enabled nocommitmsg]} {
3507                $ui_comm configure -state disabled -background gray
3508        }
3509}
3510if {[is_enabled multicommit]} {
3511        after 1000 hint_gc
3512}
3513if {[is_enabled retcode]} {
3514        bind . <Destroy> {+terminate_me %W}
3515}
3516if {$picked && [is_config_true gui.autoexplore]} {
3517        do_explore
3518}