1# git-gui blame viewer
2# Copyright (C) 2006, 2007 Shawn Pearce
3class blame {
5image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
7# Persistant data (survives loads)
9#
10field history {}; # viewer history: {commit path}
11field header ; # array commit,key -> header field
12# Tk UI control paths
14#
15field w ; # top window in this viewer
16field w_back ; # our back button
17field w_path ; # label showing the current file path
18field w_columns ; # list of all column widgets in the viewer
19field w_line ; # text column: all line numbers
20field w_amov ; # text column: annotations + move tracking
21field w_asim ; # text column: annotations (simple computation)
22field w_file ; # text column: actual file data
23field w_cviewer ; # pane showing commit message
24field status ; # text variable bound to status bar
25field old_height ; # last known height of $w.file_pane
26# Tk UI colors
28#
29variable active_color #c0edc5
30variable group_colors {
31 #d6d6d6
32 #e1e1e1
33 #ececec
34}
35# Current blame data; cleared/reset on each load
37#
38field commit ; # input commit to blame
39field path ; # input filename to view in $commit
40field current_fd {} ; # background process running
42field highlight_line -1 ; # current line selected
43field highlight_column {} ; # current commit column selected
44field highlight_commit {} ; # sha1 of commit selected
45field total_lines 0 ; # total length of file
47field blame_lines 0 ; # number of lines computed
48field amov_data ; # list of {commit origfile origline}
49field asim_data ; # list of {commit origfile origline}
50field r_commit ; # commit currently being parsed
52field r_orig_line ; # original line number
53field r_final_line ; # final line number
54field r_line_count ; # lines in this region
55field tooltip_wm {} ; # Current tooltip toplevel, if open
57field tooltip_t {} ; # Text widget in $tooltip_wm
58field tooltip_timer {} ; # Current timer event for our tooltip
59field tooltip_commit {} ; # Commit(s) in tooltip
60constructor new {i_commit i_path} {
62 global cursor_ptr
63 variable active_color
64 variable group_colors
65 set commit $i_commit
67 set path $i_path
68 make_toplevel top w
70 wm title $top "[appname] ([reponame]): File Viewer"
71 frame $w.header -background gold
73 label $w.header.commit_l \
74 -text {Commit:} \
75 -background gold \
76 -anchor w \
77 -justify left
78 set w_back $w.header.commit_b
79 label $w_back \
80 -image ::blame::img_back_arrow \
81 -borderwidth 0 \
82 -relief flat \
83 -state disabled \
84 -background gold \
85 -activebackground gold
86 bind $w_back <Button-1> "
87 if {\[$w_back cget -state\] eq {normal}} {
88 [cb _history_menu]
89 }
90 "
91 label $w.header.commit \
92 -textvariable @commit \
93 -background gold \
94 -anchor w \
95 -justify left
96 label $w.header.path_l \
97 -text {File:} \
98 -background gold \
99 -anchor w \
100 -justify left
101 set w_path $w.header.path
102 label $w_path \
103 -background gold \
104 -anchor w \
105 -justify left
106 pack $w.header.commit_l -side left
107 pack $w_back -side left
108 pack $w.header.commit -side left
109 pack $w_path -fill x -side right
110 pack $w.header.path_l -side right
111 panedwindow $w.file_pane -orient vertical
113 frame $w.file_pane.out
114 frame $w.file_pane.cm
115 $w.file_pane add $w.file_pane.out \
116 -sticky nsew \
117 -minsize 100 \
118 -height 100 \
119 -width 100
120 $w.file_pane add $w.file_pane.cm \
121 -sticky nsew \
122 -minsize 25 \
123 -height 25 \
124 -width 100
125 set w_line $w.file_pane.out.linenumber_t
127 text $w_line \
128 -takefocus 0 \
129 -highlightthickness 0 \
130 -padx 0 -pady 0 \
131 -background white -borderwidth 0 \
132 -state disabled \
133 -wrap none \
134 -height 40 \
135 -width 6 \
136 -font font_diff
137 $w_line tag conf linenumber -justify right -rmargin 5
138 set w_amov $w.file_pane.out.amove_t
140 text $w_amov \
141 -takefocus 0 \
142 -highlightthickness 0 \
143 -padx 0 -pady 0 \
144 -background white -borderwidth 0 \
145 -state disabled \
146 -wrap none \
147 -height 40 \
148 -width 5 \
149 -font font_diff
150 $w_amov tag conf author_abbr -justify right -rmargin 5
151 $w_amov tag conf curr_commit
152 $w_amov tag conf prior_commit -foreground blue -underline 1
153 $w_amov tag bind prior_commit \
154 <Button-1> \
155 "[cb _load_commit $w_amov @amov_data @%x,%y];break"
156 set w_asim $w.file_pane.out.asimple_t
158 text $w_asim \
159 -takefocus 0 \
160 -highlightthickness 0 \
161 -padx 0 -pady 0 \
162 -background white -borderwidth 0 \
163 -state disabled \
164 -wrap none \
165 -height 40 \
166 -width 4 \
167 -font font_diff
168 $w_asim tag conf author_abbr -justify right
169 $w_asim tag conf curr_commit
170 $w_asim tag conf prior_commit -foreground blue -underline 1
171 $w_asim tag bind prior_commit \
172 <Button-1> \
173 "[cb _load_commit $w_asim @asim_data @%x,%y];break"
174 set w_file $w.file_pane.out.file_t
176 text $w_file \
177 -takefocus 0 \
178 -highlightthickness 0 \
179 -padx 0 -pady 0 \
180 -background white -borderwidth 0 \
181 -state disabled \
182 -wrap none \
183 -height 40 \
184 -width 80 \
185 -xscrollcommand [list $w.file_pane.out.sbx set] \
186 -font font_diff
187 set w_columns [list $w_amov $w_asim $w_line $w_file]
189 scrollbar $w.file_pane.out.sbx \
191 -orient h \
192 -command [list $w_file xview]
193 scrollbar $w.file_pane.out.sby \
194 -orient v \
195 -command [list scrollbar2many $w_columns yview]
196 eval grid $w_columns $w.file_pane.out.sby -sticky nsew
197 grid conf \
198 $w.file_pane.out.sbx \
199 -column [expr {[llength $w_columns] - 1}] \
200 -sticky we
201 grid columnconfigure \
202 $w.file_pane.out \
203 [expr {[llength $w_columns] - 1}] \
204 -weight 1
205 grid rowconfigure $w.file_pane.out 0 -weight 1
206 set w_cviewer $w.file_pane.cm.t
208 text $w_cviewer \
209 -background white -borderwidth 0 \
210 -state disabled \
211 -wrap none \
212 -height 10 \
213 -width 80 \
214 -xscrollcommand [list $w.file_pane.cm.sbx set] \
215 -yscrollcommand [list $w.file_pane.cm.sby set] \
216 -font font_diff
217 $w_cviewer tag conf still_loading \
218 -font font_uiitalic \
219 -justify center
220 $w_cviewer tag conf header_key \
221 -tabs {3c} \
222 -background $active_color \
223 -font font_uibold
224 $w_cviewer tag conf header_val \
225 -background $active_color \
226 -font font_ui
227 $w_cviewer tag raise sel
228 scrollbar $w.file_pane.cm.sbx \
229 -orient h \
230 -command [list $w_cviewer xview]
231 scrollbar $w.file_pane.cm.sby \
232 -orient v \
233 -command [list $w_cviewer yview]
234 pack $w.file_pane.cm.sby -side right -fill y
235 pack $w.file_pane.cm.sbx -side bottom -fill x
236 pack $w_cviewer -expand 1 -fill both
237 frame $w.status \
239 -borderwidth 1 \
240 -relief sunken
241 label $w.status.l \
242 -textvariable @status \
243 -anchor w \
244 -justify left
245 pack $w.status.l -side left
246 menu $w.ctxm -tearoff 0
248 $w.ctxm add command \
249 -label "Copy Commit" \
250 -command [cb _copycommit]
251 foreach i $w_columns {
253 for {set g 0} {$g < [llength $group_colors]} {incr g} {
254 $i tag conf color$g -background [lindex $group_colors $g]
255 }
256 $i conf -cursor $cursor_ptr
258 $i conf -yscrollcommand [list many2scrollbar \
259 $w_columns yview $w.file_pane.out.sby]
260 bind $i <Button-1> "
261 [cb _hide_tooltip]
262 [cb _click $i @%x,%y]
263 focus $i
264 "
265 bind $i <Any-Motion> [cb _show_tooltip $i @%x,%y]
266 bind $i <Any-Enter> [cb _hide_tooltip]
267 bind $i <Any-Leave> [cb _hide_tooltip]
268 bind_button3 $i "
269 [cb _hide_tooltip]
270 set cursorX %x
271 set cursorY %y
272 set cursorW %W
273 tk_popup $w.ctxm %X %Y
274 "
275 }
276 foreach i [concat $w_columns $w_cviewer] {
278 bind $i <Key-Up> {catch {%W yview scroll -1 units};break}
279 bind $i <Key-Down> {catch {%W yview scroll 1 units};break}
280 bind $i <Key-Left> {catch {%W xview scroll -1 units};break}
281 bind $i <Key-Right> {catch {%W xview scroll 1 units};break}
282 bind $i <Key-k> {catch {%W yview scroll -1 units};break}
283 bind $i <Key-j> {catch {%W yview scroll 1 units};break}
284 bind $i <Key-h> {catch {%W xview scroll -1 units};break}
285 bind $i <Key-l> {catch {%W xview scroll 1 units};break}
286 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
287 bind $i <Control-Key-f> {catch {%W yview scroll 1 pages};break}
288 }
289 bind $w_cviewer <Button-1> [list focus $w_cviewer]
291 bind $top <Visibility> [list focus $top]
292 grid configure $w.header -sticky ew
294 grid configure $w.file_pane -sticky nsew
295 grid configure $w.status -sticky ew
296 grid columnconfigure $top 0 -weight 1
297 grid rowconfigure $top 0 -weight 0
298 grid rowconfigure $top 1 -weight 1
299 grid rowconfigure $top 2 -weight 0
300 set req_w [winfo reqwidth $top]
302 set req_h [winfo reqheight $top]
303 if {$req_w < 600} {set req_w 600}
304 if {$req_h < 400} {set req_h 400}
305 set g "${req_w}x${req_h}"
306 wm geometry $top $g
307 update
308 set old_height [winfo height $w.file_pane]
310 $w.file_pane sash place 0 \
311 [lindex [$w.file_pane sash coord 0] 0] \
312 [expr {int($old_height * 0.70)}]
313 bind $w.file_pane <Configure> \
314 "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
315 _load $this {}
317}
318method _load {jump} {
320 variable group_colors
321 _hide_tooltip $this
323 if {$total_lines != 0 || $current_fd ne {}} {
325 if {$current_fd ne {}} {
326 catch {close $current_fd}
327 set current_fd {}
328 }
329 foreach i $w_columns {
331 $i conf -state normal
332 $i delete 0.0 end
333 foreach g [$i tag names] {
334 if {[regexp {^g[0-9a-f]{40}$} $g]} {
335 $i tag delete $g
336 }
337 }
338 $i conf -state disabled
339 }
340 $w_cviewer conf -state normal
342 $w_cviewer delete 0.0 end
343 $w_cviewer conf -state disabled
344 set highlight_line -1
346 set highlight_column {}
347 set highlight_commit {}
348 set total_lines 0
349 }
350 if {[winfo exists $w.status.c]} {
352 $w.status.c coords bar 0 0 0 20
353 } else {
354 canvas $w.status.c \
355 -width 100 \
356 -height [expr {int([winfo reqheight $w.status.l] * 0.6)}] \
357 -borderwidth 1 \
358 -relief groove \
359 -highlightt 0
360 $w.status.c create rectangle 0 0 0 20 -tags bar -fill navy
361 pack $w.status.c -side right
362 }
363 if {$history eq {}} {
365 $w_back conf -state disabled
366 } else {
367 $w_back conf -state normal
368 }
369 # Index 0 is always empty. There is never line 0 as
371 # we use only 1 based lines, as that matches both with
372 # git-blame output and with Tk's text widget.
373 #
374 set amov_data [list [list]]
375 set asim_data [list [list]]
376 set status "Loading $commit:[escape_path $path]..."
378 $w_path conf -text [escape_path $path]
379 if {$commit eq {}} {
380 set fd [open $path r]
381 } else {
382 set cmd [list git cat-file blob "$commit:$path"]
383 set fd [open "| $cmd" r]
384 }
385 fconfigure $fd -blocking 0 -translation lf -encoding binary
386 fileevent $fd readable [cb _read_file $fd $jump]
387 set current_fd $fd
388}
389method _history_menu {} {
391 set m $w.backmenu
392 if {[winfo exists $m]} {
393 $m delete 0 end
394 } else {
395 menu $m -tearoff 0
396 }
397 for {set i [expr {[llength $history] - 1}]
399 } {$i >= 0} {incr i -1} {
400 set e [lindex $history $i]
401 set c [lindex $e 0]
402 set f [lindex $e 1]
403 if {[regexp {^[0-9a-f]{40}$} $c]} {
405 set t [string range $c 0 8]...
406 } elseif {$c eq {}} {
407 set t {Working Directory}
408 } else {
409 set t $c
410 }
411 if {![catch {set summary $header($c,summary)}]} {
412 append t " $summary"
413 if {[string length $t] > 70} {
414 set t [string range $t 0 66]...
415 }
416 }
417 $m add command -label $t -command [cb _goback $i]
419 }
420 set X [winfo rootx $w_back]
421 set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
422 tk_popup $m $X $Y
423}
424method _goback {i} {
426 set dat [lindex $history $i]
427 set history [lrange $history 0 [expr {$i - 1}]]
428 set commit [lindex $dat 0]
429 set path [lindex $dat 1]
430 _load $this [lrange $dat 2 5]
431}
432method _read_file {fd jump} {
434 if {$fd ne $current_fd} {
435 catch {close $fd}
436 return
437 }
438 foreach i $w_columns {$i conf -state normal}
440 while {[gets $fd line] >= 0} {
441 regsub "\r\$" $line {} line
442 incr total_lines
443 lappend amov_data {}
444 lappend asim_data {}
445 if {$total_lines > 1} {
447 foreach i $w_columns {$i insert end "\n"}
448 }
449 $w_line insert end "$total_lines" linenumber
451 $w_file insert end "$line"
452 }
453 set ln_wc [expr {[string length $total_lines] + 2}]
455 if {[$w_line cget -width] < $ln_wc} {
456 $w_line conf -width $ln_wc
457 }
458 foreach i $w_columns {$i conf -state disabled}
460 if {[eof $fd]} {
462 close $fd
463 # If we don't force Tk to update the widgets *right now*
465 # none of our jump commands will cause a change in the UI.
466 #
467 update
468 if {[llength $jump] == 1} {
470 set highlight_line [lindex $jump 0]
471 $w_file see "$highlight_line.0"
472 } elseif {[llength $jump] == 4} {
473 set highlight_column [lindex $jump 0]
474 set highlight_line [lindex $jump 1]
475 $w_file xview moveto [lindex $jump 2]
476 $w_file yview moveto [lindex $jump 3]
477 }
478 _exec_blame $this $w_asim @asim_data \
480 [list] \
481 { copy/move tracking}
482 }
483} ifdeleted { catch {close $fd} }
484method _exec_blame {cur_w cur_d options cur_s} {
486 set cmd [list nice git blame]
487 set cmd [concat $cmd $options]
488 lappend cmd --incremental
489 if {$commit eq {}} {
490 lappend cmd --contents $path
491 } else {
492 lappend cmd $commit
493 }
494 lappend cmd -- $path
495 set fd [open "| $cmd" r]
496 fconfigure $fd -blocking 0 -translation lf -encoding binary
497 fileevent $fd readable [cb _read_blame $fd $cur_w $cur_d $cur_s]
498 set current_fd $fd
499 set blame_lines 0
500 _status $this $cur_s
501}
502method _read_blame {fd cur_w cur_d cur_s} {
504 upvar #0 $cur_d line_data
505 variable group_colors
506 if {$fd ne $current_fd} {
508 catch {close $fd}
509 return
510 }
511 $cur_w conf -state normal
513 while {[gets $fd line] >= 0} {
514 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
515 cmit original_line final_line line_count]} {
516 set r_commit $cmit
517 set r_orig_line $original_line
518 set r_final_line $final_line
519 set r_line_count $line_count
520 } elseif {[string match {filename *} $line]} {
521 set file [string range $line 9 end]
522 set n $r_line_count
523 set lno $r_final_line
524 set oln $r_orig_line
525 set cmit $r_commit
526 if {[regexp {^0{40}$} $cmit]} {
528 set commit_abbr work
529 set commit_type curr_commit
530 } elseif {$cmit eq $commit} {
531 set commit_abbr this
532 set commit_type curr_commit
533 } else {
534 set commit_type prior_commit
535 set commit_abbr [string range $cmit 0 3]
536 }
537 set author_abbr {}
539 set a_name {}
540 catch {set a_name $header($cmit,author)}
541 while {$a_name ne {}} {
542 if {![regexp {^([[:upper:]])} $a_name _a]} break
543 append author_abbr $_a
544 unset _a
545 if {![regsub \
546 {^[[:upper:]][^\s]*\s+} \
547 $a_name {} a_name ]} break
548 }
549 if {$author_abbr eq {}} {
550 set author_abbr { |}
551 } else {
552 set author_abbr [string range $author_abbr 0 3]
553 }
554 unset a_name
555 set first_lno $lno
557 while {
558 $first_lno > 1
559 && $cmit eq [lindex $line_data [expr {$first_lno - 1}] 0]
560 && $file eq [lindex $line_data [expr {$first_lno - 1}] 1]
561 } {
562 incr first_lno -1
563 }
564 set color {}
566 if {$first_lno < $lno} {
567 foreach g [$w_file tag names $first_lno.0] {
568 if {[regexp {^color[0-9]+$} $g]} {
569 set color $g
570 break
571 }
572 }
573 } else {
574 set i [lsort [concat \
575 [$w_file tag names "[expr {$first_lno - 1}].0"] \
576 [$w_file tag names "[expr {$lno + $n}].0"] \
577 ]]
578 for {set g 0} {$g < [llength $group_colors]} {incr g} {
579 if {[lsearch -sorted -exact $i color$g] == -1} {
580 set color color$g
581 break
582 }
583 }
584 }
585 if {$color eq {}} {
586 set color color0
587 }
588 while {$n > 0} {
590 set lno_e "$lno.0 lineend + 1c"
591 if {[lindex $line_data $lno] ne {}} {
592 set g [lindex $line_data $lno 0]
593 foreach i $w_columns {
594 $i tag remove g$g $lno.0 $lno_e
595 }
596 }
597 lset line_data $lno [list $cmit $file $oln]
598 $cur_w delete $lno.0 "$lno.0 lineend"
600 if {$lno == $first_lno} {
601 $cur_w insert $lno.0 $commit_abbr $commit_type
602 } elseif {$lno == [expr {$first_lno + 1}]} {
603 $cur_w insert $lno.0 $author_abbr author_abbr
604 } else {
605 $cur_w insert $lno.0 { |}
606 }
607 foreach i $w_columns {
609 if {$cur_w eq $w_amov} {
610 for {set g 0} \
611 {$g < [llength $group_colors]} \
612 {incr g} {
613 $i tag remove color$g $lno.0 $lno_e
614 }
615 $i tag add $color $lno.0 $lno_e
616 }
617 $i tag add g$cmit $lno.0 $lno_e
618 }
619 if {$highlight_column eq $cur_w} {
621 if {$highlight_line == -1
622 && [lindex [$w_file yview] 0] == 0} {
623 $w_file see $lno.0
624 set highlight_line $lno
625 }
626 if {$highlight_line == $lno} {
627 _showcommit $this $cur_w $lno
628 }
629 }
630 incr n -1
632 incr lno
633 incr oln
634 incr blame_lines
635 }
636 while {
638 $cmit eq [lindex $line_data $lno 0]
639 && $file eq [lindex $line_data $lno 1]
640 } {
641 $cur_w delete $lno.0 "$lno.0 lineend"
642 if {$lno == $first_lno} {
644 $cur_w insert $lno.0 $commit_abbr $commit_type
645 } elseif {$lno == [expr {$first_lno + 1}]} {
646 $cur_w insert $lno.0 $author_abbr author_abbr
647 } else {
648 $cur_w insert $lno.0 { |}
649 }
650 if {$cur_w eq $w_amov} {
652 foreach i $w_columns {
653 for {set g 0} \
654 {$g < [llength $group_colors]} \
655 {incr g} {
656 $i tag remove color$g $lno.0 $lno_e
657 }
658 $i tag add $color $lno.0 $lno_e
659 }
660 }
661 incr lno
663 }
664 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
666 set header($r_commit,$key) $data
667 }
668 }
669 $cur_w conf -state disabled
670 if {[eof $fd]} {
672 close $fd
673 if {$cur_w eq $w_asim} {
674 _exec_blame $this $w_amov @amov_data \
675 [list -M -C -C] \
676 { original location}
677 } else {
678 set current_fd {}
679 set status {Annotation complete.}
680 destroy $w.status.c
681 }
682 } else {
683 _status $this $cur_s
684 }
685} ifdeleted { catch {close $fd} }
686method _status {cur_s} {
688 set have $blame_lines
689 set total $total_lines
690 set pdone 0
691 if {$total} {set pdone [expr {100 * $have / $total}]}
692 set status [format \
694 "Loading%s annotations... %i of %i lines annotated (%2i%%)" \
695 $cur_s $have $total $pdone]
696 $w.status.c coords bar 0 0 $pdone 20
697}
698method _click {cur_w pos} {
700 set lno [lindex [split [$cur_w index $pos] .] 0]
701 _showcommit $this $cur_w $lno
702}
703method _load_commit {cur_w cur_d pos} {
705 upvar #0 $cur_d line_data
706 set lno [lindex [split [$cur_w index $pos] .] 0]
707 set dat [lindex $line_data $lno]
708 if {$dat ne {}} {
709 lappend history [list \
710 $commit $path \
711 $highlight_column \
712 $highlight_line \
713 [lindex [$w_file xview] 0] \
714 [lindex [$w_file yview] 0] \
715 ]
716 set commit [lindex $dat 0]
717 set path [lindex $dat 1]
718 _load $this [list [lindex $dat 2]]
719 }
720}
721method _showcommit {cur_w lno} {
723 global repo_config
724 variable active_color
725 if {$highlight_commit ne {}} {
727 foreach i $w_columns {
728 $i tag conf g$highlight_commit -background {}
729 $i tag lower g$highlight_commit
730 }
731 }
732 if {$cur_w eq $w_asim} {
734 set dat [lindex $asim_data $lno]
735 set highlight_column $w_asim
736 } else {
737 set dat [lindex $amov_data $lno]
738 set highlight_column $w_amov
739 }
740 $w_cviewer conf -state normal
742 $w_cviewer delete 0.0 end
743 if {$dat eq {}} {
745 set cmit {}
746 $w_cviewer insert end "Loading annotation..." still_loading
747 } else {
748 set cmit [lindex $dat 0]
749 set file [lindex $dat 1]
750 foreach i $w_columns {
752 $i tag conf g$cmit -background $active_color
753 $i tag raise g$cmit
754 }
755 set author_name {}
757 set author_email {}
758 set author_time {}
759 catch {set author_name $header($cmit,author)}
760 catch {set author_email $header($cmit,author-mail)}
761 catch {set author_time [clock format \
762 $header($cmit,author-time) \
763 -format {%Y-%m-%d %H:%M:%S}
764 ]}
765 set committer_name {}
767 set committer_email {}
768 set committer_time {}
769 catch {set committer_name $header($cmit,committer)}
770 catch {set committer_email $header($cmit,committer-mail)}
771 catch {set committer_time [clock format \
772 $header($cmit,committer-time) \
773 -format {%Y-%m-%d %H:%M:%S}
774 ]}
775 if {[catch {set msg $header($cmit,message)}]} {
777 set msg {}
778 catch {
779 set fd [open "| git cat-file commit $cmit" r]
780 fconfigure $fd -encoding binary -translation lf
781 if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
782 set enc utf-8
783 }
784 while {[gets $fd line] > 0} {
785 if {[string match {encoding *} $line]} {
786 set enc [string tolower [string range $line 9 end]]
787 }
788 }
789 set msg [encoding convertfrom $enc [read $fd]]
790 set msg [string trim $msg]
791 close $fd
792 set author_name [encoding convertfrom $enc $author_name]
794 set committer_name [encoding convertfrom $enc $committer_name]
795 set header($cmit,author) $author_name
797 set header($cmit,committer) $committer_name
798 }
799 set header($cmit,message) $msg
800 }
801 $w_cviewer insert end "commit $cmit\n" header_key
803 $w_cviewer insert end "Author:\t" header_key
804 $w_cviewer insert end "$author_name $author_email" header_val
805 $w_cviewer insert end " $author_time\n" header_val
806 $w_cviewer insert end "Committer:\t" header_key
808 $w_cviewer insert end "$committer_name $committer_email" header_val
809 $w_cviewer insert end " $committer_time\n" header_val
810 if {$file ne $path} {
812 $w_cviewer insert end "Original File:\t" header_key
813 $w_cviewer insert end "[escape_path $file]\n" header_val
814 }
815 $w_cviewer insert end "\n$msg"
817 }
818 $w_cviewer conf -state disabled
819 set highlight_line $lno
821 set highlight_commit $cmit
822 if {[lsearch -exact $tooltip_commit $highlight_commit] != -1} {
824 _hide_tooltip $this
825 }
826}
827method _copycommit {} {
829 set pos @$::cursorX,$::cursorY
830 set lno [lindex [split [$::cursorW index $pos] .] 0]
831 set dat [lindex $amov_data $lno]
832 if {$dat ne {}} {
833 clipboard clear
834 clipboard append \
835 -format STRING \
836 -type STRING \
837 -- [lindex $dat 0]
838 }
839}
840method _show_tooltip {cur_w pos} {
842 if {$tooltip_wm ne {}} {
843 _open_tooltip $this $cur_w
844 } elseif {$tooltip_timer eq {}} {
845 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
846 }
847}
848method _open_tooltip {cur_w} {
850 set tooltip_timer {}
851 set pos_x [winfo pointerx $cur_w]
852 set pos_y [winfo pointery $cur_w]
853 if {[winfo containing $pos_x $pos_y] ne $cur_w} {
854 _hide_tooltip $this
855 return
856 }
857 if {$tooltip_wm ne "$cur_w.tooltip"} {
859 _hide_tooltip $this
860 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
862 wm overrideredirect $tooltip_wm 1
863 wm transient $tooltip_wm [winfo toplevel $cur_w]
864 set tooltip_t $tooltip_wm.label
865 text $tooltip_t \
866 -takefocus 0 \
867 -highlightthickness 0 \
868 -relief flat \
869 -borderwidth 0 \
870 -wrap none \
871 -background lightyellow \
872 -foreground black
873 $tooltip_t tag conf section_header -font font_uibold
874 pack $tooltip_t
875 } else {
876 $tooltip_t conf -state normal
877 $tooltip_t delete 0.0 end
878 }
879 set pos @[join [list \
881 [expr {$pos_x - [winfo rootx $cur_w]}] \
882 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
883 set lno [lindex [split [$cur_w index $pos] .] 0]
884 if {$cur_w eq $w_amov} {
885 set dat [lindex $amov_data $lno]
886 set org {}
887 } else {
888 set dat [lindex $asim_data $lno]
889 set org [lindex $amov_data $lno]
890 }
891 set cmit [lindex $dat 0]
893 set tooltip_commit [list $cmit]
894 set author_name {}
896 set summary {}
897 set author_time {}
898 catch {set author_name $header($cmit,author)}
899 catch {set summary $header($cmit,summary)}
900 catch {set author_time [clock format \
901 $header($cmit,author-time) \
902 -format {%Y-%m-%d %H:%M:%S}
903 ]}
904 $tooltip_t insert end "commit $cmit\n"
906 $tooltip_t insert end "$author_name $author_time\n"
907 $tooltip_t insert end "$summary"
908 if {$org ne {} && [lindex $org 0] ne $cmit} {
910 set save [$tooltip_t get 0.0 end]
911 $tooltip_t delete 0.0 end
912 set cmit [lindex $org 0]
914 set file [lindex $org 1]
915 lappend tooltip_commit $cmit
916 set author_name {}
918 set summary {}
919 set author_time {}
920 catch {set author_name $header($cmit,author)}
921 catch {set summary $header($cmit,summary)}
922 catch {set author_time [clock format \
923 $header($cmit,author-time) \
924 -format {%Y-%m-%d %H:%M:%S}
925 ]}
926 $tooltip_t insert end "Originally By:\n" section_header
928 $tooltip_t insert end "commit $cmit\n"
929 $tooltip_t insert end "$author_name $author_time\n"
930 $tooltip_t insert end "$summary\n"
931 if {$file ne $path} {
933 $tooltip_t insert end "In File: " section_header
934 $tooltip_t insert end "$file\n"
935 }
936 $tooltip_t insert end "\n"
938 $tooltip_t insert end "Copied Or Moved Here By:\n" section_header
939 $tooltip_t insert end $save
940 }
941 $tooltip_t conf -state disabled
943 _position_tooltip $this
944}
945method _position_tooltip {} {
947 set max_h [lindex [split [$tooltip_t index end] .] 0]
948 set max_w 0
949 for {set i 1} {$i <= $max_h} {incr i} {
950 set c [lindex [split [$tooltip_t index "$i.0 lineend"] .] 1]
951 if {$c > $max_w} {set max_w $c}
952 }
953 $tooltip_t conf -width $max_w -height $max_h
954 set req_w [winfo reqwidth $tooltip_t]
956 set req_h [winfo reqheight $tooltip_t]
957 set pos_x [expr {[winfo pointerx .] + 5}]
958 set pos_y [expr {[winfo pointery .] + 10}]
959 set g "${req_w}x${req_h}"
961 if {$pos_x >= 0} {append g +}
962 append g $pos_x
963 if {$pos_y >= 0} {append g +}
964 append g $pos_y
965 wm geometry $tooltip_wm $g
967 raise $tooltip_wm
968}
969method _hide_tooltip {} {
971 if {$tooltip_wm ne {}} {
972 destroy $tooltip_wm
973 set tooltip_wm {}
974 set tooltip_commit {}
975 }
976 if {$tooltip_timer ne {}} {
977 after cancel $tooltip_timer
978 set tooltip_timer {}
979 }
980}
981method _resize {new_height} {
983 set diff [expr {$new_height - $old_height}]
984 if {$diff == 0} return
985 set my [expr {[winfo height $w.file_pane] - 25}]
987 set o [$w.file_pane sash coord 0]
988 set ox [lindex $o 0]
989 set oy [expr {[lindex $o 1] + $diff}]
990 if {$oy < 0} {set oy 0}
991 if {$oy > $my} {set oy $my}
992 $w.file_pane sash place 0 $ox $oy
993 set old_height $new_height
995}
996}