Andrew's git / gitweb.git / configure.ac
?
configure.acon commit Change incorrect uses of "remote branch" meaning "remote-tracking" (29b9a66)
   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26# Optional second argument allows setting NO_PROGRAM=YesPlease if
  27# --without-PROGRAM version used.
  28AC_DEFUN([GIT_ARG_SET_PATH],
  29[AC_ARG_WITH([$1],
  30 [AS_HELP_STRING([--with-$1=PATH],
  31                 [provide PATH to $1])],
  32 [GIT_CONF_APPEND_PATH($1,$2)],[])
  33])# GIT_ARG_SET_PATH
  34#
  35# GIT_CONF_APPEND_PATH(PROGRAM)
  36# ------------------------------
  37# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  38# Used by GIT_ARG_SET_PATH(PROGRAM)
  39# Optional second argument allows setting NO_PROGRAM=YesPlease if
  40# --without-PROGRAM is used.
  41AC_DEFUN([GIT_CONF_APPEND_PATH],
  42[PROGRAM=m4_toupper($1); \
  43if test "$withval" = "no"; then \
  44        if test -n "$2"; then \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Disabling use of ${PROGRAM}]); \
  47                GIT_CONF_APPEND_LINE(NO_${PROGRAM}=YesPlease); \
  48                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=); \
  49        else \
  50                AC_MSG_ERROR([You cannot use git without $1]); \
  51        fi; \
  52else \
  53        if test "$withval" = "yes"; then \
  54                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  55        else \
  56                m4_toupper($1)_PATH=$withval; \
  57                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  58                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  59        fi; \
  60fi; \
  61]) # GIT_CONF_APPEND_PATH
  62#
  63# GIT_PARSE_WITH(PACKAGE)
  64# -----------------------
  65# For use in AC_ARG_WITH action-if-found, for packages default ON.
  66# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  67# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  68# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  69AC_DEFUN([GIT_PARSE_WITH],
  70[PACKAGE=m4_toupper($1); \
  71if test "$withval" = "no"; then \
  72        m4_toupper(NO_$1)=YesPlease; \
  73elif test "$withval" = "yes"; then \
  74        m4_toupper(NO_$1)=; \
  75else \
  76        m4_toupper(NO_$1)=; \
  77        m4_toupper($1)DIR=$withval; \
  78        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  79        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  80fi \
  81])# GIT_PARSE_WITH
  82#
  83# GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  84# ---------------------
  85# Set VAR to the value specied by --with-WITHNAME.
  86# No verification of arguments is performed, but warnings are issued
  87# if either 'yes' or 'no' is specified.
  88# HELP_TEXT is presented when --help is called.
  89# This is a direct way to allow setting variables in the Makefile.
  90AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  91[AC_ARG_WITH([$1],
  92 [AS_HELP_STRING([--with-$1=VALUE], $3)],
  93 if test -n "$withval"; then \
  94  if test "$withval" = "yes" -o "$withval" = "no"; then \
  95    AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  96                     [a value for $1 ($2).  Maybe you do...?]); \
  97  fi; \
  98  \
  99  AC_MSG_NOTICE([Setting $2 to $withval]); \
 100  GIT_CONF_APPEND_LINE($2=$withval); \
 101 fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 102
 103dnl
 104dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 105dnl -----------------------------------------
 106dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
 107dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
 108dnl -Wall), it does not work.  By looking for function definition in
 109dnl libraries, this problem can be worked around.
 110AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 111  AC_SEARCH_LIBS([$1],,
 112  [$2],[$3])
 113],[$3])])
 114
 115dnl
 116dnl GIT_STASH_FLAGS(BASEPATH_VAR)
 117dnl -----------------------------
 118dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 119dnl tests that may want to take user settings into account.
 120AC_DEFUN([GIT_STASH_FLAGS],[
 121if test -n "$1"; then
 122   old_CPPFLAGS="$CPPFLAGS"
 123   old_LDFLAGS="$LDFLAGS"
 124   CPPFLAGS="-I$1/include $CPPFLAGS"
 125   LDFLAGS="-L$1/$lib $LDFLAGS"
 126fi
 127])
 128
 129dnl
 130dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 131dnl -----------------------------
 132dnl Restore the stashed *FLAGS values.
 133AC_DEFUN([GIT_UNSTASH_FLAGS],[
 134if test -n "$1"; then
 135   CPPFLAGS="$old_CPPFLAGS"
 136   LDFLAGS="$old_LDFLAGS"
 137fi
 138])
 139
 140## Site configuration related to programs (before tests)
 141## --with-PACKAGE[=ARG] and --without-PACKAGE
 142#
 143# Set lib to alternative name of lib directory (e.g. lib64)
 144AC_ARG_WITH([lib],
 145 [AS_HELP_STRING([--with-lib=ARG],
 146                 [ARG specifies alternative name for lib directory])],
 147 [if test "$withval" = "no" || test "$withval" = "yes"; then \
 148        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 149else \
 150        lib=$withval; \
 151        AC_MSG_NOTICE([Setting lib to '$lib']); \
 152        GIT_CONF_APPEND_LINE(lib=$withval); \
 153fi; \
 154],[])
 155
 156if test -z "$lib"; then
 157   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 158   lib=lib
 159fi
 160
 161AC_ARG_ENABLE([pthreads],
 162 [AS_HELP_STRING([--enable-pthreads=FLAGS],
 163  [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 164  [The default if FLAGS is not specified is to try first -pthread]
 165  [and then -lpthread.]
 166  [--without-pthreads will disable threading.])],
 167[
 168if test "x$enableval" = "xyes"; then
 169   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 170elif test "x$enableval" != "xno"; then
 171   PTHREAD_CFLAGS=$enableval
 172   AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 173else
 174   AC_MSG_NOTICE([POSIX Threads will be disabled.])
 175   NO_PTHREADS=YesPlease
 176   USER_NOPTHREAD=1
 177fi],
 178[
 179   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 180])
 181
 182# Define option to enable JavaScript minification
 183AC_ARG_ENABLE([jsmin],
 184[AS_HELP_STRING([--enable-jsmin=PATH],
 185  [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 186[
 187  JSMIN=$enableval;
 188  AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 189  GIT_CONF_APPEND_LINE(JSMIN=$enableval);
 190])
 191
 192# Define option to enable CSS minification
 193AC_ARG_ENABLE([cssmin],
 194[AS_HELP_STRING([--enable-cssmin=PATH],
 195  [PATH is the name of a CSS minifier or the absolute path to one.])],
 196[
 197  CSSMIN=$enableval;
 198  AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 199  GIT_CONF_APPEND_LINE(CSSMIN=$enableval);
 200])
 201
 202## Site configuration (override autodetection)
 203## --with-PACKAGE[=ARG] and --without-PACKAGE
 204AC_MSG_NOTICE([CHECKS for site configuration])
 205#
 206# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 207# tests.  These tests take up a significant amount of the total test time
 208# but are not needed unless you plan to talk to SVN repos.
 209#
 210# Define PPC_SHA1 environment variable when running make to make use of
 211# a bundled SHA1 routine optimized for PowerPC.
 212#
 213# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 214# This also implies BLK_SHA1.
 215#
 216# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 217# /foo/bar/include and /foo/bar/lib directories.
 218AC_ARG_WITH(openssl,
 219AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 220AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 221GIT_PARSE_WITH(openssl))
 222#
 223# Define NO_CURL if you do not have curl installed.  git-http-pull and
 224# git-http-push are not built, and you cannot use http:// and https://
 225# transports.
 226#
 227# Define CURLDIR=/foo/bar if your curl header and library files are in
 228# /foo/bar/include and /foo/bar/lib directories.
 229AC_ARG_WITH(curl,
 230AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 231AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 232GIT_PARSE_WITH(curl))
 233#
 234# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 235# not built, and you cannot push using http:// and https:// transports.
 236#
 237# Define EXPATDIR=/foo/bar if your expat header and library files are in
 238# /foo/bar/include and /foo/bar/lib directories.
 239AC_ARG_WITH(expat,
 240AS_HELP_STRING([--with-expat],
 241[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 242AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 243GIT_PARSE_WITH(expat))
 244#
 245# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 246# installed in /sw, but don't want GIT to link against any libraries
 247# installed there.  If defined you may specify your own (or Fink's)
 248# include directories and library directories by defining CFLAGS
 249# and LDFLAGS appropriately.
 250#
 251# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 252# have DarwinPorts installed in /opt/local, but don't want GIT to
 253# link against any libraries installed there.  If defined you may
 254# specify your own (or DarwinPort's) include directories and
 255# library directories by defining CFLAGS and LDFLAGS appropriately.
 256#
 257# Define NO_MMAP if you want to avoid mmap.
 258#
 259# Define NO_ICONV if your libc does not properly support iconv.
 260AC_ARG_WITH(iconv,
 261AS_HELP_STRING([--without-iconv],
 262[if your architecture doesn't properly support iconv])
 263AS_HELP_STRING([--with-iconv=PATH],
 264[PATH is prefix for libiconv library and headers])
 265AS_HELP_STRING([],
 266[used only if you need linking with libiconv]),
 267GIT_PARSE_WITH(iconv))
 268
 269## --enable-FEATURE[=ARG] and --disable-FEATURE
 270#
 271# Define USE_NSEC below if you want git to care about sub-second file mtimes
 272# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 273# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 274# randomly break unless your underlying filesystem supports those sub-second
 275# times (my ext3 doesn't).
 276#
 277# Define USE_STDEV below if you want git to care about the underlying device
 278# change being considered an inode change from the update-index perspective.
 279
 280#
 281# Allow user to set ETC_GITCONFIG variable
 282GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 283                        Use VALUE instead of /etc/gitconfig as the
 284                        global git configuration file.
 285                        If VALUE is not fully qualified it will be interpreted
 286                        as a path relative to the computed prefix at runtime.)
 287
 288#
 289# Allow user to set ETC_GITATTRIBUTES variable
 290GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 291                        Use VALUE instead of /etc/gitattributes as the
 292                        global git attributes file.
 293                        If VALUE is not fully qualified it will be interpreted
 294                        as a path relative to the computed prefix at runtime.)
 295
 296#
 297# Allow user to set the default pager
 298GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 299                        Use VALUE as the fall-back pager instead of 'less'.
 300                        This is used by things like 'git log' when the user
 301                        does not specify a pager to use through alternate
 302                        methods. eg: /usr/bin/pager)
 303#
 304# Allow user to set the default editor
 305GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 306                        Use VALUE as the fall-back editor instead of 'vi'.
 307                        This is used by things like 'git commit' when the user
 308                        does not specify a preferred editor through other
 309                        methods. eg: /usr/bin/editor)
 310
 311#
 312# Define SHELL_PATH to provide path to shell.
 313GIT_ARG_SET_PATH(shell)
 314#
 315# Define PERL_PATH to provide path to Perl.
 316GIT_ARG_SET_PATH(perl)
 317#
 318# Define PYTHON_PATH to provide path to Python.
 319GIT_ARG_SET_PATH(python, allow-without)
 320#
 321# Define ZLIB_PATH to provide path to zlib.
 322GIT_ARG_SET_PATH(zlib)
 323#
 324# Declare the with-tcltk/without-tcltk options.
 325AC_ARG_WITH(tcltk,
 326AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 327AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 328AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 329AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 330GIT_PARSE_WITH(tcltk))
 331#
 332
 333
 334## Checks for programs.
 335AC_MSG_NOTICE([CHECKS for programs])
 336#
 337AC_PROG_CC([cc gcc])
 338AC_C_INLINE
 339case $ac_cv_c_inline in
 340  inline | yes | no)    ;;
 341  *)                    AC_SUBST([INLINE], [$ac_cv_c_inline]) ;;
 342esac
 343
 344# which switch to pass runtime path to dynamic libraries to the linker
 345AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 346   SAVE_LDFLAGS="${LDFLAGS}"
 347   LDFLAGS="${SAVE_LDFLAGS} -R /"
 348   AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 349   LDFLAGS="${SAVE_LDFLAGS}"
 350])
 351if test "$git_cv_ld_dashr" = "yes"; then
 352   AC_SUBST(CC_LD_DYNPATH, [-R])
 353else
 354   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 355      SAVE_LDFLAGS="${LDFLAGS}"
 356      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 357      AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 358      LDFLAGS="${SAVE_LDFLAGS}"
 359   ])
 360   if test "$git_cv_ld_wl_rpath" = "yes"; then
 361      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 362   else
 363      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 364         SAVE_LDFLAGS="${LDFLAGS}"
 365         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 366         AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 367         LDFLAGS="${SAVE_LDFLAGS}"
 368      ])
 369      if test "$git_cv_ld_rpath" = "yes"; then
 370         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 371      else
 372         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 373      fi
 374   fi
 375fi
 376#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 377AC_CHECK_TOOLS(AR, [gar ar], :)
 378AC_CHECK_PROGS(TAR, [gtar tar])
 379AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 380# TCLTK_PATH will be set to some value if we want Tcl/Tk
 381# or will be empty otherwise.
 382if test -z "$NO_TCLTK"; then
 383  if test "$with_tcltk" = ""; then
 384  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 385    TCLTK_PATH=wish
 386    AC_SUBST(TCLTK_PATH)
 387  elif test "$with_tcltk" = "yes"; then
 388  # Tcl/Tk check requested.
 389    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 390  else
 391    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 392    TCLTK_PATH="$with_tcltk"
 393    AC_SUBST(TCLTK_PATH)
 394  fi
 395fi
 396AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 397if test -n "$ASCIIDOC"; then
 398        AC_MSG_CHECKING([for asciidoc version])
 399        asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 400        case "${asciidoc_version}" in
 401        asciidoc' '8*)
 402                ASCIIDOC8=YesPlease
 403                AC_MSG_RESULT([${asciidoc_version} > 7])
 404                ;;
 405        asciidoc' '7*)
 406                ASCIIDOC8=
 407                AC_MSG_RESULT([${asciidoc_version}])
 408                ;;
 409        *)
 410                ASCIIDOC8=
 411                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 412                ;;
 413        esac
 414fi
 415AC_SUBST(ASCIIDOC8)
 416
 417
 418## Checks for libraries.
 419AC_MSG_NOTICE([CHECKS for libraries])
 420#
 421# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 422# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 423
 424GIT_STASH_FLAGS($OPENSSLDIR)
 425
 426AC_CHECK_LIB([crypto], [SHA1_Init],
 427[NEEDS_SSL_WITH_CRYPTO=],
 428[AC_CHECK_LIB([ssl], [SHA1_Init],
 429 [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 430 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 431
 432GIT_UNSTASH_FLAGS($OPENSSLDIR)
 433
 434AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 435AC_SUBST(NO_OPENSSL)
 436
 437#
 438# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 439# git-http-push are not built, and you cannot use http:// and https://
 440# transports.
 441
 442GIT_STASH_FLAGS($CURLDIR)
 443
 444AC_CHECK_LIB([curl], [curl_global_init],
 445[NO_CURL=],
 446[NO_CURL=YesPlease])
 447
 448GIT_UNSTASH_FLAGS($CURLDIR)
 449
 450AC_SUBST(NO_CURL)
 451
 452#
 453# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 454# not built, and you cannot push using http:// and https:// transports.
 455
 456GIT_STASH_FLAGS($EXPATDIR)
 457
 458AC_CHECK_LIB([expat], [XML_ParserCreate],
 459[NO_EXPAT=],
 460[NO_EXPAT=YesPlease])
 461
 462GIT_UNSTASH_FLAGS($EXPATDIR)
 463
 464AC_SUBST(NO_EXPAT)
 465
 466#
 467# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 468# some Solaris installations).
 469# Define NO_ICONV if neither libc nor libiconv support iconv.
 470
 471if test -z "$NO_ICONV"; then
 472
 473GIT_STASH_FLAGS($ICONVDIR)
 474
 475AC_DEFUN([ICONVTEST_SRC], [
 476#include <iconv.h>
 477
 478int main(void)
 479{
 480        iconv_open("", "");
 481        return 0;
 482}
 483])
 484
 485if test -n "$ICONVDIR"; then
 486   lib_order="-liconv -lc"
 487else
 488   lib_order="-lc -liconv"
 489fi
 490
 491NO_ICONV=YesPlease
 492
 493for l in $lib_order; do
 494    if test "$l" = "-liconv"; then
 495       NEEDS_LIBICONV=YesPlease
 496    else
 497       NEEDS_LIBICONV=
 498    fi
 499
 500    old_LIBS="$LIBS"
 501    LIBS="$LIBS $l"
 502    AC_MSG_CHECKING([for iconv in $l])
 503    AC_LINK_IFELSE(ICONVTEST_SRC,
 504        [AC_MSG_RESULT([yes])
 505        NO_ICONV=
 506        break],
 507        [AC_MSG_RESULT([no])])
 508    LIBS="$old_LIBS"
 509done
 510
 511#in case of break
 512LIBS="$old_LIBS"
 513
 514GIT_UNSTASH_FLAGS($ICONVDIR)
 515
 516AC_SUBST(NEEDS_LIBICONV)
 517AC_SUBST(NO_ICONV)
 518
 519if test -n "$NO_ICONV"; then
 520    NEEDS_LIBICONV=
 521fi
 522
 523fi
 524
 525#
 526# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 527
 528GIT_STASH_FLAGS($ZLIB_PATH)
 529
 530AC_DEFUN([ZLIBTEST_SRC], [
 531#include <zlib.h>
 532
 533int main(void)
 534{
 535        deflateBound(0, 0);
 536        return 0;
 537}
 538])
 539AC_MSG_CHECKING([for deflateBound in -lz])
 540old_LIBS="$LIBS"
 541LIBS="$LIBS -lz"
 542AC_LINK_IFELSE(ZLIBTEST_SRC,
 543        [AC_MSG_RESULT([yes])],
 544        [AC_MSG_RESULT([no])
 545        NO_DEFLATE_BOUND=yes])
 546LIBS="$old_LIBS"
 547
 548GIT_UNSTASH_FLAGS($ZLIB_PATH)
 549
 550AC_SUBST(NO_DEFLATE_BOUND)
 551
 552#
 553# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 554# Patrick Mauritz).
 555AC_CHECK_LIB([c], [socket],
 556[NEEDS_SOCKET=],
 557[NEEDS_SOCKET=YesPlease])
 558AC_SUBST(NEEDS_SOCKET)
 559test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 560
 561#
 562# The next few tests will define NEEDS_RESOLV if linking with
 563# libresolv provides some of the functions we would normally get
 564# from libc.
 565NEEDS_RESOLV=
 566AC_SUBST(NEEDS_RESOLV)
 567#
 568# Define NO_INET_NTOP if linking with -lresolv is not enough.
 569# Solaris 2.7 in particular hos inet_ntop in -lresolv.
 570NO_INET_NTOP=
 571AC_SUBST(NO_INET_NTOP)
 572AC_CHECK_FUNC([inet_ntop],
 573        [],
 574    [AC_CHECK_LIB([resolv], [inet_ntop],
 575            [NEEDS_RESOLV=YesPlease],
 576        [NO_INET_NTOP=YesPlease])
 577])
 578#
 579# Define NO_INET_PTON if linking with -lresolv is not enough.
 580# Solaris 2.7 in particular hos inet_pton in -lresolv.
 581NO_INET_PTON=
 582AC_SUBST(NO_INET_PTON)
 583AC_CHECK_FUNC([inet_pton],
 584        [],
 585    [AC_CHECK_LIB([resolv], [inet_pton],
 586            [NEEDS_RESOLV=YesPlease],
 587        [NO_INET_PTON=YesPlease])
 588])
 589#
 590# Define NO_HSTRERROR if linking with -lresolv is not enough.
 591# Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 592NO_HSTRERROR=
 593AC_CHECK_FUNC([hstrerror],
 594        [],
 595    [AC_CHECK_LIB([resolv], [hstrerror],
 596            [NEEDS_RESOLV=YesPlease],
 597        [NO_HSTRERROR=YesPlease])
 598])
 599AC_SUBST(NO_HSTRERROR)
 600#
 601# If any of the above tests determined that -lresolv is needed at
 602# build-time, also set it here for remaining configure-time checks.
 603test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 604
 605AC_CHECK_LIB([c], [basename],
 606[NEEDS_LIBGEN=],
 607[NEEDS_LIBGEN=YesPlease])
 608AC_SUBST(NEEDS_LIBGEN)
 609test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 610
 611## Checks for header files.
 612AC_MSG_NOTICE([CHECKS for header files])
 613#
 614# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 615AC_CHECK_HEADER([sys/select.h],
 616[NO_SYS_SELECT_H=],
 617[NO_SYS_SELECT_H=UnfortunatelyYes])
 618AC_SUBST(NO_SYS_SELECT_H)
 619#
 620# Define OLD_ICONV if your library has an old iconv(), where the second
 621# (input buffer pointer) parameter is declared with type (const char **).
 622AC_DEFUN([OLDICONVTEST_SRC], [[
 623#include <iconv.h>
 624
 625extern size_t iconv(iconv_t cd,
 626                    char **inbuf, size_t *inbytesleft,
 627                    char **outbuf, size_t *outbytesleft);
 628
 629int main(void)
 630{
 631        return 0;
 632}
 633]])
 634
 635GIT_STASH_FLAGS($ICONVDIR)
 636
 637AC_MSG_CHECKING([for old iconv()])
 638AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 639        [AC_MSG_RESULT([no])],
 640        [AC_MSG_RESULT([yes])
 641        OLD_ICONV=UnfortunatelyYes])
 642
 643GIT_UNSTASH_FLAGS($ICONVDIR)
 644
 645AC_SUBST(OLD_ICONV)
 646
 647## Checks for typedefs, structures, and compiler characteristics.
 648AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 649#
 650TYPE_SOCKLEN_T
 651case $ac_cv_type_socklen_t in
 652  yes)  ;;
 653  *)    AC_SUBST([SOCKLEN_T], [$git_cv_socklen_t_equiv]) ;;
 654esac
 655
 656# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 657AC_CHECK_MEMBER(struct dirent.d_ino,
 658[NO_D_INO_IN_DIRENT=],
 659[NO_D_INO_IN_DIRENT=YesPlease],
 660[#include <dirent.h>])
 661AC_SUBST(NO_D_INO_IN_DIRENT)
 662#
 663# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 664# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 665AC_CHECK_MEMBER(struct dirent.d_type,
 666[NO_D_TYPE_IN_DIRENT=],
 667[NO_D_TYPE_IN_DIRENT=YesPlease],
 668[#include <dirent.h>])
 669AC_SUBST(NO_D_TYPE_IN_DIRENT)
 670#
 671# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 672# sockaddr_storage.
 673AC_CHECK_TYPE(struct sockaddr_storage,
 674[NO_SOCKADDR_STORAGE=],
 675[NO_SOCKADDR_STORAGE=YesPlease],[
 676#include <sys/types.h>
 677#include <sys/socket.h>
 678])
 679AC_SUBST(NO_SOCKADDR_STORAGE)
 680#
 681# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 682AC_CHECK_TYPE([struct addrinfo],[
 683 GIT_CHECK_FUNC([getaddrinfo],
 684  [NO_IPV6=],
 685  [NO_IPV6=YesPlease])
 686],[NO_IPV6=YesPlease],[
 687#include <sys/types.h>
 688#include <sys/socket.h>
 689#include <netdb.h>
 690])
 691AC_SUBST(NO_IPV6)
 692#
 693# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 694# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 695# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 696# some C compilers supported these specifiers prior to C99 as an extension.
 697AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 698 [ac_cv_c_c99_format],
 699[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 700AC_RUN_IFELSE(
 701        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 702                [[char buf[64];
 703                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 704                  return 1;
 705                else if (strcmp(buf, "12345"))
 706                  return 2;]])],
 707        [ac_cv_c_c99_format=yes],
 708        [ac_cv_c_c99_format=no])
 709])
 710if test $ac_cv_c_c99_format = no; then
 711        NO_C99_FORMAT=YesPlease
 712else
 713        NO_C99_FORMAT=
 714fi
 715AC_SUBST(NO_C99_FORMAT)
 716#
 717# Define NO_REGEX if you have no or inferior regex support in your C library.
 718AC_CACHE_CHECK([whether the platform regex can handle null bytes],
 719 [ac_cv_c_excellent_regex], [
 720AC_EGREP_CPP(yippeeyeswehaveit,
 721        AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 722#include <regex.h>
 723],
 724[#ifdef REG_STARTEND
 725yippeeyeswehaveit
 726#endif
 727]),
 728        [ac_cv_c_excellent_regex=yes],
 729        [ac_cv_c_excellent_regex=no])
 730])
 731if test $ac_cv_c_excellent_regex = yes; then
 732        NO_REGEX=
 733else
 734        NO_REGEX=YesPlease
 735fi
 736AC_SUBST(NO_REGEX)
 737#
 738# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 739# when attempting to read from an fopen'ed directory.
 740AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 741 [ac_cv_fread_reads_directories],
 742[
 743AC_RUN_IFELSE(
 744        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 745                [[char c;
 746                FILE *f = fopen(".", "r");
 747                return f && fread(&c, 1, 1, f)]])],
 748        [ac_cv_fread_reads_directories=no],
 749        [ac_cv_fread_reads_directories=yes])
 750])
 751if test $ac_cv_fread_reads_directories = yes; then
 752        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 753else
 754        FREAD_READS_DIRECTORIES=
 755fi
 756AC_SUBST(FREAD_READS_DIRECTORIES)
 757#
 758# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 759# or vsnprintf() return -1 instead of number of characters which would
 760# have been written to the final string if enough space had been available.
 761AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 762 [ac_cv_snprintf_returns_bogus],
 763[
 764AC_RUN_IFELSE(
 765        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 766                #include "stdarg.h"
 767
 768                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 769                {
 770                  int ret;
 771                  va_list ap;
 772                  va_start(ap, format);
 773                  ret = vsnprintf(str, maxsize, format, ap);
 774                  va_end(ap);
 775                  return ret;
 776                }],
 777                [[char buf[6];
 778                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 779                      || strcmp(buf, "12")) return 1;
 780                  if (snprintf(buf, 3, "%s", "12345") != 5
 781                      || strcmp(buf, "12")) return 1]])],
 782        [ac_cv_snprintf_returns_bogus=no],
 783        [ac_cv_snprintf_returns_bogus=yes])
 784])
 785if test $ac_cv_snprintf_returns_bogus = yes; then
 786        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 787else
 788        SNPRINTF_RETURNS_BOGUS=
 789fi
 790AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 791
 792
 793## Checks for library functions.
 794## (in default C library and libraries checked by AC_CHECK_LIB)
 795AC_MSG_NOTICE([CHECKS for library functions])
 796#
 797# Define NO_LIBGEN_H if you don't have libgen.h.
 798AC_CHECK_HEADER([libgen.h],
 799[NO_LIBGEN_H=],
 800[NO_LIBGEN_H=YesPlease])
 801AC_SUBST(NO_LIBGEN_H)
 802#
 803# Define HAVE_PATHS_H if you have paths.h.
 804AC_CHECK_HEADER([paths.h],
 805[HAVE_PATHS_H=YesPlease],
 806[HAVE_PATHS_H=])
 807AC_SUBST(HAVE_PATHS_H)
 808#
 809# Define NO_STRCASESTR if you don't have strcasestr.
 810GIT_CHECK_FUNC(strcasestr,
 811[NO_STRCASESTR=],
 812[NO_STRCASESTR=YesPlease])
 813AC_SUBST(NO_STRCASESTR)
 814#
 815# Define NO_STRTOK_R if you don't have strtok_r
 816GIT_CHECK_FUNC(strtok_r,
 817[NO_STRTOK_R=],
 818[NO_STRTOK_R=YesPlease])
 819AC_SUBST(NO_STRTOK_R)
 820#
 821# Define NO_MEMMEM if you don't have memmem.
 822GIT_CHECK_FUNC(memmem,
 823[NO_MEMMEM=],
 824[NO_MEMMEM=YesPlease])
 825AC_SUBST(NO_MEMMEM)
 826#
 827# Define NO_STRLCPY if you don't have strlcpy.
 828GIT_CHECK_FUNC(strlcpy,
 829[NO_STRLCPY=],
 830[NO_STRLCPY=YesPlease])
 831AC_SUBST(NO_STRLCPY)
 832#
 833# Define NO_UINTMAX_T if your platform does not have uintmax_t
 834AC_CHECK_TYPE(uintmax_t,
 835[NO_UINTMAX_T=],
 836[NO_UINTMAX_T=YesPlease],[
 837#include <inttypes.h>
 838])
 839AC_SUBST(NO_UINTMAX_T)
 840#
 841# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 842GIT_CHECK_FUNC(strtoumax,
 843[NO_STRTOUMAX=],
 844[NO_STRTOUMAX=YesPlease])
 845AC_SUBST(NO_STRTOUMAX)
 846#
 847# Define NO_SETENV if you don't have setenv in the C library.
 848GIT_CHECK_FUNC(setenv,
 849[NO_SETENV=],
 850[NO_SETENV=YesPlease])
 851AC_SUBST(NO_SETENV)
 852#
 853# Define NO_UNSETENV if you don't have unsetenv in the C library.
 854GIT_CHECK_FUNC(unsetenv,
 855[NO_UNSETENV=],
 856[NO_UNSETENV=YesPlease])
 857AC_SUBST(NO_UNSETENV)
 858#
 859# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 860GIT_CHECK_FUNC(mkdtemp,
 861[NO_MKDTEMP=],
 862[NO_MKDTEMP=YesPlease])
 863AC_SUBST(NO_MKDTEMP)
 864#
 865# Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 866GIT_CHECK_FUNC(mkstemps,
 867[NO_MKSTEMPS=],
 868[NO_MKSTEMPS=YesPlease])
 869AC_SUBST(NO_MKSTEMPS)
 870#
 871#
 872# Define NO_MMAP if you want to avoid mmap.
 873#
 874# Define NO_ICONV if your libc does not properly support iconv.
 875
 876
 877## Other checks.
 878# Define USE_PIC if you need the main git objects to be built with -fPIC
 879# in order to build and link perl/Git.so.  x86-64 seems to need this.
 880#
 881# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 882# Enable it on Windows.  By default, symrefs are still used.
 883#
 884# Define NO_PTHREADS if we do not have pthreads.
 885#
 886# Define PTHREAD_LIBS to the linker flag used for Pthread support.
 887AC_DEFUN([PTHREADTEST_SRC], [
 888#include <pthread.h>
 889
 890int main(void)
 891{
 892        pthread_mutex_t test_mutex;
 893        int retcode = 0;
 894        retcode |= pthread_mutex_init(&test_mutex,(void *)0);
 895        retcode |= pthread_mutex_lock(&test_mutex);
 896        retcode |= pthread_mutex_unlock(&test_mutex);
 897        return retcode;
 898}
 899])
 900
 901dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 902dnl   [[#include <pthread.h>]],
 903dnl   [[pthread_mutex_t test_mutex;]]
 904dnl )])
 905
 906NO_PTHREADS=UnfortunatelyYes
 907PTHREAD_LIBS=
 908
 909if test -n "$USER_NOPTHREAD"; then
 910   AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 911# handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 912# -D_REENTRANT' or some such.
 913elif test -z "$PTHREAD_CFLAGS"; then
 914  threads_found=no
 915  for opt in -mt -pthread -lpthread; do
 916     old_CFLAGS="$CFLAGS"
 917     CFLAGS="$opt $CFLAGS"
 918     AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 919     AC_LINK_IFELSE(PTHREADTEST_SRC,
 920        [AC_MSG_RESULT([yes])
 921                NO_PTHREADS=
 922                PTHREAD_LIBS="$opt"
 923                PTHREAD_CFLAGS="$opt"
 924                threads_found=yes
 925                break
 926        ],
 927        [AC_MSG_RESULT([no])])
 928      CFLAGS="$old_CFLAGS"
 929  done
 930  if test $threads_found != yes; then
 931    AC_CHECK_LIB([pthread], [pthread_create],
 932        [PTHREAD_LIBS="-lpthread"],
 933        [NO_PTHREADS=UnfortunatelyYes])
 934  fi
 935else
 936  old_CFLAGS="$CFLAGS"
 937  CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 938  AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 939  AC_LINK_IFELSE(PTHREADTEST_SRC,
 940        [AC_MSG_RESULT([yes])
 941                NO_PTHREADS=
 942                PTHREAD_LIBS="$PTHREAD_CFLAGS"
 943        ],
 944        [AC_MSG_RESULT([no])])
 945
 946  CFLAGS="$old_CFLAGS"
 947fi
 948
 949CFLAGS="$old_CFLAGS"
 950
 951AC_SUBST(PTHREAD_CFLAGS)
 952AC_SUBST(PTHREAD_LIBS)
 953AC_SUBST(NO_PTHREADS)
 954
 955## Output files
 956AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 957AC_OUTPUT
 958
 959
 960## Cleanup
 961rm -f "${config_append}"