1#!/usr/bin/perl -w
2#
3# Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
4# Copyright 2005 Ryan Anderson <ryan@michonline.com>
5#
6# GPL v2 (See COPYING)
7#
8# Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
9#
10# Sends a collection of emails to the given email addresses, disturbingly fast.
11#
12# Supports two formats:
13# 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
14# 2. The original format support by Greg's script:
15# first line of the message is who to CC,
16# and second line is the subject of the message.
17#
18use strict;
20use warnings;
21use Term::ReadLine;
22use Getopt::Long;
23use Text::ParseWords;
24use Data::Dumper;
25use Term::ANSIColor;
26use File::Temp qw/ tempdir tempfile /;
27use Error qw(:try);
28use Git;
29Getopt::Long::Configure qw/ pass_through /;
31package FakeTerm;
33sub new {
34 my ($class, $reason) = @_;
35 return bless \$reason, shift;
36}
37sub readline {
38 my $self = shift;
39 die "Cannot use readline on FakeTerm: $$self";
40}
41package main;
42sub usage {
45 print <<EOT;
46git send-email [options] <file | directory | rev-list options >
47 Composing:
49 --from <str> * Email From:
50 --[no-]to <str> * Email To:
51 --[no-]cc <str> * Email Cc:
52 --[no-]bcc <str> * Email Bcc:
53 --subject <str> * Email "Subject:"
54 --in-reply-to <str> * Email "In-Reply-To:"
55 --annotate * Review each patch that will be sent in an editor.
56 --compose * Open an editor for introduction.
57 Sending:
59 --envelope-sender <str> * Email envelope sender.
60 --smtp-server <str:int> * Outgoing SMTP server to use. The port
61 is optional. Default 'localhost'.
62 --smtp-server-port <int> * Outgoing SMTP server port.
63 --smtp-user <str> * Username for SMTP-AUTH.
64 --smtp-pass <str> * Password for SMTP-AUTH; not necessary.
65 --smtp-encryption <str> * tls or ssl; anything else disables.
66 --smtp-ssl * Deprecated. Use '--smtp-encryption ssl'.
67 Automating:
69 --identity <str> * Use the sendemail.<id> options.
70 --cc-cmd <str> * Email Cc: via `<str> \$patch_path`
71 --suppress-cc <str> * author, self, sob, cc, cccmd, body, bodycc, all.
72 --[no-]signed-off-by-cc * Send to Signed-off-by: addresses. Default on.
73 --[no-]suppress-from * Send to self. Default off.
74 --[no-]chain-reply-to * Chain In-Reply-To: fields. Default off.
75 --[no-]thread * Use In-Reply-To: field. Default on.
76 Administering:
78 --confirm <str> * Confirm recipients before sending;
79 auto, cc, compose, always, or never.
80 --quiet * Output one line of info per email.
81 --dry-run * Don't actually send the emails.
82 --[no-]validate * Perform patch sanity checks. Default on.
83 --[no-]format-patch * understand any non optional arguments as
84 `git format-patch` ones.
85EOT
87 exit(1);
88}
89# most mail servers generate the Date: header, but not all...
91sub format_2822_time {
92 my ($time) = @_;
93 my @localtm = localtime($time);
94 my @gmttm = gmtime($time);
95 my $localmin = $localtm[1] + $localtm[2] * 60;
96 my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
97 if ($localtm[0] != $gmttm[0]) {
98 die "local zone differs from GMT by a non-minute interval\n";
99 }
100 if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
101 $localmin += 1440;
102 } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
103 $localmin -= 1440;
104 } elsif ($gmttm[6] != $localtm[6]) {
105 die "local time offset greater than or equal to 24 hours\n";
106 }
107 my $offset = $localmin - $gmtmin;
108 my $offhour = $offset / 60;
109 my $offmin = abs($offset % 60);
110 if (abs($offhour) >= 24) {
111 die ("local time offset greater than or equal to 24 hours\n");
112 }
113 return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
115 qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
116 $localtm[3],
117 qw(Jan Feb Mar Apr May Jun
118 Jul Aug Sep Oct Nov Dec)[$localtm[4]],
119 $localtm[5]+1900,
120 $localtm[2],
121 $localtm[1],
122 $localtm[0],
123 ($offset >= 0) ? '+' : '-',
124 abs($offhour),
125 $offmin,
126 );
127}
128my $have_email_valid = eval { require Email::Valid; 1 };
130my $have_mail_address = eval { require Mail::Address; 1 };
131my $smtp;
132my $auth;
133sub unique_email_list(@);
135sub cleanup_compose_files();
136# Variables we fill in automatically, or via prompting:
138my (@to,$no_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
139 $initial_reply_to,$initial_subject,@files,
140 $author,$sender,$smtp_authpass,$annotate,$compose,$time);
141my $envelope_sender;
143# Example reply to:
145#$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
146my $repo = eval { Git->repository() };
148my @repo = $repo ? ($repo) : ();
149my $term = eval {
150 $ENV{"GIT_SEND_EMAIL_NOTTY"}
151 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
152 : new Term::ReadLine 'git-send-email';
153};
154if ($@) {
155 $term = new FakeTerm "$@: going non-interactive";
156}
157# Behavior modification variables
159my ($quiet, $dry_run) = (0, 0);
160my $format_patch;
161my $compose_filename;
162# Handle interactive edition of files.
164my $multiedit;
165my $editor = Git::command_oneline('var', 'GIT_EDITOR');
166sub do_edit {
168 if (defined($multiedit) && !$multiedit) {
169 map {
170 system('sh', '-c', $editor.' "$@"', $editor, $_);
171 if (($? & 127) || ($? >> 8)) {
172 die("the editor exited uncleanly, aborting everything");
173 }
174 } @_;
175 } else {
176 system('sh', '-c', $editor.' "$@"', $editor, @_);
177 if (($? & 127) || ($? >> 8)) {
178 die("the editor exited uncleanly, aborting everything");
179 }
180 }
181}
182# Variables with corresponding config settings
184my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
185my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
186my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
187my ($validate, $confirm);
188my (@suppress_cc);
189my $not_set_by_user = "true but not set by the user";
191my %config_bool_settings = (
193 "thread" => [\$thread, 1],
194 "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
195 "suppressfrom" => [\$suppress_from, undef],
196 "signedoffbycc" => [\$signed_off_by_cc, undef],
197 "signedoffcc" => [\$signed_off_by_cc, undef], # Deprecated
198 "validate" => [\$validate, 1],
199);
200my %config_settings = (
202 "smtpserver" => \$smtp_server,
203 "smtpserverport" => \$smtp_server_port,
204 "smtpuser" => \$smtp_authuser,
205 "smtppass" => \$smtp_authpass,
206 "to" => \@to,
207 "cc" => \@initial_cc,
208 "cccmd" => \$cc_cmd,
209 "aliasfiletype" => \$aliasfiletype,
210 "bcc" => \@bcclist,
211 "aliasesfile" => \@alias_files,
212 "suppresscc" => \@suppress_cc,
213 "envelopesender" => \$envelope_sender,
214 "multiedit" => \$multiedit,
215 "confirm" => \$confirm,
216 "from" => \$sender,
217);
218# Help users prepare for 1.7.0
220sub chain_reply_to {
221 if (defined $chain_reply_to &&
222 $chain_reply_to eq $not_set_by_user) {
223 print STDERR
224 "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
225 "Set sendemail.chainreplyto configuration variable to true if\n" .
226 "you want to keep --chain-reply-to as your default.\n";
227 $chain_reply_to = 0;
228 }
229 return $chain_reply_to;
230}
231# Handle Uncouth Termination
233sub signal_handler {
234 # Make text normal
236 print color("reset"), "\n";
237 # SMTP password masked
239 system "stty echo";
240 # tmp files from --compose
242 if (defined $compose_filename) {
243 if (-e $compose_filename) {
244 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
245 }
246 if (-e ($compose_filename . ".final")) {
247 print "'$compose_filename.final' contains the composed email.\n"
248 }
249 }
250 exit;
252};
253$SIG{TERM} = \&signal_handler;
255$SIG{INT} = \&signal_handler;
256# Begin by accumulating all the variables (defined above), that we will end up
258# needing, first, from the command line:
259my $rc = GetOptions("sender|from=s" => \$sender,
261 "in-reply-to=s" => \$initial_reply_to,
262 "subject=s" => \$initial_subject,
263 "to=s" => \@to,
264 "no-to" => \$no_to,
265 "cc=s" => \@initial_cc,
266 "no-cc" => \$no_cc,
267 "bcc=s" => \@bcclist,
268 "no-bcc" => \$no_bcc,
269 "chain-reply-to!" => \$chain_reply_to,
270 "smtp-server=s" => \$smtp_server,
271 "smtp-server-port=s" => \$smtp_server_port,
272 "smtp-user=s" => \$smtp_authuser,
273 "smtp-pass:s" => \$smtp_authpass,
274 "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
275 "smtp-encryption=s" => \$smtp_encryption,
276 "identity=s" => \$identity,
277 "annotate" => \$annotate,
278 "compose" => \$compose,
279 "quiet" => \$quiet,
280 "cc-cmd=s" => \$cc_cmd,
281 "suppress-from!" => \$suppress_from,
282 "suppress-cc=s" => \@suppress_cc,
283 "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
284 "confirm=s" => \$confirm,
285 "dry-run" => \$dry_run,
286 "envelope-sender=s" => \$envelope_sender,
287 "thread!" => \$thread,
288 "validate!" => \$validate,
289 "format-patch!" => \$format_patch,
290 );
291unless ($rc) {
293 usage();
294}
295die "Cannot run git format-patch from outside a repository\n"
297 if $format_patch and not $repo;
298# Now, let's fill any that aren't set in with defaults:
300sub read_config {
302 my ($prefix) = @_;
303 foreach my $setting (keys %config_bool_settings) {
305 my $target = $config_bool_settings{$setting}->[0];
306 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
307 }
308 foreach my $setting (keys %config_settings) {
310 my $target = $config_settings{$setting};
311 next if $setting eq "to" and defined $no_to;
312 next if $setting eq "cc" and defined $no_cc;
313 next if $setting eq "bcc" and defined $no_bcc;
314 if (ref($target) eq "ARRAY") {
315 unless (@$target) {
316 my @values = Git::config(@repo, "$prefix.$setting");
317 @$target = @values if (@values && defined $values[0]);
318 }
319 }
320 else {
321 $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
322 }
323 }
324 if (!defined $smtp_encryption) {
326 my $enc = Git::config(@repo, "$prefix.smtpencryption");
327 if (defined $enc) {
328 $smtp_encryption = $enc;
329 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
330 $smtp_encryption = 'ssl';
331 }
332 }
333}
334# read configuration from [sendemail "$identity"], fall back on [sendemail]
336$identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
337read_config("sendemail.$identity") if (defined $identity);
338read_config("sendemail");
339# fall back on builtin bool defaults
341foreach my $setting (values %config_bool_settings) {
342 ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
343}
344# 'default' encryption is none -- this only prevents a warning
346$smtp_encryption = '' unless (defined $smtp_encryption);
347# Set CC suppressions
349my(%suppress_cc);
350if (@suppress_cc) {
351 foreach my $entry (@suppress_cc) {
352 die "Unknown --suppress-cc field: '$entry'\n"
353 unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
354 $suppress_cc{$entry} = 1;
355 }
356}
357if ($suppress_cc{'all'}) {
359 foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
360 $suppress_cc{$entry} = 1;
361 }
362 delete $suppress_cc{'all'};
363}
364# If explicit old-style ones are specified, they trump --suppress-cc.
366$suppress_cc{'self'} = $suppress_from if defined $suppress_from;
367$suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
368if ($suppress_cc{'body'}) {
370 foreach my $entry (qw (sob bodycc)) {
371 $suppress_cc{$entry} = 1;
372 }
373 delete $suppress_cc{'body'};
374}
375# Set confirm's default value
377my $confirm_unconfigured = !defined $confirm;
378if ($confirm_unconfigured) {
379 $confirm = scalar %suppress_cc ? 'compose' : 'auto';
380};
381die "Unknown --confirm setting: '$confirm'\n"
382 unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
383# Debugging, print out the suppressions.
385if (0) {
386 print "suppressions:\n";
387 foreach my $entry (keys %suppress_cc) {
388 printf " %-5s -> $suppress_cc{$entry}\n", $entry;
389 }
390}
391my ($repoauthor, $repocommitter);
393($repoauthor) = Git::ident_person(@repo, 'author');
394($repocommitter) = Git::ident_person(@repo, 'committer');
395# Verify the user input
397foreach my $entry (@to) {
399 die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
400}
401foreach my $entry (@initial_cc) {
403 die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
404}
405foreach my $entry (@bcclist) {
407 die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
408}
409sub parse_address_line {
411 if ($have_mail_address) {
412 return map { $_->format } Mail::Address->parse($_[0]);
413 } else {
414 return split_addrs($_[0]);
415 }
416}
417sub split_addrs {
419 return quotewords('\s*,\s*', 1, @_);
420}
421my %aliases;
423my %parse_alias = (
424 # multiline formats can be supported in the future
425 mutt => sub { my $fh = shift; while (<$fh>) {
426 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
427 my ($alias, $addr) = ($1, $2);
428 $addr =~ s/#.*$//; # mutt allows # comments
429 # commas delimit multiple addresses
430 $aliases{$alias} = [ split_addrs($addr) ];
431 }}},
432 mailrc => sub { my $fh = shift; while (<$fh>) {
433 if (/^alias\s+(\S+)\s+(.*)$/) {
434 # spaces delimit multiple addresses
435 $aliases{$1} = [ quotewords('\s+', 0, $2) ];
436 }}},
437 pine => sub { my $fh = shift; my $f='\t[^\t]*';
438 for (my $x = ''; defined($x); $x = $_) {
439 chomp $x;
440 $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
441 $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
442 $aliases{$1} = [ split_addrs($2) ];
443 }},
444 elm => sub { my $fh = shift;
445 while (<$fh>) {
446 if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
447 my ($alias, $addr) = ($1, $2);
448 $aliases{$alias} = [ split_addrs($addr) ];
449 }
450 } },
451 gnus => sub { my $fh = shift; while (<$fh>) {
453 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
454 $aliases{$1} = [ $2 ];
455 }}}
456);
457if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
459 foreach my $file (@alias_files) {
460 open my $fh, '<', $file or die "opening $file: $!\n";
461 $parse_alias{$aliasfiletype}->($fh);
462 close $fh;
463 }
464}
465($sender) = expand_aliases($sender) if defined $sender;
467# returns 1 if the conflict must be solved using it as a format-patch argument
469sub check_file_rev_conflict($) {
470 return unless $repo;
471 my $f = shift;
472 try {
473 $repo->command('rev-parse', '--verify', '--quiet', $f);
474 if (defined($format_patch)) {
475 return $format_patch;
476 }
477 die(<<EOF);
478File '$f' exists but it could also be the range of commits
479to produce patches for. Please disambiguate by...
480 * Saying "./$f" if you mean a file; or
482 * Giving --format-patch option if you mean a range.
483EOF
484 } catch Git::Error::Command with {
485 return 0;
486 }
487}
488# Now that all the defaults are set, process the rest of the command line
490# arguments and collect up the files that need to be processed.
491my @rev_list_opts;
492while (defined(my $f = shift @ARGV)) {
493 if ($f eq "--") {
494 push @rev_list_opts, "--", @ARGV;
495 @ARGV = ();
496 } elsif (-d $f and !check_file_rev_conflict($f)) {
497 opendir(DH,$f)
498 or die "Failed to opendir $f: $!";
499 push @files, grep { -f $_ } map { +$f . "/" . $_ }
501 sort readdir(DH);
502 closedir(DH);
503 } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
504 push @files, $f;
505 } else {
506 push @rev_list_opts, $f;
507 }
508}
509if (@rev_list_opts) {
511 die "Cannot run git format-patch from outside a repository\n"
512 unless $repo;
513 push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
514}
515if ($validate) {
517 foreach my $f (@files) {
518 unless (-p $f) {
519 my $error = validate_patch($f);
520 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
521 }
522 }
523}
524if (@files) {
526 unless ($quiet) {
527 print $_,"\n" for (@files);
528 }
529} else {
530 print STDERR "\nNo patch files specified!\n\n";
531 usage();
532}
533sub get_patch_subject($) {
535 my $fn = shift;
536 open (my $fh, '<', $fn);
537 while (my $line = <$fh>) {
538 next unless ($line =~ /^Subject: (.*)$/);
539 close $fh;
540 return "GIT: $1\n";
541 }
542 close $fh;
543 die "No subject line in $fn ?";
544}
545if ($compose) {
547 # Note that this does not need to be secure, but we will make a small
548 # effort to have it be unique
549 $compose_filename = ($repo ?
550 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
551 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
552 open(C,">",$compose_filename)
553 or die "Failed to open for writing $compose_filename: $!";
554 my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
557 my $tpl_subject = $initial_subject || '';
558 my $tpl_reply_to = $initial_reply_to || '';
559 print C <<EOT;
561From $tpl_sender # This line is ignored.
562GIT: Lines beginning in "GIT:" will be removed.
563GIT: Consider including an overall diffstat or table of contents
564GIT: for the patch you are writing.
565GIT:
566GIT: Clear the body content if you don't wish to send a summary.
567From: $tpl_sender
568Subject: $tpl_subject
569In-Reply-To: $tpl_reply_to
570EOT
572 for my $f (@files) {
573 print C get_patch_subject($f);
574 }
575 close(C);
576 if ($annotate) {
578 do_edit($compose_filename, @files);
579 } else {
580 do_edit($compose_filename);
581 }
582 open(C2,">",$compose_filename . ".final")
584 or die "Failed to open $compose_filename.final : " . $!;
585 open(C,"<",$compose_filename)
587 or die "Failed to open $compose_filename : " . $!;
588 my $need_8bit_cte = file_has_nonascii($compose_filename);
590 my $in_body = 0;
591 my $summary_empty = 1;
592 while(<C>) {
593 next if m/^GIT:/;
594 if ($in_body) {
595 $summary_empty = 0 unless (/^\n$/);
596 } elsif (/^\n$/) {
597 $in_body = 1;
598 if ($need_8bit_cte) {
599 print C2 "MIME-Version: 1.0\n",
600 "Content-Type: text/plain; ",
601 "charset=UTF-8\n",
602 "Content-Transfer-Encoding: 8bit\n";
603 }
604 } elsif (/^MIME-Version:/i) {
605 $need_8bit_cte = 0;
606 } elsif (/^Subject:\s*(.+)\s*$/i) {
607 $initial_subject = $1;
608 my $subject = $initial_subject;
609 $_ = "Subject: " .
610 ($subject =~ /[^[:ascii:]]/ ?
611 quote_rfc2047($subject) :
612 $subject) .
613 "\n";
614 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
615 $initial_reply_to = $1;
616 next;
617 } elsif (/^From:\s*(.+)\s*$/i) {
618 $sender = $1;
619 next;
620 } elsif (/^(?:To|Cc|Bcc):/i) {
621 print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
622 next;
623 }
624 print C2 $_;
625 }
626 close(C);
627 close(C2);
628 if ($summary_empty) {
630 print "Summary email is empty, skipping it\n";
631 $compose = -1;
632 }
633} elsif ($annotate) {
634 do_edit(@files);
635}
636sub ask {
638 my ($prompt, %arg) = @_;
639 my $valid_re = $arg{valid_re};
640 my $default = $arg{default};
641 my $resp;
642 my $i = 0;
643 return defined $default ? $default : undef
644 unless defined $term->IN and defined fileno($term->IN) and
645 defined $term->OUT and defined fileno($term->OUT);
646 while ($i++ < 10) {
647 $resp = $term->readline($prompt);
648 if (!defined $resp) { # EOF
649 print "\n";
650 return defined $default ? $default : undef;
651 }
652 if ($resp eq '' and defined $default) {
653 return $default;
654 }
655 if (!defined $valid_re or $resp =~ /$valid_re/) {
656 return $resp;
657 }
658 }
659 return undef;
660}
661my $prompting = 0;
663if (!defined $sender) {
664 $sender = $repoauthor || $repocommitter || '';
665 $sender = ask("Who should the emails appear to be from? [$sender] ",
666 default => $sender);
667 print "Emails will be sent from: ", $sender, "\n";
668 $prompting++;
669}
670if (!@to) {
672 my $to = ask("Who should the emails be sent to? ");
673 push @to, parse_address_line($to) if defined $to; # sanitized/validated later
674 $prompting++;
675}
676sub expand_aliases {
678 return map { expand_one_alias($_) } @_;
679}
680my %EXPANDED_ALIASES;
682sub expand_one_alias {
683 my $alias = shift;
684 if ($EXPANDED_ALIASES{$alias}) {
685 die "fatal: alias '$alias' expands to itself\n";
686 }
687 local $EXPANDED_ALIASES{$alias} = 1;
688 return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
689}
690@to = expand_aliases(@to);
692@to = (map { sanitize_address($_) } @to);
693@initial_cc = expand_aliases(@initial_cc);
694@bcclist = expand_aliases(@bcclist);
695if ($thread && !defined $initial_reply_to && $prompting) {
697 $initial_reply_to = ask(
698 "Message-ID to be used as In-Reply-To for the first email? ");
699}
700if (defined $initial_reply_to) {
701 $initial_reply_to =~ s/^\s*<?//;
702 $initial_reply_to =~ s/>?\s*$//;
703 $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
704}
705if (!defined $smtp_server) {
707 foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
708 if (-x $_) {
709 $smtp_server = $_;
710 last;
711 }
712 }
713 $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
714}
715if ($compose && $compose > 0) {
717 @files = ($compose_filename . ".final", @files);
718}
719# Variables we set as part of the loop over files
721our ($message_id, %mail, $subject, $reply_to, $references, $message,
722 $needs_confirm, $message_num, $ask_default);
723sub extract_valid_address {
725 my $address = shift;
726 my $local_part_regexp = '[^<>"\s@]+';
727 my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
728 # check for a local address:
730 return $address if ($address =~ /^($local_part_regexp)$/);
731 $address =~ s/^\s*<(.*)>\s*$/$1/;
733 if ($have_email_valid) {
734 return scalar Email::Valid->address($address);
735 } else {
736 # less robust/correct than the monster regexp in Email::Valid,
737 # but still does a 99% job, and one less dependency
738 $address =~ /($local_part_regexp\@$domain_regexp)/;
739 return $1;
740 }
741}
742# Usually don't need to change anything below here.
744# we make a "fake" message id by taking the current number
746# of seconds since the beginning of Unix time and tacking on
747# a random number to the end, in case we are called quicker than
748# 1 second since the last time we were called.
749# We'll setup a template for the message id, using the "from" address:
751my ($message_id_stamp, $message_id_serial);
753sub make_message_id
754{
755 my $uniq;
756 if (!defined $message_id_stamp) {
757 $message_id_stamp = sprintf("%s-%s", time, $$);
758 $message_id_serial = 0;
759 }
760 $message_id_serial++;
761 $uniq = "$message_id_stamp-$message_id_serial";
762 my $du_part;
764 for ($sender, $repocommitter, $repoauthor) {
765 $du_part = extract_valid_address(sanitize_address($_));
766 last if (defined $du_part and $du_part ne '');
767 }
768 if (not defined $du_part or $du_part eq '') {
769 use Sys::Hostname qw();
770 $du_part = 'user@' . Sys::Hostname::hostname();
771 }
772 my $message_id_template = "<%s-git-send-email-%s>";
773 $message_id = sprintf($message_id_template, $uniq, $du_part);
774 #print "new message id = $message_id\n"; # Was useful for debugging
775}
776$time = time - scalar $#files;
780sub unquote_rfc2047 {
782 local ($_) = @_;
783 my $encoding;
784 if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
785 $encoding = $1;
786 s/_/ /g;
787 s/=([0-9A-F]{2})/chr(hex($1))/eg;
788 }
789 return wantarray ? ($_, $encoding) : $_;
790}
791sub quote_rfc2047 {
793 local $_ = shift;
794 my $encoding = shift || 'UTF-8';
795 s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
796 s/(.*)/=\?$encoding\?q\?$1\?=/;
797 return $_;
798}
799sub is_rfc2047_quoted {
801 my $s = shift;
802 my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
803 my $encoded_text = '[!->@-~]+';
804 length($s) <= 75 &&
805 $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
806}
807# use the simplest quoting being able to handle the recipient
809sub sanitize_address
810{
811 my ($recipient) = @_;
812 my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
813 if (not $recipient_name) {
815 return "$recipient";
816 }
817 # if recipient_name is already quoted, do nothing
819 if (is_rfc2047_quoted($recipient_name)) {
820 return $recipient;
821 }
822 # rfc2047 is needed if a non-ascii char is included
824 if ($recipient_name =~ /[^[:ascii:]]/) {
825 $recipient_name =~ s/^"(.*)"$/$1/;
826 $recipient_name = quote_rfc2047($recipient_name);
827 }
828 # double quotes are needed if specials or CTLs are included
830 elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
831 $recipient_name =~ s/(["\\\r])/\\$1/g;
832 $recipient_name = "\"$recipient_name\"";
833 }
834 return "$recipient_name $recipient_addr";
836}
838# Returns 1 if the message was sent, and 0 otherwise.
840# In actuality, the whole program dies when there
841# is an error sending a message.
842sub send_message
844{
845 my @recipients = unique_email_list(@to);
846 @cc = (grep { my $cc = extract_valid_address($_);
847 not grep { $cc eq $_ } @recipients
848 }
849 map { sanitize_address($_) }
850 @cc);
851 my $to = join (",\n\t", @recipients);
852 @recipients = unique_email_list(@recipients,@cc,@bcclist);
853 @recipients = (map { extract_valid_address($_) } @recipients);
854 my $date = format_2822_time($time++);
855 my $gitversion = '@@GIT_VERSION@@';
856 if ($gitversion =~ m/..GIT_VERSION../) {
857 $gitversion = Git::version();
858 }
859 my $cc = join(",\n\t", unique_email_list(@cc));
861 my $ccline = "";
862 if ($cc ne '') {
863 $ccline = "\nCc: $cc";
864 }
865 my $sanitized_sender = sanitize_address($sender);
866 make_message_id() unless defined($message_id);
867 my $header = "From: $sanitized_sender
869To: $to${ccline}
870Subject: $subject
871Date: $date
872Message-Id: $message_id
873X-Mailer: git-send-email $gitversion
874";
875 if ($reply_to) {
876 $header .= "In-Reply-To: $reply_to\n";
878 $header .= "References: $references\n";
879 }
880 if (@xh) {
881 $header .= join("\n", @xh) . "\n";
882 }
883 my @sendmail_parameters = ('-i', @recipients);
885 my $raw_from = $sanitized_sender;
886 if (defined $envelope_sender && $envelope_sender ne "auto") {
887 $raw_from = $envelope_sender;
888 }
889 $raw_from = extract_valid_address($raw_from);
890 unshift (@sendmail_parameters,
891 '-f', $raw_from) if(defined $envelope_sender);
892 if ($needs_confirm && !$dry_run) {
894 print "\n$header\n";
895 if ($needs_confirm eq "inform") {
896 $confirm_unconfigured = 0; # squelch this message for the rest of this run
897 $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
898 print " The Cc list above has been expanded by additional\n";
899 print " addresses found in the patch commit message. By default\n";
900 print " send-email prompts before sending whenever this occurs.\n";
901 print " This behavior is controlled by the sendemail.confirm\n";
902 print " configuration setting.\n";
903 print "\n";
904 print " For additional information, run 'git send-email --help'.\n";
905 print " To retain the current behavior, but squelch this message,\n";
906 print " run 'git config --global sendemail.confirm auto'.\n\n";
907 }
908 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
909 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
910 default => $ask_default);
911 die "Send this email reply required" unless defined $_;
912 if (/^n/i) {
913 return 0;
914 } elsif (/^q/i) {
915 cleanup_compose_files();
916 exit(0);
917 } elsif (/^a/i) {
918 $confirm = 'never';
919 }
920 }
921 if ($dry_run) {
923 # We don't want to send the email.
924 } elsif ($smtp_server =~ m#^/#) {
925 my $pid = open my $sm, '|-';
926 defined $pid or die $!;
927 if (!$pid) {
928 exec($smtp_server, @sendmail_parameters) or die $!;
929 }
930 print $sm "$header\n$message";
931 close $sm or die $?;
932 } else {
933 if (!defined $smtp_server) {
935 die "The required SMTP server is not properly defined."
936 }
937 if ($smtp_encryption eq 'ssl') {
939 $smtp_server_port ||= 465; # ssmtp
940 require Net::SMTP::SSL;
941 $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
942 }
943 else {
944 require Net::SMTP;
945 $smtp ||= Net::SMTP->new((defined $smtp_server_port)
946 ? "$smtp_server:$smtp_server_port"
947 : $smtp_server);
948 if ($smtp_encryption eq 'tls' && $smtp) {
949 require Net::SMTP::SSL;
950 $smtp->command('STARTTLS');
951 $smtp->response();
952 if ($smtp->code == 220) {
953 $smtp = Net::SMTP::SSL->start_SSL($smtp)
954 or die "STARTTLS failed! ".$smtp->message;
955 $smtp_encryption = '';
956 # Send EHLO again to receive fresh
957 # supported commands
958 $smtp->hello();
959 } else {
960 die "Server does not support STARTTLS! ".$smtp->message;
961 }
962 }
963 }
964 if (!$smtp) {
966 die "Unable to initialize SMTP properly. Is there something wrong with your config?";
967 }
968 if (defined $smtp_authuser) {
970 if (!defined $smtp_authpass) {
972 system "stty -echo";
974 do {
976 print "Password: ";
977 $_ = <STDIN>;
978 print "\n";
979 } while (!defined $_);
980 chomp($smtp_authpass = $_);
982 system "stty echo";
984 }
985 $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
987 }
988 $smtp->mail( $raw_from ) or die $smtp->message;
990 $smtp->to( @recipients ) or die $smtp->message;
991 $smtp->data or die $smtp->message;
992 $smtp->datasend("$header\n$message") or die $smtp->message;
993 $smtp->dataend() or die $smtp->message;
994 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
995 }
996 if ($quiet) {
997 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
998 } else {
999 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1000 if ($smtp_server !~ m#^/#) {
1001 print "Server: $smtp_server\n";
1002 print "MAIL FROM:<$raw_from>\n";
1003 foreach my $entry (@recipients) {
1004 print "RCPT TO:<$entry>\n";
1005 }
1006 } else {
1007 print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1008 }
1009 print $header, "\n";
1010 if ($smtp) {
1011 print "Result: ", $smtp->code, ' ',
1012 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1013 } else {
1014 print "Result: OK\n";
1015 }
1016 }
1017 return 1;
1019}
1020$reply_to = $initial_reply_to;
1022$references = $initial_reply_to || '';
1023$subject = $initial_subject;
1024$message_num = 0;
1025foreach my $t (@files) {
1027 open(F,"<",$t) or die "can't open file $t";
1028 my $author = undef;
1030 my $author_encoding;
1031 my $has_content_type;
1032 my $body_encoding;
1033 @cc = ();
1034 @xh = ();
1035 my $input_format = undef;
1036 my @header = ();
1037 $message = "";
1038 $message_num++;
1039 # First unfold multiline header fields
1040 while(<F>) {
1041 last if /^\s*$/;
1042 if (/^\s+\S/ and @header) {
1043 chomp($header[$#header]);
1044 s/^\s+/ /;
1045 $header[$#header] .= $_;
1046 } else {
1047 push(@header, $_);
1048 }
1049 }
1050 # Now parse the header
1051 foreach(@header) {
1052 if (/^From /) {
1053 $input_format = 'mbox';
1054 next;
1055 }
1056 chomp;
1057 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1058 $input_format = 'mbox';
1059 }
1060 if (defined $input_format && $input_format eq 'mbox') {
1062 if (/^Subject:\s+(.*)$/) {
1063 $subject = $1;
1064 }
1065 elsif (/^From:\s+(.*)$/) {
1066 ($author, $author_encoding) = unquote_rfc2047($1);
1067 next if $suppress_cc{'author'};
1068 next if $suppress_cc{'self'} and $author eq $sender;
1069 printf("(mbox) Adding cc: %s from line '%s'\n",
1070 $1, $_) unless $quiet;
1071 push @cc, $1;
1072 }
1073 elsif (/^Cc:\s+(.*)$/) {
1074 foreach my $addr (parse_address_line($1)) {
1075 if (unquote_rfc2047($addr) eq $sender) {
1076 next if ($suppress_cc{'self'});
1077 } else {
1078 next if ($suppress_cc{'cc'});
1079 }
1080 printf("(mbox) Adding cc: %s from line '%s'\n",
1081 $addr, $_) unless $quiet;
1082 push @cc, $addr;
1083 }
1084 }
1085 elsif (/^Content-type:/i) {
1086 $has_content_type = 1;
1087 if (/charset="?([^ "]+)/) {
1088 $body_encoding = $1;
1089 }
1090 push @xh, $_;
1091 }
1092 elsif (/^Message-Id: (.*)/i) {
1093 $message_id = $1;
1094 }
1095 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1096 push @xh, $_;
1097 }
1098 } else {
1100 # In the traditional
1101 # "send lots of email" format,
1102 # line 1 = cc
1103 # line 2 = subject
1104 # So let's support that, too.
1105 $input_format = 'lots';
1106 if (@cc == 0 && !$suppress_cc{'cc'}) {
1107 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1108 $_, $_) unless $quiet;
1109 push @cc, $_;
1110 } elsif (!defined $subject) {
1111 $subject = $_;
1112 }
1113 }
1114 }
1115 # Now parse the message body
1116 while(<F>) {
1117 $message .= $_;
1118 if (/^(Signed-off-by|Cc): (.*)$/i) {
1119 chomp;
1120 my ($what, $c) = ($1, $2);
1121 chomp $c;
1122 if ($c eq $sender) {
1123 next if ($suppress_cc{'self'});
1124 } else {
1125 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1126 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1127 }
1128 push @cc, $c;
1129 printf("(body) Adding cc: %s from line '%s'\n",
1130 $c, $_) unless $quiet;
1131 }
1132 }
1133 close F;
1134 if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1136 open(F, "$cc_cmd \Q$t\E |")
1137 or die "(cc-cmd) Could not execute '$cc_cmd'";
1138 while(<F>) {
1139 my $c = $_;
1140 $c =~ s/^\s*//g;
1141 $c =~ s/\n$//g;
1142 next if ($c eq $sender and $suppress_from);
1143 push @cc, $c;
1144 printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1145 $c, $cc_cmd) unless $quiet;
1146 }
1147 close F
1148 or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1149 }
1150 if (defined $author and $author ne $sender) {
1152 $message = "From: $author\n\n$message";
1153 if (defined $author_encoding) {
1154 if ($has_content_type) {
1155 if ($body_encoding eq $author_encoding) {
1156 # ok, we already have the right encoding
1157 }
1158 else {
1159 # uh oh, we should re-encode
1160 }
1161 }
1162 else {
1163 push @xh,
1164 'MIME-Version: 1.0',
1165 "Content-Type: text/plain; charset=$author_encoding",
1166 'Content-Transfer-Encoding: 8bit';
1167 }
1168 }
1169 }
1170 $needs_confirm = (
1172 $confirm eq "always" or
1173 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1174 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1175 $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1176 @cc = (@initial_cc, @cc);
1178 my $message_was_sent = send_message();
1180 # set up for the next message
1182 if ($thread && $message_was_sent &&
1183 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1184 $reply_to = $message_id;
1185 if (length $references > 0) {
1186 $references .= "\n $message_id";
1187 } else {
1188 $references = "$message_id";
1189 }
1190 }
1191 $message_id = undef;
1192}
1193cleanup_compose_files();
1195sub cleanup_compose_files() {
1197 unlink($compose_filename, $compose_filename . ".final") if $compose;
1198}
1199$smtp->quit if $smtp;
1201sub unique_email_list(@) {
1203 my %seen;
1204 my @emails;
1205 foreach my $entry (@_) {
1207 if (my $clean = extract_valid_address($entry)) {
1208 $seen{$clean} ||= 0;
1209 next if $seen{$clean}++;
1210 push @emails, $entry;
1211 } else {
1212 print STDERR "W: unable to extract a valid address",
1213 " from: $entry\n";
1214 }
1215 }
1216 return @emails;
1217}
1218sub validate_patch {
1220 my $fn = shift;
1221 open(my $fh, '<', $fn)
1222 or die "unable to open $fn: $!\n";
1223 while (my $line = <$fh>) {
1224 if (length($line) > 998) {
1225 return "$.: patch contains a line longer than 998 characters";
1226 }
1227 }
1228 return undef;
1229}
1230sub file_has_nonascii {
1232 my $fn = shift;
1233 open(my $fh, '<', $fn)
1234 or die "unable to open $fn: $!\n";
1235 while (my $line = <$fh>) {
1236 return 1 if $line =~ /[^[:ascii:]]/;
1237 }
1238 return 0;
1239}