Andrew's git / gitweb.git / git-difftool.perl
?
git-difftool.perlon commit log: teach --invert-grep option (22dfa8a)
   1#!/usr/bin/perl
   2# Copyright (c) 2009, 2010 David Aguilar
   3# Copyright (c) 2012 Tim Henigan
   4#
   5# This is a wrapper around the GIT_EXTERNAL_DIFF-compatible
   6# git-difftool--helper script.
   7#
   8# This script exports GIT_EXTERNAL_DIFF and GIT_PAGER for use by git.
   9# The GIT_DIFF* variables are exported for use by git-difftool--helper.
  10#
  11# Any arguments that are unknown to this script are forwarded to 'git diff'.
  12
  13use 5.008;
  14use strict;
  15use warnings;
  16use Error qw(:try);
  17use File::Basename qw(dirname);
  18use File::Copy;
  19use File::Find;
  20use File::stat;
  21use File::Path qw(mkpath rmtree);
  22use File::Temp qw(tempdir);
  23use Getopt::Long qw(:config pass_through);
  24use Git;
  25
  26sub usage
  27{
  28        my $exitcode = shift;
  29        print << 'USAGE';
  30usage: git difftool [-t|--tool=<tool>] [--tool-help]
  31                    [-x|--extcmd=<cmd>]
  32                    [-g|--gui] [--no-gui]
  33                    [--prompt] [-y|--no-prompt]
  34                    [-d|--dir-diff]
  35                    ['git diff' options]
  36USAGE
  37        exit($exitcode);
  38}
  39
  40sub find_worktree
  41{
  42        # Git->repository->wc_path() does not honor changes to the working
  43        # tree location made by $ENV{GIT_WORK_TREE} or the 'core.worktree'
  44        # config variable.
  45        return Git::command_oneline('rev-parse', '--show-toplevel');
  46}
  47
  48sub print_tool_help
  49{
  50        my $cmd = 'TOOL_MODE=diff';
  51        $cmd .= ' && . "$(git --exec-path)/git-mergetool--lib"';
  52        $cmd .= ' && show_tool_help';
  53
  54        # See the comment at the bottom of file_diff() for the reason behind
  55        # using system() followed by exit() instead of exec().
  56        my $rc = system('sh', '-c', $cmd);
  57        exit($rc | ($rc >> 8));
  58}
  59
  60sub exit_cleanup
  61{
  62        my ($tmpdir, $status) = @_;
  63        my $errno = $!;
  64        rmtree($tmpdir);
  65        if ($status and $errno) {
  66                my ($package, $file, $line) = caller();
  67                warn "$file line $line: $errno\n";
  68        }
  69        exit($status | ($status >> 8));
  70}
  71
  72sub use_wt_file
  73{
  74        my ($repo, $workdir, $file, $sha1) = @_;
  75        my $null_sha1 = '0' x 40;
  76
  77        if (! -e "$workdir/$file") {
  78                # If the file doesn't exist in the working tree, we cannot
  79                # use it.
  80                return (0, $null_sha1);
  81        }
  82
  83        my $wt_sha1 = $repo->command_oneline('hash-object', "$workdir/$file");
  84        my $use = ($sha1 eq $null_sha1) || ($sha1 eq $wt_sha1);
  85        return ($use, $wt_sha1);
  86}
  87
  88sub changed_files
  89{
  90        my ($repo_path, $index, $worktree) = @_;
  91        $ENV{GIT_INDEX_FILE} = $index;
  92        $ENV{GIT_WORK_TREE} = $worktree;
  93        my $must_unset_git_dir = 0;
  94        if (not defined($ENV{GIT_DIR})) {
  95                $must_unset_git_dir = 1;
  96                $ENV{GIT_DIR} = $repo_path;
  97        }
  98
  99        my @refreshargs = qw/update-index --really-refresh -q --unmerged/;
 100        my @gitargs = qw/diff-files --name-only -z/;
 101        try {
 102                Git::command_oneline(@refreshargs);
 103        } catch Git::Error::Command with {};
 104
 105        my $line = Git::command_oneline(@gitargs);
 106        my @files;
 107        if (defined $line) {
 108                @files = split('\0', $line);
 109        } else {
 110                @files = ();
 111        }
 112
 113        delete($ENV{GIT_INDEX_FILE});
 114        delete($ENV{GIT_WORK_TREE});
 115        delete($ENV{GIT_DIR}) if ($must_unset_git_dir);
 116
 117        return map { $_ => 1 } @files;
 118}
 119
 120sub setup_dir_diff
 121{
 122        my ($repo, $workdir, $symlinks) = @_;
 123
 124        # Run the diff; exit immediately if no diff found
 125        # 'Repository' and 'WorkingCopy' must be explicitly set to insure that
 126        # if $GIT_DIR and $GIT_WORK_TREE are set in ENV, they are actually used
 127        # by Git->repository->command*.
 128        my $repo_path = $repo->repo_path();
 129        my %repo_args = (Repository => $repo_path, WorkingCopy => $workdir);
 130        my $diffrepo = Git->repository(%repo_args);
 131
 132        my @gitargs = ('diff', '--raw', '--no-abbrev', '-z', @ARGV);
 133        my $diffrtn = $diffrepo->command_oneline(@gitargs);
 134        exit(0) unless defined($diffrtn);
 135
 136        # Build index info for left and right sides of the diff
 137        my $submodule_mode = '160000';
 138        my $symlink_mode = '120000';
 139        my $null_mode = '0' x 6;
 140        my $null_sha1 = '0' x 40;
 141        my $lindex = '';
 142        my $rindex = '';
 143        my $wtindex = '';
 144        my %submodule;
 145        my %symlink;
 146        my @working_tree = ();
 147        my @rawdiff = split('\0', $diffrtn);
 148
 149        my $i = 0;
 150        while ($i < $#rawdiff) {
 151                if ($rawdiff[$i] =~ /^::/) {
 152                        warn << 'EOF';
 153Combined diff formats ('-c' and '--cc') are not supported in
 154directory diff mode ('-d' and '--dir-diff').
 155EOF
 156                        exit(1);
 157                }
 158
 159                my ($lmode, $rmode, $lsha1, $rsha1, $status) =
 160                        split(' ', substr($rawdiff[$i], 1));
 161                my $src_path = $rawdiff[$i + 1];
 162                my $dst_path;
 163
 164                if ($status =~ /^[CR]/) {
 165                        $dst_path = $rawdiff[$i + 2];
 166                        $i += 3;
 167                } else {
 168                        $dst_path = $src_path;
 169                        $i += 2;
 170                }
 171
 172                if ($lmode eq $submodule_mode or $rmode eq $submodule_mode) {
 173                        $submodule{$src_path}{left} = $lsha1;
 174                        if ($lsha1 ne $rsha1) {
 175                                $submodule{$dst_path}{right} = $rsha1;
 176                        } else {
 177                                $submodule{$dst_path}{right} = "$rsha1-dirty";
 178                        }
 179                        next;
 180                }
 181
 182                if ($lmode eq $symlink_mode) {
 183                        $symlink{$src_path}{left} =
 184                                $diffrepo->command_oneline('show', "$lsha1");
 185                }
 186
 187                if ($rmode eq $symlink_mode) {
 188                        $symlink{$dst_path}{right} =
 189                                $diffrepo->command_oneline('show', "$rsha1");
 190                }
 191
 192                if ($lmode ne $null_mode and $status !~ /^C/) {
 193                        $lindex .= "$lmode $lsha1\t$src_path\0";
 194                }
 195
 196                if ($rmode ne $null_mode) {
 197                        my ($use, $wt_sha1) = use_wt_file($repo, $workdir,
 198                                                          $dst_path, $rsha1);
 199                        if ($use) {
 200                                push @working_tree, $dst_path;
 201                                $wtindex .= "$rmode $wt_sha1\t$dst_path\0";
 202                        } else {
 203                                $rindex .= "$rmode $rsha1\t$dst_path\0";
 204                        }
 205                }
 206        }
 207
 208        # Setup temp directories
 209        my $tmpdir = tempdir('git-difftool.XXXXX', CLEANUP => 0, TMPDIR => 1);
 210        my $ldir = "$tmpdir/left";
 211        my $rdir = "$tmpdir/right";
 212        mkpath($ldir) or exit_cleanup($tmpdir, 1);
 213        mkpath($rdir) or exit_cleanup($tmpdir, 1);
 214
 215        # If $GIT_DIR is not set prior to calling 'git update-index' and
 216        # 'git checkout-index', then those commands will fail if difftool
 217        # is called from a directory other than the repo root.
 218        my $must_unset_git_dir = 0;
 219        if (not defined($ENV{GIT_DIR})) {
 220                $must_unset_git_dir = 1;
 221                $ENV{GIT_DIR} = $repo_path;
 222        }
 223
 224        # Populate the left and right directories based on each index file
 225        my ($inpipe, $ctx);
 226        $ENV{GIT_INDEX_FILE} = "$tmpdir/lindex";
 227        ($inpipe, $ctx) =
 228                $repo->command_input_pipe(qw(update-index -z --index-info));
 229        print($inpipe $lindex);
 230        $repo->command_close_pipe($inpipe, $ctx);
 231
 232        my $rc = system('git', 'checkout-index', '--all', "--prefix=$ldir/");
 233        exit_cleanup($tmpdir, $rc) if $rc != 0;
 234
 235        $ENV{GIT_INDEX_FILE} = "$tmpdir/rindex";
 236        ($inpipe, $ctx) =
 237                $repo->command_input_pipe(qw(update-index -z --index-info));
 238        print($inpipe $rindex);
 239        $repo->command_close_pipe($inpipe, $ctx);
 240
 241        $rc = system('git', 'checkout-index', '--all', "--prefix=$rdir/");
 242        exit_cleanup($tmpdir, $rc) if $rc != 0;
 243
 244        $ENV{GIT_INDEX_FILE} = "$tmpdir/wtindex";
 245        ($inpipe, $ctx) =
 246                $repo->command_input_pipe(qw(update-index --info-only -z --index-info));
 247        print($inpipe $wtindex);
 248        $repo->command_close_pipe($inpipe, $ctx);
 249
 250        # If $GIT_DIR was explicitly set just for the update/checkout
 251        # commands, then it should be unset before continuing.
 252        delete($ENV{GIT_DIR}) if ($must_unset_git_dir);
 253        delete($ENV{GIT_INDEX_FILE});
 254
 255        # Changes in the working tree need special treatment since they are
 256        # not part of the index. Remove any trailing slash from $workdir
 257        # before starting to avoid double slashes in symlink targets.
 258        $workdir =~ s|/$||;
 259        for my $file (@working_tree) {
 260                my $dir = dirname($file);
 261                unless (-d "$rdir/$dir") {
 262                        mkpath("$rdir/$dir") or
 263                        exit_cleanup($tmpdir, 1);
 264                }
 265                if ($symlinks) {
 266                        symlink("$workdir/$file", "$rdir/$file") or
 267                        exit_cleanup($tmpdir, 1);
 268                } else {
 269                        copy("$workdir/$file", "$rdir/$file") or
 270                        exit_cleanup($tmpdir, 1);
 271
 272                        my $mode = stat("$workdir/$file")->mode;
 273                        chmod($mode, "$rdir/$file") or
 274                        exit_cleanup($tmpdir, 1);
 275                }
 276        }
 277
 278        # Changes to submodules require special treatment. This loop writes a
 279        # temporary file to both the left and right directories to show the
 280        # change in the recorded SHA1 for the submodule.
 281        for my $path (keys %submodule) {
 282                my $ok;
 283                if (defined($submodule{$path}{left})) {
 284                        $ok = write_to_file("$ldir/$path",
 285                                "Subproject commit $submodule{$path}{left}");
 286                }
 287                if (defined($submodule{$path}{right})) {
 288                        $ok = write_to_file("$rdir/$path",
 289                                "Subproject commit $submodule{$path}{right}");
 290                }
 291                exit_cleanup($tmpdir, 1) if not $ok;
 292        }
 293
 294        # Symbolic links require special treatment. The standard "git diff"
 295        # shows only the link itself, not the contents of the link target.
 296        # This loop replicates that behavior.
 297        for my $path (keys %symlink) {
 298                my $ok;
 299                if (defined($symlink{$path}{left})) {
 300                        $ok = write_to_file("$ldir/$path",
 301                                        $symlink{$path}{left});
 302                }
 303                if (defined($symlink{$path}{right})) {
 304                        $ok = write_to_file("$rdir/$path",
 305                                        $symlink{$path}{right});
 306                }
 307                exit_cleanup($tmpdir, 1) if not $ok;
 308        }
 309
 310        return ($ldir, $rdir, $tmpdir, @working_tree);
 311}
 312
 313sub write_to_file
 314{
 315        my $path = shift;
 316        my $value = shift;
 317
 318        # Make sure the path to the file exists
 319        my $dir = dirname($path);
 320        unless (-d "$dir") {
 321                mkpath("$dir") or return 0;
 322        }
 323
 324        # If the file already exists in that location, delete it.  This
 325        # is required in the case of symbolic links.
 326        unlink($path);
 327
 328        open(my $fh, '>', $path) or return 0;
 329        print($fh $value);
 330        close($fh);
 331
 332        return 1;
 333}
 334
 335sub main
 336{
 337        # parse command-line options. all unrecognized options and arguments
 338        # are passed through to the 'git diff' command.
 339        my %opts = (
 340                difftool_cmd => undef,
 341                dirdiff => undef,
 342                extcmd => undef,
 343                gui => undef,
 344                help => undef,
 345                prompt => undef,
 346                symlinks => $^O ne 'cygwin' &&
 347                                $^O ne 'MSWin32' && $^O ne 'msys',
 348                tool_help => undef,
 349        );
 350        GetOptions('g|gui!' => \$opts{gui},
 351                'd|dir-diff' => \$opts{dirdiff},
 352                'h' => \$opts{help},
 353                'prompt!' => \$opts{prompt},
 354                'y' => sub { $opts{prompt} = 0; },
 355                'symlinks' => \$opts{symlinks},
 356                'no-symlinks' => sub { $opts{symlinks} = 0; },
 357                't|tool:s' => \$opts{difftool_cmd},
 358                'tool-help' => \$opts{tool_help},
 359                'x|extcmd:s' => \$opts{extcmd});
 360
 361        if (defined($opts{help})) {
 362                usage(0);
 363        }
 364        if (defined($opts{tool_help})) {
 365                print_tool_help();
 366        }
 367        if (defined($opts{difftool_cmd})) {
 368                if (length($opts{difftool_cmd}) > 0) {
 369                        $ENV{GIT_DIFF_TOOL} = $opts{difftool_cmd};
 370                } else {
 371                        print "No <tool> given for --tool=<tool>\n";
 372                        usage(1);
 373                }
 374        }
 375        if (defined($opts{extcmd})) {
 376                if (length($opts{extcmd}) > 0) {
 377                        $ENV{GIT_DIFFTOOL_EXTCMD} = $opts{extcmd};
 378                } else {
 379                        print "No <cmd> given for --extcmd=<cmd>\n";
 380                        usage(1);
 381                }
 382        }
 383        if ($opts{gui}) {
 384                my $guitool = Git::config('diff.guitool');
 385                if (defined($guitool) && length($guitool) > 0) {
 386                        $ENV{GIT_DIFF_TOOL} = $guitool;
 387                }
 388        }
 389
 390        # In directory diff mode, 'git-difftool--helper' is called once
 391        # to compare the a/b directories.  In file diff mode, 'git diff'
 392        # will invoke a separate instance of 'git-difftool--helper' for
 393        # each file that changed.
 394        if (defined($opts{dirdiff})) {
 395                dir_diff($opts{extcmd}, $opts{symlinks});
 396        } else {
 397                file_diff($opts{prompt});
 398        }
 399}
 400
 401sub dir_diff
 402{
 403        my ($extcmd, $symlinks) = @_;
 404        my $rc;
 405        my $error = 0;
 406        my $repo = Git->repository();
 407        my $workdir = find_worktree();
 408        my ($a, $b, $tmpdir, @worktree) =
 409                setup_dir_diff($repo, $workdir, $symlinks);
 410
 411        if (defined($extcmd)) {
 412                $rc = system($extcmd, $a, $b);
 413        } else {
 414                $ENV{GIT_DIFFTOOL_DIRDIFF} = 'true';
 415                $rc = system('git', 'difftool--helper', $a, $b);
 416        }
 417        # If the diff including working copy files and those
 418        # files were modified during the diff, then the changes
 419        # should be copied back to the working tree.
 420        # Do not copy back files when symlinks are used and the
 421        # external tool did not replace the original link with a file.
 422        #
 423        # These hashes are loaded lazily since they aren't needed
 424        # in the common case of --symlinks and the difftool updating
 425        # files through the symlink.
 426        my %wt_modified;
 427        my %tmp_modified;
 428        my $indices_loaded = 0;
 429
 430        for my $file (@worktree) {
 431                next if $symlinks && -l "$b/$file";
 432                next if ! -f "$b/$file";
 433
 434                if (!$indices_loaded) {
 435                        %wt_modified = changed_files($repo->repo_path(),
 436                                "$tmpdir/wtindex", "$workdir");
 437                        %tmp_modified = changed_files($repo->repo_path(),
 438                                "$tmpdir/wtindex", "$b");
 439                        $indices_loaded = 1;
 440                }
 441
 442                if (exists $wt_modified{$file} and exists $tmp_modified{$file}) {
 443                        my $errmsg = "warning: Both files modified: ";
 444                        $errmsg .= "'$workdir/$file' and '$b/$file'.\n";
 445                        $errmsg .= "warning: Working tree file has been left.\n";
 446                        $errmsg .= "warning:\n";
 447                        warn $errmsg;
 448                        $error = 1;
 449                } elsif (exists $tmp_modified{$file}) {
 450                        my $mode = stat("$b/$file")->mode;
 451                        copy("$b/$file", "$workdir/$file") or
 452                        exit_cleanup($tmpdir, 1);
 453
 454                        chmod($mode, "$workdir/$file") or
 455                        exit_cleanup($tmpdir, 1);
 456                }
 457        }
 458        if ($error) {
 459                warn "warning: Temporary files exist in '$tmpdir'.\n";
 460                warn "warning: You may want to cleanup or recover these.\n";
 461                exit(1);
 462        } else {
 463                exit_cleanup($tmpdir, $rc);
 464        }
 465}
 466
 467sub file_diff
 468{
 469        my ($prompt) = @_;
 470
 471        if (defined($prompt)) {
 472                if ($prompt) {
 473                        $ENV{GIT_DIFFTOOL_PROMPT} = 'true';
 474                } else {
 475                        $ENV{GIT_DIFFTOOL_NO_PROMPT} = 'true';
 476                }
 477        }
 478
 479        $ENV{GIT_PAGER} = '';
 480        $ENV{GIT_EXTERNAL_DIFF} = 'git-difftool--helper';
 481
 482        # ActiveState Perl for Win32 does not implement POSIX semantics of
 483        # exec* system call. It just spawns the given executable and finishes
 484        # the starting program, exiting with code 0.
 485        # system will at least catch the errors returned by git diff,
 486        # allowing the caller of git difftool better handling of failures.
 487        my $rc = system('git', 'diff', @ARGV);
 488        exit($rc | ($rc >> 8));
 489}
 490
 491main();