Andrew's git / gitweb.git / git-cvsimport.perl
?
git-cvsimport.perlon commit Built git-upload-tar should be ignored. (4acdeaf)
   1#!/usr/bin/perl -w
   2
   3# This tool is copyright (c) 2005, Matthias Urlichs.
   4# It is released under the Gnu Public License, version 2.
   5#
   6# The basic idea is to aggregate CVS check-ins into related changes.
   7# Fortunately, "cvsps" does that for us; all we have to do is to parse
   8# its output.
   9#
  10# Checking out the files is done by a single long-running CVS connection
  11# / server process.
  12#
  13# The head revision is on branch "origin" by default.
  14# You can change that with the '-o' option.
  15
  16use strict;
  17use warnings;
  18use Getopt::Std;
  19use File::Spec;
  20use File::Temp qw(tempfile);
  21use File::Path qw(mkpath);
  22use File::Basename qw(basename dirname);
  23use Time::Local;
  24use IO::Socket;
  25use IO::Pipe;
  26use POSIX qw(strftime dup2 :errno_h);
  27use IPC::Open2;
  28
  29$SIG{'PIPE'}="IGNORE";
  30$ENV{'TZ'}="UTC";
  31
  32our($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S,$opt_L);
  33my (%conv_author_name, %conv_author_email);
  34
  35sub usage() {
  36        print STDERR <<END;
  37Usage: ${\basename $0}     # fetch/update GIT from CVS
  38       [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  39       [-p opts-for-cvsps] [-C GIT_repository] [-z fuzz] [-i] [-k] [-u]
  40       [-s subst] [-m] [-M regex] [-S regex] [CVS_module]
  41END
  42        exit(1);
  43}
  44
  45sub read_author_info($) {
  46        my ($file) = @_;
  47        my $user;
  48        open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  49
  50        while (<$f>) {
  51                # Expected format is this:
  52                #   exon=Andreas Ericsson <ae@op5.se>
  53                if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  54                        $user = $1;
  55                        $conv_author_name{$user} = $2;
  56                        $conv_author_email{$user} = $3;
  57                }
  58                # However, we also read from CVSROOT/users format
  59                # to ease migration.
  60                elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  61                        my $mapped;
  62                        ($user, $mapped) = ($1, $3);
  63                        if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  64                                $conv_author_name{$user} = $1;
  65                                $conv_author_email{$user} = $2;
  66                        }
  67                        elsif ($mapped =~ /^<?(.*)>?$/) {
  68                                $conv_author_name{$user} = $user;
  69                                $conv_author_email{$user} = $1;
  70                        }
  71                }
  72                # NEEDSWORK: Maybe warn on unrecognized lines?
  73        }
  74        close ($f);
  75}
  76
  77sub write_author_info($) {
  78        my ($file) = @_;
  79        open my $f, '>', $file or
  80          die("Failed to open $file for writing: $!");
  81
  82        foreach (keys %conv_author_name) {
  83                print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  84        }
  85        close ($f);
  86}
  87
  88getopts("hivmkuo:d:p:C:z:s:M:P:A:S:L:") or usage();
  89usage if $opt_h;
  90
  91@ARGV <= 1 or usage();
  92
  93if($opt_d) {
  94        $ENV{"CVSROOT"} = $opt_d;
  95} elsif(-f 'CVS/Root') {
  96        open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
  97        $opt_d = <$f>;
  98        chomp $opt_d;
  99        close $f;
 100        $ENV{"CVSROOT"} = $opt_d;
 101} elsif($ENV{"CVSROOT"}) {
 102        $opt_d = $ENV{"CVSROOT"};
 103} else {
 104        die "CVSROOT needs to be set";
 105}
 106$opt_o ||= "origin";
 107$opt_s ||= "-";
 108my $git_tree = $opt_C;
 109$git_tree ||= ".";
 110
 111my $cvs_tree;
 112if ($#ARGV == 0) {
 113        $cvs_tree = $ARGV[0];
 114} elsif (-f 'CVS/Repository') {
 115        open my $f, '<', 'CVS/Repository' or 
 116            die 'Failed to open CVS/Repository';
 117        $cvs_tree = <$f>;
 118        chomp $cvs_tree;
 119        close $f;
 120} else {
 121        usage();
 122}
 123
 124our @mergerx = ();
 125if ($opt_m) {
 126        @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
 127}
 128if ($opt_M) {
 129        push (@mergerx, qr/$opt_M/);
 130}
 131
 132select(STDERR); $|=1; select(STDOUT);
 133
 134
 135package CVSconn;
 136# Basic CVS dialog.
 137# We're only interested in connecting and downloading, so ...
 138
 139use File::Spec;
 140use File::Temp qw(tempfile);
 141use POSIX qw(strftime dup2);
 142
 143sub new {
 144        my($what,$repo,$subdir) = @_;
 145        $what=ref($what) if ref($what);
 146
 147        my $self = {};
 148        $self->{'buffer'} = "";
 149        bless($self,$what);
 150
 151        $repo =~ s#/+$##;
 152        $self->{'fullrep'} = $repo;
 153        $self->conn();
 154
 155        $self->{'subdir'} = $subdir;
 156        $self->{'lines'} = undef;
 157
 158        return $self;
 159}
 160
 161sub conn {
 162        my $self = shift;
 163        my $repo = $self->{'fullrep'};
 164        if($repo =~ s/^:pserver:(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 165                my($user,$pass,$serv,$port) = ($1,$2,$3,$4);
 166                $user="anonymous" unless defined $user;
 167                my $rr2 = "-";
 168                unless($port) {
 169                        $rr2 = ":pserver:$user\@$serv:$repo";
 170                        $port=2401;
 171                }
 172                my $rr = ":pserver:$user\@$serv:$port$repo";
 173
 174                unless($pass) {
 175                        open(H,$ENV{'HOME'}."/.cvspass") and do {
 176                                # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 177                                while(<H>) {
 178                                        chomp;
 179                                        s/^\/\d+\s+//;
 180                                        my ($w,$p) = split(/\s/,$_,2);
 181                                        if($w eq $rr or $w eq $rr2) {
 182                                                $pass = $p;
 183                                                last;
 184                                        }
 185                                }
 186                        };
 187                }
 188                $pass="A" unless $pass;
 189
 190                my $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 191                die "Socket to $serv: $!\n" unless defined $s;
 192                $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 193                        or die "Write to $serv: $!\n";
 194                $s->flush();
 195
 196                my $rep = <$s>;
 197
 198                if($rep ne "I LOVE YOU\n") {
 199                        $rep="<unknown>" unless $rep;
 200                        die "AuthReply: $rep\n";
 201                }
 202                $self->{'socketo'} = $s;
 203                $self->{'socketi'} = $s;
 204        } else { # local or ext: Fork off our own cvs server.
 205                my $pr = IO::Pipe->new();
 206                my $pw = IO::Pipe->new();
 207                my $pid = fork();
 208                die "Fork: $!\n" unless defined $pid;
 209                my $cvs = 'cvs';
 210                $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 211                my $rsh = 'rsh';
 212                $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 213
 214                my @cvs = ($cvs, 'server');
 215                my ($local, $user, $host);
 216                $local = $repo =~ s/:local://;
 217                if (!$local) {
 218                    $repo =~ s/:ext://;
 219                    $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 220                    ($user, $host) = ($1, $2);
 221                }
 222                if (!$local) {
 223                    if ($user) {
 224                        unshift @cvs, $rsh, '-l', $user, $host;
 225                    } else {
 226                        unshift @cvs, $rsh, $host;
 227                    }
 228                }
 229
 230                unless($pid) {
 231                        $pr->writer();
 232                        $pw->reader();
 233                        dup2($pw->fileno(),0);
 234                        dup2($pr->fileno(),1);
 235                        $pr->close();
 236                        $pw->close();
 237                        exec(@cvs);
 238                }
 239                $pw->writer();
 240                $pr->reader();
 241                $self->{'socketo'} = $pw;
 242                $self->{'socketi'} = $pr;
 243        }
 244        $self->{'socketo'}->write("Root $repo\n");
 245
 246        # Trial and error says that this probably is the minimum set
 247        $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 248
 249        $self->{'socketo'}->write("valid-requests\n");
 250        $self->{'socketo'}->flush();
 251
 252        chomp(my $rep=$self->readline());
 253        if($rep !~ s/^Valid-requests\s*//) {
 254                $rep="<unknown>" unless $rep;
 255                die "Expected Valid-requests from server, but got: $rep\n";
 256        }
 257        chomp(my $res=$self->readline());
 258        die "validReply: $res\n" if $res ne "ok";
 259
 260        $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 261        $self->{'repo'} = $repo;
 262}
 263
 264sub readline {
 265        my($self) = @_;
 266        return $self->{'socketi'}->getline();
 267}
 268
 269sub _file {
 270        # Request a file with a given revision.
 271        # Trial and error says this is a good way to do it. :-/
 272        my($self,$fn,$rev) = @_;
 273        $self->{'socketo'}->write("Argument -N\n") or return undef;
 274        $self->{'socketo'}->write("Argument -P\n") or return undef;
 275        # -kk: Linus' version doesn't use it - defaults to off
 276        if ($opt_k) {
 277            $self->{'socketo'}->write("Argument -kk\n") or return undef;
 278        }
 279        $self->{'socketo'}->write("Argument -r\n") or return undef;
 280        $self->{'socketo'}->write("Argument $rev\n") or return undef;
 281        $self->{'socketo'}->write("Argument --\n") or return undef;
 282        $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 283        $self->{'socketo'}->write("Directory .\n") or return undef;
 284        $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 285        # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 286        $self->{'socketo'}->write("co\n") or return undef;
 287        $self->{'socketo'}->flush() or return undef;
 288        $self->{'lines'} = 0;
 289        return 1;
 290}
 291sub _line {
 292        # Read a line from the server.
 293        # ... except that 'line' may be an entire file. ;-)
 294        my($self, $fh) = @_;
 295        die "Not in lines" unless defined $self->{'lines'};
 296
 297        my $line;
 298        my $res=0;
 299        while(defined($line = $self->readline())) {
 300                # M U gnupg-cvs-rep/AUTHORS
 301                # Updated gnupg-cvs-rep/
 302                # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 303                # /AUTHORS/1.1///T1.1
 304                # u=rw,g=rw,o=rw
 305                # 0
 306                # ok
 307
 308                if($line =~ s/^(?:Created|Updated) //) {
 309                        $line = $self->readline(); # path
 310                        $line = $self->readline(); # Entries line
 311                        my $mode = $self->readline(); chomp $mode;
 312                        $self->{'mode'} = $mode;
 313                        defined (my $cnt = $self->readline())
 314                                or die "EOF from server after 'Changed'\n";
 315                        chomp $cnt;
 316                        die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 317                        $line="";
 318                        $res = $self->_fetchfile($fh, $cnt);
 319                } elsif($line =~ s/^ //) {
 320                        print $fh $line;
 321                        $res += length($line);
 322                } elsif($line =~ /^M\b/) {
 323                        # output, do nothing
 324                } elsif($line =~ /^Mbinary\b/) {
 325                        my $cnt;
 326                        die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 327                        chomp $cnt;
 328                        die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 329                        $line="";
 330                        $res += $self->_fetchfile($fh, $cnt);
 331                } else {
 332                        chomp $line;
 333                        if($line eq "ok") {
 334                                # print STDERR "S: ok (".length($res).")\n";
 335                                return $res;
 336                        } elsif($line =~ s/^E //) {
 337                                # print STDERR "S: $line\n";
 338                        } elsif($line =~ /^(Remove-entry|Removed) /i) {
 339                                $line = $self->readline(); # filename
 340                                $line = $self->readline(); # OK
 341                                chomp $line;
 342                                die "Unknown: $line" if $line ne "ok";
 343                                return -1;
 344                        } else {
 345                                die "Unknown: $line\n";
 346                        }
 347                }
 348        }
 349        return undef;
 350}
 351sub file {
 352        my($self,$fn,$rev) = @_;
 353        my $res;
 354
 355        my ($fh, $name) = tempfile('gitcvs.XXXXXX', 
 356                    DIR => File::Spec->tmpdir(), UNLINK => 1);
 357
 358        $self->_file($fn,$rev) and $res = $self->_line($fh);
 359
 360        if (!defined $res) {
 361            print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
 362            truncate $fh, 0;
 363            $self->conn();
 364            $self->_file($fn,$rev) or die "No file command send";
 365            $res = $self->_line($fh);
 366            die "Retry failed" unless defined $res;
 367        }
 368        close ($fh);
 369
 370        return ($name, $res);
 371}
 372sub _fetchfile {
 373        my ($self, $fh, $cnt) = @_;
 374        my $res = 0;
 375        my $bufsize = 1024 * 1024;
 376        while($cnt) {
 377            if ($bufsize > $cnt) {
 378                $bufsize = $cnt;
 379            }
 380            my $buf;
 381            my $num = $self->{'socketi'}->read($buf,$bufsize);
 382            die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 383            print $fh $buf;
 384            $res += $num;
 385            $cnt -= $num;
 386        }
 387        return $res;
 388}
 389
 390
 391package main;
 392
 393my $cvs = CVSconn->new($opt_d, $cvs_tree);
 394
 395
 396sub pdate($) {
 397        my($d) = @_;
 398        m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 399                or die "Unparseable date: $d\n";
 400        my $y=$1; $y-=1900 if $y>1900;
 401        return timegm($6||0,$5,$4,$3,$2-1,$y);
 402}
 403
 404sub pmode($) {
 405        my($mode) = @_;
 406        my $m = 0;
 407        my $mm = 0;
 408        my $um = 0;
 409        for my $x(split(//,$mode)) {
 410                if($x eq ",") {
 411                        $m |= $mm&$um;
 412                        $mm = 0;
 413                        $um = 0;
 414                } elsif($x eq "u") { $um |= 0700;
 415                } elsif($x eq "g") { $um |= 0070;
 416                } elsif($x eq "o") { $um |= 0007;
 417                } elsif($x eq "r") { $mm |= 0444;
 418                } elsif($x eq "w") { $mm |= 0222;
 419                } elsif($x eq "x") { $mm |= 0111;
 420                } elsif($x eq "=") { # do nothing
 421                } else { die "Unknown mode: $mode\n";
 422                }
 423        }
 424        $m |= $mm&$um;
 425        return $m;
 426}
 427
 428sub getwd() {
 429        my $pwd = `pwd`;
 430        chomp $pwd;
 431        return $pwd;
 432}
 433
 434sub is_sha1 {
 435        my $s = shift;
 436        return $s =~ /^[a-f0-9]{40}$/;
 437}
 438
 439sub get_headref ($$) {
 440    my $name    = shift;
 441    my $git_dir = shift; 
 442    
 443    my $f = "$git_dir/refs/heads/$name";
 444    if(open(my $fh, $f)) {
 445            chomp(my $r = <$fh>);
 446            is_sha1($r) or die "Cannot get head id for $name ($r): $!";
 447            return $r;
 448    }
 449    die "unable to open $f: $!" unless $! == POSIX::ENOENT;
 450    return undef;
 451}
 452
 453-d $git_tree
 454        or mkdir($git_tree,0777)
 455        or die "Could not create $git_tree: $!";
 456chdir($git_tree);
 457
 458my $last_branch = "";
 459my $orig_branch = "";
 460my %branch_date;
 461my $tip_at_start = undef;
 462
 463my $git_dir = $ENV{"GIT_DIR"} || ".git";
 464$git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 465$ENV{"GIT_DIR"} = $git_dir;
 466my $orig_git_index;
 467$orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 468my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 469                                    DIR => File::Spec->tmpdir());
 470close ($git_ih);
 471$ENV{GIT_INDEX_FILE} = $git_index;
 472unless(-d $git_dir) {
 473        system("git-init-db");
 474        die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 475        system("git-read-tree");
 476        die "Cannot init an empty tree: $?\n" if $?;
 477
 478        $last_branch = $opt_o;
 479        $orig_branch = "";
 480} else {
 481        -f "$git_dir/refs/heads/$opt_o"
 482                or die "Branch '$opt_o' does not exist.\n".
 483                       "Either use the correct '-o branch' option,\n".
 484                       "or import to a new repository.\n";
 485
 486        open(F, "git-symbolic-ref HEAD |") or
 487                die "Cannot run git-symbolic-ref: $!\n";
 488        chomp ($last_branch = <F>);
 489        $last_branch = basename($last_branch);
 490        close(F);
 491        unless($last_branch) {
 492                warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 493                $last_branch = "master";
 494        }
 495        $orig_branch = $last_branch;
 496        $tip_at_start = `git-rev-parse --verify HEAD`;
 497
 498        # populate index
 499        system('git-read-tree', $last_branch);
 500        die "read-tree failed: $?\n" if $?;
 501
 502        # Get the last import timestamps
 503        opendir(D,"$git_dir/refs/heads");
 504        while(defined(my $head = readdir(D))) {
 505                next if $head =~ /^\./;
 506                open(F,"$git_dir/refs/heads/$head")
 507                        or die "Bad head branch: $head: $!\n";
 508                chomp(my $ftag = <F>);
 509                close(F);
 510                open(F,"git-cat-file commit $ftag |");
 511                while(<F>) {
 512                        next unless /^author\s.*\s(\d+)\s[-+]\d{4}$/;
 513                        $branch_date{$head} = $1;
 514                        last;
 515                }
 516                close(F);
 517        }
 518        closedir(D);
 519}
 520
 521-d $git_dir
 522        or die "Could not create git subdir ($git_dir).\n";
 523
 524# now we read (and possibly save) author-info as well
 525-f "$git_dir/cvs-authors" and
 526  read_author_info("$git_dir/cvs-authors");
 527if ($opt_A) {
 528        read_author_info($opt_A);
 529        write_author_info("$git_dir/cvs-authors");
 530}
 531
 532my $pid = open(CVS,"-|");
 533die "Cannot fork: $!\n" unless defined $pid;
 534unless($pid) {
 535        my @opt;
 536        @opt = split(/,/,$opt_p) if defined $opt_p;
 537        unshift @opt, '-z', $opt_z if defined $opt_z;
 538        unshift @opt, '-q'         unless defined $opt_v;
 539        unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 540                push @opt, '--cvs-direct';
 541        }
 542        if ($opt_P) {
 543            exec("cat", $opt_P);
 544        } else {
 545            exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 546            die "Could not start cvsps: $!\n";
 547        }
 548}
 549
 550
 551## cvsps output:
 552#---------------------
 553#PatchSet 314
 554#Date: 1999/09/18 13:03:59
 555#Author: wkoch
 556#Branch: STABLE-BRANCH-1-0
 557#Ancestor branch: HEAD
 558#Tag: (none)
 559#Log:
 560#    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 561#Members:
 562#       README:1.57->1.57.2.1
 563#       VERSION:1.96->1.96.2.1
 564#
 565#---------------------
 566
 567my $state = 0;
 568
 569sub update_index (\@\@) {
 570        my $old = shift;
 571        my $new = shift;
 572        open(my $fh, '|-', qw(git-update-index -z --index-info))
 573                or die "unable to open git-update-index: $!";
 574        print $fh
 575                (map { "0 0000000000000000000000000000000000000000\t$_\0" }
 576                        @$old),
 577                (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
 578                        @$new)
 579                or die "unable to write to git-update-index: $!";
 580        close $fh
 581                or die "unable to write to git-update-index: $!";
 582        $? and die "git-update-index reported error: $?";
 583}
 584
 585sub write_tree () {
 586        open(my $fh, '-|', qw(git-write-tree))
 587                or die "unable to open git-write-tree: $!";
 588        chomp(my $tree = <$fh>);
 589        is_sha1($tree)
 590                or die "Cannot get tree id ($tree): $!";
 591        close($fh)
 592                or die "Error running git-write-tree: $?\n";
 593        print "Tree ID $tree\n" if $opt_v;
 594        return $tree;
 595}
 596
 597my($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 598my(@old,@new,@skipped);
 599sub commit {
 600        update_index(@old, @new);
 601        @old = @new = ();
 602        my $tree = write_tree();
 603        my $parent = get_headref($last_branch, $git_dir);
 604        print "Parent ID " . ($parent ? $parent : "(empty)") . "\n" if $opt_v;
 605
 606        my @commit_args;
 607        push @commit_args, ("-p", $parent) if $parent;
 608
 609        # loose detection of merges
 610        # based on the commit msg
 611        foreach my $rx (@mergerx) {
 612                next unless $logmsg =~ $rx && $1;
 613                my $mparent = $1 eq 'HEAD' ? $opt_o : $1;
 614                if(my $sha1 = get_headref($mparent, $git_dir)) {
 615                        push @commit_args, '-p', $mparent;
 616                        print "Merge parent branch: $mparent\n" if $opt_v;
 617                }
 618        }
 619
 620        my $commit_date = strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date));
 621        $ENV{GIT_AUTHOR_NAME} = $author_name;
 622        $ENV{GIT_AUTHOR_EMAIL} = $author_email;
 623        $ENV{GIT_AUTHOR_DATE} = $commit_date;
 624        $ENV{GIT_COMMITTER_NAME} = $author_name;
 625        $ENV{GIT_COMMITTER_EMAIL} = $author_email;
 626        $ENV{GIT_COMMITTER_DATE} = $commit_date;
 627        my $pid = open2(my $commit_read, my $commit_write,
 628                'git-commit-tree', $tree, @commit_args);
 629
 630        # compatibility with git2cvs
 631        substr($logmsg,32767) = "" if length($logmsg) > 32767;
 632        $logmsg =~ s/[\s\n]+\z//;
 633
 634        if (@skipped) {
 635            $logmsg .= "\n\n\nSKIPPED:\n\t";
 636            $logmsg .= join("\n\t", @skipped) . "\n";
 637            @skipped = ();
 638        }
 639
 640        print($commit_write "$logmsg\n") && close($commit_write)
 641                or die "Error writing to git-commit-tree: $!\n";
 642
 643        print "Committed patch $patchset ($branch $commit_date)\n" if $opt_v;
 644        chomp(my $cid = <$commit_read>);
 645        is_sha1($cid) or die "Cannot get commit id ($cid): $!\n";
 646        print "Commit ID $cid\n" if $opt_v;
 647        close($commit_read);
 648
 649        waitpid($pid,0);
 650        die "Error running git-commit-tree: $?\n" if $?;
 651
 652        system("git-update-ref refs/heads/$branch $cid") == 0
 653                or die "Cannot write branch $branch for update: $!\n";
 654
 655        if($tag) {
 656                my($in, $out) = ('','');
 657                my($xtag) = $tag;
 658                $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 659                $xtag =~ tr/_/\./ if ( $opt_u );
 660                $xtag =~ s/[\/]/$opt_s/g;
 661                
 662                my $pid = open2($in, $out, 'git-mktag');
 663                print $out "object $cid\n".
 664                    "type commit\n".
 665                    "tag $xtag\n".
 666                    "tagger $author_name <$author_email>\n"
 667                    or die "Cannot create tag object $xtag: $!\n";
 668                close($out)
 669                    or die "Cannot create tag object $xtag: $!\n";
 670
 671                my $tagobj = <$in>;
 672                chomp $tagobj;
 673
 674                if ( !close($in) or waitpid($pid, 0) != $pid or
 675                     $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 676                    die "Cannot create tag object $xtag: $!\n";
 677                }
 678                
 679
 680                open(C,">$git_dir/refs/tags/$xtag")
 681                        or die "Cannot create tag $xtag: $!\n";
 682                print C "$tagobj\n"
 683                        or die "Cannot write tag $xtag: $!\n";
 684                close(C)
 685                        or die "Cannot write tag $xtag: $!\n";
 686
 687                print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 688        }
 689};
 690
 691my $commitcount = 1;
 692while(<CVS>) {
 693        chomp;
 694        if($state == 0 and /^-+$/) {
 695                $state = 1;
 696        } elsif($state == 0) {
 697                $state = 1;
 698                redo;
 699        } elsif(($state==0 or $state==1) and s/^PatchSet\s+//) {
 700                $patchset = 0+$_;
 701                $state=2;
 702        } elsif($state == 2 and s/^Date:\s+//) {
 703                $date = pdate($_);
 704                unless($date) {
 705                        print STDERR "Could not parse date: $_\n";
 706                        $state=0;
 707                        next;
 708                }
 709                $state=3;
 710        } elsif($state == 3 and s/^Author:\s+//) {
 711                s/\s+$//;
 712                if (/^(.*?)\s+<(.*)>/) {
 713                    ($author_name, $author_email) = ($1, $2);
 714                } elsif ($conv_author_name{$_}) {
 715                        $author_name = $conv_author_name{$_};
 716                        $author_email = $conv_author_email{$_};
 717                } else {
 718                    $author_name = $author_email = $_;
 719                }
 720                $state = 4;
 721        } elsif($state == 4 and s/^Branch:\s+//) {
 722                s/\s+$//;
 723                s/[\/]/$opt_s/g;
 724                $branch = $_;
 725                $state = 5;
 726        } elsif($state == 5 and s/^Ancestor branch:\s+//) {
 727                s/\s+$//;
 728                $ancestor = $_;
 729                $ancestor = $opt_o if $ancestor eq "HEAD";
 730                $state = 6;
 731        } elsif($state == 5) {
 732                $ancestor = undef;
 733                $state = 6;
 734                redo;
 735        } elsif($state == 6 and s/^Tag:\s+//) {
 736                s/\s+$//;
 737                if($_ eq "(none)") {
 738                        $tag = undef;
 739                } else {
 740                        $tag = $_;
 741                }
 742                $state = 7;
 743        } elsif($state == 7 and /^Log:/) {
 744                $logmsg = "";
 745                $state = 8;
 746        } elsif($state == 8 and /^Members:/) {
 747                $branch = $opt_o if $branch eq "HEAD";
 748                if(defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 749                        # skip
 750                        print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 751                        $state = 11;
 752                        next;
 753                }
 754                if($ancestor) {
 755                        if(-f "$git_dir/refs/heads/$branch") {
 756                                print STDERR "Branch $branch already exists!\n";
 757                                $state=11;
 758                                next;
 759                        }
 760                        unless(open(H,"$git_dir/refs/heads/$ancestor")) {
 761                                print STDERR "Branch $ancestor does not exist!\n";
 762                                $state=11;
 763                                next;
 764                        }
 765                        chomp(my $id = <H>);
 766                        close(H);
 767                        unless(open(H,"> $git_dir/refs/heads/$branch")) {
 768                                print STDERR "Could not create branch $branch: $!\n";
 769                                $state=11;
 770                                next;
 771                        }
 772                        print H "$id\n"
 773                                or die "Could not write branch $branch: $!";
 774                        close(H)
 775                                or die "Could not write branch $branch: $!";
 776                }
 777                if(($ancestor || $branch) ne $last_branch) {
 778                        print "Switching from $last_branch to $branch\n" if $opt_v;
 779                        system("git-read-tree", $branch);
 780                        die "read-tree failed: $?\n" if $?;
 781                }
 782                $last_branch = $branch if $branch ne $last_branch;
 783                $state = 9;
 784        } elsif($state == 8) {
 785                $logmsg .= "$_\n";
 786        } elsif($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 787#       VERSION:1.96->1.96.2.1
 788                my $init = ($2 eq "INITIAL");
 789                my $fn = $1;
 790                my $rev = $3;
 791                $fn =~ s#^/+##;
 792                if ($opt_S && $fn =~ m/$opt_S/) {
 793                    print "SKIPPING $fn v $rev\n";
 794                    push(@skipped, $fn);
 795                    next;
 796                }
 797                print "Fetching $fn   v $rev\n" if $opt_v;
 798                my ($tmpname, $size) = $cvs->file($fn,$rev);
 799                if($size == -1) {
 800                        push(@old,$fn);
 801                        print "Drop $fn\n" if $opt_v;
 802                } else {
 803                        print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 804                        my $pid = open(my $F, '-|');
 805                        die $! unless defined $pid;
 806                        if (!$pid) {
 807                            exec("git-hash-object", "-w", $tmpname)
 808                                or die "Cannot create object: $!\n";
 809                        }
 810                        my $sha = <$F>;
 811                        chomp $sha;
 812                        close $F;
 813                        my $mode = pmode($cvs->{'mode'});
 814                        push(@new,[$mode, $sha, $fn]); # may be resurrected!
 815                }
 816                unlink($tmpname);
 817        } elsif($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 818                my $fn = $1;
 819                $fn =~ s#^/+##;
 820                push(@old,$fn);
 821                print "Delete $fn\n" if $opt_v;
 822        } elsif($state == 9 and /^\s*$/) {
 823                $state = 10;
 824        } elsif(($state == 9 or $state == 10) and /^-+$/) {
 825                $commitcount++;
 826                if ($opt_L && $commitcount > $opt_L) {
 827                        last;
 828                }
 829                commit();
 830                if (($commitcount & 1023) == 0) {
 831                        system("git repack -a -d");
 832                }
 833                $state = 1;
 834        } elsif($state == 11 and /^-+$/) {
 835                $state = 1;
 836        } elsif(/^-+$/) { # end of unknown-line processing
 837                $state = 1;
 838        } elsif($state != 11) { # ignore stuff when skipping
 839                print "* UNKNOWN LINE * $_\n";
 840        }
 841}
 842commit() if $branch and $state != 11;
 843
 844unlink($git_index);
 845
 846if (defined $orig_git_index) {
 847        $ENV{GIT_INDEX_FILE} = $orig_git_index;
 848} else {
 849        delete $ENV{GIT_INDEX_FILE};
 850}
 851
 852# Now switch back to the branch we were in before all of this happened
 853if($orig_branch) {
 854        print "DONE.\n" if $opt_v;
 855        if ($opt_i) {
 856                exit 0;
 857        }
 858        my $tip_at_end = `git-rev-parse --verify HEAD`;
 859        if ($tip_at_start ne $tip_at_end) {
 860                for ($tip_at_start, $tip_at_end) { chomp; }
 861                print "Fetched into the current branch.\n" if $opt_v;
 862                system(qw(git-read-tree -u -m),
 863                       $tip_at_start, $tip_at_end);
 864                die "Fast-forward update failed: $?\n" if $?;
 865        }
 866        else {
 867                system(qw(git-merge cvsimport HEAD), "refs/heads/$opt_o");
 868                die "Could not merge $opt_o into the current branch.\n" if $?;
 869        }
 870} else {
 871        $orig_branch = "master";
 872        print "DONE; creating $orig_branch branch\n" if $opt_v;
 873        system("git-update-ref", "refs/heads/master", "refs/heads/$opt_o")
 874                unless -f "$git_dir/refs/heads/master";
 875        system('git-update-ref', 'HEAD', "$orig_branch");
 876        unless ($opt_i) {
 877                system('git checkout');
 878                die "checkout failed: $?\n" if $?;
 879        }
 880}