Andrew's git - gitweb.git/blob

   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_ERROR([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  47                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  48        fi; \
  49fi; \
  50]) # GIT_CONF_APPEND_PATH
  51#
  52# GIT_PARSE_WITH(PACKAGE)
  53# -----------------------
  54# For use in AC_ARG_WITH action-if-found, for packages default ON.
  55# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  56# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  57# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  58AC_DEFUN([GIT_PARSE_WITH],
  59[PACKAGE=m4_toupper($1); \
  60if test "$withval" = "no"; then \
  61        m4_toupper(NO_$1)=YesPlease; \
  62elif test "$withval" = "yes"; then \
  63        m4_toupper(NO_$1)=; \
  64else \
  65        m4_toupper(NO_$1)=; \
  66        m4_toupper($1)DIR=$withval; \
  67        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  68        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  69fi \
  70])# GIT_PARSE_WITH
  71#
  72# GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  73# ---------------------
  74# Set VAR to the value specied by --with-WITHNAME.
  75# No verification of arguments is performed, but warnings are issued
  76# if either 'yes' or 'no' is specified.
  77# HELP_TEXT is presented when --help is called.
  78# This is a direct way to allow setting variables in the Makefile.
  79AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  80[AC_ARG_WITH([$1],
  81 [AS_HELP_STRING([--with-$1=VALUE], $3)],
  82 if test -n "$withval"; then \
  83  if test "$withval" = "yes" -o "$withval" = "no"; then \
  84    AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  85                     [a value for $1 ($2).  Maybe you do...?]); \
  86  fi; \
  87  \
  88  AC_MSG_NOTICE([Setting $2 to $withval]); \
  89  GIT_CONF_APPEND_LINE($2=$withval); \
  90 fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
  91
  92dnl
  93dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
  94dnl -----------------------------------------
  95dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
  96dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
  97dnl -Wall), it does not work.  By looking for function definition in
  98dnl libraries, this problem can be worked around.
  99AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 100  AC_SEARCH_LIBS([$1],,
 101  [$2],[$3])
 102],[$3])])
 103
 104dnl
 105dnl GIT_STASH_FLAGS(BASEPATH_VAR)
 106dnl -----------------------------
 107dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 108dnl tests that may want to take user settings into account.
 109AC_DEFUN([GIT_STASH_FLAGS],[
 110if test -n "$1"; then
 111   old_CPPFLAGS="$CPPFLAGS"
 112   old_LDFLAGS="$LDFLAGS"
 113   CPPFLAGS="-I$1/include $CPPFLAGS"
 114   LDFLAGS="-L$1/$lib $LDFLAGS"
 115fi
 116])
 117
 118dnl
 119dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 120dnl -----------------------------
 121dnl Restore the stashed *FLAGS values.
 122AC_DEFUN([GIT_UNSTASH_FLAGS],[
 123if test -n "$1"; then
 124   CPPFLAGS="$old_CPPFLAGS"
 125   LDFLAGS="$old_LDFLAGS"
 126fi
 127])
 128
 129## Site configuration related to programs (before tests)
 130## --with-PACKAGE[=ARG] and --without-PACKAGE
 131#
 132# Set lib to alternative name of lib directory (e.g. lib64)
 133AC_ARG_WITH([lib],
 134 [AS_HELP_STRING([--with-lib=ARG],
 135                 [ARG specifies alternative name for lib directory])],
 136 [if test "$withval" = "no" || test "$withval" = "yes"; then \
 137        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 138else \
 139        lib=$withval; \
 140        AC_MSG_NOTICE([Setting lib to '$lib']); \
 141        GIT_CONF_APPEND_LINE(lib=$withval); \
 142fi; \
 143],[])
 144
 145if test -z "$lib"; then
 146   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 147   lib=lib
 148fi
 149
 150AC_ARG_ENABLE([pthreads],
 151 [AS_HELP_STRING([--enable-pthreads=FLAGS],
 152  [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 153  [The default if FLAGS is not specified is to try first -pthread]
 154  [and then -lpthread.]
 155  [--without-pthreads will disable threading.])],
 156[
 157if test "x$enableval" = "xyes"; then
 158   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 159elif test "x$enableval" != "xno"; then
 160   PTHREAD_CFLAGS=$enableval
 161   AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 162else
 163   AC_MSG_NOTICE([POSIX Threads will be disabled.])
 164   NO_PTHREADS=YesPlease
 165   USER_NOPTHREAD=1
 166fi],
 167[
 168   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 169])
 170
 171## Site configuration (override autodetection)
 172## --with-PACKAGE[=ARG] and --without-PACKAGE
 173AC_MSG_NOTICE([CHECKS for site configuration])
 174#
 175# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 176# tests.  These tests take up a significant amount of the total test time
 177# but are not needed unless you plan to talk to SVN repos.
 178#
 179# Define PPC_SHA1 environment variable when running make to make use of
 180# a bundled SHA1 routine optimized for PowerPC.
 181#
 182# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 183# This also implies BLK_SHA1.
 184#
 185# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 186# /foo/bar/include and /foo/bar/lib directories.
 187AC_ARG_WITH(openssl,
 188AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 189AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 190GIT_PARSE_WITH(openssl))
 191#
 192# Define NO_CURL if you do not have curl installed.  git-http-pull and
 193# git-http-push are not built, and you cannot use http:// and https://
 194# transports.
 195#
 196# Define CURLDIR=/foo/bar if your curl header and library files are in
 197# /foo/bar/include and /foo/bar/lib directories.
 198AC_ARG_WITH(curl,
 199AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 200AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 201GIT_PARSE_WITH(curl))
 202#
 203# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 204# not built, and you cannot push using http:// and https:// transports.
 205#
 206# Define EXPATDIR=/foo/bar if your expat header and library files are in
 207# /foo/bar/include and /foo/bar/lib directories.
 208AC_ARG_WITH(expat,
 209AS_HELP_STRING([--with-expat],
 210[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 211AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 212GIT_PARSE_WITH(expat))
 213#
 214# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 215# installed in /sw, but don't want GIT to link against any libraries
 216# installed there.  If defined you may specify your own (or Fink's)
 217# include directories and library directories by defining CFLAGS
 218# and LDFLAGS appropriately.
 219#
 220# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 221# have DarwinPorts installed in /opt/local, but don't want GIT to
 222# link against any libraries installed there.  If defined you may
 223# specify your own (or DarwinPort's) include directories and
 224# library directories by defining CFLAGS and LDFLAGS appropriately.
 225#
 226# Define NO_MMAP if you want to avoid mmap.
 227#
 228# Define NO_ICONV if your libc does not properly support iconv.
 229AC_ARG_WITH(iconv,
 230AS_HELP_STRING([--without-iconv],
 231[if your architecture doesn't properly support iconv])
 232AS_HELP_STRING([--with-iconv=PATH],
 233[PATH is prefix for libiconv library and headers])
 234AS_HELP_STRING([],
 235[used only if you need linking with libiconv]),
 236GIT_PARSE_WITH(iconv))
 237
 238## --enable-FEATURE[=ARG] and --disable-FEATURE
 239#
 240# Define USE_NSEC below if you want git to care about sub-second file mtimes
 241# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 242# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 243# randomly break unless your underlying filesystem supports those sub-second
 244# times (my ext3 doesn't).
 245#
 246# Define USE_STDEV below if you want git to care about the underlying device
 247# change being considered an inode change from the update-index perspective.
 248
 249#
 250# Define SHELL_PATH to provide path to shell.
 251GIT_ARG_SET_PATH(shell)
 252#
 253# Define PERL_PATH to provide path to Perl.
 254GIT_ARG_SET_PATH(perl)
 255#
 256# Define ZLIB_PATH to provide path to zlib.
 257GIT_ARG_SET_PATH(zlib)
 258#
 259# Declare the with-tcltk/without-tcltk options.
 260AC_ARG_WITH(tcltk,
 261AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 262AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 263AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 264AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 265GIT_PARSE_WITH(tcltk))
 266#
 267
 268
 269## Checks for programs.
 270AC_MSG_NOTICE([CHECKS for programs])
 271#
 272AC_PROG_CC([cc gcc])
 273# which switch to pass runtime path to dynamic libraries to the linker
 274AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 275   SAVE_LDFLAGS="${LDFLAGS}"
 276   LDFLAGS="${SAVE_LDFLAGS} -R /"
 277   AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 278   LDFLAGS="${SAVE_LDFLAGS}"
 279])
 280if test "$git_cv_ld_dashr" = "yes"; then
 281   AC_SUBST(CC_LD_DYNPATH, [-R])
 282else
 283   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 284      SAVE_LDFLAGS="${LDFLAGS}"
 285      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 286      AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 287      LDFLAGS="${SAVE_LDFLAGS}"
 288   ])
 289   if test "$git_cv_ld_wl_rpath" = "yes"; then
 290      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 291   else
 292      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 293         SAVE_LDFLAGS="${LDFLAGS}"
 294         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 295         AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 296         LDFLAGS="${SAVE_LDFLAGS}"
 297      ])
 298      if test "$git_cv_ld_rpath" = "yes"; then
 299         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 300      else
 301         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 302      fi
 303   fi
 304fi
 305#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 306AC_CHECK_TOOLS(AR, [gar ar], :)
 307AC_CHECK_PROGS(TAR, [gtar tar])
 308# TCLTK_PATH will be set to some value if we want Tcl/Tk
 309# or will be empty otherwise.
 310if test -z "$NO_TCLTK"; then
 311  if test "$with_tcltk" = ""; then
 312  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 313    TCLTK_PATH=wish
 314    AC_SUBST(TCLTK_PATH)
 315  elif test "$with_tcltk" = "yes"; then
 316  # Tcl/Tk check requested.
 317    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 318  else
 319    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 320    TCLTK_PATH="$with_tcltk"
 321    AC_SUBST(TCLTK_PATH)
 322  fi
 323fi
 324AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 325if test -n "$ASCIIDOC"; then
 326        AC_MSG_CHECKING([for asciidoc version])
 327        asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 328        case "${asciidoc_version}" in
 329        asciidoc' '8*)
 330                ASCIIDOC8=YesPlease
 331                AC_MSG_RESULT([${asciidoc_version} > 7])
 332                ;;
 333        asciidoc' '7*)
 334                ASCIIDOC8=
 335                AC_MSG_RESULT([${asciidoc_version}])
 336                ;;
 337        *)
 338                ASCIIDOC8=
 339                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 340                ;;
 341        esac
 342fi
 343AC_SUBST(ASCIIDOC8)
 344
 345
 346## Checks for libraries.
 347AC_MSG_NOTICE([CHECKS for libraries])
 348#
 349# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 350# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 351
 352GIT_STASH_FLAGS($OPENSSLDIR)
 353
 354AC_CHECK_LIB([crypto], [SHA1_Init],
 355[NEEDS_SSL_WITH_CRYPTO=],
 356[AC_CHECK_LIB([ssl], [SHA1_Init],
 357 [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 358 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 359
 360GIT_UNSTASH_FLAGS($OPENSSLDIR)
 361
 362AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 363AC_SUBST(NO_OPENSSL)
 364
 365#
 366# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 367# git-http-push are not built, and you cannot use http:// and https://
 368# transports.
 369
 370GIT_STASH_FLAGS($CURLDIR)
 371
 372AC_CHECK_LIB([curl], [curl_global_init],
 373[NO_CURL=],
 374[NO_CURL=YesPlease])
 375
 376GIT_UNSTASH_FLAGS($CURLDIR)
 377
 378AC_SUBST(NO_CURL)
 379
 380#
 381# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 382# not built, and you cannot push using http:// and https:// transports.
 383
 384GIT_STASH_FLAGS($EXPATDIR)
 385
 386AC_CHECK_LIB([expat], [XML_ParserCreate],
 387[NO_EXPAT=],
 388[NO_EXPAT=YesPlease])
 389
 390GIT_UNSTASH_FLAGS($EXPATDIR)
 391
 392AC_SUBST(NO_EXPAT)
 393
 394#
 395# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 396# some Solaris installations).
 397# Define NO_ICONV if neither libc nor libiconv support iconv.
 398
 399if test -z "$NO_ICONV"; then
 400
 401GIT_STASH_FLAGS($ICONVDIR)
 402
 403AC_DEFUN([ICONVTEST_SRC], [
 404#include <iconv.h>
 405
 406int main(void)
 407{
 408        iconv_open("", "");
 409        return 0;
 410}
 411])
 412
 413if test -n "$ICONVDIR"; then
 414   lib_order="-liconv -lc"
 415else
 416   lib_order="-lc -liconv"
 417fi
 418
 419NO_ICONV=YesPlease
 420
 421for l in $lib_order; do
 422    if test "$l" = "-liconv"; then
 423       NEEDS_LIBICONV=YesPlease
 424    else
 425       NEEDS_LIBICONV=
 426    fi
 427
 428    old_LIBS="$LIBS"
 429    LIBS="$LIBS $l"
 430    AC_MSG_CHECKING([for iconv in $l])
 431    AC_LINK_IFELSE(ICONVTEST_SRC,
 432        [AC_MSG_RESULT([yes])
 433        NO_ICONV=
 434        break],
 435        [AC_MSG_RESULT([no])])
 436    LIBS="$old_LIBS"
 437done
 438
 439#in case of break
 440LIBS="$old_LIBS"
 441
 442GIT_UNSTASH_FLAGS($ICONVDIR)
 443
 444AC_SUBST(NEEDS_LIBICONV)
 445AC_SUBST(NO_ICONV)
 446
 447if test -n "$NO_ICONV"; then
 448    NEEDS_LIBICONV=
 449fi
 450
 451fi
 452
 453#
 454# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 455
 456GIT_STASH_FLAGS($ZLIB_PATH)
 457
 458AC_DEFUN([ZLIBTEST_SRC], [
 459#include <zlib.h>
 460
 461int main(void)
 462{
 463        deflateBound(0, 0);
 464        return 0;
 465}
 466])
 467AC_MSG_CHECKING([for deflateBound in -lz])
 468old_LIBS="$LIBS"
 469LIBS="$LIBS -lz"
 470AC_LINK_IFELSE(ZLIBTEST_SRC,
 471        [AC_MSG_RESULT([yes])],
 472        [AC_MSG_RESULT([no])
 473        NO_DEFLATE_BOUND=yes])
 474LIBS="$old_LIBS"
 475
 476GIT_UNSTASH_FLAGS($ZLIB_PATH)
 477
 478AC_SUBST(NO_DEFLATE_BOUND)
 479
 480#
 481# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 482# Patrick Mauritz).
 483AC_CHECK_LIB([c], [socket],
 484[NEEDS_SOCKET=],
 485[NEEDS_SOCKET=YesPlease])
 486AC_SUBST(NEEDS_SOCKET)
 487test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 488
 489#
 490# Define NEEDS_RESOLV if linking with -lnsl and/or -lsocket is not enough.
 491# Notably on Solaris hstrerror resides in libresolv and on Solaris 7
 492# inet_ntop and inet_pton additionally reside there.
 493AC_CHECK_LIB([c], [hstrerror],
 494[NEEDS_RESOLV=],
 495[NEEDS_RESOLV=YesPlease])
 496AC_SUBST(NEEDS_RESOLV)
 497test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 498
 499AC_CHECK_LIB([c], [basename],
 500[NEEDS_LIBGEN=],
 501[NEEDS_LIBGEN=YesPlease])
 502AC_SUBST(NEEDS_LIBGEN)
 503test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 504
 505## Checks for header files.
 506AC_MSG_NOTICE([CHECKS for header files])
 507#
 508# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 509AC_CHECK_HEADER([sys/select.h],
 510[NO_SYS_SELECT_H=],
 511[NO_SYS_SELECT_H=UnfortunatelyYes])
 512AC_SUBST(NO_SYS_SELECT_H)
 513#
 514# Define OLD_ICONV if your library has an old iconv(), where the second
 515# (input buffer pointer) parameter is declared with type (const char **).
 516AC_DEFUN([OLDICONVTEST_SRC], [[
 517#include <iconv.h>
 518
 519extern size_t iconv(iconv_t cd,
 520                    char **inbuf, size_t *inbytesleft,
 521                    char **outbuf, size_t *outbytesleft);
 522
 523int main(void)
 524{
 525        return 0;
 526}
 527]])
 528
 529GIT_STASH_FLAGS($ICONVDIR)
 530
 531AC_MSG_CHECKING([for old iconv()])
 532AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 533        [AC_MSG_RESULT([no])],
 534        [AC_MSG_RESULT([yes])
 535        OLD_ICONV=UnfortunatelyYes])
 536
 537GIT_UNSTASH_FLAGS($ICONVDIR)
 538
 539AC_SUBST(OLD_ICONV)
 540
 541## Checks for typedefs, structures, and compiler characteristics.
 542AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 543#
 544# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 545AC_CHECK_MEMBER(struct dirent.d_ino,
 546[NO_D_INO_IN_DIRENT=],
 547[NO_D_INO_IN_DIRENT=YesPlease],
 548[#include <dirent.h>])
 549AC_SUBST(NO_D_INO_IN_DIRENT)
 550#
 551# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 552# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 553AC_CHECK_MEMBER(struct dirent.d_type,
 554[NO_D_TYPE_IN_DIRENT=],
 555[NO_D_TYPE_IN_DIRENT=YesPlease],
 556[#include <dirent.h>])
 557AC_SUBST(NO_D_TYPE_IN_DIRENT)
 558#
 559# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 560# sockaddr_storage.
 561AC_CHECK_TYPE(struct sockaddr_storage,
 562[NO_SOCKADDR_STORAGE=],
 563[NO_SOCKADDR_STORAGE=YesPlease],[
 564#include <sys/types.h>
 565#include <sys/socket.h>
 566])
 567AC_SUBST(NO_SOCKADDR_STORAGE)
 568#
 569# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 570AC_CHECK_TYPE([struct addrinfo],[
 571 GIT_CHECK_FUNC([getaddrinfo],
 572  [NO_IPV6=],
 573  [NO_IPV6=YesPlease])
 574],[NO_IPV6=YesPlease],[
 575#include <sys/types.h>
 576#include <sys/socket.h>
 577#include <netdb.h>
 578])
 579AC_SUBST(NO_IPV6)
 580#
 581# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 582# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 583# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 584# some C compilers supported these specifiers prior to C99 as an extension.
 585AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 586 [ac_cv_c_c99_format],
 587[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 588AC_RUN_IFELSE(
 589        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 590                [[char buf[64];
 591                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 592                  return 1;
 593                else if (strcmp(buf, "12345"))
 594                  return 2;]])],
 595        [ac_cv_c_c99_format=yes],
 596        [ac_cv_c_c99_format=no])
 597])
 598if test $ac_cv_c_c99_format = no; then
 599        NO_C99_FORMAT=YesPlease
 600else
 601        NO_C99_FORMAT=
 602fi
 603AC_SUBST(NO_C99_FORMAT)
 604#
 605# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 606# when attempting to read from an fopen'ed directory.
 607AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 608 [ac_cv_fread_reads_directories],
 609[
 610AC_RUN_IFELSE(
 611        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 612                [[char c;
 613                FILE *f = fopen(".", "r");
 614                return f && fread(&c, 1, 1, f)]])],
 615        [ac_cv_fread_reads_directories=no],
 616        [ac_cv_fread_reads_directories=yes])
 617])
 618if test $ac_cv_fread_reads_directories = yes; then
 619        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 620else
 621        FREAD_READS_DIRECTORIES=
 622fi
 623AC_SUBST(FREAD_READS_DIRECTORIES)
 624#
 625# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 626# or vsnprintf() return -1 instead of number of characters which would
 627# have been written to the final string if enough space had been available.
 628AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 629 [ac_cv_snprintf_returns_bogus],
 630[
 631AC_RUN_IFELSE(
 632        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 633                #include "stdarg.h"
 634
 635                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 636                {
 637                  int ret;
 638                  va_list ap;
 639                  va_start(ap, format);
 640                  ret = vsnprintf(str, maxsize, format, ap);
 641                  va_end(ap);
 642                  return ret;
 643                }],
 644                [[char buf[6];
 645                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 646                      || strcmp(buf, "12")) return 1;
 647                  if (snprintf(buf, 3, "%s", "12345") != 5
 648                      || strcmp(buf, "12")) return 1]])],
 649        [ac_cv_snprintf_returns_bogus=no],
 650        [ac_cv_snprintf_returns_bogus=yes])
 651])
 652if test $ac_cv_snprintf_returns_bogus = yes; then
 653        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 654else
 655        SNPRINTF_RETURNS_BOGUS=
 656fi
 657AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 658
 659
 660## Checks for library functions.
 661## (in default C library and libraries checked by AC_CHECK_LIB)
 662AC_MSG_NOTICE([CHECKS for library functions])
 663#
 664# Define NO_LIBGEN_H if you don't have libgen.h.
 665AC_CHECK_HEADER([libgen.h],
 666[NO_LIBGEN_H=],
 667[NO_LIBGEN_H=YesPlease])
 668AC_SUBST(NO_LIBGEN_H)
 669#
 670# Define NO_STRCASESTR if you don't have strcasestr.
 671GIT_CHECK_FUNC(strcasestr,
 672[NO_STRCASESTR=],
 673[NO_STRCASESTR=YesPlease])
 674AC_SUBST(NO_STRCASESTR)
 675#
 676# Define NO_MEMMEM if you don't have memmem.
 677GIT_CHECK_FUNC(memmem,
 678[NO_MEMMEM=],
 679[NO_MEMMEM=YesPlease])
 680AC_SUBST(NO_MEMMEM)
 681#
 682# Define NO_STRLCPY if you don't have strlcpy.
 683GIT_CHECK_FUNC(strlcpy,
 684[NO_STRLCPY=],
 685[NO_STRLCPY=YesPlease])
 686AC_SUBST(NO_STRLCPY)
 687#
 688# Define NO_UINTMAX_T if your platform does not have uintmax_t
 689AC_CHECK_TYPE(uintmax_t,
 690[NO_UINTMAX_T=],
 691[NO_UINTMAX_T=YesPlease],[
 692#include <inttypes.h>
 693])
 694AC_SUBST(NO_UINTMAX_T)
 695#
 696# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 697GIT_CHECK_FUNC(strtoumax,
 698[NO_STRTOUMAX=],
 699[NO_STRTOUMAX=YesPlease])
 700AC_SUBST(NO_STRTOUMAX)
 701#
 702# Define NO_SETENV if you don't have setenv in the C library.
 703GIT_CHECK_FUNC(setenv,
 704[NO_SETENV=],
 705[NO_SETENV=YesPlease])
 706AC_SUBST(NO_SETENV)
 707#
 708# Define NO_UNSETENV if you don't have unsetenv in the C library.
 709GIT_CHECK_FUNC(unsetenv,
 710[NO_UNSETENV=],
 711[NO_UNSETENV=YesPlease])
 712AC_SUBST(NO_UNSETENV)
 713#
 714# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 715GIT_CHECK_FUNC(mkdtemp,
 716[NO_MKDTEMP=],
 717[NO_MKDTEMP=YesPlease])
 718AC_SUBST(NO_MKDTEMP)
 719#
 720# Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 721GIT_CHECK_FUNC(mkstemps,
 722[NO_MKSTEMPS=],
 723[NO_MKSTEMPS=YesPlease])
 724AC_SUBST(NO_MKSTEMPS)
 725#
 726#
 727# Define NO_MMAP if you want to avoid mmap.
 728#
 729# Define NO_ICONV if your libc does not properly support iconv.
 730
 731
 732## Other checks.
 733# Define USE_PIC if you need the main git objects to be built with -fPIC
 734# in order to build and link perl/Git.so.  x86-64 seems to need this.
 735#
 736# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 737# Enable it on Windows.  By default, symrefs are still used.
 738#
 739# Define NO_PTHREADS if we do not have pthreads
 740#
 741# Define PTHREAD_LIBS to the linker flag used for Pthread support and define
 742# THREADED_DELTA_SEARCH if Pthreads are available.
 743AC_DEFUN([PTHREADTEST_SRC], [
 744#include <pthread.h>
 745
 746int main(void)
 747{
 748        pthread_mutex_t test_mutex;
 749        return (0);
 750}
 751])
 752
 753dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 754dnl   [[#include <pthread.h>]],
 755dnl   [[pthread_mutex_t test_mutex;]]
 756dnl )])
 757
 758NO_PTHREADS=UnfortunatelyYes
 759THREADED_DELTA_SEARCH=
 760PTHREAD_LIBS=
 761
 762if test -n "$USER_NOPTHREAD"; then
 763   AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 764# handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 765# -D_REENTRANT' or some such.
 766elif test -z "$PTHREAD_CFLAGS"; then
 767  for opt in -pthread -lpthread; do
 768     old_CFLAGS="$CFLAGS"
 769     CFLAGS="$opt $CFLAGS"
 770     AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 771     AC_LINK_IFELSE(PTHREADTEST_SRC,
 772        [AC_MSG_RESULT([yes])
 773                NO_PTHREADS=
 774                PTHREAD_LIBS="$opt"
 775                THREADED_DELTA_SEARCH=YesPlease
 776                break
 777        ],
 778        [AC_MSG_RESULT([no])])
 779      CFLAGS="$old_CFLAGS"
 780  done
 781else
 782  old_CFLAGS="$CFLAGS"
 783  CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 784  AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 785  AC_LINK_IFELSE(PTHREADTEST_SRC,
 786        [AC_MSG_RESULT([yes])
 787                NO_PTHREADS=
 788                PTHREAD_LIBS="$PTHREAD_CFLAGS"
 789                THREADED_DELTA_SEARCH=YesPlease
 790        ],
 791        [AC_MSG_RESULT([no])])
 792
 793  CFLAGS="$old_CFLAGS"
 794fi
 795
 796CFLAGS="$old_CFLAGS"
 797
 798AC_SUBST(PTHREAD_LIBS)
 799AC_SUBST(NO_PTHREADS)
 800AC_SUBST(THREADED_DELTA_SEARCH)
 801
 802## Output files
 803AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 804AC_OUTPUT
 805
 806
 807## Cleanup
 808rm -f "${config_append}"