Andrew's git - gitweb.git/blob

   1#!/usr/bin/perl
   2# Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3# License: GPL v2 or later
   4use 5.008;
   5use warnings;
   6use strict;
   7use vars qw/    $AUTHOR $VERSION
   8                $sha1 $sha1_short $_revision $_repository
   9                $_q $_authors $_authors_prog %users/;
  10$AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11$VERSION = '@@GIT_VERSION@@';
  12
  13use Carp qw/croak/;
  14use Digest::MD5;
  15use IO::File qw//;
  16use File::Basename qw/dirname basename/;
  17use File::Path qw/mkpath/;
  18use File::Spec;
  19use File::Find;
  20use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  21use IPC::Open3;
  22use Memoize;
  23
  24use Git::SVN;
  25use Git::SVN::Editor;
  26use Git::SVN::Fetcher;
  27use Git::SVN::Ra;
  28use Git::SVN::Prompt;
  29use Git::SVN::Log;
  30use Git::SVN::Migration;
  31
  32use Git::SVN::Utils qw(
  33        fatal
  34        can_compress
  35        canonicalize_path
  36        canonicalize_url
  37        join_paths
  38        add_path_to_url
  39        join_paths
  40);
  41
  42use Git qw(
  43        git_cmd_try
  44        command
  45        command_oneline
  46        command_noisy
  47        command_output_pipe
  48        command_close_pipe
  49        command_bidi_pipe
  50        command_close_bidi_pipe
  51);
  52
  53BEGIN {
  54        Memoize::memoize 'Git::config';
  55        Memoize::memoize 'Git::config_bool';
  56}
  57
  58
  59# From which subdir have we been invoked?
  60my $cmd_dir_prefix = eval {
  61        command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  62} || '';
  63
  64my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  65$ENV{GIT_DIR} ||= '.git';
  66$Git::SVN::Ra::_log_window_size = 100;
  67
  68if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  69        $ENV{SVN_SSH} = $ENV{GIT_SSH};
  70}
  71
  72if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  73        $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  74        $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  75}
  76
  77$Git::SVN::Log::TZ = $ENV{TZ};
  78$ENV{TZ} = 'UTC';
  79$| = 1; # unbuffer STDOUT
  80
  81# All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  82# repository decides to close the connection which we expect to be kept alive.
  83$SIG{PIPE} = 'IGNORE';
  84
  85# Given a dot separated version number, "subtract" it from
  86# the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  87# is at least at the version the caller asked for.
  88sub compare_svn_version {
  89        my (@ours) = split(/\./, $SVN::Core::VERSION);
  90        my (@theirs) = split(/\./, $_[0]);
  91        my ($i, $diff);
  92
  93        for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  94                $diff = $ours[$i] - $theirs[$i];
  95                return $diff if ($diff);
  96        }
  97        return 1 if ($i < @ours);
  98        return -1 if ($i < @theirs);
  99        return 0;
 100}
 101
 102sub _req_svn {
 103        require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
 104        require SVN::Ra;
 105        require SVN::Delta;
 106        if (::compare_svn_version('1.1.0') < 0) {
 107                fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 108        }
 109}
 110
 111$sha1 = qr/[a-f\d]{40}/;
 112$sha1_short = qr/[a-f\d]{4,40}/;
 113my ($_stdin, $_help, $_edit,
 114        $_message, $_file, $_branch_dest,
 115        $_template, $_shared,
 116        $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 117        $_before, $_after,
 118        $_merge, $_strategy, $_preserve_merges, $_dry_run, $_local,
 119        $_prefix, $_no_checkout, $_url, $_verbose,
 120        $_commit_url, $_tag, $_merge_info, $_interactive);
 121
 122# This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 123sub opt_prefix { return $_prefix || '' }
 124
 125$Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 126$_q ||= 0;
 127my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 128                    'config-dir=s' => \$Git::SVN::Ra::config_dir,
 129                    'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 130                    'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 131                    'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 132my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 133                'authors-file|A=s' => \$_authors,
 134                'authors-prog=s' => \$_authors_prog,
 135                'repack:i' => \$Git::SVN::_repack,
 136                'noMetadata' => \$Git::SVN::_no_metadata,
 137                'useSvmProps' => \$Git::SVN::_use_svm_props,
 138                'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 139                'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 140                'no-checkout' => \$_no_checkout,
 141                'quiet|q+' => \$_q,
 142                'repack-flags|repack-args|repack-opts=s' =>
 143                   \$Git::SVN::_repack_flags,
 144                'use-log-author' => \$Git::SVN::_use_log_author,
 145                'add-author-from' => \$Git::SVN::_add_author_from,
 146                'localtime' => \$Git::SVN::_localtime,
 147                %remote_opts );
 148
 149my ($_trunk, @_tags, @_branches, $_stdlayout);
 150my %icv;
 151my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 152                  'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 153                  'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 154                  'stdlayout|s' => \$_stdlayout,
 155                  'minimize-url|m!' => \$Git::SVN::_minimize_url,
 156                  'no-metadata' => sub { $icv{noMetadata} = 1 },
 157                  'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 158                  'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 159                  'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 160                  'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 161                  %remote_opts );
 162my %cmt_opts = ( 'edit|e' => \$_edit,
 163                'rmdir' => \$Git::SVN::Editor::_rmdir,
 164                'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 165                'l=i' => \$Git::SVN::Editor::_rename_limit,
 166                'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 167);
 168
 169my %cmd = (
 170        fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 171                        { 'revision|r=s' => \$_revision,
 172                          'fetch-all|all' => \$_fetch_all,
 173                          'parent|p' => \$_fetch_parent,
 174                           %fc_opts } ],
 175        clone => [ \&cmd_clone, "Initialize and fetch revisions",
 176                        { 'revision|r=s' => \$_revision,
 177                          'preserve-empty-dirs' =>
 178                                \$Git::SVN::Fetcher::_preserve_empty_dirs,
 179                          'placeholder-filename=s' =>
 180                                \$Git::SVN::Fetcher::_placeholder_filename,
 181                           %fc_opts, %init_opts } ],
 182        init => [ \&cmd_init, "Initialize a repo for tracking" .
 183                          " (requires URL argument)",
 184                          \%init_opts ],
 185        'multi-init' => [ \&cmd_multi_init,
 186                          "Deprecated alias for ".
 187                          "'$0 init -T<trunk> -b<branches> -t<tags>'",
 188                          \%init_opts ],
 189        dcommit => [ \&cmd_dcommit,
 190                     'Commit several diffs to merge with upstream',
 191                        { 'merge|m|M' => \$_merge,
 192                          'strategy|s=s' => \$_strategy,
 193                          'verbose|v' => \$_verbose,
 194                          'dry-run|n' => \$_dry_run,
 195                          'fetch-all|all' => \$_fetch_all,
 196                          'commit-url=s' => \$_commit_url,
 197                          'revision|r=i' => \$_revision,
 198                          'no-rebase' => \$_no_rebase,
 199                          'mergeinfo=s' => \$_merge_info,
 200                          'interactive|i' => \$_interactive,
 201                        %cmt_opts, %fc_opts } ],
 202        branch => [ \&cmd_branch,
 203                    'Create a branch in the SVN repository',
 204                    { 'message|m=s' => \$_message,
 205                      'destination|d=s' => \$_branch_dest,
 206                      'dry-run|n' => \$_dry_run,
 207                      'tag|t' => \$_tag,
 208                      'username=s' => \$Git::SVN::Prompt::_username,
 209                      'commit-url=s' => \$_commit_url } ],
 210        tag => [ sub { $_tag = 1; cmd_branch(@_) },
 211                 'Create a tag in the SVN repository',
 212                 { 'message|m=s' => \$_message,
 213                   'destination|d=s' => \$_branch_dest,
 214                   'dry-run|n' => \$_dry_run,
 215                   'username=s' => \$Git::SVN::Prompt::_username,
 216                   'commit-url=s' => \$_commit_url } ],
 217        'set-tree' => [ \&cmd_set_tree,
 218                        "Set an SVN repository to a git tree-ish",
 219                        { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 220        'create-ignore' => [ \&cmd_create_ignore,
 221                             'Create a .gitignore per svn:ignore',
 222                             { 'revision|r=i' => \$_revision
 223                             } ],
 224        'mkdirs' => [ \&cmd_mkdirs ,
 225                      "recreate empty directories after a checkout",
 226                      { 'revision|r=i' => \$_revision } ],
 227        'propget' => [ \&cmd_propget,
 228                       'Print the value of a property on a file or directory',
 229                       { 'revision|r=i' => \$_revision } ],
 230        'proplist' => [ \&cmd_proplist,
 231                       'List all properties of a file or directory',
 232                       { 'revision|r=i' => \$_revision } ],
 233        'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 234                        { 'revision|r=i' => \$_revision
 235                        } ],
 236        'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 237                        { 'revision|r=i' => \$_revision
 238                        } ],
 239        'multi-fetch' => [ \&cmd_multi_fetch,
 240                           "Deprecated alias for $0 fetch --all",
 241                           { 'revision|r=s' => \$_revision, %fc_opts } ],
 242        'migrate' => [ sub { },
 243                       # no-op, we automatically run this anyways,
 244                       'Migrate configuration/metadata/layout from
 245                        previous versions of git-svn',
 246                       { 'minimize' => \$Git::SVN::Migration::_minimize,
 247                         %remote_opts } ],
 248        'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 249                        { 'limit=i' => \$Git::SVN::Log::limit,
 250                          'revision|r=s' => \$_revision,
 251                          'verbose|v' => \$Git::SVN::Log::verbose,
 252                          'incremental' => \$Git::SVN::Log::incremental,
 253                          'oneline' => \$Git::SVN::Log::oneline,
 254                          'show-commit' => \$Git::SVN::Log::show_commit,
 255                          'non-recursive' => \$Git::SVN::Log::non_recursive,
 256                          'authors-file|A=s' => \$_authors,
 257                          'color' => \$Git::SVN::Log::color,
 258                          'pager=s' => \$Git::SVN::Log::pager
 259                        } ],
 260        'find-rev' => [ \&cmd_find_rev,
 261                        "Translate between SVN revision numbers and tree-ish",
 262                        { 'before' => \$_before,
 263                          'after' => \$_after } ],
 264        'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 265                        { 'merge|m|M' => \$_merge,
 266                          'verbose|v' => \$_verbose,
 267                          'strategy|s=s' => \$_strategy,
 268                          'local|l' => \$_local,
 269                          'fetch-all|all' => \$_fetch_all,
 270                          'dry-run|n' => \$_dry_run,
 271                          'preserve-merges|p' => \$_preserve_merges,
 272                          %fc_opts } ],
 273        'commit-diff' => [ \&cmd_commit_diff,
 274                           'Commit a diff between two trees',
 275                        { 'message|m=s' => \$_message,
 276                          'file|F=s' => \$_file,
 277                          'revision|r=s' => \$_revision,
 278                        %cmt_opts } ],
 279        'info' => [ \&cmd_info,
 280                    "Show info about the latest SVN revision
 281                     on the current branch",
 282                    { 'url' => \$_url, } ],
 283        'blame' => [ \&Git::SVN::Log::cmd_blame,
 284                    "Show what revision and author last modified each line of a file",
 285                    { 'git-format' => \$Git::SVN::Log::_git_format } ],
 286        'reset' => [ \&cmd_reset,
 287                     "Undo fetches back to the specified SVN revision",
 288                     { 'revision|r=s' => \$_revision,
 289                       'parent|p' => \$_fetch_parent } ],
 290        'gc' => [ \&cmd_gc,
 291                  "Compress unhandled.log files in .git/svn and remove " .
 292                  "index files in .git/svn",
 293                {} ],
 294);
 295
 296use Term::ReadLine;
 297package FakeTerm;
 298sub new {
 299        my ($class, $reason) = @_;
 300        return bless \$reason, shift;
 301}
 302sub readline {
 303        my $self = shift;
 304        die "Cannot use readline on FakeTerm: $$self";
 305}
 306package main;
 307
 308my $term = eval {
 309        $ENV{"GIT_SVN_NOTTY"}
 310                ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 311                : new Term::ReadLine 'git-svn';
 312};
 313if ($@) {
 314        $term = new FakeTerm "$@: going non-interactive";
 315}
 316
 317my $cmd;
 318for (my $i = 0; $i < @ARGV; $i++) {
 319        if (defined $cmd{$ARGV[$i]}) {
 320                $cmd = $ARGV[$i];
 321                splice @ARGV, $i, 1;
 322                last;
 323        } elsif ($ARGV[$i] eq 'help') {
 324                $cmd = $ARGV[$i+1];
 325                usage(0);
 326        }
 327};
 328
 329# make sure we're always running at the top-level working directory
 330unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 331        unless (-d $ENV{GIT_DIR}) {
 332                if ($git_dir_user_set) {
 333                        die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 334                            "but it is not a directory\n";
 335                }
 336                my $git_dir = delete $ENV{GIT_DIR};
 337                my $cdup = undef;
 338                git_cmd_try {
 339                        $cdup = command_oneline(qw/rev-parse --show-cdup/);
 340                        $git_dir = '.' unless ($cdup);
 341                        chomp $cdup if ($cdup);
 342                        $cdup = "." unless ($cdup && length $cdup);
 343                } "Already at toplevel, but $git_dir not found\n";
 344                chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 345                unless (-d $git_dir) {
 346                        die "$git_dir still not found after going to ",
 347                            "'$cdup'\n";
 348                }
 349                $ENV{GIT_DIR} = $git_dir;
 350        }
 351        $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 352}
 353
 354my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 355
 356read_git_config(\%opts);
 357if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 358        Getopt::Long::Configure('pass_through');
 359}
 360my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 361                    'minimize-connections' => \$Git::SVN::Migration::_minimize,
 362                    'id|i=s' => \$Git::SVN::default_ref_id,
 363                    'svn-remote|remote|R=s' => sub {
 364                       $Git::SVN::no_reuse_existing = 1;
 365                       $Git::SVN::default_repo_id = $_[1] });
 366exit 1 if (!$rv && $cmd && $cmd ne 'log');
 367
 368usage(0) if $_help;
 369version() if $_version;
 370usage(1) unless defined $cmd;
 371load_authors() if $_authors;
 372if (defined $_authors_prog) {
 373        $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 374}
 375
 376unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 377        Git::SVN::Migration::migration_check();
 378}
 379Git::SVN::init_vars();
 380eval {
 381        Git::SVN::verify_remotes_sanity();
 382        $cmd{$cmd}->[0]->(@ARGV);
 383        post_fetch_checkout();
 384};
 385fatal $@ if $@;
 386exit 0;
 387
 388####################### primary functions ######################
 389sub usage {
 390        my $exit = shift || 0;
 391        my $fd = $exit ? \*STDERR : \*STDOUT;
 392        print $fd <<"";
 393git-svn - bidirectional operations between a single Subversion tree and git
 394Usage: git svn <command> [options] [arguments]\n
 395
 396        print $fd "Available commands:\n" unless $cmd;
 397
 398        foreach (sort keys %cmd) {
 399                next if $cmd && $cmd ne $_;
 400                next if /^multi-/; # don't show deprecated commands
 401                print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 402                foreach (sort keys %{$cmd{$_}->[2]}) {
 403                        # mixed-case options are for .git/config only
 404                        next if /[A-Z]/ && /^[a-z]+$/i;
 405                        # prints out arguments as they should be passed:
 406                        my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 407                        print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 408                                                        "--$_" : "-$_" }
 409                                                split /\|/,$_)," $x\n";
 410                }
 411        }
 412        print $fd <<"";
 413\nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 414arbitrary identifier if you're tracking multiple SVN branches/repositories in
 415one git repository and want to keep them separate.  See git-svn(1) for more
 416information.
 417
 418        exit $exit;
 419}
 420
 421sub version {
 422        ::_req_svn();
 423        print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 424        exit 0;
 425}
 426
 427sub ask {
 428        my ($prompt, %arg) = @_;
 429        my $valid_re = $arg{valid_re};
 430        my $default = $arg{default};
 431        my $resp;
 432        my $i = 0;
 433
 434        if ( !( defined($term->IN)
 435            && defined( fileno($term->IN) )
 436            && defined( $term->OUT )
 437            && defined( fileno($term->OUT) ) ) ){
 438                return defined($default) ? $default : undef;
 439        }
 440
 441        while ($i++ < 10) {
 442                $resp = $term->readline($prompt);
 443                if (!defined $resp) { # EOF
 444                        print "\n";
 445                        return defined $default ? $default : undef;
 446                }
 447                if ($resp eq '' and defined $default) {
 448                        return $default;
 449                }
 450                if (!defined $valid_re or $resp =~ /$valid_re/) {
 451                        return $resp;
 452                }
 453        }
 454        return undef;
 455}
 456
 457sub do_git_init_db {
 458        unless (-d $ENV{GIT_DIR}) {
 459                my @init_db = ('init');
 460                push @init_db, "--template=$_template" if defined $_template;
 461                if (defined $_shared) {
 462                        if ($_shared =~ /[a-z]/) {
 463                                push @init_db, "--shared=$_shared";
 464                        } else {
 465                                push @init_db, "--shared";
 466                        }
 467                }
 468                command_noisy(@init_db);
 469                $_repository = Git->repository(Repository => ".git");
 470        }
 471        my $set;
 472        my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 473        foreach my $i (keys %icv) {
 474                die "'$set' and '$i' cannot both be set\n" if $set;
 475                next unless defined $icv{$i};
 476                command_noisy('config', "$pfx.$i", $icv{$i});
 477                $set = $i;
 478        }
 479        my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 480        command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 481                if defined $$ignore_paths_regex;
 482        my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 483        command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 484                if defined $$ignore_refs_regex;
 485
 486        if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 487                my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 488                command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 489                command_noisy('config', "$pfx.placeholder-filename", $$fname);
 490        }
 491}
 492
 493sub init_subdir {
 494        my $repo_path = shift or return;
 495        mkpath([$repo_path]) unless -d $repo_path;
 496        chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 497        $ENV{GIT_DIR} = '.git';
 498        $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 499}
 500
 501sub cmd_clone {
 502        my ($url, $path) = @_;
 503        if (!defined $path &&
 504            (defined $_trunk || @_branches || @_tags ||
 505             defined $_stdlayout) &&
 506            $url !~ m#^[a-z\+]+://#) {
 507                $path = $url;
 508        }
 509        $path = basename($url) if !defined $path || !length $path;
 510        my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 511        cmd_init($url, $path);
 512        command_oneline('config', 'svn.authorsfile', $authors_absolute)
 513            if $_authors;
 514        Git::SVN::fetch_all($Git::SVN::default_repo_id);
 515}
 516
 517sub cmd_init {
 518        if (defined $_stdlayout) {
 519                $_trunk = 'trunk' if (!defined $_trunk);
 520                @_tags = 'tags' if (! @_tags);
 521                @_branches = 'branches' if (! @_branches);
 522        }
 523        if (defined $_trunk || @_branches || @_tags) {
 524                return cmd_multi_init(@_);
 525        }
 526        my $url = shift or die "SVN repository location required ",
 527                               "as a command-line argument\n";
 528        $url = canonicalize_url($url);
 529        init_subdir(@_);
 530        do_git_init_db();
 531
 532        if ($Git::SVN::_minimize_url eq 'unset') {
 533                $Git::SVN::_minimize_url = 0;
 534        }
 535
 536        Git::SVN->init($url);
 537}
 538
 539sub cmd_fetch {
 540        if (grep /^\d+=./, @_) {
 541                die "'<rev>=<commit>' fetch arguments are ",
 542                    "no longer supported.\n";
 543        }
 544        my ($remote) = @_;
 545        if (@_ > 1) {
 546                die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 547        }
 548        $Git::SVN::no_reuse_existing = undef;
 549        if ($_fetch_parent) {
 550                my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 551                unless ($gs) {
 552                        die "Unable to determine upstream SVN information from ",
 553                            "working tree history\n";
 554                }
 555                # just fetch, don't checkout.
 556                $_no_checkout = 'true';
 557                $_fetch_all ? $gs->fetch_all : $gs->fetch;
 558        } elsif ($_fetch_all) {
 559                cmd_multi_fetch();
 560        } else {
 561                $remote ||= $Git::SVN::default_repo_id;
 562                Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 563        }
 564}
 565
 566sub cmd_set_tree {
 567        my (@commits) = @_;
 568        if ($_stdin || !@commits) {
 569                print "Reading from stdin...\n";
 570                @commits = ();
 571                while (<STDIN>) {
 572                        if (/\b($sha1_short)\b/o) {
 573                                unshift @commits, $1;
 574                        }
 575                }
 576        }
 577        my @revs;
 578        foreach my $c (@commits) {
 579                my @tmp = command('rev-parse',$c);
 580                if (scalar @tmp == 1) {
 581                        push @revs, $tmp[0];
 582                } elsif (scalar @tmp > 1) {
 583                        push @revs, reverse(command('rev-list',@tmp));
 584                } else {
 585                        fatal "Failed to rev-parse $c";
 586                }
 587        }
 588        my $gs = Git::SVN->new;
 589        my ($r_last, $cmt_last) = $gs->last_rev_commit;
 590        $gs->fetch;
 591        if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 592                fatal "There are new revisions that were fetched ",
 593                      "and need to be merged (or acknowledged) ",
 594                      "before committing.\nlast rev: $r_last\n",
 595                      " current: $gs->{last_rev}";
 596        }
 597        $gs->set_tree($_) foreach @revs;
 598        print "Done committing ",scalar @revs," revisions to SVN\n";
 599        unlink $gs->{index};
 600}
 601
 602sub split_merge_info_range {
 603        my ($range) = @_;
 604        if ($range =~ /(\d+)-(\d+)/) {
 605                return (int($1), int($2));
 606        } else {
 607                return (int($range), int($range));
 608        }
 609}
 610
 611sub combine_ranges {
 612        my ($in) = @_;
 613
 614        my @fnums = ();
 615        my @arr = split(/,/, $in);
 616        for my $element (@arr) {
 617                my ($start, $end) = split_merge_info_range($element);
 618                push @fnums, $start;
 619        }
 620
 621        my @sorted = @arr [ sort {
 622                $fnums[$a] <=> $fnums[$b]
 623        } 0..$#arr ];
 624
 625        my @return = ();
 626        my $last = -1;
 627        my $first = -1;
 628        for my $element (@sorted) {
 629                my ($start, $end) = split_merge_info_range($element);
 630
 631                if ($last == -1) {
 632                        $first = $start;
 633                        $last = $end;
 634                        next;
 635                }
 636                if ($start <= $last+1) {
 637                        if ($end > $last) {
 638                                $last = $end;
 639                        }
 640                        next;
 641                }
 642                if ($first == $last) {
 643                        push @return, "$first";
 644                } else {
 645                        push @return, "$first-$last";
 646                }
 647                $first = $start;
 648                $last = $end;
 649        }
 650
 651        if ($first != -1) {
 652                if ($first == $last) {
 653                        push @return, "$first";
 654                } else {
 655                        push @return, "$first-$last";
 656                }
 657        }
 658
 659        return join(',', @return);
 660}
 661
 662sub merge_revs_into_hash {
 663        my ($hash, $minfo) = @_;
 664        my @lines = split(' ', $minfo);
 665
 666        for my $line (@lines) {
 667                my ($branchpath, $revs) = split(/:/, $line);
 668
 669                if (exists($hash->{$branchpath})) {
 670                        # Merge the two revision sets
 671                        my $combined = "$hash->{$branchpath},$revs";
 672                        $hash->{$branchpath} = combine_ranges($combined);
 673                } else {
 674                        # Just do range combining for consolidation
 675                        $hash->{$branchpath} = combine_ranges($revs);
 676                }
 677        }
 678}
 679
 680sub merge_merge_info {
 681        my ($mergeinfo_one, $mergeinfo_two) = @_;
 682        my %result_hash = ();
 683
 684        merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 685        merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 686
 687        my $result = '';
 688        # Sort below is for consistency's sake
 689        for my $branchname (sort keys(%result_hash)) {
 690                my $revlist = $result_hash{$branchname};
 691                $result .= "$branchname:$revlist\n"
 692        }
 693        return $result;
 694}
 695
 696sub populate_merge_info {
 697        my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 698
 699        my %parentshash;
 700        read_commit_parents(\%parentshash, $d);
 701        my @parents = @{$parentshash{$d}};
 702        if ($#parents > 0) {
 703                # Merge commit
 704                my $all_parents_ok = 1;
 705                my $aggregate_mergeinfo = '';
 706                my $rooturl = $gs->repos_root;
 707
 708                if (defined($rewritten_parent)) {
 709                        # Replace first parent with newly-rewritten version
 710                        shift @parents;
 711                        unshift @parents, $rewritten_parent;
 712                }
 713
 714                foreach my $parent (@parents) {
 715                        my ($branchurl, $svnrev, $paruuid) =
 716                                cmt_metadata($parent);
 717
 718                        unless (defined($svnrev)) {
 719                                # Should have been caught be preflight check
 720                                fatal "merge commit $d has ancestor $parent, but that change "
 721                     ."does not have git-svn metadata!";
 722                        }
 723                        unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 724                                fatal "commit $parent git-svn metadata changed mid-run!";
 725                        }
 726                        my $branchpath = $1;
 727
 728                        my $ra = Git::SVN::Ra->new($branchurl);
 729                        my (undef, undef, $props) =
 730                                $ra->get_dir(canonicalize_path("."), $svnrev);
 731                        my $par_mergeinfo = $props->{'svn:mergeinfo'};
 732                        unless (defined $par_mergeinfo) {
 733                                $par_mergeinfo = '';
 734                        }
 735                        # Merge previous mergeinfo values
 736                        $aggregate_mergeinfo =
 737                                merge_merge_info($aggregate_mergeinfo,
 738                                                                 $par_mergeinfo, 0);
 739
 740                        next if $parent eq $parents[0]; # Skip first parent
 741                        # Add new changes being placed in tree by merge
 742                        my @cmd = (qw/rev-list --reverse/,
 743                                           $parent, qw/--not/);
 744                        foreach my $par (@parents) {
 745                                unless ($par eq $parent) {
 746                                        push @cmd, $par;
 747                                }
 748                        }
 749                        my @revsin = ();
 750                        my ($revlist, $ctx) = command_output_pipe(@cmd);
 751                        while (<$revlist>) {
 752                                my $irev = $_;
 753                                chomp $irev;
 754                                my (undef, $csvnrev, undef) =
 755                                        cmt_metadata($irev);
 756                                unless (defined $csvnrev) {
 757                                        # A child is missing SVN annotations...
 758                                        # this might be OK, or might not be.
 759                                        warn "W:child $irev is merged into revision "
 760                                                 ."$d but does not have git-svn metadata. "
 761                                                 ."This means git-svn cannot determine the "
 762                                                 ."svn revision numbers to place into the "
 763                                                 ."svn:mergeinfo property. You must ensure "
 764                                                 ."a branch is entirely committed to "
 765                                                 ."SVN before merging it in order for "
 766                                                 ."svn:mergeinfo population to function "
 767                                                 ."properly";
 768                                }
 769                                push @revsin, $csvnrev;
 770                        }
 771                        command_close_pipe($revlist, $ctx);
 772
 773                        last unless $all_parents_ok;
 774
 775                        # We now have a list of all SVN revnos which are
 776                        # merged by this particular parent. Integrate them.
 777                        next if $#revsin == -1;
 778                        my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 779                        $aggregate_mergeinfo =
 780                                merge_merge_info($aggregate_mergeinfo,
 781                                                                 $newmergeinfo, 1);
 782                }
 783                if ($all_parents_ok and $aggregate_mergeinfo) {
 784                        return $aggregate_mergeinfo;
 785                }
 786        }
 787
 788        return undef;
 789}
 790
 791sub dcommit_rebase {
 792        my ($is_last, $current, $fetched_ref, $svn_error) = @_;
 793        my @diff;
 794
 795        if ($svn_error) {
 796                print STDERR "\nERROR from SVN:\n",
 797                                $svn_error->expanded_message, "\n";
 798        }
 799        unless ($_no_rebase) {
 800                # we always want to rebase against the current HEAD,
 801                # not any head that was passed to us
 802                @diff = command('diff-tree', $current,
 803                           $fetched_ref, '--');
 804                my @finish;
 805                if (@diff) {
 806                        @finish = rebase_cmd();
 807                        print STDERR "W: $current and ", $fetched_ref,
 808                                     " differ, using @finish:\n",
 809                                     join("\n", @diff), "\n";
 810                } elsif ($is_last) {
 811                        print "No changes between ", $current, " and ",
 812                              $fetched_ref,
 813                              "\nResetting to the latest ",
 814                              $fetched_ref, "\n";
 815                        @finish = qw/reset --mixed/;
 816                }
 817                command_noisy(@finish, $fetched_ref) if @finish;
 818        }
 819        if ($svn_error) {
 820                die "ERROR: Not all changes have been committed into SVN"
 821                        .($_no_rebase ? ".\n" : ", however the committed\n"
 822                        ."ones (if any) seem to be successfully integrated "
 823                        ."into the working tree.\n")
 824                        ."Please see the above messages for details.\n";
 825        }
 826        return @diff;
 827}
 828
 829sub cmd_dcommit {
 830        my $head = shift;
 831        command_noisy(qw/update-index --refresh/);
 832        git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 833                'Cannot dcommit with a dirty index.  Commit your changes first, '
 834                . "or stash them with `git stash'.\n";
 835        $head ||= 'HEAD';
 836
 837        my $old_head;
 838        if ($head ne 'HEAD') {
 839                $old_head = eval {
 840                        command_oneline([qw/symbolic-ref -q HEAD/])
 841                };
 842                if ($old_head) {
 843                        $old_head =~ s{^refs/heads/}{};
 844                } else {
 845                        $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 846                }
 847                command(['checkout', $head], STDERR => 0);
 848        }
 849
 850        my @refs;
 851        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 852        unless ($gs) {
 853                die "Unable to determine upstream SVN information from ",
 854                    "$head history.\nPerhaps the repository is empty.";
 855        }
 856
 857        if (defined $_commit_url) {
 858                $url = $_commit_url;
 859        } else {
 860                $url = eval { command_oneline('config', '--get',
 861                              "svn-remote.$gs->{repo_id}.commiturl") };
 862                if (!$url) {
 863                        $url = $gs->full_pushurl
 864                }
 865        }
 866
 867        my $last_rev = $_revision if defined $_revision;
 868        if ($url) {
 869                print "Committing to $url ...\n";
 870        }
 871        my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 872        if ($_no_rebase && scalar(@$linear_refs) > 1) {
 873                warn "Attempting to commit more than one change while ",
 874                     "--no-rebase is enabled.\n",
 875                     "If these changes depend on each other, re-running ",
 876                     "without --no-rebase may be required."
 877        }
 878
 879        if (defined $_interactive){
 880                my $ask_default = "y";
 881                foreach my $d (@$linear_refs){
 882                        my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 883                        while (<$fh>){
 884                                print $_;
 885                        }
 886                        command_close_pipe($fh, $ctx);
 887                        $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 888                                 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 889                                 default => $ask_default);
 890                        die "Commit this patch reply required" unless defined $_;
 891                        if (/^[nq]/i) {
 892                                exit(0);
 893                        } elsif (/^a/i) {
 894                                last;
 895                        }
 896                }
 897        }
 898
 899        my $expect_url = $url;
 900
 901        my $push_merge_info = eval {
 902                command_oneline(qw/config --get svn.pushmergeinfo/)
 903                };
 904        if (not defined($push_merge_info)
 905                        or $push_merge_info eq "false"
 906                        or $push_merge_info eq "no"
 907                        or $push_merge_info eq "never") {
 908                $push_merge_info = 0;
 909        }
 910
 911        unless (defined($_merge_info) || ! $push_merge_info) {
 912                # Preflight check of changes to ensure no issues with mergeinfo
 913                # This includes check for uncommitted-to-SVN parents
 914                # (other than the first parent, which we will handle),
 915                # information from different SVN repos, and paths
 916                # which are not underneath this repository root.
 917                my $rooturl = $gs->repos_root;
 918                foreach my $d (@$linear_refs) {
 919                        my %parentshash;
 920                        read_commit_parents(\%parentshash, $d);
 921                        my @realparents = @{$parentshash{$d}};
 922                        if ($#realparents > 0) {
 923                                # Merge commit
 924                                shift @realparents; # Remove/ignore first parent
 925                                foreach my $parent (@realparents) {
 926                                        my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 927                                        unless (defined $paruuid) {
 928                                                # A parent is missing SVN annotations...
 929                                                # abort the whole operation.
 930                                                fatal "$parent is merged into revision $d, "
 931                                                         ."but does not have git-svn metadata. "
 932                                                         ."Either dcommit the branch or use a "
 933                                                         ."local cherry-pick, FF merge, or rebase "
 934                                                         ."instead of an explicit merge commit.";
 935                                        }
 936
 937                                        unless ($paruuid eq $uuid) {
 938                                                # Parent has SVN metadata from different repository
 939                                                fatal "merge parent $parent for change $d has "
 940                                                         ."git-svn uuid $paruuid, while current change "
 941                                                         ."has uuid $uuid!";
 942                                        }
 943
 944                                        unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 945                                                # This branch is very strange indeed.
 946                                                fatal "merge parent $parent for $d is on branch "
 947                                                         ."$branchurl, which is not under the "
 948                                                         ."git-svn root $rooturl!";
 949                                        }
 950                                }
 951                        }
 952                }
 953        }
 954
 955        my $rewritten_parent;
 956        my $current_head = command_oneline(qw/rev-parse HEAD/);
 957        Git::SVN::remove_username($expect_url);
 958        if (defined($_merge_info)) {
 959                $_merge_info =~ tr{ }{\n};
 960        }
 961        while (1) {
 962                my $d = shift @$linear_refs or last;
 963                unless (defined $last_rev) {
 964                        (undef, $last_rev, undef) = cmt_metadata("$d~1");
 965                        unless (defined $last_rev) {
 966                                fatal "Unable to extract revision information ",
 967                                      "from commit $d~1";
 968                        }
 969                }
 970                if ($_dry_run) {
 971                        print "diff-tree $d~1 $d\n";
 972                } else {
 973                        my $cmt_rev;
 974
 975                        unless (defined($_merge_info) || ! $push_merge_info) {
 976                                $_merge_info = populate_merge_info($d, $gs,
 977                                                             $uuid,
 978                                                             $linear_refs,
 979                                                             $rewritten_parent);
 980                        }
 981
 982                        my %ed_opts = ( r => $last_rev,
 983                                        log => get_commit_entry($d)->{log},
 984                                        ra => Git::SVN::Ra->new($url),
 985                                        config => SVN::Core::config_get_config(
 986                                                $Git::SVN::Ra::config_dir
 987                                        ),
 988                                        tree_a => "$d~1",
 989                                        tree_b => $d,
 990                                        editor_cb => sub {
 991                                               print "Committed r$_[0]\n";
 992                                               $cmt_rev = $_[0];
 993                                        },
 994                                        mergeinfo => $_merge_info,
 995                                        svn_path => '');
 996
 997                        my $err_handler = $SVN::Error::handler;
 998                        $SVN::Error::handler = sub {
 999                                my $err = shift;
1000                                dcommit_rebase(1, $current_head, $gs->refname,
1001                                        $err);
1002                        };
1003
1004                        if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1005                                print "No changes\n$d~1 == $d\n";
1006                        } elsif ($parents->{$d} && @{$parents->{$d}}) {
1007                                $gs->{inject_parents_dcommit}->{$cmt_rev} =
1008                                                               $parents->{$d};
1009                        }
1010                        $_fetch_all ? $gs->fetch_all : $gs->fetch;
1011                        $SVN::Error::handler = $err_handler;
1012                        $last_rev = $cmt_rev;
1013                        next if $_no_rebase;
1014
1015                        my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1016                                                $gs->refname, undef);
1017
1018                        $rewritten_parent = command_oneline(qw/rev-parse/,
1019                                                        $gs->refname);
1020
1021                        if (@diff) {
1022                                $current_head = command_oneline(qw/rev-parse
1023                                                                HEAD/);
1024                                @refs = ();
1025                                my ($url_, $rev_, $uuid_, $gs_) =
1026                                              working_head_info('HEAD', \@refs);
1027                                my ($linear_refs_, $parents_) =
1028                                              linearize_history($gs_, \@refs);
1029                                if (scalar(@$linear_refs) !=
1030                                    scalar(@$linear_refs_)) {
1031                                        fatal "# of revisions changed ",
1032                                          "\nbefore:\n",
1033                                          join("\n", @$linear_refs),
1034                                          "\n\nafter:\n",
1035                                          join("\n", @$linear_refs_), "\n",
1036                                          'If you are attempting to commit ',
1037                                          "merges, try running:\n\t",
1038                                          'git rebase --interactive',
1039                                          '--preserve-merges ',
1040                                          $gs->refname,
1041                                          "\nBefore dcommitting";
1042                                }
1043                                if ($url_ ne $expect_url) {
1044                                        if ($url_ eq $gs->metadata_url) {
1045                                                print
1046                                                  "Accepting rewritten URL:",
1047                                                  " $url_\n";
1048                                        } else {
1049                                                fatal
1050                                                  "URL mismatch after rebase:",
1051                                                  " $url_ != $expect_url";
1052                                        }
1053                                }
1054                                if ($uuid_ ne $uuid) {
1055                                        fatal "uuid mismatch after rebase: ",
1056                                              "$uuid_ != $uuid";
1057                                }
1058                                # remap parents
1059                                my (%p, @l, $i);
1060                                for ($i = 0; $i < scalar @$linear_refs; $i++) {
1061                                        my $new = $linear_refs_->[$i] or next;
1062                                        $p{$new} =
1063                                                $parents->{$linear_refs->[$i]};
1064                                        push @l, $new;
1065                                }
1066                                $parents = \%p;
1067                                $linear_refs = \@l;
1068                                undef $last_rev;
1069                        }
1070                }
1071        }
1072
1073        if ($old_head) {
1074                my $new_head = command_oneline(qw/rev-parse HEAD/);
1075                my $new_is_symbolic = eval {
1076                        command_oneline(qw/symbolic-ref -q HEAD/);
1077                };
1078                if ($new_is_symbolic) {
1079                        print "dcommitted the branch ", $head, "\n";
1080                } else {
1081                        print "dcommitted on a detached HEAD because you gave ",
1082                              "a revision argument.\n",
1083                              "The rewritten commit is: ", $new_head, "\n";
1084                }
1085                command(['checkout', $old_head], STDERR => 0);
1086        }
1087
1088        unlink $gs->{index};
1089}
1090
1091sub cmd_branch {
1092        my ($branch_name, $head) = @_;
1093
1094        unless (defined $branch_name && length $branch_name) {
1095                die(($_tag ? "tag" : "branch") . " name required\n");
1096        }
1097        $head ||= 'HEAD';
1098
1099        my (undef, $rev, undef, $gs) = working_head_info($head);
1100        my $src = $gs->full_pushurl;
1101
1102        my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1103        my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1104        my $glob;
1105        if ($#{$allglobs} == 0) {
1106                $glob = $allglobs->[0];
1107        } else {
1108                unless(defined $_branch_dest) {
1109                        die "Multiple ",
1110                            $_tag ? "tag" : "branch",
1111                            " paths defined for Subversion repository.\n",
1112                            "You must specify where you want to create the ",
1113                            $_tag ? "tag" : "branch",
1114                            " with the --destination argument.\n";
1115                }
1116                foreach my $g (@{$allglobs}) {
1117                        my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1118                        if ($_branch_dest =~ /$re/) {
1119                                $glob = $g;
1120                                last;
1121                        }
1122                }
1123                unless (defined $glob) {
1124                        my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1125                        foreach my $g (@{$allglobs}) {
1126                                $g->{path}->{left} =~ /$dest_re/ or next;
1127                                if (defined $glob) {
1128                                        die "Ambiguous destination: ",
1129                                            $_branch_dest, "\nmatches both '",
1130                                            $glob->{path}->{left}, "' and '",
1131                                            $g->{path}->{left}, "'\n";
1132                                }
1133                                $glob = $g;
1134                        }
1135                        unless (defined $glob) {
1136                                die "Unknown ",
1137                                    $_tag ? "tag" : "branch",
1138                                    " destination $_branch_dest\n";
1139                        }
1140                }
1141        }
1142        my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1143        my $url;
1144        if (defined $_commit_url) {
1145                $url = $_commit_url;
1146        } else {
1147                $url = eval { command_oneline('config', '--get',
1148                        "svn-remote.$gs->{repo_id}.commiturl") };
1149                if (!$url) {
1150                        $url = $remote->{pushurl} || $remote->{url};
1151                }
1152        }
1153        my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1154
1155        if ($dst =~ /^https:/ && $src =~ /^http:/) {
1156                $src=~s/^http:/https:/;
1157        }
1158
1159        ::_req_svn();
1160
1161        my $ctx = SVN::Client->new(
1162                auth    => Git::SVN::Ra::_auth_providers(),
1163                log_msg => sub {
1164                        ${ $_[0] } = defined $_message
1165                                ? $_message
1166                                : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1167                                . $branch_name;
1168                },
1169        );
1170
1171        eval {
1172                $ctx->ls($dst, 'HEAD', 0);
1173        } and die "branch ${branch_name} already exists\n";
1174
1175        print "Copying ${src} at r${rev} to ${dst}...\n";
1176        $ctx->copy($src, $rev, $dst)
1177                unless $_dry_run;
1178
1179        $gs->fetch_all;
1180}
1181
1182sub cmd_find_rev {
1183        my $revision_or_hash = shift or die "SVN or git revision required ",
1184                                            "as a command-line argument\n";
1185        my $result;
1186        if ($revision_or_hash =~ /^r\d+$/) {
1187                my $head = shift;
1188                $head ||= 'HEAD';
1189                my @refs;
1190                my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1191                unless ($gs) {
1192                        die "Unable to determine upstream SVN information from ",
1193                            "$head history\n";
1194                }
1195                my $desired_revision = substr($revision_or_hash, 1);
1196                if ($_before) {
1197                        $result = $gs->find_rev_before($desired_revision, 1);
1198                } elsif ($_after) {
1199                        $result = $gs->find_rev_after($desired_revision, 1);
1200                } else {
1201                        $result = $gs->rev_map_get($desired_revision, $uuid);
1202                }
1203        } else {
1204                my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1205                $result = $rev;
1206        }
1207        print "$result\n" if $result;
1208}
1209
1210sub auto_create_empty_directories {
1211        my ($gs) = @_;
1212        my $var = eval { command_oneline('config', '--get', '--bool',
1213                                         "svn-remote.$gs->{repo_id}.automkdirs") };
1214        # By default, create empty directories by consulting the unhandled log,
1215        # but allow setting it to 'false' to skip it.
1216        return !($var && $var eq 'false');
1217}
1218
1219sub cmd_rebase {
1220        command_noisy(qw/update-index --refresh/);
1221        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1222        unless ($gs) {
1223                die "Unable to determine upstream SVN information from ",
1224                    "working tree history\n";
1225        }
1226        if ($_dry_run) {
1227                print "Remote Branch: " . $gs->refname . "\n";
1228                print "SVN URL: " . $url . "\n";
1229                return;
1230        }
1231        if (command(qw/diff-index HEAD --/)) {
1232                print STDERR "Cannot rebase with uncommited changes:\n";
1233                command_noisy('status');
1234                exit 1;
1235        }
1236        unless ($_local) {
1237                # rebase will checkout for us, so no need to do it explicitly
1238                $_no_checkout = 'true';
1239                $_fetch_all ? $gs->fetch_all : $gs->fetch;
1240        }
1241        command_noisy(rebase_cmd(), $gs->refname);
1242        if (auto_create_empty_directories($gs)) {
1243                $gs->mkemptydirs;
1244        }
1245}
1246
1247sub cmd_show_ignore {
1248        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1249        $gs ||= Git::SVN->new;
1250        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1251        $gs->prop_walk($gs->path, $r, sub {
1252                my ($gs, $path, $props) = @_;
1253                print STDOUT "\n# $path\n";
1254                my $s = $props->{'svn:ignore'} or return;
1255                $s =~ s/[\r\n]+/\n/g;
1256                $s =~ s/^\n+//;
1257                chomp $s;
1258                $s =~ s#^#$path#gm;
1259                print STDOUT "$s\n";
1260        });
1261}
1262
1263sub cmd_show_externals {
1264        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1265        $gs ||= Git::SVN->new;
1266        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1267        $gs->prop_walk($gs->path, $r, sub {
1268                my ($gs, $path, $props) = @_;
1269                print STDOUT "\n# $path\n";
1270                my $s = $props->{'svn:externals'} or return;
1271                $s =~ s/[\r\n]+/\n/g;
1272                chomp $s;
1273                $s =~ s#^#$path#gm;
1274                print STDOUT "$s\n";
1275        });
1276}
1277
1278sub cmd_create_ignore {
1279        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1280        $gs ||= Git::SVN->new;
1281        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1282        $gs->prop_walk($gs->path, $r, sub {
1283                my ($gs, $path, $props) = @_;
1284                # $path is of the form /path/to/dir/
1285                $path = '.' . $path;
1286                # SVN can have attributes on empty directories,
1287                # which git won't track
1288                mkpath([$path]) unless -d $path;
1289                my $ignore = $path . '.gitignore';
1290                my $s = $props->{'svn:ignore'} or return;
1291                open(GITIGNORE, '>', $ignore)
1292                  or fatal("Failed to open `$ignore' for writing: $!");
1293                $s =~ s/[\r\n]+/\n/g;
1294                $s =~ s/^\n+//;
1295                chomp $s;
1296                # Prefix all patterns so that the ignore doesn't apply
1297                # to sub-directories.
1298                $s =~ s#^#/#gm;
1299                print GITIGNORE "$s\n";
1300                close(GITIGNORE)
1301                  or fatal("Failed to close `$ignore': $!");
1302                command_noisy('add', '-f', $ignore);
1303        });
1304}
1305
1306sub cmd_mkdirs {
1307        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1308        $gs ||= Git::SVN->new;
1309        $gs->mkemptydirs($_revision);
1310}
1311
1312# get_svnprops(PATH)
1313# ------------------
1314# Helper for cmd_propget and cmd_proplist below.
1315sub get_svnprops {
1316        my $path = shift;
1317        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1318        $gs ||= Git::SVN->new;
1319
1320        # prefix THE PATH by the sub-directory from which the user
1321        # invoked us.
1322        $path = $cmd_dir_prefix . $path;
1323        fatal("No such file or directory: $path") unless -e $path;
1324        my $is_dir = -d $path ? 1 : 0;
1325        $path = join_paths($gs->path, $path);
1326
1327        # canonicalize the path (otherwise libsvn will abort or fail to
1328        # find the file)
1329        $path = canonicalize_path($path);
1330
1331        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1332        my $props;
1333        if ($is_dir) {
1334                (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1335        }
1336        else {
1337                (undef, $props) = $gs->ra->get_file($path, $r, undef);
1338        }
1339        return $props;
1340}
1341
1342# cmd_propget (PROP, PATH)
1343# ------------------------
1344# Print the SVN property PROP for PATH.
1345sub cmd_propget {
1346        my ($prop, $path) = @_;
1347        $path = '.' if not defined $path;
1348        usage(1) if not defined $prop;
1349        my $props = get_svnprops($path);
1350        if (not defined $props->{$prop}) {
1351                fatal("`$path' does not have a `$prop' SVN property.");
1352        }
1353        print $props->{$prop} . "\n";
1354}
1355
1356# cmd_proplist (PATH)
1357# -------------------
1358# Print the list of SVN properties for PATH.
1359sub cmd_proplist {
1360        my $path = shift;
1361        $path = '.' if not defined $path;
1362        my $props = get_svnprops($path);
1363        print "Properties on '$path':\n";
1364        foreach (sort keys %{$props}) {
1365                print "  $_\n";
1366        }
1367}
1368
1369sub cmd_multi_init {
1370        my $url = shift;
1371        unless (defined $_trunk || @_branches || @_tags) {
1372                usage(1);
1373        }
1374
1375        $_prefix = '' unless defined $_prefix;
1376        if (defined $url) {
1377                $url = canonicalize_url($url);
1378                init_subdir(@_);
1379        }
1380        do_git_init_db();
1381        if (defined $_trunk) {
1382                $_trunk =~ s#^/+##;
1383                my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1384                # try both old-style and new-style lookups:
1385                my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1386                unless ($gs_trunk) {
1387                        my ($trunk_url, $trunk_path) =
1388                                              complete_svn_url($url, $_trunk);
1389                        $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1390                                                   undef, $trunk_ref);
1391                }
1392        }
1393        return unless @_branches || @_tags;
1394        my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1395        foreach my $path (@_branches) {
1396                complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1397        }
1398        foreach my $path (@_tags) {
1399                complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1400        }
1401}
1402
1403sub cmd_multi_fetch {
1404        $Git::SVN::no_reuse_existing = undef;
1405        my $remotes = Git::SVN::read_all_remotes();
1406        foreach my $repo_id (sort keys %$remotes) {
1407                if ($remotes->{$repo_id}->{url}) {
1408                        Git::SVN::fetch_all($repo_id, $remotes);
1409                }
1410        }
1411}
1412
1413# this command is special because it requires no metadata
1414sub cmd_commit_diff {
1415        my ($ta, $tb, $url) = @_;
1416        my $usage = "Usage: $0 commit-diff -r<revision> ".
1417                    "<tree-ish> <tree-ish> [<URL>]";
1418        fatal($usage) if (!defined $ta || !defined $tb);
1419        my $svn_path = '';
1420        if (!defined $url) {
1421                my $gs = eval { Git::SVN->new };
1422                if (!$gs) {
1423                        fatal("Needed URL or usable git-svn --id in ",
1424                              "the command-line\n", $usage);
1425                }
1426                $url = $gs->url;
1427                $svn_path = $gs->path;
1428        }
1429        unless (defined $_revision) {
1430                fatal("-r|--revision is a required argument\n", $usage);
1431        }
1432        if (defined $_message && defined $_file) {
1433                fatal("Both --message/-m and --file/-F specified ",
1434                      "for the commit message.\n",
1435                      "I have no idea what you mean");
1436        }
1437        if (defined $_file) {
1438                $_message = file_to_s($_file);
1439        } else {
1440                $_message ||= get_commit_entry($tb)->{log};
1441        }
1442        my $ra ||= Git::SVN::Ra->new($url);
1443        my $r = $_revision;
1444        if ($r eq 'HEAD') {
1445                $r = $ra->get_latest_revnum;
1446        } elsif ($r !~ /^\d+$/) {
1447                die "revision argument: $r not understood by git-svn\n";
1448        }
1449        my %ed_opts = ( r => $r,
1450                        log => $_message,
1451                        ra => $ra,
1452                        tree_a => $ta,
1453                        tree_b => $tb,
1454                        editor_cb => sub { print "Committed r$_[0]\n" },
1455                        svn_path => $svn_path );
1456        if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1457                print "No changes\n$ta == $tb\n";
1458        }
1459}
1460
1461
1462sub cmd_info {
1463        my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1464        my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1465        if (exists $_[1]) {
1466                die "Too many arguments specified\n";
1467        }
1468
1469        my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1470
1471        if (!$file_type && !$diff_status) {
1472                print STDERR "svn: '$path' is not under version control\n";
1473                exit 1;
1474        }
1475
1476        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1477        unless ($gs) {
1478                die "Unable to determine upstream SVN information from ",
1479                    "working tree history\n";
1480        }
1481
1482        # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1483        $path = "." if $path eq "";
1484
1485        my $full_url = canonicalize_url( add_path_to_url( $url, $fullpath ) );
1486
1487        if ($_url) {
1488                print "$full_url\n";
1489                return;
1490        }
1491
1492        my $result = "Path: $path\n";
1493        $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1494        $result .= "URL: $full_url\n";
1495
1496        eval {
1497                my $repos_root = $gs->repos_root;
1498                Git::SVN::remove_username($repos_root);
1499                $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1500        };
1501        if ($@) {
1502                $result .= "Repository Root: (offline)\n";
1503        }
1504        ::_req_svn();
1505        $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1506                (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1507        $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1508
1509        $result .= "Node Kind: " .
1510                   ($file_type eq "dir" ? "directory" : "file") . "\n";
1511
1512        my $schedule = $diff_status eq "A"
1513                       ? "add"
1514                       : ($diff_status eq "D" ? "delete" : "normal");
1515        $result .= "Schedule: $schedule\n";
1516
1517        if ($diff_status eq "A") {
1518                print $result, "\n";
1519                return;
1520        }
1521
1522        my ($lc_author, $lc_rev, $lc_date_utc);
1523        my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1524        my $log = command_output_pipe(@args);
1525        my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1526        while (<$log>) {
1527                if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1528                        $lc_author = $1;
1529                        $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1530                } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1531                        (undef, $lc_rev, undef) = ::extract_metadata($1);
1532                }
1533        }
1534        close $log;
1535
1536        Git::SVN::Log::set_local_timezone();
1537
1538        $result .= "Last Changed Author: $lc_author\n";
1539        $result .= "Last Changed Rev: $lc_rev\n";
1540        $result .= "Last Changed Date: " .
1541                   Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1542
1543        if ($file_type ne "dir") {
1544                my $text_last_updated_date =
1545                    ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1546                $result .=
1547                    "Text Last Updated: " .
1548                    Git::SVN::Log::format_svn_date($text_last_updated_date) .
1549                    "\n";
1550                my $checksum;
1551                if ($diff_status eq "D") {
1552                        my ($fh, $ctx) =
1553                            command_output_pipe(qw(cat-file blob), "HEAD:$path");
1554                        if ($file_type eq "link") {
1555                                my $file_name = <$fh>;
1556                                $checksum = md5sum("link $file_name");
1557                        } else {
1558                                $checksum = md5sum($fh);
1559                        }
1560                        command_close_pipe($fh, $ctx);
1561                } elsif ($file_type eq "link") {
1562                        my $file_name =
1563                            command(qw(cat-file blob), "HEAD:$path");
1564                        $checksum =
1565                            md5sum("link " . $file_name);
1566                } else {
1567                        open FILE, "<", $path or die $!;
1568                        $checksum = md5sum(\*FILE);
1569                        close FILE or die $!;
1570                }
1571                $result .= "Checksum: " . $checksum . "\n";
1572        }
1573
1574        print $result, "\n";
1575}
1576
1577sub cmd_reset {
1578        my $target = shift || $_revision or die "SVN revision required\n";
1579        $target = $1 if $target =~ /^r(\d+)$/;
1580        $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1581        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1582        unless ($gs) {
1583                die "Unable to determine upstream SVN information from ".
1584                    "history\n";
1585        }
1586        my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1587        die "Cannot find SVN revision $target\n" unless defined($c);
1588        $gs->rev_map_set($r, $c, 'reset', $uuid);
1589        print "r$r = $c ($gs->{ref_id})\n";
1590}
1591
1592sub cmd_gc {
1593        if (!can_compress()) {
1594                warn "Compress::Zlib could not be found; unhandled.log " .
1595                     "files will not be compressed.\n";
1596        }
1597        find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1598}
1599
1600########################### utility functions #########################
1601
1602sub rebase_cmd {
1603        my @cmd = qw/rebase/;
1604        push @cmd, '-v' if $_verbose;
1605        push @cmd, qw/--merge/ if $_merge;
1606        push @cmd, "--strategy=$_strategy" if $_strategy;
1607        push @cmd, "--preserve-merges" if $_preserve_merges;
1608        @cmd;
1609}
1610
1611sub post_fetch_checkout {
1612        return if $_no_checkout;
1613        return if verify_ref('HEAD^0');
1614        my $gs = $Git::SVN::_head or return;
1615
1616        # look for "trunk" ref if it exists
1617        my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1618        my $fetch = $remote->{fetch};
1619        if ($fetch) {
1620                foreach my $p (keys %$fetch) {
1621                        basename($fetch->{$p}) eq 'trunk' or next;
1622                        $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1623                        last;
1624                }
1625        }
1626
1627        command_noisy(qw(update-ref HEAD), $gs->refname);
1628        return unless verify_ref('HEAD^0');
1629
1630        return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1631        my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1632        return if -f $index;
1633
1634        return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1635        return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1636        command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1637        print STDERR "Checked out HEAD:\n  ",
1638                     $gs->full_url, " r", $gs->last_rev, "\n";
1639        if (auto_create_empty_directories($gs)) {
1640                $gs->mkemptydirs($gs->last_rev);
1641        }
1642}
1643
1644sub complete_svn_url {
1645        my ($url, $path) = @_;
1646        $path = canonicalize_path($path);
1647
1648        # If the path is not a URL...
1649        if ($path !~ m#^[a-z\+]+://#) {
1650                if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1651                        fatal("E: '$path' is not a complete URL ",
1652                              "and a separate URL is not specified");
1653                }
1654                return ($url, $path);
1655        }
1656        return ($path, '');
1657}
1658
1659sub complete_url_ls_init {
1660        my ($ra, $repo_path, $switch, $pfx) = @_;
1661        unless ($repo_path) {
1662                print STDERR "W: $switch not specified\n";
1663                return;
1664        }
1665        $repo_path = canonicalize_path($repo_path);
1666        if ($repo_path =~ m#^[a-z\+]+://#) {
1667                $ra = Git::SVN::Ra->new($repo_path);
1668                $repo_path = '';
1669        } else {
1670                $repo_path =~ s#^/+##;
1671                unless ($ra) {
1672                        fatal("E: '$repo_path' is not a complete URL ",
1673                              "and a separate URL is not specified");
1674                }
1675        }
1676        my $url = $ra->url;
1677        my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1678        my $k = "svn-remote.$gs->{repo_id}.url";
1679        my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1680        if ($orig_url && ($orig_url ne $gs->url)) {
1681                die "$k already set: $orig_url\n",
1682                    "wanted to set to: $gs->url\n";
1683        }
1684        command_oneline('config', $k, $gs->url) unless $orig_url;
1685
1686        my $remote_path = join_paths( $gs->path, $repo_path );
1687        $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1688        $remote_path =~ s#^/##g;
1689        $remote_path .= "/*" if $remote_path !~ /\*/;
1690        my ($n) = ($switch =~ /^--(\w+)/);
1691        if (length $pfx && $pfx !~ m#/$#) {
1692                die "--prefix='$pfx' must have a trailing slash '/'\n";
1693        }
1694        command_noisy('config',
1695                      '--add',
1696                      "svn-remote.$gs->{repo_id}.$n",
1697                      "$remote_path:refs/remotes/$pfx*" .
1698                        ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1699}
1700
1701sub verify_ref {
1702        my ($ref) = @_;
1703        eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1704                               { STDERR => 0 }); };
1705}
1706
1707sub get_tree_from_treeish {
1708        my ($treeish) = @_;
1709        # $treeish can be a symbolic ref, too:
1710        my $type = command_oneline(qw/cat-file -t/, $treeish);
1711        my $expected;
1712        while ($type eq 'tag') {
1713                ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1714        }
1715        if ($type eq 'commit') {
1716                $expected = (grep /^tree /, command(qw/cat-file commit/,
1717                                                    $treeish))[0];
1718                ($expected) = ($expected =~ /^tree ($sha1)$/o);
1719                die "Unable to get tree from $treeish\n" unless $expected;
1720        } elsif ($type eq 'tree') {
1721                $expected = $treeish;
1722        } else {
1723                die "$treeish is a $type, expected tree, tag or commit\n";
1724        }
1725        return $expected;
1726}
1727
1728sub get_commit_entry {
1729        my ($treeish) = shift;
1730        my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1731        my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1732        my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1733        open my $log_fh, '>', $commit_editmsg or croak $!;
1734
1735        my $type = command_oneline(qw/cat-file -t/, $treeish);
1736        if ($type eq 'commit' || $type eq 'tag') {
1737                my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1738                                                         $type, $treeish);
1739                my $in_msg = 0;
1740                my $author;
1741                my $saw_from = 0;
1742                my $msgbuf = "";
1743                while (<$msg_fh>) {
1744                        if (!$in_msg) {
1745                                $in_msg = 1 if (/^\s*$/);
1746                                $author = $1 if (/^author (.*>)/);
1747                        } elsif (/^git-svn-id: /) {
1748                                # skip this for now, we regenerate the
1749                                # correct one on re-fetch anyways
1750                                # TODO: set *:merge properties or like...
1751                        } else {
1752                                if (/^From:/ || /^Signed-off-by:/) {
1753                                        $saw_from = 1;
1754                                }
1755                                $msgbuf .= $_;
1756                        }
1757                }
1758                $msgbuf =~ s/\s+$//s;
1759                if ($Git::SVN::_add_author_from && defined($author)
1760                    && !$saw_from) {
1761                        $msgbuf .= "\n\nFrom: $author";
1762                }
1763                print $log_fh $msgbuf or croak $!;
1764                command_close_pipe($msg_fh, $ctx);
1765        }
1766        close $log_fh or croak $!;
1767
1768        if ($_edit || ($type eq 'tree')) {
1769                chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1770                system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1771        }
1772        rename $commit_editmsg, $commit_msg or croak $!;
1773        {
1774                require Encode;
1775                # SVN requires messages to be UTF-8 when entering the repo
1776                local $/;
1777                open $log_fh, '<', $commit_msg or croak $!;
1778                binmode $log_fh;
1779                chomp($log_entry{log} = <$log_fh>);
1780
1781                my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1782                my $msg = $log_entry{log};
1783
1784                eval { $msg = Encode::decode($enc, $msg, 1) };
1785                if ($@) {
1786                        die "Could not decode as $enc:\n", $msg,
1787                            "\nPerhaps you need to set i18n.commitencoding\n";
1788                }
1789
1790                eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1791                die "Could not encode as UTF-8:\n$msg\n" if $@;
1792
1793                $log_entry{log} = $msg;
1794
1795                close $log_fh or croak $!;
1796        }
1797        unlink $commit_msg;
1798        \%log_entry;
1799}
1800
1801sub s_to_file {
1802        my ($str, $file, $mode) = @_;
1803        open my $fd,'>',$file or croak $!;
1804        print $fd $str,"\n" or croak $!;
1805        close $fd or croak $!;
1806        chmod ($mode &~ umask, $file) if (defined $mode);
1807}
1808
1809sub file_to_s {
1810        my $file = shift;
1811        open my $fd,'<',$file or croak "$!: file: $file\n";
1812        local $/;
1813        my $ret = <$fd>;
1814        close $fd or croak $!;
1815        $ret =~ s/\s*$//s;
1816        return $ret;
1817}
1818
1819# '<svn username> = real-name <email address>' mapping based on git-svnimport:
1820sub load_authors {
1821        open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1822        my $log = $cmd eq 'log';
1823        while (<$authors>) {
1824                chomp;
1825                next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1826                my ($user, $name, $email) = ($1, $2, $3);
1827                if ($log) {
1828                        $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1829                } else {
1830                        $users{$user} = [$name, $email];
1831                }
1832        }
1833        close $authors or croak $!;
1834}
1835
1836# convert GetOpt::Long specs for use by git-config
1837sub read_git_config {
1838        my $opts = shift;
1839        my @config_only;
1840        foreach my $o (keys %$opts) {
1841                # if we have mixedCase and a long option-only, then
1842                # it's a config-only variable that we don't need for
1843                # the command-line.
1844                push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1845                my $v = $opts->{$o};
1846                my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1847                $key =~ s/-//g;
1848                my $arg = 'git config';
1849                $arg .= ' --int' if ($o =~ /[:=]i$/);
1850                $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1851                if (ref $v eq 'ARRAY') {
1852                        chomp(my @tmp = `$arg --get-all svn.$key`);
1853                        @$v = @tmp if @tmp;
1854                } else {
1855                        chomp(my $tmp = `$arg --get svn.$key`);
1856                        if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1857                                $$v = $tmp;
1858                        }
1859                }
1860        }
1861        delete @$opts{@config_only} if @config_only;
1862}
1863
1864sub extract_metadata {
1865        my $id = shift or return (undef, undef, undef);
1866        my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1867                                                        \s([a-f\d\-]+)$/ix);
1868        if (!defined $rev || !$uuid || !$url) {
1869                # some of the original repositories I made had
1870                # identifiers like this:
1871                ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1872        }
1873        return ($url, $rev, $uuid);
1874}
1875
1876sub cmt_metadata {
1877        return extract_metadata((grep(/^git-svn-id: /,
1878                command(qw/cat-file commit/, shift)))[-1]);
1879}
1880
1881sub cmt_sha2rev_batch {
1882        my %s2r;
1883        my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1884        my $list = shift;
1885
1886        foreach my $sha (@{$list}) {
1887                my $first = 1;
1888                my $size = 0;
1889                print $out $sha, "\n";
1890
1891                while (my $line = <$in>) {
1892                        if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1893                                last;
1894                        } elsif ($first &&
1895                               $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1896                                $first = 0;
1897                                $size = $1;
1898                                next;
1899                        } elsif ($line =~ /^(git-svn-id: )/) {
1900                                my (undef, $rev, undef) =
1901                                                      extract_metadata($line);
1902                                $s2r{$sha} = $rev;
1903                        }
1904
1905                        $size -= length($line);
1906                        last if ($size == 0);
1907                }
1908        }
1909
1910        command_close_bidi_pipe($pid, $in, $out, $ctx);
1911
1912        return \%s2r;
1913}
1914
1915sub working_head_info {
1916        my ($head, $refs) = @_;
1917        my @args = qw/rev-list --first-parent --pretty=medium/;
1918        my ($fh, $ctx) = command_output_pipe(@args, $head);
1919        my $hash;
1920        my %max;
1921        while (<$fh>) {
1922                if ( m{^commit ($::sha1)$} ) {
1923                        unshift @$refs, $hash if $hash and $refs;
1924                        $hash = $1;
1925                        next;
1926                }
1927                next unless s{^\s*(git-svn-id:)}{$1};
1928                my ($url, $rev, $uuid) = extract_metadata($_);
1929                if (defined $url && defined $rev) {
1930                        next if $max{$url} and $max{$url} < $rev;
1931                        if (my $gs = Git::SVN->find_by_url($url)) {
1932                                my $c = $gs->rev_map_get($rev, $uuid);
1933                                if ($c && $c eq $hash) {
1934                                        close $fh; # break the pipe
1935                                        return ($url, $rev, $uuid, $gs);
1936                                } else {
1937                                        $max{$url} ||= $gs->rev_map_max;
1938                                }
1939                        }
1940                }
1941        }
1942        command_close_pipe($fh, $ctx);
1943        (undef, undef, undef, undef);
1944}
1945
1946sub read_commit_parents {
1947        my ($parents, $c) = @_;
1948        chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1949        $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1950        @{$parents->{$c}} = split(/ /, $p);
1951}
1952
1953sub linearize_history {
1954        my ($gs, $refs) = @_;
1955        my %parents;
1956        foreach my $c (@$refs) {
1957                read_commit_parents(\%parents, $c);
1958        }
1959
1960        my @linear_refs;
1961        my %skip = ();
1962        my $last_svn_commit = $gs->last_commit;
1963        foreach my $c (reverse @$refs) {
1964                next if $c eq $last_svn_commit;
1965                last if $skip{$c};
1966
1967                unshift @linear_refs, $c;
1968                $skip{$c} = 1;
1969
1970                # we only want the first parent to diff against for linear
1971                # history, we save the rest to inject when we finalize the
1972                # svn commit
1973                my $fp_a = verify_ref("$c~1");
1974                my $fp_b = shift @{$parents{$c}} if $parents{$c};
1975                if (!$fp_a || !$fp_b) {
1976                        die "Commit $c\n",
1977                            "has no parent commit, and therefore ",
1978                            "nothing to diff against.\n",
1979                            "You should be working from a repository ",
1980                            "originally created by git-svn\n";
1981                }
1982                if ($fp_a ne $fp_b) {
1983                        die "$c~1 = $fp_a, however parsing commit $c ",
1984                            "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1985                }
1986
1987                foreach my $p (@{$parents{$c}}) {
1988                        $skip{$p} = 1;
1989                }
1990        }
1991        (\@linear_refs, \%parents);
1992}
1993
1994sub find_file_type_and_diff_status {
1995        my ($path) = @_;
1996        return ('dir', '') if $path eq '';
1997
1998        my $diff_output =
1999            command_oneline(qw(diff --cached --name-status --), $path) || "";
2000        my $diff_status = (split(' ', $diff_output))[0] || "";
2001
2002        my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
2003
2004        return (undef, undef) if !$diff_status && !$ls_tree;
2005
2006        if ($diff_status eq "A") {
2007                return ("link", $diff_status) if -l $path;
2008                return ("dir", $diff_status) if -d $path;
2009                return ("file", $diff_status);
2010        }
2011
2012        my $mode = (split(' ', $ls_tree))[0] || "";
2013
2014        return ("link", $diff_status) if $mode eq "120000";
2015        return ("dir", $diff_status) if $mode eq "040000";
2016        return ("file", $diff_status);
2017}
2018
2019sub md5sum {
2020        my $arg = shift;
2021        my $ref = ref $arg;
2022        my $md5 = Digest::MD5->new();
2023        if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2024                $md5->addfile($arg) or croak $!;
2025        } elsif ($ref eq 'SCALAR') {
2026                $md5->add($$arg) or croak $!;
2027        } elsif (!$ref) {
2028                $md5->add($arg) or croak $!;
2029        } else {
2030                fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2031        }
2032        return $md5->hexdigest();
2033}
2034
2035sub gc_directory {
2036        if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2037                my $out_filename = $_ . ".gz";
2038                open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2039                binmode $in_fh;
2040                my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2041                                die "Unable to open $out_filename: $!\n";
2042
2043                my $res;
2044                while ($res = sysread($in_fh, my $str, 1024)) {
2045                        $gz->gzwrite($str) or
2046                                die "Unable to write: ".$gz->gzerror()."!\n";
2047                }
2048                unlink $_ or die "unlink $File::Find::name: $!\n";
2049        } elsif (-f $_ && basename($_) eq "index") {
2050                unlink $_ or die "unlink $_: $!\n";
2051        }
2052}
2053
2054__END__
2055
2056Data structures:
2057
2058
2059$remotes = { # returned by read_all_remotes()
2060        'svn' => {
2061                # svn-remote.svn.url=https://svn.musicpd.org
2062                url => 'https://svn.musicpd.org',
2063                # svn-remote.svn.fetch=mpd/trunk:trunk
2064                fetch => {
2065                        'mpd/trunk' => 'trunk',
2066                },
2067                # svn-remote.svn.tags=mpd/tags/*:tags/*
2068                tags => {
2069                        path => {
2070                                left => 'mpd/tags',
2071                                right => '',
2072                                regex => qr!mpd/tags/([^/]+)$!,
2073                                glob => 'tags/*',
2074                        },
2075                        ref => {
2076                                left => 'tags',
2077                                right => '',
2078                                regex => qr!tags/([^/]+)$!,
2079                                glob => 'tags/*',
2080                        },
2081                }
2082        }
2083};
2084
2085$log_entry hashref as returned by libsvn_log_entry()
2086{
2087        log => 'whitespace-formatted log entry
2088',                                              # trailing newline is preserved
2089        revision => '8',                        # integer
2090        date => '2004-02-24T17:01:44.108345Z',  # commit date
2091        author => 'committer name'
2092};
2093
2094
2095# this is generated by generate_diff();
2096@mods = array of diff-index line hashes, each element represents one line
2097        of diff-index output
2098
2099diff-index line ($m hash)
2100{
2101        mode_a => first column of diff-index output, no leading ':',
2102        mode_b => second column of diff-index output,
2103        sha1_b => sha1sum of the final blob,
2104        chg => change type [MCRADT],
2105        file_a => original file name of a file (iff chg is 'C' or 'R')
2106        file_b => new/current file name of a file (any chg)
2107}
2108;
2109
2110# retval of read_url_paths{,_all}();
2111$l_map = {
2112        # repository root url
2113        'https://svn.musicpd.org' => {
2114                # repository path               # GIT_SVN_ID
2115                'mpd/trunk'             =>      'trunk',
2116                'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2117        },
2118}
2119
2120Notes:
2121        I don't trust the each() function on unless I created %hash myself
2122        because the internal iterator may not have started at base.