1#!/usr/bin/perl
2# Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3# License: GPL v2 or later
4use 5.008;
5use warnings;
6use strict;
7use vars qw/ $AUTHOR $VERSION
8 $sha1 $sha1_short $_revision $_repository
9 $_q $_authors $_authors_prog %users/;
10$AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
11$VERSION = '@@GIT_VERSION@@';
12use Carp qw/croak/;
14use Digest::MD5;
15use IO::File qw//;
16use File::Basename qw/dirname basename/;
17use File::Path qw/mkpath/;
18use File::Spec;
19use File::Find;
20use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
21use IPC::Open3;
22use Memoize;
23use Git::SVN;
25use Git::SVN::Editor;
26use Git::SVN::Fetcher;
27use Git::SVN::Ra;
28use Git::SVN::Prompt;
29use Git::SVN::Log;
30use Git::SVN::Migration;
31use Git::SVN::Utils qw(
33 fatal
34 can_compress
35 canonicalize_path
36 canonicalize_url
37 join_paths
38 add_path_to_url
39 join_paths
40);
41use Git qw(
43 git_cmd_try
44 command
45 command_oneline
46 command_noisy
47 command_output_pipe
48 command_close_pipe
49 command_bidi_pipe
50 command_close_bidi_pipe
51);
52BEGIN {
54 Memoize::memoize 'Git::config';
55 Memoize::memoize 'Git::config_bool';
56}
57# From which subdir have we been invoked?
60my $cmd_dir_prefix = eval {
61 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
62} || '';
63$Git::SVN::Ra::_log_window_size = 100;
65if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
67 $ENV{SVN_SSH} = $ENV{GIT_SSH};
68}
69if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
71 $ENV{SVN_SSH} =~ s/\\/\\\\/g;
72 $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
73}
74$Git::SVN::Log::TZ = $ENV{TZ};
76$ENV{TZ} = 'UTC';
77$| = 1; # unbuffer STDOUT
78# All SVN commands do it. Otherwise we may die on SIGPIPE when the remote
80# repository decides to close the connection which we expect to be kept alive.
81$SIG{PIPE} = 'IGNORE';
82# Given a dot separated version number, "subtract" it from
84# the SVN::Core::VERSION; non-negaitive return means the SVN::Core
85# is at least at the version the caller asked for.
86sub compare_svn_version {
87 my (@ours) = split(/\./, $SVN::Core::VERSION);
88 my (@theirs) = split(/\./, $_[0]);
89 my ($i, $diff);
90 for ($i = 0; $i < @ours && $i < @theirs; $i++) {
92 $diff = $ours[$i] - $theirs[$i];
93 return $diff if ($diff);
94 }
95 return 1 if ($i < @ours);
96 return -1 if ($i < @theirs);
97 return 0;
98}
99sub _req_svn {
101 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
102 require SVN::Ra;
103 require SVN::Delta;
104 if (::compare_svn_version('1.1.0') < 0) {
105 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
106 }
107}
108$sha1 = qr/[a-f\d]{40}/;
110$sha1_short = qr/[a-f\d]{4,40}/;
111my ($_stdin, $_help, $_edit,
112 $_message, $_file, $_branch_dest,
113 $_template, $_shared,
114 $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
115 $_before, $_after,
116 $_merge, $_strategy, $_preserve_merges, $_dry_run, $_parents, $_local,
117 $_prefix, $_no_checkout, $_url, $_verbose,
118 $_commit_url, $_tag, $_merge_info, $_interactive, $_set_svn_props);
119# This is a refactoring artifact so Git::SVN can get at this git-svn switch.
121sub opt_prefix { return $_prefix || '' }
122$Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
124$_q ||= 0;
125my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
126 'config-dir=s' => \$Git::SVN::Ra::config_dir,
127 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
128 'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
129 'include-paths=s' => \$Git::SVN::Fetcher::_include_regex,
130 'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
131my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
132 'authors-file|A=s' => \$_authors,
133 'authors-prog=s' => \$_authors_prog,
134 'repack:i' => \$Git::SVN::_repack,
135 'noMetadata' => \$Git::SVN::_no_metadata,
136 'useSvmProps' => \$Git::SVN::_use_svm_props,
137 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
138 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
139 'no-checkout' => \$_no_checkout,
140 'quiet|q+' => \$_q,
141 'repack-flags|repack-args|repack-opts=s' =>
142 \$Git::SVN::_repack_flags,
143 'use-log-author' => \$Git::SVN::_use_log_author,
144 'add-author-from' => \$Git::SVN::_add_author_from,
145 'localtime' => \$Git::SVN::_localtime,
146 %remote_opts );
147my ($_trunk, @_tags, @_branches, $_stdlayout);
149my %icv;
150my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
151 'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
152 'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
153 'stdlayout|s' => \$_stdlayout,
154 'minimize-url|m!' => \$Git::SVN::_minimize_url,
155 'no-metadata' => sub { $icv{noMetadata} = 1 },
156 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
157 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
158 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
159 'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
160 %remote_opts );
161my %cmt_opts = ( 'edit|e' => \$_edit,
162 'rmdir' => \$Git::SVN::Editor::_rmdir,
163 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
164 'l=i' => \$Git::SVN::Editor::_rename_limit,
165 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
166);
167my %cmd = (
169 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
170 { 'revision|r=s' => \$_revision,
171 'fetch-all|all' => \$_fetch_all,
172 'parent|p' => \$_fetch_parent,
173 %fc_opts } ],
174 clone => [ \&cmd_clone, "Initialize and fetch revisions",
175 { 'revision|r=s' => \$_revision,
176 'preserve-empty-dirs' =>
177 \$Git::SVN::Fetcher::_preserve_empty_dirs,
178 'placeholder-filename=s' =>
179 \$Git::SVN::Fetcher::_placeholder_filename,
180 %fc_opts, %init_opts } ],
181 init => [ \&cmd_init, "Initialize a repo for tracking" .
182 " (requires URL argument)",
183 \%init_opts ],
184 'multi-init' => [ \&cmd_multi_init,
185 "Deprecated alias for ".
186 "'$0 init -T<trunk> -b<branches> -t<tags>'",
187 \%init_opts ],
188 dcommit => [ \&cmd_dcommit,
189 'Commit several diffs to merge with upstream',
190 { 'merge|m|M' => \$_merge,
191 'strategy|s=s' => \$_strategy,
192 'verbose|v' => \$_verbose,
193 'dry-run|n' => \$_dry_run,
194 'fetch-all|all' => \$_fetch_all,
195 'commit-url=s' => \$_commit_url,
196 'set-svn-props=s' => \$_set_svn_props,
197 'revision|r=i' => \$_revision,
198 'no-rebase' => \$_no_rebase,
199 'mergeinfo=s' => \$_merge_info,
200 'interactive|i' => \$_interactive,
201 %cmt_opts, %fc_opts } ],
202 branch => [ \&cmd_branch,
203 'Create a branch in the SVN repository',
204 { 'message|m=s' => \$_message,
205 'destination|d=s' => \$_branch_dest,
206 'dry-run|n' => \$_dry_run,
207 'parents' => \$_parents,
208 'tag|t' => \$_tag,
209 'username=s' => \$Git::SVN::Prompt::_username,
210 'commit-url=s' => \$_commit_url } ],
211 tag => [ sub { $_tag = 1; cmd_branch(@_) },
212 'Create a tag in the SVN repository',
213 { 'message|m=s' => \$_message,
214 'destination|d=s' => \$_branch_dest,
215 'dry-run|n' => \$_dry_run,
216 'parents' => \$_parents,
217 'username=s' => \$Git::SVN::Prompt::_username,
218 'commit-url=s' => \$_commit_url } ],
219 'set-tree' => [ \&cmd_set_tree,
220 "Set an SVN repository to a git tree-ish",
221 { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
222 'create-ignore' => [ \&cmd_create_ignore,
223 'Create a .gitignore per svn:ignore',
224 { 'revision|r=i' => \$_revision
225 } ],
226 'mkdirs' => [ \&cmd_mkdirs ,
227 "recreate empty directories after a checkout",
228 { 'revision|r=i' => \$_revision } ],
229 'propget' => [ \&cmd_propget,
230 'Print the value of a property on a file or directory',
231 { 'revision|r=i' => \$_revision } ],
232 'propset' => [ \&cmd_propset,
233 'Set the value of a property on a file or directory - will be set on commit',
234 {} ],
235 'proplist' => [ \&cmd_proplist,
236 'List all properties of a file or directory',
237 { 'revision|r=i' => \$_revision } ],
238 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
239 { 'revision|r=i' => \$_revision
240 } ],
241 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
242 { 'revision|r=i' => \$_revision
243 } ],
244 'multi-fetch' => [ \&cmd_multi_fetch,
245 "Deprecated alias for $0 fetch --all",
246 { 'revision|r=s' => \$_revision, %fc_opts } ],
247 'migrate' => [ sub { },
248 # no-op, we automatically run this anyways,
249 'Migrate configuration/metadata/layout from
250 previous versions of git-svn',
251 { 'minimize' => \$Git::SVN::Migration::_minimize,
252 %remote_opts } ],
253 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
254 { 'limit=i' => \$Git::SVN::Log::limit,
255 'revision|r=s' => \$_revision,
256 'verbose|v' => \$Git::SVN::Log::verbose,
257 'incremental' => \$Git::SVN::Log::incremental,
258 'oneline' => \$Git::SVN::Log::oneline,
259 'show-commit' => \$Git::SVN::Log::show_commit,
260 'non-recursive' => \$Git::SVN::Log::non_recursive,
261 'authors-file|A=s' => \$_authors,
262 'color' => \$Git::SVN::Log::color,
263 'pager=s' => \$Git::SVN::Log::pager
264 } ],
265 'find-rev' => [ \&cmd_find_rev,
266 "Translate between SVN revision numbers and tree-ish",
267 { 'B|before' => \$_before,
268 'A|after' => \$_after } ],
269 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
270 { 'merge|m|M' => \$_merge,
271 'verbose|v' => \$_verbose,
272 'strategy|s=s' => \$_strategy,
273 'local|l' => \$_local,
274 'fetch-all|all' => \$_fetch_all,
275 'dry-run|n' => \$_dry_run,
276 'preserve-merges|p' => \$_preserve_merges,
277 %fc_opts } ],
278 'commit-diff' => [ \&cmd_commit_diff,
279 'Commit a diff between two trees',
280 { 'message|m=s' => \$_message,
281 'file|F=s' => \$_file,
282 'revision|r=s' => \$_revision,
283 %cmt_opts } ],
284 'info' => [ \&cmd_info,
285 "Show info about the latest SVN revision
286 on the current branch",
287 { 'url' => \$_url, } ],
288 'blame' => [ \&Git::SVN::Log::cmd_blame,
289 "Show what revision and author last modified each line of a file",
290 { 'git-format' => \$Git::SVN::Log::_git_format } ],
291 'reset' => [ \&cmd_reset,
292 "Undo fetches back to the specified SVN revision",
293 { 'revision|r=s' => \$_revision,
294 'parent|p' => \$_fetch_parent } ],
295 'gc' => [ \&cmd_gc,
296 "Compress unhandled.log files in .git/svn and remove " .
297 "index files in .git/svn",
298 {} ],
299);
300use Term::ReadLine;
302package FakeTerm;
303sub new {
304 my ($class, $reason) = @_;
305 return bless \$reason, shift;
306}
307sub readline {
308 my $self = shift;
309 die "Cannot use readline on FakeTerm: $$self";
310}
311package main;
312my $term;
314sub term_init {
315 $term = eval {
316 $ENV{"GIT_SVN_NOTTY"}
317 ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
318 : new Term::ReadLine 'git-svn';
319 };
320 if ($@) {
321 $term = new FakeTerm "$@: going non-interactive";
322 }
323}
324my $cmd;
326for (my $i = 0; $i < @ARGV; $i++) {
327 if (defined $cmd{$ARGV[$i]}) {
328 $cmd = $ARGV[$i];
329 splice @ARGV, $i, 1;
330 last;
331 } elsif ($ARGV[$i] eq 'help') {
332 $cmd = $ARGV[$i+1];
333 usage(0);
334 }
335};
336# make sure we're always running at the top-level working directory
338if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
339 $ENV{GIT_DIR} ||= ".git";
340 # catch the submodule case
341 if (-f $ENV{GIT_DIR}) {
342 open(my $fh, '<', $ENV{GIT_DIR}) or
343 die "failed to open $ENV{GIT_DIR}: $!\n";
344 $ENV{GIT_DIR} = $1 if <$fh> =~ /^gitdir: (.+)$/;
345 }
346} else {
347 my ($git_dir, $cdup);
348 git_cmd_try {
349 $git_dir = command_oneline([qw/rev-parse --git-dir/]);
350 } "Unable to find .git directory\n";
351 git_cmd_try {
352 $cdup = command_oneline(qw/rev-parse --show-cdup/);
353 chomp $cdup if ($cdup);
354 $cdup = "." unless ($cdup && length $cdup);
355 } "Already at toplevel, but $git_dir not found\n";
356 $ENV{GIT_DIR} = $git_dir;
357 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
358 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
359}
360my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
362read_git_config(\%opts);
364if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
365 Getopt::Long::Configure('pass_through');
366}
367my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
368 'minimize-connections' => \$Git::SVN::Migration::_minimize,
369 'id|i=s' => \$Git::SVN::default_ref_id,
370 'svn-remote|remote|R=s' => sub {
371 $Git::SVN::no_reuse_existing = 1;
372 $Git::SVN::default_repo_id = $_[1] });
373exit 1 if (!$rv && $cmd && $cmd ne 'log');
374usage(0) if $_help;
376version() if $_version;
377usage(1) unless defined $cmd;
378load_authors() if $_authors;
379if (defined $_authors_prog) {
380 $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
381}
382unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
384 Git::SVN::Migration::migration_check();
385}
386Git::SVN::init_vars();
387eval {
388 Git::SVN::verify_remotes_sanity();
389 $cmd{$cmd}->[0]->(@ARGV);
390 post_fetch_checkout();
391};
392fatal $@ if $@;
393exit 0;
394####################### primary functions ######################
396sub usage {
397 my $exit = shift || 0;
398 my $fd = $exit ? \*STDERR : \*STDOUT;
399 print $fd <<"";
400git-svn - bidirectional operations between a single Subversion tree and git
401usage: git svn <command> [options] [arguments]\n
402 print $fd "Available commands:\n" unless $cmd;
404 foreach (sort keys %cmd) {
406 next if $cmd && $cmd ne $_;
407 next if /^multi-/; # don't show deprecated commands
408 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
409 foreach (sort keys %{$cmd{$_}->[2]}) {
410 # mixed-case options are for .git/config only
411 next if /[A-Z]/ && /^[a-z]+$/i;
412 # prints out arguments as they should be passed:
413 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
414 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
415 "--$_" : "-$_" }
416 split /\|/,$_)," $x\n";
417 }
418 }
419 print $fd <<"";
420\nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
421arbitrary identifier if you're tracking multiple SVN branches/repositories in
422one git repository and want to keep them separate. See git-svn(1) for more
423information.
424 exit $exit;
426}
427sub version {
429 ::_req_svn();
430 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
431 exit 0;
432}
433sub ask {
435 my ($prompt, %arg) = @_;
436 my $valid_re = $arg{valid_re};
437 my $default = $arg{default};
438 my $resp;
439 my $i = 0;
440 term_init() unless $term;
441 if ( !( defined($term->IN)
443 && defined( fileno($term->IN) )
444 && defined( $term->OUT )
445 && defined( fileno($term->OUT) ) ) ){
446 return defined($default) ? $default : undef;
447 }
448 while ($i++ < 10) {
450 $resp = $term->readline($prompt);
451 if (!defined $resp) { # EOF
452 print "\n";
453 return defined $default ? $default : undef;
454 }
455 if ($resp eq '' and defined $default) {
456 return $default;
457 }
458 if (!defined $valid_re or $resp =~ /$valid_re/) {
459 return $resp;
460 }
461 }
462 return undef;
463}
464sub do_git_init_db {
466 unless (-d $ENV{GIT_DIR}) {
467 my @init_db = ('init');
468 push @init_db, "--template=$_template" if defined $_template;
469 if (defined $_shared) {
470 if ($_shared =~ /[a-z]/) {
471 push @init_db, "--shared=$_shared";
472 } else {
473 push @init_db, "--shared";
474 }
475 }
476 command_noisy(@init_db);
477 $_repository = Git->repository(Repository => ".git");
478 }
479 my $set;
480 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
481 foreach my $i (keys %icv) {
482 die "'$set' and '$i' cannot both be set\n" if $set;
483 next unless defined $icv{$i};
484 command_noisy('config', "$pfx.$i", $icv{$i});
485 $set = $i;
486 }
487 my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
488 command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
489 if defined $$ignore_paths_regex;
490 my $include_paths_regex = \$Git::SVN::Fetcher::_include_regex;
491 command_noisy('config', "$pfx.include-paths", $$include_paths_regex)
492 if defined $$include_paths_regex;
493 my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
494 command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
495 if defined $$ignore_refs_regex;
496 if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
498 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
499 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
500 command_noisy('config', "$pfx.placeholder-filename", $$fname);
501 }
502}
503sub init_subdir {
505 my $repo_path = shift or return;
506 mkpath([$repo_path]) unless -d $repo_path;
507 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
508 $ENV{GIT_DIR} = '.git';
509 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
510}
511sub cmd_clone {
513 my ($url, $path) = @_;
514 if (!defined $path &&
515 (defined $_trunk || @_branches || @_tags ||
516 defined $_stdlayout) &&
517 $url !~ m#^[a-z\+]+://#) {
518 $path = $url;
519 }
520 $path = basename($url) if !defined $path || !length $path;
521 my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
522 cmd_init($url, $path);
523 command_oneline('config', 'svn.authorsfile', $authors_absolute)
524 if $_authors;
525 Git::SVN::fetch_all($Git::SVN::default_repo_id);
526}
527sub cmd_init {
529 if (defined $_stdlayout) {
530 $_trunk = 'trunk' if (!defined $_trunk);
531 @_tags = 'tags' if (! @_tags);
532 @_branches = 'branches' if (! @_branches);
533 }
534 if (defined $_trunk || @_branches || @_tags) {
535 return cmd_multi_init(@_);
536 }
537 my $url = shift or die "SVN repository location required ",
538 "as a command-line argument\n";
539 $url = canonicalize_url($url);
540 init_subdir(@_);
541 do_git_init_db();
542 if ($Git::SVN::_minimize_url eq 'unset') {
544 $Git::SVN::_minimize_url = 0;
545 }
546 Git::SVN->init($url);
548}
549sub cmd_fetch {
551 if (grep /^\d+=./, @_) {
552 die "'<rev>=<commit>' fetch arguments are ",
553 "no longer supported.\n";
554 }
555 my ($remote) = @_;
556 if (@_ > 1) {
557 die "usage: $0 fetch [--all] [--parent] [svn-remote]\n";
558 }
559 $Git::SVN::no_reuse_existing = undef;
560 if ($_fetch_parent) {
561 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
562 unless ($gs) {
563 die "Unable to determine upstream SVN information from ",
564 "working tree history\n";
565 }
566 # just fetch, don't checkout.
567 $_no_checkout = 'true';
568 $_fetch_all ? $gs->fetch_all : $gs->fetch;
569 } elsif ($_fetch_all) {
570 cmd_multi_fetch();
571 } else {
572 $remote ||= $Git::SVN::default_repo_id;
573 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
574 }
575}
576sub cmd_set_tree {
578 my (@commits) = @_;
579 if ($_stdin || !@commits) {
580 print "Reading from stdin...\n";
581 @commits = ();
582 while (<STDIN>) {
583 if (/\b($sha1_short)\b/o) {
584 unshift @commits, $1;
585 }
586 }
587 }
588 my @revs;
589 foreach my $c (@commits) {
590 my @tmp = command('rev-parse',$c);
591 if (scalar @tmp == 1) {
592 push @revs, $tmp[0];
593 } elsif (scalar @tmp > 1) {
594 push @revs, reverse(command('rev-list',@tmp));
595 } else {
596 fatal "Failed to rev-parse $c";
597 }
598 }
599 my $gs = Git::SVN->new;
600 my ($r_last, $cmt_last) = $gs->last_rev_commit;
601 $gs->fetch;
602 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
603 fatal "There are new revisions that were fetched ",
604 "and need to be merged (or acknowledged) ",
605 "before committing.\nlast rev: $r_last\n",
606 " current: $gs->{last_rev}";
607 }
608 $gs->set_tree($_) foreach @revs;
609 print "Done committing ",scalar @revs," revisions to SVN\n";
610 unlink $gs->{index};
611}
612sub split_merge_info_range {
614 my ($range) = @_;
615 if ($range =~ /(\d+)-(\d+)/) {
616 return (int($1), int($2));
617 } else {
618 return (int($range), int($range));
619 }
620}
621sub combine_ranges {
623 my ($in) = @_;
624 my @fnums = ();
626 my @arr = split(/,/, $in);
627 for my $element (@arr) {
628 my ($start, $end) = split_merge_info_range($element);
629 push @fnums, $start;
630 }
631 my @sorted = @arr [ sort {
633 $fnums[$a] <=> $fnums[$b]
634 } 0..$#arr ];
635 my @return = ();
637 my $last = -1;
638 my $first = -1;
639 for my $element (@sorted) {
640 my ($start, $end) = split_merge_info_range($element);
641 if ($last == -1) {
643 $first = $start;
644 $last = $end;
645 next;
646 }
647 if ($start <= $last+1) {
648 if ($end > $last) {
649 $last = $end;
650 }
651 next;
652 }
653 if ($first == $last) {
654 push @return, "$first";
655 } else {
656 push @return, "$first-$last";
657 }
658 $first = $start;
659 $last = $end;
660 }
661 if ($first != -1) {
663 if ($first == $last) {
664 push @return, "$first";
665 } else {
666 push @return, "$first-$last";
667 }
668 }
669 return join(',', @return);
671}
672sub merge_revs_into_hash {
674 my ($hash, $minfo) = @_;
675 my @lines = split(' ', $minfo);
676 for my $line (@lines) {
678 my ($branchpath, $revs) = split(/:/, $line);
679 if (exists($hash->{$branchpath})) {
681 # Merge the two revision sets
682 my $combined = "$hash->{$branchpath},$revs";
683 $hash->{$branchpath} = combine_ranges($combined);
684 } else {
685 # Just do range combining for consolidation
686 $hash->{$branchpath} = combine_ranges($revs);
687 }
688 }
689}
690sub merge_merge_info {
692 my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_;
693 my %result_hash = ();
694 merge_revs_into_hash(\%result_hash, $mergeinfo_one);
696 merge_revs_into_hash(\%result_hash, $mergeinfo_two);
697 delete $result_hash{$ignore_branch} if $ignore_branch;
699 my $result = '';
701 # Sort below is for consistency's sake
702 for my $branchname (sort keys(%result_hash)) {
703 my $revlist = $result_hash{$branchname};
704 $result .= "$branchname:$revlist\n"
705 }
706 return $result;
707}
708sub populate_merge_info {
710 my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
711 my %parentshash;
713 read_commit_parents(\%parentshash, $d);
714 my @parents = @{$parentshash{$d}};
715 if ($#parents > 0) {
716 # Merge commit
717 my $all_parents_ok = 1;
718 my $aggregate_mergeinfo = '';
719 my $rooturl = $gs->repos_root;
720 my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/;
721 if (defined($rewritten_parent)) {
723 # Replace first parent with newly-rewritten version
724 shift @parents;
725 unshift @parents, $rewritten_parent;
726 }
727 foreach my $parent (@parents) {
729 my ($branchurl, $svnrev, $paruuid) =
730 cmt_metadata($parent);
731 unless (defined($svnrev)) {
733 # Should have been caught be preflight check
734 fatal "merge commit $d has ancestor $parent, but that change "
735 ."does not have git-svn metadata!";
736 }
737 unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
738 fatal "commit $parent git-svn metadata changed mid-run!";
739 }
740 my $branchpath = $1;
741 my $ra = Git::SVN::Ra->new($branchurl);
743 my (undef, undef, $props) =
744 $ra->get_dir(canonicalize_path("."), $svnrev);
745 my $par_mergeinfo = $props->{'svn:mergeinfo'};
746 unless (defined $par_mergeinfo) {
747 $par_mergeinfo = '';
748 }
749 # Merge previous mergeinfo values
750 $aggregate_mergeinfo =
751 merge_merge_info($aggregate_mergeinfo,
752 $par_mergeinfo,
753 $target_branch);
754 next if $parent eq $parents[0]; # Skip first parent
756 # Add new changes being placed in tree by merge
757 my @cmd = (qw/rev-list --reverse/,
758 $parent, qw/--not/);
759 foreach my $par (@parents) {
760 unless ($par eq $parent) {
761 push @cmd, $par;
762 }
763 }
764 my @revsin = ();
765 my ($revlist, $ctx) = command_output_pipe(@cmd);
766 while (<$revlist>) {
767 my $irev = $_;
768 chomp $irev;
769 my (undef, $csvnrev, undef) =
770 cmt_metadata($irev);
771 unless (defined $csvnrev) {
772 # A child is missing SVN annotations...
773 # this might be OK, or might not be.
774 warn "W:child $irev is merged into revision "
775 ."$d but does not have git-svn metadata. "
776 ."This means git-svn cannot determine the "
777 ."svn revision numbers to place into the "
778 ."svn:mergeinfo property. You must ensure "
779 ."a branch is entirely committed to "
780 ."SVN before merging it in order for "
781 ."svn:mergeinfo population to function "
782 ."properly";
783 }
784 push @revsin, $csvnrev;
785 }
786 command_close_pipe($revlist, $ctx);
787 last unless $all_parents_ok;
789 # We now have a list of all SVN revnos which are
791 # merged by this particular parent. Integrate them.
792 next if $#revsin == -1;
793 my $newmergeinfo = "$branchpath:" . join(',', @revsin);
794 $aggregate_mergeinfo =
795 merge_merge_info($aggregate_mergeinfo,
796 $newmergeinfo,
797 $target_branch);
798 }
799 if ($all_parents_ok and $aggregate_mergeinfo) {
800 return $aggregate_mergeinfo;
801 }
802 }
803 return undef;
805}
806sub dcommit_rebase {
808 my ($is_last, $current, $fetched_ref, $svn_error) = @_;
809 my @diff;
810 if ($svn_error) {
812 print STDERR "\nERROR from SVN:\n",
813 $svn_error->expanded_message, "\n";
814 }
815 unless ($_no_rebase) {
816 # we always want to rebase against the current HEAD,
817 # not any head that was passed to us
818 @diff = command('diff-tree', $current,
819 $fetched_ref, '--');
820 my @finish;
821 if (@diff) {
822 @finish = rebase_cmd();
823 print STDERR "W: $current and ", $fetched_ref,
824 " differ, using @finish:\n",
825 join("\n", @diff), "\n";
826 } elsif ($is_last) {
827 print "No changes between ", $current, " and ",
828 $fetched_ref,
829 "\nResetting to the latest ",
830 $fetched_ref, "\n";
831 @finish = qw/reset --mixed/;
832 }
833 command_noisy(@finish, $fetched_ref) if @finish;
834 }
835 if ($svn_error) {
836 die "ERROR: Not all changes have been committed into SVN"
837 .($_no_rebase ? ".\n" : ", however the committed\n"
838 ."ones (if any) seem to be successfully integrated "
839 ."into the working tree.\n")
840 ."Please see the above messages for details.\n";
841 }
842 return @diff;
843}
844sub cmd_dcommit {
846 my $head = shift;
847 command_noisy(qw/update-index --refresh/);
848 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD --/) }
849 'Cannot dcommit with a dirty index. Commit your changes first, '
850 . "or stash them with `git stash'.\n";
851 $head ||= 'HEAD';
852 my $old_head;
854 if ($head ne 'HEAD') {
855 $old_head = eval {
856 command_oneline([qw/symbolic-ref -q HEAD/])
857 };
858 if ($old_head) {
859 $old_head =~ s{^refs/heads/}{};
860 } else {
861 $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
862 }
863 command(['checkout', $head], STDERR => 0);
864 }
865 my @refs;
867 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
868 unless ($gs) {
869 die "Unable to determine upstream SVN information from ",
870 "$head history.\nPerhaps the repository is empty.";
871 }
872 if (defined $_commit_url) {
874 $url = $_commit_url;
875 } else {
876 $url = eval { command_oneline('config', '--get',
877 "svn-remote.$gs->{repo_id}.commiturl") };
878 if (!$url) {
879 $url = $gs->full_pushurl
880 }
881 }
882 my $last_rev = $_revision if defined $_revision;
884 if ($url) {
885 print "Committing to $url ...\n";
886 }
887 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
888 if ($_no_rebase && scalar(@$linear_refs) > 1) {
889 warn "Attempting to commit more than one change while ",
890 "--no-rebase is enabled.\n",
891 "If these changes depend on each other, re-running ",
892 "without --no-rebase may be required."
893 }
894 if (defined $_interactive){
896 my $ask_default = "y";
897 foreach my $d (@$linear_refs){
898 my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
899 while (<$fh>){
900 print $_;
901 }
902 command_close_pipe($fh, $ctx);
903 $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
904 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
905 default => $ask_default);
906 die "Commit this patch reply required" unless defined $_;
907 if (/^[nq]/i) {
908 exit(0);
909 } elsif (/^a/i) {
910 last;
911 }
912 }
913 }
914 my $expect_url = $url;
916 my $push_merge_info = eval {
918 command_oneline(qw/config --get svn.pushmergeinfo/)
919 };
920 if (not defined($push_merge_info)
921 or $push_merge_info eq "false"
922 or $push_merge_info eq "no"
923 or $push_merge_info eq "never") {
924 $push_merge_info = 0;
925 }
926 unless (defined($_merge_info) || ! $push_merge_info) {
928 # Preflight check of changes to ensure no issues with mergeinfo
929 # This includes check for uncommitted-to-SVN parents
930 # (other than the first parent, which we will handle),
931 # information from different SVN repos, and paths
932 # which are not underneath this repository root.
933 my $rooturl = $gs->repos_root;
934 foreach my $d (@$linear_refs) {
935 my %parentshash;
936 read_commit_parents(\%parentshash, $d);
937 my @realparents = @{$parentshash{$d}};
938 if ($#realparents > 0) {
939 # Merge commit
940 shift @realparents; # Remove/ignore first parent
941 foreach my $parent (@realparents) {
942 my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
943 unless (defined $paruuid) {
944 # A parent is missing SVN annotations...
945 # abort the whole operation.
946 fatal "$parent is merged into revision $d, "
947 ."but does not have git-svn metadata. "
948 ."Either dcommit the branch or use a "
949 ."local cherry-pick, FF merge, or rebase "
950 ."instead of an explicit merge commit.";
951 }
952 unless ($paruuid eq $uuid) {
954 # Parent has SVN metadata from different repository
955 fatal "merge parent $parent for change $d has "
956 ."git-svn uuid $paruuid, while current change "
957 ."has uuid $uuid!";
958 }
959 unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
961 # This branch is very strange indeed.
962 fatal "merge parent $parent for $d is on branch "
963 ."$branchurl, which is not under the "
964 ."git-svn root $rooturl!";
965 }
966 }
967 }
968 }
969 }
970 my $rewritten_parent;
972 my $current_head = command_oneline(qw/rev-parse HEAD/);
973 Git::SVN::remove_username($expect_url);
974 if (defined($_merge_info)) {
975 $_merge_info =~ tr{ }{\n};
976 }
977 while (1) {
978 my $d = shift @$linear_refs or last;
979 unless (defined $last_rev) {
980 (undef, $last_rev, undef) = cmt_metadata("$d~1");
981 unless (defined $last_rev) {
982 fatal "Unable to extract revision information ",
983 "from commit $d~1";
984 }
985 }
986 if ($_dry_run) {
987 print "diff-tree $d~1 $d\n";
988 } else {
989 my $cmt_rev;
990 unless (defined($_merge_info) || ! $push_merge_info) {
992 $_merge_info = populate_merge_info($d, $gs,
993 $uuid,
994 $linear_refs,
995 $rewritten_parent);
996 }
997 my %ed_opts = ( r => $last_rev,
999 log => get_commit_entry($d)->{log},
1000 ra => Git::SVN::Ra->new($url),
1001 config => SVN::Core::config_get_config(
1002 $Git::SVN::Ra::config_dir
1003 ),
1004 tree_a => "$d~1",
1005 tree_b => $d,
1006 editor_cb => sub {
1007 print "Committed r$_[0]\n";
1008 $cmt_rev = $_[0];
1009 },
1010 mergeinfo => $_merge_info,
1011 svn_path => '');
1012 my $err_handler = $SVN::Error::handler;
1014 $SVN::Error::handler = sub {
1015 my $err = shift;
1016 dcommit_rebase(1, $current_head, $gs->refname,
1017 $err);
1018 };
1019 if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1021 print "No changes\n$d~1 == $d\n";
1022 } elsif ($parents->{$d} && @{$parents->{$d}}) {
1023 $gs->{inject_parents_dcommit}->{$cmt_rev} =
1024 $parents->{$d};
1025 }
1026 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1027 $SVN::Error::handler = $err_handler;
1028 $last_rev = $cmt_rev;
1029 next if $_no_rebase;
1030 my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1032 $gs->refname, undef);
1033 $rewritten_parent = command_oneline(qw/rev-parse/,
1035 $gs->refname);
1036 if (@diff) {
1038 $current_head = command_oneline(qw/rev-parse
1039 HEAD/);
1040 @refs = ();
1041 my ($url_, $rev_, $uuid_, $gs_) =
1042 working_head_info('HEAD', \@refs);
1043 my ($linear_refs_, $parents_) =
1044 linearize_history($gs_, \@refs);
1045 if (scalar(@$linear_refs) !=
1046 scalar(@$linear_refs_)) {
1047 fatal "# of revisions changed ",
1048 "\nbefore:\n",
1049 join("\n", @$linear_refs),
1050 "\n\nafter:\n",
1051 join("\n", @$linear_refs_), "\n",
1052 'If you are attempting to commit ',
1053 "merges, try running:\n\t",
1054 'git rebase --interactive',
1055 '--preserve-merges ',
1056 $gs->refname,
1057 "\nBefore dcommitting";
1058 }
1059 if ($url_ ne $expect_url) {
1060 if ($url_ eq $gs->metadata_url) {
1061 print
1062 "Accepting rewritten URL:",
1063 " $url_\n";
1064 } else {
1065 fatal
1066 "URL mismatch after rebase:",
1067 " $url_ != $expect_url";
1068 }
1069 }
1070 if ($uuid_ ne $uuid) {
1071 fatal "uuid mismatch after rebase: ",
1072 "$uuid_ != $uuid";
1073 }
1074 # remap parents
1075 my (%p, @l, $i);
1076 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1077 my $new = $linear_refs_->[$i] or next;
1078 $p{$new} =
1079 $parents->{$linear_refs->[$i]};
1080 push @l, $new;
1081 }
1082 $parents = \%p;
1083 $linear_refs = \@l;
1084 undef $last_rev;
1085 }
1086 }
1087 }
1088 if ($old_head) {
1090 my $new_head = command_oneline(qw/rev-parse HEAD/);
1091 my $new_is_symbolic = eval {
1092 command_oneline(qw/symbolic-ref -q HEAD/);
1093 };
1094 if ($new_is_symbolic) {
1095 print "dcommitted the branch ", $head, "\n";
1096 } else {
1097 print "dcommitted on a detached HEAD because you gave ",
1098 "a revision argument.\n",
1099 "The rewritten commit is: ", $new_head, "\n";
1100 }
1101 command(['checkout', $old_head], STDERR => 0);
1102 }
1103 unlink $gs->{index};
1105}
1106sub cmd_branch {
1108 my ($branch_name, $head) = @_;
1109 unless (defined $branch_name && length $branch_name) {
1111 die(($_tag ? "tag" : "branch") . " name required\n");
1112 }
1113 $head ||= 'HEAD';
1114 my (undef, $rev, undef, $gs) = working_head_info($head);
1116 my $src = $gs->full_pushurl;
1117 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1119 my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1120 my $glob;
1121 if ($#{$allglobs} == 0) {
1122 $glob = $allglobs->[0];
1123 } else {
1124 unless(defined $_branch_dest) {
1125 die "Multiple ",
1126 $_tag ? "tag" : "branch",
1127 " paths defined for Subversion repository.\n",
1128 "You must specify where you want to create the ",
1129 $_tag ? "tag" : "branch",
1130 " with the --destination argument.\n";
1131 }
1132 foreach my $g (@{$allglobs}) {
1133 my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1134 if ($_branch_dest =~ /$re/) {
1135 $glob = $g;
1136 last;
1137 }
1138 }
1139 unless (defined $glob) {
1140 my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1141 foreach my $g (@{$allglobs}) {
1142 $g->{path}->{left} =~ /$dest_re/ or next;
1143 if (defined $glob) {
1144 die "Ambiguous destination: ",
1145 $_branch_dest, "\nmatches both '",
1146 $glob->{path}->{left}, "' and '",
1147 $g->{path}->{left}, "'\n";
1148 }
1149 $glob = $g;
1150 }
1151 unless (defined $glob) {
1152 die "Unknown ",
1153 $_tag ? "tag" : "branch",
1154 " destination $_branch_dest\n";
1155 }
1156 }
1157 }
1158 my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1159 my $url;
1160 if (defined $_commit_url) {
1161 $url = $_commit_url;
1162 } else {
1163 $url = eval { command_oneline('config', '--get',
1164 "svn-remote.$gs->{repo_id}.commiturl") };
1165 if (!$url) {
1166 $url = $remote->{pushurl} || $remote->{url};
1167 }
1168 }
1169 my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1170 if ($dst =~ /^https:/ && $src =~ /^http:/) {
1172 $src=~s/^http:/https:/;
1173 }
1174 ::_req_svn();
1176 my $ctx = SVN::Client->new(
1178 config => SVN::Core::config_get_config(
1179 $Git::SVN::Ra::config_dir
1180 ),
1181 log_msg => sub {
1182 ${ $_[0] } = defined $_message
1183 ? $_message
1184 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1185 . $branch_name;
1186 },
1187 );
1188 eval {
1190 $ctx->ls($dst, 'HEAD', 0);
1191 } and die "branch ${branch_name} already exists\n";
1192 if ($_parents) {
1194 mk_parent_dirs($ctx, $dst);
1195 }
1196 print "Copying ${src} at r${rev} to ${dst}...\n";
1198 $ctx->copy($src, $rev, $dst)
1199 unless $_dry_run;
1200 $gs->fetch_all;
1202}
1203sub mk_parent_dirs {
1205 my ($ctx, $parent) = @_;
1206 $parent =~ s{/[^/]*$}{};
1207 if (!eval{$ctx->ls($parent, 'HEAD', 0)}) {
1209 mk_parent_dirs($ctx, $parent);
1210 print "Creating parent folder ${parent} ...\n";
1211 $ctx->mkdir($parent) unless $_dry_run;
1212 }
1213}
1214sub cmd_find_rev {
1216 my $revision_or_hash = shift or die "SVN or git revision required ",
1217 "as a command-line argument\n";
1218 my $result;
1219 if ($revision_or_hash =~ /^r\d+$/) {
1220 my $head = shift;
1221 $head ||= 'HEAD';
1222 my @refs;
1223 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1224 unless ($gs) {
1225 die "Unable to determine upstream SVN information from ",
1226 "$head history\n";
1227 }
1228 my $desired_revision = substr($revision_or_hash, 1);
1229 if ($_before) {
1230 $result = $gs->find_rev_before($desired_revision, 1);
1231 } elsif ($_after) {
1232 $result = $gs->find_rev_after($desired_revision, 1);
1233 } else {
1234 $result = $gs->rev_map_get($desired_revision, $uuid);
1235 }
1236 } else {
1237 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1238 $result = $rev;
1239 }
1240 print "$result\n" if $result;
1241}
1242sub auto_create_empty_directories {
1244 my ($gs) = @_;
1245 my $var = eval { command_oneline('config', '--get', '--bool',
1246 "svn-remote.$gs->{repo_id}.automkdirs") };
1247 # By default, create empty directories by consulting the unhandled log,
1248 # but allow setting it to 'false' to skip it.
1249 return !($var && $var eq 'false');
1250}
1251sub cmd_rebase {
1253 command_noisy(qw/update-index --refresh/);
1254 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1255 unless ($gs) {
1256 die "Unable to determine upstream SVN information from ",
1257 "working tree history\n";
1258 }
1259 if ($_dry_run) {
1260 print "Remote Branch: " . $gs->refname . "\n";
1261 print "SVN URL: " . $url . "\n";
1262 return;
1263 }
1264 if (command(qw/diff-index HEAD --/)) {
1265 print STDERR "Cannot rebase with uncommitted changes:\n";
1266 command_noisy('status');
1267 exit 1;
1268 }
1269 unless ($_local) {
1270 # rebase will checkout for us, so no need to do it explicitly
1271 $_no_checkout = 'true';
1272 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1273 }
1274 command_noisy(rebase_cmd(), $gs->refname);
1275 if (auto_create_empty_directories($gs)) {
1276 $gs->mkemptydirs;
1277 }
1278}
1279sub cmd_show_ignore {
1281 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1282 $gs ||= Git::SVN->new;
1283 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1284 $gs->prop_walk($gs->path, $r, sub {
1285 my ($gs, $path, $props) = @_;
1286 print STDOUT "\n# $path\n";
1287 my $s = $props->{'svn:ignore'} or return;
1288 $s =~ s/[\r\n]+/\n/g;
1289 $s =~ s/^\n+//;
1290 chomp $s;
1291 $s =~ s#^#$path#gm;
1292 print STDOUT "$s\n";
1293 });
1294}
1295sub cmd_show_externals {
1297 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1298 $gs ||= Git::SVN->new;
1299 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1300 $gs->prop_walk($gs->path, $r, sub {
1301 my ($gs, $path, $props) = @_;
1302 print STDOUT "\n# $path\n";
1303 my $s = $props->{'svn:externals'} or return;
1304 $s =~ s/[\r\n]+/\n/g;
1305 chomp $s;
1306 $s =~ s#^#$path#gm;
1307 print STDOUT "$s\n";
1308 });
1309}
1310sub cmd_create_ignore {
1312 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1313 $gs ||= Git::SVN->new;
1314 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1315 $gs->prop_walk($gs->path, $r, sub {
1316 my ($gs, $path, $props) = @_;
1317 # $path is of the form /path/to/dir/
1318 $path = '.' . $path;
1319 # SVN can have attributes on empty directories,
1320 # which git won't track
1321 mkpath([$path]) unless -d $path;
1322 my $ignore = $path . '.gitignore';
1323 my $s = $props->{'svn:ignore'} or return;
1324 open(GITIGNORE, '>', $ignore)
1325 or fatal("Failed to open `$ignore' for writing: $!");
1326 $s =~ s/[\r\n]+/\n/g;
1327 $s =~ s/^\n+//;
1328 chomp $s;
1329 # Prefix all patterns so that the ignore doesn't apply
1330 # to sub-directories.
1331 $s =~ s#^#/#gm;
1332 print GITIGNORE "$s\n";
1333 close(GITIGNORE)
1334 or fatal("Failed to close `$ignore': $!");
1335 command_noisy('add', '-f', $ignore);
1336 });
1337}
1338sub cmd_mkdirs {
1340 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1341 $gs ||= Git::SVN->new;
1342 $gs->mkemptydirs($_revision);
1343}
1344# get_svnprops(PATH)
1346# ------------------
1347# Helper for cmd_propget and cmd_proplist below.
1348sub get_svnprops {
1349 my $path = shift;
1350 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1351 $gs ||= Git::SVN->new;
1352 # prefix THE PATH by the sub-directory from which the user
1354 # invoked us.
1355 $path = $cmd_dir_prefix . $path;
1356 fatal("No such file or directory: $path") unless -e $path;
1357 my $is_dir = -d $path ? 1 : 0;
1358 $path = join_paths($gs->path, $path);
1359 # canonicalize the path (otherwise libsvn will abort or fail to
1361 # find the file)
1362 $path = canonicalize_path($path);
1363 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1365 my $props;
1366 if ($is_dir) {
1367 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1368 }
1369 else {
1370 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1371 }
1372 return $props;
1373}
1374# cmd_propget (PROP, PATH)
1376# ------------------------
1377# Print the SVN property PROP for PATH.
1378sub cmd_propget {
1379 my ($prop, $path) = @_;
1380 $path = '.' if not defined $path;
1381 usage(1) if not defined $prop;
1382 my $props = get_svnprops($path);
1383 if (not defined $props->{$prop}) {
1384 fatal("`$path' does not have a `$prop' SVN property.");
1385 }
1386 print $props->{$prop} . "\n";
1387}
1388# cmd_propset (PROPNAME, PROPVAL, PATH)
1390# ------------------------
1391# Adjust the SVN property PROPNAME to PROPVAL for PATH.
1392sub cmd_propset {
1393 my ($propname, $propval, $path) = @_;
1394 $path = '.' if not defined $path;
1395 $path = $cmd_dir_prefix . $path;
1396 usage(1) if not defined $propname;
1397 usage(1) if not defined $propval;
1398 my $file = basename($path);
1399 my $dn = dirname($path);
1400 my $cur_props = Git::SVN::Editor::check_attr( "svn-properties", $path );
1401 my @new_props;
1402 if (!$cur_props || $cur_props eq "unset" || $cur_props eq "" || $cur_props eq "set") {
1403 push @new_props, "$propname=$propval";
1404 } else {
1405 # TODO: handle combining properties better
1406 my @props = split(/;/, $cur_props);
1407 my $replaced_prop;
1408 foreach my $prop (@props) {
1409 # Parse 'name=value' syntax and set the property.
1410 if ($prop =~ /([^=]+)=(.*)/) {
1411 my ($n,$v) = ($1,$2);
1412 if ($n eq $propname) {
1413 $v = $propval;
1414 $replaced_prop = 1;
1415 }
1416 push @new_props, "$n=$v";
1417 }
1418 }
1419 if (!$replaced_prop) {
1420 push @new_props, "$propname=$propval";
1421 }
1422 }
1423 my $attrfile = "$dn/.gitattributes";
1424 open my $attrfh, '>>', $attrfile or die "Can't open $attrfile: $!\n";
1425 # TODO: don't simply append here if $file already has svn-properties
1426 my $new_props = join(';', @new_props);
1427 print $attrfh "$file svn-properties=$new_props\n" or
1428 die "write to $attrfile: $!\n";
1429 close $attrfh or die "close $attrfile: $!\n";
1430}
1431# cmd_proplist (PATH)
1433# -------------------
1434# Print the list of SVN properties for PATH.
1435sub cmd_proplist {
1436 my $path = shift;
1437 $path = '.' if not defined $path;
1438 my $props = get_svnprops($path);
1439 print "Properties on '$path':\n";
1440 foreach (sort keys %{$props}) {
1441 print " $_\n";
1442 }
1443}
1444sub cmd_multi_init {
1446 my $url = shift;
1447 unless (defined $_trunk || @_branches || @_tags) {
1448 usage(1);
1449 }
1450 $_prefix = 'origin/' unless defined $_prefix;
1452 if (defined $url) {
1453 $url = canonicalize_url($url);
1454 init_subdir(@_);
1455 }
1456 do_git_init_db();
1457 if (defined $_trunk) {
1458 $_trunk =~ s#^/+##;
1459 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1460 # try both old-style and new-style lookups:
1461 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1462 unless ($gs_trunk) {
1463 my ($trunk_url, $trunk_path) =
1464 complete_svn_url($url, $_trunk);
1465 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1466 undef, $trunk_ref);
1467 }
1468 }
1469 return unless @_branches || @_tags;
1470 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1471 foreach my $path (@_branches) {
1472 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1473 }
1474 foreach my $path (@_tags) {
1475 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1476 }
1477}
1478sub cmd_multi_fetch {
1480 $Git::SVN::no_reuse_existing = undef;
1481 my $remotes = Git::SVN::read_all_remotes();
1482 foreach my $repo_id (sort keys %$remotes) {
1483 if ($remotes->{$repo_id}->{url}) {
1484 Git::SVN::fetch_all($repo_id, $remotes);
1485 }
1486 }
1487}
1488# this command is special because it requires no metadata
1490sub cmd_commit_diff {
1491 my ($ta, $tb, $url) = @_;
1492 my $usage = "usage: $0 commit-diff -r<revision> ".
1493 "<tree-ish> <tree-ish> [<URL>]";
1494 fatal($usage) if (!defined $ta || !defined $tb);
1495 my $svn_path = '';
1496 if (!defined $url) {
1497 my $gs = eval { Git::SVN->new };
1498 if (!$gs) {
1499 fatal("Needed URL or usable git-svn --id in ",
1500 "the command-line\n", $usage);
1501 }
1502 $url = $gs->url;
1503 $svn_path = $gs->path;
1504 }
1505 unless (defined $_revision) {
1506 fatal("-r|--revision is a required argument\n", $usage);
1507 }
1508 if (defined $_message && defined $_file) {
1509 fatal("Both --message/-m and --file/-F specified ",
1510 "for the commit message.\n",
1511 "I have no idea what you mean");
1512 }
1513 if (defined $_file) {
1514 $_message = file_to_s($_file);
1515 } else {
1516 $_message ||= get_commit_entry($tb)->{log};
1517 }
1518 my $ra ||= Git::SVN::Ra->new($url);
1519 my $r = $_revision;
1520 if ($r eq 'HEAD') {
1521 $r = $ra->get_latest_revnum;
1522 } elsif ($r !~ /^\d+$/) {
1523 die "revision argument: $r not understood by git-svn\n";
1524 }
1525 my %ed_opts = ( r => $r,
1526 log => $_message,
1527 ra => $ra,
1528 tree_a => $ta,
1529 tree_b => $tb,
1530 editor_cb => sub { print "Committed r$_[0]\n" },
1531 svn_path => $svn_path );
1532 if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1533 print "No changes\n$ta == $tb\n";
1534 }
1535}
1536sub cmd_info {
1538 my $path_arg = defined($_[0]) ? $_[0] : '.';
1539 my $path = $path_arg;
1540 if (File::Spec->file_name_is_absolute($path)) {
1541 $path = canonicalize_path($path);
1542 my $toplevel = eval {
1544 my @cmd = qw/rev-parse --show-toplevel/;
1545 command_oneline(\@cmd, STDERR => 0);
1546 };
1547 # remove $toplevel from the absolute path:
1549 my ($vol, $dirs, $file) = File::Spec->splitpath($path);
1550 my (undef, $tdirs, $tfile) = File::Spec->splitpath($toplevel);
1551 my @dirs = File::Spec->splitdir($dirs);
1552 my @tdirs = File::Spec->splitdir($tdirs);
1553 pop @dirs if $dirs[-1] eq '';
1554 pop @tdirs if $tdirs[-1] eq '';
1555 push @dirs, $file;
1556 push @tdirs, $tfile;
1557 while (@tdirs && @dirs && $tdirs[0] eq $dirs[0]) {
1558 shift @dirs;
1559 shift @tdirs;
1560 }
1561 $dirs = File::Spec->catdir(@dirs);
1562 $path = File::Spec->catpath($vol, $dirs);
1563 $path = canonicalize_path($path);
1565 } else {
1566 $path = canonicalize_path($cmd_dir_prefix . $path);
1567 }
1568 if (exists $_[1]) {
1569 die "Too many arguments specified\n";
1570 }
1571 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1573 if (!$file_type && !$diff_status) {
1575 print STDERR "svn: '$path' is not under version control\n";
1576 exit 1;
1577 }
1578 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1580 unless ($gs) {
1581 die "Unable to determine upstream SVN information from ",
1582 "working tree history\n";
1583 }
1584 # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1586 $path = "." if $path eq "";
1587 my $full_url = canonicalize_url( add_path_to_url( $url, $path ) );
1589 if ($_url) {
1591 print "$full_url\n";
1592 return;
1593 }
1594 my $result = "Path: $path_arg\n";
1596 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1597 $result .= "URL: $full_url\n";
1598 eval {
1600 my $repos_root = $gs->repos_root;
1601 Git::SVN::remove_username($repos_root);
1602 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1603 };
1604 if ($@) {
1605 $result .= "Repository Root: (offline)\n";
1606 }
1607 ::_req_svn();
1608 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1609 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1610 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1611 $result .= "Node Kind: " .
1613 ($file_type eq "dir" ? "directory" : "file") . "\n";
1614 my $schedule = $diff_status eq "A"
1616 ? "add"
1617 : ($diff_status eq "D" ? "delete" : "normal");
1618 $result .= "Schedule: $schedule\n";
1619 if ($diff_status eq "A") {
1621 print $result, "\n";
1622 return;
1623 }
1624 my ($lc_author, $lc_rev, $lc_date_utc);
1626 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
1627 my $log = command_output_pipe(@args);
1628 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1629 while (<$log>) {
1630 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1631 $lc_author = $1;
1632 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1633 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
1634 (undef, $lc_rev, undef) = ::extract_metadata($1);
1635 }
1636 }
1637 close $log;
1638 Git::SVN::Log::set_local_timezone();
1640 $result .= "Last Changed Author: $lc_author\n";
1642 $result .= "Last Changed Rev: $lc_rev\n";
1643 $result .= "Last Changed Date: " .
1644 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1645 if ($file_type ne "dir") {
1647 my $text_last_updated_date =
1648 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1649 $result .=
1650 "Text Last Updated: " .
1651 Git::SVN::Log::format_svn_date($text_last_updated_date) .
1652 "\n";
1653 my $checksum;
1654 if ($diff_status eq "D") {
1655 my ($fh, $ctx) =
1656 command_output_pipe(qw(cat-file blob), "HEAD:$path");
1657 if ($file_type eq "link") {
1658 my $file_name = <$fh>;
1659 $checksum = md5sum("link $file_name");
1660 } else {
1661 $checksum = md5sum($fh);
1662 }
1663 command_close_pipe($fh, $ctx);
1664 } elsif ($file_type eq "link") {
1665 my $file_name =
1666 command(qw(cat-file blob), "HEAD:$path");
1667 $checksum =
1668 md5sum("link " . $file_name);
1669 } else {
1670 open FILE, "<", $path or die $!;
1671 $checksum = md5sum(\*FILE);
1672 close FILE or die $!;
1673 }
1674 $result .= "Checksum: " . $checksum . "\n";
1675 }
1676 print $result, "\n";
1678}
1679sub cmd_reset {
1681 my $target = shift || $_revision or die "SVN revision required\n";
1682 $target = $1 if $target =~ /^r(\d+)$/;
1683 $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1684 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1685 unless ($gs) {
1686 die "Unable to determine upstream SVN information from ".
1687 "history\n";
1688 }
1689 my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1690 die "Cannot find SVN revision $target\n" unless defined($c);
1691 $gs->rev_map_set($r, $c, 'reset', $uuid);
1692 print "r$r = $c ($gs->{ref_id})\n";
1693}
1694sub cmd_gc {
1696 if (!can_compress()) {
1697 warn "Compress::Zlib could not be found; unhandled.log " .
1698 "files will not be compressed.\n";
1699 }
1700 find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1701}
1702########################### utility functions #########################
1704sub rebase_cmd {
1706 my @cmd = qw/rebase/;
1707 push @cmd, '-v' if $_verbose;
1708 push @cmd, qw/--merge/ if $_merge;
1709 push @cmd, "--strategy=$_strategy" if $_strategy;
1710 push @cmd, "--preserve-merges" if $_preserve_merges;
1711 @cmd;
1712}
1713sub post_fetch_checkout {
1715 return if $_no_checkout;
1716 return if verify_ref('HEAD^0');
1717 my $gs = $Git::SVN::_head or return;
1718 # look for "trunk" ref if it exists
1720 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1721 my $fetch = $remote->{fetch};
1722 if ($fetch) {
1723 foreach my $p (keys %$fetch) {
1724 basename($fetch->{$p}) eq 'trunk' or next;
1725 $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1726 last;
1727 }
1728 }
1729 command_noisy(qw(update-ref HEAD), $gs->refname);
1731 return unless verify_ref('HEAD^0');
1732 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1734 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1735 return if -f $index;
1736 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1738 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1739 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1740 print STDERR "Checked out HEAD:\n ",
1741 $gs->full_url, " r", $gs->last_rev, "\n";
1742 if (auto_create_empty_directories($gs)) {
1743 $gs->mkemptydirs($gs->last_rev);
1744 }
1745}
1746sub complete_svn_url {
1748 my ($url, $path) = @_;
1749 $path = canonicalize_path($path);
1750 # If the path is not a URL...
1752 if ($path !~ m#^[a-z\+]+://#) {
1753 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1754 fatal("E: '$path' is not a complete URL ",
1755 "and a separate URL is not specified");
1756 }
1757 return ($url, $path);
1758 }
1759 return ($path, '');
1760}
1761sub complete_url_ls_init {
1763 my ($ra, $repo_path, $switch, $pfx) = @_;
1764 unless ($repo_path) {
1765 print STDERR "W: $switch not specified\n";
1766 return;
1767 }
1768 $repo_path = canonicalize_path($repo_path);
1769 if ($repo_path =~ m#^[a-z\+]+://#) {
1770 $ra = Git::SVN::Ra->new($repo_path);
1771 $repo_path = '';
1772 } else {
1773 $repo_path =~ s#^/+##;
1774 unless ($ra) {
1775 fatal("E: '$repo_path' is not a complete URL ",
1776 "and a separate URL is not specified");
1777 }
1778 }
1779 my $url = $ra->url;
1780 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1781 my $k = "svn-remote.$gs->{repo_id}.url";
1782 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1783 if ($orig_url && ($orig_url ne $gs->url)) {
1784 die "$k already set: $orig_url\n",
1785 "wanted to set to: $gs->url\n";
1786 }
1787 command_oneline('config', $k, $gs->url) unless $orig_url;
1788 my $remote_path = join_paths( $gs->path, $repo_path );
1790 $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1791 $remote_path =~ s#^/##g;
1792 $remote_path .= "/*" if $remote_path !~ /\*/;
1793 my ($n) = ($switch =~ /^--(\w+)/);
1794 if (length $pfx && $pfx !~ m#/$#) {
1795 die "--prefix='$pfx' must have a trailing slash '/'\n";
1796 }
1797 command_noisy('config',
1798 '--add',
1799 "svn-remote.$gs->{repo_id}.$n",
1800 "$remote_path:refs/remotes/$pfx*" .
1801 ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1802}
1803sub verify_ref {
1805 my ($ref) = @_;
1806 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1807 { STDERR => 0 }); };
1808}
1809sub get_tree_from_treeish {
1811 my ($treeish) = @_;
1812 # $treeish can be a symbolic ref, too:
1813 my $type = command_oneline(qw/cat-file -t/, $treeish);
1814 my $expected;
1815 while ($type eq 'tag') {
1816 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1817 }
1818 if ($type eq 'commit') {
1819 $expected = (grep /^tree /, command(qw/cat-file commit/,
1820 $treeish))[0];
1821 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1822 die "Unable to get tree from $treeish\n" unless $expected;
1823 } elsif ($type eq 'tree') {
1824 $expected = $treeish;
1825 } else {
1826 die "$treeish is a $type, expected tree, tag or commit\n";
1827 }
1828 return $expected;
1829}
1830sub get_commit_entry {
1832 my ($treeish) = shift;
1833 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1834 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1835 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1836 open my $log_fh, '>', $commit_editmsg or croak $!;
1837 my $type = command_oneline(qw/cat-file -t/, $treeish);
1839 if ($type eq 'commit' || $type eq 'tag') {
1840 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1841 $type, $treeish);
1842 my $in_msg = 0;
1843 my $author;
1844 my $saw_from = 0;
1845 my $msgbuf = "";
1846 while (<$msg_fh>) {
1847 if (!$in_msg) {
1848 $in_msg = 1 if (/^$/);
1849 $author = $1 if (/^author (.*>)/);
1850 } elsif (/^git-svn-id: /) {
1851 # skip this for now, we regenerate the
1852 # correct one on re-fetch anyways
1853 # TODO: set *:merge properties or like...
1854 } else {
1855 if (/^From:/ || /^Signed-off-by:/) {
1856 $saw_from = 1;
1857 }
1858 $msgbuf .= $_;
1859 }
1860 }
1861 $msgbuf =~ s/\s+$//s;
1862 if ($Git::SVN::_add_author_from && defined($author)
1863 && !$saw_from) {
1864 $msgbuf .= "\n\nFrom: $author";
1865 }
1866 print $log_fh $msgbuf or croak $!;
1867 command_close_pipe($msg_fh, $ctx);
1868 }
1869 close $log_fh or croak $!;
1870 if ($_edit || ($type eq 'tree')) {
1872 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1873 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1874 }
1875 rename $commit_editmsg, $commit_msg or croak $!;
1876 {
1877 require Encode;
1878 # SVN requires messages to be UTF-8 when entering the repo
1879 local $/;
1880 open $log_fh, '<', $commit_msg or croak $!;
1881 binmode $log_fh;
1882 chomp($log_entry{log} = <$log_fh>);
1883 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1885 my $msg = $log_entry{log};
1886 eval { $msg = Encode::decode($enc, $msg, 1) };
1888 if ($@) {
1889 die "Could not decode as $enc:\n", $msg,
1890 "\nPerhaps you need to set i18n.commitencoding\n";
1891 }
1892 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1894 die "Could not encode as UTF-8:\n$msg\n" if $@;
1895 $log_entry{log} = $msg;
1897 close $log_fh or croak $!;
1899 }
1900 unlink $commit_msg;
1901 \%log_entry;
1902}
1903sub s_to_file {
1905 my ($str, $file, $mode) = @_;
1906 open my $fd,'>',$file or croak $!;
1907 print $fd $str,"\n" or croak $!;
1908 close $fd or croak $!;
1909 chmod ($mode &~ umask, $file) if (defined $mode);
1910}
1911sub file_to_s {
1913 my $file = shift;
1914 open my $fd,'<',$file or croak "$!: file: $file\n";
1915 local $/;
1916 my $ret = <$fd>;
1917 close $fd or croak $!;
1918 $ret =~ s/\s*$//s;
1919 return $ret;
1920}
1921# '<svn username> = real-name <email address>' mapping based on git-svnimport:
1923sub load_authors {
1924 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1925 my $log = $cmd eq 'log';
1926 while (<$authors>) {
1927 chomp;
1928 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1929 my ($user, $name, $email) = ($1, $2, $3);
1930 if ($log) {
1931 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1932 } else {
1933 $users{$user} = [$name, $email];
1934 }
1935 }
1936 close $authors or croak $!;
1937}
1938# convert GetOpt::Long specs for use by git-config
1940sub read_git_config {
1941 my $opts = shift;
1942 my @config_only;
1943 foreach my $o (keys %$opts) {
1944 # if we have mixedCase and a long option-only, then
1945 # it's a config-only variable that we don't need for
1946 # the command-line.
1947 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1948 my $v = $opts->{$o};
1949 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1950 $key =~ s/-//g;
1951 my $arg = 'git config';
1952 $arg .= ' --int' if ($o =~ /[:=]i$/);
1953 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1954 if (ref $v eq 'ARRAY') {
1955 chomp(my @tmp = `$arg --get-all svn.$key`);
1956 @$v = @tmp if @tmp;
1957 } else {
1958 chomp(my $tmp = `$arg --get svn.$key`);
1959 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1960 $$v = $tmp;
1961 }
1962 }
1963 }
1964 delete @$opts{@config_only} if @config_only;
1965}
1966sub extract_metadata {
1968 my $id = shift or return (undef, undef, undef);
1969 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1970 \s([a-f\d\-]+)$/ix);
1971 if (!defined $rev || !$uuid || !$url) {
1972 # some of the original repositories I made had
1973 # identifiers like this:
1974 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1975 }
1976 return ($url, $rev, $uuid);
1977}
1978sub cmt_metadata {
1980 return extract_metadata((grep(/^git-svn-id: /,
1981 command(qw/cat-file commit/, shift)))[-1]);
1982}
1983sub cmt_sha2rev_batch {
1985 my %s2r;
1986 my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1987 my $list = shift;
1988 foreach my $sha (@{$list}) {
1990 my $first = 1;
1991 my $size = 0;
1992 print $out $sha, "\n";
1993 while (my $line = <$in>) {
1995 if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1996 last;
1997 } elsif ($first &&
1998 $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1999 $first = 0;
2000 $size = $1;
2001 next;
2002 } elsif ($line =~ /^(git-svn-id: )/) {
2003 my (undef, $rev, undef) =
2004 extract_metadata($line);
2005 $s2r{$sha} = $rev;
2006 }
2007 $size -= length($line);
2009 last if ($size == 0);
2010 }
2011 }
2012 command_close_bidi_pipe($pid, $in, $out, $ctx);
2014 return \%s2r;
2016}
2017sub working_head_info {
2019 my ($head, $refs) = @_;
2020 my @args = qw/rev-list --first-parent --pretty=medium/;
2021 my ($fh, $ctx) = command_output_pipe(@args, $head, "--");
2022 my $hash;
2023 my %max;
2024 while (<$fh>) {
2025 if ( m{^commit ($::sha1)$} ) {
2026 unshift @$refs, $hash if $hash and $refs;
2027 $hash = $1;
2028 next;
2029 }
2030 next unless s{^\s*(git-svn-id:)}{$1};
2031 my ($url, $rev, $uuid) = extract_metadata($_);
2032 if (defined $url && defined $rev) {
2033 next if $max{$url} and $max{$url} < $rev;
2034 if (my $gs = Git::SVN->find_by_url($url)) {
2035 my $c = $gs->rev_map_get($rev, $uuid);
2036 if ($c && $c eq $hash) {
2037 close $fh; # break the pipe
2038 return ($url, $rev, $uuid, $gs);
2039 } else {
2040 $max{$url} ||= $gs->rev_map_max;
2041 }
2042 }
2043 }
2044 }
2045 command_close_pipe($fh, $ctx);
2046 (undef, undef, undef, undef);
2047}
2048sub read_commit_parents {
2050 my ($parents, $c) = @_;
2051 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
2052 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
2053 @{$parents->{$c}} = split(/ /, $p);
2054}
2055sub linearize_history {
2057 my ($gs, $refs) = @_;
2058 my %parents;
2059 foreach my $c (@$refs) {
2060 read_commit_parents(\%parents, $c);
2061 }
2062 my @linear_refs;
2064 my %skip = ();
2065 my $last_svn_commit = $gs->last_commit;
2066 foreach my $c (reverse @$refs) {
2067 next if $c eq $last_svn_commit;
2068 last if $skip{$c};
2069 unshift @linear_refs, $c;
2071 $skip{$c} = 1;
2072 # we only want the first parent to diff against for linear
2074 # history, we save the rest to inject when we finalize the
2075 # svn commit
2076 my $fp_a = verify_ref("$c~1");
2077 my $fp_b = shift @{$parents{$c}} if $parents{$c};
2078 if (!$fp_a || !$fp_b) {
2079 die "Commit $c\n",
2080 "has no parent commit, and therefore ",
2081 "nothing to diff against.\n",
2082 "You should be working from a repository ",
2083 "originally created by git-svn\n";
2084 }
2085 if ($fp_a ne $fp_b) {
2086 die "$c~1 = $fp_a, however parsing commit $c ",
2087 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
2088 }
2089 foreach my $p (@{$parents{$c}}) {
2091 $skip{$p} = 1;
2092 }
2093 }
2094 (\@linear_refs, \%parents);
2095}
2096sub find_file_type_and_diff_status {
2098 my ($path) = @_;
2099 return ('dir', '') if $path eq '';
2100 my $diff_output =
2102 command_oneline(qw(diff --cached --name-status --), $path) || "";
2103 my $diff_status = (split(' ', $diff_output))[0] || "";
2104 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
2106 return (undef, undef) if !$diff_status && !$ls_tree;
2108 if ($diff_status eq "A") {
2110 return ("link", $diff_status) if -l $path;
2111 return ("dir", $diff_status) if -d $path;
2112 return ("file", $diff_status);
2113 }
2114 my $mode = (split(' ', $ls_tree))[0] || "";
2116 return ("link", $diff_status) if $mode eq "120000";
2118 return ("dir", $diff_status) if $mode eq "040000";
2119 return ("file", $diff_status);
2120}
2121sub md5sum {
2123 my $arg = shift;
2124 my $ref = ref $arg;
2125 my $md5 = Digest::MD5->new();
2126 if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2127 $md5->addfile($arg) or croak $!;
2128 } elsif ($ref eq 'SCALAR') {
2129 $md5->add($$arg) or croak $!;
2130 } elsif (!$ref) {
2131 $md5->add($arg) or croak $!;
2132 } else {
2133 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2134 }
2135 return $md5->hexdigest();
2136}
2137sub gc_directory {
2139 if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2140 my $out_filename = $_ . ".gz";
2141 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2142 binmode $in_fh;
2143 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2144 die "Unable to open $out_filename: $!\n";
2145 my $res;
2147 while ($res = sysread($in_fh, my $str, 1024)) {
2148 $gz->gzwrite($str) or
2149 die "Unable to write: ".$gz->gzerror()."!\n";
2150 }
2151 unlink $_ or die "unlink $File::Find::name: $!\n";
2152 } elsif (-f $_ && basename($_) eq "index") {
2153 unlink $_ or die "unlink $_: $!\n";
2154 }
2155}
2156__END__
2158Data structures:
2160$remotes = { # returned by read_all_remotes()
2163 'svn' => {
2164 # svn-remote.svn.url=https://svn.musicpd.org
2165 url => 'https://svn.musicpd.org',
2166 # svn-remote.svn.fetch=mpd/trunk:trunk
2167 fetch => {
2168 'mpd/trunk' => 'trunk',
2169 },
2170 # svn-remote.svn.tags=mpd/tags/*:tags/*
2171 tags => {
2172 path => {
2173 left => 'mpd/tags',
2174 right => '',
2175 regex => qr!mpd/tags/([^/]+)$!,
2176 glob => 'tags/*',
2177 },
2178 ref => {
2179 left => 'tags',
2180 right => '',
2181 regex => qr!tags/([^/]+)$!,
2182 glob => 'tags/*',
2183 },
2184 }
2185 }
2186};
2187$log_entry hashref as returned by libsvn_log_entry()
2189{
2190 log => 'whitespace-formatted log entry
2191', # trailing newline is preserved
2192 revision => '8', # integer
2193 date => '2004-02-24T17:01:44.108345Z', # commit date
2194 author => 'committer name'
2195};
2196# this is generated by generate_diff();
2199@mods = array of diff-index line hashes, each element represents one line
2200 of diff-index output
2201diff-index line ($m hash)
2203{
2204 mode_a => first column of diff-index output, no leading ':',
2205 mode_b => second column of diff-index output,
2206 sha1_b => sha1sum of the final blob,
2207 chg => change type [MCRADT],
2208 file_a => original file name of a file (iff chg is 'C' or 'R')
2209 file_b => new/current file name of a file (any chg)
2210}
2211;
2212# retval of read_url_paths{,_all}();
2214$l_map = {
2215 # repository root url
2216 'https://svn.musicpd.org' => {
2217 # repository path # GIT_SVN_ID
2218 'mpd/trunk' => 'trunk',
2219 'mpd/tags/0.11.5' => 'tags/0.11.5',
2220 },
2221}
2222Notes:
2224 I don't trust the each() function on unless I created %hash myself
2225 because the internal iterator may not have started at base.