1#!/usr/bin/perl -w
2#
3# Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
4# Copyright 2005 Ryan Anderson <ryan@michonline.com>
5#
6# GPL v2 (See COPYING)
7#
8# Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
9#
10# Sends a collection of emails to the given email addresses, disturbingly fast.
11#
12# Supports two formats:
13# 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
14# 2. The original format support by Greg's script:
15# first line of the message is who to CC,
16# and second line is the subject of the message.
17#
18use strict;
20use warnings;
21use Term::ReadLine;
22use Getopt::Long;
23use Text::ParseWords;
24use Data::Dumper;
25use Term::ANSIColor;
26use File::Temp qw/ tempdir tempfile /;
27use Error qw(:try);
28use Git;
29Getopt::Long::Configure qw/ pass_through /;
31package FakeTerm;
33sub new {
34 my ($class, $reason) = @_;
35 return bless \$reason, shift;
36}
37sub readline {
38 my $self = shift;
39 die "Cannot use readline on FakeTerm: $$self";
40}
41package main;
42sub usage {
45 print <<EOT;
46git send-email [options] <file | directory | rev-list options >
47 Composing:
49 --from <str> * Email From:
50 --to <str> * Email To:
51 --cc <str> * Email Cc:
52 --bcc <str> * Email Bcc:
53 --subject <str> * Email "Subject:"
54 --in-reply-to <str> * Email "In-Reply-To:"
55 --annotate * Review each patch that will be sent in an editor.
56 --compose * Open an editor for introduction.
57 Sending:
59 --envelope-sender <str> * Email envelope sender.
60 --smtp-server <str:int> * Outgoing SMTP server to use. The port
61 is optional. Default 'localhost'.
62 --smtp-server-port <int> * Outgoing SMTP server port.
63 --smtp-user <str> * Username for SMTP-AUTH.
64 --smtp-pass <str> * Password for SMTP-AUTH; not necessary.
65 --smtp-encryption <str> * tls or ssl; anything else disables.
66 --smtp-ssl * Deprecated. Use '--smtp-encryption ssl'.
67 Automating:
69 --identity <str> * Use the sendemail.<id> options.
70 --cc-cmd <str> * Email Cc: via `<str> \$patch_path`
71 --suppress-cc <str> * author, self, sob, cc, cccmd, body, bodycc, all.
72 --[no-]signed-off-by-cc * Send to Signed-off-by: addresses. Default on.
73 --[no-]suppress-from * Send to self. Default off.
74 --[no-]chain-reply-to * Chain In-Reply-To: fields. Default on.
75 --[no-]thread * Use In-Reply-To: field. Default on.
76 Administering:
78 --confirm <str> * Confirm recipients before sending;
79 auto, cc, compose, always, or never.
80 --quiet * Output one line of info per email.
81 --dry-run * Don't actually send the emails.
82 --[no-]validate * Perform patch sanity checks. Default on.
83 --[no-]format-patch * understand any non optional arguments as
84 `git format-patch` ones.
85EOT
87 exit(1);
88}
89# most mail servers generate the Date: header, but not all...
91sub format_2822_time {
92 my ($time) = @_;
93 my @localtm = localtime($time);
94 my @gmttm = gmtime($time);
95 my $localmin = $localtm[1] + $localtm[2] * 60;
96 my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
97 if ($localtm[0] != $gmttm[0]) {
98 die "local zone differs from GMT by a non-minute interval\n";
99 }
100 if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
101 $localmin += 1440;
102 } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
103 $localmin -= 1440;
104 } elsif ($gmttm[6] != $localtm[6]) {
105 die "local time offset greater than or equal to 24 hours\n";
106 }
107 my $offset = $localmin - $gmtmin;
108 my $offhour = $offset / 60;
109 my $offmin = abs($offset % 60);
110 if (abs($offhour) >= 24) {
111 die ("local time offset greater than or equal to 24 hours\n");
112 }
113 return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
115 qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
116 $localtm[3],
117 qw(Jan Feb Mar Apr May Jun
118 Jul Aug Sep Oct Nov Dec)[$localtm[4]],
119 $localtm[5]+1900,
120 $localtm[2],
121 $localtm[1],
122 $localtm[0],
123 ($offset >= 0) ? '+' : '-',
124 abs($offhour),
125 $offmin,
126 );
127}
128my $have_email_valid = eval { require Email::Valid; 1 };
130my $have_mail_address = eval { require Mail::Address; 1 };
131my $smtp;
132my $auth;
133sub unique_email_list(@);
135sub cleanup_compose_files();
136# Variables we fill in automatically, or via prompting:
138my (@to,@cc,@initial_cc,@bcclist,@xh,
139 $initial_reply_to,$initial_subject,@files,
140 $author,$sender,$smtp_authpass,$annotate,$compose,$time);
141my $envelope_sender;
143# Example reply to:
145#$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
146my $repo = eval { Git->repository() };
148my @repo = $repo ? ($repo) : ();
149my $term = eval {
150 $ENV{"GIT_SEND_EMAIL_NOTTY"}
151 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
152 : new Term::ReadLine 'git-send-email';
153};
154if ($@) {
155 $term = new FakeTerm "$@: going non-interactive";
156}
157# Behavior modification variables
159my ($quiet, $dry_run) = (0, 0);
160my $format_patch;
161my $compose_filename;
162# Handle interactive edition of files.
164my $multiedit;
165my $editor = Git::command_oneline('var', 'GIT_EDITOR');
166sub do_edit {
168 if (defined($multiedit) && !$multiedit) {
169 map {
170 system('sh', '-c', $editor.' "$@"', $editor, $_);
171 if (($? & 127) || ($? >> 8)) {
172 die("the editor exited uncleanly, aborting everything");
173 }
174 } @_;
175 } else {
176 system('sh', '-c', $editor.' "$@"', $editor, @_);
177 if (($? & 127) || ($? >> 8)) {
178 die("the editor exited uncleanly, aborting everything");
179 }
180 }
181}
182# Variables with corresponding config settings
184my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
185my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
186my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
187my ($validate, $confirm);
188my (@suppress_cc);
189my $not_set_by_user = "true but not set by the user";
191my %config_bool_settings = (
193 "thread" => [\$thread, 1],
194 "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
195 "suppressfrom" => [\$suppress_from, undef],
196 "signedoffbycc" => [\$signed_off_by_cc, undef],
197 "signedoffcc" => [\$signed_off_by_cc, undef], # Deprecated
198 "validate" => [\$validate, 1],
199);
200my %config_settings = (
202 "smtpserver" => \$smtp_server,
203 "smtpserverport" => \$smtp_server_port,
204 "smtpuser" => \$smtp_authuser,
205 "smtppass" => \$smtp_authpass,
206 "to" => \@to,
207 "cc" => \@initial_cc,
208 "cccmd" => \$cc_cmd,
209 "aliasfiletype" => \$aliasfiletype,
210 "bcc" => \@bcclist,
211 "aliasesfile" => \@alias_files,
212 "suppresscc" => \@suppress_cc,
213 "envelopesender" => \$envelope_sender,
214 "multiedit" => \$multiedit,
215 "confirm" => \$confirm,
216 "from" => \$sender,
217);
218# Help users prepare for 1.7.0
220sub chain_reply_to {
221 if (defined $chain_reply_to &&
222 $chain_reply_to eq $not_set_by_user) {
223 print STDERR
224 "In git 1.7.0, the default will be changed to --no-chain-reply-to\n" .
225 "Set sendemail.chainreplyto configuration variable to true if\n" .
226 "you want to keep --chain-reply-to as your default.\n";
227 $chain_reply_to = 1;
228 }
229 return $chain_reply_to;
230}
231# Handle Uncouth Termination
233sub signal_handler {
234 # Make text normal
236 print color("reset"), "\n";
237 # SMTP password masked
239 system "stty echo";
240 # tmp files from --compose
242 if (defined $compose_filename) {
243 if (-e $compose_filename) {
244 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
245 }
246 if (-e ($compose_filename . ".final")) {
247 print "'$compose_filename.final' contains the composed email.\n"
248 }
249 }
250 exit;
252};
253$SIG{TERM} = \&signal_handler;
255$SIG{INT} = \&signal_handler;
256# Begin by accumulating all the variables (defined above), that we will end up
258# needing, first, from the command line:
259my $rc = GetOptions("sender|from=s" => \$sender,
261 "in-reply-to=s" => \$initial_reply_to,
262 "subject=s" => \$initial_subject,
263 "to=s" => \@to,
264 "cc=s" => \@initial_cc,
265 "bcc=s" => \@bcclist,
266 "chain-reply-to!" => \$chain_reply_to,
267 "smtp-server=s" => \$smtp_server,
268 "smtp-server-port=s" => \$smtp_server_port,
269 "smtp-user=s" => \$smtp_authuser,
270 "smtp-pass:s" => \$smtp_authpass,
271 "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
272 "smtp-encryption=s" => \$smtp_encryption,
273 "identity=s" => \$identity,
274 "annotate" => \$annotate,
275 "compose" => \$compose,
276 "quiet" => \$quiet,
277 "cc-cmd=s" => \$cc_cmd,
278 "suppress-from!" => \$suppress_from,
279 "suppress-cc=s" => \@suppress_cc,
280 "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
281 "confirm=s" => \$confirm,
282 "dry-run" => \$dry_run,
283 "envelope-sender=s" => \$envelope_sender,
284 "thread!" => \$thread,
285 "validate!" => \$validate,
286 "format-patch!" => \$format_patch,
287 );
288unless ($rc) {
290 usage();
291}
292die "Cannot run git format-patch from outside a repository\n"
294 if $format_patch and not $repo;
295# Now, let's fill any that aren't set in with defaults:
297sub read_config {
299 my ($prefix) = @_;
300 foreach my $setting (keys %config_bool_settings) {
302 my $target = $config_bool_settings{$setting}->[0];
303 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
304 }
305 foreach my $setting (keys %config_settings) {
307 my $target = $config_settings{$setting};
308 if (ref($target) eq "ARRAY") {
309 unless (@$target) {
310 my @values = Git::config(@repo, "$prefix.$setting");
311 @$target = @values if (@values && defined $values[0]);
312 }
313 }
314 else {
315 $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
316 }
317 }
318 if (!defined $smtp_encryption) {
320 my $enc = Git::config(@repo, "$prefix.smtpencryption");
321 if (defined $enc) {
322 $smtp_encryption = $enc;
323 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
324 $smtp_encryption = 'ssl';
325 }
326 }
327}
328# read configuration from [sendemail "$identity"], fall back on [sendemail]
330$identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
331read_config("sendemail.$identity") if (defined $identity);
332read_config("sendemail");
333# fall back on builtin bool defaults
335foreach my $setting (values %config_bool_settings) {
336 ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
337}
338# 'default' encryption is none -- this only prevents a warning
340$smtp_encryption = '' unless (defined $smtp_encryption);
341# Set CC suppressions
343my(%suppress_cc);
344if (@suppress_cc) {
345 foreach my $entry (@suppress_cc) {
346 die "Unknown --suppress-cc field: '$entry'\n"
347 unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
348 $suppress_cc{$entry} = 1;
349 }
350}
351if ($suppress_cc{'all'}) {
353 foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
354 $suppress_cc{$entry} = 1;
355 }
356 delete $suppress_cc{'all'};
357}
358# If explicit old-style ones are specified, they trump --suppress-cc.
360$suppress_cc{'self'} = $suppress_from if defined $suppress_from;
361$suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
362if ($suppress_cc{'body'}) {
364 foreach my $entry (qw (sob bodycc)) {
365 $suppress_cc{$entry} = 1;
366 }
367 delete $suppress_cc{'body'};
368}
369# Set confirm's default value
371my $confirm_unconfigured = !defined $confirm;
372if ($confirm_unconfigured) {
373 $confirm = scalar %suppress_cc ? 'compose' : 'auto';
374};
375die "Unknown --confirm setting: '$confirm'\n"
376 unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
377# Debugging, print out the suppressions.
379if (0) {
380 print "suppressions:\n";
381 foreach my $entry (keys %suppress_cc) {
382 printf " %-5s -> $suppress_cc{$entry}\n", $entry;
383 }
384}
385my ($repoauthor, $repocommitter);
387($repoauthor) = Git::ident_person(@repo, 'author');
388($repocommitter) = Git::ident_person(@repo, 'committer');
389# Verify the user input
391foreach my $entry (@to) {
393 die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
394}
395foreach my $entry (@initial_cc) {
397 die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
398}
399foreach my $entry (@bcclist) {
401 die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
402}
403sub parse_address_line {
405 if ($have_mail_address) {
406 return map { $_->format } Mail::Address->parse($_[0]);
407 } else {
408 return split_addrs($_[0]);
409 }
410}
411sub split_addrs {
413 return quotewords('\s*,\s*', 1, @_);
414}
415my %aliases;
417my %parse_alias = (
418 # multiline formats can be supported in the future
419 mutt => sub { my $fh = shift; while (<$fh>) {
420 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
421 my ($alias, $addr) = ($1, $2);
422 $addr =~ s/#.*$//; # mutt allows # comments
423 # commas delimit multiple addresses
424 $aliases{$alias} = [ split_addrs($addr) ];
425 }}},
426 mailrc => sub { my $fh = shift; while (<$fh>) {
427 if (/^alias\s+(\S+)\s+(.*)$/) {
428 # spaces delimit multiple addresses
429 $aliases{$1} = [ quotewords('\s+', 0, $2) ];
430 }}},
431 pine => sub { my $fh = shift; my $f='\t[^\t]*';
432 for (my $x = ''; defined($x); $x = $_) {
433 chomp $x;
434 $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
435 $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
436 $aliases{$1} = [ split_addrs($2) ];
437 }},
438 elm => sub { my $fh = shift;
439 while (<$fh>) {
440 if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
441 my ($alias, $addr) = ($1, $2);
442 $aliases{$alias} = [ split_addrs($addr) ];
443 }
444 } },
445 gnus => sub { my $fh = shift; while (<$fh>) {
447 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
448 $aliases{$1} = [ $2 ];
449 }}}
450);
451if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
453 foreach my $file (@alias_files) {
454 open my $fh, '<', $file or die "opening $file: $!\n";
455 $parse_alias{$aliasfiletype}->($fh);
456 close $fh;
457 }
458}
459($sender) = expand_aliases($sender) if defined $sender;
461# returns 1 if the conflict must be solved using it as a format-patch argument
463sub check_file_rev_conflict($) {
464 return unless $repo;
465 my $f = shift;
466 try {
467 $repo->command('rev-parse', '--verify', '--quiet', $f);
468 if (defined($format_patch)) {
469 return $format_patch;
470 }
471 die(<<EOF);
472File '$f' exists but it could also be the range of commits
473to produce patches for. Please disambiguate by...
474 * Saying "./$f" if you mean a file; or
476 * Giving --format-patch option if you mean a range.
477EOF
478 } catch Git::Error::Command with {
479 return 0;
480 }
481}
482# Now that all the defaults are set, process the rest of the command line
484# arguments and collect up the files that need to be processed.
485my @rev_list_opts;
486while (defined(my $f = shift @ARGV)) {
487 if ($f eq "--") {
488 push @rev_list_opts, "--", @ARGV;
489 @ARGV = ();
490 } elsif (-d $f and !check_file_rev_conflict($f)) {
491 opendir(DH,$f)
492 or die "Failed to opendir $f: $!";
493 push @files, grep { -f $_ } map { +$f . "/" . $_ }
495 sort readdir(DH);
496 closedir(DH);
497 } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
498 push @files, $f;
499 } else {
500 push @rev_list_opts, $f;
501 }
502}
503if (@rev_list_opts) {
505 die "Cannot run git format-patch from outside a repository\n"
506 unless $repo;
507 push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
508}
509if ($validate) {
511 foreach my $f (@files) {
512 unless (-p $f) {
513 my $error = validate_patch($f);
514 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
515 }
516 }
517}
518if (@files) {
520 unless ($quiet) {
521 print $_,"\n" for (@files);
522 }
523} else {
524 print STDERR "\nNo patch files specified!\n\n";
525 usage();
526}
527sub get_patch_subject($) {
529 my $fn = shift;
530 open (my $fh, '<', $fn);
531 while (my $line = <$fh>) {
532 next unless ($line =~ /^Subject: (.*)$/);
533 close $fh;
534 return "GIT: $1\n";
535 }
536 close $fh;
537 die "No subject line in $fn ?";
538}
539if ($compose) {
541 # Note that this does not need to be secure, but we will make a small
542 # effort to have it be unique
543 $compose_filename = ($repo ?
544 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
545 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
546 open(C,">",$compose_filename)
547 or die "Failed to open for writing $compose_filename: $!";
548 my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
551 my $tpl_subject = $initial_subject || '';
552 my $tpl_reply_to = $initial_reply_to || '';
553 print C <<EOT;
555From $tpl_sender # This line is ignored.
556GIT: Lines beginning in "GIT:" will be removed.
557GIT: Consider including an overall diffstat or table of contents
558GIT: for the patch you are writing.
559GIT:
560GIT: Clear the body content if you don't wish to send a summary.
561From: $tpl_sender
562Subject: $tpl_subject
563In-Reply-To: $tpl_reply_to
564EOT
566 for my $f (@files) {
567 print C get_patch_subject($f);
568 }
569 close(C);
570 if ($annotate) {
572 do_edit($compose_filename, @files);
573 } else {
574 do_edit($compose_filename);
575 }
576 open(C2,">",$compose_filename . ".final")
578 or die "Failed to open $compose_filename.final : " . $!;
579 open(C,"<",$compose_filename)
581 or die "Failed to open $compose_filename : " . $!;
582 my $need_8bit_cte = file_has_nonascii($compose_filename);
584 my $in_body = 0;
585 my $summary_empty = 1;
586 while(<C>) {
587 next if m/^GIT:/;
588 if ($in_body) {
589 $summary_empty = 0 unless (/^\n$/);
590 } elsif (/^\n$/) {
591 $in_body = 1;
592 if ($need_8bit_cte) {
593 print C2 "MIME-Version: 1.0\n",
594 "Content-Type: text/plain; ",
595 "charset=UTF-8\n",
596 "Content-Transfer-Encoding: 8bit\n";
597 }
598 } elsif (/^MIME-Version:/i) {
599 $need_8bit_cte = 0;
600 } elsif (/^Subject:\s*(.+)\s*$/i) {
601 $initial_subject = $1;
602 my $subject = $initial_subject;
603 $_ = "Subject: " .
604 ($subject =~ /[^[:ascii:]]/ ?
605 quote_rfc2047($subject) :
606 $subject) .
607 "\n";
608 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
609 $initial_reply_to = $1;
610 next;
611 } elsif (/^From:\s*(.+)\s*$/i) {
612 $sender = $1;
613 next;
614 } elsif (/^(?:To|Cc|Bcc):/i) {
615 print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
616 next;
617 }
618 print C2 $_;
619 }
620 close(C);
621 close(C2);
622 if ($summary_empty) {
624 print "Summary email is empty, skipping it\n";
625 $compose = -1;
626 }
627} elsif ($annotate) {
628 do_edit(@files);
629}
630sub ask {
632 my ($prompt, %arg) = @_;
633 my $valid_re = $arg{valid_re};
634 my $default = $arg{default};
635 my $resp;
636 my $i = 0;
637 return defined $default ? $default : undef
638 unless defined $term->IN and defined fileno($term->IN) and
639 defined $term->OUT and defined fileno($term->OUT);
640 while ($i++ < 10) {
641 $resp = $term->readline($prompt);
642 if (!defined $resp) { # EOF
643 print "\n";
644 return defined $default ? $default : undef;
645 }
646 if ($resp eq '' and defined $default) {
647 return $default;
648 }
649 if (!defined $valid_re or $resp =~ /$valid_re/) {
650 return $resp;
651 }
652 }
653 return undef;
654}
655my $prompting = 0;
657if (!defined $sender) {
658 $sender = $repoauthor || $repocommitter || '';
659 $sender = ask("Who should the emails appear to be from? [$sender] ",
660 default => $sender);
661 print "Emails will be sent from: ", $sender, "\n";
662 $prompting++;
663}
664if (!@to) {
666 my $to = ask("Who should the emails be sent to? ");
667 push @to, parse_address_line($to) if defined $to; # sanitized/validated later
668 $prompting++;
669}
670sub expand_aliases {
672 return map { expand_one_alias($_) } @_;
673}
674my %EXPANDED_ALIASES;
676sub expand_one_alias {
677 my $alias = shift;
678 if ($EXPANDED_ALIASES{$alias}) {
679 die "fatal: alias '$alias' expands to itself\n";
680 }
681 local $EXPANDED_ALIASES{$alias} = 1;
682 return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
683}
684@to = expand_aliases(@to);
686@to = (map { sanitize_address($_) } @to);
687@initial_cc = expand_aliases(@initial_cc);
688@bcclist = expand_aliases(@bcclist);
689if ($thread && !defined $initial_reply_to && $prompting) {
691 $initial_reply_to = ask(
692 "Message-ID to be used as In-Reply-To for the first email? ");
693}
694if (defined $initial_reply_to) {
695 $initial_reply_to =~ s/^\s*<?//;
696 $initial_reply_to =~ s/>?\s*$//;
697 $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
698}
699if (!defined $smtp_server) {
701 foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
702 if (-x $_) {
703 $smtp_server = $_;
704 last;
705 }
706 }
707 $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
708}
709if ($compose && $compose > 0) {
711 @files = ($compose_filename . ".final", @files);
712}
713# Variables we set as part of the loop over files
715our ($message_id, %mail, $subject, $reply_to, $references, $message,
716 $needs_confirm, $message_num, $ask_default);
717sub extract_valid_address {
719 my $address = shift;
720 my $local_part_regexp = '[^<>"\s@]+';
721 my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
722 # check for a local address:
724 return $address if ($address =~ /^($local_part_regexp)$/);
725 $address =~ s/^\s*<(.*)>\s*$/$1/;
727 if ($have_email_valid) {
728 return scalar Email::Valid->address($address);
729 } else {
730 # less robust/correct than the monster regexp in Email::Valid,
731 # but still does a 99% job, and one less dependency
732 $address =~ /($local_part_regexp\@$domain_regexp)/;
733 return $1;
734 }
735}
736# Usually don't need to change anything below here.
738# we make a "fake" message id by taking the current number
740# of seconds since the beginning of Unix time and tacking on
741# a random number to the end, in case we are called quicker than
742# 1 second since the last time we were called.
743# We'll setup a template for the message id, using the "from" address:
745my ($message_id_stamp, $message_id_serial);
747sub make_message_id
748{
749 my $uniq;
750 if (!defined $message_id_stamp) {
751 $message_id_stamp = sprintf("%s-%s", time, $$);
752 $message_id_serial = 0;
753 }
754 $message_id_serial++;
755 $uniq = "$message_id_stamp-$message_id_serial";
756 my $du_part;
758 for ($sender, $repocommitter, $repoauthor) {
759 $du_part = extract_valid_address(sanitize_address($_));
760 last if (defined $du_part and $du_part ne '');
761 }
762 if (not defined $du_part or $du_part eq '') {
763 use Sys::Hostname qw();
764 $du_part = 'user@' . Sys::Hostname::hostname();
765 }
766 my $message_id_template = "<%s-git-send-email-%s>";
767 $message_id = sprintf($message_id_template, $uniq, $du_part);
768 #print "new message id = $message_id\n"; # Was useful for debugging
769}
770$time = time - scalar $#files;
774sub unquote_rfc2047 {
776 local ($_) = @_;
777 my $encoding;
778 if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
779 $encoding = $1;
780 s/_/ /g;
781 s/=([0-9A-F]{2})/chr(hex($1))/eg;
782 }
783 return wantarray ? ($_, $encoding) : $_;
784}
785sub quote_rfc2047 {
787 local $_ = shift;
788 my $encoding = shift || 'UTF-8';
789 s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
790 s/(.*)/=\?$encoding\?q\?$1\?=/;
791 return $_;
792}
793sub is_rfc2047_quoted {
795 my $s = shift;
796 my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
797 my $encoded_text = '[!->@-~]+';
798 length($s) <= 75 &&
799 $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
800}
801# use the simplest quoting being able to handle the recipient
803sub sanitize_address
804{
805 my ($recipient) = @_;
806 my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
807 if (not $recipient_name) {
809 return "$recipient";
810 }
811 # if recipient_name is already quoted, do nothing
813 if (is_rfc2047_quoted($recipient_name)) {
814 return $recipient;
815 }
816 # rfc2047 is needed if a non-ascii char is included
818 if ($recipient_name =~ /[^[:ascii:]]/) {
819 $recipient_name =~ s/^"(.*)"$/$1/;
820 $recipient_name = quote_rfc2047($recipient_name);
821 }
822 # double quotes are needed if specials or CTLs are included
824 elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
825 $recipient_name =~ s/(["\\\r])/\\$1/g;
826 $recipient_name = "\"$recipient_name\"";
827 }
828 return "$recipient_name $recipient_addr";
830}
832# Returns 1 if the message was sent, and 0 otherwise.
834# In actuality, the whole program dies when there
835# is an error sending a message.
836sub send_message
838{
839 my @recipients = unique_email_list(@to);
840 @cc = (grep { my $cc = extract_valid_address($_);
841 not grep { $cc eq $_ } @recipients
842 }
843 map { sanitize_address($_) }
844 @cc);
845 my $to = join (",\n\t", @recipients);
846 @recipients = unique_email_list(@recipients,@cc,@bcclist);
847 @recipients = (map { extract_valid_address($_) } @recipients);
848 my $date = format_2822_time($time++);
849 my $gitversion = '@@GIT_VERSION@@';
850 if ($gitversion =~ m/..GIT_VERSION../) {
851 $gitversion = Git::version();
852 }
853 my $cc = join(",\n\t", unique_email_list(@cc));
855 my $ccline = "";
856 if ($cc ne '') {
857 $ccline = "\nCc: $cc";
858 }
859 my $sanitized_sender = sanitize_address($sender);
860 make_message_id() unless defined($message_id);
861 my $header = "From: $sanitized_sender
863To: $to${ccline}
864Subject: $subject
865Date: $date
866Message-Id: $message_id
867X-Mailer: git-send-email $gitversion
868";
869 if ($reply_to) {
870 $header .= "In-Reply-To: $reply_to\n";
872 $header .= "References: $references\n";
873 }
874 if (@xh) {
875 $header .= join("\n", @xh) . "\n";
876 }
877 my @sendmail_parameters = ('-i', @recipients);
879 my $raw_from = $sanitized_sender;
880 $raw_from = $envelope_sender if (defined $envelope_sender);
881 $raw_from = extract_valid_address($raw_from);
882 unshift (@sendmail_parameters,
883 '-f', $raw_from) if(defined $envelope_sender);
884 if ($needs_confirm && !$dry_run) {
886 print "\n$header\n";
887 if ($needs_confirm eq "inform") {
888 $confirm_unconfigured = 0; # squelch this message for the rest of this run
889 $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
890 print " The Cc list above has been expanded by additional\n";
891 print " addresses found in the patch commit message. By default\n";
892 print " send-email prompts before sending whenever this occurs.\n";
893 print " This behavior is controlled by the sendemail.confirm\n";
894 print " configuration setting.\n";
895 print "\n";
896 print " For additional information, run 'git send-email --help'.\n";
897 print " To retain the current behavior, but squelch this message,\n";
898 print " run 'git config --global sendemail.confirm auto'.\n\n";
899 }
900 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
901 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
902 default => $ask_default);
903 die "Send this email reply required" unless defined $_;
904 if (/^n/i) {
905 return 0;
906 } elsif (/^q/i) {
907 cleanup_compose_files();
908 exit(0);
909 } elsif (/^a/i) {
910 $confirm = 'never';
911 }
912 }
913 if ($dry_run) {
915 # We don't want to send the email.
916 } elsif ($smtp_server =~ m#^/#) {
917 my $pid = open my $sm, '|-';
918 defined $pid or die $!;
919 if (!$pid) {
920 exec($smtp_server, @sendmail_parameters) or die $!;
921 }
922 print $sm "$header\n$message";
923 close $sm or die $?;
924 } else {
925 if (!defined $smtp_server) {
927 die "The required SMTP server is not properly defined."
928 }
929 if ($smtp_encryption eq 'ssl') {
931 $smtp_server_port ||= 465; # ssmtp
932 require Net::SMTP::SSL;
933 $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
934 }
935 else {
936 require Net::SMTP;
937 $smtp ||= Net::SMTP->new((defined $smtp_server_port)
938 ? "$smtp_server:$smtp_server_port"
939 : $smtp_server);
940 if ($smtp_encryption eq 'tls' && $smtp) {
941 require Net::SMTP::SSL;
942 $smtp->command('STARTTLS');
943 $smtp->response();
944 if ($smtp->code == 220) {
945 $smtp = Net::SMTP::SSL->start_SSL($smtp)
946 or die "STARTTLS failed! ".$smtp->message;
947 $smtp_encryption = '';
948 # Send EHLO again to receive fresh
949 # supported commands
950 $smtp->hello();
951 } else {
952 die "Server does not support STARTTLS! ".$smtp->message;
953 }
954 }
955 }
956 if (!$smtp) {
958 die "Unable to initialize SMTP properly. Is there something wrong with your config?";
959 }
960 if (defined $smtp_authuser) {
962 if (!defined $smtp_authpass) {
964 system "stty -echo";
966 do {
968 print "Password: ";
969 $_ = <STDIN>;
970 print "\n";
971 } while (!defined $_);
972 chomp($smtp_authpass = $_);
974 system "stty echo";
976 }
977 $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
979 }
980 $smtp->mail( $raw_from ) or die $smtp->message;
982 $smtp->to( @recipients ) or die $smtp->message;
983 $smtp->data or die $smtp->message;
984 $smtp->datasend("$header\n$message") or die $smtp->message;
985 $smtp->dataend() or die $smtp->message;
986 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
987 }
988 if ($quiet) {
989 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
990 } else {
991 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
992 if ($smtp_server !~ m#^/#) {
993 print "Server: $smtp_server\n";
994 print "MAIL FROM:<$raw_from>\n";
995 foreach my $entry (@recipients) {
996 print "RCPT TO:<$entry>\n";
997 }
998 } else {
999 print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1000 }
1001 print $header, "\n";
1002 if ($smtp) {
1003 print "Result: ", $smtp->code, ' ',
1004 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1005 } else {
1006 print "Result: OK\n";
1007 }
1008 }
1009 return 1;
1011}
1012$reply_to = $initial_reply_to;
1014$references = $initial_reply_to || '';
1015$subject = $initial_subject;
1016$message_num = 0;
1017foreach my $t (@files) {
1019 open(F,"<",$t) or die "can't open file $t";
1020 my $author = undef;
1022 my $author_encoding;
1023 my $has_content_type;
1024 my $body_encoding;
1025 @cc = ();
1026 @xh = ();
1027 my $input_format = undef;
1028 my @header = ();
1029 $message = "";
1030 $message_num++;
1031 # First unfold multiline header fields
1032 while(<F>) {
1033 last if /^\s*$/;
1034 if (/^\s+\S/ and @header) {
1035 chomp($header[$#header]);
1036 s/^\s+/ /;
1037 $header[$#header] .= $_;
1038 } else {
1039 push(@header, $_);
1040 }
1041 }
1042 # Now parse the header
1043 foreach(@header) {
1044 if (/^From /) {
1045 $input_format = 'mbox';
1046 next;
1047 }
1048 chomp;
1049 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1050 $input_format = 'mbox';
1051 }
1052 if (defined $input_format && $input_format eq 'mbox') {
1054 if (/^Subject:\s+(.*)$/) {
1055 $subject = $1;
1056 }
1057 elsif (/^From:\s+(.*)$/) {
1058 ($author, $author_encoding) = unquote_rfc2047($1);
1059 next if $suppress_cc{'author'};
1060 next if $suppress_cc{'self'} and $author eq $sender;
1061 printf("(mbox) Adding cc: %s from line '%s'\n",
1062 $1, $_) unless $quiet;
1063 push @cc, $1;
1064 }
1065 elsif (/^Cc:\s+(.*)$/) {
1066 foreach my $addr (parse_address_line($1)) {
1067 if (unquote_rfc2047($addr) eq $sender) {
1068 next if ($suppress_cc{'self'});
1069 } else {
1070 next if ($suppress_cc{'cc'});
1071 }
1072 printf("(mbox) Adding cc: %s from line '%s'\n",
1073 $addr, $_) unless $quiet;
1074 push @cc, $addr;
1075 }
1076 }
1077 elsif (/^Content-type:/i) {
1078 $has_content_type = 1;
1079 if (/charset="?([^ "]+)/) {
1080 $body_encoding = $1;
1081 }
1082 push @xh, $_;
1083 }
1084 elsif (/^Message-Id: (.*)/i) {
1085 $message_id = $1;
1086 }
1087 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1088 push @xh, $_;
1089 }
1090 } else {
1092 # In the traditional
1093 # "send lots of email" format,
1094 # line 1 = cc
1095 # line 2 = subject
1096 # So let's support that, too.
1097 $input_format = 'lots';
1098 if (@cc == 0 && !$suppress_cc{'cc'}) {
1099 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1100 $_, $_) unless $quiet;
1101 push @cc, $_;
1102 } elsif (!defined $subject) {
1103 $subject = $_;
1104 }
1105 }
1106 }
1107 # Now parse the message body
1108 while(<F>) {
1109 $message .= $_;
1110 if (/^(Signed-off-by|Cc): (.*)$/i) {
1111 chomp;
1112 my ($what, $c) = ($1, $2);
1113 chomp $c;
1114 if ($c eq $sender) {
1115 next if ($suppress_cc{'self'});
1116 } else {
1117 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1118 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1119 }
1120 push @cc, $c;
1121 printf("(body) Adding cc: %s from line '%s'\n",
1122 $c, $_) unless $quiet;
1123 }
1124 }
1125 close F;
1126 if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1128 open(F, "$cc_cmd \Q$t\E |")
1129 or die "(cc-cmd) Could not execute '$cc_cmd'";
1130 while(<F>) {
1131 my $c = $_;
1132 $c =~ s/^\s*//g;
1133 $c =~ s/\n$//g;
1134 next if ($c eq $sender and $suppress_from);
1135 push @cc, $c;
1136 printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1137 $c, $cc_cmd) unless $quiet;
1138 }
1139 close F
1140 or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1141 }
1142 if (defined $author and $author ne $sender) {
1144 $message = "From: $author\n\n$message";
1145 if (defined $author_encoding) {
1146 if ($has_content_type) {
1147 if ($body_encoding eq $author_encoding) {
1148 # ok, we already have the right encoding
1149 }
1150 else {
1151 # uh oh, we should re-encode
1152 }
1153 }
1154 else {
1155 push @xh,
1156 'MIME-Version: 1.0',
1157 "Content-Type: text/plain; charset=$author_encoding",
1158 'Content-Transfer-Encoding: 8bit';
1159 }
1160 }
1161 }
1162 $needs_confirm = (
1164 $confirm eq "always" or
1165 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1166 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1167 $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1168 @cc = (@initial_cc, @cc);
1170 my $message_was_sent = send_message();
1172 # set up for the next message
1174 if ($thread && $message_was_sent &&
1175 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1176 $reply_to = $message_id;
1177 if (length $references > 0) {
1178 $references .= "\n $message_id";
1179 } else {
1180 $references = "$message_id";
1181 }
1182 }
1183 $message_id = undef;
1184}
1185cleanup_compose_files();
1187sub cleanup_compose_files() {
1189 unlink($compose_filename, $compose_filename . ".final") if $compose;
1190}
1191$smtp->quit if $smtp;
1193sub unique_email_list(@) {
1195 my %seen;
1196 my @emails;
1197 foreach my $entry (@_) {
1199 if (my $clean = extract_valid_address($entry)) {
1200 $seen{$clean} ||= 0;
1201 next if $seen{$clean}++;
1202 push @emails, $entry;
1203 } else {
1204 print STDERR "W: unable to extract a valid address",
1205 " from: $entry\n";
1206 }
1207 }
1208 return @emails;
1209}
1210sub validate_patch {
1212 my $fn = shift;
1213 open(my $fh, '<', $fn)
1214 or die "unable to open $fn: $!\n";
1215 while (my $line = <$fh>) {
1216 if (length($line) > 998) {
1217 return "$.: patch contains a line longer than 998 characters";
1218 }
1219 }
1220 return undef;
1221}
1222sub file_has_nonascii {
1224 my $fn = shift;
1225 open(my $fh, '<', $fn)
1226 or die "unable to open $fn: $!\n";
1227 while (my $line = <$fh>) {
1228 return 1 if $line =~ /[^[:ascii:]]/;
1229 }
1230 return 0;
1231}