Andrew's git - gitweb.git/blob

   1#!/bin/sh
   2# Tcl ignores the next line -*- tcl -*- \
   3 if test "z$*" = zversion \
   4 || test "z$*" = z--version; \
   5 then \
   6        echo 'git-gui version @@GITGUI_VERSION@@'; \
   7        exit; \
   8 fi; \
   9 argv0=$0; \
  10 exec wish "$argv0" -- "$@"
  11
  12set appvers {@@GITGUI_VERSION@@}
  13set copyright [string map [list (c) \u00a9] {
  14Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16This program is free software; you can redistribute it and/or modify
  17it under the terms of the GNU General Public License as published by
  18the Free Software Foundation; either version 2 of the License, or
  19(at your option) any later version.
  20
  21This program is distributed in the hope that it will be useful,
  22but WITHOUT ANY WARRANTY; without even the implied warranty of
  23MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24GNU General Public License for more details.
  25
  26You should have received a copy of the GNU General Public License
  27along with this program; if not, write to the Free Software
  28Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30######################################################################
  31##
  32## Tcl/Tk sanity check
  33
  34if {[catch {package require Tcl 8.4} err]
  35 || [catch {package require Tk  8.4} err]
  36} {
  37        catch {wm withdraw .}
  38        tk_messageBox \
  39                -icon error \
  40                -type ok \
  41                -title "git-gui: fatal error" \
  42                -message $err
  43        exit 1
  44}
  45
  46catch {rename send {}} ; # What an evil concept...
  47
  48######################################################################
  49##
  50## locate our library
  51
  52if { [info exists ::env(GIT_GUI_LIB_DIR) ] } {
  53        set oguilib $::env(GIT_GUI_LIB_DIR)
  54} else {
  55        set oguilib {@@GITGUI_LIBDIR@@}
  56}
  57set oguirel {@@GITGUI_RELATIVE@@}
  58if {$oguirel eq {1}} {
  59        set oguilib [file dirname [file normalize $argv0]]
  60        if {[file tail $oguilib] eq {git-core}} {
  61                set oguilib [file dirname $oguilib]
  62        }
  63        set oguilib [file dirname $oguilib]
  64        set oguilib [file join $oguilib share git-gui lib]
  65        set oguimsg [file join $oguilib msgs]
  66} elseif {[string match @@* $oguirel]} {
  67        set oguilib [file join [file dirname [file normalize $argv0]] lib]
  68        set oguimsg [file join [file dirname [file normalize $argv0]] po]
  69} else {
  70        set oguimsg [file join $oguilib msgs]
  71}
  72unset oguirel
  73
  74######################################################################
  75##
  76## enable verbose loading?
  77
  78if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  79        unset _verbose
  80        rename auto_load real__auto_load
  81        proc auto_load {name args} {
  82                puts stderr "auto_load $name"
  83                return [uplevel 1 real__auto_load $name $args]
  84        }
  85        rename source real__source
  86        proc source {args} {
  87                puts stderr "source    $args"
  88                uplevel 1 [linsert $args 0 real__source]
  89        }
  90        if {[tk windowingsystem] eq "win32"} { console show }
  91}
  92
  93######################################################################
  94##
  95## Internationalization (i18n) through msgcat and gettext. See
  96## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  97
  98package require msgcat
  99
 100# Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
 101if {[tk windowingsystem] eq "win32"
 102        && [package vcompare [package provide msgcat] 1.4.4] < 0
 103} then {
 104        proc _mc_update_locale {} {
 105                set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 106                if {![catch {
 107                        package require registry
 108                        set uilocale [registry get $key "PreferredUILanguages"]
 109                        msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 110                } uilocale]} {
 111                        if {[string length $uilocale] > 0} {
 112                                msgcat::mclocale $uilocale
 113                        }
 114                }
 115        }
 116        _mc_update_locale
 117}
 118
 119proc _mc_trim {fmt} {
 120        set cmk [string first @@ $fmt]
 121        if {$cmk > 0} {
 122                return [string range $fmt 0 [expr {$cmk - 1}]]
 123        }
 124        return $fmt
 125}
 126
 127proc mc {en_fmt args} {
 128        set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 129        if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 130                set msg [eval [list format [_mc_trim $en_fmt]] $args]
 131        }
 132        return $msg
 133}
 134
 135proc strcat {args} {
 136        return [join $args {}]
 137}
 138
 139::msgcat::mcload $oguimsg
 140unset oguimsg
 141
 142######################################################################
 143##
 144## On Mac, bring the current Wish process window to front
 145
 146if {[tk windowingsystem] eq "aqua"} {
 147        catch {
 148                exec osascript -e [format {
 149                        tell application "System Events"
 150                                set frontmost of processes whose unix id is %d to true
 151                        end tell
 152                } [pid]]
 153        }
 154}
 155
 156######################################################################
 157##
 158## read only globals
 159
 160set _appname {Git Gui}
 161set _gitdir {}
 162set _gitworktree {}
 163set _isbare {}
 164set _gitexec {}
 165set _githtmldir {}
 166set _reponame {}
 167set _iscygwin {}
 168set _search_path {}
 169set _shellpath {@@SHELL_PATH@@}
 170
 171set _trace [lsearch -exact $argv --trace]
 172if {$_trace >= 0} {
 173        set argv [lreplace $argv $_trace $_trace]
 174        set _trace 1
 175        if {[tk windowingsystem] eq "win32"} { console show }
 176} else {
 177        set _trace 0
 178}
 179
 180# variable for the last merged branch (useful for a default when deleting
 181# branches).
 182set _last_merged_branch {}
 183
 184proc shellpath {} {
 185        global _shellpath env
 186        if {[string match @@* $_shellpath]} {
 187                if {[info exists env(SHELL)]} {
 188                        return $env(SHELL)
 189                } else {
 190                        return /bin/sh
 191                }
 192        }
 193        return $_shellpath
 194}
 195
 196proc appname {} {
 197        global _appname
 198        return $_appname
 199}
 200
 201proc gitdir {args} {
 202        global _gitdir
 203        if {$args eq {}} {
 204                return $_gitdir
 205        }
 206        return [eval [list file join $_gitdir] $args]
 207}
 208
 209proc gitexec {args} {
 210        global _gitexec
 211        if {$_gitexec eq {}} {
 212                if {[catch {set _gitexec [git --exec-path]} err]} {
 213                        error "Git not installed?\n\n$err"
 214                }
 215                if {[is_Cygwin]} {
 216                        set _gitexec [exec cygpath \
 217                                --windows \
 218                                --absolute \
 219                                $_gitexec]
 220                } else {
 221                        set _gitexec [file normalize $_gitexec]
 222                }
 223        }
 224        if {$args eq {}} {
 225                return $_gitexec
 226        }
 227        return [eval [list file join $_gitexec] $args]
 228}
 229
 230proc githtmldir {args} {
 231        global _githtmldir
 232        if {$_githtmldir eq {}} {
 233                if {[catch {set _githtmldir [git --html-path]}]} {
 234                        # Git not installed or option not yet supported
 235                        return {}
 236                }
 237                if {[is_Cygwin]} {
 238                        set _githtmldir [exec cygpath \
 239                                --windows \
 240                                --absolute \
 241                                $_githtmldir]
 242                } else {
 243                        set _githtmldir [file normalize $_githtmldir]
 244                }
 245        }
 246        if {$args eq {}} {
 247                return $_githtmldir
 248        }
 249        return [eval [list file join $_githtmldir] $args]
 250}
 251
 252proc reponame {} {
 253        return $::_reponame
 254}
 255
 256proc is_MacOSX {} {
 257        if {[tk windowingsystem] eq {aqua}} {
 258                return 1
 259        }
 260        return 0
 261}
 262
 263proc is_Windows {} {
 264        if {$::tcl_platform(platform) eq {windows}} {
 265                return 1
 266        }
 267        return 0
 268}
 269
 270proc is_Cygwin {} {
 271        global _iscygwin
 272        if {$_iscygwin eq {}} {
 273                if {$::tcl_platform(platform) eq {windows}} {
 274                        if {[catch {set p [exec cygpath --windir]} err]} {
 275                                set _iscygwin 0
 276                        } else {
 277                                set _iscygwin 1
 278                                # Handle MSys2 which is only cygwin when MSYSTEM is MSYS.
 279                                if {[info exists ::env(MSYSTEM)] && $::env(MSYSTEM) ne "MSYS"} {
 280                                        set _iscygwin 0
 281                                }
 282                        }
 283                } else {
 284                        set _iscygwin 0
 285                }
 286        }
 287        return $_iscygwin
 288}
 289
 290proc is_enabled {option} {
 291        global enabled_options
 292        if {[catch {set on $enabled_options($option)}]} {return 0}
 293        return $on
 294}
 295
 296proc enable_option {option} {
 297        global enabled_options
 298        set enabled_options($option) 1
 299}
 300
 301proc disable_option {option} {
 302        global enabled_options
 303        set enabled_options($option) 0
 304}
 305
 306######################################################################
 307##
 308## config
 309
 310proc is_many_config {name} {
 311        switch -glob -- $name {
 312        gui.recentrepo -
 313        remote.*.fetch -
 314        remote.*.push
 315                {return 1}
 316        *
 317                {return 0}
 318        }
 319}
 320
 321proc is_config_true {name} {
 322        global repo_config
 323        if {[catch {set v $repo_config($name)}]} {
 324                return 0
 325        }
 326        set v [string tolower $v]
 327        if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
 328                return 1
 329        } else {
 330                return 0
 331        }
 332}
 333
 334proc is_config_false {name} {
 335        global repo_config
 336        if {[catch {set v $repo_config($name)}]} {
 337                return 0
 338        }
 339        set v [string tolower $v]
 340        if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
 341                return 1
 342        } else {
 343                return 0
 344        }
 345}
 346
 347proc get_config {name} {
 348        global repo_config
 349        if {[catch {set v $repo_config($name)}]} {
 350                return {}
 351        } else {
 352                return $v
 353        }
 354}
 355
 356proc is_bare {} {
 357        global _isbare
 358        global _gitdir
 359        global _gitworktree
 360
 361        if {$_isbare eq {}} {
 362                if {[catch {
 363                        set _bare [git rev-parse --is-bare-repository]
 364                        switch  -- $_bare {
 365                        true { set _isbare 1 }
 366                        false { set _isbare 0}
 367                        default { throw }
 368                        }
 369                }]} {
 370                        if {[is_config_true core.bare]
 371                                || ($_gitworktree eq {}
 372                                        && [lindex [file split $_gitdir] end] ne {.git})} {
 373                                set _isbare 1
 374                        } else {
 375                                set _isbare 0
 376                        }
 377                }
 378        }
 379        return $_isbare
 380}
 381
 382######################################################################
 383##
 384## handy utils
 385
 386proc _trace_exec {cmd} {
 387        if {!$::_trace} return
 388        set d {}
 389        foreach v $cmd {
 390                if {$d ne {}} {
 391                        append d { }
 392                }
 393                if {[regexp {[ \t\r\n'"$?*]} $v]} {
 394                        set v [sq $v]
 395                }
 396                append d $v
 397        }
 398        puts stderr $d
 399}
 400
 401#'"  fix poor old emacs font-lock mode
 402
 403proc _git_cmd {name} {
 404        global _git_cmd_path
 405
 406        if {[catch {set v $_git_cmd_path($name)}]} {
 407                switch -- $name {
 408                  version   -
 409                --version   -
 410                --exec-path { return [list $::_git $name] }
 411                }
 412
 413                set p [gitexec git-$name$::_search_exe]
 414                if {[file exists $p]} {
 415                        set v [list $p]
 416                } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 417                        # Try to determine what sort of magic will make
 418                        # git-$name go and do its thing, because native
 419                        # Tcl on Windows doesn't know it.
 420                        #
 421                        set p [gitexec git-$name]
 422                        set f [open $p r]
 423                        set s [gets $f]
 424                        close $f
 425
 426                        switch -glob -- [lindex $s 0] {
 427                        #!*sh     { set i sh     }
 428                        #!*perl   { set i perl   }
 429                        #!*python { set i python }
 430                        default   { error "git-$name is not supported: $s" }
 431                        }
 432
 433                        upvar #0 _$i interp
 434                        if {![info exists interp]} {
 435                                set interp [_which $i]
 436                        }
 437                        if {$interp eq {}} {
 438                                error "git-$name requires $i (not in PATH)"
 439                        }
 440                        set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 441                } else {
 442                        # Assume it is builtin to git somehow and we
 443                        # aren't actually able to see a file for it.
 444                        #
 445                        set v [list $::_git $name]
 446                }
 447                set _git_cmd_path($name) $v
 448        }
 449        return $v
 450}
 451
 452proc _which {what args} {
 453        global env _search_exe _search_path
 454
 455        if {$_search_path eq {}} {
 456                if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 457                        set _search_path [split [exec cygpath \
 458                                --windows \
 459                                --path \
 460                                --absolute \
 461                                $env(PATH)] {;}]
 462                        set _search_exe .exe
 463                } elseif {[is_Windows]} {
 464                        set gitguidir [file dirname [info script]]
 465                        regsub -all ";" $gitguidir "\\;" gitguidir
 466                        set env(PATH) "$gitguidir;$env(PATH)"
 467                        set _search_path [split $env(PATH) {;}]
 468                        set _search_exe .exe
 469                } else {
 470                        set _search_path [split $env(PATH) :]
 471                        set _search_exe {}
 472                }
 473        }
 474
 475        if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 476                set suffix {}
 477        } else {
 478                set suffix $_search_exe
 479        }
 480
 481        foreach p $_search_path {
 482                set p [file join $p $what$suffix]
 483                if {[file exists $p]} {
 484                        return [file normalize $p]
 485                }
 486        }
 487        return {}
 488}
 489
 490# Test a file for a hashbang to identify executable scripts on Windows.
 491proc is_shellscript {filename} {
 492        if {![file exists $filename]} {return 0}
 493        set f [open $filename r]
 494        fconfigure $f -encoding binary
 495        set magic [read $f 2]
 496        close $f
 497        return [expr {$magic eq "#!"}]
 498}
 499
 500# Run a command connected via pipes on stdout.
 501# This is for use with textconv filters and uses sh -c "..." to allow it to
 502# contain a command with arguments. On windows we must check for shell
 503# scripts specifically otherwise just call the filter command.
 504proc open_cmd_pipe {cmd path} {
 505        global env
 506        if {![file executable [shellpath]]} {
 507                set exe [auto_execok [lindex $cmd 0]]
 508                if {[is_shellscript [lindex $exe 0]]} {
 509                        set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
 510                } else {
 511                        set run [concat $exe [lrange $cmd 1 end] $path]
 512                }
 513        } else {
 514                set run [list [shellpath] -c "$cmd \"\$0\"" $path]
 515        }
 516        return [open |$run r]
 517}
 518
 519proc _lappend_nice {cmd_var} {
 520        global _nice
 521        upvar $cmd_var cmd
 522
 523        if {![info exists _nice]} {
 524                set _nice [_which nice]
 525                if {[catch {exec $_nice git version}]} {
 526                        set _nice {}
 527                } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 528                        set _nice {}
 529                }
 530        }
 531        if {$_nice ne {}} {
 532                lappend cmd $_nice
 533        }
 534}
 535
 536proc git {args} {
 537        set fd [eval [list git_read] $args]
 538        fconfigure $fd -translation binary -encoding utf-8
 539        set result [string trimright [read $fd] "\n"]
 540        close $fd
 541        if {$::_trace} {
 542                puts stderr "< $result"
 543        }
 544        return $result
 545}
 546
 547proc _open_stdout_stderr {cmd} {
 548        _trace_exec $cmd
 549        if {[catch {
 550                        set fd [open [concat [list | ] $cmd] r]
 551                } err]} {
 552                if {   [lindex $cmd end] eq {2>@1}
 553                    && $err eq {can not find channel named "1"}
 554                        } {
 555                        # Older versions of Tcl 8.4 don't have this 2>@1 IO
 556                        # redirect operator.  Fallback to |& cat for those.
 557                        # The command was not actually started, so its safe
 558                        # to try to start it a second time.
 559                        #
 560                        set fd [open [concat \
 561                                [list | ] \
 562                                [lrange $cmd 0 end-1] \
 563                                [list |& cat] \
 564                                ] r]
 565                } else {
 566                        error $err
 567                }
 568        }
 569        fconfigure $fd -eofchar {}
 570        return $fd
 571}
 572
 573proc git_read {args} {
 574        set opt [list]
 575
 576        while {1} {
 577                switch -- [lindex $args 0] {
 578                --nice {
 579                        _lappend_nice opt
 580                }
 581
 582                --stderr {
 583                        lappend args 2>@1
 584                }
 585
 586                default {
 587                        break
 588                }
 589
 590                }
 591
 592                set args [lrange $args 1 end]
 593        }
 594
 595        set cmdp [_git_cmd [lindex $args 0]]
 596        set args [lrange $args 1 end]
 597
 598        return [_open_stdout_stderr [concat $opt $cmdp $args]]
 599}
 600
 601proc git_write {args} {
 602        set opt [list]
 603
 604        while {1} {
 605                switch -- [lindex $args 0] {
 606                --nice {
 607                        _lappend_nice opt
 608                }
 609
 610                default {
 611                        break
 612                }
 613
 614                }
 615
 616                set args [lrange $args 1 end]
 617        }
 618
 619        set cmdp [_git_cmd [lindex $args 0]]
 620        set args [lrange $args 1 end]
 621
 622        _trace_exec [concat $opt $cmdp $args]
 623        return [open [concat [list | ] $opt $cmdp $args] w]
 624}
 625
 626proc githook_read {hook_name args} {
 627        set pchook [gitdir hooks $hook_name]
 628        lappend args 2>@1
 629
 630        # On Windows [file executable] might lie so we need to ask
 631        # the shell if the hook is executable.  Yes that's annoying.
 632        #
 633        if {[is_Windows]} {
 634                upvar #0 _sh interp
 635                if {![info exists interp]} {
 636                        set interp [_which sh]
 637                }
 638                if {$interp eq {}} {
 639                        error "hook execution requires sh (not in PATH)"
 640                }
 641
 642                set scr {if test -x "$1";then exec "$@";fi}
 643                set sh_c [list $interp -c $scr $interp $pchook]
 644                return [_open_stdout_stderr [concat $sh_c $args]]
 645        }
 646
 647        if {[file executable $pchook]} {
 648                return [_open_stdout_stderr [concat [list $pchook] $args]]
 649        }
 650
 651        return {}
 652}
 653
 654proc kill_file_process {fd} {
 655        set process [pid $fd]
 656
 657        catch {
 658                if {[is_Windows]} {
 659                        exec taskkill /pid $process
 660                } else {
 661                        exec kill $process
 662                }
 663        }
 664}
 665
 666proc gitattr {path attr default} {
 667        if {[catch {set r [git check-attr $attr -- $path]}]} {
 668                set r unspecified
 669        } else {
 670                set r [join [lrange [split $r :] 2 end] :]
 671                regsub {^ } $r {} r
 672        }
 673        if {$r eq {unspecified}} {
 674                return $default
 675        }
 676        return $r
 677}
 678
 679proc sq {value} {
 680        regsub -all ' $value "'\\''" value
 681        return "'$value'"
 682}
 683
 684proc load_current_branch {} {
 685        global current_branch is_detached
 686
 687        set fd [open [gitdir HEAD] r]
 688        if {[gets $fd ref] < 1} {
 689                set ref {}
 690        }
 691        close $fd
 692
 693        set pfx {ref: refs/heads/}
 694        set len [string length $pfx]
 695        if {[string equal -length $len $pfx $ref]} {
 696                # We're on a branch.  It might not exist.  But
 697                # HEAD looks good enough to be a branch.
 698                #
 699                set current_branch [string range $ref $len end]
 700                set is_detached 0
 701        } else {
 702                # Assume this is a detached head.
 703                #
 704                set current_branch HEAD
 705                set is_detached 1
 706        }
 707}
 708
 709auto_load tk_optionMenu
 710rename tk_optionMenu real__tkOptionMenu
 711proc tk_optionMenu {w varName args} {
 712        set m [eval real__tkOptionMenu $w $varName $args]
 713        $m configure -font font_ui
 714        $w configure -font font_ui
 715        return $m
 716}
 717
 718proc rmsel_tag {text} {
 719        $text tag conf sel \
 720                -background [$text cget -background] \
 721                -foreground [$text cget -foreground] \
 722                -borderwidth 0
 723        $text tag conf in_sel -background lightgray
 724        bind $text <Motion> break
 725        return $text
 726}
 727
 728wm withdraw .
 729set root_exists 0
 730bind . <Visibility> {
 731        bind . <Visibility> {}
 732        set root_exists 1
 733}
 734
 735if {[is_Windows]} {
 736        wm iconbitmap . -default $oguilib/git-gui.ico
 737        set ::tk::AlwaysShowSelection 1
 738        bind . <Control-F2> {console show}
 739
 740        # Spoof an X11 display for SSH
 741        if {![info exists env(DISPLAY)]} {
 742                set env(DISPLAY) :9999
 743        }
 744} else {
 745        catch {
 746                image create photo gitlogo -width 16 -height 16
 747
 748                gitlogo put #33CC33 -to  7  0  9  2
 749                gitlogo put #33CC33 -to  4  2 12  4
 750                gitlogo put #33CC33 -to  7  4  9  6
 751                gitlogo put #CC3333 -to  4  6 12  8
 752                gitlogo put gray26  -to  4  9  6 10
 753                gitlogo put gray26  -to  3 10  6 12
 754                gitlogo put gray26  -to  8  9 13 11
 755                gitlogo put gray26  -to  8 11 10 12
 756                gitlogo put gray26  -to 11 11 13 14
 757                gitlogo put gray26  -to  3 12  5 14
 758                gitlogo put gray26  -to  5 13
 759                gitlogo put gray26  -to 10 13
 760                gitlogo put gray26  -to  4 14 12 15
 761                gitlogo put gray26  -to  5 15 11 16
 762                gitlogo redither
 763
 764                image create photo gitlogo32 -width 32 -height 32
 765                gitlogo32 copy gitlogo -zoom 2 2
 766
 767                wm iconphoto . -default gitlogo gitlogo32
 768        }
 769}
 770
 771######################################################################
 772##
 773## config defaults
 774
 775set cursor_ptr arrow
 776font create font_ui
 777if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 778        eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 779        eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 780} else {
 781        font create font_diff -family Courier -size 10
 782        catch {
 783                label .dummy
 784                eval font configure font_ui [font actual [.dummy cget -font]]
 785                destroy .dummy
 786        }
 787}
 788
 789font create font_uiitalic
 790font create font_uibold
 791font create font_diffbold
 792font create font_diffitalic
 793
 794foreach class {Button Checkbutton Entry Label
 795                Labelframe Listbox Message
 796                Radiobutton Spinbox Text} {
 797        option add *$class.font font_ui
 798}
 799if {![is_MacOSX]} {
 800        option add *Menu.font font_ui
 801        option add *Entry.borderWidth 1 startupFile
 802        option add *Entry.relief sunken startupFile
 803        option add *RadioButton.anchor w startupFile
 804}
 805unset class
 806
 807if {[is_Windows] || [is_MacOSX]} {
 808        option add *Menu.tearOff 0
 809}
 810
 811if {[is_MacOSX]} {
 812        set M1B M1
 813        set M1T Cmd
 814} else {
 815        set M1B Control
 816        set M1T Ctrl
 817}
 818
 819proc bind_button3 {w cmd} {
 820        bind $w <Any-Button-3> $cmd
 821        if {[is_MacOSX]} {
 822                # Mac OS X sends Button-2 on right click through three-button mouse,
 823                # or through trackpad right-clicking (two-finger touch + click).
 824                bind $w <Any-Button-2> $cmd
 825                bind $w <Control-Button-1> $cmd
 826        }
 827}
 828
 829proc apply_config {} {
 830        global repo_config font_descs
 831
 832        foreach option $font_descs {
 833                set name [lindex $option 0]
 834                set font [lindex $option 1]
 835                if {[catch {
 836                        set need_weight 1
 837                        foreach {cn cv} $repo_config(gui.$name) {
 838                                if {$cn eq {-weight}} {
 839                                        set need_weight 0
 840                                }
 841                                font configure $font $cn $cv
 842                        }
 843                        if {$need_weight} {
 844                                font configure $font -weight normal
 845                        }
 846                        } err]} {
 847                        error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 848                }
 849                foreach {cn cv} [font configure $font] {
 850                        font configure ${font}bold $cn $cv
 851                        font configure ${font}italic $cn $cv
 852                }
 853                font configure ${font}bold -weight bold
 854                font configure ${font}italic -slant italic
 855        }
 856
 857        global use_ttk NS
 858        set use_ttk 0
 859        set NS {}
 860        if {$repo_config(gui.usettk)} {
 861                set use_ttk [package vsatisfies [package provide Tk] 8.5]
 862                if {$use_ttk} {
 863                        set NS ttk
 864                        bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 865                        pave_toplevel .
 866                }
 867        }
 868}
 869
 870set default_config(branch.autosetupmerge) true
 871set default_config(merge.tool) {}
 872set default_config(mergetool.keepbackup) true
 873set default_config(merge.diffstat) true
 874set default_config(merge.summary) false
 875set default_config(merge.verbosity) 2
 876set default_config(user.name) {}
 877set default_config(user.email) {}
 878
 879set default_config(gui.encoding) [encoding system]
 880set default_config(gui.matchtrackingbranch) false
 881set default_config(gui.textconv) true
 882set default_config(gui.pruneduringfetch) false
 883set default_config(gui.trustmtime) false
 884set default_config(gui.fastcopyblame) false
 885set default_config(gui.maxrecentrepo) 10
 886set default_config(gui.copyblamethreshold) 40
 887set default_config(gui.blamehistoryctx) 7
 888set default_config(gui.diffcontext) 5
 889set default_config(gui.diffopts) {}
 890set default_config(gui.commitmsgwidth) 75
 891set default_config(gui.newbranchtemplate) {}
 892set default_config(gui.spellingdictionary) {}
 893set default_config(gui.fontui) [font configure font_ui]
 894set default_config(gui.fontdiff) [font configure font_diff]
 895# TODO: this option should be added to the git-config documentation
 896set default_config(gui.maxfilesdisplayed) 5000
 897set default_config(gui.usettk) 1
 898set default_config(gui.warndetachedcommit) 1
 899set default_config(gui.tabsize) 8
 900set font_descs {
 901        {fontui   font_ui   {mc "Main Font"}}
 902        {fontdiff font_diff {mc "Diff/Console Font"}}
 903}
 904set default_config(gui.stageuntracked) ask
 905set default_config(gui.displayuntracked) true
 906
 907######################################################################
 908##
 909## find git
 910
 911set _git  [_which git]
 912if {$_git eq {}} {
 913        catch {wm withdraw .}
 914        tk_messageBox \
 915                -icon error \
 916                -type ok \
 917                -title [mc "git-gui: fatal error"] \
 918                -message [mc "Cannot find git in PATH."]
 919        exit 1
 920}
 921
 922######################################################################
 923##
 924## version check
 925
 926if {[catch {set _git_version [git --version]} err]} {
 927        catch {wm withdraw .}
 928        tk_messageBox \
 929                -icon error \
 930                -type ok \
 931                -title [mc "git-gui: fatal error"] \
 932                -message "Cannot determine Git version:
 933
 934$err
 935
 936[appname] requires Git 1.5.0 or later."
 937        exit 1
 938}
 939if {![regsub {^git version } $_git_version {} _git_version]} {
 940        catch {wm withdraw .}
 941        tk_messageBox \
 942                -icon error \
 943                -type ok \
 944                -title [mc "git-gui: fatal error"] \
 945                -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 946        exit 1
 947}
 948
 949proc get_trimmed_version {s} {
 950    set r {}
 951    foreach x [split $s -._] {
 952        if {[string is integer -strict $x]} {
 953            lappend r $x
 954        } else {
 955            break
 956        }
 957    }
 958    return [join $r .]
 959}
 960set _real_git_version $_git_version
 961set _git_version [get_trimmed_version $_git_version]
 962
 963if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 964        catch {wm withdraw .}
 965        if {[tk_messageBox \
 966                -icon warning \
 967                -type yesno \
 968                -default no \
 969                -title "[appname]: warning" \
 970                 -message [mc "Git version cannot be determined.
 971
 972%s claims it is version '%s'.
 973
 974%s requires at least Git 1.5.0 or later.
 975
 976Assume '%s' is version 1.5.0?
 977" $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 978                set _git_version 1.5.0
 979        } else {
 980                exit 1
 981        }
 982}
 983unset _real_git_version
 984
 985proc git-version {args} {
 986        global _git_version
 987
 988        switch [llength $args] {
 989        0 {
 990                return $_git_version
 991        }
 992
 993        2 {
 994                set op [lindex $args 0]
 995                set vr [lindex $args 1]
 996                set cm [package vcompare $_git_version $vr]
 997                return [expr $cm $op 0]
 998        }
 999
1000        4 {
1001                set type [lindex $args 0]
1002                set name [lindex $args 1]
1003                set parm [lindex $args 2]
1004                set body [lindex $args 3]
1005
1006                if {($type ne {proc} && $type ne {method})} {
1007                        error "Invalid arguments to git-version"
1008                }
1009                if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1010                        error "Last arm of $type $name must be default"
1011                }
1012
1013                foreach {op vr cb} [lrange $body 0 end-2] {
1014                        if {[git-version $op $vr]} {
1015                                return [uplevel [list $type $name $parm $cb]]
1016                        }
1017                }
1018
1019                return [uplevel [list $type $name $parm [lindex $body end]]]
1020        }
1021
1022        default {
1023                error "git-version >= x"
1024        }
1025
1026        }
1027}
1028
1029if {[git-version < 1.5]} {
1030        catch {wm withdraw .}
1031        tk_messageBox \
1032                -icon error \
1033                -type ok \
1034                -title [mc "git-gui: fatal error"] \
1035                -message "[appname] requires Git 1.5.0 or later.
1036
1037You are using [git-version]:
1038
1039[git --version]"
1040        exit 1
1041}
1042
1043######################################################################
1044##
1045## configure our library
1046
1047set idx [file join $oguilib tclIndex]
1048if {[catch {set fd [open $idx r]} err]} {
1049        catch {wm withdraw .}
1050        tk_messageBox \
1051                -icon error \
1052                -type ok \
1053                -title [mc "git-gui: fatal error"] \
1054                -message $err
1055        exit 1
1056}
1057if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1058        set idx [list]
1059        while {[gets $fd n] >= 0} {
1060                if {$n ne {} && ![string match #* $n]} {
1061                        lappend idx $n
1062                }
1063        }
1064} else {
1065        set idx {}
1066}
1067close $fd
1068
1069if {$idx ne {}} {
1070        set loaded [list]
1071        foreach p $idx {
1072                if {[lsearch -exact $loaded $p] >= 0} continue
1073                source [file join $oguilib $p]
1074                lappend loaded $p
1075        }
1076        unset loaded p
1077} else {
1078        set auto_path [concat [list $oguilib] $auto_path]
1079}
1080unset -nocomplain idx fd
1081
1082######################################################################
1083##
1084## config file parsing
1085
1086git-version proc _parse_config {arr_name args} {
1087        >= 1.5.3 {
1088                upvar $arr_name arr
1089                array unset arr
1090                set buf {}
1091                catch {
1092                        set fd_rc [eval \
1093                                [list git_read config] \
1094                                $args \
1095                                [list --null --list]]
1096                        fconfigure $fd_rc -translation binary -encoding utf-8
1097                        set buf [read $fd_rc]
1098                        close $fd_rc
1099                }
1100                foreach line [split $buf "\0"] {
1101                        if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1102                                if {[is_many_config $name]} {
1103                                        lappend arr($name) $value
1104                                } else {
1105                                        set arr($name) $value
1106                                }
1107                        } elseif {[regexp {^([^\n]+)$} $line line name]} {
1108                                # no value given, but interpreting them as
1109                                # boolean will be handled as true
1110                                set arr($name) {}
1111                        }
1112                }
1113        }
1114        default {
1115                upvar $arr_name arr
1116                array unset arr
1117                catch {
1118                        set fd_rc [eval [list git_read config --list] $args]
1119                        while {[gets $fd_rc line] >= 0} {
1120                                if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1121                                        if {[is_many_config $name]} {
1122                                                lappend arr($name) $value
1123                                        } else {
1124                                                set arr($name) $value
1125                                        }
1126                                } elseif {[regexp {^([^=]+)$} $line line name]} {
1127                                        # no value given, but interpreting them as
1128                                        # boolean will be handled as true
1129                                        set arr($name) {}
1130                                }
1131                        }
1132                        close $fd_rc
1133                }
1134        }
1135}
1136
1137proc load_config {include_global} {
1138        global repo_config global_config system_config default_config
1139
1140        if {$include_global} {
1141                _parse_config system_config --system
1142                _parse_config global_config --global
1143        }
1144        _parse_config repo_config
1145
1146        foreach name [array names default_config] {
1147                if {[catch {set v $system_config($name)}]} {
1148                        set system_config($name) $default_config($name)
1149                }
1150        }
1151        foreach name [array names system_config] {
1152                if {[catch {set v $global_config($name)}]} {
1153                        set global_config($name) $system_config($name)
1154                }
1155                if {[catch {set v $repo_config($name)}]} {
1156                        set repo_config($name) $system_config($name)
1157                }
1158        }
1159}
1160
1161######################################################################
1162##
1163## feature option selection
1164
1165if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1166        unset _junk
1167} else {
1168        set subcommand gui
1169}
1170if {$subcommand eq {gui.sh}} {
1171        set subcommand gui
1172}
1173if {$subcommand eq {gui} && [llength $argv] > 0} {
1174        set subcommand [lindex $argv 0]
1175        set argv [lrange $argv 1 end]
1176}
1177
1178enable_option multicommit
1179enable_option branch
1180enable_option transport
1181disable_option bare
1182
1183switch -- $subcommand {
1184browser -
1185blame {
1186        enable_option bare
1187
1188        disable_option multicommit
1189        disable_option branch
1190        disable_option transport
1191}
1192citool {
1193        enable_option singlecommit
1194        enable_option retcode
1195
1196        disable_option multicommit
1197        disable_option branch
1198        disable_option transport
1199
1200        while {[llength $argv] > 0} {
1201                set a [lindex $argv 0]
1202                switch -- $a {
1203                --amend {
1204                        enable_option initialamend
1205                }
1206                --nocommit {
1207                        enable_option nocommit
1208                        enable_option nocommitmsg
1209                }
1210                --commitmsg {
1211                        disable_option nocommitmsg
1212                }
1213                default {
1214                        break
1215                }
1216                }
1217
1218                set argv [lrange $argv 1 end]
1219        }
1220}
1221}
1222
1223######################################################################
1224##
1225## execution environment
1226
1227set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1228
1229# Suggest our implementation of askpass, if none is set
1230if {![info exists env(SSH_ASKPASS)]} {
1231        set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1232}
1233
1234######################################################################
1235##
1236## repository setup
1237
1238set picked 0
1239if {[catch {
1240                set _gitdir $env(GIT_DIR)
1241                set _prefix {}
1242                }]
1243        && [catch {
1244                # beware that from the .git dir this sets _gitdir to .
1245                # and _prefix to the empty string
1246                set _gitdir [git rev-parse --git-dir]
1247                set _prefix [git rev-parse --show-prefix]
1248        } err]} {
1249        load_config 1
1250        apply_config
1251        choose_repository::pick
1252        set picked 1
1253}
1254
1255# we expand the _gitdir when it's just a single dot (i.e. when we're being
1256# run from the .git dir itself) lest the routines to find the worktree
1257# get confused
1258if {$_gitdir eq "."} {
1259        set _gitdir [pwd]
1260}
1261
1262if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1263        catch {set _gitdir [exec cygpath --windows $_gitdir]}
1264}
1265if {![file isdirectory $_gitdir]} {
1266        catch {wm withdraw .}
1267        error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1268        exit 1
1269}
1270# _gitdir exists, so try loading the config
1271load_config 0
1272apply_config
1273
1274# v1.7.0 introduced --show-toplevel to return the canonical work-tree
1275if {[package vcompare $_git_version 1.7.0] >= 0} {
1276        if { [is_Cygwin] } {
1277                catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1278        } else {
1279                set _gitworktree [git rev-parse --show-toplevel]
1280        }
1281} else {
1282        # try to set work tree from environment, core.worktree or use
1283        # cdup to obtain a relative path to the top of the worktree. If
1284        # run from the top, the ./ prefix ensures normalize expands pwd.
1285        if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1286                set _gitworktree [get_config core.worktree]
1287                if {$_gitworktree eq ""} {
1288                        set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1289                }
1290        }
1291}
1292
1293if {$_prefix ne {}} {
1294        if {$_gitworktree eq {}} {
1295                regsub -all {[^/]+/} $_prefix ../ cdup
1296        } else {
1297                set cdup $_gitworktree
1298        }
1299        if {[catch {cd $cdup} err]} {
1300                catch {wm withdraw .}
1301                error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1302                exit 1
1303        }
1304        set _gitworktree [pwd]
1305        unset cdup
1306} elseif {![is_enabled bare]} {
1307        if {[is_bare]} {
1308                catch {wm withdraw .}
1309                error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1310                exit 1
1311        }
1312        if {$_gitworktree eq {}} {
1313                set _gitworktree [file dirname $_gitdir]
1314        }
1315        if {[catch {cd $_gitworktree} err]} {
1316                catch {wm withdraw .}
1317                error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1318                exit 1
1319        }
1320        set _gitworktree [pwd]
1321}
1322set _reponame [file split [file normalize $_gitdir]]
1323if {[lindex $_reponame end] eq {.git}} {
1324        set _reponame [lindex $_reponame end-1]
1325} else {
1326        set _reponame [lindex $_reponame end]
1327}
1328
1329set env(GIT_DIR) $_gitdir
1330set env(GIT_WORK_TREE) $_gitworktree
1331
1332######################################################################
1333##
1334## global init
1335
1336set current_diff_path {}
1337set current_diff_side {}
1338set diff_actions [list]
1339
1340set HEAD {}
1341set PARENT {}
1342set MERGE_HEAD [list]
1343set commit_type {}
1344set empty_tree {}
1345set current_branch {}
1346set is_detached 0
1347set current_diff_path {}
1348set is_3way_diff 0
1349set is_submodule_diff 0
1350set is_conflict_diff 0
1351set selected_commit_type new
1352set diff_empty_count 0
1353set last_revert {}
1354set last_revert_enc {}
1355
1356set nullid "0000000000000000000000000000000000000000"
1357set nullid2 "0000000000000000000000000000000000000001"
1358
1359######################################################################
1360##
1361## task management
1362
1363set rescan_active 0
1364set diff_active 0
1365set last_clicked {}
1366
1367set disable_on_lock [list]
1368set index_lock_type none
1369
1370proc lock_index {type} {
1371        global index_lock_type disable_on_lock
1372
1373        if {$index_lock_type eq {none}} {
1374                set index_lock_type $type
1375                foreach w $disable_on_lock {
1376                        uplevel #0 $w disabled
1377                }
1378                return 1
1379        } elseif {$index_lock_type eq "begin-$type"} {
1380                set index_lock_type $type
1381                return 1
1382        }
1383        return 0
1384}
1385
1386proc unlock_index {} {
1387        global index_lock_type disable_on_lock
1388
1389        set index_lock_type none
1390        foreach w $disable_on_lock {
1391                uplevel #0 $w normal
1392        }
1393}
1394
1395######################################################################
1396##
1397## status
1398
1399proc repository_state {ctvar hdvar mhvar} {
1400        global current_branch
1401        upvar $ctvar ct $hdvar hd $mhvar mh
1402
1403        set mh [list]
1404
1405        load_current_branch
1406        if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1407                set hd {}
1408                set ct initial
1409                return
1410        }
1411
1412        set merge_head [gitdir MERGE_HEAD]
1413        if {[file exists $merge_head]} {
1414                set ct merge
1415                set fd_mh [open $merge_head r]
1416                while {[gets $fd_mh line] >= 0} {
1417                        lappend mh $line
1418                }
1419                close $fd_mh
1420                return
1421        }
1422
1423        set ct normal
1424}
1425
1426proc PARENT {} {
1427        global PARENT empty_tree
1428
1429        set p [lindex $PARENT 0]
1430        if {$p ne {}} {
1431                return $p
1432        }
1433        if {$empty_tree eq {}} {
1434                set empty_tree [git mktree << {}]
1435        }
1436        return $empty_tree
1437}
1438
1439proc force_amend {} {
1440        global selected_commit_type
1441        global HEAD PARENT MERGE_HEAD commit_type
1442
1443        repository_state newType newHEAD newMERGE_HEAD
1444        set HEAD $newHEAD
1445        set PARENT $newHEAD
1446        set MERGE_HEAD $newMERGE_HEAD
1447        set commit_type $newType
1448
1449        set selected_commit_type amend
1450        do_select_commit_type
1451}
1452
1453proc rescan {after {honor_trustmtime 1}} {
1454        global HEAD PARENT MERGE_HEAD commit_type
1455        global ui_index ui_workdir ui_comm
1456        global rescan_active file_states
1457        global repo_config
1458
1459        if {$rescan_active > 0 || ![lock_index read]} return
1460
1461        repository_state newType newHEAD newMERGE_HEAD
1462        if {[string match amend* $commit_type]
1463                && $newType eq {normal}
1464                && $newHEAD eq $HEAD} {
1465        } else {
1466                set HEAD $newHEAD
1467                set PARENT $newHEAD
1468                set MERGE_HEAD $newMERGE_HEAD
1469                set commit_type $newType
1470        }
1471
1472        array unset file_states
1473
1474        if {!$::GITGUI_BCK_exists &&
1475                (![$ui_comm edit modified]
1476                || [string trim [$ui_comm get 0.0 end]] eq {})} {
1477                if {[string match amend* $commit_type]} {
1478                } elseif {[load_message GITGUI_MSG utf-8]} {
1479                } elseif {[run_prepare_commit_msg_hook]} {
1480                } elseif {[load_message MERGE_MSG]} {
1481                } elseif {[load_message SQUASH_MSG]} {
1482                }
1483                $ui_comm edit reset
1484                $ui_comm edit modified false
1485        }
1486
1487        if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1488                rescan_stage2 {} $after
1489        } else {
1490                set rescan_active 1
1491                ui_status [mc "Refreshing file status..."]
1492                set fd_rf [git_read update-index \
1493                        -q \
1494                        --unmerged \
1495                        --ignore-missing \
1496                        --refresh \
1497                        ]
1498                fconfigure $fd_rf -blocking 0 -translation binary
1499                fileevent $fd_rf readable \
1500                        [list rescan_stage2 $fd_rf $after]
1501        }
1502}
1503
1504if {[is_Cygwin]} {
1505        set is_git_info_exclude {}
1506        proc have_info_exclude {} {
1507                global is_git_info_exclude
1508
1509                if {$is_git_info_exclude eq {}} {
1510                        if {[catch {exec test -f [gitdir info exclude]}]} {
1511                                set is_git_info_exclude 0
1512                        } else {
1513                                set is_git_info_exclude 1
1514                        }
1515                }
1516                return $is_git_info_exclude
1517        }
1518} else {
1519        proc have_info_exclude {} {
1520                return [file readable [gitdir info exclude]]
1521        }
1522}
1523
1524proc rescan_stage2 {fd after} {
1525        global rescan_active buf_rdi buf_rdf buf_rlo
1526
1527        if {$fd ne {}} {
1528                read $fd
1529                if {![eof $fd]} return
1530                close $fd
1531        }
1532
1533        if {[package vcompare $::_git_version 1.6.3] >= 0} {
1534                set ls_others [list --exclude-standard]
1535        } else {
1536                set ls_others [list --exclude-per-directory=.gitignore]
1537                if {[have_info_exclude]} {
1538                        lappend ls_others "--exclude-from=[gitdir info exclude]"
1539                }
1540                set user_exclude [get_config core.excludesfile]
1541                if {$user_exclude ne {} && [file readable $user_exclude]} {
1542                        lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1543                }
1544        }
1545
1546        set buf_rdi {}
1547        set buf_rdf {}
1548        set buf_rlo {}
1549
1550        set rescan_active 2
1551        ui_status [mc "Scanning for modified files ..."]
1552        if {[git-version >= "1.7.2"]} {
1553                set fd_di [git_read diff-index --cached --ignore-submodules=dirty -z [PARENT]]
1554        } else {
1555                set fd_di [git_read diff-index --cached -z [PARENT]]
1556        }
1557        set fd_df [git_read diff-files -z]
1558
1559        fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1560        fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1561
1562        fileevent $fd_di readable [list read_diff_index $fd_di $after]
1563        fileevent $fd_df readable [list read_diff_files $fd_df $after]
1564
1565        if {[is_config_true gui.displayuntracked]} {
1566                set fd_lo [eval git_read ls-files --others -z $ls_others]
1567                fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1568                fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1569                incr rescan_active
1570        }
1571}
1572
1573proc load_message {file {encoding {}}} {
1574        global ui_comm
1575
1576        set f [gitdir $file]
1577        if {[file isfile $f]} {
1578                if {[catch {set fd [open $f r]}]} {
1579                        return 0
1580                }
1581                fconfigure $fd -eofchar {}
1582                if {$encoding ne {}} {
1583                        fconfigure $fd -encoding $encoding
1584                }
1585                set content [string trim [read $fd]]
1586                close $fd
1587                regsub -all -line {[ \r\t]+$} $content {} content
1588                $ui_comm delete 0.0 end
1589                $ui_comm insert end $content
1590                return 1
1591        }
1592        return 0
1593}
1594
1595proc run_prepare_commit_msg_hook {} {
1596        global pch_error
1597
1598        # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1599        # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1600        # empty file but existent file.
1601
1602        set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1603
1604        if {[file isfile [gitdir MERGE_MSG]]} {
1605                set pcm_source "merge"
1606                set fd_mm [open [gitdir MERGE_MSG] r]
1607                fconfigure $fd_mm -encoding utf-8
1608                puts -nonewline $fd_pcm [read $fd_mm]
1609                close $fd_mm
1610        } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1611                set pcm_source "squash"
1612                set fd_sm [open [gitdir SQUASH_MSG] r]
1613                fconfigure $fd_sm -encoding utf-8
1614                puts -nonewline $fd_pcm [read $fd_sm]
1615                close $fd_sm
1616        } else {
1617                set pcm_source ""
1618        }
1619
1620        close $fd_pcm
1621
1622        set fd_ph [githook_read prepare-commit-msg \
1623                        [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1624        if {$fd_ph eq {}} {
1625                catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1626                return 0;
1627        }
1628
1629        ui_status [mc "Calling prepare-commit-msg hook..."]
1630        set pch_error {}
1631
1632        fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1633        fileevent $fd_ph readable \
1634                [list prepare_commit_msg_hook_wait $fd_ph]
1635
1636        return 1;
1637}
1638
1639proc prepare_commit_msg_hook_wait {fd_ph} {
1640        global pch_error
1641
1642        append pch_error [read $fd_ph]
1643        fconfigure $fd_ph -blocking 1
1644        if {[eof $fd_ph]} {
1645                if {[catch {close $fd_ph}]} {
1646                        ui_status [mc "Commit declined by prepare-commit-msg hook."]
1647                        hook_failed_popup prepare-commit-msg $pch_error
1648                        catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1649                        exit 1
1650                } else {
1651                        load_message PREPARE_COMMIT_MSG
1652                }
1653                set pch_error {}
1654                catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1655                return
1656        }
1657        fconfigure $fd_ph -blocking 0
1658        catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1659}
1660
1661proc read_diff_index {fd after} {
1662        global buf_rdi
1663
1664        append buf_rdi [read $fd]
1665        set c 0
1666        set n [string length $buf_rdi]
1667        while {$c < $n} {
1668                set z1 [string first "\0" $buf_rdi $c]
1669                if {$z1 == -1} break
1670                incr z1
1671                set z2 [string first "\0" $buf_rdi $z1]
1672                if {$z2 == -1} break
1673
1674                incr c
1675                set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1676                set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1677                merge_state \
1678                        [encoding convertfrom utf-8 $p] \
1679                        [lindex $i 4]? \
1680                        [list [lindex $i 0] [lindex $i 2]] \
1681                        [list]
1682                set c $z2
1683                incr c
1684        }
1685        if {$c < $n} {
1686                set buf_rdi [string range $buf_rdi $c end]
1687        } else {
1688                set buf_rdi {}
1689        }
1690
1691        rescan_done $fd buf_rdi $after
1692}
1693
1694proc read_diff_files {fd after} {
1695        global buf_rdf
1696
1697        append buf_rdf [read $fd]
1698        set c 0
1699        set n [string length $buf_rdf]
1700        while {$c < $n} {
1701                set z1 [string first "\0" $buf_rdf $c]
1702                if {$z1 == -1} break
1703                incr z1
1704                set z2 [string first "\0" $buf_rdf $z1]
1705                if {$z2 == -1} break
1706
1707                incr c
1708                set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1709                set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1710                merge_state \
1711                        [encoding convertfrom utf-8 $p] \
1712                        ?[lindex $i 4] \
1713                        [list] \
1714                        [list [lindex $i 0] [lindex $i 2]]
1715                set c $z2
1716                incr c
1717        }
1718        if {$c < $n} {
1719                set buf_rdf [string range $buf_rdf $c end]
1720        } else {
1721                set buf_rdf {}
1722        }
1723
1724        rescan_done $fd buf_rdf $after
1725}
1726
1727proc read_ls_others {fd after} {
1728        global buf_rlo
1729
1730        append buf_rlo [read $fd]
1731        set pck [split $buf_rlo "\0"]
1732        set buf_rlo [lindex $pck end]
1733        foreach p [lrange $pck 0 end-1] {
1734                set p [encoding convertfrom utf-8 $p]
1735                if {[string index $p end] eq {/}} {
1736                        set p [string range $p 0 end-1]
1737                }
1738                merge_state $p ?O
1739        }
1740        rescan_done $fd buf_rlo $after
1741}
1742
1743proc rescan_done {fd buf after} {
1744        global rescan_active current_diff_path
1745        global file_states repo_config
1746        upvar $buf to_clear
1747
1748        if {![eof $fd]} return
1749        set to_clear {}
1750        close $fd
1751        if {[incr rescan_active -1] > 0} return
1752
1753        prune_selection
1754        unlock_index
1755        display_all_files
1756        if {$current_diff_path ne {}} { reshow_diff $after }
1757        if {$current_diff_path eq {}} { select_first_diff $after }
1758}
1759
1760proc prune_selection {} {
1761        global file_states selected_paths
1762
1763        foreach path [array names selected_paths] {
1764                if {[catch {set still_here $file_states($path)}]} {
1765                        unset selected_paths($path)
1766                }
1767        }
1768}
1769
1770######################################################################
1771##
1772## ui helpers
1773
1774proc mapicon {w state path} {
1775        global all_icons
1776
1777        if {[catch {set r $all_icons($state$w)}]} {
1778                puts "error: no icon for $w state={$state} $path"
1779                return file_plain
1780        }
1781        return $r
1782}
1783
1784proc mapdesc {state path} {
1785        global all_descs
1786
1787        if {[catch {set r $all_descs($state)}]} {
1788                puts "error: no desc for state={$state} $path"
1789                return $state
1790        }
1791        return $r
1792}
1793
1794proc ui_status {msg} {
1795        global main_status
1796        if {[info exists main_status]} {
1797                $main_status show $msg
1798        }
1799}
1800
1801proc ui_ready {{test {}}} {
1802        global main_status
1803        if {[info exists main_status]} {
1804                $main_status show [mc "Ready."] $test
1805        }
1806}
1807
1808proc escape_path {path} {
1809        regsub -all {\\} $path "\\\\" path
1810        regsub -all "\n" $path "\\n" path
1811        return $path
1812}
1813
1814proc short_path {path} {
1815        return [escape_path [lindex [file split $path] end]]
1816}
1817
1818set next_icon_id 0
1819set null_sha1 [string repeat 0 40]
1820
1821proc merge_state {path new_state {head_info {}} {index_info {}}} {
1822        global file_states next_icon_id null_sha1
1823
1824        set s0 [string index $new_state 0]
1825        set s1 [string index $new_state 1]
1826
1827        if {[catch {set info $file_states($path)}]} {
1828                set state __
1829                set icon n[incr next_icon_id]
1830        } else {
1831                set state [lindex $info 0]
1832                set icon [lindex $info 1]
1833                if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1834                if {$index_info eq {}} {set index_info [lindex $info 3]}
1835        }
1836
1837        if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1838        elseif {$s0 eq {_}} {set s0 _}
1839
1840        if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1841        elseif {$s1 eq {_}} {set s1 _}
1842
1843        if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1844                set head_info [list 0 $null_sha1]
1845        } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1846                && $head_info eq {}} {
1847                set head_info $index_info
1848        } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1849                set index_info $head_info
1850                set head_info {}
1851        }
1852
1853        set file_states($path) [list $s0$s1 $icon \
1854                $head_info $index_info \
1855                ]
1856        return $state
1857}
1858
1859proc display_file_helper {w path icon_name old_m new_m} {
1860        global file_lists
1861
1862        if {$new_m eq {_}} {
1863                set lno [lsearch -sorted -exact $file_lists($w) $path]
1864                if {$lno >= 0} {
1865                        set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1866                        incr lno
1867                        $w conf -state normal
1868                        $w delete $lno.0 [expr {$lno + 1}].0
1869                        $w conf -state disabled
1870                }
1871        } elseif {$old_m eq {_} && $new_m ne {_}} {
1872                lappend file_lists($w) $path
1873                set file_lists($w) [lsort -unique $file_lists($w)]
1874                set lno [lsearch -sorted -exact $file_lists($w) $path]
1875                incr lno
1876                $w conf -state normal
1877                $w image create $lno.0 \
1878                        -align center -padx 5 -pady 1 \
1879                        -name $icon_name \
1880                        -image [mapicon $w $new_m $path]
1881                $w insert $lno.1 "[escape_path $path]\n"
1882                $w conf -state disabled
1883        } elseif {$old_m ne $new_m} {
1884                $w conf -state normal
1885                $w image conf $icon_name -image [mapicon $w $new_m $path]
1886                $w conf -state disabled
1887        }
1888}
1889
1890proc display_file {path state} {
1891        global file_states selected_paths
1892        global ui_index ui_workdir
1893
1894        set old_m [merge_state $path $state]
1895        set s $file_states($path)
1896        set new_m [lindex $s 0]
1897        set icon_name [lindex $s 1]
1898
1899        set o [string index $old_m 0]
1900        set n [string index $new_m 0]
1901        if {$o eq {U}} {
1902                set o _
1903        }
1904        if {$n eq {U}} {
1905                set n _
1906        }
1907        display_file_helper     $ui_index $path $icon_name $o $n
1908
1909        if {[string index $old_m 0] eq {U}} {
1910                set o U
1911        } else {
1912                set o [string index $old_m 1]
1913        }
1914        if {[string index $new_m 0] eq {U}} {
1915                set n U
1916        } else {
1917                set n [string index $new_m 1]
1918        }
1919        display_file_helper     $ui_workdir $path $icon_name $o $n
1920
1921        if {$new_m eq {__}} {
1922                unset file_states($path)
1923                catch {unset selected_paths($path)}
1924        }
1925}
1926
1927proc display_all_files_helper {w path icon_name m} {
1928        global file_lists
1929
1930        lappend file_lists($w) $path
1931        set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1932        $w image create end \
1933                -align center -padx 5 -pady 1 \
1934                -name $icon_name \
1935                -image [mapicon $w $m $path]
1936        $w insert end "[escape_path $path]\n"
1937}
1938
1939set files_warning 0
1940proc display_all_files {} {
1941        global ui_index ui_workdir
1942        global file_states file_lists
1943        global last_clicked
1944        global files_warning
1945
1946        $ui_index conf -state normal
1947        $ui_workdir conf -state normal
1948
1949        $ui_index delete 0.0 end
1950        $ui_workdir delete 0.0 end
1951        set last_clicked {}
1952
1953        set file_lists($ui_index) [list]
1954        set file_lists($ui_workdir) [list]
1955
1956        set to_display [lsort [array names file_states]]
1957        set display_limit [get_config gui.maxfilesdisplayed]
1958        set displayed 0
1959        foreach path $to_display {
1960                set s $file_states($path)
1961                set m [lindex $s 0]
1962                set icon_name [lindex $s 1]
1963
1964                if {$displayed > $display_limit && [string index $m 1] eq {O} } {
1965                        if {!$files_warning} {
1966                                # do not repeatedly warn:
1967                                set files_warning 1
1968                                info_popup [mc "Display limit (gui.maxfilesdisplayed = %s) reached, not showing all %s files." \
1969                                        $display_limit [llength $to_display]]
1970                        }
1971                        continue
1972                }
1973
1974                set s [string index $m 0]
1975                if {$s ne {U} && $s ne {_}} {
1976                        display_all_files_helper $ui_index $path \
1977                                $icon_name $s
1978                }
1979
1980                if {[string index $m 0] eq {U}} {
1981                        set s U
1982                } else {
1983                        set s [string index $m 1]
1984                }
1985                if {$s ne {_}} {
1986                        display_all_files_helper $ui_workdir $path \
1987                                $icon_name $s
1988                        incr displayed
1989                }
1990        }
1991
1992        $ui_index conf -state disabled
1993        $ui_workdir conf -state disabled
1994}
1995
1996######################################################################
1997##
1998## icons
1999
2000set filemask {
2001#define mask_width 14
2002#define mask_height 15
2003static unsigned char mask_bits[] = {
2004   0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2005   0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2006   0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2007}
2008
2009image create bitmap file_plain -background white -foreground black -data {
2010#define plain_width 14
2011#define plain_height 15
2012static unsigned char plain_bits[] = {
2013   0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2014   0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2015   0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2016} -maskdata $filemask
2017
2018image create bitmap file_mod -background white -foreground blue -data {
2019#define mod_width 14
2020#define mod_height 15
2021static unsigned char mod_bits[] = {
2022   0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2023   0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2024   0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2025} -maskdata $filemask
2026
2027image create bitmap file_fulltick -background white -foreground "#007000" -data {
2028#define file_fulltick_width 14
2029#define file_fulltick_height 15
2030static unsigned char file_fulltick_bits[] = {
2031   0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2032   0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2033   0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2034} -maskdata $filemask
2035
2036image create bitmap file_question -background white -foreground black -data {
2037#define file_question_width 14
2038#define file_question_height 15
2039static unsigned char file_question_bits[] = {
2040   0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2041   0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2042   0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2043} -maskdata $filemask
2044
2045image create bitmap file_removed -background white -foreground red -data {
2046#define file_removed_width 14
2047#define file_removed_height 15
2048static unsigned char file_removed_bits[] = {
2049   0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2050   0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2051   0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2052} -maskdata $filemask
2053
2054image create bitmap file_merge -background white -foreground blue -data {
2055#define file_merge_width 14
2056#define file_merge_height 15
2057static unsigned char file_merge_bits[] = {
2058   0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2059   0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2060   0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2061} -maskdata $filemask
2062
2063image create bitmap file_statechange -background white -foreground green -data {
2064#define file_statechange_width 14
2065#define file_statechange_height 15
2066static unsigned char file_statechange_bits[] = {
2067   0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2068   0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2069   0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2070} -maskdata $filemask
2071
2072set ui_index .vpane.files.index.list
2073set ui_workdir .vpane.files.workdir.list
2074
2075set all_icons(_$ui_index)   file_plain
2076set all_icons(A$ui_index)   file_plain
2077set all_icons(M$ui_index)   file_fulltick
2078set all_icons(D$ui_index)   file_removed
2079set all_icons(U$ui_index)   file_merge
2080set all_icons(T$ui_index)   file_statechange
2081
2082set all_icons(_$ui_workdir) file_plain
2083set all_icons(M$ui_workdir) file_mod
2084set all_icons(D$ui_workdir) file_question
2085set all_icons(U$ui_workdir) file_merge
2086set all_icons(O$ui_workdir) file_plain
2087set all_icons(T$ui_workdir) file_statechange
2088
2089set max_status_desc 0
2090foreach i {
2091                {__ {mc "Unmodified"}}
2092
2093                {_M {mc "Modified, not staged"}}
2094                {M_ {mc "Staged for commit"}}
2095                {MM {mc "Portions staged for commit"}}
2096                {MD {mc "Staged for commit, missing"}}
2097
2098                {_T {mc "File type changed, not staged"}}
2099                {MT {mc "File type changed, old type staged for commit"}}
2100                {AT {mc "File type changed, old type staged for commit"}}
2101                {T_ {mc "File type changed, staged"}}
2102                {TM {mc "File type change staged, modification not staged"}}
2103                {TD {mc "File type change staged, file missing"}}
2104
2105                {_O {mc "Untracked, not staged"}}
2106                {A_ {mc "Staged for commit"}}
2107                {AM {mc "Portions staged for commit"}}
2108                {AD {mc "Staged for commit, missing"}}
2109
2110                {_D {mc "Missing"}}
2111                {D_ {mc "Staged for removal"}}
2112                {DO {mc "Staged for removal, still present"}}
2113
2114                {_U {mc "Requires merge resolution"}}
2115                {U_ {mc "Requires merge resolution"}}
2116                {UU {mc "Requires merge resolution"}}
2117                {UM {mc "Requires merge resolution"}}
2118                {UD {mc "Requires merge resolution"}}
2119                {UT {mc "Requires merge resolution"}}
2120        } {
2121        set text [eval [lindex $i 1]]
2122        if {$max_status_desc < [string length $text]} {
2123                set max_status_desc [string length $text]
2124        }
2125        set all_descs([lindex $i 0]) $text
2126}
2127unset i
2128
2129######################################################################
2130##
2131## util
2132
2133proc scrollbar2many {list mode args} {
2134        foreach w $list {eval $w $mode $args}
2135}
2136
2137proc many2scrollbar {list mode sb top bottom} {
2138        $sb set $top $bottom
2139        foreach w $list {$w $mode moveto $top}
2140}
2141
2142proc incr_font_size {font {amt 1}} {
2143        set sz [font configure $font -size]
2144        incr sz $amt
2145        font configure $font -size $sz
2146        font configure ${font}bold -size $sz
2147        font configure ${font}italic -size $sz
2148}
2149
2150######################################################################
2151##
2152## ui commands
2153
2154set starting_gitk_msg [mc "Starting gitk... please wait..."]
2155
2156proc do_gitk {revs {is_submodule false}} {
2157        global current_diff_path file_states current_diff_side ui_index
2158        global _gitdir _gitworktree
2159
2160        # -- Always start gitk through whatever we were loaded with.  This
2161        #    lets us bypass using shell process on Windows systems.
2162        #
2163        set exe [_which gitk -script]
2164        set cmd [list [info nameofexecutable] $exe]
2165        if {$exe eq {}} {
2166                error_popup [mc "Couldn't find gitk in PATH"]
2167        } else {
2168                global env
2169
2170                set pwd [pwd]
2171
2172                if {!$is_submodule} {
2173                        if {![is_bare]} {
2174                                cd $_gitworktree
2175                        }
2176                } else {
2177                        cd $current_diff_path
2178                        if {$revs eq {--}} {
2179                                set s $file_states($current_diff_path)
2180                                set old_sha1 {}
2181                                set new_sha1 {}
2182                                switch -glob -- [lindex $s 0] {
2183                                M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2184                                _M { set old_sha1 [lindex [lindex $s 3] 1] }
2185                                MM {
2186                                        if {$current_diff_side eq $ui_index} {
2187                                                set old_sha1 [lindex [lindex $s 2] 1]
2188                                                set new_sha1 [lindex [lindex $s 3] 1]
2189                                        } else {
2190                                                set old_sha1 [lindex [lindex $s 3] 1]
2191                                        }
2192                                }
2193                                }
2194                                set revs $old_sha1...$new_sha1
2195                        }
2196                        # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2197                        # we've been using for the main repository, so unset them.
2198                        # TODO we could make life easier (start up faster?) for gitk
2199                        # by setting these to the appropriate values to allow gitk
2200                        # to skip the heuristics to find their proper value
2201                        unset env(GIT_DIR)
2202                        unset env(GIT_WORK_TREE)
2203                }
2204                eval exec $cmd $revs "--" "--" &
2205
2206                set env(GIT_DIR) $_gitdir
2207                set env(GIT_WORK_TREE) $_gitworktree
2208                cd $pwd
2209
2210                ui_status $::starting_gitk_msg
2211                after 10000 {
2212                        ui_ready $starting_gitk_msg
2213                }
2214        }
2215}
2216
2217proc do_git_gui {} {
2218        global current_diff_path
2219
2220        # -- Always start git gui through whatever we were loaded with.  This
2221        #    lets us bypass using shell process on Windows systems.
2222        #
2223        set exe [list [_which git]]
2224        if {$exe eq {}} {
2225                error_popup [mc "Couldn't find git gui in PATH"]
2226        } else {
2227                global env
2228                global _gitdir _gitworktree
2229
2230                # see note in do_gitk about unsetting these vars when
2231                # running tools in a submodule
2232                unset env(GIT_DIR)
2233                unset env(GIT_WORK_TREE)
2234
2235                set pwd [pwd]
2236                cd $current_diff_path
2237
2238                eval exec $exe gui &
2239
2240                set env(GIT_DIR) $_gitdir
2241                set env(GIT_WORK_TREE) $_gitworktree
2242                cd $pwd
2243
2244                ui_status $::starting_gitk_msg
2245                after 10000 {
2246                        ui_ready $starting_gitk_msg
2247                }
2248        }
2249}
2250
2251proc do_explore {} {
2252        global _gitworktree
2253        set explorer {}
2254        if {[is_Cygwin] || [is_Windows]} {
2255                set explorer "explorer.exe"
2256        } elseif {[is_MacOSX]} {
2257                set explorer "open"
2258        } else {
2259                # freedesktop.org-conforming system is our best shot
2260                set explorer "xdg-open"
2261        }
2262        eval exec $explorer [list [file nativename $_gitworktree]] &
2263}
2264
2265set is_quitting 0
2266set ret_code    1
2267
2268proc terminate_me {win} {
2269        global ret_code
2270        if {$win ne {.}} return
2271        exit $ret_code
2272}
2273
2274proc do_quit {{rc {1}}} {
2275        global ui_comm is_quitting repo_config commit_type
2276        global GITGUI_BCK_exists GITGUI_BCK_i
2277        global ui_comm_spell
2278        global ret_code use_ttk
2279
2280        if {$is_quitting} return
2281        set is_quitting 1
2282
2283        if {[winfo exists $ui_comm]} {
2284                # -- Stash our current commit buffer.
2285                #
2286                set save [gitdir GITGUI_MSG]
2287                if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2288                        file rename -force [gitdir GITGUI_BCK] $save
2289                        set GITGUI_BCK_exists 0
2290                } else {
2291                        set msg [string trim [$ui_comm get 0.0 end]]
2292                        regsub -all -line {[ \r\t]+$} $msg {} msg
2293                        if {(![string match amend* $commit_type]
2294                                || [$ui_comm edit modified])
2295                                && $msg ne {}} {
2296                                catch {
2297                                        set fd [open $save w]
2298                                        fconfigure $fd -encoding utf-8
2299                                        puts -nonewline $fd $msg
2300                                        close $fd
2301                                }
2302                        } else {
2303                                catch {file delete $save}
2304                        }
2305                }
2306
2307                # -- Cancel our spellchecker if its running.
2308                #
2309                if {[info exists ui_comm_spell]} {
2310                        $ui_comm_spell stop
2311                }
2312
2313                # -- Remove our editor backup, its not needed.
2314                #
2315                after cancel $GITGUI_BCK_i
2316                if {$GITGUI_BCK_exists} {
2317                        catch {file delete [gitdir GITGUI_BCK]}
2318                }
2319
2320                # -- Stash our current window geometry into this repository.
2321                #
2322                set cfg_wmstate [wm state .]
2323                if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2324                        set rc_wmstate {}
2325                }
2326                if {$cfg_wmstate ne $rc_wmstate} {
2327                        catch {git config gui.wmstate $cfg_wmstate}
2328                }
2329                if {$cfg_wmstate eq {zoomed}} {
2330                        # on Windows wm geometry will lie about window
2331                        # position (but not size) when window is zoomed
2332                        # restore the window before querying wm geometry
2333                        wm state . normal
2334                }
2335                set cfg_geometry [list]
2336                lappend cfg_geometry [wm geometry .]
2337                if {$use_ttk} {
2338                        lappend cfg_geometry [.vpane sashpos 0]
2339                        lappend cfg_geometry [.vpane.files sashpos 0]
2340                } else {
2341                        lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2342                        lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2343                }
2344                if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2345                        set rc_geometry {}
2346                }
2347                if {$cfg_geometry ne $rc_geometry} {
2348                        catch {git config gui.geometry $cfg_geometry}
2349                }
2350        }
2351
2352        set ret_code $rc
2353
2354        # Briefly enable send again, working around Tk bug
2355        # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2356        tk appname [appname]
2357
2358        destroy .
2359}
2360
2361proc do_rescan {} {
2362        rescan ui_ready
2363}
2364
2365proc ui_do_rescan {} {
2366        rescan {force_first_diff ui_ready}
2367}
2368
2369proc do_commit {} {
2370        commit_tree
2371}
2372
2373proc next_diff {{after {}}} {
2374        global next_diff_p next_diff_w next_diff_i
2375        show_diff $next_diff_p $next_diff_w {} {} $after
2376}
2377
2378proc find_anchor_pos {lst name} {
2379        set lid [lsearch -sorted -exact $lst $name]
2380
2381        if {$lid == -1} {
2382                set lid 0
2383                foreach lname $lst {
2384                        if {$lname >= $name} break
2385                        incr lid
2386                }
2387        }
2388
2389        return $lid
2390}
2391
2392proc find_file_from {flist idx delta path mmask} {
2393        global file_states
2394
2395        set len [llength $flist]
2396        while {$idx >= 0 && $idx < $len} {
2397                set name [lindex $flist $idx]
2398
2399                if {$name ne $path && [info exists file_states($name)]} {
2400                        set state [lindex $file_states($name) 0]
2401
2402                        if {$mmask eq {} || [regexp $mmask $state]} {
2403                                return $idx
2404                        }
2405                }
2406
2407                incr idx $delta
2408        }
2409
2410        return {}
2411}
2412
2413proc find_next_diff {w path {lno {}} {mmask {}}} {
2414        global next_diff_p next_diff_w next_diff_i
2415        global file_lists ui_index ui_workdir
2416
2417        set flist $file_lists($w)
2418        if {$lno eq {}} {
2419                set lno [find_anchor_pos $flist $path]
2420        } else {
2421                incr lno -1
2422        }
2423
2424        if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2425                if {$w eq $ui_index} {
2426                        set mmask "^$mmask"
2427                } else {
2428                        set mmask "$mmask\$"
2429                }
2430        }
2431
2432        set idx [find_file_from $flist $lno 1 $path $mmask]
2433        if {$idx eq {}} {
2434                incr lno -1
2435                set idx [find_file_from $flist $lno -1 $path $mmask]
2436        }
2437
2438        if {$idx ne {}} {
2439                set next_diff_w $w
2440                set next_diff_p [lindex $flist $idx]
2441                set next_diff_i [expr {$idx+1}]
2442                return 1
2443        } else {
2444                return 0
2445        }
2446}
2447
2448proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2449        global current_diff_path
2450
2451        if {$path ne $current_diff_path} {
2452                return {}
2453        } elseif {[find_next_diff $w $path $lno $mmask]} {
2454                return {next_diff;}
2455        } else {
2456                return {reshow_diff;}
2457        }
2458}
2459
2460proc select_first_diff {after} {
2461        global ui_workdir
2462
2463        if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2464            [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2465                next_diff $after
2466        } else {
2467                uplevel #0 $after
2468        }
2469}
2470
2471proc force_first_diff {after} {
2472        global ui_workdir current_diff_path file_states
2473
2474        if {[info exists file_states($current_diff_path)]} {
2475                set state [lindex $file_states($current_diff_path) 0]
2476        } else {
2477                set state {OO}
2478        }
2479
2480        set reselect 0
2481        if {[string first {U} $state] >= 0} {
2482                # Already a conflict, do nothing
2483        } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2484                set reselect 1
2485        } elseif {[string index $state 1] ne {O}} {
2486                # Already a diff & no conflicts, do nothing
2487        } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2488                set reselect 1
2489        }
2490
2491        if {$reselect} {
2492                next_diff $after
2493        } else {
2494                uplevel #0 $after
2495        }
2496}
2497
2498proc toggle_or_diff {mode w args} {
2499        global file_states file_lists current_diff_path ui_index ui_workdir
2500        global last_clicked selected_paths
2501
2502        if {$mode eq "click"} {
2503                foreach {x y} $args break
2504                set pos [split [$w index @$x,$y] .]
2505                foreach {lno col} $pos break
2506        } else {
2507                if {$last_clicked ne {}} {
2508                        set lno [lindex $last_clicked 1]
2509                } else {
2510                        set lno [expr {int([lindex [$w tag ranges in_diff] 0])}]
2511                }
2512                if {$mode eq "toggle"} {
2513                        set col 0; set y 2
2514                } else {
2515                        incr lno [expr {$mode eq "up" ? -1 : 1}]
2516                        set col 1
2517                }
2518        }
2519
2520        set path [lindex $file_lists($w) [expr {$lno - 1}]]
2521        if {$path eq {}} {
2522                set last_clicked {}
2523                return
2524        }
2525
2526        set last_clicked [list $w $lno]
2527        focus $w
2528        array unset selected_paths
2529        $ui_index tag remove in_sel 0.0 end
2530        $ui_workdir tag remove in_sel 0.0 end
2531
2532        # Determine the state of the file
2533        if {[info exists file_states($path)]} {
2534                set state [lindex $file_states($path) 0]
2535        } else {
2536                set state {__}
2537        }
2538
2539        # Restage the file, or simply show the diff
2540        if {$col == 0 && $y > 1} {
2541                # Conflicts need special handling
2542                if {[string first {U} $state] >= 0} {
2543                        # $w must always be $ui_workdir, but...
2544                        if {$w ne $ui_workdir} { set lno {} }
2545                        merge_stage_workdir $path $lno
2546                        return
2547                }
2548
2549                if {[string index $state 1] eq {O}} {
2550                        set mmask {}
2551                } else {
2552                        set mmask {[^O]}
2553                }
2554
2555                set after [next_diff_after_action $w $path $lno $mmask]
2556
2557                if {$w eq $ui_index} {
2558                        update_indexinfo \
2559                                "Unstaging [short_path $path] from commit" \
2560                                [list $path] \
2561                                [concat $after [list ui_ready]]
2562                } elseif {$w eq $ui_workdir} {
2563                        update_index \
2564                                "Adding [short_path $path]" \
2565                                [list $path] \
2566                                [concat $after [list ui_ready]]
2567                }
2568        } else {
2569                set selected_paths($path) 1
2570                show_diff $path $w $lno
2571        }
2572}
2573
2574proc add_one_to_selection {w x y} {
2575        global file_lists last_clicked selected_paths
2576
2577        set lno [lindex [split [$w index @$x,$y] .] 0]
2578        set path [lindex $file_lists($w) [expr {$lno - 1}]]
2579        if {$path eq {}} {
2580                set last_clicked {}
2581                return
2582        }
2583
2584        if {$last_clicked ne {}
2585                && [lindex $last_clicked 0] ne $w} {
2586                array unset selected_paths
2587                [lindex $last_clicked 0] tag remove in_sel 0.0 end
2588        }
2589
2590        set last_clicked [list $w $lno]
2591        if {[catch {set in_sel $selected_paths($path)}]} {
2592                set in_sel 0
2593        }
2594        if {$in_sel} {
2595                unset selected_paths($path)
2596                $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2597        } else {
2598                set selected_paths($path) 1
2599                $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2600        }
2601}
2602
2603proc add_range_to_selection {w x y} {
2604        global file_lists last_clicked selected_paths
2605
2606        if {[lindex $last_clicked 0] ne $w} {
2607                toggle_or_diff click $w $x $y
2608                return
2609        }
2610
2611        set lno [lindex [split [$w index @$x,$y] .] 0]
2612        set lc [lindex $last_clicked 1]
2613        if {$lc < $lno} {
2614                set begin $lc
2615                set end $lno
2616        } else {
2617                set begin $lno
2618                set end $lc
2619        }
2620
2621        foreach path [lrange $file_lists($w) \
2622                [expr {$begin - 1}] \
2623                [expr {$end - 1}]] {
2624                set selected_paths($path) 1
2625        }
2626        $w tag add in_sel $begin.0 [expr {$end + 1}].0
2627}
2628
2629proc show_more_context {} {
2630        global repo_config
2631        if {$repo_config(gui.diffcontext) < 99} {
2632                incr repo_config(gui.diffcontext)
2633                reshow_diff
2634        }
2635}
2636
2637proc show_less_context {} {
2638        global repo_config
2639        if {$repo_config(gui.diffcontext) > 1} {
2640                incr repo_config(gui.diffcontext) -1
2641                reshow_diff
2642        }
2643}
2644
2645######################################################################
2646##
2647## ui construction
2648
2649set ui_comm {}
2650
2651# -- Menu Bar
2652#
2653menu .mbar -tearoff 0
2654if {[is_MacOSX]} {
2655        # -- Apple Menu (Mac OS X only)
2656        #
2657        .mbar add cascade -label Apple -menu .mbar.apple
2658        menu .mbar.apple
2659}
2660.mbar add cascade -label [mc Repository] -menu .mbar.repository
2661.mbar add cascade -label [mc Edit] -menu .mbar.edit
2662if {[is_enabled branch]} {
2663        .mbar add cascade -label [mc Branch] -menu .mbar.branch
2664}
2665if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2666        .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2667}
2668if {[is_enabled transport]} {
2669        .mbar add cascade -label [mc Merge] -menu .mbar.merge
2670        .mbar add cascade -label [mc Remote] -menu .mbar.remote
2671}
2672if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2673        .mbar add cascade -label [mc Tools] -menu .mbar.tools
2674}
2675
2676# -- Repository Menu
2677#
2678menu .mbar.repository
2679
2680if {![is_bare]} {
2681        .mbar.repository add command \
2682                -label [mc "Explore Working Copy"] \
2683                -command {do_explore}
2684}
2685
2686if {[is_Windows]} {
2687        .mbar.repository add command \
2688                -label [mc "Git Bash"] \
2689                -command {eval exec [auto_execok start] \
2690                                          [list "Git Bash" bash --login -l &]}
2691}
2692
2693if {[is_Windows] || ![is_bare]} {
2694        .mbar.repository add separator
2695}
2696
2697.mbar.repository add command \
2698        -label [mc "Browse Current Branch's Files"] \
2699        -command {browser::new $current_branch}
2700set ui_browse_current [.mbar.repository index last]
2701.mbar.repository add command \
2702        -label [mc "Browse Branch Files..."] \
2703        -command browser_open::dialog
2704.mbar.repository add separator
2705
2706.mbar.repository add command \
2707        -label [mc "Visualize Current Branch's History"] \
2708        -command {do_gitk $current_branch}
2709set ui_visualize_current [.mbar.repository index last]
2710.mbar.repository add command \
2711        -label [mc "Visualize All Branch History"] \
2712        -command {do_gitk --all}
2713.mbar.repository add separator
2714
2715proc current_branch_write {args} {
2716        global current_branch
2717        .mbar.repository entryconf $::ui_browse_current \
2718                -label [mc "Browse %s's Files" $current_branch]
2719        .mbar.repository entryconf $::ui_visualize_current \
2720                -label [mc "Visualize %s's History" $current_branch]
2721}
2722trace add variable current_branch write current_branch_write
2723
2724if {[is_enabled multicommit]} {
2725        .mbar.repository add command -label [mc "Database Statistics"] \
2726                -command do_stats
2727
2728        .mbar.repository add command -label [mc "Compress Database"] \
2729                -command do_gc
2730
2731        .mbar.repository add command -label [mc "Verify Database"] \
2732                -command do_fsck_objects
2733
2734        .mbar.repository add separator
2735
2736        if {[is_Cygwin]} {
2737                .mbar.repository add command \
2738                        -label [mc "Create Desktop Icon"] \
2739                        -command do_cygwin_shortcut
2740        } elseif {[is_Windows]} {
2741                .mbar.repository add command \
2742                        -label [mc "Create Desktop Icon"] \
2743                        -command do_windows_shortcut
2744        } elseif {[is_MacOSX]} {
2745                .mbar.repository add command \
2746                        -label [mc "Create Desktop Icon"] \
2747                        -command do_macosx_app
2748        }
2749}
2750
2751if {[is_MacOSX]} {
2752        proc ::tk::mac::Quit {args} { do_quit }
2753} else {
2754        .mbar.repository add command -label [mc Quit] \
2755                -command do_quit \
2756                -accelerator $M1T-Q
2757}
2758
2759# -- Edit Menu
2760#
2761menu .mbar.edit
2762.mbar.edit add command -label [mc Undo] \
2763        -command {catch {[focus] edit undo}} \
2764        -accelerator $M1T-Z
2765.mbar.edit add command -label [mc Redo] \
2766        -command {catch {[focus] edit redo}} \
2767        -accelerator $M1T-Y
2768.mbar.edit add separator
2769.mbar.edit add command -label [mc Cut] \
2770        -command {catch {tk_textCut [focus]}} \
2771        -accelerator $M1T-X
2772.mbar.edit add command -label [mc Copy] \
2773        -command {catch {tk_textCopy [focus]}} \
2774        -accelerator $M1T-C
2775.mbar.edit add command -label [mc Paste] \
2776        -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2777        -accelerator $M1T-V
2778.mbar.edit add command -label [mc Delete] \
2779        -command {catch {[focus] delete sel.first sel.last}} \
2780        -accelerator Del
2781.mbar.edit add separator
2782.mbar.edit add command -label [mc "Select All"] \
2783        -command {catch {[focus] tag add sel 0.0 end}} \
2784        -accelerator $M1T-A
2785
2786# -- Branch Menu
2787#
2788if {[is_enabled branch]} {
2789        menu .mbar.branch
2790
2791        .mbar.branch add command -label [mc "Create..."] \
2792                -command branch_create::dialog \
2793                -accelerator $M1T-N
2794        lappend disable_on_lock [list .mbar.branch entryconf \
2795                [.mbar.branch index last] -state]
2796
2797        .mbar.branch add command -label [mc "Checkout..."] \
2798                -command branch_checkout::dialog \
2799                -accelerator $M1T-O
2800        lappend disable_on_lock [list .mbar.branch entryconf \
2801                [.mbar.branch index last] -state]
2802
2803        .mbar.branch add command -label [mc "Rename..."] \
2804                -command branch_rename::dialog
2805        lappend disable_on_lock [list .mbar.branch entryconf \
2806                [.mbar.branch index last] -state]
2807
2808        .mbar.branch add command -label [mc "Delete..."] \
2809                -command branch_delete::dialog
2810        lappend disable_on_lock [list .mbar.branch entryconf \
2811                [.mbar.branch index last] -state]
2812
2813        .mbar.branch add command -label [mc "Reset..."] \
2814                -command merge::reset_hard
2815        lappend disable_on_lock [list .mbar.branch entryconf \
2816                [.mbar.branch index last] -state]
2817}
2818
2819# -- Commit Menu
2820#
2821proc commit_btn_caption {} {
2822        if {[is_enabled nocommit]} {
2823                return [mc "Done"]
2824        } else {
2825                return [mc Commit@@verb]
2826        }
2827}
2828
2829if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2830        menu .mbar.commit
2831
2832        if {![is_enabled nocommit]} {
2833                .mbar.commit add radiobutton \
2834                        -label [mc "New Commit"] \
2835                        -command do_select_commit_type \
2836                        -variable selected_commit_type \
2837                        -value new
2838                lappend disable_on_lock \
2839                        [list .mbar.commit entryconf [.mbar.commit index last] -state]
2840
2841                .mbar.commit add radiobutton \
2842                        -label [mc "Amend Last Commit"] \
2843                        -command do_select_commit_type \
2844                        -variable selected_commit_type \
2845                        -value amend
2846                lappend disable_on_lock \
2847                        [list .mbar.commit entryconf [.mbar.commit index last] -state]
2848
2849                .mbar.commit add separator
2850        }
2851
2852        .mbar.commit add command -label [mc Rescan] \
2853                -command ui_do_rescan \
2854                -accelerator F5
2855        lappend disable_on_lock \
2856                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2857
2858        .mbar.commit add command -label [mc "Stage To Commit"] \
2859                -command do_add_selection \
2860                -accelerator $M1T-T
2861        lappend disable_on_lock \
2862                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2863
2864        .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2865                -command do_add_all \
2866                -accelerator $M1T-I
2867        lappend disable_on_lock \
2868                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2869
2870        .mbar.commit add command -label [mc "Unstage From Commit"] \
2871                -command do_unstage_selection \
2872                -accelerator $M1T-U
2873        lappend disable_on_lock \
2874                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2875
2876        .mbar.commit add command -label [mc "Revert Changes"] \
2877                -command do_revert_selection \
2878                -accelerator $M1T-J
2879        lappend disable_on_lock \
2880                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2881
2882        .mbar.commit add separator
2883
2884        .mbar.commit add command -label [mc "Show Less Context"] \
2885                -command show_less_context \
2886                -accelerator $M1T-\-
2887
2888        .mbar.commit add command -label [mc "Show More Context"] \
2889                -command show_more_context \
2890                -accelerator $M1T-=
2891
2892        .mbar.commit add separator
2893
2894        if {![is_enabled nocommitmsg]} {
2895                .mbar.commit add command -label [mc "Sign Off"] \
2896                        -command do_signoff \
2897                        -accelerator $M1T-S
2898        }
2899
2900        .mbar.commit add command -label [commit_btn_caption] \
2901                -command do_commit \
2902                -accelerator $M1T-Return
2903        lappend disable_on_lock \
2904                [list .mbar.commit entryconf [.mbar.commit index last] -state]
2905}
2906
2907# -- Merge Menu
2908#
2909if {[is_enabled branch]} {
2910        menu .mbar.merge
2911        .mbar.merge add command -label [mc "Local Merge..."] \
2912                -command merge::dialog \
2913                -accelerator $M1T-M
2914        lappend disable_on_lock \
2915                [list .mbar.merge entryconf [.mbar.merge index last] -state]
2916        .mbar.merge add command -label [mc "Abort Merge..."] \
2917                -command merge::reset_hard
2918        lappend disable_on_lock \
2919                [list .mbar.merge entryconf [.mbar.merge index last] -state]
2920}
2921
2922# -- Transport Menu
2923#
2924if {[is_enabled transport]} {
2925        menu .mbar.remote
2926
2927        .mbar.remote add command \
2928                -label [mc "Add..."] \
2929                -command remote_add::dialog \
2930                -accelerator $M1T-A
2931        .mbar.remote add command \
2932                -label [mc "Push..."] \
2933                -command do_push_anywhere \
2934                -accelerator $M1T-P
2935        .mbar.remote add command \
2936                -label [mc "Delete Branch..."] \
2937                -command remote_branch_delete::dialog
2938}
2939
2940if {[is_MacOSX]} {
2941        proc ::tk::mac::ShowPreferences {} {do_options}
2942} else {
2943        # -- Edit Menu
2944        #
2945        .mbar.edit add separator
2946        .mbar.edit add command -label [mc "Options..."] \
2947                -command do_options
2948}
2949
2950# -- Tools Menu
2951#
2952if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2953        set tools_menubar .mbar.tools
2954        menu $tools_menubar
2955        $tools_menubar add separator
2956        $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2957        $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2958        set tools_tailcnt 3
2959        if {[array names repo_config guitool.*.cmd] ne {}} {
2960                tools_populate_all
2961        }
2962}
2963
2964# -- Help Menu
2965#
2966.mbar add cascade -label [mc Help] -menu .mbar.help
2967menu .mbar.help
2968
2969if {[is_MacOSX]} {
2970        .mbar.apple add command -label [mc "About %s" [appname]] \
2971                -command do_about
2972        .mbar.apple add separator
2973} else {
2974        .mbar.help add command -label [mc "About %s" [appname]] \
2975                -command do_about
2976}
2977. configure -menu .mbar
2978
2979set doc_path [githtmldir]
2980if {$doc_path ne {}} {
2981        set doc_path [file join $doc_path index.html]
2982
2983        if {[is_Cygwin]} {
2984                set doc_path [exec cygpath --mixed $doc_path]
2985        }
2986}
2987
2988if {[file isfile $doc_path]} {
2989        set doc_url "file:$doc_path"
2990} else {
2991        set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2992}
2993
2994proc start_browser {url} {
2995        git "web--browse" $url
2996}
2997
2998.mbar.help add command -label [mc "Online Documentation"] \
2999        -command [list start_browser $doc_url]
3000
3001.mbar.help add command -label [mc "Show SSH Key"] \
3002        -command do_ssh_key
3003
3004unset doc_path doc_url
3005
3006# -- Standard bindings
3007#
3008wm protocol . WM_DELETE_WINDOW do_quit
3009bind all <$M1B-Key-q> do_quit
3010bind all <$M1B-Key-Q> do_quit
3011bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3012bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3013
3014set subcommand_args {}
3015proc usage {} {
3016        set s "[mc usage:] $::argv0 $::subcommand $::subcommand_args"
3017        if {[tk windowingsystem] eq "win32"} {
3018                wm withdraw .
3019                tk_messageBox -icon info -message $s \
3020                        -title [mc "Usage"]
3021        } else {
3022                puts stderr $s
3023        }
3024        exit 1
3025}
3026
3027proc normalize_relpath {path} {
3028        set elements {}
3029        foreach item [file split $path] {
3030                if {$item eq {.}} continue
3031                if {$item eq {..} && [llength $elements] > 0
3032                    && [lindex $elements end] ne {..}} {
3033                        set elements [lrange $elements 0 end-1]
3034                        continue
3035                }
3036                lappend elements $item
3037        }
3038        return [eval file join $elements]
3039}
3040
3041# -- Not a normal commit type invocation?  Do that instead!
3042#
3043switch -- $subcommand {
3044browser -
3045blame {
3046        if {$subcommand eq "blame"} {
3047                set subcommand_args {[--line=<num>] rev? path}
3048        } else {
3049                set subcommand_args {rev? path}
3050        }
3051        if {$argv eq {}} usage
3052        set head {}
3053        set path {}
3054        set jump_spec {}
3055        set is_path 0
3056        foreach a $argv {
3057                set p [file join $_prefix $a]
3058
3059                if {$is_path || [file exists $p]} {
3060                        if {$path ne {}} usage
3061                        set path [normalize_relpath $p]
3062                        break
3063                } elseif {$a eq {--}} {
3064                        if {$path ne {}} {
3065                                if {$head ne {}} usage
3066                                set head $path
3067                                set path {}
3068                        }
3069                        set is_path 1
3070                } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3071                        if {$jump_spec ne {} || $head ne {}} usage
3072                        set jump_spec [list $lnum]
3073                } elseif {$head eq {}} {
3074                        if {$head ne {}} usage
3075                        set head $a
3076                        set is_path 1
3077                } else {
3078                        usage
3079                }
3080        }
3081        unset is_path
3082
3083        if {$head ne {} && $path eq {}} {
3084                if {[string index $head 0] eq {/}} {
3085                        set path [normalize_relpath $head]
3086                        set head {}
3087                } else {
3088                        set path [normalize_relpath $_prefix$head]
3089                        set head {}
3090                }
3091        }
3092
3093        if {$head eq {}} {
3094                load_current_branch
3095        } else {
3096                if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3097                        if {[catch {
3098                                        set head [git rev-parse --verify $head]
3099                                } err]} {
3100                                if {[tk windowingsystem] eq "win32"} {
3101                                        tk_messageBox -icon error -title [mc Error] -message $err
3102                                } else {
3103                                        puts stderr $err
3104                                }
3105                                exit 1
3106                        }
3107                }
3108                set current_branch $head
3109        }
3110
3111        wm deiconify .
3112        switch -- $subcommand {
3113        browser {
3114                if {$jump_spec ne {}} usage
3115                if {$head eq {}} {
3116                        if {$path ne {} && [file isdirectory $path]} {
3117                                set head $current_branch
3118                        } else {
3119                                set head $path
3120                                set path {}
3121                        }
3122                }
3123                browser::new $head $path
3124        }
3125        blame   {
3126                if {$head eq {} && ![file exists $path]} {
3127                        catch {wm withdraw .}
3128                        tk_messageBox \
3129                                -icon error \
3130                                -type ok \
3131                                -title [mc "git-gui: fatal error"] \
3132                                -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3133                        exit 1
3134                }
3135                blame::new $head $path $jump_spec
3136        }
3137        }
3138        return
3139}
3140citool -
3141gui {
3142        if {[llength $argv] != 0} {
3143                usage
3144        }
3145        # fall through to setup UI for commits
3146}
3147default {
3148        set err "[mc usage:] $argv0 \[{blame|browser|citool}\]"
3149        if {[tk windowingsystem] eq "win32"} {
3150                wm withdraw .
3151                tk_messageBox -icon error -message $err \
3152                        -title [mc "Usage"]
3153        } else {
3154                puts stderr $err
3155        }
3156        exit 1
3157}
3158}
3159
3160# -- Branch Control
3161#
3162${NS}::frame .branch
3163if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3164${NS}::label .branch.l1 \
3165        -text [mc "Current Branch:"] \
3166        -anchor w \
3167        -justify left
3168${NS}::label .branch.cb \
3169        -textvariable current_branch \
3170        -anchor w \
3171        -justify left
3172pack .branch.l1 -side left
3173pack .branch.cb -side left -fill x
3174pack .branch -side top -fill x
3175
3176# -- Main Window Layout
3177#
3178${NS}::panedwindow .vpane -orient horizontal
3179${NS}::panedwindow .vpane.files -orient vertical
3180if {$use_ttk} {
3181        .vpane add .vpane.files
3182} else {
3183        .vpane add .vpane.files -sticky nsew -height 100 -width 200
3184}
3185pack .vpane -anchor n -side top -fill both -expand 1
3186
3187# -- Working Directory File List
3188
3189textframe .vpane.files.workdir -height 100 -width 200
3190tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3191        -background lightsalmon -foreground black
3192ttext $ui_workdir -background white -foreground black \
3193        -borderwidth 0 \
3194        -width 20 -height 10 \
3195        -wrap none \
3196        -takefocus 1 -highlightthickness 1\
3197        -cursor $cursor_ptr \
3198        -xscrollcommand {.vpane.files.workdir.sx set} \
3199        -yscrollcommand {.vpane.files.workdir.sy set} \
3200        -state disabled
3201${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3202${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3203pack .vpane.files.workdir.title -side top -fill x
3204pack .vpane.files.workdir.sx -side bottom -fill x
3205pack .vpane.files.workdir.sy -side right -fill y
3206pack $ui_workdir -side left -fill both -expand 1
3207
3208# -- Index File List
3209#
3210textframe .vpane.files.index -height 100 -width 200
3211tlabel .vpane.files.index.title \
3212        -text [mc "Staged Changes (Will Commit)"] \
3213        -background lightgreen -foreground black
3214ttext $ui_index -background white -foreground black \
3215        -borderwidth 0 \
3216        -width 20 -height 10 \
3217        -wrap none \
3218        -takefocus 1 -highlightthickness 1\
3219        -cursor $cursor_ptr \
3220        -xscrollcommand {.vpane.files.index.sx set} \
3221        -yscrollcommand {.vpane.files.index.sy set} \
3222        -state disabled
3223${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3224${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3225pack .vpane.files.index.title -side top -fill x
3226pack .vpane.files.index.sx -side bottom -fill x
3227pack .vpane.files.index.sy -side right -fill y
3228pack $ui_index -side left -fill both -expand 1
3229
3230# -- Insert the workdir and index into the panes
3231#
3232.vpane.files add .vpane.files.workdir
3233.vpane.files add .vpane.files.index
3234if {!$use_ttk} {
3235        .vpane.files paneconfigure .vpane.files.workdir -sticky news
3236        .vpane.files paneconfigure .vpane.files.index -sticky news
3237}
3238
3239foreach i [list $ui_index $ui_workdir] {
3240        rmsel_tag $i
3241        $i tag conf in_diff -background [$i tag cget in_sel -background]
3242}
3243unset i
3244
3245# -- Diff and Commit Area
3246#
3247if {$have_tk85} {
3248        ${NS}::panedwindow .vpane.lower -orient vertical
3249        ${NS}::frame .vpane.lower.commarea
3250        ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3251        .vpane.lower add .vpane.lower.diff
3252        .vpane.lower add .vpane.lower.commarea
3253        .vpane add .vpane.lower
3254        if {$use_ttk} {
3255                .vpane.lower pane .vpane.lower.diff -weight 1
3256                .vpane.lower pane .vpane.lower.commarea -weight 0
3257        } else {
3258                .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3259                .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3260        }
3261} else {
3262        frame .vpane.lower -height 300 -width 400
3263        frame .vpane.lower.commarea
3264        frame .vpane.lower.diff -relief sunken -borderwidth 1
3265        pack .vpane.lower.diff -fill both -expand 1
3266        pack .vpane.lower.commarea -side bottom -fill x
3267        .vpane add .vpane.lower
3268        .vpane paneconfigure .vpane.lower -sticky nsew
3269}
3270
3271# -- Commit Area Buttons
3272#
3273${NS}::frame .vpane.lower.commarea.buttons
3274${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3275        -anchor w \
3276        -justify left
3277pack .vpane.lower.commarea.buttons.l -side top -fill x
3278pack .vpane.lower.commarea.buttons -side left -fill y
3279
3280${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3281        -command ui_do_rescan
3282pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3283lappend disable_on_lock \
3284        {.vpane.lower.commarea.buttons.rescan conf -state}
3285
3286${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3287        -command do_add_all
3288pack .vpane.lower.commarea.buttons.incall -side top -fill x
3289lappend disable_on_lock \
3290        {.vpane.lower.commarea.buttons.incall conf -state}
3291
3292if {![is_enabled nocommitmsg]} {
3293        ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3294                -command do_signoff
3295        pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3296}
3297
3298${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3299        -command do_commit
3300pack .vpane.lower.commarea.buttons.commit -side top -fill x
3301lappend disable_on_lock \
3302        {.vpane.lower.commarea.buttons.commit conf -state}
3303
3304if {![is_enabled nocommit]} {
3305        ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3306                -command do_push_anywhere
3307        pack .vpane.lower.commarea.buttons.push -side top -fill x
3308}
3309
3310# -- Commit Message Buffer
3311#
3312${NS}::frame .vpane.lower.commarea.buffer
3313${NS}::frame .vpane.lower.commarea.buffer.header
3314set ui_comm .vpane.lower.commarea.buffer.frame.t
3315set ui_coml .vpane.lower.commarea.buffer.header.l
3316
3317if {![is_enabled nocommit]} {
3318        ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3319                -text [mc "New Commit"] \
3320                -command do_select_commit_type \
3321                -variable selected_commit_type \
3322                -value new
3323        lappend disable_on_lock \
3324                [list .vpane.lower.commarea.buffer.header.new conf -state]
3325        ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3326                -text [mc "Amend Last Commit"] \
3327                -command do_select_commit_type \
3328                -variable selected_commit_type \
3329                -value amend
3330        lappend disable_on_lock \
3331                [list .vpane.lower.commarea.buffer.header.amend conf -state]
3332}
3333
3334${NS}::label $ui_coml \
3335        -anchor w \
3336        -justify left
3337proc trace_commit_type {varname args} {
3338        global ui_coml commit_type
3339        switch -glob -- $commit_type {
3340        initial       {set txt [mc "Initial Commit Message:"]}
3341        amend         {set txt [mc "Amended Commit Message:"]}
3342        amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3343        amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3344        merge         {set txt [mc "Merge Commit Message:"]}
3345        *             {set txt [mc "Commit Message:"]}
3346        }
3347        $ui_coml conf -text $txt
3348}
3349trace add variable commit_type write trace_commit_type
3350pack $ui_coml -side left -fill x
3351
3352if {![is_enabled nocommit]} {
3353        pack .vpane.lower.commarea.buffer.header.amend -side right
3354        pack .vpane.lower.commarea.buffer.header.new -side right
3355}
3356
3357textframe .vpane.lower.commarea.buffer.frame
3358ttext $ui_comm -background white -foreground black \
3359        -borderwidth 1 \
3360        -undo true \
3361        -maxundo 20 \
3362        -autoseparators true \
3363        -takefocus 1 \
3364        -highlightthickness 1 \
3365        -relief sunken \
3366        -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3367        -font font_diff \
3368        -yscrollcommand {.vpane.lower.commarea.buffer.frame.sby set}
3369${NS}::scrollbar .vpane.lower.commarea.buffer.frame.sby \
3370        -command [list $ui_comm yview]
3371
3372pack .vpane.lower.commarea.buffer.frame.sby -side right -fill y
3373pack $ui_comm -side left -fill y
3374pack .vpane.lower.commarea.buffer.header -side top -fill x
3375pack .vpane.lower.commarea.buffer.frame -side left -fill y
3376pack .vpane.lower.commarea.buffer -side left -fill y
3377
3378# -- Commit Message Buffer Context Menu
3379#
3380set ctxm .vpane.lower.commarea.buffer.ctxm
3381menu $ctxm -tearoff 0
3382$ctxm add command \
3383        -label [mc Cut] \
3384        -command {tk_textCut $ui_comm}
3385$ctxm add command \
3386        -label [mc Copy] \
3387        -command {tk_textCopy $ui_comm}
3388$ctxm add command \
3389        -label [mc Paste] \
3390        -command {tk_textPaste $ui_comm}
3391$ctxm add command \
3392        -label [mc Delete] \
3393        -command {catch {$ui_comm delete sel.first sel.last}}
3394$ctxm add separator
3395$ctxm add command \
3396        -label [mc "Select All"] \
3397        -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3398$ctxm add command \
3399        -label [mc "Copy All"] \
3400        -command {
3401                $ui_comm tag add sel 0.0 end
3402                tk_textCopy $ui_comm
3403                $ui_comm tag remove sel 0.0 end
3404        }
3405$ctxm add separator
3406$ctxm add command \
3407        -label [mc "Sign Off"] \
3408        -command do_signoff
3409set ui_comm_ctxm $ctxm
3410
3411# -- Diff Header
3412#
3413proc trace_current_diff_path {varname args} {
3414        global current_diff_path diff_actions file_states
3415        if {$current_diff_path eq {}} {
3416                set s {}
3417                set f {}
3418                set p {}
3419                set o disabled
3420        } else {
3421                set p $current_diff_path
3422                set s [mapdesc [lindex $file_states($p) 0] $p]
3423                set f [mc "File:"]
3424                set p [escape_path $p]
3425                set o normal
3426        }
3427
3428        .vpane.lower.diff.header.status configure -text $s
3429        .vpane.lower.diff.header.file configure -text $f
3430        .vpane.lower.diff.header.path configure -text $p
3431        foreach w $diff_actions {
3432                uplevel #0 $w $o
3433        }
3434}
3435trace add variable current_diff_path write trace_current_diff_path
3436
3437gold_frame .vpane.lower.diff.header
3438tlabel .vpane.lower.diff.header.status \
3439        -background gold \
3440        -foreground black \
3441        -width $max_status_desc \
3442        -anchor w \
3443        -justify left
3444tlabel .vpane.lower.diff.header.file \
3445        -background gold \
3446        -foreground black \
3447        -anchor w \
3448        -justify left
3449tlabel .vpane.lower.diff.header.path \
3450        -background gold \
3451        -foreground black \
3452        -anchor w \
3453        -justify left
3454pack .vpane.lower.diff.header.status -side left
3455pack .vpane.lower.diff.header.file -side left
3456pack .vpane.lower.diff.header.path -fill x
3457set ctxm .vpane.lower.diff.header.ctxm
3458menu $ctxm -tearoff 0
3459$ctxm add command \
3460        -label [mc Copy] \
3461        -command {
3462                clipboard clear
3463                clipboard append \
3464                        -format STRING \
3465                        -type STRING \
3466                        -- $current_diff_path
3467        }
3468lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3469bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3470
3471# -- Diff Body
3472#
3473textframe .vpane.lower.diff.body
3474set ui_diff .vpane.lower.diff.body.t
3475ttext $ui_diff -background white -foreground black \
3476        -borderwidth 0 \
3477        -width 80 -height 5 -wrap none \
3478        -font font_diff \
3479        -takefocus 1 -highlightthickness 1 \
3480        -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3481        -yscrollcommand {.vpane.lower.diff.body.sby set} \
3482        -state disabled
3483catch {$ui_diff configure -tabstyle wordprocessor}
3484${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3485        -command [list $ui_diff xview]
3486${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3487        -command [list $ui_diff yview]
3488pack .vpane.lower.diff.body.sbx -side bottom -fill x
3489pack .vpane.lower.diff.body.sby -side right -fill y
3490pack $ui_diff -side left -fill both -expand 1
3491pack .vpane.lower.diff.header -side top -fill x
3492pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3493
3494foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3495        $ui_diff tag configure clr4$n -background $c
3496        $ui_diff tag configure clri4$n -foreground $c
3497        $ui_diff tag configure clr3$n -foreground $c
3498        $ui_diff tag configure clri3$n -background $c
3499}
3500$ui_diff tag configure clr1 -font font_diffbold
3501$ui_diff tag configure clr4 -underline 1
3502
3503$ui_diff tag conf d_info -foreground blue -font font_diffbold
3504
3505$ui_diff tag conf d_cr -elide true
3506$ui_diff tag conf d_@ -font font_diffbold
3507$ui_diff tag conf d_+ -foreground {#00a000}
3508$ui_diff tag conf d_- -foreground red
3509
3510$ui_diff tag conf d_++ -foreground {#00a000}
3511$ui_diff tag conf d_-- -foreground red
3512$ui_diff tag conf d_+s \
3513        -foreground {#00a000} \
3514        -background {#e2effa}
3515$ui_diff tag conf d_-s \
3516        -foreground red \
3517        -background {#e2effa}
3518$ui_diff tag conf d_s+ \
3519        -foreground {#00a000} \
3520        -background ivory1
3521$ui_diff tag conf d_s- \
3522        -foreground red \
3523        -background ivory1
3524
3525$ui_diff tag conf d< \
3526        -foreground orange \
3527        -font font_diffbold
3528$ui_diff tag conf d= \
3529        -foreground orange \
3530        -font font_diffbold
3531$ui_diff tag conf d> \
3532        -foreground orange \
3533        -font font_diffbold
3534
3535$ui_diff tag raise sel
3536
3537# -- Diff Body Context Menu
3538#
3539
3540proc create_common_diff_popup {ctxm} {
3541        $ctxm add command \
3542                -label [mc Refresh] \
3543                -command reshow_diff
3544        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3545        $ctxm add command \
3546                -label [mc Copy] \
3547                -command {tk_textCopy $ui_diff}
3548        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3549        $ctxm add command \
3550                -label [mc "Select All"] \
3551                -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3552        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3553        $ctxm add command \
3554                -label [mc "Copy All"] \
3555                -command {
3556                        $ui_diff tag add sel 0.0 end
3557                        tk_textCopy $ui_diff
3558                        $ui_diff tag remove sel 0.0 end
3559                }
3560        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3561        $ctxm add separator
3562        $ctxm add command \
3563                -label [mc "Decrease Font Size"] \
3564                -command {incr_font_size font_diff -1}
3565        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3566        $ctxm add command \
3567                -label [mc "Increase Font Size"] \
3568                -command {incr_font_size font_diff 1}
3569        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3570        $ctxm add separator
3571        set emenu $ctxm.enc
3572        menu $emenu
3573        build_encoding_menu $emenu [list force_diff_encoding]
3574        $ctxm add cascade \
3575                -label [mc "Encoding"] \
3576                -menu $emenu
3577        lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3578        $ctxm add separator
3579        $ctxm add command -label [mc "Options..."] \
3580                -command do_options
3581}
3582
3583set ctxm .vpane.lower.diff.body.ctxm
3584menu $ctxm -tearoff 0
3585$ctxm add command \
3586        -label [mc "Apply/Reverse Hunk"] \
3587        -command {apply_or_revert_hunk $cursorX $cursorY 0}
3588set ui_diff_applyhunk [$ctxm index last]
3589lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3590$ctxm add command \
3591        -label [mc "Apply/Reverse Line"] \
3592        -command {apply_or_revert_range_or_line $cursorX $cursorY 0; do_rescan}
3593set ui_diff_applyline [$ctxm index last]
3594lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3595$ctxm add separator
3596$ctxm add command \
3597        -label [mc "Revert Hunk"] \
3598        -command {apply_or_revert_hunk $cursorX $cursorY 1}
3599set ui_diff_reverthunk [$ctxm index last]
3600lappend diff_actions [list $ctxm entryconf $ui_diff_reverthunk -state]
3601$ctxm add command \
3602        -label [mc "Revert Line"] \
3603        -command {apply_or_revert_range_or_line $cursorX $cursorY 1; do_rescan}
3604set ui_diff_revertline [$ctxm index last]
3605lappend diff_actions [list $ctxm entryconf $ui_diff_revertline -state]
3606$ctxm add command \
3607        -label [mc "Undo Last Revert"] \
3608        -command {undo_last_revert; do_rescan}
3609set ui_diff_undorevert [$ctxm index last]
3610lappend diff_actions [list $ctxm entryconf $ui_diff_undorevert -state]
3611$ctxm add separator
3612$ctxm add command \
3613        -label [mc "Show Less Context"] \
3614        -command show_less_context
3615lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3616$ctxm add command \
3617        -label [mc "Show More Context"] \
3618        -command show_more_context
3619lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3620$ctxm add separator
3621create_common_diff_popup $ctxm
3622
3623set ctxmmg .vpane.lower.diff.body.ctxmmg
3624menu $ctxmmg -tearoff 0
3625$ctxmmg add command \
3626        -label [mc "Run Merge Tool"] \
3627        -command {merge_resolve_tool}
3628lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3629$ctxmmg add separator
3630$ctxmmg add command \
3631        -label [mc "Use Remote Version"] \
3632        -command {merge_resolve_one 3}
3633lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3634$ctxmmg add command \
3635        -label [mc "Use Local Version"] \
3636        -command {merge_resolve_one 2}
3637lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3638$ctxmmg add command \
3639        -label [mc "Revert To Base"] \
3640        -command {merge_resolve_one 1}
3641lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3642$ctxmmg add separator
3643$ctxmmg add command \
3644        -label [mc "Show Less Context"] \
3645        -command show_less_context
3646lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3647$ctxmmg add command \
3648        -label [mc "Show More Context"] \
3649        -command show_more_context
3650lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3651$ctxmmg add separator
3652create_common_diff_popup $ctxmmg
3653
3654set ctxmsm .vpane.lower.diff.body.ctxmsm
3655menu $ctxmsm -tearoff 0
3656$ctxmsm add command \
3657        -label [mc "Visualize These Changes In The Submodule"] \
3658        -command {do_gitk -- true}
3659lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3660$ctxmsm add command \
3661        -label [mc "Visualize Current Branch History In The Submodule"] \
3662        -command {do_gitk {} true}
3663lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3664$ctxmsm add command \
3665        -label [mc "Visualize All Branch History In The Submodule"] \
3666        -command {do_gitk --all true}
3667lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3668$ctxmsm add separator
3669$ctxmsm add command \
3670        -label [mc "Start git gui In The Submodule"] \
3671        -command {do_git_gui}
3672lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3673$ctxmsm add separator
3674create_common_diff_popup $ctxmsm
3675
3676proc has_textconv {path} {
3677        if {[is_config_false gui.textconv]} {
3678                return 0
3679        }
3680        set filter [gitattr $path diff set]
3681        set textconv [get_config [join [list diff $filter textconv] .]]
3682        if {$filter ne {set} && $textconv ne {}} {
3683                return 1
3684        } else {
3685                return 0
3686        }
3687}
3688
3689proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3690        global current_diff_path file_states last_revert
3691        set ::cursorX $x
3692        set ::cursorY $y
3693        if {[info exists file_states($current_diff_path)]} {
3694                set state [lindex $file_states($current_diff_path) 0]
3695        } else {
3696                set state {__}
3697        }
3698        if {[string first {U} $state] >= 0} {
3699                tk_popup $ctxmmg $X $Y
3700        } elseif {$::is_submodule_diff} {
3701                tk_popup $ctxmsm $X $Y
3702        } else {
3703                set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3704                set u [mc "Undo Last Revert"]
3705                if {$::ui_index eq $::current_diff_side} {
3706                        set l [mc "Unstage Hunk From Commit"]
3707                        set h [mc "Revert Hunk"]
3708
3709                        if {$has_range} {
3710                                set t [mc "Unstage Lines From Commit"]
3711                                set r [mc "Revert Lines"]
3712                        } else {
3713                                set t [mc "Unstage Line From Commit"]
3714                                set r [mc "Revert Line"]
3715                        }
3716                } else {
3717                        set l [mc "Stage Hunk For Commit"]
3718                        set h [mc "Revert Hunk"]
3719
3720                        if {$has_range} {
3721                                set t [mc "Stage Lines For Commit"]
3722                                set r [mc "Revert Lines"]
3723                        } else {
3724                                set t [mc "Stage Line For Commit"]
3725                                set r [mc "Revert Line"]
3726                        }
3727                }
3728                if {$::is_3way_diff
3729                        || $current_diff_path eq {}
3730                        || {__} eq $state
3731                        || {_O} eq $state
3732                        || [string match {?T} $state]
3733                        || [string match {T?} $state]
3734                        || [has_textconv $current_diff_path]} {
3735                        set s disabled
3736                        set revert_state disabled
3737                } else {
3738                        set s normal
3739
3740                        # Only allow reverting changes in the working tree. If
3741                        # the user wants to revert changes in the index, they
3742                        # need to unstage those first.
3743                        if {$::ui_workdir eq $::current_diff_side} {
3744                                set revert_state normal
3745                        } else {
3746                                set revert_state disabled
3747                        }
3748                }
3749
3750                if {$last_revert eq {}} {
3751                        set undo_state disabled
3752                } else {
3753                        set undo_state normal
3754                }
3755
3756                $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3757                $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3758                $ctxm entryconf $::ui_diff_revertline -state $revert_state \
3759                        -label $r
3760                $ctxm entryconf $::ui_diff_reverthunk -state $revert_state \
3761                        -label $h
3762                $ctxm entryconf $::ui_diff_undorevert -state $undo_state \
3763                        -label $u
3764
3765                tk_popup $ctxm $X $Y
3766        }
3767}
3768bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3769
3770# -- Status Bar
3771#
3772set main_status [::status_bar::new .status]
3773pack .status -anchor w -side bottom -fill x
3774$main_status show [mc "Initializing..."]
3775
3776# -- Load geometry
3777#
3778proc on_ttk_pane_mapped {w pane pos} {
3779        bind $w <Map> {}
3780        after 0 [list after idle [list $w sashpos $pane $pos]]
3781}
3782proc on_tk_pane_mapped {w pane x y} {
3783        bind $w <Map> {}
3784        after 0 [list after idle [list $w sash place $pane $x $y]]
3785}
3786proc on_application_mapped {} {
3787        global repo_config use_ttk
3788        bind . <Map> {}
3789        set gm $repo_config(gui.geometry)
3790        if {$use_ttk} {
3791                bind .vpane <Map> \
3792                    [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3793                bind .vpane.files <Map> \
3794                    [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3795        } else {
3796                bind .vpane <Map> \
3797                    [list on_tk_pane_mapped %W 0 \
3798                         [lindex $gm 1] \
3799                         [lindex [.vpane sash coord 0] 1]]
3800                bind .vpane.files <Map> \
3801                    [list on_tk_pane_mapped %W 0 \
3802                         [lindex [.vpane.files sash coord 0] 0] \
3803                         [lindex $gm 2]]
3804        }
3805        wm geometry . [lindex $gm 0]
3806}
3807if {[info exists repo_config(gui.geometry)]} {
3808        bind . <Map> [list on_application_mapped]
3809        wm geometry . [lindex $repo_config(gui.geometry) 0]
3810}
3811
3812# -- Load window state
3813#
3814if {[info exists repo_config(gui.wmstate)]} {
3815        catch {wm state . $repo_config(gui.wmstate)}
3816}
3817
3818# -- Key Bindings
3819#
3820bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3821bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3822bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3823bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3824bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3825bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3826bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3827bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3828bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3829bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3830bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3831bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3832bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3833bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3834bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3835bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3836bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3837bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3838bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3839bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3840bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3841bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3842
3843bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3844bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3845bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3846bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3847bind $ui_diff <$M1B-Key-v> {break}
3848bind $ui_diff <$M1B-Key-V> {break}
3849bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3850bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3851bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3852bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3853bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3854bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3855bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3856bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3857bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3858bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3859bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3860bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3861bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3862bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3863bind $ui_diff <Button-1>   {focus %W}
3864
3865if {[is_enabled branch]} {
3866        bind . <$M1B-Key-n> branch_create::dialog
3867        bind . <$M1B-Key-N> branch_create::dialog
3868        bind . <$M1B-Key-o> branch_checkout::dialog
3869        bind . <$M1B-Key-O> branch_checkout::dialog
3870        bind . <$M1B-Key-m> merge::dialog
3871        bind . <$M1B-Key-M> merge::dialog
3872}
3873if {[is_enabled transport]} {
3874        bind . <$M1B-Key-p> do_push_anywhere
3875        bind . <$M1B-Key-P> do_push_anywhere
3876}
3877
3878bind .   <Key-F5>     ui_do_rescan
3879bind .   <$M1B-Key-r> ui_do_rescan
3880bind .   <$M1B-Key-R> ui_do_rescan
3881bind .   <$M1B-Key-s> do_signoff
3882bind .   <$M1B-Key-S> do_signoff
3883bind .   <$M1B-Key-t> { toggle_or_diff toggle %W }
3884bind .   <$M1B-Key-T> { toggle_or_diff toggle %W }
3885bind .   <$M1B-Key-u> { toggle_or_diff toggle %W }
3886bind .   <$M1B-Key-U> { toggle_or_diff toggle %W }
3887bind .   <$M1B-Key-j> do_revert_selection
3888bind .   <$M1B-Key-J> do_revert_selection
3889bind .   <$M1B-Key-i> do_add_all
3890bind .   <$M1B-Key-I> do_add_all
3891bind .   <$M1B-Key-minus> {show_less_context;break}
3892bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3893bind .   <$M1B-Key-equal> {show_more_context;break}
3894bind .   <$M1B-Key-plus> {show_more_context;break}
3895bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3896bind .   <$M1B-Key-Return> do_commit
3897foreach i [list $ui_index $ui_workdir] {
3898        bind $i <Button-1>       { toggle_or_diff click %W %x %y; break }
3899        bind $i <$M1B-Button-1>  { add_one_to_selection %W %x %y; break }
3900        bind $i <Shift-Button-1> { add_range_to_selection %W %x %y; break }
3901        bind $i <Key-Up>         { toggle_or_diff up %W; break }
3902        bind $i <Key-Down>       { toggle_or_diff down %W; break }
3903}
3904unset i
3905
3906set file_lists($ui_index) [list]
3907set file_lists($ui_workdir) [list]
3908
3909wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3910focus -force $ui_comm
3911
3912# -- Warn the user about environmental problems.  Cygwin's Tcl
3913#    does *not* pass its env array onto any processes it spawns.
3914#    This means that git processes get none of our environment.
3915#
3916if {[is_Cygwin]} {
3917        set ignored_env 0
3918        set suggest_user {}
3919        set msg [mc "Possible environment issues exist.
3920
3921The following environment variables are probably
3922going to be ignored by any Git subprocess run
3923by %s:
3924
3925" [appname]]
3926        foreach name [array names env] {
3927                switch -regexp -- $name {
3928                {^GIT_INDEX_FILE$} -
3929                {^GIT_OBJECT_DIRECTORY$} -
3930                {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3931                {^GIT_DIFF_OPTS$} -
3932                {^GIT_EXTERNAL_DIFF$} -
3933                {^GIT_PAGER$} -
3934                {^GIT_TRACE$} -
3935                {^GIT_CONFIG$} -
3936                {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3937                        append msg " - $name\n"
3938                        incr ignored_env
3939                }
3940                {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3941                        append msg " - $name\n"
3942                        incr ignored_env
3943                        set suggest_user $name
3944                }
3945                }
3946        }
3947        if {$ignored_env > 0} {
3948                append msg [mc "
3949This is due to a known issue with the
3950Tcl binary distributed by Cygwin."]
3951
3952                if {$suggest_user ne {}} {
3953                        append msg [mc "
3954
3955A good replacement for %s
3956is placing values for the user.name and
3957user.email settings into your personal
3958~/.gitconfig file.
3959" $suggest_user]
3960                }
3961                warn_popup $msg
3962        }
3963        unset ignored_env msg suggest_user name
3964}
3965
3966# -- Only initialize complex UI if we are going to stay running.
3967#
3968if {[is_enabled transport]} {
3969        load_all_remotes
3970
3971        set n [.mbar.remote index end]
3972        populate_remotes_menu
3973        set n [expr {[.mbar.remote index end] - $n}]
3974        if {$n > 0} {
3975                if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3976                .mbar.remote insert $n separator
3977        }
3978        unset n
3979}
3980
3981if {[winfo exists $ui_comm]} {
3982        set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
3983
3984        # -- If both our backup and message files exist use the
3985        #    newer of the two files to initialize the buffer.
3986        #
3987        if {$GITGUI_BCK_exists} {
3988                set m [gitdir GITGUI_MSG]
3989                if {[file isfile $m]} {
3990                        if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3991                                catch {file delete [gitdir GITGUI_MSG]}
3992                        } else {
3993                                $ui_comm delete 0.0 end
3994                                $ui_comm edit reset
3995                                $ui_comm edit modified false
3996                                catch {file delete [gitdir GITGUI_BCK]}
3997                                set GITGUI_BCK_exists 0
3998                        }
3999                }
4000                unset m
4001        }
4002
4003        proc backup_commit_buffer {} {
4004                global ui_comm GITGUI_BCK_exists
4005
4006                set m [$ui_comm edit modified]
4007                if {$m || $GITGUI_BCK_exists} {
4008                        set msg [string trim [$ui_comm get 0.0 end]]
4009                        regsub -all -line {[ \r\t]+$} $msg {} msg
4010
4011                        if {$msg eq {}} {
4012                                if {$GITGUI_BCK_exists} {
4013                                        catch {file delete [gitdir GITGUI_BCK]}
4014                                        set GITGUI_BCK_exists 0
4015                                }
4016                        } elseif {$m} {
4017                                catch {
4018                                        set fd [open [gitdir GITGUI_BCK] w]
4019                                        fconfigure $fd -encoding utf-8
4020                                        puts -nonewline $fd $msg
4021                                        close $fd
4022                                        set GITGUI_BCK_exists 1
4023                                }
4024                        }
4025
4026                        $ui_comm edit modified false
4027                }
4028
4029                set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
4030        }
4031
4032        backup_commit_buffer
4033
4034        # -- If the user has aspell available we can drive it
4035        #    in pipe mode to spellcheck the commit message.
4036        #
4037        set spell_cmd [list |]
4038        set spell_dict [get_config gui.spellingdictionary]
4039        lappend spell_cmd aspell
4040        if {$spell_dict ne {}} {
4041                lappend spell_cmd --master=$spell_dict
4042        }
4043        lappend spell_cmd --mode=none
4044        lappend spell_cmd --encoding=utf-8
4045        lappend spell_cmd pipe
4046        if {$spell_dict eq {none}
4047         || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
4048                bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
4049        } else {
4050                set ui_comm_spell [spellcheck::init \
4051                        $spell_fd \
4052                        $ui_comm \
4053                        $ui_comm_ctxm \
4054                ]
4055        }
4056        unset -nocomplain spell_cmd spell_fd spell_err spell_dict
4057}
4058
4059lock_index begin-read
4060if {![winfo ismapped .]} {
4061        wm deiconify .
4062}
4063after 1 {
4064        if {[is_enabled initialamend]} {
4065                force_amend
4066        } else {
4067                do_rescan
4068        }
4069
4070        if {[is_enabled nocommitmsg]} {
4071                $ui_comm configure -state disabled -background gray
4072        }
4073}
4074if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
4075        after 1000 hint_gc
4076}
4077if {[is_enabled retcode]} {
4078        bind . <Destroy> {+terminate_me %W}
4079}
4080if {$picked && [is_config_true gui.autoexplore]} {
4081        do_explore
4082}
4083
4084# Local variables:
4085# mode: tcl
4086# indent-tabs-mode: t
4087# tab-width: 4
4088# End: