Andrew's git / gitweb.git / contrib/emacs/git.el
?
contrib / emacs / git.elon commit git.el: Support for showing unknown/ignored directories. (3f3d564)
   1;;; git.el --- A user interface for git
   2
   3;; Copyright (C) 2005, 2006, 2007 Alexandre Julliard <julliard@winehq.org>
   4
   5;; Version: 1.0
   6
   7;; This program is free software; you can redistribute it and/or
   8;; modify it under the terms of the GNU General Public License as
   9;; published by the Free Software Foundation; either version 2 of
  10;; the License, or (at your option) any later version.
  11;;
  12;; This program is distributed in the hope that it will be
  13;; useful, but WITHOUT ANY WARRANTY; without even the implied
  14;; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15;; PURPOSE.  See the GNU General Public License for more details.
  16;;
  17;; You should have received a copy of the GNU General Public
  18;; License along with this program; if not, write to the Free
  19;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20;; MA 02111-1307 USA
  21
  22;;; Commentary:
  23
  24;; This file contains an interface for the git version control
  25;; system. It provides easy access to the most frequently used git
  26;; commands. The user interface is as far as possible identical to
  27;; that of the PCL-CVS mode.
  28;;
  29;; To install: put this file on the load-path and place the following
  30;; in your .emacs file:
  31;;
  32;;    (require 'git)
  33;;
  34;; To start: `M-x git-status'
  35;;
  36;; TODO
  37;;  - portability to XEmacs
  38;;  - better handling of subprocess errors
  39;;  - diff against other branch
  40;;  - renaming files from the status buffer
  41;;  - creating tags
  42;;  - fetch/pull
  43;;  - switching branches
  44;;  - revlist browser
  45;;  - git-show-branch browser
  46;;  - menus
  47;;
  48
  49(eval-when-compile (require 'cl))
  50(require 'ewoc)
  51(require 'log-edit)
  52(require 'easymenu)
  53
  54
  55;;;; Customizations
  56;;;; ------------------------------------------------------------
  57
  58(defgroup git nil
  59  "A user interface for the git versioning system."
  60  :group 'tools)
  61
  62(defcustom git-committer-name nil
  63  "User name to use for commits.
  64The default is to fall back to the repository config,
  65then to `add-log-full-name' and then to `user-full-name'."
  66  :group 'git
  67  :type '(choice (const :tag "Default" nil)
  68                 (string :tag "Name")))
  69
  70(defcustom git-committer-email nil
  71  "Email address to use for commits.
  72The default is to fall back to the git repository config,
  73then to `add-log-mailing-address' and then to `user-mail-address'."
  74  :group 'git
  75  :type '(choice (const :tag "Default" nil)
  76                 (string :tag "Email")))
  77
  78(defcustom git-commits-coding-system nil
  79  "Default coding system for the log message of git commits."
  80  :group 'git
  81  :type '(choice (const :tag "From repository config" nil)
  82                 (coding-system)))
  83
  84(defcustom git-append-signed-off-by nil
  85  "Whether to append a Signed-off-by line to the commit message before editing."
  86  :group 'git
  87  :type 'boolean)
  88
  89(defcustom git-reuse-status-buffer t
  90  "Whether `git-status' should try to reuse an existing buffer
  91if there is already one that displays the same directory."
  92  :group 'git
  93  :type 'boolean)
  94
  95(defcustom git-per-dir-ignore-file ".gitignore"
  96  "Name of the per-directory ignore file."
  97  :group 'git
  98  :type 'string)
  99
 100(defcustom git-show-uptodate nil
 101  "Whether to display up-to-date files."
 102  :group 'git
 103  :type 'boolean)
 104
 105(defcustom git-show-ignored nil
 106  "Whether to display ignored files."
 107  :group 'git
 108  :type 'boolean)
 109
 110(defcustom git-show-unknown t
 111  "Whether to display unknown files."
 112  :group 'git
 113  :type 'boolean)
 114
 115
 116(defface git-status-face
 117  '((((class color) (background light)) (:foreground "purple"))
 118    (((class color) (background dark)) (:foreground "salmon")))
 119  "Git mode face used to highlight added and modified files."
 120  :group 'git)
 121
 122(defface git-unmerged-face
 123  '((((class color) (background light)) (:foreground "red" :bold t))
 124    (((class color) (background dark)) (:foreground "red" :bold t)))
 125  "Git mode face used to highlight unmerged files."
 126  :group 'git)
 127
 128(defface git-unknown-face
 129  '((((class color) (background light)) (:foreground "goldenrod" :bold t))
 130    (((class color) (background dark)) (:foreground "goldenrod" :bold t)))
 131  "Git mode face used to highlight unknown files."
 132  :group 'git)
 133
 134(defface git-uptodate-face
 135  '((((class color) (background light)) (:foreground "grey60"))
 136    (((class color) (background dark)) (:foreground "grey40")))
 137  "Git mode face used to highlight up-to-date files."
 138  :group 'git)
 139
 140(defface git-ignored-face
 141  '((((class color) (background light)) (:foreground "grey60"))
 142    (((class color) (background dark)) (:foreground "grey40")))
 143  "Git mode face used to highlight ignored files."
 144  :group 'git)
 145
 146(defface git-mark-face
 147  '((((class color) (background light)) (:foreground "red" :bold t))
 148    (((class color) (background dark)) (:foreground "tomato" :bold t)))
 149  "Git mode face used for the file marks."
 150  :group 'git)
 151
 152(defface git-header-face
 153  '((((class color) (background light)) (:foreground "blue"))
 154    (((class color) (background dark)) (:foreground "blue")))
 155  "Git mode face used for commit headers."
 156  :group 'git)
 157
 158(defface git-separator-face
 159  '((((class color) (background light)) (:foreground "brown"))
 160    (((class color) (background dark)) (:foreground "brown")))
 161  "Git mode face used for commit separator."
 162  :group 'git)
 163
 164(defface git-permission-face
 165  '((((class color) (background light)) (:foreground "green" :bold t))
 166    (((class color) (background dark)) (:foreground "green" :bold t)))
 167  "Git mode face used for permission changes."
 168  :group 'git)
 169
 170
 171;;;; Utilities
 172;;;; ------------------------------------------------------------
 173
 174(defconst git-log-msg-separator "--- log message follows this line ---")
 175
 176(defvar git-log-edit-font-lock-keywords
 177  `(("^\\(Author:\\|Date:\\|Parent:\\|Signed-off-by:\\)\\(.*\\)$"
 178     (1 font-lock-keyword-face)
 179     (2 font-lock-function-name-face))
 180    (,(concat "^\\(" (regexp-quote git-log-msg-separator) "\\)$")
 181     (1 font-lock-comment-face))))
 182
 183(defun git-get-env-strings (env)
 184  "Build a list of NAME=VALUE strings from a list of environment strings."
 185  (mapcar (lambda (entry) (concat (car entry) "=" (cdr entry))) env))
 186
 187(defun git-call-process-env (buffer env &rest args)
 188  "Wrapper for call-process that sets environment strings."
 189  (if env
 190      (apply #'call-process "env" nil buffer nil
 191             (append (git-get-env-strings env) (list "git") args))
 192    (apply #'call-process "git" nil buffer nil args)))
 193
 194(defun git-call-process-env-string (env &rest args)
 195  "Wrapper for call-process that sets environment strings,
 196and returns the process output as a string."
 197  (with-temp-buffer
 198    (and (eq 0 (apply #' git-call-process-env t env args))
 199         (buffer-string))))
 200
 201(defun git-run-process-region (buffer start end program args)
 202  "Run a git process with a buffer region as input."
 203  (let ((output-buffer (current-buffer))
 204        (dir default-directory))
 205    (with-current-buffer buffer
 206      (cd dir)
 207      (apply #'call-process-region start end program
 208             nil (list output-buffer nil) nil args))))
 209
 210(defun git-run-command-buffer (buffer-name &rest args)
 211  "Run a git command, sending the output to a buffer named BUFFER-NAME."
 212  (let ((dir default-directory)
 213        (buffer (get-buffer-create buffer-name)))
 214    (message "Running git %s..." (car args))
 215    (with-current-buffer buffer
 216      (let ((default-directory dir)
 217            (buffer-read-only nil))
 218        (erase-buffer)
 219        (apply #'git-call-process-env buffer nil args)))
 220    (message "Running git %s...done" (car args))
 221    buffer))
 222
 223(defun git-run-command-region (buffer start end env &rest args)
 224  "Run a git command with specified buffer region as input."
 225  (unless (eq 0 (if env
 226                    (git-run-process-region
 227                     buffer start end "env"
 228                     (append (git-get-env-strings env) (list "git") args))
 229                  (git-run-process-region
 230                   buffer start end "git" args)))
 231    (error "Failed to run \"git %s\":\n%s" (mapconcat (lambda (x) x) args " ") (buffer-string))))
 232
 233(defun git-run-hook (hook env &rest args)
 234  "Run a git hook and display its output if any."
 235  (let ((dir default-directory)
 236        (hook-name (expand-file-name (concat ".git/hooks/" hook))))
 237    (or (not (file-executable-p hook-name))
 238        (let (status (buffer (get-buffer-create "*Git Hook Output*")))
 239          (with-current-buffer buffer
 240            (erase-buffer)
 241            (cd dir)
 242            (setq status
 243                  (if env
 244                      (apply #'call-process "env" nil (list buffer t) nil
 245                             (append (git-get-env-strings env) (list hook-name) args))
 246                    (apply #'call-process hook-name nil (list buffer t) nil args))))
 247          (display-message-or-buffer buffer)
 248          (eq 0 status)))))
 249
 250(defun git-get-string-sha1 (string)
 251  "Read a SHA1 from the specified string."
 252  (and string
 253       (string-match "[0-9a-f]\\{40\\}" string)
 254       (match-string 0 string)))
 255
 256(defun git-get-committer-name ()
 257  "Return the name to use as GIT_COMMITTER_NAME."
 258  ; copied from log-edit
 259  (or git-committer-name
 260      (git-config "user.name")
 261      (and (boundp 'add-log-full-name) add-log-full-name)
 262      (and (fboundp 'user-full-name) (user-full-name))
 263      (and (boundp 'user-full-name) user-full-name)))
 264
 265(defun git-get-committer-email ()
 266  "Return the email address to use as GIT_COMMITTER_EMAIL."
 267  ; copied from log-edit
 268  (or git-committer-email
 269      (git-config "user.email")
 270      (and (boundp 'add-log-mailing-address) add-log-mailing-address)
 271      (and (fboundp 'user-mail-address) (user-mail-address))
 272      (and (boundp 'user-mail-address) user-mail-address)))
 273
 274(defun git-get-commits-coding-system ()
 275  "Return the coding system to use for commits."
 276  (let ((repo-config (git-config "i18n.commitencoding")))
 277    (or git-commits-coding-system
 278        (and repo-config
 279             (fboundp 'locale-charset-to-coding-system)
 280             (locale-charset-to-coding-system repo-config))
 281      'utf-8)))
 282
 283(defun git-get-logoutput-coding-system ()
 284  "Return the coding system used for git-log output."
 285  (let ((repo-config (or (git-config "i18n.logoutputencoding")
 286                         (git-config "i18n.commitencoding"))))
 287    (or git-commits-coding-system
 288        (and repo-config
 289             (fboundp 'locale-charset-to-coding-system)
 290             (locale-charset-to-coding-system repo-config))
 291      'utf-8)))
 292
 293(defun git-escape-file-name (name)
 294  "Escape a file name if necessary."
 295  (if (string-match "[\n\t\"\\]" name)
 296      (concat "\""
 297              (mapconcat (lambda (c)
 298                   (case c
 299                     (?\n "\\n")
 300                     (?\t "\\t")
 301                     (?\\ "\\\\")
 302                     (?\" "\\\"")
 303                     (t (char-to-string c))))
 304                 name "")
 305              "\"")
 306    name))
 307
 308(defun git-success-message (text files)
 309  "Print a success message after having handled FILES."
 310  (let ((n (length files)))
 311    (if (equal n 1)
 312        (message "%s %s" text (car files))
 313      (message "%s %d files" text n))))
 314
 315(defun git-get-top-dir (dir)
 316  "Retrieve the top-level directory of a git tree."
 317  (let ((cdup (with-output-to-string
 318                (with-current-buffer standard-output
 319                  (cd dir)
 320                  (unless (eq 0 (call-process "git" nil t nil "rev-parse" "--show-cdup"))
 321                    (error "cannot find top-level git tree for %s." dir))))))
 322    (expand-file-name (concat (file-name-as-directory dir)
 323                              (car (split-string cdup "\n"))))))
 324
 325;stolen from pcl-cvs
 326(defun git-append-to-ignore (file)
 327  "Add a file name to the ignore file in its directory."
 328  (let* ((fullname (expand-file-name file))
 329         (dir (file-name-directory fullname))
 330         (name (file-name-nondirectory fullname))
 331         (ignore-name (expand-file-name git-per-dir-ignore-file dir))
 332         (created (not (file-exists-p ignore-name))))
 333  (save-window-excursion
 334    (set-buffer (find-file-noselect ignore-name))
 335    (goto-char (point-max))
 336    (unless (zerop (current-column)) (insert "\n"))
 337    (insert "/" name "\n")
 338    (sort-lines nil (point-min) (point-max))
 339    (save-buffer))
 340  (when created
 341    (git-call-process-env nil nil "update-index" "--add" "--" (file-relative-name ignore-name)))
 342  (git-update-status-files (list (file-relative-name ignore-name)) 'unknown)))
 343
 344; propertize definition for XEmacs, stolen from erc-compat
 345(eval-when-compile
 346  (unless (fboundp 'propertize)
 347    (defun propertize (string &rest props)
 348      (let ((string (copy-sequence string)))
 349        (while props
 350          (put-text-property 0 (length string) (nth 0 props) (nth 1 props) string)
 351          (setq props (cddr props)))
 352        string))))
 353
 354;;;; Wrappers for basic git commands
 355;;;; ------------------------------------------------------------
 356
 357(defun git-rev-parse (rev)
 358  "Parse a revision name and return its SHA1."
 359  (git-get-string-sha1
 360   (git-call-process-env-string nil "rev-parse" rev)))
 361
 362(defun git-config (key)
 363  "Retrieve the value associated to KEY in the git repository config file."
 364  (let ((str (git-call-process-env-string nil "config" key)))
 365    (and str (car (split-string str "\n")))))
 366
 367(defun git-symbolic-ref (ref)
 368  "Wrapper for the git-symbolic-ref command."
 369  (let ((str (git-call-process-env-string nil "symbolic-ref" ref)))
 370    (and str (car (split-string str "\n")))))
 371
 372(defun git-update-ref (ref newval &optional oldval reason)
 373  "Update a reference by calling git-update-ref."
 374  (let ((args (and oldval (list oldval))))
 375    (push newval args)
 376    (push ref args)
 377    (when reason
 378     (push reason args)
 379     (push "-m" args))
 380    (eq 0 (apply #'git-call-process-env nil nil "update-ref" args))))
 381
 382(defun git-read-tree (tree &optional index-file)
 383  "Read a tree into the index file."
 384  (apply #'git-call-process-env nil
 385         (if index-file `(("GIT_INDEX_FILE" . ,index-file)) nil)
 386         "read-tree" (if tree (list tree))))
 387
 388(defun git-write-tree (&optional index-file)
 389  "Call git-write-tree and return the resulting tree SHA1 as a string."
 390  (git-get-string-sha1
 391   (git-call-process-env-string (and index-file `(("GIT_INDEX_FILE" . ,index-file))) "write-tree")))
 392
 393(defun git-commit-tree (buffer tree head)
 394  "Call git-commit-tree with buffer as input and return the resulting commit SHA1."
 395  (let ((author-name (git-get-committer-name))
 396        (author-email (git-get-committer-email))
 397        (subject "commit (initial): ")
 398        author-date log-start log-end args coding-system-for-write)
 399    (when head
 400      (setq subject "commit: ")
 401      (push "-p" args)
 402      (push head args))
 403    (with-current-buffer buffer
 404      (goto-char (point-min))
 405      (if
 406          (setq log-start (re-search-forward (concat "^" (regexp-quote git-log-msg-separator) "\n") nil t))
 407          (save-restriction
 408            (narrow-to-region (point-min) log-start)
 409            (goto-char (point-min))
 410            (when (re-search-forward "^Author: +\\(.*?\\) *<\\(.*\\)> *$" nil t)
 411              (setq author-name (match-string 1)
 412                    author-email (match-string 2)))
 413            (goto-char (point-min))
 414            (when (re-search-forward "^Date: +\\(.*\\)$" nil t)
 415              (setq author-date (match-string 1)))
 416            (goto-char (point-min))
 417            (while (re-search-forward "^Parent: +\\([0-9a-f]+\\)" nil t)
 418              (unless (string-equal head (match-string 1))
 419                (setq subject "commit (merge): ")
 420                (push "-p" args)
 421                (push (match-string 1) args))))
 422        (setq log-start (point-min)))
 423      (setq log-end (point-max))
 424      (goto-char log-start)
 425      (when (re-search-forward ".*$" nil t)
 426        (setq subject (concat subject (match-string 0))))
 427      (setq coding-system-for-write buffer-file-coding-system))
 428    (let ((commit
 429           (git-get-string-sha1
 430            (with-output-to-string
 431              (with-current-buffer standard-output
 432                (let ((env `(("GIT_AUTHOR_NAME" . ,author-name)
 433                             ("GIT_AUTHOR_EMAIL" . ,author-email)
 434                             ("GIT_COMMITTER_NAME" . ,(git-get-committer-name))
 435                             ("GIT_COMMITTER_EMAIL" . ,(git-get-committer-email)))))
 436                  (when author-date (push `("GIT_AUTHOR_DATE" . ,author-date) env))
 437                  (apply #'git-run-command-region
 438                         buffer log-start log-end env
 439                         "commit-tree" tree (nreverse args))))))))
 440      (and (git-update-ref "HEAD" commit head subject)
 441           commit))))
 442
 443(defun git-empty-db-p ()
 444  "Check if the git db is empty (no commit done yet)."
 445  (not (eq 0 (call-process "git" nil nil nil "rev-parse" "--verify" "HEAD"))))
 446
 447(defun git-get-merge-heads ()
 448  "Retrieve the merge heads from the MERGE_HEAD file if present."
 449  (let (heads)
 450    (when (file-readable-p ".git/MERGE_HEAD")
 451      (with-temp-buffer
 452        (insert-file-contents ".git/MERGE_HEAD" nil nil nil t)
 453        (goto-char (point-min))
 454        (while (re-search-forward "[0-9a-f]\\{40\\}" nil t)
 455          (push (match-string 0) heads))))
 456    (nreverse heads)))
 457
 458(defun git-get-commit-description (commit)
 459  "Get a one-line description of COMMIT."
 460  (let ((coding-system-for-read (git-get-logoutput-coding-system)))
 461    (let ((descr (git-call-process-env-string nil "log" "--max-count=1" "--pretty=oneline" commit)))
 462      (if (and descr (string-match "\\`\\([0-9a-f]\\{40\\}\\) *\\(.*\\)$" descr))
 463          (concat (substring (match-string 1 descr) 0 10) " - " (match-string 2 descr))
 464        descr))))
 465
 466;;;; File info structure
 467;;;; ------------------------------------------------------------
 468
 469; fileinfo structure stolen from pcl-cvs
 470(defstruct (git-fileinfo
 471            (:copier nil)
 472            (:constructor git-create-fileinfo (state name &optional old-perm new-perm rename-state orig-name marked))
 473            (:conc-name git-fileinfo->))
 474  marked              ;; t/nil
 475  state               ;; current state
 476  name                ;; file name
 477  old-perm new-perm   ;; permission flags
 478  rename-state        ;; rename or copy state
 479  orig-name           ;; original name for renames or copies
 480  needs-refresh)      ;; whether file needs to be refreshed
 481
 482(defvar git-status nil)
 483
 484(defun git-clear-status (status)
 485  "Remove everything from the status list."
 486  (ewoc-filter status (lambda (info) nil)))
 487
 488(defun git-set-fileinfo-state (info state)
 489  "Set the state of a file info."
 490  (unless (eq (git-fileinfo->state info) state)
 491    (setf (git-fileinfo->state info) state
 492          (git-fileinfo->new-perm info) (git-fileinfo->old-perm info)
 493          (git-fileinfo->rename-state info) nil
 494          (git-fileinfo->orig-name info) nil
 495          (git-fileinfo->needs-refresh info) t)))
 496
 497(defun git-status-filenames-map (status func files &rest args)
 498  "Apply FUNC to the status files names in the FILES list."
 499  (when files
 500    (setq files (sort files #'string-lessp))
 501    (let ((file (pop files))
 502          (node (ewoc-nth status 0)))
 503      (while (and file node)
 504        (let ((info (ewoc-data node)))
 505          (if (string-lessp (git-fileinfo->name info) file)
 506              (setq node (ewoc-next status node))
 507            (if (string-equal (git-fileinfo->name info) file)
 508                (apply func info args))
 509            (setq file (pop files))))))))
 510
 511(defun git-set-filenames-state (status files state)
 512  "Set the state of a list of named files."
 513  (when files
 514    (git-status-filenames-map status #'git-set-fileinfo-state files state)
 515    (unless state  ;; delete files whose state has been set to nil
 516      (ewoc-filter status (lambda (info) (git-fileinfo->state info))))))
 517
 518(defun git-state-code (code)
 519  "Convert from a string to a added/deleted/modified state."
 520  (case (string-to-char code)
 521    (?M 'modified)
 522    (?? 'unknown)
 523    (?A 'added)
 524    (?D 'deleted)
 525    (?U 'unmerged)
 526    (?T 'modified)
 527    (t nil)))
 528
 529(defun git-status-code-as-string (code)
 530  "Format a git status code as string."
 531  (case code
 532    ('modified (propertize "Modified" 'face 'git-status-face))
 533    ('unknown  (propertize "Unknown " 'face 'git-unknown-face))
 534    ('added    (propertize "Added   " 'face 'git-status-face))
 535    ('deleted  (propertize "Deleted " 'face 'git-status-face))
 536    ('unmerged (propertize "Unmerged" 'face 'git-unmerged-face))
 537    ('uptodate (propertize "Uptodate" 'face 'git-uptodate-face))
 538    ('ignored  (propertize "Ignored " 'face 'git-ignored-face))
 539    (t "?       ")))
 540
 541(defun git-file-type-as-string (old-perm new-perm)
 542  "Return a string describing the file type based on its permissions."
 543  (let* ((old-type (lsh (or old-perm 0) -9))
 544         (new-type (lsh (or new-perm 0) -9))
 545         (str (case new-type
 546                (?\100  ;; file
 547                 (case old-type
 548                   (?\100 nil)
 549                   (?\120 "   (type change symlink -> file)")
 550                   (?\160 "   (type change subproject -> file)")))
 551                 (?\120  ;; symlink
 552                  (case old-type
 553                    (?\100 "   (type change file -> symlink)")
 554                    (?\160 "   (type change subproject -> symlink)")
 555                    (t "   (symlink)")))
 556                  (?\160  ;; subproject
 557                   (case old-type
 558                     (?\100 "   (type change file -> subproject)")
 559                     (?\120 "   (type change symlink -> subproject)")
 560                     (t "   (subproject)")))
 561                  (?\110 nil)  ;; directory (internal, not a real git state)
 562                  (?\000  ;; deleted or unknown
 563                   (case old-type
 564                     (?\120 "   (symlink)")
 565                     (?\160 "   (subproject)")))
 566                  (t (format "   (unknown type %o)" new-type)))))
 567    (cond (str (propertize str 'face 'git-status-face))
 568          ((eq new-type ?\110) "/")
 569          (t ""))))
 570
 571(defun git-rename-as-string (info)
 572  "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 573  (let ((state (git-fileinfo->rename-state info)))
 574    (if state
 575        (propertize
 576         (concat "   ("
 577                 (if (eq state 'copy) "copied from "
 578                   (if (eq (git-fileinfo->state info) 'added) "renamed from "
 579                     "renamed to "))
 580                 (git-escape-file-name (git-fileinfo->orig-name info))
 581                 ")") 'face 'git-status-face)
 582      "")))
 583
 584(defun git-permissions-as-string (old-perm new-perm)
 585  "Format a permission change as string."
 586  (propertize
 587   (if (or (not old-perm)
 588           (not new-perm)
 589           (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 590       "  "
 591     (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 592  'face 'git-permission-face))
 593
 594(defun git-fileinfo-prettyprint (info)
 595  "Pretty-printer for the git-fileinfo structure."
 596  (let ((old-perm (git-fileinfo->old-perm info))
 597        (new-perm (git-fileinfo->new-perm info)))
 598    (insert (concat "   " (if (git-fileinfo->marked info) (propertize "*" 'face 'git-mark-face) " ")
 599                    " " (git-status-code-as-string (git-fileinfo->state info))
 600                    " " (git-permissions-as-string old-perm new-perm)
 601                    "  " (git-escape-file-name (git-fileinfo->name info))
 602                    (git-file-type-as-string old-perm new-perm)
 603                    (git-rename-as-string info)))))
 604
 605(defun git-insert-info-list (status infolist)
 606  "Insert a list of file infos in the status buffer, replacing existing ones if any."
 607  (setq infolist (sort infolist
 608                       (lambda (info1 info2)
 609                         (string-lessp (git-fileinfo->name info1)
 610                                       (git-fileinfo->name info2)))))
 611  (let ((info (pop infolist))
 612        (node (ewoc-nth status 0)))
 613    (while info
 614      (cond ((not node)
 615             (setq node (ewoc-enter-last status info))
 616             (setq info (pop infolist)))
 617            ((string-lessp (git-fileinfo->name (ewoc-data node))
 618                           (git-fileinfo->name info))
 619             (setq node (ewoc-next status node)))
 620            ((string-equal (git-fileinfo->name (ewoc-data node))
 621                           (git-fileinfo->name info))
 622              ;; preserve the marked flag
 623              (setf (git-fileinfo->marked info) (git-fileinfo->marked (ewoc-data node)))
 624              (setf (git-fileinfo->needs-refresh info) t)
 625              (setf (ewoc-data node) info)
 626              (setq info (pop infolist)))
 627            (t
 628             (setq node (ewoc-enter-before status node info))
 629             (setq info (pop infolist)))))))
 630
 631(defun git-run-diff-index (status files)
 632  "Run git-diff-index on FILES and parse the results into STATUS.
 633Return the list of files that haven't been handled."
 634  (let ((remaining (copy-sequence files))
 635        infolist)
 636    (with-temp-buffer
 637      (apply #'git-call-process-env t nil "diff-index" "-z" "-M" "HEAD" "--" files)
 638      (goto-char (point-min))
 639      (while (re-search-forward
 640              ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMUT]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 641              nil t 1)
 642        (let ((old-perm (string-to-number (match-string 1) 8))
 643              (new-perm (string-to-number (match-string 2) 8))
 644              (state (or (match-string 4) (match-string 6)))
 645              (name (or (match-string 5) (match-string 7)))
 646              (new-name (match-string 8)))
 647          (if new-name  ; copy or rename
 648              (if (eq ?C (string-to-char state))
 649                  (push (git-create-fileinfo 'added new-name old-perm new-perm 'copy name) infolist)
 650                (push (git-create-fileinfo 'deleted name 0 0 'rename new-name) infolist)
 651                (push (git-create-fileinfo 'added new-name old-perm new-perm 'rename name) infolist))
 652            (push (git-create-fileinfo (git-state-code state) name old-perm new-perm) infolist))
 653          (setq remaining (delete name remaining))
 654          (when new-name (setq remaining (delete new-name remaining))))))
 655    (git-insert-info-list status infolist)
 656    remaining))
 657
 658(defun git-find-status-file (status file)
 659  "Find a given file in the status ewoc and return its node."
 660  (let ((node (ewoc-nth status 0)))
 661    (while (and node (not (string= file (git-fileinfo->name (ewoc-data node)))))
 662      (setq node (ewoc-next status node)))
 663    node))
 664
 665(defun git-run-ls-files (status files default-state &rest options)
 666  "Run git-ls-files on FILES and parse the results into STATUS.
 667Return the list of files that haven't been handled."
 668  (let (infolist)
 669    (with-temp-buffer
 670      (apply #'git-call-process-env t nil "ls-files" "-z" (append options (list "--") files))
 671      (goto-char (point-min))
 672      (while (re-search-forward "\\([^\0]*?\\)\\(/?\\)\0" nil t 1)
 673        (let ((name (match-string 1)))
 674          (push (git-create-fileinfo default-state name 0
 675                                     (if (string-equal "/" (match-string 2)) (lsh ?\110 9) 0))
 676                infolist)
 677          (setq files (delete name files)))))
 678    (git-insert-info-list status infolist)
 679    files))
 680
 681(defun git-run-ls-files-cached (status files default-state)
 682  "Run git-ls-files -c on FILES and parse the results into STATUS.
 683Return the list of files that haven't been handled."
 684  (let ((remaining (copy-sequence files))
 685        infolist)
 686    (with-temp-buffer
 687      (apply #'git-call-process-env t nil "ls-files" "-z" "-s" "-c" "--" files)
 688      (goto-char (point-min))
 689      (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 690        (let* ((new-perm (string-to-number (match-string 1) 8))
 691               (old-perm (if (eq default-state 'added) 0 new-perm))
 692               (name (match-string 2)))
 693          (push (git-create-fileinfo default-state name old-perm new-perm) infolist)
 694          (setq remaining (delete name remaining)))))
 695    (git-insert-info-list status infolist)
 696    remaining))
 697
 698(defun git-run-ls-unmerged (status files)
 699  "Run git-ls-files -u on FILES and parse the results into STATUS."
 700  (with-temp-buffer
 701    (apply #'git-call-process-env t nil "ls-files" "-z" "-u" "--" files)
 702    (goto-char (point-min))
 703    (let (unmerged-files)
 704      (while (re-search-forward "[0-7]\\{6\\} [0-9a-f]\\{40\\} [123]\t\\([^\0]+\\)\0" nil t)
 705        (push (match-string 1) unmerged-files))
 706      (git-set-filenames-state status unmerged-files 'unmerged))))
 707
 708(defun git-get-exclude-files ()
 709  "Get the list of exclude files to pass to git-ls-files."
 710  (let (files
 711        (config (git-config "core.excludesfile")))
 712    (when (file-readable-p ".git/info/exclude")
 713      (push ".git/info/exclude" files))
 714    (when (and config (file-readable-p config))
 715      (push config files))
 716    files))
 717
 718(defun git-run-ls-files-with-excludes (status files default-state &rest options)
 719  "Run git-ls-files on FILES with appropriate --exclude-from options."
 720  (let ((exclude-files (git-get-exclude-files)))
 721    (apply #'git-run-ls-files status files default-state "--directory"
 722           (concat "--exclude-per-directory=" git-per-dir-ignore-file)
 723           (append options (mapcar (lambda (f) (concat "--exclude-from=" f)) exclude-files)))))
 724
 725(defun git-update-status-files (files &optional default-state)
 726  "Update the status of FILES from the index."
 727  (unless git-status (error "Not in git-status buffer."))
 728  (when (or git-show-uptodate files)
 729    (git-run-ls-files-cached git-status files 'uptodate))
 730  (let* ((remaining-files
 731          (if (git-empty-db-p) ; we need some special handling for an empty db
 732              (git-run-ls-files-cached git-status files 'added)
 733            (git-run-diff-index git-status files))))
 734    (git-run-ls-unmerged git-status files)
 735    (when (or remaining-files (and git-show-unknown (not files)))
 736      (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'unknown "-o")))
 737    (when (or remaining-files (and git-show-ignored (not files)))
 738      (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'ignored "-o" "-i")))
 739    (git-set-filenames-state git-status remaining-files default-state)
 740    (git-refresh-files)
 741    (git-refresh-ewoc-hf git-status)))
 742
 743(defun git-marked-files ()
 744  "Return a list of all marked files, or if none a list containing just the file at cursor position."
 745  (unless git-status (error "Not in git-status buffer."))
 746  (or (ewoc-collect git-status (lambda (info) (git-fileinfo->marked info)))
 747      (list (ewoc-data (ewoc-locate git-status)))))
 748
 749(defun git-marked-files-state (&rest states)
 750  "Return marked files that are in the specified states."
 751  (let ((files (git-marked-files))
 752        result)
 753    (dolist (info files)
 754      (when (memq (git-fileinfo->state info) states)
 755        (push info result)))
 756    result))
 757
 758(defun git-refresh-files ()
 759  "Refresh all files that need it and clear the needs-refresh flag."
 760  (unless git-status (error "Not in git-status buffer."))
 761  (ewoc-map
 762   (lambda (info)
 763     (let ((refresh (git-fileinfo->needs-refresh info)))
 764       (setf (git-fileinfo->needs-refresh info) nil)
 765       refresh))
 766   git-status)
 767  ; move back to goal column
 768  (when goal-column (move-to-column goal-column)))
 769
 770(defun git-refresh-ewoc-hf (status)
 771  "Refresh the ewoc header and footer."
 772  (let ((branch (git-symbolic-ref "HEAD"))
 773        (head (if (git-empty-db-p) "Nothing committed yet"
 774                (git-get-commit-description "HEAD")))
 775        (merge-heads (git-get-merge-heads)))
 776    (ewoc-set-hf status
 777                 (format "Directory:  %s\nBranch:     %s\nHead:       %s%s\n"
 778                         default-directory
 779                         (if branch
 780                             (if (string-match "^refs/heads/" branch)
 781                                 (substring branch (match-end 0))
 782                               branch)
 783                           "none (detached HEAD)")
 784                         head
 785                         (if merge-heads
 786                             (concat "\nMerging:    "
 787                                     (mapconcat (lambda (str) (git-get-commit-description str)) merge-heads "\n            "))
 788                           ""))
 789                 (if (ewoc-nth status 0) "" "    No changes."))))
 790
 791(defun git-get-filenames (files)
 792  (mapcar (lambda (info) (git-fileinfo->name info)) files))
 793
 794(defun git-update-index (index-file files)
 795  "Run git-update-index on a list of files."
 796  (let ((env (and index-file `(("GIT_INDEX_FILE" . ,index-file))))
 797        added deleted modified)
 798    (dolist (info files)
 799      (case (git-fileinfo->state info)
 800        ('added (push info added))
 801        ('deleted (push info deleted))
 802        ('modified (push info modified))))
 803    (when added
 804      (apply #'git-call-process-env nil env "update-index" "--add" "--" (git-get-filenames added)))
 805    (when deleted
 806      (apply #'git-call-process-env nil env "update-index" "--remove" "--" (git-get-filenames deleted)))
 807    (when modified
 808      (apply #'git-call-process-env nil env "update-index" "--" (git-get-filenames modified)))))
 809
 810(defun git-run-pre-commit-hook ()
 811  "Run the pre-commit hook if any."
 812  (unless git-status (error "Not in git-status buffer."))
 813  (let ((files (git-marked-files-state 'added 'deleted 'modified)))
 814    (or (not files)
 815        (not (file-executable-p ".git/hooks/pre-commit"))
 816        (let ((index-file (make-temp-file "gitidx")))
 817          (unwind-protect
 818            (let ((head-tree (unless (git-empty-db-p) (git-rev-parse "HEAD^{tree}"))))
 819              (git-read-tree head-tree index-file)
 820              (git-update-index index-file files)
 821              (git-run-hook "pre-commit" `(("GIT_INDEX_FILE" . ,index-file))))
 822          (delete-file index-file))))))
 823
 824(defun git-do-commit ()
 825  "Perform the actual commit using the current buffer as log message."
 826  (interactive)
 827  (let ((buffer (current-buffer))
 828        (index-file (make-temp-file "gitidx")))
 829    (with-current-buffer log-edit-parent-buffer
 830      (if (git-marked-files-state 'unmerged)
 831          (message "You cannot commit unmerged files, resolve them first.")
 832        (unwind-protect
 833            (let ((files (git-marked-files-state 'added 'deleted 'modified))
 834                  head head-tree)
 835              (unless (git-empty-db-p)
 836                (setq head (git-rev-parse "HEAD")
 837                      head-tree (git-rev-parse "HEAD^{tree}")))
 838              (if files
 839                  (progn
 840                    (message "Running git commit...")
 841                    (git-read-tree head-tree index-file)
 842                    (git-update-index nil files)         ;update both the default index
 843                    (git-update-index index-file files)  ;and the temporary one
 844                    (let ((tree (git-write-tree index-file)))
 845                      (if (or (not (string-equal tree head-tree))
 846                              (yes-or-no-p "The tree was not modified, do you really want to perform an empty commit? "))
 847                          (let ((commit (git-commit-tree buffer tree head)))
 848                            (condition-case nil (delete-file ".git/MERGE_HEAD") (error nil))
 849                            (condition-case nil (delete-file ".git/MERGE_MSG") (error nil))
 850                            (with-current-buffer buffer (erase-buffer))
 851                            (git-update-status-files (git-get-filenames files) 'uptodate)
 852                            (git-call-process-env nil nil "rerere")
 853                            (git-call-process-env nil nil "gc" "--auto")
 854                            (git-refresh-files)
 855                            (git-refresh-ewoc-hf git-status)
 856                            (message "Committed %s." commit)
 857                            (git-run-hook "post-commit" nil))
 858                        (message "Commit aborted."))))
 859                (message "No files to commit.")))
 860          (delete-file index-file))))))
 861
 862
 863;;;; Interactive functions
 864;;;; ------------------------------------------------------------
 865
 866(defun git-mark-file ()
 867  "Mark the file that the cursor is on and move to the next one."
 868  (interactive)
 869  (unless git-status (error "Not in git-status buffer."))
 870  (let* ((pos (ewoc-locate git-status))
 871         (info (ewoc-data pos)))
 872    (setf (git-fileinfo->marked info) t)
 873    (ewoc-invalidate git-status pos)
 874    (ewoc-goto-next git-status 1)))
 875
 876(defun git-unmark-file ()
 877  "Unmark the file that the cursor is on and move to the next one."
 878  (interactive)
 879  (unless git-status (error "Not in git-status buffer."))
 880  (let* ((pos (ewoc-locate git-status))
 881         (info (ewoc-data pos)))
 882    (setf (git-fileinfo->marked info) nil)
 883    (ewoc-invalidate git-status pos)
 884    (ewoc-goto-next git-status 1)))
 885
 886(defun git-unmark-file-up ()
 887  "Unmark the file that the cursor is on and move to the previous one."
 888  (interactive)
 889  (unless git-status (error "Not in git-status buffer."))
 890  (let* ((pos (ewoc-locate git-status))
 891         (info (ewoc-data pos)))
 892    (setf (git-fileinfo->marked info) nil)
 893    (ewoc-invalidate git-status pos)
 894    (ewoc-goto-prev git-status 1)))
 895
 896(defun git-mark-all ()
 897  "Mark all files."
 898  (interactive)
 899  (unless git-status (error "Not in git-status buffer."))
 900  (ewoc-map (lambda (info) (unless (git-fileinfo->marked info)
 901                             (setf (git-fileinfo->marked info) t))) git-status)
 902  ; move back to goal column after invalidate
 903  (when goal-column (move-to-column goal-column)))
 904
 905(defun git-unmark-all ()
 906  "Unmark all files."
 907  (interactive)
 908  (unless git-status (error "Not in git-status buffer."))
 909  (ewoc-map (lambda (info) (when (git-fileinfo->marked info)
 910                             (setf (git-fileinfo->marked info) nil)
 911                             t)) git-status)
 912  ; move back to goal column after invalidate
 913  (when goal-column (move-to-column goal-column)))
 914
 915(defun git-toggle-all-marks ()
 916  "Toggle all file marks."
 917  (interactive)
 918  (unless git-status (error "Not in git-status buffer."))
 919  (ewoc-map (lambda (info) (setf (git-fileinfo->marked info) (not (git-fileinfo->marked info))) t) git-status)
 920  ; move back to goal column after invalidate
 921  (when goal-column (move-to-column goal-column)))
 922
 923(defun git-next-file (&optional n)
 924  "Move the selection down N files."
 925  (interactive "p")
 926  (unless git-status (error "Not in git-status buffer."))
 927  (ewoc-goto-next git-status n))
 928
 929(defun git-prev-file (&optional n)
 930  "Move the selection up N files."
 931  (interactive "p")
 932  (unless git-status (error "Not in git-status buffer."))
 933  (ewoc-goto-prev git-status n))
 934
 935(defun git-next-unmerged-file (&optional n)
 936  "Move the selection down N unmerged files."
 937  (interactive "p")
 938  (unless git-status (error "Not in git-status buffer."))
 939  (let* ((last (ewoc-locate git-status))
 940         (node (ewoc-next git-status last)))
 941    (while (and node (> n 0))
 942      (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 943        (setq n (1- n))
 944        (setq last node))
 945      (setq node (ewoc-next git-status node)))
 946    (ewoc-goto-node git-status last)))
 947
 948(defun git-prev-unmerged-file (&optional n)
 949  "Move the selection up N unmerged files."
 950  (interactive "p")
 951  (unless git-status (error "Not in git-status buffer."))
 952  (let* ((last (ewoc-locate git-status))
 953         (node (ewoc-prev git-status last)))
 954    (while (and node (> n 0))
 955      (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 956        (setq n (1- n))
 957        (setq last node))
 958      (setq node (ewoc-prev git-status node)))
 959    (ewoc-goto-node git-status last)))
 960
 961(defun git-add-file ()
 962  "Add marked file(s) to the index cache."
 963  (interactive)
 964  (let ((files (git-get-filenames (git-marked-files-state 'unknown 'ignored))))
 965    ;; FIXME: add support for directories
 966    (unless files
 967      (push (file-relative-name (read-file-name "File to add: " nil nil t)) files))
 968    (apply #'git-call-process-env nil nil "update-index" "--add" "--" files)
 969    (git-update-status-files files 'uptodate)
 970    (git-success-message "Added" files)))
 971
 972(defun git-ignore-file ()
 973  "Add marked file(s) to the ignore list."
 974  (interactive)
 975  (let ((files (git-get-filenames (git-marked-files-state 'unknown))))
 976    (unless files
 977      (push (file-relative-name (read-file-name "File to ignore: " nil nil t)) files))
 978    (dolist (f files) (git-append-to-ignore f))
 979    (git-update-status-files files 'ignored)
 980    (git-success-message "Ignored" files)))
 981
 982(defun git-remove-file ()
 983  "Remove the marked file(s)."
 984  (interactive)
 985  (let ((files (git-get-filenames (git-marked-files-state 'added 'modified 'unknown 'uptodate 'ignored))))
 986    (unless files
 987      (push (file-relative-name (read-file-name "File to remove: " nil nil t)) files))
 988    (if (yes-or-no-p
 989         (format "Remove %d file%s? " (length files) (if (> (length files) 1) "s" "")))
 990        (progn
 991          (dolist (name files)
 992            (ignore-errors
 993              (if (file-directory-p name)
 994                  (delete-directory name)
 995                (delete-file name))))
 996          (apply #'git-call-process-env nil nil "update-index" "--remove" "--" files)
 997          (git-update-status-files files nil)
 998          (git-success-message "Removed" files))
 999      (message "Aborting"))))
1000
1001(defun git-revert-file ()
1002  "Revert changes to the marked file(s)."
1003  (interactive)
1004  (let ((files (git-marked-files-state 'added 'deleted 'modified 'unmerged))
1005        added modified)
1006    (when (and files
1007               (yes-or-no-p
1008                (format "Revert %d file%s? " (length files) (if (> (length files) 1) "s" ""))))
1009      (dolist (info files)
1010        (case (git-fileinfo->state info)
1011          ('added (push (git-fileinfo->name info) added))
1012          ('deleted (push (git-fileinfo->name info) modified))
1013          ('unmerged (push (git-fileinfo->name info) modified))
1014          ('modified (push (git-fileinfo->name info) modified))))
1015      (when added
1016        (apply #'git-call-process-env nil nil "update-index" "--force-remove" "--" added))
1017      (when modified
1018        (apply #'git-call-process-env nil nil "checkout" "HEAD" modified))
1019      (git-update-status-files (append added modified) 'uptodate)
1020      (git-success-message "Reverted" (git-get-filenames files)))))
1021
1022(defun git-resolve-file ()
1023  "Resolve conflicts in marked file(s)."
1024  (interactive)
1025  (let ((files (git-get-filenames (git-marked-files-state 'unmerged))))
1026    (when files
1027      (apply #'git-call-process-env nil nil "update-index" "--" files)
1028      (git-update-status-files files 'uptodate)
1029      (git-success-message "Resolved" files))))
1030
1031(defun git-remove-handled ()
1032  "Remove handled files from the status list."
1033  (interactive)
1034  (ewoc-filter git-status
1035               (lambda (info)
1036                 (case (git-fileinfo->state info)
1037                   ('ignored git-show-ignored)
1038                   ('uptodate git-show-uptodate)
1039                   ('unknown git-show-unknown)
1040                   (t t))))
1041  (unless (ewoc-nth git-status 0)  ; refresh header if list is empty
1042    (git-refresh-ewoc-hf git-status)))
1043
1044(defun git-toggle-show-uptodate ()
1045  "Toogle the option for showing up-to-date files."
1046  (interactive)
1047  (if (setq git-show-uptodate (not git-show-uptodate))
1048      (git-refresh-status)
1049    (git-remove-handled)))
1050
1051(defun git-toggle-show-ignored ()
1052  "Toogle the option for showing ignored files."
1053  (interactive)
1054  (if (setq git-show-ignored (not git-show-ignored))
1055      (progn
1056        (message "Inserting ignored files...")
1057        (git-run-ls-files-with-excludes git-status nil 'ignored "-o" "-i")
1058        (git-refresh-files)
1059        (git-refresh-ewoc-hf git-status)
1060        (message "Inserting ignored files...done"))
1061    (git-remove-handled)))
1062
1063(defun git-toggle-show-unknown ()
1064  "Toogle the option for showing unknown files."
1065  (interactive)
1066  (if (setq git-show-unknown (not git-show-unknown))
1067      (progn
1068        (message "Inserting unknown files...")
1069        (git-run-ls-files-with-excludes git-status nil 'unknown "-o")
1070        (git-refresh-files)
1071        (git-refresh-ewoc-hf git-status)
1072        (message "Inserting unknown files...done"))
1073    (git-remove-handled)))
1074
1075(defun git-expand-directory (info)
1076  "Expand the directory represented by INFO to list its files."
1077  (when (eq (lsh (git-fileinfo->new-perm info) -9) ?\110)
1078    (let ((dir (git-fileinfo->name info)))
1079      (git-set-filenames-state git-status (list dir) nil)
1080      (git-run-ls-files-with-excludes git-status (list (concat dir "/")) 'unknown "-o")
1081      (git-refresh-files)
1082      (git-refresh-ewoc-hf git-status)
1083      t)))
1084
1085(defun git-setup-diff-buffer (buffer)
1086  "Setup a buffer for displaying a diff."
1087  (let ((dir default-directory))
1088    (with-current-buffer buffer
1089      (diff-mode)
1090      (goto-char (point-min))
1091      (setq default-directory dir)
1092      (setq buffer-read-only t)))
1093  (display-buffer buffer)
1094  ; shrink window only if it displays the status buffer
1095  (when (eq (window-buffer) (current-buffer))
1096    (shrink-window-if-larger-than-buffer)))
1097
1098(defun git-diff-file ()
1099  "Diff the marked file(s) against HEAD."
1100  (interactive)
1101  (let ((files (git-marked-files)))
1102    (git-setup-diff-buffer
1103     (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M" "HEAD" "--" (git-get-filenames files)))))
1104
1105(defun git-diff-file-merge-head (arg)
1106  "Diff the marked file(s) against the first merge head (or the nth one with a numeric prefix)."
1107  (interactive "p")
1108  (let ((files (git-marked-files))
1109        (merge-heads (git-get-merge-heads)))
1110    (unless merge-heads (error "No merge in progress"))
1111    (git-setup-diff-buffer
1112     (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M"
1113            (or (nth (1- arg) merge-heads) "HEAD") "--" (git-get-filenames files)))))
1114
1115(defun git-diff-unmerged-file (stage)
1116  "Diff the marked unmerged file(s) against the specified stage."
1117  (let ((files (git-marked-files)))
1118    (git-setup-diff-buffer
1119     (apply #'git-run-command-buffer "*git-diff*" "diff-files" "-p" stage "--" (git-get-filenames files)))))
1120
1121(defun git-diff-file-base ()
1122  "Diff the marked unmerged file(s) against the common base file."
1123  (interactive)
1124  (git-diff-unmerged-file "-1"))
1125
1126(defun git-diff-file-mine ()
1127  "Diff the marked unmerged file(s) against my pre-merge version."
1128  (interactive)
1129  (git-diff-unmerged-file "-2"))
1130
1131(defun git-diff-file-other ()
1132  "Diff the marked unmerged file(s) against the other's pre-merge version."
1133  (interactive)
1134  (git-diff-unmerged-file "-3"))
1135
1136(defun git-diff-file-combined ()
1137  "Do a combined diff of the marked unmerged file(s)."
1138  (interactive)
1139  (git-diff-unmerged-file "-c"))
1140
1141(defun git-diff-file-idiff ()
1142  "Perform an interactive diff on the current file."
1143  (interactive)
1144  (let ((files (git-marked-files-state 'added 'deleted 'modified)))
1145    (unless (eq 1 (length files))
1146      (error "Cannot perform an interactive diff on multiple files."))
1147    (let* ((filename (car (git-get-filenames files)))
1148           (buff1 (find-file-noselect filename))
1149           (buff2 (git-run-command-buffer (concat filename ".~HEAD~") "cat-file" "blob" (concat "HEAD:" filename))))
1150      (ediff-buffers buff1 buff2))))
1151
1152(defun git-log-file ()
1153  "Display a log of changes to the marked file(s)."
1154  (interactive)
1155  (let* ((files (git-marked-files))
1156         (coding-system-for-read git-commits-coding-system)
1157         (buffer (apply #'git-run-command-buffer "*git-log*" "rev-list" "--pretty" "HEAD" "--" (git-get-filenames files))))
1158    (with-current-buffer buffer
1159      ; (git-log-mode)  FIXME: implement log mode
1160      (goto-char (point-min))
1161      (setq buffer-read-only t))
1162    (display-buffer buffer)))
1163
1164(defun git-log-edit-files ()
1165  "Return a list of marked files for use in the log-edit buffer."
1166  (with-current-buffer log-edit-parent-buffer
1167    (git-get-filenames (git-marked-files-state 'added 'deleted 'modified))))
1168
1169(defun git-log-edit-diff ()
1170  "Run a diff of the current files being committed from a log-edit buffer."
1171  (with-current-buffer log-edit-parent-buffer
1172    (git-diff-file)))
1173
1174(defun git-append-sign-off (name email)
1175  "Append a Signed-off-by entry to the current buffer, avoiding duplicates."
1176  (let ((sign-off (format "Signed-off-by: %s <%s>" name email))
1177        (case-fold-search t))
1178    (goto-char (point-min))
1179    (unless (re-search-forward (concat "^" (regexp-quote sign-off)) nil t)
1180      (goto-char (point-min))
1181      (unless (re-search-forward "^Signed-off-by: " nil t)
1182        (setq sign-off (concat "\n" sign-off)))
1183      (goto-char (point-max))
1184      (insert sign-off "\n"))))
1185
1186(defun git-setup-log-buffer (buffer &optional author-name author-email subject date msg)
1187  "Setup the log buffer for a commit."
1188  (unless git-status (error "Not in git-status buffer."))
1189  (let ((merge-heads (git-get-merge-heads))
1190        (dir default-directory)
1191        (committer-name (git-get-committer-name))
1192        (committer-email (git-get-committer-email))
1193        (sign-off git-append-signed-off-by))
1194    (with-current-buffer buffer
1195      (cd dir)
1196      (erase-buffer)
1197      (insert
1198       (propertize
1199        (format "Author: %s <%s>\n%s%s"
1200                (or author-name committer-name)
1201                (or author-email committer-email)
1202                (if date (format "Date: %s\n" date) "")
1203                (if merge-heads
1204                    (format "Parent: %s\n%s\n"
1205                            (git-rev-parse "HEAD")
1206                            (mapconcat (lambda (str) (concat "Parent: " str)) merge-heads "\n"))
1207                  ""))
1208        'face 'git-header-face)
1209       (propertize git-log-msg-separator 'face 'git-separator-face)
1210       "\n")
1211      (when subject (insert subject "\n\n"))
1212      (cond (msg (insert msg "\n"))
1213            ((file-readable-p ".dotest/msg")
1214             (insert-file-contents ".dotest/msg"))
1215            ((file-readable-p ".git/MERGE_MSG")
1216             (insert-file-contents ".git/MERGE_MSG")))
1217      ; delete empty lines at end
1218      (goto-char (point-min))
1219      (when (re-search-forward "\n+\\'" nil t)
1220        (replace-match "\n" t t))
1221      (when sign-off (git-append-sign-off committer-name committer-email)))))
1222
1223(defun git-commit-file ()
1224  "Commit the marked file(s), asking for a commit message."
1225  (interactive)
1226  (unless git-status (error "Not in git-status buffer."))
1227  (when (git-run-pre-commit-hook)
1228    (let ((buffer (get-buffer-create "*git-commit*"))
1229          (coding-system (git-get-commits-coding-system))
1230          author-name author-email subject date)
1231      (when (eq 0 (buffer-size buffer))
1232        (when (file-readable-p ".dotest/info")
1233          (with-temp-buffer
1234            (insert-file-contents ".dotest/info")
1235            (goto-char (point-min))
1236            (when (re-search-forward "^Author: \\(.*\\)\nEmail: \\(.*\\)$" nil t)
1237              (setq author-name (match-string 1))
1238              (setq author-email (match-string 2)))
1239            (goto-char (point-min))
1240            (when (re-search-forward "^Subject: \\(.*\\)$" nil t)
1241              (setq subject (match-string 1)))
1242            (goto-char (point-min))
1243            (when (re-search-forward "^Date: \\(.*\\)$" nil t)
1244              (setq date (match-string 1)))))
1245        (git-setup-log-buffer buffer author-name author-email subject date))
1246      (if (boundp 'log-edit-diff-function)
1247          (log-edit 'git-do-commit nil '((log-edit-listfun . git-log-edit-files)
1248                                         (log-edit-diff-function . git-log-edit-diff)) buffer)
1249        (log-edit 'git-do-commit nil 'git-log-edit-files buffer))
1250      (setq font-lock-keywords (font-lock-compile-keywords git-log-edit-font-lock-keywords))
1251      (setq buffer-file-coding-system coding-system)
1252      (re-search-forward (regexp-quote (concat git-log-msg-separator "\n")) nil t))))
1253
1254(defun git-find-file ()
1255  "Visit the current file in its own buffer."
1256  (interactive)
1257  (unless git-status (error "Not in git-status buffer."))
1258  (let ((info (ewoc-data (ewoc-locate git-status))))
1259    (unless (git-expand-directory info)
1260      (find-file (git-fileinfo->name info))
1261      (when (eq 'unmerged (git-fileinfo->state info))
1262        (smerge-mode 1)))))
1263
1264(defun git-find-file-other-window ()
1265  "Visit the current file in its own buffer in another window."
1266  (interactive)
1267  (unless git-status (error "Not in git-status buffer."))
1268  (let ((info (ewoc-data (ewoc-locate git-status))))
1269    (find-file-other-window (git-fileinfo->name info))
1270    (when (eq 'unmerged (git-fileinfo->state info))
1271      (smerge-mode))))
1272
1273(defun git-find-file-imerge ()
1274  "Visit the current file in interactive merge mode."
1275  (interactive)
1276  (unless git-status (error "Not in git-status buffer."))
1277  (let ((info (ewoc-data (ewoc-locate git-status))))
1278    (find-file (git-fileinfo->name info))
1279    (smerge-ediff)))
1280
1281(defun git-view-file ()
1282  "View the current file in its own buffer."
1283  (interactive)
1284  (unless git-status (error "Not in git-status buffer."))
1285  (let ((info (ewoc-data (ewoc-locate git-status))))
1286    (view-file (git-fileinfo->name info))))
1287
1288(defun git-refresh-status ()
1289  "Refresh the git status buffer."
1290  (interactive)
1291  (let* ((status git-status)
1292         (pos (ewoc-locate status))
1293         (marked-files (git-get-filenames (ewoc-collect status (lambda (info) (git-fileinfo->marked info)))))
1294         (cur-name (and pos (git-fileinfo->name (ewoc-data pos)))))
1295    (unless status (error "Not in git-status buffer."))
1296    (message "Refreshing git status...")
1297    (git-call-process-env nil nil "update-index" "--refresh")
1298    (git-clear-status status)
1299    (git-update-status-files nil)
1300    ; restore file marks
1301    (when marked-files
1302      (git-status-filenames-map status
1303                                (lambda (info)
1304                                        (setf (git-fileinfo->marked info) t)
1305                                        (setf (git-fileinfo->needs-refresh info) t))
1306                                marked-files)
1307      (git-refresh-files))
1308    ; move point to the current file name if any
1309    (message "Refreshing git status...done")
1310    (let ((node (and cur-name (git-find-status-file status cur-name))))
1311      (when node (ewoc-goto-node status node)))))
1312
1313(defun git-status-quit ()
1314  "Quit git-status mode."
1315  (interactive)
1316  (bury-buffer))
1317
1318;;;; Major Mode
1319;;;; ------------------------------------------------------------
1320
1321(defvar git-status-mode-hook nil
1322  "Run after `git-status-mode' is setup.")
1323
1324(defvar git-status-mode-map nil
1325  "Keymap for git major mode.")
1326
1327(defvar git-status nil
1328  "List of all files managed by the git-status mode.")
1329
1330(unless git-status-mode-map
1331  (let ((map (make-keymap))
1332        (diff-map (make-sparse-keymap))
1333        (toggle-map (make-sparse-keymap)))
1334    (suppress-keymap map)
1335    (define-key map "?"   'git-help)
1336    (define-key map "h"   'git-help)
1337    (define-key map " "   'git-next-file)
1338    (define-key map "a"   'git-add-file)
1339    (define-key map "c"   'git-commit-file)
1340    (define-key map "d"    diff-map)
1341    (define-key map "="   'git-diff-file)
1342    (define-key map "f"   'git-find-file)
1343    (define-key map "\r"  'git-find-file)
1344    (define-key map "g"   'git-refresh-status)
1345    (define-key map "i"   'git-ignore-file)
1346    (define-key map "l"   'git-log-file)
1347    (define-key map "m"   'git-mark-file)
1348    (define-key map "M"   'git-mark-all)
1349    (define-key map "n"   'git-next-file)
1350    (define-key map "N"   'git-next-unmerged-file)
1351    (define-key map "o"   'git-find-file-other-window)
1352    (define-key map "p"   'git-prev-file)
1353    (define-key map "P"   'git-prev-unmerged-file)
1354    (define-key map "q"   'git-status-quit)
1355    (define-key map "r"   'git-remove-file)
1356    (define-key map "R"   'git-resolve-file)
1357    (define-key map "t"    toggle-map)
1358    (define-key map "T"   'git-toggle-all-marks)
1359    (define-key map "u"   'git-unmark-file)
1360    (define-key map "U"   'git-revert-file)
1361    (define-key map "v"   'git-view-file)
1362    (define-key map "x"   'git-remove-handled)
1363    (define-key map "\C-?" 'git-unmark-file-up)
1364    (define-key map "\M-\C-?" 'git-unmark-all)
1365    ; the diff submap
1366    (define-key diff-map "b" 'git-diff-file-base)
1367    (define-key diff-map "c" 'git-diff-file-combined)
1368    (define-key diff-map "=" 'git-diff-file)
1369    (define-key diff-map "e" 'git-diff-file-idiff)
1370    (define-key diff-map "E" 'git-find-file-imerge)
1371    (define-key diff-map "h" 'git-diff-file-merge-head)
1372    (define-key diff-map "m" 'git-diff-file-mine)
1373    (define-key diff-map "o" 'git-diff-file-other)
1374    ; the toggle submap
1375    (define-key toggle-map "u" 'git-toggle-show-uptodate)
1376    (define-key toggle-map "i" 'git-toggle-show-ignored)
1377    (define-key toggle-map "k" 'git-toggle-show-unknown)
1378    (define-key toggle-map "m" 'git-toggle-all-marks)
1379    (setq git-status-mode-map map))
1380  (easy-menu-define git-menu git-status-mode-map
1381    "Git Menu"
1382    `("Git"
1383      ["Refresh" git-refresh-status t]
1384      ["Commit" git-commit-file t]
1385      ("Merge"
1386        ["Next Unmerged File" git-next-unmerged-file t]
1387        ["Prev Unmerged File" git-prev-unmerged-file t]
1388        ["Mark as Resolved" git-resolve-file t]
1389        ["Interactive Merge File" git-find-file-imerge t]
1390        ["Diff Against Common Base File" git-diff-file-base t]
1391        ["Diff Combined" git-diff-file-combined t]
1392        ["Diff Against Merge Head" git-diff-file-merge-head t]
1393        ["Diff Against Mine" git-diff-file-mine t]
1394        ["Diff Against Other" git-diff-file-other t])
1395      "--------"
1396      ["Add File" git-add-file t]
1397      ["Revert File" git-revert-file t]
1398      ["Ignore File" git-ignore-file t]
1399      ["Remove File" git-remove-file t]
1400      "--------"
1401      ["Find File" git-find-file t]
1402      ["View File" git-view-file t]
1403      ["Diff File" git-diff-file t]
1404      ["Interactive Diff File" git-diff-file-idiff t]
1405      ["Log" git-log-file t]
1406      "--------"
1407      ["Mark" git-mark-file t]
1408      ["Mark All" git-mark-all t]
1409      ["Unmark" git-unmark-file t]
1410      ["Unmark All" git-unmark-all t]
1411      ["Toggle All Marks" git-toggle-all-marks t]
1412      ["Hide Handled Files" git-remove-handled t]
1413      "--------"
1414      ["Show Uptodate Files" git-toggle-show-uptodate :style toggle :selected git-show-uptodate]
1415      ["Show Ignored Files" git-toggle-show-ignored :style toggle :selected git-show-ignored]
1416      ["Show Unknown Files" git-toggle-show-unknown :style toggle :selected git-show-unknown]
1417      "--------"
1418      ["Quit" git-status-quit t])))
1419
1420
1421;; git mode should only run in the *git status* buffer
1422(put 'git-status-mode 'mode-class 'special)
1423
1424(defun git-status-mode ()
1425  "Major mode for interacting with Git.
1426Commands:
1427\\{git-status-mode-map}"
1428  (kill-all-local-variables)
1429  (buffer-disable-undo)
1430  (setq mode-name "git status"
1431        major-mode 'git-status-mode
1432        goal-column 17
1433        buffer-read-only t)
1434  (use-local-map git-status-mode-map)
1435  (let ((buffer-read-only nil))
1436    (erase-buffer)
1437  (let ((status (ewoc-create 'git-fileinfo-prettyprint "" "")))
1438    (set (make-local-variable 'git-status) status))
1439  (set (make-local-variable 'list-buffers-directory) default-directory)
1440  (make-local-variable 'git-show-uptodate)
1441  (make-local-variable 'git-show-ignored)
1442  (make-local-variable 'git-show-unknown)
1443  (run-hooks 'git-status-mode-hook)))
1444
1445(defun git-find-status-buffer (dir)
1446  "Find the git status buffer handling a specified directory."
1447  (let ((list (buffer-list))
1448        (fulldir (expand-file-name dir))
1449        found)
1450    (while (and list (not found))
1451      (let ((buffer (car list)))
1452        (with-current-buffer buffer
1453          (when (and list-buffers-directory
1454                     (string-equal fulldir (expand-file-name list-buffers-directory))
1455                     (string-match "\\*git-status\\*$" (buffer-name buffer)))
1456            (setq found buffer))))
1457      (setq list (cdr list)))
1458    found))
1459
1460(defun git-status (dir)
1461  "Entry point into git-status mode."
1462  (interactive "DSelect directory: ")
1463  (setq dir (git-get-top-dir dir))
1464  (if (file-directory-p (concat (file-name-as-directory dir) ".git"))
1465      (let ((buffer (or (and git-reuse-status-buffer (git-find-status-buffer dir))
1466                        (create-file-buffer (expand-file-name "*git-status*" dir)))))
1467        (switch-to-buffer buffer)
1468        (cd dir)
1469        (git-status-mode)
1470        (git-refresh-status)
1471        (goto-char (point-min))
1472        (add-hook 'after-save-hook 'git-update-saved-file))
1473    (message "%s is not a git working tree." dir)))
1474
1475(defun git-update-saved-file ()
1476  "Update the corresponding git-status buffer when a file is saved.
1477Meant to be used in `after-save-hook'."
1478  (let* ((file (expand-file-name buffer-file-name))
1479         (dir (condition-case nil (git-get-top-dir (file-name-directory file)) (error nil)))
1480         (buffer (and dir (git-find-status-buffer dir))))
1481    (when buffer
1482      (with-current-buffer buffer
1483        (let ((filename (file-relative-name file dir)))
1484          ; skip files located inside the .git directory
1485          (unless (string-match "^\\.git/" filename)
1486            (git-call-process-env nil nil "add" "--refresh" "--" filename)
1487            (git-update-status-files (list filename) 'uptodate)))))))
1488
1489(defun git-help ()
1490  "Display help for Git mode."
1491  (interactive)
1492  (describe-function 'git-status-mode))
1493
1494(provide 'git)
1495;;; git.el ends here