Andrew's git - gitweb.git/blob

   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_ERROR([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46        fi; \
  47fi; \
  48]) # GIT_CONF_APPEND_PATH
  49
  50
  51## Site configuration
  52## --with-PACKAGE[=ARG] and --without-PACKAGE
  53#
  54# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
  55# tests.  These tests take up a significant amount of the total test time
  56# but are not needed unless you plan to talk to SVN repos.
  57#
  58# Define MOZILLA_SHA1 environment variable when running make to make use of
  59# a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
  60# on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
  61# choice) has very fast version optimized for i586.
  62#
  63# Define PPC_SHA1 environment variable when running make to make use of
  64# a bundled SHA1 routine optimized for PowerPC.
  65#
  66# Define ARM_SHA1 environment variable when running make to make use of
  67# a bundled SHA1 routine optimized for ARM.
  68#
  69# Define NO_OPENSSL environment variable if you do not have OpenSSL.
  70# This also implies MOZILLA_SHA1.
  71#
  72# Define NO_CURL if you do not have curl installed.  git-http-pull and
  73# git-http-push are not built, and you cannot use http:// and https://
  74# transports.
  75#
  76# Define CURLDIR=/foo/bar if your curl header and library files are in
  77# /foo/bar/include and /foo/bar/lib directories.
  78#
  79# Define NO_EXPAT if you do not have expat installed.  git-http-push is
  80# not built, and you cannot push using http:// and https:// transports.
  81#
  82# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
  83# installed in /sw, but don't want GIT to link against any libraries
  84# installed there.  If defined you may specify your own (or Fink's)
  85# include directories and library directories by defining CFLAGS
  86# and LDFLAGS appropriately.
  87#
  88# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
  89# have DarwinPorts installed in /opt/local, but don't want GIT to
  90# link against any libraries installed there.  If defined you may
  91# specify your own (or DarwinPort's) include directories and
  92# library directories by defining CFLAGS and LDFLAGS appropriately.
  93#
  94# Define NO_MMAP if you want to avoid mmap.
  95#
  96# Define SHELL_PATH to provide path to shell.
  97GIT_ARG_SET_PATH(shell)
  98#
  99# Define PERL_PATH to provide path to Perl.
 100GIT_ARG_SET_PATH(perl)
 101#
 102# Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 103# Define PYTHON_PATH to provide path to Python.
 104AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
 105AS_HELP_STRING([--no-python], [don't use python scripts])],
 106 [if test "$withval" = "no"; then \
 107    NO_PYTHON=YesPlease; \
 108  elif test "$withval" = "yes"; then \
 109    NO_PYTHON=; \
 110  else \
 111    NO_PYTHON=; \
 112    PYTHON_PATH=$withval; \
 113  fi; \
 114 ])
 115AC_SUBST(NO_PYTHON)
 116AC_SUBST(PYTHON_PATH)
 117#
 118## --enable-FEATURE[=ARG] and --disable-FEATURE
 119# Define COLLISION_CHECK below if you believe that SHA1's
 120# 1461501637330902918203684832716283019655932542976 hashes do not give you
 121# sufficient guarantee that no collisions between objects will ever happen.
 122#
 123# Define USE_NSEC below if you want git to care about sub-second file mtimes
 124# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 125# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 126# randomly break unless your underlying filesystem supports those sub-second
 127# times (my ext3 doesn't).
 128#
 129# Define USE_STDEV below if you want git to care about the underlying device
 130# change being considered an inode change from the update-cache perspective.
 131
 132
 133## Checks for programs.
 134AC_MSG_NOTICE([CHECKS for programs])
 135#
 136AC_PROG_CC
 137#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 138AC_CHECK_TOOL(AR, ar, :)
 139AC_CHECK_PROGS(TAR, [gtar tar])
 140#
 141# Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 142# Define PYTHON_PATH to provide path to Python.
 143if test -z "$NO_PYTHON"; then
 144        if test -z "$PYTHON_PATH"; then
 145                AC_PATH_PROGS(PYTHON_PATH, [python python2.4 python2.3 python2])
 146        fi
 147        if test -n "$PYTHON_PATH"; then
 148                GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
 149                NO_PYTHON=""
 150        fi
 151fi
 152GIT_CONF_APPEND_LINE([NO_PYTHON=@NO_PYTHON@])
 153
 154
 155## Checks for libraries.
 156AC_MSG_NOTICE([CHECKS for libraries])
 157#
 158# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 159# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 160AC_CHECK_LIB([crypto], [SHA1_Init],
 161[GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=)],
 162[AC_CHECK_LIB([ssl], [SHA1_Init],
 163 [GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=YesPlease)
 164  GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=)],
 165 [GIT_CONF_APPEND_LINE(NO_OPENSSL=YesPlease)])])
 166#
 167# Define NO_CURL if you do not have curl installed.  git-http-pull and
 168# git-http-push are not built, and you cannot use http:// and https://
 169# transports.
 170AC_CHECK_LIB([curl], [curl_global_init],
 171[GIT_CONF_APPEND_LINE(NO_CURL=)],
 172[GIT_CONF_APPEND_LINE(NO_CURL=YesPlease)])
 173#
 174# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 175# not built, and you cannot push using http:// and https:// transports.
 176AC_CHECK_LIB([expat], [XML_ParserCreate],
 177[GIT_CONF_APPEND_LINE(NO_EXPAT=)],
 178[GIT_CONF_APPEND_LINE(NO_EXPAT=YesPlease)])
 179#
 180# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 181AC_CHECK_LIB([c], [iconv],
 182[GIT_CONF_APPEND_LINE(NEEDS_LIBICONV=)],
 183[GIT_CONF_APPEND_LINE(NEEDS_LIBICONV=YesPlease)])
 184#
 185# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 186# Patrick Mauritz).
 187AC_CHECK_LIB([c], [socket],
 188[GIT_CONF_APPEND_LINE(NEEDS_SOCKET=)],
 189[GIT_CONF_APPEND_LINE(NEEDS_SOCKET=YesPlease)])
 190
 191
 192## Checks for header files.
 193
 194
 195## Checks for typedefs, structures, and compiler characteristics.
 196AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 197#
 198# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 199AC_CHECK_MEMBER(struct dirent.d_ino,
 200[GIT_CONF_APPEND_LINE(NO_D_INO_IN_DIRENT=)],
 201[GIT_CONF_APPEND_LINE(NO_D_INO_IN_DIRENT=YesPlease)],
 202[#include <dirent.h>])
 203#
 204# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 205# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 206AC_CHECK_MEMBER(struct dirent.d_type,
 207[GIT_CONF_APPEND_LINE(NO_D_TYPE_IN_DIRENT=)],
 208[GIT_CONF_APPEND_LINE(NO_D_TYPE_IN_DIRENT=YesPlease)],
 209[#include <dirent.h>])
 210#
 211# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 212# sockaddr_storage.
 213AC_CHECK_TYPE(struct sockaddr_storage,
 214[GIT_CONF_APPEND_LINE(NO_SOCKADDR_STORAGE=)],
 215[GIT_CONF_APPEND_LINE(NO_SOCKADDR_STORAGE=YesPlease)],
 216[#include <netinet/in.h>])
 217# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 218AC_CHECK_TYPE([struct addrinfo],[
 219 AC_CHECK_FUNC([getaddrinfo],
 220  [GIT_CONF_APPEND_LINE(NO_IPV6=)],
 221  [GIT_CONF_APPEND_LINE(NO_IPV6=YesPlease)])
 222],[GIT_CONF_APPEND_LINE(NO_IPV6=YesPlease)],[
 223#include <sys/types.h>
 224#include <sys/socket.h>
 225#include <netdb.h>
 226])
 227#
 228# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 229# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 230# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 231# some C compilers supported these specifiers prior to C99 as an extension.
 232AC_CACHE_CHECK(whether formatted IO functions support C99 size specifiers,
 233 ac_cv_c_c99_format,
 234[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 235AC_RUN_IFELSE(
 236        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 237                [[char buf[64];
 238                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 239                  exit(1);
 240                else if (strcmp(buf, "12345"))
 241                  exit(2);]])],
 242        [ac_cv_c_c99_format=yes],
 243        [ac_cv_c_c99_format=no])
 244])
 245if test $ac_cv_c_c99_format = no; then
 246        GIT_CONF_APPEND_LINE(NO_C99_FORMAT=YesPlease)
 247else
 248        GIT_CONF_APPEND_LINE(NO_C99_FORMAT=)
 249fi
 250
 251
 252## Checks for library functions.
 253## (in default C library and libraries checked by AC_CHECK_LIB)
 254AC_MSG_NOTICE([CHECKS for library functions])
 255#
 256# Define NO_STRCASESTR if you don't have strcasestr.
 257AC_CHECK_FUNC(strcasestr,
 258[GIT_CONF_APPEND_LINE(NO_STRCASESTR=)],
 259[GIT_CONF_APPEND_LINE(NO_STRCASESTR=YesPlease)])
 260#
 261# Define NO_STRLCPY if you don't have strlcpy.
 262AC_CHECK_FUNC(strlcpy,
 263[GIT_CONF_APPEND_LINE(NO_STRLCPY=)],
 264[GIT_CONF_APPEND_LINE(NO_STRLCPY=YesPlease)])
 265#
 266# Define NO_SETENV if you don't have setenv in the C library.
 267AC_CHECK_FUNC(setenv,
 268[GIT_CONF_APPEND_LINE(NO_SETENV=)],
 269[GIT_CONF_APPEND_LINE(NO_SETENV=YesPlease)])
 270#
 271# Define NO_MMAP if you want to avoid mmap.
 272#
 273# Define NO_ICONV if your libc does not properly support iconv.
 274
 275
 276## Other checks.
 277# Define USE_PIC if you need the main git objects to be built with -fPIC
 278# in order to build and link perl/Git.so.  x86-64 seems to need this.
 279#
 280# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 281# Enable it on Windows.  By default, symrefs are still used.
 282#
 283# Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 284#
 285# Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 286# a missing newline at the end of the file.
 287
 288
 289## Output files
 290AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 291AC_OUTPUT
 292
 293
 294## Cleanup
 295rm -f "${config_append}"