1#!/bin/sh
2# Tcl ignores the next line -*- tcl -*- \
3exec wish "$0" -- "$@"
4set copyright {
6Copyright © 2006 Shawn Pearce, Paul Mackerras.
7All rights reserved.
9This program is free software; it may be used, copied, modified
11and distributed under the terms of the GNU General Public Licence,
12either version 2, or (at your option) any later version.}
13set appname [lindex [file split $argv0] end]
15set gitdir {}
16######################################################################
18##
19## config
20proc is_many_config {name} {
22 switch -glob -- $name {
23 remote.*.fetch -
24 remote.*.push
25 {return 1}
26 *
27 {return 0}
28 }
29}
30proc load_config {include_global} {
32 global repo_config global_config default_config
33 array unset global_config
35 if {$include_global} {
36 catch {
37 set fd_rc [open "| git repo-config --global --list" r]
38 while {[gets $fd_rc line] >= 0} {
39 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
40 if {[is_many_config $name]} {
41 lappend global_config($name) $value
42 } else {
43 set global_config($name) $value
44 }
45 }
46 }
47 close $fd_rc
48 }
49 }
50 array unset repo_config
52 catch {
53 set fd_rc [open "| git repo-config --list" r]
54 while {[gets $fd_rc line] >= 0} {
55 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
56 if {[is_many_config $name]} {
57 lappend repo_config($name) $value
58 } else {
59 set repo_config($name) $value
60 }
61 }
62 }
63 close $fd_rc
64 }
65 foreach name [array names default_config] {
67 if {[catch {set v $global_config($name)}]} {
68 set global_config($name) $default_config($name)
69 }
70 if {[catch {set v $repo_config($name)}]} {
71 set repo_config($name) $default_config($name)
72 }
73 }
74}
75proc save_config {} {
77 global default_config font_descs
78 global repo_config global_config
79 global repo_config_new global_config_new
80 foreach option $font_descs {
82 set name [lindex $option 0]
83 set font [lindex $option 1]
84 font configure $font \
85 -family $global_config_new(gui.$font^^family) \
86 -size $global_config_new(gui.$font^^size)
87 font configure ${font}bold \
88 -family $global_config_new(gui.$font^^family) \
89 -size $global_config_new(gui.$font^^size)
90 set global_config_new(gui.$name) [font configure $font]
91 unset global_config_new(gui.$font^^family)
92 unset global_config_new(gui.$font^^size)
93 }
94 foreach name [array names default_config] {
96 set value $global_config_new($name)
97 if {$value ne $global_config($name)} {
98 if {$value eq $default_config($name)} {
99 catch {exec git repo-config --global --unset $name}
100 } else {
101 regsub -all "\[{}\]" $value {"} value
102 exec git repo-config --global $name $value
103 }
104 set global_config($name) $value
105 if {$value eq $repo_config($name)} {
106 catch {exec git repo-config --unset $name}
107 set repo_config($name) $value
108 }
109 }
110 }
111 foreach name [array names default_config] {
113 set value $repo_config_new($name)
114 if {$value ne $repo_config($name)} {
115 if {$value eq $global_config($name)} {
116 catch {exec git repo-config --unset $name}
117 } else {
118 regsub -all "\[{}\]" $value {"} value
119 exec git repo-config $name $value
120 }
121 set repo_config($name) $value
122 }
123 }
124}
125proc error_popup {msg} {
127 global gitdir appname
128 set title $appname
130 if {$gitdir ne {}} {
131 append title { (}
132 append title [lindex \
133 [file split [file normalize [file dirname $gitdir]]] \
134 end]
135 append title {)}
136 }
137 set cmd [list tk_messageBox \
138 -icon error \
139 -type ok \
140 -title "$title: error" \
141 -message $msg]
142 if {[winfo ismapped .]} {
143 lappend cmd -parent .
144 }
145 eval $cmd
146}
147proc warn_popup {msg} {
149 global gitdir appname
150 set title $appname
152 if {$gitdir ne {}} {
153 append title { (}
154 append title [lindex \
155 [file split [file normalize [file dirname $gitdir]]] \
156 end]
157 append title {)}
158 }
159 set cmd [list tk_messageBox \
160 -icon warning \
161 -type ok \
162 -title "$title: warning" \
163 -message $msg]
164 if {[winfo ismapped .]} {
165 lappend cmd -parent .
166 }
167 eval $cmd
168}
169proc info_popup {msg} {
171 global gitdir appname
172 set title $appname
174 if {$gitdir ne {}} {
175 append title { (}
176 append title [lindex \
177 [file split [file normalize [file dirname $gitdir]]] \
178 end]
179 append title {)}
180 }
181 tk_messageBox \
182 -parent . \
183 -icon info \
184 -type ok \
185 -title $title \
186 -message $msg
187}
188######################################################################
190##
191## repository setup
192if { [catch {set gitdir $env(GIT_DIR)}]
194 && [catch {set gitdir [exec git rev-parse --git-dir]} err]} {
195 catch {wm withdraw .}
196 error_popup "Cannot find the git directory:\n\n$err"
197 exit 1
198}
199if {![file isdirectory $gitdir]} {
200 catch {wm withdraw .}
201 error_popup "Git directory not found:\n\n$gitdir"
202 exit 1
203}
204if {[lindex [file split $gitdir] end] ne {.git}} {
205 catch {wm withdraw .}
206 error_popup "Cannot use funny .git directory:\n\n$gitdir"
207 exit 1
208}
209if {[catch {cd [file dirname $gitdir]} err]} {
210 catch {wm withdraw .}
211 error_popup "No working directory [file dirname $gitdir]:\n\n$err"
212 exit 1
213}
214set single_commit 0
216if {$appname eq {git-citool}} {
217 set single_commit 1
218}
219######################################################################
221##
222## task management
223set rescan_active 0
225set diff_active 0
226set last_clicked {}
227set disable_on_lock [list]
229set index_lock_type none
230proc lock_index {type} {
232 global index_lock_type disable_on_lock
233 if {$index_lock_type eq {none}} {
235 set index_lock_type $type
236 foreach w $disable_on_lock {
237 uplevel #0 $w disabled
238 }
239 return 1
240 } elseif {$index_lock_type eq "begin-$type"} {
241 set index_lock_type $type
242 return 1
243 }
244 return 0
245}
246proc unlock_index {} {
248 global index_lock_type disable_on_lock
249 set index_lock_type none
251 foreach w $disable_on_lock {
252 uplevel #0 $w normal
253 }
254}
255######################################################################
257##
258## status
259proc repository_state {ctvar hdvar mhvar} {
261 global gitdir current_branch
262 upvar $ctvar ct $hdvar hd $mhvar mh
263 set mh [list]
265 if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
267 set current_branch {}
268 } else {
269 regsub ^refs/((heads|tags|remotes)/)? \
270 $current_branch \
271 {} \
272 current_branch
273 }
274 if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
276 set hd {}
277 set ct initial
278 return
279 }
280 set merge_head [file join $gitdir MERGE_HEAD]
282 if {[file exists $merge_head]} {
283 set ct merge
284 set fd_mh [open $merge_head r]
285 while {[gets $fd_mh line] >= 0} {
286 lappend mh $line
287 }
288 close $fd_mh
289 return
290 }
291 set ct normal
293}
294proc PARENT {} {
296 global PARENT empty_tree
297 set p [lindex $PARENT 0]
299 if {$p ne {}} {
300 return $p
301 }
302 if {$empty_tree eq {}} {
303 set empty_tree [exec git mktree << {}]
304 }
305 return $empty_tree
306}
307proc rescan {after} {
309 global HEAD PARENT MERGE_HEAD commit_type
310 global ui_index ui_other ui_status_value ui_comm
311 global rescan_active file_states
312 global repo_config
313 if {$rescan_active > 0 || ![lock_index read]} return
315 repository_state newType newHEAD newMERGE_HEAD
317 if {[string match amend* $commit_type]
318 && $newType eq {normal}
319 && $newHEAD eq $HEAD} {
320 } else {
321 set HEAD $newHEAD
322 set PARENT $newHEAD
323 set MERGE_HEAD $newMERGE_HEAD
324 set commit_type $newType
325 }
326 array unset file_states
328 if {![$ui_comm edit modified]
330 || [string trim [$ui_comm get 0.0 end]] eq {}} {
331 if {[load_message GITGUI_MSG]} {
332 } elseif {[load_message MERGE_MSG]} {
333 } elseif {[load_message SQUASH_MSG]} {
334 }
335 $ui_comm edit reset
336 $ui_comm edit modified false
337 }
338 if {$repo_config(gui.trustmtime) eq {true}} {
340 rescan_stage2 {} $after
341 } else {
342 set rescan_active 1
343 set ui_status_value {Refreshing file status...}
344 set cmd [list git update-index]
345 lappend cmd -q
346 lappend cmd --unmerged
347 lappend cmd --ignore-missing
348 lappend cmd --refresh
349 set fd_rf [open "| $cmd" r]
350 fconfigure $fd_rf -blocking 0 -translation binary
351 fileevent $fd_rf readable \
352 [list rescan_stage2 $fd_rf $after]
353 }
354}
355proc rescan_stage2 {fd after} {
357 global gitdir ui_status_value
358 global rescan_active buf_rdi buf_rdf buf_rlo
359 if {$fd ne {}} {
361 read $fd
362 if {![eof $fd]} return
363 close $fd
364 }
365 set ls_others [list | git ls-files --others -z \
367 --exclude-per-directory=.gitignore]
368 set info_exclude [file join $gitdir info exclude]
369 if {[file readable $info_exclude]} {
370 lappend ls_others "--exclude-from=$info_exclude"
371 }
372 set buf_rdi {}
374 set buf_rdf {}
375 set buf_rlo {}
376 set rescan_active 3
378 set ui_status_value {Scanning for modified files ...}
379 set fd_di [open "| git diff-index --cached -z [PARENT]" r]
380 set fd_df [open "| git diff-files -z" r]
381 set fd_lo [open $ls_others r]
382 fconfigure $fd_di -blocking 0 -translation binary
384 fconfigure $fd_df -blocking 0 -translation binary
385 fconfigure $fd_lo -blocking 0 -translation binary
386 fileevent $fd_di readable [list read_diff_index $fd_di $after]
387 fileevent $fd_df readable [list read_diff_files $fd_df $after]
388 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
389}
390proc load_message {file} {
392 global gitdir ui_comm
393 set f [file join $gitdir $file]
395 if {[file isfile $f]} {
396 if {[catch {set fd [open $f r]}]} {
397 return 0
398 }
399 set content [string trim [read $fd]]
400 close $fd
401 $ui_comm delete 0.0 end
402 $ui_comm insert end $content
403 return 1
404 }
405 return 0
406}
407proc read_diff_index {fd after} {
409 global buf_rdi
410 append buf_rdi [read $fd]
412 set c 0
413 set n [string length $buf_rdi]
414 while {$c < $n} {
415 set z1 [string first "\0" $buf_rdi $c]
416 if {$z1 == -1} break
417 incr z1
418 set z2 [string first "\0" $buf_rdi $z1]
419 if {$z2 == -1} break
420 incr c
422 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
423 merge_state \
424 [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
425 [lindex $i 4]? \
426 [list [lindex $i 0] [lindex $i 2]] \
427 [list]
428 set c $z2
429 incr c
430 }
431 if {$c < $n} {
432 set buf_rdi [string range $buf_rdi $c end]
433 } else {
434 set buf_rdi {}
435 }
436 rescan_done $fd buf_rdi $after
438}
439proc read_diff_files {fd after} {
441 global buf_rdf
442 append buf_rdf [read $fd]
444 set c 0
445 set n [string length $buf_rdf]
446 while {$c < $n} {
447 set z1 [string first "\0" $buf_rdf $c]
448 if {$z1 == -1} break
449 incr z1
450 set z2 [string first "\0" $buf_rdf $z1]
451 if {$z2 == -1} break
452 incr c
454 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
455 merge_state \
456 [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
457 ?[lindex $i 4] \
458 [list] \
459 [list [lindex $i 0] [lindex $i 2]]
460 set c $z2
461 incr c
462 }
463 if {$c < $n} {
464 set buf_rdf [string range $buf_rdf $c end]
465 } else {
466 set buf_rdf {}
467 }
468 rescan_done $fd buf_rdf $after
470}
471proc read_ls_others {fd after} {
473 global buf_rlo
474 append buf_rlo [read $fd]
476 set pck [split $buf_rlo "\0"]
477 set buf_rlo [lindex $pck end]
478 foreach p [lrange $pck 0 end-1] {
479 merge_state $p ?O
480 }
481 rescan_done $fd buf_rlo $after
482}
483proc rescan_done {fd buf after} {
485 global rescan_active
486 global file_states repo_config
487 upvar $buf to_clear
488 if {![eof $fd]} return
490 set to_clear {}
491 close $fd
492 if {[incr rescan_active -1] > 0} return
493 prune_selection
495 unlock_index
496 display_all_files
497 if {$repo_config(gui.partialinclude) ne {true}} {
499 set pathList [list]
500 foreach path [array names file_states] {
501 switch -- [lindex $file_states($path) 0] {
502 A? -
503 M? {lappend pathList $path}
504 }
505 }
506 if {$pathList ne {}} {
507 update_index \
508 "Updating included files" \
509 $pathList \
510 [concat {reshow_diff;} $after]
511 return
512 }
513 }
514 reshow_diff
516 uplevel #0 $after
517}
518proc prune_selection {} {
520 global file_states selected_paths
521 foreach path [array names selected_paths] {
523 if {[catch {set still_here $file_states($path)}]} {
524 unset selected_paths($path)
525 }
526 }
527}
528######################################################################
530##
531## diff
532proc clear_diff {} {
534 global ui_diff current_diff ui_index ui_other
535 $ui_diff conf -state normal
537 $ui_diff delete 0.0 end
538 $ui_diff conf -state disabled
539 set current_diff {}
541 $ui_index tag remove in_diff 0.0 end
543 $ui_other tag remove in_diff 0.0 end
544}
545proc reshow_diff {} {
547 global current_diff ui_status_value file_states
548 if {$current_diff eq {}
550 || [catch {set s $file_states($current_diff)}]} {
551 clear_diff
552 } else {
553 show_diff $current_diff
554 }
555}
556proc handle_empty_diff {} {
558 global current_diff file_states file_lists
559 set path $current_diff
561 set s $file_states($path)
562 if {[lindex $s 0] ne {_M}} return
563 info_popup "No differences detected.
565[short_path $path] has no changes.
567The modification date of this file was updated
569by another application and you currently have
570the Trust File Modification Timestamps option
571enabled, so Git did not automatically detect
572that there are no content differences in this
573file.
574This file will now be removed from the modified
576files list, to prevent possible confusion.
577"
578 if {[catch {exec git update-index -- $path} err]} {
579 error_popup "Failed to refresh index:\n\n$err"
580 }
581 clear_diff
583 set old_w [mapcol [lindex $file_states($path) 0] $path]
584 set lno [lsearch -sorted $file_lists($old_w) $path]
585 if {$lno >= 0} {
586 set file_lists($old_w) \
587 [lreplace $file_lists($old_w) $lno $lno]
588 incr lno
589 $old_w conf -state normal
590 $old_w delete $lno.0 [expr {$lno + 1}].0
591 $old_w conf -state disabled
592 }
593}
594proc show_diff {path {w {}} {lno {}}} {
596 global file_states file_lists
597 global is_3way_diff diff_active repo_config
598 global ui_diff current_diff ui_status_value
599 if {$diff_active || ![lock_index read]} return
601 clear_diff
603 if {$w eq {} || $lno == {}} {
604 foreach w [array names file_lists] {
605 set lno [lsearch -sorted $file_lists($w) $path]
606 if {$lno >= 0} {
607 incr lno
608 break
609 }
610 }
611 }
612 if {$w ne {} && $lno >= 1} {
613 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
614 }
615 set s $file_states($path)
617 set m [lindex $s 0]
618 set is_3way_diff 0
619 set diff_active 1
620 set current_diff $path
621 set ui_status_value "Loading diff of [escape_path $path]..."
622 set cmd [list | git diff-index]
624 lappend cmd --no-color
625 if {$repo_config(gui.diffcontext) > 0} {
626 lappend cmd "-U$repo_config(gui.diffcontext)"
627 }
628 lappend cmd -p
629 switch $m {
631 MM {
632 lappend cmd -c
633 }
634 _O {
635 if {[catch {
636 set fd [open $path r]
637 set content [read $fd]
638 close $fd
639 } err ]} {
640 set diff_active 0
641 unlock_index
642 set ui_status_value "Unable to display [escape_path $path]"
643 error_popup "Error loading file:\n\n$err"
644 return
645 }
646 $ui_diff conf -state normal
647 $ui_diff insert end $content
648 $ui_diff conf -state disabled
649 set diff_active 0
650 unlock_index
651 set ui_status_value {Ready.}
652 return
653 }
654 }
655 lappend cmd [PARENT]
657 lappend cmd --
658 lappend cmd $path
659 if {[catch {set fd [open $cmd r]} err]} {
661 set diff_active 0
662 unlock_index
663 set ui_status_value "Unable to display [escape_path $path]"
664 error_popup "Error loading diff:\n\n$err"
665 return
666 }
667 fconfigure $fd -blocking 0 -translation auto
669 fileevent $fd readable [list read_diff $fd]
670}
671proc read_diff {fd} {
673 global ui_diff ui_status_value is_3way_diff diff_active
674 global repo_config
675 $ui_diff conf -state normal
677 while {[gets $fd line] >= 0} {
678 # -- Cleanup uninteresting diff header lines.
679 #
680 if {[string match {diff --git *} $line]} continue
681 if {[string match {diff --combined *} $line]} continue
682 if {[string match {--- *} $line]} continue
683 if {[string match {+++ *} $line]} continue
684 if {$line eq {deleted file mode 120000}} {
685 set line "deleted symlink"
686 }
687 # -- Automatically detect if this is a 3 way diff.
689 #
690 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
691 # -- Reformat a 3 way diff, 'cause its too weird.
693 #
694 if {$is_3way_diff} {
695 set op [string range $line 0 1]
696 switch -- $op {
697 {@@} {set tags d_@}
698 {++} {set tags d_+ ; set op { +}}
699 {--} {set tags d_- ; set op { -}}
700 { +} {set tags d_++; set op {++}}
701 { -} {set tags d_--; set op {--}}
702 {+ } {set tags d_-+; set op {-+}}
703 {- } {set tags d_+-; set op {+-}}
704 default {set tags {}}
705 }
706 set line [string replace $line 0 1 $op]
707 } else {
708 switch -- [string index $line 0] {
709 @ {set tags d_@}
710 + {set tags d_+}
711 - {set tags d_-}
712 default {set tags {}}
713 }
714 }
715 $ui_diff insert end $line $tags
716 $ui_diff insert end "\n" $tags
717 }
718 $ui_diff conf -state disabled
719 if {[eof $fd]} {
721 close $fd
722 set diff_active 0
723 unlock_index
724 set ui_status_value {Ready.}
725 if {$repo_config(gui.trustmtime) eq {true}
727 && [$ui_diff index end] eq {2.0}} {
728 handle_empty_diff
729 }
730 }
731}
732######################################################################
734##
735## commit
736proc load_last_commit {} {
738 global HEAD PARENT MERGE_HEAD commit_type ui_comm
739 if {[llength $PARENT] == 0} {
741 error_popup {There is nothing to amend.
742You are about to create the initial commit.
744There is no commit before this to amend.
745}
746 return
747 }
748 repository_state curType curHEAD curMERGE_HEAD
750 if {$curType eq {merge}} {
751 error_popup {Cannot amend while merging.
752You are currently in the middle of a merge that
754has not been fully completed. You cannot amend
755the prior commit unless you first abort the
756current merge activity.
757}
758 return
759 }
760 set msg {}
762 set parents [list]
763 if {[catch {
764 set fd [open "| git cat-file commit $curHEAD" r]
765 while {[gets $fd line] > 0} {
766 if {[string match {parent *} $line]} {
767 lappend parents [string range $line 7 end]
768 }
769 }
770 set msg [string trim [read $fd]]
771 close $fd
772 } err]} {
773 error_popup "Error loading commit data for amend:\n\n$err"
774 return
775 }
776 set HEAD $curHEAD
778 set PARENT $parents
779 set MERGE_HEAD [list]
780 switch -- [llength $parents] {
781 0 {set commit_type amend-initial}
782 1 {set commit_type amend}
783 default {set commit_type amend-merge}
784 }
785 $ui_comm delete 0.0 end
787 $ui_comm insert end $msg
788 $ui_comm edit reset
789 $ui_comm edit modified false
790 rescan {set ui_status_value {Ready.}}
791}
792proc create_new_commit {} {
794 global commit_type ui_comm
795 set commit_type normal
797 $ui_comm delete 0.0 end
798 $ui_comm edit reset
799 $ui_comm edit modified false
800 rescan {set ui_status_value {Ready.}}
801}
802set GIT_COMMITTER_IDENT {}
804proc committer_ident {} {
806 global GIT_COMMITTER_IDENT
807 if {$GIT_COMMITTER_IDENT eq {}} {
809 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
810 error_popup "Unable to obtain your identity:\n\n$err"
811 return {}
812 }
813 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
814 $me me GIT_COMMITTER_IDENT]} {
815 error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
816 return {}
817 }
818 }
819 return $GIT_COMMITTER_IDENT
821}
822proc commit_tree {} {
824 global HEAD commit_type file_states ui_comm repo_config
825 if {![lock_index update]} return
827 if {[committer_ident] eq {}} return
828 # -- Our in memory state should match the repository.
830 #
831 repository_state curType curHEAD curMERGE_HEAD
832 if {[string match amend* $commit_type]
833 && $curType eq {normal}
834 && $curHEAD eq $HEAD} {
835 } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
836 info_popup {Last scanned state does not match repository state.
837Another Git program has modified this repository
839since the last scan. A rescan must be performed
840before another commit can be created.
841The rescan will be automatically started now.
843}
844 unlock_index
845 rescan {set ui_status_value {Ready.}}
846 return
847 }
848 # -- At least one file should differ in the index.
850 #
851 set files_ready 0
852 foreach path [array names file_states] {
853 switch -glob -- [lindex $file_states($path) 0] {
854 _? {continue}
855 A? -
856 D? -
857 M? {set files_ready 1; break}
858 U? {
859 error_popup "Unmerged files cannot be committed.
860File [short_path $path] has merge conflicts.
862You must resolve them and include the file before committing.
863"
864 unlock_index
865 return
866 }
867 default {
868 error_popup "Unknown file state [lindex $s 0] detected.
869File [short_path $path] cannot be committed by this program.
871"
872 }
873 }
874 }
875 if {!$files_ready} {
876 error_popup {No included files to commit.
877You must include at least 1 file before you can commit.
879}
880 unlock_index
881 return
882 }
883 # -- A message is required.
885 #
886 set msg [string trim [$ui_comm get 1.0 end]]
887 if {$msg eq {}} {
888 error_popup {Please supply a commit message.
889A good commit message has the following format:
891- First line: Describe in one sentance what you did.
893- Second line: Blank
894- Remaining lines: Describe why this change is good.
895}
896 unlock_index
897 return
898 }
899 # -- Update included files if partialincludes are off.
901 #
902 if {$repo_config(gui.partialinclude) ne {true}} {
903 set pathList [list]
904 foreach path [array names file_states] {
905 switch -glob -- [lindex $file_states($path) 0] {
906 A? -
907 M? {lappend pathList $path}
908 }
909 }
910 if {$pathList ne {}} {
911 unlock_index
912 update_index \
913 "Updating included files" \
914 $pathList \
915 [concat {lock_index update;} \
916 [list commit_prehook $curHEAD $msg]]
917 return
918 }
919 }
920 commit_prehook $curHEAD $msg
922}
923proc commit_prehook {curHEAD msg} {
925 global gitdir ui_status_value pch_error
926 set pchook [file join $gitdir hooks pre-commit]
928 # On Cygwin [file executable] might lie so we need to ask
930 # the shell if the hook is executable. Yes that's annoying.
931 #
932 if {[is_Windows] && [file isfile $pchook]} {
933 set pchook [list sh -c [concat \
934 "if test -x \"$pchook\";" \
935 "then exec \"$pchook\" 2>&1;" \
936 "fi"]]
937 } elseif {[file executable $pchook]} {
938 set pchook [list $pchook |& cat]
939 } else {
940 commit_writetree $curHEAD $msg
941 return
942 }
943 set ui_status_value {Calling pre-commit hook...}
945 set pch_error {}
946 set fd_ph [open "| $pchook" r]
947 fconfigure $fd_ph -blocking 0 -translation binary
948 fileevent $fd_ph readable \
949 [list commit_prehook_wait $fd_ph $curHEAD $msg]
950}
951proc commit_prehook_wait {fd_ph curHEAD msg} {
953 global pch_error ui_status_value
954 append pch_error [read $fd_ph]
956 fconfigure $fd_ph -blocking 1
957 if {[eof $fd_ph]} {
958 if {[catch {close $fd_ph}]} {
959 set ui_status_value {Commit declined by pre-commit hook.}
960 hook_failed_popup pre-commit $pch_error
961 unlock_index
962 } else {
963 commit_writetree $curHEAD $msg
964 }
965 set pch_error {}
966 return
967 }
968 fconfigure $fd_ph -blocking 0
969}
970proc commit_writetree {curHEAD msg} {
972 global ui_status_value
973 set ui_status_value {Committing changes...}
975 set fd_wt [open "| git write-tree" r]
976 fileevent $fd_wt readable \
977 [list commit_committree $fd_wt $curHEAD $msg]
978}
979proc commit_committree {fd_wt curHEAD msg} {
981 global HEAD PARENT MERGE_HEAD commit_type
982 global single_commit gitdir
983 global ui_status_value ui_comm selected_commit_type
984 global file_states selected_paths rescan_active
985 gets $fd_wt tree_id
987 if {$tree_id eq {} || [catch {close $fd_wt} err]} {
988 error_popup "write-tree failed:\n\n$err"
989 set ui_status_value {Commit failed.}
990 unlock_index
991 return
992 }
993 # -- Create the commit.
995 #
996 set cmd [list git commit-tree $tree_id]
997 set parents [concat $PARENT $MERGE_HEAD]
998 if {[llength $parents] > 0} {
999 foreach p $parents {
1000 lappend cmd -p $p
1001 }
1002 } else {
1003 # git commit-tree writes to stderr during initial commit.
1004 lappend cmd 2>/dev/null
1005 }
1006 lappend cmd << $msg
1007 if {[catch {set cmt_id [eval exec $cmd]} err]} {
1008 error_popup "commit-tree failed:\n\n$err"
1009 set ui_status_value {Commit failed.}
1010 unlock_index
1011 return
1012 }
1013 # -- Update the HEAD ref.
1015 #
1016 set reflogm commit
1017 if {$commit_type ne {normal}} {
1018 append reflogm " ($commit_type)"
1019 }
1020 set i [string first "\n" $msg]
1021 if {$i >= 0} {
1022 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1023 } else {
1024 append reflogm {: } $msg
1025 }
1026 set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1027 if {[catch {eval exec $cmd} err]} {
1028 error_popup "update-ref failed:\n\n$err"
1029 set ui_status_value {Commit failed.}
1030 unlock_index
1031 return
1032 }
1033 # -- Cleanup after ourselves.
1035 #
1036 catch {file delete [file join $gitdir MERGE_HEAD]}
1037 catch {file delete [file join $gitdir MERGE_MSG]}
1038 catch {file delete [file join $gitdir SQUASH_MSG]}
1039 catch {file delete [file join $gitdir GITGUI_MSG]}
1040 # -- Let rerere do its thing.
1042 #
1043 if {[file isdirectory [file join $gitdir rr-cache]]} {
1044 catch {exec git rerere}
1045 }
1046 # -- Run the post-commit hook.
1048 #
1049 set pchook [file join $gitdir hooks post-commit]
1050 if {[is_Windows] && [file isfile $pchook]} {
1051 set pchook [list sh -c [concat \
1052 "if test -x \"$pchook\";" \
1053 "then exec \"$pchook\";" \
1054 "fi"]]
1055 } elseif {![file executable $pchook]} {
1056 set pchook {}
1057 }
1058 if {$pchook ne {}} {
1059 catch {exec $pchook &}
1060 }
1061 $ui_comm delete 0.0 end
1063 $ui_comm edit reset
1064 $ui_comm edit modified false
1065 if {$single_commit} do_quit
1067 # -- Update in memory status
1069 #
1070 set selected_commit_type new
1071 set commit_type normal
1072 set HEAD $cmt_id
1073 set PARENT $cmt_id
1074 set MERGE_HEAD [list]
1075 foreach path [array names file_states] {
1077 set s $file_states($path)
1078 set m [lindex $s 0]
1079 switch -glob -- $m {
1080 _O -
1081 _M -
1082 _D {continue}
1083 __ -
1084 A_ -
1085 M_ -
1086 DD {
1087 unset file_states($path)
1088 catch {unset selected_paths($path)}
1089 }
1090 DO {
1091 set file_states($path) [list _O [lindex $s 1] {} {}]
1092 }
1093 AM -
1094 AD -
1095 MM -
1096 MD -
1097 DM {
1098 set file_states($path) [list \
1099 _[string index $m 1] \
1100 [lindex $s 1] \
1101 [lindex $s 3] \
1102 {}]
1103 }
1104 }
1105 }
1106 display_all_files
1108 unlock_index
1109 reshow_diff
1110 set ui_status_value \
1111 "Changes committed as [string range $cmt_id 0 7]."
1112}
1113######################################################################
1115##
1116## fetch pull push
1117proc fetch_from {remote} {
1119 set w [new_console "fetch $remote" \
1120 "Fetching new changes from $remote"]
1121 set cmd [list git fetch]
1122 lappend cmd $remote
1123 console_exec $w $cmd
1124}
1125proc pull_remote {remote branch} {
1127 global HEAD commit_type file_states repo_config
1128 if {![lock_index update]} return
1130 # -- Our in memory state should match the repository.
1132 #
1133 repository_state curType curHEAD curMERGE_HEAD
1134 if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1135 info_popup {Last scanned state does not match repository state.
1136Another Git program has modified this repository
1138since the last scan. A rescan must be performed
1139before a pull operation can be started.
1140The rescan will be automatically started now.
1142}
1143 unlock_index
1144 rescan {set ui_status_value {Ready.}}
1145 return
1146 }
1147 # -- No differences should exist before a pull.
1149 #
1150 if {[array size file_states] != 0} {
1151 error_popup {Uncommitted but modified files are present.
1152You should not perform a pull with unmodified
1154files in your working directory as Git will be
1155unable to recover from an incorrect merge.
1156You should commit or revert all changes before
1158starting a pull operation.
1159}
1160 unlock_index
1161 return
1162 }
1163 set w [new_console "pull $remote $branch" \
1165 "Pulling new changes from branch $branch in $remote"]
1166 set cmd [list git pull]
1167 if {$repo_config(gui.pullsummary) eq {false}} {
1168 lappend cmd --no-summary
1169 }
1170 lappend cmd $remote
1171 lappend cmd $branch
1172 console_exec $w $cmd [list post_pull_remote $remote $branch]
1173}
1174proc post_pull_remote {remote branch success} {
1176 global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1177 global ui_status_value
1178 unlock_index
1180 if {$success} {
1181 repository_state commit_type HEAD MERGE_HEAD
1182 set PARENT $HEAD
1183 set selected_commit_type new
1184 set ui_status_value "Pulling $branch from $remote complete."
1185 } else {
1186 rescan [list set ui_status_value \
1187 "Conflicts detected while pulling $branch from $remote."]
1188 }
1189}
1190proc push_to {remote} {
1192 set w [new_console "push $remote" \
1193 "Pushing changes to $remote"]
1194 set cmd [list git push]
1195 lappend cmd $remote
1196 console_exec $w $cmd
1197}
1198######################################################################
1200##
1201## ui helpers
1202proc mapcol {state path} {
1204 global all_cols ui_other
1205 if {[catch {set r $all_cols($state)}]} {
1207 puts "error: no column for state={$state} $path"
1208 return $ui_other
1209 }
1210 return $r
1211}
1212proc mapicon {state path} {
1214 global all_icons
1215 if {[catch {set r $all_icons($state)}]} {
1217 puts "error: no icon for state={$state} $path"
1218 return file_plain
1219 }
1220 return $r
1221}
1222proc mapdesc {state path} {
1224 global all_descs
1225 if {[catch {set r $all_descs($state)}]} {
1227 puts "error: no desc for state={$state} $path"
1228 return $state
1229 }
1230 return $r
1231}
1232proc escape_path {path} {
1234 regsub -all "\n" $path "\\n" path
1235 return $path
1236}
1237proc short_path {path} {
1239 return [escape_path [lindex [file split $path] end]]
1240}
1241set next_icon_id 0
1243set null_sha1 [string repeat 0 40]
1244proc merge_state {path new_state {head_info {}} {index_info {}}} {
1246 global file_states next_icon_id null_sha1
1247 set s0 [string index $new_state 0]
1249 set s1 [string index $new_state 1]
1250 if {[catch {set info $file_states($path)}]} {
1252 set state __
1253 set icon n[incr next_icon_id]
1254 } else {
1255 set state [lindex $info 0]
1256 set icon [lindex $info 1]
1257 if {$head_info eq {}} {set head_info [lindex $info 2]}
1258 if {$index_info eq {}} {set index_info [lindex $info 3]}
1259 }
1260 if {$s0 eq {?}} {set s0 [string index $state 0]} \
1262 elseif {$s0 eq {_}} {set s0 _}
1263 if {$s1 eq {?}} {set s1 [string index $state 1]} \
1265 elseif {$s1 eq {_}} {set s1 _}
1266 if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1268 set head_info [list 0 $null_sha1]
1269 } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1270 && $head_info eq {}} {
1271 set head_info $index_info
1272 }
1273 set file_states($path) [list $s0$s1 $icon \
1275 $head_info $index_info \
1276 ]
1277 return $state
1278}
1279proc display_file {path state} {
1281 global file_states file_lists selected_paths
1282 set old_m [merge_state $path $state]
1284 set s $file_states($path)
1285 set new_m [lindex $s 0]
1286 set new_w [mapcol $new_m $path]
1287 set old_w [mapcol $old_m $path]
1288 set new_icon [mapicon $new_m $path]
1289 if {$new_m eq {__}} {
1291 set lno [lsearch -sorted $file_lists($old_w) $path]
1292 if {$lno >= 0} {
1293 set file_lists($old_w) \
1294 [lreplace $file_lists($old_w) $lno $lno]
1295 incr lno
1296 $old_w conf -state normal
1297 $old_w delete $lno.0 [expr {$lno + 1}].0
1298 $old_w conf -state disabled
1299 }
1300 unset file_states($path)
1301 catch {unset selected_paths($path)}
1302 return
1303 }
1304 if {$new_w ne $old_w} {
1306 set lno [lsearch -sorted $file_lists($old_w) $path]
1307 if {$lno >= 0} {
1308 set file_lists($old_w) \
1309 [lreplace $file_lists($old_w) $lno $lno]
1310 incr lno
1311 $old_w conf -state normal
1312 $old_w delete $lno.0 [expr {$lno + 1}].0
1313 $old_w conf -state disabled
1314 }
1315 lappend file_lists($new_w) $path
1317 set file_lists($new_w) [lsort $file_lists($new_w)]
1318 set lno [lsearch -sorted $file_lists($new_w) $path]
1319 incr lno
1320 $new_w conf -state normal
1321 $new_w image create $lno.0 \
1322 -align center -padx 5 -pady 1 \
1323 -name [lindex $s 1] \
1324 -image $new_icon
1325 $new_w insert $lno.1 "[escape_path $path]\n"
1326 if {[catch {set in_sel $selected_paths($path)}]} {
1327 set in_sel 0
1328 }
1329 if {$in_sel} {
1330 $new_w tag add in_sel $lno.0 [expr {$lno + 1}].0
1331 }
1332 $new_w conf -state disabled
1333 } elseif {$new_icon ne [mapicon $old_m $path]} {
1334 $new_w conf -state normal
1335 $new_w image conf [lindex $s 1] -image $new_icon
1336 $new_w conf -state disabled
1337 }
1338}
1339proc display_all_files {} {
1341 global ui_index ui_other
1342 global file_states file_lists
1343 global last_clicked selected_paths
1344 $ui_index conf -state normal
1346 $ui_other conf -state normal
1347 $ui_index delete 0.0 end
1349 $ui_other delete 0.0 end
1350 set last_clicked {}
1351 set file_lists($ui_index) [list]
1353 set file_lists($ui_other) [list]
1354 foreach path [lsort [array names file_states]] {
1356 set s $file_states($path)
1357 set m [lindex $s 0]
1358 set w [mapcol $m $path]
1359 lappend file_lists($w) $path
1360 set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1361 $w image create end \
1362 -align center -padx 5 -pady 1 \
1363 -name [lindex $s 1] \
1364 -image [mapicon $m $path]
1365 $w insert end "[escape_path $path]\n"
1366 if {[catch {set in_sel $selected_paths($path)}]} {
1367 set in_sel 0
1368 }
1369 if {$in_sel} {
1370 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1371 }
1372 }
1373 $ui_index conf -state disabled
1375 $ui_other conf -state disabled
1376}
1377proc update_indexinfo {msg pathList after} {
1379 global update_index_cp ui_status_value
1380 if {![lock_index update]} return
1382 set update_index_cp 0
1384 set pathList [lsort $pathList]
1385 set totalCnt [llength $pathList]
1386 set batch [expr {int($totalCnt * .01) + 1}]
1387 if {$batch > 25} {set batch 25}
1388 set ui_status_value [format \
1390 "$msg... %i/%i files (%.2f%%)" \
1391 $update_index_cp \
1392 $totalCnt \
1393 0.0]
1394 set fd [open "| git update-index -z --index-info" w]
1395 fconfigure $fd \
1396 -blocking 0 \
1397 -buffering full \
1398 -buffersize 512 \
1399 -translation binary
1400 fileevent $fd writable [list \
1401 write_update_indexinfo \
1402 $fd \
1403 $pathList \
1404 $totalCnt \
1405 $batch \
1406 $msg \
1407 $after \
1408 ]
1409}
1410proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1412 global update_index_cp ui_status_value
1413 global file_states current_diff
1414 if {$update_index_cp >= $totalCnt} {
1416 close $fd
1417 unlock_index
1418 uplevel #0 $after
1419 return
1420 }
1421 for {set i $batch} \
1423 {$update_index_cp < $totalCnt && $i > 0} \
1424 {incr i -1} {
1425 set path [lindex $pathList $update_index_cp]
1426 incr update_index_cp
1427 set s $file_states($path)
1429 switch -glob -- [lindex $s 0] {
1430 A? {set new _O}
1431 M? {set new _M}
1432 D? {set new _?}
1433 ?? {continue}
1434 }
1435 set info [lindex $s 2]
1436 if {$info eq {}} continue
1437 puts -nonewline $fd $info
1439 puts -nonewline $fd "\t"
1440 puts -nonewline $fd $path
1441 puts -nonewline $fd "\0"
1442 display_file $path $new
1443 }
1444 set ui_status_value [format \
1446 "$msg... %i/%i files (%.2f%%)" \
1447 $update_index_cp \
1448 $totalCnt \
1449 [expr {100.0 * $update_index_cp / $totalCnt}]]
1450}
1451proc update_index {msg pathList after} {
1453 global update_index_cp ui_status_value
1454 if {![lock_index update]} return
1456 set update_index_cp 0
1458 set pathList [lsort $pathList]
1459 set totalCnt [llength $pathList]
1460 set batch [expr {int($totalCnt * .01) + 1}]
1461 if {$batch > 25} {set batch 25}
1462 set ui_status_value [format \
1464 "$msg... %i/%i files (%.2f%%)" \
1465 $update_index_cp \
1466 $totalCnt \
1467 0.0]
1468 set fd [open "| git update-index --add --remove -z --stdin" w]
1469 fconfigure $fd \
1470 -blocking 0 \
1471 -buffering full \
1472 -buffersize 512 \
1473 -translation binary
1474 fileevent $fd writable [list \
1475 write_update_index \
1476 $fd \
1477 $pathList \
1478 $totalCnt \
1479 $batch \
1480 $msg \
1481 $after \
1482 ]
1483}
1484proc write_update_index {fd pathList totalCnt batch msg after} {
1486 global update_index_cp ui_status_value
1487 global file_states current_diff
1488 if {$update_index_cp >= $totalCnt} {
1490 close $fd
1491 unlock_index
1492 uplevel #0 $after
1493 return
1494 }
1495 for {set i $batch} \
1497 {$update_index_cp < $totalCnt && $i > 0} \
1498 {incr i -1} {
1499 set path [lindex $pathList $update_index_cp]
1500 incr update_index_cp
1501 switch -glob -- [lindex $file_states($path) 0] {
1503 AD -
1504 MD -
1505 UD -
1506 _D {set new DD}
1507 _M -
1509 MM -
1510 UM -
1511 U_ -
1512 M_ {set new M_}
1513 _O -
1515 AM -
1516 A_ {set new A_}
1517 ?? {continue}
1519 }
1520 puts -nonewline $fd $path
1522 puts -nonewline $fd "\0"
1523 display_file $path $new
1524 }
1525 set ui_status_value [format \
1527 "$msg... %i/%i files (%.2f%%)" \
1528 $update_index_cp \
1529 $totalCnt \
1530 [expr {100.0 * $update_index_cp / $totalCnt}]]
1531}
1532proc checkout_index {msg pathList after} {
1534 global update_index_cp ui_status_value
1535 if {![lock_index update]} return
1537 set update_index_cp 0
1539 set pathList [lsort $pathList]
1540 set totalCnt [llength $pathList]
1541 set batch [expr {int($totalCnt * .01) + 1}]
1542 if {$batch > 25} {set batch 25}
1543 set ui_status_value [format \
1545 "$msg... %i/%i files (%.2f%%)" \
1546 $update_index_cp \
1547 $totalCnt \
1548 0.0]
1549 set cmd [list git checkout-index]
1550 lappend cmd --index
1551 lappend cmd --quiet
1552 lappend cmd --force
1553 lappend cmd -z
1554 lappend cmd --stdin
1555 set fd [open "| $cmd " w]
1556 fconfigure $fd \
1557 -blocking 0 \
1558 -buffering full \
1559 -buffersize 512 \
1560 -translation binary
1561 fileevent $fd writable [list \
1562 write_checkout_index \
1563 $fd \
1564 $pathList \
1565 $totalCnt \
1566 $batch \
1567 $msg \
1568 $after \
1569 ]
1570}
1571proc write_checkout_index {fd pathList totalCnt batch msg after} {
1573 global update_index_cp ui_status_value
1574 global file_states current_diff
1575 if {$update_index_cp >= $totalCnt} {
1577 close $fd
1578 unlock_index
1579 uplevel #0 $after
1580 return
1581 }
1582 for {set i $batch} \
1584 {$update_index_cp < $totalCnt && $i > 0} \
1585 {incr i -1} {
1586 set path [lindex $pathList $update_index_cp]
1587 incr update_index_cp
1588 switch -glob -- [lindex $file_states($path) 0] {
1590 AM -
1591 AD {set new A_}
1592 MM -
1593 MD {set new M_}
1594 _M -
1595 _D {set new __}
1596 ?? {continue}
1597 }
1598 puts -nonewline $fd $path
1600 puts -nonewline $fd "\0"
1601 display_file $path $new
1602 }
1603 set ui_status_value [format \
1605 "$msg... %i/%i files (%.2f%%)" \
1606 $update_index_cp \
1607 $totalCnt \
1608 [expr {100.0 * $update_index_cp / $totalCnt}]]
1609}
1610######################################################################
1612##
1613## branch management
1614proc load_all_heads {} {
1616 global all_heads tracking_branches
1617 set all_heads [list]
1619 set cmd [list git for-each-ref]
1620 lappend cmd --format=%(refname)
1621 lappend cmd refs/heads
1622 set fd [open "| $cmd" r]
1623 while {[gets $fd line] > 0} {
1624 if {![catch {set info $tracking_branches($line)}]} continue
1625 if {![regsub ^refs/heads/ $line {} name]} continue
1626 lappend all_heads $name
1627 }
1628 close $fd
1629 set all_heads [lsort $all_heads]
1631}
1632proc populate_branch_menu {m} {
1634 global all_heads disable_on_lock
1635 $m add separator
1637 foreach b $all_heads {
1638 $m add radiobutton \
1639 -label $b \
1640 -command [list switch_branch $b] \
1641 -variable current_branch \
1642 -value $b \
1643 -font font_ui
1644 lappend disable_on_lock \
1645 [list $m entryconf [$m index last] -state]
1646 }
1647}
1648proc do_create_branch {} {
1650 error "NOT IMPLEMENTED"
1651}
1652proc do_delete_branch {} {
1654 error "NOT IMPLEMENTED"
1655}
1656proc switch_branch {b} {
1658 global HEAD commit_type file_states current_branch
1659 global selected_commit_type ui_comm
1660 if {![lock_index switch]} return
1662 # -- Backup the selected branch (repository_state resets it)
1664 #
1665 set new_branch $current_branch
1666 # -- Our in memory state should match the repository.
1668 #
1669 repository_state curType curHEAD curMERGE_HEAD
1670 if {[string match amend* $commit_type]
1671 && $curType eq {normal}
1672 && $curHEAD eq $HEAD} {
1673 } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
1674 info_popup {Last scanned state does not match repository state.
1675Another Git program has modified this repository
1677since the last scan. A rescan must be performed
1678before the current branch can be changed.
1679The rescan will be automatically started now.
1681}
1682 unlock_index
1683 rescan {set ui_status_value {Ready.}}
1684 return
1685 }
1686 # -- Toss the message buffer if we are in amend mode.
1688 #
1689 if {[string match amend* $curType]} {
1690 $ui_comm delete 0.0 end
1691 $ui_comm edit reset
1692 $ui_comm edit modified false
1693 }
1694 set selected_commit_type new
1696 set current_branch $new_branch
1697 unlock_index
1699 error "NOT FINISHED"
1700}
1701######################################################################
1703##
1704## remote management
1705proc load_all_remotes {} {
1707 global gitdir repo_config
1708 global all_remotes tracking_branches
1709 set all_remotes [list]
1711 array unset tracking_branches
1712 set rm_dir [file join $gitdir remotes]
1714 if {[file isdirectory $rm_dir]} {
1715 set all_remotes [glob \
1716 -types f \
1717 -tails \
1718 -nocomplain \
1719 -directory $rm_dir *]
1720 foreach name $all_remotes {
1722 catch {
1723 set fd [open [file join $rm_dir $name] r]
1724 while {[gets $fd line] >= 0} {
1725 if {![regexp {^Pull:[ ]*([^:]+):(.+)$} \
1726 $line line src dst]} continue
1727 if {![regexp ^refs/ $dst]} {
1728 set dst "refs/heads/$dst"
1729 }
1730 set tracking_branches($dst) [list $name $src]
1731 }
1732 close $fd
1733 }
1734 }
1735 }
1736 foreach line [array names repo_config remote.*.url] {
1738 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
1739 lappend all_remotes $name
1740 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
1742 set fl {}
1743 }
1744 foreach line $fl {
1745 if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
1746 if {![regexp ^refs/ $dst]} {
1747 set dst "refs/heads/$dst"
1748 }
1749 set tracking_branches($dst) [list $name $src]
1750 }
1751 }
1752 set all_remotes [lsort -unique $all_remotes]
1754}
1755proc populate_fetch_menu {m} {
1757 global gitdir all_remotes repo_config
1758 foreach r $all_remotes {
1760 set enable 0
1761 if {![catch {set a $repo_config(remote.$r.url)}]} {
1762 if {![catch {set a $repo_config(remote.$r.fetch)}]} {
1763 set enable 1
1764 }
1765 } else {
1766 catch {
1767 set fd [open [file join $gitdir remotes $r] r]
1768 while {[gets $fd n] >= 0} {
1769 if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
1770 set enable 1
1771 break
1772 }
1773 }
1774 close $fd
1775 }
1776 }
1777 if {$enable} {
1779 $m add command \
1780 -label "Fetch from $r..." \
1781 -command [list fetch_from $r] \
1782 -font font_ui
1783 }
1784 }
1785}
1786proc populate_push_menu {m} {
1788 global gitdir all_remotes repo_config
1789 foreach r $all_remotes {
1791 set enable 0
1792 if {![catch {set a $repo_config(remote.$r.url)}]} {
1793 if {![catch {set a $repo_config(remote.$r.push)}]} {
1794 set enable 1
1795 }
1796 } else {
1797 catch {
1798 set fd [open [file join $gitdir remotes $r] r]
1799 while {[gets $fd n] >= 0} {
1800 if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
1801 set enable 1
1802 break
1803 }
1804 }
1805 close $fd
1806 }
1807 }
1808 if {$enable} {
1810 $m add command \
1811 -label "Push to $r..." \
1812 -command [list push_to $r] \
1813 -font font_ui
1814 }
1815 }
1816}
1817proc populate_pull_menu {m} {
1819 global gitdir repo_config all_remotes disable_on_lock
1820 foreach remote $all_remotes {
1822 set rb_list [list]
1823 if {[array get repo_config remote.$remote.url] ne {}} {
1824 if {[array get repo_config remote.$remote.fetch] ne {}} {
1825 foreach line $repo_config(remote.$remote.fetch) {
1826 if {[regexp {^([^:]+):} $line line rb]} {
1827 lappend rb_list $rb
1828 }
1829 }
1830 }
1831 } else {
1832 catch {
1833 set fd [open [file join $gitdir remotes $remote] r]
1834 while {[gets $fd line] >= 0} {
1835 if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
1836 lappend rb_list $rb
1837 }
1838 }
1839 close $fd
1840 }
1841 }
1842 foreach rb $rb_list {
1844 regsub ^refs/heads/ $rb {} rb_short
1845 $m add command \
1846 -label "Branch $rb_short from $remote..." \
1847 -command [list pull_remote $remote $rb] \
1848 -font font_ui
1849 lappend disable_on_lock \
1850 [list $m entryconf [$m index last] -state]
1851 }
1852 }
1853}
1854######################################################################
1856##
1857## icons
1858set filemask {
1860#define mask_width 14
1861#define mask_height 15
1862static unsigned char mask_bits[] = {
1863 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1864 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1865 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1866}
1867image create bitmap file_plain -background white -foreground black -data {
1869#define plain_width 14
1870#define plain_height 15
1871static unsigned char plain_bits[] = {
1872 0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1873 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1874 0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1875} -maskdata $filemask
1876image create bitmap file_mod -background white -foreground blue -data {
1878#define mod_width 14
1879#define mod_height 15
1880static unsigned char mod_bits[] = {
1881 0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1882 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1883 0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1884} -maskdata $filemask
1885image create bitmap file_fulltick -background white -foreground "#007000" -data {
1887#define file_fulltick_width 14
1888#define file_fulltick_height 15
1889static unsigned char file_fulltick_bits[] = {
1890 0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1891 0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1892 0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1893} -maskdata $filemask
1894image create bitmap file_parttick -background white -foreground "#005050" -data {
1896#define parttick_width 14
1897#define parttick_height 15
1898static unsigned char parttick_bits[] = {
1899 0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1900 0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1901 0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1902} -maskdata $filemask
1903image create bitmap file_question -background white -foreground black -data {
1905#define file_question_width 14
1906#define file_question_height 15
1907static unsigned char file_question_bits[] = {
1908 0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1909 0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1910 0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1911} -maskdata $filemask
1912image create bitmap file_removed -background white -foreground red -data {
1914#define file_removed_width 14
1915#define file_removed_height 15
1916static unsigned char file_removed_bits[] = {
1917 0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1918 0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1919 0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1920} -maskdata $filemask
1921image create bitmap file_merge -background white -foreground blue -data {
1923#define file_merge_width 14
1924#define file_merge_height 15
1925static unsigned char file_merge_bits[] = {
1926 0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1927 0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1928 0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1929} -maskdata $filemask
1930set ui_index .vpane.files.index.list
1932set ui_other .vpane.files.other.list
1933set max_status_desc 0
1934foreach i {
1935 {__ i plain "Unmodified"}
1936 {_M i mod "Modified"}
1937 {M_ i fulltick "Included in commit"}
1938 {MM i parttick "Partially included"}
1939 {MD i question "Included (but gone)"}
1940 {_O o plain "Untracked"}
1942 {A_ o fulltick "Added by commit"}
1943 {AM o parttick "Partially added"}
1944 {AD o question "Added (but gone)"}
1945 {_D i question "Missing"}
1947 {DD i removed "Removed by commit"}
1948 {DO i removed "Removed (still exists)"}
1949 {DM i removed "Removed (but modified)"}
1950 {UD i merge "Merge conflicts"}
1952 {UM i merge "Merge conflicts"}
1953 {U_ i merge "Merge conflicts"}
1954 } {
1955 if {$max_status_desc < [string length [lindex $i 3]]} {
1956 set max_status_desc [string length [lindex $i 3]]
1957 }
1958 if {[lindex $i 1] eq {i}} {
1959 set all_cols([lindex $i 0]) $ui_index
1960 } else {
1961 set all_cols([lindex $i 0]) $ui_other
1962 }
1963 set all_icons([lindex $i 0]) file_[lindex $i 2]
1964 set all_descs([lindex $i 0]) [lindex $i 3]
1965}
1966unset filemask i
1967######################################################################
1969##
1970## util
1971proc is_MacOSX {} {
1973 global tcl_platform tk_library
1974 if {[tk windowingsystem] eq {aqua}} {
1975 return 1
1976 }
1977 return 0
1978}
1979proc is_Windows {} {
1981 global tcl_platform
1982 if {$tcl_platform(platform) eq {windows}} {
1983 return 1
1984 }
1985 return 0
1986}
1987proc bind_button3 {w cmd} {
1989 bind $w <Any-Button-3> $cmd
1990 if {[is_MacOSX]} {
1991 bind $w <Control-Button-1> $cmd
1992 }
1993}
1994proc incr_font_size {font {amt 1}} {
1996 set sz [font configure $font -size]
1997 incr sz $amt
1998 font configure $font -size $sz
1999 font configure ${font}bold -size $sz
2000}
2001proc hook_failed_popup {hook msg} {
2003 global gitdir appname
2004 set w .hookfail
2006 toplevel $w
2007 frame $w.m
2009 label $w.m.l1 -text "$hook hook failed:" \
2010 -anchor w \
2011 -justify left \
2012 -font font_uibold
2013 text $w.m.t \
2014 -background white -borderwidth 1 \
2015 -relief sunken \
2016 -width 80 -height 10 \
2017 -font font_diff \
2018 -yscrollcommand [list $w.m.sby set]
2019 label $w.m.l2 \
2020 -text {You must correct the above errors before committing.} \
2021 -anchor w \
2022 -justify left \
2023 -font font_uibold
2024 scrollbar $w.m.sby -command [list $w.m.t yview]
2025 pack $w.m.l1 -side top -fill x
2026 pack $w.m.l2 -side bottom -fill x
2027 pack $w.m.sby -side right -fill y
2028 pack $w.m.t -side left -fill both -expand 1
2029 pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2030 $w.m.t insert 1.0 $msg
2032 $w.m.t conf -state disabled
2033 button $w.ok -text OK \
2035 -width 15 \
2036 -font font_ui \
2037 -command "destroy $w"
2038 pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2039 bind $w <Visibility> "grab $w; focus $w"
2041 bind $w <Key-Return> "destroy $w"
2042 wm title $w "$appname ([lindex [file split \
2043 [file normalize [file dirname $gitdir]]] \
2044 end]): error"
2045 tkwait window $w
2046}
2047set next_console_id 0
2049proc new_console {short_title long_title} {
2051 global next_console_id console_data
2052 set w .console[incr next_console_id]
2053 set console_data($w) [list $short_title $long_title]
2054 return [console_init $w]
2055}
2056proc console_init {w} {
2058 global console_cr console_data
2059 global gitdir appname M1B
2060 set console_cr($w) 1.0
2062 toplevel $w
2063 frame $w.m
2064 label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2065 -anchor w \
2066 -justify left \
2067 -font font_uibold
2068 text $w.m.t \
2069 -background white -borderwidth 1 \
2070 -relief sunken \
2071 -width 80 -height 10 \
2072 -font font_diff \
2073 -state disabled \
2074 -yscrollcommand [list $w.m.sby set]
2075 label $w.m.s -text {Working... please wait...} \
2076 -anchor w \
2077 -justify left \
2078 -font font_uibold
2079 scrollbar $w.m.sby -command [list $w.m.t yview]
2080 pack $w.m.l1 -side top -fill x
2081 pack $w.m.s -side bottom -fill x
2082 pack $w.m.sby -side right -fill y
2083 pack $w.m.t -side left -fill both -expand 1
2084 pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2085 menu $w.ctxm -tearoff 0
2087 $w.ctxm add command -label "Copy" \
2088 -font font_ui \
2089 -command "tk_textCopy $w.m.t"
2090 $w.ctxm add command -label "Select All" \
2091 -font font_ui \
2092 -command "$w.m.t tag add sel 0.0 end"
2093 $w.ctxm add command -label "Copy All" \
2094 -font font_ui \
2095 -command "
2096 $w.m.t tag add sel 0.0 end
2097 tk_textCopy $w.m.t
2098 $w.m.t tag remove sel 0.0 end
2099 "
2100 button $w.ok -text {Close} \
2102 -font font_ui \
2103 -state disabled \
2104 -command "destroy $w"
2105 pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2106 bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2108 bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2109 bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2110 bind $w <Visibility> "focus $w"
2111 wm title $w "$appname ([lindex [file split \
2112 [file normalize [file dirname $gitdir]]] \
2113 end]): [lindex $console_data($w) 0]"
2114 return $w
2115}
2116proc console_exec {w cmd {after {}}} {
2118 # -- Windows tosses the enviroment when we exec our child.
2119 # But most users need that so we have to relogin. :-(
2120 #
2121 if {[is_Windows]} {
2122 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2123 }
2124 # -- Tcl won't let us redirect both stdout and stderr to
2126 # the same pipe. So pass it through cat...
2127 #
2128 set cmd [concat | $cmd |& cat]
2129 set fd_f [open $cmd r]
2131 fconfigure $fd_f -blocking 0 -translation binary
2132 fileevent $fd_f readable [list console_read $w $fd_f $after]
2133}
2134proc console_read {w fd after} {
2136 global console_cr console_data
2137 set buf [read $fd]
2139 if {$buf ne {}} {
2140 if {![winfo exists $w]} {console_init $w}
2141 $w.m.t conf -state normal
2142 set c 0
2143 set n [string length $buf]
2144 while {$c < $n} {
2145 set cr [string first "\r" $buf $c]
2146 set lf [string first "\n" $buf $c]
2147 if {$cr < 0} {set cr [expr {$n + 1}]}
2148 if {$lf < 0} {set lf [expr {$n + 1}]}
2149 if {$lf < $cr} {
2151 $w.m.t insert end [string range $buf $c $lf]
2152 set console_cr($w) [$w.m.t index {end -1c}]
2153 set c $lf
2154 incr c
2155 } else {
2156 $w.m.t delete $console_cr($w) end
2157 $w.m.t insert end "\n"
2158 $w.m.t insert end [string range $buf $c $cr]
2159 set c $cr
2160 incr c
2161 }
2162 }
2163 $w.m.t conf -state disabled
2164 $w.m.t see end
2165 }
2166 fconfigure $fd -blocking 1
2168 if {[eof $fd]} {
2169 if {[catch {close $fd}]} {
2170 if {![winfo exists $w]} {console_init $w}
2171 $w.m.s conf -background red -text {Error: Command Failed}
2172 $w.ok conf -state normal
2173 set ok 0
2174 } elseif {[winfo exists $w]} {
2175 $w.m.s conf -background green -text {Success}
2176 $w.ok conf -state normal
2177 set ok 1
2178 }
2179 array unset console_cr $w
2180 array unset console_data $w
2181 if {$after ne {}} {
2182 uplevel #0 $after $ok
2183 }
2184 return
2185 }
2186 fconfigure $fd -blocking 0
2187}
2188######################################################################
2190##
2191## ui commands
2192set starting_gitk_msg {Please wait... Starting gitk...}
2194proc do_gitk {revs} {
2196 global ui_status_value starting_gitk_msg
2197 set cmd gitk
2199 if {$revs ne {}} {
2200 append cmd { }
2201 append cmd $revs
2202 }
2203 if {[is_Windows]} {
2204 set cmd "sh -c \"exec $cmd\""
2205 }
2206 append cmd { &}
2207 if {[catch {eval exec $cmd} err]} {
2209 error_popup "Failed to start gitk:\n\n$err"
2210 } else {
2211 set ui_status_value $starting_gitk_msg
2212 after 10000 {
2213 if {$ui_status_value eq $starting_gitk_msg} {
2214 set ui_status_value {Ready.}
2215 }
2216 }
2217 }
2218}
2219proc do_repack {} {
2221 set w [new_console {repack} \
2222 {Repacking the object database}]
2223 set cmd [list git repack]
2224 lappend cmd -a
2225 lappend cmd -d
2226 console_exec $w $cmd
2227}
2228proc do_fsck_objects {} {
2230 set w [new_console {fsck-objects} \
2231 {Verifying the object database with fsck-objects}]
2232 set cmd [list git fsck-objects]
2233 lappend cmd --full
2234 lappend cmd --cache
2235 lappend cmd --strict
2236 console_exec $w $cmd
2237}
2238set is_quitting 0
2240proc do_quit {} {
2242 global gitdir ui_comm is_quitting repo_config commit_type
2243 if {$is_quitting} return
2245 set is_quitting 1
2246 # -- Stash our current commit buffer.
2248 #
2249 set save [file join $gitdir GITGUI_MSG]
2250 set msg [string trim [$ui_comm get 0.0 end]]
2251 if {![string match amend* $commit_type]
2252 && [$ui_comm edit modified]
2253 && $msg ne {}} {
2254 catch {
2255 set fd [open $save w]
2256 puts $fd [string trim [$ui_comm get 0.0 end]]
2257 close $fd
2258 }
2259 } else {
2260 catch {file delete $save}
2261 }
2262 # -- Stash our current window geometry into this repository.
2264 #
2265 set cfg_geometry [list]
2266 lappend cfg_geometry [wm geometry .]
2267 lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2268 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2269 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2270 set rc_geometry {}
2271 }
2272 if {$cfg_geometry ne $rc_geometry} {
2273 catch {exec git repo-config gui.geometry $cfg_geometry}
2274 }
2275 destroy .
2277}
2278proc do_rescan {} {
2280 rescan {set ui_status_value {Ready.}}
2281}
2282proc remove_helper {txt paths} {
2284 global file_states current_diff
2285 if {![lock_index begin-update]} return
2287 set pathList [list]
2289 set after {}
2290 foreach path $paths {
2291 switch -glob -- [lindex $file_states($path) 0] {
2292 A? -
2293 M? -
2294 D? {
2295 lappend pathList $path
2296 if {$path eq $current_diff} {
2297 set after {reshow_diff;}
2298 }
2299 }
2300 }
2301 }
2302 if {$pathList eq {}} {
2303 unlock_index
2304 } else {
2305 update_indexinfo \
2306 $txt \
2307 $pathList \
2308 [concat $after {set ui_status_value {Ready.}}]
2309 }
2310}
2311proc do_remove_selection {} {
2313 global current_diff selected_paths
2314 if {[array size selected_paths] > 0} {
2316 remove_helper \
2317 {Removing selected files from commit} \
2318 [array names selected_paths]
2319 } elseif {$current_diff ne {}} {
2320 remove_helper \
2321 "Removing [short_path $current_diff] from commit" \
2322 [list $current_diff]
2323 }
2324}
2325proc include_helper {txt paths} {
2327 global file_states current_diff
2328 if {![lock_index begin-update]} return
2330 set pathList [list]
2332 set after {}
2333 foreach path $paths {
2334 switch -glob -- [lindex $file_states($path) 0] {
2335 AM -
2336 AD -
2337 MM -
2338 MD -
2339 U? -
2340 _M -
2341 _D -
2342 _O {
2343 lappend pathList $path
2344 if {$path eq $current_diff} {
2345 set after {reshow_diff;}
2346 }
2347 }
2348 }
2349 }
2350 if {$pathList eq {}} {
2351 unlock_index
2352 } else {
2353 update_index \
2354 $txt \
2355 $pathList \
2356 [concat $after {set ui_status_value {Ready to commit.}}]
2357 }
2358}
2359proc do_include_selection {} {
2361 global current_diff selected_paths
2362 if {[array size selected_paths] > 0} {
2364 include_helper \
2365 {Including selected files} \
2366 [array names selected_paths]
2367 } elseif {$current_diff ne {}} {
2368 include_helper \
2369 "Including [short_path $current_diff]" \
2370 [list $current_diff]
2371 }
2372}
2373proc do_include_all {} {
2375 global file_states
2376 set paths [list]
2378 foreach path [array names file_states] {
2379 switch -- [lindex $file_states($path) 0] {
2380 AM -
2381 AD -
2382 MM -
2383 MD -
2384 _M -
2385 _D {lappend paths $path}
2386 }
2387 }
2388 include_helper \
2389 {Including all modified files} \
2390 $paths
2391}
2392proc revert_helper {txt paths} {
2394 global gitdir appname
2395 global file_states current_diff
2396 if {![lock_index begin-update]} return
2398 set pathList [list]
2400 set after {}
2401 foreach path $paths {
2402 switch -glob -- [lindex $file_states($path) 0] {
2403 AM -
2404 AD -
2405 MM -
2406 MD -
2407 _M -
2408 _D {
2409 lappend pathList $path
2410 if {$path eq $current_diff} {
2411 set after {reshow_diff;}
2412 }
2413 }
2414 }
2415 }
2416 set n [llength $pathList]
2418 if {$n == 0} {
2419 unlock_index
2420 return
2421 } elseif {$n == 1} {
2422 set s "[short_path [lindex $pathList]]"
2423 } else {
2424 set s "these $n files"
2425 }
2426 set reponame [lindex [file split \
2428 [file normalize [file dirname $gitdir]]] \
2429 end]
2430 set reply [tk_dialog \
2432 .confirm_revert \
2433 "$appname ($reponame)" \
2434 "Revert unincluded changes in $s?
2435Any unincluded changes will be permanently lost by the revert." \
2437 question \
2438 1 \
2439 {Do Nothing} \
2440 {Revert Changes} \
2441 ]
2442 if {$reply == 1} {
2443 checkout_index \
2444 $txt \
2445 $pathList \
2446 [concat $after {set ui_status_value {Ready.}}]
2447 } else {
2448 unlock_index
2449 }
2450}
2451proc do_revert_selection {} {
2453 global current_diff selected_paths
2454 if {[array size selected_paths] > 0} {
2456 revert_helper \
2457 {Reverting selected files} \
2458 [array names selected_paths]
2459 } elseif {$current_diff ne {}} {
2460 revert_helper \
2461 "Reverting [short_path $current_diff]" \
2462 [list $current_diff]
2463 }
2464}
2465proc do_signoff {} {
2467 global ui_comm
2468 set me [committer_ident]
2470 if {$me eq {}} return
2471 set sob "Signed-off-by: $me"
2473 set last [$ui_comm get {end -1c linestart} {end -1c}]
2474 if {$last ne $sob} {
2475 $ui_comm edit separator
2476 if {$last ne {}
2477 && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2478 $ui_comm insert end "\n"
2479 }
2480 $ui_comm insert end "\n$sob"
2481 $ui_comm edit separator
2482 $ui_comm see end
2483 }
2484}
2485proc do_select_commit_type {} {
2487 global commit_type selected_commit_type
2488 if {$selected_commit_type eq {new}
2490 && [string match amend* $commit_type]} {
2491 create_new_commit
2492 } elseif {$selected_commit_type eq {amend}
2493 && ![string match amend* $commit_type]} {
2494 load_last_commit
2495 # The amend request was rejected...
2497 #
2498 if {![string match amend* $commit_type]} {
2499 set selected_commit_type new
2500 }
2501 }
2502}
2503proc do_commit {} {
2505 commit_tree
2506}
2507proc do_about {} {
2509 global appname copyright
2510 global tcl_patchLevel tk_patchLevel
2511 set w .about_dialog
2513 toplevel $w
2514 wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2515 label $w.header -text "About $appname" \
2517 -font font_uibold
2518 pack $w.header -side top -fill x
2519 frame $w.buttons
2521 button $w.buttons.close -text {Close} \
2522 -font font_ui \
2523 -command [list destroy $w]
2524 pack $w.buttons.close -side right
2525 pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2526 label $w.desc \
2528 -text "$appname - a commit creation tool for Git.
2529$copyright" \
2530 -padx 5 -pady 5 \
2531 -justify left \
2532 -anchor w \
2533 -borderwidth 1 \
2534 -relief solid \
2535 -font font_ui
2536 pack $w.desc -side top -fill x -padx 5 -pady 5
2537 set v [exec git --version]
2539 append v "\n\n"
2540 if {$tcl_patchLevel eq $tk_patchLevel} {
2541 append v "Tcl/Tk version $tcl_patchLevel"
2542 } else {
2543 append v "Tcl version $tcl_patchLevel"
2544 append v ", Tk version $tk_patchLevel"
2545 }
2546 label $w.vers \
2548 -text $v \
2549 -padx 5 -pady 5 \
2550 -justify left \
2551 -anchor w \
2552 -borderwidth 1 \
2553 -relief solid \
2554 -font font_ui
2555 pack $w.vers -side top -fill x -padx 5 -pady 5
2556 bind $w <Visibility> "grab $w; focus $w"
2558 bind $w <Key-Escape> "destroy $w"
2559 wm title $w "About $appname"
2560 tkwait window $w
2561}
2562proc do_options {} {
2564 global appname gitdir font_descs
2565 global repo_config global_config
2566 global repo_config_new global_config_new
2567 array unset repo_config_new
2569 array unset global_config_new
2570 foreach name [array names repo_config] {
2571 set repo_config_new($name) $repo_config($name)
2572 }
2573 load_config 1
2574 foreach name [array names repo_config] {
2575 switch -- $name {
2576 gui.diffcontext {continue}
2577 }
2578 set repo_config_new($name) $repo_config($name)
2579 }
2580 foreach name [array names global_config] {
2581 set global_config_new($name) $global_config($name)
2582 }
2583 set reponame [lindex [file split \
2584 [file normalize [file dirname $gitdir]]] \
2585 end]
2586 set w .options_editor
2588 toplevel $w
2589 wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2590 label $w.header -text "$appname Options" \
2592 -font font_uibold
2593 pack $w.header -side top -fill x
2594 frame $w.buttons
2596 button $w.buttons.restore -text {Restore Defaults} \
2597 -font font_ui \
2598 -command do_restore_defaults
2599 pack $w.buttons.restore -side left
2600 button $w.buttons.save -text Save \
2601 -font font_ui \
2602 -command [list do_save_config $w]
2603 pack $w.buttons.save -side right
2604 button $w.buttons.cancel -text {Cancel} \
2605 -font font_ui \
2606 -command [list destroy $w]
2607 pack $w.buttons.cancel -side right
2608 pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2609 labelframe $w.repo -text "$reponame Repository" \
2611 -font font_ui \
2612 -relief raised -borderwidth 2
2613 labelframe $w.global -text {Global (All Repositories)} \
2614 -font font_ui \
2615 -relief raised -borderwidth 2
2616 pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2617 pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2618 foreach option {
2620 {b partialinclude {Allow Partially Included Files}}
2621 {b pullsummary {Show Pull Summary}}
2622 {b trustmtime {Trust File Modification Timestamps}}
2623 {i diffcontext {Number of Diff Context Lines}}
2624 } {
2625 set type [lindex $option 0]
2626 set name [lindex $option 1]
2627 set text [lindex $option 2]
2628 foreach f {repo global} {
2629 switch $type {
2630 b {
2631 checkbutton $w.$f.$name -text $text \
2632 -variable ${f}_config_new(gui.$name) \
2633 -onvalue true \
2634 -offvalue false \
2635 -font font_ui
2636 pack $w.$f.$name -side top -anchor w
2637 }
2638 i {
2639 frame $w.$f.$name
2640 label $w.$f.$name.l -text "$text:" -font font_ui
2641 pack $w.$f.$name.l -side left -anchor w -fill x
2642 spinbox $w.$f.$name.v \
2643 -textvariable ${f}_config_new(gui.$name) \
2644 -from 1 -to 99 -increment 1 \
2645 -width 3 \
2646 -font font_ui
2647 pack $w.$f.$name.v -side right -anchor e
2648 pack $w.$f.$name -side top -anchor w -fill x
2649 }
2650 }
2651 }
2652 }
2653 set all_fonts [lsort [font families]]
2655 foreach option $font_descs {
2656 set name [lindex $option 0]
2657 set font [lindex $option 1]
2658 set text [lindex $option 2]
2659 set global_config_new(gui.$font^^family) \
2661 [font configure $font -family]
2662 set global_config_new(gui.$font^^size) \
2663 [font configure $font -size]
2664 frame $w.global.$name
2666 label $w.global.$name.l -text "$text:" -font font_ui
2667 pack $w.global.$name.l -side left -anchor w -fill x
2668 eval tk_optionMenu $w.global.$name.family \
2669 global_config_new(gui.$font^^family) \
2670 $all_fonts
2671 spinbox $w.global.$name.size \
2672 -textvariable global_config_new(gui.$font^^size) \
2673 -from 2 -to 80 -increment 1 \
2674 -width 3 \
2675 -font font_ui
2676 pack $w.global.$name.size -side right -anchor e
2677 pack $w.global.$name.family -side right -anchor e
2678 pack $w.global.$name -side top -anchor w -fill x
2679 }
2680 bind $w <Visibility> "grab $w; focus $w"
2682 bind $w <Key-Escape> "destroy $w"
2683 wm title $w "$appname ($reponame): Options"
2684 tkwait window $w
2685}
2686proc do_restore_defaults {} {
2688 global font_descs default_config repo_config
2689 global repo_config_new global_config_new
2690 foreach name [array names default_config] {
2692 set repo_config_new($name) $default_config($name)
2693 set global_config_new($name) $default_config($name)
2694 }
2695 foreach option $font_descs {
2697 set name [lindex $option 0]
2698 set repo_config(gui.$name) $default_config(gui.$name)
2699 }
2700 apply_config
2701 foreach option $font_descs {
2703 set name [lindex $option 0]
2704 set font [lindex $option 1]
2705 set global_config_new(gui.$font^^family) \
2706 [font configure $font -family]
2707 set global_config_new(gui.$font^^size) \
2708 [font configure $font -size]
2709 }
2710}
2711proc do_save_config {w} {
2713 if {[catch {save_config} err]} {
2714 error_popup "Failed to completely save options:\n\n$err"
2715 }
2716 reshow_diff
2717 destroy $w
2718}
2719proc do_windows_shortcut {} {
2721 global gitdir appname argv0
2722 set reponame [lindex [file split \
2724 [file normalize [file dirname $gitdir]]] \
2725 end]
2726 if {[catch {
2728 set desktop [exec cygpath \
2729 --windows \
2730 --absolute \
2731 --long-name \
2732 --desktop]
2733 }]} {
2734 set desktop .
2735 }
2736 set fn [tk_getSaveFile \
2737 -parent . \
2738 -title "$appname ($reponame): Create Desktop Icon" \
2739 -initialdir $desktop \
2740 -initialfile "Git $reponame.bat"]
2741 if {$fn != {}} {
2742 if {[catch {
2743 set fd [open $fn w]
2744 set sh [exec cygpath \
2745 --windows \
2746 --absolute \
2747 --long-name \
2748 /bin/sh]
2749 set me [exec cygpath \
2750 --unix \
2751 --absolute \
2752 $argv0]
2753 set gd [exec cygpath \
2754 --unix \
2755 --absolute \
2756 $gitdir]
2757 regsub -all ' $me "'\\''" me
2758 regsub -all ' $gd "'\\''" gd
2759 puts -nonewline $fd "\"$sh\" --login -c \""
2760 puts -nonewline $fd "GIT_DIR='$gd'"
2761 puts -nonewline $fd " '$me'"
2762 puts $fd "&\""
2763 close $fd
2764 } err]} {
2765 error_popup "Cannot write script:\n\n$err"
2766 }
2767 }
2768}
2769proc do_macosx_app {} {
2771 global gitdir appname argv0 env
2772 set reponame [lindex [file split \
2774 [file normalize [file dirname $gitdir]]] \
2775 end]
2776 set fn [tk_getSaveFile \
2778 -parent . \
2779 -title "$appname ($reponame): Create Desktop Icon" \
2780 -initialdir [file join $env(HOME) Desktop] \
2781 -initialfile "Git $reponame.app"]
2782 if {$fn != {}} {
2783 if {[catch {
2784 set Contents [file join $fn Contents]
2785 set MacOS [file join $Contents MacOS]
2786 set exe [file join $MacOS git-gui]
2787 file mkdir $MacOS
2789 set fd [open [file join $Contents Info.plist] w]
2791 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
2792<!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
2793<plist version="1.0">
2794<dict>
2795 <key>CFBundleDevelopmentRegion</key>
2796 <string>English</string>
2797 <key>CFBundleExecutable</key>
2798 <string>git-gui</string>
2799 <key>CFBundleIdentifier</key>
2800 <string>org.spearce.git-gui</string>
2801 <key>CFBundleInfoDictionaryVersion</key>
2802 <string>6.0</string>
2803 <key>CFBundlePackageType</key>
2804 <string>APPL</string>
2805 <key>CFBundleSignature</key>
2806 <string>????</string>
2807 <key>CFBundleVersion</key>
2808 <string>1.0</string>
2809 <key>NSPrincipalClass</key>
2810 <string>NSApplication</string>
2811</dict>
2812</plist>}
2813 close $fd
2814 set fd [open $exe w]
2816 set gd [file normalize $gitdir]
2817 set ep [file normalize [exec git --exec-path]]
2818 regsub -all ' $gd "'\\''" gd
2819 regsub -all ' $ep "'\\''" ep
2820 puts $fd "#!/bin/sh"
2821 foreach name [array names env] {
2822 if {[string match GIT_* $name]} {
2823 regsub -all ' $env($name) "'\\''" v
2824 puts $fd "export $name='$v'"
2825 }
2826 }
2827 puts $fd "export PATH='$ep':\$PATH"
2828 puts $fd "export GIT_DIR='$gd'"
2829 puts $fd "exec [file normalize $argv0]"
2830 close $fd
2831 file attributes $exe -permissions u+x,g+x,o+x
2833 } err]} {
2834 error_popup "Cannot write icon:\n\n$err"
2835 }
2836 }
2837}
2838proc toggle_or_diff {w x y} {
2840 global file_states file_lists current_diff ui_index ui_other
2841 global last_clicked selected_paths
2842 set pos [split [$w index @$x,$y] .]
2844 set lno [lindex $pos 0]
2845 set col [lindex $pos 1]
2846 set path [lindex $file_lists($w) [expr {$lno - 1}]]
2847 if {$path eq {}} {
2848 set last_clicked {}
2849 return
2850 }
2851 set last_clicked [list $w $lno]
2853 array unset selected_paths
2854 $ui_index tag remove in_sel 0.0 end
2855 $ui_other tag remove in_sel 0.0 end
2856 if {$col == 0} {
2858 if {$current_diff eq $path} {
2859 set after {reshow_diff;}
2860 } else {
2861 set after {}
2862 }
2863 switch -glob -- [lindex $file_states($path) 0] {
2864 A_ -
2865 M_ -
2866 DD -
2867 DO -
2868 DM {
2869 update_indexinfo \
2870 "Removing [short_path $path] from commit" \
2871 [list $path] \
2872 [concat $after {set ui_status_value {Ready.}}]
2873 }
2874 ?? {
2875 update_index \
2876 "Including [short_path $path]" \
2877 [list $path] \
2878 [concat $after {set ui_status_value {Ready.}}]
2879 }
2880 }
2881 } else {
2882 show_diff $path $w $lno
2883 }
2884}
2885proc add_one_to_selection {w x y} {
2887 global file_lists
2888 global last_clicked selected_paths
2889 set pos [split [$w index @$x,$y] .]
2891 set lno [lindex $pos 0]
2892 set col [lindex $pos 1]
2893 set path [lindex $file_lists($w) [expr {$lno - 1}]]
2894 if {$path eq {}} {
2895 set last_clicked {}
2896 return
2897 }
2898 set last_clicked [list $w $lno]
2900 if {[catch {set in_sel $selected_paths($path)}]} {
2901 set in_sel 0
2902 }
2903 if {$in_sel} {
2904 unset selected_paths($path)
2905 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2906 } else {
2907 set selected_paths($path) 1
2908 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2909 }
2910}
2911proc add_range_to_selection {w x y} {
2913 global file_lists
2914 global last_clicked selected_paths
2915 if {[lindex $last_clicked 0] ne $w} {
2917 toggle_or_diff $w $x $y
2918 return
2919 }
2920 set pos [split [$w index @$x,$y] .]
2922 set lno [lindex $pos 0]
2923 set lc [lindex $last_clicked 1]
2924 if {$lc < $lno} {
2925 set begin $lc
2926 set end $lno
2927 } else {
2928 set begin $lno
2929 set end $lc
2930 }
2931 foreach path [lrange $file_lists($w) \
2933 [expr {$begin - 1}] \
2934 [expr {$end - 1}]] {
2935 set selected_paths($path) 1
2936 }
2937 $w tag add in_sel $begin.0 [expr {$end + 1}].0
2938}
2939######################################################################
2941##
2942## config defaults
2943set cursor_ptr arrow
2945font create font_diff -family Courier -size 10
2946font create font_ui
2947catch {
2948 label .dummy
2949 eval font configure font_ui [font actual [.dummy cget -font]]
2950 destroy .dummy
2951}
2952font create font_uibold
2954font create font_diffbold
2955if {[is_Windows]} {
2957 set M1B Control
2958 set M1T Ctrl
2959} elseif {[is_MacOSX]} {
2960 set M1B M1
2961 set M1T Cmd
2962} else {
2963 set M1B M1
2964 set M1T M1
2965}
2966proc apply_config {} {
2968 global repo_config font_descs
2969 foreach option $font_descs {
2971 set name [lindex $option 0]
2972 set font [lindex $option 1]
2973 if {[catch {
2974 foreach {cn cv} $repo_config(gui.$name) {
2975 font configure $font $cn $cv
2976 }
2977 } err]} {
2978 error_popup "Invalid font specified in gui.$name:\n\n$err"
2979 }
2980 foreach {cn cv} [font configure $font] {
2981 font configure ${font}bold $cn $cv
2982 }
2983 font configure ${font}bold -weight bold
2984 }
2985}
2986set default_config(gui.trustmtime) false
2988set default_config(gui.pullsummary) true
2989set default_config(gui.partialinclude) false
2990set default_config(gui.diffcontext) 5
2991set default_config(gui.fontui) [font configure font_ui]
2992set default_config(gui.fontdiff) [font configure font_diff]
2993set font_descs {
2994 {fontui font_ui {Main Font}}
2995 {fontdiff font_diff {Diff/Console Font}}
2996}
2997load_config 0
2998apply_config
2999######################################################################
3001##
3002## ui construction
3003# -- Menu Bar
3005#
3006menu .mbar -tearoff 0
3007.mbar add cascade -label Repository -menu .mbar.repository
3008.mbar add cascade -label Edit -menu .mbar.edit
3009if {!$single_commit} {
3010 .mbar add cascade -label Branch -menu .mbar.branch
3011}
3012.mbar add cascade -label Commit -menu .mbar.commit
3013if {!$single_commit} {
3014 .mbar add cascade -label Fetch -menu .mbar.fetch
3015 .mbar add cascade -label Pull -menu .mbar.pull
3016 .mbar add cascade -label Push -menu .mbar.push
3017}
3018. configure -menu .mbar
3019# -- Repository Menu
3021#
3022menu .mbar.repository
3023.mbar.repository add command \
3024 -label {Visualize Current Branch} \
3025 -command {do_gitk {}} \
3026 -font font_ui
3027if {![is_MacOSX]} {
3028 .mbar.repository add command \
3029 -label {Visualize All Branches} \
3030 -command {do_gitk {--all}} \
3031 -font font_ui
3032}
3033.mbar.repository add separator
3034if {!$single_commit} {
3036 .mbar.repository add command -label {Repack Database} \
3037 -command do_repack \
3038 -font font_ui
3039 .mbar.repository add command -label {Verify Database} \
3041 -command do_fsck_objects \
3042 -font font_ui
3043 .mbar.repository add separator
3045 if {[is_Windows]} {
3047 .mbar.repository add command \
3048 -label {Create Desktop Icon} \
3049 -command do_windows_shortcut \
3050 -font font_ui
3051 } elseif {[is_MacOSX]} {
3052 .mbar.repository add command \
3053 -label {Create Desktop Icon} \
3054 -command do_macosx_app \
3055 -font font_ui
3056 }
3057}
3058.mbar.repository add command -label Quit \
3060 -command do_quit \
3061 -accelerator $M1T-Q \
3062 -font font_ui
3063# -- Edit Menu
3065#
3066menu .mbar.edit
3067.mbar.edit add command -label Undo \
3068 -command {catch {[focus] edit undo}} \
3069 -accelerator $M1T-Z \
3070 -font font_ui
3071.mbar.edit add command -label Redo \
3072 -command {catch {[focus] edit redo}} \
3073 -accelerator $M1T-Y \
3074 -font font_ui
3075.mbar.edit add separator
3076.mbar.edit add command -label Cut \
3077 -command {catch {tk_textCut [focus]}} \
3078 -accelerator $M1T-X \
3079 -font font_ui
3080.mbar.edit add command -label Copy \
3081 -command {catch {tk_textCopy [focus]}} \
3082 -accelerator $M1T-C \
3083 -font font_ui
3084.mbar.edit add command -label Paste \
3085 -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3086 -accelerator $M1T-V \
3087 -font font_ui
3088.mbar.edit add command -label Delete \
3089 -command {catch {[focus] delete sel.first sel.last}} \
3090 -accelerator Del \
3091 -font font_ui
3092.mbar.edit add separator
3093.mbar.edit add command -label {Select All} \
3094 -command {catch {[focus] tag add sel 0.0 end}} \
3095 -accelerator $M1T-A \
3096 -font font_ui
3097# -- Branch Menu
3099#
3100if {!$single_commit} {
3101 menu .mbar.branch
3102 .mbar.branch add command -label {Create...} \
3104 -command do_create_branch \
3105 -font font_ui
3106 lappend disable_on_lock [list .mbar.branch entryconf \
3107 [.mbar.branch index last] -state]
3108 .mbar.branch add command -label {Delete...} \
3110 -command do_delete_branch \
3111 -font font_ui
3112 lappend disable_on_lock [list .mbar.branch entryconf \
3113 [.mbar.branch index last] -state]
3114}
3115# -- Commit Menu
3117#
3118menu .mbar.commit
3119.mbar.commit add radiobutton \
3121 -label {New Commit} \
3122 -command do_select_commit_type \
3123 -variable selected_commit_type \
3124 -value new \
3125 -font font_ui
3126lappend disable_on_lock \
3127 [list .mbar.commit entryconf [.mbar.commit index last] -state]
3128.mbar.commit add radiobutton \
3130 -label {Amend Last Commit} \
3131 -command do_select_commit_type \
3132 -variable selected_commit_type \
3133 -value amend \
3134 -font font_ui
3135lappend disable_on_lock \
3136 [list .mbar.commit entryconf [.mbar.commit index last] -state]
3137.mbar.commit add separator
3139.mbar.commit add command -label Rescan \
3141 -command do_rescan \
3142 -accelerator F5 \
3143 -font font_ui
3144lappend disable_on_lock \
3145 [list .mbar.commit entryconf [.mbar.commit index last] -state]
3146.mbar.commit add command -label {Add To Commit} \
3148 -command do_include_selection \
3149 -font font_ui
3150lappend disable_on_lock \
3151 [list .mbar.commit entryconf [.mbar.commit index last] -state]
3152.mbar.commit add command -label {Add All To Commit} \
3154 -command do_include_all \
3155 -accelerator $M1T-I \
3156 -font font_ui
3157lappend disable_on_lock \
3158 [list .mbar.commit entryconf [.mbar.commit index last] -state]
3159.mbar.commit add command -label {Remove From Commit} \
3161 -command do_remove_selection \
3162 -font font_ui
3163lappend disable_on_lock \
3164 [list .mbar.commit entryconf [.mbar.commit index last] -state]
3165.mbar.commit add command -label {Revert Changes} \
3167 -command do_revert_selection \
3168 -font font_ui
3169lappend disable_on_lock \
3170 [list .mbar.commit entryconf [.mbar.commit index last] -state]
3171.mbar.commit add separator
3173.mbar.commit add command -label {Sign Off} \
3175 -command do_signoff \
3176 -accelerator $M1T-S \
3177 -font font_ui
3178.mbar.commit add command -label Commit \
3180 -command do_commit \
3181 -accelerator $M1T-Return \
3182 -font font_ui
3183lappend disable_on_lock \
3184 [list .mbar.commit entryconf [.mbar.commit index last] -state]
3185# -- Transport menus
3187#
3188if {!$single_commit} {
3189 menu .mbar.fetch
3190 menu .mbar.pull
3191 menu .mbar.push
3192}
3193if {[is_MacOSX]} {
3195 # -- Apple Menu (Mac OS X only)
3196 #
3197 .mbar add cascade -label Apple -menu .mbar.apple
3198 menu .mbar.apple
3199 .mbar.apple add command -label "About $appname" \
3201 -command do_about \
3202 -font font_ui
3203 .mbar.apple add command -label "$appname Options..." \
3204 -command do_options \
3205 -font font_ui
3206} else {
3207 # -- Edit Menu
3208 #
3209 .mbar.edit add separator
3210 .mbar.edit add command -label {Options...} \
3211 -command do_options \
3212 -font font_ui
3213 # -- Tools Menu
3215 #
3216 if {[file exists /usr/local/miga/lib/gui-miga]} {
3217 proc do_miga {} {
3218 global gitdir ui_status_value
3219 if {![lock_index update]} return
3220 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3221 set miga_fd [open "|$cmd" r]
3222 fconfigure $miga_fd -blocking 0
3223 fileevent $miga_fd readable [list miga_done $miga_fd]
3224 set ui_status_value {Running miga...}
3225 }
3226 proc miga_done {fd} {
3227 read $fd 512
3228 if {[eof $fd]} {
3229 close $fd
3230 unlock_index
3231 rescan [list set ui_status_value {Ready.}]
3232 }
3233 }
3234 .mbar add cascade -label Tools -menu .mbar.tools
3235 menu .mbar.tools
3236 .mbar.tools add command -label "Migrate" \
3237 -command do_miga \
3238 -font font_ui
3239 lappend disable_on_lock \
3240 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3241 }
3242 # -- Help Menu
3244 #
3245 .mbar add cascade -label Help -menu .mbar.help
3246 menu .mbar.help
3247 .mbar.help add command -label "About $appname" \
3249 -command do_about \
3250 -font font_ui
3251}
3252# -- Branch Control
3255#
3256frame .branch \
3257 -borderwidth 1 \
3258 -relief sunken
3259label .branch.l1 \
3260 -text {Current Branch:} \
3261 -anchor w \
3262 -justify left \
3263 -font font_ui
3264label .branch.cb \
3265 -textvariable current_branch \
3266 -anchor w \
3267 -justify left \
3268 -font font_ui
3269pack .branch.l1 -side left
3270pack .branch.cb -side left -fill x
3271pack .branch -side top -fill x
3272# -- Main Window Layout
3274#
3275panedwindow .vpane -orient vertical
3276panedwindow .vpane.files -orient horizontal
3277.vpane add .vpane.files -sticky nsew -height 100 -width 400
3278pack .vpane -anchor n -side top -fill both -expand 1
3279# -- Index File List
3281#
3282frame .vpane.files.index -height 100 -width 400
3283label .vpane.files.index.title -text {Modified Files} \
3284 -background green \
3285 -font font_ui
3286text $ui_index -background white -borderwidth 0 \
3287 -width 40 -height 10 \
3288 -font font_ui \
3289 -cursor $cursor_ptr \
3290 -yscrollcommand {.vpane.files.index.sb set} \
3291 -state disabled
3292scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3293pack .vpane.files.index.title -side top -fill x
3294pack .vpane.files.index.sb -side right -fill y
3295pack $ui_index -side left -fill both -expand 1
3296.vpane.files add .vpane.files.index -sticky nsew
3297# -- Other (Add) File List
3299#
3300frame .vpane.files.other -height 100 -width 100
3301label .vpane.files.other.title -text {Untracked Files} \
3302 -background red \
3303 -font font_ui
3304text $ui_other -background white -borderwidth 0 \
3305 -width 40 -height 10 \
3306 -font font_ui \
3307 -cursor $cursor_ptr \
3308 -yscrollcommand {.vpane.files.other.sb set} \
3309 -state disabled
3310scrollbar .vpane.files.other.sb -command [list $ui_other yview]
3311pack .vpane.files.other.title -side top -fill x
3312pack .vpane.files.other.sb -side right -fill y
3313pack $ui_other -side left -fill both -expand 1
3314.vpane.files add .vpane.files.other -sticky nsew
3315foreach i [list $ui_index $ui_other] {
3317 $i tag conf in_diff -font font_uibold
3318 $i tag conf in_sel \
3319 -background [$i cget -foreground] \
3320 -foreground [$i cget -background]
3321}
3322unset i
3323# -- Diff and Commit Area
3325#
3326frame .vpane.lower -height 300 -width 400
3327frame .vpane.lower.commarea
3328frame .vpane.lower.diff -relief sunken -borderwidth 1
3329pack .vpane.lower.commarea -side top -fill x
3330pack .vpane.lower.diff -side bottom -fill both -expand 1
3331.vpane add .vpane.lower -stick nsew
3332# -- Commit Area Buttons
3334#
3335frame .vpane.lower.commarea.buttons
3336label .vpane.lower.commarea.buttons.l -text {} \
3337 -anchor w \
3338 -justify left \
3339 -font font_ui
3340pack .vpane.lower.commarea.buttons.l -side top -fill x
3341pack .vpane.lower.commarea.buttons -side left -fill y
3342button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3344 -command do_rescan \
3345 -font font_ui
3346pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3347lappend disable_on_lock \
3348 {.vpane.lower.commarea.buttons.rescan conf -state}
3349button .vpane.lower.commarea.buttons.incall -text {Add All} \
3351 -command do_include_all \
3352 -font font_ui
3353pack .vpane.lower.commarea.buttons.incall -side top -fill x
3354lappend disable_on_lock \
3355 {.vpane.lower.commarea.buttons.incall conf -state}
3356button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3358 -command do_signoff \
3359 -font font_ui
3360pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3361button .vpane.lower.commarea.buttons.commit -text {Commit} \
3363 -command do_commit \
3364 -font font_ui
3365pack .vpane.lower.commarea.buttons.commit -side top -fill x
3366lappend disable_on_lock \
3367 {.vpane.lower.commarea.buttons.commit conf -state}
3368# -- Commit Message Buffer
3370#
3371frame .vpane.lower.commarea.buffer
3372frame .vpane.lower.commarea.buffer.header
3373set ui_comm .vpane.lower.commarea.buffer.t
3374set ui_coml .vpane.lower.commarea.buffer.header.l
3375radiobutton .vpane.lower.commarea.buffer.header.new \
3376 -text {New Commit} \
3377 -command do_select_commit_type \
3378 -variable selected_commit_type \
3379 -value new \
3380 -font font_ui
3381lappend disable_on_lock \
3382 [list .vpane.lower.commarea.buffer.header.new conf -state]
3383radiobutton .vpane.lower.commarea.buffer.header.amend \
3384 -text {Amend Last Commit} \
3385 -command do_select_commit_type \
3386 -variable selected_commit_type \
3387 -value amend \
3388 -font font_ui
3389lappend disable_on_lock \
3390 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3391label $ui_coml \
3392 -anchor w \
3393 -justify left \
3394 -font font_ui
3395proc trace_commit_type {varname args} {
3396 global ui_coml commit_type
3397 switch -glob -- $commit_type {
3398 initial {set txt {Initial Commit Message:}}
3399 amend {set txt {Amended Commit Message:}}
3400 amend-initial {set txt {Amended Initial Commit Message:}}
3401 amend-merge {set txt {Amended Merge Commit Message:}}
3402 merge {set txt {Merge Commit Message:}}
3403 * {set txt {Commit Message:}}
3404 }
3405 $ui_coml conf -text $txt
3406}
3407trace add variable commit_type write trace_commit_type
3408pack $ui_coml -side left -fill x
3409pack .vpane.lower.commarea.buffer.header.amend -side right
3410pack .vpane.lower.commarea.buffer.header.new -side right
3411text $ui_comm -background white -borderwidth 1 \
3413 -undo true \
3414 -maxundo 20 \
3415 -autoseparators true \
3416 -relief sunken \
3417 -width 75 -height 9 -wrap none \
3418 -font font_diff \
3419 -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3420scrollbar .vpane.lower.commarea.buffer.sby \
3421 -command [list $ui_comm yview]
3422pack .vpane.lower.commarea.buffer.header -side top -fill x
3423pack .vpane.lower.commarea.buffer.sby -side right -fill y
3424pack $ui_comm -side left -fill y
3425pack .vpane.lower.commarea.buffer -side left -fill y
3426# -- Commit Message Buffer Context Menu
3428#
3429set ctxm .vpane.lower.commarea.buffer.ctxm
3430menu $ctxm -tearoff 0
3431$ctxm add command \
3432 -label {Cut} \
3433 -font font_ui \
3434 -command {tk_textCut $ui_comm}
3435$ctxm add command \
3436 -label {Copy} \
3437 -font font_ui \
3438 -command {tk_textCopy $ui_comm}
3439$ctxm add command \
3440 -label {Paste} \
3441 -font font_ui \
3442 -command {tk_textPaste $ui_comm}
3443$ctxm add command \
3444 -label {Delete} \
3445 -font font_ui \
3446 -command {$ui_comm delete sel.first sel.last}
3447$ctxm add separator
3448$ctxm add command \
3449 -label {Select All} \
3450 -font font_ui \
3451 -command {$ui_comm tag add sel 0.0 end}
3452$ctxm add command \
3453 -label {Copy All} \
3454 -font font_ui \
3455 -command {
3456 $ui_comm tag add sel 0.0 end
3457 tk_textCopy $ui_comm
3458 $ui_comm tag remove sel 0.0 end
3459 }
3460$ctxm add separator
3461$ctxm add command \
3462 -label {Sign Off} \
3463 -font font_ui \
3464 -command do_signoff
3465bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3466# -- Diff Header
3468#
3469set current_diff {}
3470set diff_actions [list]
3471proc trace_current_diff {varname args} {
3472 global current_diff diff_actions file_states
3473 if {$current_diff eq {}} {
3474 set s {}
3475 set f {}
3476 set p {}
3477 set o disabled
3478 } else {
3479 set p $current_diff
3480 set s [mapdesc [lindex $file_states($p) 0] $p]
3481 set f {File:}
3482 set p [escape_path $p]
3483 set o normal
3484 }
3485 .vpane.lower.diff.header.status configure -text $s
3487 .vpane.lower.diff.header.file configure -text $f
3488 .vpane.lower.diff.header.path configure -text $p
3489 foreach w $diff_actions {
3490 uplevel #0 $w $o
3491 }
3492}
3493trace add variable current_diff write trace_current_diff
3494frame .vpane.lower.diff.header -background orange
3496label .vpane.lower.diff.header.status \
3497 -background orange \
3498 -width $max_status_desc \
3499 -anchor w \
3500 -justify left \
3501 -font font_ui
3502label .vpane.lower.diff.header.file \
3503 -background orange \
3504 -anchor w \
3505 -justify left \
3506 -font font_ui
3507label .vpane.lower.diff.header.path \
3508 -background orange \
3509 -anchor w \
3510 -justify left \
3511 -font font_ui
3512pack .vpane.lower.diff.header.status -side left
3513pack .vpane.lower.diff.header.file -side left
3514pack .vpane.lower.diff.header.path -fill x
3515set ctxm .vpane.lower.diff.header.ctxm
3516menu $ctxm -tearoff 0
3517$ctxm add command \
3518 -label {Copy} \
3519 -font font_ui \
3520 -command {
3521 clipboard clear
3522 clipboard append \
3523 -format STRING \
3524 -type STRING \
3525 -- $current_diff
3526 }
3527lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3528bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3529# -- Diff Body
3531#
3532frame .vpane.lower.diff.body
3533set ui_diff .vpane.lower.diff.body.t
3534text $ui_diff -background white -borderwidth 0 \
3535 -width 80 -height 15 -wrap none \
3536 -font font_diff \
3537 -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3538 -yscrollcommand {.vpane.lower.diff.body.sby set} \
3539 -state disabled
3540scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3541 -command [list $ui_diff xview]
3542scrollbar .vpane.lower.diff.body.sby -orient vertical \
3543 -command [list $ui_diff yview]
3544pack .vpane.lower.diff.body.sbx -side bottom -fill x
3545pack .vpane.lower.diff.body.sby -side right -fill y
3546pack $ui_diff -side left -fill both -expand 1
3547pack .vpane.lower.diff.header -side top -fill x
3548pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3549$ui_diff tag conf d_@ -font font_diffbold
3551$ui_diff tag conf d_+ -foreground blue
3552$ui_diff tag conf d_- -foreground red
3553$ui_diff tag conf d_++ -foreground {#00a000}
3554$ui_diff tag conf d_-- -foreground {#a000a0}
3555$ui_diff tag conf d_+- \
3556 -foreground red \
3557 -background {light goldenrod yellow}
3558$ui_diff tag conf d_-+ \
3559 -foreground blue \
3560 -background azure2
3561# -- Diff Body Context Menu
3563#
3564set ctxm .vpane.lower.diff.body.ctxm
3565menu $ctxm -tearoff 0
3566$ctxm add command \
3567 -label {Copy} \
3568 -font font_ui \
3569 -command {tk_textCopy $ui_diff}
3570lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3571$ctxm add command \
3572 -label {Select All} \
3573 -font font_ui \
3574 -command {$ui_diff tag add sel 0.0 end}
3575lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3576$ctxm add command \
3577 -label {Copy All} \
3578 -font font_ui \
3579 -command {
3580 $ui_diff tag add sel 0.0 end
3581 tk_textCopy $ui_diff
3582 $ui_diff tag remove sel 0.0 end
3583 }
3584lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3585$ctxm add separator
3586$ctxm add command \
3587 -label {Decrease Font Size} \
3588 -font font_ui \
3589 -command {incr_font_size font_diff -1}
3590lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3591$ctxm add command \
3592 -label {Increase Font Size} \
3593 -font font_ui \
3594 -command {incr_font_size font_diff 1}
3595lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3596$ctxm add separator
3597$ctxm add command \
3598 -label {Show Less Context} \
3599 -font font_ui \
3600 -command {if {$repo_config(gui.diffcontext) >= 2} {
3601 incr repo_config(gui.diffcontext) -1
3602 reshow_diff
3603 }}
3604lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3605$ctxm add command \
3606 -label {Show More Context} \
3607 -font font_ui \
3608 -command {
3609 incr repo_config(gui.diffcontext)
3610 reshow_diff
3611 }
3612lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3613$ctxm add separator
3614$ctxm add command -label {Options...} \
3615 -font font_ui \
3616 -command do_options
3617bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3618# -- Status Bar
3620#
3621set ui_status_value {Initializing...}
3622label .status -textvariable ui_status_value \
3623 -anchor w \
3624 -justify left \
3625 -borderwidth 1 \
3626 -relief sunken \
3627 -font font_ui
3628pack .status -anchor w -side bottom -fill x
3629# -- Load geometry
3631#
3632catch {
3633set gm $repo_config(gui.geometry)
3634wm geometry . [lindex $gm 0]
3635.vpane sash place 0 \
3636 [lindex [.vpane sash coord 0] 0] \
3637 [lindex $gm 1]
3638.vpane.files sash place 0 \
3639 [lindex $gm 2] \
3640 [lindex [.vpane.files sash coord 0] 1]
3641unset gm
3642}
3643# -- Key Bindings
3645#
3646bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3647bind $ui_comm <$M1B-Key-i> {do_include_all;break}
3648bind $ui_comm <$M1B-Key-I> {do_include_all;break}
3649bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3650bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3651bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3652bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3653bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3654bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3655bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3656bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3657bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3659bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3660bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3661bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3662bind $ui_diff <$M1B-Key-v> {break}
3663bind $ui_diff <$M1B-Key-V> {break}
3664bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3665bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3666bind $ui_diff <Key-Up> {catch {%W yview scroll -1 units};break}
3667bind $ui_diff <Key-Down> {catch {%W yview scroll 1 units};break}
3668bind $ui_diff <Key-Left> {catch {%W xview scroll -1 units};break}
3669bind $ui_diff <Key-Right> {catch {%W xview scroll 1 units};break}
3670bind . <Destroy> do_quit
3672bind all <Key-F5> do_rescan
3673bind all <$M1B-Key-r> do_rescan
3674bind all <$M1B-Key-R> do_rescan
3675bind . <$M1B-Key-s> do_signoff
3676bind . <$M1B-Key-S> do_signoff
3677bind . <$M1B-Key-i> do_include_all
3678bind . <$M1B-Key-I> do_include_all
3679bind . <$M1B-Key-Return> do_commit
3680bind all <$M1B-Key-q> do_quit
3681bind all <$M1B-Key-Q> do_quit
3682bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3683bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3684foreach i [list $ui_index $ui_other] {
3685 bind $i <Button-1> "toggle_or_diff $i %x %y; break"
3686 bind $i <$M1B-Button-1> "add_one_to_selection $i %x %y; break"
3687 bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3688}
3689unset i
3690set file_lists($ui_index) [list]
3692set file_lists($ui_other) [list]
3693set HEAD {}
3695set PARENT {}
3696set MERGE_HEAD [list]
3697set commit_type {}
3698set empty_tree {}
3699set current_branch {}
3700set current_diff {}
3701set selected_commit_type new
3702wm title . "$appname ([file normalize [file dirname $gitdir]])"
3704focus -force $ui_comm
3705# -- Warn the user about environmental problems. Cygwin's Tcl
3707# does *not* pass its env array onto any processes it spawns.
3708# This means that git processes get none of our environment.
3709#
3710if {[is_Windows]} {
3711 set ignored_env 0
3712 set suggest_user {}
3713 set msg "Possible environment issues exist.
3714The following environment variables are probably
3716going to be ignored by any Git subprocess run
3717by $appname:
3718"
3720 foreach name [array names env] {
3721 switch -regexp -- $name {
3722 {^GIT_INDEX_FILE$} -
3723 {^GIT_OBJECT_DIRECTORY$} -
3724 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3725 {^GIT_DIFF_OPTS$} -
3726 {^GIT_EXTERNAL_DIFF$} -
3727 {^GIT_PAGER$} -
3728 {^GIT_TRACE$} -
3729 {^GIT_CONFIG$} -
3730 {^GIT_CONFIG_LOCAL$} -
3731 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3732 append msg " - $name\n"
3733 incr ignored_env
3734 }
3735 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3736 append msg " - $name\n"
3737 incr ignored_env
3738 set suggest_user $name
3739 }
3740 }
3741 }
3742 if {$ignored_env > 0} {
3743 append msg "
3744This is due to a known issue with the
3745Tcl binary distributed by Cygwin."
3746 if {$suggest_user ne {}} {
3748 append msg "
3749A good replacement for $suggest_user
3751is placing values for the user.name and
3752user.email settings into your personal
3753~/.gitconfig file.
3754"
3755 }
3756 warn_popup $msg
3757 }
3758 unset ignored_env msg suggest_user name
3759}
3760# -- Only initialize complex UI if we are going to stay running.
3762#
3763if {!$single_commit} {
3764 load_all_remotes
3765 load_all_heads
3766 populate_branch_menu .mbar.branch
3768 populate_fetch_menu .mbar.fetch
3769 populate_pull_menu .mbar.pull
3770 populate_push_menu .mbar.push
3771}
3772lock_index begin-read
3774after 1 do_rescan