d3fbcbc15cc2f251fe22c8995f962bc609456d1a
1#!/usr/bin/perl -w
2# This tool is copyright (c) 2005, Matthias Urlichs.
4# It is released under the Gnu Public License, version 2.
5#
6# The basic idea is to aggregate CVS check-ins into related changes.
7# Fortunately, "cvsps" does that for us; all we have to do is to parse
8# its output.
9#
10# Checking out the files is done by a single long-running CVS connection
11# / server process.
12#
13# The head revision is on branch "origin" by default.
14# You can change that with the '-o' option.
15use strict;
17use warnings;
18use Getopt::Std;
19use File::Spec;
20use File::Temp qw(tempfile tmpnam);
21use File::Path qw(mkpath);
22use File::Basename qw(basename dirname);
23use Time::Local;
24use IO::Socket;
25use IO::Pipe;
26use POSIX qw(strftime dup2 ENOENT);
27use IPC::Open2;
28$SIG{'PIPE'}="IGNORE";
30$ENV{'TZ'}="UTC";
31our ($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S,$opt_L, $opt_a);
33my (%conv_author_name, %conv_author_email);
34sub usage() {
36 print STDERR <<END;
37Usage: ${\basename $0} # fetch/update GIT from CVS
38 [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
39 [-p opts-for-cvsps] [-P file] [-C GIT_repository] [-z fuzz] [-i] [-k]
40 [-u] [-s subst] [-a] [-m] [-M regex] [-S regex] [-L commitlimit]
41 [CVS_module]
42END
43 exit(1);
44}
45sub read_author_info($) {
47 my ($file) = @_;
48 my $user;
49 open my $f, '<', "$file" or die("Failed to open $file: $!\n");
50 while (<$f>) {
52 # Expected format is this:
53 # exon=Andreas Ericsson <ae@op5.se>
54 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
55 $user = $1;
56 $conv_author_name{$user} = $2;
57 $conv_author_email{$user} = $3;
58 }
59 # However, we also read from CVSROOT/users format
60 # to ease migration.
61 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
62 my $mapped;
63 ($user, $mapped) = ($1, $3);
64 if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
65 $conv_author_name{$user} = $1;
66 $conv_author_email{$user} = $2;
67 }
68 elsif ($mapped =~ /^<?(.*)>?$/) {
69 $conv_author_name{$user} = $user;
70 $conv_author_email{$user} = $1;
71 }
72 }
73 # NEEDSWORK: Maybe warn on unrecognized lines?
74 }
75 close ($f);
76}
77sub write_author_info($) {
79 my ($file) = @_;
80 open my $f, '>', $file or
81 die("Failed to open $file for writing: $!");
82 foreach (keys %conv_author_name) {
84 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
85 }
86 close ($f);
87}
88# convert getopts specs for use by git-repo-config
90sub read_repo_config {
91 # Split the string between characters, unless there is a ':'
92 # So "abc:de" becomes ["a", "b", "c:", "d", "e"]
93 my @opts = split(/ *(?!:)/, shift);
94 foreach my $o (@opts) {
95 my $key = $o;
96 $key =~ s/://g;
97 my $arg = 'git-repo-config';
98 $arg .= ' --bool' if ($o !~ /:$/);
99 chomp(my $tmp = `$arg --get cvsimport.$key`);
101 if ($tmp && !($arg =~ /--bool/ && $tmp eq 'false')) {
102 no strict 'refs';
103 my $opt_name = "opt_" . $key;
104 if (!$$opt_name) {
105 $$opt_name = $tmp;
106 }
107 }
108 }
109 if (@ARGV == 0) {
110 chomp(my $module = `git-repo-config --get cvsimport.module`);
111 push(@ARGV, $module);
112 }
113}
114my $opts = "haivmkuo:d:p:C:z:s:M:P:A:S:L:";
116read_repo_config($opts);
117getopts($opts) or usage();
118usage if $opt_h;
119@ARGV <= 1 or usage();
121if ($opt_d) {
123 $ENV{"CVSROOT"} = $opt_d;
124} elsif (-f 'CVS/Root') {
125 open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
126 $opt_d = <$f>;
127 chomp $opt_d;
128 close $f;
129 $ENV{"CVSROOT"} = $opt_d;
130} elsif ($ENV{"CVSROOT"}) {
131 $opt_d = $ENV{"CVSROOT"};
132} else {
133 die "CVSROOT needs to be set";
134}
135$opt_o ||= "origin";
136$opt_s ||= "-";
137$opt_a ||= 0;
138my $git_tree = $opt_C;
140$git_tree ||= ".";
141my $cvs_tree;
143if ($#ARGV == 0) {
144 $cvs_tree = $ARGV[0];
145} elsif (-f 'CVS/Repository') {
146 open my $f, '<', 'CVS/Repository' or
147 die 'Failed to open CVS/Repository';
148 $cvs_tree = <$f>;
149 chomp $cvs_tree;
150 close $f;
151} else {
152 usage();
153}
154our @mergerx = ();
156if ($opt_m) {
157 @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
158}
159if ($opt_M) {
160 push (@mergerx, qr/$opt_M/);
161}
162# Remember UTC of our starting time
164# we'll want to avoid importing commits
165# that are too recent
166our $starttime = time();
167select(STDERR); $|=1; select(STDOUT);
169package CVSconn;
172# Basic CVS dialog.
173# We're only interested in connecting and downloading, so ...
174use File::Spec;
176use File::Temp qw(tempfile);
177use POSIX qw(strftime dup2);
178sub new {
180 my ($what,$repo,$subdir) = @_;
181 $what=ref($what) if ref($what);
182 my $self = {};
184 $self->{'buffer'} = "";
185 bless($self,$what);
186 $repo =~ s#/+$##;
188 $self->{'fullrep'} = $repo;
189 $self->conn();
190 $self->{'subdir'} = $subdir;
192 $self->{'lines'} = undef;
193 return $self;
195}
196sub conn {
198 my $self = shift;
199 my $repo = $self->{'fullrep'};
200 if ($repo =~ s/^:pserver(?:([^:]*)):(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
201 my ($param,$user,$pass,$serv,$port) = ($1,$2,$3,$4,$5);
202 my ($proxyhost,$proxyport);
204 if ($param && ($param =~ m/proxy=([^;]+)/)) {
205 $proxyhost = $1;
206 # Default proxyport, if not specified, is 8080.
207 $proxyport = 8080;
208 if ($ENV{"CVS_PROXY_PORT"}) {
209 $proxyport = $ENV{"CVS_PROXY_PORT"};
210 }
211 if ($param =~ m/proxyport=([^;]+)/) {
212 $proxyport = $1;
213 }
214 }
215 $user="anonymous" unless defined $user;
217 my $rr2 = "-";
218 unless ($port) {
219 $rr2 = ":pserver:$user\@$serv:$repo";
220 $port=2401;
221 }
222 my $rr = ":pserver:$user\@$serv:$port$repo";
223 unless ($pass) {
225 open(H,$ENV{'HOME'}."/.cvspass") and do {
226 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
227 while (<H>) {
228 chomp;
229 s/^\/\d+\s+//;
230 my ($w,$p) = split(/\s/,$_,2);
231 if ($w eq $rr or $w eq $rr2) {
232 $pass = $p;
233 last;
234 }
235 }
236 };
237 }
238 $pass="A" unless $pass;
239 my ($s, $rep);
241 if ($proxyhost) {
242 # Use a HTTP Proxy. Only works for HTTP proxies that
244 # don't require user authentication
245 #
246 # See: http://www.ietf.org/rfc/rfc2817.txt
247 $s = IO::Socket::INET->new(PeerHost => $proxyhost, PeerPort => $proxyport);
249 die "Socket to $proxyhost: $!\n" unless defined $s;
250 $s->write("CONNECT $serv:$port HTTP/1.1\r\nHost: $serv:$port\r\n\r\n")
251 or die "Write to $proxyhost: $!\n";
252 $s->flush();
253 $rep = <$s>;
255 # The answer should look like 'HTTP/1.x 2yy ....'
257 if (!($rep =~ m#^HTTP/1\.. 2[0-9][0-9]#)) {
258 die "Proxy connect: $rep\n";
259 }
260 # Skip up to the empty line of the proxy server output
261 # including the response headers.
262 while ($rep = <$s>) {
263 last if (!defined $rep ||
264 $rep eq "\n" ||
265 $rep eq "\r\n");
266 }
267 } else {
268 $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
269 die "Socket to $serv: $!\n" unless defined $s;
270 }
271 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
273 or die "Write to $serv: $!\n";
274 $s->flush();
275 $rep = <$s>;
277 if ($rep ne "I LOVE YOU\n") {
279 $rep="<unknown>" unless $rep;
280 die "AuthReply: $rep\n";
281 }
282 $self->{'socketo'} = $s;
283 $self->{'socketi'} = $s;
284 } else { # local or ext: Fork off our own cvs server.
285 my $pr = IO::Pipe->new();
286 my $pw = IO::Pipe->new();
287 my $pid = fork();
288 die "Fork: $!\n" unless defined $pid;
289 my $cvs = 'cvs';
290 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
291 my $rsh = 'rsh';
292 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
293 my @cvs = ($cvs, 'server');
295 my ($local, $user, $host);
296 $local = $repo =~ s/:local://;
297 if (!$local) {
298 $repo =~ s/:ext://;
299 $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
300 ($user, $host) = ($1, $2);
301 }
302 if (!$local) {
303 if ($user) {
304 unshift @cvs, $rsh, '-l', $user, $host;
305 } else {
306 unshift @cvs, $rsh, $host;
307 }
308 }
309 unless ($pid) {
311 $pr->writer();
312 $pw->reader();
313 dup2($pw->fileno(),0);
314 dup2($pr->fileno(),1);
315 $pr->close();
316 $pw->close();
317 exec(@cvs);
318 }
319 $pw->writer();
320 $pr->reader();
321 $self->{'socketo'} = $pw;
322 $self->{'socketi'} = $pr;
323 }
324 $self->{'socketo'}->write("Root $repo\n");
325 # Trial and error says that this probably is the minimum set
327 $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
328 $self->{'socketo'}->write("valid-requests\n");
330 $self->{'socketo'}->flush();
331 chomp(my $rep=$self->readline());
333 if ($rep !~ s/^Valid-requests\s*//) {
334 $rep="<unknown>" unless $rep;
335 die "Expected Valid-requests from server, but got: $rep\n";
336 }
337 chomp(my $res=$self->readline());
338 die "validReply: $res\n" if $res ne "ok";
339 $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
341 $self->{'repo'} = $repo;
342}
343sub readline {
345 my ($self) = @_;
346 return $self->{'socketi'}->getline();
347}
348sub _file {
350 # Request a file with a given revision.
351 # Trial and error says this is a good way to do it. :-/
352 my ($self,$fn,$rev) = @_;
353 $self->{'socketo'}->write("Argument -N\n") or return undef;
354 $self->{'socketo'}->write("Argument -P\n") or return undef;
355 # -kk: Linus' version doesn't use it - defaults to off
356 if ($opt_k) {
357 $self->{'socketo'}->write("Argument -kk\n") or return undef;
358 }
359 $self->{'socketo'}->write("Argument -r\n") or return undef;
360 $self->{'socketo'}->write("Argument $rev\n") or return undef;
361 $self->{'socketo'}->write("Argument --\n") or return undef;
362 $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
363 $self->{'socketo'}->write("Directory .\n") or return undef;
364 $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
365 # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
366 $self->{'socketo'}->write("co\n") or return undef;
367 $self->{'socketo'}->flush() or return undef;
368 $self->{'lines'} = 0;
369 return 1;
370}
371sub _line {
372 # Read a line from the server.
373 # ... except that 'line' may be an entire file. ;-)
374 my ($self, $fh) = @_;
375 die "Not in lines" unless defined $self->{'lines'};
376 my $line;
378 my $res=0;
379 while (defined($line = $self->readline())) {
380 # M U gnupg-cvs-rep/AUTHORS
381 # Updated gnupg-cvs-rep/
382 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
383 # /AUTHORS/1.1///T1.1
384 # u=rw,g=rw,o=rw
385 # 0
386 # ok
387 if ($line =~ s/^(?:Created|Updated) //) {
389 $line = $self->readline(); # path
390 $line = $self->readline(); # Entries line
391 my $mode = $self->readline(); chomp $mode;
392 $self->{'mode'} = $mode;
393 defined (my $cnt = $self->readline())
394 or die "EOF from server after 'Changed'\n";
395 chomp $cnt;
396 die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
397 $line="";
398 $res = $self->_fetchfile($fh, $cnt);
399 } elsif ($line =~ s/^ //) {
400 print $fh $line;
401 $res += length($line);
402 } elsif ($line =~ /^M\b/) {
403 # output, do nothing
404 } elsif ($line =~ /^Mbinary\b/) {
405 my $cnt;
406 die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
407 chomp $cnt;
408 die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
409 $line="";
410 $res += $self->_fetchfile($fh, $cnt);
411 } else {
412 chomp $line;
413 if ($line eq "ok") {
414 # print STDERR "S: ok (".length($res).")\n";
415 return $res;
416 } elsif ($line =~ s/^E //) {
417 # print STDERR "S: $line\n";
418 } elsif ($line =~ /^(Remove-entry|Removed) /i) {
419 $line = $self->readline(); # filename
420 $line = $self->readline(); # OK
421 chomp $line;
422 die "Unknown: $line" if $line ne "ok";
423 return -1;
424 } else {
425 die "Unknown: $line\n";
426 }
427 }
428 }
429 return undef;
430}
431sub file {
432 my ($self,$fn,$rev) = @_;
433 my $res;
434 my ($fh, $name) = tempfile('gitcvs.XXXXXX',
436 DIR => File::Spec->tmpdir(), UNLINK => 1);
437 $self->_file($fn,$rev) and $res = $self->_line($fh);
439 if (!defined $res) {
441 print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
442 truncate $fh, 0;
443 $self->conn();
444 $self->_file($fn,$rev) or die "No file command send";
445 $res = $self->_line($fh);
446 die "Retry failed" unless defined $res;
447 }
448 close ($fh);
449 return ($name, $res);
451}
452sub _fetchfile {
453 my ($self, $fh, $cnt) = @_;
454 my $res = 0;
455 my $bufsize = 1024 * 1024;
456 while ($cnt) {
457 if ($bufsize > $cnt) {
458 $bufsize = $cnt;
459 }
460 my $buf;
461 my $num = $self->{'socketi'}->read($buf,$bufsize);
462 die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
463 print $fh $buf;
464 $res += $num;
465 $cnt -= $num;
466 }
467 return $res;
468}
469package main;
472my $cvs = CVSconn->new($opt_d, $cvs_tree);
474sub pdate($) {
477 my ($d) = @_;
478 m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
479 or die "Unparseable date: $d\n";
480 my $y=$1; $y-=1900 if $y>1900;
481 return timegm($6||0,$5,$4,$3,$2-1,$y);
482}
483sub pmode($) {
485 my ($mode) = @_;
486 my $m = 0;
487 my $mm = 0;
488 my $um = 0;
489 for my $x(split(//,$mode)) {
490 if ($x eq ",") {
491 $m |= $mm&$um;
492 $mm = 0;
493 $um = 0;
494 } elsif ($x eq "u") { $um |= 0700;
495 } elsif ($x eq "g") { $um |= 0070;
496 } elsif ($x eq "o") { $um |= 0007;
497 } elsif ($x eq "r") { $mm |= 0444;
498 } elsif ($x eq "w") { $mm |= 0222;
499 } elsif ($x eq "x") { $mm |= 0111;
500 } elsif ($x eq "=") { # do nothing
501 } else { die "Unknown mode: $mode\n";
502 }
503 }
504 $m |= $mm&$um;
505 return $m;
506}
507sub getwd() {
509 my $pwd = `pwd`;
510 chomp $pwd;
511 return $pwd;
512}
513sub is_sha1 {
515 my $s = shift;
516 return $s =~ /^[a-f0-9]{40}$/;
517}
518sub get_headref ($$) {
520 my $name = shift;
521 my $git_dir = shift;
522
523 my $f = "$git_dir/refs/heads/$name";
524 if (open(my $fh, $f)) {
525 chomp(my $r = <$fh>);
526 is_sha1($r) or die "Cannot get head id for $name ($r): $!";
527 return $r;
528 }
529 die "unable to open $f: $!" unless $! == POSIX::ENOENT;
530 return undef;
531}
532-d $git_tree
534 or mkdir($git_tree,0777)
535 or die "Could not create $git_tree: $!";
536chdir($git_tree);
537my $last_branch = "";
539my $orig_branch = "";
540my %branch_date;
541my $tip_at_start = undef;
542my $git_dir = $ENV{"GIT_DIR"} || ".git";
544$git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
545$ENV{"GIT_DIR"} = $git_dir;
546my $orig_git_index;
547$orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
548my %index; # holds filenames of one index per branch
550unless (-d $git_dir) {
552 system("git-init");
553 die "Cannot init the GIT db at $git_tree: $?\n" if $?;
554 system("git-read-tree");
555 die "Cannot init an empty tree: $?\n" if $?;
556 $last_branch = $opt_o;
558 $orig_branch = "";
559} else {
560 -f "$git_dir/refs/heads/$opt_o"
561 or die "Branch '$opt_o' does not exist.\n".
562 "Either use the correct '-o branch' option,\n".
563 "or import to a new repository.\n";
564 open(F, "git-symbolic-ref HEAD |") or
566 die "Cannot run git-symbolic-ref: $!\n";
567 chomp ($last_branch = <F>);
568 $last_branch = basename($last_branch);
569 close(F);
570 unless ($last_branch) {
571 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
572 $last_branch = "master";
573 }
574 $orig_branch = $last_branch;
575 $tip_at_start = `git-rev-parse --verify HEAD`;
576 # Get the last import timestamps
578 my $fmt = '($ref, $author) = (%(refname), %(author));';
579 open(H, "git-for-each-ref --perl --format='$fmt' refs/heads |") or
580 die "Cannot run git-for-each-ref: $!\n";
581 while (defined(my $entry = <H>)) {
582 my ($ref, $author);
583 eval($entry) || die "cannot eval refs list: $@";
584 my ($head) = ($ref =~ m|^refs/heads/(.*)|);
585 $author =~ /^.*\s(\d+)\s[-+]\d{4}$/;
586 $branch_date{$head} = $1;
587 }
588 close(H);
589}
590-d $git_dir
592 or die "Could not create git subdir ($git_dir).\n";
593# now we read (and possibly save) author-info as well
595-f "$git_dir/cvs-authors" and
596 read_author_info("$git_dir/cvs-authors");
597if ($opt_A) {
598 read_author_info($opt_A);
599 write_author_info("$git_dir/cvs-authors");
600}
601#
604# run cvsps into a file unless we are getting
605# it passed as a file via $opt_P
606#
607my $cvspsfile;
608unless ($opt_P) {
609 print "Running cvsps...\n" if $opt_v;
610 my $pid = open(CVSPS,"-|");
611 my $cvspsfh;
612 die "Cannot fork: $!\n" unless defined $pid;
613 unless ($pid) {
614 my @opt;
615 @opt = split(/,/,$opt_p) if defined $opt_p;
616 unshift @opt, '-z', $opt_z if defined $opt_z;
617 unshift @opt, '-q' unless defined $opt_v;
618 unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
619 push @opt, '--cvs-direct';
620 }
621 exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
622 die "Could not start cvsps: $!\n";
623 }
624 ($cvspsfh, $cvspsfile) = tempfile('gitXXXXXX', SUFFIX => '.cvsps',
625 DIR => File::Spec->tmpdir());
626 while (<CVSPS>) {
627 print $cvspsfh $_;
628 }
629 close CVSPS;
630 close $cvspsfh;
631} else {
632 $cvspsfile = $opt_P;
633}
634open(CVS, "<$cvspsfile") or die $!;
636## cvsps output:
638#---------------------
639#PatchSet 314
640#Date: 1999/09/18 13:03:59
641#Author: wkoch
642#Branch: STABLE-BRANCH-1-0
643#Ancestor branch: HEAD
644#Tag: (none)
645#Log:
646# See ChangeLog: Sat Sep 18 13:03:28 CEST 1999 Werner Koch
647#Members:
648# README:1.57->1.57.2.1
649# VERSION:1.96->1.96.2.1
650#
651#---------------------
652my $state = 0;
654sub update_index (\@\@) {
656 my $old = shift;
657 my $new = shift;
658 open(my $fh, '|-', qw(git-update-index -z --index-info))
659 or die "unable to open git-update-index: $!";
660 print $fh
661 (map { "0 0000000000000000000000000000000000000000\t$_\0" }
662 @$old),
663 (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
664 @$new)
665 or die "unable to write to git-update-index: $!";
666 close $fh
667 or die "unable to write to git-update-index: $!";
668 $? and die "git-update-index reported error: $?";
669}
670sub write_tree () {
672 open(my $fh, '-|', qw(git-write-tree))
673 or die "unable to open git-write-tree: $!";
674 chomp(my $tree = <$fh>);
675 is_sha1($tree)
676 or die "Cannot get tree id ($tree): $!";
677 close($fh)
678 or die "Error running git-write-tree: $?\n";
679 print "Tree ID $tree\n" if $opt_v;
680 return $tree;
681}
682my ($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
684my (@old,@new,@skipped,%ignorebranch);
685# commits that cvsps cannot place anywhere...
687$ignorebranch{'#CVSPS_NO_BRANCH'} = 1;
688sub commit {
690 if ($branch eq $opt_o && !$index{branch} && !get_headref($branch, $git_dir)) {
691 # looks like an initial commit
692 # use the index primed by git-init
693 $ENV{GIT_INDEX_FILE} = '.git/index';
694 $index{$branch} = '.git/index';
695 } else {
696 # use an index per branch to speed up
697 # imports of projects with many branches
698 unless ($index{$branch}) {
699 $index{$branch} = tmpnam();
700 $ENV{GIT_INDEX_FILE} = $index{$branch};
701 if ($ancestor) {
702 system("git-read-tree", $ancestor);
703 } else {
704 system("git-read-tree", $branch);
705 }
706 die "read-tree failed: $?\n" if $?;
707 }
708 }
709 $ENV{GIT_INDEX_FILE} = $index{$branch};
710 update_index(@old, @new);
712 @old = @new = ();
713 my $tree = write_tree();
714 my $parent = get_headref($last_branch, $git_dir);
715 print "Parent ID " . ($parent ? $parent : "(empty)") . "\n" if $opt_v;
716 my @commit_args;
718 push @commit_args, ("-p", $parent) if $parent;
719 # loose detection of merges
721 # based on the commit msg
722 foreach my $rx (@mergerx) {
723 next unless $logmsg =~ $rx && $1;
724 my $mparent = $1 eq 'HEAD' ? $opt_o : $1;
725 if (my $sha1 = get_headref($mparent, $git_dir)) {
726 push @commit_args, '-p', $mparent;
727 print "Merge parent branch: $mparent\n" if $opt_v;
728 }
729 }
730 my $commit_date = strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date));
732 $ENV{GIT_AUTHOR_NAME} = $author_name;
733 $ENV{GIT_AUTHOR_EMAIL} = $author_email;
734 $ENV{GIT_AUTHOR_DATE} = $commit_date;
735 $ENV{GIT_COMMITTER_NAME} = $author_name;
736 $ENV{GIT_COMMITTER_EMAIL} = $author_email;
737 $ENV{GIT_COMMITTER_DATE} = $commit_date;
738 my $pid = open2(my $commit_read, my $commit_write,
739 'git-commit-tree', $tree, @commit_args);
740 # compatibility with git2cvs
742 substr($logmsg,32767) = "" if length($logmsg) > 32767;
743 $logmsg =~ s/[\s\n]+\z//;
744 if (@skipped) {
746 $logmsg .= "\n\n\nSKIPPED:\n\t";
747 $logmsg .= join("\n\t", @skipped) . "\n";
748 @skipped = ();
749 }
750 print($commit_write "$logmsg\n") && close($commit_write)
752 or die "Error writing to git-commit-tree: $!\n";
753 print "Committed patch $patchset ($branch $commit_date)\n" if $opt_v;
755 chomp(my $cid = <$commit_read>);
756 is_sha1($cid) or die "Cannot get commit id ($cid): $!\n";
757 print "Commit ID $cid\n" if $opt_v;
758 close($commit_read);
759 waitpid($pid,0);
761 die "Error running git-commit-tree: $?\n" if $?;
762 system("git-update-ref refs/heads/$branch $cid") == 0
764 or die "Cannot write branch $branch for update: $!\n";
765 if ($tag) {
767 my ($in, $out) = ('','');
768 my ($xtag) = $tag;
769 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
770 $xtag =~ tr/_/\./ if ( $opt_u );
771 $xtag =~ s/[\/]/$opt_s/g;
772
773 my $pid = open2($in, $out, 'git-mktag');
774 print $out "object $cid\n".
775 "type commit\n".
776 "tag $xtag\n".
777 "tagger $author_name <$author_email>\n"
778 or die "Cannot create tag object $xtag: $!\n";
779 close($out)
780 or die "Cannot create tag object $xtag: $!\n";
781 my $tagobj = <$in>;
783 chomp $tagobj;
784 if ( !close($in) or waitpid($pid, 0) != $pid or
786 $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
787 die "Cannot create tag object $xtag: $!\n";
788 }
789
790 open(C,">$git_dir/refs/tags/$xtag")
792 or die "Cannot create tag $xtag: $!\n";
793 print C "$tagobj\n"
794 or die "Cannot write tag $xtag: $!\n";
795 close(C)
796 or die "Cannot write tag $xtag: $!\n";
797 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
799 }
800};
801my $commitcount = 1;
803while (<CVS>) {
804 chomp;
805 if ($state == 0 and /^-+$/) {
806 $state = 1;
807 } elsif ($state == 0) {
808 $state = 1;
809 redo;
810 } elsif (($state==0 or $state==1) and s/^PatchSet\s+//) {
811 $patchset = 0+$_;
812 $state=2;
813 } elsif ($state == 2 and s/^Date:\s+//) {
814 $date = pdate($_);
815 unless ($date) {
816 print STDERR "Could not parse date: $_\n";
817 $state=0;
818 next;
819 }
820 $state=3;
821 } elsif ($state == 3 and s/^Author:\s+//) {
822 s/\s+$//;
823 if (/^(.*?)\s+<(.*)>/) {
824 ($author_name, $author_email) = ($1, $2);
825 } elsif ($conv_author_name{$_}) {
826 $author_name = $conv_author_name{$_};
827 $author_email = $conv_author_email{$_};
828 } else {
829 $author_name = $author_email = $_;
830 }
831 $state = 4;
832 } elsif ($state == 4 and s/^Branch:\s+//) {
833 s/\s+$//;
834 s/[\/]/$opt_s/g;
835 $branch = $_;
836 $state = 5;
837 } elsif ($state == 5 and s/^Ancestor branch:\s+//) {
838 s/\s+$//;
839 $ancestor = $_;
840 $ancestor = $opt_o if $ancestor eq "HEAD";
841 $state = 6;
842 } elsif ($state == 5) {
843 $ancestor = undef;
844 $state = 6;
845 redo;
846 } elsif ($state == 6 and s/^Tag:\s+//) {
847 s/\s+$//;
848 if ($_ eq "(none)") {
849 $tag = undef;
850 } else {
851 $tag = $_;
852 }
853 $state = 7;
854 } elsif ($state == 7 and /^Log:/) {
855 $logmsg = "";
856 $state = 8;
857 } elsif ($state == 8 and /^Members:/) {
858 $branch = $opt_o if $branch eq "HEAD";
859 if (defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
860 # skip
861 print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
862 $state = 11;
863 next;
864 }
865 if (!$opt_a && $starttime - 300 - (defined $opt_z ? $opt_z : 300) <= $date) {
866 # skip if the commit is too recent
867 # that the cvsps default fuzz is 300s, we give ourselves another
868 # 300s just in case -- this also prevents skipping commits
869 # due to server clock drift
870 print "skip patchset $patchset: $date too recent\n" if $opt_v;
871 $state = 11;
872 next;
873 }
874 if (exists $ignorebranch{$branch}) {
875 print STDERR "Skipping $branch\n";
876 $state = 11;
877 next;
878 }
879 if ($ancestor) {
880 if ($ancestor eq $branch) {
881 print STDERR "Branch $branch erroneously stems from itself -- changed ancestor to $opt_o\n";
882 $ancestor = $opt_o;
883 }
884 if (-f "$git_dir/refs/heads/$branch") {
885 print STDERR "Branch $branch already exists!\n";
886 $state=11;
887 next;
888 }
889 unless (open(H,"$git_dir/refs/heads/$ancestor")) {
890 print STDERR "Branch $ancestor does not exist!\n";
891 $ignorebranch{$branch} = 1;
892 $state=11;
893 next;
894 }
895 chomp(my $id = <H>);
896 close(H);
897 unless (open(H,"> $git_dir/refs/heads/$branch")) {
898 print STDERR "Could not create branch $branch: $!\n";
899 $ignorebranch{$branch} = 1;
900 $state=11;
901 next;
902 }
903 print H "$id\n"
904 or die "Could not write branch $branch: $!";
905 close(H)
906 or die "Could not write branch $branch: $!";
907 }
908 $last_branch = $branch if $branch ne $last_branch;
909 $state = 9;
910 } elsif ($state == 8) {
911 $logmsg .= "$_\n";
912 } elsif ($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
913# VERSION:1.96->1.96.2.1
914 my $init = ($2 eq "INITIAL");
915 my $fn = $1;
916 my $rev = $3;
917 $fn =~ s#^/+##;
918 if ($opt_S && $fn =~ m/$opt_S/) {
919 print "SKIPPING $fn v $rev\n";
920 push(@skipped, $fn);
921 next;
922 }
923 print "Fetching $fn v $rev\n" if $opt_v;
924 my ($tmpname, $size) = $cvs->file($fn,$rev);
925 if ($size == -1) {
926 push(@old,$fn);
927 print "Drop $fn\n" if $opt_v;
928 } else {
929 print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
930 my $pid = open(my $F, '-|');
931 die $! unless defined $pid;
932 if (!$pid) {
933 exec("git-hash-object", "-w", $tmpname)
934 or die "Cannot create object: $!\n";
935 }
936 my $sha = <$F>;
937 chomp $sha;
938 close $F;
939 my $mode = pmode($cvs->{'mode'});
940 push(@new,[$mode, $sha, $fn]); # may be resurrected!
941 }
942 unlink($tmpname);
943 } elsif ($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
944 my $fn = $1;
945 $fn =~ s#^/+##;
946 push(@old,$fn);
947 print "Delete $fn\n" if $opt_v;
948 } elsif ($state == 9 and /^\s*$/) {
949 $state = 10;
950 } elsif (($state == 9 or $state == 10) and /^-+$/) {
951 $commitcount++;
952 if ($opt_L && $commitcount > $opt_L) {
953 last;
954 }
955 commit();
956 if (($commitcount & 1023) == 0) {
957 system("git repack -a -d");
958 }
959 $state = 1;
960 } elsif ($state == 11 and /^-+$/) {
961 $state = 1;
962 } elsif (/^-+$/) { # end of unknown-line processing
963 $state = 1;
964 } elsif ($state != 11) { # ignore stuff when skipping
965 print "* UNKNOWN LINE * $_\n";
966 }
967}
968commit() if $branch and $state != 11;
969unless ($opt_P) {
971 unlink($cvspsfile);
972}
973# The heuristic of repacking every 1024 commits can leave a
975# lot of unpacked data. If there is more than 1MB worth of
976# not-packed objects, repack once more.
977my $line = `git-count-objects`;
978if ($line =~ /^(\d+) objects, (\d+) kilobytes$/) {
979 my ($n_objects, $kb) = ($1, $2);
980 1024 < $kb
981 and system("git repack -a -d");
982}
983foreach my $git_index (values %index) {
985 if ($git_index ne '.git/index') {
986 unlink($git_index);
987 }
988}
989if (defined $orig_git_index) {
991 $ENV{GIT_INDEX_FILE} = $orig_git_index;
992} else {
993 delete $ENV{GIT_INDEX_FILE};
994}
995# Now switch back to the branch we were in before all of this happened
997if ($orig_branch) {
998 print "DONE.\n" if $opt_v;
999 if ($opt_i) {
1000 exit 0;
1001 }
1002 my $tip_at_end = `git-rev-parse --verify HEAD`;
1003 if ($tip_at_start ne $tip_at_end) {
1004 for ($tip_at_start, $tip_at_end) { chomp; }
1005 print "Fetched into the current branch.\n" if $opt_v;
1006 system(qw(git-read-tree -u -m),
1007 $tip_at_start, $tip_at_end);
1008 die "Fast-forward update failed: $?\n" if $?;
1009 }
1010 else {
1011 system(qw(git-merge cvsimport HEAD), "refs/heads/$opt_o");
1012 die "Could not merge $opt_o into the current branch.\n" if $?;
1013 }
1014} else {
1015 $orig_branch = "master";
1016 print "DONE; creating $orig_branch branch\n" if $opt_v;
1017 system("git-update-ref", "refs/heads/master", "refs/heads/$opt_o")
1018 unless -f "$git_dir/refs/heads/master";
1019 system('git-update-ref', 'HEAD', "$orig_branch");
1020 unless ($opt_i) {
1021 system('git checkout');
1022 die "checkout failed: $?\n" if $?;
1023 }
1024}