Andrew's git - gitweb.git/blob

   1#!/usr/bin/perl
   2# Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3# License: GPL v2 or later
   4use 5.008;
   5use warnings;
   6use strict;
   7use vars qw/    $AUTHOR $VERSION
   8                $sha1 $sha1_short $_revision $_repository
   9                $_q $_authors $_authors_prog %users/;
  10$AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11$VERSION = '@@GIT_VERSION@@';
  12
  13use Carp qw/croak/;
  14use Digest::MD5;
  15use IO::File qw//;
  16use File::Basename qw/dirname basename/;
  17use File::Path qw/mkpath/;
  18use File::Spec;
  19use File::Find;
  20use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  21use IPC::Open3;
  22use Memoize;
  23
  24use Git::SVN;
  25use Git::SVN::Editor;
  26use Git::SVN::Fetcher;
  27use Git::SVN::Ra;
  28use Git::SVN::Prompt;
  29use Git::SVN::Log;
  30use Git::SVN::Migration;
  31
  32use Git::SVN::Utils qw(
  33        fatal
  34        can_compress
  35        canonicalize_path
  36        canonicalize_url
  37        join_paths
  38        add_path_to_url
  39        join_paths
  40);
  41
  42use Git qw(
  43        git_cmd_try
  44        command
  45        command_oneline
  46        command_noisy
  47        command_output_pipe
  48        command_close_pipe
  49        command_bidi_pipe
  50        command_close_bidi_pipe
  51);
  52
  53BEGIN {
  54        Memoize::memoize 'Git::config';
  55        Memoize::memoize 'Git::config_bool';
  56}
  57
  58
  59# From which subdir have we been invoked?
  60my $cmd_dir_prefix = eval {
  61        command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  62} || '';
  63
  64$Git::SVN::Ra::_log_window_size = 100;
  65
  66if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  67        $ENV{SVN_SSH} = $ENV{GIT_SSH};
  68}
  69
  70if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  71        $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  72        $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  73}
  74
  75$Git::SVN::Log::TZ = $ENV{TZ};
  76$ENV{TZ} = 'UTC';
  77$| = 1; # unbuffer STDOUT
  78
  79# All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  80# repository decides to close the connection which we expect to be kept alive.
  81$SIG{PIPE} = 'IGNORE';
  82
  83# Given a dot separated version number, "subtract" it from
  84# the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  85# is at least at the version the caller asked for.
  86sub compare_svn_version {
  87        my (@ours) = split(/\./, $SVN::Core::VERSION);
  88        my (@theirs) = split(/\./, $_[0]);
  89        my ($i, $diff);
  90
  91        for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  92                $diff = $ours[$i] - $theirs[$i];
  93                return $diff if ($diff);
  94        }
  95        return 1 if ($i < @ours);
  96        return -1 if ($i < @theirs);
  97        return 0;
  98}
  99
 100sub _req_svn {
 101        require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
 102        require SVN::Ra;
 103        require SVN::Delta;
 104        if (::compare_svn_version('1.1.0') < 0) {
 105                fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
 106        }
 107}
 108
 109$sha1 = qr/[a-f\d]{40}/;
 110$sha1_short = qr/[a-f\d]{4,40}/;
 111my ($_stdin, $_help, $_edit,
 112        $_message, $_file, $_branch_dest,
 113        $_template, $_shared,
 114        $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 115        $_before, $_after,
 116        $_merge, $_strategy, $_preserve_merges, $_dry_run, $_parents, $_local,
 117        $_prefix, $_no_checkout, $_url, $_verbose,
 118        $_commit_url, $_tag, $_merge_info, $_interactive, $_set_svn_props);
 119
 120# This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 121sub opt_prefix { return $_prefix || '' }
 122
 123$Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 124$_q ||= 0;
 125my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 126                    'config-dir=s' => \$Git::SVN::Ra::config_dir,
 127                    'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 128                    'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 129                    'include-paths=s' => \$Git::SVN::Fetcher::_include_regex,
 130                    'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 131my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 132                'authors-file|A=s' => \$_authors,
 133                'authors-prog=s' => \$_authors_prog,
 134                'repack:i' => \$Git::SVN::_repack,
 135                'noMetadata' => \$Git::SVN::_no_metadata,
 136                'useSvmProps' => \$Git::SVN::_use_svm_props,
 137                'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 138                'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 139                'no-checkout' => \$_no_checkout,
 140                'quiet|q+' => \$_q,
 141                'repack-flags|repack-args|repack-opts=s' =>
 142                   \$Git::SVN::_repack_flags,
 143                'use-log-author' => \$Git::SVN::_use_log_author,
 144                'add-author-from' => \$Git::SVN::_add_author_from,
 145                'localtime' => \$Git::SVN::_localtime,
 146                %remote_opts );
 147
 148my ($_trunk, @_tags, @_branches, $_stdlayout);
 149my %icv;
 150my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 151                  'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 152                  'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 153                  'stdlayout|s' => \$_stdlayout,
 154                  'minimize-url|m!' => \$Git::SVN::_minimize_url,
 155                  'no-metadata' => sub { $icv{noMetadata} = 1 },
 156                  'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 157                  'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 158                  'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 159                  'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 160                  %remote_opts );
 161my %cmt_opts = ( 'edit|e' => \$_edit,
 162                'rmdir' => \$Git::SVN::Editor::_rmdir,
 163                'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 164                'l=i' => \$Git::SVN::Editor::_rename_limit,
 165                'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 166);
 167
 168my %cmd = (
 169        fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 170                        { 'revision|r=s' => \$_revision,
 171                          'fetch-all|all' => \$_fetch_all,
 172                          'parent|p' => \$_fetch_parent,
 173                           %fc_opts } ],
 174        clone => [ \&cmd_clone, "Initialize and fetch revisions",
 175                        { 'revision|r=s' => \$_revision,
 176                          'preserve-empty-dirs' =>
 177                                \$Git::SVN::Fetcher::_preserve_empty_dirs,
 178                          'placeholder-filename=s' =>
 179                                \$Git::SVN::Fetcher::_placeholder_filename,
 180                           %fc_opts, %init_opts } ],
 181        init => [ \&cmd_init, "Initialize a repo for tracking" .
 182                          " (requires URL argument)",
 183                          \%init_opts ],
 184        'multi-init' => [ \&cmd_multi_init,
 185                          "Deprecated alias for ".
 186                          "'$0 init -T<trunk> -b<branches> -t<tags>'",
 187                          \%init_opts ],
 188        dcommit => [ \&cmd_dcommit,
 189                     'Commit several diffs to merge with upstream',
 190                        { 'merge|m|M' => \$_merge,
 191                          'strategy|s=s' => \$_strategy,
 192                          'verbose|v' => \$_verbose,
 193                          'dry-run|n' => \$_dry_run,
 194                          'fetch-all|all' => \$_fetch_all,
 195                          'commit-url=s' => \$_commit_url,
 196                          'set-svn-props=s' => \$_set_svn_props,
 197                          'revision|r=i' => \$_revision,
 198                          'no-rebase' => \$_no_rebase,
 199                          'mergeinfo=s' => \$_merge_info,
 200                          'interactive|i' => \$_interactive,
 201                        %cmt_opts, %fc_opts } ],
 202        branch => [ \&cmd_branch,
 203                    'Create a branch in the SVN repository',
 204                    { 'message|m=s' => \$_message,
 205                      'destination|d=s' => \$_branch_dest,
 206                      'dry-run|n' => \$_dry_run,
 207                      'parents' => \$_parents,
 208                      'tag|t' => \$_tag,
 209                      'username=s' => \$Git::SVN::Prompt::_username,
 210                      'commit-url=s' => \$_commit_url } ],
 211        tag => [ sub { $_tag = 1; cmd_branch(@_) },
 212                 'Create a tag in the SVN repository',
 213                 { 'message|m=s' => \$_message,
 214                   'destination|d=s' => \$_branch_dest,
 215                   'dry-run|n' => \$_dry_run,
 216                   'parents' => \$_parents,
 217                   'username=s' => \$Git::SVN::Prompt::_username,
 218                   'commit-url=s' => \$_commit_url } ],
 219        'set-tree' => [ \&cmd_set_tree,
 220                        "Set an SVN repository to a git tree-ish",
 221                        { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 222        'create-ignore' => [ \&cmd_create_ignore,
 223                             'Create a .gitignore per svn:ignore',
 224                             { 'revision|r=i' => \$_revision
 225                             } ],
 226        'mkdirs' => [ \&cmd_mkdirs ,
 227                      "recreate empty directories after a checkout",
 228                      { 'revision|r=i' => \$_revision } ],
 229        'propget' => [ \&cmd_propget,
 230                       'Print the value of a property on a file or directory',
 231                       { 'revision|r=i' => \$_revision } ],
 232        'propset' => [ \&cmd_propset,
 233                       'Set the value of a property on a file or directory - will be set on commit',
 234                       {} ],
 235        'proplist' => [ \&cmd_proplist,
 236                       'List all properties of a file or directory',
 237                       { 'revision|r=i' => \$_revision } ],
 238        'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 239                        { 'revision|r=i' => \$_revision
 240                        } ],
 241        'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 242                        { 'revision|r=i' => \$_revision
 243                        } ],
 244        'multi-fetch' => [ \&cmd_multi_fetch,
 245                           "Deprecated alias for $0 fetch --all",
 246                           { 'revision|r=s' => \$_revision, %fc_opts } ],
 247        'migrate' => [ sub { },
 248                       # no-op, we automatically run this anyways,
 249                       'Migrate configuration/metadata/layout from
 250                        previous versions of git-svn',
 251                       { 'minimize' => \$Git::SVN::Migration::_minimize,
 252                         %remote_opts } ],
 253        'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 254                        { 'limit=i' => \$Git::SVN::Log::limit,
 255                          'revision|r=s' => \$_revision,
 256                          'verbose|v' => \$Git::SVN::Log::verbose,
 257                          'incremental' => \$Git::SVN::Log::incremental,
 258                          'oneline' => \$Git::SVN::Log::oneline,
 259                          'show-commit' => \$Git::SVN::Log::show_commit,
 260                          'non-recursive' => \$Git::SVN::Log::non_recursive,
 261                          'authors-file|A=s' => \$_authors,
 262                          'color' => \$Git::SVN::Log::color,
 263                          'pager=s' => \$Git::SVN::Log::pager
 264                        } ],
 265        'find-rev' => [ \&cmd_find_rev,
 266                        "Translate between SVN revision numbers and tree-ish",
 267                        { 'B|before' => \$_before,
 268                          'A|after' => \$_after } ],
 269        'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 270                        { 'merge|m|M' => \$_merge,
 271                          'verbose|v' => \$_verbose,
 272                          'strategy|s=s' => \$_strategy,
 273                          'local|l' => \$_local,
 274                          'fetch-all|all' => \$_fetch_all,
 275                          'dry-run|n' => \$_dry_run,
 276                          'preserve-merges|p' => \$_preserve_merges,
 277                          %fc_opts } ],
 278        'commit-diff' => [ \&cmd_commit_diff,
 279                           'Commit a diff between two trees',
 280                        { 'message|m=s' => \$_message,
 281                          'file|F=s' => \$_file,
 282                          'revision|r=s' => \$_revision,
 283                        %cmt_opts } ],
 284        'info' => [ \&cmd_info,
 285                    "Show info about the latest SVN revision
 286                     on the current branch",
 287                    { 'url' => \$_url, } ],
 288        'blame' => [ \&Git::SVN::Log::cmd_blame,
 289                    "Show what revision and author last modified each line of a file",
 290                    { 'git-format' => \$Git::SVN::Log::_git_format } ],
 291        'reset' => [ \&cmd_reset,
 292                     "Undo fetches back to the specified SVN revision",
 293                     { 'revision|r=s' => \$_revision,
 294                       'parent|p' => \$_fetch_parent } ],
 295        'gc' => [ \&cmd_gc,
 296                  "Compress unhandled.log files in .git/svn and remove " .
 297                  "index files in .git/svn",
 298                {} ],
 299);
 300
 301use Term::ReadLine;
 302package FakeTerm;
 303sub new {
 304        my ($class, $reason) = @_;
 305        return bless \$reason, shift;
 306}
 307sub readline {
 308        my $self = shift;
 309        die "Cannot use readline on FakeTerm: $$self";
 310}
 311package main;
 312
 313my $term;
 314sub term_init {
 315        $term = eval {
 316                $ENV{"GIT_SVN_NOTTY"}
 317                        ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 318                        : new Term::ReadLine 'git-svn';
 319        };
 320        if ($@) {
 321                $term = new FakeTerm "$@: going non-interactive";
 322        }
 323}
 324
 325my $cmd;
 326for (my $i = 0; $i < @ARGV; $i++) {
 327        if (defined $cmd{$ARGV[$i]}) {
 328                $cmd = $ARGV[$i];
 329                splice @ARGV, $i, 1;
 330                last;
 331        } elsif ($ARGV[$i] eq 'help') {
 332                $cmd = $ARGV[$i+1];
 333                usage(0);
 334        }
 335};
 336
 337# make sure we're always running at the top-level working directory
 338if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 339        $ENV{GIT_DIR} ||= ".git";
 340} else {
 341        my ($git_dir, $cdup);
 342        git_cmd_try {
 343                $git_dir = command_oneline([qw/rev-parse --git-dir/]);
 344        } "Unable to find .git directory\n";
 345        git_cmd_try {
 346                $cdup = command_oneline(qw/rev-parse --show-cdup/);
 347                chomp $cdup if ($cdup);
 348                $cdup = "." unless ($cdup && length $cdup);
 349        } "Already at toplevel, but $git_dir not found\n";
 350        $ENV{GIT_DIR} = $git_dir;
 351        chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 352        $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 353}
 354
 355my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 356
 357read_git_config(\%opts);
 358if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 359        Getopt::Long::Configure('pass_through');
 360}
 361my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 362                    'minimize-connections' => \$Git::SVN::Migration::_minimize,
 363                    'id|i=s' => \$Git::SVN::default_ref_id,
 364                    'svn-remote|remote|R=s' => sub {
 365                       $Git::SVN::no_reuse_existing = 1;
 366                       $Git::SVN::default_repo_id = $_[1] });
 367exit 1 if (!$rv && $cmd && $cmd ne 'log');
 368
 369usage(0) if $_help;
 370version() if $_version;
 371usage(1) unless defined $cmd;
 372load_authors() if $_authors;
 373if (defined $_authors_prog) {
 374        $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 375}
 376
 377unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 378        Git::SVN::Migration::migration_check();
 379}
 380Git::SVN::init_vars();
 381eval {
 382        Git::SVN::verify_remotes_sanity();
 383        $cmd{$cmd}->[0]->(@ARGV);
 384        post_fetch_checkout();
 385};
 386fatal $@ if $@;
 387exit 0;
 388
 389####################### primary functions ######################
 390sub usage {
 391        my $exit = shift || 0;
 392        my $fd = $exit ? \*STDERR : \*STDOUT;
 393        print $fd <<"";
 394git-svn - bidirectional operations between a single Subversion tree and git
 395usage: git svn <command> [options] [arguments]\n
 396
 397        print $fd "Available commands:\n" unless $cmd;
 398
 399        foreach (sort keys %cmd) {
 400                next if $cmd && $cmd ne $_;
 401                next if /^multi-/; # don't show deprecated commands
 402                print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 403                foreach (sort keys %{$cmd{$_}->[2]}) {
 404                        # mixed-case options are for .git/config only
 405                        next if /[A-Z]/ && /^[a-z]+$/i;
 406                        # prints out arguments as they should be passed:
 407                        my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 408                        print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 409                                                        "--$_" : "-$_" }
 410                                                split /\|/,$_)," $x\n";
 411                }
 412        }
 413        print $fd <<"";
 414\nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 415arbitrary identifier if you're tracking multiple SVN branches/repositories in
 416one git repository and want to keep them separate.  See git-svn(1) for more
 417information.
 418
 419        exit $exit;
 420}
 421
 422sub version {
 423        ::_req_svn();
 424        print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 425        exit 0;
 426}
 427
 428sub ask {
 429        my ($prompt, %arg) = @_;
 430        my $valid_re = $arg{valid_re};
 431        my $default = $arg{default};
 432        my $resp;
 433        my $i = 0;
 434        term_init() unless $term;
 435
 436        if ( !( defined($term->IN)
 437            && defined( fileno($term->IN) )
 438            && defined( $term->OUT )
 439            && defined( fileno($term->OUT) ) ) ){
 440                return defined($default) ? $default : undef;
 441        }
 442
 443        while ($i++ < 10) {
 444                $resp = $term->readline($prompt);
 445                if (!defined $resp) { # EOF
 446                        print "\n";
 447                        return defined $default ? $default : undef;
 448                }
 449                if ($resp eq '' and defined $default) {
 450                        return $default;
 451                }
 452                if (!defined $valid_re or $resp =~ /$valid_re/) {
 453                        return $resp;
 454                }
 455        }
 456        return undef;
 457}
 458
 459sub do_git_init_db {
 460        unless (-d $ENV{GIT_DIR}) {
 461                my @init_db = ('init');
 462                push @init_db, "--template=$_template" if defined $_template;
 463                if (defined $_shared) {
 464                        if ($_shared =~ /[a-z]/) {
 465                                push @init_db, "--shared=$_shared";
 466                        } else {
 467                                push @init_db, "--shared";
 468                        }
 469                }
 470                command_noisy(@init_db);
 471                $_repository = Git->repository(Repository => ".git");
 472        }
 473        my $set;
 474        my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 475        foreach my $i (keys %icv) {
 476                die "'$set' and '$i' cannot both be set\n" if $set;
 477                next unless defined $icv{$i};
 478                command_noisy('config', "$pfx.$i", $icv{$i});
 479                $set = $i;
 480        }
 481        my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 482        command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 483                if defined $$ignore_paths_regex;
 484        my $include_paths_regex = \$Git::SVN::Fetcher::_include_regex;
 485        command_noisy('config', "$pfx.include-paths", $$include_paths_regex)
 486                if defined $$include_paths_regex;
 487        my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 488        command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 489                if defined $$ignore_refs_regex;
 490
 491        if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 492                my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 493                command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 494                command_noisy('config', "$pfx.placeholder-filename", $$fname);
 495        }
 496}
 497
 498sub init_subdir {
 499        my $repo_path = shift or return;
 500        mkpath([$repo_path]) unless -d $repo_path;
 501        chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 502        $ENV{GIT_DIR} = '.git';
 503        $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 504}
 505
 506sub cmd_clone {
 507        my ($url, $path) = @_;
 508        if (!defined $path &&
 509            (defined $_trunk || @_branches || @_tags ||
 510             defined $_stdlayout) &&
 511            $url !~ m#^[a-z\+]+://#) {
 512                $path = $url;
 513        }
 514        $path = basename($url) if !defined $path || !length $path;
 515        my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 516        cmd_init($url, $path);
 517        command_oneline('config', 'svn.authorsfile', $authors_absolute)
 518            if $_authors;
 519        Git::SVN::fetch_all($Git::SVN::default_repo_id);
 520}
 521
 522sub cmd_init {
 523        if (defined $_stdlayout) {
 524                $_trunk = 'trunk' if (!defined $_trunk);
 525                @_tags = 'tags' if (! @_tags);
 526                @_branches = 'branches' if (! @_branches);
 527        }
 528        if (defined $_trunk || @_branches || @_tags) {
 529                return cmd_multi_init(@_);
 530        }
 531        my $url = shift or die "SVN repository location required ",
 532                               "as a command-line argument\n";
 533        $url = canonicalize_url($url);
 534        init_subdir(@_);
 535        do_git_init_db();
 536
 537        if ($Git::SVN::_minimize_url eq 'unset') {
 538                $Git::SVN::_minimize_url = 0;
 539        }
 540
 541        Git::SVN->init($url);
 542}
 543
 544sub cmd_fetch {
 545        if (grep /^\d+=./, @_) {
 546                die "'<rev>=<commit>' fetch arguments are ",
 547                    "no longer supported.\n";
 548        }
 549        my ($remote) = @_;
 550        if (@_ > 1) {
 551                die "usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 552        }
 553        $Git::SVN::no_reuse_existing = undef;
 554        if ($_fetch_parent) {
 555                my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 556                unless ($gs) {
 557                        die "Unable to determine upstream SVN information from ",
 558                            "working tree history\n";
 559                }
 560                # just fetch, don't checkout.
 561                $_no_checkout = 'true';
 562                $_fetch_all ? $gs->fetch_all : $gs->fetch;
 563        } elsif ($_fetch_all) {
 564                cmd_multi_fetch();
 565        } else {
 566                $remote ||= $Git::SVN::default_repo_id;
 567                Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 568        }
 569}
 570
 571sub cmd_set_tree {
 572        my (@commits) = @_;
 573        if ($_stdin || !@commits) {
 574                print "Reading from stdin...\n";
 575                @commits = ();
 576                while (<STDIN>) {
 577                        if (/\b($sha1_short)\b/o) {
 578                                unshift @commits, $1;
 579                        }
 580                }
 581        }
 582        my @revs;
 583        foreach my $c (@commits) {
 584                my @tmp = command('rev-parse',$c);
 585                if (scalar @tmp == 1) {
 586                        push @revs, $tmp[0];
 587                } elsif (scalar @tmp > 1) {
 588                        push @revs, reverse(command('rev-list',@tmp));
 589                } else {
 590                        fatal "Failed to rev-parse $c";
 591                }
 592        }
 593        my $gs = Git::SVN->new;
 594        my ($r_last, $cmt_last) = $gs->last_rev_commit;
 595        $gs->fetch;
 596        if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 597                fatal "There are new revisions that were fetched ",
 598                      "and need to be merged (or acknowledged) ",
 599                      "before committing.\nlast rev: $r_last\n",
 600                      " current: $gs->{last_rev}";
 601        }
 602        $gs->set_tree($_) foreach @revs;
 603        print "Done committing ",scalar @revs," revisions to SVN\n";
 604        unlink $gs->{index};
 605}
 606
 607sub split_merge_info_range {
 608        my ($range) = @_;
 609        if ($range =~ /(\d+)-(\d+)/) {
 610                return (int($1), int($2));
 611        } else {
 612                return (int($range), int($range));
 613        }
 614}
 615
 616sub combine_ranges {
 617        my ($in) = @_;
 618
 619        my @fnums = ();
 620        my @arr = split(/,/, $in);
 621        for my $element (@arr) {
 622                my ($start, $end) = split_merge_info_range($element);
 623                push @fnums, $start;
 624        }
 625
 626        my @sorted = @arr [ sort {
 627                $fnums[$a] <=> $fnums[$b]
 628        } 0..$#arr ];
 629
 630        my @return = ();
 631        my $last = -1;
 632        my $first = -1;
 633        for my $element (@sorted) {
 634                my ($start, $end) = split_merge_info_range($element);
 635
 636                if ($last == -1) {
 637                        $first = $start;
 638                        $last = $end;
 639                        next;
 640                }
 641                if ($start <= $last+1) {
 642                        if ($end > $last) {
 643                                $last = $end;
 644                        }
 645                        next;
 646                }
 647                if ($first == $last) {
 648                        push @return, "$first";
 649                } else {
 650                        push @return, "$first-$last";
 651                }
 652                $first = $start;
 653                $last = $end;
 654        }
 655
 656        if ($first != -1) {
 657                if ($first == $last) {
 658                        push @return, "$first";
 659                } else {
 660                        push @return, "$first-$last";
 661                }
 662        }
 663
 664        return join(',', @return);
 665}
 666
 667sub merge_revs_into_hash {
 668        my ($hash, $minfo) = @_;
 669        my @lines = split(' ', $minfo);
 670
 671        for my $line (@lines) {
 672                my ($branchpath, $revs) = split(/:/, $line);
 673
 674                if (exists($hash->{$branchpath})) {
 675                        # Merge the two revision sets
 676                        my $combined = "$hash->{$branchpath},$revs";
 677                        $hash->{$branchpath} = combine_ranges($combined);
 678                } else {
 679                        # Just do range combining for consolidation
 680                        $hash->{$branchpath} = combine_ranges($revs);
 681                }
 682        }
 683}
 684
 685sub merge_merge_info {
 686        my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_;
 687        my %result_hash = ();
 688
 689        merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 690        merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 691
 692        delete $result_hash{$ignore_branch} if $ignore_branch;
 693
 694        my $result = '';
 695        # Sort below is for consistency's sake
 696        for my $branchname (sort keys(%result_hash)) {
 697                my $revlist = $result_hash{$branchname};
 698                $result .= "$branchname:$revlist\n"
 699        }
 700        return $result;
 701}
 702
 703sub populate_merge_info {
 704        my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 705
 706        my %parentshash;
 707        read_commit_parents(\%parentshash, $d);
 708        my @parents = @{$parentshash{$d}};
 709        if ($#parents > 0) {
 710                # Merge commit
 711                my $all_parents_ok = 1;
 712                my $aggregate_mergeinfo = '';
 713                my $rooturl = $gs->repos_root;
 714                my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/;
 715
 716                if (defined($rewritten_parent)) {
 717                        # Replace first parent with newly-rewritten version
 718                        shift @parents;
 719                        unshift @parents, $rewritten_parent;
 720                }
 721
 722                foreach my $parent (@parents) {
 723                        my ($branchurl, $svnrev, $paruuid) =
 724                                cmt_metadata($parent);
 725
 726                        unless (defined($svnrev)) {
 727                                # Should have been caught be preflight check
 728                                fatal "merge commit $d has ancestor $parent, but that change "
 729                     ."does not have git-svn metadata!";
 730                        }
 731                        unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 732                                fatal "commit $parent git-svn metadata changed mid-run!";
 733                        }
 734                        my $branchpath = $1;
 735
 736                        my $ra = Git::SVN::Ra->new($branchurl);
 737                        my (undef, undef, $props) =
 738                                $ra->get_dir(canonicalize_path("."), $svnrev);
 739                        my $par_mergeinfo = $props->{'svn:mergeinfo'};
 740                        unless (defined $par_mergeinfo) {
 741                                $par_mergeinfo = '';
 742                        }
 743                        # Merge previous mergeinfo values
 744                        $aggregate_mergeinfo =
 745                                merge_merge_info($aggregate_mergeinfo,
 746                                                                $par_mergeinfo,
 747                                                                $target_branch);
 748
 749                        next if $parent eq $parents[0]; # Skip first parent
 750                        # Add new changes being placed in tree by merge
 751                        my @cmd = (qw/rev-list --reverse/,
 752                                           $parent, qw/--not/);
 753                        foreach my $par (@parents) {
 754                                unless ($par eq $parent) {
 755                                        push @cmd, $par;
 756                                }
 757                        }
 758                        my @revsin = ();
 759                        my ($revlist, $ctx) = command_output_pipe(@cmd);
 760                        while (<$revlist>) {
 761                                my $irev = $_;
 762                                chomp $irev;
 763                                my (undef, $csvnrev, undef) =
 764                                        cmt_metadata($irev);
 765                                unless (defined $csvnrev) {
 766                                        # A child is missing SVN annotations...
 767                                        # this might be OK, or might not be.
 768                                        warn "W:child $irev is merged into revision "
 769                                                 ."$d but does not have git-svn metadata. "
 770                                                 ."This means git-svn cannot determine the "
 771                                                 ."svn revision numbers to place into the "
 772                                                 ."svn:mergeinfo property. You must ensure "
 773                                                 ."a branch is entirely committed to "
 774                                                 ."SVN before merging it in order for "
 775                                                 ."svn:mergeinfo population to function "
 776                                                 ."properly";
 777                                }
 778                                push @revsin, $csvnrev;
 779                        }
 780                        command_close_pipe($revlist, $ctx);
 781
 782                        last unless $all_parents_ok;
 783
 784                        # We now have a list of all SVN revnos which are
 785                        # merged by this particular parent. Integrate them.
 786                        next if $#revsin == -1;
 787                        my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 788                        $aggregate_mergeinfo =
 789                                merge_merge_info($aggregate_mergeinfo,
 790                                                                $newmergeinfo,
 791                                                                $target_branch);
 792                }
 793                if ($all_parents_ok and $aggregate_mergeinfo) {
 794                        return $aggregate_mergeinfo;
 795                }
 796        }
 797
 798        return undef;
 799}
 800
 801sub dcommit_rebase {
 802        my ($is_last, $current, $fetched_ref, $svn_error) = @_;
 803        my @diff;
 804
 805        if ($svn_error) {
 806                print STDERR "\nERROR from SVN:\n",
 807                                $svn_error->expanded_message, "\n";
 808        }
 809        unless ($_no_rebase) {
 810                # we always want to rebase against the current HEAD,
 811                # not any head that was passed to us
 812                @diff = command('diff-tree', $current,
 813                           $fetched_ref, '--');
 814                my @finish;
 815                if (@diff) {
 816                        @finish = rebase_cmd();
 817                        print STDERR "W: $current and ", $fetched_ref,
 818                                     " differ, using @finish:\n",
 819                                     join("\n", @diff), "\n";
 820                } elsif ($is_last) {
 821                        print "No changes between ", $current, " and ",
 822                              $fetched_ref,
 823                              "\nResetting to the latest ",
 824                              $fetched_ref, "\n";
 825                        @finish = qw/reset --mixed/;
 826                }
 827                command_noisy(@finish, $fetched_ref) if @finish;
 828        }
 829        if ($svn_error) {
 830                die "ERROR: Not all changes have been committed into SVN"
 831                        .($_no_rebase ? ".\n" : ", however the committed\n"
 832                        ."ones (if any) seem to be successfully integrated "
 833                        ."into the working tree.\n")
 834                        ."Please see the above messages for details.\n";
 835        }
 836        return @diff;
 837}
 838
 839sub cmd_dcommit {
 840        my $head = shift;
 841        command_noisy(qw/update-index --refresh/);
 842        git_cmd_try { command_oneline(qw/diff-index --quiet HEAD --/) }
 843                'Cannot dcommit with a dirty index.  Commit your changes first, '
 844                . "or stash them with `git stash'.\n";
 845        $head ||= 'HEAD';
 846
 847        my $old_head;
 848        if ($head ne 'HEAD') {
 849                $old_head = eval {
 850                        command_oneline([qw/symbolic-ref -q HEAD/])
 851                };
 852                if ($old_head) {
 853                        $old_head =~ s{^refs/heads/}{};
 854                } else {
 855                        $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 856                }
 857                command(['checkout', $head], STDERR => 0);
 858        }
 859
 860        my @refs;
 861        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 862        unless ($gs) {
 863                die "Unable to determine upstream SVN information from ",
 864                    "$head history.\nPerhaps the repository is empty.";
 865        }
 866
 867        if (defined $_commit_url) {
 868                $url = $_commit_url;
 869        } else {
 870                $url = eval { command_oneline('config', '--get',
 871                              "svn-remote.$gs->{repo_id}.commiturl") };
 872                if (!$url) {
 873                        $url = $gs->full_pushurl
 874                }
 875        }
 876
 877        my $last_rev = $_revision if defined $_revision;
 878        if ($url) {
 879                print "Committing to $url ...\n";
 880        }
 881        my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 882        if ($_no_rebase && scalar(@$linear_refs) > 1) {
 883                warn "Attempting to commit more than one change while ",
 884                     "--no-rebase is enabled.\n",
 885                     "If these changes depend on each other, re-running ",
 886                     "without --no-rebase may be required."
 887        }
 888
 889        if (defined $_interactive){
 890                my $ask_default = "y";
 891                foreach my $d (@$linear_refs){
 892                        my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 893                        while (<$fh>){
 894                                print $_;
 895                        }
 896                        command_close_pipe($fh, $ctx);
 897                        $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 898                                 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 899                                 default => $ask_default);
 900                        die "Commit this patch reply required" unless defined $_;
 901                        if (/^[nq]/i) {
 902                                exit(0);
 903                        } elsif (/^a/i) {
 904                                last;
 905                        }
 906                }
 907        }
 908
 909        my $expect_url = $url;
 910
 911        my $push_merge_info = eval {
 912                command_oneline(qw/config --get svn.pushmergeinfo/)
 913                };
 914        if (not defined($push_merge_info)
 915                        or $push_merge_info eq "false"
 916                        or $push_merge_info eq "no"
 917                        or $push_merge_info eq "never") {
 918                $push_merge_info = 0;
 919        }
 920
 921        unless (defined($_merge_info) || ! $push_merge_info) {
 922                # Preflight check of changes to ensure no issues with mergeinfo
 923                # This includes check for uncommitted-to-SVN parents
 924                # (other than the first parent, which we will handle),
 925                # information from different SVN repos, and paths
 926                # which are not underneath this repository root.
 927                my $rooturl = $gs->repos_root;
 928                foreach my $d (@$linear_refs) {
 929                        my %parentshash;
 930                        read_commit_parents(\%parentshash, $d);
 931                        my @realparents = @{$parentshash{$d}};
 932                        if ($#realparents > 0) {
 933                                # Merge commit
 934                                shift @realparents; # Remove/ignore first parent
 935                                foreach my $parent (@realparents) {
 936                                        my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 937                                        unless (defined $paruuid) {
 938                                                # A parent is missing SVN annotations...
 939                                                # abort the whole operation.
 940                                                fatal "$parent is merged into revision $d, "
 941                                                         ."but does not have git-svn metadata. "
 942                                                         ."Either dcommit the branch or use a "
 943                                                         ."local cherry-pick, FF merge, or rebase "
 944                                                         ."instead of an explicit merge commit.";
 945                                        }
 946
 947                                        unless ($paruuid eq $uuid) {
 948                                                # Parent has SVN metadata from different repository
 949                                                fatal "merge parent $parent for change $d has "
 950                                                         ."git-svn uuid $paruuid, while current change "
 951                                                         ."has uuid $uuid!";
 952                                        }
 953
 954                                        unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 955                                                # This branch is very strange indeed.
 956                                                fatal "merge parent $parent for $d is on branch "
 957                                                         ."$branchurl, which is not under the "
 958                                                         ."git-svn root $rooturl!";
 959                                        }
 960                                }
 961                        }
 962                }
 963        }
 964
 965        my $rewritten_parent;
 966        my $current_head = command_oneline(qw/rev-parse HEAD/);
 967        Git::SVN::remove_username($expect_url);
 968        if (defined($_merge_info)) {
 969                $_merge_info =~ tr{ }{\n};
 970        }
 971        while (1) {
 972                my $d = shift @$linear_refs or last;
 973                unless (defined $last_rev) {
 974                        (undef, $last_rev, undef) = cmt_metadata("$d~1");
 975                        unless (defined $last_rev) {
 976                                fatal "Unable to extract revision information ",
 977                                      "from commit $d~1";
 978                        }
 979                }
 980                if ($_dry_run) {
 981                        print "diff-tree $d~1 $d\n";
 982                } else {
 983                        my $cmt_rev;
 984
 985                        unless (defined($_merge_info) || ! $push_merge_info) {
 986                                $_merge_info = populate_merge_info($d, $gs,
 987                                                             $uuid,
 988                                                             $linear_refs,
 989                                                             $rewritten_parent);
 990                        }
 991
 992                        my %ed_opts = ( r => $last_rev,
 993                                        log => get_commit_entry($d)->{log},
 994                                        ra => Git::SVN::Ra->new($url),
 995                                        config => SVN::Core::config_get_config(
 996                                                $Git::SVN::Ra::config_dir
 997                                        ),
 998                                        tree_a => "$d~1",
 999                                        tree_b => $d,
1000                                        editor_cb => sub {
1001                                               print "Committed r$_[0]\n";
1002                                               $cmt_rev = $_[0];
1003                                        },
1004                                        mergeinfo => $_merge_info,
1005                                        svn_path => '');
1006
1007                        my $err_handler = $SVN::Error::handler;
1008                        $SVN::Error::handler = sub {
1009                                my $err = shift;
1010                                dcommit_rebase(1, $current_head, $gs->refname,
1011                                        $err);
1012                        };
1013
1014                        if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1015                                print "No changes\n$d~1 == $d\n";
1016                        } elsif ($parents->{$d} && @{$parents->{$d}}) {
1017                                $gs->{inject_parents_dcommit}->{$cmt_rev} =
1018                                                               $parents->{$d};
1019                        }
1020                        $_fetch_all ? $gs->fetch_all : $gs->fetch;
1021                        $SVN::Error::handler = $err_handler;
1022                        $last_rev = $cmt_rev;
1023                        next if $_no_rebase;
1024
1025                        my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1026                                                $gs->refname, undef);
1027
1028                        $rewritten_parent = command_oneline(qw/rev-parse/,
1029                                                        $gs->refname);
1030
1031                        if (@diff) {
1032                                $current_head = command_oneline(qw/rev-parse
1033                                                                HEAD/);
1034                                @refs = ();
1035                                my ($url_, $rev_, $uuid_, $gs_) =
1036                                              working_head_info('HEAD', \@refs);
1037                                my ($linear_refs_, $parents_) =
1038                                              linearize_history($gs_, \@refs);
1039                                if (scalar(@$linear_refs) !=
1040                                    scalar(@$linear_refs_)) {
1041                                        fatal "# of revisions changed ",
1042                                          "\nbefore:\n",
1043                                          join("\n", @$linear_refs),
1044                                          "\n\nafter:\n",
1045                                          join("\n", @$linear_refs_), "\n",
1046                                          'If you are attempting to commit ',
1047                                          "merges, try running:\n\t",
1048                                          'git rebase --interactive',
1049                                          '--preserve-merges ',
1050                                          $gs->refname,
1051                                          "\nBefore dcommitting";
1052                                }
1053                                if ($url_ ne $expect_url) {
1054                                        if ($url_ eq $gs->metadata_url) {
1055                                                print
1056                                                  "Accepting rewritten URL:",
1057                                                  " $url_\n";
1058                                        } else {
1059                                                fatal
1060                                                  "URL mismatch after rebase:",
1061                                                  " $url_ != $expect_url";
1062                                        }
1063                                }
1064                                if ($uuid_ ne $uuid) {
1065                                        fatal "uuid mismatch after rebase: ",
1066                                              "$uuid_ != $uuid";
1067                                }
1068                                # remap parents
1069                                my (%p, @l, $i);
1070                                for ($i = 0; $i < scalar @$linear_refs; $i++) {
1071                                        my $new = $linear_refs_->[$i] or next;
1072                                        $p{$new} =
1073                                                $parents->{$linear_refs->[$i]};
1074                                        push @l, $new;
1075                                }
1076                                $parents = \%p;
1077                                $linear_refs = \@l;
1078                                undef $last_rev;
1079                        }
1080                }
1081        }
1082
1083        if ($old_head) {
1084                my $new_head = command_oneline(qw/rev-parse HEAD/);
1085                my $new_is_symbolic = eval {
1086                        command_oneline(qw/symbolic-ref -q HEAD/);
1087                };
1088                if ($new_is_symbolic) {
1089                        print "dcommitted the branch ", $head, "\n";
1090                } else {
1091                        print "dcommitted on a detached HEAD because you gave ",
1092                              "a revision argument.\n",
1093                              "The rewritten commit is: ", $new_head, "\n";
1094                }
1095                command(['checkout', $old_head], STDERR => 0);
1096        }
1097
1098        unlink $gs->{index};
1099}
1100
1101sub cmd_branch {
1102        my ($branch_name, $head) = @_;
1103
1104        unless (defined $branch_name && length $branch_name) {
1105                die(($_tag ? "tag" : "branch") . " name required\n");
1106        }
1107        $head ||= 'HEAD';
1108
1109        my (undef, $rev, undef, $gs) = working_head_info($head);
1110        my $src = $gs->full_pushurl;
1111
1112        my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1113        my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1114        my $glob;
1115        if ($#{$allglobs} == 0) {
1116                $glob = $allglobs->[0];
1117        } else {
1118                unless(defined $_branch_dest) {
1119                        die "Multiple ",
1120                            $_tag ? "tag" : "branch",
1121                            " paths defined for Subversion repository.\n",
1122                            "You must specify where you want to create the ",
1123                            $_tag ? "tag" : "branch",
1124                            " with the --destination argument.\n";
1125                }
1126                foreach my $g (@{$allglobs}) {
1127                        my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1128                        if ($_branch_dest =~ /$re/) {
1129                                $glob = $g;
1130                                last;
1131                        }
1132                }
1133                unless (defined $glob) {
1134                        my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1135                        foreach my $g (@{$allglobs}) {
1136                                $g->{path}->{left} =~ /$dest_re/ or next;
1137                                if (defined $glob) {
1138                                        die "Ambiguous destination: ",
1139                                            $_branch_dest, "\nmatches both '",
1140                                            $glob->{path}->{left}, "' and '",
1141                                            $g->{path}->{left}, "'\n";
1142                                }
1143                                $glob = $g;
1144                        }
1145                        unless (defined $glob) {
1146                                die "Unknown ",
1147                                    $_tag ? "tag" : "branch",
1148                                    " destination $_branch_dest\n";
1149                        }
1150                }
1151        }
1152        my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1153        my $url;
1154        if (defined $_commit_url) {
1155                $url = $_commit_url;
1156        } else {
1157                $url = eval { command_oneline('config', '--get',
1158                        "svn-remote.$gs->{repo_id}.commiturl") };
1159                if (!$url) {
1160                        $url = $remote->{pushurl} || $remote->{url};
1161                }
1162        }
1163        my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1164
1165        if ($dst =~ /^https:/ && $src =~ /^http:/) {
1166                $src=~s/^http:/https:/;
1167        }
1168
1169        ::_req_svn();
1170
1171        my $ctx = SVN::Client->new(
1172                config => SVN::Core::config_get_config(
1173                        $Git::SVN::Ra::config_dir
1174                ),
1175                log_msg => sub {
1176                        ${ $_[0] } = defined $_message
1177                                ? $_message
1178                                : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1179                                . $branch_name;
1180                },
1181        );
1182
1183        eval {
1184                $ctx->ls($dst, 'HEAD', 0);
1185        } and die "branch ${branch_name} already exists\n";
1186
1187        if ($_parents) {
1188                mk_parent_dirs($ctx, $dst);
1189        }
1190
1191        print "Copying ${src} at r${rev} to ${dst}...\n";
1192        $ctx->copy($src, $rev, $dst)
1193                unless $_dry_run;
1194
1195        $gs->fetch_all;
1196}
1197
1198sub mk_parent_dirs {
1199        my ($ctx, $parent) = @_;
1200        $parent =~ s{/[^/]*$}{};
1201
1202        if (!eval{$ctx->ls($parent, 'HEAD', 0)}) {
1203                mk_parent_dirs($ctx, $parent);
1204                print "Creating parent folder ${parent} ...\n";
1205                $ctx->mkdir($parent) unless $_dry_run;
1206        }
1207}
1208
1209sub cmd_find_rev {
1210        my $revision_or_hash = shift or die "SVN or git revision required ",
1211                                            "as a command-line argument\n";
1212        my $result;
1213        if ($revision_or_hash =~ /^r\d+$/) {
1214                my $head = shift;
1215                $head ||= 'HEAD';
1216                my @refs;
1217                my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1218                unless ($gs) {
1219                        die "Unable to determine upstream SVN information from ",
1220                            "$head history\n";
1221                }
1222                my $desired_revision = substr($revision_or_hash, 1);
1223                if ($_before) {
1224                        $result = $gs->find_rev_before($desired_revision, 1);
1225                } elsif ($_after) {
1226                        $result = $gs->find_rev_after($desired_revision, 1);
1227                } else {
1228                        $result = $gs->rev_map_get($desired_revision, $uuid);
1229                }
1230        } else {
1231                my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1232                $result = $rev;
1233        }
1234        print "$result\n" if $result;
1235}
1236
1237sub auto_create_empty_directories {
1238        my ($gs) = @_;
1239        my $var = eval { command_oneline('config', '--get', '--bool',
1240                                         "svn-remote.$gs->{repo_id}.automkdirs") };
1241        # By default, create empty directories by consulting the unhandled log,
1242        # but allow setting it to 'false' to skip it.
1243        return !($var && $var eq 'false');
1244}
1245
1246sub cmd_rebase {
1247        command_noisy(qw/update-index --refresh/);
1248        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1249        unless ($gs) {
1250                die "Unable to determine upstream SVN information from ",
1251                    "working tree history\n";
1252        }
1253        if ($_dry_run) {
1254                print "Remote Branch: " . $gs->refname . "\n";
1255                print "SVN URL: " . $url . "\n";
1256                return;
1257        }
1258        if (command(qw/diff-index HEAD --/)) {
1259                print STDERR "Cannot rebase with uncommitted changes:\n";
1260                command_noisy('status');
1261                exit 1;
1262        }
1263        unless ($_local) {
1264                # rebase will checkout for us, so no need to do it explicitly
1265                $_no_checkout = 'true';
1266                $_fetch_all ? $gs->fetch_all : $gs->fetch;
1267        }
1268        command_noisy(rebase_cmd(), $gs->refname);
1269        if (auto_create_empty_directories($gs)) {
1270                $gs->mkemptydirs;
1271        }
1272}
1273
1274sub cmd_show_ignore {
1275        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1276        $gs ||= Git::SVN->new;
1277        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1278        $gs->prop_walk($gs->path, $r, sub {
1279                my ($gs, $path, $props) = @_;
1280                print STDOUT "\n# $path\n";
1281                my $s = $props->{'svn:ignore'} or return;
1282                $s =~ s/[\r\n]+/\n/g;
1283                $s =~ s/^\n+//;
1284                chomp $s;
1285                $s =~ s#^#$path#gm;
1286                print STDOUT "$s\n";
1287        });
1288}
1289
1290sub cmd_show_externals {
1291        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1292        $gs ||= Git::SVN->new;
1293        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1294        $gs->prop_walk($gs->path, $r, sub {
1295                my ($gs, $path, $props) = @_;
1296                print STDOUT "\n# $path\n";
1297                my $s = $props->{'svn:externals'} or return;
1298                $s =~ s/[\r\n]+/\n/g;
1299                chomp $s;
1300                $s =~ s#^#$path#gm;
1301                print STDOUT "$s\n";
1302        });
1303}
1304
1305sub cmd_create_ignore {
1306        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1307        $gs ||= Git::SVN->new;
1308        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1309        $gs->prop_walk($gs->path, $r, sub {
1310                my ($gs, $path, $props) = @_;
1311                # $path is of the form /path/to/dir/
1312                $path = '.' . $path;
1313                # SVN can have attributes on empty directories,
1314                # which git won't track
1315                mkpath([$path]) unless -d $path;
1316                my $ignore = $path . '.gitignore';
1317                my $s = $props->{'svn:ignore'} or return;
1318                open(GITIGNORE, '>', $ignore)
1319                  or fatal("Failed to open `$ignore' for writing: $!");
1320                $s =~ s/[\r\n]+/\n/g;
1321                $s =~ s/^\n+//;
1322                chomp $s;
1323                # Prefix all patterns so that the ignore doesn't apply
1324                # to sub-directories.
1325                $s =~ s#^#/#gm;
1326                print GITIGNORE "$s\n";
1327                close(GITIGNORE)
1328                  or fatal("Failed to close `$ignore': $!");
1329                command_noisy('add', '-f', $ignore);
1330        });
1331}
1332
1333sub cmd_mkdirs {
1334        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1335        $gs ||= Git::SVN->new;
1336        $gs->mkemptydirs($_revision);
1337}
1338
1339# get_svnprops(PATH)
1340# ------------------
1341# Helper for cmd_propget and cmd_proplist below.
1342sub get_svnprops {
1343        my $path = shift;
1344        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1345        $gs ||= Git::SVN->new;
1346
1347        # prefix THE PATH by the sub-directory from which the user
1348        # invoked us.
1349        $path = $cmd_dir_prefix . $path;
1350        fatal("No such file or directory: $path") unless -e $path;
1351        my $is_dir = -d $path ? 1 : 0;
1352        $path = join_paths($gs->path, $path);
1353
1354        # canonicalize the path (otherwise libsvn will abort or fail to
1355        # find the file)
1356        $path = canonicalize_path($path);
1357
1358        my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1359        my $props;
1360        if ($is_dir) {
1361                (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1362        }
1363        else {
1364                (undef, $props) = $gs->ra->get_file($path, $r, undef);
1365        }
1366        return $props;
1367}
1368
1369# cmd_propget (PROP, PATH)
1370# ------------------------
1371# Print the SVN property PROP for PATH.
1372sub cmd_propget {
1373        my ($prop, $path) = @_;
1374        $path = '.' if not defined $path;
1375        usage(1) if not defined $prop;
1376        my $props = get_svnprops($path);
1377        if (not defined $props->{$prop}) {
1378                fatal("`$path' does not have a `$prop' SVN property.");
1379        }
1380        print $props->{$prop} . "\n";
1381}
1382
1383# cmd_propset (PROPNAME, PROPVAL, PATH)
1384# ------------------------
1385# Adjust the SVN property PROPNAME to PROPVAL for PATH.
1386sub cmd_propset {
1387        my ($propname, $propval, $path) = @_;
1388        $path = '.' if not defined $path;
1389        $path = $cmd_dir_prefix . $path;
1390        usage(1) if not defined $propname;
1391        usage(1) if not defined $propval;
1392        my $file = basename($path);
1393        my $dn = dirname($path);
1394        my $cur_props = Git::SVN::Editor::check_attr( "svn-properties", $path );
1395        my @new_props;
1396        if (!$cur_props || $cur_props eq "unset" || $cur_props eq "" || $cur_props eq "set") {
1397                push @new_props, "$propname=$propval";
1398        } else {
1399                # TODO: handle combining properties better
1400                my @props = split(/;/, $cur_props);
1401                my $replaced_prop;
1402                foreach my $prop (@props) {
1403                        # Parse 'name=value' syntax and set the property.
1404                        if ($prop =~ /([^=]+)=(.*)/) {
1405                                my ($n,$v) = ($1,$2);
1406                                if ($n eq $propname) {
1407                                        $v = $propval;
1408                                        $replaced_prop = 1;
1409                                }
1410                                push @new_props, "$n=$v";
1411                        }
1412                }
1413                if (!$replaced_prop) {
1414                        push @new_props, "$propname=$propval";
1415                }
1416        }
1417        my $attrfile = "$dn/.gitattributes";
1418        open my $attrfh, '>>', $attrfile or die "Can't open $attrfile: $!\n";
1419        # TODO: don't simply append here if $file already has svn-properties
1420        my $new_props = join(';', @new_props);
1421        print $attrfh "$file svn-properties=$new_props\n" or
1422                die "write to $attrfile: $!\n";
1423        close $attrfh or die "close $attrfile: $!\n";
1424}
1425
1426# cmd_proplist (PATH)
1427# -------------------
1428# Print the list of SVN properties for PATH.
1429sub cmd_proplist {
1430        my $path = shift;
1431        $path = '.' if not defined $path;
1432        my $props = get_svnprops($path);
1433        print "Properties on '$path':\n";
1434        foreach (sort keys %{$props}) {
1435                print "  $_\n";
1436        }
1437}
1438
1439sub cmd_multi_init {
1440        my $url = shift;
1441        unless (defined $_trunk || @_branches || @_tags) {
1442                usage(1);
1443        }
1444
1445        $_prefix = 'origin/' unless defined $_prefix;
1446        if (defined $url) {
1447                $url = canonicalize_url($url);
1448                init_subdir(@_);
1449        }
1450        do_git_init_db();
1451        if (defined $_trunk) {
1452                $_trunk =~ s#^/+##;
1453                my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1454                # try both old-style and new-style lookups:
1455                my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1456                unless ($gs_trunk) {
1457                        my ($trunk_url, $trunk_path) =
1458                                              complete_svn_url($url, $_trunk);
1459                        $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1460                                                   undef, $trunk_ref);
1461                }
1462        }
1463        return unless @_branches || @_tags;
1464        my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1465        foreach my $path (@_branches) {
1466                complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1467        }
1468        foreach my $path (@_tags) {
1469                complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1470        }
1471}
1472
1473sub cmd_multi_fetch {
1474        $Git::SVN::no_reuse_existing = undef;
1475        my $remotes = Git::SVN::read_all_remotes();
1476        foreach my $repo_id (sort keys %$remotes) {
1477                if ($remotes->{$repo_id}->{url}) {
1478                        Git::SVN::fetch_all($repo_id, $remotes);
1479                }
1480        }
1481}
1482
1483# this command is special because it requires no metadata
1484sub cmd_commit_diff {
1485        my ($ta, $tb, $url) = @_;
1486        my $usage = "usage: $0 commit-diff -r<revision> ".
1487                    "<tree-ish> <tree-ish> [<URL>]";
1488        fatal($usage) if (!defined $ta || !defined $tb);
1489        my $svn_path = '';
1490        if (!defined $url) {
1491                my $gs = eval { Git::SVN->new };
1492                if (!$gs) {
1493                        fatal("Needed URL or usable git-svn --id in ",
1494                              "the command-line\n", $usage);
1495                }
1496                $url = $gs->url;
1497                $svn_path = $gs->path;
1498        }
1499        unless (defined $_revision) {
1500                fatal("-r|--revision is a required argument\n", $usage);
1501        }
1502        if (defined $_message && defined $_file) {
1503                fatal("Both --message/-m and --file/-F specified ",
1504                      "for the commit message.\n",
1505                      "I have no idea what you mean");
1506        }
1507        if (defined $_file) {
1508                $_message = file_to_s($_file);
1509        } else {
1510                $_message ||= get_commit_entry($tb)->{log};
1511        }
1512        my $ra ||= Git::SVN::Ra->new($url);
1513        my $r = $_revision;
1514        if ($r eq 'HEAD') {
1515                $r = $ra->get_latest_revnum;
1516        } elsif ($r !~ /^\d+$/) {
1517                die "revision argument: $r not understood by git-svn\n";
1518        }
1519        my %ed_opts = ( r => $r,
1520                        log => $_message,
1521                        ra => $ra,
1522                        tree_a => $ta,
1523                        tree_b => $tb,
1524                        editor_cb => sub { print "Committed r$_[0]\n" },
1525                        svn_path => $svn_path );
1526        if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1527                print "No changes\n$ta == $tb\n";
1528        }
1529}
1530
1531sub cmd_info {
1532        my $path_arg = defined($_[0]) ? $_[0] : '.';
1533        my $path = $path_arg;
1534        if (File::Spec->file_name_is_absolute($path)) {
1535                $path = canonicalize_path($path);
1536
1537                my $toplevel = eval {
1538                        my @cmd = qw/rev-parse --show-toplevel/;
1539                        command_oneline(\@cmd, STDERR => 0);
1540                };
1541
1542                # remove $toplevel from the absolute path:
1543                my ($vol, $dirs, $file) = File::Spec->splitpath($path);
1544                my (undef, $tdirs, $tfile) = File::Spec->splitpath($toplevel);
1545                my @dirs = File::Spec->splitdir($dirs);
1546                my @tdirs = File::Spec->splitdir($tdirs);
1547                pop @dirs if $dirs[-1] eq '';
1548                pop @tdirs if $tdirs[-1] eq '';
1549                push @dirs, $file;
1550                push @tdirs, $tfile;
1551                while (@tdirs && @dirs && $tdirs[0] eq $dirs[0]) {
1552                        shift @dirs;
1553                        shift @tdirs;
1554                }
1555                $dirs = File::Spec->catdir(@dirs);
1556                $path = File::Spec->catpath($vol, $dirs);
1557
1558                $path = canonicalize_path($path);
1559        } else {
1560                $path = canonicalize_path($cmd_dir_prefix . $path);
1561        }
1562        if (exists $_[1]) {
1563                die "Too many arguments specified\n";
1564        }
1565
1566        my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1567
1568        if (!$file_type && !$diff_status) {
1569                print STDERR "svn: '$path' is not under version control\n";
1570                exit 1;
1571        }
1572
1573        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1574        unless ($gs) {
1575                die "Unable to determine upstream SVN information from ",
1576                    "working tree history\n";
1577        }
1578
1579        # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1580        $path = "." if $path eq "";
1581
1582        my $full_url = canonicalize_url( add_path_to_url( $url, $path ) );
1583
1584        if ($_url) {
1585                print "$full_url\n";
1586                return;
1587        }
1588
1589        my $result = "Path: $path_arg\n";
1590        $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1591        $result .= "URL: $full_url\n";
1592
1593        eval {
1594                my $repos_root = $gs->repos_root;
1595                Git::SVN::remove_username($repos_root);
1596                $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1597        };
1598        if ($@) {
1599                $result .= "Repository Root: (offline)\n";
1600        }
1601        ::_req_svn();
1602        $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1603                (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1604        $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1605
1606        $result .= "Node Kind: " .
1607                   ($file_type eq "dir" ? "directory" : "file") . "\n";
1608
1609        my $schedule = $diff_status eq "A"
1610                       ? "add"
1611                       : ($diff_status eq "D" ? "delete" : "normal");
1612        $result .= "Schedule: $schedule\n";
1613
1614        if ($diff_status eq "A") {
1615                print $result, "\n";
1616                return;
1617        }
1618
1619        my ($lc_author, $lc_rev, $lc_date_utc);
1620        my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
1621        my $log = command_output_pipe(@args);
1622        my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1623        while (<$log>) {
1624                if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1625                        $lc_author = $1;
1626                        $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1627                } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1628                        (undef, $lc_rev, undef) = ::extract_metadata($1);
1629                }
1630        }
1631        close $log;
1632
1633        Git::SVN::Log::set_local_timezone();
1634
1635        $result .= "Last Changed Author: $lc_author\n";
1636        $result .= "Last Changed Rev: $lc_rev\n";
1637        $result .= "Last Changed Date: " .
1638                   Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1639
1640        if ($file_type ne "dir") {
1641                my $text_last_updated_date =
1642                    ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1643                $result .=
1644                    "Text Last Updated: " .
1645                    Git::SVN::Log::format_svn_date($text_last_updated_date) .
1646                    "\n";
1647                my $checksum;
1648                if ($diff_status eq "D") {
1649                        my ($fh, $ctx) =
1650                            command_output_pipe(qw(cat-file blob), "HEAD:$path");
1651                        if ($file_type eq "link") {
1652                                my $file_name = <$fh>;
1653                                $checksum = md5sum("link $file_name");
1654                        } else {
1655                                $checksum = md5sum($fh);
1656                        }
1657                        command_close_pipe($fh, $ctx);
1658                } elsif ($file_type eq "link") {
1659                        my $file_name =
1660                            command(qw(cat-file blob), "HEAD:$path");
1661                        $checksum =
1662                            md5sum("link " . $file_name);
1663                } else {
1664                        open FILE, "<", $path or die $!;
1665                        $checksum = md5sum(\*FILE);
1666                        close FILE or die $!;
1667                }
1668                $result .= "Checksum: " . $checksum . "\n";
1669        }
1670
1671        print $result, "\n";
1672}
1673
1674sub cmd_reset {
1675        my $target = shift || $_revision or die "SVN revision required\n";
1676        $target = $1 if $target =~ /^r(\d+)$/;
1677        $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1678        my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1679        unless ($gs) {
1680                die "Unable to determine upstream SVN information from ".
1681                    "history\n";
1682        }
1683        my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1684        die "Cannot find SVN revision $target\n" unless defined($c);
1685        $gs->rev_map_set($r, $c, 'reset', $uuid);
1686        print "r$r = $c ($gs->{ref_id})\n";
1687}
1688
1689sub cmd_gc {
1690        if (!can_compress()) {
1691                warn "Compress::Zlib could not be found; unhandled.log " .
1692                     "files will not be compressed.\n";
1693        }
1694        find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1695}
1696
1697########################### utility functions #########################
1698
1699sub rebase_cmd {
1700        my @cmd = qw/rebase/;
1701        push @cmd, '-v' if $_verbose;
1702        push @cmd, qw/--merge/ if $_merge;
1703        push @cmd, "--strategy=$_strategy" if $_strategy;
1704        push @cmd, "--preserve-merges" if $_preserve_merges;
1705        @cmd;
1706}
1707
1708sub post_fetch_checkout {
1709        return if $_no_checkout;
1710        return if verify_ref('HEAD^0');
1711        my $gs = $Git::SVN::_head or return;
1712
1713        # look for "trunk" ref if it exists
1714        my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1715        my $fetch = $remote->{fetch};
1716        if ($fetch) {
1717                foreach my $p (keys %$fetch) {
1718                        basename($fetch->{$p}) eq 'trunk' or next;
1719                        $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1720                        last;
1721                }
1722        }
1723
1724        command_noisy(qw(update-ref HEAD), $gs->refname);
1725        return unless verify_ref('HEAD^0');
1726
1727        return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1728        my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1729        return if -f $index;
1730
1731        return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1732        return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1733        command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1734        print STDERR "Checked out HEAD:\n  ",
1735                     $gs->full_url, " r", $gs->last_rev, "\n";
1736        if (auto_create_empty_directories($gs)) {
1737                $gs->mkemptydirs($gs->last_rev);
1738        }
1739}
1740
1741sub complete_svn_url {
1742        my ($url, $path) = @_;
1743        $path = canonicalize_path($path);
1744
1745        # If the path is not a URL...
1746        if ($path !~ m#^[a-z\+]+://#) {
1747                if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1748                        fatal("E: '$path' is not a complete URL ",
1749                              "and a separate URL is not specified");
1750                }
1751                return ($url, $path);
1752        }
1753        return ($path, '');
1754}
1755
1756sub complete_url_ls_init {
1757        my ($ra, $repo_path, $switch, $pfx) = @_;
1758        unless ($repo_path) {
1759                print STDERR "W: $switch not specified\n";
1760                return;
1761        }
1762        $repo_path = canonicalize_path($repo_path);
1763        if ($repo_path =~ m#^[a-z\+]+://#) {
1764                $ra = Git::SVN::Ra->new($repo_path);
1765                $repo_path = '';
1766        } else {
1767                $repo_path =~ s#^/+##;
1768                unless ($ra) {
1769                        fatal("E: '$repo_path' is not a complete URL ",
1770                              "and a separate URL is not specified");
1771                }
1772        }
1773        my $url = $ra->url;
1774        my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1775        my $k = "svn-remote.$gs->{repo_id}.url";
1776        my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1777        if ($orig_url && ($orig_url ne $gs->url)) {
1778                die "$k already set: $orig_url\n",
1779                    "wanted to set to: $gs->url\n";
1780        }
1781        command_oneline('config', $k, $gs->url) unless $orig_url;
1782
1783        my $remote_path = join_paths( $gs->path, $repo_path );
1784        $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1785        $remote_path =~ s#^/##g;
1786        $remote_path .= "/*" if $remote_path !~ /\*/;
1787        my ($n) = ($switch =~ /^--(\w+)/);
1788        if (length $pfx && $pfx !~ m#/$#) {
1789                die "--prefix='$pfx' must have a trailing slash '/'\n";
1790        }
1791        command_noisy('config',
1792                      '--add',
1793                      "svn-remote.$gs->{repo_id}.$n",
1794                      "$remote_path:refs/remotes/$pfx*" .
1795                        ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1796}
1797
1798sub verify_ref {
1799        my ($ref) = @_;
1800        eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1801                               { STDERR => 0 }); };
1802}
1803
1804sub get_tree_from_treeish {
1805        my ($treeish) = @_;
1806        # $treeish can be a symbolic ref, too:
1807        my $type = command_oneline(qw/cat-file -t/, $treeish);
1808        my $expected;
1809        while ($type eq 'tag') {
1810                ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1811        }
1812        if ($type eq 'commit') {
1813                $expected = (grep /^tree /, command(qw/cat-file commit/,
1814                                                    $treeish))[0];
1815                ($expected) = ($expected =~ /^tree ($sha1)$/o);
1816                die "Unable to get tree from $treeish\n" unless $expected;
1817        } elsif ($type eq 'tree') {
1818                $expected = $treeish;
1819        } else {
1820                die "$treeish is a $type, expected tree, tag or commit\n";
1821        }
1822        return $expected;
1823}
1824
1825sub get_commit_entry {
1826        my ($treeish) = shift;
1827        my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1828        my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1829        my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1830        open my $log_fh, '>', $commit_editmsg or croak $!;
1831
1832        my $type = command_oneline(qw/cat-file -t/, $treeish);
1833        if ($type eq 'commit' || $type eq 'tag') {
1834                my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1835                                                         $type, $treeish);
1836                my $in_msg = 0;
1837                my $author;
1838                my $saw_from = 0;
1839                my $msgbuf = "";
1840                while (<$msg_fh>) {
1841                        if (!$in_msg) {
1842                                $in_msg = 1 if (/^$/);
1843                                $author = $1 if (/^author (.*>)/);
1844                        } elsif (/^git-svn-id: /) {
1845                                # skip this for now, we regenerate the
1846                                # correct one on re-fetch anyways
1847                                # TODO: set *:merge properties or like...
1848                        } else {
1849                                if (/^From:/ || /^Signed-off-by:/) {
1850                                        $saw_from = 1;
1851                                }
1852                                $msgbuf .= $_;
1853                        }
1854                }
1855                $msgbuf =~ s/\s+$//s;
1856                if ($Git::SVN::_add_author_from && defined($author)
1857                    && !$saw_from) {
1858                        $msgbuf .= "\n\nFrom: $author";
1859                }
1860                print $log_fh $msgbuf or croak $!;
1861                command_close_pipe($msg_fh, $ctx);
1862        }
1863        close $log_fh or croak $!;
1864
1865        if ($_edit || ($type eq 'tree')) {
1866                chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1867                system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1868        }
1869        rename $commit_editmsg, $commit_msg or croak $!;
1870        {
1871                require Encode;
1872                # SVN requires messages to be UTF-8 when entering the repo
1873                local $/;
1874                open $log_fh, '<', $commit_msg or croak $!;
1875                binmode $log_fh;
1876                chomp($log_entry{log} = <$log_fh>);
1877
1878                my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1879                my $msg = $log_entry{log};
1880
1881                eval { $msg = Encode::decode($enc, $msg, 1) };
1882                if ($@) {
1883                        die "Could not decode as $enc:\n", $msg,
1884                            "\nPerhaps you need to set i18n.commitencoding\n";
1885                }
1886
1887                eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1888                die "Could not encode as UTF-8:\n$msg\n" if $@;
1889
1890                $log_entry{log} = $msg;
1891
1892                close $log_fh or croak $!;
1893        }
1894        unlink $commit_msg;
1895        \%log_entry;
1896}
1897
1898sub s_to_file {
1899        my ($str, $file, $mode) = @_;
1900        open my $fd,'>',$file or croak $!;
1901        print $fd $str,"\n" or croak $!;
1902        close $fd or croak $!;
1903        chmod ($mode &~ umask, $file) if (defined $mode);
1904}
1905
1906sub file_to_s {
1907        my $file = shift;
1908        open my $fd,'<',$file or croak "$!: file: $file\n";
1909        local $/;
1910        my $ret = <$fd>;
1911        close $fd or croak $!;
1912        $ret =~ s/\s*$//s;
1913        return $ret;
1914}
1915
1916# '<svn username> = real-name <email address>' mapping based on git-svnimport:
1917sub load_authors {
1918        open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1919        my $log = $cmd eq 'log';
1920        while (<$authors>) {
1921                chomp;
1922                next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1923                my ($user, $name, $email) = ($1, $2, $3);
1924                if ($log) {
1925                        $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1926                } else {
1927                        $users{$user} = [$name, $email];
1928                }
1929        }
1930        close $authors or croak $!;
1931}
1932
1933# convert GetOpt::Long specs for use by git-config
1934sub read_git_config {
1935        my $opts = shift;
1936        my @config_only;
1937        foreach my $o (keys %$opts) {
1938                # if we have mixedCase and a long option-only, then
1939                # it's a config-only variable that we don't need for
1940                # the command-line.
1941                push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1942                my $v = $opts->{$o};
1943                my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1944                $key =~ s/-//g;
1945                my $arg = 'git config';
1946                $arg .= ' --int' if ($o =~ /[:=]i$/);
1947                $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1948                if (ref $v eq 'ARRAY') {
1949                        chomp(my @tmp = `$arg --get-all svn.$key`);
1950                        @$v = @tmp if @tmp;
1951                } else {
1952                        chomp(my $tmp = `$arg --get svn.$key`);
1953                        if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1954                                $$v = $tmp;
1955                        }
1956                }
1957        }
1958        delete @$opts{@config_only} if @config_only;
1959}
1960
1961sub extract_metadata {
1962        my $id = shift or return (undef, undef, undef);
1963        my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1964                                                        \s([a-f\d\-]+)$/ix);
1965        if (!defined $rev || !$uuid || !$url) {
1966                # some of the original repositories I made had
1967                # identifiers like this:
1968                ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1969        }
1970        return ($url, $rev, $uuid);
1971}
1972
1973sub cmt_metadata {
1974        return extract_metadata((grep(/^git-svn-id: /,
1975                command(qw/cat-file commit/, shift)))[-1]);
1976}
1977
1978sub cmt_sha2rev_batch {
1979        my %s2r;
1980        my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1981        my $list = shift;
1982
1983        foreach my $sha (@{$list}) {
1984                my $first = 1;
1985                my $size = 0;
1986                print $out $sha, "\n";
1987
1988                while (my $line = <$in>) {
1989                        if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1990                                last;
1991                        } elsif ($first &&
1992                               $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1993                                $first = 0;
1994                                $size = $1;
1995                                next;
1996                        } elsif ($line =~ /^(git-svn-id: )/) {
1997                                my (undef, $rev, undef) =
1998                                                      extract_metadata($line);
1999                                $s2r{$sha} = $rev;
2000                        }
2001
2002                        $size -= length($line);
2003                        last if ($size == 0);
2004                }
2005        }
2006
2007        command_close_bidi_pipe($pid, $in, $out, $ctx);
2008
2009        return \%s2r;
2010}
2011
2012sub working_head_info {
2013        my ($head, $refs) = @_;
2014        my @args = qw/rev-list --first-parent --pretty=medium/;
2015        my ($fh, $ctx) = command_output_pipe(@args, $head, "--");
2016        my $hash;
2017        my %max;
2018        while (<$fh>) {
2019                if ( m{^commit ($::sha1)$} ) {
2020                        unshift @$refs, $hash if $hash and $refs;
2021                        $hash = $1;
2022                        next;
2023                }
2024                next unless s{^\s*(git-svn-id:)}{$1};
2025                my ($url, $rev, $uuid) = extract_metadata($_);
2026                if (defined $url && defined $rev) {
2027                        next if $max{$url} and $max{$url} < $rev;
2028                        if (my $gs = Git::SVN->find_by_url($url)) {
2029                                my $c = $gs->rev_map_get($rev, $uuid);
2030                                if ($c && $c eq $hash) {
2031                                        close $fh; # break the pipe
2032                                        return ($url, $rev, $uuid, $gs);
2033                                } else {
2034                                        $max{$url} ||= $gs->rev_map_max;
2035                                }
2036                        }
2037                }
2038        }
2039        command_close_pipe($fh, $ctx);
2040        (undef, undef, undef, undef);
2041}
2042
2043sub read_commit_parents {
2044        my ($parents, $c) = @_;
2045        chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
2046        $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
2047        @{$parents->{$c}} = split(/ /, $p);
2048}
2049
2050sub linearize_history {
2051        my ($gs, $refs) = @_;
2052        my %parents;
2053        foreach my $c (@$refs) {
2054                read_commit_parents(\%parents, $c);
2055        }
2056
2057        my @linear_refs;
2058        my %skip = ();
2059        my $last_svn_commit = $gs->last_commit;
2060        foreach my $c (reverse @$refs) {
2061                next if $c eq $last_svn_commit;
2062                last if $skip{$c};
2063
2064                unshift @linear_refs, $c;
2065                $skip{$c} = 1;
2066
2067                # we only want the first parent to diff against for linear
2068                # history, we save the rest to inject when we finalize the
2069                # svn commit
2070                my $fp_a = verify_ref("$c~1");
2071                my $fp_b = shift @{$parents{$c}} if $parents{$c};
2072                if (!$fp_a || !$fp_b) {
2073                        die "Commit $c\n",
2074                            "has no parent commit, and therefore ",
2075                            "nothing to diff against.\n",
2076                            "You should be working from a repository ",
2077                            "originally created by git-svn\n";
2078                }
2079                if ($fp_a ne $fp_b) {
2080                        die "$c~1 = $fp_a, however parsing commit $c ",
2081                            "revealed that:\n$c~1 = $fp_b\nBUG!\n";
2082                }
2083
2084                foreach my $p (@{$parents{$c}}) {
2085                        $skip{$p} = 1;
2086                }
2087        }
2088        (\@linear_refs, \%parents);
2089}
2090
2091sub find_file_type_and_diff_status {
2092        my ($path) = @_;
2093        return ('dir', '') if $path eq '';
2094
2095        my $diff_output =
2096            command_oneline(qw(diff --cached --name-status --), $path) || "";
2097        my $diff_status = (split(' ', $diff_output))[0] || "";
2098
2099        my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
2100
2101        return (undef, undef) if !$diff_status && !$ls_tree;
2102
2103        if ($diff_status eq "A") {
2104                return ("link", $diff_status) if -l $path;
2105                return ("dir", $diff_status) if -d $path;
2106                return ("file", $diff_status);
2107        }
2108
2109        my $mode = (split(' ', $ls_tree))[0] || "";
2110
2111        return ("link", $diff_status) if $mode eq "120000";
2112        return ("dir", $diff_status) if $mode eq "040000";
2113        return ("file", $diff_status);
2114}
2115
2116sub md5sum {
2117        my $arg = shift;
2118        my $ref = ref $arg;
2119        my $md5 = Digest::MD5->new();
2120        if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2121                $md5->addfile($arg) or croak $!;
2122        } elsif ($ref eq 'SCALAR') {
2123                $md5->add($$arg) or croak $!;
2124        } elsif (!$ref) {
2125                $md5->add($arg) or croak $!;
2126        } else {
2127                fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2128        }
2129        return $md5->hexdigest();
2130}
2131
2132sub gc_directory {
2133        if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2134                my $out_filename = $_ . ".gz";
2135                open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2136                binmode $in_fh;
2137                my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2138                                die "Unable to open $out_filename: $!\n";
2139
2140                my $res;
2141                while ($res = sysread($in_fh, my $str, 1024)) {
2142                        $gz->gzwrite($str) or
2143                                die "Unable to write: ".$gz->gzerror()."!\n";
2144                }
2145                unlink $_ or die "unlink $File::Find::name: $!\n";
2146        } elsif (-f $_ && basename($_) eq "index") {
2147                unlink $_ or die "unlink $_: $!\n";
2148        }
2149}
2150
2151__END__
2152
2153Data structures:
2154
2155
2156$remotes = { # returned by read_all_remotes()
2157        'svn' => {
2158                # svn-remote.svn.url=https://svn.musicpd.org
2159                url => 'https://svn.musicpd.org',
2160                # svn-remote.svn.fetch=mpd/trunk:trunk
2161                fetch => {
2162                        'mpd/trunk' => 'trunk',
2163                },
2164                # svn-remote.svn.tags=mpd/tags/*:tags/*
2165                tags => {
2166                        path => {
2167                                left => 'mpd/tags',
2168                                right => '',
2169                                regex => qr!mpd/tags/([^/]+)$!,
2170                                glob => 'tags/*',
2171                        },
2172                        ref => {
2173                                left => 'tags',
2174                                right => '',
2175                                regex => qr!tags/([^/]+)$!,
2176                                glob => 'tags/*',
2177                        },
2178                }
2179        }
2180};
2181
2182$log_entry hashref as returned by libsvn_log_entry()
2183{
2184        log => 'whitespace-formatted log entry
2185',                                              # trailing newline is preserved
2186        revision => '8',                        # integer
2187        date => '2004-02-24T17:01:44.108345Z',  # commit date
2188        author => 'committer name'
2189};
2190
2191
2192# this is generated by generate_diff();
2193@mods = array of diff-index line hashes, each element represents one line
2194        of diff-index output
2195
2196diff-index line ($m hash)
2197{
2198        mode_a => first column of diff-index output, no leading ':',
2199        mode_b => second column of diff-index output,
2200        sha1_b => sha1sum of the final blob,
2201        chg => change type [MCRADT],
2202        file_a => original file name of a file (iff chg is 'C' or 'R')
2203        file_b => new/current file name of a file (any chg)
2204}
2205;
2206
2207# retval of read_url_paths{,_all}();
2208$l_map = {
2209        # repository root url
2210        'https://svn.musicpd.org' => {
2211                # repository path               # GIT_SVN_ID
2212                'mpd/trunk'             =>      'trunk',
2213                'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2214        },
2215}
2216
2217Notes:
2218        I don't trust the each() function on unless I created %hash myself
2219        because the internal iterator may not have started at base.