1# git-gui branch merge support
2# Copyright (C) 2006, 2007 Shawn Pearce
3
4namespace eval merge {
5
6proc _can_merge {} {
7 global HEAD commit_type file_states
8
9 if {[string match amend* $commit_type]} {
10 info_popup {Cannot merge while amending.
11
12You must finish amending this commit before starting any type of merge.
13}
14 return 0
15 }
16
17 if {[committer_ident] eq {}} {return 0}
18 if {![lock_index merge]} {return 0}
19
20 # -- Our in memory state should match the repository.
21 #
22 repository_state curType curHEAD curMERGE_HEAD
23 if {$commit_type ne $curType || $HEAD ne $curHEAD} {
24 info_popup {Last scanned state does not match repository state.
25
26Another Git program has modified this repository since the last scan. A rescan must be performed before a merge can be performed.
27
28The rescan will be automatically started now.
29}
30 unlock_index
31 rescan ui_ready
32 return 0
33 }
34
35 foreach path [array names file_states] {
36 switch -glob -- [lindex $file_states($path) 0] {
37 _O {
38 continue; # and pray it works!
39 }
40 U? {
41 error_popup "You are in the middle of a conflicted merge.
42
43File [short_path $path] has merge conflicts.
44
45You must resolve them, add the file, and commit to complete the current merge. Only then can you begin another merge.
46"
47 unlock_index
48 return 0
49 }
50 ?? {
51 error_popup "You are in the middle of a change.
52
53File [short_path $path] is modified.
54
55You should complete the current commit before starting a merge. Doing so will help you abort a failed merge, should the need arise.
56"
57 unlock_index
58 return 0
59 }
60 }
61 }
62
63 return 1
64}
65
66proc _refs {w list} {
67 set r {}
68 foreach i [$w.source.l curselection] {
69 lappend r [lindex [lindex $list $i] 0]
70 }
71 return $r
72}
73
74proc _visualize {w list} {
75 set revs [_refs $w $list]
76 if {$revs eq {}} return
77 lappend revs --not HEAD
78 do_gitk $revs
79}
80
81proc _start {w list} {
82 global HEAD current_branch
83
84 set cmd [list git merge]
85 set names [_refs $w $list]
86 set revcnt [llength $names]
87 append cmd { } $names
88
89 if {$revcnt == 0} {
90 return
91 } elseif {$revcnt == 1} {
92 set unit branch
93 } elseif {$revcnt <= 15} {
94 set unit branches
95
96 if {[tk_dialog \
97 $w.confirm_octopus \
98 [wm title $w] \
99 "Use octopus merge strategy?
100
101You are merging $revcnt branches at once. This requires using the octopus merge driver, which may not succeed if there are file-level conflicts.
102" \
103 question \
104 0 \
105 {Cancel} \
106 {Use octopus} \
107 ] != 1} return
108 } else {
109 tk_messageBox \
110 -icon error \
111 -type ok \
112 -title [wm title $w] \
113 -parent $w \
114 -message "Too many branches selected.
115
116You have requested to merge $revcnt branches in an octopus merge. This exceeds Git's internal limit of 15 branches per merge.
117
118Please select fewer branches. To merge more than 15 branches, merge the branches in batches.
119"
120 return
121 }
122
123 set msg "Merging $current_branch, [join $names {, }]"
124 ui_status "$msg..."
125 set cons [console::new "Merge" $msg]
126 console::exec $cons $cmd \
127 [namespace code [list _finish $revcnt $cons]]
128
129 wm protocol $w WM_DELETE_WINDOW {}
130 destroy $w
131}
132
133proc _finish {revcnt w ok} {
134 console::done $w $ok
135 if {$ok} {
136 set msg {Merge completed successfully.}
137 } else {
138 if {$revcnt != 1} {
139 info_popup "Octopus merge failed.
140
141Your merge of $revcnt branches has failed.
142
143There are file-level conflicts between the branches which must be resolved manually.
144
145The working directory will now be reset.
146
147You can attempt this merge again by merging only one branch at a time." $w
148
149 set fd [git_read read-tree --reset -u HEAD]
150 fconfigure $fd -blocking 0 -translation binary
151 fileevent $fd readable \
152 [namespace code [list _reset_wait $fd]]
153 ui_status {Aborting... please wait...}
154 return
155 }
156
157 set msg {Merge failed. Conflict resolution is required.}
158 }
159 unlock_index
160 rescan [list ui_status $msg]
161}
162
163proc dialog {} {
164 global current_branch
165 global M1B
166
167 if {![_can_merge]} return
168
169 set fmt {list %(objectname) %(*objectname) %(refname) %(subject)}
170 set fr_fd [git_read for-each-ref \
171 --tcl \
172 --format=$fmt \
173 refs/heads \
174 refs/remotes \
175 refs/tags \
176 ]
177 fconfigure $fr_fd -translation binary
178 while {[gets $fr_fd line] > 0} {
179 set line [eval $line]
180 set ref [lindex $line 2]
181 regsub ^refs/(heads|remotes|tags)/ $ref {} ref
182 set subj($ref) [lindex $line 3]
183 lappend sha1([lindex $line 0]) $ref
184 if {[lindex $line 1] ne {}} {
185 lappend sha1([lindex $line 1]) $ref
186 }
187 }
188 close $fr_fd
189
190 set to_show {}
191 set fr_fd [git_read rev-list --all --not HEAD]
192 while {[gets $fr_fd line] > 0} {
193 if {[catch {set ref $sha1($line)}]} continue
194 foreach n $ref {
195 lappend to_show [list $n $line]
196 }
197 }
198 close $fr_fd
199 set to_show [lsort -unique $to_show]
200
201 set w .merge_setup
202 toplevel $w
203 wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
204
205 set _visualize [namespace code [list _visualize $w $to_show]]
206 set _start [namespace code [list _start $w $to_show]]
207
208 label $w.header \
209 -text "Merge Into $current_branch" \
210 -font font_uibold
211 pack $w.header -side top -fill x
212
213 frame $w.buttons
214 button $w.buttons.visualize -text Visualize -command $_visualize
215 pack $w.buttons.visualize -side left
216 button $w.buttons.create -text Merge -command $_start
217 pack $w.buttons.create -side right
218 button $w.buttons.cancel \
219 -text {Cancel} \
220 -command "unlock_index;destroy $w"
221 pack $w.buttons.cancel -side right -padx 5
222 pack $w.buttons -side bottom -fill x -pady 10 -padx 10
223
224 labelframe $w.source -text {Source Branches}
225 listbox $w.source.l \
226 -height 10 \
227 -width 70 \
228 -font font_diff \
229 -selectmode extended \
230 -yscrollcommand [list $w.source.sby set]
231 scrollbar $w.source.sby -command [list $w.source.l yview]
232 pack $w.source.sby -side right -fill y
233 pack $w.source.l -side left -fill both -expand 1
234 pack $w.source -fill both -expand 1 -pady 5 -padx 5
235
236 foreach ref $to_show {
237 set n [lindex $ref 0]
238 if {[string length $n] > 20} {
239 set n "[string range $n 0 16]..."
240 }
241 $w.source.l insert end [format {%s %-20s %s} \
242 [string range [lindex $ref 1] 0 5] \
243 $n \
244 $subj([lindex $ref 0])]
245 }
246
247 bind $w.source.l <Key-K> [list event generate %W <Shift-Key-Up>]
248 bind $w.source.l <Key-J> [list event generate %W <Shift-Key-Down>]
249 bind $w.source.l <Key-k> [list event generate %W <Key-Up>]
250 bind $w.source.l <Key-j> [list event generate %W <Key-Down>]
251 bind $w.source.l <Key-h> [list event generate %W <Key-Left>]
252 bind $w.source.l <Key-l> [list event generate %W <Key-Right>]
253 bind $w.source.l <Key-v> $_visualize
254
255 bind $w <$M1B-Key-Return> $_start
256 bind $w <Visibility> "grab $w; focus $w.source.l"
257 bind $w <Key-Escape> "unlock_index;destroy $w"
258 wm protocol $w WM_DELETE_WINDOW "unlock_index;destroy $w"
259 wm title $w "[appname] ([reponame]): Merge"
260 tkwait window $w
261}
262
263proc reset_hard {} {
264 global HEAD commit_type file_states
265
266 if {[string match amend* $commit_type]} {
267 info_popup {Cannot abort while amending.
268
269You must finish amending this commit.
270}
271 return
272 }
273
274 if {![lock_index abort]} return
275
276 if {[string match *merge* $commit_type]} {
277 set op merge
278 } else {
279 set op commit
280 }
281
282 if {[ask_popup "Abort $op?
283
284Aborting the current $op will cause *ALL* uncommitted changes to be lost.
285
286Continue with aborting the current $op?"] eq {yes}} {
287 set fd [git_read read-tree --reset -u HEAD]
288 fconfigure $fd -blocking 0 -translation binary
289 fileevent $fd readable [namespace code [list _reset_wait $fd]]
290 ui_status {Aborting... please wait...}
291 } else {
292 unlock_index
293 }
294}
295
296proc _reset_wait {fd} {
297 global ui_comm
298
299 read $fd
300 if {[eof $fd]} {
301 close $fd
302 unlock_index
303
304 $ui_comm delete 0.0 end
305 $ui_comm edit modified false
306
307 catch {file delete [gitdir MERGE_HEAD]}
308 catch {file delete [gitdir rr-cache MERGE_RR]}
309 catch {file delete [gitdir SQUASH_MSG]}
310 catch {file delete [gitdir MERGE_MSG]}
311 catch {file delete [gitdir GITGUI_MSG]}
312
313 rescan {ui_status {Abort completed. Ready.}}
314 }
315}
316
317}