Andrew's git - gitweb.git/blob

   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26# Optional second argument allows setting NO_PROGRAM=YesPlease if
  27# --without-PROGRAM version used.
  28AC_DEFUN([GIT_ARG_SET_PATH],
  29[AC_ARG_WITH([$1],
  30 [AS_HELP_STRING([--with-$1=PATH],
  31                 [provide PATH to $1])],
  32 [GIT_CONF_APPEND_PATH($1,$2)],[])
  33])# GIT_ARG_SET_PATH
  34#
  35# GIT_CONF_APPEND_PATH(PROGRAM)
  36# ------------------------------
  37# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  38# Used by GIT_ARG_SET_PATH(PROGRAM)
  39# Optional second argument allows setting NO_PROGRAM=YesPlease if
  40# --without-PROGRAM is used.
  41AC_DEFUN([GIT_CONF_APPEND_PATH],
  42[PROGRAM=m4_toupper($1); \
  43if test "$withval" = "no"; then \
  44        if test -n "$2"; then \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Disabling use of ${PROGRAM}]); \
  47                GIT_CONF_APPEND_LINE(NO_${PROGRAM}=YesPlease); \
  48                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=); \
  49        else \
  50                AC_MSG_ERROR([You cannot use git without $1]); \
  51        fi; \
  52else \
  53        if test "$withval" = "yes"; then \
  54                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  55        else \
  56                m4_toupper($1)_PATH=$withval; \
  57                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  58                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  59        fi; \
  60fi; \
  61]) # GIT_CONF_APPEND_PATH
  62#
  63# GIT_PARSE_WITH(PACKAGE)
  64# -----------------------
  65# For use in AC_ARG_WITH action-if-found, for packages default ON.
  66# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  67# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  68# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  69AC_DEFUN([GIT_PARSE_WITH],
  70[PACKAGE=m4_toupper($1); \
  71if test "$withval" = "no"; then \
  72        m4_toupper(NO_$1)=YesPlease; \
  73elif test "$withval" = "yes"; then \
  74        m4_toupper(NO_$1)=; \
  75else \
  76        m4_toupper(NO_$1)=; \
  77        m4_toupper($1)DIR=$withval; \
  78        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  79        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  80fi \
  81])# GIT_PARSE_WITH
  82#
  83# GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  84# ---------------------
  85# Set VAR to the value specied by --with-WITHNAME.
  86# No verification of arguments is performed, but warnings are issued
  87# if either 'yes' or 'no' is specified.
  88# HELP_TEXT is presented when --help is called.
  89# This is a direct way to allow setting variables in the Makefile.
  90AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  91[AC_ARG_WITH([$1],
  92 [AS_HELP_STRING([--with-$1=VALUE], $3)],
  93 if test -n "$withval"; then \
  94  if test "$withval" = "yes" -o "$withval" = "no"; then \
  95    AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  96                     [a value for $1 ($2).  Maybe you do...?]); \
  97  fi; \
  98  \
  99  AC_MSG_NOTICE([Setting $2 to $withval]); \
 100  GIT_CONF_APPEND_LINE($2=$withval); \
 101 fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 102
 103dnl
 104dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 105dnl -----------------------------------------
 106dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
 107dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
 108dnl -Wall), it does not work.  By looking for function definition in
 109dnl libraries, this problem can be worked around.
 110AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 111  AC_SEARCH_LIBS([$1],,
 112  [$2],[$3])
 113],[$3])])
 114
 115dnl
 116dnl GIT_STASH_FLAGS(BASEPATH_VAR)
 117dnl -----------------------------
 118dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 119dnl tests that may want to take user settings into account.
 120AC_DEFUN([GIT_STASH_FLAGS],[
 121if test -n "$1"; then
 122   old_CPPFLAGS="$CPPFLAGS"
 123   old_LDFLAGS="$LDFLAGS"
 124   CPPFLAGS="-I$1/include $CPPFLAGS"
 125   LDFLAGS="-L$1/$lib $LDFLAGS"
 126fi
 127])
 128
 129dnl
 130dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 131dnl -----------------------------
 132dnl Restore the stashed *FLAGS values.
 133AC_DEFUN([GIT_UNSTASH_FLAGS],[
 134if test -n "$1"; then
 135   CPPFLAGS="$old_CPPFLAGS"
 136   LDFLAGS="$old_LDFLAGS"
 137fi
 138])
 139
 140## Site configuration related to programs (before tests)
 141## --with-PACKAGE[=ARG] and --without-PACKAGE
 142#
 143# Set lib to alternative name of lib directory (e.g. lib64)
 144AC_ARG_WITH([lib],
 145 [AS_HELP_STRING([--with-lib=ARG],
 146                 [ARG specifies alternative name for lib directory])],
 147 [if test "$withval" = "no" || test "$withval" = "yes"; then \
 148        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 149else \
 150        lib=$withval; \
 151        AC_MSG_NOTICE([Setting lib to '$lib']); \
 152        GIT_CONF_APPEND_LINE(lib=$withval); \
 153fi; \
 154],[])
 155
 156if test -z "$lib"; then
 157   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 158   lib=lib
 159fi
 160
 161AC_ARG_ENABLE([pthreads],
 162 [AS_HELP_STRING([--enable-pthreads=FLAGS],
 163  [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 164  [The default if FLAGS is not specified is to try first -pthread]
 165  [and then -lpthread.]
 166  [--without-pthreads will disable threading.])],
 167[
 168if test "x$enableval" = "xyes"; then
 169   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 170elif test "x$enableval" != "xno"; then
 171   PTHREAD_CFLAGS=$enableval
 172   AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 173else
 174   AC_MSG_NOTICE([POSIX Threads will be disabled.])
 175   NO_PTHREADS=YesPlease
 176   USER_NOPTHREAD=1
 177fi],
 178[
 179   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 180])
 181
 182# Define option to enable JavaScript minification
 183AC_ARG_ENABLE([jsmin],
 184[AS_HELP_STRING([--enable-jsmin=PATH],
 185  [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 186[
 187  JSMIN=$enableval;
 188  AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 189  GIT_CONF_APPEND_LINE(JSMIN=$enableval);
 190])
 191
 192# Define option to enable CSS minification
 193AC_ARG_ENABLE([cssmin],
 194[AS_HELP_STRING([--enable-cssmin=PATH],
 195  [PATH is the name of a CSS minifier or the absolute path to one.])],
 196[
 197  CSSMIN=$enableval;
 198  AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 199  GIT_CONF_APPEND_LINE(CSSMIN=$enableval);
 200])
 201
 202## Site configuration (override autodetection)
 203## --with-PACKAGE[=ARG] and --without-PACKAGE
 204AC_MSG_NOTICE([CHECKS for site configuration])
 205#
 206# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 207# tests.  These tests take up a significant amount of the total test time
 208# but are not needed unless you plan to talk to SVN repos.
 209#
 210# Define PPC_SHA1 environment variable when running make to make use of
 211# a bundled SHA1 routine optimized for PowerPC.
 212#
 213# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 214# This also implies BLK_SHA1.
 215#
 216# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 217# /foo/bar/include and /foo/bar/lib directories.
 218AC_ARG_WITH(openssl,
 219AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 220AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 221GIT_PARSE_WITH(openssl))
 222#
 223# Define NO_CURL if you do not have curl installed.  git-http-pull and
 224# git-http-push are not built, and you cannot use http:// and https://
 225# transports.
 226#
 227# Define CURLDIR=/foo/bar if your curl header and library files are in
 228# /foo/bar/include and /foo/bar/lib directories.
 229AC_ARG_WITH(curl,
 230AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 231AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 232GIT_PARSE_WITH(curl))
 233#
 234# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 235# not built, and you cannot push using http:// and https:// transports.
 236#
 237# Define EXPATDIR=/foo/bar if your expat header and library files are in
 238# /foo/bar/include and /foo/bar/lib directories.
 239AC_ARG_WITH(expat,
 240AS_HELP_STRING([--with-expat],
 241[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 242AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 243GIT_PARSE_WITH(expat))
 244#
 245# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 246# installed in /sw, but don't want GIT to link against any libraries
 247# installed there.  If defined you may specify your own (or Fink's)
 248# include directories and library directories by defining CFLAGS
 249# and LDFLAGS appropriately.
 250#
 251# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 252# have DarwinPorts installed in /opt/local, but don't want GIT to
 253# link against any libraries installed there.  If defined you may
 254# specify your own (or DarwinPort's) include directories and
 255# library directories by defining CFLAGS and LDFLAGS appropriately.
 256#
 257# Define NO_MMAP if you want to avoid mmap.
 258#
 259# Define NO_ICONV if your libc does not properly support iconv.
 260AC_ARG_WITH(iconv,
 261AS_HELP_STRING([--without-iconv],
 262[if your architecture doesn't properly support iconv])
 263AS_HELP_STRING([--with-iconv=PATH],
 264[PATH is prefix for libiconv library and headers])
 265AS_HELP_STRING([],
 266[used only if you need linking with libiconv]),
 267GIT_PARSE_WITH(iconv))
 268
 269## --enable-FEATURE[=ARG] and --disable-FEATURE
 270#
 271# Define USE_NSEC below if you want git to care about sub-second file mtimes
 272# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 273# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 274# randomly break unless your underlying filesystem supports those sub-second
 275# times (my ext3 doesn't).
 276#
 277# Define USE_STDEV below if you want git to care about the underlying device
 278# change being considered an inode change from the update-index perspective.
 279
 280#
 281# Allow user to set ETC_GITCONFIG variable
 282GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 283                        Use VALUE instead of /etc/gitconfig as the
 284                        global git configuration file.
 285                        If VALUE is not fully qualified it will be interpretted
 286                        as a path relative to the computed prefix at runtime.)
 287
 288#
 289# Allow user to set the default pager
 290GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 291                        Use VALUE as the fall-back pager instead of 'less'.
 292                        This is used by things like 'git log' when the user
 293                        does not specify a pager to use through alternate
 294                        methods. eg: /usr/bin/pager)
 295#
 296# Allow user to set the default editor
 297GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 298                        Use VALUE as the fall-back editor instead of 'vi'.
 299                        This is used by things like 'git commit' when the user
 300                        does not specify a preferred editor through other
 301                        methods. eg: /usr/bin/editor)
 302
 303#
 304# Define SHELL_PATH to provide path to shell.
 305GIT_ARG_SET_PATH(shell)
 306#
 307# Define PERL_PATH to provide path to Perl.
 308GIT_ARG_SET_PATH(perl)
 309#
 310# Define PYTHON_PATH to provide path to Python.
 311GIT_ARG_SET_PATH(python, allow-without)
 312#
 313# Define ZLIB_PATH to provide path to zlib.
 314GIT_ARG_SET_PATH(zlib)
 315#
 316# Declare the with-tcltk/without-tcltk options.
 317AC_ARG_WITH(tcltk,
 318AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 319AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 320AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 321AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 322GIT_PARSE_WITH(tcltk))
 323#
 324
 325
 326## Checks for programs.
 327AC_MSG_NOTICE([CHECKS for programs])
 328#
 329AC_PROG_CC([cc gcc])
 330# which switch to pass runtime path to dynamic libraries to the linker
 331AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 332   SAVE_LDFLAGS="${LDFLAGS}"
 333   LDFLAGS="${SAVE_LDFLAGS} -R /"
 334   AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 335   LDFLAGS="${SAVE_LDFLAGS}"
 336])
 337if test "$git_cv_ld_dashr" = "yes"; then
 338   AC_SUBST(CC_LD_DYNPATH, [-R])
 339else
 340   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 341      SAVE_LDFLAGS="${LDFLAGS}"
 342      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 343      AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 344      LDFLAGS="${SAVE_LDFLAGS}"
 345   ])
 346   if test "$git_cv_ld_wl_rpath" = "yes"; then
 347      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 348   else
 349      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 350         SAVE_LDFLAGS="${LDFLAGS}"
 351         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 352         AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 353         LDFLAGS="${SAVE_LDFLAGS}"
 354      ])
 355      if test "$git_cv_ld_rpath" = "yes"; then
 356         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 357      else
 358         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 359      fi
 360   fi
 361fi
 362#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 363AC_CHECK_TOOLS(AR, [gar ar], :)
 364AC_CHECK_PROGS(TAR, [gtar tar])
 365# TCLTK_PATH will be set to some value if we want Tcl/Tk
 366# or will be empty otherwise.
 367if test -z "$NO_TCLTK"; then
 368  if test "$with_tcltk" = ""; then
 369  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 370    TCLTK_PATH=wish
 371    AC_SUBST(TCLTK_PATH)
 372  elif test "$with_tcltk" = "yes"; then
 373  # Tcl/Tk check requested.
 374    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 375  else
 376    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 377    TCLTK_PATH="$with_tcltk"
 378    AC_SUBST(TCLTK_PATH)
 379  fi
 380fi
 381AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 382if test -n "$ASCIIDOC"; then
 383        AC_MSG_CHECKING([for asciidoc version])
 384        asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 385        case "${asciidoc_version}" in
 386        asciidoc' '8*)
 387                ASCIIDOC8=YesPlease
 388                AC_MSG_RESULT([${asciidoc_version} > 7])
 389                ;;
 390        asciidoc' '7*)
 391                ASCIIDOC8=
 392                AC_MSG_RESULT([${asciidoc_version}])
 393                ;;
 394        *)
 395                ASCIIDOC8=
 396                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 397                ;;
 398        esac
 399fi
 400AC_SUBST(ASCIIDOC8)
 401
 402
 403## Checks for libraries.
 404AC_MSG_NOTICE([CHECKS for libraries])
 405#
 406# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 407# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 408
 409GIT_STASH_FLAGS($OPENSSLDIR)
 410
 411AC_CHECK_LIB([crypto], [SHA1_Init],
 412[NEEDS_SSL_WITH_CRYPTO=],
 413[AC_CHECK_LIB([ssl], [SHA1_Init],
 414 [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 415 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 416
 417GIT_UNSTASH_FLAGS($OPENSSLDIR)
 418
 419AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 420AC_SUBST(NO_OPENSSL)
 421
 422#
 423# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 424# git-http-push are not built, and you cannot use http:// and https://
 425# transports.
 426
 427GIT_STASH_FLAGS($CURLDIR)
 428
 429AC_CHECK_LIB([curl], [curl_global_init],
 430[NO_CURL=],
 431[NO_CURL=YesPlease])
 432
 433GIT_UNSTASH_FLAGS($CURLDIR)
 434
 435AC_SUBST(NO_CURL)
 436
 437#
 438# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 439# not built, and you cannot push using http:// and https:// transports.
 440
 441GIT_STASH_FLAGS($EXPATDIR)
 442
 443AC_CHECK_LIB([expat], [XML_ParserCreate],
 444[NO_EXPAT=],
 445[NO_EXPAT=YesPlease])
 446
 447GIT_UNSTASH_FLAGS($EXPATDIR)
 448
 449AC_SUBST(NO_EXPAT)
 450
 451#
 452# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 453# some Solaris installations).
 454# Define NO_ICONV if neither libc nor libiconv support iconv.
 455
 456if test -z "$NO_ICONV"; then
 457
 458GIT_STASH_FLAGS($ICONVDIR)
 459
 460AC_DEFUN([ICONVTEST_SRC], [
 461#include <iconv.h>
 462
 463int main(void)
 464{
 465        iconv_open("", "");
 466        return 0;
 467}
 468])
 469
 470if test -n "$ICONVDIR"; then
 471   lib_order="-liconv -lc"
 472else
 473   lib_order="-lc -liconv"
 474fi
 475
 476NO_ICONV=YesPlease
 477
 478for l in $lib_order; do
 479    if test "$l" = "-liconv"; then
 480       NEEDS_LIBICONV=YesPlease
 481    else
 482       NEEDS_LIBICONV=
 483    fi
 484
 485    old_LIBS="$LIBS"
 486    LIBS="$LIBS $l"
 487    AC_MSG_CHECKING([for iconv in $l])
 488    AC_LINK_IFELSE(ICONVTEST_SRC,
 489        [AC_MSG_RESULT([yes])
 490        NO_ICONV=
 491        break],
 492        [AC_MSG_RESULT([no])])
 493    LIBS="$old_LIBS"
 494done
 495
 496#in case of break
 497LIBS="$old_LIBS"
 498
 499GIT_UNSTASH_FLAGS($ICONVDIR)
 500
 501AC_SUBST(NEEDS_LIBICONV)
 502AC_SUBST(NO_ICONV)
 503
 504if test -n "$NO_ICONV"; then
 505    NEEDS_LIBICONV=
 506fi
 507
 508fi
 509
 510#
 511# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 512
 513GIT_STASH_FLAGS($ZLIB_PATH)
 514
 515AC_DEFUN([ZLIBTEST_SRC], [
 516#include <zlib.h>
 517
 518int main(void)
 519{
 520        deflateBound(0, 0);
 521        return 0;
 522}
 523])
 524AC_MSG_CHECKING([for deflateBound in -lz])
 525old_LIBS="$LIBS"
 526LIBS="$LIBS -lz"
 527AC_LINK_IFELSE(ZLIBTEST_SRC,
 528        [AC_MSG_RESULT([yes])],
 529        [AC_MSG_RESULT([no])
 530        NO_DEFLATE_BOUND=yes])
 531LIBS="$old_LIBS"
 532
 533GIT_UNSTASH_FLAGS($ZLIB_PATH)
 534
 535AC_SUBST(NO_DEFLATE_BOUND)
 536
 537#
 538# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 539# Patrick Mauritz).
 540AC_CHECK_LIB([c], [socket],
 541[NEEDS_SOCKET=],
 542[NEEDS_SOCKET=YesPlease])
 543AC_SUBST(NEEDS_SOCKET)
 544test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 545
 546#
 547# Define NEEDS_RESOLV if linking with -lnsl and/or -lsocket is not enough.
 548# Notably on Solaris hstrerror resides in libresolv and on Solaris 7
 549# inet_ntop and inet_pton additionally reside there.
 550AC_CHECK_LIB([c], [hstrerror],
 551[NEEDS_RESOLV=],
 552[NEEDS_RESOLV=YesPlease])
 553AC_SUBST(NEEDS_RESOLV)
 554test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 555
 556AC_CHECK_LIB([c], [basename],
 557[NEEDS_LIBGEN=],
 558[NEEDS_LIBGEN=YesPlease])
 559AC_SUBST(NEEDS_LIBGEN)
 560test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 561
 562## Checks for header files.
 563AC_MSG_NOTICE([CHECKS for header files])
 564#
 565# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 566AC_CHECK_HEADER([sys/select.h],
 567[NO_SYS_SELECT_H=],
 568[NO_SYS_SELECT_H=UnfortunatelyYes])
 569AC_SUBST(NO_SYS_SELECT_H)
 570#
 571# Define OLD_ICONV if your library has an old iconv(), where the second
 572# (input buffer pointer) parameter is declared with type (const char **).
 573AC_DEFUN([OLDICONVTEST_SRC], [[
 574#include <iconv.h>
 575
 576extern size_t iconv(iconv_t cd,
 577                    char **inbuf, size_t *inbytesleft,
 578                    char **outbuf, size_t *outbytesleft);
 579
 580int main(void)
 581{
 582        return 0;
 583}
 584]])
 585
 586GIT_STASH_FLAGS($ICONVDIR)
 587
 588AC_MSG_CHECKING([for old iconv()])
 589AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 590        [AC_MSG_RESULT([no])],
 591        [AC_MSG_RESULT([yes])
 592        OLD_ICONV=UnfortunatelyYes])
 593
 594GIT_UNSTASH_FLAGS($ICONVDIR)
 595
 596AC_SUBST(OLD_ICONV)
 597
 598## Checks for typedefs, structures, and compiler characteristics.
 599AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 600#
 601# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 602AC_CHECK_MEMBER(struct dirent.d_ino,
 603[NO_D_INO_IN_DIRENT=],
 604[NO_D_INO_IN_DIRENT=YesPlease],
 605[#include <dirent.h>])
 606AC_SUBST(NO_D_INO_IN_DIRENT)
 607#
 608# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 609# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 610AC_CHECK_MEMBER(struct dirent.d_type,
 611[NO_D_TYPE_IN_DIRENT=],
 612[NO_D_TYPE_IN_DIRENT=YesPlease],
 613[#include <dirent.h>])
 614AC_SUBST(NO_D_TYPE_IN_DIRENT)
 615#
 616# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 617# sockaddr_storage.
 618AC_CHECK_TYPE(struct sockaddr_storage,
 619[NO_SOCKADDR_STORAGE=],
 620[NO_SOCKADDR_STORAGE=YesPlease],[
 621#include <sys/types.h>
 622#include <sys/socket.h>
 623])
 624AC_SUBST(NO_SOCKADDR_STORAGE)
 625#
 626# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 627AC_CHECK_TYPE([struct addrinfo],[
 628 GIT_CHECK_FUNC([getaddrinfo],
 629  [NO_IPV6=],
 630  [NO_IPV6=YesPlease])
 631],[NO_IPV6=YesPlease],[
 632#include <sys/types.h>
 633#include <sys/socket.h>
 634#include <netdb.h>
 635])
 636AC_SUBST(NO_IPV6)
 637#
 638# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 639# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 640# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 641# some C compilers supported these specifiers prior to C99 as an extension.
 642AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 643 [ac_cv_c_c99_format],
 644[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 645AC_RUN_IFELSE(
 646        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 647                [[char buf[64];
 648                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 649                  return 1;
 650                else if (strcmp(buf, "12345"))
 651                  return 2;]])],
 652        [ac_cv_c_c99_format=yes],
 653        [ac_cv_c_c99_format=no])
 654])
 655if test $ac_cv_c_c99_format = no; then
 656        NO_C99_FORMAT=YesPlease
 657else
 658        NO_C99_FORMAT=
 659fi
 660AC_SUBST(NO_C99_FORMAT)
 661#
 662# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 663# when attempting to read from an fopen'ed directory.
 664AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 665 [ac_cv_fread_reads_directories],
 666[
 667AC_RUN_IFELSE(
 668        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 669                [[char c;
 670                FILE *f = fopen(".", "r");
 671                return f && fread(&c, 1, 1, f)]])],
 672        [ac_cv_fread_reads_directories=no],
 673        [ac_cv_fread_reads_directories=yes])
 674])
 675if test $ac_cv_fread_reads_directories = yes; then
 676        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 677else
 678        FREAD_READS_DIRECTORIES=
 679fi
 680AC_SUBST(FREAD_READS_DIRECTORIES)
 681#
 682# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 683# or vsnprintf() return -1 instead of number of characters which would
 684# have been written to the final string if enough space had been available.
 685AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 686 [ac_cv_snprintf_returns_bogus],
 687[
 688AC_RUN_IFELSE(
 689        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 690                #include "stdarg.h"
 691
 692                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 693                {
 694                  int ret;
 695                  va_list ap;
 696                  va_start(ap, format);
 697                  ret = vsnprintf(str, maxsize, format, ap);
 698                  va_end(ap);
 699                  return ret;
 700                }],
 701                [[char buf[6];
 702                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 703                      || strcmp(buf, "12")) return 1;
 704                  if (snprintf(buf, 3, "%s", "12345") != 5
 705                      || strcmp(buf, "12")) return 1]])],
 706        [ac_cv_snprintf_returns_bogus=no],
 707        [ac_cv_snprintf_returns_bogus=yes])
 708])
 709if test $ac_cv_snprintf_returns_bogus = yes; then
 710        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 711else
 712        SNPRINTF_RETURNS_BOGUS=
 713fi
 714AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 715
 716
 717## Checks for library functions.
 718## (in default C library and libraries checked by AC_CHECK_LIB)
 719AC_MSG_NOTICE([CHECKS for library functions])
 720#
 721# Define NO_LIBGEN_H if you don't have libgen.h.
 722AC_CHECK_HEADER([libgen.h],
 723[NO_LIBGEN_H=],
 724[NO_LIBGEN_H=YesPlease])
 725AC_SUBST(NO_LIBGEN_H)
 726#
 727# Define HAVE_PATHS_H if you have paths.h.
 728AC_CHECK_HEADER([paths.h],
 729[HAVE_PATHS_H=YesPlease],
 730[HAVE_PATHS_H=])
 731AC_SUBST(HAVE_PATHS_H)
 732#
 733# Define NO_STRCASESTR if you don't have strcasestr.
 734GIT_CHECK_FUNC(strcasestr,
 735[NO_STRCASESTR=],
 736[NO_STRCASESTR=YesPlease])
 737AC_SUBST(NO_STRCASESTR)
 738#
 739# Define NO_MEMMEM if you don't have memmem.
 740GIT_CHECK_FUNC(memmem,
 741[NO_MEMMEM=],
 742[NO_MEMMEM=YesPlease])
 743AC_SUBST(NO_MEMMEM)
 744#
 745# Define NO_STRLCPY if you don't have strlcpy.
 746GIT_CHECK_FUNC(strlcpy,
 747[NO_STRLCPY=],
 748[NO_STRLCPY=YesPlease])
 749AC_SUBST(NO_STRLCPY)
 750#
 751# Define NO_UINTMAX_T if your platform does not have uintmax_t
 752AC_CHECK_TYPE(uintmax_t,
 753[NO_UINTMAX_T=],
 754[NO_UINTMAX_T=YesPlease],[
 755#include <inttypes.h>
 756])
 757AC_SUBST(NO_UINTMAX_T)
 758#
 759# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 760GIT_CHECK_FUNC(strtoumax,
 761[NO_STRTOUMAX=],
 762[NO_STRTOUMAX=YesPlease])
 763AC_SUBST(NO_STRTOUMAX)
 764#
 765# Define NO_SETENV if you don't have setenv in the C library.
 766GIT_CHECK_FUNC(setenv,
 767[NO_SETENV=],
 768[NO_SETENV=YesPlease])
 769AC_SUBST(NO_SETENV)
 770#
 771# Define NO_UNSETENV if you don't have unsetenv in the C library.
 772GIT_CHECK_FUNC(unsetenv,
 773[NO_UNSETENV=],
 774[NO_UNSETENV=YesPlease])
 775AC_SUBST(NO_UNSETENV)
 776#
 777# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 778GIT_CHECK_FUNC(mkdtemp,
 779[NO_MKDTEMP=],
 780[NO_MKDTEMP=YesPlease])
 781AC_SUBST(NO_MKDTEMP)
 782#
 783# Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 784GIT_CHECK_FUNC(mkstemps,
 785[NO_MKSTEMPS=],
 786[NO_MKSTEMPS=YesPlease])
 787AC_SUBST(NO_MKSTEMPS)
 788#
 789#
 790# Define NO_MMAP if you want to avoid mmap.
 791#
 792# Define NO_ICONV if your libc does not properly support iconv.
 793
 794
 795## Other checks.
 796# Define USE_PIC if you need the main git objects to be built with -fPIC
 797# in order to build and link perl/Git.so.  x86-64 seems to need this.
 798#
 799# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 800# Enable it on Windows.  By default, symrefs are still used.
 801#
 802# Define NO_PTHREADS if we do not have pthreads.
 803#
 804# Define PTHREAD_LIBS to the linker flag used for Pthread support.
 805AC_DEFUN([PTHREADTEST_SRC], [
 806#include <pthread.h>
 807
 808int main(void)
 809{
 810        pthread_mutex_t test_mutex;
 811        return (0);
 812}
 813])
 814
 815dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 816dnl   [[#include <pthread.h>]],
 817dnl   [[pthread_mutex_t test_mutex;]]
 818dnl )])
 819
 820NO_PTHREADS=UnfortunatelyYes
 821PTHREAD_LIBS=
 822
 823if test -n "$USER_NOPTHREAD"; then
 824   AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 825# handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 826# -D_REENTRANT' or some such.
 827elif test -z "$PTHREAD_CFLAGS"; then
 828  for opt in -pthread -lpthread; do
 829     old_CFLAGS="$CFLAGS"
 830     CFLAGS="$opt $CFLAGS"
 831     AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 832     AC_LINK_IFELSE(PTHREADTEST_SRC,
 833        [AC_MSG_RESULT([yes])
 834                NO_PTHREADS=
 835                PTHREAD_LIBS="$opt"
 836                break
 837        ],
 838        [AC_MSG_RESULT([no])])
 839      CFLAGS="$old_CFLAGS"
 840  done
 841else
 842  old_CFLAGS="$CFLAGS"
 843  CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 844  AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 845  AC_LINK_IFELSE(PTHREADTEST_SRC,
 846        [AC_MSG_RESULT([yes])
 847                NO_PTHREADS=
 848                PTHREAD_LIBS="$PTHREAD_CFLAGS"
 849        ],
 850        [AC_MSG_RESULT([no])])
 851
 852  CFLAGS="$old_CFLAGS"
 853fi
 854
 855CFLAGS="$old_CFLAGS"
 856
 857AC_SUBST(PTHREAD_LIBS)
 858AC_SUBST(NO_PTHREADS)
 859
 860## Output files
 861AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 862AC_OUTPUT
 863
 864
 865## Cleanup
 866rm -f "${config_append}"