1#!/usr/bin/perl -w
2#
3# Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
4# Copyright 2005 Ryan Anderson <ryan@michonline.com>
5#
6# GPL v2 (See COPYING)
7#
8# Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
9#
10# Sends a collection of emails to the given email addresses, disturbingly fast.
11#
12# Supports two formats:
13# 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
14# 2. The original format support by Greg's script:
15# first line of the message is who to CC,
16# and second line is the subject of the message.
17#
18use strict;
20use warnings;
21use Term::ReadLine;
22use Getopt::Long;
23use Text::ParseWords;
24use Data::Dumper;
25use Term::ANSIColor;
26use File::Temp qw/ tempdir tempfile /;
27use Error qw(:try);
28use Git;
29Getopt::Long::Configure qw/ pass_through /;
31package FakeTerm;
33sub new {
34 my ($class, $reason) = @_;
35 return bless \$reason, shift;
36}
37sub readline {
38 my $self = shift;
39 die "Cannot use readline on FakeTerm: $$self";
40}
41package main;
42sub usage {
45 print <<EOT;
46git send-email [options] <file | directory | rev-list options >
47 Composing:
49 --from <str> * Email From:
50 --to <str> * Email To:
51 --cc <str> * Email Cc:
52 --bcc <str> * Email Bcc:
53 --subject <str> * Email "Subject:"
54 --in-reply-to <str> * Email "In-Reply-To:"
55 --annotate * Review each patch that will be sent in an editor.
56 --compose * Open an editor for introduction.
57 Sending:
59 --envelope-sender <str> * Email envelope sender.
60 --smtp-server <str:int> * Outgoing SMTP server to use. The port
61 is optional. Default 'localhost'.
62 --smtp-server-port <int> * Outgoing SMTP server port.
63 --smtp-user <str> * Username for SMTP-AUTH.
64 --smtp-pass <str> * Password for SMTP-AUTH; not necessary.
65 --smtp-encryption <str> * tls or ssl; anything else disables.
66 --smtp-ssl * Deprecated. Use '--smtp-encryption ssl'.
67 Automating:
69 --identity <str> * Use the sendemail.<id> options.
70 --cc-cmd <str> * Email Cc: via `<str> \$patch_path`
71 --suppress-cc <str> * author, self, sob, cc, cccmd, body, bodycc, all.
72 --[no-]signed-off-by-cc * Send to Signed-off-by: addresses. Default on.
73 --[no-]suppress-from * Send to self. Default off.
74 --[no-]chain-reply-to * Chain In-Reply-To: fields. Default on.
75 --[no-]thread * Use In-Reply-To: field. Default on.
76 Administering:
78 --confirm <str> * Confirm recipients before sending;
79 auto, cc, compose, always, or never.
80 --quiet * Output one line of info per email.
81 --dry-run * Don't actually send the emails.
82 --[no-]validate * Perform patch sanity checks. Default on.
83 --[no-]format-patch * understand any non optional arguments as
84 `git format-patch` ones.
85EOT
87 exit(1);
88}
89# most mail servers generate the Date: header, but not all...
91sub format_2822_time {
92 my ($time) = @_;
93 my @localtm = localtime($time);
94 my @gmttm = gmtime($time);
95 my $localmin = $localtm[1] + $localtm[2] * 60;
96 my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
97 if ($localtm[0] != $gmttm[0]) {
98 die "local zone differs from GMT by a non-minute interval\n";
99 }
100 if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
101 $localmin += 1440;
102 } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
103 $localmin -= 1440;
104 } elsif ($gmttm[6] != $localtm[6]) {
105 die "local time offset greater than or equal to 24 hours\n";
106 }
107 my $offset = $localmin - $gmtmin;
108 my $offhour = $offset / 60;
109 my $offmin = abs($offset % 60);
110 if (abs($offhour) >= 24) {
111 die ("local time offset greater than or equal to 24 hours\n");
112 }
113 return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
115 qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
116 $localtm[3],
117 qw(Jan Feb Mar Apr May Jun
118 Jul Aug Sep Oct Nov Dec)[$localtm[4]],
119 $localtm[5]+1900,
120 $localtm[2],
121 $localtm[1],
122 $localtm[0],
123 ($offset >= 0) ? '+' : '-',
124 abs($offhour),
125 $offmin,
126 );
127}
128my $have_email_valid = eval { require Email::Valid; 1 };
130my $have_mail_address = eval { require Mail::Address; 1 };
131my $smtp;
132my $auth;
133sub unique_email_list(@);
135sub cleanup_compose_files();
136# Variables we fill in automatically, or via prompting:
138my (@to,@cc,@initial_cc,@bcclist,@xh,
139 $initial_reply_to,$initial_subject,@files,
140 $author,$sender,$smtp_authpass,$annotate,$compose,$time);
141my $envelope_sender;
143# Example reply to:
145#$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
146my $repo = eval { Git->repository() };
148my @repo = $repo ? ($repo) : ();
149my $term = eval {
150 $ENV{"GIT_SEND_EMAIL_NOTTY"}
151 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
152 : new Term::ReadLine 'git-send-email';
153};
154if ($@) {
155 $term = new FakeTerm "$@: going non-interactive";
156}
157# Behavior modification variables
159my ($quiet, $dry_run) = (0, 0);
160my $format_patch;
161my $compose_filename;
162# Handle interactive edition of files.
164my $multiedit;
165my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
166sub do_edit {
167 if (defined($multiedit) && !$multiedit) {
168 map {
169 system('sh', '-c', $editor.' "$@"', $editor, $_);
170 if (($? & 127) || ($? >> 8)) {
171 die("the editor exited uncleanly, aborting everything");
172 }
173 } @_;
174 } else {
175 system('sh', '-c', $editor.' "$@"', $editor, @_);
176 if (($? & 127) || ($? >> 8)) {
177 die("the editor exited uncleanly, aborting everything");
178 }
179 }
180}
181# Variables with corresponding config settings
183my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
184my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
185my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
186my ($validate, $confirm);
187my (@suppress_cc);
188my %config_bool_settings = (
190 "thread" => [\$thread, 1],
191 "chainreplyto" => [\$chain_reply_to, 1],
192 "suppressfrom" => [\$suppress_from, undef],
193 "signedoffbycc" => [\$signed_off_by_cc, undef],
194 "signedoffcc" => [\$signed_off_by_cc, undef], # Deprecated
195 "validate" => [\$validate, 1],
196);
197my %config_settings = (
199 "smtpserver" => \$smtp_server,
200 "smtpserverport" => \$smtp_server_port,
201 "smtpuser" => \$smtp_authuser,
202 "smtppass" => \$smtp_authpass,
203 "to" => \@to,
204 "cc" => \@initial_cc,
205 "cccmd" => \$cc_cmd,
206 "aliasfiletype" => \$aliasfiletype,
207 "bcc" => \@bcclist,
208 "aliasesfile" => \@alias_files,
209 "suppresscc" => \@suppress_cc,
210 "envelopesender" => \$envelope_sender,
211 "multiedit" => \$multiedit,
212 "confirm" => \$confirm,
213);
214# Handle Uncouth Termination
216sub signal_handler {
217 # Make text normal
219 print color("reset"), "\n";
220 # SMTP password masked
222 system "stty echo";
223 # tmp files from --compose
225 if (defined $compose_filename) {
226 if (-e $compose_filename) {
227 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
228 }
229 if (-e ($compose_filename . ".final")) {
230 print "'$compose_filename.final' contains the composed email.\n"
231 }
232 }
233 exit;
235};
236$SIG{TERM} = \&signal_handler;
238$SIG{INT} = \&signal_handler;
239# Begin by accumulating all the variables (defined above), that we will end up
241# needing, first, from the command line:
242my $rc = GetOptions("sender|from=s" => \$sender,
244 "in-reply-to=s" => \$initial_reply_to,
245 "subject=s" => \$initial_subject,
246 "to=s" => \@to,
247 "cc=s" => \@initial_cc,
248 "bcc=s" => \@bcclist,
249 "chain-reply-to!" => \$chain_reply_to,
250 "smtp-server=s" => \$smtp_server,
251 "smtp-server-port=s" => \$smtp_server_port,
252 "smtp-user=s" => \$smtp_authuser,
253 "smtp-pass:s" => \$smtp_authpass,
254 "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
255 "smtp-encryption=s" => \$smtp_encryption,
256 "identity=s" => \$identity,
257 "annotate" => \$annotate,
258 "compose" => \$compose,
259 "quiet" => \$quiet,
260 "cc-cmd=s" => \$cc_cmd,
261 "suppress-from!" => \$suppress_from,
262 "suppress-cc=s" => \@suppress_cc,
263 "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
264 "confirm=s" => \$confirm,
265 "dry-run" => \$dry_run,
266 "envelope-sender=s" => \$envelope_sender,
267 "thread!" => \$thread,
268 "validate!" => \$validate,
269 "format-patch!" => \$format_patch,
270 );
271unless ($rc) {
273 usage();
274}
275die "Cannot run git format-patch from outside a repository\n"
277 if $format_patch and not $repo;
278# Now, let's fill any that aren't set in with defaults:
280sub read_config {
282 my ($prefix) = @_;
283 foreach my $setting (keys %config_bool_settings) {
285 my $target = $config_bool_settings{$setting}->[0];
286 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
287 }
288 foreach my $setting (keys %config_settings) {
290 my $target = $config_settings{$setting};
291 if (ref($target) eq "ARRAY") {
292 unless (@$target) {
293 my @values = Git::config(@repo, "$prefix.$setting");
294 @$target = @values if (@values && defined $values[0]);
295 }
296 }
297 else {
298 $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
299 }
300 }
301 if (!defined $smtp_encryption) {
303 my $enc = Git::config(@repo, "$prefix.smtpencryption");
304 if (defined $enc) {
305 $smtp_encryption = $enc;
306 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
307 $smtp_encryption = 'ssl';
308 }
309 }
310}
311# read configuration from [sendemail "$identity"], fall back on [sendemail]
313$identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
314read_config("sendemail.$identity") if (defined $identity);
315read_config("sendemail");
316# fall back on builtin bool defaults
318foreach my $setting (values %config_bool_settings) {
319 ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
320}
321# 'default' encryption is none -- this only prevents a warning
323$smtp_encryption = '' unless (defined $smtp_encryption);
324# Set CC suppressions
326my(%suppress_cc);
327if (@suppress_cc) {
328 foreach my $entry (@suppress_cc) {
329 die "Unknown --suppress-cc field: '$entry'\n"
330 unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
331 $suppress_cc{$entry} = 1;
332 }
333}
334if ($suppress_cc{'all'}) {
336 foreach my $entry (qw (ccmd cc author self sob body bodycc)) {
337 $suppress_cc{$entry} = 1;
338 }
339 delete $suppress_cc{'all'};
340}
341# If explicit old-style ones are specified, they trump --suppress-cc.
343$suppress_cc{'self'} = $suppress_from if defined $suppress_from;
344$suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
345if ($suppress_cc{'body'}) {
347 foreach my $entry (qw (sob bodycc)) {
348 $suppress_cc{$entry} = 1;
349 }
350 delete $suppress_cc{'body'};
351}
352# Set confirm's default value
354my $confirm_unconfigured = !defined $confirm;
355if ($confirm_unconfigured) {
356 $confirm = scalar %suppress_cc ? 'compose' : 'auto';
357};
358die "Unknown --confirm setting: '$confirm'\n"
359 unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
360# Debugging, print out the suppressions.
362if (0) {
363 print "suppressions:\n";
364 foreach my $entry (keys %suppress_cc) {
365 printf " %-5s -> $suppress_cc{$entry}\n", $entry;
366 }
367}
368my ($repoauthor, $repocommitter);
370($repoauthor) = Git::ident_person(@repo, 'author');
371($repocommitter) = Git::ident_person(@repo, 'committer');
372# Verify the user input
374foreach my $entry (@to) {
376 die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
377}
378foreach my $entry (@initial_cc) {
380 die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
381}
382foreach my $entry (@bcclist) {
384 die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
385}
386sub parse_address_line {
388 if ($have_mail_address) {
389 return map { $_->format } Mail::Address->parse($_[0]);
390 } else {
391 return split_addrs($_[0]);
392 }
393}
394sub split_addrs {
396 return quotewords('\s*,\s*', 1, @_);
397}
398my %aliases;
400my %parse_alias = (
401 # multiline formats can be supported in the future
402 mutt => sub { my $fh = shift; while (<$fh>) {
403 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
404 my ($alias, $addr) = ($1, $2);
405 $addr =~ s/#.*$//; # mutt allows # comments
406 # commas delimit multiple addresses
407 $aliases{$alias} = [ split_addrs($addr) ];
408 }}},
409 mailrc => sub { my $fh = shift; while (<$fh>) {
410 if (/^alias\s+(\S+)\s+(.*)$/) {
411 # spaces delimit multiple addresses
412 $aliases{$1} = [ split(/\s+/, $2) ];
413 }}},
414 pine => sub { my $fh = shift; my $f='\t[^\t]*';
415 for (my $x = ''; defined($x); $x = $_) {
416 chomp $x;
417 $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
418 $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
419 $aliases{$1} = [ split_addrs($2) ];
420 }},
421 gnus => sub { my $fh = shift; while (<$fh>) {
422 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
423 $aliases{$1} = [ $2 ];
424 }}}
425);
426if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
428 foreach my $file (@alias_files) {
429 open my $fh, '<', $file or die "opening $file: $!\n";
430 $parse_alias{$aliasfiletype}->($fh);
431 close $fh;
432 }
433}
434($sender) = expand_aliases($sender) if defined $sender;
436# returns 1 if the conflict must be solved using it as a format-patch argument
438sub check_file_rev_conflict($) {
439 return unless $repo;
440 my $f = shift;
441 try {
442 $repo->command('rev-parse', '--verify', '--quiet', $f);
443 if (defined($format_patch)) {
444 print "foo\n";
445 return $format_patch;
446 }
447 die(<<EOF);
448File '$f' exists but it could also be the range of commits
449to produce patches for. Please disambiguate by...
450 * Saying "./$f" if you mean a file; or
452 * Giving --format-patch option if you mean a range.
453EOF
454 } catch Git::Error::Command with {
455 return 0;
456 }
457}
458# Now that all the defaults are set, process the rest of the command line
460# arguments and collect up the files that need to be processed.
461my @rev_list_opts;
462while (defined(my $f = shift @ARGV)) {
463 if ($f eq "--") {
464 push @rev_list_opts, "--", @ARGV;
465 @ARGV = ();
466 } elsif (-d $f and !check_file_rev_conflict($f)) {
467 opendir(DH,$f)
468 or die "Failed to opendir $f: $!";
469 push @files, grep { -f $_ } map { +$f . "/" . $_ }
471 sort readdir(DH);
472 closedir(DH);
473 } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
474 push @files, $f;
475 } else {
476 push @rev_list_opts, $f;
477 }
478}
479if (@rev_list_opts) {
481 die "Cannot run git format-patch from outside a repository\n"
482 unless $repo;
483 push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
484}
485if ($validate) {
487 foreach my $f (@files) {
488 unless (-p $f) {
489 my $error = validate_patch($f);
490 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
491 }
492 }
493}
494if (@files) {
496 unless ($quiet) {
497 print $_,"\n" for (@files);
498 }
499} else {
500 print STDERR "\nNo patch files specified!\n\n";
501 usage();
502}
503sub get_patch_subject($) {
505 my $fn = shift;
506 open (my $fh, '<', $fn);
507 while (my $line = <$fh>) {
508 next unless ($line =~ /^Subject: (.*)$/);
509 close $fh;
510 return "GIT: $1\n";
511 }
512 close $fh;
513 die "No subject line in $fn ?";
514}
515if ($compose) {
517 # Note that this does not need to be secure, but we will make a small
518 # effort to have it be unique
519 $compose_filename = ($repo ?
520 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
521 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
522 open(C,">",$compose_filename)
523 or die "Failed to open for writing $compose_filename: $!";
524 my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
527 my $tpl_subject = $initial_subject || '';
528 my $tpl_reply_to = $initial_reply_to || '';
529 print C <<EOT;
531From $tpl_sender # This line is ignored.
532GIT: Lines beginning in "GIT:" will be removed.
533GIT: Consider including an overall diffstat or table of contents
534GIT: for the patch you are writing.
535GIT:
536GIT: Clear the body content if you don't wish to send a summary.
537From: $tpl_sender
538Subject: $tpl_subject
539In-Reply-To: $tpl_reply_to
540EOT
542 for my $f (@files) {
543 print C get_patch_subject($f);
544 }
545 close(C);
546 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
548 if ($annotate) {
550 do_edit($compose_filename, @files);
551 } else {
552 do_edit($compose_filename);
553 }
554 open(C2,">",$compose_filename . ".final")
556 or die "Failed to open $compose_filename.final : " . $!;
557 open(C,"<",$compose_filename)
559 or die "Failed to open $compose_filename : " . $!;
560 my $need_8bit_cte = file_has_nonascii($compose_filename);
562 my $in_body = 0;
563 my $summary_empty = 1;
564 while(<C>) {
565 next if m/^GIT:/;
566 if ($in_body) {
567 $summary_empty = 0 unless (/^\n$/);
568 } elsif (/^\n$/) {
569 $in_body = 1;
570 if ($need_8bit_cte) {
571 print C2 "MIME-Version: 1.0\n",
572 "Content-Type: text/plain; ",
573 "charset=utf-8\n",
574 "Content-Transfer-Encoding: 8bit\n";
575 }
576 } elsif (/^MIME-Version:/i) {
577 $need_8bit_cte = 0;
578 } elsif (/^Subject:\s*(.+)\s*$/i) {
579 $initial_subject = $1;
580 my $subject = $initial_subject;
581 $_ = "Subject: " .
582 ($subject =~ /[^[:ascii:]]/ ?
583 quote_rfc2047($subject) :
584 $subject) .
585 "\n";
586 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
587 $initial_reply_to = $1;
588 next;
589 } elsif (/^From:\s*(.+)\s*$/i) {
590 $sender = $1;
591 next;
592 } elsif (/^(?:To|Cc|Bcc):/i) {
593 print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
594 next;
595 }
596 print C2 $_;
597 }
598 close(C);
599 close(C2);
600 if ($summary_empty) {
602 print "Summary email is empty, skipping it\n";
603 $compose = -1;
604 }
605} elsif ($annotate) {
606 do_edit(@files);
607}
608sub ask {
610 my ($prompt, %arg) = @_;
611 my $valid_re = $arg{valid_re};
612 my $default = $arg{default};
613 my $resp;
614 my $i = 0;
615 return defined $default ? $default : undef
616 unless defined $term->IN and defined fileno($term->IN) and
617 defined $term->OUT and defined fileno($term->OUT);
618 while ($i++ < 10) {
619 $resp = $term->readline($prompt);
620 if (!defined $resp) { # EOF
621 print "\n";
622 return defined $default ? $default : undef;
623 }
624 if ($resp eq '' and defined $default) {
625 return $default;
626 }
627 if (!defined $valid_re or $resp =~ /$valid_re/) {
628 return $resp;
629 }
630 }
631 return undef;
632}
633my $prompting = 0;
635if (!defined $sender) {
636 $sender = $repoauthor || $repocommitter || '';
637 $sender = ask("Who should the emails appear to be from? [$sender] ",
638 default => $sender);
639 print "Emails will be sent from: ", $sender, "\n";
640 $prompting++;
641}
642if (!@to) {
644 my $to = ask("Who should the emails be sent to? ");
645 push @to, parse_address_line($to) if defined $to; # sanitized/validated later
646 $prompting++;
647}
648sub expand_aliases {
650 my @cur = @_;
651 my @last;
652 do {
653 @last = @cur;
654 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
655 } while (join(',',@cur) ne join(',',@last));
656 return @cur;
657}
658@to = expand_aliases(@to);
660@to = (map { sanitize_address($_) } @to);
661@initial_cc = expand_aliases(@initial_cc);
662@bcclist = expand_aliases(@bcclist);
663if ($thread && !defined $initial_reply_to && $prompting) {
665 $initial_reply_to = ask(
666 "Message-ID to be used as In-Reply-To for the first email? ");
667}
668if (defined $initial_reply_to) {
669 $initial_reply_to =~ s/^\s*<?//;
670 $initial_reply_to =~ s/>?\s*$//;
671 $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
672}
673if (!defined $smtp_server) {
675 foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
676 if (-x $_) {
677 $smtp_server = $_;
678 last;
679 }
680 }
681 $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
682}
683if ($compose && $compose > 0) {
685 @files = ($compose_filename . ".final", @files);
686}
687# Variables we set as part of the loop over files
689our ($message_id, %mail, $subject, $reply_to, $references, $message,
690 $needs_confirm, $message_num, $ask_default);
691sub extract_valid_address {
693 my $address = shift;
694 my $local_part_regexp = '[^<>"\s@]+';
695 my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
696 # check for a local address:
698 return $address if ($address =~ /^($local_part_regexp)$/);
699 $address =~ s/^\s*<(.*)>\s*$/$1/;
701 if ($have_email_valid) {
702 return scalar Email::Valid->address($address);
703 } else {
704 # less robust/correct than the monster regexp in Email::Valid,
705 # but still does a 99% job, and one less dependency
706 $address =~ /($local_part_regexp\@$domain_regexp)/;
707 return $1;
708 }
709}
710# Usually don't need to change anything below here.
712# we make a "fake" message id by taking the current number
714# of seconds since the beginning of Unix time and tacking on
715# a random number to the end, in case we are called quicker than
716# 1 second since the last time we were called.
717# We'll setup a template for the message id, using the "from" address:
719my ($message_id_stamp, $message_id_serial);
721sub make_message_id
722{
723 my $uniq;
724 if (!defined $message_id_stamp) {
725 $message_id_stamp = sprintf("%s-%s", time, $$);
726 $message_id_serial = 0;
727 }
728 $message_id_serial++;
729 $uniq = "$message_id_stamp-$message_id_serial";
730 my $du_part;
732 for ($sender, $repocommitter, $repoauthor) {
733 $du_part = extract_valid_address(sanitize_address($_));
734 last if (defined $du_part and $du_part ne '');
735 }
736 if (not defined $du_part or $du_part eq '') {
737 use Sys::Hostname qw();
738 $du_part = 'user@' . Sys::Hostname::hostname();
739 }
740 my $message_id_template = "<%s-git-send-email-%s>";
741 $message_id = sprintf($message_id_template, $uniq, $du_part);
742 #print "new message id = $message_id\n"; # Was useful for debugging
743}
744$time = time - scalar $#files;
748sub unquote_rfc2047 {
750 local ($_) = @_;
751 my $encoding;
752 if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
753 $encoding = $1;
754 s/_/ /g;
755 s/=([0-9A-F]{2})/chr(hex($1))/eg;
756 }
757 return wantarray ? ($_, $encoding) : $_;
758}
759sub quote_rfc2047 {
761 local $_ = shift;
762 my $encoding = shift || 'utf-8';
763 s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
764 s/(.*)/=\?$encoding\?q\?$1\?=/;
765 return $_;
766}
767# use the simplest quoting being able to handle the recipient
769sub sanitize_address
770{
771 my ($recipient) = @_;
772 my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
773 if (not $recipient_name) {
775 return "$recipient";
776 }
777 # if recipient_name is already quoted, do nothing
779 if ($recipient_name =~ /^("[[:ascii:]]*"|=\?utf-8\?q\?.*\?=)$/) {
780 return $recipient;
781 }
782 # rfc2047 is needed if a non-ascii char is included
784 if ($recipient_name =~ /[^[:ascii:]]/) {
785 $recipient_name =~ s/^"(.*)"$/$1/;
786 $recipient_name = quote_rfc2047($recipient_name);
787 }
788 # double quotes are needed if specials or CTLs are included
790 elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
791 $recipient_name =~ s/(["\\\r])/\\$1/g;
792 $recipient_name = "\"$recipient_name\"";
793 }
794 return "$recipient_name $recipient_addr";
796}
798# Returns 1 if the message was sent, and 0 otherwise.
800# In actuality, the whole program dies when a there
801# is an error sending a message.
802sub send_message
804{
805 my @recipients = unique_email_list(@to);
806 @cc = (grep { my $cc = extract_valid_address($_);
807 not grep { $cc eq $_ } @recipients
808 }
809 map { sanitize_address($_) }
810 @cc);
811 my $to = join (",\n\t", @recipients);
812 @recipients = unique_email_list(@recipients,@cc,@bcclist);
813 @recipients = (map { extract_valid_address($_) } @recipients);
814 my $date = format_2822_time($time++);
815 my $gitversion = '@@GIT_VERSION@@';
816 if ($gitversion =~ m/..GIT_VERSION../) {
817 $gitversion = Git::version();
818 }
819 my $cc = join(", ", unique_email_list(@cc));
821 my $ccline = "";
822 if ($cc ne '') {
823 $ccline = "\nCc: $cc";
824 }
825 my $sanitized_sender = sanitize_address($sender);
826 make_message_id() unless defined($message_id);
827 my $header = "From: $sanitized_sender
829To: $to${ccline}
830Subject: $subject
831Date: $date
832Message-Id: $message_id
833X-Mailer: git-send-email $gitversion
834";
835 if ($reply_to) {
836 $header .= "In-Reply-To: $reply_to\n";
838 $header .= "References: $references\n";
839 }
840 if (@xh) {
841 $header .= join("\n", @xh) . "\n";
842 }
843 my @sendmail_parameters = ('-i', @recipients);
845 my $raw_from = $sanitized_sender;
846 $raw_from = $envelope_sender if (defined $envelope_sender);
847 $raw_from = extract_valid_address($raw_from);
848 unshift (@sendmail_parameters,
849 '-f', $raw_from) if(defined $envelope_sender);
850 if ($needs_confirm && !$dry_run) {
852 print "\n$header\n";
853 if ($needs_confirm eq "inform") {
854 $confirm_unconfigured = 0; # squelch this message for the rest of this run
855 $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
856 print " The Cc list above has been expanded by additional\n";
857 print " addresses found in the patch commit message. By default\n";
858 print " send-email prompts before sending whenever this occurs.\n";
859 print " This behavior is controlled by the sendemail.confirm\n";
860 print " configuration setting.\n";
861 print "\n";
862 print " For additional information, run 'git send-email --help'.\n";
863 print " To retain the current behavior, but squelch this message,\n";
864 print " run 'git config --global sendemail.confirm auto'.\n\n";
865 }
866 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
867 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
868 default => $ask_default);
869 die "Send this email reply required" unless defined $_;
870 if (/^n/i) {
871 return 0;
872 } elsif (/^q/i) {
873 cleanup_compose_files();
874 exit(0);
875 } elsif (/^a/i) {
876 $confirm = 'never';
877 }
878 }
879 if ($dry_run) {
881 # We don't want to send the email.
882 } elsif ($smtp_server =~ m#^/#) {
883 my $pid = open my $sm, '|-';
884 defined $pid or die $!;
885 if (!$pid) {
886 exec($smtp_server, @sendmail_parameters) or die $!;
887 }
888 print $sm "$header\n$message";
889 close $sm or die $?;
890 } else {
891 if (!defined $smtp_server) {
893 die "The required SMTP server is not properly defined."
894 }
895 if ($smtp_encryption eq 'ssl') {
897 $smtp_server_port ||= 465; # ssmtp
898 require Net::SMTP::SSL;
899 $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
900 }
901 else {
902 require Net::SMTP;
903 $smtp ||= Net::SMTP->new((defined $smtp_server_port)
904 ? "$smtp_server:$smtp_server_port"
905 : $smtp_server);
906 if ($smtp_encryption eq 'tls') {
907 require Net::SMTP::SSL;
908 $smtp->command('STARTTLS');
909 $smtp->response();
910 if ($smtp->code == 220) {
911 $smtp = Net::SMTP::SSL->start_SSL($smtp)
912 or die "STARTTLS failed! ".$smtp->message;
913 $smtp_encryption = '';
914 # Send EHLO again to receive fresh
915 # supported commands
916 $smtp->hello();
917 } else {
918 die "Server does not support STARTTLS! ".$smtp->message;
919 }
920 }
921 }
922 if (!$smtp) {
924 die "Unable to initialize SMTP properly. Is there something wrong with your config?";
925 }
926 if (defined $smtp_authuser) {
928 if (!defined $smtp_authpass) {
930 system "stty -echo";
932 do {
934 print "Password: ";
935 $_ = <STDIN>;
936 print "\n";
937 } while (!defined $_);
938 chomp($smtp_authpass = $_);
940 system "stty echo";
942 }
943 $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
945 }
946 $smtp->mail( $raw_from ) or die $smtp->message;
948 $smtp->to( @recipients ) or die $smtp->message;
949 $smtp->data or die $smtp->message;
950 $smtp->datasend("$header\n$message") or die $smtp->message;
951 $smtp->dataend() or die $smtp->message;
952 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
953 }
954 if ($quiet) {
955 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
956 } else {
957 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
958 if ($smtp_server !~ m#^/#) {
959 print "Server: $smtp_server\n";
960 print "MAIL FROM:<$raw_from>\n";
961 print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
962 } else {
963 print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
964 }
965 print $header, "\n";
966 if ($smtp) {
967 print "Result: ", $smtp->code, ' ',
968 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
969 } else {
970 print "Result: OK\n";
971 }
972 }
973 return 1;
975}
976$reply_to = $initial_reply_to;
978$references = $initial_reply_to || '';
979$subject = $initial_subject;
980$message_num = 0;
981foreach my $t (@files) {
983 open(F,"<",$t) or die "can't open file $t";
984 my $author = undef;
986 my $author_encoding;
987 my $has_content_type;
988 my $body_encoding;
989 @cc = ();
990 @xh = ();
991 my $input_format = undef;
992 my @header = ();
993 $message = "";
994 $message_num++;
995 # First unfold multiline header fields
996 while(<F>) {
997 last if /^\s*$/;
998 if (/^\s+\S/ and @header) {
999 chomp($header[$#header]);
1000 s/^\s+/ /;
1001 $header[$#header] .= $_;
1002 } else {
1003 push(@header, $_);
1004 }
1005 }
1006 # Now parse the header
1007 foreach(@header) {
1008 if (/^From /) {
1009 $input_format = 'mbox';
1010 next;
1011 }
1012 chomp;
1013 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1014 $input_format = 'mbox';
1015 }
1016 if (defined $input_format && $input_format eq 'mbox') {
1018 if (/^Subject:\s+(.*)$/) {
1019 $subject = $1;
1020 }
1021 elsif (/^From:\s+(.*)$/) {
1022 ($author, $author_encoding) = unquote_rfc2047($1);
1023 next if $suppress_cc{'author'};
1024 next if $suppress_cc{'self'} and $author eq $sender;
1025 printf("(mbox) Adding cc: %s from line '%s'\n",
1026 $1, $_) unless $quiet;
1027 push @cc, $1;
1028 }
1029 elsif (/^Cc:\s+(.*)$/) {
1030 foreach my $addr (parse_address_line($1)) {
1031 if (unquote_rfc2047($addr) eq $sender) {
1032 next if ($suppress_cc{'self'});
1033 } else {
1034 next if ($suppress_cc{'cc'});
1035 }
1036 printf("(mbox) Adding cc: %s from line '%s'\n",
1037 $addr, $_) unless $quiet;
1038 push @cc, $addr;
1039 }
1040 }
1041 elsif (/^Content-type:/i) {
1042 $has_content_type = 1;
1043 if (/charset="?([^ "]+)/) {
1044 $body_encoding = $1;
1045 }
1046 push @xh, $_;
1047 }
1048 elsif (/^Message-Id: (.*)/i) {
1049 $message_id = $1;
1050 }
1051 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1052 push @xh, $_;
1053 }
1054 } else {
1056 # In the traditional
1057 # "send lots of email" format,
1058 # line 1 = cc
1059 # line 2 = subject
1060 # So let's support that, too.
1061 $input_format = 'lots';
1062 if (@cc == 0 && !$suppress_cc{'cc'}) {
1063 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1064 $_, $_) unless $quiet;
1065 push @cc, $_;
1066 } elsif (!defined $subject) {
1067 $subject = $_;
1068 }
1069 }
1070 }
1071 # Now parse the message body
1072 while(<F>) {
1073 $message .= $_;
1074 if (/^(Signed-off-by|Cc): (.*)$/i) {
1075 chomp;
1076 my ($what, $c) = ($1, $2);
1077 chomp $c;
1078 if ($c eq $sender) {
1079 next if ($suppress_cc{'self'});
1080 } else {
1081 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1082 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1083 }
1084 push @cc, $c;
1085 printf("(body) Adding cc: %s from line '%s'\n",
1086 $c, $_) unless $quiet;
1087 }
1088 }
1089 close F;
1090 if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1092 open(F, "$cc_cmd $t |")
1093 or die "(cc-cmd) Could not execute '$cc_cmd'";
1094 while(<F>) {
1095 my $c = $_;
1096 $c =~ s/^\s*//g;
1097 $c =~ s/\n$//g;
1098 next if ($c eq $sender and $suppress_from);
1099 push @cc, $c;
1100 printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1101 $c, $cc_cmd) unless $quiet;
1102 }
1103 close F
1104 or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1105 }
1106 if (defined $author and $author ne $sender) {
1108 $message = "From: $author\n\n$message";
1109 if (defined $author_encoding) {
1110 if ($has_content_type) {
1111 if ($body_encoding eq $author_encoding) {
1112 # ok, we already have the right encoding
1113 }
1114 else {
1115 # uh oh, we should re-encode
1116 }
1117 }
1118 else {
1119 push @xh,
1120 'MIME-Version: 1.0',
1121 "Content-Type: text/plain; charset=$author_encoding",
1122 'Content-Transfer-Encoding: 8bit';
1123 }
1124 }
1125 }
1126 $needs_confirm = (
1128 $confirm eq "always" or
1129 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1130 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1131 $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1132 @cc = (@initial_cc, @cc);
1134 my $message_was_sent = send_message();
1136 # set up for the next message
1138 if ($message_was_sent and $chain_reply_to || not defined $reply_to || length($reply_to) == 0) {
1139 $reply_to = $message_id;
1140 if (length $references > 0) {
1141 $references .= "\n $message_id";
1142 } else {
1143 $references = "$message_id";
1144 }
1145 }
1146 $message_id = undef;
1147}
1148cleanup_compose_files();
1150sub cleanup_compose_files() {
1152 unlink($compose_filename, $compose_filename . ".final") if $compose;
1153}
1154$smtp->quit if $smtp;
1156sub unique_email_list(@) {
1158 my %seen;
1159 my @emails;
1160 foreach my $entry (@_) {
1162 if (my $clean = extract_valid_address($entry)) {
1163 $seen{$clean} ||= 0;
1164 next if $seen{$clean}++;
1165 push @emails, $entry;
1166 } else {
1167 print STDERR "W: unable to extract a valid address",
1168 " from: $entry\n";
1169 }
1170 }
1171 return @emails;
1172}
1173sub validate_patch {
1175 my $fn = shift;
1176 open(my $fh, '<', $fn)
1177 or die "unable to open $fn: $!\n";
1178 while (my $line = <$fh>) {
1179 if (length($line) > 998) {
1180 return "$.: patch contains a line longer than 998 characters";
1181 }
1182 }
1183 return undef;
1184}
1185sub file_has_nonascii {
1187 my $fn = shift;
1188 open(my $fh, '<', $fn)
1189 or die "unable to open $fn: $!\n";
1190 while (my $line = <$fh>) {
1191 return 1 if $line =~ /[^[:ascii:]]/;
1192 }
1193 return 0;
1194}