Andrew's git / gitweb.git / configure.ac
?
configure.acon commit git-p4: Support usage of perforce client spec (3a70cdf)
   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_ERROR([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46        fi; \
  47fi; \
  48]) # GIT_CONF_APPEND_PATH
  49#
  50# GIT_PARSE_WITH(PACKAGE)
  51# -----------------------
  52# For use in AC_ARG_WITH action-if-found, for packages default ON.
  53# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56AC_DEFUN([GIT_PARSE_WITH],
  57[PACKAGE=m4_toupper($1); \
  58if test "$withval" = "no"; then \
  59        m4_toupper(NO_$1)=YesPlease; \
  60elif test "$withval" = "yes"; then \
  61        m4_toupper(NO_$1)=; \
  62else \
  63        m4_toupper(NO_$1)=; \
  64        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65fi \
  66])# GIT_PARSE_WITH
  67
  68
  69## Site configuration related to programs (before tests)
  70## --with-PACKAGE[=ARG] and --without-PACKAGE
  71#
  72# Set lib to alternative name of lib directory (e.g. lib64)
  73AC_ARG_WITH([lib],
  74 [AS_HELP_STRING([--with-lib=ARG],
  75                 [ARG specifies alternative name for lib directory])],
  76 [if test "$withval" = "no" || test "$withval" = "yes"; then \
  77        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
  78else \
  79        GIT_CONF_APPEND_LINE(lib=$withval); \
  80fi; \
  81],[])
  82#
  83# Define SHELL_PATH to provide path to shell.
  84GIT_ARG_SET_PATH(shell)
  85#
  86# Define PERL_PATH to provide path to Perl.
  87GIT_ARG_SET_PATH(perl)
  88#
  89# Define ZLIB_PATH to provide path to zlib.
  90GIT_ARG_SET_PATH(zlib)
  91#
  92# Declare the with-tcltk/without-tcltk options.
  93AC_ARG_WITH(tcltk,
  94AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
  95AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
  96AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
  97AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
  98GIT_PARSE_WITH(tcltk))
  99#
 100
 101
 102## Checks for programs.
 103AC_MSG_NOTICE([CHECKS for programs])
 104#
 105AC_PROG_CC([cc gcc])
 106#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 107AC_CHECK_TOOLS(AR, [gar ar], :)
 108AC_CHECK_PROGS(TAR, [gtar tar])
 109# TCLTK_PATH will be set to some value if we want Tcl/Tk
 110# or will be empty otherwise.
 111if test -z "$NO_TCLTK"; then
 112  if test "$with_tcltk" = ""; then
 113  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 114    TCLTK_PATH=wish
 115    AC_SUBST(TCLTK_PATH)
 116  elif test "$with_tcltk" = "yes"; then
 117  # Tcl/Tk check requested.
 118    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 119  else
 120    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 121    TCLTK_PATH="$with_tcltk"
 122    AC_SUBST(TCLTK_PATH)
 123  fi
 124fi
 125AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 126if test -n "$ASCIIDOC"; then
 127        AC_MSG_CHECKING([for asciidoc version])
 128        asciidoc_version=`$ASCIIDOC --version 2>&1`
 129        case "${asciidoc_version}" in
 130        asciidoc' '8*)
 131                ASCIIDOC8=YesPlease
 132                AC_MSG_RESULT([${asciidoc_version} > 7])
 133                ;;
 134        asciidoc' '7*)
 135                ASCIIDOC8=
 136                AC_MSG_RESULT([${asciidoc_version}])
 137                ;;
 138        *)
 139                ASCIIDOC8=
 140                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 141                ;;
 142        esac
 143fi
 144AC_SUBST(ASCIIDOC8)
 145
 146
 147## Checks for libraries.
 148AC_MSG_NOTICE([CHECKS for libraries])
 149#
 150# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 151# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 152AC_CHECK_LIB([crypto], [SHA1_Init],
 153[NEEDS_SSL_WITH_CRYPTO=],
 154[AC_CHECK_LIB([ssl], [SHA1_Init],
 155 [NEEDS_SSL_WITH_CRYPTO=YesPlease
 156  NEEDS_SSL_WITH_CRYPTO=],
 157 [NO_OPENSSL=YesPlease])])
 158AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 159AC_SUBST(NO_OPENSSL)
 160#
 161# Define NO_CURL if you do not have curl installed.  git-http-pull and
 162# git-http-push are not built, and you cannot use http:// and https://
 163# transports.
 164AC_CHECK_LIB([curl], [curl_global_init],
 165[NO_CURL=],
 166[NO_CURL=YesPlease])
 167AC_SUBST(NO_CURL)
 168#
 169# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 170# not built, and you cannot push using http:// and https:// transports.
 171AC_CHECK_LIB([expat], [XML_ParserCreate],
 172[NO_EXPAT=],
 173[NO_EXPAT=YesPlease])
 174AC_SUBST(NO_EXPAT)
 175#
 176# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 177# some Solaris installations).
 178# Define NO_ICONV if neither libc nor libiconv support iconv.
 179AC_DEFUN([ICONVTEST_SRC], [
 180#include <iconv.h>
 181
 182int main(void)
 183{
 184        iconv_open("", "");
 185        return 0;
 186}
 187])
 188AC_MSG_CHECKING([for iconv in -lc])
 189AC_LINK_IFELSE(ICONVTEST_SRC,
 190        [AC_MSG_RESULT([yes])
 191        NEEDS_LIBICONV=],
 192        [AC_MSG_RESULT([no])
 193        old_LIBS="$LIBS"
 194        LIBS="$LIBS -liconv"
 195        AC_MSG_CHECKING([for iconv in -liconv])
 196        AC_LINK_IFELSE(ICONVTEST_SRC,
 197                [AC_MSG_RESULT([yes])
 198                NEEDS_LIBICONV=YesPlease],
 199                [AC_MSG_RESULT([no])
 200                NO_ICONV=YesPlease])
 201        LIBS="$old_LIBS"])
 202AC_SUBST(NEEDS_LIBICONV)
 203AC_SUBST(NO_ICONV)
 204test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 205#
 206# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 207AC_DEFUN([ZLIBTEST_SRC], [
 208#include <zlib.h>
 209
 210int main(void)
 211{
 212        deflateBound(0, 0);
 213        return 0;
 214}
 215])
 216AC_MSG_CHECKING([for deflateBound in -lz])
 217old_LIBS="$LIBS"
 218LIBS="$LIBS -lz"
 219AC_LINK_IFELSE(ZLIBTEST_SRC,
 220        [AC_MSG_RESULT([yes])],
 221        [AC_MSG_RESULT([no])
 222        NO_DEFLATE_BOUND=yes])
 223LIBS="$old_LIBS"
 224AC_SUBST(NO_DEFLATE_BOUND)
 225#
 226# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 227# Patrick Mauritz).
 228AC_CHECK_LIB([c], [socket],
 229[NEEDS_SOCKET=],
 230[NEEDS_SOCKET=YesPlease])
 231AC_SUBST(NEEDS_SOCKET)
 232test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 233
 234
 235## Checks for header files.
 236AC_MSG_NOTICE([CHECKS for header files])
 237#
 238# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 239AC_CHECK_HEADER([sys/select.h],
 240[NO_SYS_SELECT_H=],
 241[NO_SYS_SELECT_H=UnfortunatelyYes])
 242AC_SUBST(NO_SYS_SELECT_H)
 243#
 244# Define OLD_ICONV if your library has an old iconv(), where the second
 245# (input buffer pointer) parameter is declared with type (const char **).
 246AC_DEFUN([OLDICONVTEST_SRC], [[
 247#include <iconv.h>
 248
 249extern size_t iconv(iconv_t cd,
 250                    char **inbuf, size_t *inbytesleft,
 251                    char **outbuf, size_t *outbytesleft);
 252
 253int main(void)
 254{
 255        return 0;
 256}
 257]])
 258AC_MSG_CHECKING([for old iconv()])
 259AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 260        [AC_MSG_RESULT([no])],
 261        [AC_MSG_RESULT([yes])
 262        OLD_ICONV=UnfortunatelyYes])
 263AC_SUBST(OLD_ICONV)
 264
 265
 266## Checks for typedefs, structures, and compiler characteristics.
 267AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 268#
 269# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 270AC_CHECK_MEMBER(struct dirent.d_ino,
 271[NO_D_INO_IN_DIRENT=],
 272[NO_D_INO_IN_DIRENT=YesPlease],
 273[#include <dirent.h>])
 274AC_SUBST(NO_D_INO_IN_DIRENT)
 275#
 276# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 277# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 278AC_CHECK_MEMBER(struct dirent.d_type,
 279[NO_D_TYPE_IN_DIRENT=],
 280[NO_D_TYPE_IN_DIRENT=YesPlease],
 281[#include <dirent.h>])
 282AC_SUBST(NO_D_TYPE_IN_DIRENT)
 283#
 284# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 285# sockaddr_storage.
 286AC_CHECK_TYPE(struct sockaddr_storage,
 287[NO_SOCKADDR_STORAGE=],
 288[NO_SOCKADDR_STORAGE=YesPlease],[
 289#include <sys/types.h>
 290#include <sys/socket.h>
 291])
 292AC_SUBST(NO_SOCKADDR_STORAGE)
 293#
 294# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 295AC_CHECK_TYPE([struct addrinfo],[
 296 AC_CHECK_FUNC([getaddrinfo],
 297  [NO_IPV6=],
 298  [NO_IPV6=YesPlease])
 299],[NO_IPV6=YesPlease],[
 300#include <sys/types.h>
 301#include <sys/socket.h>
 302#include <netdb.h>
 303])
 304AC_SUBST(NO_IPV6)
 305#
 306# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 307# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 308# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 309# some C compilers supported these specifiers prior to C99 as an extension.
 310AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 311 [ac_cv_c_c99_format],
 312[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 313AC_RUN_IFELSE(
 314        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 315                [[char buf[64];
 316                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 317                  return 1;
 318                else if (strcmp(buf, "12345"))
 319                  return 2;]])],
 320        [ac_cv_c_c99_format=yes],
 321        [ac_cv_c_c99_format=no])
 322])
 323if test $ac_cv_c_c99_format = no; then
 324        NO_C99_FORMAT=YesPlease
 325else
 326        NO_C99_FORMAT=
 327fi
 328AC_SUBST(NO_C99_FORMAT)
 329
 330
 331## Checks for library functions.
 332## (in default C library and libraries checked by AC_CHECK_LIB)
 333AC_MSG_NOTICE([CHECKS for library functions])
 334#
 335# Define NO_STRCASESTR if you don't have strcasestr.
 336AC_CHECK_FUNC(strcasestr,
 337[NO_STRCASESTR=],
 338[NO_STRCASESTR=YesPlease])
 339AC_SUBST(NO_STRCASESTR)
 340#
 341# Define NO_MEMMEM if you don't have memmem.
 342AC_CHECK_FUNC(memmem,
 343[NO_MEMMEM=],
 344[NO_MEMMEM=YesPlease])
 345AC_SUBST(NO_MEMMEM)
 346#
 347# Define NO_STRLCPY if you don't have strlcpy.
 348AC_CHECK_FUNC(strlcpy,
 349[NO_STRLCPY=],
 350[NO_STRLCPY=YesPlease])
 351AC_SUBST(NO_STRLCPY)
 352#
 353# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 354AC_CHECK_FUNC(strtoumax,
 355[NO_STRTOUMAX=],
 356[NO_STRTOUMAX=YesPlease])
 357AC_SUBST(NO_STRTOUMAX)
 358#
 359# Define NO_SETENV if you don't have setenv in the C library.
 360AC_CHECK_FUNC(setenv,
 361[NO_SETENV=],
 362[NO_SETENV=YesPlease])
 363AC_SUBST(NO_SETENV)
 364#
 365# Define NO_UNSETENV if you don't have unsetenv in the C library.
 366AC_CHECK_FUNC(unsetenv,
 367[NO_UNSETENV=],
 368[NO_UNSETENV=YesPlease])
 369AC_SUBST(NO_UNSETENV)
 370#
 371# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 372AC_CHECK_FUNC(mkdtemp,
 373[NO_MKDTEMP=],
 374[NO_MKDTEMP=YesPlease])
 375AC_SUBST(NO_MKDTEMP)
 376#
 377# Define NO_MMAP if you want to avoid mmap.
 378#
 379# Define NO_ICONV if your libc does not properly support iconv.
 380
 381
 382## Other checks.
 383# Define USE_PIC if you need the main git objects to be built with -fPIC
 384# in order to build and link perl/Git.so.  x86-64 seems to need this.
 385#
 386# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 387# Enable it on Windows.  By default, symrefs are still used.
 388
 389## Site configuration (override autodetection)
 390## --with-PACKAGE[=ARG] and --without-PACKAGE
 391AC_MSG_NOTICE([CHECKS for site configuration])
 392#
 393# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 394# tests.  These tests take up a significant amount of the total test time
 395# but are not needed unless you plan to talk to SVN repos.
 396#
 397# Define MOZILLA_SHA1 environment variable when running make to make use of
 398# a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 399# on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 400# choice) has very fast version optimized for i586.
 401#
 402# Define PPC_SHA1 environment variable when running make to make use of
 403# a bundled SHA1 routine optimized for PowerPC.
 404#
 405# Define ARM_SHA1 environment variable when running make to make use of
 406# a bundled SHA1 routine optimized for ARM.
 407#
 408# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 409# This also implies MOZILLA_SHA1.
 410#
 411# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 412# /foo/bar/include and /foo/bar/lib directories.
 413AC_ARG_WITH(openssl,
 414AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 415AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 416GIT_PARSE_WITH(openssl))
 417#
 418# Define NO_CURL if you do not have curl installed.  git-http-pull and
 419# git-http-push are not built, and you cannot use http:// and https://
 420# transports.
 421#
 422# Define CURLDIR=/foo/bar if your curl header and library files are in
 423# /foo/bar/include and /foo/bar/lib directories.
 424AC_ARG_WITH(curl,
 425AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 426AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 427GIT_PARSE_WITH(curl))
 428#
 429# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 430# not built, and you cannot push using http:// and https:// transports.
 431#
 432# Define EXPATDIR=/foo/bar if your expat header and library files are in
 433# /foo/bar/include and /foo/bar/lib directories.
 434AC_ARG_WITH(expat,
 435AS_HELP_STRING([--with-expat],
 436[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 437AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 438GIT_PARSE_WITH(expat))
 439#
 440# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 441# installed in /sw, but don't want GIT to link against any libraries
 442# installed there.  If defined you may specify your own (or Fink's)
 443# include directories and library directories by defining CFLAGS
 444# and LDFLAGS appropriately.
 445#
 446# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 447# have DarwinPorts installed in /opt/local, but don't want GIT to
 448# link against any libraries installed there.  If defined you may
 449# specify your own (or DarwinPort's) include directories and
 450# library directories by defining CFLAGS and LDFLAGS appropriately.
 451#
 452# Define NO_MMAP if you want to avoid mmap.
 453#
 454# Define NO_ICONV if your libc does not properly support iconv.
 455AC_ARG_WITH(iconv,
 456AS_HELP_STRING([--without-iconv],
 457[if your architecture doesn't properly support iconv])
 458AS_HELP_STRING([--with-iconv=PATH],
 459[PATH is prefix for libiconv library and headers])
 460AS_HELP_STRING([],
 461[used only if you need linking with libiconv]),
 462GIT_PARSE_WITH(iconv))
 463
 464## --enable-FEATURE[=ARG] and --disable-FEATURE
 465#
 466# Define USE_NSEC below if you want git to care about sub-second file mtimes
 467# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 468# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 469# randomly break unless your underlying filesystem supports those sub-second
 470# times (my ext3 doesn't).
 471#
 472# Define USE_STDEV below if you want git to care about the underlying device
 473# change being considered an inode change from the update-index perspective.
 474
 475
 476## Output files
 477AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 478AC_OUTPUT
 479
 480
 481## Cleanup
 482rm -f "${config_append}"