Andrew's git / gitweb.git / git-cvsimport.perl
?
git-cvsimport.perlon commit cvsimport: use git-update-index --index-info (6a1871e)
   1#!/usr/bin/perl -w
   2
   3# This tool is copyright (c) 2005, Matthias Urlichs.
   4# It is released under the Gnu Public License, version 2.
   5#
   6# The basic idea is to aggregate CVS check-ins into related changes.
   7# Fortunately, "cvsps" does that for us; all we have to do is to parse
   8# its output.
   9#
  10# Checking out the files is done by a single long-running CVS connection
  11# / server process.
  12#
  13# The head revision is on branch "origin" by default.
  14# You can change that with the '-o' option.
  15
  16use strict;
  17use warnings;
  18use Getopt::Std;
  19use File::Spec;
  20use File::Temp qw(tempfile);
  21use File::Path qw(mkpath);
  22use File::Basename qw(basename dirname);
  23use Time::Local;
  24use IO::Socket;
  25use IO::Pipe;
  26use POSIX qw(strftime dup2);
  27use IPC::Open2;
  28
  29$SIG{'PIPE'}="IGNORE";
  30$ENV{'TZ'}="UTC";
  31
  32our($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S,$opt_L);
  33my (%conv_author_name, %conv_author_email);
  34
  35sub usage() {
  36        print STDERR <<END;
  37Usage: ${\basename $0}     # fetch/update GIT from CVS
  38       [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  39       [-p opts-for-cvsps] [-C GIT_repository] [-z fuzz] [-i] [-k] [-u]
  40       [-s subst] [-m] [-M regex] [-S regex] [CVS_module]
  41END
  42        exit(1);
  43}
  44
  45sub read_author_info($) {
  46        my ($file) = @_;
  47        my $user;
  48        open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  49
  50        while (<$f>) {
  51                # Expected format is this:
  52                #   exon=Andreas Ericsson <ae@op5.se>
  53                if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  54                        $user = $1;
  55                        $conv_author_name{$user} = $2;
  56                        $conv_author_email{$user} = $3;
  57                }
  58                # However, we also read from CVSROOT/users format
  59                # to ease migration.
  60                elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  61                        my $mapped;
  62                        ($user, $mapped) = ($1, $3);
  63                        if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  64                                $conv_author_name{$user} = $1;
  65                                $conv_author_email{$user} = $2;
  66                        }
  67                        elsif ($mapped =~ /^<?(.*)>?$/) {
  68                                $conv_author_name{$user} = $user;
  69                                $conv_author_email{$user} = $1;
  70                        }
  71                }
  72                # NEEDSWORK: Maybe warn on unrecognized lines?
  73        }
  74        close ($f);
  75}
  76
  77sub write_author_info($) {
  78        my ($file) = @_;
  79        open my $f, '>', $file or
  80          die("Failed to open $file for writing: $!");
  81
  82        foreach (keys %conv_author_name) {
  83                print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  84        }
  85        close ($f);
  86}
  87
  88getopts("hivmkuo:d:p:C:z:s:M:P:A:S:L:") or usage();
  89usage if $opt_h;
  90
  91@ARGV <= 1 or usage();
  92
  93if($opt_d) {
  94        $ENV{"CVSROOT"} = $opt_d;
  95} elsif(-f 'CVS/Root') {
  96        open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
  97        $opt_d = <$f>;
  98        chomp $opt_d;
  99        close $f;
 100        $ENV{"CVSROOT"} = $opt_d;
 101} elsif($ENV{"CVSROOT"}) {
 102        $opt_d = $ENV{"CVSROOT"};
 103} else {
 104        die "CVSROOT needs to be set";
 105}
 106$opt_o ||= "origin";
 107$opt_s ||= "-";
 108my $git_tree = $opt_C;
 109$git_tree ||= ".";
 110
 111my $cvs_tree;
 112if ($#ARGV == 0) {
 113        $cvs_tree = $ARGV[0];
 114} elsif (-f 'CVS/Repository') {
 115        open my $f, '<', 'CVS/Repository' or 
 116            die 'Failed to open CVS/Repository';
 117        $cvs_tree = <$f>;
 118        chomp $cvs_tree;
 119        close $f;
 120} else {
 121        usage();
 122}
 123
 124our @mergerx = ();
 125if ($opt_m) {
 126        @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
 127}
 128if ($opt_M) {
 129        push (@mergerx, qr/$opt_M/);
 130}
 131
 132select(STDERR); $|=1; select(STDOUT);
 133
 134
 135package CVSconn;
 136# Basic CVS dialog.
 137# We're only interested in connecting and downloading, so ...
 138
 139use File::Spec;
 140use File::Temp qw(tempfile);
 141use POSIX qw(strftime dup2);
 142
 143sub new {
 144        my($what,$repo,$subdir) = @_;
 145        $what=ref($what) if ref($what);
 146
 147        my $self = {};
 148        $self->{'buffer'} = "";
 149        bless($self,$what);
 150
 151        $repo =~ s#/+$##;
 152        $self->{'fullrep'} = $repo;
 153        $self->conn();
 154
 155        $self->{'subdir'} = $subdir;
 156        $self->{'lines'} = undef;
 157
 158        return $self;
 159}
 160
 161sub conn {
 162        my $self = shift;
 163        my $repo = $self->{'fullrep'};
 164        if($repo =~ s/^:pserver:(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 165                my($user,$pass,$serv,$port) = ($1,$2,$3,$4);
 166                $user="anonymous" unless defined $user;
 167                my $rr2 = "-";
 168                unless($port) {
 169                        $rr2 = ":pserver:$user\@$serv:$repo";
 170                        $port=2401;
 171                }
 172                my $rr = ":pserver:$user\@$serv:$port$repo";
 173
 174                unless($pass) {
 175                        open(H,$ENV{'HOME'}."/.cvspass") and do {
 176                                # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 177                                while(<H>) {
 178                                        chomp;
 179                                        s/^\/\d+\s+//;
 180                                        my ($w,$p) = split(/\s/,$_,2);
 181                                        if($w eq $rr or $w eq $rr2) {
 182                                                $pass = $p;
 183                                                last;
 184                                        }
 185                                }
 186                        };
 187                }
 188                $pass="A" unless $pass;
 189
 190                my $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 191                die "Socket to $serv: $!\n" unless defined $s;
 192                $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 193                        or die "Write to $serv: $!\n";
 194                $s->flush();
 195
 196                my $rep = <$s>;
 197
 198                if($rep ne "I LOVE YOU\n") {
 199                        $rep="<unknown>" unless $rep;
 200                        die "AuthReply: $rep\n";
 201                }
 202                $self->{'socketo'} = $s;
 203                $self->{'socketi'} = $s;
 204        } else { # local or ext: Fork off our own cvs server.
 205                my $pr = IO::Pipe->new();
 206                my $pw = IO::Pipe->new();
 207                my $pid = fork();
 208                die "Fork: $!\n" unless defined $pid;
 209                my $cvs = 'cvs';
 210                $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 211                my $rsh = 'rsh';
 212                $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 213
 214                my @cvs = ($cvs, 'server');
 215                my ($local, $user, $host);
 216                $local = $repo =~ s/:local://;
 217                if (!$local) {
 218                    $repo =~ s/:ext://;
 219                    $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 220                    ($user, $host) = ($1, $2);
 221                }
 222                if (!$local) {
 223                    if ($user) {
 224                        unshift @cvs, $rsh, '-l', $user, $host;
 225                    } else {
 226                        unshift @cvs, $rsh, $host;
 227                    }
 228                }
 229
 230                unless($pid) {
 231                        $pr->writer();
 232                        $pw->reader();
 233                        dup2($pw->fileno(),0);
 234                        dup2($pr->fileno(),1);
 235                        $pr->close();
 236                        $pw->close();
 237                        exec(@cvs);
 238                }
 239                $pw->writer();
 240                $pr->reader();
 241                $self->{'socketo'} = $pw;
 242                $self->{'socketi'} = $pr;
 243        }
 244        $self->{'socketo'}->write("Root $repo\n");
 245
 246        # Trial and error says that this probably is the minimum set
 247        $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 248
 249        $self->{'socketo'}->write("valid-requests\n");
 250        $self->{'socketo'}->flush();
 251
 252        chomp(my $rep=$self->readline());
 253        if($rep !~ s/^Valid-requests\s*//) {
 254                $rep="<unknown>" unless $rep;
 255                die "Expected Valid-requests from server, but got: $rep\n";
 256        }
 257        chomp(my $res=$self->readline());
 258        die "validReply: $res\n" if $res ne "ok";
 259
 260        $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 261        $self->{'repo'} = $repo;
 262}
 263
 264sub readline {
 265        my($self) = @_;
 266        return $self->{'socketi'}->getline();
 267}
 268
 269sub _file {
 270        # Request a file with a given revision.
 271        # Trial and error says this is a good way to do it. :-/
 272        my($self,$fn,$rev) = @_;
 273        $self->{'socketo'}->write("Argument -N\n") or return undef;
 274        $self->{'socketo'}->write("Argument -P\n") or return undef;
 275        # -kk: Linus' version doesn't use it - defaults to off
 276        if ($opt_k) {
 277            $self->{'socketo'}->write("Argument -kk\n") or return undef;
 278        }
 279        $self->{'socketo'}->write("Argument -r\n") or return undef;
 280        $self->{'socketo'}->write("Argument $rev\n") or return undef;
 281        $self->{'socketo'}->write("Argument --\n") or return undef;
 282        $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 283        $self->{'socketo'}->write("Directory .\n") or return undef;
 284        $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 285        # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 286        $self->{'socketo'}->write("co\n") or return undef;
 287        $self->{'socketo'}->flush() or return undef;
 288        $self->{'lines'} = 0;
 289        return 1;
 290}
 291sub _line {
 292        # Read a line from the server.
 293        # ... except that 'line' may be an entire file. ;-)
 294        my($self, $fh) = @_;
 295        die "Not in lines" unless defined $self->{'lines'};
 296
 297        my $line;
 298        my $res=0;
 299        while(defined($line = $self->readline())) {
 300                # M U gnupg-cvs-rep/AUTHORS
 301                # Updated gnupg-cvs-rep/
 302                # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 303                # /AUTHORS/1.1///T1.1
 304                # u=rw,g=rw,o=rw
 305                # 0
 306                # ok
 307
 308                if($line =~ s/^(?:Created|Updated) //) {
 309                        $line = $self->readline(); # path
 310                        $line = $self->readline(); # Entries line
 311                        my $mode = $self->readline(); chomp $mode;
 312                        $self->{'mode'} = $mode;
 313                        defined (my $cnt = $self->readline())
 314                                or die "EOF from server after 'Changed'\n";
 315                        chomp $cnt;
 316                        die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 317                        $line="";
 318                        $res=0;
 319                        while($cnt) {
 320                                my $buf;
 321                                my $num = $self->{'socketi'}->read($buf,$cnt);
 322                                die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 323                                print $fh $buf;
 324                                $res += $num;
 325                                $cnt -= $num;
 326                        }
 327                } elsif($line =~ s/^ //) {
 328                        print $fh $line;
 329                        $res += length($line);
 330                } elsif($line =~ /^M\b/) {
 331                        # output, do nothing
 332                } elsif($line =~ /^Mbinary\b/) {
 333                        my $cnt;
 334                        die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 335                        chomp $cnt;
 336                        die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 337                        $line="";
 338                        while($cnt) {
 339                                my $buf;
 340                                my $num = $self->{'socketi'}->read($buf,$cnt);
 341                                die "S: Mbinary $cnt: $num: $!\n" if not defined $num or $num<=0;
 342                                print $fh $buf;
 343                                $res += $num;
 344                                $cnt -= $num;
 345                        }
 346                } else {
 347                        chomp $line;
 348                        if($line eq "ok") {
 349                                # print STDERR "S: ok (".length($res).")\n";
 350                                return $res;
 351                        } elsif($line =~ s/^E //) {
 352                                # print STDERR "S: $line\n";
 353                        } elsif($line =~ /^(Remove-entry|Removed) /i) {
 354                                $line = $self->readline(); # filename
 355                                $line = $self->readline(); # OK
 356                                chomp $line;
 357                                die "Unknown: $line" if $line ne "ok";
 358                                return -1;
 359                        } else {
 360                                die "Unknown: $line\n";
 361                        }
 362                }
 363        }
 364        return undef;
 365}
 366sub file {
 367        my($self,$fn,$rev) = @_;
 368        my $res;
 369
 370        my ($fh, $name) = tempfile('gitcvs.XXXXXX', 
 371                    DIR => File::Spec->tmpdir(), UNLINK => 1);
 372
 373        $self->_file($fn,$rev) and $res = $self->_line($fh);
 374
 375        if (!defined $res) {
 376            print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
 377            truncate $fh, 0;
 378            $self->conn();
 379            $self->_file($fn,$rev) or die "No file command send";
 380            $res = $self->_line($fh);
 381            die "Retry failed" unless defined $res;
 382        }
 383        close ($fh);
 384
 385        return ($name, $res);
 386}
 387
 388
 389package main;
 390
 391my $cvs = CVSconn->new($opt_d, $cvs_tree);
 392
 393
 394sub pdate($) {
 395        my($d) = @_;
 396        m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 397                or die "Unparseable date: $d\n";
 398        my $y=$1; $y-=1900 if $y>1900;
 399        return timegm($6||0,$5,$4,$3,$2-1,$y);
 400}
 401
 402sub pmode($) {
 403        my($mode) = @_;
 404        my $m = 0;
 405        my $mm = 0;
 406        my $um = 0;
 407        for my $x(split(//,$mode)) {
 408                if($x eq ",") {
 409                        $m |= $mm&$um;
 410                        $mm = 0;
 411                        $um = 0;
 412                } elsif($x eq "u") { $um |= 0700;
 413                } elsif($x eq "g") { $um |= 0070;
 414                } elsif($x eq "o") { $um |= 0007;
 415                } elsif($x eq "r") { $mm |= 0444;
 416                } elsif($x eq "w") { $mm |= 0222;
 417                } elsif($x eq "x") { $mm |= 0111;
 418                } elsif($x eq "=") { # do nothing
 419                } else { die "Unknown mode: $mode\n";
 420                }
 421        }
 422        $m |= $mm&$um;
 423        return $m;
 424}
 425
 426sub getwd() {
 427        my $pwd = `pwd`;
 428        chomp $pwd;
 429        return $pwd;
 430}
 431
 432
 433sub get_headref($$) {
 434    my $name    = shift;
 435    my $git_dir = shift; 
 436    my $sha;
 437    
 438    if (open(C,"$git_dir/refs/heads/$name")) {
 439        chomp($sha = <C>);
 440        close(C);
 441        length($sha) == 40
 442            or die "Cannot get head id for $name ($sha): $!\n";
 443    }
 444    return $sha;
 445}
 446
 447
 448-d $git_tree
 449        or mkdir($git_tree,0777)
 450        or die "Could not create $git_tree: $!";
 451chdir($git_tree);
 452
 453my $last_branch = "";
 454my $orig_branch = "";
 455my %branch_date;
 456my $tip_at_start = undef;
 457
 458my $git_dir = $ENV{"GIT_DIR"} || ".git";
 459$git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 460$ENV{"GIT_DIR"} = $git_dir;
 461my $orig_git_index;
 462$orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 463my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 464                                    DIR => File::Spec->tmpdir());
 465close ($git_ih);
 466$ENV{GIT_INDEX_FILE} = $git_index;
 467unless(-d $git_dir) {
 468        system("git-init-db");
 469        die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 470        system("git-read-tree");
 471        die "Cannot init an empty tree: $?\n" if $?;
 472
 473        $last_branch = $opt_o;
 474        $orig_branch = "";
 475} else {
 476        -f "$git_dir/refs/heads/$opt_o"
 477                or die "Branch '$opt_o' does not exist.\n".
 478                       "Either use the correct '-o branch' option,\n".
 479                       "or import to a new repository.\n";
 480
 481        open(F, "git-symbolic-ref HEAD |") or
 482                die "Cannot run git-symbolic-ref: $!\n";
 483        chomp ($last_branch = <F>);
 484        $last_branch = basename($last_branch);
 485        close(F);
 486        unless($last_branch) {
 487                warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 488                $last_branch = "master";
 489        }
 490        $orig_branch = $last_branch;
 491        $tip_at_start = `git-rev-parse --verify HEAD`;
 492
 493        # populate index
 494        system('git-read-tree', $last_branch);
 495        die "read-tree failed: $?\n" if $?;
 496
 497        # Get the last import timestamps
 498        opendir(D,"$git_dir/refs/heads");
 499        while(defined(my $head = readdir(D))) {
 500                next if $head =~ /^\./;
 501                open(F,"$git_dir/refs/heads/$head")
 502                        or die "Bad head branch: $head: $!\n";
 503                chomp(my $ftag = <F>);
 504                close(F);
 505                open(F,"git-cat-file commit $ftag |");
 506                while(<F>) {
 507                        next unless /^author\s.*\s(\d+)\s[-+]\d{4}$/;
 508                        $branch_date{$head} = $1;
 509                        last;
 510                }
 511                close(F);
 512        }
 513        closedir(D);
 514}
 515
 516-d $git_dir
 517        or die "Could not create git subdir ($git_dir).\n";
 518
 519# now we read (and possibly save) author-info as well
 520-f "$git_dir/cvs-authors" and
 521  read_author_info("$git_dir/cvs-authors");
 522if ($opt_A) {
 523        read_author_info($opt_A);
 524        write_author_info("$git_dir/cvs-authors");
 525}
 526
 527my $pid = open(CVS,"-|");
 528die "Cannot fork: $!\n" unless defined $pid;
 529unless($pid) {
 530        my @opt;
 531        @opt = split(/,/,$opt_p) if defined $opt_p;
 532        unshift @opt, '-z', $opt_z if defined $opt_z;
 533        unshift @opt, '-q'         unless defined $opt_v;
 534        unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 535                push @opt, '--cvs-direct';
 536        }
 537        if ($opt_P) {
 538            exec("cat", $opt_P);
 539        } else {
 540            exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 541            die "Could not start cvsps: $!\n";
 542        }
 543}
 544
 545
 546## cvsps output:
 547#---------------------
 548#PatchSet 314
 549#Date: 1999/09/18 13:03:59
 550#Author: wkoch
 551#Branch: STABLE-BRANCH-1-0
 552#Ancestor branch: HEAD
 553#Tag: (none)
 554#Log:
 555#    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 556#Members:
 557#       README:1.57->1.57.2.1
 558#       VERSION:1.96->1.96.2.1
 559#
 560#---------------------
 561
 562my $state = 0;
 563
 564my($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 565my(@old,@new,@skipped);
 566sub commit {
 567        my $pid;
 568
 569        open(my $fh, '|-', qw(git-update-index -z --index-info))
 570                or die "unable to open git-update-index: $!";
 571        print $fh
 572                (map { "0 0000000000000000000000000000000000000000\t$_\0" }
 573                        @old),
 574                (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
 575                        @new)
 576                or die "unable to write to git-update-index: $!";
 577        close $fh
 578                or die "unable to write to git-update-index: $!";
 579        $? and die "git-update-index reported error: $?";
 580        @old = @new = ();
 581
 582        $pid = open(C,"-|");
 583        die "Cannot fork: $!" unless defined $pid;
 584        unless($pid) {
 585                exec("git-write-tree");
 586                die "Cannot exec git-write-tree: $!\n";
 587        }
 588        chomp(my $tree = <C>);
 589        length($tree) == 40
 590                or die "Cannot get tree id ($tree): $!\n";
 591        close(C)
 592                or die "Error running git-write-tree: $?\n";
 593        print "Tree ID $tree\n" if $opt_v;
 594
 595        my $parent = "";
 596        if(open(C,"$git_dir/refs/heads/$last_branch")) {
 597                chomp($parent = <C>);
 598                close(C);
 599                length($parent) == 40
 600                        or die "Cannot get parent id ($parent): $!\n";
 601                print "Parent ID $parent\n" if $opt_v;
 602        }
 603
 604        my $pr = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 605        my $pw = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 606        $pid = fork();
 607        die "Fork: $!\n" unless defined $pid;
 608        unless($pid) {
 609                $pr->writer();
 610                $pw->reader();
 611                open(OUT,">&STDOUT");
 612                dup2($pw->fileno(),0);
 613                dup2($pr->fileno(),1);
 614                $pr->close();
 615                $pw->close();
 616
 617                my @par = ();
 618                @par = ("-p",$parent) if $parent;
 619
 620                # loose detection of merges
 621                # based on the commit msg
 622                foreach my $rx (@mergerx) {
 623                        if ($logmsg =~ $rx) {
 624                                my $mparent = $1;
 625                                if ($mparent eq 'HEAD') { $mparent = $opt_o };
 626                                if ( -e "$git_dir/refs/heads/$mparent") {
 627                                        $mparent = get_headref($mparent, $git_dir);
 628                                        push @par, '-p', $mparent;
 629                                        print OUT "Merge parent branch: $mparent\n" if $opt_v;
 630                                }
 631                        }
 632                }
 633
 634                exec("env",
 635                        "GIT_AUTHOR_NAME=$author_name",
 636                        "GIT_AUTHOR_EMAIL=$author_email",
 637                        "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 638                        "GIT_COMMITTER_NAME=$author_name",
 639                        "GIT_COMMITTER_EMAIL=$author_email",
 640                        "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 641                        "git-commit-tree", $tree,@par);
 642                die "Cannot exec git-commit-tree: $!\n";
 643
 644                close OUT;
 645        }
 646        $pw->writer();
 647        $pr->reader();
 648
 649        # compatibility with git2cvs
 650        substr($logmsg,32767) = "" if length($logmsg) > 32767;
 651        $logmsg =~ s/[\s\n]+\z//;
 652
 653        if (@skipped) {
 654            $logmsg .= "\n\n\nSKIPPED:\n\t";
 655            $logmsg .= join("\n\t", @skipped) . "\n";
 656            @skipped = ();
 657        }
 658
 659        print $pw "$logmsg\n"
 660                or die "Error writing to git-commit-tree: $!\n";
 661        $pw->close();
 662
 663        print "Committed patch $patchset ($branch ".strftime("%Y-%m-%d %H:%M:%S",gmtime($date)).")\n" if $opt_v;
 664        chomp(my $cid = <$pr>);
 665        length($cid) == 40
 666                or die "Cannot get commit id ($cid): $!\n";
 667        print "Commit ID $cid\n" if $opt_v;
 668        $pr->close();
 669
 670        waitpid($pid,0);
 671        die "Error running git-commit-tree: $?\n" if $?;
 672
 673        system("git-update-ref refs/heads/$branch $cid") == 0
 674                or die "Cannot write branch $branch for update: $!\n";
 675
 676        if($tag) {
 677                my($in, $out) = ('','');
 678                my($xtag) = $tag;
 679                $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 680                $xtag =~ tr/_/\./ if ( $opt_u );
 681                $xtag =~ s/[\/]/$opt_s/g;
 682                
 683                my $pid = open2($in, $out, 'git-mktag');
 684                print $out "object $cid\n".
 685                    "type commit\n".
 686                    "tag $xtag\n".
 687                    "tagger $author_name <$author_email>\n"
 688                    or die "Cannot create tag object $xtag: $!\n";
 689                close($out)
 690                    or die "Cannot create tag object $xtag: $!\n";
 691
 692                my $tagobj = <$in>;
 693                chomp $tagobj;
 694
 695                if ( !close($in) or waitpid($pid, 0) != $pid or
 696                     $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 697                    die "Cannot create tag object $xtag: $!\n";
 698                }
 699                
 700
 701                open(C,">$git_dir/refs/tags/$xtag")
 702                        or die "Cannot create tag $xtag: $!\n";
 703                print C "$tagobj\n"
 704                        or die "Cannot write tag $xtag: $!\n";
 705                close(C)
 706                        or die "Cannot write tag $xtag: $!\n";
 707
 708                print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 709        }
 710};
 711
 712my $commitcount = 1;
 713while(<CVS>) {
 714        chomp;
 715        if($state == 0 and /^-+$/) {
 716                $state = 1;
 717        } elsif($state == 0) {
 718                $state = 1;
 719                redo;
 720        } elsif(($state==0 or $state==1) and s/^PatchSet\s+//) {
 721                $patchset = 0+$_;
 722                $state=2;
 723        } elsif($state == 2 and s/^Date:\s+//) {
 724                $date = pdate($_);
 725                unless($date) {
 726                        print STDERR "Could not parse date: $_\n";
 727                        $state=0;
 728                        next;
 729                }
 730                $state=3;
 731        } elsif($state == 3 and s/^Author:\s+//) {
 732                s/\s+$//;
 733                if (/^(.*?)\s+<(.*)>/) {
 734                    ($author_name, $author_email) = ($1, $2);
 735                } elsif ($conv_author_name{$_}) {
 736                        $author_name = $conv_author_name{$_};
 737                        $author_email = $conv_author_email{$_};
 738                } else {
 739                    $author_name = $author_email = $_;
 740                }
 741                $state = 4;
 742        } elsif($state == 4 and s/^Branch:\s+//) {
 743                s/\s+$//;
 744                s/[\/]/$opt_s/g;
 745                $branch = $_;
 746                $state = 5;
 747        } elsif($state == 5 and s/^Ancestor branch:\s+//) {
 748                s/\s+$//;
 749                $ancestor = $_;
 750                $ancestor = $opt_o if $ancestor eq "HEAD";
 751                $state = 6;
 752        } elsif($state == 5) {
 753                $ancestor = undef;
 754                $state = 6;
 755                redo;
 756        } elsif($state == 6 and s/^Tag:\s+//) {
 757                s/\s+$//;
 758                if($_ eq "(none)") {
 759                        $tag = undef;
 760                } else {
 761                        $tag = $_;
 762                }
 763                $state = 7;
 764        } elsif($state == 7 and /^Log:/) {
 765                $logmsg = "";
 766                $state = 8;
 767        } elsif($state == 8 and /^Members:/) {
 768                $branch = $opt_o if $branch eq "HEAD";
 769                if(defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 770                        # skip
 771                        print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 772                        $state = 11;
 773                        next;
 774                }
 775                if($ancestor) {
 776                        if(-f "$git_dir/refs/heads/$branch") {
 777                                print STDERR "Branch $branch already exists!\n";
 778                                $state=11;
 779                                next;
 780                        }
 781                        unless(open(H,"$git_dir/refs/heads/$ancestor")) {
 782                                print STDERR "Branch $ancestor does not exist!\n";
 783                                $state=11;
 784                                next;
 785                        }
 786                        chomp(my $id = <H>);
 787                        close(H);
 788                        unless(open(H,"> $git_dir/refs/heads/$branch")) {
 789                                print STDERR "Could not create branch $branch: $!\n";
 790                                $state=11;
 791                                next;
 792                        }
 793                        print H "$id\n"
 794                                or die "Could not write branch $branch: $!";
 795                        close(H)
 796                                or die "Could not write branch $branch: $!";
 797                }
 798                if(($ancestor || $branch) ne $last_branch) {
 799                        print "Switching from $last_branch to $branch\n" if $opt_v;
 800                        system("git-read-tree", $branch);
 801                        die "read-tree failed: $?\n" if $?;
 802                }
 803                $last_branch = $branch if $branch ne $last_branch;
 804                $state = 9;
 805        } elsif($state == 8) {
 806                $logmsg .= "$_\n";
 807        } elsif($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 808#       VERSION:1.96->1.96.2.1
 809                my $init = ($2 eq "INITIAL");
 810                my $fn = $1;
 811                my $rev = $3;
 812                $fn =~ s#^/+##;
 813                if ($opt_S && $fn =~ m/$opt_S/) {
 814                    print "SKIPPING $fn v $rev\n";
 815                    push(@skipped, $fn);
 816                    next;
 817                }
 818                print "Fetching $fn   v $rev\n" if $opt_v;
 819                my ($tmpname, $size) = $cvs->file($fn,$rev);
 820                if($size == -1) {
 821                        push(@old,$fn);
 822                        print "Drop $fn\n" if $opt_v;
 823                } else {
 824                        print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 825                        my $pid = open(my $F, '-|');
 826                        die $! unless defined $pid;
 827                        if (!$pid) {
 828                            exec("git-hash-object", "-w", $tmpname)
 829                                or die "Cannot create object: $!\n";
 830                        }
 831                        my $sha = <$F>;
 832                        chomp $sha;
 833                        close $F;
 834                        my $mode = pmode($cvs->{'mode'});
 835                        push(@new,[$mode, $sha, $fn]); # may be resurrected!
 836                }
 837                unlink($tmpname);
 838        } elsif($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 839                my $fn = $1;
 840                $fn =~ s#^/+##;
 841                push(@old,$fn);
 842                print "Delete $fn\n" if $opt_v;
 843        } elsif($state == 9 and /^\s*$/) {
 844                $state = 10;
 845        } elsif(($state == 9 or $state == 10) and /^-+$/) {
 846                $commitcount++;
 847                if ($opt_L && $commitcount > $opt_L) {
 848                        last;
 849                }
 850                commit();
 851                if (($commitcount & 1023) == 0) {
 852                        system("git repack -a -d");
 853                }
 854                $state = 1;
 855        } elsif($state == 11 and /^-+$/) {
 856                $state = 1;
 857        } elsif(/^-+$/) { # end of unknown-line processing
 858                $state = 1;
 859        } elsif($state != 11) { # ignore stuff when skipping
 860                print "* UNKNOWN LINE * $_\n";
 861        }
 862}
 863commit() if $branch and $state != 11;
 864
 865unlink($git_index);
 866
 867if (defined $orig_git_index) {
 868        $ENV{GIT_INDEX_FILE} = $orig_git_index;
 869} else {
 870        delete $ENV{GIT_INDEX_FILE};
 871}
 872
 873# Now switch back to the branch we were in before all of this happened
 874if($orig_branch) {
 875        print "DONE.\n" if $opt_v;
 876        if ($opt_i) {
 877                exit 0;
 878        }
 879        my $tip_at_end = `git-rev-parse --verify HEAD`;
 880        if ($tip_at_start ne $tip_at_end) {
 881                for ($tip_at_start, $tip_at_end) { chomp; }
 882                print "Fetched into the current branch.\n" if $opt_v;
 883                system(qw(git-read-tree -u -m),
 884                       $tip_at_start, $tip_at_end);
 885                die "Fast-forward update failed: $?\n" if $?;
 886        }
 887        else {
 888                system(qw(git-merge cvsimport HEAD), "refs/heads/$opt_o");
 889                die "Could not merge $opt_o into the current branch.\n" if $?;
 890        }
 891} else {
 892        $orig_branch = "master";
 893        print "DONE; creating $orig_branch branch\n" if $opt_v;
 894        system("git-update-ref", "refs/heads/master", "refs/heads/$opt_o")
 895                unless -f "$git_dir/refs/heads/master";
 896        system('git-update-ref', 'HEAD', "$orig_branch");
 897        unless ($opt_i) {
 898                system('git checkout');
 899                die "checkout failed: $?\n" if $?;
 900        }
 901}