Andrew's git - gitweb.git/blob

90338785a06e7d978a35540af56a7d9e0d4d2ae4
   1#!/bin/sh
   2# Tcl ignores the next line -*- tcl -*- \
   3 if test "z$*" = zversion \
   4 || test "z$*" = z--version; \
   5 then \
   6        echo 'git-gui version @@GITGUI_VERSION@@'; \
   7        exit; \
   8 fi; \
   9 argv0=$0; \
  10 exec wish "$argv0" -- "$@"
  11
  12set appvers {@@GITGUI_VERSION@@}
  13set copyright [encoding convertfrom utf-8 {
  14Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16This program is free software; you can redistribute it and/or modify
  17it under the terms of the GNU General Public License as published by
  18the Free Software Foundation; either version 2 of the License, or
  19(at your option) any later version.
  20
  21This program is distributed in the hope that it will be useful,
  22but WITHOUT ANY WARRANTY; without even the implied warranty of
  23MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24GNU General Public License for more details.
  25
  26You should have received a copy of the GNU General Public License
  27along with this program; if not, write to the Free Software
  28Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30######################################################################
  31##
  32## Tcl/Tk sanity check
  33
  34if {[catch {package require Tcl 8.4} err]
  35 || [catch {package require Tk  8.4} err]
  36} {
  37        catch {wm withdraw .}
  38        tk_messageBox \
  39                -icon error \
  40                -type ok \
  41                -title [mc "git-gui: fatal error"] \
  42                -message $err
  43        exit 1
  44}
  45
  46catch {rename send {}} ; # What an evil concept...
  47
  48######################################################################
  49##
  50## locate our library
  51
  52set oguilib {@@GITGUI_LIBDIR@@}
  53set oguirel {@@GITGUI_RELATIVE@@}
  54if {$oguirel eq {1}} {
  55        set oguilib [file dirname [file normalize $argv0]]
  56        if {[file tail $oguilib] eq {git-core}} {
  57                set oguilib [file dirname $oguilib]
  58        }
  59        set oguilib [file dirname $oguilib]
  60        set oguilib [file join $oguilib share git-gui lib]
  61        set oguimsg [file join $oguilib msgs]
  62} elseif {[string match @@* $oguirel]} {
  63        set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64        set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65} else {
  66        set oguimsg [file join $oguilib msgs]
  67}
  68unset oguirel
  69
  70######################################################################
  71##
  72## enable verbose loading?
  73
  74if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75        unset _verbose
  76        rename auto_load real__auto_load
  77        proc auto_load {name args} {
  78                puts stderr "auto_load $name"
  79                return [uplevel 1 real__auto_load $name $args]
  80        }
  81        rename source real__source
  82        proc source {name} {
  83                puts stderr "source    $name"
  84                uplevel 1 real__source $name
  85        }
  86}
  87
  88######################################################################
  89##
  90## Internationalization (i18n) through msgcat and gettext. See
  91## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93package require msgcat
  94
  95proc _mc_trim {fmt} {
  96        set cmk [string first @@ $fmt]
  97        if {$cmk > 0} {
  98                return [string range $fmt 0 [expr {$cmk - 1}]]
  99        }
 100        return $fmt
 101}
 102
 103proc mc {en_fmt args} {
 104        set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105        if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107        }
 108        return $msg
 109}
 110
 111proc strcat {args} {
 112        return [join $args {}]
 113}
 114
 115::msgcat::mcload $oguimsg
 116unset oguimsg
 117
 118######################################################################
 119##
 120## read only globals
 121
 122set _appname {Git Gui}
 123set _gitdir {}
 124set _gitexec {}
 125set _reponame {}
 126set _iscygwin {}
 127set _search_path {}
 128
 129set _trace [lsearch -exact $argv --trace]
 130if {$_trace >= 0} {
 131        set argv [lreplace $argv $_trace $_trace]
 132        set _trace 1
 133} else {
 134        set _trace 0
 135}
 136
 137proc appname {} {
 138        global _appname
 139        return $_appname
 140}
 141
 142proc gitdir {args} {
 143        global _gitdir
 144        if {$args eq {}} {
 145                return $_gitdir
 146        }
 147        return [eval [list file join $_gitdir] $args]
 148}
 149
 150proc gitexec {args} {
 151        global _gitexec
 152        if {$_gitexec eq {}} {
 153                if {[catch {set _gitexec [git --exec-path]} err]} {
 154                        error "Git not installed?\n\n$err"
 155                }
 156                if {[is_Cygwin]} {
 157                        set _gitexec [exec cygpath \
 158                                --windows \
 159                                --absolute \
 160                                $_gitexec]
 161                } else {
 162                        set _gitexec [file normalize $_gitexec]
 163                }
 164        }
 165        if {$args eq {}} {
 166                return $_gitexec
 167        }
 168        return [eval [list file join $_gitexec] $args]
 169}
 170
 171proc reponame {} {
 172        return $::_reponame
 173}
 174
 175proc is_MacOSX {} {
 176        if {[tk windowingsystem] eq {aqua}} {
 177                return 1
 178        }
 179        return 0
 180}
 181
 182proc is_Windows {} {
 183        if {$::tcl_platform(platform) eq {windows}} {
 184                return 1
 185        }
 186        return 0
 187}
 188
 189proc is_Cygwin {} {
 190        global _iscygwin
 191        if {$_iscygwin eq {}} {
 192                if {$::tcl_platform(platform) eq {windows}} {
 193                        if {[catch {set p [exec cygpath --windir]} err]} {
 194                                set _iscygwin 0
 195                        } else {
 196                                set _iscygwin 1
 197                        }
 198                } else {
 199                        set _iscygwin 0
 200                }
 201        }
 202        return $_iscygwin
 203}
 204
 205proc is_enabled {option} {
 206        global enabled_options
 207        if {[catch {set on $enabled_options($option)}]} {return 0}
 208        return $on
 209}
 210
 211proc enable_option {option} {
 212        global enabled_options
 213        set enabled_options($option) 1
 214}
 215
 216proc disable_option {option} {
 217        global enabled_options
 218        set enabled_options($option) 0
 219}
 220
 221######################################################################
 222##
 223## config
 224
 225proc is_many_config {name} {
 226        switch -glob -- $name {
 227        gui.recentrepo -
 228        remote.*.fetch -
 229        remote.*.push
 230                {return 1}
 231        *
 232                {return 0}
 233        }
 234}
 235
 236proc is_config_true {name} {
 237        global repo_config
 238        if {[catch {set v $repo_config($name)}]} {
 239                return 0
 240        } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 241                return 1
 242        } else {
 243                return 0
 244        }
 245}
 246
 247proc get_config {name} {
 248        global repo_config
 249        if {[catch {set v $repo_config($name)}]} {
 250                return {}
 251        } else {
 252                return $v
 253        }
 254}
 255
 256######################################################################
 257##
 258## handy utils
 259
 260proc _trace_exec {cmd} {
 261        if {!$::_trace} return
 262        set d {}
 263        foreach v $cmd {
 264                if {$d ne {}} {
 265                        append d { }
 266                }
 267                if {[regexp {[ \t\r\n'"$?*]} $v]} {
 268                        set v [sq $v]
 269                }
 270                append d $v
 271        }
 272        puts stderr $d
 273}
 274
 275proc _git_cmd {name} {
 276        global _git_cmd_path
 277
 278        if {[catch {set v $_git_cmd_path($name)}]} {
 279                switch -- $name {
 280                  version   -
 281                --version   -
 282                --exec-path { return [list $::_git $name] }
 283                }
 284
 285                set p [gitexec git-$name$::_search_exe]
 286                if {[file exists $p]} {
 287                        set v [list $p]
 288                } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 289                        # Try to determine what sort of magic will make
 290                        # git-$name go and do its thing, because native
 291                        # Tcl on Windows doesn't know it.
 292                        #
 293                        set p [gitexec git-$name]
 294                        set f [open $p r]
 295                        set s [gets $f]
 296                        close $f
 297
 298                        switch -glob -- [lindex $s 0] {
 299                        #!*sh     { set i sh     }
 300                        #!*perl   { set i perl   }
 301                        #!*python { set i python }
 302                        default   { error "git-$name is not supported: $s" }
 303                        }
 304
 305                        upvar #0 _$i interp
 306                        if {![info exists interp]} {
 307                                set interp [_which $i]
 308                        }
 309                        if {$interp eq {}} {
 310                                error "git-$name requires $i (not in PATH)"
 311                        }
 312                        set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 313                } else {
 314                        # Assume it is builtin to git somehow and we
 315                        # aren't actually able to see a file for it.
 316                        #
 317                        set v [list $::_git $name]
 318                }
 319                set _git_cmd_path($name) $v
 320        }
 321        return $v
 322}
 323
 324proc _which {what args} {
 325        global env _search_exe _search_path
 326
 327        if {$_search_path eq {}} {
 328                if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 329                        set _search_path [split [exec cygpath \
 330                                --windows \
 331                                --path \
 332                                --absolute \
 333                                $env(PATH)] {;}]
 334                        set _search_exe .exe
 335                } elseif {[is_Windows]} {
 336                        set gitguidir [file dirname [info script]]
 337                        regsub -all ";" $gitguidir "\\;" gitguidir
 338                        set env(PATH) "$gitguidir;$env(PATH)"
 339                        set _search_path [split $env(PATH) {;}]
 340                        set _search_exe .exe
 341                } else {
 342                        set _search_path [split $env(PATH) :]
 343                        set _search_exe {}
 344                }
 345        }
 346
 347        if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 348                set suffix {}
 349        } else {
 350                set suffix $_search_exe
 351        }
 352
 353        foreach p $_search_path {
 354                set p [file join $p $what$suffix]
 355                if {[file exists $p]} {
 356                        return [file normalize $p]
 357                }
 358        }
 359        return {}
 360}
 361
 362proc _lappend_nice {cmd_var} {
 363        global _nice
 364        upvar $cmd_var cmd
 365
 366        if {![info exists _nice]} {
 367                set _nice [_which nice]
 368        }
 369        if {$_nice ne {}} {
 370                lappend cmd $_nice
 371        }
 372}
 373
 374proc git {args} {
 375        set opt [list]
 376
 377        while {1} {
 378                switch -- [lindex $args 0] {
 379                --nice {
 380                        _lappend_nice opt
 381                }
 382
 383                default {
 384                        break
 385                }
 386
 387                }
 388
 389                set args [lrange $args 1 end]
 390        }
 391
 392        set cmdp [_git_cmd [lindex $args 0]]
 393        set args [lrange $args 1 end]
 394
 395        _trace_exec [concat $opt $cmdp $args]
 396        set result [eval exec $opt $cmdp $args]
 397        if {$::_trace} {
 398                puts stderr "< $result"
 399        }
 400        return $result
 401}
 402
 403proc _open_stdout_stderr {cmd} {
 404        _trace_exec $cmd
 405        if {[catch {
 406                        set fd [open [concat [list | ] $cmd] r]
 407                } err]} {
 408                if {   [lindex $cmd end] eq {2>@1}
 409                    && $err eq {can not find channel named "1"}
 410                        } {
 411                        # Older versions of Tcl 8.4 don't have this 2>@1 IO
 412                        # redirect operator.  Fallback to |& cat for those.
 413                        # The command was not actually started, so its safe
 414                        # to try to start it a second time.
 415                        #
 416                        set fd [open [concat \
 417                                [list | ] \
 418                                [lrange $cmd 0 end-1] \
 419                                [list |& cat] \
 420                                ] r]
 421                } else {
 422                        error $err
 423                }
 424        }
 425        fconfigure $fd -eofchar {}
 426        return $fd
 427}
 428
 429proc git_read {args} {
 430        set opt [list]
 431
 432        while {1} {
 433                switch -- [lindex $args 0] {
 434                --nice {
 435                        _lappend_nice opt
 436                }
 437
 438                --stderr {
 439                        lappend args 2>@1
 440                }
 441
 442                default {
 443                        break
 444                }
 445
 446                }
 447
 448                set args [lrange $args 1 end]
 449        }
 450
 451        set cmdp [_git_cmd [lindex $args 0]]
 452        set args [lrange $args 1 end]
 453
 454        return [_open_stdout_stderr [concat $opt $cmdp $args]]
 455}
 456
 457proc git_write {args} {
 458        set opt [list]
 459
 460        while {1} {
 461                switch -- [lindex $args 0] {
 462                --nice {
 463                        _lappend_nice opt
 464                }
 465
 466                default {
 467                        break
 468                }
 469
 470                }
 471
 472                set args [lrange $args 1 end]
 473        }
 474
 475        set cmdp [_git_cmd [lindex $args 0]]
 476        set args [lrange $args 1 end]
 477
 478        _trace_exec [concat $opt $cmdp $args]
 479        return [open [concat [list | ] $opt $cmdp $args] w]
 480}
 481
 482proc githook_read {hook_name args} {
 483        set pchook [gitdir hooks $hook_name]
 484        lappend args 2>@1
 485
 486        # On Windows [file executable] might lie so we need to ask
 487        # the shell if the hook is executable.  Yes that's annoying.
 488        #
 489        if {[is_Windows]} {
 490                upvar #0 _sh interp
 491                if {![info exists interp]} {
 492                        set interp [_which sh]
 493                }
 494                if {$interp eq {}} {
 495                        error "hook execution requires sh (not in PATH)"
 496                }
 497
 498                set scr {if test -x "$1";then exec "$@";fi}
 499                set sh_c [list $interp -c $scr $interp $pchook]
 500                return [_open_stdout_stderr [concat $sh_c $args]]
 501        }
 502
 503        if {[file executable $pchook]} {
 504                return [_open_stdout_stderr [concat [list $pchook] $args]]
 505        }
 506
 507        return {}
 508}
 509
 510proc kill_file_process {fd} {
 511        set process [pid $fd]
 512
 513        catch {
 514                if {[is_Windows]} {
 515                        # Use a Cygwin-specific flag to allow killing
 516                        # native Windows processes
 517                        exec kill -f $process
 518                } else {
 519                        exec kill $process
 520                }
 521        }
 522}
 523
 524proc sq {value} {
 525        regsub -all ' $value "'\\''" value
 526        return "'$value'"
 527}
 528
 529proc load_current_branch {} {
 530        global current_branch is_detached
 531
 532        set fd [open [gitdir HEAD] r]
 533        if {[gets $fd ref] < 1} {
 534                set ref {}
 535        }
 536        close $fd
 537
 538        set pfx {ref: refs/heads/}
 539        set len [string length $pfx]
 540        if {[string equal -length $len $pfx $ref]} {
 541                # We're on a branch.  It might not exist.  But
 542                # HEAD looks good enough to be a branch.
 543                #
 544                set current_branch [string range $ref $len end]
 545                set is_detached 0
 546        } else {
 547                # Assume this is a detached head.
 548                #
 549                set current_branch HEAD
 550                set is_detached 1
 551        }
 552}
 553
 554auto_load tk_optionMenu
 555rename tk_optionMenu real__tkOptionMenu
 556proc tk_optionMenu {w varName args} {
 557        set m [eval real__tkOptionMenu $w $varName $args]
 558        $m configure -font font_ui
 559        $w configure -font font_ui
 560        return $m
 561}
 562
 563proc rmsel_tag {text} {
 564        $text tag conf sel \
 565                -background [$text cget -background] \
 566                -foreground [$text cget -foreground] \
 567                -borderwidth 0
 568        $text tag conf in_sel -background lightgray
 569        bind $text <Motion> break
 570        return $text
 571}
 572
 573set root_exists 0
 574bind . <Visibility> {
 575        bind . <Visibility> {}
 576        set root_exists 1
 577}
 578
 579if {[is_Windows]} {
 580        wm iconbitmap . -default $oguilib/git-gui.ico
 581}
 582
 583######################################################################
 584##
 585## config defaults
 586
 587set cursor_ptr arrow
 588font create font_diff -family Courier -size 10
 589font create font_ui
 590catch {
 591        label .dummy
 592        eval font configure font_ui [font actual [.dummy cget -font]]
 593        destroy .dummy
 594}
 595
 596font create font_uiitalic
 597font create font_uibold
 598font create font_diffbold
 599font create font_diffitalic
 600
 601foreach class {Button Checkbutton Entry Label
 602                Labelframe Listbox Menu Message
 603                Radiobutton Spinbox Text} {
 604        option add *$class.font font_ui
 605}
 606unset class
 607
 608if {[is_Windows] || [is_MacOSX]} {
 609        option add *Menu.tearOff 0
 610}
 611
 612if {[is_MacOSX]} {
 613        set M1B M1
 614        set M1T Cmd
 615} else {
 616        set M1B Control
 617        set M1T Ctrl
 618}
 619
 620proc bind_button3 {w cmd} {
 621        bind $w <Any-Button-3> $cmd
 622        if {[is_MacOSX]} {
 623                # Mac OS X sends Button-2 on right click through three-button mouse,
 624                # or through trackpad right-clicking (two-finger touch + click).
 625                bind $w <Any-Button-2> $cmd
 626                bind $w <Control-Button-1> $cmd
 627        }
 628}
 629
 630proc apply_config {} {
 631        global repo_config font_descs
 632
 633        foreach option $font_descs {
 634                set name [lindex $option 0]
 635                set font [lindex $option 1]
 636                if {[catch {
 637                        set need_weight 1
 638                        foreach {cn cv} $repo_config(gui.$name) {
 639                                if {$cn eq {-weight}} {
 640                                        set need_weight 0
 641                                }
 642                                font configure $font $cn $cv
 643                        }
 644                        if {$need_weight} {
 645                                font configure $font -weight normal
 646                        }
 647                        } err]} {
 648                        error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 649                }
 650                foreach {cn cv} [font configure $font] {
 651                        font configure ${font}bold $cn $cv
 652                        font configure ${font}italic $cn $cv
 653                }
 654                font configure ${font}bold -weight bold
 655                font configure ${font}italic -slant italic
 656        }
 657}
 658
 659set default_config(branch.autosetupmerge) true
 660set default_config(merge.tool) {}
 661set default_config(merge.keepbackup) true
 662set default_config(merge.diffstat) true
 663set default_config(merge.summary) false
 664set default_config(merge.verbosity) 2
 665set default_config(user.name) {}
 666set default_config(user.email) {}
 667
 668set default_config(gui.matchtrackingbranch) false
 669set default_config(gui.pruneduringfetch) false
 670set default_config(gui.trustmtime) false
 671set default_config(gui.fastcopyblame) false
 672set default_config(gui.copyblamethreshold) 40
 673set default_config(gui.blamehistoryctx) 7
 674set default_config(gui.diffcontext) 5
 675set default_config(gui.commitmsgwidth) 75
 676set default_config(gui.newbranchtemplate) {}
 677set default_config(gui.spellingdictionary) {}
 678set default_config(gui.fontui) [font configure font_ui]
 679set default_config(gui.fontdiff) [font configure font_diff]
 680set font_descs {
 681        {fontui   font_ui   {mc "Main Font"}}
 682        {fontdiff font_diff {mc "Diff/Console Font"}}
 683}
 684
 685######################################################################
 686##
 687## find git
 688
 689set _git  [_which git]
 690if {$_git eq {}} {
 691        catch {wm withdraw .}
 692        tk_messageBox \
 693                -icon error \
 694                -type ok \
 695                -title [mc "git-gui: fatal error"] \
 696                -message [mc "Cannot find git in PATH."]
 697        exit 1
 698}
 699
 700######################################################################
 701##
 702## version check
 703
 704if {[catch {set _git_version [git --version]} err]} {
 705        catch {wm withdraw .}
 706        tk_messageBox \
 707                -icon error \
 708                -type ok \
 709                -title [mc "git-gui: fatal error"] \
 710                -message "Cannot determine Git version:
 711
 712$err
 713
 714[appname] requires Git 1.5.0 or later."
 715        exit 1
 716}
 717if {![regsub {^git version } $_git_version {} _git_version]} {
 718        catch {wm withdraw .}
 719        tk_messageBox \
 720                -icon error \
 721                -type ok \
 722                -title [mc "git-gui: fatal error"] \
 723                -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 724        exit 1
 725}
 726
 727set _real_git_version $_git_version
 728regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 729regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 730regsub {\.rc[0-9]+$} $_git_version {} _git_version
 731regsub {\.GIT$} $_git_version {} _git_version
 732regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 733
 734if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 735        catch {wm withdraw .}
 736        if {[tk_messageBox \
 737                -icon warning \
 738                -type yesno \
 739                -default no \
 740                -title "[appname]: warning" \
 741                 -message [mc "Git version cannot be determined.
 742
 743%s claims it is version '%s'.
 744
 745%s requires at least Git 1.5.0 or later.
 746
 747Assume '%s' is version 1.5.0?
 748" $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 749                set _git_version 1.5.0
 750        } else {
 751                exit 1
 752        }
 753}
 754unset _real_git_version
 755
 756proc git-version {args} {
 757        global _git_version
 758
 759        switch [llength $args] {
 760        0 {
 761                return $_git_version
 762        }
 763
 764        2 {
 765                set op [lindex $args 0]
 766                set vr [lindex $args 1]
 767                set cm [package vcompare $_git_version $vr]
 768                return [expr $cm $op 0]
 769        }
 770
 771        4 {
 772                set type [lindex $args 0]
 773                set name [lindex $args 1]
 774                set parm [lindex $args 2]
 775                set body [lindex $args 3]
 776
 777                if {($type ne {proc} && $type ne {method})} {
 778                        error "Invalid arguments to git-version"
 779                }
 780                if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 781                        error "Last arm of $type $name must be default"
 782                }
 783
 784                foreach {op vr cb} [lrange $body 0 end-2] {
 785                        if {[git-version $op $vr]} {
 786                                return [uplevel [list $type $name $parm $cb]]
 787                        }
 788                }
 789
 790                return [uplevel [list $type $name $parm [lindex $body end]]]
 791        }
 792
 793        default {
 794                error "git-version >= x"
 795        }
 796
 797        }
 798}
 799
 800if {[git-version < 1.5]} {
 801        catch {wm withdraw .}
 802        tk_messageBox \
 803                -icon error \
 804                -type ok \
 805                -title [mc "git-gui: fatal error"] \
 806                -message "[appname] requires Git 1.5.0 or later.
 807
 808You are using [git-version]:
 809
 810[git --version]"
 811        exit 1
 812}
 813
 814######################################################################
 815##
 816## configure our library
 817
 818set idx [file join $oguilib tclIndex]
 819if {[catch {set fd [open $idx r]} err]} {
 820        catch {wm withdraw .}
 821        tk_messageBox \
 822                -icon error \
 823                -type ok \
 824                -title [mc "git-gui: fatal error"] \
 825                -message $err
 826        exit 1
 827}
 828if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 829        set idx [list]
 830        while {[gets $fd n] >= 0} {
 831                if {$n ne {} && ![string match #* $n]} {
 832                        lappend idx $n
 833                }
 834        }
 835} else {
 836        set idx {}
 837}
 838close $fd
 839
 840if {$idx ne {}} {
 841        set loaded [list]
 842        foreach p $idx {
 843                if {[lsearch -exact $loaded $p] >= 0} continue
 844                source [file join $oguilib $p]
 845                lappend loaded $p
 846        }
 847        unset loaded p
 848} else {
 849        set auto_path [concat [list $oguilib] $auto_path]
 850}
 851unset -nocomplain idx fd
 852
 853######################################################################
 854##
 855## config file parsing
 856
 857git-version proc _parse_config {arr_name args} {
 858        >= 1.5.3 {
 859                upvar $arr_name arr
 860                array unset arr
 861                set buf {}
 862                catch {
 863                        set fd_rc [eval \
 864                                [list git_read config] \
 865                                $args \
 866                                [list --null --list]]
 867                        fconfigure $fd_rc -translation binary
 868                        set buf [read $fd_rc]
 869                        close $fd_rc
 870                }
 871                foreach line [split $buf "\0"] {
 872                        if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 873                                if {[is_many_config $name]} {
 874                                        lappend arr($name) $value
 875                                } else {
 876                                        set arr($name) $value
 877                                }
 878                        }
 879                }
 880        }
 881        default {
 882                upvar $arr_name arr
 883                array unset arr
 884                catch {
 885                        set fd_rc [eval [list git_read config --list] $args]
 886                        while {[gets $fd_rc line] >= 0} {
 887                                if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 888                                        if {[is_many_config $name]} {
 889                                                lappend arr($name) $value
 890                                        } else {
 891                                                set arr($name) $value
 892                                        }
 893                                }
 894                        }
 895                        close $fd_rc
 896                }
 897        }
 898}
 899
 900proc load_config {include_global} {
 901        global repo_config global_config default_config
 902
 903        if {$include_global} {
 904                _parse_config global_config --global
 905        }
 906        _parse_config repo_config
 907
 908        foreach name [array names default_config] {
 909                if {[catch {set v $global_config($name)}]} {
 910                        set global_config($name) $default_config($name)
 911                }
 912                if {[catch {set v $repo_config($name)}]} {
 913                        set repo_config($name) $default_config($name)
 914                }
 915        }
 916}
 917
 918######################################################################
 919##
 920## feature option selection
 921
 922if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 923        unset _junk
 924} else {
 925        set subcommand gui
 926}
 927if {$subcommand eq {gui.sh}} {
 928        set subcommand gui
 929}
 930if {$subcommand eq {gui} && [llength $argv] > 0} {
 931        set subcommand [lindex $argv 0]
 932        set argv [lrange $argv 1 end]
 933}
 934
 935enable_option multicommit
 936enable_option branch
 937enable_option transport
 938disable_option bare
 939
 940switch -- $subcommand {
 941browser -
 942blame {
 943        enable_option bare
 944
 945        disable_option multicommit
 946        disable_option branch
 947        disable_option transport
 948}
 949citool {
 950        enable_option singlecommit
 951
 952        disable_option multicommit
 953        disable_option branch
 954        disable_option transport
 955}
 956}
 957
 958######################################################################
 959##
 960## repository setup
 961
 962if {[catch {
 963                set _gitdir $env(GIT_DIR)
 964                set _prefix {}
 965                }]
 966        && [catch {
 967                set _gitdir [git rev-parse --git-dir]
 968                set _prefix [git rev-parse --show-prefix]
 969        } err]} {
 970        load_config 1
 971        apply_config
 972        choose_repository::pick
 973}
 974if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 975        catch {set _gitdir [exec cygpath --windows $_gitdir]}
 976}
 977if {![file isdirectory $_gitdir]} {
 978        catch {wm withdraw .}
 979        error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
 980        exit 1
 981}
 982if {$_prefix ne {}} {
 983        regsub -all {[^/]+/} $_prefix ../ cdup
 984        if {[catch {cd $cdup} err]} {
 985                catch {wm withdraw .}
 986                error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
 987                exit 1
 988        }
 989        unset cdup
 990} elseif {![is_enabled bare]} {
 991        if {[lindex [file split $_gitdir] end] ne {.git}} {
 992                catch {wm withdraw .}
 993                error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
 994                exit 1
 995        }
 996        if {[catch {cd [file dirname $_gitdir]} err]} {
 997                catch {wm withdraw .}
 998                error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
 999                exit 1
1000        }
1001}
1002set _reponame [file split [file normalize $_gitdir]]
1003if {[lindex $_reponame end] eq {.git}} {
1004        set _reponame [lindex $_reponame end-1]
1005} else {
1006        set _reponame [lindex $_reponame end]
1007}
1008
1009######################################################################
1010##
1011## global init
1012
1013set current_diff_path {}
1014set current_diff_side {}
1015set diff_actions [list]
1016
1017set HEAD {}
1018set PARENT {}
1019set MERGE_HEAD [list]
1020set commit_type {}
1021set empty_tree {}
1022set current_branch {}
1023set is_detached 0
1024set current_diff_path {}
1025set is_3way_diff 0
1026set selected_commit_type new
1027
1028######################################################################
1029##
1030## task management
1031
1032set rescan_active 0
1033set diff_active 0
1034set last_clicked {}
1035
1036set disable_on_lock [list]
1037set index_lock_type none
1038
1039proc lock_index {type} {
1040        global index_lock_type disable_on_lock
1041
1042        if {$index_lock_type eq {none}} {
1043                set index_lock_type $type
1044                foreach w $disable_on_lock {
1045                        uplevel #0 $w disabled
1046                }
1047                return 1
1048        } elseif {$index_lock_type eq "begin-$type"} {
1049                set index_lock_type $type
1050                return 1
1051        }
1052        return 0
1053}
1054
1055proc unlock_index {} {
1056        global index_lock_type disable_on_lock
1057
1058        set index_lock_type none
1059        foreach w $disable_on_lock {
1060                uplevel #0 $w normal
1061        }
1062}
1063
1064######################################################################
1065##
1066## status
1067
1068proc repository_state {ctvar hdvar mhvar} {
1069        global current_branch
1070        upvar $ctvar ct $hdvar hd $mhvar mh
1071
1072        set mh [list]
1073
1074        load_current_branch
1075        if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1076                set hd {}
1077                set ct initial
1078                return
1079        }
1080
1081        set merge_head [gitdir MERGE_HEAD]
1082        if {[file exists $merge_head]} {
1083                set ct merge
1084                set fd_mh [open $merge_head r]
1085                while {[gets $fd_mh line] >= 0} {
1086                        lappend mh $line
1087                }
1088                close $fd_mh
1089                return
1090        }
1091
1092        set ct normal
1093}
1094
1095proc PARENT {} {
1096        global PARENT empty_tree
1097
1098        set p [lindex $PARENT 0]
1099        if {$p ne {}} {
1100                return $p
1101        }
1102        if {$empty_tree eq {}} {
1103                set empty_tree [git mktree << {}]
1104        }
1105        return $empty_tree
1106}
1107
1108proc rescan {after {honor_trustmtime 1}} {
1109        global HEAD PARENT MERGE_HEAD commit_type
1110        global ui_index ui_workdir ui_comm
1111        global rescan_active file_states
1112        global repo_config
1113
1114        if {$rescan_active > 0 || ![lock_index read]} return
1115
1116        repository_state newType newHEAD newMERGE_HEAD
1117        if {[string match amend* $commit_type]
1118                && $newType eq {normal}
1119                && $newHEAD eq $HEAD} {
1120        } else {
1121                set HEAD $newHEAD
1122                set PARENT $newHEAD
1123                set MERGE_HEAD $newMERGE_HEAD
1124                set commit_type $newType
1125        }
1126
1127        array unset file_states
1128
1129        if {!$::GITGUI_BCK_exists &&
1130                (![$ui_comm edit modified]
1131                || [string trim [$ui_comm get 0.0 end]] eq {})} {
1132                if {[string match amend* $commit_type]} {
1133                } elseif {[load_message GITGUI_MSG]} {
1134                } elseif {[load_message MERGE_MSG]} {
1135                } elseif {[load_message SQUASH_MSG]} {
1136                }
1137                $ui_comm edit reset
1138                $ui_comm edit modified false
1139        }
1140
1141        if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1142                rescan_stage2 {} $after
1143        } else {
1144                set rescan_active 1
1145                ui_status [mc "Refreshing file status..."]
1146                set fd_rf [git_read update-index \
1147                        -q \
1148                        --unmerged \
1149                        --ignore-missing \
1150                        --refresh \
1151                        ]
1152                fconfigure $fd_rf -blocking 0 -translation binary
1153                fileevent $fd_rf readable \
1154                        [list rescan_stage2 $fd_rf $after]
1155        }
1156}
1157
1158if {[is_Cygwin]} {
1159        set is_git_info_exclude {}
1160        proc have_info_exclude {} {
1161                global is_git_info_exclude
1162
1163                if {$is_git_info_exclude eq {}} {
1164                        if {[catch {exec test -f [gitdir info exclude]}]} {
1165                                set is_git_info_exclude 0
1166                        } else {
1167                                set is_git_info_exclude 1
1168                        }
1169                }
1170                return $is_git_info_exclude
1171        }
1172} else {
1173        proc have_info_exclude {} {
1174                return [file readable [gitdir info exclude]]
1175        }
1176}
1177
1178proc rescan_stage2 {fd after} {
1179        global rescan_active buf_rdi buf_rdf buf_rlo
1180
1181        if {$fd ne {}} {
1182                read $fd
1183                if {![eof $fd]} return
1184                close $fd
1185        }
1186
1187        set ls_others [list --exclude-per-directory=.gitignore]
1188        if {[have_info_exclude]} {
1189                lappend ls_others "--exclude-from=[gitdir info exclude]"
1190        }
1191        set user_exclude [get_config core.excludesfile]
1192        if {$user_exclude ne {} && [file readable $user_exclude]} {
1193                lappend ls_others "--exclude-from=$user_exclude"
1194        }
1195
1196        set buf_rdi {}
1197        set buf_rdf {}
1198        set buf_rlo {}
1199
1200        set rescan_active 3
1201        ui_status [mc "Scanning for modified files ..."]
1202        set fd_di [git_read diff-index --cached -z [PARENT]]
1203        set fd_df [git_read diff-files -z]
1204        set fd_lo [eval git_read ls-files --others -z $ls_others]
1205
1206        fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1207        fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1208        fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1209        fileevent $fd_di readable [list read_diff_index $fd_di $after]
1210        fileevent $fd_df readable [list read_diff_files $fd_df $after]
1211        fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1212}
1213
1214proc load_message {file} {
1215        global ui_comm
1216
1217        set f [gitdir $file]
1218        if {[file isfile $f]} {
1219                if {[catch {set fd [open $f r]}]} {
1220                        return 0
1221                }
1222                fconfigure $fd -eofchar {}
1223                set content [string trim [read $fd]]
1224                close $fd
1225                regsub -all -line {[ \r\t]+$} $content {} content
1226                $ui_comm delete 0.0 end
1227                $ui_comm insert end $content
1228                return 1
1229        }
1230        return 0
1231}
1232
1233proc read_diff_index {fd after} {
1234        global buf_rdi
1235
1236        append buf_rdi [read $fd]
1237        set c 0
1238        set n [string length $buf_rdi]
1239        while {$c < $n} {
1240                set z1 [string first "\0" $buf_rdi $c]
1241                if {$z1 == -1} break
1242                incr z1
1243                set z2 [string first "\0" $buf_rdi $z1]
1244                if {$z2 == -1} break
1245
1246                incr c
1247                set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1248                set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1249                merge_state \
1250                        [encoding convertfrom $p] \
1251                        [lindex $i 4]? \
1252                        [list [lindex $i 0] [lindex $i 2]] \
1253                        [list]
1254                set c $z2
1255                incr c
1256        }
1257        if {$c < $n} {
1258                set buf_rdi [string range $buf_rdi $c end]
1259        } else {
1260                set buf_rdi {}
1261        }
1262
1263        rescan_done $fd buf_rdi $after
1264}
1265
1266proc read_diff_files {fd after} {
1267        global buf_rdf
1268
1269        append buf_rdf [read $fd]
1270        set c 0
1271        set n [string length $buf_rdf]
1272        while {$c < $n} {
1273                set z1 [string first "\0" $buf_rdf $c]
1274                if {$z1 == -1} break
1275                incr z1
1276                set z2 [string first "\0" $buf_rdf $z1]
1277                if {$z2 == -1} break
1278
1279                incr c
1280                set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1281                set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1282                merge_state \
1283                        [encoding convertfrom $p] \
1284                        ?[lindex $i 4] \
1285                        [list] \
1286                        [list [lindex $i 0] [lindex $i 2]]
1287                set c $z2
1288                incr c
1289        }
1290        if {$c < $n} {
1291                set buf_rdf [string range $buf_rdf $c end]
1292        } else {
1293                set buf_rdf {}
1294        }
1295
1296        rescan_done $fd buf_rdf $after
1297}
1298
1299proc read_ls_others {fd after} {
1300        global buf_rlo
1301
1302        append buf_rlo [read $fd]
1303        set pck [split $buf_rlo "\0"]
1304        set buf_rlo [lindex $pck end]
1305        foreach p [lrange $pck 0 end-1] {
1306                set p [encoding convertfrom $p]
1307                if {[string index $p end] eq {/}} {
1308                        set p [string range $p 0 end-1]
1309                }
1310                merge_state $p ?O
1311        }
1312        rescan_done $fd buf_rlo $after
1313}
1314
1315proc rescan_done {fd buf after} {
1316        global rescan_active current_diff_path
1317        global file_states repo_config
1318        upvar $buf to_clear
1319
1320        if {![eof $fd]} return
1321        set to_clear {}
1322        close $fd
1323        if {[incr rescan_active -1] > 0} return
1324
1325        prune_selection
1326        unlock_index
1327        display_all_files
1328        if {$current_diff_path ne {}} reshow_diff
1329        uplevel #0 $after
1330}
1331
1332proc prune_selection {} {
1333        global file_states selected_paths
1334
1335        foreach path [array names selected_paths] {
1336                if {[catch {set still_here $file_states($path)}]} {
1337                        unset selected_paths($path)
1338                }
1339        }
1340}
1341
1342######################################################################
1343##
1344## ui helpers
1345
1346proc mapicon {w state path} {
1347        global all_icons
1348
1349        if {[catch {set r $all_icons($state$w)}]} {
1350                puts "error: no icon for $w state={$state} $path"
1351                return file_plain
1352        }
1353        return $r
1354}
1355
1356proc mapdesc {state path} {
1357        global all_descs
1358
1359        if {[catch {set r $all_descs($state)}]} {
1360                puts "error: no desc for state={$state} $path"
1361                return $state
1362        }
1363        return $r
1364}
1365
1366proc ui_status {msg} {
1367        global main_status
1368        if {[info exists main_status]} {
1369                $main_status show $msg
1370        }
1371}
1372
1373proc ui_ready {{test {}}} {
1374        global main_status
1375        if {[info exists main_status]} {
1376                $main_status show [mc "Ready."] $test
1377        }
1378}
1379
1380proc escape_path {path} {
1381        regsub -all {\\} $path "\\\\" path
1382        regsub -all "\n" $path "\\n" path
1383        return $path
1384}
1385
1386proc short_path {path} {
1387        return [escape_path [lindex [file split $path] end]]
1388}
1389
1390set next_icon_id 0
1391set null_sha1 [string repeat 0 40]
1392
1393proc merge_state {path new_state {head_info {}} {index_info {}}} {
1394        global file_states next_icon_id null_sha1
1395
1396        set s0 [string index $new_state 0]
1397        set s1 [string index $new_state 1]
1398
1399        if {[catch {set info $file_states($path)}]} {
1400                set state __
1401                set icon n[incr next_icon_id]
1402        } else {
1403                set state [lindex $info 0]
1404                set icon [lindex $info 1]
1405                if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1406                if {$index_info eq {}} {set index_info [lindex $info 3]}
1407        }
1408
1409        if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1410        elseif {$s0 eq {_}} {set s0 _}
1411
1412        if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1413        elseif {$s1 eq {_}} {set s1 _}
1414
1415        if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1416                set head_info [list 0 $null_sha1]
1417        } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1418                && $head_info eq {}} {
1419                set head_info $index_info
1420        }
1421
1422        set file_states($path) [list $s0$s1 $icon \
1423                $head_info $index_info \
1424                ]
1425        return $state
1426}
1427
1428proc display_file_helper {w path icon_name old_m new_m} {
1429        global file_lists
1430
1431        if {$new_m eq {_}} {
1432                set lno [lsearch -sorted -exact $file_lists($w) $path]
1433                if {$lno >= 0} {
1434                        set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1435                        incr lno
1436                        $w conf -state normal
1437                        $w delete $lno.0 [expr {$lno + 1}].0
1438                        $w conf -state disabled
1439                }
1440        } elseif {$old_m eq {_} && $new_m ne {_}} {
1441                lappend file_lists($w) $path
1442                set file_lists($w) [lsort -unique $file_lists($w)]
1443                set lno [lsearch -sorted -exact $file_lists($w) $path]
1444                incr lno
1445                $w conf -state normal
1446                $w image create $lno.0 \
1447                        -align center -padx 5 -pady 1 \
1448                        -name $icon_name \
1449                        -image [mapicon $w $new_m $path]
1450                $w insert $lno.1 "[escape_path $path]\n"
1451                $w conf -state disabled
1452        } elseif {$old_m ne $new_m} {
1453                $w conf -state normal
1454                $w image conf $icon_name -image [mapicon $w $new_m $path]
1455                $w conf -state disabled
1456        }
1457}
1458
1459proc display_file {path state} {
1460        global file_states selected_paths
1461        global ui_index ui_workdir
1462
1463        set old_m [merge_state $path $state]
1464        set s $file_states($path)
1465        set new_m [lindex $s 0]
1466        set icon_name [lindex $s 1]
1467
1468        set o [string index $old_m 0]
1469        set n [string index $new_m 0]
1470        if {$o eq {U}} {
1471                set o _
1472        }
1473        if {$n eq {U}} {
1474                set n _
1475        }
1476        display_file_helper     $ui_index $path $icon_name $o $n
1477
1478        if {[string index $old_m 0] eq {U}} {
1479                set o U
1480        } else {
1481                set o [string index $old_m 1]
1482        }
1483        if {[string index $new_m 0] eq {U}} {
1484                set n U
1485        } else {
1486                set n [string index $new_m 1]
1487        }
1488        display_file_helper     $ui_workdir $path $icon_name $o $n
1489
1490        if {$new_m eq {__}} {
1491                unset file_states($path)
1492                catch {unset selected_paths($path)}
1493        }
1494}
1495
1496proc display_all_files_helper {w path icon_name m} {
1497        global file_lists
1498
1499        lappend file_lists($w) $path
1500        set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1501        $w image create end \
1502                -align center -padx 5 -pady 1 \
1503                -name $icon_name \
1504                -image [mapicon $w $m $path]
1505        $w insert end "[escape_path $path]\n"
1506}
1507
1508proc display_all_files {} {
1509        global ui_index ui_workdir
1510        global file_states file_lists
1511        global last_clicked
1512
1513        $ui_index conf -state normal
1514        $ui_workdir conf -state normal
1515
1516        $ui_index delete 0.0 end
1517        $ui_workdir delete 0.0 end
1518        set last_clicked {}
1519
1520        set file_lists($ui_index) [list]
1521        set file_lists($ui_workdir) [list]
1522
1523        foreach path [lsort [array names file_states]] {
1524                set s $file_states($path)
1525                set m [lindex $s 0]
1526                set icon_name [lindex $s 1]
1527
1528                set s [string index $m 0]
1529                if {$s ne {U} && $s ne {_}} {
1530                        display_all_files_helper $ui_index $path \
1531                                $icon_name $s
1532                }
1533
1534                if {[string index $m 0] eq {U}} {
1535                        set s U
1536                } else {
1537                        set s [string index $m 1]
1538                }
1539                if {$s ne {_}} {
1540                        display_all_files_helper $ui_workdir $path \
1541                                $icon_name $s
1542                }
1543        }
1544
1545        $ui_index conf -state disabled
1546        $ui_workdir conf -state disabled
1547}
1548
1549######################################################################
1550##
1551## icons
1552
1553set filemask {
1554#define mask_width 14
1555#define mask_height 15
1556static unsigned char mask_bits[] = {
1557   0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1558   0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1559   0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1560}
1561
1562image create bitmap file_plain -background white -foreground black -data {
1563#define plain_width 14
1564#define plain_height 15
1565static unsigned char plain_bits[] = {
1566   0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1567   0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1568   0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1569} -maskdata $filemask
1570
1571image create bitmap file_mod -background white -foreground blue -data {
1572#define mod_width 14
1573#define mod_height 15
1574static unsigned char mod_bits[] = {
1575   0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1576   0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1577   0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1578} -maskdata $filemask
1579
1580image create bitmap file_fulltick -background white -foreground "#007000" -data {
1581#define file_fulltick_width 14
1582#define file_fulltick_height 15
1583static unsigned char file_fulltick_bits[] = {
1584   0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1585   0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1586   0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1587} -maskdata $filemask
1588
1589image create bitmap file_parttick -background white -foreground "#005050" -data {
1590#define parttick_width 14
1591#define parttick_height 15
1592static unsigned char parttick_bits[] = {
1593   0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1594   0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1595   0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1596} -maskdata $filemask
1597
1598image create bitmap file_question -background white -foreground black -data {
1599#define file_question_width 14
1600#define file_question_height 15
1601static unsigned char file_question_bits[] = {
1602   0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1603   0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1604   0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1605} -maskdata $filemask
1606
1607image create bitmap file_removed -background white -foreground red -data {
1608#define file_removed_width 14
1609#define file_removed_height 15
1610static unsigned char file_removed_bits[] = {
1611   0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1612   0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1613   0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1614} -maskdata $filemask
1615
1616image create bitmap file_merge -background white -foreground blue -data {
1617#define file_merge_width 14
1618#define file_merge_height 15
1619static unsigned char file_merge_bits[] = {
1620   0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1621   0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1622   0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1623} -maskdata $filemask
1624
1625image create bitmap file_statechange -background white -foreground green -data {
1626#define file_merge_width 14
1627#define file_merge_height 15
1628static unsigned char file_statechange_bits[] = {
1629   0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1630   0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1631   0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1632} -maskdata $filemask
1633
1634set ui_index .vpane.files.index.list
1635set ui_workdir .vpane.files.workdir.list
1636
1637set all_icons(_$ui_index)   file_plain
1638set all_icons(A$ui_index)   file_fulltick
1639set all_icons(M$ui_index)   file_fulltick
1640set all_icons(D$ui_index)   file_removed
1641set all_icons(U$ui_index)   file_merge
1642set all_icons(T$ui_index)   file_statechange
1643
1644set all_icons(_$ui_workdir) file_plain
1645set all_icons(M$ui_workdir) file_mod
1646set all_icons(D$ui_workdir) file_question
1647set all_icons(U$ui_workdir) file_merge
1648set all_icons(O$ui_workdir) file_plain
1649set all_icons(T$ui_workdir) file_statechange
1650
1651set max_status_desc 0
1652foreach i {
1653                {__ {mc "Unmodified"}}
1654
1655                {_M {mc "Modified, not staged"}}
1656                {M_ {mc "Staged for commit"}}
1657                {MM {mc "Portions staged for commit"}}
1658                {MD {mc "Staged for commit, missing"}}
1659
1660                {_T {mc "File type changed, not staged"}}
1661                {T_ {mc "File type changed, staged"}}
1662
1663                {_O {mc "Untracked, not staged"}}
1664                {A_ {mc "Staged for commit"}}
1665                {AM {mc "Portions staged for commit"}}
1666                {AD {mc "Staged for commit, missing"}}
1667
1668                {_D {mc "Missing"}}
1669                {D_ {mc "Staged for removal"}}
1670                {DO {mc "Staged for removal, still present"}}
1671
1672                {_U {mc "Requires merge resolution"}}
1673                {U_ {mc "Requires merge resolution"}}
1674                {UU {mc "Requires merge resolution"}}
1675                {UM {mc "Requires merge resolution"}}
1676                {UD {mc "Requires merge resolution"}}
1677                {UT {mc "Requires merge resolution"}}
1678        } {
1679        set text [eval [lindex $i 1]]
1680        if {$max_status_desc < [string length $text]} {
1681                set max_status_desc [string length $text]
1682        }
1683        set all_descs([lindex $i 0]) $text
1684}
1685unset i
1686
1687######################################################################
1688##
1689## util
1690
1691proc scrollbar2many {list mode args} {
1692        foreach w $list {eval $w $mode $args}
1693}
1694
1695proc many2scrollbar {list mode sb top bottom} {
1696        $sb set $top $bottom
1697        foreach w $list {$w $mode moveto $top}
1698}
1699
1700proc incr_font_size {font {amt 1}} {
1701        set sz [font configure $font -size]
1702        incr sz $amt
1703        font configure $font -size $sz
1704        font configure ${font}bold -size $sz
1705        font configure ${font}italic -size $sz
1706}
1707
1708######################################################################
1709##
1710## ui commands
1711
1712set starting_gitk_msg [mc "Starting gitk... please wait..."]
1713
1714proc do_gitk {revs} {
1715        # -- Always start gitk through whatever we were loaded with.  This
1716        #    lets us bypass using shell process on Windows systems.
1717        #
1718        set exe [_which gitk -script]
1719        set cmd [list [info nameofexecutable] $exe]
1720        if {$exe eq {}} {
1721                error_popup [mc "Couldn't find gitk in PATH"]
1722        } else {
1723                global env
1724
1725                if {[info exists env(GIT_DIR)]} {
1726                        set old_GIT_DIR $env(GIT_DIR)
1727                } else {
1728                        set old_GIT_DIR {}
1729                }
1730
1731                set pwd [pwd]
1732                cd [file dirname [gitdir]]
1733                set env(GIT_DIR) [file tail [gitdir]]
1734
1735                eval exec $cmd $revs &
1736
1737                if {$old_GIT_DIR eq {}} {
1738                        unset env(GIT_DIR)
1739                } else {
1740                        set env(GIT_DIR) $old_GIT_DIR
1741                }
1742                cd $pwd
1743
1744                ui_status $::starting_gitk_msg
1745                after 10000 {
1746                        ui_ready $starting_gitk_msg
1747                }
1748        }
1749}
1750
1751set is_quitting 0
1752
1753proc do_quit {} {
1754        global ui_comm is_quitting repo_config commit_type
1755        global GITGUI_BCK_exists GITGUI_BCK_i
1756        global ui_comm_spell
1757
1758        if {$is_quitting} return
1759        set is_quitting 1
1760
1761        if {[winfo exists $ui_comm]} {
1762                # -- Stash our current commit buffer.
1763                #
1764                set save [gitdir GITGUI_MSG]
1765                if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1766                        file rename -force [gitdir GITGUI_BCK] $save
1767                        set GITGUI_BCK_exists 0
1768                } else {
1769                        set msg [string trim [$ui_comm get 0.0 end]]
1770                        regsub -all -line {[ \r\t]+$} $msg {} msg
1771                        if {(![string match amend* $commit_type]
1772                                || [$ui_comm edit modified])
1773                                && $msg ne {}} {
1774                                catch {
1775                                        set fd [open $save w]
1776                                        puts -nonewline $fd $msg
1777                                        close $fd
1778                                }
1779                        } else {
1780                                catch {file delete $save}
1781                        }
1782                }
1783
1784                # -- Cancel our spellchecker if its running.
1785                #
1786                if {[info exists ui_comm_spell]} {
1787                        $ui_comm_spell stop
1788                }
1789
1790                # -- Remove our editor backup, its not needed.
1791                #
1792                after cancel $GITGUI_BCK_i
1793                if {$GITGUI_BCK_exists} {
1794                        catch {file delete [gitdir GITGUI_BCK]}
1795                }
1796
1797                # -- Stash our current window geometry into this repository.
1798                #
1799                set cfg_geometry [list]
1800                lappend cfg_geometry [wm geometry .]
1801                lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
1802                lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
1803                if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1804                        set rc_geometry {}
1805                }
1806                if {$cfg_geometry ne $rc_geometry} {
1807                        catch {git config gui.geometry $cfg_geometry}
1808                }
1809        }
1810
1811        destroy .
1812}
1813
1814proc do_rescan {} {
1815        rescan ui_ready
1816}
1817
1818proc do_commit {} {
1819        commit_tree
1820}
1821
1822proc next_diff {} {
1823        global next_diff_p next_diff_w next_diff_i
1824        show_diff $next_diff_p $next_diff_w $next_diff_i
1825}
1826
1827proc toggle_or_diff {w x y} {
1828        global file_states file_lists current_diff_path ui_index ui_workdir
1829        global last_clicked selected_paths
1830
1831        set pos [split [$w index @$x,$y] .]
1832        set lno [lindex $pos 0]
1833        set col [lindex $pos 1]
1834        set path [lindex $file_lists($w) [expr {$lno - 1}]]
1835        if {$path eq {}} {
1836                set last_clicked {}
1837                return
1838        }
1839
1840        set last_clicked [list $w $lno]
1841        array unset selected_paths
1842        $ui_index tag remove in_sel 0.0 end
1843        $ui_workdir tag remove in_sel 0.0 end
1844
1845        # Do not stage files with conflicts
1846        if {[info exists file_states($path)]} {
1847                set state [lindex $file_states($path) 0]
1848                if {[string first {U} $state] >= 0} {
1849                        set col 1
1850                }
1851        }
1852
1853        if {$col == 0 && $y > 1} {
1854                set i [expr {$lno-1}]
1855                set ll [expr {[llength $file_lists($w)]-1}]
1856
1857                if {$i == $ll && $i == 0} {
1858                        set after {reshow_diff;}
1859                } else {
1860                        global next_diff_p next_diff_w next_diff_i
1861
1862                        set next_diff_w $w
1863
1864                        if {$i < $ll} {
1865                                set i [expr {$i + 1}]
1866                                set next_diff_i $i
1867                        } else {
1868                                set next_diff_i $i
1869                                set i [expr {$i - 1}]
1870                        }
1871
1872                        set next_diff_p [lindex $file_lists($w) $i]
1873
1874                        if {$next_diff_p ne {} && $current_diff_path ne {}} {
1875                                set after {next_diff;}
1876                        } else {
1877                                set after {}
1878                        }
1879                }
1880
1881                if {$w eq $ui_index} {
1882                        update_indexinfo \
1883                                "Unstaging [short_path $path] from commit" \
1884                                [list $path] \
1885                                [concat $after [list ui_ready]]
1886                } elseif {$w eq $ui_workdir} {
1887                        update_index \
1888                                "Adding [short_path $path]" \
1889                                [list $path] \
1890                                [concat $after [list ui_ready]]
1891                }
1892        } else {
1893                show_diff $path $w $lno
1894        }
1895}
1896
1897proc add_one_to_selection {w x y} {
1898        global file_lists last_clicked selected_paths
1899
1900        set lno [lindex [split [$w index @$x,$y] .] 0]
1901        set path [lindex $file_lists($w) [expr {$lno - 1}]]
1902        if {$path eq {}} {
1903                set last_clicked {}
1904                return
1905        }
1906
1907        if {$last_clicked ne {}
1908                && [lindex $last_clicked 0] ne $w} {
1909                array unset selected_paths
1910                [lindex $last_clicked 0] tag remove in_sel 0.0 end
1911        }
1912
1913        set last_clicked [list $w $lno]
1914        if {[catch {set in_sel $selected_paths($path)}]} {
1915                set in_sel 0
1916        }
1917        if {$in_sel} {
1918                unset selected_paths($path)
1919                $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
1920        } else {
1921                set selected_paths($path) 1
1922                $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1923        }
1924}
1925
1926proc add_range_to_selection {w x y} {
1927        global file_lists last_clicked selected_paths
1928
1929        if {[lindex $last_clicked 0] ne $w} {
1930                toggle_or_diff $w $x $y
1931                return
1932        }
1933
1934        set lno [lindex [split [$w index @$x,$y] .] 0]
1935        set lc [lindex $last_clicked 1]
1936        if {$lc < $lno} {
1937                set begin $lc
1938                set end $lno
1939        } else {
1940                set begin $lno
1941                set end $lc
1942        }
1943
1944        foreach path [lrange $file_lists($w) \
1945                [expr {$begin - 1}] \
1946                [expr {$end - 1}]] {
1947                set selected_paths($path) 1
1948        }
1949        $w tag add in_sel $begin.0 [expr {$end + 1}].0
1950}
1951
1952proc show_more_context {} {
1953        global repo_config
1954        if {$repo_config(gui.diffcontext) < 99} {
1955                incr repo_config(gui.diffcontext)
1956                reshow_diff
1957        }
1958}
1959
1960proc show_less_context {} {
1961        global repo_config
1962        if {$repo_config(gui.diffcontext) > 1} {
1963                incr repo_config(gui.diffcontext) -1
1964                reshow_diff
1965        }
1966}
1967
1968######################################################################
1969##
1970## ui construction
1971
1972load_config 0
1973apply_config
1974set ui_comm {}
1975
1976# -- Menu Bar
1977#
1978menu .mbar -tearoff 0
1979.mbar add cascade -label [mc Repository] -menu .mbar.repository
1980.mbar add cascade -label [mc Edit] -menu .mbar.edit
1981if {[is_enabled branch]} {
1982        .mbar add cascade -label [mc Branch] -menu .mbar.branch
1983}
1984if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1985        .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
1986}
1987if {[is_enabled transport]} {
1988        .mbar add cascade -label [mc Merge] -menu .mbar.merge
1989        .mbar add cascade -label [mc Remote] -menu .mbar.remote
1990}
1991. configure -menu .mbar
1992
1993# -- Repository Menu
1994#
1995menu .mbar.repository
1996
1997.mbar.repository add command \
1998        -label [mc "Browse Current Branch's Files"] \
1999        -command {browser::new $current_branch}
2000set ui_browse_current [.mbar.repository index last]
2001.mbar.repository add command \
2002        -label [mc "Browse Branch Files..."] \
2003        -command browser_open::dialog
2004.mbar.repository add separator
2005
2006.mbar.repository add command \
2007        -label [mc "Visualize Current Branch's History"] \
2008        -command {do_gitk $current_branch}
2009set ui_visualize_current [.mbar.repository index last]
2010.mbar.repository add command \
2011        -label [mc "Visualize All Branch History"] \
2012        -command {do_gitk --all}
2013.mbar.repository add separator
2014
2015proc current_branch_write {args} {
2016        global current_branch
2017        .mbar.repository entryconf $::ui_browse_current \
2018                -label [mc "Browse %s's Files" $current_branch]
2019        .mbar.repository entryconf $::ui_visualize_current \
2020                -label [mc "Visualize %s's History" $current_branch]
2021}
2022trace add variable current_branch write current_branch_write
2023
2024if {[is_enabled multicommit]} {
2025        .mbar.repository add command -label [mc "Database Statistics"] \
2026                -command do_stats
2027
2028        .mbar.repository add command -label [mc "Compress Database"] \
2029                -command do_gc
2030
2031        .mbar.repository add command -label [mc "Verify Database"] \
2032                -command do_fsck_objects
2033
2034        .mbar.repository add separator
2035
2036        if {[is_Cygwin]} {
2037                .mbar.repository add command \
2038                        -label [mc "Create Desktop Icon"] \
2039                        -command do_cygwin_shortcut
2040        } elseif {[is_Windows]} {
2041                .mbar.repository add command \
2042                        -label [mc "Create Desktop Icon"] \
2043                        -command do_windows_shortcut
2044        } elseif {[is_MacOSX]} {
2045                .mbar.repository add command \
2046                        -label [mc "Create Desktop Icon"] \
2047                        -command do_macosx_app
2048        }
2049}
2050
2051if {[is_MacOSX]} {
2052        proc ::tk::mac::Quit {args} { do_quit }
2053} else {
2054        .mbar.repository add command -label [mc Quit] \
2055                -command do_quit \
2056                -accelerator $M1T-Q
2057}
2058
2059# -- Edit Menu
2060#
2061menu .mbar.edit
2062.mbar.edit add command -label [mc Undo] \
2063        -command {catch {[focus] edit undo}} \
2064        -accelerator $M1T-Z
2065.mbar.edit add command -label [mc Redo] \
2066        -command {catch {[focus] edit redo}} \
2067        -accelerator $M1T-Y
2068.mbar.edit add separator
2069.mbar.edit add command -label [mc Cut] \
2070        -command {catch {tk_textCut [focus]}} \
2071        -accelerator $M1T-X
2072.mbar.edit add command -label [mc Copy] \
2073        -command {catch {tk_textCopy [focus]}} \
2074        -accelerator $M1T-C
2075.mbar.edit add command -label [mc Paste] \
2076        -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2077        -accelerator $M1T-V
2078.mbar.edit add command -label [mc Delete] \
2079        -command {catch {[focus] delete sel.first sel.last}} \
2080        -accelerator Del
2081.mbar.edit add separator
2082.mbar.edit add command -label [mc "Select All"] \
2083        -command {catch {[focus] tag add sel 0.0 end}} \
2084        -accelerator $M1T-A
2085
2086# -- Branch Menu
2087#
2088if {[is_enabled branch]} {
2089        menu .mbar.branch
2090
2091        .mbar.branch add command -label [mc "Create..."] \
2092                -command branch_create::dialog \
2093                -accelerator $M1T-N
2094        lappend disable_on_lock [list .mbar.branch entryconf \
2095                [.mbar.branch index last] -state]
2096
2097        .mbar.branch add command -label [mc "Checkout..."] \
2098                -command branch_checkout::dialog \
2099                -accelerator $M1T-O
2100        lappend disable_on_lock [list .mbar.branch entryconf \
2101                [.mbar.branch index last] -state]
2102
2103        .mbar.branch add command -label [mc "Rename..."] \
2104                -command branch_rename::dialog
2105        lappend disable_on_lock [list .mbar.branch entryconf \
2106                [.mbar.branch index last] -state]
2107
2108        .mbar.branch add command -label [mc "Delete..."] \
2109                -command branch_delete::dialog
2110        lappend disable_on_lock [list .mbar.branch entryconf \
2111                [.mbar.branch index last] -state]
2112
2113        .mbar.branch add command -label [mc "Reset..."] \
2114                -command merge::reset_hard
2115        lappend disable_on_lock [list .mbar.branch entryconf \
2116                [.mbar.branch index last] -state]
2117}
2118
2119# -- Commit Menu
2120#
2121if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2122        menu .mbar.commit
2123
2124        .mbar.commit add radiobutton \
2125                -label [mc "New Commit"] \
2126                -command do_select_commit_type \
2127                -variable selected_commit_type \
2128                -value new
2129        lappend disable_on_lock \
2130                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2131
2132        .mbar.commit add radiobutton \
2133                -label [mc "Amend Last Commit"] \
2134                -command do_select_commit_type \
2135                -variable selected_commit_type \
2136                -value amend
2137        lappend disable_on_lock \
2138                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2139
2140        .mbar.commit add separator
2141
2142        .mbar.commit add command -label [mc Rescan] \
2143                -command do_rescan \
2144                -accelerator F5
2145        lappend disable_on_lock \
2146                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2147
2148        .mbar.commit add command -label [mc "Stage To Commit"] \
2149                -command do_add_selection \
2150                -accelerator $M1T-T
2151        lappend disable_on_lock \
2152                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2153
2154        .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2155                -command do_add_all \
2156                -accelerator $M1T-I
2157        lappend disable_on_lock \
2158                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2159
2160        .mbar.commit add command -label [mc "Unstage From Commit"] \
2161                -command do_unstage_selection
2162        lappend disable_on_lock \
2163                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2164
2165        .mbar.commit add command -label [mc "Revert Changes"] \
2166                -command do_revert_selection
2167        lappend disable_on_lock \
2168                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2169
2170        .mbar.commit add separator
2171
2172        .mbar.commit add command -label [mc "Show Less Context"] \
2173                -command show_less_context \
2174                -accelerator $M1T-\-
2175
2176        .mbar.commit add command -label [mc "Show More Context"] \
2177                -command show_more_context \
2178                -accelerator $M1T-=
2179
2180        .mbar.commit add separator
2181
2182        .mbar.commit add command -label [mc "Sign Off"] \
2183                -command do_signoff \
2184                -accelerator $M1T-S
2185
2186        .mbar.commit add command -label [mc Commit@@verb] \
2187                -command do_commit \
2188                -accelerator $M1T-Return
2189        lappend disable_on_lock \
2190                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2191}
2192
2193# -- Merge Menu
2194#
2195if {[is_enabled branch]} {
2196        menu .mbar.merge
2197        .mbar.merge add command -label [mc "Local Merge..."] \
2198                -command merge::dialog \
2199                -accelerator $M1T-M
2200        lappend disable_on_lock \
2201                [list .mbar.merge entryconf [.mbar.merge index last] -state]
2202        .mbar.merge add command -label [mc "Abort Merge..."] \
2203                -command merge::reset_hard
2204        lappend disable_on_lock \
2205                [list .mbar.merge entryconf [.mbar.merge index last] -state]
2206}
2207
2208# -- Transport Menu
2209#
2210if {[is_enabled transport]} {
2211        menu .mbar.remote
2212
2213        .mbar.remote add command \
2214                -label [mc "Push..."] \
2215                -command do_push_anywhere \
2216                -accelerator $M1T-P
2217        .mbar.remote add command \
2218                -label [mc "Delete..."] \
2219                -command remote_branch_delete::dialog
2220}
2221
2222if {[is_MacOSX]} {
2223        # -- Apple Menu (Mac OS X only)
2224        #
2225        .mbar add cascade -label Apple -menu .mbar.apple
2226        menu .mbar.apple
2227
2228        .mbar.apple add command -label [mc "About %s" [appname]] \
2229                -command do_about
2230        .mbar.apple add separator
2231        .mbar.apple add command \
2232                -label [mc "Preferences..."] \
2233                -command do_options \
2234                -accelerator $M1T-,
2235        bind . <$M1B-,> do_options
2236} else {
2237        # -- Edit Menu
2238        #
2239        .mbar.edit add separator
2240        .mbar.edit add command -label [mc "Options..."] \
2241                -command do_options
2242}
2243
2244# -- Help Menu
2245#
2246.mbar add cascade -label [mc Help] -menu .mbar.help
2247menu .mbar.help
2248
2249if {![is_MacOSX]} {
2250        .mbar.help add command -label [mc "About %s" [appname]] \
2251                -command do_about
2252}
2253
2254set browser {}
2255catch {set browser $repo_config(instaweb.browser)}
2256set doc_path [file dirname [gitexec]]
2257set doc_path [file join $doc_path Documentation index.html]
2258
2259if {[is_Cygwin]} {
2260        set doc_path [exec cygpath --mixed $doc_path]
2261}
2262
2263if {$browser eq {}} {
2264        if {[is_MacOSX]} {
2265                set browser open
2266        } elseif {[is_Cygwin]} {
2267                set program_files [file dirname [exec cygpath --windir]]
2268                set program_files [file join $program_files {Program Files}]
2269                set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
2270                set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
2271                if {[file exists $firefox]} {
2272                        set browser $firefox
2273                } elseif {[file exists $ie]} {
2274                        set browser $ie
2275                }
2276                unset program_files firefox ie
2277        }
2278}
2279
2280if {[file isfile $doc_path]} {
2281        set doc_url "file:$doc_path"
2282} else {
2283        set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2284}
2285
2286if {$browser ne {}} {
2287        .mbar.help add command -label [mc "Online Documentation"] \
2288                -command [list exec $browser $doc_url &]
2289}
2290unset browser doc_path doc_url
2291
2292# -- Standard bindings
2293#
2294wm protocol . WM_DELETE_WINDOW do_quit
2295bind all <$M1B-Key-q> do_quit
2296bind all <$M1B-Key-Q> do_quit
2297bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2298bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2299
2300set subcommand_args {}
2301proc usage {} {
2302        puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2303        exit 1
2304}
2305
2306# -- Not a normal commit type invocation?  Do that instead!
2307#
2308switch -- $subcommand {
2309browser -
2310blame {
2311        if {$subcommand eq "blame"} {
2312                set subcommand_args {[--line=<num>] rev? path}
2313        } else {
2314                set subcommand_args {rev? path}
2315        }
2316        if {$argv eq {}} usage
2317        set head {}
2318        set path {}
2319        set jump_spec {}
2320        set is_path 0
2321        foreach a $argv {
2322                if {$is_path || [file exists $_prefix$a]} {
2323                        if {$path ne {}} usage
2324                        set path $_prefix$a
2325                        break
2326                } elseif {$a eq {--}} {
2327                        if {$path ne {}} {
2328                                if {$head ne {}} usage
2329                                set head $path
2330                                set path {}
2331                        }
2332                        set is_path 1
2333                } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2334                        if {$jump_spec ne {} || $head ne {}} usage
2335                        set jump_spec [list $lnum]
2336                } elseif {$head eq {}} {
2337                        if {$head ne {}} usage
2338                        set head $a
2339                        set is_path 1
2340                } else {
2341                        usage
2342                }
2343        }
2344        unset is_path
2345
2346        if {$head ne {} && $path eq {}} {
2347                set path $_prefix$head
2348                set head {}
2349        }
2350
2351        if {$head eq {}} {
2352                load_current_branch
2353        } else {
2354                if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2355                        if {[catch {
2356                                        set head [git rev-parse --verify $head]
2357                                } err]} {
2358                                puts stderr $err
2359                                exit 1
2360                        }
2361                }
2362                set current_branch $head
2363        }
2364
2365        switch -- $subcommand {
2366        browser {
2367                if {$jump_spec ne {}} usage
2368                if {$head eq {}} {
2369                        if {$path ne {} && [file isdirectory $path]} {
2370                                set head $current_branch
2371                        } else {
2372                                set head $path
2373                                set path {}
2374                        }
2375                }
2376                browser::new $head $path
2377        }
2378        blame   {
2379                if {$head eq {} && ![file exists $path]} {
2380                        puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2381                        exit 1
2382                }
2383                blame::new $head $path $jump_spec
2384        }
2385        }
2386        return
2387}
2388citool -
2389gui {
2390        if {[llength $argv] != 0} {
2391                puts -nonewline stderr "usage: $argv0"
2392                if {$subcommand ne {gui}
2393                        && [file tail $argv0] ne "git-$subcommand"} {
2394                        puts -nonewline stderr " $subcommand"
2395                }
2396                puts stderr {}
2397                exit 1
2398        }
2399        # fall through to setup UI for commits
2400}
2401default {
2402        puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2403        exit 1
2404}
2405}
2406
2407# -- Branch Control
2408#
2409frame .branch \
2410        -borderwidth 1 \
2411        -relief sunken
2412label .branch.l1 \
2413        -text [mc "Current Branch:"] \
2414        -anchor w \
2415        -justify left
2416label .branch.cb \
2417        -textvariable current_branch \
2418        -anchor w \
2419        -justify left
2420pack .branch.l1 -side left
2421pack .branch.cb -side left -fill x
2422pack .branch -side top -fill x
2423
2424# -- Main Window Layout
2425#
2426panedwindow .vpane -orient horizontal
2427panedwindow .vpane.files -orient vertical
2428.vpane add .vpane.files -sticky nsew -height 100 -width 200
2429pack .vpane -anchor n -side top -fill both -expand 1
2430
2431# -- Index File List
2432#
2433frame .vpane.files.index -height 100 -width 200
2434label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2435        -background lightgreen -foreground black
2436text $ui_index -background white -foreground black \
2437        -borderwidth 0 \
2438        -width 20 -height 10 \
2439        -wrap none \
2440        -cursor $cursor_ptr \
2441        -xscrollcommand {.vpane.files.index.sx set} \
2442        -yscrollcommand {.vpane.files.index.sy set} \
2443        -state disabled
2444scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2445scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2446pack .vpane.files.index.title -side top -fill x
2447pack .vpane.files.index.sx -side bottom -fill x
2448pack .vpane.files.index.sy -side right -fill y
2449pack $ui_index -side left -fill both -expand 1
2450
2451# -- Working Directory File List
2452#
2453frame .vpane.files.workdir -height 100 -width 200
2454label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2455        -background lightsalmon -foreground black
2456text $ui_workdir -background white -foreground black \
2457        -borderwidth 0 \
2458        -width 20 -height 10 \
2459        -wrap none \
2460        -cursor $cursor_ptr \
2461        -xscrollcommand {.vpane.files.workdir.sx set} \
2462        -yscrollcommand {.vpane.files.workdir.sy set} \
2463        -state disabled
2464scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2465scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2466pack .vpane.files.workdir.title -side top -fill x
2467pack .vpane.files.workdir.sx -side bottom -fill x
2468pack .vpane.files.workdir.sy -side right -fill y
2469pack $ui_workdir -side left -fill both -expand 1
2470
2471.vpane.files add .vpane.files.workdir -sticky nsew
2472.vpane.files add .vpane.files.index -sticky nsew
2473
2474foreach i [list $ui_index $ui_workdir] {
2475        rmsel_tag $i
2476        $i tag conf in_diff -background [$i tag cget in_sel -background]
2477}
2478unset i
2479
2480# -- Diff and Commit Area
2481#
2482frame .vpane.lower -height 300 -width 400
2483frame .vpane.lower.commarea
2484frame .vpane.lower.diff -relief sunken -borderwidth 1
2485pack .vpane.lower.diff -fill both -expand 1
2486pack .vpane.lower.commarea -side bottom -fill x
2487.vpane add .vpane.lower -sticky nsew
2488
2489# -- Commit Area Buttons
2490#
2491frame .vpane.lower.commarea.buttons
2492label .vpane.lower.commarea.buttons.l -text {} \
2493        -anchor w \
2494        -justify left
2495pack .vpane.lower.commarea.buttons.l -side top -fill x
2496pack .vpane.lower.commarea.buttons -side left -fill y
2497
2498button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2499        -command do_rescan
2500pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2501lappend disable_on_lock \
2502        {.vpane.lower.commarea.buttons.rescan conf -state}
2503
2504button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2505        -command do_add_all
2506pack .vpane.lower.commarea.buttons.incall -side top -fill x
2507lappend disable_on_lock \
2508        {.vpane.lower.commarea.buttons.incall conf -state}
2509
2510button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2511        -command do_signoff
2512pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2513
2514button .vpane.lower.commarea.buttons.commit -text [mc Commit@@verb] \
2515        -command do_commit
2516pack .vpane.lower.commarea.buttons.commit -side top -fill x
2517lappend disable_on_lock \
2518        {.vpane.lower.commarea.buttons.commit conf -state}
2519
2520button .vpane.lower.commarea.buttons.push -text [mc Push] \
2521        -command do_push_anywhere
2522pack .vpane.lower.commarea.buttons.push -side top -fill x
2523
2524# -- Commit Message Buffer
2525#
2526frame .vpane.lower.commarea.buffer
2527frame .vpane.lower.commarea.buffer.header
2528set ui_comm .vpane.lower.commarea.buffer.t
2529set ui_coml .vpane.lower.commarea.buffer.header.l
2530radiobutton .vpane.lower.commarea.buffer.header.new \
2531        -text [mc "New Commit"] \
2532        -command do_select_commit_type \
2533        -variable selected_commit_type \
2534        -value new
2535lappend disable_on_lock \
2536        [list .vpane.lower.commarea.buffer.header.new conf -state]
2537radiobutton .vpane.lower.commarea.buffer.header.amend \
2538        -text [mc "Amend Last Commit"] \
2539        -command do_select_commit_type \
2540        -variable selected_commit_type \
2541        -value amend
2542lappend disable_on_lock \
2543        [list .vpane.lower.commarea.buffer.header.amend conf -state]
2544label $ui_coml \
2545        -anchor w \
2546        -justify left
2547proc trace_commit_type {varname args} {
2548        global ui_coml commit_type
2549        switch -glob -- $commit_type {
2550        initial       {set txt [mc "Initial Commit Message:"]}
2551        amend         {set txt [mc "Amended Commit Message:"]}
2552        amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2553        amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2554        merge         {set txt [mc "Merge Commit Message:"]}
2555        *             {set txt [mc "Commit Message:"]}
2556        }
2557        $ui_coml conf -text $txt
2558}
2559trace add variable commit_type write trace_commit_type
2560pack $ui_coml -side left -fill x
2561pack .vpane.lower.commarea.buffer.header.amend -side right
2562pack .vpane.lower.commarea.buffer.header.new -side right
2563
2564text $ui_comm -background white -foreground black \
2565        -borderwidth 1 \
2566        -undo true \
2567        -maxundo 20 \
2568        -autoseparators true \
2569        -relief sunken \
2570        -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2571        -font font_diff \
2572        -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2573scrollbar .vpane.lower.commarea.buffer.sby \
2574        -command [list $ui_comm yview]
2575pack .vpane.lower.commarea.buffer.header -side top -fill x
2576pack .vpane.lower.commarea.buffer.sby -side right -fill y
2577pack $ui_comm -side left -fill y
2578pack .vpane.lower.commarea.buffer -side left -fill y
2579
2580# -- Commit Message Buffer Context Menu
2581#
2582set ctxm .vpane.lower.commarea.buffer.ctxm
2583menu $ctxm -tearoff 0
2584$ctxm add command \
2585        -label [mc Cut] \
2586        -command {tk_textCut $ui_comm}
2587$ctxm add command \
2588        -label [mc Copy] \
2589        -command {tk_textCopy $ui_comm}
2590$ctxm add command \
2591        -label [mc Paste] \
2592        -command {tk_textPaste $ui_comm}
2593$ctxm add command \
2594        -label [mc Delete] \
2595        -command {$ui_comm delete sel.first sel.last}
2596$ctxm add separator
2597$ctxm add command \
2598        -label [mc "Select All"] \
2599        -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2600$ctxm add command \
2601        -label [mc "Copy All"] \
2602        -command {
2603                $ui_comm tag add sel 0.0 end
2604                tk_textCopy $ui_comm
2605                $ui_comm tag remove sel 0.0 end
2606        }
2607$ctxm add separator
2608$ctxm add command \
2609        -label [mc "Sign Off"] \
2610        -command do_signoff
2611set ui_comm_ctxm $ctxm
2612
2613# -- Diff Header
2614#
2615proc trace_current_diff_path {varname args} {
2616        global current_diff_path diff_actions file_states
2617        if {$current_diff_path eq {}} {
2618                set s {}
2619                set f {}
2620                set p {}
2621                set o disabled
2622        } else {
2623                set p $current_diff_path
2624                set s [mapdesc [lindex $file_states($p) 0] $p]
2625                set f [mc "File:"]
2626                set p [escape_path $p]
2627                set o normal
2628        }
2629
2630        .vpane.lower.diff.header.status configure -text $s
2631        .vpane.lower.diff.header.file configure -text $f
2632        .vpane.lower.diff.header.path configure -text $p
2633        foreach w $diff_actions {
2634                uplevel #0 $w $o
2635        }
2636}
2637trace add variable current_diff_path write trace_current_diff_path
2638
2639frame .vpane.lower.diff.header -background gold
2640label .vpane.lower.diff.header.status \
2641        -background gold \
2642        -foreground black \
2643        -width $max_status_desc \
2644        -anchor w \
2645        -justify left
2646label .vpane.lower.diff.header.file \
2647        -background gold \
2648        -foreground black \
2649        -anchor w \
2650        -justify left
2651label .vpane.lower.diff.header.path \
2652        -background gold \
2653        -foreground black \
2654        -anchor w \
2655        -justify left
2656pack .vpane.lower.diff.header.status -side left
2657pack .vpane.lower.diff.header.file -side left
2658pack .vpane.lower.diff.header.path -fill x
2659set ctxm .vpane.lower.diff.header.ctxm
2660menu $ctxm -tearoff 0
2661$ctxm add command \
2662        -label [mc Copy] \
2663        -command {
2664                clipboard clear
2665                clipboard append \
2666                        -format STRING \
2667                        -type STRING \
2668                        -- $current_diff_path
2669        }
2670lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2671bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2672
2673# -- Diff Body
2674#
2675frame .vpane.lower.diff.body
2676set ui_diff .vpane.lower.diff.body.t
2677text $ui_diff -background white -foreground black \
2678        -borderwidth 0 \
2679        -width 80 -height 15 -wrap none \
2680        -font font_diff \
2681        -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2682        -yscrollcommand {.vpane.lower.diff.body.sby set} \
2683        -state disabled
2684scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2685        -command [list $ui_diff xview]
2686scrollbar .vpane.lower.diff.body.sby -orient vertical \
2687        -command [list $ui_diff yview]
2688pack .vpane.lower.diff.body.sbx -side bottom -fill x
2689pack .vpane.lower.diff.body.sby -side right -fill y
2690pack $ui_diff -side left -fill both -expand 1
2691pack .vpane.lower.diff.header -side top -fill x
2692pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2693
2694$ui_diff tag conf d_cr -elide true
2695$ui_diff tag conf d_@ -foreground blue -font font_diffbold
2696$ui_diff tag conf d_+ -foreground {#00a000}
2697$ui_diff tag conf d_- -foreground red
2698
2699$ui_diff tag conf d_++ -foreground {#00a000}
2700$ui_diff tag conf d_-- -foreground red
2701$ui_diff tag conf d_+s \
2702        -foreground {#00a000} \
2703        -background {#e2effa}
2704$ui_diff tag conf d_-s \
2705        -foreground red \
2706        -background {#e2effa}
2707$ui_diff tag conf d_s+ \
2708        -foreground {#00a000} \
2709        -background ivory1
2710$ui_diff tag conf d_s- \
2711        -foreground red \
2712        -background ivory1
2713
2714$ui_diff tag conf d<<<<<<< \
2715        -foreground orange \
2716        -font font_diffbold
2717$ui_diff tag conf d======= \
2718        -foreground orange \
2719        -font font_diffbold
2720$ui_diff tag conf d>>>>>>> \
2721        -foreground orange \
2722        -font font_diffbold
2723
2724$ui_diff tag raise sel
2725
2726# -- Diff Body Context Menu
2727#
2728
2729proc create_common_diff_popup {ctxm} {
2730        $ctxm add command \
2731                -label [mc "Show Less Context"] \
2732                -command show_less_context
2733        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2734        $ctxm add command \
2735                -label [mc "Show More Context"] \
2736                -command show_more_context
2737        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2738        $ctxm add separator
2739        $ctxm add command \
2740                -label [mc Refresh] \
2741                -command reshow_diff
2742        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2743        $ctxm add command \
2744                -label [mc Copy] \
2745                -command {tk_textCopy $ui_diff}
2746        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2747        $ctxm add command \
2748                -label [mc "Select All"] \
2749                -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2750        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2751        $ctxm add command \
2752                -label [mc "Copy All"] \
2753                -command {
2754                        $ui_diff tag add sel 0.0 end
2755                        tk_textCopy $ui_diff
2756                        $ui_diff tag remove sel 0.0 end
2757                }
2758        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2759        $ctxm add separator
2760        $ctxm add command \
2761                -label [mc "Decrease Font Size"] \
2762                -command {incr_font_size font_diff -1}
2763        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2764        $ctxm add command \
2765                -label [mc "Increase Font Size"] \
2766                -command {incr_font_size font_diff 1}
2767        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2768        $ctxm add separator
2769        $ctxm add command -label [mc "Options..."] \
2770                -command do_options
2771}
2772
2773set ctxm .vpane.lower.diff.body.ctxm
2774menu $ctxm -tearoff 0
2775$ctxm add command \
2776        -label [mc "Apply/Reverse Hunk"] \
2777        -command {apply_hunk $cursorX $cursorY}
2778set ui_diff_applyhunk [$ctxm index last]
2779lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2780$ctxm add command \
2781        -label [mc "Apply/Reverse Line"] \
2782        -command {apply_line $cursorX $cursorY; do_rescan}
2783set ui_diff_applyline [$ctxm index last]
2784lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
2785$ctxm add separator
2786create_common_diff_popup $ctxm
2787
2788set ctxmmg .vpane.lower.diff.body.ctxmmg
2789menu $ctxmmg -tearoff 0
2790$ctxmmg add command \
2791        -label [mc "Run Merge Tool"] \
2792        -command {merge_resolve_tool}
2793lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2794$ctxmmg add separator
2795$ctxmmg add command \
2796        -label [mc "Use Remote Version"] \
2797        -command {merge_resolve_one 3}
2798lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2799$ctxmmg add command \
2800        -label [mc "Use Local Version"] \
2801        -command {merge_resolve_one 2}
2802lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2803$ctxmmg add command \
2804        -label [mc "Revert To Base"] \
2805        -command {merge_resolve_one 1}
2806lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2807$ctxmmg add separator
2808create_common_diff_popup $ctxmmg
2809
2810proc popup_diff_menu {ctxm ctxmmg x y X Y} {
2811        global current_diff_path file_states
2812        set ::cursorX $x
2813        set ::cursorY $y
2814        if {[info exists file_states($current_diff_path)]} {
2815                set state [lindex $file_states($current_diff_path) 0]
2816        } else {
2817                set state {__}
2818        }
2819        if {[string first {U} $state] >= 0} {
2820                tk_popup $ctxmmg $X $Y
2821        } else {
2822                if {$::ui_index eq $::current_diff_side} {
2823                        set l [mc "Unstage Hunk From Commit"]
2824                        set t [mc "Unstage Line From Commit"]
2825                } else {
2826                        set l [mc "Stage Hunk For Commit"]
2827                        set t [mc "Stage Line For Commit"]
2828                }
2829                if {$::is_3way_diff
2830                        || $current_diff_path eq {}
2831                        || {__} eq $state
2832                        || {_O} eq $state
2833                        || {_T} eq $state
2834                        || {T_} eq $state} {
2835                        set s disabled
2836                } else {
2837                        set s normal
2838                }
2839                $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
2840                $ctxm entryconf $::ui_diff_applyline -state $s -label $t
2841                tk_popup $ctxm $X $Y
2842        }
2843}
2844bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
2845
2846# -- Status Bar
2847#
2848set main_status [::status_bar::new .status]
2849pack .status -anchor w -side bottom -fill x
2850$main_status show [mc "Initializing..."]
2851
2852# -- Load geometry
2853#
2854catch {
2855set gm $repo_config(gui.geometry)
2856wm geometry . [lindex $gm 0]
2857.vpane sash place 0 \
2858        [lindex $gm 1] \
2859        [lindex [.vpane sash coord 0] 1]
2860.vpane.files sash place 0 \
2861        [lindex [.vpane.files sash coord 0] 0] \
2862        [lindex $gm 2]
2863unset gm
2864}
2865
2866# -- Key Bindings
2867#
2868bind $ui_comm <$M1B-Key-Return> {do_commit;break}
2869bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
2870bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
2871bind $ui_comm <$M1B-Key-i> {do_add_all;break}
2872bind $ui_comm <$M1B-Key-I> {do_add_all;break}
2873bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
2874bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
2875bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
2876bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
2877bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
2878bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
2879bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2880bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2881bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
2882bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
2883bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
2884bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
2885bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
2886
2887bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
2888bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
2889bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
2890bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
2891bind $ui_diff <$M1B-Key-v> {break}
2892bind $ui_diff <$M1B-Key-V> {break}
2893bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2894bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2895bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
2896bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
2897bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
2898bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
2899bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
2900bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
2901bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
2902bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
2903bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
2904bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
2905bind $ui_diff <Button-1>   {focus %W}
2906
2907if {[is_enabled branch]} {
2908        bind . <$M1B-Key-n> branch_create::dialog
2909        bind . <$M1B-Key-N> branch_create::dialog
2910        bind . <$M1B-Key-o> branch_checkout::dialog
2911        bind . <$M1B-Key-O> branch_checkout::dialog
2912        bind . <$M1B-Key-m> merge::dialog
2913        bind . <$M1B-Key-M> merge::dialog
2914}
2915if {[is_enabled transport]} {
2916        bind . <$M1B-Key-p> do_push_anywhere
2917        bind . <$M1B-Key-P> do_push_anywhere
2918}
2919
2920bind .   <Key-F5>     do_rescan
2921bind .   <$M1B-Key-r> do_rescan
2922bind .   <$M1B-Key-R> do_rescan
2923bind .   <$M1B-Key-s> do_signoff
2924bind .   <$M1B-Key-S> do_signoff
2925bind .   <$M1B-Key-t> do_add_selection
2926bind .   <$M1B-Key-T> do_add_selection
2927bind .   <$M1B-Key-i> do_add_all
2928bind .   <$M1B-Key-I> do_add_all
2929bind .   <$M1B-Key-minus> {show_less_context;break}
2930bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
2931bind .   <$M1B-Key-equal> {show_more_context;break}
2932bind .   <$M1B-Key-plus> {show_more_context;break}
2933bind .   <$M1B-Key-KP_Add> {show_more_context;break}
2934bind .   <$M1B-Key-Return> do_commit
2935foreach i [list $ui_index $ui_workdir] {
2936        bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
2937        bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
2938        bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
2939}
2940unset i
2941
2942set file_lists($ui_index) [list]
2943set file_lists($ui_workdir) [list]
2944
2945wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
2946focus -force $ui_comm
2947
2948# -- Warn the user about environmental problems.  Cygwin's Tcl
2949#    does *not* pass its env array onto any processes it spawns.
2950#    This means that git processes get none of our environment.
2951#
2952if {[is_Cygwin]} {
2953        set ignored_env 0
2954        set suggest_user {}
2955        set msg [mc "Possible environment issues exist.
2956
2957The following environment variables are probably
2958going to be ignored by any Git subprocess run
2959by %s:
2960
2961" [appname]]
2962        foreach name [array names env] {
2963                switch -regexp -- $name {
2964                {^GIT_INDEX_FILE$} -
2965                {^GIT_OBJECT_DIRECTORY$} -
2966                {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
2967                {^GIT_DIFF_OPTS$} -
2968                {^GIT_EXTERNAL_DIFF$} -
2969                {^GIT_PAGER$} -
2970                {^GIT_TRACE$} -
2971                {^GIT_CONFIG$} -
2972                {^GIT_CONFIG_LOCAL$} -
2973                {^GIT_(AUTHOR|COMMITTER)_DATE$} {
2974                        append msg " - $name\n"
2975                        incr ignored_env
2976                }
2977                {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
2978                        append msg " - $name\n"
2979                        incr ignored_env
2980                        set suggest_user $name
2981                }
2982                }
2983        }
2984        if {$ignored_env > 0} {
2985                append msg [mc "
2986This is due to a known issue with the
2987Tcl binary distributed by Cygwin."]
2988
2989                if {$suggest_user ne {}} {
2990                        append msg [mc "
2991
2992A good replacement for %s
2993is placing values for the user.name and
2994user.email settings into your personal
2995~/.gitconfig file.
2996" $suggest_user]
2997                }
2998                warn_popup $msg
2999        }
3000        unset ignored_env msg suggest_user name
3001}
3002
3003# -- Only initialize complex UI if we are going to stay running.
3004#
3005if {[is_enabled transport]} {
3006        load_all_remotes
3007
3008        set n [.mbar.remote index end]
3009        populate_push_menu
3010        populate_fetch_menu
3011        set n [expr {[.mbar.remote index end] - $n}]
3012        if {$n > 0} {
3013                if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3014                .mbar.remote insert $n separator
3015        }
3016        unset n
3017}
3018
3019if {[winfo exists $ui_comm]} {
3020        set GITGUI_BCK_exists [load_message GITGUI_BCK]
3021
3022        # -- If both our backup and message files exist use the
3023        #    newer of the two files to initialize the buffer.
3024        #
3025        if {$GITGUI_BCK_exists} {
3026                set m [gitdir GITGUI_MSG]
3027                if {[file isfile $m]} {
3028                        if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3029                                catch {file delete [gitdir GITGUI_MSG]}
3030                        } else {
3031                                $ui_comm delete 0.0 end
3032                                $ui_comm edit reset
3033                                $ui_comm edit modified false
3034                                catch {file delete [gitdir GITGUI_BCK]}
3035                                set GITGUI_BCK_exists 0
3036                        }
3037                }
3038                unset m
3039        }
3040
3041        proc backup_commit_buffer {} {
3042                global ui_comm GITGUI_BCK_exists
3043
3044                set m [$ui_comm edit modified]
3045                if {$m || $GITGUI_BCK_exists} {
3046                        set msg [string trim [$ui_comm get 0.0 end]]
3047                        regsub -all -line {[ \r\t]+$} $msg {} msg
3048
3049                        if {$msg eq {}} {
3050                                if {$GITGUI_BCK_exists} {
3051                                        catch {file delete [gitdir GITGUI_BCK]}
3052                                        set GITGUI_BCK_exists 0
3053                                }
3054                        } elseif {$m} {
3055                                catch {
3056                                        set fd [open [gitdir GITGUI_BCK] w]
3057                                        puts -nonewline $fd $msg
3058                                        close $fd
3059                                        set GITGUI_BCK_exists 1
3060                                }
3061                        }
3062
3063                        $ui_comm edit modified false
3064                }
3065
3066                set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3067        }
3068
3069        backup_commit_buffer
3070
3071        # -- If the user has aspell available we can drive it
3072        #    in pipe mode to spellcheck the commit message.
3073        #
3074        set spell_cmd [list |]
3075        set spell_dict [get_config gui.spellingdictionary]
3076        lappend spell_cmd aspell
3077        if {$spell_dict ne {}} {
3078                lappend spell_cmd --master=$spell_dict
3079        }
3080        lappend spell_cmd --mode=none
3081        lappend spell_cmd --encoding=utf-8
3082        lappend spell_cmd pipe
3083        if {$spell_dict eq {none}
3084         || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3085                bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3086        } else {
3087                set ui_comm_spell [spellcheck::init \
3088                        $spell_fd \
3089                        $ui_comm \
3090                        $ui_comm_ctxm \
3091                ]
3092        }
3093        unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3094}
3095
3096lock_index begin-read
3097if {![winfo ismapped .]} {
3098        wm deiconify .
3099}
3100after 1 do_rescan
3101if {[is_enabled multicommit]} {
3102        after 1000 hint_gc
3103}