1# git-gui blame viewer
2# Copyright (C) 2006, 2007 Shawn Pearce
3class blame {
5image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
7# Persistant data (survives loads)
9#
10field history {}; # viewer history: {commit path}
11field header ; # array commit,key -> header field
12# Tk UI control paths
14#
15field w ; # top window in this viewer
16field w_back ; # our back button
17field w_path ; # label showing the current file path
18field w_columns ; # list of all column widgets in the viewer
19field w_line ; # text column: all line numbers
20field w_amov ; # text column: annotations + move tracking
21field w_asim ; # text column: annotations (simple computation)
22field w_file ; # text column: actual file data
23field w_cviewer ; # pane showing commit message
24field status ; # status mega-widget instance
25field old_height ; # last known height of $w.file_pane
26# Tk UI colors
28#
29variable active_color #c0edc5
30variable group_colors {
31 #d6d6d6
32 #e1e1e1
33 #ececec
34}
35# Current blame data; cleared/reset on each load
37#
38field commit ; # input commit to blame
39field path ; # input filename to view in $commit
40field current_fd {} ; # background process running
42field highlight_line -1 ; # current line selected
43field highlight_column {} ; # current commit column selected
44field highlight_commit {} ; # sha1 of commit selected
45field total_lines 0 ; # total length of file
47field blame_lines 0 ; # number of lines computed
48field amov_data ; # list of {commit origfile origline}
49field asim_data ; # list of {commit origfile origline}
50field r_commit ; # commit currently being parsed
52field r_orig_line ; # original line number
53field r_final_line ; # final line number
54field r_line_count ; # lines in this region
55field tooltip_wm {} ; # Current tooltip toplevel, if open
57field tooltip_t {} ; # Text widget in $tooltip_wm
58field tooltip_timer {} ; # Current timer event for our tooltip
59field tooltip_commit {} ; # Commit(s) in tooltip
60constructor new {i_commit i_path} {
62 global cursor_ptr
63 variable active_color
64 variable group_colors
65 set commit $i_commit
67 set path $i_path
68 make_toplevel top w
70 wm title $top [append "[appname] ([reponame]): " [mc "File Viewer"]]
71 frame $w.header -background gold
73 label $w.header.commit_l \
74 -text [mc "Commit:"] \
75 -background gold \
76 -foreground black \
77 -anchor w \
78 -justify left
79 set w_back $w.header.commit_b
80 label $w_back \
81 -image ::blame::img_back_arrow \
82 -borderwidth 0 \
83 -relief flat \
84 -state disabled \
85 -background gold \
86 -foreground black \
87 -activebackground gold
88 bind $w_back <Button-1> "
89 if {\[$w_back cget -state\] eq {normal}} {
90 [cb _history_menu]
91 }
92 "
93 label $w.header.commit \
94 -textvariable @commit \
95 -background gold \
96 -foreground black \
97 -anchor w \
98 -justify left
99 label $w.header.path_l \
100 -text [mc "File:"] \
101 -background gold \
102 -foreground black \
103 -anchor w \
104 -justify left
105 set w_path $w.header.path
106 label $w_path \
107 -background gold \
108 -foreground black \
109 -anchor w \
110 -justify left
111 pack $w.header.commit_l -side left
112 pack $w_back -side left
113 pack $w.header.commit -side left
114 pack $w_path -fill x -side right
115 pack $w.header.path_l -side right
116 panedwindow $w.file_pane -orient vertical
118 frame $w.file_pane.out
119 frame $w.file_pane.cm
120 $w.file_pane add $w.file_pane.out \
121 -sticky nsew \
122 -minsize 100 \
123 -height 100 \
124 -width 100
125 $w.file_pane add $w.file_pane.cm \
126 -sticky nsew \
127 -minsize 25 \
128 -height 25 \
129 -width 100
130 set w_line $w.file_pane.out.linenumber_t
132 text $w_line \
133 -takefocus 0 \
134 -highlightthickness 0 \
135 -padx 0 -pady 0 \
136 -background white \
137 -foreground black \
138 -borderwidth 0 \
139 -state disabled \
140 -wrap none \
141 -height 40 \
142 -width 6 \
143 -font font_diff
144 $w_line tag conf linenumber -justify right -rmargin 5
145 set w_amov $w.file_pane.out.amove_t
147 text $w_amov \
148 -takefocus 0 \
149 -highlightthickness 0 \
150 -padx 0 -pady 0 \
151 -background white \
152 -foreground black \
153 -borderwidth 0 \
154 -state disabled \
155 -wrap none \
156 -height 40 \
157 -width 5 \
158 -font font_diff
159 $w_amov tag conf author_abbr -justify right -rmargin 5
160 $w_amov tag conf curr_commit
161 $w_amov tag conf prior_commit -foreground blue -underline 1
162 $w_amov tag bind prior_commit \
163 <Button-1> \
164 "[cb _load_commit $w_amov @amov_data @%x,%y];break"
165 set w_asim $w.file_pane.out.asimple_t
167 text $w_asim \
168 -takefocus 0 \
169 -highlightthickness 0 \
170 -padx 0 -pady 0 \
171 -background white \
172 -foreground black \
173 -borderwidth 0 \
174 -state disabled \
175 -wrap none \
176 -height 40 \
177 -width 4 \
178 -font font_diff
179 $w_asim tag conf author_abbr -justify right
180 $w_asim tag conf curr_commit
181 $w_asim tag conf prior_commit -foreground blue -underline 1
182 $w_asim tag bind prior_commit \
183 <Button-1> \
184 "[cb _load_commit $w_asim @asim_data @%x,%y];break"
185 set w_file $w.file_pane.out.file_t
187 text $w_file \
188 -takefocus 0 \
189 -highlightthickness 0 \
190 -padx 0 -pady 0 \
191 -background white \
192 -foreground black \
193 -borderwidth 0 \
194 -state disabled \
195 -wrap none \
196 -height 40 \
197 -width 80 \
198 -xscrollcommand [list $w.file_pane.out.sbx set] \
199 -font font_diff
200 set w_columns [list $w_amov $w_asim $w_line $w_file]
202 scrollbar $w.file_pane.out.sbx \
204 -orient h \
205 -command [list $w_file xview]
206 scrollbar $w.file_pane.out.sby \
207 -orient v \
208 -command [list scrollbar2many $w_columns yview]
209 eval grid $w_columns $w.file_pane.out.sby -sticky nsew
210 grid conf \
211 $w.file_pane.out.sbx \
212 -column [expr {[llength $w_columns] - 1}] \
213 -sticky we
214 grid columnconfigure \
215 $w.file_pane.out \
216 [expr {[llength $w_columns] - 1}] \
217 -weight 1
218 grid rowconfigure $w.file_pane.out 0 -weight 1
219 set w_cviewer $w.file_pane.cm.t
221 text $w_cviewer \
222 -background white \
223 -foreground black \
224 -borderwidth 0 \
225 -state disabled \
226 -wrap none \
227 -height 10 \
228 -width 80 \
229 -xscrollcommand [list $w.file_pane.cm.sbx set] \
230 -yscrollcommand [list $w.file_pane.cm.sby set] \
231 -font font_diff
232 $w_cviewer tag conf still_loading \
233 -font font_uiitalic \
234 -justify center
235 $w_cviewer tag conf header_key \
236 -tabs {3c} \
237 -background $active_color \
238 -font font_uibold
239 $w_cviewer tag conf header_val \
240 -background $active_color \
241 -font font_ui
242 $w_cviewer tag raise sel
243 scrollbar $w.file_pane.cm.sbx \
244 -orient h \
245 -command [list $w_cviewer xview]
246 scrollbar $w.file_pane.cm.sby \
247 -orient v \
248 -command [list $w_cviewer yview]
249 pack $w.file_pane.cm.sby -side right -fill y
250 pack $w.file_pane.cm.sbx -side bottom -fill x
251 pack $w_cviewer -expand 1 -fill both
252 set status [::status_bar::new $w.status]
254 menu $w.ctxm -tearoff 0
256 $w.ctxm add command \
257 -label [mc "Copy Commit"] \
258 -command [cb _copycommit]
259 $w.ctxm add command \
260 -label [mc "Do Full Copy Detection"] \
261 -command [cb _fullcopyblame]
262 $w.ctxm add command \
263 -label [mc "Show History Context"] \
264 -command [cb _gitkcommit]
265 $w.ctxm add command \
266 -label [mc "Blame Parent Commit"] \
267 -command [cb _blameparent]
268 foreach i $w_columns {
270 for {set g 0} {$g < [llength $group_colors]} {incr g} {
271 $i tag conf color$g -background [lindex $group_colors $g]
272 }
273 $i conf -cursor $cursor_ptr
275 $i conf -yscrollcommand [list many2scrollbar \
276 $w_columns yview $w.file_pane.out.sby]
277 bind $i <Button-1> "
278 [cb _hide_tooltip]
279 [cb _click $i @%x,%y]
280 focus $i
281 "
282 bind $i <Any-Motion> [cb _show_tooltip $i @%x,%y]
283 bind $i <Any-Enter> [cb _hide_tooltip]
284 bind $i <Any-Leave> [cb _hide_tooltip]
285 bind_button3 $i "
286 [cb _hide_tooltip]
287 set cursorX %x
288 set cursorY %y
289 set cursorW %W
290 tk_popup $w.ctxm %X %Y
291 "
292 bind $i <Shift-Tab> "[list focus $w_cviewer];break"
293 bind $i <Tab> "[list focus $w_cviewer];break"
294 }
295 foreach i [concat $w_columns $w_cviewer] {
297 bind $i <Key-Up> {catch {%W yview scroll -1 units};break}
298 bind $i <Key-Down> {catch {%W yview scroll 1 units};break}
299 bind $i <Key-Left> {catch {%W xview scroll -1 units};break}
300 bind $i <Key-Right> {catch {%W xview scroll 1 units};break}
301 bind $i <Key-k> {catch {%W yview scroll -1 units};break}
302 bind $i <Key-j> {catch {%W yview scroll 1 units};break}
303 bind $i <Key-h> {catch {%W xview scroll -1 units};break}
304 bind $i <Key-l> {catch {%W xview scroll 1 units};break}
305 bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
306 bind $i <Control-Key-f> {catch {%W yview scroll 1 pages};break}
307 }
308 bind $w_cviewer <Shift-Tab> "[list focus $w_file];break"
310 bind $w_cviewer <Tab> "[list focus $w_file];break"
311 bind $w_cviewer <Button-1> [list focus $w_cviewer]
312 bind $w_file <Visibility> [list focus $w_file]
313 grid configure $w.header -sticky ew
315 grid configure $w.file_pane -sticky nsew
316 grid configure $w.status -sticky ew
317 grid columnconfigure $top 0 -weight 1
318 grid rowconfigure $top 0 -weight 0
319 grid rowconfigure $top 1 -weight 1
320 grid rowconfigure $top 2 -weight 0
321 set req_w [winfo reqwidth $top]
323 set req_h [winfo reqheight $top]
324 set scr_h [expr {[winfo screenheight $top] - 100}]
325 if {$req_w < 600} {set req_w 600}
326 if {$req_h < $scr_h} {set req_h $scr_h}
327 set g "${req_w}x${req_h}"
328 wm geometry $top $g
329 update
330 set old_height [winfo height $w.file_pane]
332 $w.file_pane sash place 0 \
333 [lindex [$w.file_pane sash coord 0] 0] \
334 [expr {int($old_height * 0.70)}]
335 bind $w.file_pane <Configure> \
336 "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
337 wm protocol $top WM_DELETE_WINDOW "destroy $top"
339 bind $top <Destroy> [cb _kill]
340 _load $this {}
342}
343method _kill {} {
345 if {$current_fd ne {}} {
346 kill_file_process $current_fd
347 catch {close $current_fd}
348 set current_fd {}
349 }
350}
351method _load {jump} {
353 variable group_colors
354 _hide_tooltip $this
356 if {$total_lines != 0 || $current_fd ne {}} {
358 _kill $this
359 foreach i $w_columns {
361 $i conf -state normal
362 $i delete 0.0 end
363 foreach g [$i tag names] {
364 if {[regexp {^g[0-9a-f]{40}$} $g]} {
365 $i tag delete $g
366 }
367 }
368 $i conf -state disabled
369 }
370 $w_cviewer conf -state normal
372 $w_cviewer delete 0.0 end
373 $w_cviewer conf -state disabled
374 set highlight_line -1
376 set highlight_column {}
377 set highlight_commit {}
378 set total_lines 0
379 }
380 if {$history eq {}} {
382 $w_back conf -state disabled
383 } else {
384 $w_back conf -state normal
385 }
386 # Index 0 is always empty. There is never line 0 as
388 # we use only 1 based lines, as that matches both with
389 # git-blame output and with Tk's text widget.
390 #
391 set amov_data [list [list]]
392 set asim_data [list [list]]
393 $status show [mc "Reading %s..." "$commit:[escape_path $path]"]
395 $w_path conf -text [escape_path $path]
396 if {$commit eq {}} {
397 set fd [open $path r]
398 fconfigure $fd -eofchar {}
399 } else {
400 set fd [git_read cat-file blob "$commit:$path"]
401 }
402 fconfigure $fd -blocking 0 -translation lf -encoding binary
403 fileevent $fd readable [cb _read_file $fd $jump]
404 set current_fd $fd
405}
406method _history_menu {} {
408 set m $w.backmenu
409 if {[winfo exists $m]} {
410 $m delete 0 end
411 } else {
412 menu $m -tearoff 0
413 }
414 for {set i [expr {[llength $history] - 1}]
416 } {$i >= 0} {incr i -1} {
417 set e [lindex $history $i]
418 set c [lindex $e 0]
419 set f [lindex $e 1]
420 if {[regexp {^[0-9a-f]{40}$} $c]} {
422 set t [string range $c 0 8]...
423 } elseif {$c eq {}} {
424 set t {Working Directory}
425 } else {
426 set t $c
427 }
428 if {![catch {set summary $header($c,summary)}]} {
429 append t " $summary"
430 if {[string length $t] > 70} {
431 set t [string range $t 0 66]...
432 }
433 }
434 $m add command -label $t -command [cb _goback $i]
436 }
437 set X [winfo rootx $w_back]
438 set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
439 tk_popup $m $X $Y
440}
441method _goback {i} {
443 set dat [lindex $history $i]
444 set history [lrange $history 0 [expr {$i - 1}]]
445 set commit [lindex $dat 0]
446 set path [lindex $dat 1]
447 _load $this [lrange $dat 2 5]
448}
449method _read_file {fd jump} {
451 if {$fd ne $current_fd} {
452 catch {close $fd}
453 return
454 }
455 foreach i $w_columns {$i conf -state normal}
457 while {[gets $fd line] >= 0} {
458 regsub "\r\$" $line {} line
459 incr total_lines
460 lappend amov_data {}
461 lappend asim_data {}
462 if {$total_lines > 1} {
464 foreach i $w_columns {$i insert end "\n"}
465 }
466 $w_line insert end "$total_lines" linenumber
468 $w_file insert end "$line"
469 }
470 set ln_wc [expr {[string length $total_lines] + 2}]
472 if {[$w_line cget -width] < $ln_wc} {
473 $w_line conf -width $ln_wc
474 }
475 foreach i $w_columns {$i conf -state disabled}
477 if {[eof $fd]} {
479 close $fd
480 # If we don't force Tk to update the widgets *right now*
482 # none of our jump commands will cause a change in the UI.
483 #
484 update
485 if {[llength $jump] == 1} {
487 set highlight_line [lindex $jump 0]
488 $w_file see "$highlight_line.0"
489 } elseif {[llength $jump] == 4} {
490 set highlight_column [lindex $jump 0]
491 set highlight_line [lindex $jump 1]
492 $w_file xview moveto [lindex $jump 2]
493 $w_file yview moveto [lindex $jump 3]
494 }
495 _exec_blame $this $w_asim @asim_data \
497 [list] \
498 [mc "Loading copy/move tracking annotations..."]
499 }
500} ifdeleted { catch {close $fd} }
501method _exec_blame {cur_w cur_d options cur_s} {
503 lappend options --incremental
504 if {$commit eq {}} {
505 lappend options --contents $path
506 } else {
507 lappend options $commit
508 }
509 lappend options -- $path
510 set fd [eval git_read --nice blame $options]
511 fconfigure $fd -blocking 0 -translation lf -encoding binary
512 fileevent $fd readable [cb _read_blame $fd $cur_w $cur_d]
513 set current_fd $fd
514 set blame_lines 0
515 $status start \
517 $cur_s \
518 [mc "lines annotated"]
519}
520method _read_blame {fd cur_w cur_d} {
522 upvar #0 $cur_d line_data
523 variable group_colors
524 if {$fd ne $current_fd} {
526 catch {close $fd}
527 return
528 }
529 $cur_w conf -state normal
531 while {[gets $fd line] >= 0} {
532 if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
533 cmit original_line final_line line_count]} {
534 set r_commit $cmit
535 set r_orig_line $original_line
536 set r_final_line $final_line
537 set r_line_count $line_count
538 } elseif {[string match {filename *} $line]} {
539 set file [string range $line 9 end]
540 set n $r_line_count
541 set lno $r_final_line
542 set oln $r_orig_line
543 set cmit $r_commit
544 if {[regexp {^0{40}$} $cmit]} {
546 set commit_abbr work
547 set commit_type curr_commit
548 } elseif {$cmit eq $commit} {
549 set commit_abbr this
550 set commit_type curr_commit
551 } else {
552 set commit_type prior_commit
553 set commit_abbr [string range $cmit 0 3]
554 }
555 set author_abbr {}
557 set a_name {}
558 catch {set a_name $header($cmit,author)}
559 while {$a_name ne {}} {
560 if {$author_abbr ne {}
561 && [string index $a_name 0] eq {'}} {
562 regsub {^'[^']+'\s+} $a_name {} a_name
563 }
564 if {![regexp {^([[:upper:]])} $a_name _a]} break
565 append author_abbr $_a
566 unset _a
567 if {![regsub \
568 {^[[:upper:]][^\s]*\s+} \
569 $a_name {} a_name ]} break
570 }
571 if {$author_abbr eq {}} {
572 set author_abbr { |}
573 } else {
574 set author_abbr [string range $author_abbr 0 3]
575 }
576 unset a_name
577 set first_lno $lno
579 while {
580 $first_lno > 1
581 && $cmit eq [lindex $line_data [expr {$first_lno - 1}] 0]
582 && $file eq [lindex $line_data [expr {$first_lno - 1}] 1]
583 } {
584 incr first_lno -1
585 }
586 set color {}
588 if {$first_lno < $lno} {
589 foreach g [$w_file tag names $first_lno.0] {
590 if {[regexp {^color[0-9]+$} $g]} {
591 set color $g
592 break
593 }
594 }
595 } else {
596 set i [lsort [concat \
597 [$w_file tag names "[expr {$first_lno - 1}].0"] \
598 [$w_file tag names "[expr {$lno + $n}].0"] \
599 ]]
600 for {set g 0} {$g < [llength $group_colors]} {incr g} {
601 if {[lsearch -sorted -exact $i color$g] == -1} {
602 set color color$g
603 break
604 }
605 }
606 }
607 if {$color eq {}} {
608 set color color0
609 }
610 while {$n > 0} {
612 set lno_e "$lno.0 lineend + 1c"
613 if {[lindex $line_data $lno] ne {}} {
614 set g [lindex $line_data $lno 0]
615 foreach i $w_columns {
616 $i tag remove g$g $lno.0 $lno_e
617 }
618 }
619 lset line_data $lno [list $cmit $file $oln]
620 $cur_w delete $lno.0 "$lno.0 lineend"
622 if {$lno == $first_lno} {
623 $cur_w insert $lno.0 $commit_abbr $commit_type
624 } elseif {$lno == [expr {$first_lno + 1}]} {
625 $cur_w insert $lno.0 $author_abbr author_abbr
626 } else {
627 $cur_w insert $lno.0 { |}
628 }
629 foreach i $w_columns {
631 if {$cur_w eq $w_amov} {
632 for {set g 0} \
633 {$g < [llength $group_colors]} \
634 {incr g} {
635 $i tag remove color$g $lno.0 $lno_e
636 }
637 $i tag add $color $lno.0 $lno_e
638 }
639 $i tag add g$cmit $lno.0 $lno_e
640 }
641 if {$highlight_column eq $cur_w} {
643 if {$highlight_line == -1
644 && [lindex [$w_file yview] 0] == 0} {
645 $w_file see $lno.0
646 set highlight_line $lno
647 }
648 if {$highlight_line == $lno} {
649 _showcommit $this $cur_w $lno
650 }
651 }
652 incr n -1
654 incr lno
655 incr oln
656 incr blame_lines
657 }
658 while {
660 $cmit eq [lindex $line_data $lno 0]
661 && $file eq [lindex $line_data $lno 1]
662 } {
663 $cur_w delete $lno.0 "$lno.0 lineend"
664 if {$lno == $first_lno} {
666 $cur_w insert $lno.0 $commit_abbr $commit_type
667 } elseif {$lno == [expr {$first_lno + 1}]} {
668 $cur_w insert $lno.0 $author_abbr author_abbr
669 } else {
670 $cur_w insert $lno.0 { |}
671 }
672 if {$cur_w eq $w_amov} {
674 foreach i $w_columns {
675 for {set g 0} \
676 {$g < [llength $group_colors]} \
677 {incr g} {
678 $i tag remove color$g $lno.0 $lno_e
679 }
680 $i tag add $color $lno.0 $lno_e
681 }
682 }
683 incr lno
685 }
686 } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
688 set header($r_commit,$key) $data
689 }
690 }
691 $cur_w conf -state disabled
692 if {[eof $fd]} {
694 close $fd
695 if {$cur_w eq $w_asim} {
696 # Switches for original location detection
697 set threshold [get_config gui.copyblamethreshold]
698 set original_options [list "-C$threshold"]
699 if {![is_config_true gui.fastcopyblame]} {
701 # thorough copy search; insert before the threshold
702 set original_options [linsert $original_options 0 -C]
703 }
704 if {[git-version >= 1.5.3]} {
705 lappend original_options -w ; # ignore indentation changes
706 }
707 _exec_blame $this $w_amov @amov_data \
709 $original_options \
710 [mc "Loading original location annotations..."]
711 } else {
712 set current_fd {}
713 $status stop [mc "Annotation complete."]
714 }
715 } else {
716 $status update $blame_lines $total_lines
717 }
718} ifdeleted { catch {close $fd} }
719method _find_commit_bound {data_list start_idx delta} {
721 upvar #0 $data_list line_data
722 set pos $start_idx
723 set limit [expr {[llength $line_data] - 1}]
724 set base_commit [lindex $line_data $pos 0]
725 while {$pos > 0 && $pos < $limit} {
727 set new_pos [expr {$pos + $delta}]
728 if {[lindex $line_data $new_pos 0] ne $base_commit} {
729 return $pos
730 }
731 set pos $new_pos
733 }
734 return $pos
736}
737method _fullcopyblame {} {
739 if {$current_fd ne {}} {
740 tk_messageBox \
741 -icon error \
742 -type ok \
743 -title [mc "Busy"] \
744 -message [mc "Annotation process is already running."]
745 return
747 }
748 # Switches for original location detection
750 set threshold [get_config gui.copyblamethreshold]
751 set original_options [list -C -C "-C$threshold"]
752 if {[git-version >= 1.5.3]} {
754 lappend original_options -w ; # ignore indentation changes
755 }
756 # Find the line range
758 set pos @$::cursorX,$::cursorY
759 set lno [lindex [split [$::cursorW index $pos] .] 0]
760 set min_amov_lno [_find_commit_bound $this @amov_data $lno -1]
761 set max_amov_lno [_find_commit_bound $this @amov_data $lno 1]
762 set min_asim_lno [_find_commit_bound $this @asim_data $lno -1]
763 set max_asim_lno [_find_commit_bound $this @asim_data $lno 1]
764 if {$min_asim_lno < $min_amov_lno} {
766 set min_amov_lno $min_asim_lno
767 }
768 if {$max_asim_lno > $max_amov_lno} {
770 set max_amov_lno $max_asim_lno
771 }
772 lappend original_options -L "$min_amov_lno,$max_amov_lno"
774 # Clear lines
776 for {set i $min_amov_lno} {$i <= $max_amov_lno} {incr i} {
777 lset amov_data $i [list ]
778 }
779 # Start the back-end process
781 _exec_blame $this $w_amov @amov_data \
782 $original_options \
783 [mc "Running thorough copy detection..."]
784}
785method _click {cur_w pos} {
787 set lno [lindex [split [$cur_w index $pos] .] 0]
788 _showcommit $this $cur_w $lno
789}
790method _load_commit {cur_w cur_d pos} {
792 upvar #0 $cur_d line_data
793 set lno [lindex [split [$cur_w index $pos] .] 0]
794 set dat [lindex $line_data $lno]
795 if {$dat ne {}} {
796 _load_new_commit $this \
797 [lindex $dat 0] \
798 [lindex $dat 1] \
799 [list [lindex $dat 2]]
800 }
801}
802method _load_new_commit {new_commit new_path jump} {
804 lappend history [list \
805 $commit $path \
806 $highlight_column \
807 $highlight_line \
808 [lindex [$w_file xview] 0] \
809 [lindex [$w_file yview] 0] \
810 ]
811 set commit $new_commit
813 set path $new_path
814 _load $this $jump
815}
816method _showcommit {cur_w lno} {
818 global repo_config
819 variable active_color
820 if {$highlight_commit ne {}} {
822 foreach i $w_columns {
823 $i tag conf g$highlight_commit -background {}
824 $i tag lower g$highlight_commit
825 }
826 }
827 if {$cur_w eq $w_asim} {
829 set dat [lindex $asim_data $lno]
830 set highlight_column $w_asim
831 } else {
832 set dat [lindex $amov_data $lno]
833 set highlight_column $w_amov
834 }
835 $w_cviewer conf -state normal
837 $w_cviewer delete 0.0 end
838 if {$dat eq {}} {
840 set cmit {}
841 $w_cviewer insert end [mc "Loading annotation..."] still_loading
842 } else {
843 set cmit [lindex $dat 0]
844 set file [lindex $dat 1]
845 foreach i $w_columns {
847 $i tag conf g$cmit -background $active_color
848 $i tag raise g$cmit
849 }
850 set author_name {}
852 set author_email {}
853 set author_time {}
854 catch {set author_name $header($cmit,author)}
855 catch {set author_email $header($cmit,author-mail)}
856 catch {set author_time [format_date $header($cmit,author-time)]}
857 set committer_name {}
859 set committer_email {}
860 set committer_time {}
861 catch {set committer_name $header($cmit,committer)}
862 catch {set committer_email $header($cmit,committer-mail)}
863 catch {set committer_time [format_date $header($cmit,committer-time)]}
864 if {[catch {set msg $header($cmit,message)}]} {
866 set msg {}
867 catch {
868 set fd [git_read cat-file commit $cmit]
869 fconfigure $fd -encoding binary -translation lf
870 if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
871 set enc utf-8
872 }
873 while {[gets $fd line] > 0} {
874 if {[string match {encoding *} $line]} {
875 set enc [string tolower [string range $line 9 end]]
876 }
877 }
878 set msg [read $fd]
879 close $fd
880 set enc [tcl_encoding $enc]
882 if {$enc ne {}} {
883 set msg [encoding convertfrom $enc $msg]
884 set author_name [encoding convertfrom $enc $author_name]
885 set committer_name [encoding convertfrom $enc $committer_name]
886 set header($cmit,author) $author_name
887 set header($cmit,committer) $committer_name
888 set header($cmit,summary) \
889 [encoding convertfrom $enc $header($cmit,summary)]
890 }
891 set msg [string trim $msg]
892 }
893 set header($cmit,message) $msg
894 }
895 $w_cviewer insert end "commit $cmit\n" header_key
897 $w_cviewer insert end [strcat [mc "Author:"] "\t"] header_key
898 $w_cviewer insert end "$author_name $author_email" header_val
899 $w_cviewer insert end " $author_time\n" header_val
900 $w_cviewer insert end [strcat [mc "Committer:"] "\t"] header_key
902 $w_cviewer insert end "$committer_name $committer_email" header_val
903 $w_cviewer insert end " $committer_time\n" header_val
904 if {$file ne $path} {
906 $w_cviewer insert end [strcat [mc "Original File:"] "\t"] header_key
907 $w_cviewer insert end "[escape_path $file]\n" header_val
908 }
909 $w_cviewer insert end "\n$msg"
911 }
912 $w_cviewer conf -state disabled
913 set highlight_line $lno
915 set highlight_commit $cmit
916 if {[lsearch -exact $tooltip_commit $highlight_commit] != -1} {
918 _hide_tooltip $this
919 }
920}
921method _get_click_amov_info {} {
923 set pos @$::cursorX,$::cursorY
924 set lno [lindex [split [$::cursorW index $pos] .] 0]
925 return [lindex $amov_data $lno]
926}
927method _copycommit {} {
929 set dat [_get_click_amov_info $this]
930 if {$dat ne {}} {
931 clipboard clear
932 clipboard append \
933 -format STRING \
934 -type STRING \
935 -- [lindex $dat 0]
936 }
937}
938method _format_offset_date {base offset} {
940 set exval [expr {$base + $offset*24*60*60}]
941 return [clock format $exval -format {%Y-%m-%d}]
942}
943method _gitkcommit {} {
945 set dat [_get_click_amov_info $this]
946 if {$dat ne {}} {
947 set cmit [lindex $dat 0]
948 set radius [get_config gui.blamehistoryctx]
949 set cmdline [list --select-commit=$cmit]
950 if {$radius > 0} {
952 set author_time {}
953 set committer_time {}
954 catch {set author_time $header($cmit,author-time)}
956 catch {set committer_time $header($cmit,committer-time)}
957 if {$committer_time eq {}} {
959 set committer_time $author_time
960 }
961 set after_time [_format_offset_date $this $committer_time [expr {-$radius}]]
963 set before_time [_format_offset_date $this $committer_time $radius]
964 lappend cmdline --after=$after_time --before=$before_time
966 }
967 lappend cmdline $cmit
969 set base_rev "HEAD"
971 if {$commit ne {}} {
972 set base_rev $commit
973 }
974 if {$base_rev ne $cmit} {
976 lappend cmdline $base_rev
977 }
978 do_gitk $cmdline
980 }
981}
982method _blameparent {} {
984 set dat [_get_click_amov_info $this]
985 if {$dat ne {}} {
986 set cmit [lindex $dat 0]
987 if {[catch {set cparent [git rev-parse --verify "$cmit^"]}]} {
989 error_popup [strcat [mc "Cannot find parent commit:"] "\n\n$err"]
990 return;
991 }
992 _load_new_commit $this \
994 $cparent \
995 [lindex $dat 1] \
996 [list [lindex $dat 2]]
997 }
998}
999method _show_tooltip {cur_w pos} {
1001 if {$tooltip_wm ne {}} {
1002 _open_tooltip $this $cur_w
1003 } elseif {$tooltip_timer eq {}} {
1004 set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
1005 }
1006}
1007method _open_tooltip {cur_w} {
1009 set tooltip_timer {}
1010 set pos_x [winfo pointerx $cur_w]
1011 set pos_y [winfo pointery $cur_w]
1012 if {[winfo containing $pos_x $pos_y] ne $cur_w} {
1013 _hide_tooltip $this
1014 return
1015 }
1016 if {$tooltip_wm ne "$cur_w.tooltip"} {
1018 _hide_tooltip $this
1019 set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
1021 wm overrideredirect $tooltip_wm 1
1022 wm transient $tooltip_wm [winfo toplevel $cur_w]
1023 set tooltip_t $tooltip_wm.label
1024 text $tooltip_t \
1025 -takefocus 0 \
1026 -highlightthickness 0 \
1027 -relief flat \
1028 -borderwidth 0 \
1029 -wrap none \
1030 -background lightyellow \
1031 -foreground black
1032 $tooltip_t tag conf section_header -font font_uibold
1033 pack $tooltip_t
1034 } else {
1035 $tooltip_t conf -state normal
1036 $tooltip_t delete 0.0 end
1037 }
1038 set pos @[join [list \
1040 [expr {$pos_x - [winfo rootx $cur_w]}] \
1041 [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
1042 set lno [lindex [split [$cur_w index $pos] .] 0]
1043 if {$cur_w eq $w_amov} {
1044 set dat [lindex $amov_data $lno]
1045 set org {}
1046 } else {
1047 set dat [lindex $asim_data $lno]
1048 set org [lindex $amov_data $lno]
1049 }
1050 if {$dat eq {}} {
1052 _hide_tooltip $this
1053 return
1054 }
1055 set cmit [lindex $dat 0]
1057 set tooltip_commit [list $cmit]
1058 set author_name {}
1060 set summary {}
1061 set author_time {}
1062 catch {set author_name $header($cmit,author)}
1063 catch {set summary $header($cmit,summary)}
1064 catch {set author_time [format_date $header($cmit,author-time)]}
1065 $tooltip_t insert end "commit $cmit\n"
1067 $tooltip_t insert end "$author_name $author_time\n"
1068 $tooltip_t insert end "$summary"
1069 if {$org ne {} && [lindex $org 0] ne $cmit} {
1071 set save [$tooltip_t get 0.0 end]
1072 $tooltip_t delete 0.0 end
1073 set cmit [lindex $org 0]
1075 set file [lindex $org 1]
1076 lappend tooltip_commit $cmit
1077 set author_name {}
1079 set summary {}
1080 set author_time {}
1081 catch {set author_name $header($cmit,author)}
1082 catch {set summary $header($cmit,summary)}
1083 catch {set author_time [format_date $header($cmit,author-time)]}
1084 $tooltip_t insert end [strcat [mc "Originally By:"] "\n"] section_header
1086 $tooltip_t insert end "commit $cmit\n"
1087 $tooltip_t insert end "$author_name $author_time\n"
1088 $tooltip_t insert end "$summary\n"
1089 if {$file ne $path} {
1091 $tooltip_t insert end [strcat [mc "In File:"] " "] section_header
1092 $tooltip_t insert end "$file\n"
1093 }
1094 $tooltip_t insert end "\n"
1096 $tooltip_t insert end [strcat [mc "Copied Or Moved Here By:"] "\n"] section_header
1097 $tooltip_t insert end $save
1098 }
1099 $tooltip_t conf -state disabled
1101 _position_tooltip $this
1102}
1103method _position_tooltip {} {
1105 set max_h [lindex [split [$tooltip_t index end] .] 0]
1106 set max_w 0
1107 for {set i 1} {$i <= $max_h} {incr i} {
1108 set c [lindex [split [$tooltip_t index "$i.0 lineend"] .] 1]
1109 if {$c > $max_w} {set max_w $c}
1110 }
1111 $tooltip_t conf -width $max_w -height $max_h
1112 set req_w [winfo reqwidth $tooltip_t]
1114 set req_h [winfo reqheight $tooltip_t]
1115 set pos_x [expr {[winfo pointerx .] + 5}]
1116 set pos_y [expr {[winfo pointery .] + 10}]
1117 set g "${req_w}x${req_h}"
1119 if {$pos_x >= 0} {append g +}
1120 append g $pos_x
1121 if {$pos_y >= 0} {append g +}
1122 append g $pos_y
1123 wm geometry $tooltip_wm $g
1125 raise $tooltip_wm
1126}
1127method _hide_tooltip {} {
1129 if {$tooltip_wm ne {}} {
1130 destroy $tooltip_wm
1131 set tooltip_wm {}
1132 set tooltip_commit {}
1133 }
1134 if {$tooltip_timer ne {}} {
1135 after cancel $tooltip_timer
1136 set tooltip_timer {}
1137 }
1138}
1139method _resize {new_height} {
1141 set diff [expr {$new_height - $old_height}]
1142 if {$diff == 0} return
1143 set my [expr {[winfo height $w.file_pane] - 25}]
1145 set o [$w.file_pane sash coord 0]
1146 set ox [lindex $o 0]
1147 set oy [expr {[lindex $o 1] + $diff}]
1148 if {$oy < 0} {set oy 0}
1149 if {$oy > $my} {set oy $my}
1150 $w.file_pane sash place 0 $ox $oy
1151 set old_height $new_height
1153}
1154}