Andrew's git / gitweb.git / configure.ac
?
configure.acon commit gitweb: Incremental blame (using JavaScript) (4af819d)
   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_ERROR([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  47                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  48        fi; \
  49fi; \
  50]) # GIT_CONF_APPEND_PATH
  51#
  52# GIT_PARSE_WITH(PACKAGE)
  53# -----------------------
  54# For use in AC_ARG_WITH action-if-found, for packages default ON.
  55# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  56# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  57# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  58AC_DEFUN([GIT_PARSE_WITH],
  59[PACKAGE=m4_toupper($1); \
  60if test "$withval" = "no"; then \
  61        m4_toupper(NO_$1)=YesPlease; \
  62elif test "$withval" = "yes"; then \
  63        m4_toupper(NO_$1)=; \
  64else \
  65        m4_toupper(NO_$1)=; \
  66        m4_toupper($1)DIR=$withval; \
  67        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  68        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  69fi \
  70])# GIT_PARSE_WITH
  71
  72dnl
  73dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
  74dnl -----------------------------------------
  75dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
  76dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
  77dnl -Wall), it does not work.  By looking for function definition in
  78dnl libraries, this problem can be worked around.
  79AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
  80  AC_SEARCH_LIBS([$1],,
  81  [$2],[$3])
  82],[$3])])
  83
  84dnl
  85dnl GIT_STASH_FLAGS(BASEPATH_VAR)
  86dnl -----------------------------
  87dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
  88dnl tests that may want to take user settings into account.
  89AC_DEFUN([GIT_STASH_FLAGS],[
  90if test -n "$1"; then
  91   old_CPPFLAGS="$CPPFLAGS"
  92   old_LDFLAGS="$LDFLAGS"
  93   CPPFLAGS="-I$1/include $CPPFLAGS"
  94   LDFLAGS="-L$1/$lib $LDFLAGS"
  95fi
  96])
  97
  98dnl
  99dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 100dnl -----------------------------
 101dnl Restore the stashed *FLAGS values.
 102AC_DEFUN([GIT_UNSTASH_FLAGS],[
 103if test -n "$1"; then
 104   CPPFLAGS="$old_CPPFLAGS"
 105   LDFLAGS="$old_LDFLAGS"
 106fi
 107])
 108
 109## Site configuration related to programs (before tests)
 110## --with-PACKAGE[=ARG] and --without-PACKAGE
 111#
 112# Set lib to alternative name of lib directory (e.g. lib64)
 113AC_ARG_WITH([lib],
 114 [AS_HELP_STRING([--with-lib=ARG],
 115                 [ARG specifies alternative name for lib directory])],
 116 [if test "$withval" = "no" || test "$withval" = "yes"; then \
 117        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 118else \
 119        lib=$withval; \
 120        AC_MSG_NOTICE([Setting lib to '$lib']); \
 121        GIT_CONF_APPEND_LINE(lib=$withval); \
 122fi; \
 123],[])
 124
 125if test -z "$lib"; then
 126   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 127   lib=lib
 128fi
 129
 130AC_ARG_ENABLE([pthreads],
 131 [AS_HELP_STRING([--enable-pthreads=FLAGS],
 132  [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 133  [The default if FLAGS is not specified is to try first -pthread]
 134  [and then -lpthread.]
 135  [--without-pthreads will disable threading.])],
 136[
 137if test "x$enableval" = "xyes"; then
 138   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 139elif test "x$enableval" != "xno"; then
 140   PTHREAD_CFLAGS=$enableval
 141   AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 142else
 143   AC_MSG_NOTICE([POSIX Threads will be disabled.])
 144   NO_PTHREADS=YesPlease
 145   USER_NOPTHREAD=1
 146fi],
 147[
 148   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 149])
 150
 151## Site configuration (override autodetection)
 152## --with-PACKAGE[=ARG] and --without-PACKAGE
 153AC_MSG_NOTICE([CHECKS for site configuration])
 154#
 155# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 156# tests.  These tests take up a significant amount of the total test time
 157# but are not needed unless you plan to talk to SVN repos.
 158#
 159# Define MOZILLA_SHA1 environment variable when running make to make use of
 160# a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 161# on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 162# choice) has very fast version optimized for i586.
 163#
 164# Define PPC_SHA1 environment variable when running make to make use of
 165# a bundled SHA1 routine optimized for PowerPC.
 166#
 167# Define ARM_SHA1 environment variable when running make to make use of
 168# a bundled SHA1 routine optimized for ARM.
 169#
 170# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 171# This also implies MOZILLA_SHA1.
 172#
 173# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 174# /foo/bar/include and /foo/bar/lib directories.
 175AC_ARG_WITH(openssl,
 176AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 177AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 178GIT_PARSE_WITH(openssl))
 179#
 180# Define NO_CURL if you do not have curl installed.  git-http-pull and
 181# git-http-push are not built, and you cannot use http:// and https://
 182# transports.
 183#
 184# Define CURLDIR=/foo/bar if your curl header and library files are in
 185# /foo/bar/include and /foo/bar/lib directories.
 186AC_ARG_WITH(curl,
 187AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 188AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 189GIT_PARSE_WITH(curl))
 190#
 191# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 192# not built, and you cannot push using http:// and https:// transports.
 193#
 194# Define EXPATDIR=/foo/bar if your expat header and library files are in
 195# /foo/bar/include and /foo/bar/lib directories.
 196AC_ARG_WITH(expat,
 197AS_HELP_STRING([--with-expat],
 198[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 199AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 200GIT_PARSE_WITH(expat))
 201#
 202# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 203# installed in /sw, but don't want GIT to link against any libraries
 204# installed there.  If defined you may specify your own (or Fink's)
 205# include directories and library directories by defining CFLAGS
 206# and LDFLAGS appropriately.
 207#
 208# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 209# have DarwinPorts installed in /opt/local, but don't want GIT to
 210# link against any libraries installed there.  If defined you may
 211# specify your own (or DarwinPort's) include directories and
 212# library directories by defining CFLAGS and LDFLAGS appropriately.
 213#
 214# Define NO_MMAP if you want to avoid mmap.
 215#
 216# Define NO_ICONV if your libc does not properly support iconv.
 217AC_ARG_WITH(iconv,
 218AS_HELP_STRING([--without-iconv],
 219[if your architecture doesn't properly support iconv])
 220AS_HELP_STRING([--with-iconv=PATH],
 221[PATH is prefix for libiconv library and headers])
 222AS_HELP_STRING([],
 223[used only if you need linking with libiconv]),
 224GIT_PARSE_WITH(iconv))
 225
 226## --enable-FEATURE[=ARG] and --disable-FEATURE
 227#
 228# Define USE_NSEC below if you want git to care about sub-second file mtimes
 229# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 230# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 231# randomly break unless your underlying filesystem supports those sub-second
 232# times (my ext3 doesn't).
 233#
 234# Define USE_STDEV below if you want git to care about the underlying device
 235# change being considered an inode change from the update-index perspective.
 236
 237#
 238# Define SHELL_PATH to provide path to shell.
 239GIT_ARG_SET_PATH(shell)
 240#
 241# Define PERL_PATH to provide path to Perl.
 242GIT_ARG_SET_PATH(perl)
 243#
 244# Define ZLIB_PATH to provide path to zlib.
 245GIT_ARG_SET_PATH(zlib)
 246#
 247# Declare the with-tcltk/without-tcltk options.
 248AC_ARG_WITH(tcltk,
 249AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 250AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 251AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 252AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 253GIT_PARSE_WITH(tcltk))
 254#
 255
 256
 257## Checks for programs.
 258AC_MSG_NOTICE([CHECKS for programs])
 259#
 260AC_PROG_CC([cc gcc])
 261# which switch to pass runtime path to dynamic libraries to the linker
 262AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 263   SAVE_LDFLAGS="${LDFLAGS}"
 264   LDFLAGS="${SAVE_LDFLAGS} -R /"
 265   AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 266   LDFLAGS="${SAVE_LDFLAGS}"
 267])
 268if test "$git_cv_ld_dashr" = "yes"; then
 269   AC_SUBST(CC_LD_DYNPATH, [-R])
 270else
 271   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 272      SAVE_LDFLAGS="${LDFLAGS}"
 273      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 274      AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 275      LDFLAGS="${SAVE_LDFLAGS}"
 276   ])
 277   if test "$git_cv_ld_wl_rpath" = "yes"; then
 278      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 279   else
 280      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 281         SAVE_LDFLAGS="${LDFLAGS}"
 282         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 283         AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 284         LDFLAGS="${SAVE_LDFLAGS}"
 285      ])
 286      if test "$git_cv_ld_rpath" = "yes"; then
 287         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 288      else
 289         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 290      fi
 291   fi
 292fi
 293#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 294AC_CHECK_TOOLS(AR, [gar ar], :)
 295AC_CHECK_PROGS(TAR, [gtar tar])
 296# TCLTK_PATH will be set to some value if we want Tcl/Tk
 297# or will be empty otherwise.
 298if test -z "$NO_TCLTK"; then
 299  if test "$with_tcltk" = ""; then
 300  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 301    TCLTK_PATH=wish
 302    AC_SUBST(TCLTK_PATH)
 303  elif test "$with_tcltk" = "yes"; then
 304  # Tcl/Tk check requested.
 305    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 306  else
 307    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 308    TCLTK_PATH="$with_tcltk"
 309    AC_SUBST(TCLTK_PATH)
 310  fi
 311fi
 312AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 313if test -n "$ASCIIDOC"; then
 314        AC_MSG_CHECKING([for asciidoc version])
 315        asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 316        case "${asciidoc_version}" in
 317        asciidoc' '8*)
 318                ASCIIDOC8=YesPlease
 319                AC_MSG_RESULT([${asciidoc_version} > 7])
 320                ;;
 321        asciidoc' '7*)
 322                ASCIIDOC8=
 323                AC_MSG_RESULT([${asciidoc_version}])
 324                ;;
 325        *)
 326                ASCIIDOC8=
 327                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 328                ;;
 329        esac
 330fi
 331AC_SUBST(ASCIIDOC8)
 332
 333
 334## Checks for libraries.
 335AC_MSG_NOTICE([CHECKS for libraries])
 336#
 337# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 338# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 339
 340GIT_STASH_FLAGS($OPENSSLDIR)
 341
 342AC_CHECK_LIB([crypto], [SHA1_Init],
 343[NEEDS_SSL_WITH_CRYPTO=],
 344[AC_CHECK_LIB([ssl], [SHA1_Init],
 345 [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 346 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 347
 348GIT_UNSTASH_FLAGS($OPENSSLDIR)
 349
 350AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 351AC_SUBST(NO_OPENSSL)
 352
 353#
 354# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 355# git-http-push are not built, and you cannot use http:// and https://
 356# transports.
 357
 358GIT_STASH_FLAGS($CURLDIR)
 359
 360AC_CHECK_LIB([curl], [curl_global_init],
 361[NO_CURL=],
 362[NO_CURL=YesPlease])
 363
 364GIT_UNSTASH_FLAGS($CURLDIR)
 365
 366AC_SUBST(NO_CURL)
 367
 368#
 369# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 370# not built, and you cannot push using http:// and https:// transports.
 371
 372GIT_STASH_FLAGS($EXPATDIR)
 373
 374AC_CHECK_LIB([expat], [XML_ParserCreate],
 375[NO_EXPAT=],
 376[NO_EXPAT=YesPlease])
 377
 378GIT_UNSTASH_FLAGS($EXPATDIR)
 379
 380AC_SUBST(NO_EXPAT)
 381
 382#
 383# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 384# some Solaris installations).
 385# Define NO_ICONV if neither libc nor libiconv support iconv.
 386
 387if test -z "$NO_ICONV"; then
 388
 389GIT_STASH_FLAGS($ICONVDIR)
 390
 391AC_DEFUN([ICONVTEST_SRC], [
 392#include <iconv.h>
 393
 394int main(void)
 395{
 396        iconv_open("", "");
 397        return 0;
 398}
 399])
 400
 401if test -n "$ICONVDIR"; then
 402   lib_order="-liconv -lc"
 403else
 404   lib_order="-lc -liconv"
 405fi
 406
 407NO_ICONV=YesPlease
 408
 409for l in $lib_order; do
 410    if test "$l" = "-liconv"; then
 411       NEEDS_LIBICONV=YesPlease
 412    else
 413       NEEDS_LIBICONV=
 414    fi
 415
 416    old_LIBS="$LIBS"
 417    LIBS="$LIBS $l"
 418    AC_MSG_CHECKING([for iconv in $l])
 419    AC_LINK_IFELSE(ICONVTEST_SRC,
 420        [AC_MSG_RESULT([yes])
 421        NO_ICONV=
 422        break],
 423        [AC_MSG_RESULT([no])])
 424    LIBS="$old_LIBS"
 425done
 426
 427#in case of break
 428LIBS="$old_LIBS"
 429
 430GIT_UNSTASH_FLAGS($ICONVDIR)
 431
 432AC_SUBST(NEEDS_LIBICONV)
 433AC_SUBST(NO_ICONV)
 434
 435if test -n "$NO_ICONV"; then
 436    NEEDS_LIBICONV=
 437fi
 438
 439fi
 440
 441#
 442# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 443
 444GIT_STASH_FLAGS($ZLIB_PATH)
 445
 446AC_DEFUN([ZLIBTEST_SRC], [
 447#include <zlib.h>
 448
 449int main(void)
 450{
 451        deflateBound(0, 0);
 452        return 0;
 453}
 454])
 455AC_MSG_CHECKING([for deflateBound in -lz])
 456old_LIBS="$LIBS"
 457LIBS="$LIBS -lz"
 458AC_LINK_IFELSE(ZLIBTEST_SRC,
 459        [AC_MSG_RESULT([yes])],
 460        [AC_MSG_RESULT([no])
 461        NO_DEFLATE_BOUND=yes])
 462LIBS="$old_LIBS"
 463
 464GIT_UNSTASH_FLAGS($ZLIB_PATH)
 465
 466AC_SUBST(NO_DEFLATE_BOUND)
 467
 468#
 469# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 470# Patrick Mauritz).
 471AC_CHECK_LIB([c], [socket],
 472[NEEDS_SOCKET=],
 473[NEEDS_SOCKET=YesPlease])
 474AC_SUBST(NEEDS_SOCKET)
 475test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 476
 477#
 478# Define NEEDS_RESOLV if linking with -lnsl and/or -lsocket is not enough.
 479# Notably on Solaris hstrerror resides in libresolv and on Solaris 7
 480# inet_ntop and inet_pton additionally reside there.
 481AC_CHECK_LIB([c], [hstrerror],
 482[NEEDS_RESOLV=],
 483[NEEDS_RESOLV=YesPlease])
 484AC_SUBST(NEEDS_RESOLV)
 485test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 486
 487AC_CHECK_LIB([c], [basename],
 488[NEEDS_LIBGEN=],
 489[NEEDS_LIBGEN=YesPlease])
 490AC_SUBST(NEEDS_LIBGEN)
 491test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 492
 493## Checks for header files.
 494AC_MSG_NOTICE([CHECKS for header files])
 495#
 496# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 497AC_CHECK_HEADER([sys/select.h],
 498[NO_SYS_SELECT_H=],
 499[NO_SYS_SELECT_H=UnfortunatelyYes])
 500AC_SUBST(NO_SYS_SELECT_H)
 501#
 502# Define OLD_ICONV if your library has an old iconv(), where the second
 503# (input buffer pointer) parameter is declared with type (const char **).
 504AC_DEFUN([OLDICONVTEST_SRC], [[
 505#include <iconv.h>
 506
 507extern size_t iconv(iconv_t cd,
 508                    char **inbuf, size_t *inbytesleft,
 509                    char **outbuf, size_t *outbytesleft);
 510
 511int main(void)
 512{
 513        return 0;
 514}
 515]])
 516
 517GIT_STASH_FLAGS($ICONVDIR)
 518
 519AC_MSG_CHECKING([for old iconv()])
 520AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 521        [AC_MSG_RESULT([no])],
 522        [AC_MSG_RESULT([yes])
 523        OLD_ICONV=UnfortunatelyYes])
 524
 525GIT_UNSTASH_FLAGS($ICONVDIR)
 526
 527AC_SUBST(OLD_ICONV)
 528
 529## Checks for typedefs, structures, and compiler characteristics.
 530AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 531#
 532# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 533AC_CHECK_MEMBER(struct dirent.d_ino,
 534[NO_D_INO_IN_DIRENT=],
 535[NO_D_INO_IN_DIRENT=YesPlease],
 536[#include <dirent.h>])
 537AC_SUBST(NO_D_INO_IN_DIRENT)
 538#
 539# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 540# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 541AC_CHECK_MEMBER(struct dirent.d_type,
 542[NO_D_TYPE_IN_DIRENT=],
 543[NO_D_TYPE_IN_DIRENT=YesPlease],
 544[#include <dirent.h>])
 545AC_SUBST(NO_D_TYPE_IN_DIRENT)
 546#
 547# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 548# sockaddr_storage.
 549AC_CHECK_TYPE(struct sockaddr_storage,
 550[NO_SOCKADDR_STORAGE=],
 551[NO_SOCKADDR_STORAGE=YesPlease],[
 552#include <sys/types.h>
 553#include <sys/socket.h>
 554])
 555AC_SUBST(NO_SOCKADDR_STORAGE)
 556#
 557# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 558AC_CHECK_TYPE([struct addrinfo],[
 559 GIT_CHECK_FUNC([getaddrinfo],
 560  [NO_IPV6=],
 561  [NO_IPV6=YesPlease])
 562],[NO_IPV6=YesPlease],[
 563#include <sys/types.h>
 564#include <sys/socket.h>
 565#include <netdb.h>
 566])
 567AC_SUBST(NO_IPV6)
 568#
 569# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 570# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 571# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 572# some C compilers supported these specifiers prior to C99 as an extension.
 573AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 574 [ac_cv_c_c99_format],
 575[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 576AC_RUN_IFELSE(
 577        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 578                [[char buf[64];
 579                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 580                  return 1;
 581                else if (strcmp(buf, "12345"))
 582                  return 2;]])],
 583        [ac_cv_c_c99_format=yes],
 584        [ac_cv_c_c99_format=no])
 585])
 586if test $ac_cv_c_c99_format = no; then
 587        NO_C99_FORMAT=YesPlease
 588else
 589        NO_C99_FORMAT=
 590fi
 591AC_SUBST(NO_C99_FORMAT)
 592#
 593# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 594# when attempting to read from an fopen'ed directory.
 595AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 596 [ac_cv_fread_reads_directories],
 597[
 598AC_RUN_IFELSE(
 599        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 600                [[char c;
 601                FILE *f = fopen(".", "r");
 602                return f && fread(&c, 1, 1, f)]])],
 603        [ac_cv_fread_reads_directories=no],
 604        [ac_cv_fread_reads_directories=yes])
 605])
 606if test $ac_cv_fread_reads_directories = yes; then
 607        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 608else
 609        FREAD_READS_DIRECTORIES=
 610fi
 611AC_SUBST(FREAD_READS_DIRECTORIES)
 612#
 613# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 614# or vsnprintf() return -1 instead of number of characters which would
 615# have been written to the final string if enough space had been available.
 616AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 617 [ac_cv_snprintf_returns_bogus],
 618[
 619AC_RUN_IFELSE(
 620        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 621                #include "stdarg.h"
 622
 623                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 624                {
 625                  int ret;
 626                  va_list ap;
 627                  va_start(ap, format);
 628                  ret = vsnprintf(str, maxsize, format, ap);
 629                  va_end(ap);
 630                  return ret;
 631                }],
 632                [[char buf[6];
 633                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 634                      || strcmp(buf, "12")) return 1;
 635                  if (snprintf(buf, 3, "%s", "12345") != 5
 636                      || strcmp(buf, "12")) return 1]])],
 637        [ac_cv_snprintf_returns_bogus=no],
 638        [ac_cv_snprintf_returns_bogus=yes])
 639])
 640if test $ac_cv_snprintf_returns_bogus = yes; then
 641        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 642else
 643        SNPRINTF_RETURNS_BOGUS=
 644fi
 645AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 646
 647
 648## Checks for library functions.
 649## (in default C library and libraries checked by AC_CHECK_LIB)
 650AC_MSG_NOTICE([CHECKS for library functions])
 651#
 652# Define NO_LIBGEN_H if you don't have libgen.h.
 653AC_CHECK_HEADER([libgen.h],
 654[NO_LIBGEN_H=],
 655[NO_LIBGEN_H=YesPlease])
 656AC_SUBST(NO_LIBGEN_H)
 657#
 658# Define NO_STRCASESTR if you don't have strcasestr.
 659GIT_CHECK_FUNC(strcasestr,
 660[NO_STRCASESTR=],
 661[NO_STRCASESTR=YesPlease])
 662AC_SUBST(NO_STRCASESTR)
 663#
 664# Define NO_MEMMEM if you don't have memmem.
 665GIT_CHECK_FUNC(memmem,
 666[NO_MEMMEM=],
 667[NO_MEMMEM=YesPlease])
 668AC_SUBST(NO_MEMMEM)
 669#
 670# Define NO_STRLCPY if you don't have strlcpy.
 671GIT_CHECK_FUNC(strlcpy,
 672[NO_STRLCPY=],
 673[NO_STRLCPY=YesPlease])
 674AC_SUBST(NO_STRLCPY)
 675#
 676# Define NO_UINTMAX_T if your platform does not have uintmax_t
 677AC_CHECK_TYPE(uintmax_t,
 678[NO_UINTMAX_T=],
 679[NO_UINTMAX_T=YesPlease],[
 680#include <inttypes.h>
 681])
 682AC_SUBST(NO_UINTMAX_T)
 683#
 684# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 685GIT_CHECK_FUNC(strtoumax,
 686[NO_STRTOUMAX=],
 687[NO_STRTOUMAX=YesPlease])
 688AC_SUBST(NO_STRTOUMAX)
 689#
 690# Define NO_SETENV if you don't have setenv in the C library.
 691GIT_CHECK_FUNC(setenv,
 692[NO_SETENV=],
 693[NO_SETENV=YesPlease])
 694AC_SUBST(NO_SETENV)
 695#
 696# Define NO_UNSETENV if you don't have unsetenv in the C library.
 697GIT_CHECK_FUNC(unsetenv,
 698[NO_UNSETENV=],
 699[NO_UNSETENV=YesPlease])
 700AC_SUBST(NO_UNSETENV)
 701#
 702# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 703GIT_CHECK_FUNC(mkdtemp,
 704[NO_MKDTEMP=],
 705[NO_MKDTEMP=YesPlease])
 706AC_SUBST(NO_MKDTEMP)
 707#
 708# Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 709GIT_CHECK_FUNC(mkstemps,
 710[NO_MKSTEMPS=],
 711[NO_MKSTEMPS=YesPlease])
 712AC_SUBST(NO_MKSTEMPS)
 713#
 714#
 715# Define NO_MMAP if you want to avoid mmap.
 716#
 717# Define NO_ICONV if your libc does not properly support iconv.
 718
 719
 720## Other checks.
 721# Define USE_PIC if you need the main git objects to be built with -fPIC
 722# in order to build and link perl/Git.so.  x86-64 seems to need this.
 723#
 724# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 725# Enable it on Windows.  By default, symrefs are still used.
 726#
 727# Define NO_PTHREADS if we do not have pthreads
 728#
 729# Define PTHREAD_LIBS to the linker flag used for Pthread support and define
 730# THREADED_DELTA_SEARCH if Pthreads are available.
 731AC_DEFUN([PTHREADTEST_SRC], [
 732#include <pthread.h>
 733
 734int main(void)
 735{
 736        pthread_mutex_t test_mutex;
 737        return (0);
 738}
 739])
 740
 741dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 742dnl   [[#include <pthread.h>]],
 743dnl   [[pthread_mutex_t test_mutex;]]
 744dnl )])
 745
 746NO_PTHREADS=UnfortunatelyYes
 747THREADED_DELTA_SEARCH=
 748PTHREAD_LIBS=
 749
 750if test -n "$USER_NOPTHREAD"; then
 751   AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 752# handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 753# -D_REENTRANT' or some such.
 754elif test -z "$PTHREAD_CFLAGS"; then
 755  for opt in -pthread -lpthread; do
 756     old_CFLAGS="$CFLAGS"
 757     CFLAGS="$opt $CFLAGS"
 758     AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 759     AC_LINK_IFELSE(PTHREADTEST_SRC,
 760        [AC_MSG_RESULT([yes])
 761                NO_PTHREADS=
 762                PTHREAD_LIBS="$opt"
 763                THREADED_DELTA_SEARCH=YesPlease
 764                break
 765        ],
 766        [AC_MSG_RESULT([no])])
 767      CFLAGS="$old_CFLAGS"
 768  done
 769else
 770  old_CFLAGS="$CFLAGS"
 771  CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 772  AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 773  AC_LINK_IFELSE(PTHREADTEST_SRC,
 774        [AC_MSG_RESULT([yes])
 775                NO_PTHREADS=
 776                PTHREAD_LIBS="$PTHREAD_CFLAGS"
 777                THREADED_DELTA_SEARCH=YesPlease
 778        ],
 779        [AC_MSG_RESULT([no])])
 780
 781  CFLAGS="$old_CFLAGS"
 782fi
 783
 784CFLAGS="$old_CFLAGS"
 785
 786AC_SUBST(PTHREAD_LIBS)
 787AC_SUBST(NO_PTHREADS)
 788AC_SUBST(THREADED_DELTA_SEARCH)
 789
 790## Output files
 791AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 792AC_OUTPUT
 793
 794
 795## Cleanup
 796rm -f "${config_append}"