Andrew's git / gitweb.git / configure.ac
?
configure.acon commit Update draft release notes to 1.7.9 (876a6f4)
   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26# Optional second argument allows setting NO_PROGRAM=YesPlease if
  27# --without-PROGRAM version used.
  28AC_DEFUN([GIT_ARG_SET_PATH],
  29[AC_ARG_WITH([$1],
  30 [AS_HELP_STRING([--with-$1=PATH],
  31                 [provide PATH to $1])],
  32 [GIT_CONF_APPEND_PATH($1,$2)],[])
  33])# GIT_ARG_SET_PATH
  34#
  35# GIT_CONF_APPEND_PATH(PROGRAM)
  36# ------------------------------
  37# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  38# Used by GIT_ARG_SET_PATH(PROGRAM)
  39# Optional second argument allows setting NO_PROGRAM=YesPlease if
  40# --without-PROGRAM is used.
  41AC_DEFUN([GIT_CONF_APPEND_PATH],
  42[PROGRAM=m4_toupper($1); \
  43if test "$withval" = "no"; then \
  44        if test -n "$2"; then \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Disabling use of ${PROGRAM}]); \
  47                GIT_CONF_APPEND_LINE(NO_${PROGRAM}=YesPlease); \
  48                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=); \
  49        else \
  50                AC_MSG_ERROR([You cannot use git without $1]); \
  51        fi; \
  52else \
  53        if test "$withval" = "yes"; then \
  54                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  55        else \
  56                m4_toupper($1)_PATH=$withval; \
  57                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  58                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  59        fi; \
  60fi; \
  61]) # GIT_CONF_APPEND_PATH
  62#
  63# GIT_PARSE_WITH(PACKAGE)
  64# -----------------------
  65# For use in AC_ARG_WITH action-if-found, for packages default ON.
  66# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  67# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  68# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  69AC_DEFUN([GIT_PARSE_WITH],
  70[PACKAGE=m4_toupper($1); \
  71if test "$withval" = "no"; then \
  72        m4_toupper(NO_$1)=YesPlease; \
  73elif test "$withval" = "yes"; then \
  74        m4_toupper(NO_$1)=; \
  75else \
  76        m4_toupper(NO_$1)=; \
  77        m4_toupper($1)DIR=$withval; \
  78        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  79        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  80fi \
  81])# GIT_PARSE_WITH
  82#
  83# GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  84# ---------------------
  85# Set VAR to the value specied by --with-WITHNAME.
  86# No verification of arguments is performed, but warnings are issued
  87# if either 'yes' or 'no' is specified.
  88# HELP_TEXT is presented when --help is called.
  89# This is a direct way to allow setting variables in the Makefile.
  90AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  91[AC_ARG_WITH([$1],
  92 [AS_HELP_STRING([--with-$1=VALUE], $3)],
  93 if test -n "$withval"; then \
  94  if test "$withval" = "yes" -o "$withval" = "no"; then \
  95    AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  96                     [a value for $1 ($2).  Maybe you do...?]); \
  97  fi; \
  98  \
  99  AC_MSG_NOTICE([Setting $2 to $withval]); \
 100  GIT_CONF_APPEND_LINE($2=$withval); \
 101 fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 102
 103dnl
 104dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 105dnl -----------------------------------------
 106dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
 107dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
 108dnl -Wall), it does not work.  By looking for function definition in
 109dnl libraries, this problem can be worked around.
 110AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 111  AC_SEARCH_LIBS([$1],,
 112  [$2],[$3])
 113],[$3])])
 114
 115dnl
 116dnl GIT_STASH_FLAGS(BASEPATH_VAR)
 117dnl -----------------------------
 118dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 119dnl tests that may want to take user settings into account.
 120AC_DEFUN([GIT_STASH_FLAGS],[
 121if test -n "$1"; then
 122   old_CPPFLAGS="$CPPFLAGS"
 123   old_LDFLAGS="$LDFLAGS"
 124   CPPFLAGS="-I$1/include $CPPFLAGS"
 125   LDFLAGS="-L$1/$lib $LDFLAGS"
 126fi
 127])
 128
 129dnl
 130dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 131dnl -----------------------------
 132dnl Restore the stashed *FLAGS values.
 133AC_DEFUN([GIT_UNSTASH_FLAGS],[
 134if test -n "$1"; then
 135   CPPFLAGS="$old_CPPFLAGS"
 136   LDFLAGS="$old_LDFLAGS"
 137fi
 138])
 139
 140## Site configuration related to programs (before tests)
 141## --with-PACKAGE[=ARG] and --without-PACKAGE
 142#
 143# Set lib to alternative name of lib directory (e.g. lib64)
 144AC_ARG_WITH([lib],
 145 [AS_HELP_STRING([--with-lib=ARG],
 146                 [ARG specifies alternative name for lib directory])],
 147 [if test "$withval" = "no" || test "$withval" = "yes"; then \
 148        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 149else \
 150        lib=$withval; \
 151        AC_MSG_NOTICE([Setting lib to '$lib']); \
 152        GIT_CONF_APPEND_LINE(lib=$withval); \
 153fi; \
 154],[])
 155
 156if test -z "$lib"; then
 157   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 158   lib=lib
 159fi
 160
 161AC_ARG_ENABLE([pthreads],
 162 [AS_HELP_STRING([--enable-pthreads=FLAGS],
 163  [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 164  [The default if FLAGS is not specified is to try first -pthread]
 165  [and then -lpthread.]
 166  [--without-pthreads will disable threading.])],
 167[
 168if test "x$enableval" = "xyes"; then
 169   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 170elif test "x$enableval" != "xno"; then
 171   PTHREAD_CFLAGS=$enableval
 172   AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 173else
 174   AC_MSG_NOTICE([POSIX Threads will be disabled.])
 175   NO_PTHREADS=YesPlease
 176   USER_NOPTHREAD=1
 177fi],
 178[
 179   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 180])
 181
 182# Define option to enable JavaScript minification
 183AC_ARG_ENABLE([jsmin],
 184[AS_HELP_STRING([--enable-jsmin=PATH],
 185  [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 186[
 187  JSMIN=$enableval;
 188  AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 189  GIT_CONF_APPEND_LINE(JSMIN=$enableval);
 190])
 191
 192# Define option to enable CSS minification
 193AC_ARG_ENABLE([cssmin],
 194[AS_HELP_STRING([--enable-cssmin=PATH],
 195  [PATH is the name of a CSS minifier or the absolute path to one.])],
 196[
 197  CSSMIN=$enableval;
 198  AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 199  GIT_CONF_APPEND_LINE(CSSMIN=$enableval);
 200])
 201
 202## Site configuration (override autodetection)
 203## --with-PACKAGE[=ARG] and --without-PACKAGE
 204AC_MSG_NOTICE([CHECKS for site configuration])
 205#
 206# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 207# tests.  These tests take up a significant amount of the total test time
 208# but are not needed unless you plan to talk to SVN repos.
 209#
 210# Define PPC_SHA1 environment variable when running make to make use of
 211# a bundled SHA1 routine optimized for PowerPC.
 212#
 213# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 214# This also implies BLK_SHA1.
 215#
 216# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 217# /foo/bar/include and /foo/bar/lib directories.
 218AC_ARG_WITH(openssl,
 219AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 220AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 221GIT_PARSE_WITH(openssl))
 222#
 223# Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
 224# able to use Perl-compatible regular expressions.
 225#
 226# Define LIBPCREDIR=/foo/bar if your libpcre header and library files are in
 227# /foo/bar/include and /foo/bar/lib directories.
 228#
 229AC_ARG_WITH(libpcre,
 230AS_HELP_STRING([--with-libpcre],[support Perl-compatible regexes (default is NO)])
 231AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 232if test "$withval" = "no"; then \
 233        USE_LIBPCRE=; \
 234elif test "$withval" = "yes"; then \
 235        USE_LIBPCRE=YesPlease; \
 236else
 237        USE_LIBPCRE=YesPlease; \
 238        LIBPCREDIR=$withval; \
 239        AC_MSG_NOTICE([Setting LIBPCREDIR to $withval]); \
 240        GIT_CONF_APPEND_LINE(LIBPCREDIR=$withval); \
 241fi \
 242)
 243#
 244# Define NO_CURL if you do not have curl installed.  git-http-pull and
 245# git-http-push are not built, and you cannot use http:// and https://
 246# transports.
 247#
 248# Define CURLDIR=/foo/bar if your curl header and library files are in
 249# /foo/bar/include and /foo/bar/lib directories.
 250AC_ARG_WITH(curl,
 251AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 252AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 253GIT_PARSE_WITH(curl))
 254#
 255# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 256# not built, and you cannot push using http:// and https:// transports.
 257#
 258# Define EXPATDIR=/foo/bar if your expat header and library files are in
 259# /foo/bar/include and /foo/bar/lib directories.
 260AC_ARG_WITH(expat,
 261AS_HELP_STRING([--with-expat],
 262[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 263AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 264GIT_PARSE_WITH(expat))
 265#
 266# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 267# installed in /sw, but don't want GIT to link against any libraries
 268# installed there.  If defined you may specify your own (or Fink's)
 269# include directories and library directories by defining CFLAGS
 270# and LDFLAGS appropriately.
 271#
 272# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 273# have DarwinPorts installed in /opt/local, but don't want GIT to
 274# link against any libraries installed there.  If defined you may
 275# specify your own (or DarwinPort's) include directories and
 276# library directories by defining CFLAGS and LDFLAGS appropriately.
 277#
 278# Define NO_MMAP if you want to avoid mmap.
 279#
 280# Define NO_ICONV if your libc does not properly support iconv.
 281AC_ARG_WITH(iconv,
 282AS_HELP_STRING([--without-iconv],
 283[if your architecture doesn't properly support iconv])
 284AS_HELP_STRING([--with-iconv=PATH],
 285[PATH is prefix for libiconv library and headers])
 286AS_HELP_STRING([],
 287[used only if you need linking with libiconv]),
 288GIT_PARSE_WITH(iconv))
 289
 290## --enable-FEATURE[=ARG] and --disable-FEATURE
 291#
 292# Define USE_NSEC below if you want git to care about sub-second file mtimes
 293# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 294# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 295# randomly break unless your underlying filesystem supports those sub-second
 296# times (my ext3 doesn't).
 297#
 298# Define USE_STDEV below if you want git to care about the underlying device
 299# change being considered an inode change from the update-index perspective.
 300
 301#
 302# Allow user to set ETC_GITCONFIG variable
 303GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 304                        Use VALUE instead of /etc/gitconfig as the
 305                        global git configuration file.
 306                        If VALUE is not fully qualified it will be interpreted
 307                        as a path relative to the computed prefix at runtime.)
 308
 309#
 310# Allow user to set ETC_GITATTRIBUTES variable
 311GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 312                        Use VALUE instead of /etc/gitattributes as the
 313                        global git attributes file.
 314                        If VALUE is not fully qualified it will be interpreted
 315                        as a path relative to the computed prefix at runtime.)
 316
 317#
 318# Allow user to set the default pager
 319GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 320                        Use VALUE as the fall-back pager instead of 'less'.
 321                        This is used by things like 'git log' when the user
 322                        does not specify a pager to use through alternate
 323                        methods. eg: /usr/bin/pager)
 324#
 325# Allow user to set the default editor
 326GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 327                        Use VALUE as the fall-back editor instead of 'vi'.
 328                        This is used by things like 'git commit' when the user
 329                        does not specify a preferred editor through other
 330                        methods. eg: /usr/bin/editor)
 331
 332#
 333# Define SHELL_PATH to provide path to shell.
 334GIT_ARG_SET_PATH(shell)
 335#
 336# Define PERL_PATH to provide path to Perl.
 337GIT_ARG_SET_PATH(perl)
 338#
 339# Define PYTHON_PATH to provide path to Python.
 340GIT_ARG_SET_PATH(python, allow-without)
 341#
 342# Define ZLIB_PATH to provide path to zlib.
 343GIT_ARG_SET_PATH(zlib)
 344#
 345# Declare the with-tcltk/without-tcltk options.
 346AC_ARG_WITH(tcltk,
 347AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 348AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 349AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 350AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 351GIT_PARSE_WITH(tcltk))
 352#
 353
 354
 355## Checks for programs.
 356AC_MSG_NOTICE([CHECKS for programs])
 357#
 358AC_PROG_CC([cc gcc])
 359AC_C_INLINE
 360case $ac_cv_c_inline in
 361  inline | yes | no)    ;;
 362  *)                    AC_SUBST([INLINE], [$ac_cv_c_inline]) ;;
 363esac
 364
 365# which switch to pass runtime path to dynamic libraries to the linker
 366AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 367   SAVE_LDFLAGS="${LDFLAGS}"
 368   LDFLAGS="${SAVE_LDFLAGS} -R /"
 369   AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 370   LDFLAGS="${SAVE_LDFLAGS}"
 371])
 372if test "$git_cv_ld_dashr" = "yes"; then
 373   AC_SUBST(CC_LD_DYNPATH, [-R])
 374else
 375   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 376      SAVE_LDFLAGS="${LDFLAGS}"
 377      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 378      AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 379      LDFLAGS="${SAVE_LDFLAGS}"
 380   ])
 381   if test "$git_cv_ld_wl_rpath" = "yes"; then
 382      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 383   else
 384      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 385         SAVE_LDFLAGS="${LDFLAGS}"
 386         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 387         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 388         LDFLAGS="${SAVE_LDFLAGS}"
 389      ])
 390      if test "$git_cv_ld_rpath" = "yes"; then
 391         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 392      else
 393         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 394      fi
 395   fi
 396fi
 397#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 398AC_CHECK_TOOLS(AR, [gar ar], :)
 399AC_CHECK_PROGS(TAR, [gtar tar])
 400AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 401# TCLTK_PATH will be set to some value if we want Tcl/Tk
 402# or will be empty otherwise.
 403if test -z "$NO_TCLTK"; then
 404  if test "$with_tcltk" = ""; then
 405  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 406    TCLTK_PATH=wish
 407    AC_SUBST(TCLTK_PATH)
 408  elif test "$with_tcltk" = "yes"; then
 409  # Tcl/Tk check requested.
 410    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 411  else
 412    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 413    TCLTK_PATH="$with_tcltk"
 414    AC_SUBST(TCLTK_PATH)
 415  fi
 416fi
 417AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 418if test -n "$ASCIIDOC"; then
 419        AC_MSG_CHECKING([for asciidoc version])
 420        asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 421        case "${asciidoc_version}" in
 422        asciidoc' '7*)
 423                ASCIIDOC7=YesPlease
 424                AC_MSG_RESULT([${asciidoc_version} > 7])
 425                ;;
 426        asciidoc' '8*)
 427                ASCIIDOC7=
 428                AC_MSG_RESULT([${asciidoc_version}])
 429                ;;
 430        *)
 431                ASCIIDOC7=
 432                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 433                ;;
 434        esac
 435fi
 436AC_SUBST(ASCIIDOC7)
 437
 438
 439## Checks for libraries.
 440AC_MSG_NOTICE([CHECKS for libraries])
 441#
 442# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 443# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 444
 445GIT_STASH_FLAGS($OPENSSLDIR)
 446
 447AC_CHECK_LIB([crypto], [SHA1_Init],
 448[NEEDS_SSL_WITH_CRYPTO=],
 449[AC_CHECK_LIB([ssl], [SHA1_Init],
 450 [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 451 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 452
 453GIT_UNSTASH_FLAGS($OPENSSLDIR)
 454
 455AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 456AC_SUBST(NO_OPENSSL)
 457
 458#
 459# Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
 460# able to use Perl-compatible regular expressions.
 461#
 462
 463if test -n "$USE_LIBPCRE"; then
 464
 465GIT_STASH_FLAGS($LIBPCREDIR)
 466
 467AC_CHECK_LIB([pcre], [pcre_version],
 468[USE_LIBPCRE=YesPlease],
 469[USE_LIBPCRE=])
 470
 471GIT_UNSTASH_FLAGS($LIBPCREDIR)
 472
 473AC_SUBST(USE_LIBPCRE)
 474
 475fi
 476
 477#
 478# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 479# git-http-push are not built, and you cannot use http:// and https://
 480# transports.
 481
 482GIT_STASH_FLAGS($CURLDIR)
 483
 484AC_CHECK_LIB([curl], [curl_global_init],
 485[NO_CURL=],
 486[NO_CURL=YesPlease])
 487
 488GIT_UNSTASH_FLAGS($CURLDIR)
 489
 490AC_SUBST(NO_CURL)
 491
 492#
 493# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 494# not built, and you cannot push using http:// and https:// transports.
 495
 496GIT_STASH_FLAGS($EXPATDIR)
 497
 498AC_CHECK_LIB([expat], [XML_ParserCreate],
 499[NO_EXPAT=],
 500[NO_EXPAT=YesPlease])
 501
 502GIT_UNSTASH_FLAGS($EXPATDIR)
 503
 504AC_SUBST(NO_EXPAT)
 505
 506#
 507# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 508# some Solaris installations).
 509# Define NO_ICONV if neither libc nor libiconv support iconv.
 510
 511if test -z "$NO_ICONV"; then
 512
 513GIT_STASH_FLAGS($ICONVDIR)
 514
 515AC_DEFUN([ICONVTEST_SRC],
 516[AC_LANG_PROGRAM([#include <iconv.h>],
 517 [iconv_open("", "");])])
 518
 519if test -n "$ICONVDIR"; then
 520   lib_order="-liconv -lc"
 521else
 522   lib_order="-lc -liconv"
 523fi
 524
 525NO_ICONV=YesPlease
 526
 527for l in $lib_order; do
 528    if test "$l" = "-liconv"; then
 529       NEEDS_LIBICONV=YesPlease
 530    else
 531       NEEDS_LIBICONV=
 532    fi
 533
 534    old_LIBS="$LIBS"
 535    LIBS="$LIBS $l"
 536    AC_MSG_CHECKING([for iconv in $l])
 537    AC_LINK_IFELSE([ICONVTEST_SRC],
 538        [AC_MSG_RESULT([yes])
 539        NO_ICONV=
 540        break],
 541        [AC_MSG_RESULT([no])])
 542    LIBS="$old_LIBS"
 543done
 544
 545#in case of break
 546LIBS="$old_LIBS"
 547
 548GIT_UNSTASH_FLAGS($ICONVDIR)
 549
 550AC_SUBST(NEEDS_LIBICONV)
 551AC_SUBST(NO_ICONV)
 552
 553if test -n "$NO_ICONV"; then
 554    NEEDS_LIBICONV=
 555fi
 556
 557fi
 558
 559#
 560# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 561
 562GIT_STASH_FLAGS($ZLIB_PATH)
 563
 564AC_DEFUN([ZLIBTEST_SRC], [
 565AC_LANG_PROGRAM([#include <zlib.h>],
 566 [deflateBound(0, 0);])])
 567AC_MSG_CHECKING([for deflateBound in -lz])
 568old_LIBS="$LIBS"
 569LIBS="$LIBS -lz"
 570AC_LINK_IFELSE([ZLIBTEST_SRC],
 571        [AC_MSG_RESULT([yes])],
 572        [AC_MSG_RESULT([no])
 573        NO_DEFLATE_BOUND=yes])
 574LIBS="$old_LIBS"
 575
 576GIT_UNSTASH_FLAGS($ZLIB_PATH)
 577
 578AC_SUBST(NO_DEFLATE_BOUND)
 579
 580#
 581# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 582# Patrick Mauritz).
 583AC_CHECK_LIB([c], [socket],
 584[NEEDS_SOCKET=],
 585[NEEDS_SOCKET=YesPlease])
 586AC_SUBST(NEEDS_SOCKET)
 587test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 588
 589#
 590# The next few tests will define NEEDS_RESOLV if linking with
 591# libresolv provides some of the functions we would normally get
 592# from libc.
 593NEEDS_RESOLV=
 594AC_SUBST(NEEDS_RESOLV)
 595#
 596# Define NO_INET_NTOP if linking with -lresolv is not enough.
 597# Solaris 2.7 in particular hos inet_ntop in -lresolv.
 598NO_INET_NTOP=
 599AC_SUBST(NO_INET_NTOP)
 600AC_CHECK_FUNC([inet_ntop],
 601        [],
 602    [AC_CHECK_LIB([resolv], [inet_ntop],
 603            [NEEDS_RESOLV=YesPlease],
 604        [NO_INET_NTOP=YesPlease])
 605])
 606#
 607# Define NO_INET_PTON if linking with -lresolv is not enough.
 608# Solaris 2.7 in particular hos inet_pton in -lresolv.
 609NO_INET_PTON=
 610AC_SUBST(NO_INET_PTON)
 611AC_CHECK_FUNC([inet_pton],
 612        [],
 613    [AC_CHECK_LIB([resolv], [inet_pton],
 614            [NEEDS_RESOLV=YesPlease],
 615        [NO_INET_PTON=YesPlease])
 616])
 617#
 618# Define NO_HSTRERROR if linking with -lresolv is not enough.
 619# Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 620NO_HSTRERROR=
 621AC_CHECK_FUNC([hstrerror],
 622        [],
 623    [AC_CHECK_LIB([resolv], [hstrerror],
 624            [NEEDS_RESOLV=YesPlease],
 625        [NO_HSTRERROR=YesPlease])
 626])
 627AC_SUBST(NO_HSTRERROR)
 628#
 629# If any of the above tests determined that -lresolv is needed at
 630# build-time, also set it here for remaining configure-time checks.
 631test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 632
 633AC_CHECK_LIB([c], [basename],
 634[NEEDS_LIBGEN=],
 635[NEEDS_LIBGEN=YesPlease])
 636AC_SUBST(NEEDS_LIBGEN)
 637test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 638
 639AC_CHECK_LIB([c], [gettext],
 640[LIBC_CONTAINS_LIBINTL=YesPlease],
 641[LIBC_CONTAINS_LIBINTL=])
 642AC_SUBST(LIBC_CONTAINS_LIBINTL)
 643test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
 644
 645## Checks for header files.
 646AC_MSG_NOTICE([CHECKS for header files])
 647#
 648# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 649AC_CHECK_HEADER([sys/select.h],
 650[NO_SYS_SELECT_H=],
 651[NO_SYS_SELECT_H=UnfortunatelyYes])
 652AC_SUBST(NO_SYS_SELECT_H)
 653#
 654# Define NO_SYS_POLL_H if you don't have sys/poll.h
 655AC_CHECK_HEADER([sys/poll.h],
 656[NO_SYS_POLL_H=],
 657[NO_SYS_POLL_H=UnfortunatelyYes])
 658AC_SUBST(NO_SYS_POLL_H)
 659#
 660# Define NO_INTTYPES_H if you don't have inttypes.h
 661AC_CHECK_HEADER([inttypes.h],
 662[NO_INTTYPES_H=],
 663[NO_INTTYPES_H=UnfortunatelyYes])
 664AC_SUBST(NO_INTTYPES_H)
 665#
 666# Define OLD_ICONV if your library has an old iconv(), where the second
 667# (input buffer pointer) parameter is declared with type (const char **).
 668AC_DEFUN([OLDICONVTEST_SRC], [
 669AC_LANG_PROGRAM([[
 670#include <iconv.h>
 671
 672extern size_t iconv(iconv_t cd,
 673                    char **inbuf, size_t *inbytesleft,
 674                    char **outbuf, size_t *outbytesleft);
 675]], [])])
 676
 677GIT_STASH_FLAGS($ICONVDIR)
 678
 679AC_MSG_CHECKING([for old iconv()])
 680AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 681        [AC_MSG_RESULT([no])],
 682        [AC_MSG_RESULT([yes])
 683        OLD_ICONV=UnfortunatelyYes])
 684
 685GIT_UNSTASH_FLAGS($ICONVDIR)
 686
 687AC_SUBST(OLD_ICONV)
 688
 689## Checks for typedefs, structures, and compiler characteristics.
 690AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 691#
 692TYPE_SOCKLEN_T
 693case $ac_cv_type_socklen_t in
 694  yes)  ;;
 695  *)    AC_SUBST([SOCKLEN_T], [$git_cv_socklen_t_equiv]) ;;
 696esac
 697
 698# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 699AC_CHECK_MEMBER(struct dirent.d_ino,
 700[NO_D_INO_IN_DIRENT=],
 701[NO_D_INO_IN_DIRENT=YesPlease],
 702[#include <dirent.h>])
 703AC_SUBST(NO_D_INO_IN_DIRENT)
 704#
 705# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 706# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 707AC_CHECK_MEMBER(struct dirent.d_type,
 708[NO_D_TYPE_IN_DIRENT=],
 709[NO_D_TYPE_IN_DIRENT=YesPlease],
 710[#include <dirent.h>])
 711AC_SUBST(NO_D_TYPE_IN_DIRENT)
 712#
 713# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 714# sockaddr_storage.
 715AC_CHECK_TYPE(struct sockaddr_storage,
 716[NO_SOCKADDR_STORAGE=],
 717[NO_SOCKADDR_STORAGE=YesPlease],[
 718#include <sys/types.h>
 719#include <sys/socket.h>
 720])
 721AC_SUBST(NO_SOCKADDR_STORAGE)
 722#
 723# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 724AC_CHECK_TYPE([struct addrinfo],[
 725 GIT_CHECK_FUNC([getaddrinfo],
 726  [NO_IPV6=],
 727  [NO_IPV6=YesPlease])
 728],[NO_IPV6=YesPlease],[
 729#include <sys/types.h>
 730#include <sys/socket.h>
 731#include <netdb.h>
 732])
 733AC_SUBST(NO_IPV6)
 734#
 735# Define NO_REGEX if you have no or inferior regex support in your C library.
 736AC_CACHE_CHECK([whether the platform regex can handle null bytes],
 737 [ac_cv_c_excellent_regex], [
 738AC_EGREP_CPP(yippeeyeswehaveit,
 739        AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 740#include <regex.h>
 741],
 742[#ifdef REG_STARTEND
 743yippeeyeswehaveit
 744#endif
 745]),
 746        [ac_cv_c_excellent_regex=yes],
 747        [ac_cv_c_excellent_regex=no])
 748])
 749if test $ac_cv_c_excellent_regex = yes; then
 750        NO_REGEX=
 751else
 752        NO_REGEX=YesPlease
 753fi
 754AC_SUBST(NO_REGEX)
 755#
 756# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 757# when attempting to read from an fopen'ed directory.
 758AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 759 [ac_cv_fread_reads_directories],
 760[
 761AC_RUN_IFELSE(
 762        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 763                [[char c;
 764                FILE *f = fopen(".", "r");
 765                return f && fread(&c, 1, 1, f)]])],
 766        [ac_cv_fread_reads_directories=no],
 767        [ac_cv_fread_reads_directories=yes])
 768])
 769if test $ac_cv_fread_reads_directories = yes; then
 770        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 771else
 772        FREAD_READS_DIRECTORIES=
 773fi
 774AC_SUBST(FREAD_READS_DIRECTORIES)
 775#
 776# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 777# or vsnprintf() return -1 instead of number of characters which would
 778# have been written to the final string if enough space had been available.
 779AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 780 [ac_cv_snprintf_returns_bogus],
 781[
 782AC_RUN_IFELSE(
 783        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 784                #include "stdarg.h"
 785
 786                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 787                {
 788                  int ret;
 789                  va_list ap;
 790                  va_start(ap, format);
 791                  ret = vsnprintf(str, maxsize, format, ap);
 792                  va_end(ap);
 793                  return ret;
 794                }],
 795                [[char buf[6];
 796                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 797                      || strcmp(buf, "12")) return 1;
 798                  if (snprintf(buf, 3, "%s", "12345") != 5
 799                      || strcmp(buf, "12")) return 1]])],
 800        [ac_cv_snprintf_returns_bogus=no],
 801        [ac_cv_snprintf_returns_bogus=yes])
 802])
 803if test $ac_cv_snprintf_returns_bogus = yes; then
 804        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 805else
 806        SNPRINTF_RETURNS_BOGUS=
 807fi
 808AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 809
 810
 811## Checks for library functions.
 812## (in default C library and libraries checked by AC_CHECK_LIB)
 813AC_MSG_NOTICE([CHECKS for library functions])
 814#
 815# Define NO_LIBGEN_H if you don't have libgen.h.
 816AC_CHECK_HEADER([libgen.h],
 817[NO_LIBGEN_H=],
 818[NO_LIBGEN_H=YesPlease])
 819AC_SUBST(NO_LIBGEN_H)
 820#
 821# Define HAVE_PATHS_H if you have paths.h.
 822AC_CHECK_HEADER([paths.h],
 823[HAVE_PATHS_H=YesPlease],
 824[HAVE_PATHS_H=])
 825AC_SUBST(HAVE_PATHS_H)
 826#
 827# Define NO_GETTEXT if you don't want Git output to be translated.
 828# A translated Git requires GNU libintl or another gettext implementation
 829AC_CHECK_HEADER([libintl.h],
 830[NO_GETTEXT=],
 831[NO_GETTEXT=YesPlease])
 832AC_SUBST(NO_GETTEXT)
 833#
 834# Define HAVE_LIBCHARSET_H if have libcharset.h
 835AC_CHECK_HEADER([libcharset.h],
 836[HAVE_LIBCHARSET_H=YesPlease],
 837[HAVE_LIBCHARSET_H=])
 838AC_SUBST(HAVE_LIBCHARSET_H)
 839#
 840# Define NO_STRCASESTR if you don't have strcasestr.
 841GIT_CHECK_FUNC(strcasestr,
 842[NO_STRCASESTR=],
 843[NO_STRCASESTR=YesPlease])
 844AC_SUBST(NO_STRCASESTR)
 845#
 846# Define NO_STRTOK_R if you don't have strtok_r
 847GIT_CHECK_FUNC(strtok_r,
 848[NO_STRTOK_R=],
 849[NO_STRTOK_R=YesPlease])
 850AC_SUBST(NO_STRTOK_R)
 851#
 852# Define NO_FNMATCH if you don't have fnmatch
 853GIT_CHECK_FUNC(fnmatch,
 854[NO_FNMATCH=],
 855[NO_FNMATCH=YesPlease])
 856AC_SUBST(NO_FNMATCH)
 857#
 858# Define NO_FNMATCH_CASEFOLD if your fnmatch function doesn't have the
 859# FNM_CASEFOLD GNU extension.
 860AC_CACHE_CHECK([whether the fnmatch function supports the FNMATCH_CASEFOLD GNU extension],
 861 [ac_cv_c_excellent_fnmatch], [
 862AC_EGREP_CPP(yippeeyeswehaveit,
 863        AC_LANG_PROGRAM([
 864#include <fnmatch.h>
 865],
 866[#ifdef FNM_CASEFOLD
 867yippeeyeswehaveit
 868#endif
 869]),
 870        [ac_cv_c_excellent_fnmatch=yes],
 871        [ac_cv_c_excellent_fnmatch=no])
 872])
 873if test $ac_cv_c_excellent_fnmatch = yes; then
 874        NO_FNMATCH_CASEFOLD=
 875else
 876        NO_FNMATCH_CASEFOLD=YesPlease
 877fi
 878AC_SUBST(NO_FNMATCH_CASEFOLD)
 879#
 880# Define NO_MEMMEM if you don't have memmem.
 881GIT_CHECK_FUNC(memmem,
 882[NO_MEMMEM=],
 883[NO_MEMMEM=YesPlease])
 884AC_SUBST(NO_MEMMEM)
 885#
 886# Define NO_STRLCPY if you don't have strlcpy.
 887GIT_CHECK_FUNC(strlcpy,
 888[NO_STRLCPY=],
 889[NO_STRLCPY=YesPlease])
 890AC_SUBST(NO_STRLCPY)
 891#
 892# Define NO_UINTMAX_T if your platform does not have uintmax_t
 893AC_CHECK_TYPE(uintmax_t,
 894[NO_UINTMAX_T=],
 895[NO_UINTMAX_T=YesPlease],[
 896#include <inttypes.h>
 897])
 898AC_SUBST(NO_UINTMAX_T)
 899#
 900# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 901GIT_CHECK_FUNC(strtoumax,
 902[NO_STRTOUMAX=],
 903[NO_STRTOUMAX=YesPlease])
 904AC_SUBST(NO_STRTOUMAX)
 905#
 906# Define NO_SETENV if you don't have setenv in the C library.
 907GIT_CHECK_FUNC(setenv,
 908[NO_SETENV=],
 909[NO_SETENV=YesPlease])
 910AC_SUBST(NO_SETENV)
 911#
 912# Define NO_UNSETENV if you don't have unsetenv in the C library.
 913GIT_CHECK_FUNC(unsetenv,
 914[NO_UNSETENV=],
 915[NO_UNSETENV=YesPlease])
 916AC_SUBST(NO_UNSETENV)
 917#
 918# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 919GIT_CHECK_FUNC(mkdtemp,
 920[NO_MKDTEMP=],
 921[NO_MKDTEMP=YesPlease])
 922AC_SUBST(NO_MKDTEMP)
 923#
 924# Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 925GIT_CHECK_FUNC(mkstemps,
 926[NO_MKSTEMPS=],
 927[NO_MKSTEMPS=YesPlease])
 928AC_SUBST(NO_MKSTEMPS)
 929#
 930# Define NO_INITGROUPS if you don't have initgroups in the C library.
 931GIT_CHECK_FUNC(initgroups,
 932[NO_INITGROUPS=],
 933[NO_INITGROUPS=YesPlease])
 934AC_SUBST(NO_INITGROUPS)
 935#
 936#
 937# Define NO_MMAP if you want to avoid mmap.
 938#
 939# Define NO_ICONV if your libc does not properly support iconv.
 940
 941
 942## Other checks.
 943# Define USE_PIC if you need the main git objects to be built with -fPIC
 944# in order to build and link perl/Git.so.  x86-64 seems to need this.
 945#
 946# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 947# Enable it on Windows.  By default, symrefs are still used.
 948#
 949# Define NO_PTHREADS if we do not have pthreads.
 950#
 951# Define PTHREAD_LIBS to the linker flag used for Pthread support.
 952AC_DEFUN([PTHREADTEST_SRC], [
 953AC_LANG_PROGRAM([[
 954#include <pthread.h>
 955]], [[
 956        pthread_mutex_t test_mutex;
 957        pthread_key_t test_key;
 958        int retcode = 0;
 959        retcode |= pthread_key_create(&test_key, (void *)0);
 960        retcode |= pthread_mutex_init(&test_mutex,(void *)0);
 961        retcode |= pthread_mutex_lock(&test_mutex);
 962        retcode |= pthread_mutex_unlock(&test_mutex);
 963        return retcode;
 964]])])
 965
 966dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 967dnl   [[#include <pthread.h>]],
 968dnl   [[pthread_mutex_t test_mutex;]]
 969dnl )])
 970
 971NO_PTHREADS=UnfortunatelyYes
 972PTHREAD_LIBS=
 973
 974if test -n "$USER_NOPTHREAD"; then
 975   AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 976# handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 977# -D_REENTRANT' or some such.
 978elif test -z "$PTHREAD_CFLAGS"; then
 979  threads_found=no
 980  for opt in -mt -pthread -lpthread; do
 981     old_CFLAGS="$CFLAGS"
 982     CFLAGS="$opt $CFLAGS"
 983     AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 984     AC_LINK_IFELSE([PTHREADTEST_SRC],
 985        [AC_MSG_RESULT([yes])
 986                NO_PTHREADS=
 987                PTHREAD_LIBS="$opt"
 988                PTHREAD_CFLAGS="$opt"
 989                threads_found=yes
 990                break
 991        ],
 992        [AC_MSG_RESULT([no])])
 993      CFLAGS="$old_CFLAGS"
 994  done
 995  if test $threads_found != yes; then
 996    AC_CHECK_LIB([pthread], [pthread_create],
 997        [PTHREAD_LIBS="-lpthread"],
 998        [NO_PTHREADS=UnfortunatelyYes])
 999  fi
1000else
1001  old_CFLAGS="$CFLAGS"
1002  CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1003  AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
1004  AC_LINK_IFELSE([PTHREADTEST_SRC],
1005        [AC_MSG_RESULT([yes])
1006                NO_PTHREADS=
1007                PTHREAD_LIBS="$PTHREAD_CFLAGS"
1008        ],
1009        [AC_MSG_RESULT([no])])
1010
1011  CFLAGS="$old_CFLAGS"
1012fi
1013
1014CFLAGS="$old_CFLAGS"
1015
1016AC_SUBST(PTHREAD_CFLAGS)
1017AC_SUBST(PTHREAD_LIBS)
1018AC_SUBST(NO_PTHREADS)
1019
1020## Output files
1021AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
1022AC_OUTPUT
1023
1024
1025## Cleanup
1026rm -f "${config_append}"