Andrew's git - gitweb.git/blob - gitweb/gitweb.perl

   1#!/usr/bin/perl
   2
   3# gitweb - simple web interface to track changes in git repositories
   4#
   5# (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6# (C) 2005, Christian Gierke
   7#
   8# This program is licensed under the GPLv2
   9
  10use 5.008;
  11use strict;
  12use warnings;
  13use CGI qw(:standard :escapeHTML -nosticky);
  14use CGI::Util qw(unescape);
  15use CGI::Carp qw(fatalsToBrowser set_message);
  16use Encode;
  17use Fcntl ':mode';
  18use File::Find qw();
  19use File::Basename qw(basename);
  20use Time::HiRes qw(gettimeofday tv_interval);
  21binmode STDOUT, ':utf8';
  22
  23our $t0 = [ gettimeofday() ];
  24our $number_of_git_cmds = 0;
  25
  26BEGIN {
  27        CGI->compile() if $ENV{'MOD_PERL'};
  28}
  29
  30our $version = "++GIT_VERSION++";
  31
  32our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33sub evaluate_uri {
  34        our $cgi;
  35
  36        our $my_url = $cgi->url();
  37        our $my_uri = $cgi->url(-absolute => 1);
  38
  39        # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40        # needed and used only for URLs with nonempty PATH_INFO
  41        our $base_url = $my_url;
  42
  43        # When the script is used as DirectoryIndex, the URL does not contain the name
  44        # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45        # have to do it ourselves. We make $path_info global because it's also used
  46        # later on.
  47        #
  48        # Another issue with the script being the DirectoryIndex is that the resulting
  49        # $my_url data is not the full script URL: this is good, because we want
  50        # generated links to keep implying the script name if it wasn't explicitly
  51        # indicated in the URL we're handling, but it means that $my_url cannot be used
  52        # as base URL.
  53        # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54        # to build the base URL ourselves:
  55        our $path_info = decode_utf8($ENV{"PATH_INFO"});
  56        if ($path_info) {
  57                if ($my_url =~ s,\Q$path_info\E$,, &&
  58                    $my_uri =~ s,\Q$path_info\E$,, &&
  59                    defined $ENV{'SCRIPT_NAME'}) {
  60                        $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                }
  62        }
  63
  64        # target of the home link on top of all pages
  65        our $home_link = $my_uri || "/";
  66}
  67
  68# core git executable to use
  69# this can just be "git" if your webserver has a sensible PATH
  70our $GIT = "++GIT_BINDIR++/git";
  71
  72# absolute fs-path which will be prepended to the project path
  73#our $projectroot = "/pub/scm";
  74our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76# fs traversing limit for getting project list
  77# the number is relative to the projectroot
  78our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80# string of the home link on top of all pages
  81our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83# name of your site or organization to appear in page titles
  84# replace this with something more descriptive for clearer bookmarks
  85our $site_name = "++GITWEB_SITENAME++"
  86                 || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88# html snippet to include in the <head> section of each page
  89our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90# filename of html text to include at top of each page
  91our $site_header = "++GITWEB_SITE_HEADER++";
  92# html text to include at home page
  93our $home_text = "++GITWEB_HOMETEXT++";
  94# filename of html text to include at bottom of each page
  95our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97# URI of stylesheets
  98our @stylesheets = ("++GITWEB_CSS++");
  99# URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100our $stylesheet = undef;
 101# URI of GIT logo (72x27 size)
 102our $logo = "++GITWEB_LOGO++";
 103# URI of GIT favicon, assumed to be image/png type
 104our $favicon = "++GITWEB_FAVICON++";
 105# URI of gitweb.js (JavaScript code for gitweb)
 106our $javascript = "++GITWEB_JS++";
 107
 108# URI and label (title) of GIT logo link
 109#our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 110#our $logo_label = "git documentation";
 111our $logo_url = "http://git-scm.com/";
 112our $logo_label = "git homepage";
 113
 114# source of projects list
 115our $projects_list = "++GITWEB_LIST++";
 116
 117# the width (in characters) of the projects list "Description" column
 118our $projects_list_description_width = 25;
 119
 120# group projects by category on the projects list
 121# (enabled if this variable evaluates to true)
 122our $projects_list_group_categories = 0;
 123
 124# default category if none specified
 125# (leave the empty string for no category)
 126our $project_list_default_category = "";
 127
 128# default order of projects list
 129# valid values are none, project, descr, owner, and age
 130our $default_projects_order = "project";
 131
 132# show repository only if this file exists
 133# (only effective if this variable evaluates to true)
 134our $export_ok = "++GITWEB_EXPORT_OK++";
 135
 136# show repository only if this subroutine returns true
 137# when given the path to the project, for example:
 138#    sub { return -e "$_[0]/git-daemon-export-ok"; }
 139our $export_auth_hook = undef;
 140
 141# only allow viewing of repositories also shown on the overview page
 142our $strict_export = "++GITWEB_STRICT_EXPORT++";
 143
 144# list of git base URLs used for URL to where fetch project from,
 145# i.e. full URL is "$git_base_url/$project"
 146our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 147
 148# default blob_plain mimetype and default charset for text/plain blob
 149our $default_blob_plain_mimetype = 'text/plain';
 150our $default_text_plain_charset  = undef;
 151
 152# file to use for guessing MIME types before trying /etc/mime.types
 153# (relative to the current git repository)
 154our $mimetypes_file = undef;
 155
 156# assume this charset if line contains non-UTF-8 characters;
 157# it should be valid encoding (see Encoding::Supported(3pm) for list),
 158# for which encoding all byte sequences are valid, for example
 159# 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 160# could be even 'utf-8' for the old behavior)
 161our $fallback_encoding = 'latin1';
 162
 163# rename detection options for git-diff and git-diff-tree
 164# - default is '-M', with the cost proportional to
 165#   (number of removed files) * (number of new files).
 166# - more costly is '-C' (which implies '-M'), with the cost proportional to
 167#   (number of changed files + number of removed files) * (number of new files)
 168# - even more costly is '-C', '--find-copies-harder' with cost
 169#   (number of files in the original tree) * (number of new files)
 170# - one might want to include '-B' option, e.g. '-B', '-M'
 171our @diff_opts = ('-M'); # taken from git_commit
 172
 173# Disables features that would allow repository owners to inject script into
 174# the gitweb domain.
 175our $prevent_xss = 0;
 176
 177# Path to the highlight executable to use (must be the one from
 178# http://www.andre-simon.de due to assumptions about parameters and output).
 179# Useful if highlight is not installed on your webserver's PATH.
 180# [Default: highlight]
 181our $highlight_bin = "++HIGHLIGHT_BIN++";
 182
 183# information about snapshot formats that gitweb is capable of serving
 184our %known_snapshot_formats = (
 185        # name => {
 186        #       'display' => display name,
 187        #       'type' => mime type,
 188        #       'suffix' => filename suffix,
 189        #       'format' => --format for git-archive,
 190        #       'compressor' => [compressor command and arguments]
 191        #                       (array reference, optional)
 192        #       'disabled' => boolean (optional)}
 193        #
 194        'tgz' => {
 195                'display' => 'tar.gz',
 196                'type' => 'application/x-gzip',
 197                'suffix' => '.tar.gz',
 198                'format' => 'tar',
 199                'compressor' => ['gzip', '-n']},
 200
 201        'tbz2' => {
 202                'display' => 'tar.bz2',
 203                'type' => 'application/x-bzip2',
 204                'suffix' => '.tar.bz2',
 205                'format' => 'tar',
 206                'compressor' => ['bzip2']},
 207
 208        'txz' => {
 209                'display' => 'tar.xz',
 210                'type' => 'application/x-xz',
 211                'suffix' => '.tar.xz',
 212                'format' => 'tar',
 213                'compressor' => ['xz'],
 214                'disabled' => 1},
 215
 216        'zip' => {
 217                'display' => 'zip',
 218                'type' => 'application/x-zip',
 219                'suffix' => '.zip',
 220                'format' => 'zip'},
 221);
 222
 223# Aliases so we understand old gitweb.snapshot values in repository
 224# configuration.
 225our %known_snapshot_format_aliases = (
 226        'gzip'  => 'tgz',
 227        'bzip2' => 'tbz2',
 228        'xz'    => 'txz',
 229
 230        # backward compatibility: legacy gitweb config support
 231        'x-gzip' => undef, 'gz' => undef,
 232        'x-bzip2' => undef, 'bz2' => undef,
 233        'x-zip' => undef, '' => undef,
 234);
 235
 236# Pixel sizes for icons and avatars. If the default font sizes or lineheights
 237# are changed, it may be appropriate to change these values too via
 238# $GITWEB_CONFIG.
 239our %avatar_size = (
 240        'default' => 16,
 241        'double'  => 32
 242);
 243
 244# Used to set the maximum load that we will still respond to gitweb queries.
 245# If server load exceed this value then return "503 server busy" error.
 246# If gitweb cannot determined server load, it is taken to be 0.
 247# Leave it undefined (or set to 'undef') to turn off load checking.
 248our $maxload = 300;
 249
 250# configuration for 'highlight' (http://www.andre-simon.de/)
 251# match by basename
 252our %highlight_basename = (
 253        #'Program' => 'py',
 254        #'Library' => 'py',
 255        'SConstruct' => 'py', # SCons equivalent of Makefile
 256        'Makefile' => 'make',
 257);
 258# match by extension
 259our %highlight_ext = (
 260        # main extensions, defining name of syntax;
 261        # see files in /usr/share/highlight/langDefs/ directory
 262        map { $_ => $_ }
 263                qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 264        # alternate extensions, see /etc/highlight/filetypes.conf
 265        'h' => 'c',
 266        map { $_ => 'sh'  } qw(bash zsh ksh),
 267        map { $_ => 'cpp' } qw(cxx c++ cc),
 268        map { $_ => 'php' } qw(php3 php4 php5 phps),
 269        map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 270        map { $_ => 'make'} qw(mak mk),
 271        map { $_ => 'xml' } qw(xhtml html htm),
 272);
 273
 274# You define site-wide feature defaults here; override them with
 275# $GITWEB_CONFIG as necessary.
 276our %feature = (
 277        # feature => {
 278        #       'sub' => feature-sub (subroutine),
 279        #       'override' => allow-override (boolean),
 280        #       'default' => [ default options...] (array reference)}
 281        #
 282        # if feature is overridable (it means that allow-override has true value),
 283        # then feature-sub will be called with default options as parameters;
 284        # return value of feature-sub indicates if to enable specified feature
 285        #
 286        # if there is no 'sub' key (no feature-sub), then feature cannot be
 287        # overridden
 288        #
 289        # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 290        # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 291        # is enabled
 292
 293        # Enable the 'blame' blob view, showing the last commit that modified
 294        # each line in the file. This can be very CPU-intensive.
 295
 296        # To enable system wide have in $GITWEB_CONFIG
 297        # $feature{'blame'}{'default'} = [1];
 298        # To have project specific config enable override in $GITWEB_CONFIG
 299        # $feature{'blame'}{'override'} = 1;
 300        # and in project config gitweb.blame = 0|1;
 301        'blame' => {
 302                'sub' => sub { feature_bool('blame', @_) },
 303                'override' => 0,
 304                'default' => [0]},
 305
 306        # Enable the 'snapshot' link, providing a compressed archive of any
 307        # tree. This can potentially generate high traffic if you have large
 308        # project.
 309
 310        # Value is a list of formats defined in %known_snapshot_formats that
 311        # you wish to offer.
 312        # To disable system wide have in $GITWEB_CONFIG
 313        # $feature{'snapshot'}{'default'} = [];
 314        # To have project specific config enable override in $GITWEB_CONFIG
 315        # $feature{'snapshot'}{'override'} = 1;
 316        # and in project config, a comma-separated list of formats or "none"
 317        # to disable.  Example: gitweb.snapshot = tbz2,zip;
 318        'snapshot' => {
 319                'sub' => \&feature_snapshot,
 320                'override' => 0,
 321                'default' => ['tgz']},
 322
 323        # Enable text search, which will list the commits which match author,
 324        # committer or commit text to a given string.  Enabled by default.
 325        # Project specific override is not supported.
 326        #
 327        # Note that this controls all search features, which means that if
 328        # it is disabled, then 'grep' and 'pickaxe' search would also be
 329        # disabled.
 330        'search' => {
 331                'override' => 0,
 332                'default' => [1]},
 333
 334        # Enable grep search, which will list the files in currently selected
 335        # tree containing the given string. Enabled by default. This can be
 336        # potentially CPU-intensive, of course.
 337        # Note that you need to have 'search' feature enabled too.
 338
 339        # To enable system wide have in $GITWEB_CONFIG
 340        # $feature{'grep'}{'default'} = [1];
 341        # To have project specific config enable override in $GITWEB_CONFIG
 342        # $feature{'grep'}{'override'} = 1;
 343        # and in project config gitweb.grep = 0|1;
 344        'grep' => {
 345                'sub' => sub { feature_bool('grep', @_) },
 346                'override' => 0,
 347                'default' => [1]},
 348
 349        # Enable the pickaxe search, which will list the commits that modified
 350        # a given string in a file. This can be practical and quite faster
 351        # alternative to 'blame', but still potentially CPU-intensive.
 352        # Note that you need to have 'search' feature enabled too.
 353
 354        # To enable system wide have in $GITWEB_CONFIG
 355        # $feature{'pickaxe'}{'default'} = [1];
 356        # To have project specific config enable override in $GITWEB_CONFIG
 357        # $feature{'pickaxe'}{'override'} = 1;
 358        # and in project config gitweb.pickaxe = 0|1;
 359        'pickaxe' => {
 360                'sub' => sub { feature_bool('pickaxe', @_) },
 361                'override' => 0,
 362                'default' => [1]},
 363
 364        # Enable showing size of blobs in a 'tree' view, in a separate
 365        # column, similar to what 'ls -l' does.  This cost a bit of IO.
 366
 367        # To disable system wide have in $GITWEB_CONFIG
 368        # $feature{'show-sizes'}{'default'} = [0];
 369        # To have project specific config enable override in $GITWEB_CONFIG
 370        # $feature{'show-sizes'}{'override'} = 1;
 371        # and in project config gitweb.showsizes = 0|1;
 372        'show-sizes' => {
 373                'sub' => sub { feature_bool('showsizes', @_) },
 374                'override' => 0,
 375                'default' => [1]},
 376
 377        # Make gitweb use an alternative format of the URLs which can be
 378        # more readable and natural-looking: project name is embedded
 379        # directly in the path and the query string contains other
 380        # auxiliary information. All gitweb installations recognize
 381        # URL in either format; this configures in which formats gitweb
 382        # generates links.
 383
 384        # To enable system wide have in $GITWEB_CONFIG
 385        # $feature{'pathinfo'}{'default'} = [1];
 386        # Project specific override is not supported.
 387
 388        # Note that you will need to change the default location of CSS,
 389        # favicon, logo and possibly other files to an absolute URL. Also,
 390        # if gitweb.cgi serves as your indexfile, you will need to force
 391        # $my_uri to contain the script name in your $GITWEB_CONFIG.
 392        'pathinfo' => {
 393                'override' => 0,
 394                'default' => [0]},
 395
 396        # Make gitweb consider projects in project root subdirectories
 397        # to be forks of existing projects. Given project $projname.git,
 398        # projects matching $projname/*.git will not be shown in the main
 399        # projects list, instead a '+' mark will be added to $projname
 400        # there and a 'forks' view will be enabled for the project, listing
 401        # all the forks. If project list is taken from a file, forks have
 402        # to be listed after the main project.
 403
 404        # To enable system wide have in $GITWEB_CONFIG
 405        # $feature{'forks'}{'default'} = [1];
 406        # Project specific override is not supported.
 407        'forks' => {
 408                'override' => 0,
 409                'default' => [0]},
 410
 411        # Insert custom links to the action bar of all project pages.
 412        # This enables you mainly to link to third-party scripts integrating
 413        # into gitweb; e.g. git-browser for graphical history representation
 414        # or custom web-based repository administration interface.
 415
 416        # The 'default' value consists of a list of triplets in the form
 417        # (label, link, position) where position is the label after which
 418        # to insert the link and link is a format string where %n expands
 419        # to the project name, %f to the project path within the filesystem,
 420        # %h to the current hash (h gitweb parameter) and %b to the current
 421        # hash base (hb gitweb parameter); %% expands to %.
 422
 423        # To enable system wide have in $GITWEB_CONFIG e.g.
 424        # $feature{'actions'}{'default'} = [('graphiclog',
 425        #       '/git-browser/by-commit.html?r=%n', 'summary')];
 426        # Project specific override is not supported.
 427        'actions' => {
 428                'override' => 0,
 429                'default' => []},
 430
 431        # Allow gitweb scan project content tags of project repository,
 432        # and display the popular Web 2.0-ish "tag cloud" near the projects
 433        # list.  Note that this is something COMPLETELY different from the
 434        # normal Git tags.
 435
 436        # gitweb by itself can show existing tags, but it does not handle
 437        # tagging itself; you need to do it externally, outside gitweb.
 438        # The format is described in git_get_project_ctags() subroutine.
 439        # You may want to install the HTML::TagCloud Perl module to get
 440        # a pretty tag cloud instead of just a list of tags.
 441
 442        # To enable system wide have in $GITWEB_CONFIG
 443        # $feature{'ctags'}{'default'} = [1];
 444        # Project specific override is not supported.
 445
 446        # In the future whether ctags editing is enabled might depend
 447        # on the value, but using 1 should always mean no editing of ctags.
 448        'ctags' => {
 449                'override' => 0,
 450                'default' => [0]},
 451
 452        # The maximum number of patches in a patchset generated in patch
 453        # view. Set this to 0 or undef to disable patch view, or to a
 454        # negative number to remove any limit.
 455
 456        # To disable system wide have in $GITWEB_CONFIG
 457        # $feature{'patches'}{'default'} = [0];
 458        # To have project specific config enable override in $GITWEB_CONFIG
 459        # $feature{'patches'}{'override'} = 1;
 460        # and in project config gitweb.patches = 0|n;
 461        # where n is the maximum number of patches allowed in a patchset.
 462        'patches' => {
 463                'sub' => \&feature_patches,
 464                'override' => 0,
 465                'default' => [16]},
 466
 467        # Avatar support. When this feature is enabled, views such as
 468        # shortlog or commit will display an avatar associated with
 469        # the email of the committer(s) and/or author(s).
 470
 471        # Currently available providers are gravatar and picon.
 472        # If an unknown provider is specified, the feature is disabled.
 473
 474        # Gravatar depends on Digest::MD5.
 475        # Picon currently relies on the indiana.edu database.
 476
 477        # To enable system wide have in $GITWEB_CONFIG
 478        # $feature{'avatar'}{'default'} = ['<provider>'];
 479        # where <provider> is either gravatar or picon.
 480        # To have project specific config enable override in $GITWEB_CONFIG
 481        # $feature{'avatar'}{'override'} = 1;
 482        # and in project config gitweb.avatar = <provider>;
 483        'avatar' => {
 484                'sub' => \&feature_avatar,
 485                'override' => 0,
 486                'default' => ['']},
 487
 488        # Enable displaying how much time and how many git commands
 489        # it took to generate and display page.  Disabled by default.
 490        # Project specific override is not supported.
 491        'timed' => {
 492                'override' => 0,
 493                'default' => [0]},
 494
 495        # Enable turning some links into links to actions which require
 496        # JavaScript to run (like 'blame_incremental').  Not enabled by
 497        # default.  Project specific override is currently not supported.
 498        'javascript-actions' => {
 499                'override' => 0,
 500                'default' => [0]},
 501
 502        # Enable and configure ability to change common timezone for dates
 503        # in gitweb output via JavaScript.  Enabled by default.
 504        # Project specific override is not supported.
 505        'javascript-timezone' => {
 506                'override' => 0,
 507                'default' => [
 508                        'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 509                                     # or undef to turn off this feature
 510                        'gitweb_tz', # name of cookie where to store selected timezone
 511                        'datetime',  # CSS class used to mark up dates for manipulation
 512                ]},
 513
 514        # Syntax highlighting support. This is based on Daniel Svensson's
 515        # and Sham Chukoury's work in gitweb-xmms2.git.
 516        # It requires the 'highlight' program present in $PATH,
 517        # and therefore is disabled by default.
 518
 519        # To enable system wide have in $GITWEB_CONFIG
 520        # $feature{'highlight'}{'default'} = [1];
 521
 522        'highlight' => {
 523                'sub' => sub { feature_bool('highlight', @_) },
 524                'override' => 0,
 525                'default' => [0]},
 526
 527        # Enable displaying of remote heads in the heads list
 528
 529        # To enable system wide have in $GITWEB_CONFIG
 530        # $feature{'remote_heads'}{'default'} = [1];
 531        # To have project specific config enable override in $GITWEB_CONFIG
 532        # $feature{'remote_heads'}{'override'} = 1;
 533        # and in project config gitweb.remote_heads = 0|1;
 534        'remote_heads' => {
 535                'sub' => sub { feature_bool('remote_heads', @_) },
 536                'override' => 0,
 537                'default' => [0]},
 538);
 539
 540sub gitweb_get_feature {
 541        my ($name) = @_;
 542        return unless exists $feature{$name};
 543        my ($sub, $override, @defaults) = (
 544                $feature{$name}{'sub'},
 545                $feature{$name}{'override'},
 546                @{$feature{$name}{'default'}});
 547        # project specific override is possible only if we have project
 548        our $git_dir; # global variable, declared later
 549        if (!$override || !defined $git_dir) {
 550                return @defaults;
 551        }
 552        if (!defined $sub) {
 553                warn "feature $name is not overridable";
 554                return @defaults;
 555        }
 556        return $sub->(@defaults);
 557}
 558
 559# A wrapper to check if a given feature is enabled.
 560# With this, you can say
 561#
 562#   my $bool_feat = gitweb_check_feature('bool_feat');
 563#   gitweb_check_feature('bool_feat') or somecode;
 564#
 565# instead of
 566#
 567#   my ($bool_feat) = gitweb_get_feature('bool_feat');
 568#   (gitweb_get_feature('bool_feat'))[0] or somecode;
 569#
 570sub gitweb_check_feature {
 571        return (gitweb_get_feature(@_))[0];
 572}
 573
 574
 575sub feature_bool {
 576        my $key = shift;
 577        my ($val) = git_get_project_config($key, '--bool');
 578
 579        if (!defined $val) {
 580                return ($_[0]);
 581        } elsif ($val eq 'true') {
 582                return (1);
 583        } elsif ($val eq 'false') {
 584                return (0);
 585        }
 586}
 587
 588sub feature_snapshot {
 589        my (@fmts) = @_;
 590
 591        my ($val) = git_get_project_config('snapshot');
 592
 593        if ($val) {
 594                @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 595        }
 596
 597        return @fmts;
 598}
 599
 600sub feature_patches {
 601        my @val = (git_get_project_config('patches', '--int'));
 602
 603        if (@val) {
 604                return @val;
 605        }
 606
 607        return ($_[0]);
 608}
 609
 610sub feature_avatar {
 611        my @val = (git_get_project_config('avatar'));
 612
 613        return @val ? @val : @_;
 614}
 615
 616# checking HEAD file with -e is fragile if the repository was
 617# initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 618# and then pruned.
 619sub check_head_link {
 620        my ($dir) = @_;
 621        my $headfile = "$dir/HEAD";
 622        return ((-e $headfile) ||
 623                (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 624}
 625
 626sub check_export_ok {
 627        my ($dir) = @_;
 628        return (check_head_link($dir) &&
 629                (!$export_ok || -e "$dir/$export_ok") &&
 630                (!$export_auth_hook || $export_auth_hook->($dir)));
 631}
 632
 633# process alternate names for backward compatibility
 634# filter out unsupported (unknown) snapshot formats
 635sub filter_snapshot_fmts {
 636        my @fmts = @_;
 637
 638        @fmts = map {
 639                exists $known_snapshot_format_aliases{$_} ?
 640                       $known_snapshot_format_aliases{$_} : $_} @fmts;
 641        @fmts = grep {
 642                exists $known_snapshot_formats{$_} &&
 643                !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 644}
 645
 646# If it is set to code reference, it is code that it is to be run once per
 647# request, allowing updating configurations that change with each request,
 648# while running other code in config file only once.
 649#
 650# Otherwise, if it is false then gitweb would process config file only once;
 651# if it is true then gitweb config would be run for each request.
 652our $per_request_config = 1;
 653
 654# read and parse gitweb config file given by its parameter.
 655# returns true on success, false on recoverable error, allowing
 656# to chain this subroutine, using first file that exists.
 657# dies on errors during parsing config file, as it is unrecoverable.
 658sub read_config_file {
 659        my $filename = shift;
 660        return unless defined $filename;
 661        # die if there are errors parsing config file
 662        if (-e $filename) {
 663                do $filename;
 664                die $@ if $@;
 665                return 1;
 666        }
 667        return;
 668}
 669
 670our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 671sub evaluate_gitweb_config {
 672        our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 673        our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 674        our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 675
 676        # Protect agains duplications of file names, to not read config twice.
 677        # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 678        # there possibility of duplication of filename there doesn't matter.
 679        $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 680        $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 681
 682        # Common system-wide settings for convenience.
 683        # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 684        read_config_file($GITWEB_CONFIG_COMMON);
 685
 686        # Use first config file that exists.  This means use the per-instance
 687        # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 688        read_config_file($GITWEB_CONFIG) and return;
 689        read_config_file($GITWEB_CONFIG_SYSTEM);
 690}
 691
 692# Get loadavg of system, to compare against $maxload.
 693# Currently it requires '/proc/loadavg' present to get loadavg;
 694# if it is not present it returns 0, which means no load checking.
 695sub get_loadavg {
 696        if( -e '/proc/loadavg' ){
 697                open my $fd, '<', '/proc/loadavg'
 698                        or return 0;
 699                my @load = split(/\s+/, scalar <$fd>);
 700                close $fd;
 701
 702                # The first three columns measure CPU and IO utilization of the last one,
 703                # five, and 10 minute periods.  The fourth column shows the number of
 704                # currently running processes and the total number of processes in the m/n
 705                # format.  The last column displays the last process ID used.
 706                return $load[0] || 0;
 707        }
 708        # additional checks for load average should go here for things that don't export
 709        # /proc/loadavg
 710
 711        return 0;
 712}
 713
 714# version of the core git binary
 715our $git_version;
 716sub evaluate_git_version {
 717        our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 718        $number_of_git_cmds++;
 719}
 720
 721sub check_loadavg {
 722        if (defined $maxload && get_loadavg() > $maxload) {
 723                die_error(503, "The load average on the server is too high");
 724        }
 725}
 726
 727# ======================================================================
 728# input validation and dispatch
 729
 730# input parameters can be collected from a variety of sources (presently, CGI
 731# and PATH_INFO), so we define an %input_params hash that collects them all
 732# together during validation: this allows subsequent uses (e.g. href()) to be
 733# agnostic of the parameter origin
 734
 735our %input_params = ();
 736
 737# input parameters are stored with the long parameter name as key. This will
 738# also be used in the href subroutine to convert parameters to their CGI
 739# equivalent, and since the href() usage is the most frequent one, we store
 740# the name -> CGI key mapping here, instead of the reverse.
 741#
 742# XXX: Warning: If you touch this, check the search form for updating,
 743# too.
 744
 745our @cgi_param_mapping = (
 746        project => "p",
 747        action => "a",
 748        file_name => "f",
 749        file_parent => "fp",
 750        hash => "h",
 751        hash_parent => "hp",
 752        hash_base => "hb",
 753        hash_parent_base => "hpb",
 754        page => "pg",
 755        order => "o",
 756        searchtext => "s",
 757        searchtype => "st",
 758        snapshot_format => "sf",
 759        extra_options => "opt",
 760        search_use_regexp => "sr",
 761        ctag => "by_tag",
 762        diff_style => "ds",
 763        project_filter => "pf",
 764        # this must be last entry (for manipulation from JavaScript)
 765        javascript => "js"
 766);
 767our %cgi_param_mapping = @cgi_param_mapping;
 768
 769# we will also need to know the possible actions, for validation
 770our %actions = (
 771        "blame" => \&git_blame,
 772        "blame_incremental" => \&git_blame_incremental,
 773        "blame_data" => \&git_blame_data,
 774        "blobdiff" => \&git_blobdiff,
 775        "blobdiff_plain" => \&git_blobdiff_plain,
 776        "blob" => \&git_blob,
 777        "blob_plain" => \&git_blob_plain,
 778        "commitdiff" => \&git_commitdiff,
 779        "commitdiff_plain" => \&git_commitdiff_plain,
 780        "commit" => \&git_commit,
 781        "forks" => \&git_forks,
 782        "heads" => \&git_heads,
 783        "history" => \&git_history,
 784        "log" => \&git_log,
 785        "patch" => \&git_patch,
 786        "patches" => \&git_patches,
 787        "remotes" => \&git_remotes,
 788        "rss" => \&git_rss,
 789        "atom" => \&git_atom,
 790        "search" => \&git_search,
 791        "search_help" => \&git_search_help,
 792        "shortlog" => \&git_shortlog,
 793        "summary" => \&git_summary,
 794        "tag" => \&git_tag,
 795        "tags" => \&git_tags,
 796        "tree" => \&git_tree,
 797        "snapshot" => \&git_snapshot,
 798        "object" => \&git_object,
 799        # those below don't need $project
 800        "opml" => \&git_opml,
 801        "project_list" => \&git_project_list,
 802        "project_index" => \&git_project_index,
 803);
 804
 805# finally, we have the hash of allowed extra_options for the commands that
 806# allow them
 807our %allowed_options = (
 808        "--no-merges" => [ qw(rss atom log shortlog history) ],
 809);
 810
 811# fill %input_params with the CGI parameters. All values except for 'opt'
 812# should be single values, but opt can be an array. We should probably
 813# build an array of parameters that can be multi-valued, but since for the time
 814# being it's only this one, we just single it out
 815sub evaluate_query_params {
 816        our $cgi;
 817
 818        while (my ($name, $symbol) = each %cgi_param_mapping) {
 819                if ($symbol eq 'opt') {
 820                        $input_params{$name} = [ map { decode_utf8($_) } $cgi->param($symbol) ];
 821                } else {
 822                        $input_params{$name} = decode_utf8($cgi->param($symbol));
 823                }
 824        }
 825}
 826
 827# now read PATH_INFO and update the parameter list for missing parameters
 828sub evaluate_path_info {
 829        return if defined $input_params{'project'};
 830        return if !$path_info;
 831        $path_info =~ s,^/+,,;
 832        return if !$path_info;
 833
 834        # find which part of PATH_INFO is project
 835        my $project = $path_info;
 836        $project =~ s,/+$,,;
 837        while ($project && !check_head_link("$projectroot/$project")) {
 838                $project =~ s,/*[^/]*$,,;
 839        }
 840        return unless $project;
 841        $input_params{'project'} = $project;
 842
 843        # do not change any parameters if an action is given using the query string
 844        return if $input_params{'action'};
 845        $path_info =~ s,^\Q$project\E/*,,;
 846
 847        # next, check if we have an action
 848        my $action = $path_info;
 849        $action =~ s,/.*$,,;
 850        if (exists $actions{$action}) {
 851                $path_info =~ s,^$action/*,,;
 852                $input_params{'action'} = $action;
 853        }
 854
 855        # list of actions that want hash_base instead of hash, but can have no
 856        # pathname (f) parameter
 857        my @wants_base = (
 858                'tree',
 859                'history',
 860        );
 861
 862        # we want to catch, among others
 863        # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 864        my ($parentrefname, $parentpathname, $refname, $pathname) =
 865                ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 866
 867        # first, analyze the 'current' part
 868        if (defined $pathname) {
 869                # we got "branch:filename" or "branch:dir/"
 870                # we could use git_get_type(branch:pathname), but:
 871                # - it needs $git_dir
 872                # - it does a git() call
 873                # - the convention of terminating directories with a slash
 874                #   makes it superfluous
 875                # - embedding the action in the PATH_INFO would make it even
 876                #   more superfluous
 877                $pathname =~ s,^/+,,;
 878                if (!$pathname || substr($pathname, -1) eq "/") {
 879                        $input_params{'action'} ||= "tree";
 880                        $pathname =~ s,/$,,;
 881                } else {
 882                        # the default action depends on whether we had parent info
 883                        # or not
 884                        if ($parentrefname) {
 885                                $input_params{'action'} ||= "blobdiff_plain";
 886                        } else {
 887                                $input_params{'action'} ||= "blob_plain";
 888                        }
 889                }
 890                $input_params{'hash_base'} ||= $refname;
 891                $input_params{'file_name'} ||= $pathname;
 892        } elsif (defined $refname) {
 893                # we got "branch". In this case we have to choose if we have to
 894                # set hash or hash_base.
 895                #
 896                # Most of the actions without a pathname only want hash to be
 897                # set, except for the ones specified in @wants_base that want
 898                # hash_base instead. It should also be noted that hand-crafted
 899                # links having 'history' as an action and no pathname or hash
 900                # set will fail, but that happens regardless of PATH_INFO.
 901                if (defined $parentrefname) {
 902                        # if there is parent let the default be 'shortlog' action
 903                        # (for http://git.example.com/repo.git/A..B links); if there
 904                        # is no parent, dispatch will detect type of object and set
 905                        # action appropriately if required (if action is not set)
 906                        $input_params{'action'} ||= "shortlog";
 907                }
 908                if ($input_params{'action'} &&
 909                    grep { $_ eq $input_params{'action'} } @wants_base) {
 910                        $input_params{'hash_base'} ||= $refname;
 911                } else {
 912                        $input_params{'hash'} ||= $refname;
 913                }
 914        }
 915
 916        # next, handle the 'parent' part, if present
 917        if (defined $parentrefname) {
 918                # a missing pathspec defaults to the 'current' filename, allowing e.g.
 919                # someproject/blobdiff/oldrev..newrev:/filename
 920                if ($parentpathname) {
 921                        $parentpathname =~ s,^/+,,;
 922                        $parentpathname =~ s,/$,,;
 923                        $input_params{'file_parent'} ||= $parentpathname;
 924                } else {
 925                        $input_params{'file_parent'} ||= $input_params{'file_name'};
 926                }
 927                # we assume that hash_parent_base is wanted if a path was specified,
 928                # or if the action wants hash_base instead of hash
 929                if (defined $input_params{'file_parent'} ||
 930                        grep { $_ eq $input_params{'action'} } @wants_base) {
 931                        $input_params{'hash_parent_base'} ||= $parentrefname;
 932                } else {
 933                        $input_params{'hash_parent'} ||= $parentrefname;
 934                }
 935        }
 936
 937        # for the snapshot action, we allow URLs in the form
 938        # $project/snapshot/$hash.ext
 939        # where .ext determines the snapshot and gets removed from the
 940        # passed $refname to provide the $hash.
 941        #
 942        # To be able to tell that $refname includes the format extension, we
 943        # require the following two conditions to be satisfied:
 944        # - the hash input parameter MUST have been set from the $refname part
 945        #   of the URL (i.e. they must be equal)
 946        # - the snapshot format MUST NOT have been defined already (e.g. from
 947        #   CGI parameter sf)
 948        # It's also useless to try any matching unless $refname has a dot,
 949        # so we check for that too
 950        if (defined $input_params{'action'} &&
 951                $input_params{'action'} eq 'snapshot' &&
 952                defined $refname && index($refname, '.') != -1 &&
 953                $refname eq $input_params{'hash'} &&
 954                !defined $input_params{'snapshot_format'}) {
 955                # We loop over the known snapshot formats, checking for
 956                # extensions. Allowed extensions are both the defined suffix
 957                # (which includes the initial dot already) and the snapshot
 958                # format key itself, with a prepended dot
 959                while (my ($fmt, $opt) = each %known_snapshot_formats) {
 960                        my $hash = $refname;
 961                        unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 962                                next;
 963                        }
 964                        my $sfx = $1;
 965                        # a valid suffix was found, so set the snapshot format
 966                        # and reset the hash parameter
 967                        $input_params{'snapshot_format'} = $fmt;
 968                        $input_params{'hash'} = $hash;
 969                        # we also set the format suffix to the one requested
 970                        # in the URL: this way a request for e.g. .tgz returns
 971                        # a .tgz instead of a .tar.gz
 972                        $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 973                        last;
 974                }
 975        }
 976}
 977
 978our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 979     $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 980     $searchtext, $search_regexp, $project_filter);
 981sub evaluate_and_validate_params {
 982        our $action = $input_params{'action'};
 983        if (defined $action) {
 984                if (!validate_action($action)) {
 985                        die_error(400, "Invalid action parameter");
 986                }
 987        }
 988
 989        # parameters which are pathnames
 990        our $project = $input_params{'project'};
 991        if (defined $project) {
 992                if (!validate_project($project)) {
 993                        undef $project;
 994                        die_error(404, "No such project");
 995                }
 996        }
 997
 998        our $project_filter = $input_params{'project_filter'};
 999        if (defined $project_filter) {
1000                if (!validate_pathname($project_filter)) {
1001                        die_error(404, "Invalid project_filter parameter");
1002                }
1003        }
1004
1005        our $file_name = $input_params{'file_name'};
1006        if (defined $file_name) {
1007                if (!validate_pathname($file_name)) {
1008                        die_error(400, "Invalid file parameter");
1009                }
1010        }
1011
1012        our $file_parent = $input_params{'file_parent'};
1013        if (defined $file_parent) {
1014                if (!validate_pathname($file_parent)) {
1015                        die_error(400, "Invalid file parent parameter");
1016                }
1017        }
1018
1019        # parameters which are refnames
1020        our $hash = $input_params{'hash'};
1021        if (defined $hash) {
1022                if (!validate_refname($hash)) {
1023                        die_error(400, "Invalid hash parameter");
1024                }
1025        }
1026
1027        our $hash_parent = $input_params{'hash_parent'};
1028        if (defined $hash_parent) {
1029                if (!validate_refname($hash_parent)) {
1030                        die_error(400, "Invalid hash parent parameter");
1031                }
1032        }
1033
1034        our $hash_base = $input_params{'hash_base'};
1035        if (defined $hash_base) {
1036                if (!validate_refname($hash_base)) {
1037                        die_error(400, "Invalid hash base parameter");
1038                }
1039        }
1040
1041        our @extra_options = @{$input_params{'extra_options'}};
1042        # @extra_options is always defined, since it can only be (currently) set from
1043        # CGI, and $cgi->param() returns the empty array in array context if the param
1044        # is not set
1045        foreach my $opt (@extra_options) {
1046                if (not exists $allowed_options{$opt}) {
1047                        die_error(400, "Invalid option parameter");
1048                }
1049                if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1050                        die_error(400, "Invalid option parameter for this action");
1051                }
1052        }
1053
1054        our $hash_parent_base = $input_params{'hash_parent_base'};
1055        if (defined $hash_parent_base) {
1056                if (!validate_refname($hash_parent_base)) {
1057                        die_error(400, "Invalid hash parent base parameter");
1058                }
1059        }
1060
1061        # other parameters
1062        our $page = $input_params{'page'};
1063        if (defined $page) {
1064                if ($page =~ m/[^0-9]/) {
1065                        die_error(400, "Invalid page parameter");
1066                }
1067        }
1068
1069        our $searchtype = $input_params{'searchtype'};
1070        if (defined $searchtype) {
1071                if ($searchtype =~ m/[^a-z]/) {
1072                        die_error(400, "Invalid searchtype parameter");
1073                }
1074        }
1075
1076        our $search_use_regexp = $input_params{'search_use_regexp'};
1077
1078        our $searchtext = $input_params{'searchtext'};
1079        our $search_regexp;
1080        if (defined $searchtext) {
1081                if (length($searchtext) < 2) {
1082                        die_error(403, "At least two characters are required for search parameter");
1083                }
1084                if ($search_use_regexp) {
1085                        $search_regexp = $searchtext;
1086                        if (!eval { qr/$search_regexp/; 1; }) {
1087                                (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1088                                die_error(400, "Invalid search regexp '$search_regexp'",
1089                                          esc_html($error));
1090                        }
1091                } else {
1092                        $search_regexp = quotemeta $searchtext;
1093                }
1094        }
1095}
1096
1097# path to the current git repository
1098our $git_dir;
1099sub evaluate_git_dir {
1100        our $git_dir = "$projectroot/$project" if $project;
1101}
1102
1103our (@snapshot_fmts, $git_avatar);
1104sub configure_gitweb_features {
1105        # list of supported snapshot formats
1106        our @snapshot_fmts = gitweb_get_feature('snapshot');
1107        @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1108
1109        # check that the avatar feature is set to a known provider name,
1110        # and for each provider check if the dependencies are satisfied.
1111        # if the provider name is invalid or the dependencies are not met,
1112        # reset $git_avatar to the empty string.
1113        our ($git_avatar) = gitweb_get_feature('avatar');
1114        if ($git_avatar eq 'gravatar') {
1115                $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1116        } elsif ($git_avatar eq 'picon') {
1117                # no dependencies
1118        } else {
1119                $git_avatar = '';
1120        }
1121}
1122
1123# custom error handler: 'die <message>' is Internal Server Error
1124sub handle_errors_html {
1125        my $msg = shift; # it is already HTML escaped
1126
1127        # to avoid infinite loop where error occurs in die_error,
1128        # change handler to default handler, disabling handle_errors_html
1129        set_message("Error occured when inside die_error:\n$msg");
1130
1131        # you cannot jump out of die_error when called as error handler;
1132        # the subroutine set via CGI::Carp::set_message is called _after_
1133        # HTTP headers are already written, so it cannot write them itself
1134        die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1135}
1136set_message(\&handle_errors_html);
1137
1138# dispatch
1139sub dispatch {
1140        if (!defined $action) {
1141                if (defined $hash) {
1142                        $action = git_get_type($hash);
1143                        $action or die_error(404, "Object does not exist");
1144                } elsif (defined $hash_base && defined $file_name) {
1145                        $action = git_get_type("$hash_base:$file_name");
1146                        $action or die_error(404, "File or directory does not exist");
1147                } elsif (defined $project) {
1148                        $action = 'summary';
1149                } else {
1150                        $action = 'project_list';
1151                }
1152        }
1153        if (!defined($actions{$action})) {
1154                die_error(400, "Unknown action");
1155        }
1156        if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1157            !$project) {
1158                die_error(400, "Project needed");
1159        }
1160        $actions{$action}->();
1161}
1162
1163sub reset_timer {
1164        our $t0 = [ gettimeofday() ]
1165                if defined $t0;
1166        our $number_of_git_cmds = 0;
1167}
1168
1169our $first_request = 1;
1170sub run_request {
1171        reset_timer();
1172
1173        evaluate_uri();
1174        if ($first_request) {
1175                evaluate_gitweb_config();
1176                evaluate_git_version();
1177        }
1178        if ($per_request_config) {
1179                if (ref($per_request_config) eq 'CODE') {
1180                        $per_request_config->();
1181                } elsif (!$first_request) {
1182                        evaluate_gitweb_config();
1183                }
1184        }
1185        check_loadavg();
1186
1187        # $projectroot and $projects_list might be set in gitweb config file
1188        $projects_list ||= $projectroot;
1189
1190        evaluate_query_params();
1191        evaluate_path_info();
1192        evaluate_and_validate_params();
1193        evaluate_git_dir();
1194
1195        configure_gitweb_features();
1196
1197        dispatch();
1198}
1199
1200our $is_last_request = sub { 1 };
1201our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1202our $CGI = 'CGI';
1203our $cgi;
1204sub configure_as_fcgi {
1205        require CGI::Fast;
1206        our $CGI = 'CGI::Fast';
1207
1208        my $request_number = 0;
1209        # let each child service 100 requests
1210        our $is_last_request = sub { ++$request_number > 100 };
1211}
1212sub evaluate_argv {
1213        my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1214        configure_as_fcgi()
1215                if $script_name =~ /\.fcgi$/;
1216
1217        return unless (@ARGV);
1218
1219        require Getopt::Long;
1220        Getopt::Long::GetOptions(
1221                'fastcgi|fcgi|f' => \&configure_as_fcgi,
1222                'nproc|n=i' => sub {
1223                        my ($arg, $val) = @_;
1224                        return unless eval { require FCGI::ProcManager; 1; };
1225                        my $proc_manager = FCGI::ProcManager->new({
1226                                n_processes => $val,
1227                        });
1228                        our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1229                        our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1230                        our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1231                },
1232        );
1233}
1234
1235sub run {
1236        evaluate_argv();
1237
1238        $first_request = 1;
1239        $pre_listen_hook->()
1240                if $pre_listen_hook;
1241
1242 REQUEST:
1243        while ($cgi = $CGI->new()) {
1244                $pre_dispatch_hook->()
1245                        if $pre_dispatch_hook;
1246
1247                run_request();
1248
1249                $post_dispatch_hook->()
1250                        if $post_dispatch_hook;
1251                $first_request = 0;
1252
1253                last REQUEST if ($is_last_request->());
1254        }
1255
1256 DONE_GITWEB:
1257        1;
1258}
1259
1260run();
1261
1262if (defined caller) {
1263        # wrapped in a subroutine processing requests,
1264        # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1265        return;
1266} else {
1267        # pure CGI script, serving single request
1268        exit;
1269}
1270
1271## ======================================================================
1272## action links
1273
1274# possible values of extra options
1275# -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1276# -replay => 1      - start from a current view (replay with modifications)
1277# -path_info => 0|1 - don't use/use path_info URL (if possible)
1278# -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1279sub href {
1280        my %params = @_;
1281        # default is to use -absolute url() i.e. $my_uri
1282        my $href = $params{-full} ? $my_url : $my_uri;
1283
1284        # implicit -replay, must be first of implicit params
1285        $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1286
1287        $params{'project'} = $project unless exists $params{'project'};
1288
1289        if ($params{-replay}) {
1290                while (my ($name, $symbol) = each %cgi_param_mapping) {
1291                        if (!exists $params{$name}) {
1292                                $params{$name} = $input_params{$name};
1293                        }
1294                }
1295        }
1296
1297        my $use_pathinfo = gitweb_check_feature('pathinfo');
1298        if (defined $params{'project'} &&
1299            (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1300                # try to put as many parameters as possible in PATH_INFO:
1301                #   - project name
1302                #   - action
1303                #   - hash_parent or hash_parent_base:/file_parent
1304                #   - hash or hash_base:/filename
1305                #   - the snapshot_format as an appropriate suffix
1306
1307                # When the script is the root DirectoryIndex for the domain,
1308                # $href here would be something like http://gitweb.example.com/
1309                # Thus, we strip any trailing / from $href, to spare us double
1310                # slashes in the final URL
1311                $href =~ s,/$,,;
1312
1313                # Then add the project name, if present
1314                $href .= "/".esc_path_info($params{'project'});
1315                delete $params{'project'};
1316
1317                # since we destructively absorb parameters, we keep this
1318                # boolean that remembers if we're handling a snapshot
1319                my $is_snapshot = $params{'action'} eq 'snapshot';
1320
1321                # Summary just uses the project path URL, any other action is
1322                # added to the URL
1323                if (defined $params{'action'}) {
1324                        $href .= "/".esc_path_info($params{'action'})
1325                                unless $params{'action'} eq 'summary';
1326                        delete $params{'action'};
1327                }
1328
1329                # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1330                # stripping nonexistent or useless pieces
1331                $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1332                        || $params{'hash_parent'} || $params{'hash'});
1333                if (defined $params{'hash_base'}) {
1334                        if (defined $params{'hash_parent_base'}) {
1335                                $href .= esc_path_info($params{'hash_parent_base'});
1336                                # skip the file_parent if it's the same as the file_name
1337                                if (defined $params{'file_parent'}) {
1338                                        if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1339                                                delete $params{'file_parent'};
1340                                        } elsif ($params{'file_parent'} !~ /\.\./) {
1341                                                $href .= ":/".esc_path_info($params{'file_parent'});
1342                                                delete $params{'file_parent'};
1343                                        }
1344                                }
1345                                $href .= "..";
1346                                delete $params{'hash_parent'};
1347                                delete $params{'hash_parent_base'};
1348                        } elsif (defined $params{'hash_parent'}) {
1349                                $href .= esc_path_info($params{'hash_parent'}). "..";
1350                                delete $params{'hash_parent'};
1351                        }
1352
1353                        $href .= esc_path_info($params{'hash_base'});
1354                        if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1355                                $href .= ":/".esc_path_info($params{'file_name'});
1356                                delete $params{'file_name'};
1357                        }
1358                        delete $params{'hash'};
1359                        delete $params{'hash_base'};
1360                } elsif (defined $params{'hash'}) {
1361                        $href .= esc_path_info($params{'hash'});
1362                        delete $params{'hash'};
1363                }
1364
1365                # If the action was a snapshot, we can absorb the
1366                # snapshot_format parameter too
1367                if ($is_snapshot) {
1368                        my $fmt = $params{'snapshot_format'};
1369                        # snapshot_format should always be defined when href()
1370                        # is called, but just in case some code forgets, we
1371                        # fall back to the default
1372                        $fmt ||= $snapshot_fmts[0];
1373                        $href .= $known_snapshot_formats{$fmt}{'suffix'};
1374                        delete $params{'snapshot_format'};
1375                }
1376        }
1377
1378        # now encode the parameters explicitly
1379        my @result = ();
1380        for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1381                my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1382                if (defined $params{$name}) {
1383                        if (ref($params{$name}) eq "ARRAY") {
1384                                foreach my $par (@{$params{$name}}) {
1385                                        push @result, $symbol . "=" . esc_param($par);
1386                                }
1387                        } else {
1388                                push @result, $symbol . "=" . esc_param($params{$name});
1389                        }
1390                }
1391        }
1392        $href .= "?" . join(';', @result) if scalar @result;
1393
1394        # final transformation: trailing spaces must be escaped (URI-encoded)
1395        $href =~ s/(\s+)$/CGI::escape($1)/e;
1396
1397        if ($params{-anchor}) {
1398                $href .= "#".esc_param($params{-anchor});
1399        }
1400
1401        return $href;
1402}
1403
1404
1405## ======================================================================
1406## validation, quoting/unquoting and escaping
1407
1408sub validate_action {
1409        my $input = shift || return undef;
1410        return undef unless exists $actions{$input};
1411        return $input;
1412}
1413
1414sub validate_project {
1415        my $input = shift || return undef;
1416        if (!validate_pathname($input) ||
1417                !(-d "$projectroot/$input") ||
1418                !check_export_ok("$projectroot/$input") ||
1419                ($strict_export && !project_in_list($input))) {
1420                return undef;
1421        } else {
1422                return $input;
1423        }
1424}
1425
1426sub validate_pathname {
1427        my $input = shift || return undef;
1428
1429        # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1430        # at the beginning, at the end, and between slashes.
1431        # also this catches doubled slashes
1432        if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1433                return undef;
1434        }
1435        # no null characters
1436        if ($input =~ m!\0!) {
1437                return undef;
1438        }
1439        return $input;
1440}
1441
1442sub validate_refname {
1443        my $input = shift || return undef;
1444
1445        # textual hashes are O.K.
1446        if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1447                return $input;
1448        }
1449        # it must be correct pathname
1450        $input = validate_pathname($input)
1451                or return undef;
1452        # restrictions on ref name according to git-check-ref-format
1453        if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1454                return undef;
1455        }
1456        return $input;
1457}
1458
1459# decode sequences of octets in utf8 into Perl's internal form,
1460# which is utf-8 with utf8 flag set if needed.  gitweb writes out
1461# in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1462sub to_utf8 {
1463        my $str = shift;
1464        return undef unless defined $str;
1465
1466        if (utf8::is_utf8($str) || utf8::decode($str)) {
1467                return $str;
1468        } else {
1469                return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1470        }
1471}
1472
1473# quote unsafe chars, but keep the slash, even when it's not
1474# correct, but quoted slashes look too horrible in bookmarks
1475sub esc_param {
1476        my $str = shift;
1477        return undef unless defined $str;
1478        $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1479        $str =~ s/ /\+/g;
1480        return $str;
1481}
1482
1483# the quoting rules for path_info fragment are slightly different
1484sub esc_path_info {
1485        my $str = shift;
1486        return undef unless defined $str;
1487
1488        # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1489        $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1490
1491        return $str;
1492}
1493
1494# quote unsafe chars in whole URL, so some characters cannot be quoted
1495sub esc_url {
1496        my $str = shift;
1497        return undef unless defined $str;
1498        $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1499        $str =~ s/ /\+/g;
1500        return $str;
1501}
1502
1503# quote unsafe characters in HTML attributes
1504sub esc_attr {
1505
1506        # for XHTML conformance escaping '"' to '&quot;' is not enough
1507        return esc_html(@_);
1508}
1509
1510# replace invalid utf8 character with SUBSTITUTION sequence
1511sub esc_html {
1512        my $str = shift;
1513        my %opts = @_;
1514
1515        return undef unless defined $str;
1516
1517        $str = to_utf8($str);
1518        $str = $cgi->escapeHTML($str);
1519        if ($opts{'-nbsp'}) {
1520                $str =~ s/ /&nbsp;/g;
1521        }
1522        $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1523        return $str;
1524}
1525
1526# quote control characters and escape filename to HTML
1527sub esc_path {
1528        my $str = shift;
1529        my %opts = @_;
1530
1531        return undef unless defined $str;
1532
1533        $str = to_utf8($str);
1534        $str = $cgi->escapeHTML($str);
1535        if ($opts{'-nbsp'}) {
1536                $str =~ s/ /&nbsp;/g;
1537        }
1538        $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1539        return $str;
1540}
1541
1542# Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1543sub sanitize {
1544        my $str = shift;
1545
1546        return undef unless defined $str;
1547
1548        $str = to_utf8($str);
1549        $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1550        return $str;
1551}
1552
1553# Make control characters "printable", using character escape codes (CEC)
1554sub quot_cec {
1555        my $cntrl = shift;
1556        my %opts = @_;
1557        my %es = ( # character escape codes, aka escape sequences
1558                "\t" => '\t',   # tab            (HT)
1559                "\n" => '\n',   # line feed      (LF)
1560                "\r" => '\r',   # carrige return (CR)
1561                "\f" => '\f',   # form feed      (FF)
1562                "\b" => '\b',   # backspace      (BS)
1563                "\a" => '\a',   # alarm (bell)   (BEL)
1564                "\e" => '\e',   # escape         (ESC)
1565                "\013" => '\v', # vertical tab   (VT)
1566                "\000" => '\0', # nul character  (NUL)
1567        );
1568        my $chr = ( (exists $es{$cntrl})
1569                    ? $es{$cntrl}
1570                    : sprintf('\%2x', ord($cntrl)) );
1571        if ($opts{-nohtml}) {
1572                return $chr;
1573        } else {
1574                return "<span class=\"cntrl\">$chr</span>";
1575        }
1576}
1577
1578# Alternatively use unicode control pictures codepoints,
1579# Unicode "printable representation" (PR)
1580sub quot_upr {
1581        my $cntrl = shift;
1582        my %opts = @_;
1583
1584        my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1585        if ($opts{-nohtml}) {
1586                return $chr;
1587        } else {
1588                return "<span class=\"cntrl\">$chr</span>";
1589        }
1590}
1591
1592# git may return quoted and escaped filenames
1593sub unquote {
1594        my $str = shift;
1595
1596        sub unq {
1597                my $seq = shift;
1598                my %es = ( # character escape codes, aka escape sequences
1599                        't' => "\t",   # tab            (HT, TAB)
1600                        'n' => "\n",   # newline        (NL)
1601                        'r' => "\r",   # return         (CR)
1602                        'f' => "\f",   # form feed      (FF)
1603                        'b' => "\b",   # backspace      (BS)
1604                        'a' => "\a",   # alarm (bell)   (BEL)
1605                        'e' => "\e",   # escape         (ESC)
1606                        'v' => "\013", # vertical tab   (VT)
1607                );
1608
1609                if ($seq =~ m/^[0-7]{1,3}$/) {
1610                        # octal char sequence
1611                        return chr(oct($seq));
1612                } elsif (exists $es{$seq}) {
1613                        # C escape sequence, aka character escape code
1614                        return $es{$seq};
1615                }
1616                # quoted ordinary character
1617                return $seq;
1618        }
1619
1620        if ($str =~ m/^"(.*)"$/) {
1621                # needs unquoting
1622                $str = $1;
1623                $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1624        }
1625        return $str;
1626}
1627
1628# escape tabs (convert tabs to spaces)
1629sub untabify {
1630        my $line = shift;
1631
1632        while ((my $pos = index($line, "\t")) != -1) {
1633                if (my $count = (8 - ($pos % 8))) {
1634                        my $spaces = ' ' x $count;
1635                        $line =~ s/\t/$spaces/;
1636                }
1637        }
1638
1639        return $line;
1640}
1641
1642sub project_in_list {
1643        my $project = shift;
1644        my @list = git_get_projects_list();
1645        return @list && scalar(grep { $_->{'path'} eq $project } @list);
1646}
1647
1648## ----------------------------------------------------------------------
1649## HTML aware string manipulation
1650
1651# Try to chop given string on a word boundary between position
1652# $len and $len+$add_len. If there is no word boundary there,
1653# chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1654# (marking chopped part) would be longer than given string.
1655sub chop_str {
1656        my $str = shift;
1657        my $len = shift;
1658        my $add_len = shift || 10;
1659        my $where = shift || 'right'; # 'left' | 'center' | 'right'
1660
1661        # Make sure perl knows it is utf8 encoded so we don't
1662        # cut in the middle of a utf8 multibyte char.
1663        $str = to_utf8($str);
1664
1665        # allow only $len chars, but don't cut a word if it would fit in $add_len
1666        # if it doesn't fit, cut it if it's still longer than the dots we would add
1667        # remove chopped character entities entirely
1668
1669        # when chopping in the middle, distribute $len into left and right part
1670        # return early if chopping wouldn't make string shorter
1671        if ($where eq 'center') {
1672                return $str if ($len + 5 >= length($str)); # filler is length 5
1673                $len = int($len/2);
1674        } else {
1675                return $str if ($len + 4 >= length($str)); # filler is length 4
1676        }
1677
1678        # regexps: ending and beginning with word part up to $add_len
1679        my $endre = qr/.{$len}\w{0,$add_len}/;
1680        my $begre = qr/\w{0,$add_len}.{$len}/;
1681
1682        if ($where eq 'left') {
1683                $str =~ m/^(.*?)($begre)$/;
1684                my ($lead, $body) = ($1, $2);
1685                if (length($lead) > 4) {
1686                        $lead = " ...";
1687                }
1688                return "$lead$body";
1689
1690        } elsif ($where eq 'center') {
1691                $str =~ m/^($endre)(.*)$/;
1692                my ($left, $str)  = ($1, $2);
1693                $str =~ m/^(.*?)($begre)$/;
1694                my ($mid, $right) = ($1, $2);
1695                if (length($mid) > 5) {
1696                        $mid = " ... ";
1697                }
1698                return "$left$mid$right";
1699
1700        } else {
1701                $str =~ m/^($endre)(.*)$/;
1702                my $body = $1;
1703                my $tail = $2;
1704                if (length($tail) > 4) {
1705                        $tail = "... ";
1706                }
1707                return "$body$tail";
1708        }
1709}
1710
1711# takes the same arguments as chop_str, but also wraps a <span> around the
1712# result with a title attribute if it does get chopped. Additionally, the
1713# string is HTML-escaped.
1714sub chop_and_escape_str {
1715        my ($str) = @_;
1716
1717        my $chopped = chop_str(@_);
1718        $str = to_utf8($str);
1719        if ($chopped eq $str) {
1720                return esc_html($chopped);
1721        } else {
1722                $str =~ s/[[:cntrl:]]/?/g;
1723                return $cgi->span({-title=>$str}, esc_html($chopped));
1724        }
1725}
1726
1727# Highlight selected fragments of string, using given CSS class,
1728# and escape HTML.  It is assumed that fragments do not overlap.
1729# Regions are passed as list of pairs (array references).
1730#
1731# Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1732# '<span class="mark">foo</span>bar'
1733sub esc_html_hl_regions {
1734        my ($str, $css_class, @sel) = @_;
1735        return esc_html($str) unless @sel;
1736
1737        my $out = '';
1738        my $pos = 0;
1739
1740        for my $s (@sel) {
1741                $out .= esc_html(substr($str, $pos, $s->[0] - $pos))
1742                        if ($s->[0] - $pos > 0);
1743                $out .= $cgi->span({-class => $css_class},
1744                                   esc_html(substr($str, $s->[0], $s->[1] - $s->[0])));
1745
1746                $pos = $s->[1];
1747        }
1748        $out .= esc_html(substr($str, $pos))
1749                if ($pos < length($str));
1750
1751        return $out;
1752}
1753
1754# return positions of beginning and end of each match
1755sub matchpos_list {
1756        my ($str, $regexp) = @_;
1757        return unless (defined $str && defined $regexp);
1758
1759        my @matches;
1760        while ($str =~ /$regexp/g) {
1761                push @matches, [$-[0], $+[0]];
1762        }
1763        return @matches;
1764}
1765
1766# highlight match (if any), and escape HTML
1767sub esc_html_match_hl {
1768        my ($str, $regexp) = @_;
1769        return esc_html($str) unless defined $regexp;
1770
1771        my @matches = matchpos_list($str, $regexp);
1772        return esc_html($str) unless @matches;
1773
1774        return esc_html_hl_regions($str, 'match', @matches);
1775}
1776
1777
1778# highlight match (if any) of shortened string, and escape HTML
1779sub esc_html_match_hl_chopped {
1780        my ($str, $chopped, $regexp) = @_;
1781        return esc_html_match_hl($str, $regexp) unless defined $chopped;
1782
1783        my @matches = matchpos_list($str, $regexp);
1784        return esc_html($chopped) unless @matches;
1785
1786        # filter matches so that we mark chopped string
1787        my $tail = "... "; # see chop_str
1788        unless ($chopped =~ s/\Q$tail\E$//) {
1789                $tail = '';
1790        }
1791        my $chop_len = length($chopped);
1792        my $tail_len = length($tail);
1793        my @filtered;
1794
1795        for my $m (@matches) {
1796                if ($m->[0] > $chop_len) {
1797                        push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1798                        last;
1799                } elsif ($m->[1] > $chop_len) {
1800                        push @filtered, [ $m->[0], $chop_len + $tail_len ];
1801                        last;
1802                }
1803                push @filtered, $m;
1804        }
1805
1806        return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1807}
1808
1809## ----------------------------------------------------------------------
1810## functions returning short strings
1811
1812# CSS class for given age value (in seconds)
1813sub age_class {
1814        my $age = shift;
1815
1816        if (!defined $age) {
1817                return "noage";
1818        } elsif ($age < 60*60*2) {
1819                return "age0";
1820        } elsif ($age < 60*60*24*2) {
1821                return "age1";
1822        } else {
1823                return "age2";
1824        }
1825}
1826
1827# convert age in seconds to "nn units ago" string
1828sub age_string {
1829        my $age = shift;
1830        my $age_str;
1831
1832        if ($age > 60*60*24*365*2) {
1833                $age_str = (int $age/60/60/24/365);
1834                $age_str .= " years ago";
1835        } elsif ($age > 60*60*24*(365/12)*2) {
1836                $age_str = int $age/60/60/24/(365/12);
1837                $age_str .= " months ago";
1838        } elsif ($age > 60*60*24*7*2) {
1839                $age_str = int $age/60/60/24/7;
1840                $age_str .= " weeks ago";
1841        } elsif ($age > 60*60*24*2) {
1842                $age_str = int $age/60/60/24;
1843                $age_str .= " days ago";
1844        } elsif ($age > 60*60*2) {
1845                $age_str = int $age/60/60;
1846                $age_str .= " hours ago";
1847        } elsif ($age > 60*2) {
1848                $age_str = int $age/60;
1849                $age_str .= " min ago";
1850        } elsif ($age > 2) {
1851                $age_str = int $age;
1852                $age_str .= " sec ago";
1853        } else {
1854                $age_str .= " right now";
1855        }
1856        return $age_str;
1857}
1858
1859use constant {
1860        S_IFINVALID => 0030000,
1861        S_IFGITLINK => 0160000,
1862};
1863
1864# submodule/subproject, a commit object reference
1865sub S_ISGITLINK {
1866        my $mode = shift;
1867
1868        return (($mode & S_IFMT) == S_IFGITLINK)
1869}
1870
1871# convert file mode in octal to symbolic file mode string
1872sub mode_str {
1873        my $mode = oct shift;
1874
1875        if (S_ISGITLINK($mode)) {
1876                return 'm---------';
1877        } elsif (S_ISDIR($mode & S_IFMT)) {
1878                return 'drwxr-xr-x';
1879        } elsif (S_ISLNK($mode)) {
1880                return 'lrwxrwxrwx';
1881        } elsif (S_ISREG($mode)) {
1882                # git cares only about the executable bit
1883                if ($mode & S_IXUSR) {
1884                        return '-rwxr-xr-x';
1885                } else {
1886                        return '-rw-r--r--';
1887                };
1888        } else {
1889                return '----------';
1890        }
1891}
1892
1893# convert file mode in octal to file type string
1894sub file_type {
1895        my $mode = shift;
1896
1897        if ($mode !~ m/^[0-7]+$/) {
1898                return $mode;
1899        } else {
1900                $mode = oct $mode;
1901        }
1902
1903        if (S_ISGITLINK($mode)) {
1904                return "submodule";
1905        } elsif (S_ISDIR($mode & S_IFMT)) {
1906                return "directory";
1907        } elsif (S_ISLNK($mode)) {
1908                return "symlink";
1909        } elsif (S_ISREG($mode)) {
1910                return "file";
1911        } else {
1912                return "unknown";
1913        }
1914}
1915
1916# convert file mode in octal to file type description string
1917sub file_type_long {
1918        my $mode = shift;
1919
1920        if ($mode !~ m/^[0-7]+$/) {
1921                return $mode;
1922        } else {
1923                $mode = oct $mode;
1924        }
1925
1926        if (S_ISGITLINK($mode)) {
1927                return "submodule";
1928        } elsif (S_ISDIR($mode & S_IFMT)) {
1929                return "directory";
1930        } elsif (S_ISLNK($mode)) {
1931                return "symlink";
1932        } elsif (S_ISREG($mode)) {
1933                if ($mode & S_IXUSR) {
1934                        return "executable";
1935                } else {
1936                        return "file";
1937                };
1938        } else {
1939                return "unknown";
1940        }
1941}
1942
1943
1944## ----------------------------------------------------------------------
1945## functions returning short HTML fragments, or transforming HTML fragments
1946## which don't belong to other sections
1947
1948# format line of commit message.
1949sub format_log_line_html {
1950        my $line = shift;
1951
1952        $line = esc_html($line, -nbsp=>1);
1953        $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1954                $cgi->a({-href => href(action=>"object", hash=>$1),
1955                                        -class => "text"}, $1);
1956        }eg;
1957
1958        return $line;
1959}
1960
1961# format marker of refs pointing to given object
1962
1963# the destination action is chosen based on object type and current context:
1964# - for annotated tags, we choose the tag view unless it's the current view
1965#   already, in which case we go to shortlog view
1966# - for other refs, we keep the current view if we're in history, shortlog or
1967#   log view, and select shortlog otherwise
1968sub format_ref_marker {
1969        my ($refs, $id) = @_;
1970        my $markers = '';
1971
1972        if (defined $refs->{$id}) {
1973                foreach my $ref (@{$refs->{$id}}) {
1974                        # this code exploits the fact that non-lightweight tags are the
1975                        # only indirect objects, and that they are the only objects for which
1976                        # we want to use tag instead of shortlog as action
1977                        my ($type, $name) = qw();
1978                        my $indirect = ($ref =~ s/\^\{\}$//);
1979                        # e.g. tags/v2.6.11 or heads/next
1980                        if ($ref =~ m!^(.*?)s?/(.*)$!) {
1981                                $type = $1;
1982                                $name = $2;
1983                        } else {
1984                                $type = "ref";
1985                                $name = $ref;
1986                        }
1987
1988                        my $class = $type;
1989                        $class .= " indirect" if $indirect;
1990
1991                        my $dest_action = "shortlog";
1992
1993                        if ($indirect) {
1994                                $dest_action = "tag" unless $action eq "tag";
1995                        } elsif ($action =~ /^(history|(short)?log)$/) {
1996                                $dest_action = $action;
1997                        }
1998
1999                        my $dest = "";
2000                        $dest .= "refs/" unless $ref =~ m!^refs/!;
2001                        $dest .= $ref;
2002
2003                        my $link = $cgi->a({
2004                                -href => href(
2005                                        action=>$dest_action,
2006                                        hash=>$dest
2007                                )}, $name);
2008
2009                        $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2010                                $link . "</span>";
2011                }
2012        }
2013
2014        if ($markers) {
2015                return ' <span class="refs">'. $markers . '</span>';
2016        } else {
2017                return "";
2018        }
2019}
2020
2021# format, perhaps shortened and with markers, title line
2022sub format_subject_html {
2023        my ($long, $short, $href, $extra) = @_;
2024        $extra = '' unless defined($extra);
2025
2026        if (length($short) < length($long)) {
2027                $long =~ s/[[:cntrl:]]/?/g;
2028                return $cgi->a({-href => $href, -class => "list subject",
2029                                -title => to_utf8($long)},
2030                       esc_html($short)) . $extra;
2031        } else {
2032                return $cgi->a({-href => $href, -class => "list subject"},
2033                       esc_html($long)) . $extra;
2034        }
2035}
2036
2037# Rather than recomputing the url for an email multiple times, we cache it
2038# after the first hit. This gives a visible benefit in views where the avatar
2039# for the same email is used repeatedly (e.g. shortlog).
2040# The cache is shared by all avatar engines (currently gravatar only), which
2041# are free to use it as preferred. Since only one avatar engine is used for any
2042# given page, there's no risk for cache conflicts.
2043our %avatar_cache = ();
2044
2045# Compute the picon url for a given email, by using the picon search service over at
2046# http://www.cs.indiana.edu/picons/search.html
2047sub picon_url {
2048        my $email = lc shift;
2049        if (!$avatar_cache{$email}) {
2050                my ($user, $domain) = split('@', $email);
2051                $avatar_cache{$email} =
2052                        "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2053                        "$domain/$user/" .
2054                        "users+domains+unknown/up/single";
2055        }
2056        return $avatar_cache{$email};
2057}
2058
2059# Compute the gravatar url for a given email, if it's not in the cache already.
2060# Gravatar stores only the part of the URL before the size, since that's the
2061# one computationally more expensive. This also allows reuse of the cache for
2062# different sizes (for this particular engine).
2063sub gravatar_url {
2064        my $email = lc shift;
2065        my $size = shift;
2066        $avatar_cache{$email} ||=
2067                "http://www.gravatar.com/avatar/" .
2068                        Digest::MD5::md5_hex($email) . "?s=";
2069        return $avatar_cache{$email} . $size;
2070}
2071
2072# Insert an avatar for the given $email at the given $size if the feature
2073# is enabled.
2074sub git_get_avatar {
2075        my ($email, %opts) = @_;
2076        my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2077        my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2078        $opts{-size} ||= 'default';
2079        my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2080        my $url = "";
2081        if ($git_avatar eq 'gravatar') {
2082                $url = gravatar_url($email, $size);
2083        } elsif ($git_avatar eq 'picon') {
2084                $url = picon_url($email);
2085        }
2086        # Other providers can be added by extending the if chain, defining $url
2087        # as needed. If no variant puts something in $url, we assume avatars
2088        # are completely disabled/unavailable.
2089        if ($url) {
2090                return $pre_white .
2091                       "<img width=\"$size\" " .
2092                            "class=\"avatar\" " .
2093                            "src=\"".esc_url($url)."\" " .
2094                            "alt=\"\" " .
2095                       "/>" . $post_white;
2096        } else {
2097                return "";
2098        }
2099}
2100
2101sub format_search_author {
2102        my ($author, $searchtype, $displaytext) = @_;
2103        my $have_search = gitweb_check_feature('search');
2104
2105        if ($have_search) {
2106                my $performed = "";
2107                if ($searchtype eq 'author') {
2108                        $performed = "authored";
2109                } elsif ($searchtype eq 'committer') {
2110                        $performed = "committed";
2111                }
2112
2113                return $cgi->a({-href => href(action=>"search", hash=>$hash,
2114                                searchtext=>$author,
2115                                searchtype=>$searchtype), class=>"list",
2116                                title=>"Search for commits $performed by $author"},
2117                                $displaytext);
2118
2119        } else {
2120                return $displaytext;
2121        }
2122}
2123
2124# format the author name of the given commit with the given tag
2125# the author name is chopped and escaped according to the other
2126# optional parameters (see chop_str).
2127sub format_author_html {
2128        my $tag = shift;
2129        my $co = shift;
2130        my $author = chop_and_escape_str($co->{'author_name'}, @_);
2131        return "<$tag class=\"author\">" .
2132               format_search_author($co->{'author_name'}, "author",
2133                       git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2134                       $author) .
2135               "</$tag>";
2136}
2137
2138# format git diff header line, i.e. "diff --(git|combined|cc) ..."
2139sub format_git_diff_header_line {
2140        my $line = shift;
2141        my $diffinfo = shift;
2142        my ($from, $to) = @_;
2143
2144        if ($diffinfo->{'nparents'}) {
2145                # combined diff
2146                $line =~ s!^(diff (.*?) )"?.*$!$1!;
2147                if ($to->{'href'}) {
2148                        $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2149                                         esc_path($to->{'file'}));
2150                } else { # file was deleted (no href)
2151                        $line .= esc_path($to->{'file'});
2152                }
2153        } else {
2154                # "ordinary" diff
2155                $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2156                if ($from->{'href'}) {
2157                        $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2158                                         'a/' . esc_path($from->{'file'}));
2159                } else { # file was added (no href)
2160                        $line .= 'a/' . esc_path($from->{'file'});
2161                }
2162                $line .= ' ';
2163                if ($to->{'href'}) {
2164                        $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2165                                         'b/' . esc_path($to->{'file'}));
2166                } else { # file was deleted
2167                        $line .= 'b/' . esc_path($to->{'file'});
2168                }
2169        }
2170
2171        return "<div class=\"diff header\">$line</div>\n";
2172}
2173
2174# format extended diff header line, before patch itself
2175sub format_extended_diff_header_line {
2176        my $line = shift;
2177        my $diffinfo = shift;
2178        my ($from, $to) = @_;
2179
2180        # match <path>
2181        if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2182                $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2183                                       esc_path($from->{'file'}));
2184        }
2185        if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2186                $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2187                                 esc_path($to->{'file'}));
2188        }
2189        # match single <mode>
2190        if ($line =~ m/\s(\d{6})$/) {
2191                $line .= '<span class="info"> (' .
2192                         file_type_long($1) .
2193                         ')</span>';
2194        }
2195        # match <hash>
2196        if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2197                # can match only for combined diff
2198                $line = 'index ';
2199                for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2200                        if ($from->{'href'}[$i]) {
2201                                $line .= $cgi->a({-href=>$from->{'href'}[$i],
2202                                                  -class=>"hash"},
2203                                                 substr($diffinfo->{'from_id'}[$i],0,7));
2204                        } else {
2205                                $line .= '0' x 7;
2206                        }
2207                        # separator
2208                        $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2209                }
2210                $line .= '..';
2211                if ($to->{'href'}) {
2212                        $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2213                                         substr($diffinfo->{'to_id'},0,7));
2214                } else {
2215                        $line .= '0' x 7;
2216                }
2217
2218        } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2219                # can match only for ordinary diff
2220                my ($from_link, $to_link);
2221                if ($from->{'href'}) {
2222                        $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2223                                             substr($diffinfo->{'from_id'},0,7));
2224                } else {
2225                        $from_link = '0' x 7;
2226                }
2227                if ($to->{'href'}) {
2228                        $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2229                                           substr($diffinfo->{'to_id'},0,7));
2230                } else {
2231                        $to_link = '0' x 7;
2232                }
2233                my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2234                $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2235        }
2236
2237        return $line . "<br/>\n";
2238}
2239
2240# format from-file/to-file diff header
2241sub format_diff_from_to_header {
2242        my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2243        my $line;
2244        my $result = '';
2245
2246        $line = $from_line;
2247        #assert($line =~ m/^---/) if DEBUG;
2248        # no extra formatting for "^--- /dev/null"
2249        if (! $diffinfo->{'nparents'}) {
2250                # ordinary (single parent) diff
2251                if ($line =~ m!^--- "?a/!) {
2252                        if ($from->{'href'}) {
2253                                $line = '--- a/' .
2254                                        $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2255                                                esc_path($from->{'file'}));
2256                        } else {
2257                                $line = '--- a/' .
2258                                        esc_path($from->{'file'});
2259                        }
2260                }
2261                $result .= qq!<div class="diff from_file">$line</div>\n!;
2262
2263        } else {
2264                # combined diff (merge commit)
2265                for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2266                        if ($from->{'href'}[$i]) {
2267                                $line = '--- ' .
2268                                        $cgi->a({-href=>href(action=>"blobdiff",
2269                                                             hash_parent=>$diffinfo->{'from_id'}[$i],
2270                                                             hash_parent_base=>$parents[$i],
2271                                                             file_parent=>$from->{'file'}[$i],
2272                                                             hash=>$diffinfo->{'to_id'},
2273                                                             hash_base=>$hash,
2274                                                             file_name=>$to->{'file'}),
2275                                                 -class=>"path",
2276                                                 -title=>"diff" . ($i+1)},
2277                                                $i+1) .
2278                                        '/' .
2279                                        $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2280                                                esc_path($from->{'file'}[$i]));
2281                        } else {
2282                                $line = '--- /dev/null';
2283                        }
2284                        $result .= qq!<div class="diff from_file">$line</div>\n!;
2285                }
2286        }
2287
2288        $line = $to_line;
2289        #assert($line =~ m/^\+\+\+/) if DEBUG;
2290        # no extra formatting for "^+++ /dev/null"
2291        if ($line =~ m!^\+\+\+ "?b/!) {
2292                if ($to->{'href'}) {
2293                        $line = '+++ b/' .
2294                                $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2295                                        esc_path($to->{'file'}));
2296                } else {
2297                        $line = '+++ b/' .
2298                                esc_path($to->{'file'});
2299                }
2300        }
2301        $result .= qq!<div class="diff to_file">$line</div>\n!;
2302
2303        return $result;
2304}
2305
2306# create note for patch simplified by combined diff
2307sub format_diff_cc_simplified {
2308        my ($diffinfo, @parents) = @_;
2309        my $result = '';
2310
2311        $result .= "<div class=\"diff header\">" .
2312                   "diff --cc ";
2313        if (!is_deleted($diffinfo)) {
2314                $result .= $cgi->a({-href => href(action=>"blob",
2315                                                  hash_base=>$hash,
2316                                                  hash=>$diffinfo->{'to_id'},
2317                                                  file_name=>$diffinfo->{'to_file'}),
2318                                    -class => "path"},
2319                                   esc_path($diffinfo->{'to_file'}));
2320        } else {
2321                $result .= esc_path($diffinfo->{'to_file'});
2322        }
2323        $result .= "</div>\n" . # class="diff header"
2324                   "<div class=\"diff nodifferences\">" .
2325                   "Simple merge" .
2326                   "</div>\n"; # class="diff nodifferences"
2327
2328        return $result;
2329}
2330
2331sub diff_line_class {
2332        my ($line, $from, $to) = @_;
2333
2334        # ordinary diff
2335        my $num_sign = 1;
2336        # combined diff
2337        if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2338                $num_sign = scalar @{$from->{'href'}};
2339        }
2340
2341        my @diff_line_classifier = (
2342                { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2343                { regexp => qr/^\\/,               class => "incomplete"  },
2344                { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2345                # classifier for context must come before classifier add/rem,
2346                # or we would have to use more complicated regexp, for example
2347                # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2348                { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2349                { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2350        );
2351        for my $clsfy (@diff_line_classifier) {
2352                return $clsfy->{'class'}
2353                        if ($line =~ $clsfy->{'regexp'});
2354        }
2355
2356        # fallback
2357        return "";
2358}
2359
2360# assumes that $from and $to are defined and correctly filled,
2361# and that $line holds a line of chunk header for unified diff
2362sub format_unidiff_chunk_header {
2363        my ($line, $from, $to) = @_;
2364
2365        my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2366                $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2367
2368        $from_lines = 0 unless defined $from_lines;
2369        $to_lines   = 0 unless defined $to_lines;
2370
2371        if ($from->{'href'}) {
2372                $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2373                                     -class=>"list"}, $from_text);
2374        }
2375        if ($to->{'href'}) {
2376                $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2377                                     -class=>"list"}, $to_text);
2378        }
2379        $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2380                "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2381        return $line;
2382}
2383
2384# assumes that $from and $to are defined and correctly filled,
2385# and that $line holds a line of chunk header for combined diff
2386sub format_cc_diff_chunk_header {
2387        my ($line, $from, $to) = @_;
2388
2389        my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2390        my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2391
2392        @from_text = split(' ', $ranges);
2393        for (my $i = 0; $i < @from_text; ++$i) {
2394                ($from_start[$i], $from_nlines[$i]) =
2395                        (split(',', substr($from_text[$i], 1)), 0);
2396        }
2397
2398        $to_text   = pop @from_text;
2399        $to_start  = pop @from_start;
2400        $to_nlines = pop @from_nlines;
2401
2402        $line = "<span class=\"chunk_info\">$prefix ";
2403        for (my $i = 0; $i < @from_text; ++$i) {
2404                if ($from->{'href'}[$i]) {
2405                        $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2406                                          -class=>"list"}, $from_text[$i]);
2407                } else {
2408                        $line .= $from_text[$i];
2409                }
2410                $line .= " ";
2411        }
2412        if ($to->{'href'}) {
2413                $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2414                                  -class=>"list"}, $to_text);
2415        } else {
2416                $line .= $to_text;
2417        }
2418        $line .= " $prefix</span>" .
2419                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2420        return $line;
2421}
2422
2423# process patch (diff) line (not to be used for diff headers),
2424# returning class and HTML-formatted (but not wrapped) line
2425sub process_diff_line {
2426        my $line = shift;
2427        my ($from, $to) = @_;
2428
2429        my $diff_class = diff_line_class($line, $from, $to);
2430
2431        chomp $line;
2432        $line = untabify($line);
2433
2434        if ($from && $to && $line =~ m/^\@{2} /) {
2435                $line = format_unidiff_chunk_header($line, $from, $to);
2436                return $diff_class, $line;
2437
2438        } elsif ($from && $to && $line =~ m/^\@{3}/) {
2439                $line = format_cc_diff_chunk_header($line, $from, $to);
2440                return $diff_class, $line;
2441
2442        }
2443        return $diff_class, esc_html($line, -nbsp=>1);
2444}
2445
2446# Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2447# linked.  Pass the hash of the tree/commit to snapshot.
2448sub format_snapshot_links {
2449        my ($hash) = @_;
2450        my $num_fmts = @snapshot_fmts;
2451        if ($num_fmts > 1) {
2452                # A parenthesized list of links bearing format names.
2453                # e.g. "snapshot (_tar.gz_ _zip_)"
2454                return "snapshot (" . join(' ', map
2455                        $cgi->a({
2456                                -href => href(
2457                                        action=>"snapshot",
2458                                        hash=>$hash,
2459                                        snapshot_format=>$_
2460                                )
2461                        }, $known_snapshot_formats{$_}{'display'})
2462                , @snapshot_fmts) . ")";
2463        } elsif ($num_fmts == 1) {
2464                # A single "snapshot" link whose tooltip bears the format name.
2465                # i.e. "_snapshot_"
2466                my ($fmt) = @snapshot_fmts;
2467                return
2468                        $cgi->a({
2469                                -href => href(
2470                                        action=>"snapshot",
2471                                        hash=>$hash,
2472                                        snapshot_format=>$fmt
2473                                ),
2474                                -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2475                        }, "snapshot");
2476        } else { # $num_fmts == 0
2477                return undef;
2478        }
2479}
2480
2481## ......................................................................
2482## functions returning values to be passed, perhaps after some
2483## transformation, to other functions; e.g. returning arguments to href()
2484
2485# returns hash to be passed to href to generate gitweb URL
2486# in -title key it returns description of link
2487sub get_feed_info {
2488        my $format = shift || 'Atom';
2489        my %res = (action => lc($format));
2490
2491        # feed links are possible only for project views
2492        return unless (defined $project);
2493        # some views should link to OPML, or to generic project feed,
2494        # or don't have specific feed yet (so they should use generic)
2495        return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2496
2497        my $branch;
2498        # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2499        # from tag links; this also makes possible to detect branch links
2500        if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2501            (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2502                $branch = $1;
2503        }
2504        # find log type for feed description (title)
2505        my $type = 'log';
2506        if (defined $file_name) {
2507                $type  = "history of $file_name";
2508                $type .= "/" if ($action eq 'tree');
2509                $type .= " on '$branch'" if (defined $branch);
2510        } else {
2511                $type = "log of $branch" if (defined $branch);
2512        }
2513
2514        $res{-title} = $type;
2515        $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2516        $res{'file_name'} = $file_name;
2517
2518        return %res;
2519}
2520
2521## ----------------------------------------------------------------------
2522## git utility subroutines, invoking git commands
2523
2524# returns path to the core git executable and the --git-dir parameter as list
2525sub git_cmd {
2526        $number_of_git_cmds++;
2527        return $GIT, '--git-dir='.$git_dir;
2528}
2529
2530# quote the given arguments for passing them to the shell
2531# quote_command("command", "arg 1", "arg with ' and ! characters")
2532# => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2533# Try to avoid using this function wherever possible.
2534sub quote_command {
2535        return join(' ',
2536                map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2537}
2538
2539# get HEAD ref of given project as hash
2540sub git_get_head_hash {
2541        return git_get_full_hash(shift, 'HEAD');
2542}
2543
2544sub git_get_full_hash {
2545        return git_get_hash(@_);
2546}
2547
2548sub git_get_short_hash {
2549        return git_get_hash(@_, '--short=7');
2550}
2551
2552sub git_get_hash {
2553        my ($project, $hash, @options) = @_;
2554        my $o_git_dir = $git_dir;
2555        my $retval = undef;
2556        $git_dir = "$projectroot/$project";
2557        if (open my $fd, '-|', git_cmd(), 'rev-parse',
2558            '--verify', '-q', @options, $hash) {
2559                $retval = <$fd>;
2560                chomp $retval if defined $retval;
2561                close $fd;
2562        }
2563        if (defined $o_git_dir) {
2564                $git_dir = $o_git_dir;
2565        }
2566        return $retval;
2567}
2568
2569# get type of given object
2570sub git_get_type {
2571        my $hash = shift;
2572
2573        open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2574        my $type = <$fd>;
2575        close $fd or return;
2576        chomp $type;
2577        return $type;
2578}
2579
2580# repository configuration
2581our $config_file = '';
2582our %config;
2583
2584# store multiple values for single key as anonymous array reference
2585# single values stored directly in the hash, not as [ <value> ]
2586sub hash_set_multi {
2587        my ($hash, $key, $value) = @_;
2588
2589        if (!exists $hash->{$key}) {
2590                $hash->{$key} = $value;
2591        } elsif (!ref $hash->{$key}) {
2592                $hash->{$key} = [ $hash->{$key}, $value ];
2593        } else {
2594                push @{$hash->{$key}}, $value;
2595        }
2596}
2597
2598# return hash of git project configuration
2599# optionally limited to some section, e.g. 'gitweb'
2600sub git_parse_project_config {
2601        my $section_regexp = shift;
2602        my %config;
2603
2604        local $/ = "\0";
2605
2606        open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2607                or return;
2608
2609        while (my $keyval = <$fh>) {
2610                chomp $keyval;
2611                my ($key, $value) = split(/\n/, $keyval, 2);
2612
2613                hash_set_multi(\%config, $key, $value)
2614                        if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2615        }
2616        close $fh;
2617
2618        return %config;
2619}
2620
2621# convert config value to boolean: 'true' or 'false'
2622# no value, number > 0, 'true' and 'yes' values are true
2623# rest of values are treated as false (never as error)
2624sub config_to_bool {
2625        my $val = shift;
2626
2627        return 1 if !defined $val;             # section.key
2628
2629        # strip leading and trailing whitespace
2630        $val =~ s/^\s+//;
2631        $val =~ s/\s+$//;
2632
2633        return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2634                ($val =~ /^(?:true|yes)$/i));  # section.key = true
2635}
2636
2637# convert config value to simple decimal number
2638# an optional value suffix of 'k', 'm', or 'g' will cause the value
2639# to be multiplied by 1024, 1048576, or 1073741824
2640sub config_to_int {
2641        my $val = shift;
2642
2643        # strip leading and trailing whitespace
2644        $val =~ s/^\s+//;
2645        $val =~ s/\s+$//;
2646
2647        if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2648                $unit = lc($unit);
2649                # unknown unit is treated as 1
2650                return $num * ($unit eq 'g' ? 1073741824 :
2651                               $unit eq 'm' ?    1048576 :
2652                               $unit eq 'k' ?       1024 : 1);
2653        }
2654        return $val;
2655}
2656
2657# convert config value to array reference, if needed
2658sub config_to_multi {
2659        my $val = shift;
2660
2661        return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2662}
2663
2664sub git_get_project_config {
2665        my ($key, $type) = @_;
2666
2667        return unless defined $git_dir;
2668
2669        # key sanity check
2670        return unless ($key);
2671        # only subsection, if exists, is case sensitive,
2672        # and not lowercased by 'git config -z -l'
2673        if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2674                $key = join(".", lc($hi), $mi, lc($lo));
2675        } else {
2676                $key = lc($key);
2677        }
2678        $key =~ s/^gitweb\.//;
2679        return if ($key =~ m/\W/);
2680
2681        # type sanity check
2682        if (defined $type) {
2683                $type =~ s/^--//;
2684                $type = undef
2685                        unless ($type eq 'bool' || $type eq 'int');
2686        }
2687
2688        # get config
2689        if (!defined $config_file ||
2690            $config_file ne "$git_dir/config") {
2691                %config = git_parse_project_config('gitweb');
2692                $config_file = "$git_dir/config";
2693        }
2694
2695        # check if config variable (key) exists
2696        return unless exists $config{"gitweb.$key"};
2697
2698        # ensure given type
2699        if (!defined $type) {
2700                return $config{"gitweb.$key"};
2701        } elsif ($type eq 'bool') {
2702                # backward compatibility: 'git config --bool' returns true/false
2703                return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2704        } elsif ($type eq 'int') {
2705                return config_to_int($config{"gitweb.$key"});
2706        }
2707        return $config{"gitweb.$key"};
2708}
2709
2710# get hash of given path at given ref
2711sub git_get_hash_by_path {
2712        my $base = shift;
2713        my $path = shift || return undef;
2714        my $type = shift;
2715
2716        $path =~ s,/+$,,;
2717
2718        open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2719                or die_error(500, "Open git-ls-tree failed");
2720        my $line = <$fd>;
2721        close $fd or return undef;
2722
2723        if (!defined $line) {
2724                # there is no tree or hash given by $path at $base
2725                return undef;
2726        }
2727
2728        #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2729        $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2730        if (defined $type && $type ne $2) {
2731                # type doesn't match
2732                return undef;
2733        }
2734        return $3;
2735}
2736
2737# get path of entry with given hash at given tree-ish (ref)
2738# used to get 'from' filename for combined diff (merge commit) for renames
2739sub git_get_path_by_hash {
2740        my $base = shift || return;
2741        my $hash = shift || return;
2742
2743        local $/ = "\0";
2744
2745        open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2746                or return undef;
2747        while (my $line = <$fd>) {
2748                chomp $line;
2749
2750                #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2751                #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2752                if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2753                        close $fd;
2754                        return $1;
2755                }
2756        }
2757        close $fd;
2758        return undef;
2759}
2760
2761## ......................................................................
2762## git utility functions, directly accessing git repository
2763
2764# get the value of config variable either from file named as the variable
2765# itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2766# configuration variable in the repository config file.
2767sub git_get_file_or_project_config {
2768        my ($path, $name) = @_;
2769
2770        $git_dir = "$projectroot/$path";
2771        open my $fd, '<', "$git_dir/$name"
2772                or return git_get_project_config($name);
2773        my $conf = <$fd>;
2774        close $fd;
2775        if (defined $conf) {
2776                chomp $conf;
2777        }
2778        return $conf;
2779}
2780
2781sub git_get_project_description {
2782        my $path = shift;
2783        return git_get_file_or_project_config($path, 'description');
2784}
2785
2786sub git_get_project_category {
2787        my $path = shift;
2788        return git_get_file_or_project_config($path, 'category');
2789}
2790
2791
2792# supported formats:
2793# * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2794#   - if its contents is a number, use it as tag weight,
2795#   - otherwise add a tag with weight 1
2796# * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2797#   the same value multiple times increases tag weight
2798# * `gitweb.ctag' multi-valued repo config variable
2799sub git_get_project_ctags {
2800        my $project = shift;
2801        my $ctags = {};
2802
2803        $git_dir = "$projectroot/$project";
2804        if (opendir my $dh, "$git_dir/ctags") {
2805                my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2806                foreach my $tagfile (@files) {
2807                        open my $ct, '<', $tagfile
2808                                or next;
2809                        my $val = <$ct>;
2810                        chomp $val if $val;
2811                        close $ct;
2812
2813                        (my $ctag = $tagfile) =~ s#.*/##;
2814                        if ($val =~ /^\d+$/) {
2815                                $ctags->{$ctag} = $val;
2816                        } else {
2817                                $ctags->{$ctag} = 1;
2818                        }
2819                }
2820                closedir $dh;
2821
2822        } elsif (open my $fh, '<', "$git_dir/ctags") {
2823                while (my $line = <$fh>) {
2824                        chomp $line;
2825                        $ctags->{$line}++ if $line;
2826                }
2827                close $fh;
2828
2829        } else {
2830                my $taglist = config_to_multi(git_get_project_config('ctag'));
2831                foreach my $tag (@$taglist) {
2832                        $ctags->{$tag}++;
2833                }
2834        }
2835
2836        return $ctags;
2837}
2838
2839# return hash, where keys are content tags ('ctags'),
2840# and values are sum of weights of given tag in every project
2841sub git_gather_all_ctags {
2842        my $projects = shift;
2843        my $ctags = {};
2844
2845        foreach my $p (@$projects) {
2846                foreach my $ct (keys %{$p->{'ctags'}}) {
2847                        $ctags->{$ct} += $p->{'ctags'}->{$ct};
2848                }
2849        }
2850
2851        return $ctags;
2852}
2853
2854sub git_populate_project_tagcloud {
2855        my $ctags = shift;
2856
2857        # First, merge different-cased tags; tags vote on casing
2858        my %ctags_lc;
2859        foreach (keys %$ctags) {
2860                $ctags_lc{lc $_}->{count} += $ctags->{$_};
2861                if (not $ctags_lc{lc $_}->{topcount}
2862                    or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2863                        $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2864                        $ctags_lc{lc $_}->{topname} = $_;
2865                }
2866        }
2867
2868        my $cloud;
2869        my $matched = $input_params{'ctag'};
2870        if (eval { require HTML::TagCloud; 1; }) {
2871                $cloud = HTML::TagCloud->new;
2872                foreach my $ctag (sort keys %ctags_lc) {
2873                        # Pad the title with spaces so that the cloud looks
2874                        # less crammed.
2875                        my $title = esc_html($ctags_lc{$ctag}->{topname});
2876                        $title =~ s/ /&nbsp;/g;
2877                        $title =~ s/^/&nbsp;/g;
2878                        $title =~ s/$/&nbsp;/g;
2879                        if (defined $matched && $matched eq $ctag) {
2880                                $title = qq(<span class="match">$title</span>);
2881                        }
2882                        $cloud->add($title, href(project=>undef, ctag=>$ctag),
2883                                    $ctags_lc{$ctag}->{count});
2884                }
2885        } else {
2886                $cloud = {};
2887                foreach my $ctag (keys %ctags_lc) {
2888                        my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2889                        if (defined $matched && $matched eq $ctag) {
2890                                $title = qq(<span class="match">$title</span>);
2891                        }
2892                        $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2893                        $cloud->{$ctag}{ctag} =
2894                                $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2895                }
2896        }
2897        return $cloud;
2898}
2899
2900sub git_show_project_tagcloud {
2901        my ($cloud, $count) = @_;
2902        if (ref $cloud eq 'HTML::TagCloud') {
2903                return $cloud->html_and_css($count);
2904        } else {
2905                my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2906                return
2907                        '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2908                        join (', ', map {
2909                                $cloud->{$_}->{'ctag'}
2910                        } splice(@tags, 0, $count)) .
2911                        '</div>';
2912        }
2913}
2914
2915sub git_get_project_url_list {
2916        my $path = shift;
2917
2918        $git_dir = "$projectroot/$path";
2919        open my $fd, '<', "$git_dir/cloneurl"
2920                or return wantarray ?
2921                @{ config_to_multi(git_get_project_config('url')) } :
2922                   config_to_multi(git_get_project_config('url'));
2923        my @git_project_url_list = map { chomp; $_ } <$fd>;
2924        close $fd;
2925
2926        return wantarray ? @git_project_url_list : \@git_project_url_list;
2927}
2928
2929sub git_get_projects_list {
2930        my $filter = shift || '';
2931        my $paranoid = shift;
2932        my @list;
2933
2934        if (-d $projects_list) {
2935                # search in directory
2936                my $dir = $projects_list;
2937                # remove the trailing "/"
2938                $dir =~ s!/+$!!;
2939                my $pfxlen = length("$dir");
2940                my $pfxdepth = ($dir =~ tr!/!!);
2941                # when filtering, search only given subdirectory
2942                if ($filter && !$paranoid) {
2943                        $dir .= "/$filter";
2944                        $dir =~ s!/+$!!;
2945                }
2946
2947                File::Find::find({
2948                        follow_fast => 1, # follow symbolic links
2949                        follow_skip => 2, # ignore duplicates
2950                        dangling_symlinks => 0, # ignore dangling symlinks, silently
2951                        wanted => sub {
2952                                # global variables
2953                                our $project_maxdepth;
2954                                our $projectroot;
2955                                # skip project-list toplevel, if we get it.
2956                                return if (m!^[/.]$!);
2957                                # only directories can be git repositories
2958                                return unless (-d $_);
2959                                # don't traverse too deep (Find is super slow on os x)
2960                                # $project_maxdepth excludes depth of $projectroot
2961                                if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2962                                        $File::Find::prune = 1;
2963                                        return;
2964                                }
2965
2966                                my $path = substr($File::Find::name, $pfxlen + 1);
2967                                # paranoidly only filter here
2968                                if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
2969                                        next;
2970                                }
2971                                # we check related file in $projectroot
2972                                if (check_export_ok("$projectroot/$path")) {
2973                                        push @list, { path => $path };
2974                                        $File::Find::prune = 1;
2975                                }
2976                        },
2977                }, "$dir");
2978
2979        } elsif (-f $projects_list) {
2980                # read from file(url-encoded):
2981                # 'git%2Fgit.git Linus+Torvalds'
2982                # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2983                # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2984                open my $fd, '<', $projects_list or return;
2985        PROJECT:
2986                while (my $line = <$fd>) {
2987                        chomp $line;
2988                        my ($path, $owner) = split ' ', $line;
2989                        $path = unescape($path);
2990                        $owner = unescape($owner);
2991                        if (!defined $path) {
2992                                next;
2993                        }
2994                        # if $filter is rpovided, check if $path begins with $filter
2995                        if ($filter && $path !~ m!^\Q$filter\E/!) {
2996                                next;
2997                        }
2998                        if (check_export_ok("$projectroot/$path")) {
2999                                my $pr = {
3000                                        path => $path,
3001                                        owner => to_utf8($owner),
3002                                };
3003                                push @list, $pr;
3004                        }
3005                }
3006                close $fd;
3007        }
3008        return @list;
3009}
3010
3011# written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3012# as side effects it sets 'forks' field to list of forks for forked projects
3013sub filter_forks_from_projects_list {
3014        my $projects = shift;
3015
3016        my %trie; # prefix tree of directories (path components)
3017        # generate trie out of those directories that might contain forks
3018        foreach my $pr (@$projects) {
3019                my $path = $pr->{'path'};
3020                $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3021                next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3022                next unless ($path);      # skip '.git' repository: tests, git-instaweb
3023                next unless (-d "$projectroot/$path"); # containing directory exists
3024                $pr->{'forks'} = [];      # there can be 0 or more forks of project
3025
3026                # add to trie
3027                my @dirs = split('/', $path);
3028                # walk the trie, until either runs out of components or out of trie
3029                my $ref = \%trie;
3030                while (scalar @dirs &&
3031                       exists($ref->{$dirs[0]})) {
3032                        $ref = $ref->{shift @dirs};
3033                }
3034                # create rest of trie structure from rest of components
3035                foreach my $dir (@dirs) {
3036                        $ref = $ref->{$dir} = {};
3037                }
3038                # create end marker, store $pr as a data
3039                $ref->{''} = $pr if (!exists $ref->{''});
3040        }
3041
3042        # filter out forks, by finding shortest prefix match for paths
3043        my @filtered;
3044 PROJECT:
3045        foreach my $pr (@$projects) {
3046                # trie lookup
3047                my $ref = \%trie;
3048        DIR:
3049                foreach my $dir (split('/', $pr->{'path'})) {
3050                        if (exists $ref->{''}) {
3051                                # found [shortest] prefix, is a fork - skip it
3052                                push @{$ref->{''}{'forks'}}, $pr;
3053                                next PROJECT;
3054                        }
3055                        if (!exists $ref->{$dir}) {
3056                                # not in trie, cannot have prefix, not a fork
3057                                push @filtered, $pr;
3058                                next PROJECT;
3059                        }
3060                        # If the dir is there, we just walk one step down the trie.
3061                        $ref = $ref->{$dir};
3062                }
3063                # we ran out of trie
3064                # (shouldn't happen: it's either no match, or end marker)
3065                push @filtered, $pr;
3066        }
3067
3068        return @filtered;
3069}
3070
3071# note: fill_project_list_info must be run first,
3072# for 'descr_long' and 'ctags' to be filled
3073sub search_projects_list {
3074        my ($projlist, %opts) = @_;
3075        my $tagfilter  = $opts{'tagfilter'};
3076        my $searchtext = $opts{'searchtext'};
3077
3078        return @$projlist
3079                unless ($tagfilter || $searchtext);
3080
3081        # searching projects require filling to be run before it;
3082        fill_project_list_info($projlist,
3083                               $tagfilter  ? 'ctags' : (),
3084                               $searchtext ? ('path', 'descr') : ());
3085        my @projects;
3086 PROJECT:
3087        foreach my $pr (@$projlist) {
3088
3089                if ($tagfilter) {
3090                        next unless ref($pr->{'ctags'}) eq 'HASH';
3091                        next unless
3092                                grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3093                }
3094
3095                if ($searchtext) {
3096                        next unless
3097                                $pr->{'path'} =~ /$searchtext/ ||
3098                                $pr->{'descr_long'} =~ /$searchtext/;
3099                }
3100
3101                push @projects, $pr;
3102        }
3103
3104        return @projects;
3105}
3106
3107our $gitweb_project_owner = undef;
3108sub git_get_project_list_from_file {
3109
3110        return if (defined $gitweb_project_owner);
3111
3112        $gitweb_project_owner = {};
3113        # read from file (url-encoded):
3114        # 'git%2Fgit.git Linus+Torvalds'
3115        # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3116        # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3117        if (-f $projects_list) {
3118                open(my $fd, '<', $projects_list);
3119                while (my $line = <$fd>) {
3120                        chomp $line;
3121                        my ($pr, $ow) = split ' ', $line;
3122                        $pr = unescape($pr);
3123                        $ow = unescape($ow);
3124                        $gitweb_project_owner->{$pr} = to_utf8($ow);
3125                }
3126                close $fd;
3127        }
3128}
3129
3130sub git_get_project_owner {
3131        my $project = shift;
3132        my $owner;
3133
3134        return undef unless $project;
3135        $git_dir = "$projectroot/$project";
3136
3137        if (!defined $gitweb_project_owner) {
3138                git_get_project_list_from_file();
3139        }
3140
3141        if (exists $gitweb_project_owner->{$project}) {
3142                $owner = $gitweb_project_owner->{$project};
3143        }
3144        if (!defined $owner){
3145                $owner = git_get_project_config('owner');
3146        }
3147        if (!defined $owner) {
3148                $owner = get_file_owner("$git_dir");
3149        }
3150
3151        return $owner;
3152}
3153
3154sub git_get_last_activity {
3155        my ($path) = @_;
3156        my $fd;
3157
3158        $git_dir = "$projectroot/$path";
3159        open($fd, "-|", git_cmd(), 'for-each-ref',
3160             '--format=%(committer)',
3161             '--sort=-committerdate',
3162             '--count=1',
3163             'refs/heads') or return;
3164        my $most_recent = <$fd>;
3165        close $fd or return;
3166        if (defined $most_recent &&
3167            $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3168                my $timestamp = $1;
3169                my $age = time - $timestamp;
3170                return ($age, age_string($age));
3171        }
3172        return (undef, undef);
3173}
3174
3175# Implementation note: when a single remote is wanted, we cannot use 'git
3176# remote show -n' because that command always work (assuming it's a remote URL
3177# if it's not defined), and we cannot use 'git remote show' because that would
3178# try to make a network roundtrip. So the only way to find if that particular
3179# remote is defined is to walk the list provided by 'git remote -v' and stop if
3180# and when we find what we want.
3181sub git_get_remotes_list {
3182        my $wanted = shift;
3183        my %remotes = ();
3184
3185        open my $fd, '-|' , git_cmd(), 'remote', '-v';
3186        return unless $fd;
3187        while (my $remote = <$fd>) {
3188                chomp $remote;
3189                $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3190                next if $wanted and not $remote eq $wanted;
3191                my ($url, $key) = ($1, $2);
3192
3193                $remotes{$remote} ||= { 'heads' => () };
3194                $remotes{$remote}{$key} = $url;
3195        }
3196        close $fd or return;
3197        return wantarray ? %remotes : \%remotes;
3198}
3199
3200# Takes a hash of remotes as first parameter and fills it by adding the
3201# available remote heads for each of the indicated remotes.
3202sub fill_remote_heads {
3203        my $remotes = shift;
3204        my @heads = map { "remotes/$_" } keys %$remotes;
3205        my @remoteheads = git_get_heads_list(undef, @heads);
3206        foreach my $remote (keys %$remotes) {
3207                $remotes->{$remote}{'heads'} = [ grep {
3208                        $_->{'name'} =~ s!^$remote/!!
3209                        } @remoteheads ];
3210        }
3211}
3212
3213sub git_get_references {
3214        my $type = shift || "";
3215        my %refs;
3216        # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3217        # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3218        open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3219                ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3220                or return;
3221
3222        while (my $line = <$fd>) {
3223                chomp $line;
3224                if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3225                        if (defined $refs{$1}) {
3226                                push @{$refs{$1}}, $2;
3227                        } else {
3228                                $refs{$1} = [ $2 ];
3229                        }
3230                }
3231        }
3232        close $fd or return;
3233        return \%refs;
3234}
3235
3236sub git_get_rev_name_tags {
3237        my $hash = shift || return undef;
3238
3239        open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3240                or return;
3241        my $name_rev = <$fd>;
3242        close $fd;
3243
3244        if ($name_rev =~ m|^$hash tags/(.*)$|) {
3245                return $1;
3246        } else {
3247                # catches also '$hash undefined' output
3248                return undef;
3249        }
3250}
3251
3252## ----------------------------------------------------------------------
3253## parse to hash functions
3254
3255sub parse_date {
3256        my $epoch = shift;
3257        my $tz = shift || "-0000";
3258
3259        my %date;
3260        my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3261        my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3262        my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3263        $date{'hour'} = $hour;
3264        $date{'minute'} = $min;
3265        $date{'mday'} = $mday;
3266        $date{'day'} = $days[$wday];
3267        $date{'month'} = $months[$mon];
3268        $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3269                             $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3270        $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3271                             $mday, $months[$mon], $hour ,$min;
3272        $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3273                             1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3274
3275        my ($tz_sign, $tz_hour, $tz_min) =
3276                ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3277        $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3278        my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3279        ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3280        $date{'hour_local'} = $hour;
3281        $date{'minute_local'} = $min;
3282        $date{'tz_local'} = $tz;
3283        $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3284                                  1900+$year, $mon+1, $mday,
3285                                  $hour, $min, $sec, $tz);
3286        return %date;
3287}
3288
3289sub parse_tag {
3290        my $tag_id = shift;
3291        my %tag;
3292        my @comment;
3293
3294        open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3295        $tag{'id'} = $tag_id;
3296        while (my $line = <$fd>) {
3297                chomp $line;
3298                if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3299                        $tag{'object'} = $1;
3300                } elsif ($line =~ m/^type (.+)$/) {
3301                        $tag{'type'} = $1;
3302                } elsif ($line =~ m/^tag (.+)$/) {
3303                        $tag{'name'} = $1;
3304                } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3305                        $tag{'author'} = $1;
3306                        $tag{'author_epoch'} = $2;
3307                        $tag{'author_tz'} = $3;
3308                        if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3309                                $tag{'author_name'}  = $1;
3310                                $tag{'author_email'} = $2;
3311                        } else {
3312                                $tag{'author_name'} = $tag{'author'};
3313                        }
3314                } elsif ($line =~ m/--BEGIN/) {
3315                        push @comment, $line;
3316                        last;
3317                } elsif ($line eq "") {
3318                        last;
3319                }
3320        }
3321        push @comment, <$fd>;
3322        $tag{'comment'} = \@comment;
3323        close $fd or return;
3324        if (!defined $tag{'name'}) {
3325                return
3326        };
3327        return %tag
3328}
3329
3330sub parse_commit_text {
3331        my ($commit_text, $withparents) = @_;
3332        my @commit_lines = split '\n', $commit_text;
3333        my %co;
3334
3335        pop @commit_lines; # Remove '\0'
3336
3337        if (! @commit_lines) {
3338                return;
3339        }
3340
3341        my $header = shift @commit_lines;
3342        if ($header !~ m/^[0-9a-fA-F]{40}/) {
3343                return;
3344        }
3345        ($co{'id'}, my @parents) = split ' ', $header;
3346        while (my $line = shift @commit_lines) {
3347                last if $line eq "\n";
3348                if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3349                        $co{'tree'} = $1;
3350                } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3351                        push @parents, $1;
3352                } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3353                        $co{'author'} = to_utf8($1);
3354                        $co{'author_epoch'} = $2;
3355                        $co{'author_tz'} = $3;
3356                        if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3357                                $co{'author_name'}  = $1;
3358                                $co{'author_email'} = $2;
3359                        } else {
3360                                $co{'author_name'} = $co{'author'};
3361                        }
3362                } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3363                        $co{'committer'} = to_utf8($1);
3364                        $co{'committer_epoch'} = $2;
3365                        $co{'committer_tz'} = $3;
3366                        if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3367                                $co{'committer_name'}  = $1;
3368                                $co{'committer_email'} = $2;
3369                        } else {
3370                                $co{'committer_name'} = $co{'committer'};
3371                        }
3372                }
3373        }
3374        if (!defined $co{'tree'}) {
3375                return;
3376        };
3377        $co{'parents'} = \@parents;
3378        $co{'parent'} = $parents[0];
3379
3380        foreach my $title (@commit_lines) {
3381                $title =~ s/^    //;
3382                if ($title ne "") {
3383                        $co{'title'} = chop_str($title, 80, 5);
3384                        # remove leading stuff of merges to make the interesting part visible
3385                        if (length($title) > 50) {
3386                                $title =~ s/^Automatic //;
3387                                $title =~ s/^merge (of|with) /Merge ... /i;
3388                                if (length($title) > 50) {
3389                                        $title =~ s/(http|rsync):\/\///;
3390                                }
3391                                if (length($title) > 50) {
3392                                        $title =~ s/(master|www|rsync)\.//;
3393                                }
3394                                if (length($title) > 50) {
3395                                        $title =~ s/kernel.org:?//;
3396                                }
3397                                if (length($title) > 50) {
3398                                        $title =~ s/\/pub\/scm//;
3399                                }
3400                        }
3401                        $co{'title_short'} = chop_str($title, 50, 5);
3402                        last;
3403                }
3404        }
3405        if (! defined $co{'title'} || $co{'title'} eq "") {
3406                $co{'title'} = $co{'title_short'} = '(no commit message)';
3407        }
3408        # remove added spaces
3409        foreach my $line (@commit_lines) {
3410                $line =~ s/^    //;
3411        }
3412        $co{'comment'} = \@commit_lines;
3413
3414        my $age = time - $co{'committer_epoch'};
3415        $co{'age'} = $age;
3416        $co{'age_string'} = age_string($age);
3417        my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3418        if ($age > 60*60*24*7*2) {
3419                $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3420                $co{'age_string_age'} = $co{'age_string'};
3421        } else {
3422                $co{'age_string_date'} = $co{'age_string'};
3423                $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3424        }
3425        return %co;
3426}
3427
3428sub parse_commit {
3429        my ($commit_id) = @_;
3430        my %co;
3431
3432        local $/ = "\0";
3433
3434        open my $fd, "-|", git_cmd(), "rev-list",
3435                "--parents",
3436                "--header",
3437                "--max-count=1",
3438                $commit_id,
3439                "--",
3440                or die_error(500, "Open git-rev-list failed");
3441        %co = parse_commit_text(<$fd>, 1);
3442        close $fd;
3443
3444        return %co;
3445}
3446
3447sub parse_commits {
3448        my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3449        my @cos;
3450
3451        $maxcount ||= 1;
3452        $skip ||= 0;
3453
3454        local $/ = "\0";
3455
3456        open my $fd, "-|", git_cmd(), "rev-list",
3457                "--header",
3458                @args,
3459                ("--max-count=" . $maxcount),
3460                ("--skip=" . $skip),
3461                @extra_options,
3462                $commit_id,
3463                "--",
3464                ($filename ? ($filename) : ())
3465                or die_error(500, "Open git-rev-list failed");
3466        while (my $line = <$fd>) {
3467                my %co = parse_commit_text($line);
3468                push @cos, \%co;
3469        }
3470        close $fd;
3471
3472        return wantarray ? @cos : \@cos;
3473}
3474
3475# parse line of git-diff-tree "raw" output
3476sub parse_difftree_raw_line {
3477        my $line = shift;
3478        my %res;
3479
3480        # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3481        # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3482        if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3483                $res{'from_mode'} = $1;
3484                $res{'to_mode'} = $2;
3485                $res{'from_id'} = $3;
3486                $res{'to_id'} = $4;
3487                $res{'status'} = $5;
3488                $res{'similarity'} = $6;
3489                if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3490                        ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3491                } else {
3492                        $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3493                }
3494        }
3495        # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3496        # combined diff (for merge commit)
3497        elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3498                $res{'nparents'}  = length($1);
3499                $res{'from_mode'} = [ split(' ', $2) ];
3500                $res{'to_mode'} = pop @{$res{'from_mode'}};
3501                $res{'from_id'} = [ split(' ', $3) ];
3502                $res{'to_id'} = pop @{$res{'from_id'}};
3503                $res{'status'} = [ split('', $4) ];
3504                $res{'to_file'} = unquote($5);
3505        }
3506        # 'c512b523472485aef4fff9e57b229d9d243c967f'
3507        elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3508                $res{'commit'} = $1;
3509        }
3510
3511        return wantarray ? %res : \%res;
3512}
3513
3514# wrapper: return parsed line of git-diff-tree "raw" output
3515# (the argument might be raw line, or parsed info)
3516sub parsed_difftree_line {
3517        my $line_or_ref = shift;
3518
3519        if (ref($line_or_ref) eq "HASH") {
3520                # pre-parsed (or generated by hand)
3521                return $line_or_ref;
3522        } else {
3523                return parse_difftree_raw_line($line_or_ref);
3524        }
3525}
3526
3527# parse line of git-ls-tree output
3528sub parse_ls_tree_line {
3529        my $line = shift;
3530        my %opts = @_;
3531        my %res;
3532
3533        if ($opts{'-l'}) {
3534                #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3535                $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3536
3537                $res{'mode'} = $1;
3538                $res{'type'} = $2;
3539                $res{'hash'} = $3;
3540                $res{'size'} = $4;
3541                if ($opts{'-z'}) {
3542                        $res{'name'} = $5;
3543                } else {
3544                        $res{'name'} = unquote($5);
3545                }
3546        } else {
3547                #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3548                $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3549
3550                $res{'mode'} = $1;
3551                $res{'type'} = $2;
3552                $res{'hash'} = $3;
3553                if ($opts{'-z'}) {
3554                        $res{'name'} = $4;
3555                } else {
3556                        $res{'name'} = unquote($4);
3557                }
3558        }
3559
3560        return wantarray ? %res : \%res;
3561}
3562
3563# generates _two_ hashes, references to which are passed as 2 and 3 argument
3564sub parse_from_to_diffinfo {
3565        my ($diffinfo, $from, $to, @parents) = @_;
3566
3567        if ($diffinfo->{'nparents'}) {
3568                # combined diff
3569                $from->{'file'} = [];
3570                $from->{'href'} = [];
3571                fill_from_file_info($diffinfo, @parents)
3572                        unless exists $diffinfo->{'from_file'};
3573                for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3574                        $from->{'file'}[$i] =
3575                                defined $diffinfo->{'from_file'}[$i] ?
3576                                        $diffinfo->{'from_file'}[$i] :
3577                                        $diffinfo->{'to_file'};
3578                        if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3579                                $from->{'href'}[$i] = href(action=>"blob",
3580                                                           hash_base=>$parents[$i],
3581                                                           hash=>$diffinfo->{'from_id'}[$i],
3582                                                           file_name=>$from->{'file'}[$i]);
3583                        } else {
3584                                $from->{'href'}[$i] = undef;
3585                        }
3586                }
3587        } else {
3588                # ordinary (not combined) diff
3589                $from->{'file'} = $diffinfo->{'from_file'};
3590                if ($diffinfo->{'status'} ne "A") { # not new (added) file
3591                        $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3592                                               hash=>$diffinfo->{'from_id'},
3593                                               file_name=>$from->{'file'});
3594                } else {
3595                        delete $from->{'href'};
3596                }
3597        }
3598
3599        $to->{'file'} = $diffinfo->{'to_file'};
3600        if (!is_deleted($diffinfo)) { # file exists in result
3601                $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3602                                     hash=>$diffinfo->{'to_id'},
3603                                     file_name=>$to->{'file'});
3604        } else {
3605                delete $to->{'href'};
3606        }
3607}
3608
3609## ......................................................................
3610## parse to array of hashes functions
3611
3612sub git_get_heads_list {
3613        my ($limit, @classes) = @_;
3614        @classes = ('heads') unless @classes;
3615        my @patterns = map { "refs/$_" } @classes;
3616        my @headslist;
3617
3618        open my $fd, '-|', git_cmd(), 'for-each-ref',
3619                ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3620                '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3621                @patterns
3622                or return;
3623        while (my $line = <$fd>) {
3624                my %ref_item;
3625
3626                chomp $line;
3627                my ($refinfo, $committerinfo) = split(/\0/, $line);
3628                my ($hash, $name, $title) = split(' ', $refinfo, 3);
3629                my ($committer, $epoch, $tz) =
3630                        ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3631                $ref_item{'fullname'}  = $name;
3632                $name =~ s!^refs/(?:head|remote)s/!!;
3633
3634                $ref_item{'name'}  = $name;
3635                $ref_item{'id'}    = $hash;
3636                $ref_item{'title'} = $title || '(no commit message)';
3637                $ref_item{'epoch'} = $epoch;
3638                if ($epoch) {
3639                        $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3640                } else {
3641                        $ref_item{'age'} = "unknown";
3642                }
3643
3644                push @headslist, \%ref_item;
3645        }
3646        close $fd;
3647
3648        return wantarray ? @headslist : \@headslist;
3649}
3650
3651sub git_get_tags_list {
3652        my $limit = shift;
3653        my @tagslist;
3654
3655        open my $fd, '-|', git_cmd(), 'for-each-ref',
3656                ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3657                '--format=%(objectname) %(objecttype) %(refname) '.
3658                '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3659                'refs/tags'
3660                or return;
3661        while (my $line = <$fd>) {
3662                my %ref_item;
3663
3664                chomp $line;
3665                my ($refinfo, $creatorinfo) = split(/\0/, $line);
3666                my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3667                my ($creator, $epoch, $tz) =
3668                        ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3669                $ref_item{'fullname'} = $name;
3670                $name =~ s!^refs/tags/!!;
3671
3672                $ref_item{'type'} = $type;
3673                $ref_item{'id'} = $id;
3674                $ref_item{'name'} = $name;
3675                if ($type eq "tag") {
3676                        $ref_item{'subject'} = $title;
3677                        $ref_item{'reftype'} = $reftype;
3678                        $ref_item{'refid'}   = $refid;
3679                } else {
3680                        $ref_item{'reftype'} = $type;
3681                        $ref_item{'refid'}   = $id;
3682                }
3683
3684                if ($type eq "tag" || $type eq "commit") {
3685                        $ref_item{'epoch'} = $epoch;
3686                        if ($epoch) {
3687                                $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3688                        } else {
3689                                $ref_item{'age'} = "unknown";
3690                        }
3691                }
3692
3693                push @tagslist, \%ref_item;
3694        }
3695        close $fd;
3696
3697        return wantarray ? @tagslist : \@tagslist;
3698}
3699
3700## ----------------------------------------------------------------------
3701## filesystem-related functions
3702
3703sub get_file_owner {
3704        my $path = shift;
3705
3706        my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3707        my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3708        if (!defined $gcos) {
3709                return undef;
3710        }
3711        my $owner = $gcos;
3712        $owner =~ s/[,;].*$//;
3713        return to_utf8($owner);
3714}
3715
3716# assume that file exists
3717sub insert_file {
3718        my $filename = shift;
3719
3720        open my $fd, '<', $filename;
3721        print map { to_utf8($_) } <$fd>;
3722        close $fd;
3723}
3724
3725## ......................................................................
3726## mimetype related functions
3727
3728sub mimetype_guess_file {
3729        my $filename = shift;
3730        my $mimemap = shift;
3731        -r $mimemap or return undef;
3732
3733        my %mimemap;
3734        open(my $mh, '<', $mimemap) or return undef;
3735        while (<$mh>) {
3736                next if m/^#/; # skip comments
3737                my ($mimetype, @exts) = split(/\s+/);
3738                foreach my $ext (@exts) {
3739                        $mimemap{$ext} = $mimetype;
3740                }
3741        }
3742        close($mh);
3743
3744        $filename =~ /\.([^.]*)$/;
3745        return $mimemap{$1};
3746}
3747
3748sub mimetype_guess {
3749        my $filename = shift;
3750        my $mime;
3751        $filename =~ /\./ or return undef;
3752
3753        if ($mimetypes_file) {
3754                my $file = $mimetypes_file;
3755                if ($file !~ m!^/!) { # if it is relative path
3756                        # it is relative to project
3757                        $file = "$projectroot/$project/$file";
3758                }
3759                $mime = mimetype_guess_file($filename, $file);
3760        }
3761        $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3762        return $mime;
3763}
3764
3765sub blob_mimetype {
3766        my $fd = shift;
3767        my $filename = shift;
3768
3769        if ($filename) {
3770                my $mime = mimetype_guess($filename);
3771                $mime and return $mime;
3772        }
3773
3774        # just in case
3775        return $default_blob_plain_mimetype unless $fd;
3776
3777        if (-T $fd) {
3778                return 'text/plain';
3779        } elsif (! $filename) {
3780                return 'application/octet-stream';
3781        } elsif ($filename =~ m/\.png$/i) {
3782                return 'image/png';
3783        } elsif ($filename =~ m/\.gif$/i) {
3784                return 'image/gif';
3785        } elsif ($filename =~ m/\.jpe?g$/i) {
3786                return 'image/jpeg';
3787        } else {
3788                return 'application/octet-stream';
3789        }
3790}
3791
3792sub blob_contenttype {
3793        my ($fd, $file_name, $type) = @_;
3794
3795        $type ||= blob_mimetype($fd, $file_name);
3796        if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3797                $type .= "; charset=$default_text_plain_charset";
3798        }
3799
3800        return $type;
3801}
3802
3803# guess file syntax for syntax highlighting; return undef if no highlighting
3804# the name of syntax can (in the future) depend on syntax highlighter used
3805sub guess_file_syntax {
3806        my ($highlight, $mimetype, $file_name) = @_;
3807        return undef unless ($highlight && defined $file_name);
3808        my $basename = basename($file_name, '.in');
3809        return $highlight_basename{$basename}
3810                if exists $highlight_basename{$basename};
3811
3812        $basename =~ /\.([^.]*)$/;
3813        my $ext = $1 or return undef;
3814        return $highlight_ext{$ext}
3815                if exists $highlight_ext{$ext};
3816
3817        return undef;
3818}
3819
3820# run highlighter and return FD of its output,
3821# or return original FD if no highlighting
3822sub run_highlighter {
3823        my ($fd, $highlight, $syntax) = @_;
3824        return $fd unless ($highlight && defined $syntax);
3825
3826        close $fd;
3827        open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3828                  quote_command($highlight_bin).
3829                  " --replace-tabs=8 --fragment --syntax $syntax |"
3830                or die_error(500, "Couldn't open file or run syntax highlighter");
3831        return $fd;
3832}
3833
3834## ======================================================================
3835## functions printing HTML: header, footer, error page
3836
3837sub get_page_title {
3838        my $title = to_utf8($site_name);
3839
3840        unless (defined $project) {
3841                if (defined $project_filter) {
3842                        $title .= " - projects in '" . esc_path($project_filter) . "'";
3843                }
3844                return $title;
3845        }
3846        $title .= " - " . to_utf8($project);
3847
3848        return $title unless (defined $action);
3849        $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3850
3851        return $title unless (defined $file_name);
3852        $title .= " - " . esc_path($file_name);
3853        if ($action eq "tree" && $file_name !~ m|/$|) {
3854                $title .= "/";
3855        }
3856
3857        return $title;
3858}
3859
3860sub get_content_type_html {
3861        # require explicit support from the UA if we are to send the page as
3862        # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3863        # we have to do this because MSIE sometimes globs '*/*', pretending to
3864        # support xhtml+xml but choking when it gets what it asked for.
3865        if (defined $cgi->http('HTTP_ACCEPT') &&
3866            $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3867            $cgi->Accept('application/xhtml+xml') != 0) {
3868                return 'application/xhtml+xml';
3869        } else {
3870                return 'text/html';
3871        }
3872}
3873
3874sub print_feed_meta {
3875        if (defined $project) {
3876                my %href_params = get_feed_info();
3877                if (!exists $href_params{'-title'}) {
3878                        $href_params{'-title'} = 'log';
3879                }
3880
3881                foreach my $format (qw(RSS Atom)) {
3882                        my $type = lc($format);
3883                        my %link_attr = (
3884                                '-rel' => 'alternate',
3885                                '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3886                                '-type' => "application/$type+xml"
3887                        );
3888
3889                        $href_params{'action'} = $type;
3890                        $link_attr{'-href'} = href(%href_params);
3891                        print "<link ".
3892                              "rel=\"$link_attr{'-rel'}\" ".
3893                              "title=\"$link_attr{'-title'}\" ".
3894                              "href=\"$link_attr{'-href'}\" ".
3895                              "type=\"$link_attr{'-type'}\" ".
3896                              "/>\n";
3897
3898                        $href_params{'extra_options'} = '--no-merges';
3899                        $link_attr{'-href'} = href(%href_params);
3900                        $link_attr{'-title'} .= ' (no merges)';
3901                        print "<link ".
3902                              "rel=\"$link_attr{'-rel'}\" ".
3903                              "title=\"$link_attr{'-title'}\" ".
3904                              "href=\"$link_attr{'-href'}\" ".
3905                              "type=\"$link_attr{'-type'}\" ".
3906                              "/>\n";
3907                }
3908
3909        } else {
3910                printf('<link rel="alternate" title="%s projects list" '.
3911                       'href="%s" type="text/plain; charset=utf-8" />'."\n",
3912                       esc_attr($site_name), href(project=>undef, action=>"project_index"));
3913                printf('<link rel="alternate" title="%s projects feeds" '.
3914                       'href="%s" type="text/x-opml" />'."\n",
3915                       esc_attr($site_name), href(project=>undef, action=>"opml"));
3916        }
3917}
3918
3919sub print_header_links {
3920        my $status = shift;
3921
3922        # print out each stylesheet that exist, providing backwards capability
3923        # for those people who defined $stylesheet in a config file
3924        if (defined $stylesheet) {
3925                print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3926        } else {
3927                foreach my $stylesheet (@stylesheets) {
3928                        next unless $stylesheet;
3929                        print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3930                }
3931        }
3932        print_feed_meta()
3933                if ($status eq '200 OK');
3934        if (defined $favicon) {
3935                print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3936        }
3937}
3938
3939sub print_nav_breadcrumbs_path {
3940        my $dirprefix = undef;
3941        while (my $part = shift) {
3942                $dirprefix .= "/" if defined $dirprefix;
3943                $dirprefix .= $part;
3944                print $cgi->a({-href => href(project => undef,
3945                                             project_filter => $dirprefix,
3946                                             action => "project_list")},
3947                              esc_html($part)) . " / ";
3948        }
3949}
3950
3951sub print_nav_breadcrumbs {
3952        my %opts = @_;
3953
3954        print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3955        if (defined $project) {
3956                my @dirname = split '/', $project;
3957                my $projectbasename = pop @dirname;
3958                print_nav_breadcrumbs_path(@dirname);
3959                print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
3960                if (defined $action) {
3961                        my $action_print = $action ;
3962                        if (defined $opts{-action_extra}) {
3963                                $action_print = $cgi->a({-href => href(action=>$action)},
3964                                        $action);
3965                        }
3966                        print " / $action_print";
3967                }
3968                if (defined $opts{-action_extra}) {
3969                        print " / $opts{-action_extra}";
3970                }
3971                print "\n";
3972        } elsif (defined $project_filter) {
3973                print_nav_breadcrumbs_path(split '/', $project_filter);
3974        }
3975}
3976
3977sub print_search_form {
3978        if (!defined $searchtext) {
3979                $searchtext = "";
3980        }
3981        my $search_hash;
3982        if (defined $hash_base) {
3983                $search_hash = $hash_base;
3984        } elsif (defined $hash) {
3985                $search_hash = $hash;
3986        } else {
3987                $search_hash = "HEAD";
3988        }
3989        my $action = $my_uri;
3990        my $use_pathinfo = gitweb_check_feature('pathinfo');
3991        if ($use_pathinfo) {
3992                $action .= "/".esc_url($project);
3993        }
3994        print $cgi->startform(-method => "get", -action => $action) .
3995              "<div class=\"search\">\n" .
3996              (!$use_pathinfo &&
3997              $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3998              $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3999              $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4000              $cgi->popup_menu(-name => 'st', -default => 'commit',
4001                               -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4002              $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
4003              " search:\n",
4004              $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4005              "<span title=\"Extended regular expression\">" .
4006              $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4007                             -checked => $search_use_regexp) .
4008              "</span>" .
4009              "</div>" .
4010              $cgi->end_form() . "\n";
4011}
4012
4013sub git_header_html {
4014        my $status = shift || "200 OK";
4015        my $expires = shift;
4016        my %opts = @_;
4017
4018        my $title = get_page_title();
4019        my $content_type = get_content_type_html();
4020        print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4021                           -status=> $status, -expires => $expires)
4022                unless ($opts{'-no_http_header'});
4023        my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4024        print <<EOF;
4025<?xml version="1.0" encoding="utf-8"?>
4026<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4027<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4028<!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4029<!-- git core binaries version $git_version -->
4030<head>
4031<meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4032<meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4033<meta name="robots" content="index, nofollow"/>
4034<title>$title</title>
4035EOF
4036        # the stylesheet, favicon etc urls won't work correctly with path_info
4037        # unless we set the appropriate base URL
4038        if ($ENV{'PATH_INFO'}) {
4039                print "<base href=\"".esc_url($base_url)."\" />\n";
4040        }
4041        print_header_links($status);
4042
4043        if (defined $site_html_head_string) {
4044                print to_utf8($site_html_head_string);
4045        }
4046
4047        print "</head>\n" .
4048              "<body>\n";
4049
4050        if (defined $site_header && -f $site_header) {
4051                insert_file($site_header);
4052        }
4053
4054        print "<div class=\"page_header\">\n";
4055        if (defined $logo) {
4056                print $cgi->a({-href => esc_url($logo_url),
4057                               -title => $logo_label},
4058                              $cgi->img({-src => esc_url($logo),
4059                                         -width => 72, -height => 27,
4060                                         -alt => "git",
4061                                         -class => "logo"}));
4062        }
4063        print_nav_breadcrumbs(%opts);
4064        print "</div>\n";
4065
4066        my $have_search = gitweb_check_feature('search');
4067        if (defined $project && $have_search) {
4068                print_search_form();
4069        }
4070}
4071
4072sub git_footer_html {
4073        my $feed_class = 'rss_logo';
4074
4075        print "<div class=\"page_footer\">\n";
4076        if (defined $project) {
4077                my $descr = git_get_project_description($project);
4078                if (defined $descr) {
4079                        print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4080                }
4081
4082                my %href_params = get_feed_info();
4083                if (!%href_params) {
4084                        $feed_class .= ' generic';
4085                }
4086                $href_params{'-title'} ||= 'log';
4087
4088                foreach my $format (qw(RSS Atom)) {
4089                        $href_params{'action'} = lc($format);
4090                        print $cgi->a({-href => href(%href_params),
4091                                      -title => "$href_params{'-title'} $format feed",
4092                                      -class => $feed_class}, $format)."\n";
4093                }
4094
4095        } else {
4096                print $cgi->a({-href => href(project=>undef, action=>"opml",
4097                                             project_filter => $project_filter),
4098                              -class => $feed_class}, "OPML") . " ";
4099                print $cgi->a({-href => href(project=>undef, action=>"project_index",
4100                                             project_filter => $project_filter),
4101                              -class => $feed_class}, "TXT") . "\n";
4102        }
4103        print "</div>\n"; # class="page_footer"
4104
4105        if (defined $t0 && gitweb_check_feature('timed')) {
4106                print "<div id=\"generating_info\">\n";
4107                print 'This page took '.
4108                      '<span id="generating_time" class="time_span">'.
4109                      tv_interval($t0, [ gettimeofday() ]).
4110                      ' seconds </span>'.
4111                      ' and '.
4112                      '<span id="generating_cmd">'.
4113                      $number_of_git_cmds.
4114                      '</span> git commands '.
4115                      " to generate.\n";
4116                print "</div>\n"; # class="page_footer"
4117        }
4118
4119        if (defined $site_footer && -f $site_footer) {
4120                insert_file($site_footer);
4121        }
4122
4123        print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4124        if (defined $action &&
4125            $action eq 'blame_incremental') {
4126                print qq!<script type="text/javascript">\n!.
4127                      qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4128                      qq!           "!. href() .qq!");\n!.
4129                      qq!</script>\n!;
4130        } else {
4131                my ($jstimezone, $tz_cookie, $datetime_class) =
4132                        gitweb_get_feature('javascript-timezone');
4133
4134                print qq!<script type="text/javascript">\n!.
4135                      qq!window.onload = function () {\n!;
4136                if (gitweb_check_feature('javascript-actions')) {
4137                        print qq!       fixLinks();\n!;
4138                }
4139                if ($jstimezone && $tz_cookie && $datetime_class) {
4140                        print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4141                              qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4142                }
4143                print qq!};\n!.
4144                      qq!</script>\n!;
4145        }
4146
4147        print "</body>\n" .
4148              "</html>";
4149}
4150
4151# die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4152# Example: die_error(404, 'Hash not found')
4153# By convention, use the following status codes (as defined in RFC 2616):
4154# 400: Invalid or missing CGI parameters, or
4155#      requested object exists but has wrong type.
4156# 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4157#      this server or project.
4158# 404: Requested object/revision/project doesn't exist.
4159# 500: The server isn't configured properly, or
4160#      an internal error occurred (e.g. failed assertions caused by bugs), or
4161#      an unknown error occurred (e.g. the git binary died unexpectedly).
4162# 503: The server is currently unavailable (because it is overloaded,
4163#      or down for maintenance).  Generally, this is a temporary state.
4164sub die_error {
4165        my $status = shift || 500;
4166        my $error = esc_html(shift) || "Internal Server Error";
4167        my $extra = shift;
4168        my %opts = @_;
4169
4170        my %http_responses = (
4171                400 => '400 Bad Request',
4172                403 => '403 Forbidden',
4173                404 => '404 Not Found',
4174                500 => '500 Internal Server Error',
4175                503 => '503 Service Unavailable',
4176        );
4177        git_header_html($http_responses{$status}, undef, %opts);
4178        print <<EOF;
4179<div class="page_body">
4180<br /><br />
4181$status - $error
4182<br />
4183EOF
4184        if (defined $extra) {
4185                print "<hr />\n" .
4186                      "$extra\n";
4187        }
4188        print "</div>\n";
4189
4190        git_footer_html();
4191        goto DONE_GITWEB
4192                unless ($opts{'-error_handler'});
4193}
4194
4195## ----------------------------------------------------------------------
4196## functions printing or outputting HTML: navigation
4197
4198sub git_print_page_nav {
4199        my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4200        $extra = '' if !defined $extra; # pager or formats
4201
4202        my @navs = qw(summary shortlog log commit commitdiff tree);
4203        if ($suppress) {
4204                @navs = grep { $_ ne $suppress } @navs;
4205        }
4206
4207        my %arg = map { $_ => {action=>$_} } @navs;
4208        if (defined $head) {
4209                for (qw(commit commitdiff)) {
4210                        $arg{$_}{'hash'} = $head;
4211                }
4212                if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4213                        for (qw(shortlog log)) {
4214                                $arg{$_}{'hash'} = $head;
4215                        }
4216                }
4217        }
4218
4219        $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4220        $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4221
4222        my @actions = gitweb_get_feature('actions');
4223        my %repl = (
4224                '%' => '%',
4225                'n' => $project,         # project name
4226                'f' => $git_dir,         # project path within filesystem
4227                'h' => $treehead || '',  # current hash ('h' parameter)
4228                'b' => $treebase || '',  # hash base ('hb' parameter)
4229        );
4230        while (@actions) {
4231                my ($label, $link, $pos) = splice(@actions,0,3);
4232                # insert
4233                @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4234                # munch munch
4235                $link =~ s/%([%nfhb])/$repl{$1}/g;
4236                $arg{$label}{'_href'} = $link;
4237        }
4238
4239        print "<div class=\"page_nav\">\n" .
4240                (join " | ",
4241                 map { $_ eq $current ?
4242                       $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4243                 } @navs);
4244        print "<br/>\n$extra<br/>\n" .
4245              "</div>\n";
4246}
4247
4248# returns a submenu for the nagivation of the refs views (tags, heads,
4249# remotes) with the current view disabled and the remotes view only
4250# available if the feature is enabled
4251sub format_ref_views {
4252        my ($current) = @_;
4253        my @ref_views = qw{tags heads};
4254        push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4255        return join " | ", map {
4256                $_ eq $current ? $_ :
4257                $cgi->a({-href => href(action=>$_)}, $_)
4258        } @ref_views
4259}
4260
4261sub format_paging_nav {
4262        my ($action, $page, $has_next_link) = @_;
4263        my $paging_nav;
4264
4265
4266        if ($page > 0) {
4267                $paging_nav .=
4268                        $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4269                        " &sdot; " .
4270                        $cgi->a({-href => href(-replay=>1, page=>$page-1),
4271                                 -accesskey => "p", -title => "Alt-p"}, "prev");
4272        } else {
4273                $paging_nav .= "first &sdot; prev";
4274        }
4275
4276        if ($has_next_link) {
4277                $paging_nav .= " &sdot; " .
4278                        $cgi->a({-href => href(-replay=>1, page=>$page+1),
4279                                 -accesskey => "n", -title => "Alt-n"}, "next");
4280        } else {
4281                $paging_nav .= " &sdot; next";
4282        }
4283
4284        return $paging_nav;
4285}
4286
4287## ......................................................................
4288## functions printing or outputting HTML: div
4289
4290sub git_print_header_div {
4291        my ($action, $title, $hash, $hash_base) = @_;
4292        my %args = ();
4293
4294        $args{'action'} = $action;
4295        $args{'hash'} = $hash if $hash;
4296        $args{'hash_base'} = $hash_base if $hash_base;
4297
4298        print "<div class=\"header\">\n" .
4299              $cgi->a({-href => href(%args), -class => "title"},
4300              $title ? $title : $action) .
4301              "\n</div>\n";
4302}
4303
4304sub format_repo_url {
4305        my ($name, $url) = @_;
4306        return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4307}
4308
4309# Group output by placing it in a DIV element and adding a header.
4310# Options for start_div() can be provided by passing a hash reference as the
4311# first parameter to the function.
4312# Options to git_print_header_div() can be provided by passing an array
4313# reference. This must follow the options to start_div if they are present.
4314# The content can be a scalar, which is output as-is, a scalar reference, which
4315# is output after html escaping, an IO handle passed either as *handle or
4316# *handle{IO}, or a function reference. In the latter case all following
4317# parameters will be taken as argument to the content function call.
4318sub git_print_section {
4319        my ($div_args, $header_args, $content);
4320        my $arg = shift;
4321        if (ref($arg) eq 'HASH') {
4322                $div_args = $arg;
4323                $arg = shift;
4324        }
4325        if (ref($arg) eq 'ARRAY') {
4326                $header_args = $arg;
4327                $arg = shift;
4328        }
4329        $content = $arg;
4330
4331        print $cgi->start_div($div_args);
4332        git_print_header_div(@$header_args);
4333
4334        if (ref($content) eq 'CODE') {
4335                $content->(@_);
4336        } elsif (ref($content) eq 'SCALAR') {
4337                print esc_html($$content);
4338        } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4339                print <$content>;
4340        } elsif (!ref($content) && defined($content)) {
4341                print $content;
4342        }
4343
4344        print $cgi->end_div;
4345}
4346
4347sub format_timestamp_html {
4348        my $date = shift;
4349        my $strtime = $date->{'rfc2822'};
4350
4351        my (undef, undef, $datetime_class) =
4352                gitweb_get_feature('javascript-timezone');
4353        if ($datetime_class) {
4354                $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4355        }
4356
4357        my $localtime_format = '(%02d:%02d %s)';
4358        if ($date->{'hour_local'} < 6) {
4359                $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4360        }
4361        $strtime .= ' ' .
4362                    sprintf($localtime_format,
4363                            $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4364
4365        return $strtime;
4366}
4367
4368# Outputs the author name and date in long form
4369sub git_print_authorship {
4370        my $co = shift;
4371        my %opts = @_;
4372        my $tag = $opts{-tag} || 'div';
4373        my $author = $co->{'author_name'};
4374
4375        my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4376        print "<$tag class=\"author_date\">" .
4377              format_search_author($author, "author", esc_html($author)) .
4378              " [".format_timestamp_html(\%ad)."]".
4379              git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4380              "</$tag>\n";
4381}
4382
4383# Outputs table rows containing the full author or committer information,
4384# in the format expected for 'commit' view (& similar).
4385# Parameters are a commit hash reference, followed by the list of people
4386# to output information for. If the list is empty it defaults to both
4387# author and committer.
4388sub git_print_authorship_rows {
4389        my $co = shift;
4390        # too bad we can't use @people = @_ || ('author', 'committer')
4391        my @people = @_;
4392        @people = ('author', 'committer') unless @people;
4393        foreach my $who (@people) {
4394                my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4395                print "<tr><td>$who</td><td>" .
4396                      format_search_author($co->{"${who}_name"}, $who,
4397                                           esc_html($co->{"${who}_name"})) . " " .
4398                      format_search_author($co->{"${who}_email"}, $who,
4399                                           esc_html("<" . $co->{"${who}_email"} . ">")) .
4400                      "</td><td rowspan=\"2\">" .
4401                      git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4402                      "</td></tr>\n" .
4403                      "<tr>" .
4404                      "<td></td><td>" .
4405                      format_timestamp_html(\%wd) .
4406                      "</td>" .
4407                      "</tr>\n";
4408        }
4409}
4410
4411sub git_print_page_path {
4412        my $name = shift;
4413        my $type = shift;
4414        my $hb = shift;
4415
4416
4417        print "<div class=\"page_path\">";
4418        print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4419                      -title => 'tree root'}, to_utf8("[$project]"));
4420        print " / ";
4421        if (defined $name) {
4422                my @dirname = split '/', $name;
4423                my $basename = pop @dirname;
4424                my $fullname = '';
4425
4426                foreach my $dir (@dirname) {
4427                        $fullname .= ($fullname ? '/' : '') . $dir;
4428                        print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4429                                                     hash_base=>$hb),
4430                                      -title => $fullname}, esc_path($dir));
4431                        print " / ";
4432                }
4433                if (defined $type && $type eq 'blob') {
4434                        print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4435                                                     hash_base=>$hb),
4436                                      -title => $name}, esc_path($basename));
4437                } elsif (defined $type && $type eq 'tree') {
4438                        print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4439                                                     hash_base=>$hb),
4440                                      -title => $name}, esc_path($basename));
4441                        print " / ";
4442                } else {
4443                        print esc_path($basename);
4444                }
4445        }
4446        print "<br/></div>\n";
4447}
4448
4449sub git_print_log {
4450        my $log = shift;
4451        my %opts = @_;
4452
4453        if ($opts{'-remove_title'}) {
4454                # remove title, i.e. first line of log
4455                shift @$log;
4456        }
4457        # remove leading empty lines
4458        while (defined $log->[0] && $log->[0] eq "") {
4459                shift @$log;
4460        }
4461
4462        # print log
4463        my $signoff = 0;
4464        my $empty = 0;
4465        foreach my $line (@$log) {
4466                if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4467                        $signoff = 1;
4468                        $empty = 0;
4469                        if (! $opts{'-remove_signoff'}) {
4470                                print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4471                                next;
4472                        } else {
4473                                # remove signoff lines
4474                                next;
4475                        }
4476                } else {
4477                        $signoff = 0;
4478                }
4479
4480                # print only one empty line
4481                # do not print empty line after signoff
4482                if ($line eq "") {
4483                        next if ($empty || $signoff);
4484                        $empty = 1;
4485                } else {
4486                        $empty = 0;
4487                }
4488
4489                print format_log_line_html($line) . "<br/>\n";
4490        }
4491
4492        if ($opts{'-final_empty_line'}) {
4493                # end with single empty line
4494                print "<br/>\n" unless $empty;
4495        }
4496}
4497
4498# return link target (what link points to)
4499sub git_get_link_target {
4500        my $hash = shift;
4501        my $link_target;
4502
4503        # read link
4504        open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4505                or return;
4506        {
4507                local $/ = undef;
4508                $link_target = <$fd>;
4509        }
4510        close $fd
4511                or return;
4512
4513        return $link_target;
4514}
4515
4516# given link target, and the directory (basedir) the link is in,
4517# return target of link relative to top directory (top tree);
4518# return undef if it is not possible (including absolute links).
4519sub normalize_link_target {
4520        my ($link_target, $basedir) = @_;
4521
4522        # absolute symlinks (beginning with '/') cannot be normalized
4523        return if (substr($link_target, 0, 1) eq '/');
4524
4525        # normalize link target to path from top (root) tree (dir)
4526        my $path;
4527        if ($basedir) {
4528                $path = $basedir . '/' . $link_target;
4529        } else {
4530                # we are in top (root) tree (dir)
4531                $path = $link_target;
4532        }
4533
4534        # remove //, /./, and /../
4535        my @path_parts;
4536        foreach my $part (split('/', $path)) {
4537                # discard '.' and ''
4538                next if (!$part || $part eq '.');
4539                # handle '..'
4540                if ($part eq '..') {
4541                        if (@path_parts) {
4542                                pop @path_parts;
4543                        } else {
4544                                # link leads outside repository (outside top dir)
4545                                return;
4546                        }
4547                } else {
4548                        push @path_parts, $part;
4549                }
4550        }
4551        $path = join('/', @path_parts);
4552
4553        return $path;
4554}
4555
4556# print tree entry (row of git_tree), but without encompassing <tr> element
4557sub git_print_tree_entry {
4558        my ($t, $basedir, $hash_base, $have_blame) = @_;
4559
4560        my %base_key = ();
4561        $base_key{'hash_base'} = $hash_base if defined $hash_base;
4562
4563        # The format of a table row is: mode list link.  Where mode is
4564        # the mode of the entry, list is the name of the entry, an href,
4565        # and link is the action links of the entry.
4566
4567        print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4568        if (exists $t->{'size'}) {
4569                print "<td class=\"size\">$t->{'size'}</td>\n";
4570        }
4571        if ($t->{'type'} eq "blob") {
4572                print "<td class=\"list\">" .
4573                        $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4574                                               file_name=>"$basedir$t->{'name'}", %base_key),
4575                                -class => "list"}, esc_path($t->{'name'}));
4576                if (S_ISLNK(oct $t->{'mode'})) {
4577                        my $link_target = git_get_link_target($t->{'hash'});
4578                        if ($link_target) {
4579                                my $norm_target = normalize_link_target($link_target, $basedir);
4580                                if (defined $norm_target) {
4581                                        print " -> " .
4582                                              $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4583                                                                     file_name=>$norm_target),
4584                                                       -title => $norm_target}, esc_path($link_target));
4585                                } else {
4586                                        print " -> " . esc_path($link_target);
4587                                }
4588                        }
4589                }
4590                print "</td>\n";
4591                print "<td class=\"link\">";
4592                print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4593                                             file_name=>"$basedir$t->{'name'}", %base_key)},
4594                              "blob");
4595                if ($have_blame) {
4596                        print " | " .
4597                              $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4598                                                     file_name=>"$basedir$t->{'name'}", %base_key)},
4599                                      "blame");
4600                }
4601                if (defined $hash_base) {
4602                        print " | " .
4603                              $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4604                                                     hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4605                                      "history");
4606                }
4607                print " | " .
4608                        $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4609                                               file_name=>"$basedir$t->{'name'}")},
4610                                "raw");
4611                print "</td>\n";
4612
4613        } elsif ($t->{'type'} eq "tree") {
4614                print "<td class=\"list\">";
4615                print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4616                                             file_name=>"$basedir$t->{'name'}",
4617                                             %base_key)},
4618                              esc_path($t->{'name'}));
4619                print "</td>\n";
4620                print "<td class=\"link\">";
4621                print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4622                                             file_name=>"$basedir$t->{'name'}",
4623                                             %base_key)},
4624                              "tree");
4625                if (defined $hash_base) {
4626                        print " | " .
4627                              $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4628                                                     file_name=>"$basedir$t->{'name'}")},
4629                                      "history");
4630                }
4631                print "</td>\n";
4632        } else {
4633                # unknown object: we can only present history for it
4634                # (this includes 'commit' object, i.e. submodule support)
4635                print "<td class=\"list\">" .
4636                      esc_path($t->{'name'}) .
4637                      "</td>\n";
4638                print "<td class=\"link\">";
4639                if (defined $hash_base) {
4640                        print $cgi->a({-href => href(action=>"history",
4641                                                     hash_base=>$hash_base,
4642                                                     file_name=>"$basedir$t->{'name'}")},
4643                                      "history");
4644                }
4645                print "</td>\n";
4646        }
4647}
4648
4649## ......................................................................
4650## functions printing large fragments of HTML
4651
4652# get pre-image filenames for merge (combined) diff
4653sub fill_from_file_info {
4654        my ($diff, @parents) = @_;
4655
4656        $diff->{'from_file'} = [ ];
4657        $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4658        for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4659                if ($diff->{'status'}[$i] eq 'R' ||
4660                    $diff->{'status'}[$i] eq 'C') {
4661                        $diff->{'from_file'}[$i] =
4662                                git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4663                }
4664        }
4665
4666        return $diff;
4667}
4668
4669# is current raw difftree line of file deletion
4670sub is_deleted {
4671        my $diffinfo = shift;
4672
4673        return $diffinfo->{'to_id'} eq ('0' x 40);
4674}
4675
4676# does patch correspond to [previous] difftree raw line
4677# $diffinfo  - hashref of parsed raw diff format
4678# $patchinfo - hashref of parsed patch diff format
4679#              (the same keys as in $diffinfo)
4680sub is_patch_split {
4681        my ($diffinfo, $patchinfo) = @_;
4682
4683        return defined $diffinfo && defined $patchinfo
4684                && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4685}
4686
4687
4688sub git_difftree_body {
4689        my ($difftree, $hash, @parents) = @_;
4690        my ($parent) = $parents[0];
4691        my $have_blame = gitweb_check_feature('blame');
4692        print "<div class=\"list_head\">\n";
4693        if ($#{$difftree} > 10) {
4694                print(($#{$difftree} + 1) . " files changed:\n");
4695        }
4696        print "</div>\n";
4697
4698        print "<table class=\"" .
4699              (@parents > 1 ? "combined " : "") .
4700              "diff_tree\">\n";
4701
4702        # header only for combined diff in 'commitdiff' view
4703        my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4704        if ($has_header) {
4705                # table header
4706                print "<thead><tr>\n" .
4707                       "<th></th><th></th>\n"; # filename, patchN link
4708                for (my $i = 0; $i < @parents; $i++) {
4709                        my $par = $parents[$i];
4710                        print "<th>" .
4711                              $cgi->a({-href => href(action=>"commitdiff",
4712                                                     hash=>$hash, hash_parent=>$par),
4713                                       -title => 'commitdiff to parent number ' .
4714                                                  ($i+1) . ': ' . substr($par,0,7)},
4715                                      $i+1) .
4716                              "&nbsp;</th>\n";
4717                }
4718                print "</tr></thead>\n<tbody>\n";
4719        }
4720
4721        my $alternate = 1;
4722        my $patchno = 0;
4723        foreach my $line (@{$difftree}) {
4724                my $diff = parsed_difftree_line($line);
4725
4726                if ($alternate) {
4727                        print "<tr class=\"dark\">\n";
4728                } else {
4729                        print "<tr class=\"light\">\n";
4730                }
4731                $alternate ^= 1;
4732
4733                if (exists $diff->{'nparents'}) { # combined diff
4734
4735                        fill_from_file_info($diff, @parents)
4736                                unless exists $diff->{'from_file'};
4737
4738                        if (!is_deleted($diff)) {
4739                                # file exists in the result (child) commit
4740                                print "<td>" .
4741                                      $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4742                                                             file_name=>$diff->{'to_file'},
4743                                                             hash_base=>$hash),
4744                                              -class => "list"}, esc_path($diff->{'to_file'})) .
4745                                      "</td>\n";
4746                        } else {
4747                                print "<td>" .
4748                                      esc_path($diff->{'to_file'}) .
4749                                      "</td>\n";
4750                        }
4751
4752                        if ($action eq 'commitdiff') {
4753                                # link to patch
4754                                $patchno++;
4755                                print "<td class=\"link\">" .
4756                                      $cgi->a({-href => href(-anchor=>"patch$patchno")},
4757                                              "patch") .
4758                                      " | " .
4759                                      "</td>\n";
4760                        }
4761
4762                        my $has_history = 0;
4763                        my $not_deleted = 0;
4764                        for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4765                                my $hash_parent = $parents[$i];
4766                                my $from_hash = $diff->{'from_id'}[$i];
4767                                my $from_path = $diff->{'from_file'}[$i];
4768                                my $status = $diff->{'status'}[$i];
4769
4770                                $has_history ||= ($status ne 'A');
4771                                $not_deleted ||= ($status ne 'D');
4772
4773                                if ($status eq 'A') {
4774                                        print "<td  class=\"link\" align=\"right\"> | </td>\n";
4775                                } elsif ($status eq 'D') {
4776                                        print "<td class=\"link\">" .
4777                                              $cgi->a({-href => href(action=>"blob",
4778                                                                     hash_base=>$hash,
4779                                                                     hash=>$from_hash,
4780                                                                     file_name=>$from_path)},
4781                                                      "blob" . ($i+1)) .
4782                                              " | </td>\n";
4783                                } else {
4784                                        if ($diff->{'to_id'} eq $from_hash) {
4785                                                print "<td class=\"link nochange\">";
4786                                        } else {
4787                                                print "<td class=\"link\">";
4788                                        }
4789                                        print $cgi->a({-href => href(action=>"blobdiff",
4790                                                                     hash=>$diff->{'to_id'},
4791                                                                     hash_parent=>$from_hash,
4792                                                                     hash_base=>$hash,
4793                                                                     hash_parent_base=>$hash_parent,
4794                                                                     file_name=>$diff->{'to_file'},
4795                                                                     file_parent=>$from_path)},
4796                                                      "diff" . ($i+1)) .
4797                                              " | </td>\n";
4798                                }
4799                        }
4800
4801                        print "<td class=\"link\">";
4802                        if ($not_deleted) {
4803                                print $cgi->a({-href => href(action=>"blob",
4804                                                             hash=>$diff->{'to_id'},
4805                                                             file_name=>$diff->{'to_file'},
4806                                                             hash_base=>$hash)},
4807                                              "blob");
4808                                print " | " if ($has_history);
4809                        }
4810                        if ($has_history) {
4811                                print $cgi->a({-href => href(action=>"history",
4812                                                             file_name=>$diff->{'to_file'},
4813                                                             hash_base=>$hash)},
4814                                              "history");
4815                        }
4816                        print "</td>\n";
4817
4818                        print "</tr>\n";
4819                        next; # instead of 'else' clause, to avoid extra indent
4820                }
4821                # else ordinary diff
4822
4823                my ($to_mode_oct, $to_mode_str, $to_file_type);
4824                my ($from_mode_oct, $from_mode_str, $from_file_type);
4825                if ($diff->{'to_mode'} ne ('0' x 6)) {
4826                        $to_mode_oct = oct $diff->{'to_mode'};
4827                        if (S_ISREG($to_mode_oct)) { # only for regular file
4828                                $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4829                        }
4830                        $to_file_type = file_type($diff->{'to_mode'});
4831                }
4832                if ($diff->{'from_mode'} ne ('0' x 6)) {
4833                        $from_mode_oct = oct $diff->{'from_mode'};
4834                        if (S_ISREG($from_mode_oct)) { # only for regular file
4835                                $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4836                        }
4837                        $from_file_type = file_type($diff->{'from_mode'});
4838                }
4839
4840                if ($diff->{'status'} eq "A") { # created
4841                        my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4842                        $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4843                        $mode_chng   .= "]</span>";
4844                        print "<td>";
4845                        print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4846                                                     hash_base=>$hash, file_name=>$diff->{'file'}),
4847                                      -class => "list"}, esc_path($diff->{'file'}));
4848                        print "</td>\n";
4849                        print "<td>$mode_chng</td>\n";
4850                        print "<td class=\"link\">";
4851                        if ($action eq 'commitdiff') {
4852                                # link to patch
4853                                $patchno++;
4854                                print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4855                                              "patch") .
4856                                      " | ";
4857                        }
4858                        print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4859                                                     hash_base=>$hash, file_name=>$diff->{'file'})},
4860                                      "blob");
4861                        print "</td>\n";
4862
4863                } elsif ($diff->{'status'} eq "D") { # deleted
4864                        my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4865                        print "<td>";
4866                        print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4867                                                     hash_base=>$parent, file_name=>$diff->{'file'}),
4868                                       -class => "list"}, esc_path($diff->{'file'}));
4869                        print "</td>\n";
4870                        print "<td>$mode_chng</td>\n";
4871                        print "<td class=\"link\">";
4872                        if ($action eq 'commitdiff') {
4873                                # link to patch
4874                                $patchno++;
4875                                print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4876                                              "patch") .
4877                                      " | ";
4878                        }
4879                        print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4880                                                     hash_base=>$parent, file_name=>$diff->{'file'})},
4881                                      "blob") . " | ";
4882                        if ($have_blame) {
4883                                print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4884                                                             file_name=>$diff->{'file'})},
4885                                              "blame") . " | ";
4886                        }
4887                        print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4888                                                     file_name=>$diff->{'file'})},
4889                                      "history");
4890                        print "</td>\n";
4891
4892                } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4893                        my $mode_chnge = "";
4894                        if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4895                                $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4896                                if ($from_file_type ne $to_file_type) {
4897                                        $mode_chnge .= " from $from_file_type to $to_file_type";
4898                                }
4899                                if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4900                                        if ($from_mode_str && $to_mode_str) {
4901                                                $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4902                                        } elsif ($to_mode_str) {
4903                                                $mode_chnge .= " mode: $to_mode_str";
4904                                        }
4905                                }
4906                                $mode_chnge .= "]</span>\n";
4907                        }
4908                        print "<td>";
4909                        print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4910                                                     hash_base=>$hash, file_name=>$diff->{'file'}),
4911                                      -class => "list"}, esc_path($diff->{'file'}));
4912                        print "</td>\n";
4913                        print "<td>$mode_chnge</td>\n";
4914                        print "<td class=\"link\">";
4915                        if ($action eq 'commitdiff') {
4916                                # link to patch
4917                                $patchno++;
4918                                print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4919                                              "patch") .
4920                                      " | ";
4921                        } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4922                                # "commit" view and modified file (not onlu mode changed)
4923                                print $cgi->a({-href => href(action=>"blobdiff",
4924                                                             hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4925                                                             hash_base=>$hash, hash_parent_base=>$parent,
4926                                                             file_name=>$diff->{'file'})},
4927                                              "diff") .
4928                                      " | ";
4929                        }
4930                        print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4931                                                     hash_base=>$hash, file_name=>$diff->{'file'})},
4932                                       "blob") . " | ";
4933                        if ($have_blame) {
4934                                print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4935                                                             file_name=>$diff->{'file'})},
4936                                              "blame") . " | ";
4937                        }
4938                        print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4939                                                     file_name=>$diff->{'file'})},
4940                                      "history");
4941                        print "</td>\n";
4942
4943                } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4944                        my %status_name = ('R' => 'moved', 'C' => 'copied');
4945                        my $nstatus = $status_name{$diff->{'status'}};
4946                        my $mode_chng = "";
4947                        if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4948                                # mode also for directories, so we cannot use $to_mode_str
4949                                $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4950                        }
4951                        print "<td>" .
4952                              $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4953                                                     hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4954                                      -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4955                              "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4956                              $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4957                                                     hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4958                                      -class => "list"}, esc_path($diff->{'from_file'})) .
4959                              " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4960                              "<td class=\"link\">";
4961                        if ($action eq 'commitdiff') {
4962                                # link to patch
4963                                $patchno++;
4964                                print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4965                                              "patch") .
4966                                      " | ";
4967                        } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4968                                # "commit" view and modified file (not only pure rename or copy)
4969                                print $cgi->a({-href => href(action=>"blobdiff",
4970                                                             hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4971                                                             hash_base=>$hash, hash_parent_base=>$parent,
4972                                                             file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4973                                              "diff") .
4974                                      " | ";
4975                        }
4976                        print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4977                                                     hash_base=>$parent, file_name=>$diff->{'to_file'})},
4978                                      "blob") . " | ";
4979                        if ($have_blame) {
4980                                print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4981                                                             file_name=>$diff->{'to_file'})},
4982                                              "blame") . " | ";
4983                        }
4984                        print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4985                                                    file_name=>$diff->{'to_file'})},
4986                                      "history");
4987                        print "</td>\n";
4988
4989                } # we should not encounter Unmerged (U) or Unknown (X) status
4990                print "</tr>\n";
4991        }
4992        print "</tbody>" if $has_header;
4993        print "</table>\n";
4994}
4995
4996sub print_sidebyside_diff_chunk {
4997        my @chunk = @_;
4998        my (@ctx, @rem, @add);
4999
5000        return unless @chunk;
5001
5002        # incomplete last line might be among removed or added lines,
5003        # or both, or among context lines: find which
5004        for (my $i = 1; $i < @chunk; $i++) {
5005                if ($chunk[$i][0] eq 'incomplete') {
5006                        $chunk[$i][0] = $chunk[$i-1][0];
5007                }
5008        }
5009
5010        # guardian
5011        push @chunk, ["", ""];
5012
5013        foreach my $line_info (@chunk) {
5014                my ($class, $line) = @$line_info;
5015
5016                # print chunk headers
5017                if ($class && $class eq 'chunk_header') {
5018                        print $line;
5019                        next;
5020                }
5021
5022                ## print from accumulator when type of class of lines change
5023                # empty contents block on start rem/add block, or end of chunk
5024                if (@ctx && (!$class || $class eq 'rem' || $class eq 'add')) {
5025                        print join '',
5026                                '<div class="chunk_block ctx">',
5027                                        '<div class="old">',
5028                                        @ctx,
5029                                        '</div>',
5030                                        '<div class="new">',
5031                                        @ctx,
5032                                        '</div>',
5033                                '</div>';
5034                        @ctx = ();
5035                }
5036                # empty add/rem block on start context block, or end of chunk
5037                if ((@rem || @add) && (!$class || $class eq 'ctx')) {
5038                        if (!@add) {
5039                                # pure removal
5040                                print join '',
5041                                        '<div class="chunk_block rem">',
5042                                                '<div class="old">',
5043                                                @rem,
5044                                                '</div>',
5045                                        '</div>';
5046                        } elsif (!@rem) {
5047                                # pure addition
5048                                print join '',
5049                                        '<div class="chunk_block add">',
5050                                                '<div class="new">',
5051                                                @add,
5052                                                '</div>',
5053                                        '</div>';
5054                        } else {
5055                                # assume that it is change
5056                                print join '',
5057                                        '<div class="chunk_block chg">',
5058                                                '<div class="old">',
5059                                                @rem,
5060                                                '</div>',
5061                                                '<div class="new">',
5062                                                @add,
5063                                                '</div>',
5064                                        '</div>';
5065                        }
5066                        @rem = @add = ();
5067                }
5068
5069                ## adding lines to accumulator
5070                # guardian value
5071                last unless $line;
5072                # rem, add or change
5073                if ($class eq 'rem') {
5074                        push @rem, $line;
5075                } elsif ($class eq 'add') {
5076                        push @add, $line;
5077                }
5078                # context line
5079                if ($class eq 'ctx') {
5080                        push @ctx, $line;
5081                }
5082        }
5083}
5084
5085sub git_patchset_body {
5086        my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5087        my ($hash_parent) = $hash_parents[0];
5088
5089        my $is_combined = (@hash_parents > 1);
5090        my $patch_idx = 0;
5091        my $patch_number = 0;
5092        my $patch_line;
5093        my $diffinfo;
5094        my $to_name;
5095        my (%from, %to);
5096        my @chunk; # for side-by-side diff
5097
5098        print "<div class=\"patchset\">\n";
5099
5100        # skip to first patch
5101        while ($patch_line = <$fd>) {
5102                chomp $patch_line;
5103
5104                last if ($patch_line =~ m/^diff /);
5105        }
5106
5107 PATCH:
5108        while ($patch_line) {
5109
5110                # parse "git diff" header line
5111                if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5112                        # $1 is from_name, which we do not use
5113                        $to_name = unquote($2);
5114                        $to_name =~ s!^b/!!;
5115                } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5116                        # $1 is 'cc' or 'combined', which we do not use
5117                        $to_name = unquote($2);
5118                } else {
5119                        $to_name = undef;
5120                }
5121
5122                # check if current patch belong to current raw line
5123                # and parse raw git-diff line if needed
5124                if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5125                        # this is continuation of a split patch
5126                        print "<div class=\"patch cont\">\n";
5127                } else {
5128                        # advance raw git-diff output if needed
5129                        $patch_idx++ if defined $diffinfo;
5130
5131                        # read and prepare patch information
5132                        $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5133
5134                        # compact combined diff output can have some patches skipped
5135                        # find which patch (using pathname of result) we are at now;
5136                        if ($is_combined) {
5137                                while ($to_name ne $diffinfo->{'to_file'}) {
5138                                        print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5139                                              format_diff_cc_simplified($diffinfo, @hash_parents) .
5140                                              "</div>\n";  # class="patch"
5141
5142                                        $patch_idx++;
5143                                        $patch_number++;
5144
5145                                        last if $patch_idx > $#$difftree;
5146                                        $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5147                                }
5148                        }
5149
5150                        # modifies %from, %to hashes
5151                        parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5152
5153                        # this is first patch for raw difftree line with $patch_idx index
5154                        # we index @$difftree array from 0, but number patches from 1
5155                        print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5156                }
5157
5158                # git diff header
5159                #assert($patch_line =~ m/^diff /) if DEBUG;
5160                #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5161                $patch_number++;
5162                # print "git diff" header
5163                print format_git_diff_header_line($patch_line, $diffinfo,
5164                                                  \%from, \%to);
5165
5166                # print extended diff header
5167                print "<div class=\"diff extended_header\">\n";
5168        EXTENDED_HEADER:
5169                while ($patch_line = <$fd>) {
5170                        chomp $patch_line;
5171
5172                        last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5173
5174                        print format_extended_diff_header_line($patch_line, $diffinfo,
5175                                                               \%from, \%to);
5176                }
5177                print "</div>\n"; # class="diff extended_header"
5178
5179                # from-file/to-file diff header
5180                if (! $patch_line) {
5181                        print "</div>\n"; # class="patch"
5182                        last PATCH;
5183                }
5184                next PATCH if ($patch_line =~ m/^diff /);
5185                #assert($patch_line =~ m/^---/) if DEBUG;
5186
5187                my $last_patch_line = $patch_line;
5188                $patch_line = <$fd>;
5189                chomp $patch_line;
5190                #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5191
5192                print format_diff_from_to_header($last_patch_line, $patch_line,
5193                                                 $diffinfo, \%from, \%to,
5194                                                 @hash_parents);
5195
5196                # the patch itself
5197        LINE:
5198                while ($patch_line = <$fd>) {
5199                        chomp $patch_line;
5200
5201                        next PATCH if ($patch_line =~ m/^diff /);
5202
5203                        my ($class, $line) = process_diff_line($patch_line, \%from, \%to);
5204                        my $diff_classes = "diff";
5205                        $diff_classes .= " $class" if ($class);
5206                        $line = "<div class=\"$diff_classes\">$line</div>\n";
5207
5208                        if ($diff_style eq 'sidebyside' && !$is_combined) {
5209                                if ($class eq 'chunk_header') {
5210                                        print_sidebyside_diff_chunk(@chunk);
5211                                        @chunk = ( [ $class, $line ] );
5212                                } else {
5213                                        push @chunk, [ $class, $line ];
5214                                }
5215                        } else {
5216                                # default 'inline' style and unknown styles
5217                                print $line;
5218                        }
5219                }
5220
5221        } continue {
5222                if (@chunk) {
5223                        print_sidebyside_diff_chunk(@chunk);
5224                        @chunk = ();
5225                }
5226                print "</div>\n"; # class="patch"
5227        }
5228
5229        # for compact combined (--cc) format, with chunk and patch simplification
5230        # the patchset might be empty, but there might be unprocessed raw lines
5231        for (++$patch_idx if $patch_number > 0;
5232             $patch_idx < @$difftree;
5233             ++$patch_idx) {
5234                # read and prepare patch information
5235                $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5236
5237                # generate anchor for "patch" links in difftree / whatchanged part
5238                print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5239                      format_diff_cc_simplified($diffinfo, @hash_parents) .
5240                      "</div>\n";  # class="patch"
5241
5242                $patch_number++;
5243        }
5244
5245        if ($patch_number == 0) {
5246                if (@hash_parents > 1) {
5247                        print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5248                } else {
5249                        print "<div class=\"diff nodifferences\">No differences found</div>\n";
5250                }
5251        }
5252
5253        print "</div>\n"; # class="patchset"
5254}
5255
5256# . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5257
5258sub git_project_search_form {
5259        my ($searchtext, $search_use_regexp) = @_;
5260
5261        my $limit = '';
5262        if ($project_filter) {
5263                $limit = " in '$project_filter/'";
5264        }
5265
5266        print "<div class=\"projsearch\">\n";
5267        print $cgi->startform(-method => 'get', -action => $my_uri) .
5268              $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5269        print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5270                if (defined $project_filter);
5271        print $cgi->textfield(-name => 's', -value => $searchtext,
5272                              -title => "Search project by name and description$limit",
5273                              -size => 60) . "\n" .
5274              "<span title=\"Extended regular expression\">" .
5275              $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5276                             -checked => $search_use_regexp) .
5277              "</span>\n" .
5278              $cgi->submit(-name => 'btnS', -value => 'Search') .
5279              $cgi->end_form() . "\n" .
5280              $cgi->a({-href => href(project => undef, searchtext => undef,
5281                                     project_filter => $project_filter)},
5282                      esc_html("List all projects$limit")) . "<br />\n";
5283        print "</div>\n";
5284}
5285
5286# entry for given @keys needs filling if at least one of keys in list
5287# is not present in %$project_info
5288sub project_info_needs_filling {
5289        my ($project_info, @keys) = @_;
5290
5291        # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5292        foreach my $key (@keys) {
5293                if (!exists $project_info->{$key}) {
5294                        return 1;
5295                }
5296        }
5297        return;
5298}
5299
5300# fills project list info (age, description, owner, category, forks, etc.)
5301# for each project in the list, removing invalid projects from
5302# returned list, or fill only specified info.
5303#
5304# Invalid projects are removed from the returned list if and only if you
5305# ask 'age' or 'age_string' to be filled, because they are the only fields
5306# that run unconditionally git command that requires repository, and
5307# therefore do always check if project repository is invalid.
5308#
5309# USAGE:
5310# * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5311#   ensures that 'descr_long' and 'ctags' fields are filled
5312# * @project_list = fill_project_list_info(\@project_list)
5313#   ensures that all fields are filled (and invalid projects removed)
5314#
5315# NOTE: modifies $projlist, but does not remove entries from it
5316sub fill_project_list_info {
5317        my ($projlist, @wanted_keys) = @_;
5318        my @projects;
5319        my $filter_set = sub { return @_; };
5320        if (@wanted_keys) {
5321                my %wanted_keys = map { $_ => 1 } @wanted_keys;
5322                $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5323        }
5324
5325        my $show_ctags = gitweb_check_feature('ctags');
5326 PROJECT:
5327        foreach my $pr (@$projlist) {
5328                if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5329                        my (@activity) = git_get_last_activity($pr->{'path'});
5330                        unless (@activity) {
5331                                next PROJECT;
5332                        }
5333                        ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5334                }
5335                if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5336                        my $descr = git_get_project_description($pr->{'path'}) || "";
5337                        $descr = to_utf8($descr);
5338                        $pr->{'descr_long'} = $descr;
5339                        $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5340                }
5341                if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5342                        $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5343                }
5344                if ($show_ctags &&
5345                    project_info_needs_filling($pr, $filter_set->('ctags'))) {
5346                        $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5347                }
5348                if ($projects_list_group_categories &&
5349                    project_info_needs_filling($pr, $filter_set->('category'))) {
5350                        my $cat = git_get_project_category($pr->{'path'}) ||
5351                                                           $project_list_default_category;
5352                        $pr->{'category'} = to_utf8($cat);
5353                }
5354
5355                push @projects, $pr;
5356        }
5357
5358        return @projects;
5359}
5360
5361sub sort_projects_list {
5362        my ($projlist, $order) = @_;
5363        my @projects;
5364
5365        my %order_info = (
5366                project => { key => 'path', type => 'str' },
5367                descr => { key => 'descr_long', type => 'str' },
5368                owner => { key => 'owner', type => 'str' },
5369                age => { key => 'age', type => 'num' }
5370        );
5371        my $oi = $order_info{$order};
5372        return @$projlist unless defined $oi;
5373        if ($oi->{'type'} eq 'str') {
5374                @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5375        } else {
5376                @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5377        }
5378
5379        return @projects;
5380}
5381
5382# returns a hash of categories, containing the list of project
5383# belonging to each category
5384sub build_projlist_by_category {
5385        my ($projlist, $from, $to) = @_;
5386        my %categories;
5387
5388        $from = 0 unless defined $from;
5389        $to = $#$projlist if (!defined $to || $#$projlist < $to);
5390
5391        for (my $i = $from; $i <= $to; $i++) {
5392                my $pr = $projlist->[$i];
5393                push @{$categories{ $pr->{'category'} }}, $pr;
5394        }
5395
5396        return wantarray ? %categories : \%categories;
5397}
5398
5399# print 'sort by' <th> element, generating 'sort by $name' replay link
5400# if that order is not selected
5401sub print_sort_th {
5402        print format_sort_th(@_);
5403}
5404
5405sub format_sort_th {
5406        my ($name, $order, $header) = @_;
5407        my $sort_th = "";
5408        $header ||= ucfirst($name);
5409
5410        if ($order eq $name) {
5411                $sort_th .= "<th>$header</th>\n";
5412        } else {
5413                $sort_th .= "<th>" .
5414                            $cgi->a({-href => href(-replay=>1, order=>$name),
5415                                     -class => "header"}, $header) .
5416                            "</th>\n";
5417        }
5418
5419        return $sort_th;
5420}
5421
5422sub git_project_list_rows {
5423        my ($projlist, $from, $to, $check_forks) = @_;
5424
5425        $from = 0 unless defined $from;
5426        $to = $#$projlist if (!defined $to || $#$projlist < $to);
5427
5428        my $alternate = 1;
5429        for (my $i = $from; $i <= $to; $i++) {
5430                my $pr = $projlist->[$i];
5431
5432                if ($alternate) {
5433                        print "<tr class=\"dark\">\n";
5434                } else {
5435                        print "<tr class=\"light\">\n";
5436                }
5437                $alternate ^= 1;
5438
5439                if ($check_forks) {
5440                        print "<td>";
5441                        if ($pr->{'forks'}) {
5442                                my $nforks = scalar @{$pr->{'forks'}};
5443                                if ($nforks > 0) {
5444                                        print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5445                                                       -title => "$nforks forks"}, "+");
5446                                } else {
5447                                        print $cgi->span({-title => "$nforks forks"}, "+");
5448                                }
5449                        }
5450                        print "</td>\n";
5451                }
5452                print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5453                                        -class => "list"},
5454                                       esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5455                      "</td>\n" .
5456                      "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5457                                        -class => "list",
5458                                        -title => $pr->{'descr_long'}},
5459                                        $search_regexp
5460                                        ? esc_html_match_hl_chopped($pr->{'descr_long'},
5461                                                                    $pr->{'descr'}, $search_regexp)
5462                                        : esc_html($pr->{'descr'})) .
5463                      "</td>\n" .
5464                      "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5465                print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5466                      (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5467                      "<td class=\"link\">" .
5468                      $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5469                      $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5470                      $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5471                      $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5472                      ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5473                      "</td>\n" .
5474                      "</tr>\n";
5475        }
5476}
5477
5478sub git_project_list_body {
5479        # actually uses global variable $project
5480        my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5481        my @projects = @$projlist;
5482
5483        my $check_forks = gitweb_check_feature('forks');
5484        my $show_ctags  = gitweb_check_feature('ctags');
5485        my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5486        $check_forks = undef
5487                if ($tagfilter || $searchtext);
5488
5489        # filtering out forks before filling info allows to do less work
5490        @projects = filter_forks_from_projects_list(\@projects)
5491                if ($check_forks);
5492        # search_projects_list pre-fills required info
5493        @projects = search_projects_list(\@projects,
5494                                         'searchtext' => $searchtext,
5495                                         'tagfilter'  => $tagfilter)
5496                if ($tagfilter || $searchtext);
5497        # fill the rest
5498        @projects = fill_project_list_info(\@projects);
5499
5500        $order ||= $default_projects_order;
5501        $from = 0 unless defined $from;
5502        $to = $#projects if (!defined $to || $#projects < $to);
5503
5504        # short circuit
5505        if ($from > $to) {
5506                print "<center>\n".
5507                      "<b>No such projects found</b><br />\n".
5508                      "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5509                      "</center>\n<br />\n";
5510                return;
5511        }
5512
5513        @projects = sort_projects_list(\@projects, $order);
5514
5515        if ($show_ctags) {
5516                my $ctags = git_gather_all_ctags(\@projects);
5517                my $cloud = git_populate_project_tagcloud($ctags);
5518                print git_show_project_tagcloud($cloud, 64);
5519        }
5520
5521        print "<table class=\"project_list\">\n";
5522        unless ($no_header) {
5523                print "<tr>\n";
5524                if ($check_forks) {
5525                        print "<th></th>\n";
5526                }
5527                print_sort_th('project', $order, 'Project');
5528                print_sort_th('descr', $order, 'Description');
5529                print_sort_th('owner', $order, 'Owner');
5530                print_sort_th('age', $order, 'Last Change');
5531                print "<th></th>\n" . # for links
5532                      "</tr>\n";
5533        }
5534
5535        if ($projects_list_group_categories) {
5536                # only display categories with projects in the $from-$to window
5537                @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5538                my %categories = build_projlist_by_category(\@projects, $from, $to);
5539                foreach my $cat (sort keys %categories) {
5540                        unless ($cat eq "") {
5541                                print "<tr>\n";
5542                                if ($check_forks) {
5543                                        print "<td></td>\n";
5544                                }
5545                                print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5546                                print "</tr>\n";
5547                        }
5548
5549                        git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5550                }
5551        } else {
5552                git_project_list_rows(\@projects, $from, $to, $check_forks);
5553        }
5554
5555        if (defined $extra) {
5556                print "<tr>\n";
5557                if ($check_forks) {
5558                        print "<td></td>\n";
5559                }
5560                print "<td colspan=\"5\">$extra</td>\n" .
5561                      "</tr>\n";
5562        }
5563        print "</table>\n";
5564}
5565
5566sub git_log_body {
5567        # uses global variable $project
5568        my ($commitlist, $from, $to, $refs, $extra) = @_;
5569
5570        $from = 0 unless defined $from;
5571        $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5572
5573        for (my $i = 0; $i <= $to; $i++) {
5574                my %co = %{$commitlist->[$i]};
5575                next if !%co;
5576                my $commit = $co{'id'};
5577                my $ref = format_ref_marker($refs, $commit);
5578                git_print_header_div('commit',
5579                               "<span class=\"age\">$co{'age_string'}</span>" .
5580                               esc_html($co{'title'}) . $ref,
5581                               $commit);
5582                print "<div class=\"title_text\">\n" .
5583                      "<div class=\"log_link\">\n" .
5584                      $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5585                      " | " .
5586                      $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5587                      " | " .
5588                      $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5589                      "<br/>\n" .
5590                      "</div>\n";
5591                      git_print_authorship(\%co, -tag => 'span');
5592                      print "<br/>\n</div>\n";
5593
5594                print "<div class=\"log_body\">\n";
5595                git_print_log($co{'comment'}, -final_empty_line=> 1);
5596                print "</div>\n";
5597        }
5598        if ($extra) {
5599                print "<div class=\"page_nav\">\n";
5600                print "$extra\n";
5601                print "</div>\n";
5602        }
5603}
5604
5605sub git_shortlog_body {
5606        # uses global variable $project
5607        my ($commitlist, $from, $to, $refs, $extra) = @_;
5608
5609        $from = 0 unless defined $from;
5610        $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5611
5612        print "<table class=\"shortlog\">\n";
5613        my $alternate = 1;
5614        for (my $i = $from; $i <= $to; $i++) {
5615                my %co = %{$commitlist->[$i]};
5616                my $commit = $co{'id'};
5617                my $ref = format_ref_marker($refs, $commit);
5618                if ($alternate) {
5619                        print "<tr class=\"dark\">\n";
5620                } else {
5621                        print "<tr class=\"light\">\n";
5622                }
5623                $alternate ^= 1;
5624                # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5625                print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5626                      format_author_html('td', \%co, 10) . "<td>";
5627                print format_subject_html($co{'title'}, $co{'title_short'},
5628                                          href(action=>"commit", hash=>$commit), $ref);
5629                print "</td>\n" .
5630                      "<td class=\"link\">" .
5631                      $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5632                      $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5633                      $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5634                my $snapshot_links = format_snapshot_links($commit);
5635                if (defined $snapshot_links) {
5636                        print " | " . $snapshot_links;
5637                }
5638                print "</td>\n" .
5639                      "</tr>\n";
5640        }
5641        if (defined $extra) {
5642                print "<tr>\n" .
5643                      "<td colspan=\"4\">$extra</td>\n" .
5644                      "</tr>\n";
5645        }
5646        print "</table>\n";
5647}
5648
5649sub git_history_body {
5650        # Warning: assumes constant type (blob or tree) during history
5651        my ($commitlist, $from, $to, $refs, $extra,
5652            $file_name, $file_hash, $ftype) = @_;
5653
5654        $from = 0 unless defined $from;
5655        $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5656
5657        print "<table class=\"history\">\n";
5658        my $alternate = 1;
5659        for (my $i = $from; $i <= $to; $i++) {
5660                my %co = %{$commitlist->[$i]};
5661                if (!%co) {
5662                        next;
5663                }
5664                my $commit = $co{'id'};
5665
5666                my $ref = format_ref_marker($refs, $commit);
5667
5668                if ($alternate) {
5669                        print "<tr class=\"dark\">\n";
5670                } else {
5671                        print "<tr class=\"light\">\n";
5672                }
5673                $alternate ^= 1;
5674                print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5675        # shortlog:   format_author_html('td', \%co, 10)
5676                      format_author_html('td', \%co, 15, 3) . "<td>";
5677                # originally git_history used chop_str($co{'title'}, 50)
5678                print format_subject_html($co{'title'}, $co{'title_short'},
5679                                          href(action=>"commit", hash=>$commit), $ref);
5680                print "</td>\n" .
5681                      "<td class=\"link\">" .
5682                      $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5683                      $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5684
5685                if ($ftype eq 'blob') {
5686                        my $blob_current = $file_hash;
5687                        my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5688                        if (defined $blob_current && defined $blob_parent &&
5689                                        $blob_current ne $blob_parent) {
5690                                print " | " .
5691                                        $cgi->a({-href => href(action=>"blobdiff",
5692                                                               hash=>$blob_current, hash_parent=>$blob_parent,
5693                                                               hash_base=>$hash_base, hash_parent_base=>$commit,
5694                                                               file_name=>$file_name)},
5695                                                "diff to current");
5696                        }
5697                }
5698                print "</td>\n" .
5699                      "</tr>\n";
5700        }
5701        if (defined $extra) {
5702                print "<tr>\n" .
5703                      "<td colspan=\"4\">$extra</td>\n" .
5704                      "</tr>\n";
5705        }
5706        print "</table>\n";
5707}
5708
5709sub git_tags_body {
5710        # uses global variable $project
5711        my ($taglist, $from, $to, $extra) = @_;
5712        $from = 0 unless defined $from;
5713        $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5714
5715        print "<table class=\"tags\">\n";
5716        my $alternate = 1;
5717        for (my $i = $from; $i <= $to; $i++) {
5718                my $entry = $taglist->[$i];
5719                my %tag = %$entry;
5720                my $comment = $tag{'subject'};
5721                my $comment_short;
5722                if (defined $comment) {
5723                        $comment_short = chop_str($comment, 30, 5);
5724                }
5725                if ($alternate) {
5726                        print "<tr class=\"dark\">\n";
5727                } else {
5728                        print "<tr class=\"light\">\n";
5729                }
5730                $alternate ^= 1;
5731                if (defined $tag{'age'}) {
5732                        print "<td><i>$tag{'age'}</i></td>\n";
5733                } else {
5734                        print "<td></td>\n";
5735                }
5736                print "<td>" .
5737                      $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5738                               -class => "list name"}, esc_html($tag{'name'})) .
5739                      "</td>\n" .
5740                      "<td>";
5741                if (defined $comment) {
5742                        print format_subject_html($comment, $comment_short,
5743                                                  href(action=>"tag", hash=>$tag{'id'}));
5744                }
5745                print "</td>\n" .
5746                      "<td class=\"selflink\">";
5747                if ($tag{'type'} eq "tag") {
5748                        print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5749                } else {
5750                        print "&nbsp;";
5751                }
5752                print "</td>\n" .
5753                      "<td class=\"link\">" . " | " .
5754                      $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5755                if ($tag{'reftype'} eq "commit") {
5756                        print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5757                              " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5758                } elsif ($tag{'reftype'} eq "blob") {
5759                        print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5760                }
5761                print "</td>\n" .
5762                      "</tr>";
5763        }
5764        if (defined $extra) {
5765                print "<tr>\n" .
5766                      "<td colspan=\"5\">$extra</td>\n" .
5767                      "</tr>\n";
5768        }
5769        print "</table>\n";
5770}
5771
5772sub git_heads_body {
5773        # uses global variable $project
5774        my ($headlist, $head_at, $from, $to, $extra) = @_;
5775        $from = 0 unless defined $from;
5776        $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5777
5778        print "<table class=\"heads\">\n";
5779        my $alternate = 1;
5780        for (my $i = $from; $i <= $to; $i++) {
5781                my $entry = $headlist->[$i];
5782                my %ref = %$entry;
5783                my $curr = defined $head_at && $ref{'id'} eq $head_at;
5784                if ($alternate) {
5785                        print "<tr class=\"dark\">\n";
5786                } else {
5787                        print "<tr class=\"light\">\n";
5788                }
5789                $alternate ^= 1;
5790                print "<td><i>$ref{'age'}</i></td>\n" .
5791                      ($curr ? "<td class=\"current_head\">" : "<td>") .
5792                      $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5793                               -class => "list name"},esc_html($ref{'name'})) .
5794                      "</td>\n" .
5795                      "<td class=\"link\">" .
5796                      $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5797                      $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5798                      $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5799                      "</td>\n" .
5800                      "</tr>";
5801        }
5802        if (defined $extra) {
5803                print "<tr>\n" .
5804                      "<td colspan=\"3\">$extra</td>\n" .
5805                      "</tr>\n";
5806        }
5807        print "</table>\n";
5808}
5809
5810# Display a single remote block
5811sub git_remote_block {
5812        my ($remote, $rdata, $limit, $head) = @_;
5813
5814        my $heads = $rdata->{'heads'};
5815        my $fetch = $rdata->{'fetch'};
5816        my $push = $rdata->{'push'};
5817
5818        my $urls_table = "<table class=\"projects_list\">\n" ;
5819
5820        if (defined $fetch) {
5821                if ($fetch eq $push) {
5822                        $urls_table .= format_repo_url("URL", $fetch);
5823                } else {
5824                        $urls_table .= format_repo_url("Fetch URL", $fetch);
5825                        $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5826                }
5827        } elsif (defined $push) {
5828                $urls_table .= format_repo_url("Push URL", $push);
5829        } else {
5830                $urls_table .= format_repo_url("", "No remote URL");
5831        }
5832
5833        $urls_table .= "</table>\n";
5834
5835        my $dots;
5836        if (defined $limit && $limit < @$heads) {
5837                $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5838        }
5839
5840        print $urls_table;
5841        git_heads_body($heads, $head, 0, $limit, $dots);
5842}
5843
5844# Display a list of remote names with the respective fetch and push URLs
5845sub git_remotes_list {
5846        my ($remotedata, $limit) = @_;
5847        print "<table class=\"heads\">\n";
5848        my $alternate = 1;
5849        my @remotes = sort keys %$remotedata;
5850
5851        my $limited = $limit && $limit < @remotes;
5852
5853        $#remotes = $limit - 1 if $limited;
5854
5855        while (my $remote = shift @remotes) {
5856                my $rdata = $remotedata->{$remote};
5857                my $fetch = $rdata->{'fetch'};
5858                my $push = $rdata->{'push'};
5859                if ($alternate) {
5860                        print "<tr class=\"dark\">\n";
5861                } else {
5862                        print "<tr class=\"light\">\n";
5863                }
5864                $alternate ^= 1;
5865                print "<td>" .
5866                      $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5867                               -class=> "list name"},esc_html($remote)) .
5868                      "</td>";
5869                print "<td class=\"link\">" .
5870                      (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5871                      " | " .
5872                      (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5873                      "</td>";
5874
5875                print "</tr>\n";
5876        }
5877
5878        if ($limited) {
5879                print "<tr>\n" .
5880                      "<td colspan=\"3\">" .
5881                      $cgi->a({-href => href(action=>"remotes")}, "...") .
5882                      "</td>\n" . "</tr>\n";
5883        }
5884
5885        print "</table>";
5886}
5887
5888# Display remote heads grouped by remote, unless there are too many
5889# remotes, in which case we only display the remote names
5890sub git_remotes_body {
5891        my ($remotedata, $limit, $head) = @_;
5892        if ($limit and $limit < keys %$remotedata) {
5893                git_remotes_list($remotedata, $limit);
5894        } else {
5895                fill_remote_heads($remotedata);
5896                while (my ($remote, $rdata) = each %$remotedata) {
5897                        git_print_section({-class=>"remote", -id=>$remote},
5898                                ["remotes", $remote, $remote], sub {
5899                                        git_remote_block($remote, $rdata, $limit, $head);
5900                                });
5901                }
5902        }
5903}
5904
5905sub git_search_message {
5906        my %co = @_;
5907
5908        my $greptype;
5909        if ($searchtype eq 'commit') {
5910                $greptype = "--grep=";
5911        } elsif ($searchtype eq 'author') {
5912                $greptype = "--author=";
5913        } elsif ($searchtype eq 'committer') {
5914                $greptype = "--committer=";
5915        }
5916        $greptype .= $searchtext;
5917        my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5918                                       $greptype, '--regexp-ignore-case',
5919                                       $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5920
5921        my $paging_nav = '';
5922        if ($page > 0) {
5923                $paging_nav .=
5924                        $cgi->a({-href => href(-replay=>1, page=>undef)},
5925                                "first") .
5926                        " &sdot; " .
5927                        $cgi->a({-href => href(-replay=>1, page=>$page-1),
5928                                 -accesskey => "p", -title => "Alt-p"}, "prev");
5929        } else {
5930                $paging_nav .= "first &sdot; prev";
5931        }
5932        my $next_link = '';
5933        if ($#commitlist >= 100) {
5934                $next_link =
5935                        $cgi->a({-href => href(-replay=>1, page=>$page+1),
5936                                 -accesskey => "n", -title => "Alt-n"}, "next");
5937                $paging_nav .= " &sdot; $next_link";
5938        } else {
5939                $paging_nav .= " &sdot; next";
5940        }
5941
5942        git_header_html();
5943
5944        git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5945        git_print_header_div('commit', esc_html($co{'title'}), $hash);
5946        if ($page == 0 && !@commitlist) {
5947                print "<p>No match.</p>\n";
5948        } else {
5949                git_search_grep_body(\@commitlist, 0, 99, $next_link);
5950        }
5951
5952        git_footer_html();
5953}
5954
5955sub git_search_changes {
5956        my %co = @_;
5957
5958        local $/ = "\n";
5959        open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5960                '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5961                ($search_use_regexp ? '--pickaxe-regex' : ())
5962                        or die_error(500, "Open git-log failed");
5963
5964        git_header_html();
5965
5966        git_print_page_nav('','', $hash,$co{'tree'},$hash);
5967        git_print_header_div('commit', esc_html($co{'title'}), $hash);
5968
5969        print "<table class=\"pickaxe search\">\n";
5970        my $alternate = 1;
5971        undef %co;
5972        my @files;
5973        while (my $line = <$fd>) {
5974                chomp $line;
5975                next unless $line;
5976
5977                my %set = parse_difftree_raw_line($line);
5978                if (defined $set{'commit'}) {
5979                        # finish previous commit
5980                        if (%co) {
5981                                print "</td>\n" .
5982                                      "<td class=\"link\">" .
5983                                      $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5984                                              "commit") .
5985                                      " | " .
5986                                      $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5987                                                             hash_base=>$co{'id'})},
5988                                              "tree") .
5989                                      "</td>\n" .
5990                                      "</tr>\n";
5991                        }
5992
5993                        if ($alternate) {
5994                                print "<tr class=\"dark\">\n";
5995                        } else {
5996                                print "<tr class=\"light\">\n";
5997                        }
5998                        $alternate ^= 1;
5999                        %co = parse_commit($set{'commit'});
6000                        my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6001                        print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6002                              "<td><i>$author</i></td>\n" .
6003                              "<td>" .
6004                              $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6005                                      -class => "list subject"},
6006                                      chop_and_escape_str($co{'title'}, 50) . "<br/>");
6007                } elsif (defined $set{'to_id'}) {
6008                        next if ($set{'to_id'} =~ m/^0{40}$/);
6009
6010                        print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6011                                                     hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6012                                      -class => "list"},
6013                                      "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6014                              "<br/>\n";
6015                }
6016        }
6017        close $fd;
6018
6019        # finish last commit (warning: repetition!)
6020        if (%co) {
6021                print "</td>\n" .
6022                      "<td class=\"link\">" .
6023                      $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6024                              "commit") .
6025                      " | " .
6026                      $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6027                                             hash_base=>$co{'id'})},
6028                              "tree") .
6029                      "</td>\n" .
6030                      "</tr>\n";
6031        }
6032
6033        print "</table>\n";
6034
6035        git_footer_html();
6036}
6037
6038sub git_search_files {
6039        my %co = @_;
6040
6041        local $/ = "\n";
6042        open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6043                $search_use_regexp ? ('-E', '-i') : '-F',
6044                $searchtext, $co{'tree'}
6045                        or die_error(500, "Open git-grep failed");
6046
6047        git_header_html();
6048
6049        git_print_page_nav('','', $hash,$co{'tree'},$hash);
6050        git_print_header_div('commit', esc_html($co{'title'}), $hash);
6051
6052        print "<table class=\"grep_search\">\n";
6053        my $alternate = 1;
6054        my $matches = 0;
6055        my $lastfile = '';
6056        my $file_href;
6057        while (my $line = <$fd>) {
6058                chomp $line;
6059                my ($file, $lno, $ltext, $binary);
6060                last if ($matches++ > 1000);
6061                if ($line =~ /^Binary file (.+) matches$/) {
6062                        $file = $1;
6063                        $binary = 1;
6064                } else {
6065                        ($file, $lno, $ltext) = split(/\0/, $line, 3);
6066                        $file =~ s/^$co{'tree'}://;
6067                }
6068                if ($file ne $lastfile) {
6069                        $lastfile and print "</td></tr>\n";
6070                        if ($alternate++) {
6071                                print "<tr class=\"dark\">\n";
6072                        } else {
6073                                print "<tr class=\"light\">\n";
6074                        }
6075                        $file_href = href(action=>"blob", hash_base=>$co{'id'},
6076                                          file_name=>$file);
6077                        print "<td class=\"list\">".
6078                                $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6079                        print "</td><td>\n";
6080                        $lastfile = $file;
6081                }
6082                if ($binary) {
6083                        print "<div class=\"binary\">Binary file</div>\n";
6084                } else {
6085                        $ltext = untabify($ltext);
6086                        if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6087                                $ltext = esc_html($1, -nbsp=>1);
6088                                $ltext .= '<span class="match">';
6089                                $ltext .= esc_html($2, -nbsp=>1);
6090                                $ltext .= '</span>';
6091                                $ltext .= esc_html($3, -nbsp=>1);
6092                        } else {
6093                                $ltext = esc_html($ltext, -nbsp=>1);
6094                        }
6095                        print "<div class=\"pre\">" .
6096                                $cgi->a({-href => $file_href.'#l'.$lno,
6097                                        -class => "linenr"}, sprintf('%4i', $lno)) .
6098                                ' ' .  $ltext . "</div>\n";
6099                }
6100        }
6101        if ($lastfile) {
6102                print "</td></tr>\n";
6103                if ($matches > 1000) {
6104                        print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6105                }
6106        } else {
6107                print "<div class=\"diff nodifferences\">No matches found</div>\n";
6108        }
6109        close $fd;
6110
6111        print "</table>\n";
6112
6113        git_footer_html();
6114}
6115
6116sub git_search_grep_body {
6117        my ($commitlist, $from, $to, $extra) = @_;
6118        $from = 0 unless defined $from;
6119        $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6120
6121        print "<table class=\"commit_search\">\n";
6122        my $alternate = 1;
6123        for (my $i = $from; $i <= $to; $i++) {
6124                my %co = %{$commitlist->[$i]};
6125                if (!%co) {
6126                        next;
6127                }
6128                my $commit = $co{'id'};
6129                if ($alternate) {
6130                        print "<tr class=\"dark\">\n";
6131                } else {
6132                        print "<tr class=\"light\">\n";
6133                }
6134                $alternate ^= 1;
6135                print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6136                      format_author_html('td', \%co, 15, 5) .
6137                      "<td>" .
6138                      $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6139                               -class => "list subject"},
6140                              chop_and_escape_str($co{'title'}, 50) . "<br/>");
6141                my $comment = $co{'comment'};
6142                foreach my $line (@$comment) {
6143                        if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6144                                my ($lead, $match, $trail) = ($1, $2, $3);
6145                                $match = chop_str($match, 70, 5, 'center');
6146                                my $contextlen = int((80 - length($match))/2);
6147                                $contextlen = 30 if ($contextlen > 30);
6148                                $lead  = chop_str($lead,  $contextlen, 10, 'left');
6149                                $trail = chop_str($trail, $contextlen, 10, 'right');
6150
6151                                $lead  = esc_html($lead);
6152                                $match = esc_html($match);
6153                                $trail = esc_html($trail);
6154
6155                                print "$lead<span class=\"match\">$match</span>$trail<br />";
6156                        }
6157                }
6158                print "</td>\n" .
6159                      "<td class=\"link\">" .
6160                      $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6161                      " | " .
6162                      $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6163                      " | " .
6164                      $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6165                print "</td>\n" .
6166                      "</tr>\n";
6167        }
6168        if (defined $extra) {
6169                print "<tr>\n" .
6170                      "<td colspan=\"3\">$extra</td>\n" .
6171                      "</tr>\n";
6172        }
6173        print "</table>\n";
6174}
6175
6176## ======================================================================
6177## ======================================================================
6178## actions
6179
6180sub git_project_list {
6181        my $order = $input_params{'order'};
6182        if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6183                die_error(400, "Unknown order parameter");
6184        }
6185
6186        my @list = git_get_projects_list($project_filter, $strict_export);
6187        if (!@list) {
6188                die_error(404, "No projects found");
6189        }
6190
6191        git_header_html();
6192        if (defined $home_text && -f $home_text) {
6193                print "<div class=\"index_include\">\n";
6194                insert_file($home_text);
6195                print "</div>\n";
6196        }
6197
6198        git_project_search_form($searchtext, $search_use_regexp);
6199        git_project_list_body(\@list, $order);
6200        git_footer_html();
6201}
6202
6203sub git_forks {
6204        my $order = $input_params{'order'};
6205        if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6206                die_error(400, "Unknown order parameter");
6207        }
6208
6209        my $filter = $project;
6210        $filter =~ s/\.git$//;
6211        my @list = git_get_projects_list($filter);
6212        if (!@list) {
6213                die_error(404, "No forks found");
6214        }
6215
6216        git_header_html();
6217        git_print_page_nav('','');
6218        git_print_header_div('summary', "$project forks");
6219        git_project_list_body(\@list, $order);
6220        git_footer_html();
6221}
6222
6223sub git_project_index {
6224        my @projects = git_get_projects_list($project_filter, $strict_export);
6225        if (!@projects) {
6226                die_error(404, "No projects found");
6227        }
6228
6229        print $cgi->header(
6230                -type => 'text/plain',
6231                -charset => 'utf-8',
6232                -content_disposition => 'inline; filename="index.aux"');
6233
6234        foreach my $pr (@projects) {
6235                if (!exists $pr->{'owner'}) {
6236                        $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6237                }
6238
6239                my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6240                # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6241                $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6242                $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6243                $path  =~ s/ /\+/g;
6244                $owner =~ s/ /\+/g;
6245
6246                print "$path $owner\n";
6247        }
6248}
6249
6250sub git_summary {
6251        my $descr = git_get_project_description($project) || "none";
6252        my %co = parse_commit("HEAD");
6253        my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6254        my $head = $co{'id'};
6255        my $remote_heads = gitweb_check_feature('remote_heads');
6256
6257        my $owner = git_get_project_owner($project);
6258
6259        my $refs = git_get_references();
6260        # These get_*_list functions return one more to allow us to see if
6261        # there are more ...
6262        my @taglist  = git_get_tags_list(16);
6263        my @headlist = git_get_heads_list(16);
6264        my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6265        my @forklist;
6266        my $check_forks = gitweb_check_feature('forks');
6267
6268        if ($check_forks) {
6269                # find forks of a project
6270                my $filter = $project;
6271                $filter =~ s/\.git$//;
6272                @forklist = git_get_projects_list($filter);
6273                # filter out forks of forks
6274                @forklist = filter_forks_from_projects_list(\@forklist)
6275                        if (@forklist);
6276        }
6277
6278        git_header_html();
6279        git_print_page_nav('summary','', $head);
6280
6281        print "<div class=\"title\">&nbsp;</div>\n";
6282        print "<table class=\"projects_list\">\n" .
6283              "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
6284              "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6285        if (defined $cd{'rfc2822'}) {
6286                print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6287                      "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6288        }
6289
6290        # use per project git URL list in $projectroot/$project/cloneurl
6291        # or make project git URL from git base URL and project name
6292        my $url_tag = "URL";
6293        my @url_list = git_get_project_url_list($project);
6294        @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6295        foreach my $git_url (@url_list) {
6296                next unless $git_url;
6297                print format_repo_url($url_tag, $git_url);
6298                $url_tag = "";
6299        }
6300
6301        # Tag cloud
6302        my $show_ctags = gitweb_check_feature('ctags');
6303        if ($show_ctags) {
6304                my $ctags = git_get_project_ctags($project);
6305                if (%$ctags) {
6306                        # without ability to add tags, don't show if there are none
6307                        my $cloud = git_populate_project_tagcloud($ctags);
6308                        print "<tr id=\"metadata_ctags\">" .
6309                              "<td>content tags</td>" .
6310                              "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6311                              "</tr>\n";
6312                }
6313        }
6314
6315        print "</table>\n";
6316
6317        # If XSS prevention is on, we don't include README.html.
6318        # TODO: Allow a readme in some safe format.
6319        if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6320                print "<div class=\"title\">readme</div>\n" .
6321                      "<div class=\"readme\">\n";
6322                insert_file("$projectroot/$project/README.html");
6323                print "\n</div>\n"; # class="readme"
6324        }
6325
6326        # we need to request one more than 16 (0..15) to check if
6327        # those 16 are all
6328        my @commitlist = $head ? parse_commits($head, 17) : ();
6329        if (@commitlist) {
6330                git_print_header_div('shortlog');
6331                git_shortlog_body(\@commitlist, 0, 15, $refs,
6332                                  $#commitlist <=  15 ? undef :
6333                                  $cgi->a({-href => href(action=>"shortlog")}, "..."));
6334        }
6335
6336        if (@taglist) {
6337                git_print_header_div('tags');
6338                git_tags_body(\@taglist, 0, 15,
6339                              $#taglist <=  15 ? undef :
6340                              $cgi->a({-href => href(action=>"tags")}, "..."));
6341        }
6342
6343        if (@headlist) {
6344                git_print_header_div('heads');
6345                git_heads_body(\@headlist, $head, 0, 15,
6346                               $#headlist <= 15 ? undef :
6347                               $cgi->a({-href => href(action=>"heads")}, "..."));
6348        }
6349
6350        if (%remotedata) {
6351                git_print_header_div('remotes');
6352                git_remotes_body(\%remotedata, 15, $head);
6353        }
6354
6355        if (@forklist) {
6356                git_print_header_div('forks');
6357                git_project_list_body(\@forklist, 'age', 0, 15,
6358                                      $#forklist <= 15 ? undef :
6359                                      $cgi->a({-href => href(action=>"forks")}, "..."),
6360                                      'no_header');
6361        }
6362
6363        git_footer_html();
6364}
6365
6366sub git_tag {
6367        my %tag = parse_tag($hash);
6368
6369        if (! %tag) {
6370                die_error(404, "Unknown tag object");
6371        }
6372
6373        my $head = git_get_head_hash($project);
6374        git_header_html();
6375        git_print_page_nav('','', $head,undef,$head);
6376        git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6377        print "<div class=\"title_text\">\n" .
6378              "<table class=\"object_header\">\n" .
6379              "<tr>\n" .
6380              "<td>object</td>\n" .
6381              "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6382                               $tag{'object'}) . "</td>\n" .
6383              "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6384                                              $tag{'type'}) . "</td>\n" .
6385              "</tr>\n";
6386        if (defined($tag{'author'})) {
6387                git_print_authorship_rows(\%tag, 'author');
6388        }
6389        print "</table>\n\n" .
6390              "</div>\n";
6391        print "<div class=\"page_body\">";
6392        my $comment = $tag{'comment'};
6393        foreach my $line (@$comment) {
6394                chomp $line;
6395                print esc_html($line, -nbsp=>1) . "<br/>\n";
6396        }
6397        print "</div>\n";
6398        git_footer_html();
6399}
6400
6401sub git_blame_common {
6402        my $format = shift || 'porcelain';
6403        if ($format eq 'porcelain' && $input_params{'javascript'}) {
6404                $format = 'incremental';
6405                $action = 'blame_incremental'; # for page title etc
6406        }
6407
6408        # permissions
6409        gitweb_check_feature('blame')
6410                or die_error(403, "Blame view not allowed");
6411
6412        # error checking
6413        die_error(400, "No file name given") unless $file_name;
6414        $hash_base ||= git_get_head_hash($project);
6415        die_error(404, "Couldn't find base commit") unless $hash_base;
6416        my %co = parse_commit($hash_base)
6417                or die_error(404, "Commit not found");
6418        my $ftype = "blob";
6419        if (!defined $hash) {
6420                $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6421                        or die_error(404, "Error looking up file");
6422        } else {
6423                $ftype = git_get_type($hash);
6424                if ($ftype !~ "blob") {
6425                        die_error(400, "Object is not a blob");
6426                }
6427        }
6428
6429        my $fd;
6430        if ($format eq 'incremental') {
6431                # get file contents (as base)
6432                open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6433                        or die_error(500, "Open git-cat-file failed");
6434        } elsif ($format eq 'data') {
6435                # run git-blame --incremental
6436                open $fd, "-|", git_cmd(), "blame", "--incremental",
6437                        $hash_base, "--", $file_name
6438                        or die_error(500, "Open git-blame --incremental failed");
6439        } else {
6440                # run git-blame --porcelain
6441                open $fd, "-|", git_cmd(), "blame", '-p',
6442                        $hash_base, '--', $file_name
6443                        or die_error(500, "Open git-blame --porcelain failed");
6444        }
6445
6446        # incremental blame data returns early
6447        if ($format eq 'data') {
6448                print $cgi->header(
6449                        -type=>"text/plain", -charset => "utf-8",
6450                        -status=> "200 OK");
6451                local $| = 1; # output autoflush
6452                while (my $line = <$fd>) {
6453                        print to_utf8($line);
6454                }
6455                close $fd
6456                        or print "ERROR $!\n";
6457
6458                print 'END';
6459                if (defined $t0 && gitweb_check_feature('timed')) {
6460                        print ' '.
6461                              tv_interval($t0, [ gettimeofday() ]).
6462                              ' '.$number_of_git_cmds;
6463                }
6464                print "\n";
6465
6466                return;
6467        }
6468
6469        # page header
6470        git_header_html();
6471        my $formats_nav =
6472                $cgi->a({-href => href(action=>"blob", -replay=>1)},
6473                        "blob") .
6474                " | ";
6475        if ($format eq 'incremental') {
6476                $formats_nav .=
6477                        $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6478                                "blame") . " (non-incremental)";
6479        } else {
6480                $formats_nav .=
6481                        $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6482                                "blame") . " (incremental)";
6483        }
6484        $formats_nav .=
6485                " | " .
6486                $cgi->a({-href => href(action=>"history", -replay=>1)},
6487                        "history") .
6488                " | " .
6489                $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6490                        "HEAD");
6491        git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6492        git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6493        git_print_page_path($file_name, $ftype, $hash_base);
6494
6495        # page body
6496        if ($format eq 'incremental') {
6497                print "<noscript>\n<div class=\"error\"><center><b>\n".
6498                      "This page requires JavaScript to run.\n Use ".
6499                      $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6500                              'this page').
6501                      " instead.\n".
6502                      "</b></center></div>\n</noscript>\n";
6503
6504                print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6505        }
6506
6507        print qq!<div class="page_body">\n!;
6508        print qq!<div id="progress_info">... / ...</div>\n!
6509                if ($format eq 'incremental');
6510        print qq!<table id="blame_table" class="blame" width="100%">\n!.
6511              #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6512              qq!<thead>\n!.
6513              qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6514              qq!</thead>\n!.
6515              qq!<tbody>\n!;
6516
6517        my @rev_color = qw(light dark);
6518        my $num_colors = scalar(@rev_color);
6519        my $current_color = 0;
6520
6521        if ($format eq 'incremental') {
6522                my $color_class = $rev_color[$current_color];
6523
6524                #contents of a file
6525                my $linenr = 0;
6526        LINE:
6527                while (my $line = <$fd>) {
6528                        chomp $line;
6529                        $linenr++;
6530
6531                        print qq!<tr id="l$linenr" class="$color_class">!.
6532                              qq!<td class="sha1"><a href=""> </a></td>!.
6533                              qq!<td class="linenr">!.
6534                              qq!<a class="linenr" href="">$linenr</a></td>!;
6535                        print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6536                        print qq!</tr>\n!;
6537                }
6538
6539        } else { # porcelain, i.e. ordinary blame
6540                my %metainfo = (); # saves information about commits
6541
6542                # blame data
6543        LINE:
6544                while (my $line = <$fd>) {
6545                        chomp $line;
6546                        # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6547                        # no <lines in group> for subsequent lines in group of lines
6548                        my ($full_rev, $orig_lineno, $lineno, $group_size) =
6549                           ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6550                        if (!exists $metainfo{$full_rev}) {
6551                                $metainfo{$full_rev} = { 'nprevious' => 0 };
6552                        }
6553                        my $meta = $metainfo{$full_rev};
6554                        my $data;
6555                        while ($data = <$fd>) {
6556                                chomp $data;
6557                                last if ($data =~ s/^\t//); # contents of line
6558                                if ($data =~ /^(\S+)(?: (.*))?$/) {
6559                                        $meta->{$1} = $2 unless exists $meta->{$1};
6560                                }
6561                                if ($data =~ /^previous /) {
6562                                        $meta->{'nprevious'}++;
6563                                }
6564                        }
6565                        my $short_rev = substr($full_rev, 0, 8);
6566                        my $author = $meta->{'author'};
6567                        my %date =
6568                                parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6569                        my $date = $date{'iso-tz'};
6570                        if ($group_size) {
6571                                $current_color = ($current_color + 1) % $num_colors;
6572                        }
6573                        my $tr_class = $rev_color[$current_color];
6574                        $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6575                        $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6576                        $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6577                        print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6578                        if ($group_size) {
6579                                print "<td class=\"sha1\"";
6580                                print " title=\"". esc_html($author) . ", $date\"";
6581                                print " rowspan=\"$group_size\"" if ($group_size > 1);
6582                                print ">";
6583                                print $cgi->a({-href => href(action=>"commit",
6584                                                             hash=>$full_rev,
6585                                                             file_name=>$file_name)},
6586                                              esc_html($short_rev));
6587                                if ($group_size >= 2) {
6588                                        my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6589                                        if (@author_initials) {
6590                                                print "<br />" .
6591                                                      esc_html(join('', @author_initials));
6592                                                #           or join('.', ...)
6593                                        }
6594                                }
6595                                print "</td>\n";
6596                        }
6597                        # 'previous' <sha1 of parent commit> <filename at commit>
6598                        if (exists $meta->{'previous'} &&
6599                            $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6600                                $meta->{'parent'} = $1;
6601                                $meta->{'file_parent'} = unquote($2);
6602                        }
6603                        my $linenr_commit =
6604                                exists($meta->{'parent'}) ?
6605                                $meta->{'parent'} : $full_rev;
6606                        my $linenr_filename =
6607                                exists($meta->{'file_parent'}) ?
6608                                $meta->{'file_parent'} : unquote($meta->{'filename'});
6609                        my $blamed = href(action => 'blame',
6610                                          file_name => $linenr_filename,
6611                                          hash_base => $linenr_commit);
6612                        print "<td class=\"linenr\">";
6613                        print $cgi->a({ -href => "$blamed#l$orig_lineno",
6614                                        -class => "linenr" },
6615                                      esc_html($lineno));
6616                        print "</td>";
6617                        print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6618                        print "</tr>\n";
6619                } # end while
6620
6621        }
6622
6623        # footer
6624        print "</tbody>\n".
6625              "</table>\n"; # class="blame"
6626        print "</div>\n";   # class="blame_body"
6627        close $fd
6628                or print "Reading blob failed\n";
6629
6630        git_footer_html();
6631}
6632
6633sub git_blame {
6634        git_blame_common();
6635}
6636
6637sub git_blame_incremental {
6638        git_blame_common('incremental');
6639}
6640
6641sub git_blame_data {
6642        git_blame_common('data');
6643}
6644
6645sub git_tags {
6646        my $head = git_get_head_hash($project);
6647        git_header_html();
6648        git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6649        git_print_header_div('summary', $project);
6650
6651        my @tagslist = git_get_tags_list();
6652        if (@tagslist) {
6653                git_tags_body(\@tagslist);
6654        }
6655        git_footer_html();
6656}
6657
6658sub git_heads {
6659        my $head = git_get_head_hash($project);
6660        git_header_html();
6661        git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6662        git_print_header_div('summary', $project);
6663
6664        my @headslist = git_get_heads_list();
6665        if (@headslist) {
6666                git_heads_body(\@headslist, $head);
6667        }
6668        git_footer_html();
6669}
6670
6671# used both for single remote view and for list of all the remotes
6672sub git_remotes {
6673        gitweb_check_feature('remote_heads')
6674                or die_error(403, "Remote heads view is disabled");
6675
6676        my $head = git_get_head_hash($project);
6677        my $remote = $input_params{'hash'};
6678
6679        my $remotedata = git_get_remotes_list($remote);
6680        die_error(500, "Unable to get remote information") unless defined $remotedata;
6681
6682        unless (%$remotedata) {
6683                die_error(404, defined $remote ?
6684                        "Remote $remote not found" :
6685                        "No remotes found");
6686        }
6687
6688        git_header_html(undef, undef, -action_extra => $remote);
6689        git_print_page_nav('', '',  $head, undef, $head,
6690                format_ref_views($remote ? '' : 'remotes'));
6691
6692        fill_remote_heads($remotedata);
6693        if (defined $remote) {
6694                git_print_header_div('remotes', "$remote remote for $project");
6695                git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6696        } else {
6697                git_print_header_div('summary', "$project remotes");
6698                git_remotes_body($remotedata, undef, $head);
6699        }
6700
6701        git_footer_html();
6702}
6703
6704sub git_blob_plain {
6705        my $type = shift;
6706        my $expires;
6707
6708        if (!defined $hash) {
6709                if (defined $file_name) {
6710                        my $base = $hash_base || git_get_head_hash($project);
6711                        $hash = git_get_hash_by_path($base, $file_name, "blob")
6712                                or die_error(404, "Cannot find file");
6713                } else {
6714                        die_error(400, "No file name defined");
6715                }
6716        } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6717                # blobs defined by non-textual hash id's can be cached
6718                $expires = "+1d";
6719        }
6720
6721        open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6722                or die_error(500, "Open git-cat-file blob '$hash' failed");
6723
6724        # content-type (can include charset)
6725        $type = blob_contenttype($fd, $file_name, $type);
6726
6727        # "save as" filename, even when no $file_name is given
6728        my $save_as = "$hash";
6729        if (defined $file_name) {
6730                $save_as = $file_name;
6731        } elsif ($type =~ m/^text\//) {
6732                $save_as .= '.txt';
6733        }
6734
6735        # With XSS prevention on, blobs of all types except a few known safe
6736        # ones are served with "Content-Disposition: attachment" to make sure
6737        # they don't run in our security domain.  For certain image types,
6738        # blob view writes an <img> tag referring to blob_plain view, and we
6739        # want to be sure not to break that by serving the image as an
6740        # attachment (though Firefox 3 doesn't seem to care).
6741        my $sandbox = $prevent_xss &&
6742                $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6743
6744        # serve text/* as text/plain
6745        if ($prevent_xss &&
6746            ($type =~ m!^text/[a-z]+\b(.*)$! ||
6747             ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6748                my $rest = $1;
6749                $rest = defined $rest ? $rest : '';
6750                $type = "text/plain$rest";
6751        }
6752
6753        print $cgi->header(
6754                -type => $type,
6755                -expires => $expires,
6756                -content_disposition =>
6757                        ($sandbox ? 'attachment' : 'inline')
6758                        . '; filename="' . $save_as . '"');
6759        local $/ = undef;
6760        binmode STDOUT, ':raw';
6761        print <$fd>;
6762        binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6763        close $fd;
6764}
6765
6766sub git_blob {
6767        my $expires;
6768
6769        if (!defined $hash) {
6770                if (defined $file_name) {
6771                        my $base = $hash_base || git_get_head_hash($project);
6772                        $hash = git_get_hash_by_path($base, $file_name, "blob")
6773                                or die_error(404, "Cannot find file");
6774                } else {
6775                        die_error(400, "No file name defined");
6776                }
6777        } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6778                # blobs defined by non-textual hash id's can be cached
6779                $expires = "+1d";
6780        }
6781
6782        my $have_blame = gitweb_check_feature('blame');
6783        open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6784                or die_error(500, "Couldn't cat $file_name, $hash");
6785        my $mimetype = blob_mimetype($fd, $file_name);
6786        # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6787        if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6788                close $fd;
6789                return git_blob_plain($mimetype);
6790        }
6791        # we can have blame only for text/* mimetype
6792        $have_blame &&= ($mimetype =~ m!^text/!);
6793
6794        my $highlight = gitweb_check_feature('highlight');
6795        my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6796        $fd = run_highlighter($fd, $highlight, $syntax)
6797                if $syntax;
6798
6799        git_header_html(undef, $expires);
6800        my $formats_nav = '';
6801        if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6802                if (defined $file_name) {
6803                        if ($have_blame) {
6804                                $formats_nav .=
6805                                        $cgi->a({-href => href(action=>"blame", -replay=>1)},
6806                                                "blame") .
6807                                        " | ";
6808                        }
6809                        $formats_nav .=
6810                                $cgi->a({-href => href(action=>"history", -replay=>1)},
6811                                        "history") .
6812                                " | " .
6813                                $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6814                                        "raw") .
6815                                " | " .
6816                                $cgi->a({-href => href(action=>"blob",
6817                                                       hash_base=>"HEAD", file_name=>$file_name)},
6818                                        "HEAD");
6819                } else {
6820                        $formats_nav .=
6821                                $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6822                                        "raw");
6823                }
6824                git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6825                git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6826        } else {
6827                print "<div class=\"page_nav\">\n" .
6828                      "<br/><br/></div>\n" .
6829                      "<div class=\"title\">".esc_html($hash)."</div>\n";
6830        }
6831        git_print_page_path($file_name, "blob", $hash_base);
6832        print "<div class=\"page_body\">\n";
6833        if ($mimetype =~ m!^image/!) {
6834                print qq!<img type="!.esc_attr($mimetype).qq!"!;
6835                if ($file_name) {
6836                        print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6837                }
6838                print qq! src="! .
6839                      href(action=>"blob_plain", hash=>$hash,
6840                           hash_base=>$hash_base, file_name=>$file_name) .
6841                      qq!" />\n!;
6842        } else {
6843                my $nr;
6844                while (my $line = <$fd>) {
6845                        chomp $line;
6846                        $nr++;
6847                        $line = untabify($line);
6848                        printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6849                               $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6850                               $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6851                }
6852        }
6853        close $fd
6854                or print "Reading blob failed.\n";
6855        print "</div>";
6856        git_footer_html();
6857}
6858
6859sub git_tree {
6860        if (!defined $hash_base) {
6861                $hash_base = "HEAD";
6862        }
6863        if (!defined $hash) {
6864                if (defined $file_name) {
6865                        $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6866                } else {
6867                        $hash = $hash_base;
6868                }
6869        }
6870        die_error(404, "No such tree") unless defined($hash);
6871
6872        my $show_sizes = gitweb_check_feature('show-sizes');
6873        my $have_blame = gitweb_check_feature('blame');
6874
6875        my @entries = ();
6876        {
6877                local $/ = "\0";
6878                open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6879                        ($show_sizes ? '-l' : ()), @extra_options, $hash
6880                        or die_error(500, "Open git-ls-tree failed");
6881                @entries = map { chomp; $_ } <$fd>;
6882                close $fd
6883                        or die_error(404, "Reading tree failed");
6884        }
6885
6886        my $refs = git_get_references();
6887        my $ref = format_ref_marker($refs, $hash_base);
6888        git_header_html();
6889        my $basedir = '';
6890        if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6891                my @views_nav = ();
6892                if (defined $file_name) {
6893                        push @views_nav,
6894                                $cgi->a({-href => href(action=>"history", -replay=>1)},
6895                                        "history"),
6896                                $cgi->a({-href => href(action=>"tree",
6897                                                       hash_base=>"HEAD", file_name=>$file_name)},
6898                                        "HEAD"),
6899                }
6900                my $snapshot_links = format_snapshot_links($hash);
6901                if (defined $snapshot_links) {
6902                        # FIXME: Should be available when we have no hash base as well.
6903                        push @views_nav, $snapshot_links;
6904                }
6905                git_print_page_nav('tree','', $hash_base, undef, undef,
6906                                   join(' | ', @views_nav));
6907                git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6908        } else {
6909                undef $hash_base;
6910                print "<div class=\"page_nav\">\n";
6911                print "<br/><br/></div>\n";
6912                print "<div class=\"title\">".esc_html($hash)."</div>\n";
6913        }
6914        if (defined $file_name) {
6915                $basedir = $file_name;
6916                if ($basedir ne '' && substr($basedir, -1) ne '/') {
6917                        $basedir .= '/';
6918                }
6919                git_print_page_path($file_name, 'tree', $hash_base);
6920        }
6921        print "<div class=\"page_body\">\n";
6922        print "<table class=\"tree\">\n";
6923        my $alternate = 1;
6924        # '..' (top directory) link if possible
6925        if (defined $hash_base &&
6926            defined $file_name && $file_name =~ m![^/]+$!) {
6927                if ($alternate) {
6928                        print "<tr class=\"dark\">\n";
6929                } else {
6930                        print "<tr class=\"light\">\n";
6931                }
6932                $alternate ^= 1;
6933
6934                my $up = $file_name;
6935                $up =~ s!/?[^/]+$!!;
6936                undef $up unless $up;
6937                # based on git_print_tree_entry
6938                print '<td class="mode">' . mode_str('040000') . "</td>\n";
6939                print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6940                print '<td class="list">';
6941                print $cgi->a({-href => href(action=>"tree",
6942                                             hash_base=>$hash_base,
6943                                             file_name=>$up)},
6944                              "..");
6945                print "</td>\n";
6946                print "<td class=\"link\"></td>\n";
6947
6948                print "</tr>\n";
6949        }
6950        foreach my $line (@entries) {
6951                my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6952
6953                if ($alternate) {
6954                        print "<tr class=\"dark\">\n";
6955                } else {
6956                        print "<tr class=\"light\">\n";
6957                }
6958                $alternate ^= 1;
6959
6960                git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6961
6962                print "</tr>\n";
6963        }
6964        print "</table>\n" .
6965              "</div>";
6966        git_footer_html();
6967}
6968
6969sub snapshot_name {
6970        my ($project, $hash) = @_;
6971
6972        # path/to/project.git  -> project
6973        # path/to/project/.git -> project
6974        my $name = to_utf8($project);
6975        $name =~ s,([^/])/*\.git$,$1,;
6976        $name = basename($name);
6977        # sanitize name
6978        $name =~ s/[[:cntrl:]]/?/g;
6979
6980        my $ver = $hash;
6981        if ($hash =~ /^[0-9a-fA-F]+$/) {
6982                # shorten SHA-1 hash
6983                my $full_hash = git_get_full_hash($project, $hash);
6984                if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6985                        $ver = git_get_short_hash($project, $hash);
6986                }
6987        } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6988                # tags don't need shortened SHA-1 hash
6989                $ver = $1;
6990        } else {
6991                # branches and other need shortened SHA-1 hash
6992                if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6993                        $ver = $1;
6994                }
6995                $ver .= '-' . git_get_short_hash($project, $hash);
6996        }
6997        # in case of hierarchical branch names
6998        $ver =~ s!/!.!g;
6999
7000        # name = project-version_string
7001        $name = "$name-$ver";
7002
7003        return wantarray ? ($name, $name) : $name;
7004}
7005
7006sub git_snapshot {
7007        my $format = $input_params{'snapshot_format'};
7008        if (!@snapshot_fmts) {
7009                die_error(403, "Snapshots not allowed");
7010        }
7011        # default to first supported snapshot format
7012        $format ||= $snapshot_fmts[0];
7013        if ($format !~ m/^[a-z0-9]+$/) {
7014                die_error(400, "Invalid snapshot format parameter");
7015        } elsif (!exists($known_snapshot_formats{$format})) {
7016                die_error(400, "Unknown snapshot format");
7017        } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7018                die_error(403, "Snapshot format not allowed");
7019        } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7020                die_error(403, "Unsupported snapshot format");
7021        }
7022
7023        my $type = git_get_type("$hash^{}");
7024        if (!$type) {
7025                die_error(404, 'Object does not exist');
7026        }  elsif ($type eq 'blob') {
7027                die_error(400, 'Object is not a tree-ish');
7028        }
7029
7030        my ($name, $prefix) = snapshot_name($project, $hash);
7031        my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7032        my $cmd = quote_command(
7033                git_cmd(), 'archive',
7034                "--format=$known_snapshot_formats{$format}{'format'}",
7035                "--prefix=$prefix/", $hash);
7036        if (exists $known_snapshot_formats{$format}{'compressor'}) {
7037                $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7038        }
7039
7040        $filename =~ s/(["\\])/\\$1/g;
7041        print $cgi->header(
7042                -type => $known_snapshot_formats{$format}{'type'},
7043                -content_disposition => 'inline; filename="' . $filename . '"',
7044                -status => '200 OK');
7045
7046        open my $fd, "-|", $cmd
7047                or die_error(500, "Execute git-archive failed");
7048        binmode STDOUT, ':raw';
7049        print <$fd>;
7050        binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7051        close $fd;
7052}
7053
7054sub git_log_generic {
7055        my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7056
7057        my $head = git_get_head_hash($project);
7058        if (!defined $base) {
7059                $base = $head;
7060        }
7061        if (!defined $page) {
7062                $page = 0;
7063        }
7064        my $refs = git_get_references();
7065
7066        my $commit_hash = $base;
7067        if (defined $parent) {
7068                $commit_hash = "$parent..$base";
7069        }
7070        my @commitlist =
7071                parse_commits($commit_hash, 101, (100 * $page),
7072                              defined $file_name ? ($file_name, "--full-history") : ());
7073
7074        my $ftype;
7075        if (!defined $file_hash && defined $file_name) {
7076                # some commits could have deleted file in question,
7077                # and not have it in tree, but one of them has to have it
7078                for (my $i = 0; $i < @commitlist; $i++) {
7079                        $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7080                        last if defined $file_hash;
7081                }
7082        }
7083        if (defined $file_hash) {
7084                $ftype = git_get_type($file_hash);
7085        }
7086        if (defined $file_name && !defined $ftype) {
7087                die_error(500, "Unknown type of object");
7088        }
7089        my %co;
7090        if (defined $file_name) {
7091                %co = parse_commit($base)
7092                        or die_error(404, "Unknown commit object");
7093        }
7094
7095
7096        my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7097        my $next_link = '';
7098        if ($#commitlist >= 100) {
7099                $next_link =
7100                        $cgi->a({-href => href(-replay=>1, page=>$page+1),
7101                                 -accesskey => "n", -title => "Alt-n"}, "next");
7102        }
7103        my $patch_max = gitweb_get_feature('patches');
7104        if ($patch_max && !defined $file_name) {
7105                if ($patch_max < 0 || @commitlist <= $patch_max) {
7106                        $paging_nav .= " &sdot; " .
7107                                $cgi->a({-href => href(action=>"patches", -replay=>1)},
7108                                        "patches");
7109                }
7110        }
7111
7112        git_header_html();
7113        git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7114        if (defined $file_name) {
7115                git_print_header_div('commit', esc_html($co{'title'}), $base);
7116        } else {
7117                git_print_header_div('summary', $project)
7118        }
7119        git_print_page_path($file_name, $ftype, $hash_base)
7120                if (defined $file_name);
7121
7122        $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7123                     $file_name, $file_hash, $ftype);
7124
7125        git_footer_html();
7126}
7127
7128sub git_log {
7129        git_log_generic('log', \&git_log_body,
7130                        $hash, $hash_parent);
7131}
7132
7133sub git_commit {
7134        $hash ||= $hash_base || "HEAD";
7135        my %co = parse_commit($hash)
7136            or die_error(404, "Unknown commit object");
7137
7138        my $parent  = $co{'parent'};
7139        my $parents = $co{'parents'}; # listref
7140
7141        # we need to prepare $formats_nav before any parameter munging
7142        my $formats_nav;
7143        if (!defined $parent) {
7144                # --root commitdiff
7145                $formats_nav .= '(initial)';
7146        } elsif (@$parents == 1) {
7147                # single parent commit
7148                $formats_nav .=
7149                        '(parent: ' .
7150                        $cgi->a({-href => href(action=>"commit",
7151                                               hash=>$parent)},
7152                                esc_html(substr($parent, 0, 7))) .
7153                        ')';
7154        } else {
7155                # merge commit
7156                $formats_nav .=
7157                        '(merge: ' .
7158                        join(' ', map {
7159                                $cgi->a({-href => href(action=>"commit",
7160                                                       hash=>$_)},
7161                                        esc_html(substr($_, 0, 7)));
7162                        } @$parents ) .
7163                        ')';
7164        }
7165        if (gitweb_check_feature('patches') && @$parents <= 1) {
7166                $formats_nav .= " | " .
7167                        $cgi->a({-href => href(action=>"patch", -replay=>1)},
7168                                "patch");
7169        }
7170
7171        if (!defined $parent) {
7172                $parent = "--root";
7173        }
7174        my @difftree;
7175        open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7176                @diff_opts,
7177                (@$parents <= 1 ? $parent : '-c'),
7178                $hash, "--"
7179                or die_error(500, "Open git-diff-tree failed");
7180        @difftree = map { chomp; $_ } <$fd>;
7181        close $fd or die_error(404, "Reading git-diff-tree failed");
7182
7183        # non-textual hash id's can be cached
7184        my $expires;
7185        if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7186                $expires = "+1d";
7187        }
7188        my $refs = git_get_references();
7189        my $ref = format_ref_marker($refs, $co{'id'});
7190
7191        git_header_html(undef, $expires);
7192        git_print_page_nav('commit', '',
7193                           $hash, $co{'tree'}, $hash,
7194                           $formats_nav);
7195
7196        if (defined $co{'parent'}) {
7197                git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7198        } else {
7199                git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7200        }
7201        print "<div class=\"title_text\">\n" .
7202              "<table class=\"object_header\">\n";
7203        git_print_authorship_rows(\%co);
7204        print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7205        print "<tr>" .
7206              "<td>tree</td>" .
7207              "<td class=\"sha1\">" .
7208              $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7209                       class => "list"}, $co{'tree'}) .
7210              "</td>" .
7211              "<td class=\"link\">" .
7212              $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7213                      "tree");
7214        my $snapshot_links = format_snapshot_links($hash);
7215        if (defined $snapshot_links) {
7216                print " | " . $snapshot_links;
7217        }
7218        print "</td>" .
7219              "</tr>\n";
7220
7221        foreach my $par (@$parents) {
7222                print "<tr>" .
7223                      "<td>parent</td>" .
7224                      "<td class=\"sha1\">" .
7225                      $cgi->a({-href => href(action=>"commit", hash=>$par),
7226                               class => "list"}, $par) .
7227                      "</td>" .
7228                      "<td class=\"link\">" .
7229                      $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7230                      " | " .
7231                      $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7232                      "</td>" .
7233                      "</tr>\n";
7234        }
7235        print "</table>".
7236              "</div>\n";
7237
7238        print "<div class=\"page_body\">\n";
7239        git_print_log($co{'comment'});
7240        print "</div>\n";
7241
7242        git_difftree_body(\@difftree, $hash, @$parents);
7243
7244        git_footer_html();
7245}
7246
7247sub git_object {
7248        # object is defined by:
7249        # - hash or hash_base alone
7250        # - hash_base and file_name
7251        my $type;
7252
7253        # - hash or hash_base alone
7254        if ($hash || ($hash_base && !defined $file_name)) {
7255                my $object_id = $hash || $hash_base;
7256
7257                open my $fd, "-|", quote_command(
7258                        git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7259                        or die_error(404, "Object does not exist");
7260                $type = <$fd>;
7261                chomp $type;
7262                close $fd
7263                        or die_error(404, "Object does not exist");
7264
7265        # - hash_base and file_name
7266        } elsif ($hash_base && defined $file_name) {
7267                $file_name =~ s,/+$,,;
7268
7269                system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7270                        or die_error(404, "Base object does not exist");
7271
7272                # here errors should not hapen
7273                open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7274                        or die_error(500, "Open git-ls-tree failed");
7275                my $line = <$fd>;
7276                close $fd;
7277
7278                #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7279                unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7280                        die_error(404, "File or directory for given base does not exist");
7281                }
7282                $type = $2;
7283                $hash = $3;
7284        } else {
7285                die_error(400, "Not enough information to find object");
7286        }
7287
7288        print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7289                                          hash=>$hash, hash_base=>$hash_base,
7290                                          file_name=>$file_name),
7291                             -status => '302 Found');
7292}
7293
7294sub git_blobdiff {
7295        my $format = shift || 'html';
7296        my $diff_style = $input_params{'diff_style'} || 'inline';
7297
7298        my $fd;
7299        my @difftree;
7300        my %diffinfo;
7301        my $expires;
7302
7303        # preparing $fd and %diffinfo for git_patchset_body
7304        # new style URI
7305        if (defined $hash_base && defined $hash_parent_base) {
7306                if (defined $file_name) {
7307                        # read raw output
7308                        open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7309                                $hash_parent_base, $hash_base,
7310                                "--", (defined $file_parent ? $file_parent : ()), $file_name
7311                                or die_error(500, "Open git-diff-tree failed");
7312                        @difftree = map { chomp; $_ } <$fd>;
7313                        close $fd
7314                                or die_error(404, "Reading git-diff-tree failed");
7315                        @difftree
7316                                or die_error(404, "Blob diff not found");
7317
7318                } elsif (defined $hash &&
7319                         $hash =~ /[0-9a-fA-F]{40}/) {
7320                        # try to find filename from $hash
7321
7322                        # read filtered raw output
7323                        open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7324                                $hash_parent_base, $hash_base, "--"
7325                                or die_error(500, "Open git-diff-tree failed");
7326                        @difftree =
7327                                # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7328                                # $hash == to_id
7329                                grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7330                                map { chomp; $_ } <$fd>;
7331                        close $fd
7332                                or die_error(404, "Reading git-diff-tree failed");
7333                        @difftree
7334                                or die_error(404, "Blob diff not found");
7335
7336                } else {
7337                        die_error(400, "Missing one of the blob diff parameters");
7338                }
7339
7340                if (@difftree > 1) {
7341                        die_error(400, "Ambiguous blob diff specification");
7342                }
7343
7344                %diffinfo = parse_difftree_raw_line($difftree[0]);
7345                $file_parent ||= $diffinfo{'from_file'} || $file_name;
7346                $file_name   ||= $diffinfo{'to_file'};
7347
7348                $hash_parent ||= $diffinfo{'from_id'};
7349                $hash        ||= $diffinfo{'to_id'};
7350
7351                # non-textual hash id's can be cached
7352                if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7353                    $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7354                        $expires = '+1d';
7355                }
7356
7357                # open patch output
7358                open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7359                        '-p', ($format eq 'html' ? "--full-index" : ()),
7360                        $hash_parent_base, $hash_base,
7361                        "--", (defined $file_parent ? $file_parent : ()), $file_name
7362                        or die_error(500, "Open git-diff-tree failed");
7363        }
7364
7365        # old/legacy style URI -- not generated anymore since 1.4.3.
7366        if (!%diffinfo) {
7367                die_error('404 Not Found', "Missing one of the blob diff parameters")
7368        }
7369
7370        # header
7371        if ($format eq 'html') {
7372                my $formats_nav =
7373                        $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7374                                "raw");
7375                $formats_nav .= diff_style_nav($diff_style);
7376                git_header_html(undef, $expires);
7377                if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7378                        git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7379                        git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7380                } else {
7381                        print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7382                        print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7383                }
7384                if (defined $file_name) {
7385                        git_print_page_path($file_name, "blob", $hash_base);
7386                } else {
7387                        print "<div class=\"page_path\"></div>\n";
7388                }
7389
7390        } elsif ($format eq 'plain') {
7391                print $cgi->header(
7392                        -type => 'text/plain',
7393                        -charset => 'utf-8',
7394                        -expires => $expires,
7395                        -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7396
7397                print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7398
7399        } else {
7400                die_error(400, "Unknown blobdiff format");
7401        }
7402
7403        # patch
7404        if ($format eq 'html') {
7405                print "<div class=\"page_body\">\n";
7406
7407                git_patchset_body($fd, $diff_style,
7408                                  [ \%diffinfo ], $hash_base, $hash_parent_base);
7409                close $fd;
7410
7411                print "</div>\n"; # class="page_body"
7412                git_footer_html();
7413
7414        } else {
7415                while (my $line = <$fd>) {
7416                        $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7417                        $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7418
7419                        print $line;
7420
7421                        last if $line =~ m!^\+\+\+!;
7422                }
7423                local $/ = undef;
7424                print <$fd>;
7425                close $fd;
7426        }
7427}
7428
7429sub git_blobdiff_plain {
7430        git_blobdiff('plain');
7431}
7432
7433# assumes that it is added as later part of already existing navigation,
7434# so it returns "| foo | bar" rather than just "foo | bar"
7435sub diff_style_nav {
7436        my ($diff_style, $is_combined) = @_;
7437        $diff_style ||= 'inline';
7438
7439        return "" if ($is_combined);
7440
7441        my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7442        my %styles = @styles;
7443        @styles =
7444                @styles[ map { $_ * 2 } 0..$#styles/2 ];
7445
7446        return join '',
7447                map { " | ".$_ }
7448                map {
7449                        $_ eq $diff_style ? $styles{$_} :
7450                        $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7451                } @styles;
7452}
7453
7454sub git_commitdiff {
7455        my %params = @_;
7456        my $format = $params{-format} || 'html';
7457        my $diff_style = $input_params{'diff_style'} || 'inline';
7458
7459        my ($patch_max) = gitweb_get_feature('patches');
7460        if ($format eq 'patch') {
7461                die_error(403, "Patch view not allowed") unless $patch_max;
7462        }
7463
7464        $hash ||= $hash_base || "HEAD";
7465        my %co = parse_commit($hash)
7466            or die_error(404, "Unknown commit object");
7467
7468        # choose format for commitdiff for merge
7469        if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7470                $hash_parent = '--cc';
7471        }
7472        # we need to prepare $formats_nav before almost any parameter munging
7473        my $formats_nav;
7474        if ($format eq 'html') {
7475                $formats_nav =
7476                        $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7477                                "raw");
7478                if ($patch_max && @{$co{'parents'}} <= 1) {
7479                        $formats_nav .= " | " .
7480                                $cgi->a({-href => href(action=>"patch", -replay=>1)},
7481                                        "patch");
7482                }
7483                $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7484
7485                if (defined $hash_parent &&
7486                    $hash_parent ne '-c' && $hash_parent ne '--cc') {
7487                        # commitdiff with two commits given
7488                        my $hash_parent_short = $hash_parent;
7489                        if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7490                                $hash_parent_short = substr($hash_parent, 0, 7);
7491                        }
7492                        $formats_nav .=
7493                                ' (from';
7494                        for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7495                                if ($co{'parents'}[$i] eq $hash_parent) {
7496                                        $formats_nav .= ' parent ' . ($i+1);
7497                                        last;
7498                                }
7499                        }
7500                        $formats_nav .= ': ' .
7501                                $cgi->a({-href => href(-replay=>1,
7502                                                       hash=>$hash_parent, hash_base=>undef)},
7503                                        esc_html($hash_parent_short)) .
7504                                ')';
7505                } elsif (!$co{'parent'}) {
7506                        # --root commitdiff
7507                        $formats_nav .= ' (initial)';
7508                } elsif (scalar @{$co{'parents'}} == 1) {
7509                        # single parent commit
7510                        $formats_nav .=
7511                                ' (parent: ' .
7512                                $cgi->a({-href => href(-replay=>1,
7513                                                       hash=>$co{'parent'}, hash_base=>undef)},
7514                                        esc_html(substr($co{'parent'}, 0, 7))) .
7515                                ')';
7516                } else {
7517                        # merge commit
7518                        if ($hash_parent eq '--cc') {
7519                                $formats_nav .= ' | ' .
7520                                        $cgi->a({-href => href(-replay=>1,
7521                                                               hash=>$hash, hash_parent=>'-c')},
7522                                                'combined');
7523                        } else { # $hash_parent eq '-c'
7524                                $formats_nav .= ' | ' .
7525                                        $cgi->a({-href => href(-replay=>1,
7526                                                               hash=>$hash, hash_parent=>'--cc')},
7527                                                'compact');
7528                        }
7529                        $formats_nav .=
7530                                ' (merge: ' .
7531                                join(' ', map {
7532                                        $cgi->a({-href => href(-replay=>1,
7533                                                               hash=>$_, hash_base=>undef)},
7534                                                esc_html(substr($_, 0, 7)));
7535                                } @{$co{'parents'}} ) .
7536                                ')';
7537                }
7538        }
7539
7540        my $hash_parent_param = $hash_parent;
7541        if (!defined $hash_parent_param) {
7542                # --cc for multiple parents, --root for parentless
7543                $hash_parent_param =
7544                        @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7545        }
7546
7547        # read commitdiff
7548        my $fd;
7549        my @difftree;
7550        if ($format eq 'html') {
7551                open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7552                        "--no-commit-id", "--patch-with-raw", "--full-index",
7553                        $hash_parent_param, $hash, "--"
7554                        or die_error(500, "Open git-diff-tree failed");
7555
7556                while (my $line = <$fd>) {
7557                        chomp $line;
7558                        # empty line ends raw part of diff-tree output
7559                        last unless $line;
7560                        push @difftree, scalar parse_difftree_raw_line($line);
7561                }
7562
7563        } elsif ($format eq 'plain') {
7564                open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7565                        '-p', $hash_parent_param, $hash, "--"
7566                        or die_error(500, "Open git-diff-tree failed");
7567        } elsif ($format eq 'patch') {
7568                # For commit ranges, we limit the output to the number of
7569                # patches specified in the 'patches' feature.
7570                # For single commits, we limit the output to a single patch,
7571                # diverging from the git-format-patch default.
7572                my @commit_spec = ();
7573                if ($hash_parent) {
7574                        if ($patch_max > 0) {
7575                                push @commit_spec, "-$patch_max";
7576                        }
7577                        push @commit_spec, '-n', "$hash_parent..$hash";
7578                } else {
7579                        if ($params{-single}) {
7580                                push @commit_spec, '-1';
7581                        } else {
7582                                if ($patch_max > 0) {
7583                                        push @commit_spec, "-$patch_max";
7584                                }
7585                                push @commit_spec, "-n";
7586                        }
7587                        push @commit_spec, '--root', $hash;
7588                }
7589                open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7590                        '--encoding=utf8', '--stdout', @commit_spec
7591                        or die_error(500, "Open git-format-patch failed");
7592        } else {
7593                die_error(400, "Unknown commitdiff format");
7594        }
7595
7596        # non-textual hash id's can be cached
7597        my $expires;
7598        if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7599                $expires = "+1d";
7600        }
7601
7602        # write commit message
7603        if ($format eq 'html') {
7604                my $refs = git_get_references();
7605                my $ref = format_ref_marker($refs, $co{'id'});
7606
7607                git_header_html(undef, $expires);
7608                git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7609                git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7610                print "<div class=\"title_text\">\n" .
7611                      "<table class=\"object_header\">\n";
7612                git_print_authorship_rows(\%co);
7613                print "</table>".
7614                      "</div>\n";
7615                print "<div class=\"page_body\">\n";
7616                if (@{$co{'comment'}} > 1) {
7617                        print "<div class=\"log\">\n";
7618                        git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7619                        print "</div>\n"; # class="log"
7620                }
7621
7622        } elsif ($format eq 'plain') {
7623                my $refs = git_get_references("tags");
7624                my $tagname = git_get_rev_name_tags($hash);
7625                my $filename = basename($project) . "-$hash.patch";
7626
7627                print $cgi->header(
7628                        -type => 'text/plain',
7629                        -charset => 'utf-8',
7630                        -expires => $expires,
7631                        -content_disposition => 'inline; filename="' . "$filename" . '"');
7632                my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7633                print "From: " . to_utf8($co{'author'}) . "\n";
7634                print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7635                print "Subject: " . to_utf8($co{'title'}) . "\n";
7636
7637                print "X-Git-Tag: $tagname\n" if $tagname;
7638                print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7639
7640                foreach my $line (@{$co{'comment'}}) {
7641                        print to_utf8($line) . "\n";
7642                }
7643                print "---\n\n";
7644        } elsif ($format eq 'patch') {
7645                my $filename = basename($project) . "-$hash.patch";
7646
7647                print $cgi->header(
7648                        -type => 'text/plain',
7649                        -charset => 'utf-8',
7650                        -expires => $expires,
7651                        -content_disposition => 'inline; filename="' . "$filename" . '"');
7652        }
7653
7654        # write patch
7655        if ($format eq 'html') {
7656                my $use_parents = !defined $hash_parent ||
7657                        $hash_parent eq '-c' || $hash_parent eq '--cc';
7658                git_difftree_body(\@difftree, $hash,
7659                                  $use_parents ? @{$co{'parents'}} : $hash_parent);
7660                print "<br/>\n";
7661
7662                git_patchset_body($fd, $diff_style,
7663                                  \@difftree, $hash,
7664                                  $use_parents ? @{$co{'parents'}} : $hash_parent);
7665                close $fd;
7666                print "</div>\n"; # class="page_body"
7667                git_footer_html();
7668
7669        } elsif ($format eq 'plain') {
7670                local $/ = undef;
7671                print <$fd>;
7672                close $fd
7673                        or print "Reading git-diff-tree failed\n";
7674        } elsif ($format eq 'patch') {
7675                local $/ = undef;
7676                print <$fd>;
7677                close $fd
7678                        or print "Reading git-format-patch failed\n";
7679        }
7680}
7681
7682sub git_commitdiff_plain {
7683        git_commitdiff(-format => 'plain');
7684}
7685
7686# format-patch-style patches
7687sub git_patch {
7688        git_commitdiff(-format => 'patch', -single => 1);
7689}
7690
7691sub git_patches {
7692        git_commitdiff(-format => 'patch');
7693}
7694
7695sub git_history {
7696        git_log_generic('history', \&git_history_body,
7697                        $hash_base, $hash_parent_base,
7698                        $file_name, $hash);
7699}
7700
7701sub git_search {
7702        $searchtype ||= 'commit';
7703
7704        # check if appropriate features are enabled
7705        gitweb_check_feature('search')
7706                or die_error(403, "Search is disabled");
7707        if ($searchtype eq 'pickaxe') {
7708                # pickaxe may take all resources of your box and run for several minutes
7709                # with every query - so decide by yourself how public you make this feature
7710                gitweb_check_feature('pickaxe')
7711                        or die_error(403, "Pickaxe search is disabled");
7712        }
7713        if ($searchtype eq 'grep') {
7714                # grep search might be potentially CPU-intensive, too
7715                gitweb_check_feature('grep')
7716                        or die_error(403, "Grep search is disabled");
7717        }
7718
7719        if (!defined $searchtext) {
7720                die_error(400, "Text field is empty");
7721        }
7722        if (!defined $hash) {
7723                $hash = git_get_head_hash($project);
7724        }
7725        my %co = parse_commit($hash);
7726        if (!%co) {
7727                die_error(404, "Unknown commit object");
7728        }
7729        if (!defined $page) {
7730                $page = 0;
7731        }
7732
7733        if ($searchtype eq 'commit' ||
7734            $searchtype eq 'author' ||
7735            $searchtype eq 'committer') {
7736                git_search_message(%co);
7737        } elsif ($searchtype eq 'pickaxe') {
7738                git_search_changes(%co);
7739        } elsif ($searchtype eq 'grep') {
7740                git_search_files(%co);
7741        } else {
7742                die_error(400, "Unknown search type");
7743        }
7744}
7745
7746sub git_search_help {
7747        git_header_html();
7748        git_print_page_nav('','', $hash,$hash,$hash);
7749        print <<EOT;
7750<p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7751regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7752the pattern entered is recognized as the POSIX extended
7753<a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7754insensitive).</p>
7755<dl>
7756<dt><b>commit</b></dt>
7757<dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7758EOT
7759        my $have_grep = gitweb_check_feature('grep');
7760        if ($have_grep) {
7761                print <<EOT;
7762<dt><b>grep</b></dt>
7763<dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7764    a different one) are searched for the given pattern. On large trees, this search can take
7765a while and put some strain on the server, so please use it with some consideration. Note that
7766due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7767case-sensitive.</dd>
7768EOT
7769        }
7770        print <<EOT;
7771<dt><b>author</b></dt>
7772<dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7773<dt><b>committer</b></dt>
7774<dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7775EOT
7776        my $have_pickaxe = gitweb_check_feature('pickaxe');
7777        if ($have_pickaxe) {
7778                print <<EOT;
7779<dt><b>pickaxe</b></dt>
7780<dd>All commits that caused the string to appear or disappear from any file (changes that
7781added, removed or "modified" the string) will be listed. This search can take a while and
7782takes a lot of strain on the server, so please use it wisely. Note that since you may be
7783interested even in changes just changing the case as well, this search is case sensitive.</dd>
7784EOT
7785        }
7786        print "</dl>\n";
7787        git_footer_html();
7788}
7789
7790sub git_shortlog {
7791        git_log_generic('shortlog', \&git_shortlog_body,
7792                        $hash, $hash_parent);
7793}
7794
7795## ......................................................................
7796## feeds (RSS, Atom; OPML)
7797
7798sub git_feed {
7799        my $format = shift || 'atom';
7800        my $have_blame = gitweb_check_feature('blame');
7801
7802        # Atom: http://www.atomenabled.org/developers/syndication/
7803        # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7804        if ($format ne 'rss' && $format ne 'atom') {
7805                die_error(400, "Unknown web feed format");
7806        }
7807
7808        # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7809        my $head = $hash || 'HEAD';
7810        my @commitlist = parse_commits($head, 150, 0, $file_name);
7811
7812        my %latest_commit;
7813        my %latest_date;
7814        my $content_type = "application/$format+xml";
7815        if (defined $cgi->http('HTTP_ACCEPT') &&
7816                 $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7817                # browser (feed reader) prefers text/xml
7818                $content_type = 'text/xml';
7819        }
7820        if (defined($commitlist[0])) {
7821                %latest_commit = %{$commitlist[0]};
7822                my $latest_epoch = $latest_commit{'committer_epoch'};
7823                %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7824                my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7825                if (defined $if_modified) {
7826                        my $since;
7827                        if (eval { require HTTP::Date; 1; }) {
7828                                $since = HTTP::Date::str2time($if_modified);
7829                        } elsif (eval { require Time::ParseDate; 1; }) {
7830                                $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7831                        }
7832                        if (defined $since && $latest_epoch <= $since) {
7833                                print $cgi->header(
7834                                        -type => $content_type,
7835                                        -charset => 'utf-8',
7836                                        -last_modified => $latest_date{'rfc2822'},
7837                                        -status => '304 Not Modified');
7838                                return;
7839                        }
7840                }
7841                print $cgi->header(
7842                        -type => $content_type,
7843                        -charset => 'utf-8',
7844                        -last_modified => $latest_date{'rfc2822'});
7845        } else {
7846                print $cgi->header(
7847                        -type => $content_type,
7848                        -charset => 'utf-8');
7849        }
7850
7851        # Optimization: skip generating the body if client asks only
7852        # for Last-Modified date.
7853        return if ($cgi->request_method() eq 'HEAD');
7854
7855        # header variables
7856        my $title = "$site_name - $project/$action";
7857        my $feed_type = 'log';
7858        if (defined $hash) {
7859                $title .= " - '$hash'";
7860                $feed_type = 'branch log';
7861                if (defined $file_name) {
7862                        $title .= " :: $file_name";
7863                        $feed_type = 'history';
7864                }
7865        } elsif (defined $file_name) {
7866                $title .= " - $file_name";
7867                $feed_type = 'history';
7868        }
7869        $title .= " $feed_type";
7870        my $descr = git_get_project_description($project);
7871        if (defined $descr) {
7872                $descr = esc_html($descr);
7873        } else {
7874                $descr = "$project " .
7875                         ($format eq 'rss' ? 'RSS' : 'Atom') .
7876                         " feed";
7877        }
7878        my $owner = git_get_project_owner($project);
7879        $owner = esc_html($owner);
7880
7881        #header
7882        my $alt_url;
7883        if (defined $file_name) {
7884                $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7885        } elsif (defined $hash) {
7886                $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7887        } else {
7888                $alt_url = href(-full=>1, action=>"summary");
7889        }
7890        print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7891        if ($format eq 'rss') {
7892                print <<XML;
7893<rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7894<channel>
7895XML
7896                print "<title>$title</title>\n" .
7897                      "<link>$alt_url</link>\n" .
7898                      "<description>$descr</description>\n" .
7899                      "<language>en</language>\n" .
7900                      # project owner is responsible for 'editorial' content
7901                      "<managingEditor>$owner</managingEditor>\n";
7902                if (defined $logo || defined $favicon) {
7903                        # prefer the logo to the favicon, since RSS
7904                        # doesn't allow both
7905                        my $img = esc_url($logo || $favicon);
7906                        print "<image>\n" .
7907                              "<url>$img</url>\n" .
7908                              "<title>$title</title>\n" .
7909                              "<link>$alt_url</link>\n" .
7910                              "</image>\n";
7911                }
7912                if (%latest_date) {
7913                        print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7914                        print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7915                }
7916                print "<generator>gitweb v.$version/$git_version</generator>\n";
7917        } elsif ($format eq 'atom') {
7918                print <<XML;
7919<feed xmlns="http://www.w3.org/2005/Atom">
7920XML
7921                print "<title>$title</title>\n" .
7922                      "<subtitle>$descr</subtitle>\n" .
7923                      '<link rel="alternate" type="text/html" href="' .
7924                      $alt_url . '" />' . "\n" .
7925                      '<link rel="self" type="' . $content_type . '" href="' .
7926                      $cgi->self_url() . '" />' . "\n" .
7927                      "<id>" . href(-full=>1) . "</id>\n" .
7928                      # use project owner for feed author
7929                      "<author><name>$owner</name></author>\n";
7930                if (defined $favicon) {
7931                        print "<icon>" . esc_url($favicon) . "</icon>\n";
7932                }
7933                if (defined $logo) {
7934                        # not twice as wide as tall: 72 x 27 pixels
7935                        print "<logo>" . esc_url($logo) . "</logo>\n";
7936                }
7937                if (! %latest_date) {
7938                        # dummy date to keep the feed valid until commits trickle in:
7939                        print "<updated>1970-01-01T00:00:00Z</updated>\n";
7940                } else {
7941                        print "<updated>$latest_date{'iso-8601'}</updated>\n";
7942                }
7943                print "<generator version='$version/$git_version'>gitweb</generator>\n";
7944        }
7945
7946        # contents
7947        for (my $i = 0; $i <= $#commitlist; $i++) {
7948                my %co = %{$commitlist[$i]};
7949                my $commit = $co{'id'};
7950                # we read 150, we always show 30 and the ones more recent than 48 hours
7951                if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7952                        last;
7953                }
7954                my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7955
7956                # get list of changed files
7957                open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7958                        $co{'parent'} || "--root",
7959                        $co{'id'}, "--", (defined $file_name ? $file_name : ())
7960                        or next;
7961                my @difftree = map { chomp; $_ } <$fd>;
7962                close $fd
7963                        or next;
7964
7965                # print element (entry, item)
7966                my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7967                if ($format eq 'rss') {
7968                        print "<item>\n" .
7969                              "<title>" . esc_html($co{'title'}) . "</title>\n" .
7970                              "<author>" . esc_html($co{'author'}) . "</author>\n" .
7971                              "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7972                              "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7973                              "<link>$co_url</link>\n" .
7974                              "<description>" . esc_html($co{'title'}) . "</description>\n" .
7975                              "<content:encoded>" .
7976                              "<![CDATA[\n";
7977                } elsif ($format eq 'atom') {
7978                        print "<entry>\n" .
7979                              "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7980                              "<updated>$cd{'iso-8601'}</updated>\n" .
7981                              "<author>\n" .
7982                              "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7983                        if ($co{'author_email'}) {
7984                                print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7985                        }
7986                        print "</author>\n" .
7987                              # use committer for contributor
7988                              "<contributor>\n" .
7989                              "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7990                        if ($co{'committer_email'}) {
7991                                print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7992                        }
7993                        print "</contributor>\n" .
7994                              "<published>$cd{'iso-8601'}</published>\n" .
7995                              "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7996                              "<id>$co_url</id>\n" .
7997                              "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7998                              "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7999                }
8000                my $comment = $co{'comment'};
8001                print "<pre>\n";
8002                foreach my $line (@$comment) {
8003                        $line = esc_html($line);
8004                        print "$line\n";
8005                }
8006                print "</pre><ul>\n";
8007                foreach my $difftree_line (@difftree) {
8008                        my %difftree = parse_difftree_raw_line($difftree_line);
8009                        next if !$difftree{'from_id'};
8010
8011                        my $file = $difftree{'file'} || $difftree{'to_file'};
8012
8013                        print "<li>" .
8014                              "[" .
8015                              $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8016                                                     hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8017                                                     hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8018                                                     file_name=>$file, file_parent=>$difftree{'from_file'}),
8019                                      -title => "diff"}, 'D');
8020                        if ($have_blame) {
8021                                print $cgi->a({-href => href(-full=>1, action=>"blame",
8022                                                             file_name=>$file, hash_base=>$commit),
8023                                              -title => "blame"}, 'B');
8024                        }
8025                        # if this is not a feed of a file history
8026                        if (!defined $file_name || $file_name ne $file) {
8027                                print $cgi->a({-href => href(-full=>1, action=>"history",
8028                                                             file_name=>$file, hash=>$commit),
8029                                              -title => "history"}, 'H');
8030                        }
8031                        $file = esc_path($file);
8032                        print "] ".
8033                              "$file</li>\n";
8034                }
8035                if ($format eq 'rss') {
8036                        print "</ul>]]>\n" .
8037                              "</content:encoded>\n" .
8038                              "</item>\n";
8039                } elsif ($format eq 'atom') {
8040                        print "</ul>\n</div>\n" .
8041                              "</content>\n" .
8042                              "</entry>\n";
8043                }
8044        }
8045
8046        # end of feed
8047        if ($format eq 'rss') {
8048                print "</channel>\n</rss>\n";
8049        } elsif ($format eq 'atom') {
8050                print "</feed>\n";
8051        }
8052}
8053
8054sub git_rss {
8055        git_feed('rss');
8056}
8057
8058sub git_atom {
8059        git_feed('atom');
8060}
8061
8062sub git_opml {
8063        my @list = git_get_projects_list($project_filter, $strict_export);
8064        if (!@list) {
8065                die_error(404, "No projects found");
8066        }
8067
8068        print $cgi->header(
8069                -type => 'text/xml',
8070                -charset => 'utf-8',
8071                -content_disposition => 'inline; filename="opml.xml"');
8072
8073        my $title = esc_html($site_name);
8074        my $filter = " within subdirectory ";
8075        if (defined $project_filter) {
8076                $filter .= esc_html($project_filter);
8077        } else {
8078                $filter = "";
8079        }
8080        print <<XML;
8081<?xml version="1.0" encoding="utf-8"?>
8082<opml version="1.0">
8083<head>
8084  <title>$title OPML Export$filter</title>
8085</head>
8086<body>
8087<outline text="git RSS feeds">
8088XML
8089
8090        foreach my $pr (@list) {
8091                my %proj = %$pr;
8092                my $head = git_get_head_hash($proj{'path'});
8093                if (!defined $head) {
8094                        next;
8095                }
8096                $git_dir = "$projectroot/$proj{'path'}";
8097                my %co = parse_commit($head);
8098                if (!%co) {
8099                        next;
8100                }
8101
8102                my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8103                my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8104                my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8105                print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8106        }
8107        print <<XML;
8108</outline>
8109</body>
8110</opml>
8111XML
8112}