Andrew's git - gitweb.git/blob - templates/hooks--fsmonitor-watchman.sample

   1#!/usr/bin/perl
   2
   3use strict;
   4use warnings;
   5use IPC::Open2;
   6
   7# An example hook script to integrate Watchman
   8# (https://facebook.github.io/watchman/) with git to speed up detecting
   9# new and modified files.
  10#
  11# The hook is passed a version (currently 1) and a time in nanoseconds
  12# formatted as a string and outputs to stdout all files that have been
  13# modified since the given time. Paths must be relative to the root of
  14# the working tree and separated by a single NUL.
  15#
  16# To enable this hook, rename this file to "query-watchman" and set
  17# 'git config core.fsmonitor .git/hooks/query-watchman'
  18#
  19my ($version, $time) = @ARGV;
  20
  21# Check the hook interface version
  22
  23if ($version == 1) {
  24        # convert nanoseconds to seconds
  25        $time = int $time / 1000000000;
  26} else {
  27        die "Unsupported query-fsmonitor hook version '$version'.\n" .
  28            "Falling back to scanning...\n";
  29}
  30
  31# Convert unix style paths to escaped Windows style paths when running
  32# in Windows command prompt
  33
  34my $system = `uname -s`;
  35$system =~ s/[\r\n]+//g;
  36my $git_work_tree;
  37
  38if ($system =~ m/^MSYS_NT/ || $system =~ m/^MINGW/) {
  39        $git_work_tree = `cygpath -aw "\$PWD"`;
  40        $git_work_tree =~ s/[\r\n]+//g;
  41        $git_work_tree =~ s,\\,/,g;
  42} else {
  43        require Cwd;
  44        $git_work_tree = Cwd::cwd();
  45}
  46
  47my $retry = 1;
  48
  49launch_watchman();
  50
  51sub launch_watchman {
  52
  53        my $pid = open2(\*CHLD_OUT, \*CHLD_IN, 'watchman -j --no-pretty')
  54            or die "open2() failed: $!\n" .
  55            "Falling back to scanning...\n";
  56
  57        # In the query expression below we're asking for names of files that
  58        # changed since $time but were not transient (ie created after
  59        # $time but no longer exist).
  60        #
  61        # To accomplish this, we're using the "since" generator to use the
  62        # recency index to select candidate nodes and "fields" to limit the
  63        # output to file names only. Then we're using the "expression" term to
  64        # further constrain the results.
  65        #
  66        # The category of transient files that we want to ignore will have a
  67        # creation clock (cclock) newer than $time_t value and will also not
  68        # currently exist.
  69
  70        my $query = <<" END";
  71                ["query", "$git_work_tree", {
  72                        "since": $time,
  73                        "fields": ["name"],
  74                        "expression": ["not", ["allof", ["since", $time, "cclock"], ["not", "exists"]]]
  75                }]
  76        END
  77
  78        print CHLD_IN $query;
  79        close CHLD_IN;
  80        my $response = do {local $/; <CHLD_OUT>};
  81
  82        die "Watchman: command returned no output.\n" .
  83            "Falling back to scanning...\n" if $response eq "";
  84        die "Watchman: command returned invalid output: $response\n" .
  85            "Falling back to scanning...\n" unless $response =~ /^\{/;
  86
  87        my $json_pkg;
  88        eval {
  89                require JSON::XS;
  90                $json_pkg = "JSON::XS";
  91                1;
  92        } or do {
  93                require JSON::PP;
  94                $json_pkg = "JSON::PP";
  95        };
  96
  97        my $o = $json_pkg->new->utf8->decode($response);
  98
  99        if ($retry > 0 and $o->{error} and $o->{error} =~ m/unable to resolve root .* directory (.*) is not watched/) {
 100                print STDERR "Adding '$git_work_tree' to watchman's watch list.\n";
 101                $retry--;
 102                qx/watchman watch "$git_work_tree"/;
 103                die "Failed to make watchman watch '$git_work_tree'.\n" .
 104                    "Falling back to scanning...\n" if $? != 0;
 105
 106                # Watchman will always return all files on the first query so
 107                # return the fast "everything is dirty" flag to git and do the
 108                # Watchman query just to get it over with now so we won't pay
 109                # the cost in git to look up each individual file.
 110                print "/\0";
 111                eval { launch_watchman() };
 112                exit 0;
 113        }
 114
 115        die "Watchman: $o->{error}.\n" .
 116            "Falling back to scanning...\n" if $o->{error};
 117
 118        binmode STDOUT, ":utf8";
 119        local $, = "\0";
 120        print @{$o->{files}};
 121}