1# git-gui blame viewer
2# Copyright (C) 2006, 2007 Shawn Pearce
3class blame {
5image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
7field commit ; # input commit to blame
9field path ; # input filename to view in $commit
10field history {}; # viewer history: {commit path}
11field w ; # top window in this viewer
13field w_back ; # our back button
14field w_path ; # label showing the current file path
15field w_line ; # text column: all line numbers
16field w_cgrp ; # text column: abbreviated commit SHA-1s
17field w_file ; # text column: actual file data
18field w_cmit ; # pane showing commit message
19field status ; # text variable bound to status bar
20field old_height ; # last known height of $w.file_pane
21field current_fd {} ; # background process running
23field highlight_line -1 ; # current line selected
24field highlight_commit {} ; # sha1 of commit selected
25field total_lines 0 ; # total length of file
27field blame_lines 0 ; # number of lines computed
28field commit_count 0 ; # number of commits in $commit_list
29field commit_list {} ; # list of commit sha1 in receipt order
30field order ; # array commit -> receipt order
31field header ; # array commit,key -> header field
32field line_commit ; # array line -> sha1 commit
33field line_file ; # array line -> file name
34field r_commit ; # commit currently being parsed
36field r_orig_line ; # original line number
37field r_final_line ; # final line number
38field r_line_count ; # lines in this region
39field tooltip_wm {} ; # Current tooltip toplevel, if open
41field tooltip_timer {} ; # Current timer event for our tooltip
42field tooltip_commit {} ; # Commit in tooltip
43field tooltip_text {} ; # Text in current tooltip
44variable active_color #c0edc5
46variable group_colors {
47 #d6d6d6
48 #e1e1e1
49 #ececec
50}
51constructor new {i_commit i_path} {
53 variable active_color
54 global cursor_ptr
55 set commit $i_commit
57 set path $i_path
58 make_toplevel top w
60 wm title $top "[appname] ([reponame]): File Viewer"
61 frame $w.header -background orange
63 label $w.header.commit_l \
64 -text {Commit:} \
65 -background orange \
66 -anchor w \
67 -justify left
68 set w_back $w.header.commit_b
69 label $w_back \
70 -image ::blame::img_back_arrow \
71 -borderwidth 0 \
72 -relief flat \
73 -state disabled \
74 -background orange \
75 -activebackground orange
76 bind $w_back <Button-1> "
77 if {\[$w_back cget -state\] eq {normal}} {
78 [cb _history_menu]
79 }
80 "
81 label $w.header.commit \
82 -textvariable @commit \
83 -background orange \
84 -anchor w \
85 -justify left
86 label $w.header.path_l \
87 -text {File:} \
88 -background orange \
89 -anchor w \
90 -justify left
91 set w_path $w.header.path
92 label $w_path \
93 -background orange \
94 -anchor w \
95 -justify left
96 pack $w.header.commit_l -side left
97 pack $w_back -side left
98 pack $w.header.commit -side left
99 pack $w_path -fill x -side right
100 pack $w.header.path_l -side right
101 panedwindow $w.file_pane -orient vertical
103 frame $w.file_pane.out
104 frame $w.file_pane.cm
105 $w.file_pane add $w.file_pane.out \
106 -sticky nsew \
107 -minsize 100 \
108 -height 100 \
109 -width 100
110 $w.file_pane add $w.file_pane.cm \
111 -sticky nsew \
112 -minsize 25 \
113 -height 25 \
114 -width 100
115 set w_line $w.file_pane.out.linenumber_t
117 text $w_line \
118 -takefocus 0 \
119 -highlightthickness 0 \
120 -padx 0 -pady 0 \
121 -background white -borderwidth 0 \
122 -state disabled \
123 -wrap none \
124 -height 40 \
125 -width 6 \
126 -font font_diff
127 $w_line tag conf linenumber -justify right -rmargin 5
128 set w_cgrp $w.file_pane.out.commit_t
130 text $w_cgrp \
131 -takefocus 0 \
132 -highlightthickness 0 \
133 -padx 0 -pady 0 \
134 -background white -borderwidth 0 \
135 -state disabled \
136 -wrap none \
137 -height 40 \
138 -width 4 \
139 -font font_diff
140 $w_cgrp tag conf curr_commit
141 $w_cgrp tag conf prior_commit \
142 -foreground blue \
143 -underline 1
144 $w_cgrp tag bind prior_commit \
145 <Button-1> \
146 "[cb _load_commit @%x,%y];break"
147 set w_file $w.file_pane.out.file_t
149 text $w_file \
150 -takefocus 0 \
151 -highlightthickness 0 \
152 -padx 0 -pady 0 \
153 -background white -borderwidth 0 \
154 -state disabled \
155 -wrap none \
156 -height 40 \
157 -width 80 \
158 -xscrollcommand [list $w.file_pane.out.sbx set] \
159 -font font_diff
160 scrollbar $w.file_pane.out.sbx \
162 -orient h \
163 -command [list $w_file xview]
164 scrollbar $w.file_pane.out.sby \
165 -orient v \
166 -command [list scrollbar2many [list \
167 $w_line \
168 $w_cgrp \
169 $w_file \
170 ] yview]
171 grid \
172 $w_cgrp \
173 $w_line \
174 $w_file \
175 $w.file_pane.out.sby \
176 -sticky nsew
177 grid conf $w.file_pane.out.sbx -column 2 -sticky we
178 grid columnconfigure $w.file_pane.out 2 -weight 1
179 grid rowconfigure $w.file_pane.out 0 -weight 1
180 set w_cmit $w.file_pane.cm.t
182 text $w_cmit \
183 -background white -borderwidth 0 \
184 -state disabled \
185 -wrap none \
186 -height 10 \
187 -width 80 \
188 -xscrollcommand [list $w.file_pane.cm.sbx set] \
189 -yscrollcommand [list $w.file_pane.cm.sby set] \
190 -font font_diff
191 $w_cmit tag conf header_key \
192 -tabs {3c} \
193 -background $active_color \
194 -font font_uibold
195 $w_cmit tag conf header_val \
196 -background $active_color \
197 -font font_ui
198 $w_cmit tag raise sel
199 scrollbar $w.file_pane.cm.sbx \
200 -orient h \
201 -command [list $w_cmit xview]
202 scrollbar $w.file_pane.cm.sby \
203 -orient v \
204 -command [list $w_cmit yview]
205 pack $w.file_pane.cm.sby -side right -fill y
206 pack $w.file_pane.cm.sbx -side bottom -fill x
207 pack $w_cmit -expand 1 -fill both
208 frame $w.status \
210 -borderwidth 1 \
211 -relief sunken
212 label $w.status.l \
213 -textvariable @status \
214 -anchor w \
215 -justify left
216 pack $w.status.l -side left
217 menu $w.ctxm -tearoff 0
219 $w.ctxm add command \
220 -label "Copy Commit" \
221 -command [cb _copycommit]
222 foreach i [list \
224 $w_cgrp \
225 $w_line \
226 $w_file] {
227 $i conf -cursor $cursor_ptr
228 $i conf -yscrollcommand \
229 [list many2scrollbar [list \
230 $w_cgrp \
231 $w_line \
232 $w_file \
233 ] yview $w.file_pane.out.sby]
234 bind $i <Button-1> "
235 [cb _hide_tooltip]
236 [cb _click $i @%x,%y]
237 focus $i
238 "
239 bind $i <Any-Motion> [cb _show_tooltip $i @%x,%y]
240 bind $i <Any-Enter> [cb _hide_tooltip]
241 bind $i <Any-Leave> [cb _hide_tooltip]
242 bind_button3 $i "
243 [cb _hide_tooltip]
244 set cursorX %x
245 set cursorY %y
246 set cursorW %W
247 tk_popup $w.ctxm %X %Y
248 "
249 }
250 foreach i [list \
252 $w_cgrp \
253 $w_line \
254 $w_file \
255 $w_cmit] {
256 bind $i <Key-Up> {catch {%W yview scroll -1 units};break}
257 bind $i <Key-Down> {catch {%W yview scroll 1 units};break}
258 bind $i <Key-Left> {catch {%W xview scroll -1 units};break}
259 bind $i <Key-Right> {catch {%W xview scroll 1 units};break}
260 bind $i <Key-k> {catch {%W yview scroll -1 units};break}
261 bind $i <Key-j> {catch {%W yview scroll 1 units};break}
262 bind $i <Key-h> {catch {%W xview scroll -1 units};break}
263 bind $i <Key-l> {catch {%W xview scroll 1 units};break}
264 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
265 bind $i <Control-Key-f> {catch {%W yview scroll 1 pages};break}
266 }
267 bind $w_cmit <Button-1> [list focus $w_cmit]
269 bind $top <Visibility> [list focus $top]
270 bind $w_file <Destroy> [list delete_this $this]
271 grid configure $w.header -sticky ew
273 grid configure $w.file_pane -sticky nsew
274 grid configure $w.status -sticky ew
275 grid columnconfigure $top 0 -weight 1
276 grid rowconfigure $top 0 -weight 0
277 grid rowconfigure $top 1 -weight 1
278 grid rowconfigure $top 2 -weight 0
279 set req_w [winfo reqwidth $top]
281 set req_h [winfo reqheight $top]
282 if {$req_w < 600} {set req_w 600}
283 if {$req_h < 400} {set req_h 400}
284 set g "${req_w}x${req_h}"
285 wm geometry $top $g
286 update
287 set old_height [winfo height $w.file_pane]
289 $w.file_pane sash place 0 \
290 [lindex [$w.file_pane sash coord 0] 0] \
291 [expr {int($old_height * 0.70)}]
292 bind $w.file_pane <Configure> \
293 "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
294 _load $this
296}
297method _load {} {
299 _hide_tooltip $this
300 if {$total_lines != 0 || $current_fd ne {}} {
302 if {$current_fd ne {}} {
303 catch {close $current_fd}
304 set current_fd {}
305 }
306 set highlight_line -1
308 set highlight_commit {}
309 set total_lines 0
310 set blame_lines 0
311 set commit_count 0
312 set commit_list {}
313 array unset order
314 array unset line_commit
315 array unset line_file
316 $w_cgrp conf -state normal
318 $w_line conf -state normal
319 $w_file conf -state normal
320 $w_cgrp delete 0.0 end
322 $w_line delete 0.0 end
323 $w_file delete 0.0 end
324 $w_cgrp conf -state disabled
326 $w_line conf -state disabled
327 $w_file conf -state disabled
328 }
329 if {[winfo exists $w.status.c]} {
331 $w.status.c coords bar 0 0 0 20
332 } else {
333 canvas $w.status.c \
334 -width 100 \
335 -height [expr {int([winfo reqheight $w.status.l] * 0.6)}] \
336 -borderwidth 1 \
337 -relief groove \
338 -highlightt 0
339 $w.status.c create rectangle 0 0 0 20 -tags bar -fill navy
340 pack $w.status.c -side right
341 }
342 if {$history eq {}} {
344 $w_back conf -state disabled
345 } else {
346 $w_back conf -state normal
347 }
348 lappend history [list $commit $path]
349 set status "Loading $commit:[escape_path $path]..."
351 $w_path conf -text [escape_path $path]
352 if {$commit eq {}} {
353 set fd [open $path r]
354 } else {
355 set cmd [list git cat-file blob "$commit:$path"]
356 set fd [open "| $cmd" r]
357 }
358 fconfigure $fd -blocking 0 -translation lf -encoding binary
359 fileevent $fd readable [cb _read_file $fd]
360 set current_fd $fd
361}
362method _history_menu {} {
364 set m $w.backmenu
365 if {[winfo exists $m]} {
366 $m delete 0 end
367 } else {
368 menu $m -tearoff 0
369 }
370 for {set i [expr {[llength $history] - 2}]
372 } {$i >= 0} {incr i -1} {
373 set e [lindex $history $i]
374 set c [lindex $e 0]
375 set f [lindex $e 1]
376 if {[regexp {^[0-9a-f]{40}$} $c]} {
378 set t [string range $c 0 8]...
379 } else {
380 set t $c
381 }
382 if {![catch {set summary $header($c,summary)}]} {
383 append t " $summary"
384 if {[string length $t] > 70} {
385 set t [string range $t 0 66]...
386 }
387 }
388 $m add command -label $t -command [cb _goback $i $c $f]
390 }
391 set X [winfo rootx $w_back]
392 set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
393 tk_popup $m $X $Y
394}
395method _goback {i c f} {
397 set history [lrange $history 0 [expr {$i - 1}]]
398 set commit $c
399 set path $f
400 _load $this
401}
402method _read_file {fd} {
404 if {$fd ne $current_fd} {
405 catch {close $fd}
406 return
407 }
408 $w_cgrp conf -state normal
410 $w_line conf -state normal
411 $w_file conf -state normal
412 while {[gets $fd line] >= 0} {
413 regsub "\r\$" $line {} line
414 incr total_lines
415 if {$total_lines > 1} {
417 $w_cgrp insert end "\n"
418 $w_line insert end "\n"
419 $w_file insert end "\n"
420 }
421 $w_line insert end "$total_lines" linenumber
423 $w_file insert end "$line"
424 }
425 $w_cgrp conf -state disabled
426 $w_line conf -state disabled
427 $w_file conf -state disabled
428 if {[eof $fd]} {
430 close $fd
431 _status $this
432 set cmd {nice git blame -M -C --incremental}
433 if {$commit eq {}} {
434 lappend cmd --contents $path
435 } else {
436 lappend cmd $commit
437 }
438 lappend cmd -- $path
439 set fd [open "| $cmd" r]
440 fconfigure $fd -blocking 0 -translation lf -encoding binary
441 fileevent $fd readable [cb _read_blame $fd]
442 set current_fd $fd
443 }
444} ifdeleted { catch {close $fd} }
445method _read_blame {fd} {
447 variable group_colors
448 if {$fd ne $current_fd} {
450 catch {close $fd}
451 return
452 }
453 $w_cgrp conf -state normal
455 while {[gets $fd line] >= 0} {
456 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
457 cmit original_line final_line line_count]} {
458 set r_commit $cmit
459 set r_orig_line $original_line
460 set r_final_line $final_line
461 set r_line_count $line_count
462 if {[catch {set g $order($cmit)}]} {
464 set bg [lindex $group_colors 0]
465 set group_colors [lrange $group_colors 1 end]
466 lappend group_colors $bg
467 $w_cgrp tag conf g$cmit -background $bg
469 $w_line tag conf g$cmit -background $bg
470 $w_file tag conf g$cmit -background $bg
471 set order($cmit) $commit_count
473 incr commit_count
474 lappend commit_list $cmit
475 }
476 } elseif {[string match {filename *} $line]} {
477 set file [string range $line 9 end]
478 set n $r_line_count
479 set lno $r_final_line
480 set cmit $r_commit
481 if {[regexp {^0{40}$} $cmit]} {
483 set commit_abbr work
484 set commit_type curr_commit
485 } elseif {$cmit eq $commit} {
486 set commit_abbr this
487 set commit_type curr_commit
488 } else {
489 set commit_type prior_commit
490 set commit_abbr [string range $cmit 0 4]
491 }
492 set author_abbr {}
494 set a_name {}
495 catch {set a_name $header($cmit,author)}
496 while {$a_name ne {}} {
497 if {![regexp {^([[:upper:]])} $a_name _a]} break
498 append author_abbr $_a
499 unset _a
500 if {![regsub \
501 {^[[:upper:]][^\s]*\s+} \
502 $a_name {} a_name ]} break
503 }
504 if {$author_abbr eq {}} {
505 set author_abbr { |}
506 } else {
507 set author_abbr [string range $author_abbr 0 3]
508 while {[string length $author_abbr] < 4} {
509 set author_abbr " $author_abbr"
510 }
511 }
512 unset a_name
513 set first_lno $lno
515 while {
516 ![catch {set ncmit $line_commit([expr {$first_lno - 1}])}]
517 && ![catch {set nfile $line_file([expr {$first_lno - 1}])}]
518 && $ncmit eq $cmit
519 && $nfile eq $file
520 } {
521 incr first_lno -1
522 }
523 while {$n > 0} {
525 set lno_e "$lno.0 lineend + 1c"
526 if {![catch {set g g$line_commit($lno)}]} {
527 $w_cgrp tag remove g$g $lno.0 $lno_e
528 $w_line tag remove g$g $lno.0 $lno_e
529 $w_file tag remove g$g $lno.0 $lno_e
530 $w_cgrp tag remove a$g $lno.0 $lno_e
532 $w_line tag remove a$g $lno.0 $lno_e
533 $w_file tag remove a$g $lno.0 $lno_e
534 }
535 set line_commit($lno) $cmit
537 set line_file($lno) $file
538 $w_cgrp delete $lno.0 "$lno.0 lineend"
540 if {$lno == $first_lno} {
541 $w_cgrp insert $lno.0 $commit_abbr $commit_type
542 } elseif {$lno == [expr {$first_lno + 1}]} {
543 $w_cgrp insert $lno.0 $author_abbr
544 } else {
545 $w_cgrp insert $lno.0 { |}
546 }
547 $w_cgrp tag add g$cmit $lno.0 $lno_e
549 $w_line tag add g$cmit $lno.0 $lno_e
550 $w_file tag add g$cmit $lno.0 $lno_e
551 $w_cgrp tag add a$cmit $lno.0 $lno_e
553 $w_line tag add a$cmit $lno.0 $lno_e
554 $w_file tag add a$cmit $lno.0 $lno_e
555 if {$highlight_line == -1} {
557 if {[lindex [$w_file yview] 0] == 0} {
558 $w_file see $lno.0
559 _showcommit $this $lno
560 }
561 } elseif {$highlight_line == $lno} {
562 _showcommit $this $lno
563 }
564 incr n -1
566 incr lno
567 incr blame_lines
568 }
569 while {
571 ![catch {set ncmit $line_commit($lno)}]
572 && ![catch {set nfile $line_file($lno)}]
573 && $ncmit eq $cmit
574 && $nfile eq $file
575 } {
576 $w_cgrp delete $lno.0 "$lno.0 lineend"
577 if {$lno == $first_lno} {
579 $w_cgrp insert $lno.0 $commit_abbr $commit_type
580 } elseif {$lno == [expr {$first_lno + 1}]} {
581 $w_cgrp insert $lno.0 $author_abbr
582 } else {
583 $w_cgrp insert $lno.0 { |}
584 }
585 incr lno
586 }
587 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
589 set header($r_commit,$key) $data
590 }
591 }
592 $w_cgrp conf -state disabled
593 if {[eof $fd]} {
595 close $fd
596 set current_fd {}
597 set status {Annotation complete.}
598 destroy $w.status.c
599 } else {
600 _status $this
601 }
602} ifdeleted { catch {close $fd} }
603method _status {} {
605 set have $blame_lines
606 set total $total_lines
607 set pdone 0
608 if {$total} {set pdone [expr {100 * $have / $total}]}
609 set status [format \
611 "Loading annotations... %i of %i lines annotated (%2i%%)" \
612 $have $total $pdone]
613 $w.status.c coords bar 0 0 $pdone 20
614}
615method _click {cur_w pos} {
617 set lno [lindex [split [$cur_w index $pos] .] 0]
618 if {$lno eq {}} return
619 _showcommit $this $lno
620}
621method _load_commit {pos} {
623 set lno [lindex [split [$w_cgrp index $pos] .] 0]
624 if {[catch {set cmit $line_commit($lno)}]} return
625 if {[catch {set file $line_file($lno) }]} return
626 set commit $cmit
628 set path $file
629 _load $this
630}
631method _showcommit {lno} {
633 global repo_config
634 variable active_color
635 if {$highlight_commit ne {}} {
637 set cmit $highlight_commit
638 $w_cgrp tag conf a$cmit -background {}
639 $w_line tag conf a$cmit -background {}
640 $w_file tag conf a$cmit -background {}
641 }
642 $w_cmit conf -state normal
644 $w_cmit delete 0.0 end
645 if {[catch {set cmit $line_commit($lno)}]} {
646 set cmit {}
647 $w_cmit insert end "Loading annotation..."
648 } else {
649 $w_cgrp tag conf a$cmit -background $active_color
650 $w_line tag conf a$cmit -background $active_color
651 $w_file tag conf a$cmit -background $active_color
652 set author_name {}
654 set author_email {}
655 set author_time {}
656 catch {set author_name $header($cmit,author)}
657 catch {set author_email $header($cmit,author-mail)}
658 catch {set author_time [clock format \
659 $header($cmit,author-time) \
660 -format {%Y-%m-%d %H:%M:%S}
661 ]}
662 set committer_name {}
664 set committer_email {}
665 set committer_time {}
666 catch {set committer_name $header($cmit,committer)}
667 catch {set committer_email $header($cmit,committer-mail)}
668 catch {set committer_time [clock format \
669 $header($cmit,committer-time) \
670 -format {%Y-%m-%d %H:%M:%S}
671 ]}
672 if {[catch {set msg $header($cmit,message)}]} {
674 set msg {}
675 catch {
676 set fd [open "| git cat-file commit $cmit" r]
677 fconfigure $fd -encoding binary -translation lf
678 if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
679 set enc utf-8
680 }
681 while {[gets $fd line] > 0} {
682 if {[string match {encoding *} $line]} {
683 set enc [string tolower [string range $line 9 end]]
684 }
685 }
686 set msg [encoding convertfrom $enc [read $fd]]
687 set msg [string trim $msg]
688 close $fd
689 set author_name [encoding convertfrom $enc $author_name]
691 set committer_name [encoding convertfrom $enc $committer_name]
692 set header($cmit,author) $author_name
694 set header($cmit,committer) $committer_name
695 }
696 set header($cmit,message) $msg
697 }
698 $w_cmit insert end "commit $cmit\n" header_key
700 $w_cmit insert end "Author:\t" header_key
701 $w_cmit insert end "$author_name $author_email" header_val
702 $w_cmit insert end "$author_time\n" header_val
703 $w_cmit insert end "Committer:\t" header_key
705 $w_cmit insert end "$committer_name $committer_email" header_val
706 $w_cmit insert end "$committer_time\n" header_val
707 if {$line_file($lno) ne $path} {
709 $w_cmit insert end "Original File:\t" header_key
710 $w_cmit insert end "[escape_path $line_file($lno)]\n" header_val
711 }
712 $w_cmit insert end "\n$msg"
714 }
715 $w_cmit conf -state disabled
716 set highlight_line $lno
718 set highlight_commit $cmit
719 if {$highlight_commit eq $tooltip_commit} {
721 _hide_tooltip $this
722 }
723}
724method _copycommit {} {
726 set pos @$::cursorX,$::cursorY
727 set lno [lindex [split [$::cursorW index $pos] .] 0]
728 if {![catch {set commit $line_commit($lno)}]} {
729 clipboard clear
730 clipboard append \
731 -format STRING \
732 -type STRING \
733 -- $commit
734 }
735}
736method _show_tooltip {cur_w pos} {
738 set lno [lindex [split [$cur_w index $pos] .] 0]
739 if {[catch {set cmit $line_commit($lno)}]} {
740 _hide_tooltip $this
741 return
742 }
743 if {$cmit eq $highlight_commit} {
745 _hide_tooltip $this
746 return
747 }
748 if {$cmit eq $tooltip_commit} {
750 _position_tooltip $this
751 } elseif {$tooltip_wm ne {}} {
752 _open_tooltip $this $cur_w
753 } elseif {$tooltip_timer eq {}} {
754 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
755 }
756}
757method _open_tooltip {cur_w} {
759 set tooltip_timer {}
760 set pos_x [winfo pointerx $cur_w]
761 set pos_y [winfo pointery $cur_w]
762 if {[winfo containing $pos_x $pos_y] ne $cur_w} {
763 _hide_tooltip $this
764 return
765 }
766 set pos @[join [list \
768 [expr {$pos_x - [winfo rootx $cur_w]}] \
769 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
770 set lno [lindex [split [$cur_w index $pos] .] 0]
771 set cmit $line_commit($lno)
772 set author_name {}
774 set author_email {}
775 set author_time {}
776 catch {set author_name $header($cmit,author)}
777 catch {set author_email $header($cmit,author-mail)}
778 catch {set author_time [clock format \
779 $header($cmit,author-time) \
780 -format {%Y-%m-%d %H:%M:%S}
781 ]}
782 set committer_name {}
784 set committer_email {}
785 set committer_time {}
786 catch {set committer_name $header($cmit,committer)}
787 catch {set committer_email $header($cmit,committer-mail)}
788 catch {set committer_time [clock format \
789 $header($cmit,committer-time) \
790 -format {%Y-%m-%d %H:%M:%S}
791 ]}
792 set summary {}
794 catch {set summary $header($cmit,summary)}
795 set tooltip_commit $cmit
797 set tooltip_text "commit $cmit
798$author_name $author_email $author_time
799$summary"
800 set file $line_file($lno)
802 if {$file ne $path} {
803 append tooltip_text "
804Original File: $file"
806 }
807 if {$tooltip_wm ne "$cur_w.tooltip"} {
809 _hide_tooltip $this
810 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
812 wm overrideredirect $tooltip_wm 1
813 wm transient $tooltip_wm [winfo toplevel $cur_w]
814 pack [label $tooltip_wm.label \
815 -background lightyellow \
816 -foreground black \
817 -textvariable @tooltip_text \
818 -justify left]
819 }
820 _position_tooltip $this
821}
822method _position_tooltip {} {
824 set req_w [winfo reqwidth $tooltip_wm.label]
825 set req_h [winfo reqheight $tooltip_wm.label]
826 set pos_x [expr {[winfo pointerx .] + 5}]
827 set pos_y [expr {[winfo pointery .] + 10}]
828 set g "${req_w}x${req_h}"
830 if {$pos_x >= 0} {append g +}
831 append g $pos_x
832 if {$pos_y >= 0} {append g +}
833 append g $pos_y
834 wm geometry $tooltip_wm $g
836 raise $tooltip_wm
837}
838method _hide_tooltip {} {
840 if {$tooltip_wm ne {}} {
841 destroy $tooltip_wm
842 set tooltip_wm {}
843 set tooltip_commit {}
844 }
845 if {$tooltip_timer ne {}} {
846 after cancel $tooltip_timer
847 set tooltip_timer {}
848 }
849}
850method _resize {new_height} {
852 set diff [expr {$new_height - $old_height}]
853 if {$diff == 0} return
854 set my [expr {[winfo height $w.file_pane] - 25}]
856 set o [$w.file_pane sash coord 0]
857 set ox [lindex $o 0]
858 set oy [expr {[lindex $o 1] + $diff}]
859 if {$oy < 0} {set oy 0}
860 if {$oy > $my} {set oy $my}
861 $w.file_pane sash place 0 $ox $oy
862 set old_height $new_height
864}
865}