Andrew's git - gitweb.git/blob - perl/Git/SVN/Utils.pm

   1package Git::SVN::Utils;
   2
   3use strict;
   4use warnings;
   5
   6use SVN::Core;
   7
   8use base qw(Exporter);
   9
  10our @EXPORT_OK = qw(
  11        fatal
  12        can_compress
  13        canonicalize_path
  14        canonicalize_url
  15        join_paths
  16);
  17
  18
  19=head1 NAME
  20
  21Git::SVN::Utils - utility functions used across Git::SVN
  22
  23=head1 SYNOPSIS
  24
  25    use Git::SVN::Utils qw(functions to import);
  26
  27=head1 DESCRIPTION
  28
  29This module contains functions which are useful across many different
  30parts of Git::SVN.  Mostly it's a place to put utility functions
  31rather than duplicate the code or have classes grabbing at other
  32classes.
  33
  34=head1 FUNCTIONS
  35
  36All functions can be imported only on request.
  37
  38=head3 fatal
  39
  40    fatal(@message);
  41
  42Display a message and exit with a fatal error code.
  43
  44=cut
  45
  46# Note: not certain why this is in use instead of die.  Probably because
  47# the exit code of die is 255?  Doesn't appear to be used consistently.
  48sub fatal (@) { print STDERR "@_\n"; exit 1 }
  49
  50
  51=head3 can_compress
  52
  53    my $can_compress = can_compress;
  54
  55Returns true if Compress::Zlib is available, false otherwise.
  56
  57=cut
  58
  59my $can_compress;
  60sub can_compress {
  61        return $can_compress if defined $can_compress;
  62
  63        return $can_compress = eval { require Compress::Zlib; };
  64}
  65
  66
  67=head3 canonicalize_path
  68
  69    my $canoncalized_path = canonicalize_path($path);
  70
  71Converts $path into a canonical form which is safe to pass to the SVN
  72API as a file path.
  73
  74=cut
  75
  76# Turn foo/../bar into bar
  77sub _collapse_dotdot {
  78        my $path = shift;
  79
  80        1 while $path =~ s{/[^/]+/+\.\.}{};
  81        1 while $path =~ s{[^/]+/+\.\./}{};
  82        1 while $path =~ s{[^/]+/+\.\.}{};
  83
  84        return $path;
  85}
  86
  87
  88sub canonicalize_path {
  89        my ($path) = @_;
  90        my $dot_slash_added = 0;
  91        if (substr($path, 0, 1) ne "/") {
  92                $path = "./" . $path;
  93                $dot_slash_added = 1;
  94        }
  95        $path =~ s#/+#/#g;
  96        $path =~ s#/\.(?:/|$)#/#g;
  97        $path = _collapse_dotdot($path);
  98        $path =~ s#/$##g;
  99        $path =~ s#^\./## if $dot_slash_added;
 100        $path =~ s#^/##;
 101        $path =~ s#^\.$##;
 102        return $path;
 103}
 104
 105
 106=head3 canonicalize_url
 107
 108    my $canonicalized_url = canonicalize_url($url);
 109
 110Converts $url into a canonical form which is safe to pass to the SVN
 111API as a URL.
 112
 113=cut
 114
 115sub canonicalize_url {
 116        my $url = shift;
 117
 118        # The 1.7 way to do it
 119        if ( defined &SVN::_Core::svn_uri_canonicalize ) {
 120                return SVN::_Core::svn_uri_canonicalize($url);
 121        }
 122        # There wasn't a 1.6 way to do it, so we do it ourself.
 123        else {
 124                return _canonicalize_url_ourselves($url);
 125        }
 126}
 127
 128
 129sub _canonicalize_url_ourselves {
 130        my ($url) = @_;
 131        $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 132        return $url;
 133}
 134
 135
 136=head3 join_paths
 137
 138    my $new_path = join_paths(@paths);
 139
 140Appends @paths together into a single path.  Any empty paths are ignored.
 141
 142=cut
 143
 144sub join_paths {
 145        my @paths = @_;
 146
 147        @paths = grep { defined $_ && length $_ } @paths;
 148
 149        return '' unless @paths;
 150        return $paths[0] if @paths == 1;
 151
 152        my $new_path = shift @paths;
 153        $new_path =~ s{/+$}{};
 154
 155        my $last_path = pop @paths;
 156        $last_path =~ s{^/+}{};
 157
 158        for my $path (@paths) {
 159                $path =~ s{^/+}{};
 160                $path =~ s{/+$}{};
 161                $new_path .= "/$path";
 162        }
 163
 164        return $new_path .= "/$last_path";
 165}
 166
 1671;