1package Git::SVN;
2use strict;
3use warnings;
4use Fcntl qw/:DEFAULT :seek/;
5use constant rev_map_fmt => 'NH40';
6use vars qw/$_no_metadata
7 $_repack $_repack_flags $_use_svm_props $_head
8 $_use_svnsync_props $no_reuse_existing
9 $_use_log_author $_add_author_from $_localtime/;
10use Carp qw/croak/;
11use File::Path qw/mkpath/;
12use File::Copy qw/copy/;
13use IPC::Open3;
14use Memoize; # core since 5.8.0, Jul 2002
15use Memoize::Storable;
16use POSIX qw(:signal_h);
17use Git qw(
19 command
20 command_oneline
21 command_noisy
22 command_output_pipe
23 command_close_pipe
24 get_tz_offset
25);
26use Git::SVN::Utils qw(
27 fatal
28 can_compress
29 join_paths
30 canonicalize_path
31 canonicalize_url
32 add_path_to_url
33);
34my $can_use_yaml;
36BEGIN {
37 $can_use_yaml = eval { require Git::SVN::Memoize::YAML; 1};
38}
39our $_follow_parent = 1;
41our $_minimize_url = 'unset';
42our $default_repo_id = 'svn';
43our $default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
44my ($_gc_nr, $_gc_period);
46# properties that we do not log:
48my %SKIP_PROP;
49BEGIN {
50 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
51 svn:special svn:executable
52 svn:entry:committed-rev
53 svn:entry:last-author
54 svn:entry:uuid
55 svn:entry:committed-date/;
56 # some options are read globally, but can be overridden locally
58 # per [svn-remote "..."] section. Command-line options will *NOT*
59 # override options set in an [svn-remote "..."] section
60 no strict 'refs';
61 for my $option (qw/follow_parent no_metadata use_svm_props
62 use_svnsync_props/) {
63 my $key = $option;
64 $key =~ tr/_//d;
65 my $prop = "-$option";
66 *$option = sub {
67 my ($self) = @_;
68 return $self->{$prop} if exists $self->{$prop};
69 my $k = "svn-remote.$self->{repo_id}.$key";
70 eval { command_oneline(qw/config --get/, $k) };
71 if ($@) {
72 $self->{$prop} = ${"Git::SVN::_$option"};
73 } else {
74 my $v = command_oneline(qw/config --bool/,$k);
75 $self->{$prop} = $v eq 'false' ? 0 : 1;
76 }
77 return $self->{$prop};
78 }
79 }
80}
81my (%LOCKFILES, %INDEX_FILES);
84END {
85 unlink keys %LOCKFILES if %LOCKFILES;
86 unlink keys %INDEX_FILES if %INDEX_FILES;
87}
88sub resolve_local_globs {
90 my ($url, $fetch, $glob_spec) = @_;
91 return unless defined $glob_spec;
92 my $ref = $glob_spec->{ref};
93 my $path = $glob_spec->{path};
94 foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
95 next unless m#^$ref->{regex}$#;
96 my $p = $1;
97 my $pathname = desanitize_refname($path->full_path($p));
98 my $refname = desanitize_refname($ref->full_path($p));
99 if (my $existing = $fetch->{$pathname}) {
100 if ($existing ne $refname) {
101 die "Refspec conflict:\n",
102 "existing: $existing\n",
103 " globbed: $refname\n";
104 }
105 my $u = (::cmt_metadata("$refname"))[0];
106 $u =~ s!^\Q$url\E(/|$)!! or die
107 "$refname: '$url' not found in '$u'\n";
108 if ($pathname ne $u) {
109 warn "W: Refspec glob conflict ",
110 "(ref: $refname):\n",
111 "expected path: $pathname\n",
112 " real path: $u\n",
113 "Continuing ahead with $u\n";
114 next;
115 }
116 } else {
117 $fetch->{$pathname} = $refname;
118 }
119 }
120}
121sub parse_revision_argument {
123 my ($base, $head) = @_;
124 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
125 return ($base, $head);
126 }
127 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
128 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
129 return ($head, $head) if ($::_revision eq 'HEAD');
130 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
131 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
132 die "revision argument: $::_revision not understood by git-svn\n";
133}
134sub fetch_all {
136 my ($repo_id, $remotes) = @_;
137 if (ref $repo_id) {
138 my $gs = $repo_id;
139 $repo_id = undef;
140 $repo_id = $gs->{repo_id};
141 }
142 $remotes ||= read_all_remotes();
143 my $remote = $remotes->{$repo_id} or
144 die "[svn-remote \"$repo_id\"] unknown\n";
145 my $fetch = $remote->{fetch};
146 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
147 my (@gs, @globs);
148 my $ra = Git::SVN::Ra->new($url);
149 my $uuid = $ra->get_uuid;
150 my $head = $ra->get_latest_revnum;
151 # ignore errors, $head revision may not even exist anymore
153 eval { $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] }) };
154 warn "W: $@\n" if $@;
155 my $base = defined $fetch ? $head : 0;
157 # read the max revs for wildcard expansion (branches/*, tags/*)
159 foreach my $t (qw/branches tags/) {
160 defined $remote->{$t} or next;
161 push @globs, @{$remote->{$t}};
162 my $max_rev = eval { tmp_config(qw/--int --get/,
164 "svn-remote.$repo_id.${t}-maxRev") };
165 if (defined $max_rev && ($max_rev < $base)) {
166 $base = $max_rev;
167 } elsif (!defined $max_rev) {
168 $base = 0;
169 }
170 }
171 if ($fetch) {
173 foreach my $p (sort keys %$fetch) {
174 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
175 my $lr = $gs->rev_map_max;
176 if (defined $lr) {
177 $base = $lr if ($lr < $base);
178 }
179 push @gs, $gs;
180 }
181 }
182 ($base, $head) = parse_revision_argument($base, $head);
184 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
185}
186sub read_all_remotes {
188 my $r = {};
189 my $use_svm_props = eval { command_oneline(qw/config --bool
190 svn.useSvmProps/) };
191 $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
192 my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
193 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
194 if (m!^(.+)\.fetch=$svn_refspec$!) {
195 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
196 die("svn-remote.$remote: remote ref '$remote_ref' "
197 . "must start with 'refs/'\n")
198 unless $remote_ref =~ m{^refs/};
199 $local_ref = uri_decode($local_ref);
200 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
201 $r->{$remote}->{svm} = {} if $use_svm_props;
202 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
203 $r->{$1}->{svm} = {};
204 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
205 $r->{$1}->{url} = canonicalize_url($2);
206 } elsif (m!^(.+)\.pushurl=\s*(.*)\s*$!) {
207 $r->{$1}->{pushurl} = canonicalize_url($2);
208 } elsif (m!^(.+)\.ignore-refs=\s*(.*)\s*$!) {
209 $r->{$1}->{ignore_refs_regex} = $2;
210 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
211 my ($remote, $t, $local_ref, $remote_ref) =
212 ($1, $2, $3, $4);
213 die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
214 . "must start with 'refs/'\n")
215 unless $remote_ref =~ m{^refs/};
216 $local_ref = uri_decode($local_ref);
217 require Git::SVN::GlobSpec;
219 my $rs = {
220 t => $t,
221 remote => $remote,
222 path => Git::SVN::GlobSpec->new($local_ref, 1),
223 ref => Git::SVN::GlobSpec->new($remote_ref, 0) };
224 if (length($rs->{ref}->{right}) != 0) {
225 die "The '*' glob character must be the last ",
226 "character of '$remote_ref'\n";
227 }
228 push @{ $r->{$remote}->{$t} }, $rs;
229 }
230 }
231 map {
233 if (defined $r->{$_}->{svm}) {
234 my $svm;
235 eval {
236 my $section = "svn-remote.$_";
237 $svm = {
238 source => tmp_config('--get',
239 "$section.svm-source"),
240 replace => tmp_config('--get',
241 "$section.svm-replace"),
242 }
243 };
244 $r->{$_}->{svm} = $svm;
245 }
246 } keys %$r;
247 foreach my $remote (keys %$r) {
249 foreach ( grep { defined $_ }
250 map { $r->{$remote}->{$_} } qw(branches tags) ) {
251 foreach my $rs ( @$_ ) {
252 $rs->{ignore_refs_regex} =
253 $r->{$remote}->{ignore_refs_regex};
254 }
255 }
256 }
257 $r;
259}
260sub init_vars {
262 $_gc_nr = $_gc_period = 1000;
263 if (defined $_repack || defined $_repack_flags) {
264 warn "Repack options are obsolete; they have no effect.\n";
265 }
266}
267sub verify_remotes_sanity {
269 return unless -d $ENV{GIT_DIR};
270 my %seen;
271 foreach (command(qw/config -l/)) {
272 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
273 if ($seen{$1}) {
274 die "Remote ref refs/remote/$1 is tracked by",
275 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
276 "Please resolve this ambiguity in ",
277 "your git configuration file before ",
278 "continuing\n";
279 }
280 $seen{$1} = $_;
281 }
282 }
283}
284sub find_existing_remote {
286 my ($url, $remotes) = @_;
287 return undef if $no_reuse_existing;
288 my $existing;
289 foreach my $repo_id (keys %$remotes) {
290 my $u = $remotes->{$repo_id}->{url} or next;
291 next if $u ne $url;
292 $existing = $repo_id;
293 last;
294 }
295 $existing;
296}
297sub init_remote_config {
299 my ($self, $url, $no_write) = @_;
300 $url = canonicalize_url($url);
301 my $r = read_all_remotes();
302 my $existing = find_existing_remote($url, $r);
303 if ($existing) {
304 unless ($no_write) {
305 print STDERR "Using existing ",
306 "[svn-remote \"$existing\"]\n";
307 }
308 $self->{repo_id} = $existing;
309 } elsif ($_minimize_url) {
310 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
311 $existing = find_existing_remote($min_url, $r);
312 if ($existing) {
313 unless ($no_write) {
314 print STDERR "Using existing ",
315 "[svn-remote \"$existing\"]\n";
316 }
317 $self->{repo_id} = $existing;
318 }
319 if ($min_url ne $url) {
320 unless ($no_write) {
321 print STDERR "Using higher level of URL: ",
322 "$url => $min_url\n";
323 }
324 my $old_path = $self->path;
325 $url =~ s!^\Q$min_url\E(/|$)!!;
326 $url = join_paths($url, $old_path);
327 $self->path($url);
328 $url = $min_url;
329 }
330 }
331 my $orig_url;
332 if (!$existing) {
333 # verify that we aren't overwriting anything:
334 $orig_url = eval {
335 command_oneline('config', '--get',
336 "svn-remote.$self->{repo_id}.url")
337 };
338 if ($orig_url && ($orig_url ne $url)) {
339 die "svn-remote.$self->{repo_id}.url already set: ",
340 "$orig_url\nwanted to set to: $url\n";
341 }
342 }
343 my ($xrepo_id, $xpath) = find_ref($self->refname);
344 if (!$no_write && defined $xpath) {
345 die "svn-remote.$xrepo_id.fetch already set to track ",
346 "$xpath:", $self->refname, "\n";
347 }
348 unless ($no_write) {
349 command_noisy('config',
350 "svn-remote.$self->{repo_id}.url", $url);
351 my $path = $self->path;
352 $path =~ s{^/}{};
353 $path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
354 $self->path($path);
355 command_noisy('config', '--add',
356 "svn-remote.$self->{repo_id}.fetch",
357 $self->path.":".$self->refname);
358 }
359 $self->url($url);
360}
361sub find_by_url { # repos_root and, path are optional
363 my ($class, $full_url, $repos_root, $path) = @_;
364 $full_url = canonicalize_url($full_url);
366 return undef unless defined $full_url;
368 remove_username($full_url);
369 remove_username($repos_root) if defined $repos_root;
370 my $remotes = read_all_remotes();
371 if (defined $full_url && defined $repos_root && !defined $path) {
372 $path = $full_url;
373 $path =~ s#^\Q$repos_root\E(?:/|$)##;
374 }
375 foreach my $repo_id (keys %$remotes) {
376 my $u = $remotes->{$repo_id}->{url} or next;
377 remove_username($u);
378 next if defined $repos_root && $repos_root ne $u;
379 my $fetch = $remotes->{$repo_id}->{fetch} || {};
381 foreach my $t (qw/branches tags/) {
382 foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
383 resolve_local_globs($u, $fetch, $globspec);
384 }
385 }
386 my $p = $path;
387 my $rwr = rewrite_root({repo_id => $repo_id});
388 my $svm = $remotes->{$repo_id}->{svm}
389 if defined $remotes->{$repo_id}->{svm};
390 unless (defined $p) {
391 $p = $full_url;
392 my $z = $u;
393 my $prefix = '';
394 if ($rwr) {
395 $z = $rwr;
396 remove_username($z);
397 } elsif (defined $svm) {
398 $z = $svm->{source};
399 $prefix = $svm->{replace};
400 $prefix =~ s#^\Q$u\E(?:/|$)##;
401 $prefix =~ s#/$##;
402 }
403 $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
404 }
405 # remote fetch paths are not URI escaped. Decode ours
407 # so they match
408 $p = uri_decode($p);
409 foreach my $f (keys %$fetch) {
411 next if $f ne $p;
412 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
413 }
414 }
415 undef;
416}
417sub init {
419 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
420 my $self = _new($class, $repo_id, $ref_id, $path);
421 if (defined $url) {
422 $self->init_remote_config($url, $no_write);
423 }
424 $self;
425}
426sub find_ref {
428 my ($ref_id) = @_;
429 foreach (command(qw/config -l/)) {
430 next unless m!^svn-remote\.(.+)\.fetch=
431 \s*(.*?)\s*:\s*(.+?)\s*$!x;
432 my ($repo_id, $path, $ref) = ($1, $2, $3);
433 if ($ref eq $ref_id) {
434 $path = '' if ($path =~ m#^\./?#);
435 return ($repo_id, $path);
436 }
437 }
438 (undef, undef, undef);
439}
440sub new {
442 my ($class, $ref_id, $repo_id, $path) = @_;
443 if (defined $ref_id && !defined $repo_id && !defined $path) {
444 ($repo_id, $path) = find_ref($ref_id);
445 if (!defined $repo_id) {
446 die "Could not find a \"svn-remote.*.fetch\" key ",
447 "in the repository configuration matching: ",
448 "$ref_id\n";
449 }
450 }
451 my $self = _new($class, $repo_id, $ref_id, $path);
452 if (!defined $self->path || !length $self->path) {
453 my $fetch = command_oneline('config', '--get',
454 "svn-remote.$repo_id.fetch",
455 ":$ref_id\$") or
456 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
457 "\":$ref_id\$\" in config\n";
458 my($path) = split(/\s*:\s*/, $fetch);
459 $self->path($path);
460 }
461 {
462 my $path = $self->path;
463 $path =~ s{\A/}{};
464 $path =~ s{/\z}{};
465 $self->path($path);
466 }
467 my $url = command_oneline('config', '--get',
468 "svn-remote.$repo_id.url") or
469 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
470 $self->url($url);
471 $self->{pushurl} = eval { command_oneline('config', '--get',
472 "svn-remote.$repo_id.pushurl") };
473 $self->rebuild;
474 $self;
475}
476sub refname {
478 my ($refname) = $_[0]->{ref_id} ;
479 # It cannot end with a slash /, we'll throw up on this because
481 # SVN can't have directories with a slash in their name, either:
482 if ($refname =~ m{/$}) {
483 die "ref: '$refname' ends with a trailing slash; this is ",
484 "not permitted by git or Subversion\n";
485 }
486 # It cannot have ASCII control character space, tilde ~, caret ^,
488 # colon :, question-mark ?, asterisk *, space, or open bracket [
489 # anywhere.
490 #
491 # Additionally, % must be escaped because it is used for escaping
492 # and we want our escaped refname to be reversible
493 $refname =~ s{([ \%~\^:\?\*\[\t])}{sprintf('%%%02X',ord($1))}eg;
494 # no slash-separated component can begin with a dot .
496 # /.* becomes /%2E*
497 $refname =~ s{/\.}{/%2E}g;
498 # It cannot have two consecutive dots .. anywhere
500 # .. becomes %2E%2E
501 $refname =~ s{\.\.}{%2E%2E}g;
502 # trailing dots and .lock are not allowed
504 # .$ becomes %2E and .lock becomes %2Elock
505 $refname =~ s{\.(?=$|lock$)}{%2E};
506 # the sequence @{ is used to access the reflog
508 # @{ becomes %40{
509 $refname =~ s{\@\{}{%40\{}g;
510 return $refname;
512}
513sub desanitize_refname {
515 my ($refname) = @_;
516 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
517 return $refname;
518}
519sub svm_uuid {
521 my ($self) = @_;
522 return $self->{svm}->{uuid} if $self->svm;
523 $self->ra;
524 unless ($self->{svm}) {
525 die "SVM UUID not cached, and reading remotely failed\n";
526 }
527 $self->{svm}->{uuid};
528}
529sub svm {
531 my ($self) = @_;
532 return $self->{svm} if $self->{svm};
533 my $svm;
534 # see if we have it in our config, first:
535 eval {
536 my $section = "svn-remote.$self->{repo_id}";
537 $svm = {
538 source => tmp_config('--get', "$section.svm-source"),
539 uuid => tmp_config('--get', "$section.svm-uuid"),
540 replace => tmp_config('--get', "$section.svm-replace"),
541 }
542 };
543 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
544 $self->{svm} = $svm;
545 }
546 $self->{svm};
547}
548sub _set_svm_vars {
550 my ($self, $ra) = @_;
551 return $ra if $self->svm;
552 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
554 "(svm:source, svm:uuid) ",
555 "from the following URLs:\n" );
556 sub read_svm_props {
557 my ($self, $ra, $path, $r) = @_;
558 my $props = ($ra->get_dir($path, $r))[2];
559 my $src = $props->{'svm:source'};
560 my $uuid = $props->{'svm:uuid'};
561 return undef if (!$src || !$uuid);
562 chomp($src, $uuid);
564 $uuid =~ m{^[0-9a-f\-]{30,}$}i
566 or die "doesn't look right - svm:uuid is '$uuid'\n";
567 # the '!' is used to mark the repos_root!/relative/path
569 $src =~ s{/?!/?}{/};
570 $src =~ s{/+$}{}; # no trailing slashes please
571 # username is of no interest
572 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
573 my $replace = add_path_to_url($ra->url, $path);
575 my $section = "svn-remote.$self->{repo_id}";
577 tmp_config("$section.svm-source", $src);
578 tmp_config("$section.svm-replace", $replace);
579 tmp_config("$section.svm-uuid", $uuid);
580 $self->{svm} = {
581 source => $src,
582 uuid => $uuid,
583 replace => $replace
584 };
585 }
586 my $r = $ra->get_latest_revnum;
588 my $path = $self->path;
589 my %tried;
590 while (length $path) {
591 my $try = add_path_to_url($self->url, $path);
592 unless ($tried{$try}) {
593 return $ra if $self->read_svm_props($ra, $path, $r);
594 $tried{$try} = 1;
595 }
596 $path =~ s#/?[^/]+$##;
597 }
598 die "Path: '$path' should be ''\n" if $path ne '';
599 return $ra if $self->read_svm_props($ra, $path, $r);
600 $tried{ add_path_to_url($self->url, $path) } = 1;
601 if ($ra->{repos_root} eq $self->url) {
603 die @err, (map { " $_\n" } keys %tried), "\n";
604 }
605 # nope, make sure we're connected to the repository root:
607 my $ok;
608 my @tried_b;
609 $path = $ra->{svn_path};
610 $ra = Git::SVN::Ra->new($ra->{repos_root});
611 while (length $path) {
612 my $try = add_path_to_url($ra->url, $path);
613 unless ($tried{$try}) {
614 $ok = $self->read_svm_props($ra, $path, $r);
615 last if $ok;
616 $tried{$try} = 1;
617 }
618 $path =~ s#/?[^/]+$##;
619 }
620 die "Path: '$path' should be ''\n" if $path ne '';
621 $ok ||= $self->read_svm_props($ra, $path, $r);
622 $tried{ add_path_to_url($ra->url, $path) } = 1;
623 if (!$ok) {
624 die @err, (map { " $_\n" } keys %tried), "\n";
625 }
626 Git::SVN::Ra->new($self->url);
627}
628sub svnsync {
630 my ($self) = @_;
631 return $self->{svnsync} if $self->{svnsync};
632 if ($self->no_metadata) {
634 die "Can't have both 'noMetadata' and ",
635 "'useSvnsyncProps' options set!\n";
636 }
637 if ($self->rewrite_root) {
638 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
639 "options set!\n";
640 }
641 if ($self->rewrite_uuid) {
642 die "Can't have both 'useSvnsyncProps' and 'rewriteUUID' ",
643 "options set!\n";
644 }
645 my $svnsync;
647 # see if we have it in our config, first:
648 eval {
649 my $section = "svn-remote.$self->{repo_id}";
650 my $url = tmp_config('--get', "$section.svnsync-url");
652 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
653 die "doesn't look right - svn:sync-from-url is '$url'\n";
654 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
656 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
657 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
658 $svnsync = { url => $url, uuid => $uuid }
660 };
661 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
662 return $self->{svnsync} = $svnsync;
663 }
664 my $err = "useSvnsyncProps set, but failed to read " .
666 "svnsync property: svn:sync-from-";
667 my $rp = $self->ra->rev_proplist(0);
668 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
670 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
671 die "doesn't look right - svn:sync-from-url is '$url'\n";
672 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
674 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
675 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
676 my $section = "svn-remote.$self->{repo_id}";
678 tmp_config('--add', "$section.svnsync-uuid", $uuid);
679 tmp_config('--add', "$section.svnsync-url", $url);
680 return $self->{svnsync} = { url => $url, uuid => $uuid };
681}
682# this allows us to memoize our SVN::Ra UUID locally and avoid a
684# remote lookup (useful for 'git svn log').
685sub ra_uuid {
686 my ($self) = @_;
687 unless ($self->{ra_uuid}) {
688 my $key = "svn-remote.$self->{repo_id}.uuid";
689 my $uuid = eval { tmp_config('--get', $key) };
690 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
691 $self->{ra_uuid} = $uuid;
692 } else {
693 die "ra_uuid called without URL\n" unless $self->url;
694 $self->{ra_uuid} = $self->ra->get_uuid;
695 tmp_config('--add', $key, $self->{ra_uuid});
696 }
697 }
698 $self->{ra_uuid};
699}
700sub _set_repos_root {
702 my ($self, $repos_root) = @_;
703 my $k = "svn-remote.$self->{repo_id}.reposRoot";
704 $repos_root ||= $self->ra->{repos_root};
705 tmp_config($k, $repos_root);
706 $repos_root;
707}
708sub repos_root {
710 my ($self) = @_;
711 my $k = "svn-remote.$self->{repo_id}.reposRoot";
712 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
713}
714sub ra {
716 my ($self) = shift;
717 my $ra = Git::SVN::Ra->new($self->url);
718 $self->_set_repos_root($ra->{repos_root});
719 if ($self->use_svm_props && !$self->{svm}) {
720 if ($self->no_metadata) {
721 die "Can't have both 'noMetadata' and ",
722 "'useSvmProps' options set!\n";
723 } elsif ($self->use_svnsync_props) {
724 die "Can't have both 'useSvnsyncProps' and ",
725 "'useSvmProps' options set!\n";
726 }
727 $ra = $self->_set_svm_vars($ra);
728 $self->{-want_revprops} = 1;
729 }
730 $ra;
731}
732# prop_walk(PATH, REV, SUB)
734# -------------------------
735# Recursively traverse PATH at revision REV and invoke SUB for each
736# directory that contains a SVN property. SUB will be invoked as
737# follows: &SUB(gs, path, props); where `gs' is this instance of
738# Git::SVN, `path' the path to the directory where the properties
739# `props' were found. The `path' will be relative to point of checkout,
740# that is, if url://repo/trunk is the current Git branch, and that
741# directory contains a sub-directory `d', SUB will be invoked with `/d/'
742# as `path' (note the trailing `/').
743sub prop_walk {
744 my ($self, $path, $rev, $sub) = @_;
745 $path =~ s#^/##;
747 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
748 $path =~ s#^/*#/#g;
749 my $p = $path;
750 # Strip the irrelevant part of the path.
751 $p =~ s#^/+\Q@{[$self->path]}\E(/|$)#/#;
752 # Ensure the path is terminated by a `/'.
753 $p =~ s#/*$#/#;
754 # The properties contain all the internal SVN stuff nobody
756 # (usually) cares about.
757 my $interesting_props = 0;
758 foreach (keys %{$props}) {
759 # If it doesn't start with `svn:', it must be a
760 # user-defined property.
761 ++$interesting_props and next if $_ !~ /^svn:/;
762 # FIXME: Fragile, if SVN adds new public properties,
763 # this needs to be updated.
764 ++$interesting_props if /^svn:(?:ignore|keywords|executable
765 |eol-style|mime-type
766 |externals|needs-lock)$/x;
767 }
768 &$sub($self, $p, $props) if $interesting_props;
769 foreach (sort keys %$dirent) {
771 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
772 $self->prop_walk($self->path . $p . $_, $rev, $sub);
773 }
774}
775sub last_rev { ($_[0]->last_rev_commit)[0] }
777sub last_commit { ($_[0]->last_rev_commit)[1] }
778# returns the newest SVN revision number and newest commit SHA1
780sub last_rev_commit {
781 my ($self) = @_;
782 if (defined $self->{last_rev} && defined $self->{last_commit}) {
783 return ($self->{last_rev}, $self->{last_commit});
784 }
785 my $c = ::verify_ref($self->refname.'^0');
786 if ($c && !$self->use_svm_props && !$self->no_metadata) {
787 my $rev = (::cmt_metadata($c))[1];
788 if (defined $rev) {
789 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
790 return ($rev, $c);
791 }
792 }
793 my $map_path = $self->map_path;
794 unless (-e $map_path) {
795 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
796 return (undef, undef);
797 }
798 my ($rev, $commit) = $self->rev_map_max(1);
799 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
800 return ($rev, $commit);
801}
802sub get_fetch_range {
804 my ($self, $min, $max) = @_;
805 $max ||= $self->ra->get_latest_revnum;
806 $min ||= $self->rev_map_max;
807 (++$min, $max);
808}
809sub tmp_config {
811 my (@args) = @_;
812 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
813 my $config = "$ENV{GIT_DIR}/svn/.metadata";
814 if (! -f $config && -f $old_def_config) {
815 rename $old_def_config, $config or
816 die "Failed rename $old_def_config => $config: $!\n";
817 }
818 my $old_config = $ENV{GIT_CONFIG};
819 $ENV{GIT_CONFIG} = $config;
820 $@ = undef;
821 my @ret = eval {
822 unless (-f $config) {
823 mkfile($config);
824 open my $fh, '>', $config or
825 die "Can't open $config: $!\n";
826 print $fh "; This file is used internally by ",
827 "git-svn\n" or die
828 "Couldn't write to $config: $!\n";
829 print $fh "; You should not have to edit it\n" or
830 die "Couldn't write to $config: $!\n";
831 close $fh or die "Couldn't close $config: $!\n";
832 }
833 command('config', @args);
834 };
835 my $err = $@;
836 if (defined $old_config) {
837 $ENV{GIT_CONFIG} = $old_config;
838 } else {
839 delete $ENV{GIT_CONFIG};
840 }
841 die $err if $err;
842 wantarray ? @ret : $ret[0];
843}
844sub tmp_index_do {
846 my ($self, $sub) = @_;
847 my $old_index = $ENV{GIT_INDEX_FILE};
848 $ENV{GIT_INDEX_FILE} = $self->{index};
849 $@ = undef;
850 my @ret = eval {
851 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
852 mkpath([$dir]) unless -d $dir;
853 &$sub;
854 };
855 my $err = $@;
856 if (defined $old_index) {
857 $ENV{GIT_INDEX_FILE} = $old_index;
858 } else {
859 delete $ENV{GIT_INDEX_FILE};
860 }
861 die $err if $err;
862 wantarray ? @ret : $ret[0];
863}
864sub assert_index_clean {
866 my ($self, $treeish) = @_;
867 $self->tmp_index_do(sub {
869 command_noisy('read-tree', $treeish) unless -e $self->{index};
870 my $x = command_oneline('write-tree');
871 my ($y) = (command(qw/cat-file commit/, $treeish) =~
872 /^tree ($::sha1)/mo);
873 return if $y eq $x;
874 warn "Index mismatch: $y != $x\nrereading $treeish\n";
876 unlink $self->{index} or die "unlink $self->{index}: $!\n";
877 command_noisy('read-tree', $treeish);
878 $x = command_oneline('write-tree');
879 if ($y ne $x) {
880 fatal "trees ($treeish) $y != $x\n",
881 "Something is seriously wrong...";
882 }
883 });
884}
885sub get_commit_parents {
887 my ($self, $log_entry) = @_;
888 my (%seen, @ret, @tmp);
889 # legacy support for 'set-tree'; this is only used by set_tree_cb:
890 if (my $ip = $self->{inject_parents}) {
891 if (my $commit = delete $ip->{$log_entry->{revision}}) {
892 push @tmp, $commit;
893 }
894 }
895 if (my $cur = ::verify_ref($self->refname.'^0')) {
896 push @tmp, $cur;
897 }
898 if (my $ipd = $self->{inject_parents_dcommit}) {
899 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
900 push @tmp, @$commit;
901 }
902 }
903 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
904 while (my $p = shift @tmp) {
905 next if $seen{$p};
906 $seen{$p} = 1;
907 push @ret, $p;
908 }
909 @ret;
910}
911sub rewrite_root {
913 my ($self) = @_;
914 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
915 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
916 my $rwr = eval { command_oneline(qw/config --get/, $k) };
917 if ($rwr) {
918 $rwr =~ s#/+$##;
919 if ($rwr !~ m#^[a-z\+]+://#) {
920 die "$rwr is not a valid URL (key: $k)\n";
921 }
922 }
923 $self->{-rewrite_root} = $rwr;
924}
925sub rewrite_uuid {
927 my ($self) = @_;
928 return $self->{-rewrite_uuid} if exists $self->{-rewrite_uuid};
929 my $k = "svn-remote.$self->{repo_id}.rewriteUUID";
930 my $rwid = eval { command_oneline(qw/config --get/, $k) };
931 if ($rwid) {
932 $rwid =~ s#/+$##;
933 if ($rwid !~ m#^[a-f0-9]{8}-(?:[a-f0-9]{4}-){3}[a-f0-9]{12}$#) {
934 die "$rwid is not a valid UUID (key: $k)\n";
935 }
936 }
937 $self->{-rewrite_uuid} = $rwid;
938}
939sub metadata_url {
941 my ($self) = @_;
942 my $url = $self->rewrite_root || $self->url;
943 return canonicalize_url( add_path_to_url( $url, $self->path ) );
944}
945sub full_url {
947 my ($self) = @_;
948 return canonicalize_url( add_path_to_url( $self->url, $self->path ) );
949}
950sub full_pushurl {
952 my ($self) = @_;
953 if ($self->{pushurl}) {
954 return canonicalize_url( add_path_to_url( $self->{pushurl}, $self->path ) );
955 } else {
956 return $self->full_url;
957 }
958}
959sub set_commit_header_env {
961 my ($log_entry) = @_;
962 my %env;
963 foreach my $ned (qw/NAME EMAIL DATE/) {
964 foreach my $ac (qw/AUTHOR COMMITTER/) {
965 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
966 }
967 }
968 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
970 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
971 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
972 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
974 ? $log_entry->{commit_name}
975 : $log_entry->{name};
976 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
977 ? $log_entry->{commit_email}
978 : $log_entry->{email};
979 \%env;
980}
981sub restore_commit_header_env {
983 my ($env) = @_;
984 foreach my $ned (qw/NAME EMAIL DATE/) {
985 foreach my $ac (qw/AUTHOR COMMITTER/) {
986 my $k = "GIT_${ac}_${ned}";
987 if (defined $env->{$k}) {
988 $ENV{$k} = $env->{$k};
989 } else {
990 delete $ENV{$k};
991 }
992 }
993 }
994}
995sub gc {
997 command_noisy('gc', '--auto');
998};
999sub do_git_commit {
1001 my ($self, $log_entry) = @_;
1002 my $lr = $self->last_rev;
1003 if (defined $lr && $lr >= $log_entry->{revision}) {
1004 die "Last fetched revision of ", $self->refname,
1005 " was r$lr, but we are about to fetch: ",
1006 "r$log_entry->{revision}!\n";
1007 }
1008 if (my $c = $self->rev_map_get($log_entry->{revision})) {
1009 croak "$log_entry->{revision} = $c already exists! ",
1010 "Why are we refetching it?\n";
1011 }
1012 my $old_env = set_commit_header_env($log_entry);
1013 my $tree = $log_entry->{tree};
1014 if (!defined $tree) {
1015 $tree = $self->tmp_index_do(sub {
1016 command_oneline('write-tree') });
1017 }
1018 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1019 my @exec = ('git', 'commit-tree', $tree);
1021 foreach ($self->get_commit_parents($log_entry)) {
1022 push @exec, '-p', $_;
1023 }
1024 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1025 or croak $!;
1026 binmode $msg_fh;
1027 # we always get UTF-8 from SVN, but we may want our commits in
1029 # a different encoding.
1030 if (my $enc = Git::config('i18n.commitencoding')) {
1031 require Encode;
1032 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
1033 }
1034 print $msg_fh $log_entry->{log} or croak $!;
1035 restore_commit_header_env($old_env);
1036 unless ($self->no_metadata) {
1037 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
1038 or croak $!;
1039 }
1040 $msg_fh->flush == 0 or croak $!;
1041 close $msg_fh or croak $!;
1042 chomp(my $commit = do { local $/; <$out_fh> });
1043 close $out_fh or croak $!;
1044 waitpid $pid, 0;
1045 croak $? if $?;
1046 if ($commit !~ /^$::sha1$/o) {
1047 die "Failed to commit, invalid sha1: $commit\n";
1048 }
1049 $self->rev_map_set($log_entry->{revision}, $commit, 1);
1051 $self->{last_rev} = $log_entry->{revision};
1053 $self->{last_commit} = $commit;
1054 print "r$log_entry->{revision}" unless $::_q > 1;
1055 if (defined $log_entry->{svm_revision}) {
1056 print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
1057 $self->rev_map_set($log_entry->{svm_revision}, $commit,
1058 0, $self->svm_uuid);
1059 }
1060 print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
1061 if (--$_gc_nr == 0) {
1062 $_gc_nr = $_gc_period;
1063 gc();
1064 }
1065 return $commit;
1066}
1067sub match_paths {
1069 my ($self, $paths, $r) = @_;
1070 return 1 if $self->path eq '';
1071 if (my $path = $paths->{"/".$self->path}) {
1072 return ($path->{action} eq 'D') ? 0 : 1;
1073 }
1074 $self->{path_regex} ||= qr{^/\Q@{[$self->path]}\E/};
1075 if (grep /$self->{path_regex}/, keys %$paths) {
1076 return 1;
1077 }
1078 my $c = '';
1079 foreach (split m#/#, $self->path) {
1080 $c .= "/$_";
1081 next unless ($paths->{$c} &&
1082 ($paths->{$c}->{action} =~ /^[AR]$/));
1083 if ($self->ra->check_path($self->path, $r) ==
1084 $SVN::Node::dir) {
1085 return 1;
1086 }
1087 }
1088 return 0;
1089}
1090sub find_parent_branch {
1092 my ($self, $paths, $rev) = @_;
1093 return undef unless $self->follow_parent;
1094 unless (defined $paths) {
1095 my $err_handler = $SVN::Error::handler;
1096 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1097 $self->ra->get_log([$self->path], $rev, $rev, 0, 1, 1,
1098 sub { $paths = $_[0] });
1099 $SVN::Error::handler = $err_handler;
1100 }
1101 return undef unless defined $paths;
1102 # look for a parent from another branch:
1104 my @b_path_components = split m#/#, $self->path;
1105 my @a_path_components;
1106 my $i;
1107 while (@b_path_components) {
1108 $i = $paths->{'/'.join('/', @b_path_components)};
1109 last if $i && defined $i->{copyfrom_path};
1110 unshift(@a_path_components, pop(@b_path_components));
1111 }
1112 return undef unless defined $i && defined $i->{copyfrom_path};
1113 my $branch_from = $i->{copyfrom_path};
1114 if (@a_path_components) {
1115 print STDERR "branch_from: $branch_from => ";
1116 $branch_from .= '/'.join('/', @a_path_components);
1117 print STDERR $branch_from, "\n";
1118 }
1119 my $r = $i->{copyfrom_rev};
1120 my $repos_root = $self->ra->{repos_root};
1121 my $url = $self->ra->url;
1122 my $new_url = canonicalize_url( add_path_to_url( $url, $branch_from ) );
1123 print STDERR "Found possible branch point: ",
1124 "$new_url => ", $self->full_url, ", $r\n"
1125 unless $::_q > 1;
1126 $branch_from =~ s#^/##;
1127 my $gs = $self->other_gs($new_url, $url,
1128 $branch_from, $r, $self->{ref_id});
1129 my ($r0, $parent) = $gs->find_rev_before($r, 1);
1130 {
1131 my ($base, $head);
1132 if (!defined $r0 || !defined $parent) {
1133 ($base, $head) = parse_revision_argument(0, $r);
1134 } else {
1135 if ($r0 < $r) {
1136 $gs->ra->get_log([$gs->path], $r0 + 1, $r, 1,
1137 0, 1, sub { $base = $_[1] - 1 });
1138 }
1139 }
1140 if (defined $base && $base <= $r) {
1141 $gs->fetch($base, $r);
1142 }
1143 ($r0, $parent) = $gs->find_rev_before($r, 1);
1144 }
1145 if (defined $r0 && defined $parent) {
1146 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
1147 unless $::_q > 1;
1148 my $ed;
1149 if ($self->ra->can_do_switch) {
1150 $self->assert_index_clean($parent);
1151 print STDERR "Following parent with do_switch\n"
1152 unless $::_q > 1;
1153 # do_switch works with svn/trunk >= r22312, but that
1154 # is not included with SVN 1.4.3 (the latest version
1155 # at the moment), so we can't rely on it
1156 $self->{last_rev} = $r0;
1157 $self->{last_commit} = $parent;
1158 $ed = Git::SVN::Fetcher->new($self, $gs->path);
1159 $gs->ra->gs_do_switch($r0, $rev, $gs,
1160 $self->full_url, $ed)
1161 or die "SVN connection failed somewhere...\n";
1162 } elsif ($self->ra->trees_match($new_url, $r0,
1163 $self->full_url, $rev)) {
1164 print STDERR "Trees match:\n",
1165 " $new_url\@$r0\n",
1166 " ${\$self->full_url}\@$rev\n",
1167 "Following parent with no changes\n"
1168 unless $::_q > 1;
1169 $self->tmp_index_do(sub {
1170 command_noisy('read-tree', $parent);
1171 });
1172 $self->{last_commit} = $parent;
1173 } else {
1174 print STDERR "Following parent with do_update\n"
1175 unless $::_q > 1;
1176 $ed = Git::SVN::Fetcher->new($self);
1177 $self->ra->gs_do_update($rev, $rev, $self, $ed)
1178 or die "SVN connection failed somewhere...\n";
1179 }
1180 print STDERR "Successfully followed parent\n" unless $::_q > 1;
1181 return $self->make_log_entry($rev, [$parent], $ed, $r0, $branch_from);
1182 }
1183 return undef;
1184}
1185sub do_fetch {
1187 my ($self, $paths, $rev) = @_;
1188 my $ed;
1189 my ($last_rev, @parents);
1190 if (my $lc = $self->last_commit) {
1191 # we can have a branch that was deleted, then re-added
1192 # under the same name but copied from another path, in
1193 # which case we'll have multiple parents (we don't
1194 # want to break the original ref or lose copypath info):
1195 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1196 push @{$log_entry->{parents}}, $lc;
1197 return $log_entry;
1198 }
1199 $ed = Git::SVN::Fetcher->new($self);
1200 $last_rev = $self->{last_rev};
1201 $ed->{c} = $lc;
1202 @parents = ($lc);
1203 } else {
1204 $last_rev = $rev;
1205 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1206 return $log_entry;
1207 }
1208 $ed = Git::SVN::Fetcher->new($self);
1209 }
1210 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1211 die "SVN connection failed somewhere...\n";
1212 }
1213 $self->make_log_entry($rev, \@parents, $ed, $last_rev, $self->path);
1214}
1215sub mkemptydirs {
1217 my ($self, $r) = @_;
1218 sub scan {
1220 my ($r, $empty_dirs, $line) = @_;
1221 if (defined $r && $line =~ /^r(\d+)$/) {
1222 return 0 if $1 > $r;
1223 } elsif ($line =~ /^ \+empty_dir: (.+)$/) {
1224 $empty_dirs->{$1} = 1;
1225 } elsif ($line =~ /^ \-empty_dir: (.+)$/) {
1226 my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
1227 delete @$empty_dirs{@d};
1228 }
1229 1; # continue
1230 };
1231 my %empty_dirs = ();
1233 my $gz_file = "$self->{dir}/unhandled.log.gz";
1234 if (-f $gz_file) {
1235 if (!can_compress()) {
1236 warn "Compress::Zlib could not be found; ",
1237 "empty directories in $gz_file will not be read\n";
1238 } else {
1239 my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
1240 die "Unable to open $gz_file: $!\n";
1241 my $line;
1242 while ($gz->gzreadline($line) > 0) {
1243 scan($r, \%empty_dirs, $line) or last;
1244 }
1245 $gz->gzclose;
1246 }
1247 }
1248 if (open my $fh, '<', "$self->{dir}/unhandled.log") {
1250 binmode $fh or croak "binmode: $!";
1251 while (<$fh>) {
1252 scan($r, \%empty_dirs, $_) or last;
1253 }
1254 close $fh;
1255 }
1256 my $strip = qr/\A\Q@{[$self->path]}\E(?:\/|$)/;
1258 foreach my $d (sort keys %empty_dirs) {
1259 $d = uri_decode($d);
1260 $d =~ s/$strip//;
1261 next unless length($d);
1262 next if -d $d;
1263 if (-e $d) {
1264 warn "$d exists but is not a directory\n";
1265 } else {
1266 print "creating empty directory: $d\n";
1267 mkpath([$d]);
1268 }
1269 }
1270}
1271sub get_untracked {
1273 my ($self, $ed) = @_;
1274 my @out;
1275 my $h = $ed->{empty};
1276 foreach (sort keys %$h) {
1277 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1278 push @out, " $act: " . uri_encode($_);
1279 warn "W: $act: $_\n";
1280 }
1281 foreach my $t (qw/dir_prop file_prop/) {
1282 $h = $ed->{$t} or next;
1283 foreach my $path (sort keys %$h) {
1284 my $ppath = $path eq '' ? '.' : $path;
1285 foreach my $prop (sort keys %{$h->{$path}}) {
1286 next if $SKIP_PROP{$prop};
1287 my $v = $h->{$path}->{$prop};
1288 my $t_ppath_prop = "$t: " .
1289 uri_encode($ppath) . ' ' .
1290 uri_encode($prop);
1291 if (defined $v) {
1292 push @out, " +$t_ppath_prop " .
1293 uri_encode($v);
1294 } else {
1295 push @out, " -$t_ppath_prop";
1296 }
1297 }
1298 }
1299 }
1300 foreach my $t (qw/absent_file absent_directory/) {
1301 $h = $ed->{$t} or next;
1302 foreach my $parent (sort keys %$h) {
1303 foreach my $path (sort @{$h->{$parent}}) {
1304 push @out, " $t: " .
1305 uri_encode("$parent/$path");
1306 warn "W: $t: $parent/$path ",
1307 "Insufficient permissions?\n";
1308 }
1309 }
1310 }
1311 \@out;
1312}
1313# parse_svn_date(DATE)
1315# --------------------
1316# Given a date (in UTC) from Subversion, return a string in the format
1317# "<TZ Offset> <local date/time>" that Git will use.
1318#
1319# By default the parsed date will be in UTC; if $Git::SVN::_localtime
1320# is true we'll convert it to the local timezone instead.
1321sub parse_svn_date {
1322 my $date = shift || return '+0000 1970-01-01 00:00:00';
1323 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1324 (\d\d?)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
1325 croak "Unable to parse date: $date\n";
1326 my $parsed_date; # Set next.
1327 if ($Git::SVN::_localtime) {
1329 # Translate the Subversion datetime to an epoch time.
1330 # Begin by switching ourselves to $date's timezone, UTC.
1331 my $old_env_TZ = $ENV{TZ};
1332 $ENV{TZ} = 'UTC';
1333 my $epoch_in_UTC =
1335 POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
1336 # Determine our local timezone (including DST) at the
1338 # time of $epoch_in_UTC. $Git::SVN::Log::TZ stored the
1339 # value of TZ, if any, at the time we were run.
1340 if (defined $Git::SVN::Log::TZ) {
1341 $ENV{TZ} = $Git::SVN::Log::TZ;
1342 } else {
1343 delete $ENV{TZ};
1344 }
1345 my $our_TZ = get_tz_offset();
1347 # This converts $epoch_in_UTC into our local timezone.
1349 my ($sec, $min, $hour, $mday, $mon, $year,
1350 $wday, $yday, $isdst) = localtime($epoch_in_UTC);
1351 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
1353 $our_TZ, $year + 1900, $mon + 1,
1354 $mday, $hour, $min, $sec);
1355 # Reset us to the timezone in effect when we entered
1357 # this routine.
1358 if (defined $old_env_TZ) {
1359 $ENV{TZ} = $old_env_TZ;
1360 } else {
1361 delete $ENV{TZ};
1362 }
1363 } else {
1364 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
1365 }
1366 return $parsed_date;
1368}
1369sub other_gs {
1371 my ($self, $new_url, $url,
1372 $branch_from, $r, $old_ref_id) = @_;
1373 my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
1374 unless ($gs) {
1375 my $ref_id = $old_ref_id;
1376 $ref_id =~ s/\@\d+-*$//;
1377 $ref_id .= "\@$r";
1378 # just grow a tail if we're not unique enough :x
1379 $ref_id .= '-' while find_ref($ref_id);
1380 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
1381 if ($u =~ s#^\Q$url\E(/|$)##) {
1382 $p = $u;
1383 $u = $url;
1384 $repo_id = $self->{repo_id};
1385 }
1386 while (1) {
1387 # It is possible to tag two different subdirectories at
1388 # the same revision. If the url for an existing ref
1389 # does not match, we must either find a ref with a
1390 # matching url or create a new ref by growing a tail.
1391 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
1392 my (undef, $max_commit) = $gs->rev_map_max(1);
1393 last if (!$max_commit);
1394 my ($url) = ::cmt_metadata($max_commit);
1395 last if ($url eq $gs->metadata_url);
1396 $ref_id .= '-';
1397 }
1398 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
1399 }
1400 $gs
1401}
1402sub call_authors_prog {
1404 my ($orig_author) = @_;
1405 $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
1406 my $author = `$::_authors_prog $orig_author`;
1407 if ($? != 0) {
1408 die "$::_authors_prog failed with exit code $?\n"
1409 }
1410 if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
1411 my ($name, $email) = ($1, $2);
1412 $email = undef if length $2 == 0;
1413 return [$name, $email];
1414 } else {
1415 die "Author: $orig_author: $::_authors_prog returned "
1416 . "invalid author format: $author\n";
1417 }
1418}
1419sub check_author {
1421 my ($author) = @_;
1422 if (!defined $author || length $author == 0) {
1423 $author = '(no author)';
1424 }
1425 if (!defined $::users{$author}) {
1426 if (defined $::_authors_prog) {
1427 $::users{$author} = call_authors_prog($author);
1428 } elsif (defined $::_authors) {
1429 die "Author: $author not defined in $::_authors file\n";
1430 }
1431 }
1432 $author;
1433}
1434sub find_extra_svk_parents {
1436 my ($self, $ed, $tickets, $parents) = @_;
1437 # aha! svk:merge property changed...
1438 my @tickets = split "\n", $tickets;
1439 my @known_parents;
1440 for my $ticket ( @tickets ) {
1441 my ($uuid, $path, $rev) = split /:/, $ticket;
1442 if ( $uuid eq $self->ra_uuid ) {
1443 my $repos_root = $self->url;
1444 my $branch_from = $path;
1445 $branch_from =~ s{^/}{};
1446 my $gs = $self->other_gs(add_path_to_url( $repos_root, $branch_from ),
1447 $repos_root,
1448 $branch_from,
1449 $rev,
1450 $self->{ref_id});
1451 if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
1452 # wahey! we found it, but it might be
1453 # an old one (!)
1454 push @known_parents, [ $rev, $commit ];
1455 }
1456 }
1457 }
1458 # Ordering matters; highest-numbered commit merge tickets
1459 # first, as they may account for later merge ticket additions
1460 # or changes.
1461 @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
1462 for my $parent ( @known_parents ) {
1463 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
1464 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
1465 my $new;
1466 while ( <$msg_fh> ) {
1467 $new=1;last;
1468 }
1469 command_close_pipe($msg_fh, $ctx);
1470 if ( $new ) {
1471 print STDERR
1472 "Found merge parent (svk:merge ticket): $parent\n";
1473 push @$parents, $parent;
1474 }
1475 }
1476}
1477sub lookup_svn_merge {
1479 my $uuid = shift;
1480 my $url = shift;
1481 my $source = shift;
1482 my $revs = shift;
1483 my $path = $source;
1485 $path =~ s{^/}{};
1486 my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
1487 if ( !$gs ) {
1488 warn "Couldn't find revmap for $url$source\n";
1489 return;
1490 }
1491 my @ranges = split ",", $revs;
1492 my ($tip, $tip_commit);
1493 my @merged_commit_ranges;
1494 # find the tip
1495 for my $range ( @ranges ) {
1496 if ($range =~ /[*]$/) {
1497 warn "W: Ignoring partial merge in svn:mergeinfo "
1498 ."dirprop: $source:$range\n";
1499 next;
1500 }
1501 my ($bottom, $top) = split "-", $range;
1502 $top ||= $bottom;
1503 my $bottom_commit = $gs->find_rev_after( $bottom, 1, $top );
1504 my $top_commit = $gs->find_rev_before( $top, 1, $bottom );
1505 unless ($top_commit and $bottom_commit) {
1507 warn "W: unknown path/rev in svn:mergeinfo "
1508 ."dirprop: $source:$range\n";
1509 next;
1510 }
1511 if (scalar(command('rev-parse', "$bottom_commit^@"))) {
1513 push @merged_commit_ranges,
1514 "$bottom_commit^..$top_commit";
1515 } else {
1516 push @merged_commit_ranges, "$top_commit";
1517 }
1518 if ( !defined $tip or $top > $tip ) {
1520 $tip = $top;
1521 $tip_commit = $top_commit;
1522 }
1523 }
1524 return ($tip_commit, @merged_commit_ranges);
1525}
1526sub _rev_list {
1528 my ($msg_fh, $ctx) = command_output_pipe(
1529 "rev-list", @_,
1530 );
1531 my @rv;
1532 while ( <$msg_fh> ) {
1533 chomp;
1534 push @rv, $_;
1535 }
1536 command_close_pipe($msg_fh, $ctx);
1537 @rv;
1538}
1539sub check_cherry_pick {
1541 my $base = shift;
1542 my $tip = shift;
1543 my $parents = shift;
1544 my @ranges = @_;
1545 my %commits = map { $_ => 1 }
1546 _rev_list("--no-merges", $tip, "--not", $base, @$parents, "--");
1547 for my $range ( @ranges ) {
1548 delete @commits{_rev_list($range, "--")};
1549 }
1550 for my $commit (keys %commits) {
1551 if (has_no_changes($commit)) {
1552 delete $commits{$commit};
1553 }
1554 }
1555 return (keys %commits);
1556}
1557sub has_no_changes {
1559 my $commit = shift;
1560 my @revs = split / /, command_oneline(
1562 qw(rev-list --parents -1 -m), $commit);
1563 # Commits with no parents, e.g. the start of a partial branch,
1565 # have changes by definition.
1566 return 1 if (@revs < 2);
1567 # Commits with multiple parents, e.g a merge, have no changes
1569 # by definition.
1570 return 0 if (@revs > 2);
1571 return (command_oneline("rev-parse", "$commit^{tree}") eq
1573 command_oneline("rev-parse", "$commit~1^{tree}"));
1574}
1575sub tie_for_persistent_memoization {
1577 my $hash = shift;
1578 my $path = shift;
1579 if ($can_use_yaml) {
1581 tie %$hash => 'Git::SVN::Memoize::YAML', "$path.yaml";
1582 } else {
1583 tie %$hash => 'Memoize::Storable', "$path.db", 'nstore';
1584 }
1585}
1586# The GIT_DIR environment variable is not always set until after the command
1588# line arguments are processed, so we can't memoize in a BEGIN block.
1589{
1590 my $memoized = 0;
1591 sub memoize_svn_mergeinfo_functions {
1593 return if $memoized;
1594 $memoized = 1;
1595 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
1597 mkpath([$cache_path]) unless -d $cache_path;
1598 my %lookup_svn_merge_cache;
1600 my %check_cherry_pick_cache;
1601 my %has_no_changes_cache;
1602 my %_rev_list_cache;
1603 tie_for_persistent_memoization(\%lookup_svn_merge_cache,
1605 "$cache_path/lookup_svn_merge");
1606 memoize 'lookup_svn_merge',
1607 SCALAR_CACHE => 'FAULT',
1608 LIST_CACHE => ['HASH' => \%lookup_svn_merge_cache],
1609 ;
1610 tie_for_persistent_memoization(\%check_cherry_pick_cache,
1612 "$cache_path/check_cherry_pick");
1613 memoize 'check_cherry_pick',
1614 SCALAR_CACHE => 'FAULT',
1615 LIST_CACHE => ['HASH' => \%check_cherry_pick_cache],
1616 ;
1617 tie_for_persistent_memoization(\%has_no_changes_cache,
1619 "$cache_path/has_no_changes");
1620 memoize 'has_no_changes',
1621 SCALAR_CACHE => ['HASH' => \%has_no_changes_cache],
1622 LIST_CACHE => 'FAULT',
1623 ;
1624 tie_for_persistent_memoization(\%_rev_list_cache,
1626 "$cache_path/_rev_list");
1627 memoize '_rev_list',
1628 SCALAR_CACHE => 'FAULT',
1629 LIST_CACHE => ['HASH' => \%_rev_list_cache],
1630 ;
1631 }
1633 sub unmemoize_svn_mergeinfo_functions {
1635 return if not $memoized;
1636 $memoized = 0;
1637 Memoize::unmemoize 'lookup_svn_merge';
1639 Memoize::unmemoize 'check_cherry_pick';
1640 Memoize::unmemoize 'has_no_changes';
1641 Memoize::unmemoize '_rev_list';
1642 }
1643 sub clear_memoized_mergeinfo_caches {
1645 die "Only call this method in non-memoized context" if ($memoized);
1646 my $cache_path = "$ENV{GIT_DIR}/svn/.caches/";
1648 return unless -d $cache_path;
1649 for my $cache_file (("$cache_path/lookup_svn_merge",
1651 "$cache_path/check_cherry_pick",
1652 "$cache_path/has_no_changes")) {
1653 for my $suffix (qw(yaml db)) {
1654 my $file = "$cache_file.$suffix";
1655 next unless -e $file;
1656 unlink($file) or die "unlink($file) failed: $!\n";
1657 }
1658 }
1659 }
1660 Memoize::memoize 'Git::SVN::repos_root';
1663}
1664END {
1666 # Force cache writeout explicitly instead of waiting for
1667 # global destruction to avoid segfault in Storable:
1668 # http://rt.cpan.org/Public/Bug/Display.html?id=36087
1669 unmemoize_svn_mergeinfo_functions();
1670}
1671sub parents_exclude {
1673 my $parents = shift;
1674 my @commits = @_;
1675 return unless @commits;
1676 my @excluded;
1678 my $excluded;
1679 do {
1680 my @cmd = ('rev-list', "-1", @commits, "--not", @$parents );
1681 $excluded = command_oneline(@cmd);
1682 if ( $excluded ) {
1683 my @new;
1684 my $found;
1685 for my $commit ( @commits ) {
1686 if ( $commit eq $excluded ) {
1687 push @excluded, $commit;
1688 $found++;
1689 }
1690 else {
1691 push @new, $commit;
1692 }
1693 }
1694 die "saw commit '$excluded' in rev-list output, "
1695 ."but we didn't ask for that commit (wanted: @commits --not @$parents)"
1696 unless $found;
1697 @commits = @new;
1698 }
1699 }
1700 while ($excluded and @commits);
1701 return @excluded;
1703}
1704# Compute what's new in svn:mergeinfo.
1706sub mergeinfo_changes {
1707 my ($self, $old_path, $old_rev, $path, $rev, $mergeinfo_prop) = @_;
1708 my %minfo = map {split ":", $_ } split "\n", $mergeinfo_prop;
1709 my $old_minfo = {};
1710 # Initialize cache on the first call.
1712 unless (defined $self->{cached_mergeinfo_rev}) {
1713 $self->{cached_mergeinfo_rev} = {};
1714 $self->{cached_mergeinfo} = {};
1715 }
1716 my $cached_rev = $self->{cached_mergeinfo_rev}{$old_path};
1718 if (defined $cached_rev && $cached_rev == $old_rev) {
1719 $old_minfo = $self->{cached_mergeinfo}{$old_path};
1720 } else {
1721 my $ra = $self->ra;
1722 # Give up if $old_path isn't in the repo.
1723 # This is probably a merge on a subtree.
1724 if ($ra->check_path($old_path, $old_rev) != $SVN::Node::dir) {
1725 warn "W: ignoring svn:mergeinfo on $old_path, ",
1726 "directory didn't exist in r$old_rev\n";
1727 return {};
1728 }
1729 my (undef, undef, $props) =
1730 $self->ra->get_dir($old_path, $old_rev);
1731 if (defined $props->{"svn:mergeinfo"}) {
1732 my %omi = map {split ":", $_ } split "\n",
1733 $props->{"svn:mergeinfo"};
1734 $old_minfo = \%omi;
1735 }
1736 $self->{cached_mergeinfo}{$old_path} = $old_minfo;
1737 $self->{cached_mergeinfo_rev}{$old_path} = $old_rev;
1738 }
1739 # Cache the new mergeinfo.
1741 $self->{cached_mergeinfo}{$path} = \%minfo;
1742 $self->{cached_mergeinfo_rev}{$path} = $rev;
1743 my %changes = ();
1745 foreach my $p (keys %minfo) {
1746 my $a = $old_minfo->{$p} || "";
1747 my $b = $minfo{$p};
1748 # Omit merged branches whose ranges lists are unchanged.
1749 next if $a eq $b;
1750 # Remove any common range list prefix.
1751 ($a ^ $b) =~ /^[\0]*/;
1752 my $common_prefix = rindex $b, ",", $+[0] - 1;
1753 $changes{$p} = substr $b, $common_prefix + 1;
1754 }
1755 print STDERR "Checking svn:mergeinfo changes since r$old_rev: ",
1756 scalar(keys %minfo), " sources, ",
1757 scalar(keys %changes), " changed\n";
1758 return \%changes;
1760}
1761# note: this function should only be called if the various dirprops
1763# have actually changed
1764sub find_extra_svn_parents {
1765 my ($self, $ed, $mergeinfo, $parents) = @_;
1766 # aha! svk:merge property changed...
1767 memoize_svn_mergeinfo_functions();
1769 # We first search for merged tips which are not in our
1771 # history. Then, we figure out which git revisions are in
1772 # that tip, but not this revision. If all of those revisions
1773 # are now marked as merge, we can add the tip as a parent.
1774 my @merges = sort keys %$mergeinfo;
1775 my @merge_tips;
1776 my $url = $self->url;
1777 my $uuid = $self->ra_uuid;
1778 my @all_ranges;
1779 for my $merge ( @merges ) {
1780 my ($tip_commit, @ranges) =
1781 lookup_svn_merge( $uuid, $url,
1782 $merge, $mergeinfo->{$merge} );
1783 unless (!$tip_commit or
1784 grep { $_ eq $tip_commit } @$parents ) {
1785 push @merge_tips, $tip_commit;
1786 push @all_ranges, @ranges;
1787 } else {
1788 push @merge_tips, undef;
1789 }
1790 }
1791 my %excluded = map { $_ => 1 }
1793 parents_exclude($parents, grep { defined } @merge_tips);
1794 # check merge tips for new parents
1796 my @new_parents;
1797 for my $merge_tip ( @merge_tips ) {
1798 my $merge = shift @merges;
1799 next unless $merge_tip and $excluded{$merge_tip};
1800 my $spec = "$merge:$mergeinfo->{$merge}";
1801 # check out 'new' tips
1803 my $merge_base;
1804 eval {
1805 $merge_base = command_oneline(
1806 "merge-base",
1807 @$parents, $merge_tip,
1808 );
1809 };
1810 if ($@) {
1811 die "An error occurred during merge-base"
1812 unless $@->isa("Git::Error::Command");
1813 warn "W: Cannot find common ancestor between ".
1815 "@$parents and $merge_tip. Ignoring merge info.\n";
1816 next;
1817 }
1818 # double check that there are no missing non-merge commits
1820 my (@incomplete) = check_cherry_pick(
1821 $merge_base, $merge_tip,
1822 $parents,
1823 @all_ranges,
1824 );
1825 if ( @incomplete ) {
1827 warn "W:svn cherry-pick ignored ($spec) - missing "
1828 .@incomplete." commit(s) (eg $incomplete[0])\n";
1829 } else {
1830 warn
1831 "Found merge parent ($spec): ",
1832 $merge_tip, "\n";
1833 push @new_parents, $merge_tip;
1834 }
1835 }
1836 # cater for merges which merge commits from multiple branches
1838 if ( @new_parents > 1 ) {
1839 for ( my $i = 0; $i <= $#new_parents; $i++ ) {
1840 for ( my $j = 0; $j <= $#new_parents; $j++ ) {
1841 next if $i == $j;
1842 next unless $new_parents[$i];
1843 next unless $new_parents[$j];
1844 my $revs = command_oneline(
1845 "rev-list", "-1",
1846 "$new_parents[$i]..$new_parents[$j]",
1847 );
1848 if ( !$revs ) {
1849 undef($new_parents[$j]);
1850 }
1851 }
1852 }
1853 }
1854 push @$parents, grep { defined } @new_parents;
1855}
1856sub make_log_entry {
1858 my ($self, $rev, $parents, $ed, $parent_rev, $parent_path) = @_;
1859 my $untracked = $self->get_untracked($ed);
1860 my @parents = @$parents;
1862 my $props = $ed->{dir_prop}{$self->path};
1863 if ( $props->{"svk:merge"} ) {
1864 $self->find_extra_svk_parents
1865 ($ed, $props->{"svk:merge"}, \@parents);
1866 }
1867 if ( $props->{"svn:mergeinfo"} ) {
1868 my $mi_changes = $self->mergeinfo_changes
1869 ($parent_path, $parent_rev,
1870 $self->path, $rev,
1871 $props->{"svn:mergeinfo"});
1872 $self->find_extra_svn_parents
1873 ($ed, $mi_changes, \@parents);
1874 }
1875 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1877 print $un "r$rev\n" or croak $!;
1878 print $un $_, "\n" foreach @$untracked;
1879 my %log_entry = ( parents => \@parents, revision => $rev,
1880 log => '');
1881 my $headrev;
1883 my $logged = delete $self->{logged_rev_props};
1884 if (!$logged || $self->{-want_revprops}) {
1885 my $rp = $self->ra->rev_proplist($rev);
1886 foreach (sort keys %$rp) {
1887 my $v = $rp->{$_};
1888 if (/^svn:(author|date|log)$/) {
1889 $log_entry{$1} = $v;
1890 } elsif ($_ eq 'svm:headrev') {
1891 $headrev = $v;
1892 } else {
1893 print $un " rev_prop: ", uri_encode($_), ' ',
1894 uri_encode($v), "\n";
1895 }
1896 }
1897 } else {
1898 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
1899 }
1900 close $un or croak $!;
1901 $log_entry{date} = parse_svn_date($log_entry{date});
1903 $log_entry{log} .= "\n";
1904 my $author = $log_entry{author} = check_author($log_entry{author});
1905 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
1906 : ($author, undef);
1907 my ($commit_name, $commit_email) = ($name, $email);
1909 if ($_use_log_author) {
1910 my $name_field;
1911 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
1912 $name_field = $1;
1913 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
1914 $name_field = $1;
1915 }
1916 if (!defined $name_field) {
1917 if (!defined $email) {
1918 $email = $name;
1919 }
1920 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
1921 ($name, $email) = ($1, $2);
1922 } elsif ($name_field =~ /(.*)@/) {
1923 ($name, $email) = ($1, $name_field);
1924 } else {
1925 ($name, $email) = ($name_field, $name_field);
1926 }
1927 }
1928 if (defined $headrev && $self->use_svm_props) {
1929 if ($self->rewrite_root) {
1930 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
1931 "options set!\n";
1932 }
1933 if ($self->rewrite_uuid) {
1934 die "Can't have both 'useSvmProps' and 'rewriteUUID' ",
1935 "options set!\n";
1936 }
1937 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
1938 # we don't want "SVM: initializing mirror for junk" ...
1939 return undef if $r == 0;
1940 my $svm = $self->svm;
1941 if ($uuid ne $svm->{uuid}) {
1942 die "UUID mismatch on SVM path:\n",
1943 "expected: $svm->{uuid}\n",
1944 " got: $uuid\n";
1945 }
1946 my $full_url = $self->full_url;
1947 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
1948 die "Failed to replace '$svm->{replace}' with ",
1949 "'$svm->{source}' in $full_url\n";
1950 # throw away username for storing in records
1951 remove_username($full_url);
1952 $log_entry{metadata} = "$full_url\@$r $uuid";
1953 $log_entry{svm_revision} = $r;
1954 $email ||= "$author\@$uuid";
1955 $commit_email ||= "$author\@$uuid";
1956 } elsif ($self->use_svnsync_props) {
1957 my $full_url = canonicalize_url(
1958 add_path_to_url( $self->svnsync->{url}, $self->path )
1959 );
1960 remove_username($full_url);
1961 my $uuid = $self->svnsync->{uuid};
1962 $log_entry{metadata} = "$full_url\@$rev $uuid";
1963 $email ||= "$author\@$uuid";
1964 $commit_email ||= "$author\@$uuid";
1965 } else {
1966 my $url = $self->metadata_url;
1967 remove_username($url);
1968 my $uuid = $self->rewrite_uuid || $self->ra->get_uuid;
1969 $log_entry{metadata} = "$url\@$rev " . $uuid;
1970 $email ||= "$author\@" . $uuid;
1971 $commit_email ||= "$author\@" . $uuid;
1972 }
1973 $log_entry{name} = $name;
1974 $log_entry{email} = $email;
1975 $log_entry{commit_name} = $commit_name;
1976 $log_entry{commit_email} = $commit_email;
1977 \%log_entry;
1978}
1979sub fetch {
1981 my ($self, $min_rev, $max_rev, @parents) = @_;
1982 my ($last_rev, $last_commit) = $self->last_rev_commit;
1983 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1984 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
1985}
1986sub set_tree_cb {
1988 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1989 $self->{inject_parents} = { $rev => $tree };
1990 $self->fetch(undef, undef);
1991}
1992sub set_tree {
1994 my ($self, $tree) = (shift, shift);
1995 my $log_entry = ::get_commit_entry($tree);
1996 unless ($self->{last_rev}) {
1997 fatal("Must have an existing revision to commit");
1998 }
1999 my %ed_opts = ( r => $self->{last_rev},
2000 log => $log_entry->{log},
2001 ra => $self->ra,
2002 tree_a => $self->{last_commit},
2003 tree_b => $tree,
2004 editor_cb => sub {
2005 $self->set_tree_cb($log_entry, $tree, @_) },
2006 svn_path => $self->path );
2007 if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
2008 print "No changes\nr$self->{last_rev} = $tree\n";
2009 }
2010}
2011sub rebuild_from_rev_db {
2013 my ($self, $path) = @_;
2014 my $r = -1;
2015 open my $fh, '<', $path or croak "open: $!";
2016 binmode $fh or croak "binmode: $!";
2017 while (<$fh>) {
2018 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2019 chomp($_);
2020 ++$r;
2021 next if $_ eq ('0' x 40);
2022 $self->rev_map_set($r, $_);
2023 print "r$r = $_\n";
2024 }
2025 close $fh or croak "close: $!";
2026 unlink $path or croak "unlink: $!";
2027}
2028#define a global associate map to record rebuild status
2030my %rebuild_status;
2031#define a global associate map to record rebuild verify status
2032my %rebuild_verify_status;
2033sub rebuild {
2035 my ($self) = @_;
2036 my $map_path = $self->map_path;
2037 my $partial = (-e $map_path && ! -z $map_path);
2038 my $verify_key = $self->refname.'^0';
2039 if (!$rebuild_verify_status{$verify_key}) {
2040 my $verify_result = ::verify_ref($verify_key);
2041 if ($verify_result) {
2042 $rebuild_verify_status{$verify_key} = 1;
2043 }
2044 }
2045 if (!$rebuild_verify_status{$verify_key}) {
2046 return;
2047 }
2048 if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
2049 my $rev_db = $self->rev_db_path;
2050 $self->rebuild_from_rev_db($rev_db);
2051 if ($self->use_svm_props) {
2052 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2053 $self->rebuild_from_rev_db($svm_rev_db);
2054 }
2055 $self->unlink_rev_db_symlink;
2056 return;
2057 }
2058 print "Rebuilding $map_path ...\n" if (!$partial);
2059 my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
2060 (undef, undef));
2061 my $key_value = ($head ? "$head.." : "") . $self->refname;
2062 if (exists $rebuild_status{$key_value}) {
2063 print "Done rebuilding $map_path\n" if (!$partial || !$head);
2064 my $rev_db_path = $self->rev_db_path;
2065 if (-f $self->rev_db_path) {
2066 unlink $self->rev_db_path or croak "unlink: $!";
2067 }
2068 $self->unlink_rev_db_symlink;
2069 return;
2070 }
2071 my ($log, $ctx) =
2072 command_output_pipe(qw/rev-list --pretty=raw --reverse/,
2073 $key_value,
2074 '--');
2075 $rebuild_status{$key_value} = 1;
2076 my $metadata_url = $self->metadata_url;
2077 remove_username($metadata_url);
2078 my $svn_uuid = $self->rewrite_uuid || $self->ra_uuid;
2079 my $c;
2080 while (<$log>) {
2081 if ( m{^commit ($::sha1)$} ) {
2082 $c = $1;
2083 next;
2084 }
2085 next unless s{^\s*(git-svn-id:)}{$1};
2086 my ($url, $rev, $uuid) = ::extract_metadata($_);
2087 remove_username($url);
2088 # ignore merges (from set-tree)
2090 next if (!defined $rev || !$uuid);
2091 # if we merged or otherwise started elsewhere, this is
2093 # how we break out of it
2094 if (($uuid ne $svn_uuid) ||
2095 ($metadata_url && $url && ($url ne $metadata_url))) {
2096 next;
2097 }
2098 if ($partial && $head) {
2099 print "Partial-rebuilding $map_path ...\n";
2100 print "Currently at $base_rev = $head\n";
2101 $head = undef;
2102 }
2103 $self->rev_map_set($rev, $c);
2105 print "r$rev = $c\n";
2106 }
2107 command_close_pipe($log, $ctx);
2108 print "Done rebuilding $map_path\n" if (!$partial || !$head);
2109 my $rev_db_path = $self->rev_db_path;
2110 if (-f $self->rev_db_path) {
2111 unlink $self->rev_db_path or croak "unlink: $!";
2112 }
2113 $self->unlink_rev_db_symlink;
2114}
2115# rev_map:
2117# Tie::File seems to be prone to offset errors if revisions get sparse,
2118# it's not that fast, either. Tie::File is also not in Perl 5.6. So
2119# one of my favorite modules is out :< Next up would be one of the DBM
2120# modules, but I'm not sure which is most portable...
2121#
2122# This is the replacement for the rev_db format, which was too big
2123# and inefficient for large repositories with a lot of sparse history
2124# (mainly tags)
2125#
2126# The format is this:
2127# - 24 bytes for every record,
2128# * 4 bytes for the integer representing an SVN revision number
2129# * 20 bytes representing the sha1 of a git commit
2130# - No empty padding records like the old format
2131# (except the last record, which can be overwritten)
2132# - new records are written append-only since SVN revision numbers
2133# increase monotonically
2134# - lookups on SVN revision number are done via a binary search
2135# - Piping the file to xxd -c24 is a good way of dumping it for
2136# viewing or editing (piped back through xxd -r), should the need
2137# ever arise.
2138# - The last record can be padding revision with an all-zero sha1
2139# This is used to optimize fetch performance when using multiple
2140# "fetch" directives in .git/config
2141#
2142# These files are disposable unless noMetadata or useSvmProps is set
2143sub _rev_map_set {
2145 my ($fh, $rev, $commit) = @_;
2146 binmode $fh or croak "binmode: $!";
2148 my $size = (stat($fh))[7];
2149 ($size % 24) == 0 or croak "inconsistent size: $size";
2150 my $wr_offset = 0;
2152 if ($size > 0) {
2153 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2154 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2155 $read == 24 or croak "read only $read bytes (!= 24)";
2156 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2157 if ($last_commit eq ('0' x40)) {
2158 if ($size >= 48) {
2159 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2160 $read = sysread($fh, $buf, 24) or
2161 croak "read: $!";
2162 $read == 24 or
2163 croak "read only $read bytes (!= 24)";
2164 ($last_rev, $last_commit) =
2165 unpack(rev_map_fmt, $buf);
2166 if ($last_commit eq ('0' x40)) {
2167 croak "inconsistent .rev_map\n";
2168 }
2169 }
2170 if ($last_rev >= $rev) {
2171 croak "last_rev is higher!: $last_rev >= $rev";
2172 }
2173 $wr_offset = -24;
2174 }
2175 }
2176 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2177 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2178 croak "write: $!";
2179}
2180sub _rev_map_reset {
2182 my ($fh, $rev, $commit) = @_;
2183 my $c = _rev_map_get($fh, $rev);
2184 $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
2185 my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
2186 truncate $fh, $offset or croak "truncate: $!";
2187}
2188sub mkfile {
2190 my ($path) = @_;
2191 unless (-e $path) {
2192 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2193 mkpath([$dir]) unless -d $dir;
2194 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2195 close $fh or die "Couldn't close (create) $path: $!\n";
2196 }
2197}
2198sub rev_map_set {
2200 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2201 defined $commit or die "missing arg3\n";
2202 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2203 my $db = $self->map_path($uuid);
2204 my $db_lock = "$db.lock";
2205 my $sigmask;
2206 $update_ref ||= 0;
2207 if ($update_ref) {
2208 $sigmask = POSIX::SigSet->new();
2209 my $signew = POSIX::SigSet->new(SIGINT, SIGHUP, SIGTERM,
2210 SIGALRM, SIGUSR1, SIGUSR2);
2211 sigprocmask(SIG_BLOCK, $signew, $sigmask) or
2212 croak "Can't block signals: $!";
2213 }
2214 mkfile($db);
2215 $LOCKFILES{$db_lock} = 1;
2217 my $sync;
2218 # both of these options make our .rev_db file very, very important
2219 # and we can't afford to lose it because rebuild() won't work
2220 if ($self->use_svm_props || $self->no_metadata) {
2221 $sync = 1;
2222 copy($db, $db_lock) or die "rev_map_set(@_): ",
2223 "Failed to copy: ",
2224 "$db => $db_lock ($!)\n";
2225 } else {
2226 rename $db, $db_lock or die "rev_map_set(@_): ",
2227 "Failed to rename: ",
2228 "$db => $db_lock ($!)\n";
2229 }
2230 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2232 or croak "Couldn't open $db_lock: $!\n";
2233 if ($update_ref eq 'reset') {
2234 clear_memoized_mergeinfo_caches();
2235 _rev_map_reset($fh, $rev, $commit);
2236 } else {
2237 _rev_map_set($fh, $rev, $commit);
2238 }
2239 if ($sync) {
2241 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2242 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2243 }
2244 close $fh or croak $!;
2245 if ($update_ref) {
2246 $_head = $self;
2247 my $note = "";
2248 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
2249 command_noisy('update-ref', '-m', "r$rev$note",
2250 $self->refname, $commit);
2251 }
2252 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2253 "$db_lock => $db ($!)\n";
2254 delete $LOCKFILES{$db_lock};
2255 if ($update_ref) {
2256 sigprocmask(SIG_SETMASK, $sigmask) or
2257 croak "Can't restore signal mask: $!";
2258 }
2259}
2260# If want_commit, this will return an array of (rev, commit) where
2262# commit _must_ be a valid commit in the archive.
2263# Otherwise, it'll return the max revision (whether or not the
2264# commit is valid or just a 0x40 placeholder).
2265sub rev_map_max {
2266 my ($self, $want_commit) = @_;
2267 $self->rebuild;
2268 my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
2269 $want_commit ? ($r, $c) : $r;
2270}
2271sub rev_map_max_norebuild {
2273 my ($self, $want_commit) = @_;
2274 my $map_path = $self->map_path;
2275 stat $map_path or return $want_commit ? (0, undef) : 0;
2276 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2277 binmode $fh or croak "binmode: $!";
2278 my $size = (stat($fh))[7];
2279 ($size % 24) == 0 or croak "inconsistent size: $size";
2280 if ($size == 0) {
2282 close $fh or croak "close: $!";
2283 return $want_commit ? (0, undef) : 0;
2284 }
2285 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2287 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2288 my ($r, $c) = unpack(rev_map_fmt, $buf);
2289 if ($want_commit && $c eq ('0' x40)) {
2290 if ($size < 48) {
2291 return $want_commit ? (0, undef) : 0;
2292 }
2293 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2294 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2295 ($r, $c) = unpack(rev_map_fmt, $buf);
2296 if ($c eq ('0'x40)) {
2297 croak "Penultimate record is all-zeroes in $map_path";
2298 }
2299 }
2300 close $fh or croak "close: $!";
2301 $want_commit ? ($r, $c) : $r;
2302}
2303sub rev_map_get {
2305 my ($self, $rev, $uuid) = @_;
2306 my $map_path = $self->map_path($uuid);
2307 return undef unless -e $map_path;
2308 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2310 my $c = _rev_map_get($fh, $rev);
2311 close($fh) or croak "close: $!";
2312 $c
2313}
2314sub _rev_map_get {
2316 my ($fh, $rev) = @_;
2317 binmode $fh or croak "binmode: $!";
2319 my $size = (stat($fh))[7];
2320 ($size % 24) == 0 or croak "inconsistent size: $size";
2321 if ($size == 0) {
2323 return undef;
2324 }
2325 my ($l, $u) = (0, $size - 24);
2327 my ($r, $c, $buf);
2328 while ($l <= $u) {
2330 my $i = int(($l/24 + $u/24) / 2) * 24;
2331 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2332 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2333 my ($r, $c) = unpack(rev_map_fmt, $buf);
2334 if ($r < $rev) {
2336 $l = $i + 24;
2337 } elsif ($r > $rev) {
2338 $u = $i - 24;
2339 } else { # $r == $rev
2340 return $c eq ('0' x 40) ? undef : $c;
2341 }
2342 }
2343 undef;
2344}
2345# Finds the first svn revision that exists on (if $eq_ok is true) or
2347# before $rev for the current branch. It will not search any lower
2348# than $min_rev. Returns the git commit hash and svn revision number
2349# if found, else (undef, undef).
2350sub find_rev_before {
2351 my ($self, $rev, $eq_ok, $min_rev) = @_;
2352 --$rev unless $eq_ok;
2353 $min_rev ||= 1;
2354 my $max_rev = $self->rev_map_max;
2355 $rev = $max_rev if ($rev > $max_rev);
2356 while ($rev >= $min_rev) {
2357 if (my $c = $self->rev_map_get($rev)) {
2358 return ($rev, $c);
2359 }
2360 --$rev;
2361 }
2362 return (undef, undef);
2363}
2364# Finds the first svn revision that exists on (if $eq_ok is true) or
2366# after $rev for the current branch. It will not search any higher
2367# than $max_rev. Returns the git commit hash and svn revision number
2368# if found, else (undef, undef).
2369sub find_rev_after {
2370 my ($self, $rev, $eq_ok, $max_rev) = @_;
2371 ++$rev unless $eq_ok;
2372 $max_rev ||= $self->rev_map_max;
2373 while ($rev <= $max_rev) {
2374 if (my $c = $self->rev_map_get($rev)) {
2375 return ($rev, $c);
2376 }
2377 ++$rev;
2378 }
2379 return (undef, undef);
2380}
2381sub _new {
2383 my ($class, $repo_id, $ref_id, $path) = @_;
2384 unless (defined $repo_id && length $repo_id) {
2385 $repo_id = $default_repo_id;
2386 }
2387 unless (defined $ref_id && length $ref_id) {
2388 # Access the prefix option from the git-svn main program if it's loaded.
2389 my $prefix = defined &::opt_prefix ? ::opt_prefix() : "";
2390 $_[2] = $ref_id =
2391 "refs/remotes/$prefix$default_ref_id";
2392 }
2393 $_[1] = $repo_id;
2394 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2395 # Older repos imported by us used $GIT_DIR/svn/foo instead of
2397 # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
2398 if ($ref_id =~ m{^refs/remotes/(.*)}) {
2399 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
2400 if (-d $old_dir && ! -d $dir) {
2401 $dir = $old_dir;
2402 }
2403 }
2404 $_[3] = $path = '' unless (defined $path);
2406 mkpath([$dir]);
2407 my $obj = bless {
2408 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2409 config => "$ENV{GIT_DIR}/svn/config",
2410 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2411 # Ensure it gets canonicalized
2413 $obj->path($path);
2414 return $obj;
2416}
2417sub path {
2419 my $self = shift;
2420 if (@_) {
2422 my $path = shift;
2423 $self->{_path} = canonicalize_path($path);
2424 return;
2425 }
2426 return $self->{_path};
2428}
2429sub url {
2431 my $self = shift;
2432 if (@_) {
2434 my $url = shift;
2435 $self->{url} = canonicalize_url($url);
2436 return;
2437 }
2438 return $self->{url};
2440}
2441# for read-only access of old .rev_db formats
2443sub unlink_rev_db_symlink {
2444 my ($self) = @_;
2445 my $link = $self->rev_db_path;
2446 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2447 if (-l $link) {
2448 unlink $link or croak "unlink: $link failed!";
2449 }
2450}
2451sub rev_db_path {
2453 my ($self, $uuid) = @_;
2454 my $db_path = $self->map_path($uuid);
2455 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2456 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2457 $db_path;
2458}
2459# the new replacement for .rev_db
2461sub map_path {
2462 my ($self, $uuid) = @_;
2463 $uuid ||= $self->ra_uuid;
2464 "$self->{map_root}.$uuid";
2465}
2466sub uri_encode {
2468 my ($f) = @_;
2469 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#sprintf("%%%02X",ord($1))#eg;
2470 $f
2471}
2472sub uri_decode {
2474 my ($f) = @_;
2475 $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
2476 $f
2477}
2478sub remove_username {
2480 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2481}
24821;