1#!/usr/bin/perl
2# Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3# License: GPL v2 or later
4use 5.008;
5use warnings;
6use strict;
7use vars qw/ $AUTHOR $VERSION
8 $sha1 $sha1_short $_revision $_repository
9 $_q $_authors $_authors_prog %users/;
10$AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
11$VERSION = '@@GIT_VERSION@@';
12use Carp qw/croak/;
14use File::Basename qw/dirname basename/;
15use File::Path qw/mkpath/;
16use File::Spec;
17use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
18use Memoize;
19use Git::SVN;
21use Git::SVN::Editor;
22use Git::SVN::Fetcher;
23use Git::SVN::Ra;
24use Git::SVN::Prompt;
25use Git::SVN::Log;
26use Git::SVN::Migration;
27use Git::SVN::Utils qw(
29 fatal
30 can_compress
31 canonicalize_path
32 canonicalize_url
33 join_paths
34 add_path_to_url
35 join_paths
36);
37use Git qw(
39 git_cmd_try
40 command
41 command_oneline
42 command_noisy
43 command_output_pipe
44 command_close_pipe
45 command_bidi_pipe
46 command_close_bidi_pipe
47 get_record
48);
49BEGIN {
51 Memoize::memoize 'Git::config';
52 Memoize::memoize 'Git::config_bool';
53}
54# From which subdir have we been invoked?
57my $cmd_dir_prefix = eval {
58 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
59} || '';
60$Git::SVN::Ra::_log_window_size = 100;
62if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
64 $ENV{SVN_SSH} = $ENV{GIT_SSH};
65}
66if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
68 $ENV{SVN_SSH} =~ s/\\/\\\\/g;
69 $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
70}
71$Git::SVN::Log::TZ = $ENV{TZ};
73$ENV{TZ} = 'UTC';
74$| = 1; # unbuffer STDOUT
75# All SVN commands do it. Otherwise we may die on SIGPIPE when the remote
77# repository decides to close the connection which we expect to be kept alive.
78$SIG{PIPE} = 'IGNORE';
79# Given a dot separated version number, "subtract" it from
81# the SVN::Core::VERSION; non-negaitive return means the SVN::Core
82# is at least at the version the caller asked for.
83sub compare_svn_version {
84 my (@ours) = split(/\./, $SVN::Core::VERSION);
85 my (@theirs) = split(/\./, $_[0]);
86 my ($i, $diff);
87 for ($i = 0; $i < @ours && $i < @theirs; $i++) {
89 $diff = $ours[$i] - $theirs[$i];
90 return $diff if ($diff);
91 }
92 return 1 if ($i < @ours);
93 return -1 if ($i < @theirs);
94 return 0;
95}
96sub _req_svn {
98 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
99 require SVN::Ra;
100 require SVN::Delta;
101 if (::compare_svn_version('1.1.0') < 0) {
102 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
103 }
104}
105$sha1 = qr/[a-f\d]{40}/;
107$sha1_short = qr/[a-f\d]{4,40}/;
108my ($_stdin, $_help, $_edit,
109 $_message, $_file, $_branch_dest,
110 $_template, $_shared,
111 $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
112 $_before, $_after,
113 $_merge, $_strategy, $_preserve_merges, $_dry_run, $_parents, $_local,
114 $_prefix, $_no_checkout, $_url, $_verbose,
115 $_commit_url, $_tag, $_merge_info, $_interactive, $_set_svn_props);
116# This is a refactoring artifact so Git::SVN can get at this git-svn switch.
118sub opt_prefix { return $_prefix || '' }
119$Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
121$_q ||= 0;
122my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
123 'config-dir=s' => \$Git::SVN::Ra::config_dir,
124 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
125 'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
126 'include-paths=s' => \$Git::SVN::Fetcher::_include_regex,
127 'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
128my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
129 'authors-file|A=s' => \$_authors,
130 'authors-prog=s' => \$_authors_prog,
131 'repack:i' => \$Git::SVN::_repack,
132 'noMetadata' => \$Git::SVN::_no_metadata,
133 'useSvmProps' => \$Git::SVN::_use_svm_props,
134 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
135 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
136 'no-checkout' => \$_no_checkout,
137 'quiet|q+' => \$_q,
138 'repack-flags|repack-args|repack-opts=s' =>
139 \$Git::SVN::_repack_flags,
140 'use-log-author' => \$Git::SVN::_use_log_author,
141 'add-author-from' => \$Git::SVN::_add_author_from,
142 'localtime' => \$Git::SVN::_localtime,
143 %remote_opts );
144my ($_trunk, @_tags, @_branches, $_stdlayout);
146my %icv;
147my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
148 'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
149 'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
150 'stdlayout|s' => \$_stdlayout,
151 'minimize-url|m!' => \$Git::SVN::_minimize_url,
152 'no-metadata' => sub { $icv{noMetadata} = 1 },
153 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
154 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
155 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
156 'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
157 %remote_opts );
158my %cmt_opts = ( 'edit|e' => \$_edit,
159 'rmdir' => \$Git::SVN::Editor::_rmdir,
160 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
161 'l=i' => \$Git::SVN::Editor::_rename_limit,
162 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
163);
164my %cmd = (
166 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
167 { 'revision|r=s' => \$_revision,
168 'fetch-all|all' => \$_fetch_all,
169 'parent|p' => \$_fetch_parent,
170 %fc_opts } ],
171 clone => [ \&cmd_clone, "Initialize and fetch revisions",
172 { 'revision|r=s' => \$_revision,
173 'preserve-empty-dirs' =>
174 \$Git::SVN::Fetcher::_preserve_empty_dirs,
175 'placeholder-filename=s' =>
176 \$Git::SVN::Fetcher::_placeholder_filename,
177 %fc_opts, %init_opts } ],
178 init => [ \&cmd_init, "Initialize a repo for tracking" .
179 " (requires URL argument)",
180 \%init_opts ],
181 'multi-init' => [ \&cmd_multi_init,
182 "Deprecated alias for ".
183 "'$0 init -T<trunk> -b<branches> -t<tags>'",
184 \%init_opts ],
185 dcommit => [ \&cmd_dcommit,
186 'Commit several diffs to merge with upstream',
187 { 'merge|m|M' => \$_merge,
188 'strategy|s=s' => \$_strategy,
189 'verbose|v' => \$_verbose,
190 'dry-run|n' => \$_dry_run,
191 'fetch-all|all' => \$_fetch_all,
192 'commit-url=s' => \$_commit_url,
193 'set-svn-props=s' => \$_set_svn_props,
194 'revision|r=i' => \$_revision,
195 'no-rebase' => \$_no_rebase,
196 'mergeinfo=s' => \$_merge_info,
197 'interactive|i' => \$_interactive,
198 %cmt_opts, %fc_opts } ],
199 branch => [ \&cmd_branch,
200 'Create a branch in the SVN repository',
201 { 'message|m=s' => \$_message,
202 'destination|d=s' => \$_branch_dest,
203 'dry-run|n' => \$_dry_run,
204 'parents' => \$_parents,
205 'tag|t' => \$_tag,
206 'username=s' => \$Git::SVN::Prompt::_username,
207 'commit-url=s' => \$_commit_url } ],
208 tag => [ sub { $_tag = 1; cmd_branch(@_) },
209 'Create a tag in the SVN repository',
210 { 'message|m=s' => \$_message,
211 'destination|d=s' => \$_branch_dest,
212 'dry-run|n' => \$_dry_run,
213 'parents' => \$_parents,
214 'username=s' => \$Git::SVN::Prompt::_username,
215 'commit-url=s' => \$_commit_url } ],
216 'set-tree' => [ \&cmd_set_tree,
217 "Set an SVN repository to a git tree-ish",
218 { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
219 'create-ignore' => [ \&cmd_create_ignore,
220 'Create a .gitignore per svn:ignore',
221 { 'revision|r=i' => \$_revision
222 } ],
223 'mkdirs' => [ \&cmd_mkdirs ,
224 "recreate empty directories after a checkout",
225 { 'revision|r=i' => \$_revision } ],
226 'propget' => [ \&cmd_propget,
227 'Print the value of a property on a file or directory',
228 { 'revision|r=i' => \$_revision } ],
229 'propset' => [ \&cmd_propset,
230 'Set the value of a property on a file or directory - will be set on commit',
231 {} ],
232 'proplist' => [ \&cmd_proplist,
233 'List all properties of a file or directory',
234 { 'revision|r=i' => \$_revision } ],
235 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
236 { 'revision|r=i' => \$_revision
237 } ],
238 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
239 { 'revision|r=i' => \$_revision
240 } ],
241 'multi-fetch' => [ \&cmd_multi_fetch,
242 "Deprecated alias for $0 fetch --all",
243 { 'revision|r=s' => \$_revision, %fc_opts } ],
244 'migrate' => [ sub { },
245 # no-op, we automatically run this anyways,
246 'Migrate configuration/metadata/layout from
247 previous versions of git-svn',
248 { 'minimize' => \$Git::SVN::Migration::_minimize,
249 %remote_opts } ],
250 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
251 { 'limit=i' => \$Git::SVN::Log::limit,
252 'revision|r=s' => \$_revision,
253 'verbose|v' => \$Git::SVN::Log::verbose,
254 'incremental' => \$Git::SVN::Log::incremental,
255 'oneline' => \$Git::SVN::Log::oneline,
256 'show-commit' => \$Git::SVN::Log::show_commit,
257 'non-recursive' => \$Git::SVN::Log::non_recursive,
258 'authors-file|A=s' => \$_authors,
259 'color' => \$Git::SVN::Log::color,
260 'pager=s' => \$Git::SVN::Log::pager
261 } ],
262 'find-rev' => [ \&cmd_find_rev,
263 "Translate between SVN revision numbers and tree-ish",
264 { 'B|before' => \$_before,
265 'A|after' => \$_after } ],
266 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
267 { 'merge|m|M' => \$_merge,
268 'verbose|v' => \$_verbose,
269 'strategy|s=s' => \$_strategy,
270 'local|l' => \$_local,
271 'fetch-all|all' => \$_fetch_all,
272 'dry-run|n' => \$_dry_run,
273 'preserve-merges|p' => \$_preserve_merges,
274 %fc_opts } ],
275 'commit-diff' => [ \&cmd_commit_diff,
276 'Commit a diff between two trees',
277 { 'message|m=s' => \$_message,
278 'file|F=s' => \$_file,
279 'revision|r=s' => \$_revision,
280 %cmt_opts } ],
281 'info' => [ \&cmd_info,
282 "Show info about the latest SVN revision
283 on the current branch",
284 { 'url' => \$_url, } ],
285 'blame' => [ \&Git::SVN::Log::cmd_blame,
286 "Show what revision and author last modified each line of a file",
287 { 'git-format' => \$Git::SVN::Log::_git_format } ],
288 'reset' => [ \&cmd_reset,
289 "Undo fetches back to the specified SVN revision",
290 { 'revision|r=s' => \$_revision,
291 'parent|p' => \$_fetch_parent } ],
292 'gc' => [ \&cmd_gc,
293 "Compress unhandled.log files in .git/svn and remove " .
294 "index files in .git/svn",
295 {} ],
296);
297package FakeTerm;
299sub new {
300 my ($class, $reason) = @_;
301 return bless \$reason, shift;
302}
303sub readline {
304 my $self = shift;
305 die "Cannot use readline on FakeTerm: $$self";
306}
307package main;
308my $term;
310sub term_init {
311 $term = eval {
312 require Term::ReadLine;
313 $ENV{"GIT_SVN_NOTTY"}
314 ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
315 : new Term::ReadLine 'git-svn';
316 };
317 if ($@) {
318 $term = new FakeTerm "$@: going non-interactive";
319 }
320}
321my $cmd;
323for (my $i = 0; $i < @ARGV; $i++) {
324 if (defined $cmd{$ARGV[$i]}) {
325 $cmd = $ARGV[$i];
326 splice @ARGV, $i, 1;
327 last;
328 } elsif ($ARGV[$i] eq 'help') {
329 $cmd = $ARGV[$i+1];
330 usage(0);
331 }
332};
333# make sure we're always running at the top-level working directory
335if ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
336 $ENV{GIT_DIR} ||= ".git";
337 # catch the submodule case
338 if (-f $ENV{GIT_DIR}) {
339 open(my $fh, '<', $ENV{GIT_DIR}) or
340 die "failed to open $ENV{GIT_DIR}: $!\n";
341 $ENV{GIT_DIR} = $1 if <$fh> =~ /^gitdir: (.+)$/;
342 }
343} elsif ($cmd) {
344 my ($git_dir, $cdup);
345 git_cmd_try {
346 $git_dir = command_oneline([qw/rev-parse --git-dir/]);
347 } "Unable to find .git directory\n";
348 git_cmd_try {
349 $cdup = command_oneline(qw/rev-parse --show-cdup/);
350 chomp $cdup if ($cdup);
351 $cdup = "." unless ($cdup && length $cdup);
352 } "Already at toplevel, but $git_dir not found\n";
353 $ENV{GIT_DIR} = $git_dir;
354 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
355 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
356}
357my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
359read_git_config(\%opts) if $ENV{GIT_DIR};
361if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
362 Getopt::Long::Configure('pass_through');
363}
364my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
365 'minimize-connections' => \$Git::SVN::Migration::_minimize,
366 'id|i=s' => \$Git::SVN::default_ref_id,
367 'svn-remote|remote|R=s' => sub {
368 $Git::SVN::no_reuse_existing = 1;
369 $Git::SVN::default_repo_id = $_[1] });
370exit 1 if (!$rv && $cmd && $cmd ne 'log');
371usage(0) if $_help;
373version() if $_version;
374usage(1) unless defined $cmd;
375load_authors() if $_authors;
376if (defined $_authors_prog) {
377 $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
378}
379unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
381 Git::SVN::Migration::migration_check();
382}
383Git::SVN::init_vars();
384eval {
385 Git::SVN::verify_remotes_sanity();
386 $cmd{$cmd}->[0]->(@ARGV);
387 post_fetch_checkout();
388};
389fatal $@ if $@;
390exit 0;
391####################### primary functions ######################
393sub usage {
394 my $exit = shift || 0;
395 my $fd = $exit ? \*STDERR : \*STDOUT;
396 print $fd <<"";
397git-svn - bidirectional operations between a single Subversion tree and git
398usage: git svn <command> [options] [arguments]\n
399 print $fd "Available commands:\n" unless $cmd;
401 foreach (sort keys %cmd) {
403 next if $cmd && $cmd ne $_;
404 next if /^multi-/; # don't show deprecated commands
405 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
406 foreach (sort keys %{$cmd{$_}->[2]}) {
407 # mixed-case options are for .git/config only
408 next if /[A-Z]/ && /^[a-z]+$/i;
409 # prints out arguments as they should be passed:
410 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
411 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
412 "--$_" : "-$_" }
413 split /\|/,$_)," $x\n";
414 }
415 }
416 print $fd <<"";
417\nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
418arbitrary identifier if you're tracking multiple SVN branches/repositories in
419one git repository and want to keep them separate. See git-svn(1) for more
420information.
421 exit $exit;
423}
424sub version {
426 ::_req_svn();
427 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
428 exit 0;
429}
430sub ask {
432 my ($prompt, %arg) = @_;
433 my $valid_re = $arg{valid_re};
434 my $default = $arg{default};
435 my $resp;
436 my $i = 0;
437 term_init() unless $term;
438 if ( !( defined($term->IN)
440 && defined( fileno($term->IN) )
441 && defined( $term->OUT )
442 && defined( fileno($term->OUT) ) ) ){
443 return defined($default) ? $default : undef;
444 }
445 while ($i++ < 10) {
447 $resp = $term->readline($prompt);
448 if (!defined $resp) { # EOF
449 print "\n";
450 return defined $default ? $default : undef;
451 }
452 if ($resp eq '' and defined $default) {
453 return $default;
454 }
455 if (!defined $valid_re or $resp =~ /$valid_re/) {
456 return $resp;
457 }
458 }
459 return undef;
460}
461sub do_git_init_db {
463 unless (-d $ENV{GIT_DIR}) {
464 my @init_db = ('init');
465 push @init_db, "--template=$_template" if defined $_template;
466 if (defined $_shared) {
467 if ($_shared =~ /[a-z]/) {
468 push @init_db, "--shared=$_shared";
469 } else {
470 push @init_db, "--shared";
471 }
472 }
473 command_noisy(@init_db);
474 $_repository = Git->repository(Repository => ".git");
475 }
476 my $set;
477 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
478 foreach my $i (keys %icv) {
479 die "'$set' and '$i' cannot both be set\n" if $set;
480 next unless defined $icv{$i};
481 command_noisy('config', "$pfx.$i", $icv{$i});
482 $set = $i;
483 }
484 my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
485 command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
486 if defined $$ignore_paths_regex;
487 my $include_paths_regex = \$Git::SVN::Fetcher::_include_regex;
488 command_noisy('config', "$pfx.include-paths", $$include_paths_regex)
489 if defined $$include_paths_regex;
490 my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
491 command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
492 if defined $$ignore_refs_regex;
493 if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
495 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
496 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
497 command_noisy('config', "$pfx.placeholder-filename", $$fname);
498 }
499}
500sub init_subdir {
502 my $repo_path = shift or return;
503 mkpath([$repo_path]) unless -d $repo_path;
504 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
505 $ENV{GIT_DIR} = '.git';
506 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
507}
508sub cmd_clone {
510 my ($url, $path) = @_;
511 if (!$url) {
512 die "SVN repository location required ",
513 "as a command-line argument\n";
514 } elsif (!defined $path &&
515 (defined $_trunk || @_branches || @_tags ||
516 defined $_stdlayout) &&
517 $url !~ m#^[a-z\+]+://#) {
518 $path = $url;
519 }
520 $path = basename($url) if !defined $path || !length $path;
521 my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
522 cmd_init($url, $path);
523 command_oneline('config', 'svn.authorsfile', $authors_absolute)
524 if $_authors;
525 Git::SVN::fetch_all($Git::SVN::default_repo_id);
526}
527sub cmd_init {
529 if (defined $_stdlayout) {
530 $_trunk = 'trunk' if (!defined $_trunk);
531 @_tags = 'tags' if (! @_tags);
532 @_branches = 'branches' if (! @_branches);
533 }
534 if (defined $_trunk || @_branches || @_tags) {
535 return cmd_multi_init(@_);
536 }
537 my $url = shift or die "SVN repository location required ",
538 "as a command-line argument\n";
539 $url = canonicalize_url($url);
540 init_subdir(@_);
541 do_git_init_db();
542 if ($Git::SVN::_minimize_url eq 'unset') {
544 $Git::SVN::_minimize_url = 0;
545 }
546 Git::SVN->init($url);
548}
549sub cmd_fetch {
551 if (grep /^\d+=./, @_) {
552 die "'<rev>=<commit>' fetch arguments are ",
553 "no longer supported.\n";
554 }
555 my ($remote) = @_;
556 if (@_ > 1) {
557 die "usage: $0 fetch [--all] [--parent] [svn-remote]\n";
558 }
559 $Git::SVN::no_reuse_existing = undef;
560 if ($_fetch_parent) {
561 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
562 unless ($gs) {
563 die "Unable to determine upstream SVN information from ",
564 "working tree history\n";
565 }
566 # just fetch, don't checkout.
567 $_no_checkout = 'true';
568 $_fetch_all ? $gs->fetch_all : $gs->fetch;
569 } elsif ($_fetch_all) {
570 cmd_multi_fetch();
571 } else {
572 $remote ||= $Git::SVN::default_repo_id;
573 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
574 }
575}
576sub cmd_set_tree {
578 my (@commits) = @_;
579 if ($_stdin || !@commits) {
580 print "Reading from stdin...\n";
581 @commits = ();
582 while (<STDIN>) {
583 if (/\b($sha1_short)\b/o) {
584 unshift @commits, $1;
585 }
586 }
587 }
588 my @revs;
589 foreach my $c (@commits) {
590 my @tmp = command('rev-parse',$c);
591 if (scalar @tmp == 1) {
592 push @revs, $tmp[0];
593 } elsif (scalar @tmp > 1) {
594 push @revs, reverse(command('rev-list',@tmp));
595 } else {
596 fatal "Failed to rev-parse $c";
597 }
598 }
599 my $gs = Git::SVN->new;
600 my ($r_last, $cmt_last) = $gs->last_rev_commit;
601 $gs->fetch;
602 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
603 fatal "There are new revisions that were fetched ",
604 "and need to be merged (or acknowledged) ",
605 "before committing.\nlast rev: $r_last\n",
606 " current: $gs->{last_rev}";
607 }
608 $gs->set_tree($_) foreach @revs;
609 print "Done committing ",scalar @revs," revisions to SVN\n";
610 unlink $gs->{index};
611}
612sub split_merge_info_range {
614 my ($range) = @_;
615 if ($range =~ /(\d+)-(\d+)/) {
616 return (int($1), int($2));
617 } else {
618 return (int($range), int($range));
619 }
620}
621sub combine_ranges {
623 my ($in) = @_;
624 my @fnums = ();
626 my @arr = split(/,/, $in);
627 for my $element (@arr) {
628 my ($start, $end) = split_merge_info_range($element);
629 push @fnums, $start;
630 }
631 my @sorted = @arr [ sort {
633 $fnums[$a] <=> $fnums[$b]
634 } 0..$#arr ];
635 my @return = ();
637 my $last = -1;
638 my $first = -1;
639 for my $element (@sorted) {
640 my ($start, $end) = split_merge_info_range($element);
641 if ($last == -1) {
643 $first = $start;
644 $last = $end;
645 next;
646 }
647 if ($start <= $last+1) {
648 if ($end > $last) {
649 $last = $end;
650 }
651 next;
652 }
653 if ($first == $last) {
654 push @return, "$first";
655 } else {
656 push @return, "$first-$last";
657 }
658 $first = $start;
659 $last = $end;
660 }
661 if ($first != -1) {
663 if ($first == $last) {
664 push @return, "$first";
665 } else {
666 push @return, "$first-$last";
667 }
668 }
669 return join(',', @return);
671}
672sub merge_revs_into_hash {
674 my ($hash, $minfo) = @_;
675 my @lines = split(' ', $minfo);
676 for my $line (@lines) {
678 my ($branchpath, $revs) = split(/:/, $line);
679 if (exists($hash->{$branchpath})) {
681 # Merge the two revision sets
682 my $combined = "$hash->{$branchpath},$revs";
683 $hash->{$branchpath} = combine_ranges($combined);
684 } else {
685 # Just do range combining for consolidation
686 $hash->{$branchpath} = combine_ranges($revs);
687 }
688 }
689}
690sub merge_merge_info {
692 my ($mergeinfo_one, $mergeinfo_two, $ignore_branch) = @_;
693 my %result_hash = ();
694 merge_revs_into_hash(\%result_hash, $mergeinfo_one);
696 merge_revs_into_hash(\%result_hash, $mergeinfo_two);
697 delete $result_hash{$ignore_branch} if $ignore_branch;
699 my $result = '';
701 # Sort below is for consistency's sake
702 for my $branchname (sort keys(%result_hash)) {
703 my $revlist = $result_hash{$branchname};
704 $result .= "$branchname:$revlist\n"
705 }
706 return $result;
707}
708sub populate_merge_info {
710 my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
711 my %parentshash;
713 read_commit_parents(\%parentshash, $d);
714 my @parents = @{$parentshash{$d}};
715 if ($#parents > 0) {
716 # Merge commit
717 my $all_parents_ok = 1;
718 my $aggregate_mergeinfo = '';
719 my $rooturl = $gs->repos_root;
720 my ($target_branch) = $gs->full_pushurl =~ /^\Q$rooturl\E(.*)/;
721 if (defined($rewritten_parent)) {
723 # Replace first parent with newly-rewritten version
724 shift @parents;
725 unshift @parents, $rewritten_parent;
726 }
727 foreach my $parent (@parents) {
729 my ($branchurl, $svnrev, $paruuid) =
730 cmt_metadata($parent);
731 unless (defined($svnrev)) {
733 # Should have been caught be preflight check
734 fatal "merge commit $d has ancestor $parent, but that change "
735 ."does not have git-svn metadata!";
736 }
737 unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
738 fatal "commit $parent git-svn metadata changed mid-run!";
739 }
740 my $branchpath = $1;
741 my $ra = Git::SVN::Ra->new($branchurl);
743 my (undef, undef, $props) =
744 $ra->get_dir(canonicalize_path("."), $svnrev);
745 my $par_mergeinfo = $props->{'svn:mergeinfo'};
746 unless (defined $par_mergeinfo) {
747 $par_mergeinfo = '';
748 }
749 # Merge previous mergeinfo values
750 $aggregate_mergeinfo =
751 merge_merge_info($aggregate_mergeinfo,
752 $par_mergeinfo,
753 $target_branch);
754 next if $parent eq $parents[0]; # Skip first parent
756 # Add new changes being placed in tree by merge
757 my @cmd = (qw/rev-list --reverse/,
758 $parent, qw/--not/);
759 foreach my $par (@parents) {
760 unless ($par eq $parent) {
761 push @cmd, $par;
762 }
763 }
764 my @revsin = ();
765 my ($revlist, $ctx) = command_output_pipe(@cmd);
766 while (<$revlist>) {
767 my $irev = $_;
768 chomp $irev;
769 my (undef, $csvnrev, undef) =
770 cmt_metadata($irev);
771 unless (defined $csvnrev) {
772 # A child is missing SVN annotations...
773 # this might be OK, or might not be.
774 warn "W:child $irev is merged into revision "
775 ."$d but does not have git-svn metadata. "
776 ."This means git-svn cannot determine the "
777 ."svn revision numbers to place into the "
778 ."svn:mergeinfo property. You must ensure "
779 ."a branch is entirely committed to "
780 ."SVN before merging it in order for "
781 ."svn:mergeinfo population to function "
782 ."properly";
783 }
784 push @revsin, $csvnrev;
785 }
786 command_close_pipe($revlist, $ctx);
787 last unless $all_parents_ok;
789 # We now have a list of all SVN revnos which are
791 # merged by this particular parent. Integrate them.
792 next if $#revsin == -1;
793 my $newmergeinfo = "$branchpath:" . join(',', @revsin);
794 $aggregate_mergeinfo =
795 merge_merge_info($aggregate_mergeinfo,
796 $newmergeinfo,
797 $target_branch);
798 }
799 if ($all_parents_ok and $aggregate_mergeinfo) {
800 return $aggregate_mergeinfo;
801 }
802 }
803 return undef;
805}
806sub dcommit_rebase {
808 my ($is_last, $current, $fetched_ref, $svn_error) = @_;
809 my @diff;
810 if ($svn_error) {
812 print STDERR "\nERROR from SVN:\n",
813 $svn_error->expanded_message, "\n";
814 }
815 unless ($_no_rebase) {
816 # we always want to rebase against the current HEAD,
817 # not any head that was passed to us
818 @diff = command('diff-tree', $current,
819 $fetched_ref, '--');
820 my @finish;
821 if (@diff) {
822 @finish = rebase_cmd();
823 print STDERR "W: $current and ", $fetched_ref,
824 " differ, using @finish:\n",
825 join("\n", @diff), "\n";
826 } elsif ($is_last) {
827 print "No changes between ", $current, " and ",
828 $fetched_ref,
829 "\nResetting to the latest ",
830 $fetched_ref, "\n";
831 @finish = qw/reset --mixed/;
832 }
833 command_noisy(@finish, $fetched_ref) if @finish;
834 }
835 if ($svn_error) {
836 die "ERROR: Not all changes have been committed into SVN"
837 .($_no_rebase ? ".\n" : ", however the committed\n"
838 ."ones (if any) seem to be successfully integrated "
839 ."into the working tree.\n")
840 ."Please see the above messages for details.\n";
841 }
842 return @diff;
843}
844sub cmd_dcommit {
846 my $head = shift;
847 command_noisy(qw/update-index --refresh/);
848 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD --/) }
849 'Cannot dcommit with a dirty index. Commit your changes first, '
850 . "or stash them with `git stash'.\n";
851 $head ||= 'HEAD';
852 my $old_head;
854 if ($head ne 'HEAD') {
855 $old_head = eval {
856 command_oneline([qw/symbolic-ref -q HEAD/])
857 };
858 if ($old_head) {
859 $old_head =~ s{^refs/heads/}{};
860 } else {
861 $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
862 }
863 command(['checkout', $head], STDERR => 0);
864 }
865 my @refs;
867 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
868 unless ($gs) {
869 die "Unable to determine upstream SVN information from ",
870 "$head history.\nPerhaps the repository is empty.";
871 }
872 if (defined $_commit_url) {
874 $url = $_commit_url;
875 } else {
876 $url = eval { command_oneline('config', '--get',
877 "svn-remote.$gs->{repo_id}.commiturl") };
878 if (!$url) {
879 $url = $gs->full_pushurl
880 }
881 }
882 my $last_rev = $_revision if defined $_revision;
884 if ($url) {
885 print "Committing to $url ...\n";
886 }
887 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
888 if ($_no_rebase && scalar(@$linear_refs) > 1) {
889 warn "Attempting to commit more than one change while ",
890 "--no-rebase is enabled.\n",
891 "If these changes depend on each other, re-running ",
892 "without --no-rebase may be required."
893 }
894 if (defined $_interactive){
896 my $ask_default = "y";
897 foreach my $d (@$linear_refs){
898 my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
899 while (<$fh>){
900 print $_;
901 }
902 command_close_pipe($fh, $ctx);
903 $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
904 valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
905 default => $ask_default);
906 die "Commit this patch reply required" unless defined $_;
907 if (/^[nq]/i) {
908 exit(0);
909 } elsif (/^a/i) {
910 last;
911 }
912 }
913 }
914 my $expect_url = $url;
916 my $push_merge_info = eval {
918 command_oneline(qw/config --get svn.pushmergeinfo/)
919 };
920 if (not defined($push_merge_info)
921 or $push_merge_info eq "false"
922 or $push_merge_info eq "no"
923 or $push_merge_info eq "never") {
924 $push_merge_info = 0;
925 }
926 unless (defined($_merge_info) || ! $push_merge_info) {
928 # Preflight check of changes to ensure no issues with mergeinfo
929 # This includes check for uncommitted-to-SVN parents
930 # (other than the first parent, which we will handle),
931 # information from different SVN repos, and paths
932 # which are not underneath this repository root.
933 my $rooturl = $gs->repos_root;
934 foreach my $d (@$linear_refs) {
935 my %parentshash;
936 read_commit_parents(\%parentshash, $d);
937 my @realparents = @{$parentshash{$d}};
938 if ($#realparents > 0) {
939 # Merge commit
940 shift @realparents; # Remove/ignore first parent
941 foreach my $parent (@realparents) {
942 my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
943 unless (defined $paruuid) {
944 # A parent is missing SVN annotations...
945 # abort the whole operation.
946 fatal "$parent is merged into revision $d, "
947 ."but does not have git-svn metadata. "
948 ."Either dcommit the branch or use a "
949 ."local cherry-pick, FF merge, or rebase "
950 ."instead of an explicit merge commit.";
951 }
952 unless ($paruuid eq $uuid) {
954 # Parent has SVN metadata from different repository
955 fatal "merge parent $parent for change $d has "
956 ."git-svn uuid $paruuid, while current change "
957 ."has uuid $uuid!";
958 }
959 unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
961 # This branch is very strange indeed.
962 fatal "merge parent $parent for $d is on branch "
963 ."$branchurl, which is not under the "
964 ."git-svn root $rooturl!";
965 }
966 }
967 }
968 }
969 }
970 my $rewritten_parent;
972 my $current_head = command_oneline(qw/rev-parse HEAD/);
973 Git::SVN::remove_username($expect_url);
974 if (defined($_merge_info)) {
975 $_merge_info =~ tr{ }{\n};
976 }
977 while (1) {
978 my $d = shift @$linear_refs or last;
979 unless (defined $last_rev) {
980 (undef, $last_rev, undef) = cmt_metadata("$d~1");
981 unless (defined $last_rev) {
982 fatal "Unable to extract revision information ",
983 "from commit $d~1";
984 }
985 }
986 if ($_dry_run) {
987 print "diff-tree $d~1 $d\n";
988 } else {
989 my $cmt_rev;
990 unless (defined($_merge_info) || ! $push_merge_info) {
992 $_merge_info = populate_merge_info($d, $gs,
993 $uuid,
994 $linear_refs,
995 $rewritten_parent);
996 }
997 my %ed_opts = ( r => $last_rev,
999 log => get_commit_entry($d)->{log},
1000 ra => Git::SVN::Ra->new($url),
1001 config => SVN::Core::config_get_config(
1002 $Git::SVN::Ra::config_dir
1003 ),
1004 tree_a => "$d~1",
1005 tree_b => $d,
1006 editor_cb => sub {
1007 print "Committed r$_[0]\n";
1008 $cmt_rev = $_[0];
1009 },
1010 mergeinfo => $_merge_info,
1011 svn_path => '');
1012 my $err_handler = $SVN::Error::handler;
1014 $SVN::Error::handler = sub {
1015 my $err = shift;
1016 dcommit_rebase(1, $current_head, $gs->refname,
1017 $err);
1018 };
1019 if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1021 print "No changes\n$d~1 == $d\n";
1022 } elsif ($parents->{$d} && @{$parents->{$d}}) {
1023 $gs->{inject_parents_dcommit}->{$cmt_rev} =
1024 $parents->{$d};
1025 }
1026 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1027 $SVN::Error::handler = $err_handler;
1028 $last_rev = $cmt_rev;
1029 next if $_no_rebase;
1030 my @diff = dcommit_rebase(@$linear_refs == 0, $d,
1032 $gs->refname, undef);
1033 $rewritten_parent = command_oneline(qw/rev-parse/,
1035 $gs->refname);
1036 if (@diff) {
1038 $current_head = command_oneline(qw/rev-parse
1039 HEAD/);
1040 @refs = ();
1041 my ($url_, $rev_, $uuid_, $gs_) =
1042 working_head_info('HEAD', \@refs);
1043 my ($linear_refs_, $parents_) =
1044 linearize_history($gs_, \@refs);
1045 if (scalar(@$linear_refs) !=
1046 scalar(@$linear_refs_)) {
1047 fatal "# of revisions changed ",
1048 "\nbefore:\n",
1049 join("\n", @$linear_refs),
1050 "\n\nafter:\n",
1051 join("\n", @$linear_refs_), "\n",
1052 'If you are attempting to commit ',
1053 "merges, try running:\n\t",
1054 'git rebase --interactive',
1055 '--preserve-merges ',
1056 $gs->refname,
1057 "\nBefore dcommitting";
1058 }
1059 if ($url_ ne $expect_url) {
1060 if ($url_ eq $gs->metadata_url) {
1061 print
1062 "Accepting rewritten URL:",
1063 " $url_\n";
1064 } else {
1065 fatal
1066 "URL mismatch after rebase:",
1067 " $url_ != $expect_url";
1068 }
1069 }
1070 if ($uuid_ ne $uuid) {
1071 fatal "uuid mismatch after rebase: ",
1072 "$uuid_ != $uuid";
1073 }
1074 # remap parents
1075 my (%p, @l, $i);
1076 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1077 my $new = $linear_refs_->[$i] or next;
1078 $p{$new} =
1079 $parents->{$linear_refs->[$i]};
1080 push @l, $new;
1081 }
1082 $parents = \%p;
1083 $linear_refs = \@l;
1084 undef $last_rev;
1085 }
1086 }
1087 }
1088 if ($old_head) {
1090 my $new_head = command_oneline(qw/rev-parse HEAD/);
1091 my $new_is_symbolic = eval {
1092 command_oneline(qw/symbolic-ref -q HEAD/);
1093 };
1094 if ($new_is_symbolic) {
1095 print "dcommitted the branch ", $head, "\n";
1096 } else {
1097 print "dcommitted on a detached HEAD because you gave ",
1098 "a revision argument.\n",
1099 "The rewritten commit is: ", $new_head, "\n";
1100 }
1101 command(['checkout', $old_head], STDERR => 0);
1102 }
1103 unlink $gs->{index};
1105}
1106sub cmd_branch {
1108 my ($branch_name, $head) = @_;
1109 unless (defined $branch_name && length $branch_name) {
1111 die(($_tag ? "tag" : "branch") . " name required\n");
1112 }
1113 $head ||= 'HEAD';
1114 my (undef, $rev, undef, $gs) = working_head_info($head);
1116 my $src = $gs->full_pushurl;
1117 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1119 my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1120 my $glob;
1121 if ($#{$allglobs} == 0) {
1122 $glob = $allglobs->[0];
1123 } else {
1124 unless(defined $_branch_dest) {
1125 die "Multiple ",
1126 $_tag ? "tag" : "branch",
1127 " paths defined for Subversion repository.\n",
1128 "You must specify where you want to create the ",
1129 $_tag ? "tag" : "branch",
1130 " with the --destination argument.\n";
1131 }
1132 foreach my $g (@{$allglobs}) {
1133 my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1134 if ($_branch_dest =~ /$re/) {
1135 $glob = $g;
1136 last;
1137 }
1138 }
1139 unless (defined $glob) {
1140 my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1141 foreach my $g (@{$allglobs}) {
1142 $g->{path}->{left} =~ /$dest_re/ or next;
1143 if (defined $glob) {
1144 die "Ambiguous destination: ",
1145 $_branch_dest, "\nmatches both '",
1146 $glob->{path}->{left}, "' and '",
1147 $g->{path}->{left}, "'\n";
1148 }
1149 $glob = $g;
1150 }
1151 unless (defined $glob) {
1152 die "Unknown ",
1153 $_tag ? "tag" : "branch",
1154 " destination $_branch_dest\n";
1155 }
1156 }
1157 }
1158 my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1159 my $url;
1160 if (defined $_commit_url) {
1161 $url = $_commit_url;
1162 } else {
1163 $url = eval { command_oneline('config', '--get',
1164 "svn-remote.$gs->{repo_id}.commiturl") };
1165 if (!$url) {
1166 $url = $remote->{pushurl} || $remote->{url};
1167 }
1168 }
1169 my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1170 if ($dst =~ /^https:/ && $src =~ /^http:/) {
1172 $src=~s/^http:/https:/;
1173 }
1174 ::_req_svn();
1176 require SVN::Client;
1177 my $ctx = SVN::Client->new(
1179 config => SVN::Core::config_get_config(
1180 $Git::SVN::Ra::config_dir
1181 ),
1182 log_msg => sub {
1183 ${ $_[0] } = defined $_message
1184 ? $_message
1185 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1186 . $branch_name;
1187 },
1188 );
1189 eval {
1191 $ctx->ls($dst, 'HEAD', 0);
1192 } and die "branch ${branch_name} already exists\n";
1193 if ($_parents) {
1195 mk_parent_dirs($ctx, $dst);
1196 }
1197 print "Copying ${src} at r${rev} to ${dst}...\n";
1199 $ctx->copy($src, $rev, $dst)
1200 unless $_dry_run;
1201 $gs->fetch_all;
1203}
1204sub mk_parent_dirs {
1206 my ($ctx, $parent) = @_;
1207 $parent =~ s{/[^/]*$}{};
1208 if (!eval{$ctx->ls($parent, 'HEAD', 0)}) {
1210 mk_parent_dirs($ctx, $parent);
1211 print "Creating parent folder ${parent} ...\n";
1212 $ctx->mkdir($parent) unless $_dry_run;
1213 }
1214}
1215sub cmd_find_rev {
1217 my $revision_or_hash = shift or die "SVN or git revision required ",
1218 "as a command-line argument\n";
1219 my $result;
1220 if ($revision_or_hash =~ /^r\d+$/) {
1221 my $head = shift;
1222 $head ||= 'HEAD';
1223 my @refs;
1224 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1225 unless ($gs) {
1226 die "Unable to determine upstream SVN information from ",
1227 "$head history\n";
1228 }
1229 my $desired_revision = substr($revision_or_hash, 1);
1230 if ($_before) {
1231 $result = $gs->find_rev_before($desired_revision, 1);
1232 } elsif ($_after) {
1233 $result = $gs->find_rev_after($desired_revision, 1);
1234 } else {
1235 $result = $gs->rev_map_get($desired_revision, $uuid);
1236 }
1237 } else {
1238 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1239 $result = $rev;
1240 }
1241 print "$result\n" if $result;
1242}
1243sub auto_create_empty_directories {
1245 my ($gs) = @_;
1246 my $var = eval { command_oneline('config', '--get', '--bool',
1247 "svn-remote.$gs->{repo_id}.automkdirs") };
1248 # By default, create empty directories by consulting the unhandled log,
1249 # but allow setting it to 'false' to skip it.
1250 return !($var && $var eq 'false');
1251}
1252sub cmd_rebase {
1254 command_noisy(qw/update-index --refresh/);
1255 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1256 unless ($gs) {
1257 die "Unable to determine upstream SVN information from ",
1258 "working tree history\n";
1259 }
1260 if ($_dry_run) {
1261 print "Remote Branch: " . $gs->refname . "\n";
1262 print "SVN URL: " . $url . "\n";
1263 return;
1264 }
1265 if (command(qw/diff-index HEAD --/)) {
1266 print STDERR "Cannot rebase with uncommitted changes:\n";
1267 command_noisy('status');
1268 exit 1;
1269 }
1270 unless ($_local) {
1271 # rebase will checkout for us, so no need to do it explicitly
1272 $_no_checkout = 'true';
1273 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1274 }
1275 command_noisy(rebase_cmd(), $gs->refname);
1276 if (auto_create_empty_directories($gs)) {
1277 $gs->mkemptydirs;
1278 }
1279}
1280sub cmd_show_ignore {
1282 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1283 $gs ||= Git::SVN->new;
1284 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1285 $gs->prop_walk($gs->path, $r, sub {
1286 my ($gs, $path, $props) = @_;
1287 print STDOUT "\n# $path\n";
1288 my $s = $props->{'svn:ignore'} or return;
1289 $s =~ s/[\r\n]+/\n/g;
1290 $s =~ s/^\n+//;
1291 chomp $s;
1292 $s =~ s#^#$path#gm;
1293 print STDOUT "$s\n";
1294 });
1295}
1296sub cmd_show_externals {
1298 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1299 $gs ||= Git::SVN->new;
1300 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1301 $gs->prop_walk($gs->path, $r, sub {
1302 my ($gs, $path, $props) = @_;
1303 print STDOUT "\n# $path\n";
1304 my $s = $props->{'svn:externals'} or return;
1305 $s =~ s/[\r\n]+/\n/g;
1306 chomp $s;
1307 $s =~ s#^#$path#gm;
1308 print STDOUT "$s\n";
1309 });
1310}
1311sub cmd_create_ignore {
1313 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1314 $gs ||= Git::SVN->new;
1315 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1316 $gs->prop_walk($gs->path, $r, sub {
1317 my ($gs, $path, $props) = @_;
1318 # $path is of the form /path/to/dir/
1319 $path = '.' . $path;
1320 # SVN can have attributes on empty directories,
1321 # which git won't track
1322 mkpath([$path]) unless -d $path;
1323 my $ignore = $path . '.gitignore';
1324 my $s = $props->{'svn:ignore'} or return;
1325 open(GITIGNORE, '>', $ignore)
1326 or fatal("Failed to open `$ignore' for writing: $!");
1327 $s =~ s/[\r\n]+/\n/g;
1328 $s =~ s/^\n+//;
1329 chomp $s;
1330 # Prefix all patterns so that the ignore doesn't apply
1331 # to sub-directories.
1332 $s =~ s#^#/#gm;
1333 print GITIGNORE "$s\n";
1334 close(GITIGNORE)
1335 or fatal("Failed to close `$ignore': $!");
1336 command_noisy('add', '-f', $ignore);
1337 });
1338}
1339sub cmd_mkdirs {
1341 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1342 $gs ||= Git::SVN->new;
1343 $gs->mkemptydirs($_revision);
1344}
1345# get_svnprops(PATH)
1347# ------------------
1348# Helper for cmd_propget and cmd_proplist below.
1349sub get_svnprops {
1350 my $path = shift;
1351 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1352 $gs ||= Git::SVN->new;
1353 # prefix THE PATH by the sub-directory from which the user
1355 # invoked us.
1356 $path = $cmd_dir_prefix . $path;
1357 fatal("No such file or directory: $path") unless -e $path;
1358 my $is_dir = -d $path ? 1 : 0;
1359 $path = join_paths($gs->path, $path);
1360 # canonicalize the path (otherwise libsvn will abort or fail to
1362 # find the file)
1363 $path = canonicalize_path($path);
1364 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1366 my $props;
1367 if ($is_dir) {
1368 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1369 }
1370 else {
1371 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1372 }
1373 return $props;
1374}
1375# cmd_propget (PROP, PATH)
1377# ------------------------
1378# Print the SVN property PROP for PATH.
1379sub cmd_propget {
1380 my ($prop, $path) = @_;
1381 $path = '.' if not defined $path;
1382 usage(1) if not defined $prop;
1383 my $props = get_svnprops($path);
1384 if (not defined $props->{$prop}) {
1385 fatal("`$path' does not have a `$prop' SVN property.");
1386 }
1387 print $props->{$prop} . "\n";
1388}
1389# cmd_propset (PROPNAME, PROPVAL, PATH)
1391# ------------------------
1392# Adjust the SVN property PROPNAME to PROPVAL for PATH.
1393sub cmd_propset {
1394 my ($propname, $propval, $path) = @_;
1395 $path = '.' if not defined $path;
1396 $path = $cmd_dir_prefix . $path;
1397 usage(1) if not defined $propname;
1398 usage(1) if not defined $propval;
1399 my $file = basename($path);
1400 my $dn = dirname($path);
1401 my $cur_props = Git::SVN::Editor::check_attr( "svn-properties", $path );
1402 my @new_props;
1403 if (!$cur_props || $cur_props eq "unset" || $cur_props eq "" || $cur_props eq "set") {
1404 push @new_props, "$propname=$propval";
1405 } else {
1406 # TODO: handle combining properties better
1407 my @props = split(/;/, $cur_props);
1408 my $replaced_prop;
1409 foreach my $prop (@props) {
1410 # Parse 'name=value' syntax and set the property.
1411 if ($prop =~ /([^=]+)=(.*)/) {
1412 my ($n,$v) = ($1,$2);
1413 if ($n eq $propname) {
1414 $v = $propval;
1415 $replaced_prop = 1;
1416 }
1417 push @new_props, "$n=$v";
1418 }
1419 }
1420 if (!$replaced_prop) {
1421 push @new_props, "$propname=$propval";
1422 }
1423 }
1424 my $attrfile = "$dn/.gitattributes";
1425 open my $attrfh, '>>', $attrfile or die "Can't open $attrfile: $!\n";
1426 # TODO: don't simply append here if $file already has svn-properties
1427 my $new_props = join(';', @new_props);
1428 print $attrfh "$file svn-properties=$new_props\n" or
1429 die "write to $attrfile: $!\n";
1430 close $attrfh or die "close $attrfile: $!\n";
1431}
1432# cmd_proplist (PATH)
1434# -------------------
1435# Print the list of SVN properties for PATH.
1436sub cmd_proplist {
1437 my $path = shift;
1438 $path = '.' if not defined $path;
1439 my $props = get_svnprops($path);
1440 print "Properties on '$path':\n";
1441 foreach (sort keys %{$props}) {
1442 print " $_\n";
1443 }
1444}
1445sub cmd_multi_init {
1447 my $url = shift;
1448 unless (defined $_trunk || @_branches || @_tags) {
1449 usage(1);
1450 }
1451 $_prefix = 'origin/' unless defined $_prefix;
1453 if (defined $url) {
1454 $url = canonicalize_url($url);
1455 init_subdir(@_);
1456 }
1457 do_git_init_db();
1458 if (defined $_trunk) {
1459 $_trunk =~ s#^/+##;
1460 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1461 # try both old-style and new-style lookups:
1462 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1463 unless ($gs_trunk) {
1464 my ($trunk_url, $trunk_path) =
1465 complete_svn_url($url, $_trunk);
1466 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1467 undef, $trunk_ref);
1468 }
1469 }
1470 return unless @_branches || @_tags;
1471 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1472 foreach my $path (@_branches) {
1473 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1474 }
1475 foreach my $path (@_tags) {
1476 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1477 }
1478}
1479sub cmd_multi_fetch {
1481 $Git::SVN::no_reuse_existing = undef;
1482 my $remotes = Git::SVN::read_all_remotes();
1483 foreach my $repo_id (sort keys %$remotes) {
1484 if ($remotes->{$repo_id}->{url}) {
1485 Git::SVN::fetch_all($repo_id, $remotes);
1486 }
1487 }
1488}
1489# this command is special because it requires no metadata
1491sub cmd_commit_diff {
1492 my ($ta, $tb, $url) = @_;
1493 my $usage = "usage: $0 commit-diff -r<revision> ".
1494 "<tree-ish> <tree-ish> [<URL>]";
1495 fatal($usage) if (!defined $ta || !defined $tb);
1496 my $svn_path = '';
1497 if (!defined $url) {
1498 my $gs = eval { Git::SVN->new };
1499 if (!$gs) {
1500 fatal("Needed URL or usable git-svn --id in ",
1501 "the command-line\n", $usage);
1502 }
1503 $url = $gs->url;
1504 $svn_path = $gs->path;
1505 }
1506 unless (defined $_revision) {
1507 fatal("-r|--revision is a required argument\n", $usage);
1508 }
1509 if (defined $_message && defined $_file) {
1510 fatal("Both --message/-m and --file/-F specified ",
1511 "for the commit message.\n",
1512 "I have no idea what you mean");
1513 }
1514 if (defined $_file) {
1515 $_message = file_to_s($_file);
1516 } else {
1517 $_message ||= get_commit_entry($tb)->{log};
1518 }
1519 my $ra ||= Git::SVN::Ra->new($url);
1520 my $r = $_revision;
1521 if ($r eq 'HEAD') {
1522 $r = $ra->get_latest_revnum;
1523 } elsif ($r !~ /^\d+$/) {
1524 die "revision argument: $r not understood by git-svn\n";
1525 }
1526 my %ed_opts = ( r => $r,
1527 log => $_message,
1528 ra => $ra,
1529 tree_a => $ta,
1530 tree_b => $tb,
1531 editor_cb => sub { print "Committed r$_[0]\n" },
1532 svn_path => $svn_path );
1533 if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1534 print "No changes\n$ta == $tb\n";
1535 }
1536}
1537sub cmd_info {
1539 my $path_arg = defined($_[0]) ? $_[0] : '.';
1540 my $path = $path_arg;
1541 if (File::Spec->file_name_is_absolute($path)) {
1542 $path = canonicalize_path($path);
1543 my $toplevel = eval {
1545 my @cmd = qw/rev-parse --show-toplevel/;
1546 command_oneline(\@cmd, STDERR => 0);
1547 };
1548 # remove $toplevel from the absolute path:
1550 my ($vol, $dirs, $file) = File::Spec->splitpath($path);
1551 my (undef, $tdirs, $tfile) = File::Spec->splitpath($toplevel);
1552 my @dirs = File::Spec->splitdir($dirs);
1553 my @tdirs = File::Spec->splitdir($tdirs);
1554 pop @dirs if $dirs[-1] eq '';
1555 pop @tdirs if $tdirs[-1] eq '';
1556 push @dirs, $file;
1557 push @tdirs, $tfile;
1558 while (@tdirs && @dirs && $tdirs[0] eq $dirs[0]) {
1559 shift @dirs;
1560 shift @tdirs;
1561 }
1562 $dirs = File::Spec->catdir(@dirs);
1563 $path = File::Spec->catpath($vol, $dirs);
1564 $path = canonicalize_path($path);
1566 } else {
1567 $path = canonicalize_path($cmd_dir_prefix . $path);
1568 }
1569 if (exists $_[1]) {
1570 die "Too many arguments specified\n";
1571 }
1572 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1574 if (!$file_type && !$diff_status) {
1576 print STDERR "svn: '$path' is not under version control\n";
1577 exit 1;
1578 }
1579 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1581 unless ($gs) {
1582 die "Unable to determine upstream SVN information from ",
1583 "working tree history\n";
1584 }
1585 # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1587 $path = "." if $path eq "";
1588 my $full_url = canonicalize_url( add_path_to_url( $url, $path ) );
1590 if ($_url) {
1592 print "$full_url\n";
1593 return;
1594 }
1595 my $result = "Path: $path_arg\n";
1597 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1598 $result .= "URL: $full_url\n";
1599 eval {
1601 my $repos_root = $gs->repos_root;
1602 Git::SVN::remove_username($repos_root);
1603 $result .= "Repository Root: " . canonicalize_url($repos_root) . "\n";
1604 };
1605 if ($@) {
1606 $result .= "Repository Root: (offline)\n";
1607 }
1608 ::_req_svn();
1609 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1610 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1611 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1612 $result .= "Node Kind: " .
1614 ($file_type eq "dir" ? "directory" : "file") . "\n";
1615 my $schedule = $diff_status eq "A"
1617 ? "add"
1618 : ($diff_status eq "D" ? "delete" : "normal");
1619 $result .= "Schedule: $schedule\n";
1620 if ($diff_status eq "A") {
1622 print $result, "\n";
1623 return;
1624 }
1625 my ($lc_author, $lc_rev, $lc_date_utc);
1627 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
1628 my $log = command_output_pipe(@args);
1629 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1630 while (<$log>) {
1631 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1632 $lc_author = $1;
1633 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1634 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
1635 (undef, $lc_rev, undef) = ::extract_metadata($1);
1636 }
1637 }
1638 close $log;
1639 Git::SVN::Log::set_local_timezone();
1641 $result .= "Last Changed Author: $lc_author\n";
1643 $result .= "Last Changed Rev: $lc_rev\n";
1644 $result .= "Last Changed Date: " .
1645 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1646 if ($file_type ne "dir") {
1648 my $text_last_updated_date =
1649 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1650 $result .=
1651 "Text Last Updated: " .
1652 Git::SVN::Log::format_svn_date($text_last_updated_date) .
1653 "\n";
1654 my $checksum;
1655 if ($diff_status eq "D") {
1656 my ($fh, $ctx) =
1657 command_output_pipe(qw(cat-file blob), "HEAD:$path");
1658 if ($file_type eq "link") {
1659 my $file_name = <$fh>;
1660 $checksum = md5sum("link $file_name");
1661 } else {
1662 $checksum = md5sum($fh);
1663 }
1664 command_close_pipe($fh, $ctx);
1665 } elsif ($file_type eq "link") {
1666 my $file_name =
1667 command(qw(cat-file blob), "HEAD:$path");
1668 $checksum =
1669 md5sum("link " . $file_name);
1670 } else {
1671 open FILE, "<", $path or die $!;
1672 $checksum = md5sum(\*FILE);
1673 close FILE or die $!;
1674 }
1675 $result .= "Checksum: " . $checksum . "\n";
1676 }
1677 print $result, "\n";
1679}
1680sub cmd_reset {
1682 my $target = shift || $_revision or die "SVN revision required\n";
1683 $target = $1 if $target =~ /^r(\d+)$/;
1684 $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1685 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1686 unless ($gs) {
1687 die "Unable to determine upstream SVN information from ".
1688 "history\n";
1689 }
1690 my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1691 die "Cannot find SVN revision $target\n" unless defined($c);
1692 $gs->rev_map_set($r, $c, 'reset', $uuid);
1693 print "r$r = $c ($gs->{ref_id})\n";
1694}
1695sub cmd_gc {
1697 require File::Find;
1698 if (!can_compress()) {
1699 warn "Compress::Zlib could not be found; unhandled.log " .
1700 "files will not be compressed.\n";
1701 }
1702 File::Find::find({ wanted => \&gc_directory, no_chdir => 1},
1703 "$ENV{GIT_DIR}/svn");
1704}
1705########################### utility functions #########################
1707sub rebase_cmd {
1709 my @cmd = qw/rebase/;
1710 push @cmd, '-v' if $_verbose;
1711 push @cmd, qw/--merge/ if $_merge;
1712 push @cmd, "--strategy=$_strategy" if $_strategy;
1713 push @cmd, "--preserve-merges" if $_preserve_merges;
1714 @cmd;
1715}
1716sub post_fetch_checkout {
1718 return if $_no_checkout;
1719 return if verify_ref('HEAD^0');
1720 my $gs = $Git::SVN::_head or return;
1721 # look for "trunk" ref if it exists
1723 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1724 my $fetch = $remote->{fetch};
1725 if ($fetch) {
1726 foreach my $p (keys %$fetch) {
1727 basename($fetch->{$p}) eq 'trunk' or next;
1728 $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1729 last;
1730 }
1731 }
1732 command_noisy(qw(update-ref HEAD), $gs->refname);
1734 return unless verify_ref('HEAD^0');
1735 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1737 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1738 return if -f $index;
1739 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1741 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1742 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1743 print STDERR "Checked out HEAD:\n ",
1744 $gs->full_url, " r", $gs->last_rev, "\n";
1745 if (auto_create_empty_directories($gs)) {
1746 $gs->mkemptydirs($gs->last_rev);
1747 }
1748}
1749sub complete_svn_url {
1751 my ($url, $path) = @_;
1752 if ($path =~ m#^[a-z\+]+://#i) { # path is a URL
1754 $path = canonicalize_url($path);
1755 } else {
1756 $path = canonicalize_path($path);
1757 if (!defined $url || $url !~ m#^[a-z\+]+://#i) {
1758 fatal("E: '$path' is not a complete URL ",
1759 "and a separate URL is not specified");
1760 }
1761 return ($url, $path);
1762 }
1763 return ($path, '');
1764}
1765sub complete_url_ls_init {
1767 my ($ra, $repo_path, $switch, $pfx) = @_;
1768 unless ($repo_path) {
1769 print STDERR "W: $switch not specified\n";
1770 return;
1771 }
1772 if ($repo_path =~ m#^[a-z\+]+://#i) {
1773 $repo_path = canonicalize_url($repo_path);
1774 $ra = Git::SVN::Ra->new($repo_path);
1775 $repo_path = '';
1776 } else {
1777 $repo_path = canonicalize_path($repo_path);
1778 $repo_path =~ s#^/+##;
1779 unless ($ra) {
1780 fatal("E: '$repo_path' is not a complete URL ",
1781 "and a separate URL is not specified");
1782 }
1783 }
1784 my $url = $ra->url;
1785 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1786 my $k = "svn-remote.$gs->{repo_id}.url";
1787 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1788 if ($orig_url && ($orig_url ne $gs->url)) {
1789 die "$k already set: $orig_url\n",
1790 "wanted to set to: $gs->url\n";
1791 }
1792 command_oneline('config', $k, $gs->url) unless $orig_url;
1793 my $remote_path = join_paths( $gs->path, $repo_path );
1795 $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1796 $remote_path =~ s#^/##g;
1797 $remote_path .= "/*" if $remote_path !~ /\*/;
1798 my ($n) = ($switch =~ /^--(\w+)/);
1799 if (length $pfx && $pfx !~ m#/$#) {
1800 die "--prefix='$pfx' must have a trailing slash '/'\n";
1801 }
1802 command_noisy('config',
1803 '--add',
1804 "svn-remote.$gs->{repo_id}.$n",
1805 "$remote_path:refs/remotes/$pfx*" .
1806 ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1807}
1808sub verify_ref {
1810 my ($ref) = @_;
1811 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1812 { STDERR => 0 }); };
1813}
1814sub get_tree_from_treeish {
1816 my ($treeish) = @_;
1817 # $treeish can be a symbolic ref, too:
1818 my $type = command_oneline(qw/cat-file -t/, $treeish);
1819 my $expected;
1820 while ($type eq 'tag') {
1821 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1822 }
1823 if ($type eq 'commit') {
1824 $expected = (grep /^tree /, command(qw/cat-file commit/,
1825 $treeish))[0];
1826 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1827 die "Unable to get tree from $treeish\n" unless $expected;
1828 } elsif ($type eq 'tree') {
1829 $expected = $treeish;
1830 } else {
1831 die "$treeish is a $type, expected tree, tag or commit\n";
1832 }
1833 return $expected;
1834}
1835sub get_commit_entry {
1837 my ($treeish) = shift;
1838 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1839 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1840 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1841 open my $log_fh, '>', $commit_editmsg or croak $!;
1842 my $type = command_oneline(qw/cat-file -t/, $treeish);
1844 if ($type eq 'commit' || $type eq 'tag') {
1845 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1846 $type, $treeish);
1847 my $in_msg = 0;
1848 my $author;
1849 my $saw_from = 0;
1850 my $msgbuf = "";
1851 while (<$msg_fh>) {
1852 if (!$in_msg) {
1853 $in_msg = 1 if (/^$/);
1854 $author = $1 if (/^author (.*>)/);
1855 } elsif (/^git-svn-id: /) {
1856 # skip this for now, we regenerate the
1857 # correct one on re-fetch anyways
1858 # TODO: set *:merge properties or like...
1859 } else {
1860 if (/^From:/ || /^Signed-off-by:/) {
1861 $saw_from = 1;
1862 }
1863 $msgbuf .= $_;
1864 }
1865 }
1866 $msgbuf =~ s/\s+$//s;
1867 if ($Git::SVN::_add_author_from && defined($author)
1868 && !$saw_from) {
1869 $msgbuf .= "\n\nFrom: $author";
1870 }
1871 print $log_fh $msgbuf or croak $!;
1872 command_close_pipe($msg_fh, $ctx);
1873 }
1874 close $log_fh or croak $!;
1875 if ($_edit || ($type eq 'tree')) {
1877 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1878 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1879 }
1880 rename $commit_editmsg, $commit_msg or croak $!;
1881 {
1882 require Encode;
1883 # SVN requires messages to be UTF-8 when entering the repo
1884 open $log_fh, '<', $commit_msg or croak $!;
1885 binmode $log_fh;
1886 chomp($log_entry{log} = get_record($log_fh, undef));
1887 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1889 my $msg = $log_entry{log};
1890 eval { $msg = Encode::decode($enc, $msg, 1) };
1892 if ($@) {
1893 die "Could not decode as $enc:\n", $msg,
1894 "\nPerhaps you need to set i18n.commitencoding\n";
1895 }
1896 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1898 die "Could not encode as UTF-8:\n$msg\n" if $@;
1899 $log_entry{log} = $msg;
1901 close $log_fh or croak $!;
1903 }
1904 unlink $commit_msg;
1905 \%log_entry;
1906}
1907sub s_to_file {
1909 my ($str, $file, $mode) = @_;
1910 open my $fd,'>',$file or croak $!;
1911 print $fd $str,"\n" or croak $!;
1912 close $fd or croak $!;
1913 chmod ($mode &~ umask, $file) if (defined $mode);
1914}
1915sub file_to_s {
1917 my $file = shift;
1918 open my $fd,'<',$file or croak "$!: file: $file\n";
1919 local $/;
1920 my $ret = <$fd>;
1921 close $fd or croak $!;
1922 $ret =~ s/\s*$//s;
1923 return $ret;
1924}
1925# '<svn username> = real-name <email address>' mapping based on git-svnimport:
1927sub load_authors {
1928 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1929 my $log = $cmd eq 'log';
1930 while (<$authors>) {
1931 chomp;
1932 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.*)>\s*$/;
1933 my ($user, $name, $email) = ($1, $2, $3);
1934 if ($log) {
1935 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1936 } else {
1937 $users{$user} = [$name, $email];
1938 }
1939 }
1940 close $authors or croak $!;
1941}
1942# convert GetOpt::Long specs for use by git-config
1944sub read_git_config {
1945 my $opts = shift;
1946 my @config_only;
1947 foreach my $o (keys %$opts) {
1948 # if we have mixedCase and a long option-only, then
1949 # it's a config-only variable that we don't need for
1950 # the command-line.
1951 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1952 my $v = $opts->{$o};
1953 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1954 $key =~ s/-//g;
1955 my $arg = 'git config';
1956 $arg .= ' --int' if ($o =~ /[:=]i$/);
1957 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1958 if (ref $v eq 'ARRAY') {
1959 chomp(my @tmp = `$arg --get-all svn.$key`);
1960 @$v = @tmp if @tmp;
1961 } else {
1962 chomp(my $tmp = `$arg --get svn.$key`);
1963 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1964 $$v = $tmp;
1965 }
1966 }
1967 }
1968 delete @$opts{@config_only} if @config_only;
1969}
1970sub extract_metadata {
1972 my $id = shift or return (undef, undef, undef);
1973 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1974 \s([a-f\d\-]+)$/ix);
1975 if (!defined $rev || !$uuid || !$url) {
1976 # some of the original repositories I made had
1977 # identifiers like this:
1978 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1979 }
1980 return ($url, $rev, $uuid);
1981}
1982sub cmt_metadata {
1984 return extract_metadata((grep(/^git-svn-id: /,
1985 command(qw/cat-file commit/, shift)))[-1]);
1986}
1987sub cmt_sha2rev_batch {
1989 my %s2r;
1990 my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1991 my $list = shift;
1992 foreach my $sha (@{$list}) {
1994 my $first = 1;
1995 my $size = 0;
1996 print $out $sha, "\n";
1997 while (my $line = <$in>) {
1999 if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
2000 last;
2001 } elsif ($first &&
2002 $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
2003 $first = 0;
2004 $size = $1;
2005 next;
2006 } elsif ($line =~ /^(git-svn-id: )/) {
2007 my (undef, $rev, undef) =
2008 extract_metadata($line);
2009 $s2r{$sha} = $rev;
2010 }
2011 $size -= length($line);
2013 last if ($size == 0);
2014 }
2015 }
2016 command_close_bidi_pipe($pid, $in, $out, $ctx);
2018 return \%s2r;
2020}
2021sub working_head_info {
2023 my ($head, $refs) = @_;
2024 my @args = qw/rev-list --first-parent --pretty=medium/;
2025 my ($fh, $ctx) = command_output_pipe(@args, $head, "--");
2026 my $hash;
2027 my %max;
2028 while (<$fh>) {
2029 if ( m{^commit ($::sha1)$} ) {
2030 unshift @$refs, $hash if $hash and $refs;
2031 $hash = $1;
2032 next;
2033 }
2034 next unless s{^\s*(git-svn-id:)}{$1};
2035 my ($url, $rev, $uuid) = extract_metadata($_);
2036 if (defined $url && defined $rev) {
2037 next if $max{$url} and $max{$url} < $rev;
2038 if (my $gs = Git::SVN->find_by_url($url)) {
2039 my $c = $gs->rev_map_get($rev, $uuid);
2040 if ($c && $c eq $hash) {
2041 close $fh; # break the pipe
2042 return ($url, $rev, $uuid, $gs);
2043 } else {
2044 $max{$url} ||= $gs->rev_map_max;
2045 }
2046 }
2047 }
2048 }
2049 command_close_pipe($fh, $ctx);
2050 (undef, undef, undef, undef);
2051}
2052sub read_commit_parents {
2054 my ($parents, $c) = @_;
2055 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
2056 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
2057 @{$parents->{$c}} = split(/ /, $p);
2058}
2059sub linearize_history {
2061 my ($gs, $refs) = @_;
2062 my %parents;
2063 foreach my $c (@$refs) {
2064 read_commit_parents(\%parents, $c);
2065 }
2066 my @linear_refs;
2068 my %skip = ();
2069 my $last_svn_commit = $gs->last_commit;
2070 foreach my $c (reverse @$refs) {
2071 next if $c eq $last_svn_commit;
2072 last if $skip{$c};
2073 unshift @linear_refs, $c;
2075 $skip{$c} = 1;
2076 # we only want the first parent to diff against for linear
2078 # history, we save the rest to inject when we finalize the
2079 # svn commit
2080 my $fp_a = verify_ref("$c~1");
2081 my $fp_b = shift @{$parents{$c}} if $parents{$c};
2082 if (!$fp_a || !$fp_b) {
2083 die "Commit $c\n",
2084 "has no parent commit, and therefore ",
2085 "nothing to diff against.\n",
2086 "You should be working from a repository ",
2087 "originally created by git-svn\n";
2088 }
2089 if ($fp_a ne $fp_b) {
2090 die "$c~1 = $fp_a, however parsing commit $c ",
2091 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
2092 }
2093 foreach my $p (@{$parents{$c}}) {
2095 $skip{$p} = 1;
2096 }
2097 }
2098 (\@linear_refs, \%parents);
2099}
2100sub find_file_type_and_diff_status {
2102 my ($path) = @_;
2103 return ('dir', '') if $path eq '';
2104 my $diff_output =
2106 command_oneline(qw(diff --cached --name-status --), $path) || "";
2107 my $diff_status = (split(' ', $diff_output))[0] || "";
2108 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
2110 return (undef, undef) if !$diff_status && !$ls_tree;
2112 if ($diff_status eq "A") {
2114 return ("link", $diff_status) if -l $path;
2115 return ("dir", $diff_status) if -d $path;
2116 return ("file", $diff_status);
2117 }
2118 my $mode = (split(' ', $ls_tree))[0] || "";
2120 return ("link", $diff_status) if $mode eq "120000";
2122 return ("dir", $diff_status) if $mode eq "040000";
2123 return ("file", $diff_status);
2124}
2125sub md5sum {
2127 my $arg = shift;
2128 my $ref = ref $arg;
2129 require Digest::MD5;
2130 my $md5 = Digest::MD5->new();
2131 if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2132 $md5->addfile($arg) or croak $!;
2133 } elsif ($ref eq 'SCALAR') {
2134 $md5->add($$arg) or croak $!;
2135 } elsif (!$ref) {
2136 $md5->add($arg) or croak $!;
2137 } else {
2138 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2139 }
2140 return $md5->hexdigest();
2141}
2142sub gc_directory {
2144 if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2145 my $out_filename = $_ . ".gz";
2146 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2147 binmode $in_fh;
2148 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2149 die "Unable to open $out_filename: $!\n";
2150 my $res;
2152 while ($res = sysread($in_fh, my $str, 1024)) {
2153 $gz->gzwrite($str) or
2154 die "Unable to write: ".$gz->gzerror()."!\n";
2155 }
2156 no warnings 'once'; # $File::Find::name would warn
2157 unlink $_ or die "unlink $File::Find::name: $!\n";
2158 } elsif (-f $_ && basename($_) eq "index") {
2159 unlink $_ or die "unlink $_: $!\n";
2160 }
2161}
2162__END__
2164Data structures:
2166$remotes = { # returned by read_all_remotes()
2169 'svn' => {
2170 # svn-remote.svn.url=https://svn.musicpd.org
2171 url => 'https://svn.musicpd.org',
2172 # svn-remote.svn.fetch=mpd/trunk:trunk
2173 fetch => {
2174 'mpd/trunk' => 'trunk',
2175 },
2176 # svn-remote.svn.tags=mpd/tags/*:tags/*
2177 tags => {
2178 path => {
2179 left => 'mpd/tags',
2180 right => '',
2181 regex => qr!mpd/tags/([^/]+)$!,
2182 glob => 'tags/*',
2183 },
2184 ref => {
2185 left => 'tags',
2186 right => '',
2187 regex => qr!tags/([^/]+)$!,
2188 glob => 'tags/*',
2189 },
2190 }
2191 }
2192};
2193$log_entry hashref as returned by libsvn_log_entry()
2195{
2196 log => 'whitespace-formatted log entry
2197', # trailing newline is preserved
2198 revision => '8', # integer
2199 date => '2004-02-24T17:01:44.108345Z', # commit date
2200 author => 'committer name'
2201};
2202# this is generated by generate_diff();
2205@mods = array of diff-index line hashes, each element represents one line
2206 of diff-index output
2207diff-index line ($m hash)
2209{
2210 mode_a => first column of diff-index output, no leading ':',
2211 mode_b => second column of diff-index output,
2212 sha1_b => sha1sum of the final blob,
2213 chg => change type [MCRADT],
2214 file_a => original file name of a file (iff chg is 'C' or 'R')
2215 file_b => new/current file name of a file (any chg)
2216}
2217;
2218# retval of read_url_paths{,_all}();
2220$l_map = {
2221 # repository root url
2222 'https://svn.musicpd.org' => {
2223 # repository path # GIT_SVN_ID
2224 'mpd/trunk' => 'trunk',
2225 'mpd/tags/0.11.5' => 'tags/0.11.5',
2226 },
2227}
2228Notes:
2230 I don't trust the each() function on unless I created %hash myself
2231 because the internal iterator may not have started at base.