1#!/usr/bin/perl
2# Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3# License: GPL v2 or later
4use 5.008;
5use warnings;
6use strict;
7use vars qw/ $AUTHOR $VERSION
8 $sha1 $sha1_short $_revision $_repository
9 $_q $_authors $_authors_prog %users/;
10$AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
11$VERSION = '@@GIT_VERSION@@';
12
13use Carp qw/croak/;
14use Digest::MD5;
15use IO::File qw//;
16use File::Basename qw/dirname basename/;
17use File::Path qw/mkpath/;
18use File::Spec;
19use File::Find;
20use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
21use IPC::Open3;
22use Memoize;
23
24use Git::SVN;
25use Git::SVN::Editor;
26use Git::SVN::Fetcher;
27use Git::SVN::Ra;
28use Git::SVN::Prompt;
29use Git::SVN::Log;
30use Git::SVN::Migration;
31
32use Git::SVN::Utils qw(
33 fatal
34 can_compress
35 canonicalize_path
36 canonicalize_url
37 join_paths
38 add_path_to_url
39 join_paths
40);
41
42use Git qw(
43 git_cmd_try
44 command
45 command_oneline
46 command_noisy
47 command_output_pipe
48 command_close_pipe
49 command_bidi_pipe
50 command_close_bidi_pipe
51);
52
53BEGIN {
54 Memoize::memoize 'Git::config';
55 Memoize::memoize 'Git::config_bool';
56}
57
58
59# From which subdir have we been invoked?
60my $cmd_dir_prefix = eval {
61 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
62} || '';
63
64my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
65$ENV{GIT_DIR} ||= '.git';
66$Git::SVN::Ra::_log_window_size = 100;
67
68if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
69 $ENV{SVN_SSH} = $ENV{GIT_SSH};
70}
71
72if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
73 $ENV{SVN_SSH} =~ s/\\/\\\\/g;
74 $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
75}
76
77$Git::SVN::Log::TZ = $ENV{TZ};
78$ENV{TZ} = 'UTC';
79$| = 1; # unbuffer STDOUT
80
81# All SVN commands do it. Otherwise we may die on SIGPIPE when the remote
82# repository decides to close the connection which we expect to be kept alive.
83$SIG{PIPE} = 'IGNORE';
84
85# Given a dot separated version number, "subtract" it from
86# the SVN::Core::VERSION; non-negaitive return means the SVN::Core
87# is at least at the version the caller asked for.
88sub compare_svn_version {
89 my (@ours) = split(/\./, $SVN::Core::VERSION);
90 my (@theirs) = split(/\./, $_[0]);
91 my ($i, $diff);
92
93 for ($i = 0; $i < @ours && $i < @theirs; $i++) {
94 $diff = $ours[$i] - $theirs[$i];
95 return $diff if ($diff);
96 }
97 return 1 if ($i < @ours);
98 return -1 if ($i < @theirs);
99 return 0;
100}
101
102sub _req_svn {
103 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
104 require SVN::Ra;
105 require SVN::Delta;
106 if (::compare_svn_version('1.1.0') < 0) {
107 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
108 }
109}
110
111$sha1 = qr/[a-f\d]{40}/;
112$sha1_short = qr/[a-f\d]{4,40}/;
113my ($_stdin, $_help, $_edit,
114 $_message, $_file, $_branch_dest,
115 $_template, $_shared,
116 $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
117 $_merge, $_strategy, $_preserve_merges, $_dry_run, $_local,
118 $_prefix, $_no_checkout, $_url, $_verbose,
119 $_commit_url, $_tag, $_merge_info, $_interactive);
120
121# This is a refactoring artifact so Git::SVN can get at this git-svn switch.
122sub opt_prefix { return $_prefix || '' }
123
124$Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
125$_q ||= 0;
126my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
127 'config-dir=s' => \$Git::SVN::Ra::config_dir,
128 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
129 'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
130 'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
131my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
132 'authors-file|A=s' => \$_authors,
133 'authors-prog=s' => \$_authors_prog,
134 'repack:i' => \$Git::SVN::_repack,
135 'noMetadata' => \$Git::SVN::_no_metadata,
136 'useSvmProps' => \$Git::SVN::_use_svm_props,
137 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
138 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
139 'no-checkout' => \$_no_checkout,
140 'quiet|q+' => \$_q,
141 'repack-flags|repack-args|repack-opts=s' =>
142 \$Git::SVN::_repack_flags,
143 'use-log-author' => \$Git::SVN::_use_log_author,
144 'add-author-from' => \$Git::SVN::_add_author_from,
145 'localtime' => \$Git::SVN::_localtime,
146 %remote_opts );
147
148my ($_trunk, @_tags, @_branches, $_stdlayout);
149my %icv;
150my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
151 'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
152 'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
153 'stdlayout|s' => \$_stdlayout,
154 'minimize-url|m!' => \$Git::SVN::_minimize_url,
155 'no-metadata' => sub { $icv{noMetadata} = 1 },
156 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
157 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
158 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
159 'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
160 %remote_opts );
161my %cmt_opts = ( 'edit|e' => \$_edit,
162 'rmdir' => \$Git::SVN::Editor::_rmdir,
163 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
164 'l=i' => \$Git::SVN::Editor::_rename_limit,
165 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
166);
167
168my %cmd = (
169 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
170 { 'revision|r=s' => \$_revision,
171 'fetch-all|all' => \$_fetch_all,
172 'parent|p' => \$_fetch_parent,
173 %fc_opts } ],
174 clone => [ \&cmd_clone, "Initialize and fetch revisions",
175 { 'revision|r=s' => \$_revision,
176 'preserve-empty-dirs' =>
177 \$Git::SVN::Fetcher::_preserve_empty_dirs,
178 'placeholder-filename=s' =>
179 \$Git::SVN::Fetcher::_placeholder_filename,
180 %fc_opts, %init_opts } ],
181 init => [ \&cmd_init, "Initialize a repo for tracking" .
182 " (requires URL argument)",
183 \%init_opts ],
184 'multi-init' => [ \&cmd_multi_init,
185 "Deprecated alias for ".
186 "'$0 init -T<trunk> -b<branches> -t<tags>'",
187 \%init_opts ],
188 dcommit => [ \&cmd_dcommit,
189 'Commit several diffs to merge with upstream',
190 { 'merge|m|M' => \$_merge,
191 'strategy|s=s' => \$_strategy,
192 'verbose|v' => \$_verbose,
193 'dry-run|n' => \$_dry_run,
194 'fetch-all|all' => \$_fetch_all,
195 'commit-url=s' => \$_commit_url,
196 'revision|r=i' => \$_revision,
197 'no-rebase' => \$_no_rebase,
198 'mergeinfo=s' => \$_merge_info,
199 'interactive|i' => \$_interactive,
200 %cmt_opts, %fc_opts } ],
201 branch => [ \&cmd_branch,
202 'Create a branch in the SVN repository',
203 { 'message|m=s' => \$_message,
204 'destination|d=s' => \$_branch_dest,
205 'dry-run|n' => \$_dry_run,
206 'tag|t' => \$_tag,
207 'username=s' => \$Git::SVN::Prompt::_username,
208 'commit-url=s' => \$_commit_url } ],
209 tag => [ sub { $_tag = 1; cmd_branch(@_) },
210 'Create a tag in the SVN repository',
211 { 'message|m=s' => \$_message,
212 'destination|d=s' => \$_branch_dest,
213 'dry-run|n' => \$_dry_run,
214 'username=s' => \$Git::SVN::Prompt::_username,
215 'commit-url=s' => \$_commit_url } ],
216 'set-tree' => [ \&cmd_set_tree,
217 "Set an SVN repository to a git tree-ish",
218 { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
219 'create-ignore' => [ \&cmd_create_ignore,
220 'Create a .gitignore per svn:ignore',
221 { 'revision|r=i' => \$_revision
222 } ],
223 'mkdirs' => [ \&cmd_mkdirs ,
224 "recreate empty directories after a checkout",
225 { 'revision|r=i' => \$_revision } ],
226 'propget' => [ \&cmd_propget,
227 'Print the value of a property on a file or directory',
228 { 'revision|r=i' => \$_revision } ],
229 'proplist' => [ \&cmd_proplist,
230 'List all properties of a file or directory',
231 { 'revision|r=i' => \$_revision } ],
232 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
233 { 'revision|r=i' => \$_revision
234 } ],
235 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
236 { 'revision|r=i' => \$_revision
237 } ],
238 'multi-fetch' => [ \&cmd_multi_fetch,
239 "Deprecated alias for $0 fetch --all",
240 { 'revision|r=s' => \$_revision, %fc_opts } ],
241 'migrate' => [ sub { },
242 # no-op, we automatically run this anyways,
243 'Migrate configuration/metadata/layout from
244 previous versions of git-svn',
245 { 'minimize' => \$Git::SVN::Migration::_minimize,
246 %remote_opts } ],
247 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
248 { 'limit=i' => \$Git::SVN::Log::limit,
249 'revision|r=s' => \$_revision,
250 'verbose|v' => \$Git::SVN::Log::verbose,
251 'incremental' => \$Git::SVN::Log::incremental,
252 'oneline' => \$Git::SVN::Log::oneline,
253 'show-commit' => \$Git::SVN::Log::show_commit,
254 'non-recursive' => \$Git::SVN::Log::non_recursive,
255 'authors-file|A=s' => \$_authors,
256 'color' => \$Git::SVN::Log::color,
257 'pager=s' => \$Git::SVN::Log::pager
258 } ],
259 'find-rev' => [ \&cmd_find_rev,
260 "Translate between SVN revision numbers and tree-ish",
261 {} ],
262 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
263 { 'merge|m|M' => \$_merge,
264 'verbose|v' => \$_verbose,
265 'strategy|s=s' => \$_strategy,
266 'local|l' => \$_local,
267 'fetch-all|all' => \$_fetch_all,
268 'dry-run|n' => \$_dry_run,
269 'preserve-merges|p' => \$_preserve_merges,
270 %fc_opts } ],
271 'commit-diff' => [ \&cmd_commit_diff,
272 'Commit a diff between two trees',
273 { 'message|m=s' => \$_message,
274 'file|F=s' => \$_file,
275 'revision|r=s' => \$_revision,
276 %cmt_opts } ],
277 'info' => [ \&cmd_info,
278 "Show info about the latest SVN revision
279 on the current branch",
280 { 'url' => \$_url, } ],
281 'blame' => [ \&Git::SVN::Log::cmd_blame,
282 "Show what revision and author last modified each line of a file",
283 { 'git-format' => \$Git::SVN::Log::_git_format } ],
284 'reset' => [ \&cmd_reset,
285 "Undo fetches back to the specified SVN revision",
286 { 'revision|r=s' => \$_revision,
287 'parent|p' => \$_fetch_parent } ],
288 'gc' => [ \&cmd_gc,
289 "Compress unhandled.log files in .git/svn and remove " .
290 "index files in .git/svn",
291 {} ],
292);
293
294use Term::ReadLine;
295package FakeTerm;
296sub new {
297 my ($class, $reason) = @_;
298 return bless \$reason, shift;
299}
300sub readline {
301 my $self = shift;
302 die "Cannot use readline on FakeTerm: $$self";
303}
304package main;
305
306my $term = eval {
307 $ENV{"GIT_SVN_NOTTY"}
308 ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
309 : new Term::ReadLine 'git-svn';
310};
311if ($@) {
312 $term = new FakeTerm "$@: going non-interactive";
313}
314
315my $cmd;
316for (my $i = 0; $i < @ARGV; $i++) {
317 if (defined $cmd{$ARGV[$i]}) {
318 $cmd = $ARGV[$i];
319 splice @ARGV, $i, 1;
320 last;
321 } elsif ($ARGV[$i] eq 'help') {
322 $cmd = $ARGV[$i+1];
323 usage(0);
324 }
325};
326
327# make sure we're always running at the top-level working directory
328unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
329 unless (-d $ENV{GIT_DIR}) {
330 if ($git_dir_user_set) {
331 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
332 "but it is not a directory\n";
333 }
334 my $git_dir = delete $ENV{GIT_DIR};
335 my $cdup = undef;
336 git_cmd_try {
337 $cdup = command_oneline(qw/rev-parse --show-cdup/);
338 $git_dir = '.' unless ($cdup);
339 chomp $cdup if ($cdup);
340 $cdup = "." unless ($cdup && length $cdup);
341 } "Already at toplevel, but $git_dir not found\n";
342 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
343 unless (-d $git_dir) {
344 die "$git_dir still not found after going to ",
345 "'$cdup'\n";
346 }
347 $ENV{GIT_DIR} = $git_dir;
348 }
349 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
350}
351
352my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
353
354read_git_config(\%opts);
355if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
356 Getopt::Long::Configure('pass_through');
357}
358my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
359 'minimize-connections' => \$Git::SVN::Migration::_minimize,
360 'id|i=s' => \$Git::SVN::default_ref_id,
361 'svn-remote|remote|R=s' => sub {
362 $Git::SVN::no_reuse_existing = 1;
363 $Git::SVN::default_repo_id = $_[1] });
364exit 1 if (!$rv && $cmd && $cmd ne 'log');
365
366usage(0) if $_help;
367version() if $_version;
368usage(1) unless defined $cmd;
369load_authors() if $_authors;
370if (defined $_authors_prog) {
371 $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
372}
373
374unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
375 Git::SVN::Migration::migration_check();
376}
377Git::SVN::init_vars();
378eval {
379 Git::SVN::verify_remotes_sanity();
380 $cmd{$cmd}->[0]->(@ARGV);
381 post_fetch_checkout();
382};
383fatal $@ if $@;
384exit 0;
385
386####################### primary functions ######################
387sub usage {
388 my $exit = shift || 0;
389 my $fd = $exit ? \*STDERR : \*STDOUT;
390 print $fd <<"";
391git-svn - bidirectional operations between a single Subversion tree and git
392Usage: git svn <command> [options] [arguments]\n
393
394 print $fd "Available commands:\n" unless $cmd;
395
396 foreach (sort keys %cmd) {
397 next if $cmd && $cmd ne $_;
398 next if /^multi-/; # don't show deprecated commands
399 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
400 foreach (sort keys %{$cmd{$_}->[2]}) {
401 # mixed-case options are for .git/config only
402 next if /[A-Z]/ && /^[a-z]+$/i;
403 # prints out arguments as they should be passed:
404 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
405 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
406 "--$_" : "-$_" }
407 split /\|/,$_)," $x\n";
408 }
409 }
410 print $fd <<"";
411\nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
412arbitrary identifier if you're tracking multiple SVN branches/repositories in
413one git repository and want to keep them separate. See git-svn(1) for more
414information.
415
416 exit $exit;
417}
418
419sub version {
420 ::_req_svn();
421 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
422 exit 0;
423}
424
425sub ask {
426 my ($prompt, %arg) = @_;
427 my $valid_re = $arg{valid_re};
428 my $default = $arg{default};
429 my $resp;
430 my $i = 0;
431
432 if ( !( defined($term->IN)
433 && defined( fileno($term->IN) )
434 && defined( $term->OUT )
435 && defined( fileno($term->OUT) ) ) ){
436 return defined($default) ? $default : undef;
437 }
438
439 while ($i++ < 10) {
440 $resp = $term->readline($prompt);
441 if (!defined $resp) { # EOF
442 print "\n";
443 return defined $default ? $default : undef;
444 }
445 if ($resp eq '' and defined $default) {
446 return $default;
447 }
448 if (!defined $valid_re or $resp =~ /$valid_re/) {
449 return $resp;
450 }
451 }
452 return undef;
453}
454
455sub do_git_init_db {
456 unless (-d $ENV{GIT_DIR}) {
457 my @init_db = ('init');
458 push @init_db, "--template=$_template" if defined $_template;
459 if (defined $_shared) {
460 if ($_shared =~ /[a-z]/) {
461 push @init_db, "--shared=$_shared";
462 } else {
463 push @init_db, "--shared";
464 }
465 }
466 command_noisy(@init_db);
467 $_repository = Git->repository(Repository => ".git");
468 }
469 my $set;
470 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
471 foreach my $i (keys %icv) {
472 die "'$set' and '$i' cannot both be set\n" if $set;
473 next unless defined $icv{$i};
474 command_noisy('config', "$pfx.$i", $icv{$i});
475 $set = $i;
476 }
477 my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
478 command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
479 if defined $$ignore_paths_regex;
480 my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
481 command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
482 if defined $$ignore_refs_regex;
483
484 if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
485 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
486 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
487 command_noisy('config', "$pfx.placeholder-filename", $$fname);
488 }
489}
490
491sub init_subdir {
492 my $repo_path = shift or return;
493 mkpath([$repo_path]) unless -d $repo_path;
494 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
495 $ENV{GIT_DIR} = '.git';
496 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
497}
498
499sub cmd_clone {
500 my ($url, $path) = @_;
501 if (!defined $path &&
502 (defined $_trunk || @_branches || @_tags ||
503 defined $_stdlayout) &&
504 $url !~ m#^[a-z\+]+://#) {
505 $path = $url;
506 }
507 $path = basename($url) if !defined $path || !length $path;
508 my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
509 cmd_init($url, $path);
510 command_oneline('config', 'svn.authorsfile', $authors_absolute)
511 if $_authors;
512 Git::SVN::fetch_all($Git::SVN::default_repo_id);
513}
514
515sub cmd_init {
516 if (defined $_stdlayout) {
517 $_trunk = 'trunk' if (!defined $_trunk);
518 @_tags = 'tags' if (! @_tags);
519 @_branches = 'branches' if (! @_branches);
520 }
521 if (defined $_trunk || @_branches || @_tags) {
522 return cmd_multi_init(@_);
523 }
524 my $url = shift or die "SVN repository location required ",
525 "as a command-line argument\n";
526 $url = canonicalize_url($url);
527 init_subdir(@_);
528 do_git_init_db();
529
530 if ($Git::SVN::_minimize_url eq 'unset') {
531 $Git::SVN::_minimize_url = 0;
532 }
533
534 Git::SVN->init($url);
535}
536
537sub cmd_fetch {
538 if (grep /^\d+=./, @_) {
539 die "'<rev>=<commit>' fetch arguments are ",
540 "no longer supported.\n";
541 }
542 my ($remote) = @_;
543 if (@_ > 1) {
544 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
545 }
546 $Git::SVN::no_reuse_existing = undef;
547 if ($_fetch_parent) {
548 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
549 unless ($gs) {
550 die "Unable to determine upstream SVN information from ",
551 "working tree history\n";
552 }
553 # just fetch, don't checkout.
554 $_no_checkout = 'true';
555 $_fetch_all ? $gs->fetch_all : $gs->fetch;
556 } elsif ($_fetch_all) {
557 cmd_multi_fetch();
558 } else {
559 $remote ||= $Git::SVN::default_repo_id;
560 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
561 }
562}
563
564sub cmd_set_tree {
565 my (@commits) = @_;
566 if ($_stdin || !@commits) {
567 print "Reading from stdin...\n";
568 @commits = ();
569 while (<STDIN>) {
570 if (/\b($sha1_short)\b/o) {
571 unshift @commits, $1;
572 }
573 }
574 }
575 my @revs;
576 foreach my $c (@commits) {
577 my @tmp = command('rev-parse',$c);
578 if (scalar @tmp == 1) {
579 push @revs, $tmp[0];
580 } elsif (scalar @tmp > 1) {
581 push @revs, reverse(command('rev-list',@tmp));
582 } else {
583 fatal "Failed to rev-parse $c";
584 }
585 }
586 my $gs = Git::SVN->new;
587 my ($r_last, $cmt_last) = $gs->last_rev_commit;
588 $gs->fetch;
589 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
590 fatal "There are new revisions that were fetched ",
591 "and need to be merged (or acknowledged) ",
592 "before committing.\nlast rev: $r_last\n",
593 " current: $gs->{last_rev}";
594 }
595 $gs->set_tree($_) foreach @revs;
596 print "Done committing ",scalar @revs," revisions to SVN\n";
597 unlink $gs->{index};
598}
599
600sub split_merge_info_range {
601 my ($range) = @_;
602 if ($range =~ /(\d+)-(\d+)/) {
603 return (int($1), int($2));
604 } else {
605 return (int($range), int($range));
606 }
607}
608
609sub combine_ranges {
610 my ($in) = @_;
611
612 my @fnums = ();
613 my @arr = split(/,/, $in);
614 for my $element (@arr) {
615 my ($start, $end) = split_merge_info_range($element);
616 push @fnums, $start;
617 }
618
619 my @sorted = @arr [ sort {
620 $fnums[$a] <=> $fnums[$b]
621 } 0..$#arr ];
622
623 my @return = ();
624 my $last = -1;
625 my $first = -1;
626 for my $element (@sorted) {
627 my ($start, $end) = split_merge_info_range($element);
628
629 if ($last == -1) {
630 $first = $start;
631 $last = $end;
632 next;
633 }
634 if ($start <= $last+1) {
635 if ($end > $last) {
636 $last = $end;
637 }
638 next;
639 }
640 if ($first == $last) {
641 push @return, "$first";
642 } else {
643 push @return, "$first-$last";
644 }
645 $first = $start;
646 $last = $end;
647 }
648
649 if ($first != -1) {
650 if ($first == $last) {
651 push @return, "$first";
652 } else {
653 push @return, "$first-$last";
654 }
655 }
656
657 return join(',', @return);
658}
659
660sub merge_revs_into_hash {
661 my ($hash, $minfo) = @_;
662 my @lines = split(' ', $minfo);
663
664 for my $line (@lines) {
665 my ($branchpath, $revs) = split(/:/, $line);
666
667 if (exists($hash->{$branchpath})) {
668 # Merge the two revision sets
669 my $combined = "$hash->{$branchpath},$revs";
670 $hash->{$branchpath} = combine_ranges($combined);
671 } else {
672 # Just do range combining for consolidation
673 $hash->{$branchpath} = combine_ranges($revs);
674 }
675 }
676}
677
678sub merge_merge_info {
679 my ($mergeinfo_one, $mergeinfo_two) = @_;
680 my %result_hash = ();
681
682 merge_revs_into_hash(\%result_hash, $mergeinfo_one);
683 merge_revs_into_hash(\%result_hash, $mergeinfo_two);
684
685 my $result = '';
686 # Sort below is for consistency's sake
687 for my $branchname (sort keys(%result_hash)) {
688 my $revlist = $result_hash{$branchname};
689 $result .= "$branchname:$revlist\n"
690 }
691 return $result;
692}
693
694sub populate_merge_info {
695 my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
696
697 my %parentshash;
698 read_commit_parents(\%parentshash, $d);
699 my @parents = @{$parentshash{$d}};
700 if ($#parents > 0) {
701 # Merge commit
702 my $all_parents_ok = 1;
703 my $aggregate_mergeinfo = '';
704 my $rooturl = $gs->repos_root;
705
706 if (defined($rewritten_parent)) {
707 # Replace first parent with newly-rewritten version
708 shift @parents;
709 unshift @parents, $rewritten_parent;
710 }
711
712 foreach my $parent (@parents) {
713 my ($branchurl, $svnrev, $paruuid) =
714 cmt_metadata($parent);
715
716 unless (defined($svnrev)) {
717 # Should have been caught be preflight check
718 fatal "merge commit $d has ancestor $parent, but that change "
719 ."does not have git-svn metadata!";
720 }
721 unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
722 fatal "commit $parent git-svn metadata changed mid-run!";
723 }
724 my $branchpath = $1;
725
726 my $ra = Git::SVN::Ra->new($branchurl);
727 my (undef, undef, $props) =
728 $ra->get_dir(canonicalize_path("."), $svnrev);
729 my $par_mergeinfo = $props->{'svn:mergeinfo'};
730 unless (defined $par_mergeinfo) {
731 $par_mergeinfo = '';
732 }
733 # Merge previous mergeinfo values
734 $aggregate_mergeinfo =
735 merge_merge_info($aggregate_mergeinfo,
736 $par_mergeinfo, 0);
737
738 next if $parent eq $parents[0]; # Skip first parent
739 # Add new changes being placed in tree by merge
740 my @cmd = (qw/rev-list --reverse/,
741 $parent, qw/--not/);
742 foreach my $par (@parents) {
743 unless ($par eq $parent) {
744 push @cmd, $par;
745 }
746 }
747 my @revsin = ();
748 my ($revlist, $ctx) = command_output_pipe(@cmd);
749 while (<$revlist>) {
750 my $irev = $_;
751 chomp $irev;
752 my (undef, $csvnrev, undef) =
753 cmt_metadata($irev);
754 unless (defined $csvnrev) {
755 # A child is missing SVN annotations...
756 # this might be OK, or might not be.
757 warn "W:child $irev is merged into revision "
758 ."$d but does not have git-svn metadata. "
759 ."This means git-svn cannot determine the "
760 ."svn revision numbers to place into the "
761 ."svn:mergeinfo property. You must ensure "
762 ."a branch is entirely committed to "
763 ."SVN before merging it in order for "
764 ."svn:mergeinfo population to function "
765 ."properly";
766 }
767 push @revsin, $csvnrev;
768 }
769 command_close_pipe($revlist, $ctx);
770
771 last unless $all_parents_ok;
772
773 # We now have a list of all SVN revnos which are
774 # merged by this particular parent. Integrate them.
775 next if $#revsin == -1;
776 my $newmergeinfo = "$branchpath:" . join(',', @revsin);
777 $aggregate_mergeinfo =
778 merge_merge_info($aggregate_mergeinfo,
779 $newmergeinfo, 1);
780 }
781 if ($all_parents_ok and $aggregate_mergeinfo) {
782 return $aggregate_mergeinfo;
783 }
784 }
785
786 return undef;
787}
788
789sub cmd_dcommit {
790 my $head = shift;
791 command_noisy(qw/update-index --refresh/);
792 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
793 'Cannot dcommit with a dirty index. Commit your changes first, '
794 . "or stash them with `git stash'.\n";
795 $head ||= 'HEAD';
796
797 my $old_head;
798 if ($head ne 'HEAD') {
799 $old_head = eval {
800 command_oneline([qw/symbolic-ref -q HEAD/])
801 };
802 if ($old_head) {
803 $old_head =~ s{^refs/heads/}{};
804 } else {
805 $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
806 }
807 command(['checkout', $head], STDERR => 0);
808 }
809
810 my @refs;
811 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
812 unless ($gs) {
813 die "Unable to determine upstream SVN information from ",
814 "$head history.\nPerhaps the repository is empty.";
815 }
816
817 if (defined $_commit_url) {
818 $url = $_commit_url;
819 } else {
820 $url = eval { command_oneline('config', '--get',
821 "svn-remote.$gs->{repo_id}.commiturl") };
822 if (!$url) {
823 $url = $gs->full_pushurl
824 }
825 }
826
827 my $last_rev = $_revision if defined $_revision;
828 if ($url) {
829 print "Committing to $url ...\n";
830 }
831 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
832 if ($_no_rebase && scalar(@$linear_refs) > 1) {
833 warn "Attempting to commit more than one change while ",
834 "--no-rebase is enabled.\n",
835 "If these changes depend on each other, re-running ",
836 "without --no-rebase may be required."
837 }
838
839 if (defined $_interactive){
840 my $ask_default = "y";
841 foreach my $d (@$linear_refs){
842 my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
843 while (<$fh>){
844 print $_;
845 }
846 command_close_pipe($fh, $ctx);
847 $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
848 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
849 default => $ask_default);
850 die "Commit this patch reply required" unless defined $_;
851 if (/^[nq]/i) {
852 exit(0);
853 } elsif (/^a/i) {
854 last;
855 }
856 }
857 }
858
859 my $expect_url = $url;
860
861 my $push_merge_info = eval {
862 command_oneline(qw/config --get svn.pushmergeinfo/)
863 };
864 if (not defined($push_merge_info)
865 or $push_merge_info eq "false"
866 or $push_merge_info eq "no"
867 or $push_merge_info eq "never") {
868 $push_merge_info = 0;
869 }
870
871 unless (defined($_merge_info) || ! $push_merge_info) {
872 # Preflight check of changes to ensure no issues with mergeinfo
873 # This includes check for uncommitted-to-SVN parents
874 # (other than the first parent, which we will handle),
875 # information from different SVN repos, and paths
876 # which are not underneath this repository root.
877 my $rooturl = $gs->repos_root;
878 foreach my $d (@$linear_refs) {
879 my %parentshash;
880 read_commit_parents(\%parentshash, $d);
881 my @realparents = @{$parentshash{$d}};
882 if ($#realparents > 0) {
883 # Merge commit
884 shift @realparents; # Remove/ignore first parent
885 foreach my $parent (@realparents) {
886 my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
887 unless (defined $paruuid) {
888 # A parent is missing SVN annotations...
889 # abort the whole operation.
890 fatal "$parent is merged into revision $d, "
891 ."but does not have git-svn metadata. "
892 ."Either dcommit the branch or use a "
893 ."local cherry-pick, FF merge, or rebase "
894 ."instead of an explicit merge commit.";
895 }
896
897 unless ($paruuid eq $uuid) {
898 # Parent has SVN metadata from different repository
899 fatal "merge parent $parent for change $d has "
900 ."git-svn uuid $paruuid, while current change "
901 ."has uuid $uuid!";
902 }
903
904 unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
905 # This branch is very strange indeed.
906 fatal "merge parent $parent for $d is on branch "
907 ."$branchurl, which is not under the "
908 ."git-svn root $rooturl!";
909 }
910 }
911 }
912 }
913 }
914
915 my $rewritten_parent;
916 Git::SVN::remove_username($expect_url);
917 if (defined($_merge_info)) {
918 $_merge_info =~ tr{ }{\n};
919 }
920 while (1) {
921 my $d = shift @$linear_refs or last;
922 unless (defined $last_rev) {
923 (undef, $last_rev, undef) = cmt_metadata("$d~1");
924 unless (defined $last_rev) {
925 fatal "Unable to extract revision information ",
926 "from commit $d~1";
927 }
928 }
929 if ($_dry_run) {
930 print "diff-tree $d~1 $d\n";
931 } else {
932 my $cmt_rev;
933
934 unless (defined($_merge_info) || ! $push_merge_info) {
935 $_merge_info = populate_merge_info($d, $gs,
936 $uuid,
937 $linear_refs,
938 $rewritten_parent);
939 }
940
941 my %ed_opts = ( r => $last_rev,
942 log => get_commit_entry($d)->{log},
943 ra => Git::SVN::Ra->new($url),
944 config => SVN::Core::config_get_config(
945 $Git::SVN::Ra::config_dir
946 ),
947 tree_a => "$d~1",
948 tree_b => $d,
949 editor_cb => sub {
950 print "Committed r$_[0]\n";
951 $cmt_rev = $_[0];
952 },
953 mergeinfo => $_merge_info,
954 svn_path => '');
955 if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
956 print "No changes\n$d~1 == $d\n";
957 } elsif ($parents->{$d} && @{$parents->{$d}}) {
958 $gs->{inject_parents_dcommit}->{$cmt_rev} =
959 $parents->{$d};
960 }
961 $_fetch_all ? $gs->fetch_all : $gs->fetch;
962 $last_rev = $cmt_rev;
963 next if $_no_rebase;
964
965 # we always want to rebase against the current HEAD,
966 # not any head that was passed to us
967 my @diff = command('diff-tree', $d,
968 $gs->refname, '--');
969 my @finish;
970 if (@diff) {
971 @finish = rebase_cmd();
972 print STDERR "W: $d and ", $gs->refname,
973 " differ, using @finish:\n",
974 join("\n", @diff), "\n";
975 } else {
976 print "No changes between current HEAD and ",
977 $gs->refname,
978 "\nResetting to the latest ",
979 $gs->refname, "\n";
980 @finish = qw/reset --mixed/;
981 }
982 command_noisy(@finish, $gs->refname);
983
984 $rewritten_parent = command_oneline(qw/rev-parse HEAD/);
985
986 if (@diff) {
987 @refs = ();
988 my ($url_, $rev_, $uuid_, $gs_) =
989 working_head_info('HEAD', \@refs);
990 my ($linear_refs_, $parents_) =
991 linearize_history($gs_, \@refs);
992 if (scalar(@$linear_refs) !=
993 scalar(@$linear_refs_)) {
994 fatal "# of revisions changed ",
995 "\nbefore:\n",
996 join("\n", @$linear_refs),
997 "\n\nafter:\n",
998 join("\n", @$linear_refs_), "\n",
999 'If you are attempting to commit ',
1000 "merges, try running:\n\t",
1001 'git rebase --interactive',
1002 '--preserve-merges ',
1003 $gs->refname,
1004 "\nBefore dcommitting";
1005 }
1006 if ($url_ ne $expect_url) {
1007 if ($url_ eq $gs->metadata_url) {
1008 print
1009 "Accepting rewritten URL:",
1010 " $url_\n";
1011 } else {
1012 fatal
1013 "URL mismatch after rebase:",
1014 " $url_ != $expect_url";
1015 }
1016 }
1017 if ($uuid_ ne $uuid) {
1018 fatal "uuid mismatch after rebase: ",
1019 "$uuid_ != $uuid";
1020 }
1021 # remap parents
1022 my (%p, @l, $i);
1023 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1024 my $new = $linear_refs_->[$i] or next;
1025 $p{$new} =
1026 $parents->{$linear_refs->[$i]};
1027 push @l, $new;
1028 }
1029 $parents = \%p;
1030 $linear_refs = \@l;
1031 }
1032 }
1033 }
1034
1035 if ($old_head) {
1036 my $new_head = command_oneline(qw/rev-parse HEAD/);
1037 my $new_is_symbolic = eval {
1038 command_oneline(qw/symbolic-ref -q HEAD/);
1039 };
1040 if ($new_is_symbolic) {
1041 print "dcommitted the branch ", $head, "\n";
1042 } else {
1043 print "dcommitted on a detached HEAD because you gave ",
1044 "a revision argument.\n",
1045 "The rewritten commit is: ", $new_head, "\n";
1046 }
1047 command(['checkout', $old_head], STDERR => 0);
1048 }
1049
1050 unlink $gs->{index};
1051}
1052
1053sub cmd_branch {
1054 my ($branch_name, $head) = @_;
1055
1056 unless (defined $branch_name && length $branch_name) {
1057 die(($_tag ? "tag" : "branch") . " name required\n");
1058 }
1059 $head ||= 'HEAD';
1060
1061 my (undef, $rev, undef, $gs) = working_head_info($head);
1062 my $src = $gs->full_pushurl;
1063
1064 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1065 my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1066 my $glob;
1067 if ($#{$allglobs} == 0) {
1068 $glob = $allglobs->[0];
1069 } else {
1070 unless(defined $_branch_dest) {
1071 die "Multiple ",
1072 $_tag ? "tag" : "branch",
1073 " paths defined for Subversion repository.\n",
1074 "You must specify where you want to create the ",
1075 $_tag ? "tag" : "branch",
1076 " with the --destination argument.\n";
1077 }
1078 foreach my $g (@{$allglobs}) {
1079 my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1080 if ($_branch_dest =~ /$re/) {
1081 $glob = $g;
1082 last;
1083 }
1084 }
1085 unless (defined $glob) {
1086 my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1087 foreach my $g (@{$allglobs}) {
1088 $g->{path}->{left} =~ /$dest_re/ or next;
1089 if (defined $glob) {
1090 die "Ambiguous destination: ",
1091 $_branch_dest, "\nmatches both '",
1092 $glob->{path}->{left}, "' and '",
1093 $g->{path}->{left}, "'\n";
1094 }
1095 $glob = $g;
1096 }
1097 unless (defined $glob) {
1098 die "Unknown ",
1099 $_tag ? "tag" : "branch",
1100 " destination $_branch_dest\n";
1101 }
1102 }
1103 }
1104 my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1105 my $url;
1106 if (defined $_commit_url) {
1107 $url = $_commit_url;
1108 } else {
1109 $url = eval { command_oneline('config', '--get',
1110 "svn-remote.$gs->{repo_id}.commiturl") };
1111 if (!$url) {
1112 $url = $remote->{pushurl} || $remote->{url};
1113 }
1114 }
1115 my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1116
1117 if ($dst =~ /^https:/ && $src =~ /^http:/) {
1118 $src=~s/^http:/https:/;
1119 }
1120
1121 ::_req_svn();
1122
1123 my $ctx = SVN::Client->new(
1124 auth => Git::SVN::Ra::_auth_providers(),
1125 log_msg => sub {
1126 ${ $_[0] } = defined $_message
1127 ? $_message
1128 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1129 . $branch_name;
1130 },
1131 );
1132
1133 eval {
1134 $ctx->ls($dst, 'HEAD', 0);
1135 } and die "branch ${branch_name} already exists\n";
1136
1137 print "Copying ${src} at r${rev} to ${dst}...\n";
1138 $ctx->copy($src, $rev, $dst)
1139 unless $_dry_run;
1140
1141 $gs->fetch_all;
1142}
1143
1144sub cmd_find_rev {
1145 my $revision_or_hash = shift or die "SVN or git revision required ",
1146 "as a command-line argument\n";
1147 my $result;
1148 if ($revision_or_hash =~ /^r\d+$/) {
1149 my $head = shift;
1150 $head ||= 'HEAD';
1151 my @refs;
1152 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1153 unless ($gs) {
1154 die "Unable to determine upstream SVN information from ",
1155 "$head history\n";
1156 }
1157 my $desired_revision = substr($revision_or_hash, 1);
1158 $result = $gs->rev_map_get($desired_revision, $uuid);
1159 } else {
1160 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1161 $result = $rev;
1162 }
1163 print "$result\n" if $result;
1164}
1165
1166sub auto_create_empty_directories {
1167 my ($gs) = @_;
1168 my $var = eval { command_oneline('config', '--get', '--bool',
1169 "svn-remote.$gs->{repo_id}.automkdirs") };
1170 # By default, create empty directories by consulting the unhandled log,
1171 # but allow setting it to 'false' to skip it.
1172 return !($var && $var eq 'false');
1173}
1174
1175sub cmd_rebase {
1176 command_noisy(qw/update-index --refresh/);
1177 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1178 unless ($gs) {
1179 die "Unable to determine upstream SVN information from ",
1180 "working tree history\n";
1181 }
1182 if ($_dry_run) {
1183 print "Remote Branch: " . $gs->refname . "\n";
1184 print "SVN URL: " . $url . "\n";
1185 return;
1186 }
1187 if (command(qw/diff-index HEAD --/)) {
1188 print STDERR "Cannot rebase with uncommited changes:\n";
1189 command_noisy('status');
1190 exit 1;
1191 }
1192 unless ($_local) {
1193 # rebase will checkout for us, so no need to do it explicitly
1194 $_no_checkout = 'true';
1195 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1196 }
1197 command_noisy(rebase_cmd(), $gs->refname);
1198 if (auto_create_empty_directories($gs)) {
1199 $gs->mkemptydirs;
1200 }
1201}
1202
1203sub cmd_show_ignore {
1204 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1205 $gs ||= Git::SVN->new;
1206 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1207 $gs->prop_walk($gs->path, $r, sub {
1208 my ($gs, $path, $props) = @_;
1209 print STDOUT "\n# $path\n";
1210 my $s = $props->{'svn:ignore'} or return;
1211 $s =~ s/[\r\n]+/\n/g;
1212 $s =~ s/^\n+//;
1213 chomp $s;
1214 $s =~ s#^#$path#gm;
1215 print STDOUT "$s\n";
1216 });
1217}
1218
1219sub cmd_show_externals {
1220 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1221 $gs ||= Git::SVN->new;
1222 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1223 $gs->prop_walk($gs->path, $r, sub {
1224 my ($gs, $path, $props) = @_;
1225 print STDOUT "\n# $path\n";
1226 my $s = $props->{'svn:externals'} or return;
1227 $s =~ s/[\r\n]+/\n/g;
1228 chomp $s;
1229 $s =~ s#^#$path#gm;
1230 print STDOUT "$s\n";
1231 });
1232}
1233
1234sub cmd_create_ignore {
1235 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1236 $gs ||= Git::SVN->new;
1237 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1238 $gs->prop_walk($gs->path, $r, sub {
1239 my ($gs, $path, $props) = @_;
1240 # $path is of the form /path/to/dir/
1241 $path = '.' . $path;
1242 # SVN can have attributes on empty directories,
1243 # which git won't track
1244 mkpath([$path]) unless -d $path;
1245 my $ignore = $path . '.gitignore';
1246 my $s = $props->{'svn:ignore'} or return;
1247 open(GITIGNORE, '>', $ignore)
1248 or fatal("Failed to open `$ignore' for writing: $!");
1249 $s =~ s/[\r\n]+/\n/g;
1250 $s =~ s/^\n+//;
1251 chomp $s;
1252 # Prefix all patterns so that the ignore doesn't apply
1253 # to sub-directories.
1254 $s =~ s#^#/#gm;
1255 print GITIGNORE "$s\n";
1256 close(GITIGNORE)
1257 or fatal("Failed to close `$ignore': $!");
1258 command_noisy('add', '-f', $ignore);
1259 });
1260}
1261
1262sub cmd_mkdirs {
1263 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1264 $gs ||= Git::SVN->new;
1265 $gs->mkemptydirs($_revision);
1266}
1267
1268# get_svnprops(PATH)
1269# ------------------
1270# Helper for cmd_propget and cmd_proplist below.
1271sub get_svnprops {
1272 my $path = shift;
1273 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1274 $gs ||= Git::SVN->new;
1275
1276 # prefix THE PATH by the sub-directory from which the user
1277 # invoked us.
1278 $path = $cmd_dir_prefix . $path;
1279 fatal("No such file or directory: $path") unless -e $path;
1280 my $is_dir = -d $path ? 1 : 0;
1281 $path = join_paths($gs->{path}, $path);
1282
1283 # canonicalize the path (otherwise libsvn will abort or fail to
1284 # find the file)
1285 $path = canonicalize_path($path);
1286
1287 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1288 my $props;
1289 if ($is_dir) {
1290 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1291 }
1292 else {
1293 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1294 }
1295 return $props;
1296}
1297
1298# cmd_propget (PROP, PATH)
1299# ------------------------
1300# Print the SVN property PROP for PATH.
1301sub cmd_propget {
1302 my ($prop, $path) = @_;
1303 $path = '.' if not defined $path;
1304 usage(1) if not defined $prop;
1305 my $props = get_svnprops($path);
1306 if (not defined $props->{$prop}) {
1307 fatal("`$path' does not have a `$prop' SVN property.");
1308 }
1309 print $props->{$prop} . "\n";
1310}
1311
1312# cmd_proplist (PATH)
1313# -------------------
1314# Print the list of SVN properties for PATH.
1315sub cmd_proplist {
1316 my $path = shift;
1317 $path = '.' if not defined $path;
1318 my $props = get_svnprops($path);
1319 print "Properties on '$path':\n";
1320 foreach (sort keys %{$props}) {
1321 print " $_\n";
1322 }
1323}
1324
1325sub cmd_multi_init {
1326 my $url = shift;
1327 unless (defined $_trunk || @_branches || @_tags) {
1328 usage(1);
1329 }
1330
1331 $_prefix = '' unless defined $_prefix;
1332 if (defined $url) {
1333 $url = canonicalize_url($url);
1334 init_subdir(@_);
1335 }
1336 do_git_init_db();
1337 if (defined $_trunk) {
1338 $_trunk =~ s#^/+##;
1339 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1340 # try both old-style and new-style lookups:
1341 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1342 unless ($gs_trunk) {
1343 my ($trunk_url, $trunk_path) =
1344 complete_svn_url($url, $_trunk);
1345 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1346 undef, $trunk_ref);
1347 }
1348 }
1349 return unless @_branches || @_tags;
1350 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1351 foreach my $path (@_branches) {
1352 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1353 }
1354 foreach my $path (@_tags) {
1355 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1356 }
1357}
1358
1359sub cmd_multi_fetch {
1360 $Git::SVN::no_reuse_existing = undef;
1361 my $remotes = Git::SVN::read_all_remotes();
1362 foreach my $repo_id (sort keys %$remotes) {
1363 if ($remotes->{$repo_id}->{url}) {
1364 Git::SVN::fetch_all($repo_id, $remotes);
1365 }
1366 }
1367}
1368
1369# this command is special because it requires no metadata
1370sub cmd_commit_diff {
1371 my ($ta, $tb, $url) = @_;
1372 my $usage = "Usage: $0 commit-diff -r<revision> ".
1373 "<tree-ish> <tree-ish> [<URL>]";
1374 fatal($usage) if (!defined $ta || !defined $tb);
1375 my $svn_path = '';
1376 if (!defined $url) {
1377 my $gs = eval { Git::SVN->new };
1378 if (!$gs) {
1379 fatal("Needed URL or usable git-svn --id in ",
1380 "the command-line\n", $usage);
1381 }
1382 $url = $gs->url;
1383 $svn_path = $gs->path;
1384 }
1385 unless (defined $_revision) {
1386 fatal("-r|--revision is a required argument\n", $usage);
1387 }
1388 if (defined $_message && defined $_file) {
1389 fatal("Both --message/-m and --file/-F specified ",
1390 "for the commit message.\n",
1391 "I have no idea what you mean");
1392 }
1393 if (defined $_file) {
1394 $_message = file_to_s($_file);
1395 } else {
1396 $_message ||= get_commit_entry($tb)->{log};
1397 }
1398 my $ra ||= Git::SVN::Ra->new($url);
1399 my $r = $_revision;
1400 if ($r eq 'HEAD') {
1401 $r = $ra->get_latest_revnum;
1402 } elsif ($r !~ /^\d+$/) {
1403 die "revision argument: $r not understood by git-svn\n";
1404 }
1405 my %ed_opts = ( r => $r,
1406 log => $_message,
1407 ra => $ra,
1408 tree_a => $ta,
1409 tree_b => $tb,
1410 editor_cb => sub { print "Committed r$_[0]\n" },
1411 svn_path => $svn_path );
1412 if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1413 print "No changes\n$ta == $tb\n";
1414 }
1415}
1416
1417
1418sub cmd_info {
1419 my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1420 my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1421 if (exists $_[1]) {
1422 die "Too many arguments specified\n";
1423 }
1424
1425 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1426
1427 if (!$file_type && !$diff_status) {
1428 print STDERR "svn: '$path' is not under version control\n";
1429 exit 1;
1430 }
1431
1432 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1433 unless ($gs) {
1434 die "Unable to determine upstream SVN information from ",
1435 "working tree history\n";
1436 }
1437
1438 # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1439 $path = "." if $path eq "";
1440
1441 my $full_url = canonicalize_url( add_path_to_url( $url, $fullpath ) );
1442
1443 if ($_url) {
1444 print "$full_url\n";
1445 return;
1446 }
1447
1448 my $result = "Path: $path\n";
1449 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1450 $result .= "URL: $full_url\n";
1451
1452 eval {
1453 my $repos_root = $gs->repos_root;
1454 Git::SVN::remove_username($repos_root);
1455 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1456 };
1457 if ($@) {
1458 $result .= "Repository Root: (offline)\n";
1459 }
1460 ::_req_svn();
1461 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1462 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1463 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1464
1465 $result .= "Node Kind: " .
1466 ($file_type eq "dir" ? "directory" : "file") . "\n";
1467
1468 my $schedule = $diff_status eq "A"
1469 ? "add"
1470 : ($diff_status eq "D" ? "delete" : "normal");
1471 $result .= "Schedule: $schedule\n";
1472
1473 if ($diff_status eq "A") {
1474 print $result, "\n";
1475 return;
1476 }
1477
1478 my ($lc_author, $lc_rev, $lc_date_utc);
1479 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1480 my $log = command_output_pipe(@args);
1481 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1482 while (<$log>) {
1483 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1484 $lc_author = $1;
1485 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1486 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
1487 (undef, $lc_rev, undef) = ::extract_metadata($1);
1488 }
1489 }
1490 close $log;
1491
1492 Git::SVN::Log::set_local_timezone();
1493
1494 $result .= "Last Changed Author: $lc_author\n";
1495 $result .= "Last Changed Rev: $lc_rev\n";
1496 $result .= "Last Changed Date: " .
1497 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1498
1499 if ($file_type ne "dir") {
1500 my $text_last_updated_date =
1501 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1502 $result .=
1503 "Text Last Updated: " .
1504 Git::SVN::Log::format_svn_date($text_last_updated_date) .
1505 "\n";
1506 my $checksum;
1507 if ($diff_status eq "D") {
1508 my ($fh, $ctx) =
1509 command_output_pipe(qw(cat-file blob), "HEAD:$path");
1510 if ($file_type eq "link") {
1511 my $file_name = <$fh>;
1512 $checksum = md5sum("link $file_name");
1513 } else {
1514 $checksum = md5sum($fh);
1515 }
1516 command_close_pipe($fh, $ctx);
1517 } elsif ($file_type eq "link") {
1518 my $file_name =
1519 command(qw(cat-file blob), "HEAD:$path");
1520 $checksum =
1521 md5sum("link " . $file_name);
1522 } else {
1523 open FILE, "<", $path or die $!;
1524 $checksum = md5sum(\*FILE);
1525 close FILE or die $!;
1526 }
1527 $result .= "Checksum: " . $checksum . "\n";
1528 }
1529
1530 print $result, "\n";
1531}
1532
1533sub cmd_reset {
1534 my $target = shift || $_revision or die "SVN revision required\n";
1535 $target = $1 if $target =~ /^r(\d+)$/;
1536 $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1537 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1538 unless ($gs) {
1539 die "Unable to determine upstream SVN information from ".
1540 "history\n";
1541 }
1542 my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1543 die "Cannot find SVN revision $target\n" unless defined($c);
1544 $gs->rev_map_set($r, $c, 'reset', $uuid);
1545 print "r$r = $c ($gs->{ref_id})\n";
1546}
1547
1548sub cmd_gc {
1549 if (!can_compress()) {
1550 warn "Compress::Zlib could not be found; unhandled.log " .
1551 "files will not be compressed.\n";
1552 }
1553 find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1554}
1555
1556########################### utility functions #########################
1557
1558sub rebase_cmd {
1559 my @cmd = qw/rebase/;
1560 push @cmd, '-v' if $_verbose;
1561 push @cmd, qw/--merge/ if $_merge;
1562 push @cmd, "--strategy=$_strategy" if $_strategy;
1563 push @cmd, "--preserve-merges" if $_preserve_merges;
1564 @cmd;
1565}
1566
1567sub post_fetch_checkout {
1568 return if $_no_checkout;
1569 return if verify_ref('HEAD^0');
1570 my $gs = $Git::SVN::_head or return;
1571
1572 # look for "trunk" ref if it exists
1573 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1574 my $fetch = $remote->{fetch};
1575 if ($fetch) {
1576 foreach my $p (keys %$fetch) {
1577 basename($fetch->{$p}) eq 'trunk' or next;
1578 $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1579 last;
1580 }
1581 }
1582
1583 command_noisy(qw(update-ref HEAD), $gs->refname);
1584 return unless verify_ref('HEAD^0');
1585
1586 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1587 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1588 return if -f $index;
1589
1590 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1591 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1592 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1593 print STDERR "Checked out HEAD:\n ",
1594 $gs->full_url, " r", $gs->last_rev, "\n";
1595 if (auto_create_empty_directories($gs)) {
1596 $gs->mkemptydirs($gs->last_rev);
1597 }
1598}
1599
1600sub complete_svn_url {
1601 my ($url, $path) = @_;
1602 $path = canonicalize_path($path);
1603
1604 # If the path is not a URL...
1605 if ($path !~ m#^[a-z\+]+://#) {
1606 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1607 fatal("E: '$path' is not a complete URL ",
1608 "and a separate URL is not specified");
1609 }
1610 return ($url, $path);
1611 }
1612 return ($path, '');
1613}
1614
1615sub complete_url_ls_init {
1616 my ($ra, $repo_path, $switch, $pfx) = @_;
1617 unless ($repo_path) {
1618 print STDERR "W: $switch not specified\n";
1619 return;
1620 }
1621 $repo_path = canonicalize_path($repo_path);
1622 if ($repo_path =~ m#^[a-z\+]+://#) {
1623 $ra = Git::SVN::Ra->new($repo_path);
1624 $repo_path = '';
1625 } else {
1626 $repo_path =~ s#^/+##;
1627 unless ($ra) {
1628 fatal("E: '$repo_path' is not a complete URL ",
1629 "and a separate URL is not specified");
1630 }
1631 }
1632 my $url = $ra->url;
1633 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1634 my $k = "svn-remote.$gs->{repo_id}.url";
1635 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1636 if ($orig_url && ($orig_url ne $gs->url)) {
1637 die "$k already set: $orig_url\n",
1638 "wanted to set to: $gs->url\n";
1639 }
1640 command_oneline('config', $k, $gs->url) unless $orig_url;
1641
1642 my $remote_path = join_paths( $gs->path, $repo_path );
1643 $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1644 $remote_path =~ s#^/##g;
1645 $remote_path .= "/*" if $remote_path !~ /\*/;
1646 my ($n) = ($switch =~ /^--(\w+)/);
1647 if (length $pfx && $pfx !~ m#/$#) {
1648 die "--prefix='$pfx' must have a trailing slash '/'\n";
1649 }
1650 command_noisy('config',
1651 '--add',
1652 "svn-remote.$gs->{repo_id}.$n",
1653 "$remote_path:refs/remotes/$pfx*" .
1654 ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1655}
1656
1657sub verify_ref {
1658 my ($ref) = @_;
1659 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1660 { STDERR => 0 }); };
1661}
1662
1663sub get_tree_from_treeish {
1664 my ($treeish) = @_;
1665 # $treeish can be a symbolic ref, too:
1666 my $type = command_oneline(qw/cat-file -t/, $treeish);
1667 my $expected;
1668 while ($type eq 'tag') {
1669 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1670 }
1671 if ($type eq 'commit') {
1672 $expected = (grep /^tree /, command(qw/cat-file commit/,
1673 $treeish))[0];
1674 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1675 die "Unable to get tree from $treeish\n" unless $expected;
1676 } elsif ($type eq 'tree') {
1677 $expected = $treeish;
1678 } else {
1679 die "$treeish is a $type, expected tree, tag or commit\n";
1680 }
1681 return $expected;
1682}
1683
1684sub get_commit_entry {
1685 my ($treeish) = shift;
1686 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1687 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1688 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1689 open my $log_fh, '>', $commit_editmsg or croak $!;
1690
1691 my $type = command_oneline(qw/cat-file -t/, $treeish);
1692 if ($type eq 'commit' || $type eq 'tag') {
1693 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1694 $type, $treeish);
1695 my $in_msg = 0;
1696 my $author;
1697 my $saw_from = 0;
1698 my $msgbuf = "";
1699 while (<$msg_fh>) {
1700 if (!$in_msg) {
1701 $in_msg = 1 if (/^\s*$/);
1702 $author = $1 if (/^author (.*>)/);
1703 } elsif (/^git-svn-id: /) {
1704 # skip this for now, we regenerate the
1705 # correct one on re-fetch anyways
1706 # TODO: set *:merge properties or like...
1707 } else {
1708 if (/^From:/ || /^Signed-off-by:/) {
1709 $saw_from = 1;
1710 }
1711 $msgbuf .= $_;
1712 }
1713 }
1714 $msgbuf =~ s/\s+$//s;
1715 if ($Git::SVN::_add_author_from && defined($author)
1716 && !$saw_from) {
1717 $msgbuf .= "\n\nFrom: $author";
1718 }
1719 print $log_fh $msgbuf or croak $!;
1720 command_close_pipe($msg_fh, $ctx);
1721 }
1722 close $log_fh or croak $!;
1723
1724 if ($_edit || ($type eq 'tree')) {
1725 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1726 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1727 }
1728 rename $commit_editmsg, $commit_msg or croak $!;
1729 {
1730 require Encode;
1731 # SVN requires messages to be UTF-8 when entering the repo
1732 local $/;
1733 open $log_fh, '<', $commit_msg or croak $!;
1734 binmode $log_fh;
1735 chomp($log_entry{log} = <$log_fh>);
1736
1737 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1738 my $msg = $log_entry{log};
1739
1740 eval { $msg = Encode::decode($enc, $msg, 1) };
1741 if ($@) {
1742 die "Could not decode as $enc:\n", $msg,
1743 "\nPerhaps you need to set i18n.commitencoding\n";
1744 }
1745
1746 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1747 die "Could not encode as UTF-8:\n$msg\n" if $@;
1748
1749 $log_entry{log} = $msg;
1750
1751 close $log_fh or croak $!;
1752 }
1753 unlink $commit_msg;
1754 \%log_entry;
1755}
1756
1757sub s_to_file {
1758 my ($str, $file, $mode) = @_;
1759 open my $fd,'>',$file or croak $!;
1760 print $fd $str,"\n" or croak $!;
1761 close $fd or croak $!;
1762 chmod ($mode &~ umask, $file) if (defined $mode);
1763}
1764
1765sub file_to_s {
1766 my $file = shift;
1767 open my $fd,'<',$file or croak "$!: file: $file\n";
1768 local $/;
1769 my $ret = <$fd>;
1770 close $fd or croak $!;
1771 $ret =~ s/\s*$//s;
1772 return $ret;
1773}
1774
1775# '<svn username> = real-name <email address>' mapping based on git-svnimport:
1776sub load_authors {
1777 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1778 my $log = $cmd eq 'log';
1779 while (<$authors>) {
1780 chomp;
1781 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1782 my ($user, $name, $email) = ($1, $2, $3);
1783 if ($log) {
1784 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1785 } else {
1786 $users{$user} = [$name, $email];
1787 }
1788 }
1789 close $authors or croak $!;
1790}
1791
1792# convert GetOpt::Long specs for use by git-config
1793sub read_git_config {
1794 my $opts = shift;
1795 my @config_only;
1796 foreach my $o (keys %$opts) {
1797 # if we have mixedCase and a long option-only, then
1798 # it's a config-only variable that we don't need for
1799 # the command-line.
1800 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1801 my $v = $opts->{$o};
1802 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1803 $key =~ s/-//g;
1804 my $arg = 'git config';
1805 $arg .= ' --int' if ($o =~ /[:=]i$/);
1806 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1807 if (ref $v eq 'ARRAY') {
1808 chomp(my @tmp = `$arg --get-all svn.$key`);
1809 @$v = @tmp if @tmp;
1810 } else {
1811 chomp(my $tmp = `$arg --get svn.$key`);
1812 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1813 $$v = $tmp;
1814 }
1815 }
1816 }
1817 delete @$opts{@config_only} if @config_only;
1818}
1819
1820sub extract_metadata {
1821 my $id = shift or return (undef, undef, undef);
1822 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1823 \s([a-f\d\-]+)$/ix);
1824 if (!defined $rev || !$uuid || !$url) {
1825 # some of the original repositories I made had
1826 # identifiers like this:
1827 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1828 }
1829 return ($url, $rev, $uuid);
1830}
1831
1832sub cmt_metadata {
1833 return extract_metadata((grep(/^git-svn-id: /,
1834 command(qw/cat-file commit/, shift)))[-1]);
1835}
1836
1837sub cmt_sha2rev_batch {
1838 my %s2r;
1839 my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1840 my $list = shift;
1841
1842 foreach my $sha (@{$list}) {
1843 my $first = 1;
1844 my $size = 0;
1845 print $out $sha, "\n";
1846
1847 while (my $line = <$in>) {
1848 if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1849 last;
1850 } elsif ($first &&
1851 $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1852 $first = 0;
1853 $size = $1;
1854 next;
1855 } elsif ($line =~ /^(git-svn-id: )/) {
1856 my (undef, $rev, undef) =
1857 extract_metadata($line);
1858 $s2r{$sha} = $rev;
1859 }
1860
1861 $size -= length($line);
1862 last if ($size == 0);
1863 }
1864 }
1865
1866 command_close_bidi_pipe($pid, $in, $out, $ctx);
1867
1868 return \%s2r;
1869}
1870
1871sub working_head_info {
1872 my ($head, $refs) = @_;
1873 my @args = qw/rev-list --first-parent --pretty=medium/;
1874 my ($fh, $ctx) = command_output_pipe(@args, $head);
1875 my $hash;
1876 my %max;
1877 while (<$fh>) {
1878 if ( m{^commit ($::sha1)$} ) {
1879 unshift @$refs, $hash if $hash and $refs;
1880 $hash = $1;
1881 next;
1882 }
1883 next unless s{^\s*(git-svn-id:)}{$1};
1884 my ($url, $rev, $uuid) = extract_metadata($_);
1885 if (defined $url && defined $rev) {
1886 next if $max{$url} and $max{$url} < $rev;
1887 if (my $gs = Git::SVN->find_by_url($url)) {
1888 my $c = $gs->rev_map_get($rev, $uuid);
1889 if ($c && $c eq $hash) {
1890 close $fh; # break the pipe
1891 return ($url, $rev, $uuid, $gs);
1892 } else {
1893 $max{$url} ||= $gs->rev_map_max;
1894 }
1895 }
1896 }
1897 }
1898 command_close_pipe($fh, $ctx);
1899 (undef, undef, undef, undef);
1900}
1901
1902sub read_commit_parents {
1903 my ($parents, $c) = @_;
1904 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1905 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1906 @{$parents->{$c}} = split(/ /, $p);
1907}
1908
1909sub linearize_history {
1910 my ($gs, $refs) = @_;
1911 my %parents;
1912 foreach my $c (@$refs) {
1913 read_commit_parents(\%parents, $c);
1914 }
1915
1916 my @linear_refs;
1917 my %skip = ();
1918 my $last_svn_commit = $gs->last_commit;
1919 foreach my $c (reverse @$refs) {
1920 next if $c eq $last_svn_commit;
1921 last if $skip{$c};
1922
1923 unshift @linear_refs, $c;
1924 $skip{$c} = 1;
1925
1926 # we only want the first parent to diff against for linear
1927 # history, we save the rest to inject when we finalize the
1928 # svn commit
1929 my $fp_a = verify_ref("$c~1");
1930 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1931 if (!$fp_a || !$fp_b) {
1932 die "Commit $c\n",
1933 "has no parent commit, and therefore ",
1934 "nothing to diff against.\n",
1935 "You should be working from a repository ",
1936 "originally created by git-svn\n";
1937 }
1938 if ($fp_a ne $fp_b) {
1939 die "$c~1 = $fp_a, however parsing commit $c ",
1940 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1941 }
1942
1943 foreach my $p (@{$parents{$c}}) {
1944 $skip{$p} = 1;
1945 }
1946 }
1947 (\@linear_refs, \%parents);
1948}
1949
1950sub find_file_type_and_diff_status {
1951 my ($path) = @_;
1952 return ('dir', '') if $path eq '';
1953
1954 my $diff_output =
1955 command_oneline(qw(diff --cached --name-status --), $path) || "";
1956 my $diff_status = (split(' ', $diff_output))[0] || "";
1957
1958 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1959
1960 return (undef, undef) if !$diff_status && !$ls_tree;
1961
1962 if ($diff_status eq "A") {
1963 return ("link", $diff_status) if -l $path;
1964 return ("dir", $diff_status) if -d $path;
1965 return ("file", $diff_status);
1966 }
1967
1968 my $mode = (split(' ', $ls_tree))[0] || "";
1969
1970 return ("link", $diff_status) if $mode eq "120000";
1971 return ("dir", $diff_status) if $mode eq "040000";
1972 return ("file", $diff_status);
1973}
1974
1975sub md5sum {
1976 my $arg = shift;
1977 my $ref = ref $arg;
1978 my $md5 = Digest::MD5->new();
1979 if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1980 $md5->addfile($arg) or croak $!;
1981 } elsif ($ref eq 'SCALAR') {
1982 $md5->add($$arg) or croak $!;
1983 } elsif (!$ref) {
1984 $md5->add($arg) or croak $!;
1985 } else {
1986 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1987 }
1988 return $md5->hexdigest();
1989}
1990
1991sub gc_directory {
1992 if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
1993 my $out_filename = $_ . ".gz";
1994 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1995 binmode $in_fh;
1996 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1997 die "Unable to open $out_filename: $!\n";
1998
1999 my $res;
2000 while ($res = sysread($in_fh, my $str, 1024)) {
2001 $gz->gzwrite($str) or
2002 die "Unable to write: ".$gz->gzerror()."!\n";
2003 }
2004 unlink $_ or die "unlink $File::Find::name: $!\n";
2005 } elsif (-f $_ && basename($_) eq "index") {
2006 unlink $_ or die "unlink $_: $!\n";
2007 }
2008}
2009
2010__END__
2011
2012Data structures:
2013
2014
2015$remotes = { # returned by read_all_remotes()
2016 'svn' => {
2017 # svn-remote.svn.url=https://svn.musicpd.org
2018 url => 'https://svn.musicpd.org',
2019 # svn-remote.svn.fetch=mpd/trunk:trunk
2020 fetch => {
2021 'mpd/trunk' => 'trunk',
2022 },
2023 # svn-remote.svn.tags=mpd/tags/*:tags/*
2024 tags => {
2025 path => {
2026 left => 'mpd/tags',
2027 right => '',
2028 regex => qr!mpd/tags/([^/]+)$!,
2029 glob => 'tags/*',
2030 },
2031 ref => {
2032 left => 'tags',
2033 right => '',
2034 regex => qr!tags/([^/]+)$!,
2035 glob => 'tags/*',
2036 },
2037 }
2038 }
2039};
2040
2041$log_entry hashref as returned by libsvn_log_entry()
2042{
2043 log => 'whitespace-formatted log entry
2044', # trailing newline is preserved
2045 revision => '8', # integer
2046 date => '2004-02-24T17:01:44.108345Z', # commit date
2047 author => 'committer name'
2048};
2049
2050
2051# this is generated by generate_diff();
2052@mods = array of diff-index line hashes, each element represents one line
2053 of diff-index output
2054
2055diff-index line ($m hash)
2056{
2057 mode_a => first column of diff-index output, no leading ':',
2058 mode_b => second column of diff-index output,
2059 sha1_b => sha1sum of the final blob,
2060 chg => change type [MCRADT],
2061 file_a => original file name of a file (iff chg is 'C' or 'R')
2062 file_b => new/current file name of a file (any chg)
2063}
2064;
2065
2066# retval of read_url_paths{,_all}();
2067$l_map = {
2068 # repository root url
2069 'https://svn.musicpd.org' => {
2070 # repository path # GIT_SVN_ID
2071 'mpd/trunk' => 'trunk',
2072 'mpd/tags/0.11.5' => 'tags/0.11.5',
2073 },
2074}
2075
2076Notes:
2077 I don't trust the each() function on unless I created %hash myself
2078 because the internal iterator may not have started at base.