Andrew's git - gitweb.git/blob

   1#!/usr/bin/env perl
   2# Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3# License: GPL v2 or later
   4use warnings;
   5use strict;
   6use vars qw/    $AUTHOR $VERSION
   7                $sha1 $sha1_short $_revision $_repository
   8                $_q $_authors %users/;
   9$AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10$VERSION = '@@GIT_VERSION@@';
  11
  12# From which subdir have we been invoked?
  13my $cmd_dir_prefix = eval {
  14        command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15} || '';
  16
  17my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18$ENV{GIT_DIR} ||= '.git';
  19$Git::SVN::default_repo_id = 'svn';
  20$Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21$Git::SVN::Ra::_log_window_size = 100;
  22
  23$Git::SVN::Log::TZ = $ENV{TZ};
  24$ENV{TZ} = 'UTC';
  25$| = 1; # unbuffer STDOUT
  26
  27sub fatal (@) { print STDERR "@_\n"; exit 1 }
  28require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  29require SVN::Ra;
  30require SVN::Delta;
  31if ($SVN::Core::VERSION lt '1.1.0') {
  32        fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  33}
  34push @Git::SVN::Ra::ISA, 'SVN::Ra';
  35push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  36push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  37use Carp qw/croak/;
  38use Digest::MD5;
  39use IO::File qw//;
  40use File::Basename qw/dirname basename/;
  41use File::Path qw/mkpath/;
  42use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  43use IPC::Open3;
  44use Git;
  45
  46BEGIN {
  47        # import functions from Git into our packages, en masse
  48        no strict 'refs';
  49        foreach (qw/command command_oneline command_noisy command_output_pipe
  50                    command_input_pipe command_close_pipe/) {
  51                for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  52                        Git::SVN::Migration Git::SVN::Log Git::SVN),
  53                        __PACKAGE__) {
  54                        *{"${package}::$_"} = \&{"Git::$_"};
  55                }
  56        }
  57}
  58
  59my ($SVN);
  60
  61$sha1 = qr/[a-f\d]{40}/;
  62$sha1_short = qr/[a-f\d]{4,40}/;
  63my ($_stdin, $_help, $_edit,
  64        $_message, $_file,
  65        $_template, $_shared,
  66        $_version, $_fetch_all, $_no_rebase,
  67        $_merge, $_strategy, $_dry_run, $_local,
  68        $_prefix, $_no_checkout, $_url, $_verbose,
  69        $_git_format, $_commit_url, $_tag);
  70$Git::SVN::_follow_parent = 1;
  71my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  72                    'config-dir=s' => \$Git::SVN::Ra::config_dir,
  73                    'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  74                    'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  75my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  76                'authors-file|A=s' => \$_authors,
  77                'repack:i' => \$Git::SVN::_repack,
  78                'noMetadata' => \$Git::SVN::_no_metadata,
  79                'useSvmProps' => \$Git::SVN::_use_svm_props,
  80                'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  81                'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  82                'no-checkout' => \$_no_checkout,
  83                'quiet|q' => \$_q,
  84                'repack-flags|repack-args|repack-opts=s' =>
  85                   \$Git::SVN::_repack_flags,
  86                'use-log-author' => \$Git::SVN::_use_log_author,
  87                'add-author-from' => \$Git::SVN::_add_author_from,
  88                'localtime' => \$Git::SVN::_localtime,
  89                %remote_opts );
  90
  91my ($_trunk, $_tags, $_branches, $_stdlayout);
  92my %icv;
  93my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
  94                  'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
  95                  'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
  96                  'stdlayout|s' => \$_stdlayout,
  97                  'minimize-url|m' => \$Git::SVN::_minimize_url,
  98                  'no-metadata' => sub { $icv{noMetadata} = 1 },
  99                  'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 100                  'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 101                  'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 102                  %remote_opts );
 103my %cmt_opts = ( 'edit|e' => \$_edit,
 104                'rmdir' => \$SVN::Git::Editor::_rmdir,
 105                'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 106                'l=i' => \$SVN::Git::Editor::_rename_limit,
 107                'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 108);
 109
 110my %cmd = (
 111        fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 112                        { 'revision|r=s' => \$_revision,
 113                          'fetch-all|all' => \$_fetch_all,
 114                           %fc_opts } ],
 115        clone => [ \&cmd_clone, "Initialize and fetch revisions",
 116                        { 'revision|r=s' => \$_revision,
 117                           %fc_opts, %init_opts } ],
 118        init => [ \&cmd_init, "Initialize a repo for tracking" .
 119                          " (requires URL argument)",
 120                          \%init_opts ],
 121        'multi-init' => [ \&cmd_multi_init,
 122                          "Deprecated alias for ".
 123                          "'$0 init -T<trunk> -b<branches> -t<tags>'",
 124                          \%init_opts ],
 125        dcommit => [ \&cmd_dcommit,
 126                     'Commit several diffs to merge with upstream',
 127                        { 'merge|m|M' => \$_merge,
 128                          'strategy|s=s' => \$_strategy,
 129                          'verbose|v' => \$_verbose,
 130                          'dry-run|n' => \$_dry_run,
 131                          'fetch-all|all' => \$_fetch_all,
 132                          'commit-url=s' => \$_commit_url,
 133                          'revision|r=i' => \$_revision,
 134                          'no-rebase' => \$_no_rebase,
 135                        %cmt_opts, %fc_opts } ],
 136        branch => [ \&cmd_branch,
 137                    'Create a branch in the SVN repository',
 138                    { 'message|m=s' => \$_message,
 139                      'dry-run|n' => \$_dry_run,
 140                      'tag|t' => \$_tag } ],
 141        tag => [ sub { $_tag = 1; cmd_branch(@_) },
 142                 'Create a tag in the SVN repository',
 143                 { 'message|m=s' => \$_message,
 144                   'dry-run|n' => \$_dry_run } ],
 145        'set-tree' => [ \&cmd_set_tree,
 146                        "Set an SVN repository to a git tree-ish",
 147                        { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 148        'create-ignore' => [ \&cmd_create_ignore,
 149                             'Create a .gitignore per svn:ignore',
 150                             { 'revision|r=i' => \$_revision
 151                             } ],
 152        'propget' => [ \&cmd_propget,
 153                       'Print the value of a property on a file or directory',
 154                       { 'revision|r=i' => \$_revision } ],
 155        'proplist' => [ \&cmd_proplist,
 156                       'List all properties of a file or directory',
 157                       { 'revision|r=i' => \$_revision } ],
 158        'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 159                        { 'revision|r=i' => \$_revision
 160                        } ],
 161        'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 162                        { 'revision|r=i' => \$_revision
 163                        } ],
 164        'multi-fetch' => [ \&cmd_multi_fetch,
 165                           "Deprecated alias for $0 fetch --all",
 166                           { 'revision|r=s' => \$_revision, %fc_opts } ],
 167        'migrate' => [ sub { },
 168                       # no-op, we automatically run this anyways,
 169                       'Migrate configuration/metadata/layout from
 170                        previous versions of git-svn',
 171                       { 'minimize' => \$Git::SVN::Migration::_minimize,
 172                         %remote_opts } ],
 173        'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 174                        { 'limit=i' => \$Git::SVN::Log::limit,
 175                          'revision|r=s' => \$_revision,
 176                          'verbose|v' => \$Git::SVN::Log::verbose,
 177                          'incremental' => \$Git::SVN::Log::incremental,
 178                          'oneline' => \$Git::SVN::Log::oneline,
 179                          'show-commit' => \$Git::SVN::Log::show_commit,
 180                          'non-recursive' => \$Git::SVN::Log::non_recursive,
 181                          'authors-file|A=s' => \$_authors,
 182                          'color' => \$Git::SVN::Log::color,
 183                          'pager=s' => \$Git::SVN::Log::pager
 184                        } ],
 185        'find-rev' => [ \&cmd_find_rev,
 186                        "Translate between SVN revision numbers and tree-ish",
 187                        {} ],
 188        'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 189                        { 'merge|m|M' => \$_merge,
 190                          'verbose|v' => \$_verbose,
 191                          'strategy|s=s' => \$_strategy,
 192                          'local|l' => \$_local,
 193                          'fetch-all|all' => \$_fetch_all,
 194                          'dry-run|n' => \$_dry_run,
 195                          %fc_opts } ],
 196        'commit-diff' => [ \&cmd_commit_diff,
 197                           'Commit a diff between two trees',
 198                        { 'message|m=s' => \$_message,
 199                          'file|F=s' => \$_file,
 200                          'revision|r=s' => \$_revision,
 201                        %cmt_opts } ],
 202        'info' => [ \&cmd_info,
 203                    "Show info about the latest SVN revision
 204                     on the current branch",
 205                    { 'url' => \$_url, } ],
 206        'blame' => [ \&Git::SVN::Log::cmd_blame,
 207                    "Show what revision and author last modified each line of a file",
 208                    { 'git-format' => \$_git_format } ],
 209);
 210
 211my $cmd;
 212for (my $i = 0; $i < @ARGV; $i++) {
 213        if (defined $cmd{$ARGV[$i]}) {
 214                $cmd = $ARGV[$i];
 215                splice @ARGV, $i, 1;
 216                last;
 217        }
 218};
 219
 220# make sure we're always running at the top-level working directory
 221unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 222        unless (-d $ENV{GIT_DIR}) {
 223                if ($git_dir_user_set) {
 224                        die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 225                            "but it is not a directory\n";
 226                }
 227                my $git_dir = delete $ENV{GIT_DIR};
 228                my $cdup = undef;
 229                git_cmd_try {
 230                        $cdup = command_oneline(qw/rev-parse --show-cdup/);
 231                        $git_dir = '.' unless ($cdup);
 232                        chomp $cdup if ($cdup);
 233                        $cdup = "." unless ($cdup && length $cdup);
 234                } "Already at toplevel, but $git_dir not found\n";
 235                chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 236                unless (-d $git_dir) {
 237                        die "$git_dir still not found after going to ",
 238                            "'$cdup'\n";
 239                }
 240                $ENV{GIT_DIR} = $git_dir;
 241        }
 242        $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 243}
 244
 245my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 246
 247read_repo_config(\%opts);
 248if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 249        Getopt::Long::Configure('pass_through');
 250}
 251my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 252                    'minimize-connections' => \$Git::SVN::Migration::_minimize,
 253                    'id|i=s' => \$Git::SVN::default_ref_id,
 254                    'svn-remote|remote|R=s' => sub {
 255                       $Git::SVN::no_reuse_existing = 1;
 256                       $Git::SVN::default_repo_id = $_[1] });
 257exit 1 if (!$rv && $cmd && $cmd ne 'log');
 258
 259usage(0) if $_help;
 260version() if $_version;
 261usage(1) unless defined $cmd;
 262load_authors() if $_authors;
 263
 264unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 265        Git::SVN::Migration::migration_check();
 266}
 267Git::SVN::init_vars();
 268eval {
 269        Git::SVN::verify_remotes_sanity();
 270        $cmd{$cmd}->[0]->(@ARGV);
 271};
 272fatal $@ if $@;
 273post_fetch_checkout();
 274exit 0;
 275
 276####################### primary functions ######################
 277sub usage {
 278        my $exit = shift || 0;
 279        my $fd = $exit ? \*STDERR : \*STDOUT;
 280        print $fd <<"";
 281git-svn - bidirectional operations between a single Subversion tree and git
 282Usage: git svn <command> [options] [arguments]\n
 283
 284        print $fd "Available commands:\n" unless $cmd;
 285
 286        foreach (sort keys %cmd) {
 287                next if $cmd && $cmd ne $_;
 288                next if /^multi-/; # don't show deprecated commands
 289                print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 290                foreach (sort keys %{$cmd{$_}->[2]}) {
 291                        # mixed-case options are for .git/config only
 292                        next if /[A-Z]/ && /^[a-z]+$/i;
 293                        # prints out arguments as they should be passed:
 294                        my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 295                        print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 296                                                        "--$_" : "-$_" }
 297                                                split /\|/,$_)," $x\n";
 298                }
 299        }
 300        print $fd <<"";
 301\nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 302arbitrary identifier if you're tracking multiple SVN branches/repositories in
 303one git repository and want to keep them separate.  See git-svn(1) for more
 304information.
 305
 306        exit $exit;
 307}
 308
 309sub version {
 310        print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 311        exit 0;
 312}
 313
 314sub do_git_init_db {
 315        unless (-d $ENV{GIT_DIR}) {
 316                my @init_db = ('init');
 317                push @init_db, "--template=$_template" if defined $_template;
 318                if (defined $_shared) {
 319                        if ($_shared =~ /[a-z]/) {
 320                                push @init_db, "--shared=$_shared";
 321                        } else {
 322                                push @init_db, "--shared";
 323                        }
 324                }
 325                command_noisy(@init_db);
 326                $_repository = Git->repository(Repository => ".git");
 327        }
 328        my $set;
 329        my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 330        foreach my $i (keys %icv) {
 331                die "'$set' and '$i' cannot both be set\n" if $set;
 332                next unless defined $icv{$i};
 333                command_noisy('config', "$pfx.$i", $icv{$i});
 334                $set = $i;
 335        }
 336}
 337
 338sub init_subdir {
 339        my $repo_path = shift or return;
 340        mkpath([$repo_path]) unless -d $repo_path;
 341        chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 342        $ENV{GIT_DIR} = '.git';
 343        $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 344}
 345
 346sub cmd_clone {
 347        my ($url, $path) = @_;
 348        if (!defined $path &&
 349            (defined $_trunk || defined $_branches || defined $_tags ||
 350             defined $_stdlayout) &&
 351            $url !~ m#^[a-z\+]+://#) {
 352                $path = $url;
 353        }
 354        $path = basename($url) if !defined $path || !length $path;
 355        cmd_init($url, $path);
 356        Git::SVN::fetch_all($Git::SVN::default_repo_id);
 357}
 358
 359sub cmd_init {
 360        if (defined $_stdlayout) {
 361                $_trunk = 'trunk' if (!defined $_trunk);
 362                $_tags = 'tags' if (!defined $_tags);
 363                $_branches = 'branches' if (!defined $_branches);
 364        }
 365        if (defined $_trunk || defined $_branches || defined $_tags) {
 366                return cmd_multi_init(@_);
 367        }
 368        my $url = shift or die "SVN repository location required ",
 369                               "as a command-line argument\n";
 370        init_subdir(@_);
 371        do_git_init_db();
 372
 373        Git::SVN->init($url);
 374}
 375
 376sub cmd_fetch {
 377        if (grep /^\d+=./, @_) {
 378                die "'<rev>=<commit>' fetch arguments are ",
 379                    "no longer supported.\n";
 380        }
 381        my ($remote) = @_;
 382        if (@_ > 1) {
 383                die "Usage: $0 fetch [--all] [svn-remote]\n";
 384        }
 385        $remote ||= $Git::SVN::default_repo_id;
 386        if ($_fetch_all) {
 387                cmd_multi_fetch();
 388        } else {
 389                Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 390        }
 391}
 392
 393sub cmd_set_tree {
 394        my (@commits) = @_;
 395        if ($_stdin || !@commits) {
 396                print "Reading from stdin...\n";
 397                @commits = ();
 398                while (<STDIN>) {
 399                        if (/\b($sha1_short)\b/o) {
 400                                unshift @commits, $1;
 401                        }
 402                }
 403        }
 404        my @revs;
 405        foreach my $c (@commits) {
 406                my @tmp = command('rev-parse',$c);
 407                if (scalar @tmp == 1) {
 408                        push @revs, $tmp[0];
 409                } elsif (scalar @tmp > 1) {
 410                        push @revs, reverse(command('rev-list',@tmp));
 411                } else {
 412                        fatal "Failed to rev-parse $c";
 413                }
 414        }
 415        my $gs = Git::SVN->new;
 416        my ($r_last, $cmt_last) = $gs->last_rev_commit;
 417        $gs->fetch;
 418        if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 419                fatal "There are new revisions that were fetched ",
 420                      "and need to be merged (or acknowledged) ",
 421                      "before committing.\nlast rev: $r_last\n",
 422                      " current: $gs->{last_rev}";
 423        }
 424        $gs->set_tree($_) foreach @revs;
 425        print "Done committing ",scalar @revs," revisions to SVN\n";
 426        unlink $gs->{index};
 427}
 428
 429sub cmd_dcommit {
 430        my $head = shift;
 431        git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 432                'Cannot dcommit with a dirty index.  Commit your changes first, '
 433                . "or stash them with `git stash'.\n";
 434        $head ||= 'HEAD';
 435        my @refs;
 436        my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
 437        unless ($gs) {
 438                die "Unable to determine upstream SVN information from ",
 439                    "$head history.\nPerhaps the repository is empty.";
 440        }
 441
 442        if (defined $_commit_url) {
 443                $url = $_commit_url;
 444        } else {
 445                $url = eval { command_oneline('config', '--get',
 446                              "svn-remote.$gs->{repo_id}.commiturl") };
 447                if (!$url) {
 448                        $url = $gs->full_url
 449                }
 450        }
 451
 452        my $last_rev = $_revision if defined $_revision;
 453        if ($url) {
 454                print "Committing to $url ...\n";
 455        }
 456        my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 457        if ($_no_rebase && scalar(@$linear_refs) > 1) {
 458                warn "Attempting to commit more than one change while ",
 459                     "--no-rebase is enabled.\n",
 460                     "If these changes depend on each other, re-running ",
 461                     "without --no-rebase may be required."
 462        }
 463        my $expect_url = $url;
 464        Git::SVN::remove_username($expect_url);
 465        while (1) {
 466                my $d = shift @$linear_refs or last;
 467                unless (defined $last_rev) {
 468                        (undef, $last_rev, undef) = cmt_metadata("$d~1");
 469                        unless (defined $last_rev) {
 470                                fatal "Unable to extract revision information ",
 471                                      "from commit $d~1";
 472                        }
 473                }
 474                if ($_dry_run) {
 475                        print "diff-tree $d~1 $d\n";
 476                } else {
 477                        my $cmt_rev;
 478                        my %ed_opts = ( r => $last_rev,
 479                                        log => get_commit_entry($d)->{log},
 480                                        ra => Git::SVN::Ra->new($url),
 481                                        config => SVN::Core::config_get_config(
 482                                                $Git::SVN::Ra::config_dir
 483                                        ),
 484                                        tree_a => "$d~1",
 485                                        tree_b => $d,
 486                                        editor_cb => sub {
 487                                               print "Committed r$_[0]\n";
 488                                               $cmt_rev = $_[0];
 489                                        },
 490                                        svn_path => '');
 491                        if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 492                                print "No changes\n$d~1 == $d\n";
 493                        } elsif ($parents->{$d} && @{$parents->{$d}}) {
 494                                $gs->{inject_parents_dcommit}->{$cmt_rev} =
 495                                                               $parents->{$d};
 496                        }
 497                        $_fetch_all ? $gs->fetch_all : $gs->fetch;
 498                        $last_rev = $cmt_rev;
 499                        next if $_no_rebase;
 500
 501                        # we always want to rebase against the current HEAD,
 502                        # not any head that was passed to us
 503                        my @diff = command('diff-tree', $d,
 504                                           $gs->refname, '--');
 505                        my @finish;
 506                        if (@diff) {
 507                                @finish = rebase_cmd();
 508                                print STDERR "W: $d and ", $gs->refname,
 509                                             " differ, using @finish:\n",
 510                                             join("\n", @diff), "\n";
 511                        } else {
 512                                print "No changes between current HEAD and ",
 513                                      $gs->refname,
 514                                      "\nResetting to the latest ",
 515                                      $gs->refname, "\n";
 516                                @finish = qw/reset --mixed/;
 517                        }
 518                        command_noisy(@finish, $gs->refname);
 519                        if (@diff) {
 520                                @refs = ();
 521                                my ($url_, $rev_, $uuid_, $gs_) =
 522                                              working_head_info($head, \@refs);
 523                                my ($linear_refs_, $parents_) =
 524                                              linearize_history($gs_, \@refs);
 525                                if (scalar(@$linear_refs) !=
 526                                    scalar(@$linear_refs_)) {
 527                                        fatal "# of revisions changed ",
 528                                          "\nbefore:\n",
 529                                          join("\n", @$linear_refs),
 530                                          "\n\nafter:\n",
 531                                          join("\n", @$linear_refs_), "\n",
 532                                          'If you are attempting to commit ',
 533                                          "merges, try running:\n\t",
 534                                          'git rebase --interactive',
 535                                          '--preserve-merges ',
 536                                          $gs->refname,
 537                                          "\nBefore dcommitting";
 538                                }
 539                                if ($url_ ne $expect_url) {
 540                                        fatal "URL mismatch after rebase: ",
 541                                              "$url_ != $expect_url";
 542                                }
 543                                if ($uuid_ ne $uuid) {
 544                                        fatal "uuid mismatch after rebase: ",
 545                                              "$uuid_ != $uuid";
 546                                }
 547                                # remap parents
 548                                my (%p, @l, $i);
 549                                for ($i = 0; $i < scalar @$linear_refs; $i++) {
 550                                        my $new = $linear_refs_->[$i] or next;
 551                                        $p{$new} =
 552                                                $parents->{$linear_refs->[$i]};
 553                                        push @l, $new;
 554                                }
 555                                $parents = \%p;
 556                                $linear_refs = \@l;
 557                        }
 558                }
 559        }
 560        unlink $gs->{index};
 561}
 562
 563sub cmd_branch {
 564        my ($branch_name, $head) = @_;
 565
 566        unless (defined $branch_name && length $branch_name) {
 567                die(($_tag ? "tag" : "branch") . " name required\n");
 568        }
 569        $head ||= 'HEAD';
 570
 571        my ($src, $rev, undef, $gs) = working_head_info($head);
 572
 573        my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 574        my $glob = $remote->{ $_tag ? 'tags' : 'branches' };
 575        my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 576        my $dst = join '/', $remote->{url}, $lft, $branch_name, ($rgt || ());
 577
 578        my $ctx = SVN::Client->new(
 579                auth    => Git::SVN::Ra::_auth_providers(),
 580                log_msg => sub {
 581                        ${ $_[0] } = defined $_message
 582                                ? $_message
 583                                : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 584                                . $branch_name;
 585                },
 586        );
 587
 588        eval {
 589                $ctx->ls($dst, 'HEAD', 0);
 590        } and die "branch ${branch_name} already exists\n";
 591
 592        print "Copying ${src} at r${rev} to ${dst}...\n";
 593        $ctx->copy($src, $rev, $dst)
 594                unless $_dry_run;
 595
 596        $gs->fetch_all;
 597}
 598
 599sub cmd_find_rev {
 600        my $revision_or_hash = shift or die "SVN or git revision required ",
 601                                            "as a command-line argument\n";
 602        my $result;
 603        if ($revision_or_hash =~ /^r\d+$/) {
 604                my $head = shift;
 605                $head ||= 'HEAD';
 606                my @refs;
 607                my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 608                unless ($gs) {
 609                        die "Unable to determine upstream SVN information from ",
 610                            "$head history\n";
 611                }
 612                my $desired_revision = substr($revision_or_hash, 1);
 613                $result = $gs->rev_map_get($desired_revision, $uuid);
 614        } else {
 615                my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 616                $result = $rev;
 617        }
 618        print "$result\n" if $result;
 619}
 620
 621sub cmd_rebase {
 622        command_noisy(qw/update-index --refresh/);
 623        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 624        unless ($gs) {
 625                die "Unable to determine upstream SVN information from ",
 626                    "working tree history\n";
 627        }
 628        if ($_dry_run) {
 629                print "Remote Branch: " . $gs->refname . "\n";
 630                print "SVN URL: " . $url . "\n";
 631                return;
 632        }
 633        if (command(qw/diff-index HEAD --/)) {
 634                print STDERR "Cannot rebase with uncommited changes:\n";
 635                command_noisy('status');
 636                exit 1;
 637        }
 638        unless ($_local) {
 639                # rebase will checkout for us, so no need to do it explicitly
 640                $_no_checkout = 'true';
 641                $_fetch_all ? $gs->fetch_all : $gs->fetch;
 642        }
 643        command_noisy(rebase_cmd(), $gs->refname);
 644}
 645
 646sub cmd_show_ignore {
 647        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 648        $gs ||= Git::SVN->new;
 649        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 650        $gs->prop_walk($gs->{path}, $r, sub {
 651                my ($gs, $path, $props) = @_;
 652                print STDOUT "\n# $path\n";
 653                my $s = $props->{'svn:ignore'} or return;
 654                $s =~ s/[\r\n]+/\n/g;
 655                chomp $s;
 656                $s =~ s#^#$path#gm;
 657                print STDOUT "$s\n";
 658        });
 659}
 660
 661sub cmd_show_externals {
 662        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 663        $gs ||= Git::SVN->new;
 664        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 665        $gs->prop_walk($gs->{path}, $r, sub {
 666                my ($gs, $path, $props) = @_;
 667                print STDOUT "\n# $path\n";
 668                my $s = $props->{'svn:externals'} or return;
 669                $s =~ s/[\r\n]+/\n/g;
 670                chomp $s;
 671                $s =~ s#^#$path#gm;
 672                print STDOUT "$s\n";
 673        });
 674}
 675
 676sub cmd_create_ignore {
 677        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 678        $gs ||= Git::SVN->new;
 679        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 680        $gs->prop_walk($gs->{path}, $r, sub {
 681                my ($gs, $path, $props) = @_;
 682                # $path is of the form /path/to/dir/
 683                $path = '.' . $path;
 684                # SVN can have attributes on empty directories,
 685                # which git won't track
 686                mkpath([$path]) unless -d $path;
 687                my $ignore = $path . '.gitignore';
 688                my $s = $props->{'svn:ignore'} or return;
 689                open(GITIGNORE, '>', $ignore)
 690                  or fatal("Failed to open `$ignore' for writing: $!");
 691                $s =~ s/[\r\n]+/\n/g;
 692                chomp $s;
 693                # Prefix all patterns so that the ignore doesn't apply
 694                # to sub-directories.
 695                $s =~ s#^#/#gm;
 696                print GITIGNORE "$s\n";
 697                close(GITIGNORE)
 698                  or fatal("Failed to close `$ignore': $!");
 699                command_noisy('add', '-f', $ignore);
 700        });
 701}
 702
 703sub canonicalize_path {
 704        my ($path) = @_;
 705        my $dot_slash_added = 0;
 706        if (substr($path, 0, 1) ne "/") {
 707                $path = "./" . $path;
 708                $dot_slash_added = 1;
 709        }
 710        # File::Spec->canonpath doesn't collapse x/../y into y (for a
 711        # good reason), so let's do this manually.
 712        $path =~ s#/+#/#g;
 713        $path =~ s#/\.(?:/|$)#/#g;
 714        $path =~ s#/[^/]+/\.\.##g;
 715        $path =~ s#/$##g;
 716        $path =~ s#^\./## if $dot_slash_added;
 717        $path =~ s#^/##;
 718        $path =~ s#^\.$##;
 719        return $path;
 720}
 721
 722# get_svnprops(PATH)
 723# ------------------
 724# Helper for cmd_propget and cmd_proplist below.
 725sub get_svnprops {
 726        my $path = shift;
 727        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 728        $gs ||= Git::SVN->new;
 729
 730        # prefix THE PATH by the sub-directory from which the user
 731        # invoked us.
 732        $path = $cmd_dir_prefix . $path;
 733        fatal("No such file or directory: $path") unless -e $path;
 734        my $is_dir = -d $path ? 1 : 0;
 735        $path = $gs->{path} . '/' . $path;
 736
 737        # canonicalize the path (otherwise libsvn will abort or fail to
 738        # find the file)
 739        $path = canonicalize_path($path);
 740
 741        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 742        my $props;
 743        if ($is_dir) {
 744                (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 745        }
 746        else {
 747                (undef, $props) = $gs->ra->get_file($path, $r, undef);
 748        }
 749        return $props;
 750}
 751
 752# cmd_propget (PROP, PATH)
 753# ------------------------
 754# Print the SVN property PROP for PATH.
 755sub cmd_propget {
 756        my ($prop, $path) = @_;
 757        $path = '.' if not defined $path;
 758        usage(1) if not defined $prop;
 759        my $props = get_svnprops($path);
 760        if (not defined $props->{$prop}) {
 761                fatal("`$path' does not have a `$prop' SVN property.");
 762        }
 763        print $props->{$prop} . "\n";
 764}
 765
 766# cmd_proplist (PATH)
 767# -------------------
 768# Print the list of SVN properties for PATH.
 769sub cmd_proplist {
 770        my $path = shift;
 771        $path = '.' if not defined $path;
 772        my $props = get_svnprops($path);
 773        print "Properties on '$path':\n";
 774        foreach (sort keys %{$props}) {
 775                print "  $_\n";
 776        }
 777}
 778
 779sub cmd_multi_init {
 780        my $url = shift;
 781        unless (defined $_trunk || defined $_branches || defined $_tags) {
 782                usage(1);
 783        }
 784
 785        # there are currently some bugs that prevent multi-init/multi-fetch
 786        # setups from working well without this.
 787        $Git::SVN::_minimize_url = 1;
 788
 789        $_prefix = '' unless defined $_prefix;
 790        if (defined $url) {
 791                $url =~ s#/+$##;
 792                init_subdir(@_);
 793        }
 794        do_git_init_db();
 795        if (defined $_trunk) {
 796                my $trunk_ref = $_prefix . 'trunk';
 797                # try both old-style and new-style lookups:
 798                my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 799                unless ($gs_trunk) {
 800                        my ($trunk_url, $trunk_path) =
 801                                              complete_svn_url($url, $_trunk);
 802                        $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 803                                                   undef, $trunk_ref);
 804                }
 805        }
 806        return unless defined $_branches || defined $_tags;
 807        my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 808        complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 809        complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 810}
 811
 812sub cmd_multi_fetch {
 813        my $remotes = Git::SVN::read_all_remotes();
 814        foreach my $repo_id (sort keys %$remotes) {
 815                if ($remotes->{$repo_id}->{url}) {
 816                        Git::SVN::fetch_all($repo_id, $remotes);
 817                }
 818        }
 819}
 820
 821# this command is special because it requires no metadata
 822sub cmd_commit_diff {
 823        my ($ta, $tb, $url) = @_;
 824        my $usage = "Usage: $0 commit-diff -r<revision> ".
 825                    "<tree-ish> <tree-ish> [<URL>]";
 826        fatal($usage) if (!defined $ta || !defined $tb);
 827        my $svn_path = '';
 828        if (!defined $url) {
 829                my $gs = eval { Git::SVN->new };
 830                if (!$gs) {
 831                        fatal("Needed URL or usable git-svn --id in ",
 832                              "the command-line\n", $usage);
 833                }
 834                $url = $gs->{url};
 835                $svn_path = $gs->{path};
 836        }
 837        unless (defined $_revision) {
 838                fatal("-r|--revision is a required argument\n", $usage);
 839        }
 840        if (defined $_message && defined $_file) {
 841                fatal("Both --message/-m and --file/-F specified ",
 842                      "for the commit message.\n",
 843                      "I have no idea what you mean");
 844        }
 845        if (defined $_file) {
 846                $_message = file_to_s($_file);
 847        } else {
 848                $_message ||= get_commit_entry($tb)->{log};
 849        }
 850        my $ra ||= Git::SVN::Ra->new($url);
 851        my $r = $_revision;
 852        if ($r eq 'HEAD') {
 853                $r = $ra->get_latest_revnum;
 854        } elsif ($r !~ /^\d+$/) {
 855                die "revision argument: $r not understood by git-svn\n";
 856        }
 857        my %ed_opts = ( r => $r,
 858                        log => $_message,
 859                        ra => $ra,
 860                        tree_a => $ta,
 861                        tree_b => $tb,
 862                        editor_cb => sub { print "Committed r$_[0]\n" },
 863                        svn_path => $svn_path );
 864        if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 865                print "No changes\n$ta == $tb\n";
 866        }
 867}
 868
 869sub escape_uri_only {
 870        my ($uri) = @_;
 871        my @tmp;
 872        foreach (split m{/}, $uri) {
 873                s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
 874                push @tmp, $_;
 875        }
 876        join('/', @tmp);
 877}
 878
 879sub escape_url {
 880        my ($url) = @_;
 881        if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
 882                my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
 883                $url = "$scheme://$domain$uri";
 884        }
 885        $url;
 886}
 887
 888sub cmd_info {
 889        my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
 890        my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
 891        if (exists $_[1]) {
 892                die "Too many arguments specified\n";
 893        }
 894
 895        my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
 896
 897        if (!$file_type && !$diff_status) {
 898                print STDERR "svn: '$path' is not under version control\n";
 899                exit 1;
 900        }
 901
 902        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 903        unless ($gs) {
 904                die "Unable to determine upstream SVN information from ",
 905                    "working tree history\n";
 906        }
 907
 908        # canonicalize_path() will return "" to make libsvn 1.5.x happy,
 909        $path = "." if $path eq "";
 910
 911        my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
 912
 913        if ($_url) {
 914                print escape_url($full_url), "\n";
 915                return;
 916        }
 917
 918        my $result = "Path: $path\n";
 919        $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
 920        $result .= "URL: " . escape_url($full_url) . "\n";
 921
 922        eval {
 923                my $repos_root = $gs->repos_root;
 924                Git::SVN::remove_username($repos_root);
 925                $result .= "Repository Root: " . escape_url($repos_root) . "\n";
 926        };
 927        if ($@) {
 928                $result .= "Repository Root: (offline)\n";
 929        }
 930        $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
 931                ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
 932        $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
 933
 934        $result .= "Node Kind: " .
 935                   ($file_type eq "dir" ? "directory" : "file") . "\n";
 936
 937        my $schedule = $diff_status eq "A"
 938                       ? "add"
 939                       : ($diff_status eq "D" ? "delete" : "normal");
 940        $result .= "Schedule: $schedule\n";
 941
 942        if ($diff_status eq "A") {
 943                print $result, "\n";
 944                return;
 945        }
 946
 947        my ($lc_author, $lc_rev, $lc_date_utc);
 948        my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
 949        my $log = command_output_pipe(@args);
 950        my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
 951        while (<$log>) {
 952                if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
 953                        $lc_author = $1;
 954                        $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
 955                } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
 956                        (undef, $lc_rev, undef) = ::extract_metadata($1);
 957                }
 958        }
 959        close $log;
 960
 961        Git::SVN::Log::set_local_timezone();
 962
 963        $result .= "Last Changed Author: $lc_author\n";
 964        $result .= "Last Changed Rev: $lc_rev\n";
 965        $result .= "Last Changed Date: " .
 966                   Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
 967
 968        if ($file_type ne "dir") {
 969                my $text_last_updated_date =
 970                    ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
 971                $result .=
 972                    "Text Last Updated: " .
 973                    Git::SVN::Log::format_svn_date($text_last_updated_date) .
 974                    "\n";
 975                my $checksum;
 976                if ($diff_status eq "D") {
 977                        my ($fh, $ctx) =
 978                            command_output_pipe(qw(cat-file blob), "HEAD:$path");
 979                        if ($file_type eq "link") {
 980                                my $file_name = <$fh>;
 981                                $checksum = md5sum("link $file_name");
 982                        } else {
 983                                $checksum = md5sum($fh);
 984                        }
 985                        command_close_pipe($fh, $ctx);
 986                } elsif ($file_type eq "link") {
 987                        my $file_name =
 988                            command(qw(cat-file blob), "HEAD:$path");
 989                        $checksum =
 990                            md5sum("link " . $file_name);
 991                } else {
 992                        open FILE, "<", $path or die $!;
 993                        $checksum = md5sum(\*FILE);
 994                        close FILE or die $!;
 995                }
 996                $result .= "Checksum: " . $checksum . "\n";
 997        }
 998
 999        print $result, "\n";
1000}
1001
1002########################### utility functions #########################
1003
1004sub rebase_cmd {
1005        my @cmd = qw/rebase/;
1006        push @cmd, '-v' if $_verbose;
1007        push @cmd, qw/--merge/ if $_merge;
1008        push @cmd, "--strategy=$_strategy" if $_strategy;
1009        @cmd;
1010}
1011
1012sub post_fetch_checkout {
1013        return if $_no_checkout;
1014        my $gs = $Git::SVN::_head or return;
1015        return if verify_ref('refs/heads/master^0');
1016
1017        my $valid_head = verify_ref('HEAD^0');
1018        command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1019        return if ($valid_head || !verify_ref('HEAD^0'));
1020
1021        return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1022        my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1023        return if -f $index;
1024
1025        return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1026        return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1027        command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1028        print STDERR "Checked out HEAD:\n  ",
1029                     $gs->full_url, " r", $gs->last_rev, "\n";
1030}
1031
1032sub complete_svn_url {
1033        my ($url, $path) = @_;
1034        $path =~ s#/+$##;
1035        if ($path !~ m#^[a-z\+]+://#) {
1036                if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1037                        fatal("E: '$path' is not a complete URL ",
1038                              "and a separate URL is not specified");
1039                }
1040                return ($url, $path);
1041        }
1042        return ($path, '');
1043}
1044
1045sub complete_url_ls_init {
1046        my ($ra, $repo_path, $switch, $pfx) = @_;
1047        unless ($repo_path) {
1048                print STDERR "W: $switch not specified\n";
1049                return;
1050        }
1051        $repo_path =~ s#/+$##;
1052        if ($repo_path =~ m#^[a-z\+]+://#) {
1053                $ra = Git::SVN::Ra->new($repo_path);
1054                $repo_path = '';
1055        } else {
1056                $repo_path =~ s#^/+##;
1057                unless ($ra) {
1058                        fatal("E: '$repo_path' is not a complete URL ",
1059                              "and a separate URL is not specified");
1060                }
1061        }
1062        my $url = $ra->{url};
1063        my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1064        my $k = "svn-remote.$gs->{repo_id}.url";
1065        my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1066        if ($orig_url && ($orig_url ne $gs->{url})) {
1067                die "$k already set: $orig_url\n",
1068                    "wanted to set to: $gs->{url}\n";
1069        }
1070        command_oneline('config', $k, $gs->{url}) unless $orig_url;
1071        my $remote_path = "$ra->{svn_path}/$repo_path";
1072        $remote_path =~ s#/+#/#g;
1073        $remote_path =~ s#^/##g;
1074        $remote_path .= "/*" if $remote_path !~ /\*/;
1075        my ($n) = ($switch =~ /^--(\w+)/);
1076        if (length $pfx && $pfx !~ m#/$#) {
1077                die "--prefix='$pfx' must have a trailing slash '/'\n";
1078        }
1079        command_noisy('config',
1080                      "svn-remote.$gs->{repo_id}.$n",
1081                      "$remote_path:refs/remotes/$pfx*" .
1082                        ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1083}
1084
1085sub verify_ref {
1086        my ($ref) = @_;
1087        eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1088                               { STDERR => 0 }); };
1089}
1090
1091sub get_tree_from_treeish {
1092        my ($treeish) = @_;
1093        # $treeish can be a symbolic ref, too:
1094        my $type = command_oneline(qw/cat-file -t/, $treeish);
1095        my $expected;
1096        while ($type eq 'tag') {
1097                ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1098        }
1099        if ($type eq 'commit') {
1100                $expected = (grep /^tree /, command(qw/cat-file commit/,
1101                                                    $treeish))[0];
1102                ($expected) = ($expected =~ /^tree ($sha1)$/o);
1103                die "Unable to get tree from $treeish\n" unless $expected;
1104        } elsif ($type eq 'tree') {
1105                $expected = $treeish;
1106        } else {
1107                die "$treeish is a $type, expected tree, tag or commit\n";
1108        }
1109        return $expected;
1110}
1111
1112sub get_commit_entry {
1113        my ($treeish) = shift;
1114        my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1115        my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1116        my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1117        open my $log_fh, '>', $commit_editmsg or croak $!;
1118
1119        my $type = command_oneline(qw/cat-file -t/, $treeish);
1120        if ($type eq 'commit' || $type eq 'tag') {
1121                my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1122                                                         $type, $treeish);
1123                my $in_msg = 0;
1124                my $author;
1125                my $saw_from = 0;
1126                my $msgbuf = "";
1127                while (<$msg_fh>) {
1128                        if (!$in_msg) {
1129                                $in_msg = 1 if (/^\s*$/);
1130                                $author = $1 if (/^author (.*>)/);
1131                        } elsif (/^git-svn-id: /) {
1132                                # skip this for now, we regenerate the
1133                                # correct one on re-fetch anyways
1134                                # TODO: set *:merge properties or like...
1135                        } else {
1136                                if (/^From:/ || /^Signed-off-by:/) {
1137                                        $saw_from = 1;
1138                                }
1139                                $msgbuf .= $_;
1140                        }
1141                }
1142                $msgbuf =~ s/\s+$//s;
1143                if ($Git::SVN::_add_author_from && defined($author)
1144                    && !$saw_from) {
1145                        $msgbuf .= "\n\nFrom: $author";
1146                }
1147                print $log_fh $msgbuf or croak $!;
1148                command_close_pipe($msg_fh, $ctx);
1149        }
1150        close $log_fh or croak $!;
1151
1152        if ($_edit || ($type eq 'tree')) {
1153                my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1154                # TODO: strip out spaces, comments, like git-commit.sh
1155                system($editor, $commit_editmsg);
1156        }
1157        rename $commit_editmsg, $commit_msg or croak $!;
1158        {
1159                # SVN requires messages to be UTF-8 when entering the repo
1160                local $/;
1161                open $log_fh, '<', $commit_msg or croak $!;
1162                binmode $log_fh;
1163                chomp($log_entry{log} = <$log_fh>);
1164
1165                if (my $enc = Git::config('i18n.commitencoding')) {
1166                        require Encode;
1167                        Encode::from_to($log_entry{log}, $enc, 'UTF-8');
1168                }
1169                close $log_fh or croak $!;
1170        }
1171        unlink $commit_msg;
1172        \%log_entry;
1173}
1174
1175sub s_to_file {
1176        my ($str, $file, $mode) = @_;
1177        open my $fd,'>',$file or croak $!;
1178        print $fd $str,"\n" or croak $!;
1179        close $fd or croak $!;
1180        chmod ($mode &~ umask, $file) if (defined $mode);
1181}
1182
1183sub file_to_s {
1184        my $file = shift;
1185        open my $fd,'<',$file or croak "$!: file: $file\n";
1186        local $/;
1187        my $ret = <$fd>;
1188        close $fd or croak $!;
1189        $ret =~ s/\s*$//s;
1190        return $ret;
1191}
1192
1193# '<svn username> = real-name <email address>' mapping based on git-svnimport:
1194sub load_authors {
1195        open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1196        my $log = $cmd eq 'log';
1197        while (<$authors>) {
1198                chomp;
1199                next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1200                my ($user, $name, $email) = ($1, $2, $3);
1201                if ($log) {
1202                        $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1203                } else {
1204                        $users{$user} = [$name, $email];
1205                }
1206        }
1207        close $authors or croak $!;
1208}
1209
1210# convert GetOpt::Long specs for use by git-config
1211sub read_repo_config {
1212        return unless -d $ENV{GIT_DIR};
1213        my $opts = shift;
1214        my @config_only;
1215        foreach my $o (keys %$opts) {
1216                # if we have mixedCase and a long option-only, then
1217                # it's a config-only variable that we don't need for
1218                # the command-line.
1219                push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1220                my $v = $opts->{$o};
1221                my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1222                $key =~ s/-//g;
1223                my $arg = 'git config';
1224                $arg .= ' --int' if ($o =~ /[:=]i$/);
1225                $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1226                if (ref $v eq 'ARRAY') {
1227                        chomp(my @tmp = `$arg --get-all svn.$key`);
1228                        @$v = @tmp if @tmp;
1229                } else {
1230                        chomp(my $tmp = `$arg --get svn.$key`);
1231                        if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1232                                $$v = $tmp;
1233                        }
1234                }
1235        }
1236        delete @$opts{@config_only} if @config_only;
1237}
1238
1239sub extract_metadata {
1240        my $id = shift or return (undef, undef, undef);
1241        my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1242                                                        \s([a-f\d\-]+)$/x);
1243        if (!defined $rev || !$uuid || !$url) {
1244                # some of the original repositories I made had
1245                # identifiers like this:
1246                ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1247        }
1248        return ($url, $rev, $uuid);
1249}
1250
1251sub cmt_metadata {
1252        return extract_metadata((grep(/^git-svn-id: /,
1253                command(qw/cat-file commit/, shift)))[-1]);
1254}
1255
1256sub working_head_info {
1257        my ($head, $refs) = @_;
1258        my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1259        my ($fh, $ctx) = command_output_pipe(@args, $head);
1260        my $hash;
1261        my %max;
1262        while (<$fh>) {
1263                if ( m{^commit ($::sha1)$} ) {
1264                        unshift @$refs, $hash if $hash and $refs;
1265                        $hash = $1;
1266                        next;
1267                }
1268                next unless s{^\s*(git-svn-id:)}{$1};
1269                my ($url, $rev, $uuid) = extract_metadata($_);
1270                if (defined $url && defined $rev) {
1271                        next if $max{$url} and $max{$url} < $rev;
1272                        if (my $gs = Git::SVN->find_by_url($url)) {
1273                                my $c = $gs->rev_map_get($rev, $uuid);
1274                                if ($c && $c eq $hash) {
1275                                        close $fh; # break the pipe
1276                                        return ($url, $rev, $uuid, $gs);
1277                                } else {
1278                                        $max{$url} ||= $gs->rev_map_max;
1279                                }
1280                        }
1281                }
1282        }
1283        command_close_pipe($fh, $ctx);
1284        (undef, undef, undef, undef);
1285}
1286
1287sub read_commit_parents {
1288        my ($parents, $c) = @_;
1289        chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1290        $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1291        @{$parents->{$c}} = split(/ /, $p);
1292}
1293
1294sub linearize_history {
1295        my ($gs, $refs) = @_;
1296        my %parents;
1297        foreach my $c (@$refs) {
1298                read_commit_parents(\%parents, $c);
1299        }
1300
1301        my @linear_refs;
1302        my %skip = ();
1303        my $last_svn_commit = $gs->last_commit;
1304        foreach my $c (reverse @$refs) {
1305                next if $c eq $last_svn_commit;
1306                last if $skip{$c};
1307
1308                unshift @linear_refs, $c;
1309                $skip{$c} = 1;
1310
1311                # we only want the first parent to diff against for linear
1312                # history, we save the rest to inject when we finalize the
1313                # svn commit
1314                my $fp_a = verify_ref("$c~1");
1315                my $fp_b = shift @{$parents{$c}} if $parents{$c};
1316                if (!$fp_a || !$fp_b) {
1317                        die "Commit $c\n",
1318                            "has no parent commit, and therefore ",
1319                            "nothing to diff against.\n",
1320                            "You should be working from a repository ",
1321                            "originally created by git-svn\n";
1322                }
1323                if ($fp_a ne $fp_b) {
1324                        die "$c~1 = $fp_a, however parsing commit $c ",
1325                            "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1326                }
1327
1328                foreach my $p (@{$parents{$c}}) {
1329                        $skip{$p} = 1;
1330                }
1331        }
1332        (\@linear_refs, \%parents);
1333}
1334
1335sub find_file_type_and_diff_status {
1336        my ($path) = @_;
1337        return ('dir', '') if $path eq '';
1338
1339        my $diff_output =
1340            command_oneline(qw(diff --cached --name-status --), $path) || "";
1341        my $diff_status = (split(' ', $diff_output))[0] || "";
1342
1343        my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1344
1345        return (undef, undef) if !$diff_status && !$ls_tree;
1346
1347        if ($diff_status eq "A") {
1348                return ("link", $diff_status) if -l $path;
1349                return ("dir", $diff_status) if -d $path;
1350                return ("file", $diff_status);
1351        }
1352
1353        my $mode = (split(' ', $ls_tree))[0] || "";
1354
1355        return ("link", $diff_status) if $mode eq "120000";
1356        return ("dir", $diff_status) if $mode eq "040000";
1357        return ("file", $diff_status);
1358}
1359
1360sub md5sum {
1361        my $arg = shift;
1362        my $ref = ref $arg;
1363        my $md5 = Digest::MD5->new();
1364        if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1365                $md5->addfile($arg) or croak $!;
1366        } elsif ($ref eq 'SCALAR') {
1367                $md5->add($$arg) or croak $!;
1368        } elsif (!$ref) {
1369                $md5->add($arg) or croak $!;
1370        } else {
1371                ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1372        }
1373        return $md5->hexdigest();
1374}
1375
1376package Git::SVN;
1377use strict;
1378use warnings;
1379use Fcntl qw/:DEFAULT :seek/;
1380use constant rev_map_fmt => 'NH40';
1381use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1382            $_repack $_repack_flags $_use_svm_props $_head
1383            $_use_svnsync_props $no_reuse_existing $_minimize_url
1384            $_use_log_author $_add_author_from $_localtime/;
1385use Carp qw/croak/;
1386use File::Path qw/mkpath/;
1387use File::Copy qw/copy/;
1388use IPC::Open3;
1389
1390my ($_gc_nr, $_gc_period);
1391
1392# properties that we do not log:
1393my %SKIP_PROP;
1394BEGIN {
1395        %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1396                                        svn:special svn:executable
1397                                        svn:entry:committed-rev
1398                                        svn:entry:last-author
1399                                        svn:entry:uuid
1400                                        svn:entry:committed-date/;
1401
1402        # some options are read globally, but can be overridden locally
1403        # per [svn-remote "..."] section.  Command-line options will *NOT*
1404        # override options set in an [svn-remote "..."] section
1405        no strict 'refs';
1406        for my $option (qw/follow_parent no_metadata use_svm_props
1407                           use_svnsync_props/) {
1408                my $key = $option;
1409                $key =~ tr/_//d;
1410                my $prop = "-$option";
1411                *$option = sub {
1412                        my ($self) = @_;
1413                        return $self->{$prop} if exists $self->{$prop};
1414                        my $k = "svn-remote.$self->{repo_id}.$key";
1415                        eval { command_oneline(qw/config --get/, $k) };
1416                        if ($@) {
1417                                $self->{$prop} = ${"Git::SVN::_$option"};
1418                        } else {
1419                                my $v = command_oneline(qw/config --bool/,$k);
1420                                $self->{$prop} = $v eq 'false' ? 0 : 1;
1421                        }
1422                        return $self->{$prop};
1423                }
1424        }
1425}
1426
1427
1428my (%LOCKFILES, %INDEX_FILES);
1429END {
1430        unlink keys %LOCKFILES if %LOCKFILES;
1431        unlink keys %INDEX_FILES if %INDEX_FILES;
1432}
1433
1434sub resolve_local_globs {
1435        my ($url, $fetch, $glob_spec) = @_;
1436        return unless defined $glob_spec;
1437        my $ref = $glob_spec->{ref};
1438        my $path = $glob_spec->{path};
1439        foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1440                next unless m#^refs/remotes/$ref->{regex}$#;
1441                my $p = $1;
1442                my $pathname = desanitize_refname($path->full_path($p));
1443                my $refname = desanitize_refname($ref->full_path($p));
1444                if (my $existing = $fetch->{$pathname}) {
1445                        if ($existing ne $refname) {
1446                                die "Refspec conflict:\n",
1447                                    "existing: refs/remotes/$existing\n",
1448                                    " globbed: refs/remotes/$refname\n";
1449                        }
1450                        my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1451                        $u =~ s!^\Q$url\E(/|$)!! or die
1452                          "refs/remotes/$refname: '$url' not found in '$u'\n";
1453                        if ($pathname ne $u) {
1454                                warn "W: Refspec glob conflict ",
1455                                     "(ref: refs/remotes/$refname):\n",
1456                                     "expected path: $pathname\n",
1457                                     "    real path: $u\n",
1458                                     "Continuing ahead with $u\n";
1459                                next;
1460                        }
1461                } else {
1462                        $fetch->{$pathname} = $refname;
1463                }
1464        }
1465}
1466
1467sub parse_revision_argument {
1468        my ($base, $head) = @_;
1469        if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1470                return ($base, $head);
1471        }
1472        return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1473        return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1474        return ($head, $head) if ($::_revision eq 'HEAD');
1475        return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1476        return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1477        die "revision argument: $::_revision not understood by git-svn\n";
1478}
1479
1480sub fetch_all {
1481        my ($repo_id, $remotes) = @_;
1482        if (ref $repo_id) {
1483                my $gs = $repo_id;
1484                $repo_id = undef;
1485                $repo_id = $gs->{repo_id};
1486        }
1487        $remotes ||= read_all_remotes();
1488        my $remote = $remotes->{$repo_id} or
1489                     die "[svn-remote \"$repo_id\"] unknown\n";
1490        my $fetch = $remote->{fetch};
1491        my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1492        my (@gs, @globs);
1493        my $ra = Git::SVN::Ra->new($url);
1494        my $uuid = $ra->get_uuid;
1495        my $head = $ra->get_latest_revnum;
1496        my $base = defined $fetch ? $head : 0;
1497
1498        # read the max revs for wildcard expansion (branches/*, tags/*)
1499        foreach my $t (qw/branches tags/) {
1500                defined $remote->{$t} or next;
1501                push @globs, $remote->{$t};
1502                my $max_rev = eval { tmp_config(qw/--int --get/,
1503                                         "svn-remote.$repo_id.${t}-maxRev") };
1504                if (defined $max_rev && ($max_rev < $base)) {
1505                        $base = $max_rev;
1506                } elsif (!defined $max_rev) {
1507                        $base = 0;
1508                }
1509        }
1510
1511        if ($fetch) {
1512                foreach my $p (sort keys %$fetch) {
1513                        my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1514                        my $lr = $gs->rev_map_max;
1515                        if (defined $lr) {
1516                                $base = $lr if ($lr < $base);
1517                        }
1518                        push @gs, $gs;
1519                }
1520        }
1521
1522        ($base, $head) = parse_revision_argument($base, $head);
1523        $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1524}
1525
1526sub read_all_remotes {
1527        my $r = {};
1528        my $use_svm_props = eval { command_oneline(qw/config --bool
1529            svn.useSvmProps/) };
1530        $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1531        foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1532                if (m!^(.+)\.fetch=\s*(.*)\s*:\s*(.+)\s*$!) {
1533                        my ($remote, $local_ref, $_remote_ref) = ($1, $2, $3);
1534                        die("svn-remote.$remote: remote ref '$_remote_ref' "
1535                            . "must start with 'refs/remotes/'\n")
1536                                unless $_remote_ref =~ m{^refs/remotes/(.+)};
1537                        my $remote_ref = $1;
1538                        $local_ref =~ s{^/}{};
1539                        $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1540                        $r->{$remote}->{svm} = {} if $use_svm_props;
1541                } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1542                        $r->{$1}->{svm} = {};
1543                } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1544                        $r->{$1}->{url} = $2;
1545                } elsif (m!^(.+)\.(branches|tags)=
1546                           (.*):refs/remotes/(.+)\s*$/!x) {
1547                        my ($p, $g) = ($3, $4);
1548                        my $rs = $r->{$1}->{$2} = {
1549                                          t => $2,
1550                                          remote => $1,
1551                                          path => Git::SVN::GlobSpec->new($p),
1552                                          ref => Git::SVN::GlobSpec->new($g) };
1553                        if (length($rs->{ref}->{right}) != 0) {
1554                                die "The '*' glob character must be the last ",
1555                                    "character of '$g'\n";
1556                        }
1557                }
1558        }
1559
1560        map {
1561                if (defined $r->{$_}->{svm}) {
1562                        my $svm;
1563                        eval {
1564                                my $section = "svn-remote.$_";
1565                                $svm = {
1566                                        source => tmp_config('--get',
1567                                            "$section.svm-source"),
1568                                        replace => tmp_config('--get',
1569                                            "$section.svm-replace"),
1570                                }
1571                        };
1572                        $r->{$_}->{svm} = $svm;
1573                }
1574        } keys %$r;
1575
1576        $r;
1577}
1578
1579sub init_vars {
1580        $_gc_nr = $_gc_period = 1000;
1581        if (defined $_repack || defined $_repack_flags) {
1582               warn "Repack options are obsolete; they have no effect.\n";
1583        }
1584}
1585
1586sub verify_remotes_sanity {
1587        return unless -d $ENV{GIT_DIR};
1588        my %seen;
1589        foreach (command(qw/config -l/)) {
1590                if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1591                        if ($seen{$1}) {
1592                                die "Remote ref refs/remote/$1 is tracked by",
1593                                    "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1594                                    "Please resolve this ambiguity in ",
1595                                    "your git configuration file before ",
1596                                    "continuing\n";
1597                        }
1598                        $seen{$1} = $_;
1599                }
1600        }
1601}
1602
1603sub find_existing_remote {
1604        my ($url, $remotes) = @_;
1605        return undef if $no_reuse_existing;
1606        my $existing;
1607        foreach my $repo_id (keys %$remotes) {
1608                my $u = $remotes->{$repo_id}->{url} or next;
1609                next if $u ne $url;
1610                $existing = $repo_id;
1611                last;
1612        }
1613        $existing;
1614}
1615
1616sub init_remote_config {
1617        my ($self, $url, $no_write) = @_;
1618        $url =~ s!/+$!!; # strip trailing slash
1619        my $r = read_all_remotes();
1620        my $existing = find_existing_remote($url, $r);
1621        if ($existing) {
1622                unless ($no_write) {
1623                        print STDERR "Using existing ",
1624                                     "[svn-remote \"$existing\"]\n";
1625                }
1626                $self->{repo_id} = $existing;
1627        } elsif ($_minimize_url) {
1628                my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1629                $existing = find_existing_remote($min_url, $r);
1630                if ($existing) {
1631                        unless ($no_write) {
1632                                print STDERR "Using existing ",
1633                                             "[svn-remote \"$existing\"]\n";
1634                        }
1635                        $self->{repo_id} = $existing;
1636                }
1637                if ($min_url ne $url) {
1638                        unless ($no_write) {
1639                                print STDERR "Using higher level of URL: ",
1640                                             "$url => $min_url\n";
1641                        }
1642                        my $old_path = $self->{path};
1643                        $self->{path} = $url;
1644                        $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1645                        if (length $old_path) {
1646                                $self->{path} .= "/$old_path";
1647                        }
1648                        $url = $min_url;
1649                }
1650        }
1651        my $orig_url;
1652        if (!$existing) {
1653                # verify that we aren't overwriting anything:
1654                $orig_url = eval {
1655                        command_oneline('config', '--get',
1656                                        "svn-remote.$self->{repo_id}.url")
1657                };
1658                if ($orig_url && ($orig_url ne $url)) {
1659                        die "svn-remote.$self->{repo_id}.url already set: ",
1660                            "$orig_url\nwanted to set to: $url\n";
1661                }
1662        }
1663        my ($xrepo_id, $xpath) = find_ref($self->refname);
1664        if (defined $xpath) {
1665                die "svn-remote.$xrepo_id.fetch already set to track ",
1666                    "$xpath:refs/remotes/", $self->refname, "\n";
1667        }
1668        unless ($no_write) {
1669                command_noisy('config',
1670                              "svn-remote.$self->{repo_id}.url", $url);
1671                $self->{path} =~ s{^/}{};
1672                command_noisy('config', '--add',
1673                              "svn-remote.$self->{repo_id}.fetch",
1674                              "$self->{path}:".$self->refname);
1675        }
1676        $self->{url} = $url;
1677}
1678
1679sub find_by_url { # repos_root and, path are optional
1680        my ($class, $full_url, $repos_root, $path) = @_;
1681
1682        return undef unless defined $full_url;
1683        remove_username($full_url);
1684        remove_username($repos_root) if defined $repos_root;
1685        my $remotes = read_all_remotes();
1686        if (defined $full_url && defined $repos_root && !defined $path) {
1687                $path = $full_url;
1688                $path =~ s#^\Q$repos_root\E(?:/|$)##;
1689        }
1690        foreach my $repo_id (keys %$remotes) {
1691                my $u = $remotes->{$repo_id}->{url} or next;
1692                remove_username($u);
1693                next if defined $repos_root && $repos_root ne $u;
1694
1695                my $fetch = $remotes->{$repo_id}->{fetch} || {};
1696                foreach (qw/branches tags/) {
1697                        resolve_local_globs($u, $fetch,
1698                                            $remotes->{$repo_id}->{$_});
1699                }
1700                my $p = $path;
1701                my $rwr = rewrite_root({repo_id => $repo_id});
1702                my $svm = $remotes->{$repo_id}->{svm}
1703                        if defined $remotes->{$repo_id}->{svm};
1704                unless (defined $p) {
1705                        $p = $full_url;
1706                        my $z = $u;
1707                        my $prefix = '';
1708                        if ($rwr) {
1709                                $z = $rwr;
1710                                remove_username($z);
1711                        } elsif (defined $svm) {
1712                                $z = $svm->{source};
1713                                $prefix = $svm->{replace};
1714                                $prefix =~ s#^\Q$u\E(?:/|$)##;
1715                                $prefix =~ s#/$##;
1716                        }
1717                        $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
1718                }
1719                foreach my $f (keys %$fetch) {
1720                        next if $f ne $p;
1721                        return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1722                }
1723        }
1724        undef;
1725}
1726
1727sub init {
1728        my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1729        my $self = _new($class, $repo_id, $ref_id, $path);
1730        if (defined $url) {
1731                $self->init_remote_config($url, $no_write);
1732        }
1733        $self;
1734}
1735
1736sub find_ref {
1737        my ($ref_id) = @_;
1738        foreach (command(qw/config -l/)) {
1739                next unless m!^svn-remote\.(.+)\.fetch=
1740                              \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1741                my ($repo_id, $path, $ref) = ($1, $2, $3);
1742                if ($ref eq $ref_id) {
1743                        $path = '' if ($path =~ m#^\./?#);
1744                        return ($repo_id, $path);
1745                }
1746        }
1747        (undef, undef, undef);
1748}
1749
1750sub new {
1751        my ($class, $ref_id, $repo_id, $path) = @_;
1752        if (defined $ref_id && !defined $repo_id && !defined $path) {
1753                ($repo_id, $path) = find_ref($ref_id);
1754                if (!defined $repo_id) {
1755                        die "Could not find a \"svn-remote.*.fetch\" key ",
1756                            "in the repository configuration matching: ",
1757                            "refs/remotes/$ref_id\n";
1758                }
1759        }
1760        my $self = _new($class, $repo_id, $ref_id, $path);
1761        if (!defined $self->{path} || !length $self->{path}) {
1762                my $fetch = command_oneline('config', '--get',
1763                                            "svn-remote.$repo_id.fetch",
1764                                            ":refs/remotes/$ref_id\$") or
1765                     die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1766                         "\":refs/remotes/$ref_id\$\" in config\n";
1767                ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1768        }
1769        $self->{url} = command_oneline('config', '--get',
1770                                       "svn-remote.$repo_id.url") or
1771                  die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1772        $self->rebuild;
1773        $self;
1774}
1775
1776sub refname {
1777        my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1778
1779        # It cannot end with a slash /, we'll throw up on this because
1780        # SVN can't have directories with a slash in their name, either:
1781        if ($refname =~ m{/$}) {
1782                die "ref: '$refname' ends with a trailing slash, this is ",
1783                    "not permitted by git nor Subversion\n";
1784        }
1785
1786        # It cannot have ASCII control character space, tilde ~, caret ^,
1787        # colon :, question-mark ?, asterisk *, space, or open bracket [
1788        # anywhere.
1789        #
1790        # Additionally, % must be escaped because it is used for escaping
1791        # and we want our escaped refname to be reversible
1792        $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1793
1794        # no slash-separated component can begin with a dot .
1795        # /.* becomes /%2E*
1796        $refname =~ s{/\.}{/%2E}g;
1797
1798        # It cannot have two consecutive dots .. anywhere
1799        # .. becomes %2E%2E
1800        $refname =~ s{\.\.}{%2E%2E}g;
1801
1802        return $refname;
1803}
1804
1805sub desanitize_refname {
1806        my ($refname) = @_;
1807        $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1808        return $refname;
1809}
1810
1811sub svm_uuid {
1812        my ($self) = @_;
1813        return $self->{svm}->{uuid} if $self->svm;
1814        $self->ra;
1815        unless ($self->{svm}) {
1816                die "SVM UUID not cached, and reading remotely failed\n";
1817        }
1818        $self->{svm}->{uuid};
1819}
1820
1821sub svm {
1822        my ($self) = @_;
1823        return $self->{svm} if $self->{svm};
1824        my $svm;
1825        # see if we have it in our config, first:
1826        eval {
1827                my $section = "svn-remote.$self->{repo_id}";
1828                $svm = {
1829                  source => tmp_config('--get', "$section.svm-source"),
1830                  uuid => tmp_config('--get', "$section.svm-uuid"),
1831                  replace => tmp_config('--get', "$section.svm-replace"),
1832                }
1833        };
1834        if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1835                $self->{svm} = $svm;
1836        }
1837        $self->{svm};
1838}
1839
1840sub _set_svm_vars {
1841        my ($self, $ra) = @_;
1842        return $ra if $self->svm;
1843
1844        my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1845                    "(svm:source, svm:uuid) ",
1846                    "from the following URLs:\n" );
1847        sub read_svm_props {
1848                my ($self, $ra, $path, $r) = @_;
1849                my $props = ($ra->get_dir($path, $r))[2];
1850                my $src = $props->{'svm:source'};
1851                my $uuid = $props->{'svm:uuid'};
1852                return undef if (!$src || !$uuid);
1853
1854                chomp($src, $uuid);
1855
1856                $uuid =~ m{^[0-9a-f\-]{30,}$}
1857                    or die "doesn't look right - svm:uuid is '$uuid'\n";
1858
1859                # the '!' is used to mark the repos_root!/relative/path
1860                $src =~ s{/?!/?}{/};
1861                $src =~ s{/+$}{}; # no trailing slashes please
1862                # username is of no interest
1863                $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1864
1865                my $replace = $ra->{url};
1866                $replace .= "/$path" if length $path;
1867
1868                my $section = "svn-remote.$self->{repo_id}";
1869                tmp_config("$section.svm-source", $src);
1870                tmp_config("$section.svm-replace", $replace);
1871                tmp_config("$section.svm-uuid", $uuid);
1872                $self->{svm} = {
1873                        source => $src,
1874                        uuid => $uuid,
1875                        replace => $replace
1876                };
1877        }
1878
1879        my $r = $ra->get_latest_revnum;
1880        my $path = $self->{path};
1881        my %tried;
1882        while (length $path) {
1883                unless ($tried{"$self->{url}/$path"}) {
1884                        return $ra if $self->read_svm_props($ra, $path, $r);
1885                        $tried{"$self->{url}/$path"} = 1;
1886                }
1887                $path =~ s#/?[^/]+$##;
1888        }
1889        die "Path: '$path' should be ''\n" if $path ne '';
1890        return $ra if $self->read_svm_props($ra, $path, $r);
1891        $tried{"$self->{url}/$path"} = 1;
1892
1893        if ($ra->{repos_root} eq $self->{url}) {
1894                die @err, (map { "  $_\n" } keys %tried), "\n";
1895        }
1896
1897        # nope, make sure we're connected to the repository root:
1898        my $ok;
1899        my @tried_b;
1900        $path = $ra->{svn_path};
1901        $ra = Git::SVN::Ra->new($ra->{repos_root});
1902        while (length $path) {
1903                unless ($tried{"$ra->{url}/$path"}) {
1904                        $ok = $self->read_svm_props($ra, $path, $r);
1905                        last if $ok;
1906                        $tried{"$ra->{url}/$path"} = 1;
1907                }
1908                $path =~ s#/?[^/]+$##;
1909        }
1910        die "Path: '$path' should be ''\n" if $path ne '';
1911        $ok ||= $self->read_svm_props($ra, $path, $r);
1912        $tried{"$ra->{url}/$path"} = 1;
1913        if (!$ok) {
1914                die @err, (map { "  $_\n" } keys %tried), "\n";
1915        }
1916        Git::SVN::Ra->new($self->{url});
1917}
1918
1919sub svnsync {
1920        my ($self) = @_;
1921        return $self->{svnsync} if $self->{svnsync};
1922
1923        if ($self->no_metadata) {
1924                die "Can't have both 'noMetadata' and ",
1925                    "'useSvnsyncProps' options set!\n";
1926        }
1927        if ($self->rewrite_root) {
1928                die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1929                    "options set!\n";
1930        }
1931
1932        my $svnsync;
1933        # see if we have it in our config, first:
1934        eval {
1935                my $section = "svn-remote.$self->{repo_id}";
1936
1937                my $url = tmp_config('--get', "$section.svnsync-url");
1938                ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1939                   die "doesn't look right - svn:sync-from-url is '$url'\n";
1940
1941                my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1942                ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1943                   die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1944
1945                $svnsync = { url => $url, uuid => $uuid }
1946        };
1947        if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1948                return $self->{svnsync} = $svnsync;
1949        }
1950
1951        my $err = "useSvnsyncProps set, but failed to read " .
1952                  "svnsync property: svn:sync-from-";
1953        my $rp = $self->ra->rev_proplist(0);
1954
1955        my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1956        ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1957                   die "doesn't look right - svn:sync-from-url is '$url'\n";
1958
1959        my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1960        ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1961                   die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1962
1963        my $section = "svn-remote.$self->{repo_id}";
1964        tmp_config('--add', "$section.svnsync-uuid", $uuid);
1965        tmp_config('--add', "$section.svnsync-url", $url);
1966        return $self->{svnsync} = { url => $url, uuid => $uuid };
1967}
1968
1969# this allows us to memoize our SVN::Ra UUID locally and avoid a
1970# remote lookup (useful for 'git svn log').
1971sub ra_uuid {
1972        my ($self) = @_;
1973        unless ($self->{ra_uuid}) {
1974                my $key = "svn-remote.$self->{repo_id}.uuid";
1975                my $uuid = eval { tmp_config('--get', $key) };
1976                if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1977                        $self->{ra_uuid} = $uuid;
1978                } else {
1979                        die "ra_uuid called without URL\n" unless $self->{url};
1980                        $self->{ra_uuid} = $self->ra->get_uuid;
1981                        tmp_config('--add', $key, $self->{ra_uuid});
1982                }
1983        }
1984        $self->{ra_uuid};
1985}
1986
1987sub _set_repos_root {
1988        my ($self, $repos_root) = @_;
1989        my $k = "svn-remote.$self->{repo_id}.reposRoot";
1990        $repos_root ||= $self->ra->{repos_root};
1991        tmp_config($k, $repos_root);
1992        $repos_root;
1993}
1994
1995sub repos_root {
1996        my ($self) = @_;
1997        my $k = "svn-remote.$self->{repo_id}.reposRoot";
1998        eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1999}
2000
2001sub ra {
2002        my ($self) = shift;
2003        my $ra = Git::SVN::Ra->new($self->{url});
2004        $self->_set_repos_root($ra->{repos_root});
2005        if ($self->use_svm_props && !$self->{svm}) {
2006                if ($self->no_metadata) {
2007                        die "Can't have both 'noMetadata' and ",
2008                            "'useSvmProps' options set!\n";
2009                } elsif ($self->use_svnsync_props) {
2010                        die "Can't have both 'useSvnsyncProps' and ",
2011                            "'useSvmProps' options set!\n";
2012                }
2013                $ra = $self->_set_svm_vars($ra);
2014                $self->{-want_revprops} = 1;
2015        }
2016        $ra;
2017}
2018
2019sub rel_path {
2020        my ($self) = @_;
2021        my $repos_root = $self->ra->{repos_root};
2022        return $self->{path} if ($self->{url} eq $repos_root);
2023        my $url = $self->{url} .
2024                  (length $self->{path} ? "/$self->{path}" : $self->{path});
2025        $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
2026        $url;
2027}
2028
2029# prop_walk(PATH, REV, SUB)
2030# -------------------------
2031# Recursively traverse PATH at revision REV and invoke SUB for each
2032# directory that contains a SVN property.  SUB will be invoked as
2033# follows:  &SUB(gs, path, props);  where `gs' is this instance of
2034# Git::SVN, `path' the path to the directory where the properties
2035# `props' were found.  The `path' will be relative to point of checkout,
2036# that is, if url://repo/trunk is the current Git branch, and that
2037# directory contains a sub-directory `d', SUB will be invoked with `/d/'
2038# as `path' (note the trailing `/').
2039sub prop_walk {
2040        my ($self, $path, $rev, $sub) = @_;
2041
2042        $path =~ s#^/##;
2043        my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2044        $path =~ s#^/*#/#g;
2045        my $p = $path;
2046        # Strip the irrelevant part of the path.
2047        $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2048        # Ensure the path is terminated by a `/'.
2049        $p =~ s#/*$#/#;
2050
2051        # The properties contain all the internal SVN stuff nobody
2052        # (usually) cares about.
2053        my $interesting_props = 0;
2054        foreach (keys %{$props}) {
2055                # If it doesn't start with `svn:', it must be a
2056                # user-defined property.
2057                ++$interesting_props and next if $_ !~ /^svn:/;
2058                # FIXME: Fragile, if SVN adds new public properties,
2059                # this needs to be updated.
2060                ++$interesting_props if /^svn:(?:ignore|keywords|executable
2061                                                 |eol-style|mime-type
2062                                                 |externals|needs-lock)$/x;
2063        }
2064        &$sub($self, $p, $props) if $interesting_props;
2065
2066        foreach (sort keys %$dirent) {
2067                next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2068                $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2069        }
2070}
2071
2072sub last_rev { ($_[0]->last_rev_commit)[0] }
2073sub last_commit { ($_[0]->last_rev_commit)[1] }
2074
2075# returns the newest SVN revision number and newest commit SHA1
2076sub last_rev_commit {
2077        my ($self) = @_;
2078        if (defined $self->{last_rev} && defined $self->{last_commit}) {
2079                return ($self->{last_rev}, $self->{last_commit});
2080        }
2081        my $c = ::verify_ref($self->refname.'^0');
2082        if ($c && !$self->use_svm_props && !$self->no_metadata) {
2083                my $rev = (::cmt_metadata($c))[1];
2084                if (defined $rev) {
2085                        ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2086                        return ($rev, $c);
2087                }
2088        }
2089        my $map_path = $self->map_path;
2090        unless (-e $map_path) {
2091                ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2092                return (undef, undef);
2093        }
2094        my ($rev, $commit) = $self->rev_map_max(1);
2095        ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2096        return ($rev, $commit);
2097}
2098
2099sub get_fetch_range {
2100        my ($self, $min, $max) = @_;
2101        $max ||= $self->ra->get_latest_revnum;
2102        $min ||= $self->rev_map_max;
2103        (++$min, $max);
2104}
2105
2106sub tmp_config {
2107        my (@args) = @_;
2108        my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2109        my $config = "$ENV{GIT_DIR}/svn/.metadata";
2110        if (! -f $config && -f $old_def_config) {
2111                rename $old_def_config, $config or
2112                       die "Failed rename $old_def_config => $config: $!\n";
2113        }
2114        my $old_config = $ENV{GIT_CONFIG};
2115        $ENV{GIT_CONFIG} = $config;
2116        $@ = undef;
2117        my @ret = eval {
2118                unless (-f $config) {
2119                        mkfile($config);
2120                        open my $fh, '>', $config or
2121                            die "Can't open $config: $!\n";
2122                        print $fh "; This file is used internally by ",
2123                                  "git-svn\n" or die
2124                                  "Couldn't write to $config: $!\n";
2125                        print $fh "; You should not have to edit it\n" or
2126                              die "Couldn't write to $config: $!\n";
2127                        close $fh or die "Couldn't close $config: $!\n";
2128                }
2129                command('config', @args);
2130        };
2131        my $err = $@;
2132        if (defined $old_config) {
2133                $ENV{GIT_CONFIG} = $old_config;
2134        } else {
2135                delete $ENV{GIT_CONFIG};
2136        }
2137        die $err if $err;
2138        wantarray ? @ret : $ret[0];
2139}
2140
2141sub tmp_index_do {
2142        my ($self, $sub) = @_;
2143        my $old_index = $ENV{GIT_INDEX_FILE};
2144        $ENV{GIT_INDEX_FILE} = $self->{index};
2145        $@ = undef;
2146        my @ret = eval {
2147                my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2148                mkpath([$dir]) unless -d $dir;
2149                &$sub;
2150        };
2151        my $err = $@;
2152        if (defined $old_index) {
2153                $ENV{GIT_INDEX_FILE} = $old_index;
2154        } else {
2155                delete $ENV{GIT_INDEX_FILE};
2156        }
2157        die $err if $err;
2158        wantarray ? @ret : $ret[0];
2159}
2160
2161sub assert_index_clean {
2162        my ($self, $treeish) = @_;
2163
2164        $self->tmp_index_do(sub {
2165                command_noisy('read-tree', $treeish) unless -e $self->{index};
2166                my $x = command_oneline('write-tree');
2167                my ($y) = (command(qw/cat-file commit/, $treeish) =~
2168                           /^tree ($::sha1)/mo);
2169                return if $y eq $x;
2170
2171                warn "Index mismatch: $y != $x\nrereading $treeish\n";
2172                unlink $self->{index} or die "unlink $self->{index}: $!\n";
2173                command_noisy('read-tree', $treeish);
2174                $x = command_oneline('write-tree');
2175                if ($y ne $x) {
2176                        ::fatal "trees ($treeish) $y != $x\n",
2177                                "Something is seriously wrong...";
2178                }
2179        });
2180}
2181
2182sub get_commit_parents {
2183        my ($self, $log_entry) = @_;
2184        my (%seen, @ret, @tmp);
2185        # legacy support for 'set-tree'; this is only used by set_tree_cb:
2186        if (my $ip = $self->{inject_parents}) {
2187                if (my $commit = delete $ip->{$log_entry->{revision}}) {
2188                        push @tmp, $commit;
2189                }
2190        }
2191        if (my $cur = ::verify_ref($self->refname.'^0')) {
2192                push @tmp, $cur;
2193        }
2194        if (my $ipd = $self->{inject_parents_dcommit}) {
2195                if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2196                        push @tmp, @$commit;
2197                }
2198        }
2199        push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2200        while (my $p = shift @tmp) {
2201                next if $seen{$p};
2202                $seen{$p} = 1;
2203                push @ret, $p;
2204                # MAXPARENT is defined to 16 in commit-tree.c:
2205                last if @ret >= 16;
2206        }
2207        if (@tmp) {
2208                die "r$log_entry->{revision}: No room for parents:\n\t",
2209                    join("\n\t", @tmp), "\n";
2210        }
2211        @ret;
2212}
2213
2214sub rewrite_root {
2215        my ($self) = @_;
2216        return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2217        my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2218        my $rwr = eval { command_oneline(qw/config --get/, $k) };
2219        if ($rwr) {
2220                $rwr =~ s#/+$##;
2221                if ($rwr !~ m#^[a-z\+]+://#) {
2222                        die "$rwr is not a valid URL (key: $k)\n";
2223                }
2224        }
2225        $self->{-rewrite_root} = $rwr;
2226}
2227
2228sub metadata_url {
2229        my ($self) = @_;
2230        ($self->rewrite_root || $self->{url}) .
2231           (length $self->{path} ? '/' . $self->{path} : '');
2232}
2233
2234sub full_url {
2235        my ($self) = @_;
2236        $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2237}
2238
2239
2240sub set_commit_header_env {
2241        my ($log_entry) = @_;
2242        my %env;
2243        foreach my $ned (qw/NAME EMAIL DATE/) {
2244                foreach my $ac (qw/AUTHOR COMMITTER/) {
2245                        $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2246                }
2247        }
2248
2249        $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2250        $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2251        $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2252
2253        $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2254                                                ? $log_entry->{commit_name}
2255                                                : $log_entry->{name};
2256        $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2257                                                ? $log_entry->{commit_email}
2258                                                : $log_entry->{email};
2259        \%env;
2260}
2261
2262sub restore_commit_header_env {
2263        my ($env) = @_;
2264        foreach my $ned (qw/NAME EMAIL DATE/) {
2265                foreach my $ac (qw/AUTHOR COMMITTER/) {
2266                        my $k = "GIT_${ac}_${ned}";
2267                        if (defined $env->{$k}) {
2268                                $ENV{$k} = $env->{$k};
2269                        } else {
2270                                delete $ENV{$k};
2271                        }
2272                }
2273        }
2274}
2275
2276sub gc {
2277        command_noisy('gc', '--auto');
2278};
2279
2280sub do_git_commit {
2281        my ($self, $log_entry) = @_;
2282        my $lr = $self->last_rev;
2283        if (defined $lr && $lr >= $log_entry->{revision}) {
2284                die "Last fetched revision of ", $self->refname,
2285                    " was r$lr, but we are about to fetch: ",
2286                    "r$log_entry->{revision}!\n";
2287        }
2288        if (my $c = $self->rev_map_get($log_entry->{revision})) {
2289                croak "$log_entry->{revision} = $c already exists! ",
2290                      "Why are we refetching it?\n";
2291        }
2292        my $old_env = set_commit_header_env($log_entry);
2293        my $tree = $log_entry->{tree};
2294        if (!defined $tree) {
2295                $tree = $self->tmp_index_do(sub {
2296                                            command_oneline('write-tree') });
2297        }
2298        die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2299
2300        my @exec = ('git', 'commit-tree', $tree);
2301        foreach ($self->get_commit_parents($log_entry)) {
2302                push @exec, '-p', $_;
2303        }
2304        defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2305                                                                   or croak $!;
2306        binmode $msg_fh;
2307
2308        # we always get UTF-8 from SVN, but we may want our commits in
2309        # a different encoding.
2310        if (my $enc = Git::config('i18n.commitencoding')) {
2311                require Encode;
2312                Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2313        }
2314        print $msg_fh $log_entry->{log} or croak $!;
2315        restore_commit_header_env($old_env);
2316        unless ($self->no_metadata) {
2317                print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2318                              or croak $!;
2319        }
2320        $msg_fh->flush == 0 or croak $!;
2321        close $msg_fh or croak $!;
2322        chomp(my $commit = do { local $/; <$out_fh> });
2323        close $out_fh or croak $!;
2324        waitpid $pid, 0;
2325        croak $? if $?;
2326        if ($commit !~ /^$::sha1$/o) {
2327                die "Failed to commit, invalid sha1: $commit\n";
2328        }
2329
2330        $self->rev_map_set($log_entry->{revision}, $commit, 1);
2331
2332        $self->{last_rev} = $log_entry->{revision};
2333        $self->{last_commit} = $commit;
2334        print "r$log_entry->{revision}";
2335        if (defined $log_entry->{svm_revision}) {
2336                 print " (\@$log_entry->{svm_revision})";
2337                 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2338                                   0, $self->svm_uuid);
2339        }
2340        print " = $commit ($self->{ref_id})\n";
2341        if (--$_gc_nr == 0) {
2342                $_gc_nr = $_gc_period;
2343                gc();
2344        }
2345        return $commit;
2346}
2347
2348sub match_paths {
2349        my ($self, $paths, $r) = @_;
2350        return 1 if $self->{path} eq '';
2351        if (my $path = $paths->{"/$self->{path}"}) {
2352                return ($path->{action} eq 'D') ? 0 : 1;
2353        }
2354        $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2355        if (grep /$self->{path_regex}/, keys %$paths) {
2356                return 1;
2357        }
2358        my $c = '';
2359        foreach (split m#/#, $self->{path}) {
2360                $c .= "/$_";
2361                next unless ($paths->{$c} &&
2362                             ($paths->{$c}->{action} =~ /^[AR]$/));
2363                if ($self->ra->check_path($self->{path}, $r) ==
2364                    $SVN::Node::dir) {
2365                        return 1;
2366                }
2367        }
2368        return 0;
2369}
2370
2371sub find_parent_branch {
2372        my ($self, $paths, $rev) = @_;
2373        return undef unless $self->follow_parent;
2374        unless (defined $paths) {
2375                my $err_handler = $SVN::Error::handler;
2376                $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2377                $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2378                                   $paths =
2379                                      Git::SVN::Ra::dup_changed_paths($_[0]) });
2380                $SVN::Error::handler = $err_handler;
2381        }
2382        return undef unless defined $paths;
2383
2384        # look for a parent from another branch:
2385        my @b_path_components = split m#/#, $self->rel_path;
2386        my @a_path_components;
2387        my $i;
2388        while (@b_path_components) {
2389                $i = $paths->{'/'.join('/', @b_path_components)};
2390                last if $i && defined $i->{copyfrom_path};
2391                unshift(@a_path_components, pop(@b_path_components));
2392        }
2393        return undef unless defined $i && defined $i->{copyfrom_path};
2394        my $branch_from = $i->{copyfrom_path};
2395        if (@a_path_components) {
2396                print STDERR "branch_from: $branch_from => ";
2397                $branch_from .= '/'.join('/', @a_path_components);
2398                print STDERR $branch_from, "\n";
2399        }
2400        my $r = $i->{copyfrom_rev};
2401        my $repos_root = $self->ra->{repos_root};
2402        my $url = $self->ra->{url};
2403        my $new_url = $repos_root . $branch_from;
2404        print STDERR  "Found possible branch point: ",
2405                      "$new_url => ", $self->full_url, ", $r\n";
2406        $branch_from =~ s#^/##;
2407        my $gs = $self->other_gs($new_url, $url, $repos_root,
2408                                 $branch_from, $r, $self->{ref_id});
2409        my ($r0, $parent) = $gs->find_rev_before($r, 1);
2410        {
2411                my ($base, $head);
2412                if (!defined $r0 || !defined $parent) {
2413                        ($base, $head) = parse_revision_argument(0, $r);
2414                } else {
2415                        if ($r0 < $r) {
2416                                $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2417                                        0, 1, sub { $base = $_[1] - 1 });
2418                        }
2419                }
2420                if (defined $base && $base <= $r) {
2421                        $gs->fetch($base, $r);
2422                }
2423                ($r0, $parent) = $gs->find_rev_before($r, 1);
2424        }
2425        if (defined $r0 && defined $parent) {
2426                print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2427                my $ed;
2428                if ($self->ra->can_do_switch) {
2429                        $self->assert_index_clean($parent);
2430                        print STDERR "Following parent with do_switch\n";
2431                        # do_switch works with svn/trunk >= r22312, but that
2432                        # is not included with SVN 1.4.3 (the latest version
2433                        # at the moment), so we can't rely on it
2434                        $self->{last_rev} = $r0;
2435                        $self->{last_commit} = $parent;
2436                        $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2437                        $gs->ra->gs_do_switch($r0, $rev, $gs,
2438                                              $self->full_url, $ed)
2439                          or die "SVN connection failed somewhere...\n";
2440                } elsif ($self->ra->trees_match($new_url, $r0,
2441                                                $self->full_url, $rev)) {
2442                        print STDERR "Trees match:\n",
2443                                     "  $new_url\@$r0\n",
2444                                     "  ${\$self->full_url}\@$rev\n",
2445                                     "Following parent with no changes\n";
2446                        $self->tmp_index_do(sub {
2447                            command_noisy('read-tree', $parent);
2448                        });
2449                        $self->{last_commit} = $parent;
2450                } else {
2451                        print STDERR "Following parent with do_update\n";
2452                        $ed = SVN::Git::Fetcher->new($self);
2453                        $self->ra->gs_do_update($rev, $rev, $self, $ed)
2454                          or die "SVN connection failed somewhere...\n";
2455                }
2456                print STDERR "Successfully followed parent\n";
2457                return $self->make_log_entry($rev, [$parent], $ed);
2458        }
2459        return undef;
2460}
2461
2462sub do_fetch {
2463        my ($self, $paths, $rev) = @_;
2464        my $ed;
2465        my ($last_rev, @parents);
2466        if (my $lc = $self->last_commit) {
2467                # we can have a branch that was deleted, then re-added
2468                # under the same name but copied from another path, in
2469                # which case we'll have multiple parents (we don't
2470                # want to break the original ref, nor lose copypath info):
2471                if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2472                        push @{$log_entry->{parents}}, $lc;
2473                        return $log_entry;
2474                }
2475                $ed = SVN::Git::Fetcher->new($self);
2476                $last_rev = $self->{last_rev};
2477                $ed->{c} = $lc;
2478                @parents = ($lc);
2479        } else {
2480                $last_rev = $rev;
2481                if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2482                        return $log_entry;
2483                }
2484                $ed = SVN::Git::Fetcher->new($self);
2485        }
2486        unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2487                die "SVN connection failed somewhere...\n";
2488        }
2489        $self->make_log_entry($rev, \@parents, $ed);
2490}
2491
2492sub get_untracked {
2493        my ($self, $ed) = @_;
2494        my @out;
2495        my $h = $ed->{empty};
2496        foreach (sort keys %$h) {
2497                my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2498                push @out, "  $act: " . uri_encode($_);
2499                warn "W: $act: $_\n";
2500        }
2501        foreach my $t (qw/dir_prop file_prop/) {
2502                $h = $ed->{$t} or next;
2503                foreach my $path (sort keys %$h) {
2504                        my $ppath = $path eq '' ? '.' : $path;
2505                        foreach my $prop (sort keys %{$h->{$path}}) {
2506                                next if $SKIP_PROP{$prop};
2507                                my $v = $h->{$path}->{$prop};
2508                                my $t_ppath_prop = "$t: " .
2509                                                    uri_encode($ppath) . ' ' .
2510                                                    uri_encode($prop);
2511                                if (defined $v) {
2512                                        push @out, "  +$t_ppath_prop " .
2513                                                   uri_encode($v);
2514                                } else {
2515                                        push @out, "  -$t_ppath_prop";
2516                                }
2517                        }
2518                }
2519        }
2520        foreach my $t (qw/absent_file absent_directory/) {
2521                $h = $ed->{$t} or next;
2522                foreach my $parent (sort keys %$h) {
2523                        foreach my $path (sort @{$h->{$parent}}) {
2524                                push @out, "  $t: " .
2525                                           uri_encode("$parent/$path");
2526                                warn "W: $t: $parent/$path ",
2527                                     "Insufficient permissions?\n";
2528                        }
2529                }
2530        }
2531        \@out;
2532}
2533
2534# parse_svn_date(DATE)
2535# --------------------
2536# Given a date (in UTC) from Subversion, return a string in the format
2537# "<TZ Offset> <local date/time>" that Git will use.
2538#
2539# By default the parsed date will be in UTC; if $Git::SVN::_localtime
2540# is true we'll convert it to the local timezone instead.
2541sub parse_svn_date {
2542        my $date = shift || return '+0000 1970-01-01 00:00:00';
2543        my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2544                                            (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2545                                         croak "Unable to parse date: $date\n";
2546        my $parsed_date;    # Set next.
2547
2548        if ($Git::SVN::_localtime) {
2549                # Translate the Subversion datetime to an epoch time.
2550                # Begin by switching ourselves to $date's timezone, UTC.
2551                my $old_env_TZ = $ENV{TZ};
2552                $ENV{TZ} = 'UTC';
2553
2554                my $epoch_in_UTC =
2555                    POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2556
2557                # Determine our local timezone (including DST) at the
2558                # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2559                # value of TZ, if any, at the time we were run.
2560                if (defined $Git::SVN::Log::TZ) {
2561                        $ENV{TZ} = $Git::SVN::Log::TZ;
2562                } else {
2563                        delete $ENV{TZ};
2564                }
2565
2566                my $our_TZ =
2567                    POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2568
2569                # This converts $epoch_in_UTC into our local timezone.
2570                my ($sec, $min, $hour, $mday, $mon, $year,
2571                    $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2572
2573                $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2574                                       $our_TZ, $year + 1900, $mon + 1,
2575                                       $mday, $hour, $min, $sec);
2576
2577                # Reset us to the timezone in effect when we entered
2578                # this routine.
2579                if (defined $old_env_TZ) {
2580                        $ENV{TZ} = $old_env_TZ;
2581                } else {
2582                        delete $ENV{TZ};
2583                }
2584        } else {
2585                $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2586        }
2587
2588        return $parsed_date;
2589}
2590
2591sub other_gs {
2592        my ($self, $new_url, $url, $repos_root,
2593            $branch_from, $r, $old_ref_id) = @_;
2594        my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2595        unless ($gs) {
2596                my $ref_id = $old_ref_id;
2597                $ref_id =~ s/\@\d+$//;
2598                $ref_id .= "\@$r";
2599                # just grow a tail if we're not unique enough :x
2600                $ref_id .= '-' while find_ref($ref_id);
2601                print STDERR "Initializing parent: $ref_id\n";
2602                my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2603                if ($u =~ s#^\Q$url\E(/|$)##) {
2604                        $p = $u;
2605                        $u = $url;
2606                        $repo_id = $self->{repo_id};
2607                }
2608                $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2609        }
2610        $gs
2611}
2612
2613sub check_author {
2614        my ($author) = @_;
2615        if (!defined $author || length $author == 0) {
2616                $author = '(no author)';
2617        } elsif (defined $::_authors && ! defined $::users{$author}) {
2618                die "Author: $author not defined in $::_authors file\n";
2619        }
2620        $author;
2621}
2622
2623sub make_log_entry {
2624        my ($self, $rev, $parents, $ed) = @_;
2625        my $untracked = $self->get_untracked($ed);
2626
2627        open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2628        print $un "r$rev\n" or croak $!;
2629        print $un $_, "\n" foreach @$untracked;
2630        my %log_entry = ( parents => $parents || [], revision => $rev,
2631                          log => '');
2632
2633        my $headrev;
2634        my $logged = delete $self->{logged_rev_props};
2635        if (!$logged || $self->{-want_revprops}) {
2636                my $rp = $self->ra->rev_proplist($rev);
2637                foreach (sort keys %$rp) {
2638                        my $v = $rp->{$_};
2639                        if (/^svn:(author|date|log)$/) {
2640                                $log_entry{$1} = $v;
2641                        } elsif ($_ eq 'svm:headrev') {
2642                                $headrev = $v;
2643                        } else {
2644                                print $un "  rev_prop: ", uri_encode($_), ' ',
2645                                          uri_encode($v), "\n";
2646                        }
2647                }
2648        } else {
2649                map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2650        }
2651        close $un or croak $!;
2652
2653        $log_entry{date} = parse_svn_date($log_entry{date});
2654        $log_entry{log} .= "\n";
2655        my $author = $log_entry{author} = check_author($log_entry{author});
2656        my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2657                                                       : ($author, undef);
2658
2659        my ($commit_name, $commit_email) = ($name, $email);
2660        if ($_use_log_author) {
2661                my $name_field;
2662                if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2663                        $name_field = $1;
2664                } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2665                        $name_field = $1;
2666                }
2667                if (!defined $name_field) {
2668                        if (!defined $email) {
2669                                $email = $name;
2670                        }
2671                } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2672                        ($name, $email) = ($1, $2);
2673                } elsif ($name_field =~ /(.*)@/) {
2674                        ($name, $email) = ($1, $name_field);
2675                } else {
2676                        ($name, $email) = ($name_field, $name_field);
2677                }
2678        }
2679        if (defined $headrev && $self->use_svm_props) {
2680                if ($self->rewrite_root) {
2681                        die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2682                            "options set!\n";
2683                }
2684                my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2685                # we don't want "SVM: initializing mirror for junk" ...
2686                return undef if $r == 0;
2687                my $svm = $self->svm;
2688                if ($uuid ne $svm->{uuid}) {
2689                        die "UUID mismatch on SVM path:\n",
2690                            "expected: $svm->{uuid}\n",
2691                            "     got: $uuid\n";
2692                }
2693                my $full_url = $self->full_url;
2694                $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2695                             die "Failed to replace '$svm->{replace}' with ",
2696                                 "'$svm->{source}' in $full_url\n";
2697                # throw away username for storing in records
2698                remove_username($full_url);
2699                $log_entry{metadata} = "$full_url\@$r $uuid";
2700                $log_entry{svm_revision} = $r;
2701                $email ||= "$author\@$uuid";
2702                $commit_email ||= "$author\@$uuid";
2703        } elsif ($self->use_svnsync_props) {
2704                my $full_url = $self->svnsync->{url};
2705                $full_url .= "/$self->{path}" if length $self->{path};
2706                remove_username($full_url);
2707                my $uuid = $self->svnsync->{uuid};
2708                $log_entry{metadata} = "$full_url\@$rev $uuid";
2709                $email ||= "$author\@$uuid";
2710                $commit_email ||= "$author\@$uuid";
2711        } else {
2712                my $url = $self->metadata_url;
2713                remove_username($url);
2714                $log_entry{metadata} = "$url\@$rev " .
2715                                       $self->ra->get_uuid;
2716                $email ||= "$author\@" . $self->ra->get_uuid;
2717                $commit_email ||= "$author\@" . $self->ra->get_uuid;
2718        }
2719        $log_entry{name} = $name;
2720        $log_entry{email} = $email;
2721        $log_entry{commit_name} = $commit_name;
2722        $log_entry{commit_email} = $commit_email;
2723        \%log_entry;
2724}
2725
2726sub fetch {
2727        my ($self, $min_rev, $max_rev, @parents) = @_;
2728        my ($last_rev, $last_commit) = $self->last_rev_commit;
2729        my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2730        $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2731}
2732
2733sub set_tree_cb {
2734        my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2735        $self->{inject_parents} = { $rev => $tree };
2736        $self->fetch(undef, undef);
2737}
2738
2739sub set_tree {
2740        my ($self, $tree) = (shift, shift);
2741        my $log_entry = ::get_commit_entry($tree);
2742        unless ($self->{last_rev}) {
2743                ::fatal("Must have an existing revision to commit");
2744        }
2745        my %ed_opts = ( r => $self->{last_rev},
2746                        log => $log_entry->{log},
2747                        ra => $self->ra,
2748                        tree_a => $self->{last_commit},
2749                        tree_b => $tree,
2750                        editor_cb => sub {
2751                               $self->set_tree_cb($log_entry, $tree, @_) },
2752                        svn_path => $self->{path} );
2753        if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2754                print "No changes\nr$self->{last_rev} = $tree\n";
2755        }
2756}
2757
2758sub rebuild_from_rev_db {
2759        my ($self, $path) = @_;
2760        my $r = -1;
2761        open my $fh, '<', $path or croak "open: $!";
2762        binmode $fh or croak "binmode: $!";
2763        while (<$fh>) {
2764                length($_) == 41 or croak "inconsistent size in ($_) != 41";
2765                chomp($_);
2766                ++$r;
2767                next if $_ eq ('0' x 40);
2768                $self->rev_map_set($r, $_);
2769                print "r$r = $_\n";
2770        }
2771        close $fh or croak "close: $!";
2772        unlink $path or croak "unlink: $!";
2773}
2774
2775sub rebuild {
2776        my ($self) = @_;
2777        my $map_path = $self->map_path;
2778        my $partial = (-e $map_path && ! -z $map_path);
2779        return unless ::verify_ref($self->refname.'^0');
2780        if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
2781                my $rev_db = $self->rev_db_path;
2782                $self->rebuild_from_rev_db($rev_db);
2783                if ($self->use_svm_props) {
2784                        my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2785                        $self->rebuild_from_rev_db($svm_rev_db);
2786                }
2787                $self->unlink_rev_db_symlink;
2788                return;
2789        }
2790        print "Rebuilding $map_path ...\n" if (!$partial);
2791        my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
2792                (undef, undef));
2793        my ($log, $ctx) =
2794            command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2795                                ($head ? "$head.." : "") . $self->refname,
2796                                '--');
2797        my $metadata_url = $self->metadata_url;
2798        remove_username($metadata_url);
2799        my $svn_uuid = $self->ra_uuid;
2800        my $c;
2801        while (<$log>) {
2802                if ( m{^commit ($::sha1)$} ) {
2803                        $c = $1;
2804                        next;
2805                }
2806                next unless s{^\s*(git-svn-id:)}{$1};
2807                my ($url, $rev, $uuid) = ::extract_metadata($_);
2808                remove_username($url);
2809
2810                # ignore merges (from set-tree)
2811                next if (!defined $rev || !$uuid);
2812
2813                # if we merged or otherwise started elsewhere, this is
2814                # how we break out of it
2815                if (($uuid ne $svn_uuid) ||
2816                    ($metadata_url && $url && ($url ne $metadata_url))) {
2817                        next;
2818                }
2819                if ($partial && $head) {
2820                        print "Partial-rebuilding $map_path ...\n";
2821                        print "Currently at $base_rev = $head\n";
2822                        $head = undef;
2823                }
2824
2825                $self->rev_map_set($rev, $c);
2826                print "r$rev = $c\n";
2827        }
2828        command_close_pipe($log, $ctx);
2829        print "Done rebuilding $map_path\n" if (!$partial || !$head);
2830        my $rev_db_path = $self->rev_db_path;
2831        if (-f $self->rev_db_path) {
2832                unlink $self->rev_db_path or croak "unlink: $!";
2833        }
2834        $self->unlink_rev_db_symlink;
2835}
2836
2837# rev_map:
2838# Tie::File seems to be prone to offset errors if revisions get sparse,
2839# it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
2840# one of my favorite modules is out :<  Next up would be one of the DBM
2841# modules, but I'm not sure which is most portable...
2842#
2843# This is the replacement for the rev_db format, which was too big
2844# and inefficient for large repositories with a lot of sparse history
2845# (mainly tags)
2846#
2847# The format is this:
2848#   - 24 bytes for every record,
2849#     * 4 bytes for the integer representing an SVN revision number
2850#     * 20 bytes representing the sha1 of a git commit
2851#   - No empty padding records like the old format
2852#     (except the last record, which can be overwritten)
2853#   - new records are written append-only since SVN revision numbers
2854#     increase monotonically
2855#   - lookups on SVN revision number are done via a binary search
2856#   - Piping the file to xxd -c24 is a good way of dumping it for
2857#     viewing or editing (piped back through xxd -r), should the need
2858#     ever arise.
2859#   - The last record can be padding revision with an all-zero sha1
2860#     This is used to optimize fetch performance when using multiple
2861#     "fetch" directives in .git/config
2862#
2863# These files are disposable unless noMetadata or useSvmProps is set
2864
2865sub _rev_map_set {
2866        my ($fh, $rev, $commit) = @_;
2867
2868        binmode $fh or croak "binmode: $!";
2869        my $size = (stat($fh))[7];
2870        ($size % 24) == 0 or croak "inconsistent size: $size";
2871
2872        my $wr_offset = 0;
2873        if ($size > 0) {
2874                sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2875                my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2876                $read == 24 or croak "read only $read bytes (!= 24)";
2877                my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2878                if ($last_commit eq ('0' x40)) {
2879                        if ($size >= 48) {
2880                                sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2881                                $read = sysread($fh, $buf, 24) or
2882                                    croak "read: $!";
2883                                $read == 24 or
2884                                    croak "read only $read bytes (!= 24)";
2885                                ($last_rev, $last_commit) =
2886                                    unpack(rev_map_fmt, $buf);
2887                                if ($last_commit eq ('0' x40)) {
2888                                        croak "inconsistent .rev_map\n";
2889                                }
2890                        }
2891                        if ($last_rev >= $rev) {
2892                                croak "last_rev is higher!: $last_rev >= $rev";
2893                        }
2894                        $wr_offset = -24;
2895                }
2896        }
2897        sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2898        syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2899          croak "write: $!";
2900}
2901
2902sub mkfile {
2903        my ($path) = @_;
2904        unless (-e $path) {
2905                my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2906                mkpath([$dir]) unless -d $dir;
2907                open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2908                close $fh or die "Couldn't close (create) $path: $!\n";
2909        }
2910}
2911
2912sub rev_map_set {
2913        my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2914        length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2915        my $db = $self->map_path($uuid);
2916        my $db_lock = "$db.lock";
2917        my $sig;
2918        if ($update_ref) {
2919                $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2920                            $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2921        }
2922        mkfile($db);
2923
2924        $LOCKFILES{$db_lock} = 1;
2925        my $sync;
2926        # both of these options make our .rev_db file very, very important
2927        # and we can't afford to lose it because rebuild() won't work
2928        if ($self->use_svm_props || $self->no_metadata) {
2929                $sync = 1;
2930                copy($db, $db_lock) or die "rev_map_set(@_): ",
2931                                           "Failed to copy: ",
2932                                           "$db => $db_lock ($!)\n";
2933        } else {
2934                rename $db, $db_lock or die "rev_map_set(@_): ",
2935                                            "Failed to rename: ",
2936                                            "$db => $db_lock ($!)\n";
2937        }
2938
2939        sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2940             or croak "Couldn't open $db_lock: $!\n";
2941        _rev_map_set($fh, $rev, $commit);
2942        if ($sync) {
2943                $fh->flush or die "Couldn't flush $db_lock: $!\n";
2944                $fh->sync or die "Couldn't sync $db_lock: $!\n";
2945        }
2946        close $fh or croak $!;
2947        if ($update_ref) {
2948                $_head = $self;
2949                command_noisy('update-ref', '-m', "r$rev",
2950                              $self->refname, $commit);
2951        }
2952        rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2953                                    "$db_lock => $db ($!)\n";
2954        delete $LOCKFILES{$db_lock};
2955        if ($update_ref) {
2956                $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2957                            $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2958                kill $sig, $$ if defined $sig;
2959        }
2960}
2961
2962# If want_commit, this will return an array of (rev, commit) where
2963# commit _must_ be a valid commit in the archive.
2964# Otherwise, it'll return the max revision (whether or not the
2965# commit is valid or just a 0x40 placeholder).
2966sub rev_map_max {
2967        my ($self, $want_commit) = @_;
2968        $self->rebuild;
2969        my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
2970        $want_commit ? ($r, $c) : $r;
2971}
2972
2973sub rev_map_max_norebuild {
2974        my ($self, $want_commit) = @_;
2975        my $map_path = $self->map_path;
2976        stat $map_path or return $want_commit ? (0, undef) : 0;
2977        sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2978        binmode $fh or croak "binmode: $!";
2979        my $size = (stat($fh))[7];
2980        ($size % 24) == 0 or croak "inconsistent size: $size";
2981
2982        if ($size == 0) {
2983                close $fh or croak "close: $!";
2984                return $want_commit ? (0, undef) : 0;
2985        }
2986
2987        sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2988        sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2989        my ($r, $c) = unpack(rev_map_fmt, $buf);
2990        if ($want_commit && $c eq ('0' x40)) {
2991                if ($size < 48) {
2992                        return $want_commit ? (0, undef) : 0;
2993                }
2994                sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2995                sysread($fh, $buf, 24) == 24 or croak "read: $!";
2996                ($r, $c) = unpack(rev_map_fmt, $buf);
2997                if ($c eq ('0'x40)) {
2998                        croak "Penultimate record is all-zeroes in $map_path";
2999                }
3000        }
3001        close $fh or croak "close: $!";
3002        $want_commit ? ($r, $c) : $r;
3003}
3004
3005sub rev_map_get {
3006        my ($self, $rev, $uuid) = @_;
3007        my $map_path = $self->map_path($uuid);
3008        return undef unless -e $map_path;
3009
3010        sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3011        binmode $fh or croak "binmode: $!";
3012        my $size = (stat($fh))[7];
3013        ($size % 24) == 0 or croak "inconsistent size: $size";
3014
3015        if ($size == 0) {
3016                close $fh or croak "close: $fh";
3017                return undef;
3018        }
3019
3020        my ($l, $u) = (0, $size - 24);
3021        my ($r, $c, $buf);
3022
3023        while ($l <= $u) {
3024                my $i = int(($l/24 + $u/24) / 2) * 24;
3025                sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3026                sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3027                my ($r, $c) = unpack('NH40', $buf);
3028
3029                if ($r < $rev) {
3030                        $l = $i + 24;
3031                } elsif ($r > $rev) {
3032                        $u = $i - 24;
3033                } else { # $r == $rev
3034                        close($fh) or croak "close: $!";
3035                        return $c eq ('0' x 40) ? undef : $c;
3036                }
3037        }
3038        close($fh) or croak "close: $!";
3039        undef;
3040}
3041
3042# Finds the first svn revision that exists on (if $eq_ok is true) or
3043# before $rev for the current branch.  It will not search any lower
3044# than $min_rev.  Returns the git commit hash and svn revision number
3045# if found, else (undef, undef).
3046sub find_rev_before {
3047        my ($self, $rev, $eq_ok, $min_rev) = @_;
3048        --$rev unless $eq_ok;
3049        $min_rev ||= 1;
3050        while ($rev >= $min_rev) {
3051                if (my $c = $self->rev_map_get($rev)) {
3052                        return ($rev, $c);
3053                }
3054                --$rev;
3055        }
3056        return (undef, undef);
3057}
3058
3059# Finds the first svn revision that exists on (if $eq_ok is true) or
3060# after $rev for the current branch.  It will not search any higher
3061# than $max_rev.  Returns the git commit hash and svn revision number
3062# if found, else (undef, undef).
3063sub find_rev_after {
3064        my ($self, $rev, $eq_ok, $max_rev) = @_;
3065        ++$rev unless $eq_ok;
3066        $max_rev ||= $self->rev_map_max;
3067        while ($rev <= $max_rev) {
3068                if (my $c = $self->rev_map_get($rev)) {
3069                        return ($rev, $c);
3070                }
3071                ++$rev;
3072        }
3073        return (undef, undef);
3074}
3075
3076sub _new {
3077        my ($class, $repo_id, $ref_id, $path) = @_;
3078        unless (defined $repo_id && length $repo_id) {
3079                $repo_id = $Git::SVN::default_repo_id;
3080        }
3081        unless (defined $ref_id && length $ref_id) {
3082                $_[2] = $ref_id = $Git::SVN::default_ref_id;
3083        }
3084        $_[1] = $repo_id;
3085        my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3086        $_[3] = $path = '' unless (defined $path);
3087        mkpath(["$ENV{GIT_DIR}/svn"]);
3088        bless {
3089                ref_id => $ref_id, dir => $dir, index => "$dir/index",
3090                path => $path, config => "$ENV{GIT_DIR}/svn/config",
3091                map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3092}
3093
3094# for read-only access of old .rev_db formats
3095sub unlink_rev_db_symlink {
3096        my ($self) = @_;
3097        my $link = $self->rev_db_path;
3098        $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3099        if (-l $link) {
3100                unlink $link or croak "unlink: $link failed!";
3101        }
3102}
3103
3104sub rev_db_path {
3105        my ($self, $uuid) = @_;
3106        my $db_path = $self->map_path($uuid);
3107        $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3108            or croak "map_path: $db_path does not contain '/.rev_map.' !";
3109        $db_path;
3110}
3111
3112# the new replacement for .rev_db
3113sub map_path {
3114        my ($self, $uuid) = @_;
3115        $uuid ||= $self->ra_uuid;
3116        "$self->{map_root}.$uuid";
3117}
3118
3119sub uri_encode {
3120        my ($f) = @_;
3121        $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3122        $f
3123}
3124
3125sub remove_username {
3126        $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3127}
3128
3129package Git::SVN::Prompt;
3130use strict;
3131use warnings;
3132require SVN::Core;
3133use vars qw/$_no_auth_cache $_username/;
3134
3135sub simple {
3136        my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3137        $may_save = undef if $_no_auth_cache;
3138        $default_username = $_username if defined $_username;
3139        if (defined $default_username && length $default_username) {
3140                if (defined $realm && length $realm) {
3141                        print STDERR "Authentication realm: $realm\n";
3142                        STDERR->flush;
3143                }
3144                $cred->username($default_username);
3145        } else {
3146                username($cred, $realm, $may_save, $pool);
3147        }
3148        $cred->password(_read_password("Password for '" .
3149                                       $cred->username . "': ", $realm));
3150        $cred->may_save($may_save);
3151        $SVN::_Core::SVN_NO_ERROR;
3152}
3153
3154sub ssl_server_trust {
3155        my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3156        $may_save = undef if $_no_auth_cache;
3157        print STDERR "Error validating server certificate for '$realm':\n";
3158        {
3159                no warnings 'once';
3160                # All variables SVN::Auth::SSL::* are used only once,
3161                # so we're shutting up Perl warnings about this.
3162                if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3163                        print STDERR " - The certificate is not issued ",
3164                            "by a trusted authority. Use the\n",
3165                            "   fingerprint to validate ",
3166                            "the certificate manually!\n";
3167                }
3168                if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3169                        print STDERR " - The certificate hostname ",
3170                            "does not match.\n";
3171                }
3172                if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3173                        print STDERR " - The certificate is not yet valid.\n";
3174                }
3175                if ($failures & $SVN::Auth::SSL::EXPIRED) {
3176                        print STDERR " - The certificate has expired.\n";
3177                }
3178                if ($failures & $SVN::Auth::SSL::OTHER) {
3179                        print STDERR " - The certificate has ",
3180                            "an unknown error.\n";
3181                }
3182        } # no warnings 'once'
3183        printf STDERR
3184                "Certificate information:\n".
3185                " - Hostname: %s\n".
3186                " - Valid: from %s until %s\n".
3187                " - Issuer: %s\n".
3188                " - Fingerprint: %s\n",
3189                map $cert_info->$_, qw(hostname valid_from valid_until
3190                                       issuer_dname fingerprint);
3191        my $choice;
3192prompt:
3193        print STDERR $may_save ?
3194              "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3195              "(R)eject or accept (t)emporarily? ";
3196        STDERR->flush;
3197        $choice = lc(substr(<STDIN> || 'R', 0, 1));
3198        if ($choice =~ /^t$/i) {
3199                $cred->may_save(undef);
3200        } elsif ($choice =~ /^r$/i) {
3201                return -1;
3202        } elsif ($may_save && $choice =~ /^p$/i) {
3203                $cred->may_save($may_save);
3204        } else {
3205                goto prompt;
3206        }
3207        $cred->accepted_failures($failures);
3208        $SVN::_Core::SVN_NO_ERROR;
3209}
3210
3211sub ssl_client_cert {
3212        my ($cred, $realm, $may_save, $pool) = @_;
3213        $may_save = undef if $_no_auth_cache;
3214        print STDERR "Client certificate filename: ";
3215        STDERR->flush;
3216        chomp(my $filename = <STDIN>);
3217        $cred->cert_file($filename);
3218        $cred->may_save($may_save);
3219        $SVN::_Core::SVN_NO_ERROR;
3220}
3221
3222sub ssl_client_cert_pw {
3223        my ($cred, $realm, $may_save, $pool) = @_;
3224        $may_save = undef if $_no_auth_cache;
3225        $cred->password(_read_password("Password: ", $realm));
3226        $cred->may_save($may_save);
3227        $SVN::_Core::SVN_NO_ERROR;
3228}
3229
3230sub username {
3231        my ($cred, $realm, $may_save, $pool) = @_;
3232        $may_save = undef if $_no_auth_cache;
3233        if (defined $realm && length $realm) {
3234                print STDERR "Authentication realm: $realm\n";
3235        }
3236        my $username;
3237        if (defined $_username) {
3238                $username = $_username;
3239        } else {
3240                print STDERR "Username: ";
3241                STDERR->flush;
3242                chomp($username = <STDIN>);
3243        }
3244        $cred->username($username);
3245        $cred->may_save($may_save);
3246        $SVN::_Core::SVN_NO_ERROR;
3247}
3248
3249sub _read_password {
3250        my ($prompt, $realm) = @_;
3251        print STDERR $prompt;
3252        STDERR->flush;
3253        require Term::ReadKey;
3254        Term::ReadKey::ReadMode('noecho');
3255        my $password = '';
3256        while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3257                last if $key =~ /[\012\015]/; # \n\r
3258                $password .= $key;
3259        }
3260        Term::ReadKey::ReadMode('restore');
3261        print STDERR "\n";
3262        STDERR->flush;
3263        $password;
3264}
3265
3266package SVN::Git::Fetcher;
3267use vars qw/@ISA/;
3268use strict;
3269use warnings;
3270use Carp qw/croak/;
3271use File::Temp qw/tempfile/;
3272use IO::File qw//;
3273use vars qw/$_ignore_regex/;
3274
3275# file baton members: path, mode_a, mode_b, pool, fh, blob, base
3276sub new {
3277        my ($class, $git_svn, $switch_path) = @_;
3278        my $self = SVN::Delta::Editor->new;
3279        bless $self, $class;
3280        if (exists $git_svn->{last_commit}) {
3281                $self->{c} = $git_svn->{last_commit};
3282                $self->{empty_symlinks} =
3283                                  _mark_empty_symlinks($git_svn, $switch_path);
3284        }
3285        $self->{empty} = {};
3286        $self->{dir_prop} = {};
3287        $self->{file_prop} = {};
3288        $self->{absent_dir} = {};
3289        $self->{absent_file} = {};
3290        $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3291        $self;
3292}
3293
3294# this uses the Ra object, so it must be called before do_{switch,update},
3295# not inside them (when the Git::SVN::Fetcher object is passed) to
3296# do_{switch,update}
3297sub _mark_empty_symlinks {
3298        my ($git_svn, $switch_path) = @_;
3299        my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
3300        return {} if (defined($bool) && ! $bool);
3301
3302        my %ret;
3303        my ($rev, $cmt) = $git_svn->last_rev_commit;
3304        return {} unless ($rev && $cmt);
3305
3306        # allow the warning to be printed for each revision we fetch to
3307        # ensure the user sees it.  The user can also disable the workaround
3308        # on the repository even while git svn is running and the next
3309        # revision fetched will skip this expensive function.
3310        my $printed_warning;
3311        chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
3312        my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
3313        local $/ = "\0";
3314        my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
3315        $pfx .= '/' if length($pfx);
3316        while (<$ls>) {
3317                chomp;
3318                s/\A100644 blob $empty_blob\t//o or next;
3319                unless ($printed_warning) {
3320                        print STDERR "Scanning for empty symlinks, ",
3321                                     "this may take a while if you have ",
3322                                     "many empty files\n",
3323                                     "You may disable this with `",
3324                                     "git config svn.brokenSymlinkWorkaround ",
3325                                     "false'.\n",
3326                                     "This may be done in a different ",
3327                                     "terminal without restarting ",
3328                                     "git svn\n";
3329                        $printed_warning = 1;
3330                }
3331                my $path = $_;
3332                my (undef, $props) =
3333                               $git_svn->ra->get_file($pfx.$path, $rev, undef);
3334                if ($props->{'svn:special'}) {
3335                        $ret{$path} = 1;
3336                }
3337        }
3338        command_close_pipe($ls, $ctx);
3339        \%ret;
3340}
3341
3342# returns true if a given path is inside a ".git" directory
3343sub in_dot_git {
3344        $_[0] =~ m{(?:^|/)\.git(?:/|$)};
3345}
3346
3347# return value: 0 -- don't ignore, 1 -- ignore
3348sub is_path_ignored {
3349        my ($path) = @_;
3350        return 1 if in_dot_git($path);
3351        return 0 unless defined($_ignore_regex);
3352        return 1 if $path =~ m!$_ignore_regex!o;
3353        return 0;
3354}
3355
3356sub set_path_strip {
3357        my ($self, $path) = @_;
3358        $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3359}
3360
3361sub open_root {
3362        { path => '' };
3363}
3364
3365sub open_directory {
3366        my ($self, $path, $pb, $rev) = @_;
3367        { path => $path };
3368}
3369
3370sub git_path {
3371        my ($self, $path) = @_;
3372        if ($self->{path_strip}) {
3373                $path =~ s!$self->{path_strip}!! or
3374                  die "Failed to strip path '$path' ($self->{path_strip})\n";
3375        }
3376        $path;
3377}
3378
3379sub delete_entry {
3380        my ($self, $path, $rev, $pb) = @_;
3381        return undef if is_path_ignored($path);
3382
3383        my $gpath = $self->git_path($path);
3384        return undef if ($gpath eq '');
3385
3386        # remove entire directories.
3387        if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3388                my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3389                                                     -r --name-only -z/,
3390                                                     $self->{c}, '--', $gpath);
3391                local $/ = "\0";
3392                while (<$ls>) {
3393                        chomp;
3394                        $self->{gii}->remove($_);
3395                        print "\tD\t$_\n" unless $::_q;
3396                }
3397                print "\tD\t$gpath/\n" unless $::_q;
3398                command_close_pipe($ls, $ctx);
3399                $self->{empty}->{$path} = 0
3400        } else {
3401                $self->{gii}->remove($gpath);
3402                print "\tD\t$gpath\n" unless $::_q;
3403        }
3404        undef;
3405}
3406
3407sub open_file {
3408        my ($self, $path, $pb, $rev) = @_;
3409        my ($mode, $blob);
3410
3411        goto out if is_path_ignored($path);
3412
3413        my $gpath = $self->git_path($path);
3414        ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3415                             =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3416        unless (defined $mode && defined $blob) {
3417                die "$path was not found in commit $self->{c} (r$rev)\n";
3418        }
3419        if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
3420                $mode = '120000';
3421        }
3422out:
3423        { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3424          pool => SVN::Pool->new, action => 'M' };
3425}
3426
3427sub add_file {
3428        my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3429        my $mode;
3430
3431        if (!is_path_ignored($path)) {
3432                my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3433                delete $self->{empty}->{$dir};
3434                $mode = '100644';
3435        }
3436        { path => $path, mode_a => $mode, mode_b => $mode,
3437          pool => SVN::Pool->new, action => 'A' };
3438}
3439
3440sub add_directory {
3441        my ($self, $path, $cp_path, $cp_rev) = @_;
3442        goto out if is_path_ignored($path);
3443        my $gpath = $self->git_path($path);
3444        if ($gpath eq '') {
3445                my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3446                                                     -r --name-only -z/,
3447                                                     $self->{c});
3448                local $/ = "\0";
3449                while (<$ls>) {
3450                        chomp;
3451                        $self->{gii}->remove($_);
3452                        print "\tD\t$_\n" unless $::_q;
3453                }
3454                command_close_pipe($ls, $ctx);
3455                $self->{empty}->{$path} = 0;
3456        }
3457        my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3458        delete $self->{empty}->{$dir};
3459        $self->{empty}->{$path} = 1;
3460out:
3461        { path => $path };
3462}
3463
3464sub change_dir_prop {
3465        my ($self, $db, $prop, $value) = @_;
3466        return undef if is_path_ignored($db->{path});
3467        $self->{dir_prop}->{$db->{path}} ||= {};
3468        $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3469        undef;
3470}
3471
3472sub absent_directory {
3473        my ($self, $path, $pb) = @_;
3474        return undef if is_path_ignored($path);
3475        $self->{absent_dir}->{$pb->{path}} ||= [];
3476        push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3477        undef;
3478}
3479
3480sub absent_file {
3481        my ($self, $path, $pb) = @_;
3482        return undef if is_path_ignored($path);
3483        $self->{absent_file}->{$pb->{path}} ||= [];
3484        push @{$self->{absent_file}->{$pb->{path}}}, $path;
3485        undef;
3486}
3487
3488sub change_file_prop {
3489        my ($self, $fb, $prop, $value) = @_;
3490        return undef if is_path_ignored($fb->{path});
3491        if ($prop eq 'svn:executable') {
3492                if ($fb->{mode_b} != 120000) {
3493                        $fb->{mode_b} = defined $value ? 100755 : 100644;
3494                }
3495        } elsif ($prop eq 'svn:special') {
3496                $fb->{mode_b} = defined $value ? 120000 : 100644;
3497        } else {
3498                $self->{file_prop}->{$fb->{path}} ||= {};
3499                $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3500        }
3501        undef;
3502}
3503
3504sub apply_textdelta {
3505        my ($self, $fb, $exp) = @_;
3506        return undef if is_path_ignored($fb->{path});
3507        my $fh = $::_repository->temp_acquire('svn_delta');
3508        # $fh gets auto-closed() by SVN::TxDelta::apply(),
3509        # (but $base does not,) so dup() it for reading in close_file
3510        open my $dup, '<&', $fh or croak $!;
3511        my $base = $::_repository->temp_acquire('git_blob');
3512
3513        if ($fb->{blob}) {
3514                my ($base_is_link, $size);
3515
3516                if ($fb->{mode_a} eq '120000' &&
3517                    ! $self->{empty_symlinks}->{$fb->{path}}) {
3518                        print $base 'link ' or die "print $!\n";
3519                        $base_is_link = 1;
3520                }
3521        retry:
3522                $size = $::_repository->cat_blob($fb->{blob}, $base);
3523                die "Failed to read object $fb->{blob}" if ($size < 0);
3524
3525                if (defined $exp) {
3526                        seek $base, 0, 0 or croak $!;
3527                        my $got = ::md5sum($base);
3528                        if ($got ne $exp) {
3529                                my $err = "Checksum mismatch: ".
3530                                       "$fb->{path} $fb->{blob}\n" .
3531                                       "expected: $exp\n" .
3532                                       "     got: $got\n";
3533                                if ($base_is_link) {
3534                                        warn $err,
3535                                             "Retrying... (possibly ",
3536                                             "a bad symlink from SVN)\n";
3537                                        $::_repository->temp_reset($base);
3538                                        $base_is_link = 0;
3539                                        goto retry;
3540                                }
3541                                die $err;
3542                        }
3543                }
3544        }
3545        seek $base, 0, 0 or croak $!;
3546        $fb->{fh} = $fh;
3547        $fb->{base} = $base;
3548        [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
3549}
3550
3551sub close_file {
3552        my ($self, $fb, $exp) = @_;
3553        return undef if is_path_ignored($fb->{path});
3554
3555        my $hash;
3556        my $path = $self->git_path($fb->{path});
3557        if (my $fh = $fb->{fh}) {
3558                if (defined $exp) {
3559                        seek($fh, 0, 0) or croak $!;
3560                        my $got = ::md5sum($fh);
3561                        if ($got ne $exp) {
3562                                die "Checksum mismatch: $path\n",
3563                                    "expected: $exp\n    got: $got\n";
3564                        }
3565                }
3566                if ($fb->{mode_b} == 120000) {
3567                        sysseek($fh, 0, 0) or croak $!;
3568                        my $rd = sysread($fh, my $buf, 5);
3569
3570                        if (!defined $rd) {
3571                                croak "sysread: $!\n";
3572                        } elsif ($rd == 0) {
3573                                warn "$path has mode 120000",
3574                                     " but it points to nothing\n",
3575                                     "converting to an empty file with mode",
3576                                     " 100644\n";
3577                                $fb->{mode_b} = '100644';
3578                        } elsif ($buf ne 'link ') {
3579                                warn "$path has mode 120000",
3580                                     " but is not a link\n";
3581                        } else {
3582                                my $tmp_fh = $::_repository->temp_acquire(
3583                                        'svn_hash');
3584                                my $res;
3585                                while ($res = sysread($fh, my $str, 1024)) {
3586                                        my $out = syswrite($tmp_fh, $str, $res);
3587                                        defined($out) && $out == $res
3588                                                or croak("write ",
3589                                                        Git::temp_path($tmp_fh),
3590                                                        ": $!\n");
3591                                }
3592                                defined $res or croak $!;
3593
3594                                ($fh, $tmp_fh) = ($tmp_fh, $fh);
3595                                Git::temp_release($tmp_fh, 1);
3596                        }
3597                }
3598
3599                $hash = $::_repository->hash_and_insert_object(
3600                                Git::temp_path($fh));
3601                $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3602
3603                Git::temp_release($fb->{base}, 1);
3604                Git::temp_release($fh, 1);
3605        } else {
3606                $hash = $fb->{blob} or die "no blob information\n";
3607        }
3608        $fb->{pool}->clear;
3609        $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3610        print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3611        undef;
3612}
3613
3614sub abort_edit {
3615        my $self = shift;
3616        $self->{nr} = $self->{gii}->{nr};
3617        delete $self->{gii};
3618        $self->SUPER::abort_edit(@_);
3619}
3620
3621sub close_edit {
3622        my $self = shift;
3623        $self->{git_commit_ok} = 1;
3624        $self->{nr} = $self->{gii}->{nr};
3625        delete $self->{gii};
3626        $self->SUPER::close_edit(@_);
3627}
3628
3629package SVN::Git::Editor;
3630use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3631use strict;
3632use warnings;
3633use Carp qw/croak/;
3634use IO::File;
3635
3636sub new {
3637        my ($class, $opts) = @_;
3638        foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3639                die "$_ required!\n" unless (defined $opts->{$_});
3640        }
3641
3642        my $pool = SVN::Pool->new;
3643        my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3644        my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3645                                     $opts->{r}, $mods);
3646
3647        # $opts->{ra} functions should not be used after this:
3648        my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
3649                                                $opts->{editor_cb}, $pool);
3650        my $self = SVN::Delta::Editor->new(@ce, $pool);
3651        bless $self, $class;
3652        foreach (qw/svn_path r tree_a tree_b/) {
3653                $self->{$_} = $opts->{$_};
3654        }
3655        $self->{url} = $opts->{ra}->{url};
3656        $self->{mods} = $mods;
3657        $self->{types} = $types;
3658        $self->{pool} = $pool;
3659        $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3660        $self->{rm} = { };
3661        $self->{path_prefix} = length $self->{svn_path} ?
3662                               "$self->{svn_path}/" : '';
3663        $self->{config} = $opts->{config};
3664        return $self;
3665}
3666
3667sub generate_diff {
3668        my ($tree_a, $tree_b) = @_;
3669        my @diff_tree = qw(diff-tree -z -r);
3670        if ($_cp_similarity) {
3671                push @diff_tree, "-C$_cp_similarity";
3672        } else {
3673                push @diff_tree, '-C';
3674        }
3675        push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3676        push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3677        push @diff_tree, $tree_a, $tree_b;
3678        my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3679        local $/ = "\0";
3680        my $state = 'meta';
3681        my @mods;
3682        while (<$diff_fh>) {
3683                chomp $_; # this gets rid of the trailing "\0"
3684                if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3685                                        ($::sha1)\s($::sha1)\s
3686                                        ([MTCRAD])\d*$/xo) {
3687                        push @mods, {   mode_a => $1, mode_b => $2,
3688                                        sha1_a => $3, sha1_b => $4,
3689                                        chg => $5 };
3690                        if ($5 =~ /^(?:C|R)$/) {
3691                                $state = 'file_a';
3692                        } else {
3693                                $state = 'file_b';
3694                        }
3695                } elsif ($state eq 'file_a') {
3696                        my $x = $mods[$#mods] or croak "Empty array\n";
3697                        if ($x->{chg} !~ /^(?:C|R)$/) {
3698                                croak "Error parsing $_, $x->{chg}\n";
3699                        }
3700                        $x->{file_a} = $_;
3701                        $state = 'file_b';
3702                } elsif ($state eq 'file_b') {
3703                        my $x = $mods[$#mods] or croak "Empty array\n";
3704                        if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3705                                croak "Error parsing $_, $x->{chg}\n";
3706                        }
3707                        if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3708                                croak "Error parsing $_, $x->{chg}\n";
3709                        }
3710                        $x->{file_b} = $_;
3711                        $state = 'meta';
3712                } else {
3713                        croak "Error parsing $_\n";
3714                }
3715        }
3716        command_close_pipe($diff_fh, $ctx);
3717        \@mods;
3718}
3719
3720sub check_diff_paths {
3721        my ($ra, $pfx, $rev, $mods) = @_;
3722        my %types;
3723        $pfx .= '/' if length $pfx;
3724
3725        sub type_diff_paths {
3726                my ($ra, $types, $path, $rev) = @_;
3727                my @p = split m#/+#, $path;
3728                my $c = shift @p;
3729                unless (defined $types->{$c}) {
3730                        $types->{$c} = $ra->check_path($c, $rev);
3731                }
3732                while (@p) {
3733                        $c .= '/' . shift @p;
3734                        next if defined $types->{$c};
3735                        $types->{$c} = $ra->check_path($c, $rev);
3736                }
3737        }
3738
3739        foreach my $m (@$mods) {
3740                foreach my $f (qw/file_a file_b/) {
3741                        next unless defined $m->{$f};
3742                        my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3743                        if (length $pfx.$dir && ! defined $types{$dir}) {
3744                                type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3745                        }
3746                }
3747        }
3748        \%types;
3749}
3750
3751sub split_path {
3752        return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3753}
3754
3755sub repo_path {
3756        my ($self, $path) = @_;
3757        $self->{path_prefix}.(defined $path ? $path : '');
3758}
3759
3760sub url_path {
3761        my ($self, $path) = @_;
3762        if ($self->{url} =~ m#^https?://#) {
3763                $path =~ s/([^~a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3764        }
3765        $self->{url} . '/' . $self->repo_path($path);
3766}
3767
3768sub rmdirs {
3769        my ($self) = @_;
3770        my $rm = $self->{rm};
3771        delete $rm->{''}; # we never delete the url we're tracking
3772        return unless %$rm;
3773
3774        foreach (keys %$rm) {
3775                my @d = split m#/#, $_;
3776                my $c = shift @d;
3777                $rm->{$c} = 1;
3778                while (@d) {
3779                        $c .= '/' . shift @d;
3780                        $rm->{$c} = 1;
3781                }
3782        }
3783        delete $rm->{$self->{svn_path}};
3784        delete $rm->{''}; # we never delete the url we're tracking
3785        return unless %$rm;
3786
3787        my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3788                                             $self->{tree_b});
3789        local $/ = "\0";
3790        while (<$fh>) {
3791                chomp;
3792                my @dn = split m#/#, $_;
3793                while (pop @dn) {
3794                        delete $rm->{join '/', @dn};
3795                }
3796                unless (%$rm) {
3797                        close $fh;
3798                        return;
3799                }
3800        }
3801        command_close_pipe($fh, $ctx);
3802
3803        my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3804        foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3805                $self->close_directory($bat->{$d}, $p);
3806                my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3807                print "\tD+\t$d/\n" unless $::_q;
3808                $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3809                delete $bat->{$d};
3810        }
3811}
3812
3813sub open_or_add_dir {
3814        my ($self, $full_path, $baton) = @_;
3815        my $t = $self->{types}->{$full_path};
3816        if (!defined $t) {
3817                die "$full_path not known in r$self->{r} or we have a bug!\n";
3818        }
3819        {
3820                no warnings 'once';
3821                # SVN::Node::none and SVN::Node::file are used only once,
3822                # so we're shutting up Perl's warnings about them.
3823                if ($t == $SVN::Node::none) {
3824                        return $self->add_directory($full_path, $baton,
3825                            undef, -1, $self->{pool});
3826                } elsif ($t == $SVN::Node::dir) {
3827                        return $self->open_directory($full_path, $baton,
3828                            $self->{r}, $self->{pool});
3829                } # no warnings 'once'
3830                print STDERR "$full_path already exists in repository at ",
3831                    "r$self->{r} and it is not a directory (",
3832                    ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3833        } # no warnings 'once'
3834        exit 1;
3835}
3836
3837sub ensure_path {
3838        my ($self, $path) = @_;
3839        my $bat = $self->{bat};
3840        my $repo_path = $self->repo_path($path);
3841        return $bat->{''} unless (length $repo_path);
3842        my @p = split m#/+#, $repo_path;
3843        my $c = shift @p;
3844        $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3845        while (@p) {
3846                my $c0 = $c;
3847                $c .= '/' . shift @p;
3848                $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3849        }
3850        return $bat->{$c};
3851}
3852
3853# Subroutine to convert a globbing pattern to a regular expression.
3854# From perl cookbook.
3855sub glob2pat {
3856        my $globstr = shift;
3857        my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
3858        $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
3859        return '^' . $globstr . '$';
3860}
3861
3862sub check_autoprop {
3863        my ($self, $pattern, $properties, $file, $fbat) = @_;
3864        # Convert the globbing pattern to a regular expression.
3865        my $regex = glob2pat($pattern);
3866        # Check if the pattern matches the file name.
3867        if($file =~ m/($regex)/) {
3868                # Parse the list of properties to set.
3869                my @props = split(/;/, $properties);
3870                foreach my $prop (@props) {
3871                        # Parse 'name=value' syntax and set the property.
3872                        if ($prop =~ /([^=]+)=(.*)/) {
3873                                my ($n,$v) = ($1,$2);
3874                                for ($n, $v) {
3875                                        s/^\s+//; s/\s+$//;
3876                                }
3877                                $self->change_file_prop($fbat, $n, $v);
3878                        }
3879                }
3880        }
3881}
3882
3883sub apply_autoprops {
3884        my ($self, $file, $fbat) = @_;
3885        my $conf_t = ${$self->{config}}{'config'};
3886        no warnings 'once';
3887        # Check [miscellany]/enable-auto-props in svn configuration.
3888        if (SVN::_Core::svn_config_get_bool(
3889                $conf_t,
3890                $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
3891                $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
3892                0)) {
3893                # Auto-props are enabled.  Enumerate them to look for matches.
3894                my $callback = sub {
3895                        $self->check_autoprop($_[0], $_[1], $file, $fbat);
3896                };
3897                SVN::_Core::svn_config_enumerate(
3898                        $conf_t,
3899                        $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
3900                        $callback);
3901        }
3902}
3903
3904sub A {
3905        my ($self, $m) = @_;
3906        my ($dir, $file) = split_path($m->{file_b});
3907        my $pbat = $self->ensure_path($dir);
3908        my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3909                                        undef, -1);
3910        print "\tA\t$m->{file_b}\n" unless $::_q;
3911        $self->apply_autoprops($file, $fbat);
3912        $self->chg_file($fbat, $m);
3913        $self->close_file($fbat,undef,$self->{pool});
3914}
3915
3916sub C {
3917        my ($self, $m) = @_;
3918        my ($dir, $file) = split_path($m->{file_b});
3919        my $pbat = $self->ensure_path($dir);
3920        my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3921                                $self->url_path($m->{file_a}), $self->{r});
3922        print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3923        $self->chg_file($fbat, $m);
3924        $self->close_file($fbat,undef,$self->{pool});
3925}
3926
3927sub delete_entry {
3928        my ($self, $path, $pbat) = @_;
3929        my $rpath = $self->repo_path($path);
3930        my ($dir, $file) = split_path($rpath);
3931        $self->{rm}->{$dir} = 1;
3932        $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3933}
3934
3935sub R {
3936        my ($self, $m) = @_;
3937        my ($dir, $file) = split_path($m->{file_b});
3938        my $pbat = $self->ensure_path($dir);
3939        my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3940                                $self->url_path($m->{file_a}), $self->{r});
3941        print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3942        $self->apply_autoprops($file, $fbat);
3943        $self->chg_file($fbat, $m);
3944        $self->close_file($fbat,undef,$self->{pool});
3945
3946        ($dir, $file) = split_path($m->{file_a});
3947        $pbat = $self->ensure_path($dir);
3948        $self->delete_entry($m->{file_a}, $pbat);
3949}
3950
3951sub M {
3952        my ($self, $m) = @_;
3953        my ($dir, $file) = split_path($m->{file_b});
3954        my $pbat = $self->ensure_path($dir);
3955        my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3956                                $pbat,$self->{r},$self->{pool});
3957        print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3958        $self->chg_file($fbat, $m);
3959        $self->close_file($fbat,undef,$self->{pool});
3960}
3961
3962sub T { shift->M(@_) }
3963
3964sub change_file_prop {
3965        my ($self, $fbat, $pname, $pval) = @_;
3966        $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3967}
3968
3969sub _chg_file_get_blob ($$$$) {
3970        my ($self, $fbat, $m, $which) = @_;
3971        my $fh = $::_repository->temp_acquire("git_blob_$which");
3972        if ($m->{"mode_$which"} =~ /^120/) {
3973                print $fh 'link ' or croak $!;
3974                $self->change_file_prop($fbat,'svn:special','*');
3975        } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
3976                $self->change_file_prop($fbat,'svn:special',undef);
3977        }
3978        my $blob = $m->{"sha1_$which"};
3979        return ($fh,) if ($blob =~ /^0{40}$/);
3980        my $size = $::_repository->cat_blob($blob, $fh);
3981        croak "Failed to read object $blob" if ($size < 0);
3982        $fh->flush == 0 or croak $!;
3983        seek $fh, 0, 0 or croak $!;
3984
3985        my $exp = ::md5sum($fh);
3986        seek $fh, 0, 0 or croak $!;
3987        return ($fh, $exp);
3988}
3989
3990sub chg_file {
3991        my ($self, $fbat, $m) = @_;
3992        if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3993                $self->change_file_prop($fbat,'svn:executable','*');
3994        } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3995                $self->change_file_prop($fbat,'svn:executable',undef);
3996        }
3997        my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
3998        my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
3999        my $pool = SVN::Pool->new;
4000        my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4001        if (-s $fh_a) {
4002                my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4003                my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4004                if (defined $res) {
4005                        die "Unexpected result from send_txstream: $res\n",
4006                            "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4007                }
4008        } else {
4009                my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4010                die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4011                    if ($got ne $exp_b);
4012        }
4013        Git::temp_release($fh_b, 1);
4014        Git::temp_release($fh_a, 1);
4015        $pool->clear;
4016}
4017
4018sub D {
4019        my ($self, $m) = @_;
4020        my ($dir, $file) = split_path($m->{file_b});
4021        my $pbat = $self->ensure_path($dir);
4022        print "\tD\t$m->{file_b}\n" unless $::_q;
4023        $self->delete_entry($m->{file_b}, $pbat);
4024}
4025
4026sub close_edit {
4027        my ($self) = @_;
4028        my ($p,$bat) = ($self->{pool}, $self->{bat});
4029        foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4030                next if $_ eq '';
4031                $self->close_directory($bat->{$_}, $p);
4032        }
4033        $self->close_directory($bat->{''}, $p);
4034        $self->SUPER::close_edit($p);
4035        $p->clear;
4036}
4037
4038sub abort_edit {
4039        my ($self) = @_;
4040        $self->SUPER::abort_edit($self->{pool});
4041}
4042
4043sub DESTROY {
4044        my $self = shift;
4045        $self->SUPER::DESTROY(@_);
4046        $self->{pool}->clear;
4047}
4048
4049# this drives the editor
4050sub apply_diff {
4051        my ($self) = @_;
4052        my $mods = $self->{mods};
4053        my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4054        foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4055                my $f = $m->{chg};
4056                if (defined $o{$f}) {
4057                        $self->$f($m);
4058                } else {
4059                        fatal("Invalid change type: $f");
4060                }
4061        }
4062        $self->rmdirs if $_rmdir;
4063        if (@$mods == 0) {
4064                $self->abort_edit;
4065        } else {
4066                $self->close_edit;
4067        }
4068        return scalar @$mods;
4069}
4070
4071package Git::SVN::Ra;
4072use vars qw/@ISA $config_dir $_log_window_size/;
4073use strict;
4074use warnings;
4075my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4076
4077BEGIN {
4078        # enforce temporary pool usage for some simple functions
4079        no strict 'refs';
4080        for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4081                      get_file/) {
4082                my $SUPER = "SUPER::$f";
4083                *$f = sub {
4084                        my $self = shift;
4085                        my $pool = SVN::Pool->new;
4086                        my @ret = $self->$SUPER(@_,$pool);
4087                        $pool->clear;
4088                        wantarray ? @ret : $ret[0];
4089                };
4090        }
4091}
4092
4093sub _auth_providers () {
4094        [
4095          SVN::Client::get_simple_provider(),
4096          SVN::Client::get_ssl_server_trust_file_provider(),
4097          SVN::Client::get_simple_prompt_provider(
4098            \&Git::SVN::Prompt::simple, 2),
4099          SVN::Client::get_ssl_client_cert_file_provider(),
4100          SVN::Client::get_ssl_client_cert_prompt_provider(
4101            \&Git::SVN::Prompt::ssl_client_cert, 2),
4102          SVN::Client::get_ssl_client_cert_pw_file_provider(),
4103          SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4104            \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4105          SVN::Client::get_username_provider(),
4106          SVN::Client::get_ssl_server_trust_prompt_provider(
4107            \&Git::SVN::Prompt::ssl_server_trust),
4108          SVN::Client::get_username_prompt_provider(
4109            \&Git::SVN::Prompt::username, 2)
4110        ]
4111}
4112
4113sub escape_uri_only {
4114        my ($uri) = @_;
4115        my @tmp;
4116        foreach (split m{/}, $uri) {
4117                s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4118                push @tmp, $_;
4119        }
4120        join('/', @tmp);
4121}
4122
4123sub escape_url {
4124        my ($url) = @_;
4125        if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4126                my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4127                $url = "$scheme://$domain$uri";
4128        }
4129        $url;
4130}
4131
4132sub new {
4133        my ($class, $url) = @_;
4134        $url =~ s!/+$!!;
4135        return $RA if ($RA && $RA->{url} eq $url);
4136
4137        SVN::_Core::svn_config_ensure($config_dir, undef);
4138        my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4139        my $config = SVN::Core::config_get_config($config_dir);
4140        $RA = undef;
4141        my $dont_store_passwords = 1;
4142        my $conf_t = ${$config}{'config'};
4143        {
4144                no warnings 'once';
4145                # The usage of $SVN::_Core::SVN_CONFIG_* variables
4146                # produces warnings that variables are used only once.
4147                # I had not found the better way to shut them up, so
4148                # the warnings of type 'once' are disabled in this block.
4149                if (SVN::_Core::svn_config_get_bool($conf_t,
4150                    $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4151                    $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4152                    1) == 0) {
4153                        SVN::_Core::svn_auth_set_parameter($baton,
4154                            $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4155                            bless (\$dont_store_passwords, "_p_void"));
4156                }
4157                if (SVN::_Core::svn_config_get_bool($conf_t,
4158                    $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4159                    $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4160                    1) == 0) {
4161                        $Git::SVN::Prompt::_no_auth_cache = 1;
4162                }
4163        } # no warnings 'once'
4164        my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4165                              config => $config,
4166                              pool => SVN::Pool->new,
4167                              auth_provider_callbacks => $callbacks);
4168        $self->{url} = $url;
4169        $self->{svn_path} = $url;
4170        $self->{repos_root} = $self->get_repos_root;
4171        $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4172        $self->{cache} = { check_path => { r => 0, data => {} },
4173                           get_dir => { r => 0, data => {} } };
4174        $RA = bless $self, $class;
4175}
4176
4177sub check_path {
4178        my ($self, $path, $r) = @_;
4179        my $cache = $self->{cache}->{check_path};
4180        if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4181                return $cache->{data}->{$path};
4182        }
4183        my $pool = SVN::Pool->new;
4184        my $t = $self->SUPER::check_path($path, $r, $pool);
4185        $pool->clear;
4186        if ($r != $cache->{r}) {
4187                %{$cache->{data}} = ();
4188                $cache->{r} = $r;
4189        }
4190        $cache->{data}->{$path} = $t;
4191}
4192
4193sub get_dir {
4194        my ($self, $dir, $r) = @_;
4195        my $cache = $self->{cache}->{get_dir};
4196        if ($r == $cache->{r}) {
4197                if (my $x = $cache->{data}->{$dir}) {
4198                        return wantarray ? @$x : $x->[0];
4199                }
4200        }
4201        my $pool = SVN::Pool->new;
4202        my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4203        my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4204        $pool->clear;
4205        if ($r != $cache->{r}) {
4206                %{$cache->{data}} = ();
4207                $cache->{r} = $r;
4208        }
4209        $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
4210        wantarray ? (\%dirents, $r, $props) : \%dirents;
4211}
4212
4213sub DESTROY {
4214        # do not call the real DESTROY since we store ourselves in $RA
4215}
4216
4217# get_log(paths, start, end, limit,
4218#         discover_changed_paths, strict_node_history, receiver)
4219sub get_log {
4220        my ($self, @args) = @_;
4221        my $pool = SVN::Pool->new;
4222
4223        # the limit parameter was not supported in SVN 1.1.x, so we
4224        # drop it.  Therefore, the receiver callback passed to it
4225        # is made aware of this limitation by being wrapped if
4226        # the limit passed to is being wrapped.
4227        if ($SVN::Core::VERSION le '1.2.0') {
4228                my $limit = splice(@args, 3, 1);
4229                if ($limit > 0) {
4230                        my $receiver = pop @args;
4231                        push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
4232                }
4233        }
4234        my $ret = $self->SUPER::get_log(@args, $pool);
4235        $pool->clear;
4236        $ret;
4237}
4238
4239sub trees_match {
4240        my ($self, $url1, $rev1, $url2, $rev2) = @_;
4241        my $ctx = SVN::Client->new(auth => _auth_providers);
4242        my $out = IO::File->new_tmpfile;
4243
4244        # older SVN (1.1.x) doesn't take $pool as the last parameter for
4245        # $ctx->diff(), so we'll create a default one
4246        my $pool = SVN::Pool->new_default_sub;
4247
4248        $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
4249        $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
4250        $out->flush;
4251        my $ret = (($out->stat)[7] == 0);
4252        close $out or croak $!;
4253
4254        $ret;
4255}
4256
4257sub get_commit_editor {
4258        my ($self, $log, $cb, $pool) = @_;
4259        my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
4260        $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
4261}
4262
4263sub gs_do_update {
4264        my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
4265        my $new = ($rev_a == $rev_b);
4266        my $path = $gs->{path};
4267
4268        if ($new && -e $gs->{index}) {
4269                unlink $gs->{index} or die
4270                  "Couldn't unlink index: $gs->{index}: $!\n";
4271        }
4272        my $pool = SVN::Pool->new;
4273        $editor->set_path_strip($path);
4274        my (@pc) = split m#/#, $path;
4275        my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
4276                                        1, $editor, $pool);
4277        my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4278
4279        # Since we can't rely on svn_ra_reparent being available, we'll
4280        # just have to do some magic with set_path to make it so
4281        # we only want a partial path.
4282        my $sp = '';
4283        my $final = join('/', @pc);
4284        while (@pc) {
4285                $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
4286                $sp .= '/' if length $sp;
4287                $sp .= shift @pc;
4288        }
4289        die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
4290
4291        $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
4292
4293        $reporter->finish_report($pool);
4294        $pool->clear;
4295        $editor->{git_commit_ok};
4296}
4297
4298# this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
4299# svn_ra_reparent didn't work before 1.4)
4300sub gs_do_switch {
4301        my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
4302        my $path = $gs->{path};
4303        my $pool = SVN::Pool->new;
4304
4305        my $full_url = $self->{url};
4306        my $old_url = $full_url;
4307        $full_url .= '/' . escape_uri_only($path) if length $path;
4308        my ($ra, $reparented);
4309
4310        if ($old_url =~ m#^svn(\+ssh)?://#) {
4311                $_[0] = undef;
4312                $self = undef;
4313                $RA = undef;
4314                $ra = Git::SVN::Ra->new($full_url);
4315                $ra_invalid = 1;
4316        } elsif ($old_url ne $full_url) {
4317                SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
4318                $self->{url} = $full_url;
4319                $reparented = 1;
4320        }
4321
4322        $ra ||= $self;
4323        $url_b = escape_url($url_b);
4324        my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
4325        my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4326        $reporter->set_path('', $rev_a, 0, @lock, $pool);
4327        $reporter->finish_report($pool);
4328
4329        if ($reparented) {
4330                SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
4331                $self->{url} = $old_url;
4332        }
4333
4334        $pool->clear;
4335        $editor->{git_commit_ok};
4336}
4337
4338sub longest_common_path {
4339        my ($gsv, $globs) = @_;
4340        my %common;
4341        my $common_max = scalar @$gsv;
4342
4343        foreach my $gs (@$gsv) {
4344                my @tmp = split m#/#, $gs->{path};
4345                my $p = '';
4346                foreach (@tmp) {
4347                        $p .= length($p) ? "/$_" : $_;
4348                        $common{$p} ||= 0;
4349                        $common{$p}++;
4350                }
4351        }
4352        $globs ||= [];
4353        $common_max += scalar @$globs;
4354        foreach my $glob (@$globs) {
4355                my @tmp = split m#/#, $glob->{path}->{left};
4356                my $p = '';
4357                foreach (@tmp) {
4358                        $p .= length($p) ? "/$_" : $_;
4359                        $common{$p} ||= 0;
4360                        $common{$p}++;
4361                }
4362        }
4363
4364        my $longest_path = '';
4365        foreach (sort {length $b <=> length $a} keys %common) {
4366                if ($common{$_} == $common_max) {
4367                        $longest_path = $_;
4368                        last;
4369                }
4370        }
4371        $longest_path;
4372}
4373
4374sub gs_fetch_loop_common {
4375        my ($self, $base, $head, $gsv, $globs) = @_;
4376        return if ($base > $head);
4377        my $inc = $_log_window_size;
4378        my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
4379        my $longest_path = longest_common_path($gsv, $globs);
4380        my $ra_url = $self->{url};
4381        while (1) {
4382                my %revs;
4383                my $err;
4384                my $err_handler = $SVN::Error::handler;
4385                $SVN::Error::handler = sub {
4386                        ($err) = @_;
4387                        skip_unknown_revs($err);
4388                };
4389                sub _cb {
4390                        my ($paths, $r, $author, $date, $log) = @_;
4391                        [ dup_changed_paths($paths),
4392                          { author => $author, date => $date, log => $log } ];
4393                }
4394                $self->get_log([$longest_path], $min, $max, 0, 1, 1,
4395                               sub { $revs{$_[1]} = _cb(@_) });
4396                if ($err) {
4397                        print "Checked through r$max\r";
4398                }
4399                if ($err && $max >= $head) {
4400                        print STDERR "Path '$longest_path' ",
4401                                     "was probably deleted:\n",
4402                                     $err->expanded_message,
4403                                     "\nWill attempt to follow ",
4404                                     "revisions r$min .. r$max ",
4405                                     "committed before the deletion\n";
4406                        my $hi = $max;
4407                        while (--$hi >= $min) {
4408                                my $ok;
4409                                $self->get_log([$longest_path], $min, $hi,
4410                                               0, 1, 1, sub {
4411                                               $ok ||= $_[1];
4412                                               $revs{$_[1]} = _cb(@_) });
4413                                if ($ok) {
4414                                        print STDERR "r$min .. r$ok OK\n";
4415                                        last;
4416                                }
4417                        }
4418                }
4419                $SVN::Error::handler = $err_handler;
4420
4421                my %exists = map { $_->{path} => $_ } @$gsv;
4422                foreach my $r (sort {$a <=> $b} keys %revs) {
4423                        my ($paths, $logged) = @{$revs{$r}};
4424
4425                        foreach my $gs ($self->match_globs(\%exists, $paths,
4426                                                           $globs, $r)) {
4427                                if ($gs->rev_map_max >= $r) {
4428                                        next;
4429                                }
4430                                next unless $gs->match_paths($paths, $r);
4431                                $gs->{logged_rev_props} = $logged;
4432                                if (my $last_commit = $gs->last_commit) {
4433                                        $gs->assert_index_clean($last_commit);
4434                                }
4435                                my $log_entry = $gs->do_fetch($paths, $r);
4436                                if ($log_entry) {
4437                                        $gs->do_git_commit($log_entry);
4438                                }
4439                                $INDEX_FILES{$gs->{index}} = 1;
4440                        }
4441                        foreach my $g (@$globs) {
4442                                my $k = "svn-remote.$g->{remote}." .
4443                                        "$g->{t}-maxRev";
4444                                Git::SVN::tmp_config($k, $r);
4445                        }
4446                        if ($ra_invalid) {
4447                                $_[0] = undef;
4448                                $self = undef;
4449                                $RA = undef;
4450                                $self = Git::SVN::Ra->new($ra_url);
4451                                $ra_invalid = undef;
4452                        }
4453                }
4454                # pre-fill the .rev_db since it'll eventually get filled in
4455                # with '0' x40 if something new gets committed
4456                foreach my $gs (@$gsv) {
4457                        next if $gs->rev_map_max >= $max;
4458                        next if defined $gs->rev_map_get($max);
4459                        $gs->rev_map_set($max, 0 x40);
4460                }
4461                foreach my $g (@$globs) {
4462                        my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
4463                        Git::SVN::tmp_config($k, $max);
4464                }
4465                last if $max >= $head;
4466                $min = $max + 1;
4467                $max += $inc;
4468                $max = $head if ($max > $head);
4469        }
4470        Git::SVN::gc();
4471}
4472
4473sub get_dir_globbed {
4474        my ($self, $left, $depth, $r) = @_;
4475
4476        my @x = eval { $self->get_dir($left, $r) };
4477        return unless scalar @x == 3;
4478        my $dirents = $x[0];
4479        my @finalents;
4480        foreach my $de (keys %$dirents) {
4481                next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4482                if ($depth > 1) {
4483                        my @args = ("$left/$de", $depth - 1, $r);
4484                        foreach my $dir ($self->get_dir_globbed(@args)) {
4485                                push @finalents, "$de/$dir";
4486                        }
4487                } else {
4488                        push @finalents, $de;
4489                }
4490        }
4491        @finalents;
4492}
4493
4494sub match_globs {
4495        my ($self, $exists, $paths, $globs, $r) = @_;
4496
4497        sub get_dir_check {
4498                my ($self, $exists, $g, $r) = @_;
4499
4500                my @dirs = $self->get_dir_globbed($g->{path}->{left},
4501                                                  $g->{path}->{depth},
4502                                                  $r);
4503
4504                foreach my $de (@dirs) {
4505                        my $p = $g->{path}->full_path($de);
4506                        next if $exists->{$p};
4507                        next if (length $g->{path}->{right} &&
4508                                 ($self->check_path($p, $r) !=
4509                                  $SVN::Node::dir));
4510                        $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4511                                         $g->{ref}->full_path($de), 1);
4512                }
4513        }
4514        foreach my $g (@$globs) {
4515                if (my $path = $paths->{"/$g->{path}->{left}"}) {
4516                        if ($path->{action} =~ /^[AR]$/) {
4517                                get_dir_check($self, $exists, $g, $r);
4518                        }
4519                }
4520                foreach (keys %$paths) {
4521                        if (/$g->{path}->{left_regex}/ &&
4522                            !/$g->{path}->{regex}/) {
4523                                next if $paths->{$_}->{action} !~ /^[AR]$/;
4524                                get_dir_check($self, $exists, $g, $r);
4525                        }
4526                        next unless /$g->{path}->{regex}/;
4527                        my $p = $1;
4528                        my $pathname = $g->{path}->full_path($p);
4529                        next if $exists->{$pathname};
4530                        next if ($self->check_path($pathname, $r) !=
4531                                 $SVN::Node::dir);
4532                        $exists->{$pathname} = Git::SVN->init(
4533                                              $self->{url}, $pathname, undef,
4534                                              $g->{ref}->full_path($p), 1);
4535                }
4536                my $c = '';
4537                foreach (split m#/#, $g->{path}->{left}) {
4538                        $c .= "/$_";
4539                        next unless ($paths->{$c} &&
4540                                     ($paths->{$c}->{action} =~ /^[AR]$/));
4541                        get_dir_check($self, $exists, $g, $r);
4542                }
4543        }
4544        values %$exists;
4545}
4546
4547sub minimize_url {
4548        my ($self) = @_;
4549        return $self->{url} if ($self->{url} eq $self->{repos_root});
4550        my $url = $self->{repos_root};
4551        my @components = split(m!/!, $self->{svn_path});
4552        my $c = '';
4553        do {
4554                $url .= "/$c" if length $c;
4555                eval { (ref $self)->new($url)->get_latest_revnum };
4556        } while ($@ && ($c = shift @components));
4557        $url;
4558}
4559
4560sub can_do_switch {
4561        my $self = shift;
4562        unless (defined $can_do_switch) {
4563                my $pool = SVN::Pool->new;
4564                my $rep = eval {
4565                        $self->do_switch(1, '', 0, $self->{url},
4566                                         SVN::Delta::Editor->new, $pool);
4567                };
4568                if ($@) {
4569                        $can_do_switch = 0;
4570                } else {
4571                        $rep->abort_report($pool);
4572                        $can_do_switch = 1;
4573                }
4574                $pool->clear;
4575        }
4576        $can_do_switch;
4577}
4578
4579sub skip_unknown_revs {
4580        my ($err) = @_;
4581        my $errno = $err->apr_err();
4582        # Maybe the branch we're tracking didn't
4583        # exist when the repo started, so it's
4584        # not an error if it doesn't, just continue
4585        #
4586        # Wonderfully consistent library, eh?
4587        # 160013 - svn:// and file://
4588        # 175002 - http(s)://
4589        # 175007 - http(s):// (this repo required authorization, too...)
4590        #   More codes may be discovered later...
4591        if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4592                my $err_key = $err->expanded_message;
4593                # revision numbers change every time, filter them out
4594                $err_key =~ s/\d+/\0/g;
4595                $err_key = "$errno\0$err_key";
4596                unless ($ignored_err{$err_key}) {
4597                        warn "W: Ignoring error from SVN, path probably ",
4598                             "does not exist: ($errno): ",
4599                             $err->expanded_message,"\n";
4600                        warn "W: Do not be alarmed at the above message ",
4601                             "git-svn is just searching aggressively for ",
4602                             "old history.\n",
4603                             "This may take a while on large repositories\n";
4604                        $ignored_err{$err_key} = 1;
4605                }
4606                return;
4607        }
4608        die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4609}
4610
4611# svn_log_changed_path_t objects passed to get_log are likely to be
4612# overwritten even if only the refs are copied to an external variable,
4613# so we should dup the structures in their entirety.  Using an externally
4614# passed pool (instead of our temporary and quickly cleared pool in
4615# Git::SVN::Ra) does not help matters at all...
4616sub dup_changed_paths {
4617        my ($paths) = @_;
4618        return undef unless $paths;
4619        my %ret;
4620        foreach my $p (keys %$paths) {
4621                my $i = $paths->{$p};
4622                my %s = map { $_ => $i->$_ }
4623                              qw/copyfrom_path copyfrom_rev action/;
4624                $ret{$p} = \%s;
4625        }
4626        \%ret;
4627}
4628
4629package Git::SVN::Log;
4630use strict;
4631use warnings;
4632use POSIX qw/strftime/;
4633use constant commit_log_separator => ('-' x 72) . "\n";
4634use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4635            %rusers $show_commit $incremental/;
4636my $l_fmt;
4637
4638sub cmt_showable {
4639        my ($c) = @_;
4640        return 1 if defined $c->{r};
4641
4642        # big commit message got truncated by the 16k pretty buffer in rev-list
4643        if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4644                                $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4645                @{$c->{l}} = ();
4646                my @log = command(qw/cat-file commit/, $c->{c});
4647
4648                # shift off the headers
4649                shift @log while ($log[0] ne '');
4650                shift @log;
4651
4652                # TODO: make $c->{l} not have a trailing newline in the future
4653                @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4654
4655                (undef, $c->{r}, undef) = ::extract_metadata(
4656                                (grep(/^git-svn-id: /, @log))[-1]);
4657        }
4658        return defined $c->{r};
4659}
4660
4661sub log_use_color {
4662        return $color || Git->repository->get_colorbool('color.diff');
4663}
4664
4665sub git_svn_log_cmd {
4666        my ($r_min, $r_max, @args) = @_;
4667        my $head = 'HEAD';
4668        my (@files, @log_opts);
4669        foreach my $x (@args) {
4670                if ($x eq '--' || @files) {
4671                        push @files, $x;
4672                } else {
4673                        if (::verify_ref("$x^0")) {
4674                                $head = $x;
4675                        } else {
4676                                push @log_opts, $x;
4677                        }
4678                }
4679        }
4680
4681        my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4682        $gs ||= Git::SVN->_new;
4683        my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4684                   $gs->refname);
4685        push @cmd, '-r' unless $non_recursive;
4686        push @cmd, qw/--raw --name-status/ if $verbose;
4687        push @cmd, '--color' if log_use_color();
4688        push @cmd, @log_opts;
4689        if (defined $r_max && $r_max == $r_min) {
4690                push @cmd, '--max-count=1';
4691                if (my $c = $gs->rev_map_get($r_max)) {
4692                        push @cmd, $c;
4693                }
4694        } elsif (defined $r_max) {
4695                if ($r_max < $r_min) {
4696                        ($r_min, $r_max) = ($r_max, $r_min);
4697                }
4698                my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4699                my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4700                # If there are no commits in the range, both $c_max and $c_min
4701                # will be undefined.  If there is at least 1 commit in the
4702                # range, both will be defined.
4703                return () if !defined $c_min || !defined $c_max;
4704                if ($c_min eq $c_max) {
4705                        push @cmd, '--max-count=1', $c_min;
4706                } else {
4707                        push @cmd, '--boundary', "$c_min..$c_max";
4708                }
4709        }
4710        return (@cmd, @files);
4711}
4712
4713# adapted from pager.c
4714sub config_pager {
4715        $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4716        if (!defined $pager) {
4717                $pager = 'less';
4718        } elsif (length $pager == 0 || $pager eq 'cat') {
4719                $pager = undef;
4720        }
4721        $ENV{GIT_PAGER_IN_USE} = defined($pager);
4722}
4723
4724sub run_pager {
4725        return unless -t *STDOUT && defined $pager;
4726        pipe my ($rfd, $wfd) or return;
4727        defined(my $pid = fork) or ::fatal "Can't fork: $!";
4728        if (!$pid) {
4729                open STDOUT, '>&', $wfd or
4730                                     ::fatal "Can't redirect to stdout: $!";
4731                return;
4732        }
4733        open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4734        $ENV{LESS} ||= 'FRSX';
4735        exec $pager or ::fatal "Can't run pager: $! ($pager)";
4736}
4737
4738sub format_svn_date {
4739        return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4740}
4741
4742sub parse_git_date {
4743        my ($t, $tz) = @_;
4744        # Date::Parse isn't in the standard Perl distro :(
4745        if ($tz =~ s/^\+//) {
4746                $t += tz_to_s_offset($tz);
4747        } elsif ($tz =~ s/^\-//) {
4748                $t -= tz_to_s_offset($tz);
4749        }
4750        return $t;
4751}
4752
4753sub set_local_timezone {
4754        if (defined $TZ) {
4755                $ENV{TZ} = $TZ;
4756        } else {
4757                delete $ENV{TZ};
4758        }
4759}
4760
4761sub tz_to_s_offset {
4762        my ($tz) = @_;
4763        $tz =~ s/(\d\d)$//;
4764        return ($1 * 60) + ($tz * 3600);
4765}
4766
4767sub get_author_info {
4768        my ($dest, $author, $t, $tz) = @_;
4769        $author =~ s/(?:^\s*|\s*$)//g;
4770        $dest->{a_raw} = $author;
4771        my $au;
4772        if ($::_authors) {
4773                $au = $rusers{$author} || undef;
4774        }
4775        if (!$au) {
4776                ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4777        }
4778        $dest->{t} = $t;
4779        $dest->{tz} = $tz;
4780        $dest->{a} = $au;
4781        $dest->{t_utc} = parse_git_date($t, $tz);
4782}
4783
4784sub process_commit {
4785        my ($c, $r_min, $r_max, $defer) = @_;
4786        if (defined $r_min && defined $r_max) {
4787                if ($r_min == $c->{r} && $r_min == $r_max) {
4788                        show_commit($c);
4789                        return 0;
4790                }
4791                return 1 if $r_min == $r_max;
4792                if ($r_min < $r_max) {
4793                        # we need to reverse the print order
4794                        return 0 if (defined $limit && --$limit < 0);
4795                        push @$defer, $c;
4796                        return 1;
4797                }
4798                if ($r_min != $r_max) {
4799                        return 1 if ($r_min < $c->{r});
4800                        return 1 if ($r_max > $c->{r});
4801                }
4802        }
4803        return 0 if (defined $limit && --$limit < 0);
4804        show_commit($c);
4805        return 1;
4806}
4807
4808sub show_commit {
4809        my $c = shift;
4810        if ($oneline) {
4811                my $x = "\n";
4812                if (my $l = $c->{l}) {
4813                        while ($l->[0] =~ /^\s*$/) { shift @$l }
4814                        $x = $l->[0];
4815                }
4816                $l_fmt ||= 'A' . length($c->{r});
4817                print 'r',pack($l_fmt, $c->{r}),' | ';
4818                print "$c->{c} | " if $show_commit;
4819                print $x;
4820        } else {
4821                show_commit_normal($c);
4822        }
4823}
4824
4825sub show_commit_changed_paths {
4826        my ($c) = @_;
4827        return unless $c->{changed};
4828        print "Changed paths:\n", @{$c->{changed}};
4829}
4830
4831sub show_commit_normal {
4832        my ($c) = @_;
4833        print commit_log_separator, "r$c->{r} | ";
4834        print "$c->{c} | " if $show_commit;
4835        print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4836        my $nr_line = 0;
4837
4838        if (my $l = $c->{l}) {
4839                while ($l->[$#$l] eq "\n" && $#$l > 0
4840                                          && $l->[($#$l - 1)] eq "\n") {
4841                        pop @$l;
4842                }
4843                $nr_line = scalar @$l;
4844                if (!$nr_line) {
4845                        print "1 line\n\n\n";
4846                } else {
4847                        if ($nr_line == 1) {
4848                                $nr_line = '1 line';
4849                        } else {
4850                                $nr_line .= ' lines';
4851                        }
4852                        print $nr_line, "\n";
4853                        show_commit_changed_paths($c);
4854                        print "\n";
4855                        print $_ foreach @$l;
4856                }
4857        } else {
4858                print "1 line\n";
4859                show_commit_changed_paths($c);
4860                print "\n";
4861
4862        }
4863        foreach my $x (qw/raw stat diff/) {
4864                if ($c->{$x}) {
4865                        print "\n";
4866                        print $_ foreach @{$c->{$x}}
4867                }
4868        }
4869}
4870
4871sub cmd_show_log {
4872        my (@args) = @_;
4873        my ($r_min, $r_max);
4874        my $r_last = -1; # prevent dupes
4875        set_local_timezone();
4876        if (defined $::_revision) {
4877                if ($::_revision =~ /^(\d+):(\d+)$/) {
4878                        ($r_min, $r_max) = ($1, $2);
4879                } elsif ($::_revision =~ /^\d+$/) {
4880                        $r_min = $r_max = $::_revision;
4881                } else {
4882                        ::fatal "-r$::_revision is not supported, use ",
4883                                "standard 'git log' arguments instead";
4884                }
4885        }
4886
4887        config_pager();
4888        @args = git_svn_log_cmd($r_min, $r_max, @args);
4889        if (!@args) {
4890                print commit_log_separator unless $incremental || $oneline;
4891                return;
4892        }
4893        my $log = command_output_pipe(@args);
4894        run_pager();
4895        my (@k, $c, $d, $stat);
4896        my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4897        while (<$log>) {
4898                if (/^${esc_color}commit -?($::sha1_short)/o) {
4899                        my $cmt = $1;
4900                        if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4901                                $r_last = $c->{r};
4902                                process_commit($c, $r_min, $r_max, \@k) or
4903                                                                goto out;
4904                        }
4905                        $d = undef;
4906                        $c = { c => $cmt };
4907                } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4908                        get_author_info($c, $1, $2, $3);
4909                } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4910                        # ignore
4911                } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4912                        push @{$c->{raw}}, $_;
4913                } elsif (/^${esc_color}[ACRMDT]\t/) {
4914                        # we could add $SVN->{svn_path} here, but that requires
4915                        # remote access at the moment (repo_path_split)...
4916                        s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
4917                        push @{$c->{changed}}, $_;
4918                } elsif (/^${esc_color}diff /o) {
4919                        $d = 1;
4920                        push @{$c->{diff}}, $_;
4921                } elsif ($d) {
4922                        push @{$c->{diff}}, $_;
4923                } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4924                          $esc_color*[\+\-]*$esc_color$/x) {
4925                        $stat = 1;
4926                        push @{$c->{stat}}, $_;
4927                } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4928                        push @{$c->{stat}}, $_;
4929                        $stat = undef;
4930                } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
4931                        ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4932                } elsif (s/^${esc_color}    //o) {
4933                        push @{$c->{l}}, $_;
4934                }
4935        }
4936        if ($c && defined $c->{r} && $c->{r} != $r_last) {
4937                $r_last = $c->{r};
4938                process_commit($c, $r_min, $r_max, \@k);
4939        }
4940        if (@k) {
4941                ($r_min, $r_max) = ($r_max, $r_min);
4942                process_commit($_, $r_min, $r_max) foreach reverse @k;
4943        }
4944out:
4945        close $log;
4946        print commit_log_separator unless $incremental || $oneline;
4947}
4948
4949sub cmd_blame {
4950        my $path = pop;
4951
4952        config_pager();
4953        run_pager();
4954
4955        my ($fh, $ctx, $rev);
4956
4957        if ($_git_format) {
4958                ($fh, $ctx) = command_output_pipe('blame', @_, $path);
4959                while (my $line = <$fh>) {
4960                        if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
4961                                # Uncommitted edits show up as a rev ID of
4962                                # all zeros, which we can't look up with
4963                                # cmt_metadata
4964                                if ($1 !~ /^0+$/) {
4965                                        (undef, $rev, undef) =
4966                                                ::cmt_metadata($1);
4967                                        $rev = '0' if (!$rev);
4968                                } else {
4969                                        $rev = '0';
4970                                }
4971                                $rev = sprintf('%-10s', $rev);
4972                                $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
4973                        }
4974                        print $line;
4975                }
4976        } else {
4977                ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
4978                                                  '--', $path);
4979                my ($sha1);
4980                my %authors;
4981                while (my $line = <$fh>) {
4982                        if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
4983                                $sha1 = $1;
4984                                (undef, $rev, undef) = ::cmt_metadata($1);
4985                                $rev = '0' if (!$rev);
4986                        }
4987                        elsif ($line =~ /^author (.*)/) {
4988                                $authors{$rev} = $1;
4989                                $authors{$rev} =~ s/\s/_/g;
4990                        }
4991                        elsif ($line =~ /^\t(.*)$/) {
4992                                printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
4993                        }
4994                }
4995        }
4996        command_close_pipe($fh, $ctx);
4997}
4998
4999package Git::SVN::Migration;
5000# these version numbers do NOT correspond to actual version numbers
5001# of git nor git-svn.  They are just relative.
5002#
5003# v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5004#
5005# v1 layout: .git/$id/info/url, refs/remotes/$id
5006#
5007# v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5008#
5009# v3 layout: .git/svn/$id, refs/remotes/$id
5010#            - info/url may remain for backwards compatibility
5011#            - this is what we migrate up to this layout automatically,
5012#            - this will be used by git svn init on single branches
5013# v3.1 layout (auto migrated):
5014#            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5015#              for backwards compatibility
5016#
5017# v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5018#            - this is only created for newly multi-init-ed
5019#              repositories.  Similar in spirit to the
5020#              --use-separate-remotes option in git-clone (now default)
5021#            - we do not automatically migrate to this (following
5022#              the example set by core git)
5023#
5024# v5 layout: .rev_db.$UUID => .rev_map.$UUID
5025#            - newer, more-efficient format that uses 24-bytes per record
5026#              with no filler space.
5027#            - use xxd -c24 < .rev_map.$UUID to view and debug
5028#            - This is a one-way migration, repositories updated to the
5029#              new format will not be able to use old git-svn without
5030#              rebuilding the .rev_db.  Rebuilding the rev_db is not
5031#              possible if noMetadata or useSvmProps are set; but should
5032#              be no problem for users that use the (sensible) defaults.
5033use strict;
5034use warnings;
5035use Carp qw/croak/;
5036use File::Path qw/mkpath/;
5037use File::Basename qw/dirname basename/;
5038use vars qw/$_minimize/;
5039
5040sub migrate_from_v0 {
5041        my $git_dir = $ENV{GIT_DIR};
5042        return undef unless -d $git_dir;
5043        my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5044        my $migrated = 0;
5045        while (<$fh>) {
5046                chomp;
5047                my ($id, $orig_ref) = ($_, $_);
5048                next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5049                next unless -f "$git_dir/$id/info/url";
5050                my $new_ref = "refs/remotes/$id";
5051                if (::verify_ref("$new_ref^0")) {
5052                        print STDERR "W: $orig_ref is probably an old ",
5053                                     "branch used by an ancient version of ",
5054                                     "git-svn.\n",
5055                                     "However, $new_ref also exists.\n",
5056                                     "We will not be able ",
5057                                     "to use this branch until this ",
5058                                     "ambiguity is resolved.\n";
5059                        next;
5060                }
5061                print STDERR "Migrating from v0 layout...\n" if !$migrated;
5062                print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5063                command_noisy('update-ref', $new_ref, $orig_ref);
5064                command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5065                $migrated++;
5066        }
5067        command_close_pipe($fh, $ctx);
5068        print STDERR "Done migrating from v0 layout...\n" if $migrated;
5069        $migrated;
5070}
5071
5072sub migrate_from_v1 {
5073        my $git_dir = $ENV{GIT_DIR};
5074        my $migrated = 0;
5075        return $migrated unless -d $git_dir;
5076        my $svn_dir = "$git_dir/svn";
5077
5078        # just in case somebody used 'svn' as their $id at some point...
5079        return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5080
5081        print STDERR "Migrating from a git-svn v1 layout...\n";
5082        mkpath([$svn_dir]);
5083        print STDERR "Data from a previous version of git-svn exists, but\n\t",
5084                     "$svn_dir\n\t(required for this version ",
5085                     "($::VERSION) of git-svn) does not exist.\n";
5086        my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5087        while (<$fh>) {
5088                my $x = $_;
5089                next unless $x =~ s#^refs/remotes/##;
5090                chomp $x;
5091                next unless -f "$git_dir/$x/info/url";
5092                my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5093                next unless $u;
5094                my $dn = dirname("$git_dir/svn/$x");
5095                mkpath([$dn]) unless -d $dn;
5096                if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5097                        mkpath(["$git_dir/svn/svn"]);
5098                        print STDERR " - $git_dir/$x/info => ",
5099                                        "$git_dir/svn/$x/info\n";
5100                        rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5101                               croak "$!: $x";
5102                        # don't worry too much about these, they probably
5103                        # don't exist with repos this old (save for index,
5104                        # and we can easily regenerate that)
5105                        foreach my $f (qw/unhandled.log index .rev_db/) {
5106                                rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5107                        }
5108                } else {
5109                        print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5110                        rename "$git_dir/$x", "$git_dir/svn/$x" or
5111                               croak "$!: $x";
5112                }
5113                $migrated++;
5114        }
5115        command_close_pipe($fh, $ctx);
5116        print STDERR "Done migrating from a git-svn v1 layout\n";
5117        $migrated;
5118}
5119
5120sub read_old_urls {
5121        my ($l_map, $pfx, $path) = @_;
5122        my @dir;
5123        foreach (<$path/*>) {
5124                if (-r "$_/info/url") {
5125                        $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5126                        my $ref_id = $pfx . basename $_;
5127                        my $url = ::file_to_s("$_/info/url");
5128                        $l_map->{$ref_id} = $url;
5129                } elsif (-d $_) {
5130                        push @dir, $_;
5131                }
5132        }
5133        foreach (@dir) {
5134                my $x = $_;
5135                $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5136                read_old_urls($l_map, $x, $_);
5137        }
5138}
5139
5140sub migrate_from_v2 {
5141        my @cfg = command(qw/config -l/);
5142        return if grep /^svn-remote\..+\.url=/, @cfg;
5143        my %l_map;
5144        read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5145        my $migrated = 0;
5146
5147        foreach my $ref_id (sort keys %l_map) {
5148                eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5149                if ($@) {
5150                        Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5151                }
5152                $migrated++;
5153        }
5154        $migrated;
5155}
5156
5157sub minimize_connections {
5158        my $r = Git::SVN::read_all_remotes();
5159        my $new_urls = {};
5160        my $root_repos = {};
5161        foreach my $repo_id (keys %$r) {
5162                my $url = $r->{$repo_id}->{url} or next;
5163                my $fetch = $r->{$repo_id}->{fetch} or next;
5164                my $ra = Git::SVN::Ra->new($url);
5165
5166                # skip existing cases where we already connect to the root
5167                if (($ra->{url} eq $ra->{repos_root}) ||
5168                    ($ra->{repos_root} eq $repo_id)) {
5169                        $root_repos->{$ra->{url}} = $repo_id;
5170                        next;
5171                }
5172
5173                my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
5174                my $root_path = $ra->{url};
5175                $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
5176                foreach my $path (keys %$fetch) {
5177                        my $ref_id = $fetch->{$path};
5178                        my $gs = Git::SVN->new($ref_id, $repo_id, $path);
5179
5180                        # make sure we can read when connecting to
5181                        # a higher level of a repository
5182                        my ($last_rev, undef) = $gs->last_rev_commit;
5183                        if (!defined $last_rev) {
5184                                $last_rev = eval {
5185                                        $root_ra->get_latest_revnum;
5186                                };
5187                                next if $@;
5188                        }
5189                        my $new = $root_path;
5190                        $new .= length $path ? "/$path" : '';
5191                        eval {
5192                                $root_ra->get_log([$new], $last_rev, $last_rev,
5193                                                  0, 0, 1, sub { });
5194                        };
5195                        next if $@;
5196                        $new_urls->{$ra->{repos_root}}->{$new} =
5197                                { ref_id => $ref_id,
5198                                  old_repo_id => $repo_id,
5199                                  old_path => $path };
5200                }
5201        }
5202
5203        my @emptied;
5204        foreach my $url (keys %$new_urls) {
5205                # see if we can re-use an existing [svn-remote "repo_id"]
5206                # instead of creating a(n ugly) new section:
5207                my $repo_id = $root_repos->{$url} || $url;
5208
5209                my $fetch = $new_urls->{$url};
5210                foreach my $path (keys %$fetch) {
5211                        my $x = $fetch->{$path};
5212                        Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
5213                        my $pfx = "svn-remote.$x->{old_repo_id}";
5214
5215                        my $old_fetch = quotemeta("$x->{old_path}:".
5216                                                  "refs/remotes/$x->{ref_id}");
5217                        command_noisy(qw/config --unset/,
5218                                      "$pfx.fetch", '^'. $old_fetch . '$');
5219                        delete $r->{$x->{old_repo_id}}->
5220                               {fetch}->{$x->{old_path}};
5221                        if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
5222                                command_noisy(qw/config --unset/,
5223                                              "$pfx.url");
5224                                push @emptied, $x->{old_repo_id}
5225                        }
5226                }
5227        }
5228        if (@emptied) {
5229                my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
5230                print STDERR <<EOF;
5231The following [svn-remote] sections in your config file ($file) are empty
5232and can be safely removed:
5233EOF
5234                print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
5235        }
5236}
5237
5238sub migration_check {
5239        migrate_from_v0();
5240        migrate_from_v1();
5241        migrate_from_v2();
5242        minimize_connections() if $_minimize;
5243}
5244
5245package Git::IndexInfo;
5246use strict;
5247use warnings;
5248use Git qw/command_input_pipe command_close_pipe/;
5249
5250sub new {
5251        my ($class) = @_;
5252        my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
5253        bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
5254}
5255
5256sub remove {
5257        my ($self, $path) = @_;
5258        if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
5259                return ++$self->{nr};
5260        }
5261        undef;
5262}
5263
5264sub update {
5265        my ($self, $mode, $hash, $path) = @_;
5266        if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
5267                return ++$self->{nr};
5268        }
5269        undef;
5270}
5271
5272sub DESTROY {
5273        my ($self) = @_;
5274        command_close_pipe($self->{gui}, $self->{ctx});
5275}
5276
5277package Git::SVN::GlobSpec;
5278use strict;
5279use warnings;
5280
5281sub new {
5282        my ($class, $glob) = @_;
5283        my $re = $glob;
5284        $re =~ s!/+$!!g; # no need for trailing slashes
5285        $re =~ m!^([^*]*)(\*(?:/\*)*)([^*]*)$!;
5286        my $temp = $re;
5287        my ($left, $right) = ($1, $3);
5288        $re = $2;
5289        my $depth = $re =~ tr/*/*/;
5290        if ($depth != $temp =~ tr/*/*/) {
5291                die "Only one set of wildcard directories " .
5292                        "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
5293        }
5294        if ($depth == 0) {
5295                die "One '*' is needed for glob: '$glob'\n";
5296        }
5297        $re =~ s!\*!\[^/\]*!g;
5298        $re = quotemeta($left) . "($re)" . quotemeta($right);
5299        if (length $left && !($left =~ s!/+$!!g)) {
5300                die "Missing trailing '/' on left side of: '$glob' ($left)\n";
5301        }
5302        if (length $right && !($right =~ s!^/+!!g)) {
5303                die "Missing leading '/' on right side of: '$glob' ($right)\n";
5304        }
5305        my $left_re = qr/^\/\Q$left\E(\/|$)/;
5306        bless { left => $left, right => $right, left_regex => $left_re,
5307                regex => qr/$re/, glob => $glob, depth => $depth }, $class;
5308}
5309
5310sub full_path {
5311        my ($self, $path) = @_;
5312        return (length $self->{left} ? "$self->{left}/" : '') .
5313               $path . (length $self->{right} ? "/$self->{right}" : '');
5314}
5315
5316__END__
5317
5318Data structures:
5319
5320
5321$remotes = { # returned by read_all_remotes()
5322        'svn' => {
5323                # svn-remote.svn.url=https://svn.musicpd.org
5324                url => 'https://svn.musicpd.org',
5325                # svn-remote.svn.fetch=mpd/trunk:trunk
5326                fetch => {
5327                        'mpd/trunk' => 'trunk',
5328                },
5329                # svn-remote.svn.tags=mpd/tags/*:tags/*
5330                tags => {
5331                        path => {
5332                                left => 'mpd/tags',
5333                                right => '',
5334                                regex => qr!mpd/tags/([^/]+)$!,
5335                                glob => 'tags/*',
5336                        },
5337                        ref => {
5338                                left => 'tags',
5339                                right => '',
5340                                regex => qr!tags/([^/]+)$!,
5341                                glob => 'tags/*',
5342                        },
5343                }
5344        }
5345};
5346
5347$log_entry hashref as returned by libsvn_log_entry()
5348{
5349        log => 'whitespace-formatted log entry
5350',                                              # trailing newline is preserved
5351        revision => '8',                        # integer
5352        date => '2004-02-24T17:01:44.108345Z',  # commit date
5353        author => 'committer name'
5354};
5355
5356
5357# this is generated by generate_diff();
5358@mods = array of diff-index line hashes, each element represents one line
5359        of diff-index output
5360
5361diff-index line ($m hash)
5362{
5363        mode_a => first column of diff-index output, no leading ':',
5364        mode_b => second column of diff-index output,
5365        sha1_b => sha1sum of the final blob,
5366        chg => change type [MCRADT],
5367        file_a => original file name of a file (iff chg is 'C' or 'R')
5368        file_b => new/current file name of a file (any chg)
5369}
5370;
5371
5372# retval of read_url_paths{,_all}();
5373$l_map = {
5374        # repository root url
5375        'https://svn.musicpd.org' => {
5376                # repository path               # GIT_SVN_ID
5377                'mpd/trunk'             =>      'trunk',
5378                'mpd/tags/0.11.5'       =>      'tags/0.11.5',
5379        },
5380}
5381
5382Notes:
5383        I don't trust the each() function on unless I created %hash myself
5384        because the internal iterator may not have started at base.