Andrew's git / gitweb.git / configure.ac
?
configure.acon commit branch -d: base the "already-merged" safety on the branch it merges with (99c419c)
   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_ERROR([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  47                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  48        fi; \
  49fi; \
  50]) # GIT_CONF_APPEND_PATH
  51#
  52# GIT_PARSE_WITH(PACKAGE)
  53# -----------------------
  54# For use in AC_ARG_WITH action-if-found, for packages default ON.
  55# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  56# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  57# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  58AC_DEFUN([GIT_PARSE_WITH],
  59[PACKAGE=m4_toupper($1); \
  60if test "$withval" = "no"; then \
  61        m4_toupper(NO_$1)=YesPlease; \
  62elif test "$withval" = "yes"; then \
  63        m4_toupper(NO_$1)=; \
  64else \
  65        m4_toupper(NO_$1)=; \
  66        m4_toupper($1)DIR=$withval; \
  67        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  68        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  69fi \
  70])# GIT_PARSE_WITH
  71#
  72# GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  73# ---------------------
  74# Set VAR to the value specied by --with-WITHNAME.
  75# No verification of arguments is performed, but warnings are issued
  76# if either 'yes' or 'no' is specified.
  77# HELP_TEXT is presented when --help is called.
  78# This is a direct way to allow setting variables in the Makefile.
  79AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  80[AC_ARG_WITH([$1],
  81 [AS_HELP_STRING([--with-$1=VALUE], $3)],
  82 if test -n "$withval"; then \
  83  if test "$withval" = "yes" -o "$withval" = "no"; then \
  84    AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  85                     [a value for $1 ($2).  Maybe you do...?]); \
  86  fi; \
  87  \
  88  AC_MSG_NOTICE([Setting $2 to $withval]); \
  89  GIT_CONF_APPEND_LINE($2=$withval); \
  90 fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
  91
  92dnl
  93dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
  94dnl -----------------------------------------
  95dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
  96dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
  97dnl -Wall), it does not work.  By looking for function definition in
  98dnl libraries, this problem can be worked around.
  99AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 100  AC_SEARCH_LIBS([$1],,
 101  [$2],[$3])
 102],[$3])])
 103
 104dnl
 105dnl GIT_STASH_FLAGS(BASEPATH_VAR)
 106dnl -----------------------------
 107dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 108dnl tests that may want to take user settings into account.
 109AC_DEFUN([GIT_STASH_FLAGS],[
 110if test -n "$1"; then
 111   old_CPPFLAGS="$CPPFLAGS"
 112   old_LDFLAGS="$LDFLAGS"
 113   CPPFLAGS="-I$1/include $CPPFLAGS"
 114   LDFLAGS="-L$1/$lib $LDFLAGS"
 115fi
 116])
 117
 118dnl
 119dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 120dnl -----------------------------
 121dnl Restore the stashed *FLAGS values.
 122AC_DEFUN([GIT_UNSTASH_FLAGS],[
 123if test -n "$1"; then
 124   CPPFLAGS="$old_CPPFLAGS"
 125   LDFLAGS="$old_LDFLAGS"
 126fi
 127])
 128
 129## Site configuration related to programs (before tests)
 130## --with-PACKAGE[=ARG] and --without-PACKAGE
 131#
 132# Set lib to alternative name of lib directory (e.g. lib64)
 133AC_ARG_WITH([lib],
 134 [AS_HELP_STRING([--with-lib=ARG],
 135                 [ARG specifies alternative name for lib directory])],
 136 [if test "$withval" = "no" || test "$withval" = "yes"; then \
 137        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 138else \
 139        lib=$withval; \
 140        AC_MSG_NOTICE([Setting lib to '$lib']); \
 141        GIT_CONF_APPEND_LINE(lib=$withval); \
 142fi; \
 143],[])
 144
 145if test -z "$lib"; then
 146   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 147   lib=lib
 148fi
 149
 150AC_ARG_ENABLE([pthreads],
 151 [AS_HELP_STRING([--enable-pthreads=FLAGS],
 152  [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 153  [The default if FLAGS is not specified is to try first -pthread]
 154  [and then -lpthread.]
 155  [--without-pthreads will disable threading.])],
 156[
 157if test "x$enableval" = "xyes"; then
 158   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 159elif test "x$enableval" != "xno"; then
 160   PTHREAD_CFLAGS=$enableval
 161   AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 162else
 163   AC_MSG_NOTICE([POSIX Threads will be disabled.])
 164   NO_PTHREADS=YesPlease
 165   USER_NOPTHREAD=1
 166fi],
 167[
 168   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 169])
 170
 171## Site configuration (override autodetection)
 172## --with-PACKAGE[=ARG] and --without-PACKAGE
 173AC_MSG_NOTICE([CHECKS for site configuration])
 174#
 175# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 176# tests.  These tests take up a significant amount of the total test time
 177# but are not needed unless you plan to talk to SVN repos.
 178#
 179# Define PPC_SHA1 environment variable when running make to make use of
 180# a bundled SHA1 routine optimized for PowerPC.
 181#
 182# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 183# This also implies BLK_SHA1.
 184#
 185# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 186# /foo/bar/include and /foo/bar/lib directories.
 187AC_ARG_WITH(openssl,
 188AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 189AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 190GIT_PARSE_WITH(openssl))
 191#
 192# Define NO_CURL if you do not have curl installed.  git-http-pull and
 193# git-http-push are not built, and you cannot use http:// and https://
 194# transports.
 195#
 196# Define CURLDIR=/foo/bar if your curl header and library files are in
 197# /foo/bar/include and /foo/bar/lib directories.
 198AC_ARG_WITH(curl,
 199AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 200AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 201GIT_PARSE_WITH(curl))
 202#
 203# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 204# not built, and you cannot push using http:// and https:// transports.
 205#
 206# Define EXPATDIR=/foo/bar if your expat header and library files are in
 207# /foo/bar/include and /foo/bar/lib directories.
 208AC_ARG_WITH(expat,
 209AS_HELP_STRING([--with-expat],
 210[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 211AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 212GIT_PARSE_WITH(expat))
 213#
 214# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 215# installed in /sw, but don't want GIT to link against any libraries
 216# installed there.  If defined you may specify your own (or Fink's)
 217# include directories and library directories by defining CFLAGS
 218# and LDFLAGS appropriately.
 219#
 220# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 221# have DarwinPorts installed in /opt/local, but don't want GIT to
 222# link against any libraries installed there.  If defined you may
 223# specify your own (or DarwinPort's) include directories and
 224# library directories by defining CFLAGS and LDFLAGS appropriately.
 225#
 226# Define NO_MMAP if you want to avoid mmap.
 227#
 228# Define NO_ICONV if your libc does not properly support iconv.
 229AC_ARG_WITH(iconv,
 230AS_HELP_STRING([--without-iconv],
 231[if your architecture doesn't properly support iconv])
 232AS_HELP_STRING([--with-iconv=PATH],
 233[PATH is prefix for libiconv library and headers])
 234AS_HELP_STRING([],
 235[used only if you need linking with libiconv]),
 236GIT_PARSE_WITH(iconv))
 237
 238## --enable-FEATURE[=ARG] and --disable-FEATURE
 239#
 240# Define USE_NSEC below if you want git to care about sub-second file mtimes
 241# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 242# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 243# randomly break unless your underlying filesystem supports those sub-second
 244# times (my ext3 doesn't).
 245#
 246# Define USE_STDEV below if you want git to care about the underlying device
 247# change being considered an inode change from the update-index perspective.
 248
 249#
 250# Allow user to set ETC_GITCONFIG variable
 251GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 252                        Use VALUE instead of /etc/gitconfig as the
 253                        global git configuration file.
 254                        If VALUE is not fully qualified it will be interpretted
 255                        as a path relative to the computed prefix at runtime.)
 256
 257#
 258# Allow user to set the default pager
 259GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 260                        Use VALUE as the fall-back pager instead of 'less'.
 261                        This is used by things like 'git log' when the user
 262                        does not specify a pager to use through alternate
 263                        methods. eg: /usr/bin/pager)
 264#
 265# Allow user to set the default editor
 266GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 267                        Use VALUE as the fall-back editor instead of 'vi'.
 268                        This is used by things like 'git commit' when the user
 269                        does not specify a preferred editor through other
 270                        methods. eg: /usr/bin/editor)
 271
 272#
 273# Define SHELL_PATH to provide path to shell.
 274GIT_ARG_SET_PATH(shell)
 275#
 276# Define PERL_PATH to provide path to Perl.
 277GIT_ARG_SET_PATH(perl)
 278#
 279# Define PYTHON_PATH to provide path to Python.
 280GIT_ARG_SET_PATH(python)
 281#
 282# Define ZLIB_PATH to provide path to zlib.
 283GIT_ARG_SET_PATH(zlib)
 284#
 285# Declare the with-tcltk/without-tcltk options.
 286AC_ARG_WITH(tcltk,
 287AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 288AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 289AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 290AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 291GIT_PARSE_WITH(tcltk))
 292#
 293
 294
 295## Checks for programs.
 296AC_MSG_NOTICE([CHECKS for programs])
 297#
 298AC_PROG_CC([cc gcc])
 299# which switch to pass runtime path to dynamic libraries to the linker
 300AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 301   SAVE_LDFLAGS="${LDFLAGS}"
 302   LDFLAGS="${SAVE_LDFLAGS} -R /"
 303   AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 304   LDFLAGS="${SAVE_LDFLAGS}"
 305])
 306if test "$git_cv_ld_dashr" = "yes"; then
 307   AC_SUBST(CC_LD_DYNPATH, [-R])
 308else
 309   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 310      SAVE_LDFLAGS="${LDFLAGS}"
 311      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 312      AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 313      LDFLAGS="${SAVE_LDFLAGS}"
 314   ])
 315   if test "$git_cv_ld_wl_rpath" = "yes"; then
 316      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 317   else
 318      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 319         SAVE_LDFLAGS="${LDFLAGS}"
 320         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 321         AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 322         LDFLAGS="${SAVE_LDFLAGS}"
 323      ])
 324      if test "$git_cv_ld_rpath" = "yes"; then
 325         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 326      else
 327         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 328      fi
 329   fi
 330fi
 331#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 332AC_CHECK_TOOLS(AR, [gar ar], :)
 333AC_CHECK_PROGS(TAR, [gtar tar])
 334# TCLTK_PATH will be set to some value if we want Tcl/Tk
 335# or will be empty otherwise.
 336if test -z "$NO_TCLTK"; then
 337  if test "$with_tcltk" = ""; then
 338  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 339    TCLTK_PATH=wish
 340    AC_SUBST(TCLTK_PATH)
 341  elif test "$with_tcltk" = "yes"; then
 342  # Tcl/Tk check requested.
 343    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 344  else
 345    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 346    TCLTK_PATH="$with_tcltk"
 347    AC_SUBST(TCLTK_PATH)
 348  fi
 349fi
 350AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 351if test -n "$ASCIIDOC"; then
 352        AC_MSG_CHECKING([for asciidoc version])
 353        asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 354        case "${asciidoc_version}" in
 355        asciidoc' '8*)
 356                ASCIIDOC8=YesPlease
 357                AC_MSG_RESULT([${asciidoc_version} > 7])
 358                ;;
 359        asciidoc' '7*)
 360                ASCIIDOC8=
 361                AC_MSG_RESULT([${asciidoc_version}])
 362                ;;
 363        *)
 364                ASCIIDOC8=
 365                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 366                ;;
 367        esac
 368fi
 369AC_SUBST(ASCIIDOC8)
 370
 371
 372## Checks for libraries.
 373AC_MSG_NOTICE([CHECKS for libraries])
 374#
 375# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 376# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 377
 378GIT_STASH_FLAGS($OPENSSLDIR)
 379
 380AC_CHECK_LIB([crypto], [SHA1_Init],
 381[NEEDS_SSL_WITH_CRYPTO=],
 382[AC_CHECK_LIB([ssl], [SHA1_Init],
 383 [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 384 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 385
 386GIT_UNSTASH_FLAGS($OPENSSLDIR)
 387
 388AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 389AC_SUBST(NO_OPENSSL)
 390
 391#
 392# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 393# git-http-push are not built, and you cannot use http:// and https://
 394# transports.
 395
 396GIT_STASH_FLAGS($CURLDIR)
 397
 398AC_CHECK_LIB([curl], [curl_global_init],
 399[NO_CURL=],
 400[NO_CURL=YesPlease])
 401
 402GIT_UNSTASH_FLAGS($CURLDIR)
 403
 404AC_SUBST(NO_CURL)
 405
 406#
 407# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 408# not built, and you cannot push using http:// and https:// transports.
 409
 410GIT_STASH_FLAGS($EXPATDIR)
 411
 412AC_CHECK_LIB([expat], [XML_ParserCreate],
 413[NO_EXPAT=],
 414[NO_EXPAT=YesPlease])
 415
 416GIT_UNSTASH_FLAGS($EXPATDIR)
 417
 418AC_SUBST(NO_EXPAT)
 419
 420#
 421# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 422# some Solaris installations).
 423# Define NO_ICONV if neither libc nor libiconv support iconv.
 424
 425if test -z "$NO_ICONV"; then
 426
 427GIT_STASH_FLAGS($ICONVDIR)
 428
 429AC_DEFUN([ICONVTEST_SRC], [
 430#include <iconv.h>
 431
 432int main(void)
 433{
 434        iconv_open("", "");
 435        return 0;
 436}
 437])
 438
 439if test -n "$ICONVDIR"; then
 440   lib_order="-liconv -lc"
 441else
 442   lib_order="-lc -liconv"
 443fi
 444
 445NO_ICONV=YesPlease
 446
 447for l in $lib_order; do
 448    if test "$l" = "-liconv"; then
 449       NEEDS_LIBICONV=YesPlease
 450    else
 451       NEEDS_LIBICONV=
 452    fi
 453
 454    old_LIBS="$LIBS"
 455    LIBS="$LIBS $l"
 456    AC_MSG_CHECKING([for iconv in $l])
 457    AC_LINK_IFELSE(ICONVTEST_SRC,
 458        [AC_MSG_RESULT([yes])
 459        NO_ICONV=
 460        break],
 461        [AC_MSG_RESULT([no])])
 462    LIBS="$old_LIBS"
 463done
 464
 465#in case of break
 466LIBS="$old_LIBS"
 467
 468GIT_UNSTASH_FLAGS($ICONVDIR)
 469
 470AC_SUBST(NEEDS_LIBICONV)
 471AC_SUBST(NO_ICONV)
 472
 473if test -n "$NO_ICONV"; then
 474    NEEDS_LIBICONV=
 475fi
 476
 477fi
 478
 479#
 480# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 481
 482GIT_STASH_FLAGS($ZLIB_PATH)
 483
 484AC_DEFUN([ZLIBTEST_SRC], [
 485#include <zlib.h>
 486
 487int main(void)
 488{
 489        deflateBound(0, 0);
 490        return 0;
 491}
 492])
 493AC_MSG_CHECKING([for deflateBound in -lz])
 494old_LIBS="$LIBS"
 495LIBS="$LIBS -lz"
 496AC_LINK_IFELSE(ZLIBTEST_SRC,
 497        [AC_MSG_RESULT([yes])],
 498        [AC_MSG_RESULT([no])
 499        NO_DEFLATE_BOUND=yes])
 500LIBS="$old_LIBS"
 501
 502GIT_UNSTASH_FLAGS($ZLIB_PATH)
 503
 504AC_SUBST(NO_DEFLATE_BOUND)
 505
 506#
 507# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 508# Patrick Mauritz).
 509AC_CHECK_LIB([c], [socket],
 510[NEEDS_SOCKET=],
 511[NEEDS_SOCKET=YesPlease])
 512AC_SUBST(NEEDS_SOCKET)
 513test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 514
 515#
 516# Define NEEDS_RESOLV if linking with -lnsl and/or -lsocket is not enough.
 517# Notably on Solaris hstrerror resides in libresolv and on Solaris 7
 518# inet_ntop and inet_pton additionally reside there.
 519AC_CHECK_LIB([c], [hstrerror],
 520[NEEDS_RESOLV=],
 521[NEEDS_RESOLV=YesPlease])
 522AC_SUBST(NEEDS_RESOLV)
 523test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 524
 525AC_CHECK_LIB([c], [basename],
 526[NEEDS_LIBGEN=],
 527[NEEDS_LIBGEN=YesPlease])
 528AC_SUBST(NEEDS_LIBGEN)
 529test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 530
 531## Checks for header files.
 532AC_MSG_NOTICE([CHECKS for header files])
 533#
 534# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 535AC_CHECK_HEADER([sys/select.h],
 536[NO_SYS_SELECT_H=],
 537[NO_SYS_SELECT_H=UnfortunatelyYes])
 538AC_SUBST(NO_SYS_SELECT_H)
 539#
 540# Define OLD_ICONV if your library has an old iconv(), where the second
 541# (input buffer pointer) parameter is declared with type (const char **).
 542AC_DEFUN([OLDICONVTEST_SRC], [[
 543#include <iconv.h>
 544
 545extern size_t iconv(iconv_t cd,
 546                    char **inbuf, size_t *inbytesleft,
 547                    char **outbuf, size_t *outbytesleft);
 548
 549int main(void)
 550{
 551        return 0;
 552}
 553]])
 554
 555GIT_STASH_FLAGS($ICONVDIR)
 556
 557AC_MSG_CHECKING([for old iconv()])
 558AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 559        [AC_MSG_RESULT([no])],
 560        [AC_MSG_RESULT([yes])
 561        OLD_ICONV=UnfortunatelyYes])
 562
 563GIT_UNSTASH_FLAGS($ICONVDIR)
 564
 565AC_SUBST(OLD_ICONV)
 566
 567## Checks for typedefs, structures, and compiler characteristics.
 568AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 569#
 570# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 571AC_CHECK_MEMBER(struct dirent.d_ino,
 572[NO_D_INO_IN_DIRENT=],
 573[NO_D_INO_IN_DIRENT=YesPlease],
 574[#include <dirent.h>])
 575AC_SUBST(NO_D_INO_IN_DIRENT)
 576#
 577# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 578# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 579AC_CHECK_MEMBER(struct dirent.d_type,
 580[NO_D_TYPE_IN_DIRENT=],
 581[NO_D_TYPE_IN_DIRENT=YesPlease],
 582[#include <dirent.h>])
 583AC_SUBST(NO_D_TYPE_IN_DIRENT)
 584#
 585# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 586# sockaddr_storage.
 587AC_CHECK_TYPE(struct sockaddr_storage,
 588[NO_SOCKADDR_STORAGE=],
 589[NO_SOCKADDR_STORAGE=YesPlease],[
 590#include <sys/types.h>
 591#include <sys/socket.h>
 592])
 593AC_SUBST(NO_SOCKADDR_STORAGE)
 594#
 595# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 596AC_CHECK_TYPE([struct addrinfo],[
 597 GIT_CHECK_FUNC([getaddrinfo],
 598  [NO_IPV6=],
 599  [NO_IPV6=YesPlease])
 600],[NO_IPV6=YesPlease],[
 601#include <sys/types.h>
 602#include <sys/socket.h>
 603#include <netdb.h>
 604])
 605AC_SUBST(NO_IPV6)
 606#
 607# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 608# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 609# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 610# some C compilers supported these specifiers prior to C99 as an extension.
 611AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 612 [ac_cv_c_c99_format],
 613[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 614AC_RUN_IFELSE(
 615        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 616                [[char buf[64];
 617                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 618                  return 1;
 619                else if (strcmp(buf, "12345"))
 620                  return 2;]])],
 621        [ac_cv_c_c99_format=yes],
 622        [ac_cv_c_c99_format=no])
 623])
 624if test $ac_cv_c_c99_format = no; then
 625        NO_C99_FORMAT=YesPlease
 626else
 627        NO_C99_FORMAT=
 628fi
 629AC_SUBST(NO_C99_FORMAT)
 630#
 631# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 632# when attempting to read from an fopen'ed directory.
 633AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 634 [ac_cv_fread_reads_directories],
 635[
 636AC_RUN_IFELSE(
 637        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 638                [[char c;
 639                FILE *f = fopen(".", "r");
 640                return f && fread(&c, 1, 1, f)]])],
 641        [ac_cv_fread_reads_directories=no],
 642        [ac_cv_fread_reads_directories=yes])
 643])
 644if test $ac_cv_fread_reads_directories = yes; then
 645        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 646else
 647        FREAD_READS_DIRECTORIES=
 648fi
 649AC_SUBST(FREAD_READS_DIRECTORIES)
 650#
 651# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 652# or vsnprintf() return -1 instead of number of characters which would
 653# have been written to the final string if enough space had been available.
 654AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 655 [ac_cv_snprintf_returns_bogus],
 656[
 657AC_RUN_IFELSE(
 658        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 659                #include "stdarg.h"
 660
 661                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 662                {
 663                  int ret;
 664                  va_list ap;
 665                  va_start(ap, format);
 666                  ret = vsnprintf(str, maxsize, format, ap);
 667                  va_end(ap);
 668                  return ret;
 669                }],
 670                [[char buf[6];
 671                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 672                      || strcmp(buf, "12")) return 1;
 673                  if (snprintf(buf, 3, "%s", "12345") != 5
 674                      || strcmp(buf, "12")) return 1]])],
 675        [ac_cv_snprintf_returns_bogus=no],
 676        [ac_cv_snprintf_returns_bogus=yes])
 677])
 678if test $ac_cv_snprintf_returns_bogus = yes; then
 679        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 680else
 681        SNPRINTF_RETURNS_BOGUS=
 682fi
 683AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 684
 685
 686## Checks for library functions.
 687## (in default C library and libraries checked by AC_CHECK_LIB)
 688AC_MSG_NOTICE([CHECKS for library functions])
 689#
 690# Define NO_LIBGEN_H if you don't have libgen.h.
 691AC_CHECK_HEADER([libgen.h],
 692[NO_LIBGEN_H=],
 693[NO_LIBGEN_H=YesPlease])
 694AC_SUBST(NO_LIBGEN_H)
 695#
 696# Define NO_STRCASESTR if you don't have strcasestr.
 697GIT_CHECK_FUNC(strcasestr,
 698[NO_STRCASESTR=],
 699[NO_STRCASESTR=YesPlease])
 700AC_SUBST(NO_STRCASESTR)
 701#
 702# Define NO_MEMMEM if you don't have memmem.
 703GIT_CHECK_FUNC(memmem,
 704[NO_MEMMEM=],
 705[NO_MEMMEM=YesPlease])
 706AC_SUBST(NO_MEMMEM)
 707#
 708# Define NO_STRLCPY if you don't have strlcpy.
 709GIT_CHECK_FUNC(strlcpy,
 710[NO_STRLCPY=],
 711[NO_STRLCPY=YesPlease])
 712AC_SUBST(NO_STRLCPY)
 713#
 714# Define NO_UINTMAX_T if your platform does not have uintmax_t
 715AC_CHECK_TYPE(uintmax_t,
 716[NO_UINTMAX_T=],
 717[NO_UINTMAX_T=YesPlease],[
 718#include <inttypes.h>
 719])
 720AC_SUBST(NO_UINTMAX_T)
 721#
 722# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 723GIT_CHECK_FUNC(strtoumax,
 724[NO_STRTOUMAX=],
 725[NO_STRTOUMAX=YesPlease])
 726AC_SUBST(NO_STRTOUMAX)
 727#
 728# Define NO_SETENV if you don't have setenv in the C library.
 729GIT_CHECK_FUNC(setenv,
 730[NO_SETENV=],
 731[NO_SETENV=YesPlease])
 732AC_SUBST(NO_SETENV)
 733#
 734# Define NO_UNSETENV if you don't have unsetenv in the C library.
 735GIT_CHECK_FUNC(unsetenv,
 736[NO_UNSETENV=],
 737[NO_UNSETENV=YesPlease])
 738AC_SUBST(NO_UNSETENV)
 739#
 740# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 741GIT_CHECK_FUNC(mkdtemp,
 742[NO_MKDTEMP=],
 743[NO_MKDTEMP=YesPlease])
 744AC_SUBST(NO_MKDTEMP)
 745#
 746# Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 747GIT_CHECK_FUNC(mkstemps,
 748[NO_MKSTEMPS=],
 749[NO_MKSTEMPS=YesPlease])
 750AC_SUBST(NO_MKSTEMPS)
 751#
 752#
 753# Define NO_MMAP if you want to avoid mmap.
 754#
 755# Define NO_ICONV if your libc does not properly support iconv.
 756
 757
 758## Other checks.
 759# Define USE_PIC if you need the main git objects to be built with -fPIC
 760# in order to build and link perl/Git.so.  x86-64 seems to need this.
 761#
 762# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 763# Enable it on Windows.  By default, symrefs are still used.
 764#
 765# Define NO_PTHREADS if we do not have pthreads
 766#
 767# Define PTHREAD_LIBS to the linker flag used for Pthread support and define
 768# THREADED_DELTA_SEARCH if Pthreads are available.
 769AC_DEFUN([PTHREADTEST_SRC], [
 770#include <pthread.h>
 771
 772int main(void)
 773{
 774        pthread_mutex_t test_mutex;
 775        return (0);
 776}
 777])
 778
 779dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 780dnl   [[#include <pthread.h>]],
 781dnl   [[pthread_mutex_t test_mutex;]]
 782dnl )])
 783
 784NO_PTHREADS=UnfortunatelyYes
 785THREADED_DELTA_SEARCH=
 786PTHREAD_LIBS=
 787
 788if test -n "$USER_NOPTHREAD"; then
 789   AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 790# handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 791# -D_REENTRANT' or some such.
 792elif test -z "$PTHREAD_CFLAGS"; then
 793  for opt in -pthread -lpthread; do
 794     old_CFLAGS="$CFLAGS"
 795     CFLAGS="$opt $CFLAGS"
 796     AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 797     AC_LINK_IFELSE(PTHREADTEST_SRC,
 798        [AC_MSG_RESULT([yes])
 799                NO_PTHREADS=
 800                PTHREAD_LIBS="$opt"
 801                THREADED_DELTA_SEARCH=YesPlease
 802                break
 803        ],
 804        [AC_MSG_RESULT([no])])
 805      CFLAGS="$old_CFLAGS"
 806  done
 807else
 808  old_CFLAGS="$CFLAGS"
 809  CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 810  AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 811  AC_LINK_IFELSE(PTHREADTEST_SRC,
 812        [AC_MSG_RESULT([yes])
 813                NO_PTHREADS=
 814                PTHREAD_LIBS="$PTHREAD_CFLAGS"
 815                THREADED_DELTA_SEARCH=YesPlease
 816        ],
 817        [AC_MSG_RESULT([no])])
 818
 819  CFLAGS="$old_CFLAGS"
 820fi
 821
 822CFLAGS="$old_CFLAGS"
 823
 824AC_SUBST(PTHREAD_LIBS)
 825AC_SUBST(NO_PTHREADS)
 826AC_SUBST(THREADED_DELTA_SEARCH)
 827
 828## Output files
 829AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 830AC_OUTPUT
 831
 832
 833## Cleanup
 834rm -f "${config_append}"