Andrew's git - gitweb.git/blob

   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [1.4.1], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_WARN([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46        fi; \
  47fi; \
  48]) # GIT_CONF_APPEND_PATH
  49
  50
  51## Site configuration
  52## --with-PACKAGE[=ARG] and --without-PACKAGE
  53#
  54# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
  55# tests.  These tests take up a significant amount of the total test time
  56# but are not needed unless you plan to talk to SVN repos.
  57#
  58# Define MOZILLA_SHA1 environment variable when running make to make use of
  59# a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
  60# on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
  61# choice) has very fast version optimized for i586.
  62#
  63# Define PPC_SHA1 environment variable when running make to make use of
  64# a bundled SHA1 routine optimized for PowerPC.
  65#
  66# Define ARM_SHA1 environment variable when running make to make use of
  67# a bundled SHA1 routine optimized for ARM.
  68#
  69# Define NO_OPENSSL environment variable if you do not have OpenSSL.
  70# This also implies MOZILLA_SHA1.
  71#
  72# Define NO_CURL if you do not have curl installed.  git-http-pull and
  73# git-http-push are not built, and you cannot use http:// and https://
  74# transports.
  75#
  76# Define CURLDIR=/foo/bar if your curl header and library files are in
  77# /foo/bar/include and /foo/bar/lib directories.
  78#
  79# Define NO_EXPAT if you do not have expat installed.  git-http-push is
  80# not built, and you cannot push using http:// and https:// transports.
  81#
  82# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
  83# installed in /sw, but don't want GIT to link against any libraries
  84# installed there.  If defined you may specify your own (or Fink's)
  85# include directories and library directories by defining CFLAGS
  86# and LDFLAGS appropriately.
  87#
  88# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
  89# have DarwinPorts installed in /opt/local, but don't want GIT to
  90# link against any libraries installed there.  If defined you may
  91# specify your own (or DarwinPort's) include directories and
  92# library directories by defining CFLAGS and LDFLAGS appropriately.
  93#
  94# Define NO_MMAP if you want to avoid mmap.
  95#
  96# Define SHELL_PATH to provide path to shell.
  97GIT_ARG_SET_PATH(shell)
  98#
  99# Define PERL_PATH to provide path to Perl.
 100GIT_ARG_SET_PATH(perl)
 101#
 102# Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 103# Define PYTHON_PATH to provide path to Python.
 104AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
 105AS_HELP_STRING([--no-python], [don't use python scripts])],
 106 [if test "$withval" = "no"; then \
 107    NO_PYTHON=YesPlease; \
 108  elif test "$withval" != "yes"; then \
 109    PYTHON_PATH=$withval; \
 110  fi; \
 111 ])
 112AC_SUBST(NO_PYTHON)
 113AC_SUBST(PYTHON_PATH)
 114#
 115## --enable-FEATURE[=ARG] and --disable-FEATURE
 116# Define COLLISION_CHECK below if you believe that SHA1's
 117# 1461501637330902918203684832716283019655932542976 hashes do not give you
 118# sufficient guarantee that no collisions between objects will ever happen.
 119#
 120# Define USE_NSEC below if you want git to care about sub-second file mtimes
 121# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 122# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 123# randomly break unless your underlying filesystem supports those sub-second
 124# times (my ext3 doesn't).
 125#
 126# Define USE_STDEV below if you want git to care about the underlying device
 127# change being considered an inode change from the update-cache perspective.
 128
 129
 130## Checks for programs.
 131AC_MSG_NOTICE([CHECKS for programs])
 132#
 133AC_PROG_CC
 134#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 135AC_CHECK_TOOL(AR, ar, :)
 136AC_CHECK_PROGS(TAR, [gtar tar])
 137#
 138# Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 139# Define PYTHON_PATH to provide path to Python.
 140if test -z "$NO_PYTHON"; then
 141        AC_PATH_PROGS(PYTHON_PATH, [python2.4 python2.3 python2 python])
 142        if test -n "$PYTHON_PATH"; then
 143                GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
 144        else
 145                GIT_CONF_APPEND_LINE([NO_PYTHON=@NO_PYTHON@])
 146        fi
 147else
 148        GIT_CONF_APPEND_LINE([NO_PYTHON=@NO_PYTHON@])
 149fi
 150
 151
 152## Checks for libraries.
 153AC_MSG_NOTICE([CHECKS for libraries])
 154#
 155# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 156# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 157AC_CHECK_LIB([ssl], [SHA1_Init],[],
 158[AC_CHECK_LIB([crypto], [SHA1_INIT],
 159 [GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=YesPlease)],
 160 [GIT_CONF_APPEND_LINE(NO_OPENSSL=YesPlease)])])
 161#
 162# Define NO_CURL if you do not have curl installed.  git-http-pull and
 163# git-http-push are not built, and you cannot use http:// and https://
 164# transports.
 165AC_CHECK_LIB([curl], [curl_global_init],[],
 166[GIT_CONF_APPEND_LINE(NO_CURL=YesPlease)])
 167#
 168# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 169# not built, and you cannot push using http:// and https:// transports.
 170AC_CHECK_LIB([expat], [XML_ParserCreate],[],
 171[GIT_CONF_APPEND_LINE(NO_EXPAT=YesPlease)])
 172#
 173# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 174AC_CHECK_LIB([c], [iconv],[],
 175[AC_CHECK_LIB([iconv],[iconv],
 176 [GIT_CONF_APPEND_LINE(NEEDS_LIBICONV=YesPlease)],[])])
 177#
 178# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 179# Patrick Mauritz).
 180AC_CHECK_LIB([c], [socket],[],
 181[AC_CHECK_LIB([socket],[socket],
 182 [GIT_CONF_APPEND_LINE(NEEDS_SOCKET=YesPlease)],[])])
 183
 184
 185## Checks for header files.
 186
 187
 188## Checks for typedefs, structures, and compiler characteristics.
 189AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 190#
 191# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 192AC_CHECK_MEMBER(struct dirent.d_ino,[],
 193[GIT_CONF_APPEND_LINE(NO_D_INO_IN_DIRENT=YesPlease)],
 194[#include <dirent.h>])
 195#
 196# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 197# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 198AC_CHECK_MEMBER(struct dirent.d_type,[],
 199[GIT_CONF_APPEND_LINE(NO_D_TYPE_IN_DIRENT=YesPlease)],
 200[#include <dirent.h>])
 201#
 202# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 203# sockaddr_storage.
 204AC_CHECK_TYPE(struct sockaddr_storage,[],
 205[GIT_CONF_APPEND_LINE(NO_SOCKADDR_STORAGE=YesPlease)],
 206[#include <netinet/in.h>])
 207#
 208# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 209# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 210# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 211# some C compilers supported these specifiers prior to C99 as an extension.
 212AC_CACHE_CHECK(whether formatted IO functions support C99 size specifiers,
 213 ac_cv_c_c99_format,
 214[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 215AC_RUN_IFELSE(
 216        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 217                [[char buf[64];
 218                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 219                  exit(1);
 220                else if (strcmp(buf, "12345"))
 221                  exit(2);]])],
 222        [ac_cv_c_c99_format=yes],
 223        [ac_cv_c_c99_format=no])
 224])
 225if test $ac_cv_c_c99_format = no; then
 226        GIT_CONF_APPEND_LINE(NO_C99_FORMAT=YesPlease)
 227fi
 228
 229
 230## Checks for library functions.
 231## (in default C library and libraries checked by AC_CHECK_LIB)
 232AC_MSG_NOTICE([CHECKS for library functions])
 233#
 234# Define NO_STRCASESTR if you don't have strcasestr.
 235AC_CHECK_FUNC(strcasestr,[],
 236[GIT_CONF_APPEND_LINE(NO_STRCASESTR=YesPlease)])
 237#
 238# Define NO_STRLCPY if you don't have strlcpy.
 239AC_CHECK_FUNC(strlcpy,[],
 240[GIT_CONF_APPEND_LINE(NO_STRLCPY=YesPlease)])
 241#
 242# Define NO_SETENV if you don't have setenv in the C library.
 243AC_CHECK_FUNC(setenv,[],
 244[GIT_CONF_APPEND_LINE(NO_SETENV=YesPlease)])
 245#
 246# Define NO_MMAP if you want to avoid mmap.
 247#
 248# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 249#
 250# Define NO_ICONV if your libc does not properly support iconv.
 251
 252
 253## Other checks.
 254# Define USE_PIC if you need the main git objects to be built with -fPIC
 255# in order to build and link perl/Git.so.  x86-64 seems to need this.
 256#
 257# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 258# Enable it on Windows.  By default, symrefs are still used.
 259#
 260# Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 261#
 262# Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 263# a missing newline at the end of the file.
 264
 265
 266## Output files
 267AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 268AC_OUTPUT
 269
 270
 271## Cleanup
 272rm -f "${config_append}"