Andrew's git / gitweb.git /
74d0af52a5d4f2443a49e16127bab652daa80697
   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_ERROR([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  47                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  48        fi; \
  49fi; \
  50]) # GIT_CONF_APPEND_PATH
  51#
  52# GIT_PARSE_WITH(PACKAGE)
  53# -----------------------
  54# For use in AC_ARG_WITH action-if-found, for packages default ON.
  55# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  56# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  57# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  58AC_DEFUN([GIT_PARSE_WITH],
  59[PACKAGE=m4_toupper($1); \
  60if test "$withval" = "no"; then \
  61        m4_toupper(NO_$1)=YesPlease; \
  62elif test "$withval" = "yes"; then \
  63        m4_toupper(NO_$1)=; \
  64else \
  65        m4_toupper(NO_$1)=; \
  66        m4_toupper($1)DIR=$withval; \
  67        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  68        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  69fi \
  70])# GIT_PARSE_WITH
  71
  72dnl
  73dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
  74dnl -----------------------------------------
  75dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
  76dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
  77dnl -Wall), it does not work.  By looking for function definition in
  78dnl libraries, this problem can be worked around.
  79AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
  80  AC_SEARCH_LIBS([$1],,
  81  [$2],[$3])
  82],[$3])])
  83
  84dnl
  85dnl GIT_STASH_FLAGS(BASEPATH_VAR)
  86dnl -----------------------------
  87dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
  88dnl tests that may want to take user settings into account.
  89AC_DEFUN([GIT_STASH_FLAGS],[
  90if test -n "$1"; then
  91   old_CPPFLAGS="$CPPFLAGS"
  92   old_LDFLAGS="$LDFLAGS"
  93   CPPFLAGS="-I$1/include $CPPFLAGS"
  94   LDFLAGS="-L$1/$lib $LDFLAGS"
  95fi
  96])
  97
  98dnl
  99dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 100dnl -----------------------------
 101dnl Restore the stashed *FLAGS values.
 102AC_DEFUN([GIT_UNSTASH_FLAGS],[
 103if test -n "$1"; then
 104   CPPFLAGS="$old_CPPFLAGS"
 105   LDFLAGS="$old_LDFLAGS"
 106fi
 107])
 108
 109## Site configuration related to programs (before tests)
 110## --with-PACKAGE[=ARG] and --without-PACKAGE
 111#
 112# Set lib to alternative name of lib directory (e.g. lib64)
 113AC_ARG_WITH([lib],
 114 [AS_HELP_STRING([--with-lib=ARG],
 115                 [ARG specifies alternative name for lib directory])],
 116 [if test "$withval" = "no" || test "$withval" = "yes"; then \
 117        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 118else \
 119        lib=$withval; \
 120        AC_MSG_NOTICE([Setting lib to '$lib']); \
 121        GIT_CONF_APPEND_LINE(lib=$withval); \
 122fi; \
 123],[])
 124
 125if test -z "$lib"; then
 126   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 127   lib=lib
 128fi
 129
 130AC_ARG_ENABLE([pthreads],
 131 [AS_HELP_STRING([--enable-pthreads=FLAGS],
 132  [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 133  [The default if FLAGS is not specified is to try first -pthread]
 134  [and then -lpthread.]
 135  [--without-pthreads will disable threading.])],
 136[
 137if test "x$enableval" = "xyes"; then
 138   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 139elif test "x$enableval" != "xno"; then
 140   PTHREAD_CFLAGS=$enableval
 141   AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 142else
 143   AC_MSG_NOTICE([POSIX Threads will be disabled.])
 144   NO_PTHREADS=YesPlease
 145   USER_NOPTHREAD=1
 146fi],
 147[
 148   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 149])
 150
 151## Site configuration (override autodetection)
 152## --with-PACKAGE[=ARG] and --without-PACKAGE
 153AC_MSG_NOTICE([CHECKS for site configuration])
 154#
 155# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 156# tests.  These tests take up a significant amount of the total test time
 157# but are not needed unless you plan to talk to SVN repos.
 158#
 159# Define MOZILLA_SHA1 environment variable when running make to make use of
 160# a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 161# on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 162# choice) has very fast version optimized for i586.
 163#
 164# Define PPC_SHA1 environment variable when running make to make use of
 165# a bundled SHA1 routine optimized for PowerPC.
 166#
 167# Define ARM_SHA1 environment variable when running make to make use of
 168# a bundled SHA1 routine optimized for ARM.
 169#
 170# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 171# This also implies MOZILLA_SHA1.
 172#
 173# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 174# /foo/bar/include and /foo/bar/lib directories.
 175AC_ARG_WITH(openssl,
 176AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 177AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 178GIT_PARSE_WITH(openssl))
 179#
 180# Define NO_CURL if you do not have curl installed.  git-http-pull and
 181# git-http-push are not built, and you cannot use http:// and https://
 182# transports.
 183#
 184# Define CURLDIR=/foo/bar if your curl header and library files are in
 185# /foo/bar/include and /foo/bar/lib directories.
 186AC_ARG_WITH(curl,
 187AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 188AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 189GIT_PARSE_WITH(curl))
 190#
 191# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 192# not built, and you cannot push using http:// and https:// transports.
 193#
 194# Define EXPATDIR=/foo/bar if your expat header and library files are in
 195# /foo/bar/include and /foo/bar/lib directories.
 196AC_ARG_WITH(expat,
 197AS_HELP_STRING([--with-expat],
 198[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 199AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 200GIT_PARSE_WITH(expat))
 201#
 202# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 203# installed in /sw, but don't want GIT to link against any libraries
 204# installed there.  If defined you may specify your own (or Fink's)
 205# include directories and library directories by defining CFLAGS
 206# and LDFLAGS appropriately.
 207#
 208# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 209# have DarwinPorts installed in /opt/local, but don't want GIT to
 210# link against any libraries installed there.  If defined you may
 211# specify your own (or DarwinPort's) include directories and
 212# library directories by defining CFLAGS and LDFLAGS appropriately.
 213#
 214# Define NO_MMAP if you want to avoid mmap.
 215#
 216# Define NO_ICONV if your libc does not properly support iconv.
 217AC_ARG_WITH(iconv,
 218AS_HELP_STRING([--without-iconv],
 219[if your architecture doesn't properly support iconv])
 220AS_HELP_STRING([--with-iconv=PATH],
 221[PATH is prefix for libiconv library and headers])
 222AS_HELP_STRING([],
 223[used only if you need linking with libiconv]),
 224GIT_PARSE_WITH(iconv))
 225
 226## --enable-FEATURE[=ARG] and --disable-FEATURE
 227#
 228# Define USE_NSEC below if you want git to care about sub-second file mtimes
 229# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 230# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 231# randomly break unless your underlying filesystem supports those sub-second
 232# times (my ext3 doesn't).
 233#
 234# Define USE_STDEV below if you want git to care about the underlying device
 235# change being considered an inode change from the update-index perspective.
 236
 237#
 238# Define SHELL_PATH to provide path to shell.
 239GIT_ARG_SET_PATH(shell)
 240#
 241# Define PERL_PATH to provide path to Perl.
 242GIT_ARG_SET_PATH(perl)
 243#
 244# Define ZLIB_PATH to provide path to zlib.
 245GIT_ARG_SET_PATH(zlib)
 246#
 247# Declare the with-tcltk/without-tcltk options.
 248AC_ARG_WITH(tcltk,
 249AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 250AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 251AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 252AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 253GIT_PARSE_WITH(tcltk))
 254#
 255
 256
 257## Checks for programs.
 258AC_MSG_NOTICE([CHECKS for programs])
 259#
 260AC_PROG_CC([cc gcc])
 261# which switch to pass runtime path to dynamic libraries to the linker
 262AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 263   SAVE_LDFLAGS="${LDFLAGS}"
 264   LDFLAGS="${SAVE_LDFLAGS} -R /"
 265   AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 266   LDFLAGS="${SAVE_LDFLAGS}"
 267])
 268if test "$git_cv_ld_dashr" = "yes"; then
 269   AC_SUBST(CC_LD_DYNPATH, [-R])
 270else
 271   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 272      SAVE_LDFLAGS="${LDFLAGS}"
 273      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 274      AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 275      LDFLAGS="${SAVE_LDFLAGS}"
 276   ])
 277   if test "$git_cv_ld_wl_rpath" = "yes"; then
 278      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 279   else
 280      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 281         SAVE_LDFLAGS="${LDFLAGS}"
 282         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 283         AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 284         LDFLAGS="${SAVE_LDFLAGS}"
 285      ])
 286      if test "$git_cv_ld_rpath" = "yes"; then
 287         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 288      else
 289         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 290      fi
 291   fi
 292fi
 293#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 294AC_CHECK_TOOLS(AR, [gar ar], :)
 295AC_CHECK_PROGS(TAR, [gtar tar])
 296# TCLTK_PATH will be set to some value if we want Tcl/Tk
 297# or will be empty otherwise.
 298if test -z "$NO_TCLTK"; then
 299  if test "$with_tcltk" = ""; then
 300  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 301    TCLTK_PATH=wish
 302    AC_SUBST(TCLTK_PATH)
 303  elif test "$with_tcltk" = "yes"; then
 304  # Tcl/Tk check requested.
 305    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 306  else
 307    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 308    TCLTK_PATH="$with_tcltk"
 309    AC_SUBST(TCLTK_PATH)
 310  fi
 311fi
 312AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 313if test -n "$ASCIIDOC"; then
 314        AC_MSG_CHECKING([for asciidoc version])
 315        asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 316        case "${asciidoc_version}" in
 317        asciidoc' '8*)
 318                ASCIIDOC8=YesPlease
 319                AC_MSG_RESULT([${asciidoc_version} > 7])
 320                ;;
 321        asciidoc' '7*)
 322                ASCIIDOC8=
 323                AC_MSG_RESULT([${asciidoc_version}])
 324                ;;
 325        *)
 326                ASCIIDOC8=
 327                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 328                ;;
 329        esac
 330fi
 331AC_SUBST(ASCIIDOC8)
 332
 333
 334## Checks for libraries.
 335AC_MSG_NOTICE([CHECKS for libraries])
 336#
 337# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 338# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 339
 340GIT_STASH_FLAGS($OPENSSLDIR)
 341
 342AC_CHECK_LIB([crypto], [SHA1_Init],
 343[NEEDS_SSL_WITH_CRYPTO=],
 344[AC_CHECK_LIB([ssl], [SHA1_Init],
 345 [NEEDS_SSL_WITH_CRYPTO=YesPlease
 346  NEEDS_SSL_WITH_CRYPTO=],
 347 [NO_OPENSSL=YesPlease])])
 348
 349GIT_UNSTASH_FLAGS($OPENSSLDIR)
 350
 351AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 352AC_SUBST(NO_OPENSSL)
 353
 354#
 355# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 356# git-http-push are not built, and you cannot use http:// and https://
 357# transports.
 358
 359GIT_STASH_FLAGS($CURLDIR)
 360
 361AC_CHECK_LIB([curl], [curl_global_init],
 362[NO_CURL=],
 363[NO_CURL=YesPlease])
 364
 365GIT_UNSTASH_FLAGS($CURLDIR)
 366
 367AC_SUBST(NO_CURL)
 368
 369#
 370# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 371# not built, and you cannot push using http:// and https:// transports.
 372
 373GIT_STASH_FLAGS($EXPATDIR)
 374
 375AC_CHECK_LIB([expat], [XML_ParserCreate],
 376[NO_EXPAT=],
 377[NO_EXPAT=YesPlease])
 378
 379GIT_UNSTASH_FLAGS($EXPATDIR)
 380
 381AC_SUBST(NO_EXPAT)
 382
 383#
 384# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 385# some Solaris installations).
 386# Define NO_ICONV if neither libc nor libiconv support iconv.
 387
 388if test -z "$NO_ICONV"; then
 389
 390GIT_STASH_FLAGS($ICONVDIR)
 391
 392AC_DEFUN([ICONVTEST_SRC], [
 393#include <iconv.h>
 394
 395int main(void)
 396{
 397        iconv_open("", "");
 398        return 0;
 399}
 400])
 401
 402if test -n "$ICONVDIR"; then
 403   lib_order="-liconv -lc"
 404else
 405   lib_order="-lc -liconv"
 406fi
 407
 408NO_ICONV=YesPlease
 409
 410for l in $lib_order; do
 411    if test "$l" = "-liconv"; then
 412       NEEDS_LIBICONV=YesPlease
 413    else
 414       NEEDS_LIBICONV=
 415    fi
 416
 417    old_LIBS="$LIBS"
 418    LIBS="$LIBS $l"
 419    AC_MSG_CHECKING([for iconv in $l])
 420    AC_LINK_IFELSE(ICONVTEST_SRC,
 421        [AC_MSG_RESULT([yes])
 422        NO_ICONV=
 423        break],
 424        [AC_MSG_RESULT([no])])
 425    LIBS="$old_LIBS"
 426done
 427
 428#in case of break
 429LIBS="$old_LIBS"
 430
 431GIT_UNSTASH_FLAGS($ICONVDIR)
 432
 433AC_SUBST(NEEDS_LIBICONV)
 434AC_SUBST(NO_ICONV)
 435
 436if test -n "$NO_ICONV"; then
 437    NEEDS_LIBICONV=
 438fi
 439
 440fi
 441
 442#
 443# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 444
 445GIT_STASH_FLAGS($ZLIB_PATH)
 446
 447AC_DEFUN([ZLIBTEST_SRC], [
 448#include <zlib.h>
 449
 450int main(void)
 451{
 452        deflateBound(0, 0);
 453        return 0;
 454}
 455])
 456AC_MSG_CHECKING([for deflateBound in -lz])
 457old_LIBS="$LIBS"
 458LIBS="$LIBS -lz"
 459AC_LINK_IFELSE(ZLIBTEST_SRC,
 460        [AC_MSG_RESULT([yes])],
 461        [AC_MSG_RESULT([no])
 462        NO_DEFLATE_BOUND=yes])
 463LIBS="$old_LIBS"
 464
 465GIT_UNSTASH_FLAGS($ZLIB_PATH)
 466
 467AC_SUBST(NO_DEFLATE_BOUND)
 468
 469#
 470# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 471# Patrick Mauritz).
 472AC_CHECK_LIB([c], [socket],
 473[NEEDS_SOCKET=],
 474[NEEDS_SOCKET=YesPlease])
 475AC_SUBST(NEEDS_SOCKET)
 476test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 477
 478#
 479# Define NEEDS_RESOLV if linking with -lnsl and/or -lsocket is not enough.
 480# Notably on Solaris hstrerror resides in libresolv and on Solaris 7
 481# inet_ntop and inet_pton additionally reside there.
 482AC_CHECK_LIB([resolv], [hstrerror],
 483[NEEDS_RESOLV=],
 484[NEEDS_RESOLV=YesPlease])
 485AC_SUBST(NEEDS_RESOLV)
 486test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 487
 488AC_CHECK_LIB([gen], [basename],
 489[NEEDS_LIBGEN=],
 490[NEEDS_LIBGEN=YesPlease])
 491AC_SUBST(NEEDS_LIBGEN)
 492test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 493
 494## Checks for header files.
 495AC_MSG_NOTICE([CHECKS for header files])
 496#
 497# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 498AC_CHECK_HEADER([sys/select.h],
 499[NO_SYS_SELECT_H=],
 500[NO_SYS_SELECT_H=UnfortunatelyYes])
 501AC_SUBST(NO_SYS_SELECT_H)
 502#
 503# Define OLD_ICONV if your library has an old iconv(), where the second
 504# (input buffer pointer) parameter is declared with type (const char **).
 505AC_DEFUN([OLDICONVTEST_SRC], [[
 506#include <iconv.h>
 507
 508extern size_t iconv(iconv_t cd,
 509                    char **inbuf, size_t *inbytesleft,
 510                    char **outbuf, size_t *outbytesleft);
 511
 512int main(void)
 513{
 514        return 0;
 515}
 516]])
 517
 518GIT_STASH_FLAGS($ICONVDIR)
 519
 520AC_MSG_CHECKING([for old iconv()])
 521AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 522        [AC_MSG_RESULT([no])],
 523        [AC_MSG_RESULT([yes])
 524        OLD_ICONV=UnfortunatelyYes])
 525
 526GIT_UNSTASH_FLAGS($ICONVDIR)
 527
 528AC_SUBST(OLD_ICONV)
 529
 530## Checks for typedefs, structures, and compiler characteristics.
 531AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 532#
 533# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 534AC_CHECK_MEMBER(struct dirent.d_ino,
 535[NO_D_INO_IN_DIRENT=],
 536[NO_D_INO_IN_DIRENT=YesPlease],
 537[#include <dirent.h>])
 538AC_SUBST(NO_D_INO_IN_DIRENT)
 539#
 540# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 541# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 542AC_CHECK_MEMBER(struct dirent.d_type,
 543[NO_D_TYPE_IN_DIRENT=],
 544[NO_D_TYPE_IN_DIRENT=YesPlease],
 545[#include <dirent.h>])
 546AC_SUBST(NO_D_TYPE_IN_DIRENT)
 547#
 548# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 549# sockaddr_storage.
 550AC_CHECK_TYPE(struct sockaddr_storage,
 551[NO_SOCKADDR_STORAGE=],
 552[NO_SOCKADDR_STORAGE=YesPlease],[
 553#include <sys/types.h>
 554#include <sys/socket.h>
 555])
 556AC_SUBST(NO_SOCKADDR_STORAGE)
 557#
 558# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 559AC_CHECK_TYPE([struct addrinfo],[
 560 GIT_CHECK_FUNC([getaddrinfo],
 561  [NO_IPV6=],
 562  [NO_IPV6=YesPlease])
 563],[NO_IPV6=YesPlease],[
 564#include <sys/types.h>
 565#include <sys/socket.h>
 566#include <netdb.h>
 567])
 568AC_SUBST(NO_IPV6)
 569#
 570# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 571# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 572# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 573# some C compilers supported these specifiers prior to C99 as an extension.
 574AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 575 [ac_cv_c_c99_format],
 576[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 577AC_RUN_IFELSE(
 578        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 579                [[char buf[64];
 580                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 581                  return 1;
 582                else if (strcmp(buf, "12345"))
 583                  return 2;]])],
 584        [ac_cv_c_c99_format=yes],
 585        [ac_cv_c_c99_format=no])
 586])
 587if test $ac_cv_c_c99_format = no; then
 588        NO_C99_FORMAT=YesPlease
 589else
 590        NO_C99_FORMAT=
 591fi
 592AC_SUBST(NO_C99_FORMAT)
 593#
 594# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 595# when attempting to read from an fopen'ed directory.
 596AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 597 [ac_cv_fread_reads_directories],
 598[
 599AC_RUN_IFELSE(
 600        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 601                [[char c;
 602                FILE *f = fopen(".", "r");
 603                return f && fread(&c, 1, 1, f)]])],
 604        [ac_cv_fread_reads_directories=no],
 605        [ac_cv_fread_reads_directories=yes])
 606])
 607if test $ac_cv_fread_reads_directories = yes; then
 608        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 609else
 610        FREAD_READS_DIRECTORIES=
 611fi
 612AC_SUBST(FREAD_READS_DIRECTORIES)
 613#
 614# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 615# or vsnprintf() return -1 instead of number of characters which would
 616# have been written to the final string if enough space had been available.
 617AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 618 [ac_cv_snprintf_returns_bogus],
 619[
 620AC_RUN_IFELSE(
 621        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 622                #include "stdarg.h"
 623
 624                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 625                {
 626                  int ret;
 627                  va_list ap;
 628                  va_start(ap, format);
 629                  ret = vsnprintf(str, maxsize, format, ap);
 630                  va_end(ap);
 631                  return ret;
 632                }],
 633                [[char buf[6];
 634                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 635                      || strcmp(buf, "12")) return 1;
 636                  if (snprintf(buf, 3, "%s", "12345") != 5
 637                      || strcmp(buf, "12")) return 1]])],
 638        [ac_cv_snprintf_returns_bogus=no],
 639        [ac_cv_snprintf_returns_bogus=yes])
 640])
 641if test $ac_cv_snprintf_returns_bogus = yes; then
 642        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 643else
 644        SNPRINTF_RETURNS_BOGUS=
 645fi
 646AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 647
 648
 649## Checks for library functions.
 650## (in default C library and libraries checked by AC_CHECK_LIB)
 651AC_MSG_NOTICE([CHECKS for library functions])
 652#
 653# Define NO_LIBGEN_H if you don't have libgen.h.
 654AC_CHECK_HEADER([libgen.h],
 655[NO_LIBGEN_H=],
 656[NO_LIBGEN_H=YesPlease])
 657AC_SUBST(NO_LIBGEN_H)
 658#
 659# Define NO_STRCASESTR if you don't have strcasestr.
 660GIT_CHECK_FUNC(strcasestr,
 661[NO_STRCASESTR=],
 662[NO_STRCASESTR=YesPlease])
 663AC_SUBST(NO_STRCASESTR)
 664#
 665# Define NO_MEMMEM if you don't have memmem.
 666GIT_CHECK_FUNC(memmem,
 667[NO_MEMMEM=],
 668[NO_MEMMEM=YesPlease])
 669AC_SUBST(NO_MEMMEM)
 670#
 671# Define NO_STRLCPY if you don't have strlcpy.
 672GIT_CHECK_FUNC(strlcpy,
 673[NO_STRLCPY=],
 674[NO_STRLCPY=YesPlease])
 675AC_SUBST(NO_STRLCPY)
 676#
 677# Define NO_UINTMAX_T if your platform does not have uintmax_t
 678AC_CHECK_TYPE(uintmax_t,
 679[NO_UINTMAX_T=],
 680[NO_UINTMAX_T=YesPlease],[
 681#include <inttypes.h>
 682])
 683AC_SUBST(NO_UINTMAX_T)
 684#
 685# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 686GIT_CHECK_FUNC(strtoumax,
 687[NO_STRTOUMAX=],
 688[NO_STRTOUMAX=YesPlease])
 689AC_SUBST(NO_STRTOUMAX)
 690#
 691# Define NO_SETENV if you don't have setenv in the C library.
 692GIT_CHECK_FUNC(setenv,
 693[NO_SETENV=],
 694[NO_SETENV=YesPlease])
 695AC_SUBST(NO_SETENV)
 696#
 697# Define NO_UNSETENV if you don't have unsetenv in the C library.
 698GIT_CHECK_FUNC(unsetenv,
 699[NO_UNSETENV=],
 700[NO_UNSETENV=YesPlease])
 701AC_SUBST(NO_UNSETENV)
 702#
 703# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 704GIT_CHECK_FUNC(mkdtemp,
 705[NO_MKDTEMP=],
 706[NO_MKDTEMP=YesPlease])
 707AC_SUBST(NO_MKDTEMP)
 708#
 709# Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 710GIT_CHECK_FUNC(mkstemps,
 711[NO_MKSTEMPS=],
 712[NO_MKSTEMPS=YesPlease])
 713AC_SUBST(NO_MKSTEMPS)
 714#
 715#
 716# Define NO_MMAP if you want to avoid mmap.
 717#
 718# Define NO_ICONV if your libc does not properly support iconv.
 719
 720
 721## Other checks.
 722# Define USE_PIC if you need the main git objects to be built with -fPIC
 723# in order to build and link perl/Git.so.  x86-64 seems to need this.
 724#
 725# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 726# Enable it on Windows.  By default, symrefs are still used.
 727#
 728# Define NO_PTHREADS if we do not have pthreads
 729#
 730# Define PTHREAD_LIBS to the linker flag used for Pthread support and define
 731# THREADED_DELTA_SEARCH if Pthreads are available.
 732AC_DEFUN([PTHREADTEST_SRC], [
 733#include <pthread.h>
 734
 735int main(void)
 736{
 737        pthread_mutex_t test_mutex;
 738        return (0);
 739}
 740])
 741
 742dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 743dnl   [[#include <pthread.h>]],
 744dnl   [[pthread_mutex_t test_mutex;]]
 745dnl )])
 746
 747NO_PTHREADS=UnfortunatelyYes
 748THREADED_DELTA_SEARCH=
 749PTHREAD_LIBS=
 750
 751if test -n "$USER_NOPTHREAD"; then
 752   AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 753# handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 754# -D_REENTRANT' or some such.
 755elif test -z "$PTHREAD_CFLAGS"; then
 756  for opt in -pthread -lpthread; do
 757     old_CFLAGS="$CFLAGS"
 758     CFLAGS="$opt $CFLAGS"
 759     AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 760     AC_LINK_IFELSE(PTHREADTEST_SRC,
 761        [AC_MSG_RESULT([yes])
 762                NO_PTHREADS=
 763                PTHREAD_LIBS="$opt"
 764                THREADED_DELTA_SEARCH=YesPlease
 765                break
 766        ],
 767        [AC_MSG_RESULT([no])])
 768      CFLAGS="$old_CFLAGS"
 769  done
 770else
 771  old_CFLAGS="$CFLAGS"
 772  CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 773  AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 774  AC_LINK_IFELSE(PTHREADTEST_SRC,
 775        [AC_MSG_RESULT([yes])
 776                NO_PTHREADS=
 777                PTHREAD_LIBS="$PTHREAD_CFLAGS"
 778                THREADED_DELTA_SEARCH=YesPlease
 779        ],
 780        [AC_MSG_RESULT([no])])
 781
 782  CFLAGS="$old_CFLAGS"
 783fi
 784
 785CFLAGS="$old_CFLAGS"
 786
 787AC_SUBST(PTHREAD_LIBS)
 788AC_SUBST(NO_PTHREADS)
 789AC_SUBST(THREADED_DELTA_SEARCH)
 790
 791## Output files
 792AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 793AC_OUTPUT
 794
 795
 796## Cleanup
 797rm -f "${config_append}"