1#!/usr/bin/perl
2#
3# Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
4# Copyright 2005 Ryan Anderson <ryan@michonline.com>
5#
6# GPL v2 (See COPYING)
7#
8# Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
9#
10# Sends a collection of emails to the given email addresses, disturbingly fast.
11#
12# Supports two formats:
13# 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
14# 2. The original format support by Greg's script:
15# first line of the message is who to CC,
16# and second line is the subject of the message.
17#
18
19use 5.008;
20use strict;
21use warnings;
22use Term::ReadLine;
23use Getopt::Long;
24use Text::ParseWords;
25use Data::Dumper;
26use Term::ANSIColor;
27use File::Temp qw/ tempdir tempfile /;
28use File::Spec::Functions qw(catfile);
29use Error qw(:try);
30use Git;
31
32Getopt::Long::Configure qw/ pass_through /;
33
34package FakeTerm;
35sub new {
36 my ($class, $reason) = @_;
37 return bless \$reason, shift;
38}
39sub readline {
40 my $self = shift;
41 die "Cannot use readline on FakeTerm: $$self";
42}
43package main;
44
45
46sub usage {
47 print <<EOT;
48git send-email [options] <file | directory | rev-list options >
49
50 Composing:
51 --from <str> * Email From:
52 --[no-]to <str> * Email To:
53 --[no-]cc <str> * Email Cc:
54 --[no-]bcc <str> * Email Bcc:
55 --subject <str> * Email "Subject:"
56 --in-reply-to <str> * Email "In-Reply-To:"
57 --[no-]annotate * Review each patch that will be sent in an editor.
58 --compose * Open an editor for introduction.
59 --compose-encoding <str> * Encoding to assume for introduction.
60 --8bit-encoding <str> * Encoding to assume 8bit mails if undeclared
61
62 Sending:
63 --envelope-sender <str> * Email envelope sender.
64 --smtp-server <str:int> * Outgoing SMTP server to use. The port
65 is optional. Default 'localhost'.
66 --smtp-server-option <str> * Outgoing SMTP server option to use.
67 --smtp-server-port <int> * Outgoing SMTP server port.
68 --smtp-user <str> * Username for SMTP-AUTH.
69 --smtp-pass <str> * Password for SMTP-AUTH; not necessary.
70 --smtp-encryption <str> * tls or ssl; anything else disables.
71 --smtp-ssl * Deprecated. Use '--smtp-encryption ssl'.
72 --smtp-ssl-cert-path <str> * Path to ca-certificates (either directory or file).
73 Pass an empty string to disable certificate
74 verification.
75 --smtp-domain <str> * The domain name sent to HELO/EHLO handshake
76 --smtp-debug <0|1> * Disable, enable Net::SMTP debug.
77
78 Automating:
79 --identity <str> * Use the sendemail.<id> options.
80 --to-cmd <str> * Email To: via `<str> \$patch_path`
81 --cc-cmd <str> * Email Cc: via `<str> \$patch_path`
82 --suppress-cc <str> * author, self, sob, cc, cccmd, body, bodycc, all.
83 --[no-]signed-off-by-cc * Send to Signed-off-by: addresses. Default on.
84 --[no-]suppress-from * Send to self. Default off.
85 --[no-]chain-reply-to * Chain In-Reply-To: fields. Default off.
86 --[no-]thread * Use In-Reply-To: field. Default on.
87
88 Administering:
89 --confirm <str> * Confirm recipients before sending;
90 auto, cc, compose, always, or never.
91 --quiet * Output one line of info per email.
92 --dry-run * Don't actually send the emails.
93 --[no-]validate * Perform patch sanity checks. Default on.
94 --[no-]format-patch * understand any non optional arguments as
95 `git format-patch` ones.
96 --force * Send even if safety checks would prevent it.
97
98EOT
99 exit(1);
100}
101
102# most mail servers generate the Date: header, but not all...
103sub format_2822_time {
104 my ($time) = @_;
105 my @localtm = localtime($time);
106 my @gmttm = gmtime($time);
107 my $localmin = $localtm[1] + $localtm[2] * 60;
108 my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
109 if ($localtm[0] != $gmttm[0]) {
110 die "local zone differs from GMT by a non-minute interval\n";
111 }
112 if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
113 $localmin += 1440;
114 } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
115 $localmin -= 1440;
116 } elsif ($gmttm[6] != $localtm[6]) {
117 die "local time offset greater than or equal to 24 hours\n";
118 }
119 my $offset = $localmin - $gmtmin;
120 my $offhour = $offset / 60;
121 my $offmin = abs($offset % 60);
122 if (abs($offhour) >= 24) {
123 die ("local time offset greater than or equal to 24 hours\n");
124 }
125
126 return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
127 qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
128 $localtm[3],
129 qw(Jan Feb Mar Apr May Jun
130 Jul Aug Sep Oct Nov Dec)[$localtm[4]],
131 $localtm[5]+1900,
132 $localtm[2],
133 $localtm[1],
134 $localtm[0],
135 ($offset >= 0) ? '+' : '-',
136 abs($offhour),
137 $offmin,
138 );
139}
140
141my $have_email_valid = eval { require Email::Valid; 1 };
142my $have_mail_address = eval { require Mail::Address; 1 };
143my $smtp;
144my $auth;
145
146# Regexes for RFC 2047 productions.
147my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
148my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
149my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
150
151# Variables we fill in automatically, or via prompting:
152my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
153 $initial_reply_to,$initial_subject,@files,
154 $author,$sender,$smtp_authpass,$annotate,$compose,$time);
155
156my $envelope_sender;
157
158# Example reply to:
159#$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
160
161my $repo = eval { Git->repository() };
162my @repo = $repo ? ($repo) : ();
163my $term = eval {
164 $ENV{"GIT_SEND_EMAIL_NOTTY"}
165 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
166 : new Term::ReadLine 'git-send-email';
167};
168if ($@) {
169 $term = new FakeTerm "$@: going non-interactive";
170}
171
172# Behavior modification variables
173my ($quiet, $dry_run) = (0, 0);
174my $format_patch;
175my $compose_filename;
176my $force = 0;
177
178# Handle interactive edition of files.
179my $multiedit;
180my $editor;
181
182sub do_edit {
183 if (!defined($editor)) {
184 $editor = Git::command_oneline('var', 'GIT_EDITOR');
185 }
186 if (defined($multiedit) && !$multiedit) {
187 map {
188 system('sh', '-c', $editor.' "$@"', $editor, $_);
189 if (($? & 127) || ($? >> 8)) {
190 die("the editor exited uncleanly, aborting everything");
191 }
192 } @_;
193 } else {
194 system('sh', '-c', $editor.' "$@"', $editor, @_);
195 if (($? & 127) || ($? >> 8)) {
196 die("the editor exited uncleanly, aborting everything");
197 }
198 }
199}
200
201# Variables with corresponding config settings
202my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
203my ($to_cmd, $cc_cmd);
204my ($smtp_server, $smtp_server_port, @smtp_server_options);
205my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
206my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
207my ($validate, $confirm);
208my (@suppress_cc);
209my ($auto_8bit_encoding);
210my ($compose_encoding);
211
212my ($debug_net_smtp) = 0; # Net::SMTP, see send_message()
213
214my %config_bool_settings = (
215 "thread" => [\$thread, 1],
216 "chainreplyto" => [\$chain_reply_to, 0],
217 "suppressfrom" => [\$suppress_from, undef],
218 "signedoffbycc" => [\$signed_off_by_cc, undef],
219 "signedoffcc" => [\$signed_off_by_cc, undef], # Deprecated
220 "validate" => [\$validate, 1],
221 "multiedit" => [\$multiedit, undef],
222 "annotate" => [\$annotate, undef]
223);
224
225my %config_settings = (
226 "smtpserver" => \$smtp_server,
227 "smtpserverport" => \$smtp_server_port,
228 "smtpserveroption" => \@smtp_server_options,
229 "smtpuser" => \$smtp_authuser,
230 "smtppass" => \$smtp_authpass,
231 "smtpsslcertpath" => \$smtp_ssl_cert_path,
232 "smtpdomain" => \$smtp_domain,
233 "to" => \@initial_to,
234 "tocmd" => \$to_cmd,
235 "cc" => \@initial_cc,
236 "cccmd" => \$cc_cmd,
237 "aliasfiletype" => \$aliasfiletype,
238 "bcc" => \@bcclist,
239 "suppresscc" => \@suppress_cc,
240 "envelopesender" => \$envelope_sender,
241 "confirm" => \$confirm,
242 "from" => \$sender,
243 "assume8bitencoding" => \$auto_8bit_encoding,
244 "composeencoding" => \$compose_encoding,
245);
246
247my %config_path_settings = (
248 "aliasesfile" => \@alias_files,
249);
250
251# Handle Uncouth Termination
252sub signal_handler {
253
254 # Make text normal
255 print color("reset"), "\n";
256
257 # SMTP password masked
258 system "stty echo";
259
260 # tmp files from --compose
261 if (defined $compose_filename) {
262 if (-e $compose_filename) {
263 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
264 }
265 if (-e ($compose_filename . ".final")) {
266 print "'$compose_filename.final' contains the composed email.\n"
267 }
268 }
269
270 exit;
271};
272
273$SIG{TERM} = \&signal_handler;
274$SIG{INT} = \&signal_handler;
275
276# Begin by accumulating all the variables (defined above), that we will end up
277# needing, first, from the command line:
278
279my $help;
280my $rc = GetOptions("h" => \$help,
281 "sender|from=s" => \$sender,
282 "in-reply-to=s" => \$initial_reply_to,
283 "subject=s" => \$initial_subject,
284 "to=s" => \@initial_to,
285 "to-cmd=s" => \$to_cmd,
286 "no-to" => \$no_to,
287 "cc=s" => \@initial_cc,
288 "no-cc" => \$no_cc,
289 "bcc=s" => \@bcclist,
290 "no-bcc" => \$no_bcc,
291 "chain-reply-to!" => \$chain_reply_to,
292 "smtp-server=s" => \$smtp_server,
293 "smtp-server-option=s" => \@smtp_server_options,
294 "smtp-server-port=s" => \$smtp_server_port,
295 "smtp-user=s" => \$smtp_authuser,
296 "smtp-pass:s" => \$smtp_authpass,
297 "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
298 "smtp-encryption=s" => \$smtp_encryption,
299 "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
300 "smtp-debug:i" => \$debug_net_smtp,
301 "smtp-domain:s" => \$smtp_domain,
302 "identity=s" => \$identity,
303 "annotate!" => \$annotate,
304 "compose" => \$compose,
305 "quiet" => \$quiet,
306 "cc-cmd=s" => \$cc_cmd,
307 "suppress-from!" => \$suppress_from,
308 "suppress-cc=s" => \@suppress_cc,
309 "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
310 "confirm=s" => \$confirm,
311 "dry-run" => \$dry_run,
312 "envelope-sender=s" => \$envelope_sender,
313 "thread!" => \$thread,
314 "validate!" => \$validate,
315 "format-patch!" => \$format_patch,
316 "8bit-encoding=s" => \$auto_8bit_encoding,
317 "compose-encoding=s" => \$compose_encoding,
318 "force" => \$force,
319 );
320
321usage() if $help;
322unless ($rc) {
323 usage();
324}
325
326die "Cannot run git format-patch from outside a repository\n"
327 if $format_patch and not $repo;
328
329# Now, let's fill any that aren't set in with defaults:
330
331sub read_config {
332 my ($prefix) = @_;
333
334 foreach my $setting (keys %config_bool_settings) {
335 my $target = $config_bool_settings{$setting}->[0];
336 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
337 }
338
339 foreach my $setting (keys %config_path_settings) {
340 my $target = $config_path_settings{$setting};
341 if (ref($target) eq "ARRAY") {
342 unless (@$target) {
343 my @values = Git::config_path(@repo, "$prefix.$setting");
344 @$target = @values if (@values && defined $values[0]);
345 }
346 }
347 else {
348 $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
349 }
350 }
351
352 foreach my $setting (keys %config_settings) {
353 my $target = $config_settings{$setting};
354 next if $setting eq "to" and defined $no_to;
355 next if $setting eq "cc" and defined $no_cc;
356 next if $setting eq "bcc" and defined $no_bcc;
357 if (ref($target) eq "ARRAY") {
358 unless (@$target) {
359 my @values = Git::config(@repo, "$prefix.$setting");
360 @$target = @values if (@values && defined $values[0]);
361 }
362 }
363 else {
364 $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
365 }
366 }
367
368 if (!defined $smtp_encryption) {
369 my $enc = Git::config(@repo, "$prefix.smtpencryption");
370 if (defined $enc) {
371 $smtp_encryption = $enc;
372 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
373 $smtp_encryption = 'ssl';
374 }
375 }
376}
377
378# read configuration from [sendemail "$identity"], fall back on [sendemail]
379$identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
380read_config("sendemail.$identity") if (defined $identity);
381read_config("sendemail");
382
383# fall back on builtin bool defaults
384foreach my $setting (values %config_bool_settings) {
385 ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
386}
387
388# 'default' encryption is none -- this only prevents a warning
389$smtp_encryption = '' unless (defined $smtp_encryption);
390
391# Set CC suppressions
392my(%suppress_cc);
393if (@suppress_cc) {
394 foreach my $entry (@suppress_cc) {
395 die "Unknown --suppress-cc field: '$entry'\n"
396 unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
397 $suppress_cc{$entry} = 1;
398 }
399}
400
401if ($suppress_cc{'all'}) {
402 foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
403 $suppress_cc{$entry} = 1;
404 }
405 delete $suppress_cc{'all'};
406}
407
408# If explicit old-style ones are specified, they trump --suppress-cc.
409$suppress_cc{'self'} = $suppress_from if defined $suppress_from;
410$suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
411
412if ($suppress_cc{'body'}) {
413 foreach my $entry (qw (sob bodycc)) {
414 $suppress_cc{$entry} = 1;
415 }
416 delete $suppress_cc{'body'};
417}
418
419# Set confirm's default value
420my $confirm_unconfigured = !defined $confirm;
421if ($confirm_unconfigured) {
422 $confirm = scalar %suppress_cc ? 'compose' : 'auto';
423};
424die "Unknown --confirm setting: '$confirm'\n"
425 unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
426
427# Debugging, print out the suppressions.
428if (0) {
429 print "suppressions:\n";
430 foreach my $entry (keys %suppress_cc) {
431 printf " %-5s -> $suppress_cc{$entry}\n", $entry;
432 }
433}
434
435my ($repoauthor, $repocommitter);
436($repoauthor) = Git::ident_person(@repo, 'author');
437($repocommitter) = Git::ident_person(@repo, 'committer');
438
439# Verify the user input
440
441foreach my $entry (@initial_to) {
442 die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
443}
444
445foreach my $entry (@initial_cc) {
446 die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
447}
448
449foreach my $entry (@bcclist) {
450 die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
451}
452
453sub parse_address_line {
454 if ($have_mail_address) {
455 return map { $_->format } Mail::Address->parse($_[0]);
456 } else {
457 return split_addrs($_[0]);
458 }
459}
460
461sub split_addrs {
462 return quotewords('\s*,\s*', 1, @_);
463}
464
465my %aliases;
466my %parse_alias = (
467 # multiline formats can be supported in the future
468 mutt => sub { my $fh = shift; while (<$fh>) {
469 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
470 my ($alias, $addr) = ($1, $2);
471 $addr =~ s/#.*$//; # mutt allows # comments
472 # commas delimit multiple addresses
473 $aliases{$alias} = [ split_addrs($addr) ];
474 }}},
475 mailrc => sub { my $fh = shift; while (<$fh>) {
476 if (/^alias\s+(\S+)\s+(.*)$/) {
477 # spaces delimit multiple addresses
478 $aliases{$1} = [ quotewords('\s+', 0, $2) ];
479 }}},
480 pine => sub { my $fh = shift; my $f='\t[^\t]*';
481 for (my $x = ''; defined($x); $x = $_) {
482 chomp $x;
483 $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
484 $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
485 $aliases{$1} = [ split_addrs($2) ];
486 }},
487 elm => sub { my $fh = shift;
488 while (<$fh>) {
489 if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
490 my ($alias, $addr) = ($1, $2);
491 $aliases{$alias} = [ split_addrs($addr) ];
492 }
493 } },
494
495 gnus => sub { my $fh = shift; while (<$fh>) {
496 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
497 $aliases{$1} = [ $2 ];
498 }}}
499);
500
501if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
502 foreach my $file (@alias_files) {
503 open my $fh, '<', $file or die "opening $file: $!\n";
504 $parse_alias{$aliasfiletype}->($fh);
505 close $fh;
506 }
507}
508
509($sender) = expand_aliases($sender) if defined $sender;
510
511# is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
512# $f is a revision list specification to be passed to format-patch.
513sub is_format_patch_arg {
514 return unless $repo;
515 my $f = shift;
516 try {
517 $repo->command('rev-parse', '--verify', '--quiet', $f);
518 if (defined($format_patch)) {
519 return $format_patch;
520 }
521 die(<<EOF);
522File '$f' exists but it could also be the range of commits
523to produce patches for. Please disambiguate by...
524
525 * Saying "./$f" if you mean a file; or
526 * Giving --format-patch option if you mean a range.
527EOF
528 } catch Git::Error::Command with {
529 # Not a valid revision. Treat it as a filename.
530 return 0;
531 }
532}
533
534# Now that all the defaults are set, process the rest of the command line
535# arguments and collect up the files that need to be processed.
536my @rev_list_opts;
537while (defined(my $f = shift @ARGV)) {
538 if ($f eq "--") {
539 push @rev_list_opts, "--", @ARGV;
540 @ARGV = ();
541 } elsif (-d $f and !is_format_patch_arg($f)) {
542 opendir my $dh, $f
543 or die "Failed to opendir $f: $!";
544
545 push @files, grep { -f $_ } map { catfile($f, $_) }
546 sort readdir $dh;
547 closedir $dh;
548 } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
549 push @files, $f;
550 } else {
551 push @rev_list_opts, $f;
552 }
553}
554
555if (@rev_list_opts) {
556 die "Cannot run git format-patch from outside a repository\n"
557 unless $repo;
558 push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
559}
560
561if ($validate) {
562 foreach my $f (@files) {
563 unless (-p $f) {
564 my $error = validate_patch($f);
565 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
566 }
567 }
568}
569
570if (@files) {
571 unless ($quiet) {
572 print $_,"\n" for (@files);
573 }
574} else {
575 print STDERR "\nNo patch files specified!\n\n";
576 usage();
577}
578
579sub get_patch_subject {
580 my $fn = shift;
581 open (my $fh, '<', $fn);
582 while (my $line = <$fh>) {
583 next unless ($line =~ /^Subject: (.*)$/);
584 close $fh;
585 return "GIT: $1\n";
586 }
587 close $fh;
588 die "No subject line in $fn ?";
589}
590
591if ($compose) {
592 # Note that this does not need to be secure, but we will make a small
593 # effort to have it be unique
594 $compose_filename = ($repo ?
595 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
596 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
597 open my $c, ">", $compose_filename
598 or die "Failed to open for writing $compose_filename: $!";
599
600
601 my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
602 my $tpl_subject = $initial_subject || '';
603 my $tpl_reply_to = $initial_reply_to || '';
604
605 print $c <<EOT;
606From $tpl_sender # This line is ignored.
607GIT: Lines beginning in "GIT:" will be removed.
608GIT: Consider including an overall diffstat or table of contents
609GIT: for the patch you are writing.
610GIT:
611GIT: Clear the body content if you don't wish to send a summary.
612From: $tpl_sender
613Subject: $tpl_subject
614In-Reply-To: $tpl_reply_to
615
616EOT
617 for my $f (@files) {
618 print $c get_patch_subject($f);
619 }
620 close $c;
621
622 if ($annotate) {
623 do_edit($compose_filename, @files);
624 } else {
625 do_edit($compose_filename);
626 }
627
628 open my $c2, ">", $compose_filename . ".final"
629 or die "Failed to open $compose_filename.final : " . $!;
630
631 open $c, "<", $compose_filename
632 or die "Failed to open $compose_filename : " . $!;
633
634 my $need_8bit_cte = file_has_nonascii($compose_filename);
635 my $in_body = 0;
636 my $summary_empty = 1;
637 if (!defined $compose_encoding) {
638 $compose_encoding = "UTF-8";
639 }
640 while(<$c>) {
641 next if m/^GIT:/;
642 if ($in_body) {
643 $summary_empty = 0 unless (/^\n$/);
644 } elsif (/^\n$/) {
645 $in_body = 1;
646 if ($need_8bit_cte) {
647 print $c2 "MIME-Version: 1.0\n",
648 "Content-Type: text/plain; ",
649 "charset=$compose_encoding\n",
650 "Content-Transfer-Encoding: 8bit\n";
651 }
652 } elsif (/^MIME-Version:/i) {
653 $need_8bit_cte = 0;
654 } elsif (/^Subject:\s*(.+)\s*$/i) {
655 $initial_subject = $1;
656 my $subject = $initial_subject;
657 $_ = "Subject: " .
658 quote_subject($subject, $compose_encoding) .
659 "\n";
660 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
661 $initial_reply_to = $1;
662 next;
663 } elsif (/^From:\s*(.+)\s*$/i) {
664 $sender = $1;
665 next;
666 } elsif (/^(?:To|Cc|Bcc):/i) {
667 print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
668 next;
669 }
670 print $c2 $_;
671 }
672 close $c;
673 close $c2;
674
675 if ($summary_empty) {
676 print "Summary email is empty, skipping it\n";
677 $compose = -1;
678 }
679} elsif ($annotate) {
680 do_edit(@files);
681}
682
683sub ask {
684 my ($prompt, %arg) = @_;
685 my $valid_re = $arg{valid_re};
686 my $default = $arg{default};
687 my $confirm_only = $arg{confirm_only};
688 my $resp;
689 my $i = 0;
690 return defined $default ? $default : undef
691 unless defined $term->IN and defined fileno($term->IN) and
692 defined $term->OUT and defined fileno($term->OUT);
693 while ($i++ < 10) {
694 $resp = $term->readline($prompt);
695 if (!defined $resp) { # EOF
696 print "\n";
697 return defined $default ? $default : undef;
698 }
699 if ($resp eq '' and defined $default) {
700 return $default;
701 }
702 if (!defined $valid_re or $resp =~ /$valid_re/) {
703 return $resp;
704 }
705 if ($confirm_only) {
706 my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
707 if (defined $yesno && $yesno =~ /y/i) {
708 return $resp;
709 }
710 }
711 }
712 return;
713}
714
715my %broken_encoding;
716
717sub file_declares_8bit_cte {
718 my $fn = shift;
719 open (my $fh, '<', $fn);
720 while (my $line = <$fh>) {
721 last if ($line =~ /^$/);
722 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
723 }
724 close $fh;
725 return 0;
726}
727
728foreach my $f (@files) {
729 next unless (body_or_subject_has_nonascii($f)
730 && !file_declares_8bit_cte($f));
731 $broken_encoding{$f} = 1;
732}
733
734if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
735 print "The following files are 8bit, but do not declare " .
736 "a Content-Transfer-Encoding.\n";
737 foreach my $f (sort keys %broken_encoding) {
738 print " $f\n";
739 }
740 $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
741 default => "UTF-8");
742}
743
744if (!$force) {
745 for my $f (@files) {
746 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
747 die "Refusing to send because the patch\n\t$f\n"
748 . "has the template subject '*** SUBJECT HERE ***'. "
749 . "Pass --force if you really want to send.\n";
750 }
751 }
752}
753
754if (!defined $sender) {
755 $sender = $repoauthor || $repocommitter || '';
756}
757
758# $sender could be an already sanitized address
759# (e.g. sendemail.from could be manually sanitized by user).
760# But it's a no-op to run sanitize_address on an already sanitized address.
761$sender = sanitize_address($sender);
762
763my $prompting = 0;
764if (!@initial_to && !defined $to_cmd) {
765 my $to = ask("Who should the emails be sent to (if any)? ",
766 default => "",
767 valid_re => qr/\@.*\./, confirm_only => 1);
768 push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
769 $prompting++;
770}
771
772sub expand_aliases {
773 return map { expand_one_alias($_) } @_;
774}
775
776my %EXPANDED_ALIASES;
777sub expand_one_alias {
778 my $alias = shift;
779 if ($EXPANDED_ALIASES{$alias}) {
780 die "fatal: alias '$alias' expands to itself\n";
781 }
782 local $EXPANDED_ALIASES{$alias} = 1;
783 return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
784}
785
786@initial_to = expand_aliases(@initial_to);
787@initial_to = validate_address_list(sanitize_address_list(@initial_to));
788@initial_cc = expand_aliases(@initial_cc);
789@initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
790@bcclist = expand_aliases(@bcclist);
791@bcclist = validate_address_list(sanitize_address_list(@bcclist));
792
793if ($thread && !defined $initial_reply_to && $prompting) {
794 $initial_reply_to = ask(
795 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
796 default => "",
797 valid_re => qr/\@.*\./, confirm_only => 1);
798}
799if (defined $initial_reply_to) {
800 $initial_reply_to =~ s/^\s*<?//;
801 $initial_reply_to =~ s/>?\s*$//;
802 $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
803}
804
805if (!defined $smtp_server) {
806 foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
807 if (-x $_) {
808 $smtp_server = $_;
809 last;
810 }
811 }
812 $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
813}
814
815if ($compose && $compose > 0) {
816 @files = ($compose_filename . ".final", @files);
817}
818
819# Variables we set as part of the loop over files
820our ($message_id, %mail, $subject, $reply_to, $references, $message,
821 $needs_confirm, $message_num, $ask_default);
822
823sub extract_valid_address {
824 my $address = shift;
825 my $local_part_regexp = qr/[^<>"\s@]+/;
826 my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
827
828 # check for a local address:
829 return $address if ($address =~ /^($local_part_regexp)$/);
830
831 $address =~ s/^\s*<(.*)>\s*$/$1/;
832 if ($have_email_valid) {
833 return scalar Email::Valid->address($address);
834 }
835
836 # less robust/correct than the monster regexp in Email::Valid,
837 # but still does a 99% job, and one less dependency
838 return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
839 return;
840}
841
842sub extract_valid_address_or_die {
843 my $address = shift;
844 $address = extract_valid_address($address);
845 die "error: unable to extract a valid address from: $address\n"
846 if !$address;
847 return $address;
848}
849
850sub validate_address {
851 my $address = shift;
852 while (!extract_valid_address($address)) {
853 print STDERR "error: unable to extract a valid address from: $address\n";
854 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
855 valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
856 default => 'q');
857 if (/^d/i) {
858 return undef;
859 } elsif (/^q/i) {
860 cleanup_compose_files();
861 exit(0);
862 }
863 $address = ask("Who should the email be sent to (if any)? ",
864 default => "",
865 valid_re => qr/\@.*\./, confirm_only => 1);
866 }
867 return $address;
868}
869
870sub validate_address_list {
871 return (grep { defined $_ }
872 map { validate_address($_) } @_);
873}
874
875# Usually don't need to change anything below here.
876
877# we make a "fake" message id by taking the current number
878# of seconds since the beginning of Unix time and tacking on
879# a random number to the end, in case we are called quicker than
880# 1 second since the last time we were called.
881
882# We'll setup a template for the message id, using the "from" address:
883
884my ($message_id_stamp, $message_id_serial);
885sub make_message_id {
886 my $uniq;
887 if (!defined $message_id_stamp) {
888 $message_id_stamp = sprintf("%s-%s", time, $$);
889 $message_id_serial = 0;
890 }
891 $message_id_serial++;
892 $uniq = "$message_id_stamp-$message_id_serial";
893
894 my $du_part;
895 for ($sender, $repocommitter, $repoauthor) {
896 $du_part = extract_valid_address(sanitize_address($_));
897 last if (defined $du_part and $du_part ne '');
898 }
899 if (not defined $du_part or $du_part eq '') {
900 require Sys::Hostname;
901 $du_part = 'user@' . Sys::Hostname::hostname();
902 }
903 my $message_id_template = "<%s-git-send-email-%s>";
904 $message_id = sprintf($message_id_template, $uniq, $du_part);
905 #print "new message id = $message_id\n"; # Was useful for debugging
906}
907
908
909
910$time = time - scalar $#files;
911
912sub unquote_rfc2047 {
913 local ($_) = @_;
914 my $charset;
915 s{$re_encoded_word}{
916 $charset = $1;
917 my $encoding = $2;
918 my $text = $3;
919 if ($encoding eq 'q' || $encoding eq 'Q') {
920 $text =~ s/_/ /g;
921 $text =~ s/=([0-9A-F]{2})/chr(hex($1))/egi;
922 $text;
923 } else {
924 $&; # other encodings not supported yet
925 }
926 }eg;
927 return wantarray ? ($_, $charset) : $_;
928}
929
930sub quote_rfc2047 {
931 local $_ = shift;
932 my $encoding = shift || 'UTF-8';
933 s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
934 s/(.*)/=\?$encoding\?q\?$1\?=/;
935 return $_;
936}
937
938sub is_rfc2047_quoted {
939 my $s = shift;
940 length($s) <= 75 &&
941 $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
942}
943
944sub subject_needs_rfc2047_quoting {
945 my $s = shift;
946
947 return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
948}
949
950sub quote_subject {
951 local $subject = shift;
952 my $encoding = shift || 'UTF-8';
953
954 if (subject_needs_rfc2047_quoting($subject)) {
955 return quote_rfc2047($subject, $encoding);
956 }
957 return $subject;
958}
959
960# use the simplest quoting being able to handle the recipient
961sub sanitize_address {
962 my ($recipient) = @_;
963
964 # remove garbage after email address
965 $recipient =~ s/(.*>).*$/$1/;
966
967 my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
968
969 if (not $recipient_name) {
970 return $recipient;
971 }
972
973 # if recipient_name is already quoted, do nothing
974 if (is_rfc2047_quoted($recipient_name)) {
975 return $recipient;
976 }
977
978 # rfc2047 is needed if a non-ascii char is included
979 if ($recipient_name =~ /[^[:ascii:]]/) {
980 $recipient_name =~ s/^"(.*)"$/$1/;
981 $recipient_name = quote_rfc2047($recipient_name);
982 }
983
984 # double quotes are needed if specials or CTLs are included
985 elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
986 $recipient_name =~ s/(["\\\r])/\\$1/g;
987 $recipient_name = qq["$recipient_name"];
988 }
989
990 return "$recipient_name $recipient_addr";
991
992}
993
994sub sanitize_address_list {
995 return (map { sanitize_address($_) } @_);
996}
997
998# Returns the local Fully Qualified Domain Name (FQDN) if available.
999#
1000# Tightly configured MTAa require that a caller sends a real DNS
1001# domain name that corresponds the IP address in the HELO/EHLO
1002# handshake. This is used to verify the connection and prevent
1003# spammers from trying to hide their identity. If the DNS and IP don't
1004# match, the receiveing MTA may deny the connection.
1005#
1006# Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1007#
1008# Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1009# Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1010#
1011# This maildomain*() code is based on ideas in Perl library Test::Reporter
1012# /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1013
1014sub valid_fqdn {
1015 my $domain = shift;
1016 return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1017}
1018
1019sub maildomain_net {
1020 my $maildomain;
1021
1022 if (eval { require Net::Domain; 1 }) {
1023 my $domain = Net::Domain::domainname();
1024 $maildomain = $domain if valid_fqdn($domain);
1025 }
1026
1027 return $maildomain;
1028}
1029
1030sub maildomain_mta {
1031 my $maildomain;
1032
1033 if (eval { require Net::SMTP; 1 }) {
1034 for my $host (qw(mailhost localhost)) {
1035 my $smtp = Net::SMTP->new($host);
1036 if (defined $smtp) {
1037 my $domain = $smtp->domain;
1038 $smtp->quit;
1039
1040 $maildomain = $domain if valid_fqdn($domain);
1041
1042 last if $maildomain;
1043 }
1044 }
1045 }
1046
1047 return $maildomain;
1048}
1049
1050sub maildomain {
1051 return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1052}
1053
1054sub smtp_host_string {
1055 if (defined $smtp_server_port) {
1056 return "$smtp_server:$smtp_server_port";
1057 } else {
1058 return $smtp_server;
1059 }
1060}
1061
1062# Returns 1 if authentication succeeded or was not necessary
1063# (smtp_user was not specified), and 0 otherwise.
1064
1065sub smtp_auth_maybe {
1066 if (!defined $smtp_authuser || $auth) {
1067 return 1;
1068 }
1069
1070 # Workaround AUTH PLAIN/LOGIN interaction defect
1071 # with Authen::SASL::Cyrus
1072 eval {
1073 require Authen::SASL;
1074 Authen::SASL->import(qw(Perl));
1075 };
1076
1077 # TODO: Authentication may fail not because credentials were
1078 # invalid but due to other reasons, in which we should not
1079 # reject credentials.
1080 $auth = Git::credential({
1081 'protocol' => 'smtp',
1082 'host' => smtp_host_string(),
1083 'username' => $smtp_authuser,
1084 # if there's no password, "git credential fill" will
1085 # give us one, otherwise it'll just pass this one.
1086 'password' => $smtp_authpass
1087 }, sub {
1088 my $cred = shift;
1089 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1090 });
1091
1092 return $auth;
1093}
1094
1095sub ssl_verify_params {
1096 eval {
1097 require IO::Socket::SSL;
1098 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1099 };
1100 if ($@) {
1101 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1102 return;
1103 }
1104
1105 if (!defined $smtp_ssl_cert_path) {
1106 # use the OpenSSL defaults
1107 return (SSL_verify_mode => SSL_VERIFY_PEER());
1108 }
1109
1110 if ($smtp_ssl_cert_path eq "") {
1111 return (SSL_verify_mode => SSL_VERIFY_NONE());
1112 } elsif (-d $smtp_ssl_cert_path) {
1113 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1114 SSL_ca_path => $smtp_ssl_cert_path);
1115 } elsif (-f $smtp_ssl_cert_path) {
1116 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1117 SSL_ca_file => $smtp_ssl_cert_path);
1118 } else {
1119 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1120 return (SSL_verify_mode => SSL_VERIFY_NONE());
1121 }
1122}
1123
1124# Returns 1 if the message was sent, and 0 otherwise.
1125# In actuality, the whole program dies when there
1126# is an error sending a message.
1127
1128sub send_message {
1129 my @recipients = unique_email_list(@to);
1130 @cc = (grep { my $cc = extract_valid_address_or_die($_);
1131 not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1132 }
1133 @cc);
1134 my $to = join (",\n\t", @recipients);
1135 @recipients = unique_email_list(@recipients,@cc,@bcclist);
1136 @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1137 my $date = format_2822_time($time++);
1138 my $gitversion = '@@GIT_VERSION@@';
1139 if ($gitversion =~ m/..GIT_VERSION../) {
1140 $gitversion = Git::version();
1141 }
1142
1143 my $cc = join(",\n\t", unique_email_list(@cc));
1144 my $ccline = "";
1145 if ($cc ne '') {
1146 $ccline = "\nCc: $cc";
1147 }
1148 make_message_id() unless defined($message_id);
1149
1150 my $header = "From: $sender
1151To: $to${ccline}
1152Subject: $subject
1153Date: $date
1154Message-Id: $message_id
1155X-Mailer: git-send-email $gitversion
1156";
1157 if ($reply_to) {
1158
1159 $header .= "In-Reply-To: $reply_to\n";
1160 $header .= "References: $references\n";
1161 }
1162 if (@xh) {
1163 $header .= join("\n", @xh) . "\n";
1164 }
1165
1166 my @sendmail_parameters = ('-i', @recipients);
1167 my $raw_from = $sender;
1168 if (defined $envelope_sender && $envelope_sender ne "auto") {
1169 $raw_from = $envelope_sender;
1170 }
1171 $raw_from = extract_valid_address($raw_from);
1172 unshift (@sendmail_parameters,
1173 '-f', $raw_from) if(defined $envelope_sender);
1174
1175 if ($needs_confirm && !$dry_run) {
1176 print "\n$header\n";
1177 if ($needs_confirm eq "inform") {
1178 $confirm_unconfigured = 0; # squelch this message for the rest of this run
1179 $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1180 print " The Cc list above has been expanded by additional\n";
1181 print " addresses found in the patch commit message. By default\n";
1182 print " send-email prompts before sending whenever this occurs.\n";
1183 print " This behavior is controlled by the sendemail.confirm\n";
1184 print " configuration setting.\n";
1185 print "\n";
1186 print " For additional information, run 'git send-email --help'.\n";
1187 print " To retain the current behavior, but squelch this message,\n";
1188 print " run 'git config --global sendemail.confirm auto'.\n\n";
1189 }
1190 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1191 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1192 default => $ask_default);
1193 die "Send this email reply required" unless defined $_;
1194 if (/^n/i) {
1195 return 0;
1196 } elsif (/^q/i) {
1197 cleanup_compose_files();
1198 exit(0);
1199 } elsif (/^a/i) {
1200 $confirm = 'never';
1201 }
1202 }
1203
1204 unshift (@sendmail_parameters, @smtp_server_options);
1205
1206 if ($dry_run) {
1207 # We don't want to send the email.
1208 } elsif ($smtp_server =~ m#^/#) {
1209 my $pid = open my $sm, '|-';
1210 defined $pid or die $!;
1211 if (!$pid) {
1212 exec($smtp_server, @sendmail_parameters) or die $!;
1213 }
1214 print $sm "$header\n$message";
1215 close $sm or die $!;
1216 } else {
1217
1218 if (!defined $smtp_server) {
1219 die "The required SMTP server is not properly defined."
1220 }
1221
1222 if ($smtp_encryption eq 'ssl') {
1223 $smtp_server_port ||= 465; # ssmtp
1224 require Net::SMTP::SSL;
1225 $smtp_domain ||= maildomain();
1226 require IO::Socket::SSL;
1227 # Net::SMTP::SSL->new() does not forward any SSL options
1228 IO::Socket::SSL::set_client_defaults(
1229 ssl_verify_params());
1230 $smtp ||= Net::SMTP::SSL->new($smtp_server,
1231 Hello => $smtp_domain,
1232 Port => $smtp_server_port,
1233 Debug => $debug_net_smtp);
1234 }
1235 else {
1236 require Net::SMTP;
1237 $smtp_domain ||= maildomain();
1238 $smtp_server_port ||= 25;
1239 $smtp ||= Net::SMTP->new($smtp_server,
1240 Hello => $smtp_domain,
1241 Debug => $debug_net_smtp,
1242 Port => $smtp_server_port);
1243 if ($smtp_encryption eq 'tls' && $smtp) {
1244 require Net::SMTP::SSL;
1245 $smtp->command('STARTTLS');
1246 $smtp->response();
1247 if ($smtp->code == 220) {
1248 $smtp = Net::SMTP::SSL->start_SSL($smtp,
1249 ssl_verify_params())
1250 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1251 $smtp_encryption = '';
1252 # Send EHLO again to receive fresh
1253 # supported commands
1254 $smtp->hello($smtp_domain);
1255 } else {
1256 die "Server does not support STARTTLS! ".$smtp->message;
1257 }
1258 }
1259 }
1260
1261 if (!$smtp) {
1262 die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1263 "VALUES: server=$smtp_server ",
1264 "encryption=$smtp_encryption ",
1265 "hello=$smtp_domain",
1266 defined $smtp_server_port ? " port=$smtp_server_port" : "";
1267 }
1268
1269 smtp_auth_maybe or die $smtp->message;
1270
1271 $smtp->mail( $raw_from ) or die $smtp->message;
1272 $smtp->to( @recipients ) or die $smtp->message;
1273 $smtp->data or die $smtp->message;
1274 $smtp->datasend("$header\n$message") or die $smtp->message;
1275 $smtp->dataend() or die $smtp->message;
1276 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1277 }
1278 if ($quiet) {
1279 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1280 } else {
1281 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1282 if ($smtp_server !~ m#^/#) {
1283 print "Server: $smtp_server\n";
1284 print "MAIL FROM:<$raw_from>\n";
1285 foreach my $entry (@recipients) {
1286 print "RCPT TO:<$entry>\n";
1287 }
1288 } else {
1289 print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1290 }
1291 print $header, "\n";
1292 if ($smtp) {
1293 print "Result: ", $smtp->code, ' ',
1294 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1295 } else {
1296 print "Result: OK\n";
1297 }
1298 }
1299
1300 return 1;
1301}
1302
1303$reply_to = $initial_reply_to;
1304$references = $initial_reply_to || '';
1305$subject = $initial_subject;
1306$message_num = 0;
1307
1308foreach my $t (@files) {
1309 open my $fh, "<", $t or die "can't open file $t";
1310
1311 my $author = undef;
1312 my $sauthor = undef;
1313 my $author_encoding;
1314 my $has_content_type;
1315 my $body_encoding;
1316 @to = ();
1317 @cc = ();
1318 @xh = ();
1319 my $input_format = undef;
1320 my @header = ();
1321 $message = "";
1322 $message_num++;
1323 # First unfold multiline header fields
1324 while(<$fh>) {
1325 last if /^\s*$/;
1326 if (/^\s+\S/ and @header) {
1327 chomp($header[$#header]);
1328 s/^\s+/ /;
1329 $header[$#header] .= $_;
1330 } else {
1331 push(@header, $_);
1332 }
1333 }
1334 # Now parse the header
1335 foreach(@header) {
1336 if (/^From /) {
1337 $input_format = 'mbox';
1338 next;
1339 }
1340 chomp;
1341 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1342 $input_format = 'mbox';
1343 }
1344
1345 if (defined $input_format && $input_format eq 'mbox') {
1346 if (/^Subject:\s+(.*)$/i) {
1347 $subject = $1;
1348 }
1349 elsif (/^From:\s+(.*)$/i) {
1350 ($author, $author_encoding) = unquote_rfc2047($1);
1351 $sauthor = sanitize_address($author);
1352 next if $suppress_cc{'author'};
1353 next if $suppress_cc{'self'} and $sauthor eq $sender;
1354 printf("(mbox) Adding cc: %s from line '%s'\n",
1355 $1, $_) unless $quiet;
1356 push @cc, $1;
1357 }
1358 elsif (/^To:\s+(.*)$/i) {
1359 foreach my $addr (parse_address_line($1)) {
1360 printf("(mbox) Adding to: %s from line '%s'\n",
1361 $addr, $_) unless $quiet;
1362 push @to, $addr;
1363 }
1364 }
1365 elsif (/^Cc:\s+(.*)$/i) {
1366 foreach my $addr (parse_address_line($1)) {
1367 my $qaddr = unquote_rfc2047($addr);
1368 my $saddr = sanitize_address($qaddr);
1369 if ($saddr eq $sender) {
1370 next if ($suppress_cc{'self'});
1371 } else {
1372 next if ($suppress_cc{'cc'});
1373 }
1374 printf("(mbox) Adding cc: %s from line '%s'\n",
1375 $addr, $_) unless $quiet;
1376 push @cc, $addr;
1377 }
1378 }
1379 elsif (/^Content-type:/i) {
1380 $has_content_type = 1;
1381 if (/charset="?([^ "]+)/) {
1382 $body_encoding = $1;
1383 }
1384 push @xh, $_;
1385 }
1386 elsif (/^Message-Id: (.*)/i) {
1387 $message_id = $1;
1388 }
1389 elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1390 push @xh, $_;
1391 }
1392
1393 } else {
1394 # In the traditional
1395 # "send lots of email" format,
1396 # line 1 = cc
1397 # line 2 = subject
1398 # So let's support that, too.
1399 $input_format = 'lots';
1400 if (@cc == 0 && !$suppress_cc{'cc'}) {
1401 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1402 $_, $_) unless $quiet;
1403 push @cc, $_;
1404 } elsif (!defined $subject) {
1405 $subject = $_;
1406 }
1407 }
1408 }
1409 # Now parse the message body
1410 while(<$fh>) {
1411 $message .= $_;
1412 if (/^(Signed-off-by|Cc): (.*)$/i) {
1413 chomp;
1414 my ($what, $c) = ($1, $2);
1415 chomp $c;
1416 my $sc = sanitize_address($c);
1417 if ($sc eq $sender) {
1418 next if ($suppress_cc{'self'});
1419 } else {
1420 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1421 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1422 }
1423 push @cc, $c;
1424 printf("(body) Adding cc: %s from line '%s'\n",
1425 $c, $_) unless $quiet;
1426 }
1427 }
1428 close $fh;
1429
1430 push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1431 if defined $to_cmd;
1432 push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1433 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1434
1435 if ($broken_encoding{$t} && !$has_content_type) {
1436 $has_content_type = 1;
1437 push @xh, "MIME-Version: 1.0",
1438 "Content-Type: text/plain; charset=$auto_8bit_encoding",
1439 "Content-Transfer-Encoding: 8bit";
1440 $body_encoding = $auto_8bit_encoding;
1441 }
1442
1443 if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1444 $subject = quote_subject($subject, $auto_8bit_encoding);
1445 }
1446
1447 if (defined $sauthor and $sauthor ne $sender) {
1448 $message = "From: $author\n\n$message";
1449 if (defined $author_encoding) {
1450 if ($has_content_type) {
1451 if ($body_encoding eq $author_encoding) {
1452 # ok, we already have the right encoding
1453 }
1454 else {
1455 # uh oh, we should re-encode
1456 }
1457 }
1458 else {
1459 $has_content_type = 1;
1460 push @xh,
1461 'MIME-Version: 1.0',
1462 "Content-Type: text/plain; charset=$author_encoding",
1463 'Content-Transfer-Encoding: 8bit';
1464 }
1465 }
1466 }
1467
1468 $needs_confirm = (
1469 $confirm eq "always" or
1470 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1471 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1472 $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1473
1474 @to = validate_address_list(sanitize_address_list(@to));
1475 @cc = validate_address_list(sanitize_address_list(@cc));
1476
1477 @to = (@initial_to, @to);
1478 @cc = (@initial_cc, @cc);
1479
1480 my $message_was_sent = send_message();
1481
1482 # set up for the next message
1483 if ($thread && $message_was_sent &&
1484 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1485 $message_num == 1)) {
1486 $reply_to = $message_id;
1487 if (length $references > 0) {
1488 $references .= "\n $message_id";
1489 } else {
1490 $references = "$message_id";
1491 }
1492 }
1493 $message_id = undef;
1494}
1495
1496# Execute a command (e.g. $to_cmd) to get a list of email addresses
1497# and return a results array
1498sub recipients_cmd {
1499 my ($prefix, $what, $cmd, $file) = @_;
1500
1501 my @addresses = ();
1502 open my $fh, "-|", "$cmd \Q$file\E"
1503 or die "($prefix) Could not execute '$cmd'";
1504 while (my $address = <$fh>) {
1505 $address =~ s/^\s*//g;
1506 $address =~ s/\s*$//g;
1507 $address = sanitize_address($address);
1508 next if ($address eq $sender and $suppress_cc{'self'});
1509 push @addresses, $address;
1510 printf("($prefix) Adding %s: %s from: '%s'\n",
1511 $what, $address, $cmd) unless $quiet;
1512 }
1513 close $fh
1514 or die "($prefix) failed to close pipe to '$cmd'";
1515 return @addresses;
1516}
1517
1518cleanup_compose_files();
1519
1520sub cleanup_compose_files {
1521 unlink($compose_filename, $compose_filename . ".final") if $compose;
1522}
1523
1524$smtp->quit if $smtp;
1525
1526sub unique_email_list {
1527 my %seen;
1528 my @emails;
1529
1530 foreach my $entry (@_) {
1531 my $clean = extract_valid_address_or_die($entry);
1532 $seen{$clean} ||= 0;
1533 next if $seen{$clean}++;
1534 push @emails, $entry;
1535 }
1536 return @emails;
1537}
1538
1539sub validate_patch {
1540 my $fn = shift;
1541 open(my $fh, '<', $fn)
1542 or die "unable to open $fn: $!\n";
1543 while (my $line = <$fh>) {
1544 if (length($line) > 998) {
1545 return "$.: patch contains a line longer than 998 characters";
1546 }
1547 }
1548 return;
1549}
1550
1551sub file_has_nonascii {
1552 my $fn = shift;
1553 open(my $fh, '<', $fn)
1554 or die "unable to open $fn: $!\n";
1555 while (my $line = <$fh>) {
1556 return 1 if $line =~ /[^[:ascii:]]/;
1557 }
1558 return 0;
1559}
1560
1561sub body_or_subject_has_nonascii {
1562 my $fn = shift;
1563 open(my $fh, '<', $fn)
1564 or die "unable to open $fn: $!\n";
1565 while (my $line = <$fh>) {
1566 last if $line =~ /^$/;
1567 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1568 }
1569 while (my $line = <$fh>) {
1570 return 1 if $line =~ /[^[:ascii:]]/;
1571 }
1572 return 0;
1573}