Andrew's git / gitweb.git / git-svnimport.perl
?
git-svnimport.perlon commit Show URL in the "Getting <foo> list" http-fetch messages (6fd72e3)
   1#!/usr/bin/perl -w
   2
   3# This tool is copyright (c) 2005, Matthias Urlichs.
   4# It is released under the Gnu Public License, version 2.
   5#
   6# The basic idea is to pull and analyze SVN changes.
   7#
   8# Checking out the files is done by a single long-running SVN connection.
   9#
  10# The head revision is on branch "origin" by default.
  11# You can change that with the '-o' option.
  12
  13require 5.008; # for shell-safe open("-|",LIST)
  14use strict;
  15use warnings;
  16use Getopt::Std;
  17use File::Spec;
  18use File::Temp qw(tempfile);
  19use File::Path qw(mkpath);
  20use File::Basename qw(basename dirname);
  21use Time::Local;
  22use IO::Pipe;
  23use POSIX qw(strftime dup2);
  24use IPC::Open2;
  25use SVN::Core;
  26use SVN::Ra;
  27
  28die "Need SVN:Core 1.2.1 or better" if $SVN::Core::VERSION lt "1.2.1";
  29
  30$SIG{'PIPE'}="IGNORE";
  31$ENV{'TZ'}="UTC";
  32
  33our($opt_h,$opt_o,$opt_v,$opt_u,$opt_C,$opt_i,$opt_m,$opt_M,$opt_t,$opt_T,$opt_b,$opt_s,$opt_l,$opt_d,$opt_D);
  34
  35sub usage() {
  36        print STDERR <<END;
  37Usage: ${\basename $0}     # fetch/update GIT from SVN
  38       [-o branch-for-HEAD] [-h] [-v] [-l max_num_changes]
  39       [-C GIT_repository] [-t tagname] [-T trunkname] [-b branchname]
  40       [-d|-D] [-i] [-u] [-s start_chg] [-m] [-M regex] [SVN_URL]
  41END
  42        exit(1);
  43}
  44
  45getopts("b:C:dDhil:mM:o:s:t:T:uv") or usage();
  46usage if $opt_h;
  47
  48my $tag_name = $opt_t || "tags";
  49my $trunk_name = $opt_T || "trunk";
  50my $branch_name = $opt_b || "branches";
  51
  52@ARGV == 1 or @ARGV == 2 or usage();
  53
  54$opt_o ||= "origin";
  55$opt_s ||= 1;
  56my $git_tree = $opt_C;
  57$git_tree ||= ".";
  58
  59my $svn_url = $ARGV[0];
  60my $svn_dir = $ARGV[1];
  61
  62our @mergerx = ();
  63if ($opt_m) {
  64        @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
  65}
  66if ($opt_M) {
  67        push (@mergerx, qr/$opt_M/);
  68}
  69
  70select(STDERR); $|=1; select(STDOUT);
  71
  72
  73package SVNconn;
  74# Basic SVN connection.
  75# We're only interested in connecting and downloading, so ...
  76
  77use File::Spec;
  78use File::Temp qw(tempfile);
  79use POSIX qw(strftime dup2);
  80
  81sub new {
  82        my($what,$repo) = @_;
  83        $what=ref($what) if ref($what);
  84
  85        my $self = {};
  86        $self->{'buffer'} = "";
  87        bless($self,$what);
  88
  89        $repo =~ s#/+$##;
  90        $self->{'fullrep'} = $repo;
  91        $self->conn();
  92
  93        return $self;
  94}
  95
  96sub conn {
  97        my $self = shift;
  98        my $repo = $self->{'fullrep'};
  99        my $s = SVN::Ra->new($repo);
 100
 101        die "SVN connection to $repo: $!\n" unless defined $s;
 102        $self->{'svn'} = $s;
 103        $self->{'repo'} = $repo;
 104        $self->{'maxrev'} = $s->get_latest_revnum();
 105}
 106
 107sub file {
 108        my($self,$path,$rev) = @_;
 109
 110        my ($fh, $name) = tempfile('gitsvn.XXXXXX',
 111                    DIR => File::Spec->tmpdir(), UNLINK => 1);
 112
 113        print "... $rev $path ...\n" if $opt_v;
 114        my $pool = SVN::Pool->new();
 115        eval { $self->{'svn'}->get_file($path,$rev,$fh,$pool); };
 116        $pool->clear;
 117        if($@) {
 118                return undef if $@ =~ /Attempted to get checksum/;
 119                die $@;
 120        }
 121        close ($fh);
 122
 123        return $name;
 124}
 125
 126package main;
 127use URI;
 128
 129my $svn = $svn_url;
 130$svn .= "/$svn_dir" if defined $svn_dir;
 131$svn = SVNconn->new($svn);
 132
 133my $lwp_ua;
 134if($opt_d or $opt_D) {
 135        $svn_url = URI->new($svn_url)->canonical;
 136        if($opt_D) {
 137                $svn_dir =~ s#/*$#/#;
 138        } else {
 139                $svn_dir = "";
 140        }
 141        if ($svn_url->scheme eq "http") {
 142                use LWP::UserAgent;
 143                $lwp_ua = LWP::UserAgent->new(keep_alive => 1, requests_redirectable => []);
 144        } else {
 145                print STDERR "Warning: not HTTP; turning off direct file access\n";
 146                $opt_d=0;
 147        }
 148}
 149
 150sub pdate($) {
 151        my($d) = @_;
 152        $d =~ m#(\d\d\d\d)-(\d\d)-(\d\d)T(\d\d):(\d\d):(\d\d)#
 153                or die "Unparseable date: $d\n";
 154        my $y=$1; $y-=1900 if $y>1900;
 155        return timegm($6||0,$5,$4,$3,$2-1,$y);
 156}
 157
 158sub getwd() {
 159        my $pwd = `pwd`;
 160        chomp $pwd;
 161        return $pwd;
 162}
 163
 164
 165sub get_headref($$) {
 166    my $name    = shift;
 167    my $git_dir = shift;
 168    my $sha;
 169
 170    if (open(C,"$git_dir/refs/heads/$name")) {
 171        chomp($sha = <C>);
 172        close(C);
 173        length($sha) == 40
 174            or die "Cannot get head id for $name ($sha): $!\n";
 175    }
 176    return $sha;
 177}
 178
 179
 180-d $git_tree
 181        or mkdir($git_tree,0777)
 182        or die "Could not create $git_tree: $!";
 183chdir($git_tree);
 184
 185my $orig_branch = "";
 186my $forward_master = 0;
 187my %branches;
 188
 189my $git_dir = $ENV{"GIT_DIR"} || ".git";
 190$git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 191$ENV{"GIT_DIR"} = $git_dir;
 192my $orig_git_index;
 193$orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 194my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 195                                    DIR => File::Spec->tmpdir());
 196close ($git_ih);
 197$ENV{GIT_INDEX_FILE} = $git_index;
 198my $maxnum = 0;
 199my $last_rev = "";
 200my $last_branch;
 201my $current_rev = $opt_s-1;
 202unless(-d $git_dir) {
 203        system("git-init-db");
 204        die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 205        system("git-read-tree");
 206        die "Cannot init an empty tree: $?\n" if $?;
 207
 208        $last_branch = $opt_o;
 209        $orig_branch = "";
 210} else {
 211        -f "$git_dir/refs/heads/$opt_o"
 212                or die "Branch '$opt_o' does not exist.\n".
 213                       "Either use the correct '-o branch' option,\n".
 214                       "or import to a new repository.\n";
 215
 216        -f "$git_dir/svn2git"
 217                or die "'$git_dir/svn2git' does not exist.\n".
 218                       "You need that file for incremental imports.\n";
 219        $last_branch = basename(readlink("$git_dir/HEAD"));
 220        unless($last_branch) {
 221                warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 222                $last_branch = "master";
 223        }
 224        $orig_branch = $last_branch;
 225        $last_rev = get_headref($orig_branch, $git_dir);
 226        if (-f "$git_dir/SVN2GIT_HEAD") {
 227                die <<EOM;
 228SVN2GIT_HEAD exists.
 229Make sure your working directory corresponds to HEAD and remove SVN2GIT_HEAD.
 230You may need to run
 231
 232    git-read-tree -m -u SVN2GIT_HEAD HEAD
 233EOM
 234        }
 235        system('cp', "$git_dir/HEAD", "$git_dir/SVN2GIT_HEAD");
 236
 237        $forward_master =
 238            $opt_o ne 'master' && -f "$git_dir/refs/heads/master" &&
 239            system('cmp', '-s', "$git_dir/refs/heads/master",
 240                                "$git_dir/refs/heads/$opt_o") == 0;
 241
 242        # populate index
 243        system('git-read-tree', $last_rev);
 244        die "read-tree failed: $?\n" if $?;
 245
 246        # Get the last import timestamps
 247        open my $B,"<", "$git_dir/svn2git";
 248        while(<$B>) {
 249                chomp;
 250                my($num,$branch,$ref) = split;
 251                $branches{$branch}{$num} = $ref;
 252                $branches{$branch}{"LAST"} = $ref;
 253                $current_rev = $num if $current_rev < $num;
 254        }
 255        close($B);
 256}
 257-d $git_dir
 258        or die "Could not create git subdir ($git_dir).\n";
 259
 260open BRANCHES,">>", "$git_dir/svn2git";
 261
 262sub node_kind($$$) {
 263        my ($branch, $path, $revision) = @_;
 264        my $pool=SVN::Pool->new;
 265        my $kind = $svn->{'svn'}->check_path(revert_split_path($branch,$path),$revision,$pool);
 266        $pool->clear;
 267        return $kind;
 268}
 269
 270sub revert_split_path($$) {
 271        my($branch,$path) = @_;
 272
 273        my $svnpath;
 274        $path = "" if $path eq "/"; # this should not happen, but ...
 275        if($branch eq "/") {
 276                $svnpath = "$trunk_name/$path";
 277        } elsif($branch =~ m#^/#) {
 278                $svnpath = "$tag_name$branch/$path";
 279        } else {
 280                $svnpath = "$branch_name/$branch/$path";
 281        }
 282
 283        return $svnpath
 284}
 285
 286sub get_file($$$) {
 287        my($rev,$branch,$path) = @_;
 288
 289        my $svnpath = revert_split_path($branch,$path);
 290
 291        # now get it
 292        my $name;
 293        if($opt_d) {
 294                my($req,$res);
 295
 296                # /svn/!svn/bc/2/django/trunk/django-docs/build.py
 297                my $url=$svn_url->clone();
 298                $url->path($url->path."/!svn/bc/$rev/$svn_dir$svnpath");
 299                print "... $path...\n" if $opt_v;
 300                $req = HTTP::Request->new(GET => $url);
 301                $res = $lwp_ua->request($req);
 302                if ($res->is_success) {
 303                        my $fh;
 304                        ($fh, $name) = tempfile('gitsvn.XXXXXX',
 305                        DIR => File::Spec->tmpdir(), UNLINK => 1);
 306                        print $fh $res->content;
 307                        close($fh) or die "Could not write $name: $!\n";
 308                } else {
 309                        return undef if $res->code == 301; # directory?
 310                        die $res->status_line." at $url\n";
 311                }
 312        } else {
 313                $name = $svn->file("/$svnpath",$rev);
 314                return undef unless defined $name;
 315        }
 316
 317        open my $F, '-|', "git-hash-object", "-w", $name
 318                or die "Cannot create object: $!\n";
 319        my $sha = <$F>;
 320        chomp $sha;
 321        close $F;
 322        unlink $name;
 323        my $mode = "0644"; # SV does not seem to store any file modes
 324        return [$mode, $sha, $path];
 325}
 326
 327sub split_path($$) {
 328        my($rev,$path) = @_;
 329        my $branch;
 330
 331        if($path =~ s#^/\Q$tag_name\E/([^/]+)/?##) {
 332                $branch = "/$1";
 333        } elsif($path =~ s#^/\Q$trunk_name\E/?##) {
 334                $branch = "/";
 335        } elsif($path =~ s#^/\Q$branch_name\E/([^/]+)/?##) {
 336                $branch = $1;
 337        } else {
 338                my %no_error = (
 339                        "/" => 1,
 340                        "/$tag_name" => 1,
 341                        "/$branch_name" => 1
 342                );
 343                print STDERR "$rev: Unrecognized path: $path\n" unless (defined $no_error{$path});
 344                return ()
 345        }
 346        $path = "/" if $path eq "";
 347        return ($branch,$path);
 348}
 349
 350sub branch_rev($$) {
 351
 352        my ($srcbranch,$uptorev) = @_;
 353
 354        my $bbranches = $branches{$srcbranch};
 355        my @revs = reverse sort { ($a eq 'LAST' ? 0 : $a) <=> ($b eq 'LAST' ? 0 : $b) } keys %$bbranches;
 356        my $therev;
 357        foreach my $arev(@revs) {
 358                next if  ($arev eq 'LAST');
 359                if ($arev <= $uptorev) {
 360                        $therev = $arev;
 361                        last;
 362                }
 363        }
 364        return $therev;
 365}
 366
 367sub copy_path($$$$$$$$) {
 368        # Somebody copied a whole subdirectory.
 369        # We need to find the index entries from the old version which the
 370        # SVN log entry points to, and add them to the new place.
 371
 372        my($newrev,$newbranch,$path,$oldpath,$rev,$node_kind,$new,$parents) = @_;
 373
 374        my($srcbranch,$srcpath) = split_path($rev,$oldpath);
 375        my $therev = branch_rev($srcbranch, $rev);
 376        my $gitrev = $branches{$srcbranch}{$therev};
 377        unless($gitrev) {
 378                print STDERR "$newrev:$newbranch: could not find $oldpath \@ $rev\n";
 379                return;
 380        }
 381        if ($srcbranch ne $newbranch) {
 382                push(@$parents, $branches{$srcbranch}{'LAST'});
 383        }
 384        print "$newrev:$newbranch:$path: copying from $srcbranch:$srcpath @ $rev\n" if $opt_v;
 385        if ($node_kind eq $SVN::Node::dir) {
 386                        $srcpath =~ s#/*$#/#;
 387        }
 388        
 389        open my $f,"-|","git-ls-tree","-r","-z",$gitrev,$srcpath;
 390        local $/ = "\0";
 391        while(<$f>) {
 392                chomp;
 393                my($m,$p) = split(/\t/,$_,2);
 394                my($mode,$type,$sha1) = split(/ /,$m);
 395                next if $type ne "blob";
 396                if ($node_kind eq $SVN::Node::dir) {
 397                        $p = $path . substr($p,length($srcpath)-1);
 398                } else {
 399                        $p = $path;
 400                }
 401                push(@$new,[$mode,$sha1,$p]);   
 402        }
 403        close($f) or
 404                print STDERR "$newrev:$newbranch: could not list files in $oldpath \@ $rev\n";
 405}
 406
 407sub commit {
 408        my($branch, $changed_paths, $revision, $author, $date, $message) = @_;
 409        my($author_name,$author_email,$dest);
 410        my(@old,@new,@parents);
 411
 412        if (not defined $author) {
 413                $author_name = $author_email = "unknown";
 414        } elsif ($author =~ /^(.*?)\s+<(.*)>$/) {
 415                ($author_name, $author_email) = ($1, $2);
 416        } else {
 417                $author =~ s/^<(.*)>$/$1/;
 418                $author_name = $author_email = $author;
 419        }
 420        $date = pdate($date);
 421
 422        my $tag;
 423        my $parent;
 424        if($branch eq "/") { # trunk
 425                $parent = $opt_o;
 426        } elsif($branch =~ m#^/(.+)#) { # tag
 427                $tag = 1;
 428                $parent = $1;
 429        } else { # "normal" branch
 430                # nothing to do
 431                $parent = $branch;
 432        }
 433        $dest = $parent;
 434
 435        my $prev = $changed_paths->{"/"};
 436        if($prev and $prev->[0] eq "A") {
 437                delete $changed_paths->{"/"};
 438                my $oldpath = $prev->[1];
 439                my $rev;
 440                if(defined $oldpath) {
 441                        my $p;
 442                        ($parent,$p) = split_path($revision,$oldpath);
 443                        if($parent eq "/") {
 444                                $parent = $opt_o;
 445                        } else {
 446                                $parent =~ s#^/##; # if it's a tag
 447                        }
 448                } else {
 449                        $parent = undef;
 450                }
 451        }
 452
 453        my $rev;
 454        if($revision > $opt_s and defined $parent) {
 455                open(H,"git-rev-parse --verify $parent |");
 456                $rev = <H>;
 457                close(H) or do {
 458                        print STDERR "$revision: cannot find commit '$parent'!\n";
 459                        return;
 460                };
 461                chop $rev;
 462                if(length($rev) != 40) {
 463                        print STDERR "$revision: cannot find commit '$parent'!\n";
 464                        return;
 465                }
 466                $rev = $branches{($parent eq $opt_o) ? "/" : $parent}{"LAST"};
 467                if($revision != $opt_s and not $rev) {
 468                        print STDERR "$revision: do not know ancestor for '$parent'!\n";
 469                        return;
 470                }
 471        } else {
 472                $rev = undef;
 473        }
 474
 475#       if($prev and $prev->[0] eq "A") {
 476#               if(not $tag) {
 477#                       unless(open(H,"> $git_dir/refs/heads/$branch")) {
 478#                               print STDERR "$revision: Could not create branch $branch: $!\n";
 479#                               $state=11;
 480#                               next;
 481#                       }
 482#                       print H "$rev\n"
 483#                               or die "Could not write branch $branch: $!";
 484#                       close(H)
 485#                               or die "Could not write branch $branch: $!";
 486#               }
 487#       }
 488        if(not defined $rev) {
 489                unlink($git_index);
 490        } elsif ($rev ne $last_rev) {
 491                print "Switching from $last_rev to $rev ($branch)\n" if $opt_v;
 492                system("git-read-tree", $rev);
 493                die "read-tree failed for $rev: $?\n" if $?;
 494                $last_rev = $rev;
 495        }
 496
 497        push (@parents, $rev) if defined $rev;
 498
 499        my $cid;
 500        if($tag and not %$changed_paths) {
 501                $cid = $rev;
 502        } else {
 503                my @paths = sort keys %$changed_paths;
 504                foreach my $path(@paths) {
 505                        my $action = $changed_paths->{$path};
 506
 507                        if ($action->[0] eq "R") {
 508                                # refer to a file/tree in an earlier commit
 509                                push(@old,$path); # remove any old stuff
 510                        }
 511                        if(($action->[0] eq "A") || ($action->[0] eq "R")) {
 512                                my $node_kind = node_kind($branch,$path,$revision);
 513                                if($action->[1]) {
 514                                        copy_path($revision,$branch,$path,$action->[1],$action->[2],$node_kind,\@new,\@parents);
 515                                } elsif ($node_kind eq $SVN::Node::file) {
 516                                        my $f = get_file($revision,$branch,$path);
 517                                        if ($f) {
 518                                                push(@new,$f) if $f;
 519                                        } else {
 520                                                my $opath = $action->[3];
 521                                                print STDERR "$revision: $branch: could not fetch '$opath'\n";
 522                                        }
 523                                }
 524                        } elsif ($action->[0] eq "D") {
 525                                push(@old,$path);
 526                        } elsif ($action->[0] eq "M") {
 527                                my $node_kind = node_kind($branch,$path,$revision);
 528                                if ($node_kind eq $SVN::Node::file) {
 529                                        my $f = get_file($revision,$branch,$path);
 530                                        push(@new,$f) if $f;
 531                                }
 532                        } else {
 533                                die "$revision: unknown action '".$action->[0]."' for $path\n";
 534                        }
 535                }
 536
 537                if(@old) {
 538                        open my $F, "-|", "git-ls-files", "-z", @old or die $!;
 539                        @old = ();
 540                        local $/ = "\0";
 541                        while(<$F>) {
 542                                chomp;
 543                                push(@old,$_);
 544                        }
 545                        close($F);
 546
 547                        while(@old) {
 548                                my @o2;
 549                                if(@old > 55) {
 550                                        @o2 = splice(@old,0,50);
 551                                } else {
 552                                        @o2 = @old;
 553                                        @old = ();
 554                                }
 555                                system("git-update-index","--force-remove","--",@o2);
 556                                die "Cannot remove files: $?\n" if $?;
 557                        }
 558                }
 559                while(@new) {
 560                        my @n2;
 561                        if(@new > 12) {
 562                                @n2 = splice(@new,0,10);
 563                        } else {
 564                                @n2 = @new;
 565                                @new = ();
 566                        }
 567                        system("git-update-index","--add",
 568                                (map { ('--cacheinfo', @$_) } @n2));
 569                        die "Cannot add files: $?\n" if $?;
 570                }
 571
 572                my $pid = open(C,"-|");
 573                die "Cannot fork: $!" unless defined $pid;
 574                unless($pid) {
 575                        exec("git-write-tree");
 576                        die "Cannot exec git-write-tree: $!\n";
 577                }
 578                chomp(my $tree = <C>);
 579                length($tree) == 40
 580                        or die "Cannot get tree id ($tree): $!\n";
 581                close(C)
 582                        or die "Error running git-write-tree: $?\n";
 583                print "Tree ID $tree\n" if $opt_v;
 584
 585                my $pr = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 586                my $pw = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 587                $pid = fork();
 588                die "Fork: $!\n" unless defined $pid;
 589                unless($pid) {
 590                        $pr->writer();
 591                        $pw->reader();
 592                        open(OUT,">&STDOUT");
 593                        dup2($pw->fileno(),0);
 594                        dup2($pr->fileno(),1);
 595                        $pr->close();
 596                        $pw->close();
 597
 598                        my @par = ();
 599
 600                        # loose detection of merges
 601                        # based on the commit msg
 602                        foreach my $rx (@mergerx) {
 603                                if ($message =~ $rx) {
 604                                        my $mparent = $1;
 605                                        if ($mparent eq 'HEAD') { $mparent = $opt_o };
 606                                        if ( -e "$git_dir/refs/heads/$mparent") {
 607                                                $mparent = get_headref($mparent, $git_dir);
 608                                                push (@parents, $mparent);
 609                                                print OUT "Merge parent branch: $mparent\n" if $opt_v;
 610                                        }
 611                                }
 612                        }
 613                        my %seen_parents = ();
 614                        my @unique_parents = grep { ! $seen_parents{$_} ++ } @parents;
 615                        foreach my $bparent (@unique_parents) {
 616                                push @par, '-p', $bparent;
 617                                print OUT "Merge parent branch: $bparent\n" if $opt_v;
 618                        }
 619
 620                        exec("env",
 621                                "GIT_AUTHOR_NAME=$author_name",
 622                                "GIT_AUTHOR_EMAIL=$author_email",
 623                                "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 624                                "GIT_COMMITTER_NAME=$author_name",
 625                                "GIT_COMMITTER_EMAIL=$author_email",
 626                                "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 627                                "git-commit-tree", $tree,@par);
 628                        die "Cannot exec git-commit-tree: $!\n";
 629                }
 630                $pw->writer();
 631                $pr->reader();
 632
 633                $message =~ s/[\s\n]+\z//;
 634
 635                print $pw "$message\n"
 636                        or die "Error writing to git-commit-tree: $!\n";
 637                $pw->close();
 638
 639                print "Committed change $revision:$branch ".strftime("%Y-%m-%d %H:%M:%S",gmtime($date)).")\n" if $opt_v;
 640                chomp($cid = <$pr>);
 641                length($cid) == 40
 642                        or die "Cannot get commit id ($cid): $!\n";
 643                print "Commit ID $cid\n" if $opt_v;
 644                $pr->close();
 645
 646                waitpid($pid,0);
 647                die "Error running git-commit-tree: $?\n" if $?;
 648        }
 649
 650        if (not defined $cid) {
 651                $cid = $branches{"/"}{"LAST"};
 652        }
 653
 654        if(not defined $dest) {
 655                print "... no known parent\n" if $opt_v;
 656        } elsif(not $tag) {
 657                print "Writing to refs/heads/$dest\n" if $opt_v;
 658                open(C,">$git_dir/refs/heads/$dest") and
 659                print C ("$cid\n") and
 660                close(C)
 661                        or die "Cannot write branch $dest for update: $!\n";
 662        }
 663
 664        if($tag) {
 665                my($in, $out) = ('','');
 666                $last_rev = "-" if %$changed_paths;
 667                # the tag was 'complex', i.e. did not refer to a "real" revision
 668
 669                $dest =~ tr/_/\./ if $opt_u;
 670                $branch = $dest;
 671
 672                my $pid = open2($in, $out, 'git-mktag');
 673                print $out ("object $cid\n".
 674                    "type commit\n".
 675                    "tag $dest\n".
 676                    "tagger $author_name <$author_email>\n") and
 677                close($out)
 678                    or die "Cannot create tag object $dest: $!\n";
 679
 680                my $tagobj = <$in>;
 681                chomp $tagobj;
 682
 683                if ( !close($in) or waitpid($pid, 0) != $pid or
 684                                $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 685                        die "Cannot create tag object $dest: $!\n";
 686                }
 687
 688                open(C,">$git_dir/refs/tags/$dest") and
 689                print C ("$tagobj\n") and
 690                close(C)
 691                        or die "Cannot create tag $branch: $!\n";
 692
 693                print "Created tag '$dest' on '$branch'\n" if $opt_v;
 694        }
 695        $branches{$branch}{"LAST"} = $cid;
 696        $branches{$branch}{$revision} = $cid;
 697        $last_rev = $cid;
 698        print BRANCHES "$revision $branch $cid\n";
 699        print "DONE: $revision $dest $cid\n" if $opt_v;
 700}
 701
 702my ($changed_paths, $revision, $author, $date, $message, $pool) = @_;
 703sub _commit_all {
 704        ($changed_paths, $revision, $author, $date, $message, $pool) = @_;
 705        my %p;
 706        while(my($path,$action) = each %$changed_paths) {
 707                $p{$path} = [ $action->action,$action->copyfrom_path, $action->copyfrom_rev, $path ];
 708        }
 709        $changed_paths = \%p;
 710}
 711
 712sub commit_all {
 713        my %done;
 714        my @col;
 715        my $pref;
 716        my $branch;
 717
 718        while(my($path,$action) = each %$changed_paths) {
 719                ($branch,$path) = split_path($revision,$path);
 720                next if not defined $branch;
 721                $done{$branch}{$path} = $action;
 722        }
 723        while(($branch,$changed_paths) = each %done) {
 724                commit($branch, $changed_paths, $revision, $author, $date, $message);
 725        }
 726}
 727
 728while(++$current_rev <= $svn->{'maxrev'}) {
 729        if (defined $opt_l) {
 730                $opt_l--;
 731                if ($opt_l < 0) {
 732                        last;
 733                }
 734        }
 735        my $pool=SVN::Pool->new;
 736        $svn->{'svn'}->get_log("/",$current_rev,$current_rev,1,1,1,\&_commit_all,$pool);
 737        $pool->clear;
 738        commit_all();
 739}
 740
 741
 742unlink($git_index);
 743
 744if (defined $orig_git_index) {
 745        $ENV{GIT_INDEX_FILE} = $orig_git_index;
 746} else {
 747        delete $ENV{GIT_INDEX_FILE};
 748}
 749
 750# Now switch back to the branch we were in before all of this happened
 751if($orig_branch) {
 752        print "DONE\n" if $opt_v and (not defined $opt_l or $opt_l > 0);
 753        system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 754                if $forward_master;
 755        unless ($opt_i) {
 756                system('git-read-tree', '-m', '-u', 'SVN2GIT_HEAD', 'HEAD');
 757                die "read-tree failed: $?\n" if $?;
 758        }
 759} else {
 760        $orig_branch = "master";
 761        print "DONE; creating $orig_branch branch\n" if $opt_v and (not defined $opt_l or $opt_l > 0);
 762        system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 763                unless -f "$git_dir/refs/heads/master";
 764        unlink("$git_dir/HEAD");
 765        symlink("refs/heads/$orig_branch","$git_dir/HEAD");
 766        unless ($opt_i) {
 767                system('git checkout');
 768                die "checkout failed: $?\n" if $?;
 769        }
 770}
 771unlink("$git_dir/SVN2GIT_HEAD");
 772close(BRANCHES);