Andrew's git / gitweb.git / contrib/emacs/git.el
?
contrib / emacs / git.elon commit git.el: Allow the add and remove commands to be applied to ignored files. (568d2cd)
   1;;; git.el --- A user interface for git
   2
   3;; Copyright (C) 2005, 2006, 2007 Alexandre Julliard <julliard@winehq.org>
   4
   5;; Version: 1.0
   6
   7;; This program is free software; you can redistribute it and/or
   8;; modify it under the terms of the GNU General Public License as
   9;; published by the Free Software Foundation; either version 2 of
  10;; the License, or (at your option) any later version.
  11;;
  12;; This program is distributed in the hope that it will be
  13;; useful, but WITHOUT ANY WARRANTY; without even the implied
  14;; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15;; PURPOSE.  See the GNU General Public License for more details.
  16;;
  17;; You should have received a copy of the GNU General Public
  18;; License along with this program; if not, write to the Free
  19;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20;; MA 02111-1307 USA
  21
  22;;; Commentary:
  23
  24;; This file contains an interface for the git version control
  25;; system. It provides easy access to the most frequently used git
  26;; commands. The user interface is as far as possible identical to
  27;; that of the PCL-CVS mode.
  28;;
  29;; To install: put this file on the load-path and place the following
  30;; in your .emacs file:
  31;;
  32;;    (require 'git)
  33;;
  34;; To start: `M-x git-status'
  35;;
  36;; TODO
  37;;  - portability to XEmacs
  38;;  - better handling of subprocess errors
  39;;  - hook into file save (after-save-hook)
  40;;  - diff against other branch
  41;;  - renaming files from the status buffer
  42;;  - creating tags
  43;;  - fetch/pull
  44;;  - switching branches
  45;;  - revlist browser
  46;;  - git-show-branch browser
  47;;  - menus
  48;;
  49
  50(eval-when-compile (require 'cl))
  51(require 'ewoc)
  52(require 'log-edit)
  53
  54
  55;;;; Customizations
  56;;;; ------------------------------------------------------------
  57
  58(defgroup git nil
  59  "A user interface for the git versioning system."
  60  :group 'tools)
  61
  62(defcustom git-committer-name nil
  63  "User name to use for commits.
  64The default is to fall back to the repository config,
  65then to `add-log-full-name' and then to `user-full-name'."
  66  :group 'git
  67  :type '(choice (const :tag "Default" nil)
  68                 (string :tag "Name")))
  69
  70(defcustom git-committer-email nil
  71  "Email address to use for commits.
  72The default is to fall back to the git repository config,
  73then to `add-log-mailing-address' and then to `user-mail-address'."
  74  :group 'git
  75  :type '(choice (const :tag "Default" nil)
  76                 (string :tag "Email")))
  77
  78(defcustom git-commits-coding-system nil
  79  "Default coding system for the log message of git commits."
  80  :group 'git
  81  :type '(choice (const :tag "From repository config" nil)
  82                 (coding-system)))
  83
  84(defcustom git-append-signed-off-by nil
  85  "Whether to append a Signed-off-by line to the commit message before editing."
  86  :group 'git
  87  :type 'boolean)
  88
  89(defcustom git-reuse-status-buffer t
  90  "Whether `git-status' should try to reuse an existing buffer
  91if there is already one that displays the same directory."
  92  :group 'git
  93  :type 'boolean)
  94
  95(defcustom git-per-dir-ignore-file ".gitignore"
  96  "Name of the per-directory ignore file."
  97  :group 'git
  98  :type 'string)
  99
 100(defcustom git-show-uptodate nil
 101  "Whether to display up-to-date files."
 102  :group 'git
 103  :type 'boolean)
 104
 105(defcustom git-show-ignored nil
 106  "Whether to display ignored files."
 107  :group 'git
 108  :type 'boolean)
 109
 110(defcustom git-show-unknown t
 111  "Whether to display unknown files."
 112  :group 'git
 113  :type 'boolean)
 114
 115
 116(defface git-status-face
 117  '((((class color) (background light)) (:foreground "purple"))
 118    (((class color) (background dark)) (:foreground "salmon")))
 119  "Git mode face used to highlight added and modified files."
 120  :group 'git)
 121
 122(defface git-unmerged-face
 123  '((((class color) (background light)) (:foreground "red" :bold t))
 124    (((class color) (background dark)) (:foreground "red" :bold t)))
 125  "Git mode face used to highlight unmerged files."
 126  :group 'git)
 127
 128(defface git-unknown-face
 129  '((((class color) (background light)) (:foreground "goldenrod" :bold t))
 130    (((class color) (background dark)) (:foreground "goldenrod" :bold t)))
 131  "Git mode face used to highlight unknown files."
 132  :group 'git)
 133
 134(defface git-uptodate-face
 135  '((((class color) (background light)) (:foreground "grey60"))
 136    (((class color) (background dark)) (:foreground "grey40")))
 137  "Git mode face used to highlight up-to-date files."
 138  :group 'git)
 139
 140(defface git-ignored-face
 141  '((((class color) (background light)) (:foreground "grey60"))
 142    (((class color) (background dark)) (:foreground "grey40")))
 143  "Git mode face used to highlight ignored files."
 144  :group 'git)
 145
 146(defface git-mark-face
 147  '((((class color) (background light)) (:foreground "red" :bold t))
 148    (((class color) (background dark)) (:foreground "tomato" :bold t)))
 149  "Git mode face used for the file marks."
 150  :group 'git)
 151
 152(defface git-header-face
 153  '((((class color) (background light)) (:foreground "blue"))
 154    (((class color) (background dark)) (:foreground "blue")))
 155  "Git mode face used for commit headers."
 156  :group 'git)
 157
 158(defface git-separator-face
 159  '((((class color) (background light)) (:foreground "brown"))
 160    (((class color) (background dark)) (:foreground "brown")))
 161  "Git mode face used for commit separator."
 162  :group 'git)
 163
 164(defface git-permission-face
 165  '((((class color) (background light)) (:foreground "green" :bold t))
 166    (((class color) (background dark)) (:foreground "green" :bold t)))
 167  "Git mode face used for permission changes."
 168  :group 'git)
 169
 170
 171;;;; Utilities
 172;;;; ------------------------------------------------------------
 173
 174(defconst git-log-msg-separator "--- log message follows this line ---")
 175
 176(defvar git-log-edit-font-lock-keywords
 177  `(("^\\(Author:\\|Date:\\|Parent:\\|Signed-off-by:\\)\\(.*\\)$"
 178     (1 font-lock-keyword-face)
 179     (2 font-lock-function-name-face))
 180    (,(concat "^\\(" (regexp-quote git-log-msg-separator) "\\)$")
 181     (1 font-lock-comment-face))))
 182
 183(defun git-get-env-strings (env)
 184  "Build a list of NAME=VALUE strings from a list of environment strings."
 185  (mapcar (lambda (entry) (concat (car entry) "=" (cdr entry))) env))
 186
 187(defun git-call-process-env (buffer env &rest args)
 188  "Wrapper for call-process that sets environment strings."
 189  (if env
 190      (apply #'call-process "env" nil buffer nil
 191             (append (git-get-env-strings env) (list "git") args))
 192    (apply #'call-process "git" nil buffer nil args)))
 193
 194(defun git-call-process-env-string (env &rest args)
 195  "Wrapper for call-process that sets environment strings,
 196and returns the process output as a string."
 197  (with-temp-buffer
 198    (and (eq 0 (apply #' git-call-process-env t env args))
 199         (buffer-string))))
 200
 201(defun git-run-process-region (buffer start end program args)
 202  "Run a git process with a buffer region as input."
 203  (let ((output-buffer (current-buffer))
 204        (dir default-directory))
 205    (with-current-buffer buffer
 206      (cd dir)
 207      (apply #'call-process-region start end program
 208             nil (list output-buffer nil) nil args))))
 209
 210(defun git-run-command-buffer (buffer-name &rest args)
 211  "Run a git command, sending the output to a buffer named BUFFER-NAME."
 212  (let ((dir default-directory)
 213        (buffer (get-buffer-create buffer-name)))
 214    (message "Running git %s..." (car args))
 215    (with-current-buffer buffer
 216      (let ((default-directory dir)
 217            (buffer-read-only nil))
 218        (erase-buffer)
 219        (apply #'git-call-process-env buffer nil args)))
 220    (message "Running git %s...done" (car args))
 221    buffer))
 222
 223(defun git-run-command (buffer env &rest args)
 224  (message "Running git %s..." (car args))
 225  (apply #'git-call-process-env buffer env args)
 226  (message "Running git %s...done" (car args)))
 227
 228(defun git-run-command-region (buffer start end env &rest args)
 229  "Run a git command with specified buffer region as input."
 230  (message "Running git %s..." (car args))
 231  (unless (eq 0 (if env
 232                    (git-run-process-region
 233                     buffer start end "env"
 234                     (append (git-get-env-strings env) (list "git") args))
 235                  (git-run-process-region
 236                   buffer start end "git" args)))
 237    (error "Failed to run \"git %s\":\n%s" (mapconcat (lambda (x) x) args " ") (buffer-string)))
 238  (message "Running git %s...done" (car args)))
 239
 240(defun git-run-hook (hook env &rest args)
 241  "Run a git hook and display its output if any."
 242  (let ((dir default-directory)
 243        (hook-name (expand-file-name (concat ".git/hooks/" hook))))
 244    (or (not (file-executable-p hook-name))
 245        (let (status (buffer (get-buffer-create "*Git Hook Output*")))
 246          (with-current-buffer buffer
 247            (erase-buffer)
 248            (cd dir)
 249            (setq status
 250                  (if env
 251                      (apply #'call-process "env" nil (list buffer t) nil
 252                             (append (git-get-env-strings env) (list hook-name) args))
 253                    (apply #'call-process hook-name nil (list buffer t) nil args))))
 254          (display-message-or-buffer buffer)
 255          (eq 0 status)))))
 256
 257(defun git-get-string-sha1 (string)
 258  "Read a SHA1 from the specified string."
 259  (and string
 260       (string-match "[0-9a-f]\\{40\\}" string)
 261       (match-string 0 string)))
 262
 263(defun git-get-committer-name ()
 264  "Return the name to use as GIT_COMMITTER_NAME."
 265  ; copied from log-edit
 266  (or git-committer-name
 267      (git-config "user.name")
 268      (and (boundp 'add-log-full-name) add-log-full-name)
 269      (and (fboundp 'user-full-name) (user-full-name))
 270      (and (boundp 'user-full-name) user-full-name)))
 271
 272(defun git-get-committer-email ()
 273  "Return the email address to use as GIT_COMMITTER_EMAIL."
 274  ; copied from log-edit
 275  (or git-committer-email
 276      (git-config "user.email")
 277      (and (boundp 'add-log-mailing-address) add-log-mailing-address)
 278      (and (fboundp 'user-mail-address) (user-mail-address))
 279      (and (boundp 'user-mail-address) user-mail-address)))
 280
 281(defun git-get-commits-coding-system ()
 282  "Return the coding system to use for commits."
 283  (let ((repo-config (git-config "i18n.commitencoding")))
 284    (or git-commits-coding-system
 285        (and repo-config
 286             (fboundp 'locale-charset-to-coding-system)
 287             (locale-charset-to-coding-system repo-config))
 288      'utf-8)))
 289
 290(defun git-get-logoutput-coding-system ()
 291  "Return the coding system used for git-log output."
 292  (let ((repo-config (or (git-config "i18n.logoutputencoding")
 293                         (git-config "i18n.commitencoding"))))
 294    (or git-commits-coding-system
 295        (and repo-config
 296             (fboundp 'locale-charset-to-coding-system)
 297             (locale-charset-to-coding-system repo-config))
 298      'utf-8)))
 299
 300(defun git-escape-file-name (name)
 301  "Escape a file name if necessary."
 302  (if (string-match "[\n\t\"\\]" name)
 303      (concat "\""
 304              (mapconcat (lambda (c)
 305                   (case c
 306                     (?\n "\\n")
 307                     (?\t "\\t")
 308                     (?\\ "\\\\")
 309                     (?\" "\\\"")
 310                     (t (char-to-string c))))
 311                 name "")
 312              "\"")
 313    name))
 314
 315(defun git-get-top-dir (dir)
 316  "Retrieve the top-level directory of a git tree."
 317  (let ((cdup (with-output-to-string
 318                (with-current-buffer standard-output
 319                  (cd dir)
 320                  (unless (eq 0 (call-process "git" nil t nil "rev-parse" "--show-cdup"))
 321                    (error "cannot find top-level git tree for %s." dir))))))
 322    (expand-file-name (concat (file-name-as-directory dir)
 323                              (car (split-string cdup "\n"))))))
 324
 325;stolen from pcl-cvs
 326(defun git-append-to-ignore (file)
 327  "Add a file name to the ignore file in its directory."
 328  (let* ((fullname (expand-file-name file))
 329         (dir (file-name-directory fullname))
 330         (name (file-name-nondirectory fullname))
 331         (ignore-name (expand-file-name git-per-dir-ignore-file dir))
 332         (created (not (file-exists-p ignore-name))))
 333  (save-window-excursion
 334    (set-buffer (find-file-noselect ignore-name))
 335    (goto-char (point-max))
 336    (unless (zerop (current-column)) (insert "\n"))
 337    (insert "/" name "\n")
 338    (sort-lines nil (point-min) (point-max))
 339    (save-buffer))
 340  (when created
 341    (git-run-command nil nil "update-index" "--add" "--" (file-relative-name ignore-name)))
 342  (git-update-status-files (list (file-relative-name ignore-name)) 'unknown)))
 343
 344; propertize definition for XEmacs, stolen from erc-compat
 345(eval-when-compile
 346  (unless (fboundp 'propertize)
 347    (defun propertize (string &rest props)
 348      (let ((string (copy-sequence string)))
 349        (while props
 350          (put-text-property 0 (length string) (nth 0 props) (nth 1 props) string)
 351          (setq props (cddr props)))
 352        string))))
 353
 354;;;; Wrappers for basic git commands
 355;;;; ------------------------------------------------------------
 356
 357(defun git-rev-parse (rev)
 358  "Parse a revision name and return its SHA1."
 359  (git-get-string-sha1
 360   (git-call-process-env-string nil "rev-parse" rev)))
 361
 362(defun git-config (key)
 363  "Retrieve the value associated to KEY in the git repository config file."
 364  (let ((str (git-call-process-env-string nil "config" key)))
 365    (and str (car (split-string str "\n")))))
 366
 367(defun git-symbolic-ref (ref)
 368  "Wrapper for the git-symbolic-ref command."
 369  (let ((str (git-call-process-env-string nil "symbolic-ref" ref)))
 370    (and str (car (split-string str "\n")))))
 371
 372(defun git-update-ref (ref newval &optional oldval reason)
 373  "Update a reference by calling git-update-ref."
 374  (let ((args (and oldval (list oldval))))
 375    (push newval args)
 376    (push ref args)
 377    (when reason
 378     (push reason args)
 379     (push "-m" args))
 380    (eq 0 (apply #'git-call-process-env nil nil "update-ref" args))))
 381
 382(defun git-read-tree (tree &optional index-file)
 383  "Read a tree into the index file."
 384  (apply #'git-call-process-env nil
 385         (if index-file `(("GIT_INDEX_FILE" . ,index-file)) nil)
 386         "read-tree" (if tree (list tree))))
 387
 388(defun git-write-tree (&optional index-file)
 389  "Call git-write-tree and return the resulting tree SHA1 as a string."
 390  (git-get-string-sha1
 391   (git-call-process-env-string (and index-file `(("GIT_INDEX_FILE" . ,index-file))) "write-tree")))
 392
 393(defun git-commit-tree (buffer tree head)
 394  "Call git-commit-tree with buffer as input and return the resulting commit SHA1."
 395  (let ((author-name (git-get-committer-name))
 396        (author-email (git-get-committer-email))
 397        (subject "commit (initial): ")
 398        author-date log-start log-end args coding-system-for-write)
 399    (when head
 400      (setq subject "commit: ")
 401      (push "-p" args)
 402      (push head args))
 403    (with-current-buffer buffer
 404      (goto-char (point-min))
 405      (if
 406          (setq log-start (re-search-forward (concat "^" (regexp-quote git-log-msg-separator) "\n") nil t))
 407          (save-restriction
 408            (narrow-to-region (point-min) log-start)
 409            (goto-char (point-min))
 410            (when (re-search-forward "^Author: +\\(.*?\\) *<\\(.*\\)> *$" nil t)
 411              (setq author-name (match-string 1)
 412                    author-email (match-string 2)))
 413            (goto-char (point-min))
 414            (when (re-search-forward "^Date: +\\(.*\\)$" nil t)
 415              (setq author-date (match-string 1)))
 416            (goto-char (point-min))
 417            (while (re-search-forward "^Parent: +\\([0-9a-f]+\\)" nil t)
 418              (unless (string-equal head (match-string 1))
 419                (setq subject "commit (merge): ")
 420                (push "-p" args)
 421                (push (match-string 1) args))))
 422        (setq log-start (point-min)))
 423      (setq log-end (point-max))
 424      (goto-char log-start)
 425      (when (re-search-forward ".*$" nil t)
 426        (setq subject (concat subject (match-string 0))))
 427      (setq coding-system-for-write buffer-file-coding-system))
 428    (let ((commit
 429           (git-get-string-sha1
 430            (with-output-to-string
 431              (with-current-buffer standard-output
 432                (let ((env `(("GIT_AUTHOR_NAME" . ,author-name)
 433                             ("GIT_AUTHOR_EMAIL" . ,author-email)
 434                             ("GIT_COMMITTER_NAME" . ,(git-get-committer-name))
 435                             ("GIT_COMMITTER_EMAIL" . ,(git-get-committer-email)))))
 436                  (when author-date (push `("GIT_AUTHOR_DATE" . ,author-date) env))
 437                  (apply #'git-run-command-region
 438                         buffer log-start log-end env
 439                         "commit-tree" tree (nreverse args))))))))
 440      (and (git-update-ref "HEAD" commit head subject)
 441           commit))))
 442
 443(defun git-empty-db-p ()
 444  "Check if the git db is empty (no commit done yet)."
 445  (not (eq 0 (call-process "git" nil nil nil "rev-parse" "--verify" "HEAD"))))
 446
 447(defun git-get-merge-heads ()
 448  "Retrieve the merge heads from the MERGE_HEAD file if present."
 449  (let (heads)
 450    (when (file-readable-p ".git/MERGE_HEAD")
 451      (with-temp-buffer
 452        (insert-file-contents ".git/MERGE_HEAD" nil nil nil t)
 453        (goto-char (point-min))
 454        (while (re-search-forward "[0-9a-f]\\{40\\}" nil t)
 455          (push (match-string 0) heads))))
 456    (nreverse heads)))
 457
 458(defun git-get-commit-description (commit)
 459  "Get a one-line description of COMMIT."
 460  (let ((coding-system-for-read (git-get-logoutput-coding-system)))
 461    (let ((descr (git-call-process-env-string nil "log" "--max-count=1" "--pretty=oneline" commit)))
 462      (if (and descr (string-match "\\`\\([0-9a-f]\\{40\\}\\) *\\(.*\\)$" descr))
 463          (concat (substring (match-string 1 descr) 0 10) " - " (match-string 2 descr))
 464        descr))))
 465
 466;;;; File info structure
 467;;;; ------------------------------------------------------------
 468
 469; fileinfo structure stolen from pcl-cvs
 470(defstruct (git-fileinfo
 471            (:copier nil)
 472            (:constructor git-create-fileinfo (state name &optional old-perm new-perm rename-state orig-name marked))
 473            (:conc-name git-fileinfo->))
 474  marked              ;; t/nil
 475  state               ;; current state
 476  name                ;; file name
 477  old-perm new-perm   ;; permission flags
 478  rename-state        ;; rename or copy state
 479  orig-name           ;; original name for renames or copies
 480  needs-refresh)      ;; whether file needs to be refreshed
 481
 482(defvar git-status nil)
 483
 484(defun git-clear-status (status)
 485  "Remove everything from the status list."
 486  (ewoc-filter status (lambda (info) nil)))
 487
 488(defun git-set-files-state (files state)
 489  "Set the state of a list of files."
 490  (dolist (info files)
 491    (unless (eq (git-fileinfo->state info) state)
 492      (setf (git-fileinfo->state info) state)
 493      (setf (git-fileinfo->rename-state info) nil)
 494      (setf (git-fileinfo->orig-name info) nil)
 495      (setf (git-fileinfo->needs-refresh info) t))))
 496
 497(defun git-set-filenames-state (status files state)
 498  "Set the state of a list of named files."
 499  (when files
 500    (setq files (sort files #'string-lessp))
 501    (let ((file (pop files))
 502          (node (ewoc-nth status 0)))
 503      (while (and file node)
 504        (let ((info (ewoc-data node)))
 505          (cond ((string-lessp (git-fileinfo->name info) file)
 506                 (setq node (ewoc-next status node)))
 507                ((string-equal (git-fileinfo->name info) file)
 508                 (unless (eq (git-fileinfo->state info) state)
 509                   (setf (git-fileinfo->state info) state)
 510                   (setf (git-fileinfo->rename-state info) nil)
 511                   (setf (git-fileinfo->orig-name info) nil)
 512                   (setf (git-fileinfo->needs-refresh info) t))
 513                 (setq file (pop files)))
 514                (t (setq file (pop files)))))))
 515    (unless state  ;; delete files whose state has been set to nil
 516      (ewoc-filter status (lambda (info) (git-fileinfo->state info))))))
 517
 518(defun git-state-code (code)
 519  "Convert from a string to a added/deleted/modified state."
 520  (case (string-to-char code)
 521    (?M 'modified)
 522    (?? 'unknown)
 523    (?A 'added)
 524    (?D 'deleted)
 525    (?U 'unmerged)
 526    (t nil)))
 527
 528(defun git-status-code-as-string (code)
 529  "Format a git status code as string."
 530  (case code
 531    ('modified (propertize "Modified" 'face 'git-status-face))
 532    ('unknown  (propertize "Unknown " 'face 'git-unknown-face))
 533    ('added    (propertize "Added   " 'face 'git-status-face))
 534    ('deleted  (propertize "Deleted " 'face 'git-status-face))
 535    ('unmerged (propertize "Unmerged" 'face 'git-unmerged-face))
 536    ('uptodate (propertize "Uptodate" 'face 'git-uptodate-face))
 537    ('ignored  (propertize "Ignored " 'face 'git-ignored-face))
 538    (t "?       ")))
 539
 540(defun git-rename-as-string (info)
 541  "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 542  (let ((state (git-fileinfo->rename-state info)))
 543    (if state
 544        (propertize
 545         (concat "   ("
 546                 (if (eq state 'copy) "copied from "
 547                   (if (eq (git-fileinfo->state info) 'added) "renamed from "
 548                     "renamed to "))
 549                 (git-escape-file-name (git-fileinfo->orig-name info))
 550                 ")") 'face 'git-status-face)
 551      "")))
 552
 553(defun git-permissions-as-string (old-perm new-perm)
 554  "Format a permission change as string."
 555  (propertize
 556   (if (or (not old-perm)
 557           (not new-perm)
 558           (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 559       "  "
 560     (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 561  'face 'git-permission-face))
 562
 563(defun git-fileinfo-prettyprint (info)
 564  "Pretty-printer for the git-fileinfo structure."
 565  (insert (concat "   " (if (git-fileinfo->marked info) (propertize "*" 'face 'git-mark-face) " ")
 566                  " " (git-status-code-as-string (git-fileinfo->state info))
 567                  " " (git-permissions-as-string (git-fileinfo->old-perm info) (git-fileinfo->new-perm info))
 568                  "  " (git-escape-file-name (git-fileinfo->name info))
 569                  (git-rename-as-string info))))
 570
 571(defun git-insert-info-list (status infolist)
 572  "Insert a list of file infos in the status buffer, replacing existing ones if any."
 573  (setq infolist (sort infolist
 574                       (lambda (info1 info2)
 575                         (string-lessp (git-fileinfo->name info1)
 576                                       (git-fileinfo->name info2)))))
 577  (let ((info (pop infolist))
 578        (node (ewoc-nth status 0)))
 579    (while info
 580      (setf (git-fileinfo->needs-refresh info) t)
 581      (cond ((not node)
 582             (ewoc-enter-last status info)
 583             (setq info (pop infolist)))
 584            ((string-lessp (git-fileinfo->name (ewoc-data node))
 585                           (git-fileinfo->name info))
 586             (setq node (ewoc-next status node)))
 587            ((string-equal (git-fileinfo->name (ewoc-data node))
 588                           (git-fileinfo->name info))
 589              ;; preserve the marked flag
 590              (setf (git-fileinfo->marked info) (git-fileinfo->marked (ewoc-data node)))
 591              (setf (ewoc-data node) info)
 592              (setq info (pop infolist)))
 593            (t
 594             (ewoc-enter-before status node info)
 595             (setq info (pop infolist)))))))
 596
 597(defun git-run-diff-index (status files)
 598  "Run git-diff-index on FILES and parse the results into STATUS.
 599Return the list of files that haven't been handled."
 600  (let (infolist)
 601    (with-temp-buffer
 602      (apply #'git-run-command t nil "diff-index" "-z" "-M" "HEAD" "--" files)
 603      (goto-char (point-min))
 604      (while (re-search-forward
 605              ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMU]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 606              nil t 1)
 607        (let ((old-perm (string-to-number (match-string 1) 8))
 608              (new-perm (string-to-number (match-string 2) 8))
 609              (state (or (match-string 4) (match-string 6)))
 610              (name (or (match-string 5) (match-string 7)))
 611              (new-name (match-string 8)))
 612          (if new-name  ; copy or rename
 613              (if (eq ?C (string-to-char state))
 614                  (push (git-create-fileinfo 'added new-name old-perm new-perm 'copy name) infolist)
 615                (push (git-create-fileinfo 'deleted name 0 0 'rename new-name) infolist)
 616                (push (git-create-fileinfo 'added new-name old-perm new-perm 'rename name) infolist))
 617            (push (git-create-fileinfo (git-state-code state) name old-perm new-perm) infolist))
 618          (setq files (delete name files))
 619          (when new-name (setq files (delete new-name files))))))
 620    (git-insert-info-list status infolist)
 621    files))
 622
 623(defun git-find-status-file (status file)
 624  "Find a given file in the status ewoc and return its node."
 625  (let ((node (ewoc-nth status 0)))
 626    (while (and node (not (string= file (git-fileinfo->name (ewoc-data node)))))
 627      (setq node (ewoc-next status node)))
 628    node))
 629
 630(defun git-run-ls-files (status files default-state &rest options)
 631  "Run git-ls-files on FILES and parse the results into STATUS.
 632Return the list of files that haven't been handled."
 633  (let (infolist)
 634    (with-temp-buffer
 635      (apply #'git-run-command t nil "ls-files" "-z" (append options (list "--") files))
 636      (goto-char (point-min))
 637      (while (re-search-forward "\\([^\0]*\\)\0" nil t 1)
 638        (let ((name (match-string 1)))
 639          (push (git-create-fileinfo default-state name) infolist)
 640          (setq files (delete name files)))))
 641    (git-insert-info-list status infolist)
 642    files))
 643
 644(defun git-run-ls-unmerged (status files)
 645  "Run git-ls-files -u on FILES and parse the results into STATUS."
 646  (with-temp-buffer
 647    (apply #'git-run-command t nil "ls-files" "-z" "-u" "--" files)
 648    (goto-char (point-min))
 649    (let (unmerged-files)
 650      (while (re-search-forward "[0-7]\\{6\\} [0-9a-f]\\{40\\} [123]\t\\([^\0]+\\)\0" nil t)
 651        (push (match-string 1) unmerged-files))
 652      (git-set-filenames-state status unmerged-files 'unmerged))))
 653
 654(defun git-get-exclude-files ()
 655  "Get the list of exclude files to pass to git-ls-files."
 656  (let (files
 657        (config (git-config "core.excludesfile")))
 658    (when (file-readable-p ".git/info/exclude")
 659      (push ".git/info/exclude" files))
 660    (when (and config (file-readable-p config))
 661      (push config files))
 662    files))
 663
 664(defun git-run-ls-files-with-excludes (status files default-state &rest options)
 665  "Run git-ls-files on FILES with appropriate --exclude-from options."
 666  (let ((exclude-files (git-get-exclude-files)))
 667    (apply #'git-run-ls-files status files default-state
 668           (concat "--exclude-per-directory=" git-per-dir-ignore-file)
 669           (append options (mapcar (lambda (f) (concat "--exclude-from=" f)) exclude-files)))))
 670
 671(defun git-update-status-files (files &optional default-state)
 672  "Update the status of FILES from the index."
 673  (unless git-status (error "Not in git-status buffer."))
 674  (unless files
 675    (when git-show-uptodate (git-run-ls-files git-status nil 'uptodate "-c")))
 676  (let* ((remaining-files
 677          (if (git-empty-db-p) ; we need some special handling for an empty db
 678              (git-run-ls-files git-status files 'added "-c")
 679            (git-run-diff-index git-status files))))
 680    (git-run-ls-unmerged git-status files)
 681    (when (or remaining-files (and git-show-unknown (not files)))
 682      (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'unknown "-o")))
 683    (when (or remaining-files (and git-show-ignored (not files)))
 684      (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'ignored "-o" "-i")))
 685    (git-set-filenames-state git-status remaining-files default-state)
 686    (git-refresh-files)
 687    (git-refresh-ewoc-hf git-status)))
 688
 689(defun git-marked-files ()
 690  "Return a list of all marked files, or if none a list containing just the file at cursor position."
 691  (unless git-status (error "Not in git-status buffer."))
 692  (or (ewoc-collect git-status (lambda (info) (git-fileinfo->marked info)))
 693      (list (ewoc-data (ewoc-locate git-status)))))
 694
 695(defun git-marked-files-state (&rest states)
 696  "Return marked files that are in the specified states."
 697  (let ((files (git-marked-files))
 698        result)
 699    (dolist (info files)
 700      (when (memq (git-fileinfo->state info) states)
 701        (push info result)))
 702    result))
 703
 704(defun git-refresh-files ()
 705  "Refresh all files that need it and clear the needs-refresh flag."
 706  (unless git-status (error "Not in git-status buffer."))
 707  (ewoc-map
 708   (lambda (info)
 709     (let ((refresh (git-fileinfo->needs-refresh info)))
 710       (setf (git-fileinfo->needs-refresh info) nil)
 711       refresh))
 712   git-status)
 713  ; move back to goal column
 714  (when goal-column (move-to-column goal-column)))
 715
 716(defun git-refresh-ewoc-hf (status)
 717  "Refresh the ewoc header and footer."
 718  (let ((branch (git-symbolic-ref "HEAD"))
 719        (head (if (git-empty-db-p) "Nothing committed yet"
 720                (git-get-commit-description "HEAD")))
 721        (merge-heads (git-get-merge-heads)))
 722    (ewoc-set-hf status
 723                 (format "Directory:  %s\nBranch:     %s\nHead:       %s%s\n"
 724                         default-directory
 725                         (if branch
 726                             (if (string-match "^refs/heads/" branch)
 727                                 (substring branch (match-end 0))
 728                               branch)
 729                           "none (detached HEAD)")
 730                         head
 731                         (if merge-heads
 732                             (concat "\nMerging:    "
 733                                     (mapconcat (lambda (str) (git-get-commit-description str)) merge-heads "\n            "))
 734                           ""))
 735                 (if (ewoc-nth status 0) "" "    No changes."))))
 736
 737(defun git-get-filenames (files)
 738  (mapcar (lambda (info) (git-fileinfo->name info)) files))
 739
 740(defun git-update-index (index-file files)
 741  "Run git-update-index on a list of files."
 742  (let ((env (and index-file `(("GIT_INDEX_FILE" . ,index-file))))
 743        added deleted modified)
 744    (dolist (info files)
 745      (case (git-fileinfo->state info)
 746        ('added (push info added))
 747        ('deleted (push info deleted))
 748        ('modified (push info modified))))
 749    (when added
 750      (apply #'git-run-command nil env "update-index" "--add" "--" (git-get-filenames added)))
 751    (when deleted
 752      (apply #'git-run-command nil env "update-index" "--remove" "--" (git-get-filenames deleted)))
 753    (when modified
 754      (apply #'git-run-command nil env "update-index" "--" (git-get-filenames modified)))))
 755
 756(defun git-run-pre-commit-hook ()
 757  "Run the pre-commit hook if any."
 758  (unless git-status (error "Not in git-status buffer."))
 759  (let ((files (git-marked-files-state 'added 'deleted 'modified)))
 760    (or (not files)
 761        (not (file-executable-p ".git/hooks/pre-commit"))
 762        (let ((index-file (make-temp-file "gitidx")))
 763          (unwind-protect
 764            (let ((head-tree (unless (git-empty-db-p) (git-rev-parse "HEAD^{tree}"))))
 765              (git-read-tree head-tree index-file)
 766              (git-update-index index-file files)
 767              (git-run-hook "pre-commit" `(("GIT_INDEX_FILE" . ,index-file))))
 768          (delete-file index-file))))))
 769
 770(defun git-do-commit ()
 771  "Perform the actual commit using the current buffer as log message."
 772  (interactive)
 773  (let ((buffer (current-buffer))
 774        (index-file (make-temp-file "gitidx")))
 775    (with-current-buffer log-edit-parent-buffer
 776      (if (git-marked-files-state 'unmerged)
 777          (message "You cannot commit unmerged files, resolve them first.")
 778        (unwind-protect
 779            (let ((files (git-marked-files-state 'added 'deleted 'modified))
 780                  head head-tree)
 781              (unless (git-empty-db-p)
 782                (setq head (git-rev-parse "HEAD")
 783                      head-tree (git-rev-parse "HEAD^{tree}")))
 784              (if files
 785                  (progn
 786                    (git-read-tree head-tree index-file)
 787                    (git-update-index nil files)         ;update both the default index
 788                    (git-update-index index-file files)  ;and the temporary one
 789                    (let ((tree (git-write-tree index-file)))
 790                      (if (or (not (string-equal tree head-tree))
 791                              (yes-or-no-p "The tree was not modified, do you really want to perform an empty commit? "))
 792                          (let ((commit (git-commit-tree buffer tree head)))
 793                            (condition-case nil (delete-file ".git/MERGE_HEAD") (error nil))
 794                            (condition-case nil (delete-file ".git/MERGE_MSG") (error nil))
 795                            (with-current-buffer buffer (erase-buffer))
 796                            (git-set-files-state files 'uptodate)
 797                            (git-run-command nil nil "rerere")
 798                            (git-refresh-files)
 799                            (git-refresh-ewoc-hf git-status)
 800                            (message "Committed %s." commit)
 801                            (git-run-hook "post-commit" nil))
 802                        (message "Commit aborted."))))
 803                (message "No files to commit.")))
 804          (delete-file index-file))))))
 805
 806
 807;;;; Interactive functions
 808;;;; ------------------------------------------------------------
 809
 810(defun git-mark-file ()
 811  "Mark the file that the cursor is on and move to the next one."
 812  (interactive)
 813  (unless git-status (error "Not in git-status buffer."))
 814  (let* ((pos (ewoc-locate git-status))
 815         (info (ewoc-data pos)))
 816    (setf (git-fileinfo->marked info) t)
 817    (ewoc-invalidate git-status pos)
 818    (ewoc-goto-next git-status 1)))
 819
 820(defun git-unmark-file ()
 821  "Unmark the file that the cursor is on and move to the next one."
 822  (interactive)
 823  (unless git-status (error "Not in git-status buffer."))
 824  (let* ((pos (ewoc-locate git-status))
 825         (info (ewoc-data pos)))
 826    (setf (git-fileinfo->marked info) nil)
 827    (ewoc-invalidate git-status pos)
 828    (ewoc-goto-next git-status 1)))
 829
 830(defun git-unmark-file-up ()
 831  "Unmark the file that the cursor is on and move to the previous one."
 832  (interactive)
 833  (unless git-status (error "Not in git-status buffer."))
 834  (let* ((pos (ewoc-locate git-status))
 835         (info (ewoc-data pos)))
 836    (setf (git-fileinfo->marked info) nil)
 837    (ewoc-invalidate git-status pos)
 838    (ewoc-goto-prev git-status 1)))
 839
 840(defun git-mark-all ()
 841  "Mark all files."
 842  (interactive)
 843  (unless git-status (error "Not in git-status buffer."))
 844  (ewoc-map (lambda (info) (setf (git-fileinfo->marked info) t) t) git-status)
 845  ; move back to goal column after invalidate
 846  (when goal-column (move-to-column goal-column)))
 847
 848(defun git-unmark-all ()
 849  "Unmark all files."
 850  (interactive)
 851  (unless git-status (error "Not in git-status buffer."))
 852  (ewoc-map (lambda (info) (setf (git-fileinfo->marked info) nil) t) git-status)
 853  ; move back to goal column after invalidate
 854  (when goal-column (move-to-column goal-column)))
 855
 856(defun git-toggle-all-marks ()
 857  "Toggle all file marks."
 858  (interactive)
 859  (unless git-status (error "Not in git-status buffer."))
 860  (ewoc-map (lambda (info) (setf (git-fileinfo->marked info) (not (git-fileinfo->marked info))) t) git-status)
 861  ; move back to goal column after invalidate
 862  (when goal-column (move-to-column goal-column)))
 863
 864(defun git-next-file (&optional n)
 865  "Move the selection down N files."
 866  (interactive "p")
 867  (unless git-status (error "Not in git-status buffer."))
 868  (ewoc-goto-next git-status n))
 869
 870(defun git-prev-file (&optional n)
 871  "Move the selection up N files."
 872  (interactive "p")
 873  (unless git-status (error "Not in git-status buffer."))
 874  (ewoc-goto-prev git-status n))
 875
 876(defun git-next-unmerged-file (&optional n)
 877  "Move the selection down N unmerged files."
 878  (interactive "p")
 879  (unless git-status (error "Not in git-status buffer."))
 880  (let* ((last (ewoc-locate git-status))
 881         (node (ewoc-next git-status last)))
 882    (while (and node (> n 0))
 883      (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 884        (setq n (1- n))
 885        (setq last node))
 886      (setq node (ewoc-next git-status node)))
 887    (ewoc-goto-node git-status last)))
 888
 889(defun git-prev-unmerged-file (&optional n)
 890  "Move the selection up N unmerged files."
 891  (interactive "p")
 892  (unless git-status (error "Not in git-status buffer."))
 893  (let* ((last (ewoc-locate git-status))
 894         (node (ewoc-prev git-status last)))
 895    (while (and node (> n 0))
 896      (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 897        (setq n (1- n))
 898        (setq last node))
 899      (setq node (ewoc-prev git-status node)))
 900    (ewoc-goto-node git-status last)))
 901
 902(defun git-add-file ()
 903  "Add marked file(s) to the index cache."
 904  (interactive)
 905  (let ((files (git-get-filenames (git-marked-files-state 'unknown 'ignored))))
 906    (unless files
 907      (push (file-relative-name (read-file-name "File to add: " nil nil t)) files))
 908    (apply #'git-run-command nil nil "update-index" "--add" "--" files)
 909    (git-update-status-files files 'uptodate)))
 910
 911(defun git-ignore-file ()
 912  "Add marked file(s) to the ignore list."
 913  (interactive)
 914  (let ((files (git-get-filenames (git-marked-files-state 'unknown))))
 915    (unless files
 916      (push (file-relative-name (read-file-name "File to ignore: " nil nil t)) files))
 917    (dolist (f files) (git-append-to-ignore f))
 918    (git-update-status-files files 'ignored)))
 919
 920(defun git-remove-file ()
 921  "Remove the marked file(s)."
 922  (interactive)
 923  (let ((files (git-get-filenames (git-marked-files-state 'added 'modified 'unknown 'uptodate 'ignored))))
 924    (unless files
 925      (push (file-relative-name (read-file-name "File to remove: " nil nil t)) files))
 926    (if (yes-or-no-p
 927         (format "Remove %d file%s? " (length files) (if (> (length files) 1) "s" "")))
 928        (progn
 929          (dolist (name files)
 930            (when (file-exists-p name) (delete-file name)))
 931          (apply #'git-run-command nil nil "update-index" "--remove" "--" files)
 932          (git-update-status-files files nil))
 933      (message "Aborting"))))
 934
 935(defun git-revert-file ()
 936  "Revert changes to the marked file(s)."
 937  (interactive)
 938  (let ((files (git-marked-files))
 939        added modified)
 940    (when (and files
 941               (yes-or-no-p
 942                (format "Revert %d file%s? " (length files) (if (> (length files) 1) "s" ""))))
 943      (dolist (info files)
 944        (case (git-fileinfo->state info)
 945          ('added (push (git-fileinfo->name info) added))
 946          ('deleted (push (git-fileinfo->name info) modified))
 947          ('unmerged (push (git-fileinfo->name info) modified))
 948          ('modified (push (git-fileinfo->name info) modified))))
 949      (when added
 950        (apply #'git-run-command nil nil "update-index" "--force-remove" "--" added))
 951      (when modified
 952        (apply #'git-run-command nil nil "checkout" "HEAD" modified))
 953      (git-update-status-files (append added modified) 'uptodate))))
 954
 955(defun git-resolve-file ()
 956  "Resolve conflicts in marked file(s)."
 957  (interactive)
 958  (let ((files (git-get-filenames (git-marked-files-state 'unmerged))))
 959    (when files
 960      (apply #'git-run-command nil nil "update-index" "--" files)
 961      (git-update-status-files files 'uptodate))))
 962
 963(defun git-remove-handled ()
 964  "Remove handled files from the status list."
 965  (interactive)
 966  (ewoc-filter git-status
 967               (lambda (info)
 968                 (case (git-fileinfo->state info)
 969                   ('ignored git-show-ignored)
 970                   ('uptodate git-show-uptodate)
 971                   ('unknown git-show-unknown)
 972                   (t t))))
 973  (unless (ewoc-nth git-status 0)  ; refresh header if list is empty
 974    (git-refresh-ewoc-hf git-status)))
 975
 976(defun git-toggle-show-uptodate ()
 977  "Toogle the option for showing up-to-date files."
 978  (interactive)
 979  (if (setq git-show-uptodate (not git-show-uptodate))
 980      (git-refresh-status)
 981    (git-remove-handled)))
 982
 983(defun git-toggle-show-ignored ()
 984  "Toogle the option for showing ignored files."
 985  (interactive)
 986  (if (setq git-show-ignored (not git-show-ignored))
 987      (progn
 988        (git-run-ls-files-with-excludes git-status nil 'ignored "-o" "-i")
 989        (git-refresh-files)
 990        (git-refresh-ewoc-hf git-status))
 991    (git-remove-handled)))
 992
 993(defun git-toggle-show-unknown ()
 994  "Toogle the option for showing unknown files."
 995  (interactive)
 996  (if (setq git-show-unknown (not git-show-unknown))
 997      (progn
 998        (git-run-ls-files-with-excludes git-status nil 'unknown "-o")
 999        (git-refresh-files)
1000        (git-refresh-ewoc-hf git-status))
1001    (git-remove-handled)))
1002
1003(defun git-setup-diff-buffer (buffer)
1004  "Setup a buffer for displaying a diff."
1005  (let ((dir default-directory))
1006    (with-current-buffer buffer
1007      (diff-mode)
1008      (goto-char (point-min))
1009      (setq default-directory dir)
1010      (setq buffer-read-only t)))
1011  (display-buffer buffer)
1012  (shrink-window-if-larger-than-buffer))
1013
1014(defun git-diff-file ()
1015  "Diff the marked file(s) against HEAD."
1016  (interactive)
1017  (let ((files (git-marked-files)))
1018    (git-setup-diff-buffer
1019     (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M" "HEAD" "--" (git-get-filenames files)))))
1020
1021(defun git-diff-file-merge-head (arg)
1022  "Diff the marked file(s) against the first merge head (or the nth one with a numeric prefix)."
1023  (interactive "p")
1024  (let ((files (git-marked-files))
1025        (merge-heads (git-get-merge-heads)))
1026    (unless merge-heads (error "No merge in progress"))
1027    (git-setup-diff-buffer
1028     (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M"
1029            (or (nth (1- arg) merge-heads) "HEAD") "--" (git-get-filenames files)))))
1030
1031(defun git-diff-unmerged-file (stage)
1032  "Diff the marked unmerged file(s) against the specified stage."
1033  (let ((files (git-marked-files)))
1034    (git-setup-diff-buffer
1035     (apply #'git-run-command-buffer "*git-diff*" "diff-files" "-p" stage "--" (git-get-filenames files)))))
1036
1037(defun git-diff-file-base ()
1038  "Diff the marked unmerged file(s) against the common base file."
1039  (interactive)
1040  (git-diff-unmerged-file "-1"))
1041
1042(defun git-diff-file-mine ()
1043  "Diff the marked unmerged file(s) against my pre-merge version."
1044  (interactive)
1045  (git-diff-unmerged-file "-2"))
1046
1047(defun git-diff-file-other ()
1048  "Diff the marked unmerged file(s) against the other's pre-merge version."
1049  (interactive)
1050  (git-diff-unmerged-file "-3"))
1051
1052(defun git-diff-file-combined ()
1053  "Do a combined diff of the marked unmerged file(s)."
1054  (interactive)
1055  (git-diff-unmerged-file "-c"))
1056
1057(defun git-diff-file-idiff ()
1058  "Perform an interactive diff on the current file."
1059  (interactive)
1060  (let ((files (git-marked-files-state 'added 'deleted 'modified)))
1061    (unless (eq 1 (length files))
1062      (error "Cannot perform an interactive diff on multiple files."))
1063    (let* ((filename (car (git-get-filenames files)))
1064           (buff1 (find-file-noselect filename))
1065           (buff2 (git-run-command-buffer (concat filename ".~HEAD~") "cat-file" "blob" (concat "HEAD:" filename))))
1066      (ediff-buffers buff1 buff2))))
1067
1068(defun git-log-file ()
1069  "Display a log of changes to the marked file(s)."
1070  (interactive)
1071  (let* ((files (git-marked-files))
1072         (coding-system-for-read git-commits-coding-system)
1073         (buffer (apply #'git-run-command-buffer "*git-log*" "rev-list" "--pretty" "HEAD" "--" (git-get-filenames files))))
1074    (with-current-buffer buffer
1075      ; (git-log-mode)  FIXME: implement log mode
1076      (goto-char (point-min))
1077      (setq buffer-read-only t))
1078    (display-buffer buffer)))
1079
1080(defun git-log-edit-files ()
1081  "Return a list of marked files for use in the log-edit buffer."
1082  (with-current-buffer log-edit-parent-buffer
1083    (git-get-filenames (git-marked-files-state 'added 'deleted 'modified))))
1084
1085(defun git-append-sign-off (name email)
1086  "Append a Signed-off-by entry to the current buffer, avoiding duplicates."
1087  (let ((sign-off (format "Signed-off-by: %s <%s>" name email))
1088        (case-fold-search t))
1089    (goto-char (point-min))
1090    (unless (re-search-forward (concat "^" (regexp-quote sign-off)) nil t)
1091      (goto-char (point-min))
1092      (unless (re-search-forward "^Signed-off-by: " nil t)
1093        (setq sign-off (concat "\n" sign-off)))
1094      (goto-char (point-max))
1095      (insert sign-off "\n"))))
1096
1097(defun git-setup-log-buffer (buffer &optional author-name author-email subject date msg)
1098  "Setup the log buffer for a commit."
1099  (unless git-status (error "Not in git-status buffer."))
1100  (let ((merge-heads (git-get-merge-heads))
1101        (dir default-directory)
1102        (committer-name (git-get-committer-name))
1103        (committer-email (git-get-committer-email))
1104        (sign-off git-append-signed-off-by))
1105    (with-current-buffer buffer
1106      (cd dir)
1107      (erase-buffer)
1108      (insert
1109       (propertize
1110        (format "Author: %s <%s>\n%s%s"
1111                (or author-name committer-name)
1112                (or author-email committer-email)
1113                (if date (format "Date: %s\n" date) "")
1114                (if merge-heads
1115                    (format "Parent: %s\n%s\n"
1116                            (git-rev-parse "HEAD")
1117                            (mapconcat (lambda (str) (concat "Parent: " str)) merge-heads "\n"))
1118                  ""))
1119        'face 'git-header-face)
1120       (propertize git-log-msg-separator 'face 'git-separator-face)
1121       "\n")
1122      (when subject (insert subject "\n\n"))
1123      (cond (msg (insert msg "\n"))
1124            ((file-readable-p ".dotest/msg")
1125             (insert-file-contents ".dotest/msg"))
1126            ((file-readable-p ".git/MERGE_MSG")
1127             (insert-file-contents ".git/MERGE_MSG")))
1128      ; delete empty lines at end
1129      (goto-char (point-min))
1130      (when (re-search-forward "\n+\\'" nil t)
1131        (replace-match "\n" t t))
1132      (when sign-off (git-append-sign-off committer-name committer-email)))))
1133
1134(defun git-commit-file ()
1135  "Commit the marked file(s), asking for a commit message."
1136  (interactive)
1137  (unless git-status (error "Not in git-status buffer."))
1138  (when (git-run-pre-commit-hook)
1139    (let ((buffer (get-buffer-create "*git-commit*"))
1140          (coding-system (git-get-commits-coding-system))
1141          author-name author-email subject date)
1142      (when (eq 0 (buffer-size buffer))
1143        (when (file-readable-p ".dotest/info")
1144          (with-temp-buffer
1145            (insert-file-contents ".dotest/info")
1146            (goto-char (point-min))
1147            (when (re-search-forward "^Author: \\(.*\\)\nEmail: \\(.*\\)$" nil t)
1148              (setq author-name (match-string 1))
1149              (setq author-email (match-string 2)))
1150            (goto-char (point-min))
1151            (when (re-search-forward "^Subject: \\(.*\\)$" nil t)
1152              (setq subject (match-string 1)))
1153            (goto-char (point-min))
1154            (when (re-search-forward "^Date: \\(.*\\)$" nil t)
1155              (setq date (match-string 1)))))
1156        (git-setup-log-buffer buffer author-name author-email subject date))
1157      (log-edit #'git-do-commit nil #'git-log-edit-files buffer)
1158      (setq font-lock-keywords (font-lock-compile-keywords git-log-edit-font-lock-keywords))
1159      (setq buffer-file-coding-system coding-system)
1160      (re-search-forward (regexp-quote (concat git-log-msg-separator "\n")) nil t))))
1161
1162(defun git-find-file ()
1163  "Visit the current file in its own buffer."
1164  (interactive)
1165  (unless git-status (error "Not in git-status buffer."))
1166  (let ((info (ewoc-data (ewoc-locate git-status))))
1167    (find-file (git-fileinfo->name info))
1168    (when (eq 'unmerged (git-fileinfo->state info))
1169      (smerge-mode 1))))
1170
1171(defun git-find-file-other-window ()
1172  "Visit the current file in its own buffer in another window."
1173  (interactive)
1174  (unless git-status (error "Not in git-status buffer."))
1175  (let ((info (ewoc-data (ewoc-locate git-status))))
1176    (find-file-other-window (git-fileinfo->name info))
1177    (when (eq 'unmerged (git-fileinfo->state info))
1178      (smerge-mode))))
1179
1180(defun git-find-file-imerge ()
1181  "Visit the current file in interactive merge mode."
1182  (interactive)
1183  (unless git-status (error "Not in git-status buffer."))
1184  (let ((info (ewoc-data (ewoc-locate git-status))))
1185    (find-file (git-fileinfo->name info))
1186    (smerge-ediff)))
1187
1188(defun git-view-file ()
1189  "View the current file in its own buffer."
1190  (interactive)
1191  (unless git-status (error "Not in git-status buffer."))
1192  (let ((info (ewoc-data (ewoc-locate git-status))))
1193    (view-file (git-fileinfo->name info))))
1194
1195(defun git-refresh-status ()
1196  "Refresh the git status buffer."
1197  (interactive)
1198  (let* ((status git-status)
1199         (pos (ewoc-locate status))
1200         (cur-name (and pos (git-fileinfo->name (ewoc-data pos)))))
1201    (unless status (error "Not in git-status buffer."))
1202    (git-run-command nil nil "update-index" "--refresh")
1203    (git-clear-status status)
1204    (git-update-status-files nil)
1205    ; move point to the current file name if any
1206    (let ((node (and cur-name (git-find-status-file status cur-name))))
1207      (when node (ewoc-goto-node status node)))))
1208
1209(defun git-status-quit ()
1210  "Quit git-status mode."
1211  (interactive)
1212  (bury-buffer))
1213
1214;;;; Major Mode
1215;;;; ------------------------------------------------------------
1216
1217(defvar git-status-mode-hook nil
1218  "Run after `git-status-mode' is setup.")
1219
1220(defvar git-status-mode-map nil
1221  "Keymap for git major mode.")
1222
1223(defvar git-status nil
1224  "List of all files managed by the git-status mode.")
1225
1226(unless git-status-mode-map
1227  (let ((map (make-keymap))
1228        (diff-map (make-sparse-keymap))
1229        (toggle-map (make-sparse-keymap)))
1230    (suppress-keymap map)
1231    (define-key map "?"   'git-help)
1232    (define-key map "h"   'git-help)
1233    (define-key map " "   'git-next-file)
1234    (define-key map "a"   'git-add-file)
1235    (define-key map "c"   'git-commit-file)
1236    (define-key map "d"    diff-map)
1237    (define-key map "="   'git-diff-file)
1238    (define-key map "f"   'git-find-file)
1239    (define-key map "\r"  'git-find-file)
1240    (define-key map "g"   'git-refresh-status)
1241    (define-key map "i"   'git-ignore-file)
1242    (define-key map "l"   'git-log-file)
1243    (define-key map "m"   'git-mark-file)
1244    (define-key map "M"   'git-mark-all)
1245    (define-key map "n"   'git-next-file)
1246    (define-key map "N"   'git-next-unmerged-file)
1247    (define-key map "o"   'git-find-file-other-window)
1248    (define-key map "p"   'git-prev-file)
1249    (define-key map "P"   'git-prev-unmerged-file)
1250    (define-key map "q"   'git-status-quit)
1251    (define-key map "r"   'git-remove-file)
1252    (define-key map "R"   'git-resolve-file)
1253    (define-key map "t"    toggle-map)
1254    (define-key map "T"   'git-toggle-all-marks)
1255    (define-key map "u"   'git-unmark-file)
1256    (define-key map "U"   'git-revert-file)
1257    (define-key map "v"   'git-view-file)
1258    (define-key map "x"   'git-remove-handled)
1259    (define-key map "\C-?" 'git-unmark-file-up)
1260    (define-key map "\M-\C-?" 'git-unmark-all)
1261    ; the diff submap
1262    (define-key diff-map "b" 'git-diff-file-base)
1263    (define-key diff-map "c" 'git-diff-file-combined)
1264    (define-key diff-map "=" 'git-diff-file)
1265    (define-key diff-map "e" 'git-diff-file-idiff)
1266    (define-key diff-map "E" 'git-find-file-imerge)
1267    (define-key diff-map "h" 'git-diff-file-merge-head)
1268    (define-key diff-map "m" 'git-diff-file-mine)
1269    (define-key diff-map "o" 'git-diff-file-other)
1270    ; the toggle submap
1271    (define-key toggle-map "u" 'git-toggle-show-uptodate)
1272    (define-key toggle-map "i" 'git-toggle-show-ignored)
1273    (define-key toggle-map "k" 'git-toggle-show-unknown)
1274    (define-key toggle-map "m" 'git-toggle-all-marks)
1275    (setq git-status-mode-map map)))
1276
1277;; git mode should only run in the *git status* buffer
1278(put 'git-status-mode 'mode-class 'special)
1279
1280(defun git-status-mode ()
1281  "Major mode for interacting with Git.
1282Commands:
1283\\{git-status-mode-map}"
1284  (kill-all-local-variables)
1285  (buffer-disable-undo)
1286  (setq mode-name "git status"
1287        major-mode 'git-status-mode
1288        goal-column 17
1289        buffer-read-only t)
1290  (use-local-map git-status-mode-map)
1291  (let ((buffer-read-only nil))
1292    (erase-buffer)
1293  (let ((status (ewoc-create 'git-fileinfo-prettyprint "" "")))
1294    (set (make-local-variable 'git-status) status))
1295  (set (make-local-variable 'list-buffers-directory) default-directory)
1296  (make-local-variable 'git-show-uptodate)
1297  (make-local-variable 'git-show-ignored)
1298  (make-local-variable 'git-show-unknown)
1299  (run-hooks 'git-status-mode-hook)))
1300
1301(defun git-find-status-buffer (dir)
1302  "Find the git status buffer handling a specified directory."
1303  (let ((list (buffer-list))
1304        (fulldir (expand-file-name dir))
1305        found)
1306    (while (and list (not found))
1307      (let ((buffer (car list)))
1308        (with-current-buffer buffer
1309          (when (and list-buffers-directory
1310                     (string-equal fulldir (expand-file-name list-buffers-directory))
1311                     (string-match "\\*git-status\\*$" (buffer-name buffer)))
1312            (setq found buffer))))
1313      (setq list (cdr list)))
1314    found))
1315
1316(defun git-status (dir)
1317  "Entry point into git-status mode."
1318  (interactive "DSelect directory: ")
1319  (setq dir (git-get-top-dir dir))
1320  (if (file-directory-p (concat (file-name-as-directory dir) ".git"))
1321      (let ((buffer (or (and git-reuse-status-buffer (git-find-status-buffer dir))
1322                        (create-file-buffer (expand-file-name "*git-status*" dir)))))
1323        (switch-to-buffer buffer)
1324        (cd dir)
1325        (git-status-mode)
1326        (git-refresh-status)
1327        (goto-char (point-min)))
1328    (message "%s is not a git working tree." dir)))
1329
1330(defun git-help ()
1331  "Display help for Git mode."
1332  (interactive)
1333  (describe-function 'git-status-mode))
1334
1335(provide 'git)
1336;;; git.el ends here