Andrew's git / gitweb.git / configure.ac
?
configure.acon commit configure: make iconv tests aware of user arguments (a8304f7)
   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_ERROR([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  47                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  48        fi; \
  49fi; \
  50]) # GIT_CONF_APPEND_PATH
  51#
  52# GIT_PARSE_WITH(PACKAGE)
  53# -----------------------
  54# For use in AC_ARG_WITH action-if-found, for packages default ON.
  55# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  56# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  57# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  58AC_DEFUN([GIT_PARSE_WITH],
  59[PACKAGE=m4_toupper($1); \
  60if test "$withval" = "no"; then \
  61        m4_toupper(NO_$1)=YesPlease; \
  62elif test "$withval" = "yes"; then \
  63        m4_toupper(NO_$1)=; \
  64else \
  65        m4_toupper(NO_$1)=; \
  66        m4_toupper($1)DIR=$withval; \
  67        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  68        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  69fi \
  70])# GIT_PARSE_WITH
  71
  72dnl
  73dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
  74dnl -----------------------------------------
  75dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
  76dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
  77dnl -Wall), it does not work.  By looking for function definition in
  78dnl libraries, this problem can be worked around.
  79AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
  80  AC_SEARCH_LIBS([$1],,
  81  [$2],[$3])
  82],[$3])])
  83
  84dnl
  85dnl GIT_STASH_FLAGS(BASEPATH_VAR)
  86dnl -----------------------------
  87dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
  88dnl tests that may want to take user settings into account.
  89AC_DEFUN([GIT_STASH_FLAGS],[
  90if test -n "$1"; then
  91   old_CPPFLAGS="$CPPFLAGS"
  92   old_LDFLAGS="$LDFLAGS"
  93   CPPFLAGS="-I$1/include $CPPFLAGS"
  94   LDFLAGS="-L$1/$lib $LDFLAGS"
  95fi
  96])
  97
  98dnl
  99dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 100dnl -----------------------------
 101dnl Restore the stashed *FLAGS values.
 102AC_DEFUN([GIT_UNSTASH_FLAGS],[
 103if test -n "$1"; then
 104   CPPFLAGS="$old_CPPFLAGS"
 105   LDFLAGS="$old_LDFLAGS"
 106fi
 107])
 108
 109## Site configuration related to programs (before tests)
 110## --with-PACKAGE[=ARG] and --without-PACKAGE
 111#
 112# Set lib to alternative name of lib directory (e.g. lib64)
 113AC_ARG_WITH([lib],
 114 [AS_HELP_STRING([--with-lib=ARG],
 115                 [ARG specifies alternative name for lib directory])],
 116 [if test "$withval" = "no" || test "$withval" = "yes"; then \
 117        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 118else \
 119        lib=$withval; \
 120        AC_MSG_NOTICE([Setting lib to '$lib']); \
 121        GIT_CONF_APPEND_LINE(lib=$withval); \
 122fi; \
 123],[])
 124
 125if test -z "$lib"; then
 126   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 127   lib=lib
 128fi
 129
 130## Site configuration (override autodetection)
 131## --with-PACKAGE[=ARG] and --without-PACKAGE
 132AC_MSG_NOTICE([CHECKS for site configuration])
 133#
 134# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 135# tests.  These tests take up a significant amount of the total test time
 136# but are not needed unless you plan to talk to SVN repos.
 137#
 138# Define MOZILLA_SHA1 environment variable when running make to make use of
 139# a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 140# on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 141# choice) has very fast version optimized for i586.
 142#
 143# Define PPC_SHA1 environment variable when running make to make use of
 144# a bundled SHA1 routine optimized for PowerPC.
 145#
 146# Define ARM_SHA1 environment variable when running make to make use of
 147# a bundled SHA1 routine optimized for ARM.
 148#
 149# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 150# This also implies MOZILLA_SHA1.
 151#
 152# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 153# /foo/bar/include and /foo/bar/lib directories.
 154AC_ARG_WITH(openssl,
 155AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 156AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 157GIT_PARSE_WITH(openssl))
 158#
 159# Define NO_CURL if you do not have curl installed.  git-http-pull and
 160# git-http-push are not built, and you cannot use http:// and https://
 161# transports.
 162#
 163# Define CURLDIR=/foo/bar if your curl header and library files are in
 164# /foo/bar/include and /foo/bar/lib directories.
 165AC_ARG_WITH(curl,
 166AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 167AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 168GIT_PARSE_WITH(curl))
 169#
 170# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 171# not built, and you cannot push using http:// and https:// transports.
 172#
 173# Define EXPATDIR=/foo/bar if your expat header and library files are in
 174# /foo/bar/include and /foo/bar/lib directories.
 175AC_ARG_WITH(expat,
 176AS_HELP_STRING([--with-expat],
 177[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 178AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 179GIT_PARSE_WITH(expat))
 180#
 181# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 182# installed in /sw, but don't want GIT to link against any libraries
 183# installed there.  If defined you may specify your own (or Fink's)
 184# include directories and library directories by defining CFLAGS
 185# and LDFLAGS appropriately.
 186#
 187# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 188# have DarwinPorts installed in /opt/local, but don't want GIT to
 189# link against any libraries installed there.  If defined you may
 190# specify your own (or DarwinPort's) include directories and
 191# library directories by defining CFLAGS and LDFLAGS appropriately.
 192#
 193# Define NO_MMAP if you want to avoid mmap.
 194#
 195# Define NO_ICONV if your libc does not properly support iconv.
 196AC_ARG_WITH(iconv,
 197AS_HELP_STRING([--without-iconv],
 198[if your architecture doesn't properly support iconv])
 199AS_HELP_STRING([--with-iconv=PATH],
 200[PATH is prefix for libiconv library and headers])
 201AS_HELP_STRING([],
 202[used only if you need linking with libiconv]),
 203GIT_PARSE_WITH(iconv))
 204
 205## --enable-FEATURE[=ARG] and --disable-FEATURE
 206#
 207# Define USE_NSEC below if you want git to care about sub-second file mtimes
 208# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 209# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 210# randomly break unless your underlying filesystem supports those sub-second
 211# times (my ext3 doesn't).
 212#
 213# Define USE_STDEV below if you want git to care about the underlying device
 214# change being considered an inode change from the update-index perspective.
 215
 216#
 217# Define SHELL_PATH to provide path to shell.
 218GIT_ARG_SET_PATH(shell)
 219#
 220# Define PERL_PATH to provide path to Perl.
 221GIT_ARG_SET_PATH(perl)
 222#
 223# Define ZLIB_PATH to provide path to zlib.
 224GIT_ARG_SET_PATH(zlib)
 225#
 226# Declare the with-tcltk/without-tcltk options.
 227AC_ARG_WITH(tcltk,
 228AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 229AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 230AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 231AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 232GIT_PARSE_WITH(tcltk))
 233#
 234
 235
 236## Checks for programs.
 237AC_MSG_NOTICE([CHECKS for programs])
 238#
 239AC_PROG_CC([cc gcc])
 240# which switch to pass runtime path to dynamic libraries to the linker
 241AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 242   SAVE_LDFLAGS="${LDFLAGS}"
 243   LDFLAGS="${SAVE_LDFLAGS} -R /"
 244   AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 245   LDFLAGS="${SAVE_LDFLAGS}"
 246])
 247if test "$git_cv_ld_dashr" = "yes"; then
 248   AC_SUBST(CC_LD_DYNPATH, [-R])
 249else
 250   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 251      SAVE_LDFLAGS="${LDFLAGS}"
 252      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 253      AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 254      LDFLAGS="${SAVE_LDFLAGS}"
 255   ])
 256   if test "$git_cv_ld_wl_rpath" = "yes"; then
 257      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 258   else
 259      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 260         SAVE_LDFLAGS="${LDFLAGS}"
 261         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 262         AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 263         LDFLAGS="${SAVE_LDFLAGS}"
 264      ])
 265      if test "$git_cv_ld_rpath" = "yes"; then
 266         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 267      else
 268         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 269      fi
 270   fi
 271fi
 272#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 273AC_CHECK_TOOLS(AR, [gar ar], :)
 274AC_CHECK_PROGS(TAR, [gtar tar])
 275# TCLTK_PATH will be set to some value if we want Tcl/Tk
 276# or will be empty otherwise.
 277if test -z "$NO_TCLTK"; then
 278  if test "$with_tcltk" = ""; then
 279  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 280    TCLTK_PATH=wish
 281    AC_SUBST(TCLTK_PATH)
 282  elif test "$with_tcltk" = "yes"; then
 283  # Tcl/Tk check requested.
 284    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 285  else
 286    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 287    TCLTK_PATH="$with_tcltk"
 288    AC_SUBST(TCLTK_PATH)
 289  fi
 290fi
 291AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 292if test -n "$ASCIIDOC"; then
 293        AC_MSG_CHECKING([for asciidoc version])
 294        asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 295        case "${asciidoc_version}" in
 296        asciidoc' '8*)
 297                ASCIIDOC8=YesPlease
 298                AC_MSG_RESULT([${asciidoc_version} > 7])
 299                ;;
 300        asciidoc' '7*)
 301                ASCIIDOC8=
 302                AC_MSG_RESULT([${asciidoc_version}])
 303                ;;
 304        *)
 305                ASCIIDOC8=
 306                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 307                ;;
 308        esac
 309fi
 310AC_SUBST(ASCIIDOC8)
 311
 312
 313## Checks for libraries.
 314AC_MSG_NOTICE([CHECKS for libraries])
 315#
 316# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 317# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 318
 319GIT_STASH_FLAGS($OPENSSLDIR)
 320
 321AC_CHECK_LIB([crypto], [SHA1_Init],
 322[NEEDS_SSL_WITH_CRYPTO=],
 323[AC_CHECK_LIB([ssl], [SHA1_Init],
 324 [NEEDS_SSL_WITH_CRYPTO=YesPlease
 325  NEEDS_SSL_WITH_CRYPTO=],
 326 [NO_OPENSSL=YesPlease])])
 327
 328GIT_UNSTASH_FLAGS($OPENSSLDIR)
 329
 330AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 331AC_SUBST(NO_OPENSSL)
 332
 333#
 334# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 335# git-http-push are not built, and you cannot use http:// and https://
 336# transports.
 337
 338GIT_STASH_FLAGS($CURLDIR)
 339
 340AC_CHECK_LIB([curl], [curl_global_init],
 341[NO_CURL=],
 342[NO_CURL=YesPlease])
 343
 344GIT_UNSTASH_FLAGS($CURLDIR)
 345
 346AC_SUBST(NO_CURL)
 347
 348#
 349# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 350# not built, and you cannot push using http:// and https:// transports.
 351
 352GIT_STASH_FLAGS($EXPATDIR)
 353
 354AC_CHECK_LIB([expat], [XML_ParserCreate],
 355[NO_EXPAT=],
 356[NO_EXPAT=YesPlease])
 357
 358GIT_UNSTASH_FLAGS($EXPATDIR)
 359
 360AC_SUBST(NO_EXPAT)
 361
 362#
 363# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 364# some Solaris installations).
 365# Define NO_ICONV if neither libc nor libiconv support iconv.
 366
 367GIT_STASH_FLAGS($ICONVDIR)
 368
 369AC_DEFUN([ICONVTEST_SRC], [
 370#include <iconv.h>
 371
 372int main(void)
 373{
 374        iconv_open("", "");
 375        return 0;
 376}
 377])
 378
 379if test -n "$ICONVDIR"; then
 380   lib_order="-liconv -lc"
 381else
 382   lib_order="-lc -liconv"
 383fi
 384
 385NO_ICONV=YesPlease
 386
 387for l in $lib_order; do
 388    if test "$l" = "-liconv"; then
 389       NEEDS_LIBICONV=YesPlease
 390    else
 391       NEEDS_LIBICONV=
 392    fi
 393
 394    old_LIBS="$LIBS"
 395    LIBS="$LIBS $l"
 396    AC_MSG_CHECKING([for iconv in $l])
 397    AC_LINK_IFELSE(ICONVTEST_SRC,
 398        [AC_MSG_RESULT([yes])
 399        NO_ICONV=
 400        break],
 401        [AC_MSG_RESULT([no])])
 402    LIBS="$old_LIBS"
 403done
 404
 405#in case of break
 406LIBS="$old_LIBS"
 407
 408GIT_UNSTASH_FLAGS($ICONVDIR)
 409
 410AC_SUBST(NEEDS_LIBICONV)
 411AC_SUBST(NO_ICONV)
 412
 413#
 414# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 415
 416GIT_STASH_FLAGS($ZLIB_PATH)
 417
 418AC_DEFUN([ZLIBTEST_SRC], [
 419#include <zlib.h>
 420
 421int main(void)
 422{
 423        deflateBound(0, 0);
 424        return 0;
 425}
 426])
 427AC_MSG_CHECKING([for deflateBound in -lz])
 428old_LIBS="$LIBS"
 429LIBS="$LIBS -lz"
 430AC_LINK_IFELSE(ZLIBTEST_SRC,
 431        [AC_MSG_RESULT([yes])],
 432        [AC_MSG_RESULT([no])
 433        NO_DEFLATE_BOUND=yes])
 434LIBS="$old_LIBS"
 435
 436GIT_UNSTASH_FLAGS($ZLIB_PATH)
 437
 438AC_SUBST(NO_DEFLATE_BOUND)
 439
 440#
 441# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 442# Patrick Mauritz).
 443AC_CHECK_LIB([c], [socket],
 444[NEEDS_SOCKET=],
 445[NEEDS_SOCKET=YesPlease])
 446AC_SUBST(NEEDS_SOCKET)
 447test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 448
 449
 450## Checks for header files.
 451AC_MSG_NOTICE([CHECKS for header files])
 452#
 453# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 454AC_CHECK_HEADER([sys/select.h],
 455[NO_SYS_SELECT_H=],
 456[NO_SYS_SELECT_H=UnfortunatelyYes])
 457AC_SUBST(NO_SYS_SELECT_H)
 458#
 459# Define OLD_ICONV if your library has an old iconv(), where the second
 460# (input buffer pointer) parameter is declared with type (const char **).
 461AC_DEFUN([OLDICONVTEST_SRC], [[
 462#include <iconv.h>
 463
 464extern size_t iconv(iconv_t cd,
 465                    char **inbuf, size_t *inbytesleft,
 466                    char **outbuf, size_t *outbytesleft);
 467
 468int main(void)
 469{
 470        return 0;
 471}
 472]])
 473
 474GIT_STASH_FLAGS($ICONVDIR)
 475
 476AC_MSG_CHECKING([for old iconv()])
 477AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 478        [AC_MSG_RESULT([no])],
 479        [AC_MSG_RESULT([yes])
 480        OLD_ICONV=UnfortunatelyYes])
 481
 482GIT_UNSTASH_FLAGS($ICONVDIR)
 483
 484AC_SUBST(OLD_ICONV)
 485
 486## Checks for typedefs, structures, and compiler characteristics.
 487AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 488#
 489# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 490AC_CHECK_MEMBER(struct dirent.d_ino,
 491[NO_D_INO_IN_DIRENT=],
 492[NO_D_INO_IN_DIRENT=YesPlease],
 493[#include <dirent.h>])
 494AC_SUBST(NO_D_INO_IN_DIRENT)
 495#
 496# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 497# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 498AC_CHECK_MEMBER(struct dirent.d_type,
 499[NO_D_TYPE_IN_DIRENT=],
 500[NO_D_TYPE_IN_DIRENT=YesPlease],
 501[#include <dirent.h>])
 502AC_SUBST(NO_D_TYPE_IN_DIRENT)
 503#
 504# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 505# sockaddr_storage.
 506AC_CHECK_TYPE(struct sockaddr_storage,
 507[NO_SOCKADDR_STORAGE=],
 508[NO_SOCKADDR_STORAGE=YesPlease],[
 509#include <sys/types.h>
 510#include <sys/socket.h>
 511])
 512AC_SUBST(NO_SOCKADDR_STORAGE)
 513#
 514# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 515AC_CHECK_TYPE([struct addrinfo],[
 516 GIT_CHECK_FUNC([getaddrinfo],
 517  [NO_IPV6=],
 518  [NO_IPV6=YesPlease])
 519],[NO_IPV6=YesPlease],[
 520#include <sys/types.h>
 521#include <sys/socket.h>
 522#include <netdb.h>
 523])
 524AC_SUBST(NO_IPV6)
 525#
 526# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 527# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 528# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 529# some C compilers supported these specifiers prior to C99 as an extension.
 530AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 531 [ac_cv_c_c99_format],
 532[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 533AC_RUN_IFELSE(
 534        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 535                [[char buf[64];
 536                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 537                  return 1;
 538                else if (strcmp(buf, "12345"))
 539                  return 2;]])],
 540        [ac_cv_c_c99_format=yes],
 541        [ac_cv_c_c99_format=no])
 542])
 543if test $ac_cv_c_c99_format = no; then
 544        NO_C99_FORMAT=YesPlease
 545else
 546        NO_C99_FORMAT=
 547fi
 548AC_SUBST(NO_C99_FORMAT)
 549#
 550# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 551# when attempting to read from an fopen'ed directory.
 552AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 553 [ac_cv_fread_reads_directories],
 554[
 555AC_RUN_IFELSE(
 556        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 557                [[char c;
 558                FILE *f = fopen(".", "r");
 559                return f && fread(&c, 1, 1, f)]])],
 560        [ac_cv_fread_reads_directories=no],
 561        [ac_cv_fread_reads_directories=yes])
 562])
 563if test $ac_cv_fread_reads_directories = yes; then
 564        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 565else
 566        FREAD_READS_DIRECTORIES=
 567fi
 568AC_SUBST(FREAD_READS_DIRECTORIES)
 569#
 570# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 571# or vsnprintf() return -1 instead of number of characters which would
 572# have been written to the final string if enough space had been available.
 573AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 574 [ac_cv_snprintf_returns_bogus],
 575[
 576AC_RUN_IFELSE(
 577        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 578                #include "stdarg.h"
 579
 580                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 581                {
 582                  int ret;
 583                  va_list ap;
 584                  va_start(ap, format);
 585                  ret = vsnprintf(str, maxsize, format, ap);
 586                  va_end(ap);
 587                  return ret;
 588                }],
 589                [[char buf[6];
 590                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 591                      || strcmp(buf, "12")) return 1;
 592                  if (snprintf(buf, 3, "%s", "12345") != 5
 593                      || strcmp(buf, "12")) return 1]])],
 594        [ac_cv_snprintf_returns_bogus=no],
 595        [ac_cv_snprintf_returns_bogus=yes])
 596])
 597if test $ac_cv_snprintf_returns_bogus = yes; then
 598        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 599else
 600        SNPRINTF_RETURNS_BOGUS=
 601fi
 602AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 603
 604
 605## Checks for library functions.
 606## (in default C library and libraries checked by AC_CHECK_LIB)
 607AC_MSG_NOTICE([CHECKS for library functions])
 608#
 609# Define NO_STRCASESTR if you don't have strcasestr.
 610GIT_CHECK_FUNC(strcasestr,
 611[NO_STRCASESTR=],
 612[NO_STRCASESTR=YesPlease])
 613AC_SUBST(NO_STRCASESTR)
 614#
 615# Define NO_MEMMEM if you don't have memmem.
 616GIT_CHECK_FUNC(memmem,
 617[NO_MEMMEM=],
 618[NO_MEMMEM=YesPlease])
 619AC_SUBST(NO_MEMMEM)
 620#
 621# Define NO_STRLCPY if you don't have strlcpy.
 622GIT_CHECK_FUNC(strlcpy,
 623[NO_STRLCPY=],
 624[NO_STRLCPY=YesPlease])
 625AC_SUBST(NO_STRLCPY)
 626#
 627# Define NO_UINTMAX_T if your platform does not have uintmax_t
 628AC_CHECK_TYPE(uintmax_t,
 629[NO_UINTMAX_T=],
 630[NO_UINTMAX_T=YesPlease],[
 631#include <inttypes.h>
 632])
 633AC_SUBST(NO_UINTMAX_T)
 634#
 635# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 636GIT_CHECK_FUNC(strtoumax,
 637[NO_STRTOUMAX=],
 638[NO_STRTOUMAX=YesPlease])
 639AC_SUBST(NO_STRTOUMAX)
 640#
 641# Define NO_SETENV if you don't have setenv in the C library.
 642GIT_CHECK_FUNC(setenv,
 643[NO_SETENV=],
 644[NO_SETENV=YesPlease])
 645AC_SUBST(NO_SETENV)
 646#
 647# Define NO_UNSETENV if you don't have unsetenv in the C library.
 648GIT_CHECK_FUNC(unsetenv,
 649[NO_UNSETENV=],
 650[NO_UNSETENV=YesPlease])
 651AC_SUBST(NO_UNSETENV)
 652#
 653# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 654GIT_CHECK_FUNC(mkdtemp,
 655[NO_MKDTEMP=],
 656[NO_MKDTEMP=YesPlease])
 657AC_SUBST(NO_MKDTEMP)
 658#
 659# Define NO_MMAP if you want to avoid mmap.
 660#
 661# Define NO_ICONV if your libc does not properly support iconv.
 662
 663
 664## Other checks.
 665# Define USE_PIC if you need the main git objects to be built with -fPIC
 666# in order to build and link perl/Git.so.  x86-64 seems to need this.
 667#
 668# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 669# Enable it on Windows.  By default, symrefs are still used.
 670#
 671# Define NO_PTHREADS if we do not have pthreads
 672#
 673# Define PTHREAD_LIBS to the linker flag used for Pthread support and define
 674# THREADED_DELTA_SEARCH if Pthreads are available.
 675AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 676  [[#include <pthread.h>]],
 677  [[pthread_mutex_t test_mutex;]]
 678)])
 679${CC} -pthread conftest.c -o conftest.o > /dev/null 2>&1
 680if test $? -eq 0;then
 681 PTHREAD_LIBS="-pthread"
 682 THREADED_DELTA_SEARCH=YesPlease
 683else
 684 ${CC} -lpthread conftest.c -o conftest.o > /dev/null 2>&1
 685 if test $? -eq 0;then
 686  PTHREAD_LIBS="-lpthread"
 687  THREADED_DELTA_SEARCH=YesPlease
 688 else
 689  NO_PTHREADS=UnfortunatelyYes
 690 fi
 691fi
 692AC_SUBST(PTHREAD_LIBS)
 693AC_SUBST(NO_PTHREADS)
 694AC_SUBST(THREADED_DELTA_SEARCH)
 695
 696## Output files
 697AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 698AC_OUTPUT
 699
 700
 701## Cleanup
 702rm -f "${config_append}"