Andrew's git / gitweb.git / configure.ac
?
configure.acon commit tag: recognize rfc1991 signatures (3d5854e)
   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26# Optional second argument allows setting NO_PROGRAM=YesPlease if
  27# --without-PROGRAM version used.
  28AC_DEFUN([GIT_ARG_SET_PATH],
  29[AC_ARG_WITH([$1],
  30 [AS_HELP_STRING([--with-$1=PATH],
  31                 [provide PATH to $1])],
  32 [GIT_CONF_APPEND_PATH($1,$2)],[])
  33])# GIT_ARG_SET_PATH
  34#
  35# GIT_CONF_APPEND_PATH(PROGRAM)
  36# ------------------------------
  37# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  38# Used by GIT_ARG_SET_PATH(PROGRAM)
  39# Optional second argument allows setting NO_PROGRAM=YesPlease if
  40# --without-PROGRAM is used.
  41AC_DEFUN([GIT_CONF_APPEND_PATH],
  42[PROGRAM=m4_toupper($1); \
  43if test "$withval" = "no"; then \
  44        if test -n "$2"; then \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Disabling use of ${PROGRAM}]); \
  47                GIT_CONF_APPEND_LINE(NO_${PROGRAM}=YesPlease); \
  48                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=); \
  49        else \
  50                AC_MSG_ERROR([You cannot use git without $1]); \
  51        fi; \
  52else \
  53        if test "$withval" = "yes"; then \
  54                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  55        else \
  56                m4_toupper($1)_PATH=$withval; \
  57                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  58                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  59        fi; \
  60fi; \
  61]) # GIT_CONF_APPEND_PATH
  62#
  63# GIT_PARSE_WITH(PACKAGE)
  64# -----------------------
  65# For use in AC_ARG_WITH action-if-found, for packages default ON.
  66# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  67# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  68# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  69AC_DEFUN([GIT_PARSE_WITH],
  70[PACKAGE=m4_toupper($1); \
  71if test "$withval" = "no"; then \
  72        m4_toupper(NO_$1)=YesPlease; \
  73elif test "$withval" = "yes"; then \
  74        m4_toupper(NO_$1)=; \
  75else \
  76        m4_toupper(NO_$1)=; \
  77        m4_toupper($1)DIR=$withval; \
  78        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  79        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  80fi \
  81])# GIT_PARSE_WITH
  82#
  83# GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  84# ---------------------
  85# Set VAR to the value specied by --with-WITHNAME.
  86# No verification of arguments is performed, but warnings are issued
  87# if either 'yes' or 'no' is specified.
  88# HELP_TEXT is presented when --help is called.
  89# This is a direct way to allow setting variables in the Makefile.
  90AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  91[AC_ARG_WITH([$1],
  92 [AS_HELP_STRING([--with-$1=VALUE], $3)],
  93 if test -n "$withval"; then \
  94  if test "$withval" = "yes" -o "$withval" = "no"; then \
  95    AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  96                     [a value for $1 ($2).  Maybe you do...?]); \
  97  fi; \
  98  \
  99  AC_MSG_NOTICE([Setting $2 to $withval]); \
 100  GIT_CONF_APPEND_LINE($2=$withval); \
 101 fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 102
 103dnl
 104dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 105dnl -----------------------------------------
 106dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
 107dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
 108dnl -Wall), it does not work.  By looking for function definition in
 109dnl libraries, this problem can be worked around.
 110AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 111  AC_SEARCH_LIBS([$1],,
 112  [$2],[$3])
 113],[$3])])
 114
 115dnl
 116dnl GIT_STASH_FLAGS(BASEPATH_VAR)
 117dnl -----------------------------
 118dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 119dnl tests that may want to take user settings into account.
 120AC_DEFUN([GIT_STASH_FLAGS],[
 121if test -n "$1"; then
 122   old_CPPFLAGS="$CPPFLAGS"
 123   old_LDFLAGS="$LDFLAGS"
 124   CPPFLAGS="-I$1/include $CPPFLAGS"
 125   LDFLAGS="-L$1/$lib $LDFLAGS"
 126fi
 127])
 128
 129dnl
 130dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 131dnl -----------------------------
 132dnl Restore the stashed *FLAGS values.
 133AC_DEFUN([GIT_UNSTASH_FLAGS],[
 134if test -n "$1"; then
 135   CPPFLAGS="$old_CPPFLAGS"
 136   LDFLAGS="$old_LDFLAGS"
 137fi
 138])
 139
 140## Site configuration related to programs (before tests)
 141## --with-PACKAGE[=ARG] and --without-PACKAGE
 142#
 143# Set lib to alternative name of lib directory (e.g. lib64)
 144AC_ARG_WITH([lib],
 145 [AS_HELP_STRING([--with-lib=ARG],
 146                 [ARG specifies alternative name for lib directory])],
 147 [if test "$withval" = "no" || test "$withval" = "yes"; then \
 148        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 149else \
 150        lib=$withval; \
 151        AC_MSG_NOTICE([Setting lib to '$lib']); \
 152        GIT_CONF_APPEND_LINE(lib=$withval); \
 153fi; \
 154],[])
 155
 156if test -z "$lib"; then
 157   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 158   lib=lib
 159fi
 160
 161AC_ARG_ENABLE([pthreads],
 162 [AS_HELP_STRING([--enable-pthreads=FLAGS],
 163  [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 164  [The default if FLAGS is not specified is to try first -pthread]
 165  [and then -lpthread.]
 166  [--without-pthreads will disable threading.])],
 167[
 168if test "x$enableval" = "xyes"; then
 169   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 170elif test "x$enableval" != "xno"; then
 171   PTHREAD_CFLAGS=$enableval
 172   AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 173else
 174   AC_MSG_NOTICE([POSIX Threads will be disabled.])
 175   NO_PTHREADS=YesPlease
 176   USER_NOPTHREAD=1
 177fi],
 178[
 179   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 180])
 181
 182# Define option to enable JavaScript minification
 183AC_ARG_ENABLE([jsmin],
 184[AS_HELP_STRING([--enable-jsmin=PATH],
 185  [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 186[
 187  JSMIN=$enableval;
 188  AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 189  GIT_CONF_APPEND_LINE(JSMIN=$enableval);
 190])
 191
 192# Define option to enable CSS minification
 193AC_ARG_ENABLE([cssmin],
 194[AS_HELP_STRING([--enable-cssmin=PATH],
 195  [PATH is the name of a CSS minifier or the absolute path to one.])],
 196[
 197  CSSMIN=$enableval;
 198  AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 199  GIT_CONF_APPEND_LINE(CSSMIN=$enableval);
 200])
 201
 202## Site configuration (override autodetection)
 203## --with-PACKAGE[=ARG] and --without-PACKAGE
 204AC_MSG_NOTICE([CHECKS for site configuration])
 205#
 206# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 207# tests.  These tests take up a significant amount of the total test time
 208# but are not needed unless you plan to talk to SVN repos.
 209#
 210# Define PPC_SHA1 environment variable when running make to make use of
 211# a bundled SHA1 routine optimized for PowerPC.
 212#
 213# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 214# This also implies BLK_SHA1.
 215#
 216# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 217# /foo/bar/include and /foo/bar/lib directories.
 218AC_ARG_WITH(openssl,
 219AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 220AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 221GIT_PARSE_WITH(openssl))
 222#
 223# Define NO_CURL if you do not have curl installed.  git-http-pull and
 224# git-http-push are not built, and you cannot use http:// and https://
 225# transports.
 226#
 227# Define CURLDIR=/foo/bar if your curl header and library files are in
 228# /foo/bar/include and /foo/bar/lib directories.
 229AC_ARG_WITH(curl,
 230AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 231AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 232GIT_PARSE_WITH(curl))
 233#
 234# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 235# not built, and you cannot push using http:// and https:// transports.
 236#
 237# Define EXPATDIR=/foo/bar if your expat header and library files are in
 238# /foo/bar/include and /foo/bar/lib directories.
 239AC_ARG_WITH(expat,
 240AS_HELP_STRING([--with-expat],
 241[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 242AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 243GIT_PARSE_WITH(expat))
 244#
 245# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 246# installed in /sw, but don't want GIT to link against any libraries
 247# installed there.  If defined you may specify your own (or Fink's)
 248# include directories and library directories by defining CFLAGS
 249# and LDFLAGS appropriately.
 250#
 251# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 252# have DarwinPorts installed in /opt/local, but don't want GIT to
 253# link against any libraries installed there.  If defined you may
 254# specify your own (or DarwinPort's) include directories and
 255# library directories by defining CFLAGS and LDFLAGS appropriately.
 256#
 257# Define NO_MMAP if you want to avoid mmap.
 258#
 259# Define NO_ICONV if your libc does not properly support iconv.
 260AC_ARG_WITH(iconv,
 261AS_HELP_STRING([--without-iconv],
 262[if your architecture doesn't properly support iconv])
 263AS_HELP_STRING([--with-iconv=PATH],
 264[PATH is prefix for libiconv library and headers])
 265AS_HELP_STRING([],
 266[used only if you need linking with libiconv]),
 267GIT_PARSE_WITH(iconv))
 268
 269## --enable-FEATURE[=ARG] and --disable-FEATURE
 270#
 271# Define USE_NSEC below if you want git to care about sub-second file mtimes
 272# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 273# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 274# randomly break unless your underlying filesystem supports those sub-second
 275# times (my ext3 doesn't).
 276#
 277# Define USE_STDEV below if you want git to care about the underlying device
 278# change being considered an inode change from the update-index perspective.
 279
 280#
 281# Allow user to set ETC_GITCONFIG variable
 282GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 283                        Use VALUE instead of /etc/gitconfig as the
 284                        global git configuration file.
 285                        If VALUE is not fully qualified it will be interpretted
 286                        as a path relative to the computed prefix at runtime.)
 287
 288#
 289# Allow user to set the default pager
 290GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 291                        Use VALUE as the fall-back pager instead of 'less'.
 292                        This is used by things like 'git log' when the user
 293                        does not specify a pager to use through alternate
 294                        methods. eg: /usr/bin/pager)
 295#
 296# Allow user to set the default editor
 297GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 298                        Use VALUE as the fall-back editor instead of 'vi'.
 299                        This is used by things like 'git commit' when the user
 300                        does not specify a preferred editor through other
 301                        methods. eg: /usr/bin/editor)
 302
 303#
 304# Define SHELL_PATH to provide path to shell.
 305GIT_ARG_SET_PATH(shell)
 306#
 307# Define PERL_PATH to provide path to Perl.
 308GIT_ARG_SET_PATH(perl)
 309#
 310# Define PYTHON_PATH to provide path to Python.
 311GIT_ARG_SET_PATH(python, allow-without)
 312#
 313# Define ZLIB_PATH to provide path to zlib.
 314GIT_ARG_SET_PATH(zlib)
 315#
 316# Declare the with-tcltk/without-tcltk options.
 317AC_ARG_WITH(tcltk,
 318AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 319AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 320AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 321AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 322GIT_PARSE_WITH(tcltk))
 323#
 324
 325
 326## Checks for programs.
 327AC_MSG_NOTICE([CHECKS for programs])
 328#
 329AC_PROG_CC([cc gcc])
 330AC_C_INLINE
 331case $ac_cv_c_inline in
 332  inline | yes | no)    ;;
 333  *)                    AC_SUBST([INLINE], [$ac_cv_c_inline]) ;;
 334esac
 335
 336# which switch to pass runtime path to dynamic libraries to the linker
 337AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 338   SAVE_LDFLAGS="${LDFLAGS}"
 339   LDFLAGS="${SAVE_LDFLAGS} -R /"
 340   AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 341   LDFLAGS="${SAVE_LDFLAGS}"
 342])
 343if test "$git_cv_ld_dashr" = "yes"; then
 344   AC_SUBST(CC_LD_DYNPATH, [-R])
 345else
 346   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 347      SAVE_LDFLAGS="${LDFLAGS}"
 348      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 349      AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 350      LDFLAGS="${SAVE_LDFLAGS}"
 351   ])
 352   if test "$git_cv_ld_wl_rpath" = "yes"; then
 353      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 354   else
 355      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 356         SAVE_LDFLAGS="${LDFLAGS}"
 357         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 358         AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 359         LDFLAGS="${SAVE_LDFLAGS}"
 360      ])
 361      if test "$git_cv_ld_rpath" = "yes"; then
 362         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 363      else
 364         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 365      fi
 366   fi
 367fi
 368#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 369AC_CHECK_TOOLS(AR, [gar ar], :)
 370AC_CHECK_PROGS(TAR, [gtar tar])
 371AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 372# TCLTK_PATH will be set to some value if we want Tcl/Tk
 373# or will be empty otherwise.
 374if test -z "$NO_TCLTK"; then
 375  if test "$with_tcltk" = ""; then
 376  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 377    TCLTK_PATH=wish
 378    AC_SUBST(TCLTK_PATH)
 379  elif test "$with_tcltk" = "yes"; then
 380  # Tcl/Tk check requested.
 381    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 382  else
 383    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 384    TCLTK_PATH="$with_tcltk"
 385    AC_SUBST(TCLTK_PATH)
 386  fi
 387fi
 388AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 389if test -n "$ASCIIDOC"; then
 390        AC_MSG_CHECKING([for asciidoc version])
 391        asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 392        case "${asciidoc_version}" in
 393        asciidoc' '8*)
 394                ASCIIDOC8=YesPlease
 395                AC_MSG_RESULT([${asciidoc_version} > 7])
 396                ;;
 397        asciidoc' '7*)
 398                ASCIIDOC8=
 399                AC_MSG_RESULT([${asciidoc_version}])
 400                ;;
 401        *)
 402                ASCIIDOC8=
 403                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 404                ;;
 405        esac
 406fi
 407AC_SUBST(ASCIIDOC8)
 408
 409
 410## Checks for libraries.
 411AC_MSG_NOTICE([CHECKS for libraries])
 412#
 413# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 414# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 415
 416GIT_STASH_FLAGS($OPENSSLDIR)
 417
 418AC_CHECK_LIB([crypto], [SHA1_Init],
 419[NEEDS_SSL_WITH_CRYPTO=],
 420[AC_CHECK_LIB([ssl], [SHA1_Init],
 421 [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 422 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 423
 424GIT_UNSTASH_FLAGS($OPENSSLDIR)
 425
 426AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 427AC_SUBST(NO_OPENSSL)
 428
 429#
 430# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 431# git-http-push are not built, and you cannot use http:// and https://
 432# transports.
 433
 434GIT_STASH_FLAGS($CURLDIR)
 435
 436AC_CHECK_LIB([curl], [curl_global_init],
 437[NO_CURL=],
 438[NO_CURL=YesPlease])
 439
 440GIT_UNSTASH_FLAGS($CURLDIR)
 441
 442AC_SUBST(NO_CURL)
 443
 444#
 445# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 446# not built, and you cannot push using http:// and https:// transports.
 447
 448GIT_STASH_FLAGS($EXPATDIR)
 449
 450AC_CHECK_LIB([expat], [XML_ParserCreate],
 451[NO_EXPAT=],
 452[NO_EXPAT=YesPlease])
 453
 454GIT_UNSTASH_FLAGS($EXPATDIR)
 455
 456AC_SUBST(NO_EXPAT)
 457
 458#
 459# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 460# some Solaris installations).
 461# Define NO_ICONV if neither libc nor libiconv support iconv.
 462
 463if test -z "$NO_ICONV"; then
 464
 465GIT_STASH_FLAGS($ICONVDIR)
 466
 467AC_DEFUN([ICONVTEST_SRC], [
 468#include <iconv.h>
 469
 470int main(void)
 471{
 472        iconv_open("", "");
 473        return 0;
 474}
 475])
 476
 477if test -n "$ICONVDIR"; then
 478   lib_order="-liconv -lc"
 479else
 480   lib_order="-lc -liconv"
 481fi
 482
 483NO_ICONV=YesPlease
 484
 485for l in $lib_order; do
 486    if test "$l" = "-liconv"; then
 487       NEEDS_LIBICONV=YesPlease
 488    else
 489       NEEDS_LIBICONV=
 490    fi
 491
 492    old_LIBS="$LIBS"
 493    LIBS="$LIBS $l"
 494    AC_MSG_CHECKING([for iconv in $l])
 495    AC_LINK_IFELSE(ICONVTEST_SRC,
 496        [AC_MSG_RESULT([yes])
 497        NO_ICONV=
 498        break],
 499        [AC_MSG_RESULT([no])])
 500    LIBS="$old_LIBS"
 501done
 502
 503#in case of break
 504LIBS="$old_LIBS"
 505
 506GIT_UNSTASH_FLAGS($ICONVDIR)
 507
 508AC_SUBST(NEEDS_LIBICONV)
 509AC_SUBST(NO_ICONV)
 510
 511if test -n "$NO_ICONV"; then
 512    NEEDS_LIBICONV=
 513fi
 514
 515fi
 516
 517#
 518# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 519
 520GIT_STASH_FLAGS($ZLIB_PATH)
 521
 522AC_DEFUN([ZLIBTEST_SRC], [
 523#include <zlib.h>
 524
 525int main(void)
 526{
 527        deflateBound(0, 0);
 528        return 0;
 529}
 530])
 531AC_MSG_CHECKING([for deflateBound in -lz])
 532old_LIBS="$LIBS"
 533LIBS="$LIBS -lz"
 534AC_LINK_IFELSE(ZLIBTEST_SRC,
 535        [AC_MSG_RESULT([yes])],
 536        [AC_MSG_RESULT([no])
 537        NO_DEFLATE_BOUND=yes])
 538LIBS="$old_LIBS"
 539
 540GIT_UNSTASH_FLAGS($ZLIB_PATH)
 541
 542AC_SUBST(NO_DEFLATE_BOUND)
 543
 544#
 545# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 546# Patrick Mauritz).
 547AC_CHECK_LIB([c], [socket],
 548[NEEDS_SOCKET=],
 549[NEEDS_SOCKET=YesPlease])
 550AC_SUBST(NEEDS_SOCKET)
 551test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 552
 553#
 554# The next few tests will define NEEDS_RESOLV if linking with
 555# libresolv provides some of the functions we would normally get
 556# from libc.
 557NEEDS_RESOLV=
 558AC_SUBST(NEEDS_RESOLV)
 559#
 560# Define NO_INET_NTOP if linking with -lresolv is not enough.
 561# Solaris 2.7 in particular hos inet_ntop in -lresolv.
 562NO_INET_NTOP=
 563AC_SUBST(NO_INET_NTOP)
 564AC_CHECK_FUNC([inet_ntop],
 565        [],
 566    [AC_CHECK_LIB([resolv], [inet_ntop],
 567            [NEEDS_RESOLV=YesPlease],
 568        [NO_INET_NTOP=YesPlease])
 569])
 570#
 571# Define NO_INET_PTON if linking with -lresolv is not enough.
 572# Solaris 2.7 in particular hos inet_pton in -lresolv.
 573NO_INET_PTON=
 574AC_SUBST(NO_INET_PTON)
 575AC_CHECK_FUNC([inet_pton],
 576        [],
 577    [AC_CHECK_LIB([resolv], [inet_pton],
 578            [NEEDS_RESOLV=YesPlease],
 579        [NO_INET_PTON=YesPlease])
 580])
 581#
 582# Define NO_HSTRERROR if linking with -lresolv is not enough.
 583# Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 584NO_HSTRERROR=
 585AC_CHECK_FUNC([hstrerror],
 586        [],
 587    [AC_CHECK_LIB([resolv], [hstrerror],
 588            [NEEDS_RESOLV=YesPlease],
 589        [NO_HSTRERROR=YesPlease])
 590])
 591AC_SUBST(NO_HSTRERROR)
 592#
 593# If any of the above tests determined that -lresolv is needed at
 594# build-time, also set it here for remaining configure-time checks.
 595test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 596
 597AC_CHECK_LIB([c], [basename],
 598[NEEDS_LIBGEN=],
 599[NEEDS_LIBGEN=YesPlease])
 600AC_SUBST(NEEDS_LIBGEN)
 601test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 602
 603## Checks for header files.
 604AC_MSG_NOTICE([CHECKS for header files])
 605#
 606# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 607AC_CHECK_HEADER([sys/select.h],
 608[NO_SYS_SELECT_H=],
 609[NO_SYS_SELECT_H=UnfortunatelyYes])
 610AC_SUBST(NO_SYS_SELECT_H)
 611#
 612# Define OLD_ICONV if your library has an old iconv(), where the second
 613# (input buffer pointer) parameter is declared with type (const char **).
 614AC_DEFUN([OLDICONVTEST_SRC], [[
 615#include <iconv.h>
 616
 617extern size_t iconv(iconv_t cd,
 618                    char **inbuf, size_t *inbytesleft,
 619                    char **outbuf, size_t *outbytesleft);
 620
 621int main(void)
 622{
 623        return 0;
 624}
 625]])
 626
 627GIT_STASH_FLAGS($ICONVDIR)
 628
 629AC_MSG_CHECKING([for old iconv()])
 630AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 631        [AC_MSG_RESULT([no])],
 632        [AC_MSG_RESULT([yes])
 633        OLD_ICONV=UnfortunatelyYes])
 634
 635GIT_UNSTASH_FLAGS($ICONVDIR)
 636
 637AC_SUBST(OLD_ICONV)
 638
 639## Checks for typedefs, structures, and compiler characteristics.
 640AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 641#
 642TYPE_SOCKLEN_T
 643case $ac_cv_type_socklen_t in
 644  yes)  ;;
 645  *)    AC_SUBST([SOCKLEN_T], [$git_cv_socklen_t_equiv]) ;;
 646esac
 647
 648# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 649AC_CHECK_MEMBER(struct dirent.d_ino,
 650[NO_D_INO_IN_DIRENT=],
 651[NO_D_INO_IN_DIRENT=YesPlease],
 652[#include <dirent.h>])
 653AC_SUBST(NO_D_INO_IN_DIRENT)
 654#
 655# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 656# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 657AC_CHECK_MEMBER(struct dirent.d_type,
 658[NO_D_TYPE_IN_DIRENT=],
 659[NO_D_TYPE_IN_DIRENT=YesPlease],
 660[#include <dirent.h>])
 661AC_SUBST(NO_D_TYPE_IN_DIRENT)
 662#
 663# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 664# sockaddr_storage.
 665AC_CHECK_TYPE(struct sockaddr_storage,
 666[NO_SOCKADDR_STORAGE=],
 667[NO_SOCKADDR_STORAGE=YesPlease],[
 668#include <sys/types.h>
 669#include <sys/socket.h>
 670])
 671AC_SUBST(NO_SOCKADDR_STORAGE)
 672#
 673# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 674AC_CHECK_TYPE([struct addrinfo],[
 675 GIT_CHECK_FUNC([getaddrinfo],
 676  [NO_IPV6=],
 677  [NO_IPV6=YesPlease])
 678],[NO_IPV6=YesPlease],[
 679#include <sys/types.h>
 680#include <sys/socket.h>
 681#include <netdb.h>
 682])
 683AC_SUBST(NO_IPV6)
 684#
 685# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 686# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 687# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 688# some C compilers supported these specifiers prior to C99 as an extension.
 689AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 690 [ac_cv_c_c99_format],
 691[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 692AC_RUN_IFELSE(
 693        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 694                [[char buf[64];
 695                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 696                  return 1;
 697                else if (strcmp(buf, "12345"))
 698                  return 2;]])],
 699        [ac_cv_c_c99_format=yes],
 700        [ac_cv_c_c99_format=no])
 701])
 702if test $ac_cv_c_c99_format = no; then
 703        NO_C99_FORMAT=YesPlease
 704else
 705        NO_C99_FORMAT=
 706fi
 707AC_SUBST(NO_C99_FORMAT)
 708#
 709# Define NO_REGEX if you have no or inferior regex support in your C library.
 710AC_CACHE_CHECK([whether the platform regex can handle null bytes],
 711 [ac_cv_c_excellent_regex], [
 712AC_EGREP_CPP(yippeeyeswehaveit,
 713        AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 714#include <regex.h>
 715],
 716[#ifdef REG_STARTEND
 717yippeeyeswehaveit
 718#endif
 719]),
 720        [ac_cv_c_excellent_regex=yes],
 721        [ac_cv_c_excellent_regex=no])
 722])
 723if test $ac_cv_c_excellent_regex = yes; then
 724        NO_REGEX=
 725else
 726        NO_REGEX=YesPlease
 727fi
 728AC_SUBST(NO_REGEX)
 729#
 730# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 731# when attempting to read from an fopen'ed directory.
 732AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 733 [ac_cv_fread_reads_directories],
 734[
 735AC_RUN_IFELSE(
 736        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 737                [[char c;
 738                FILE *f = fopen(".", "r");
 739                return f && fread(&c, 1, 1, f)]])],
 740        [ac_cv_fread_reads_directories=no],
 741        [ac_cv_fread_reads_directories=yes])
 742])
 743if test $ac_cv_fread_reads_directories = yes; then
 744        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 745else
 746        FREAD_READS_DIRECTORIES=
 747fi
 748AC_SUBST(FREAD_READS_DIRECTORIES)
 749#
 750# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 751# or vsnprintf() return -1 instead of number of characters which would
 752# have been written to the final string if enough space had been available.
 753AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 754 [ac_cv_snprintf_returns_bogus],
 755[
 756AC_RUN_IFELSE(
 757        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 758                #include "stdarg.h"
 759
 760                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 761                {
 762                  int ret;
 763                  va_list ap;
 764                  va_start(ap, format);
 765                  ret = vsnprintf(str, maxsize, format, ap);
 766                  va_end(ap);
 767                  return ret;
 768                }],
 769                [[char buf[6];
 770                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 771                      || strcmp(buf, "12")) return 1;
 772                  if (snprintf(buf, 3, "%s", "12345") != 5
 773                      || strcmp(buf, "12")) return 1]])],
 774        [ac_cv_snprintf_returns_bogus=no],
 775        [ac_cv_snprintf_returns_bogus=yes])
 776])
 777if test $ac_cv_snprintf_returns_bogus = yes; then
 778        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 779else
 780        SNPRINTF_RETURNS_BOGUS=
 781fi
 782AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 783
 784
 785## Checks for library functions.
 786## (in default C library and libraries checked by AC_CHECK_LIB)
 787AC_MSG_NOTICE([CHECKS for library functions])
 788#
 789# Define NO_LIBGEN_H if you don't have libgen.h.
 790AC_CHECK_HEADER([libgen.h],
 791[NO_LIBGEN_H=],
 792[NO_LIBGEN_H=YesPlease])
 793AC_SUBST(NO_LIBGEN_H)
 794#
 795# Define HAVE_PATHS_H if you have paths.h.
 796AC_CHECK_HEADER([paths.h],
 797[HAVE_PATHS_H=YesPlease],
 798[HAVE_PATHS_H=])
 799AC_SUBST(HAVE_PATHS_H)
 800#
 801# Define NO_STRCASESTR if you don't have strcasestr.
 802GIT_CHECK_FUNC(strcasestr,
 803[NO_STRCASESTR=],
 804[NO_STRCASESTR=YesPlease])
 805AC_SUBST(NO_STRCASESTR)
 806#
 807# Define NO_STRTOK_R if you don't have strtok_r
 808GIT_CHECK_FUNC(strtok_r,
 809[NO_STRTOK_R=],
 810[NO_STRTOK_R=YesPlease])
 811AC_SUBST(NO_STRTOK_R)
 812#
 813# Define NO_MEMMEM if you don't have memmem.
 814GIT_CHECK_FUNC(memmem,
 815[NO_MEMMEM=],
 816[NO_MEMMEM=YesPlease])
 817AC_SUBST(NO_MEMMEM)
 818#
 819# Define NO_STRLCPY if you don't have strlcpy.
 820GIT_CHECK_FUNC(strlcpy,
 821[NO_STRLCPY=],
 822[NO_STRLCPY=YesPlease])
 823AC_SUBST(NO_STRLCPY)
 824#
 825# Define NO_UINTMAX_T if your platform does not have uintmax_t
 826AC_CHECK_TYPE(uintmax_t,
 827[NO_UINTMAX_T=],
 828[NO_UINTMAX_T=YesPlease],[
 829#include <inttypes.h>
 830])
 831AC_SUBST(NO_UINTMAX_T)
 832#
 833# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 834GIT_CHECK_FUNC(strtoumax,
 835[NO_STRTOUMAX=],
 836[NO_STRTOUMAX=YesPlease])
 837AC_SUBST(NO_STRTOUMAX)
 838#
 839# Define NO_SETENV if you don't have setenv in the C library.
 840GIT_CHECK_FUNC(setenv,
 841[NO_SETENV=],
 842[NO_SETENV=YesPlease])
 843AC_SUBST(NO_SETENV)
 844#
 845# Define NO_UNSETENV if you don't have unsetenv in the C library.
 846GIT_CHECK_FUNC(unsetenv,
 847[NO_UNSETENV=],
 848[NO_UNSETENV=YesPlease])
 849AC_SUBST(NO_UNSETENV)
 850#
 851# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 852GIT_CHECK_FUNC(mkdtemp,
 853[NO_MKDTEMP=],
 854[NO_MKDTEMP=YesPlease])
 855AC_SUBST(NO_MKDTEMP)
 856#
 857# Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 858GIT_CHECK_FUNC(mkstemps,
 859[NO_MKSTEMPS=],
 860[NO_MKSTEMPS=YesPlease])
 861AC_SUBST(NO_MKSTEMPS)
 862#
 863#
 864# Define NO_MMAP if you want to avoid mmap.
 865#
 866# Define NO_ICONV if your libc does not properly support iconv.
 867
 868
 869## Other checks.
 870# Define USE_PIC if you need the main git objects to be built with -fPIC
 871# in order to build and link perl/Git.so.  x86-64 seems to need this.
 872#
 873# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 874# Enable it on Windows.  By default, symrefs are still used.
 875#
 876# Define NO_PTHREADS if we do not have pthreads.
 877#
 878# Define PTHREAD_LIBS to the linker flag used for Pthread support.
 879AC_DEFUN([PTHREADTEST_SRC], [
 880#include <pthread.h>
 881
 882int main(void)
 883{
 884        pthread_mutex_t test_mutex;
 885        int retcode = 0;
 886        retcode |= pthread_mutex_init(&test_mutex,(void *)0);
 887        retcode |= pthread_mutex_lock(&test_mutex);
 888        retcode |= pthread_mutex_unlock(&test_mutex);
 889        return retcode;
 890}
 891])
 892
 893dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 894dnl   [[#include <pthread.h>]],
 895dnl   [[pthread_mutex_t test_mutex;]]
 896dnl )])
 897
 898NO_PTHREADS=UnfortunatelyYes
 899PTHREAD_LIBS=
 900
 901if test -n "$USER_NOPTHREAD"; then
 902   AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 903# handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 904# -D_REENTRANT' or some such.
 905elif test -z "$PTHREAD_CFLAGS"; then
 906  threads_found=no
 907  for opt in -mt -pthread -lpthread; do
 908     old_CFLAGS="$CFLAGS"
 909     CFLAGS="$opt $CFLAGS"
 910     AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 911     AC_LINK_IFELSE(PTHREADTEST_SRC,
 912        [AC_MSG_RESULT([yes])
 913                NO_PTHREADS=
 914                PTHREAD_LIBS="$opt"
 915                PTHREAD_CFLAGS="$opt"
 916                threads_found=yes
 917                break
 918        ],
 919        [AC_MSG_RESULT([no])])
 920      CFLAGS="$old_CFLAGS"
 921  done
 922  if test $threads_found != yes; then
 923    AC_CHECK_LIB([pthread], [pthread_create],
 924        [PTHREAD_LIBS="-lpthread"],
 925        [NO_PTHREADS=UnfortunatelyYes])
 926  fi
 927else
 928  old_CFLAGS="$CFLAGS"
 929  CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 930  AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 931  AC_LINK_IFELSE(PTHREADTEST_SRC,
 932        [AC_MSG_RESULT([yes])
 933                NO_PTHREADS=
 934                PTHREAD_LIBS="$PTHREAD_CFLAGS"
 935        ],
 936        [AC_MSG_RESULT([no])])
 937
 938  CFLAGS="$old_CFLAGS"
 939fi
 940
 941CFLAGS="$old_CFLAGS"
 942
 943AC_SUBST(PTHREAD_CFLAGS)
 944AC_SUBST(PTHREAD_LIBS)
 945AC_SUBST(NO_PTHREADS)
 946
 947## Output files
 948AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 949AC_OUTPUT
 950
 951
 952## Cleanup
 953rm -f "${config_append}"