Andrew's git / gitweb.git / configure.ac
?
configure.acon commit Fix '--relative-date' (dbc1b1f)
   1#                                               -*- Autoconf -*-
   2# Process this file with autoconf to produce a configure script.
   3
   4AC_PREREQ(2.59)
   5AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7AC_CONFIG_SRCDIR([git.c])
   8
   9config_file=config.mak.autogen
  10config_append=config.mak.append
  11config_in=config.mak.in
  12
  13echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16## Definitions of macros
  17# GIT_CONF_APPEND_LINE(LINE)
  18# --------------------------
  19# Append LINE to file ${config_append}
  20AC_DEFUN([GIT_CONF_APPEND_LINE],
  21[echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22#
  23# GIT_ARG_SET_PATH(PROGRAM)
  24# -------------------------
  25# Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26AC_DEFUN([GIT_ARG_SET_PATH],
  27[AC_ARG_WITH([$1],
  28 [AS_HELP_STRING([--with-$1=PATH],
  29                 [provide PATH to $1])],
  30 [GIT_CONF_APPEND_PATH($1)],[])
  31])# GIT_ARG_SET_PATH
  32#
  33# GIT_CONF_APPEND_PATH(PROGRAM)
  34# ------------------------------
  35# Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36# Used by GIT_ARG_SET_PATH(PROGRAM)
  37AC_DEFUN([GIT_CONF_APPEND_PATH],
  38[PROGRAM=m4_toupper($1); \
  39if test "$withval" = "no"; then \
  40        AC_MSG_ERROR([You cannot use git without $1]); \
  41else \
  42        if test "$withval" = "yes"; then \
  43                AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44        else \
  45                m4_toupper($1)_PATH=$withval; \
  46                AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  47                GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  48        fi; \
  49fi; \
  50]) # GIT_CONF_APPEND_PATH
  51#
  52# GIT_PARSE_WITH(PACKAGE)
  53# -----------------------
  54# For use in AC_ARG_WITH action-if-found, for packages default ON.
  55# * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  56# * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  57# * Unset NO_PACKAGE for --with-PACKAGE without ARG
  58AC_DEFUN([GIT_PARSE_WITH],
  59[PACKAGE=m4_toupper($1); \
  60if test "$withval" = "no"; then \
  61        m4_toupper(NO_$1)=YesPlease; \
  62elif test "$withval" = "yes"; then \
  63        m4_toupper(NO_$1)=; \
  64else \
  65        m4_toupper(NO_$1)=; \
  66        m4_toupper($1)DIR=$withval; \
  67        AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  68        GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  69fi \
  70])# GIT_PARSE_WITH
  71
  72dnl
  73dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
  74dnl -----------------------------------------
  75dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
  76dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
  77dnl -Wall), it does not work.  By looking for function definition in
  78dnl libraries, this problem can be worked around.
  79AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
  80  AC_SEARCH_LIBS([$1],,
  81  [$2],[$3])
  82],[$3])])
  83
  84dnl
  85dnl GIT_STASH_FLAGS(BASEPATH_VAR)
  86dnl -----------------------------
  87dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
  88dnl tests that may want to take user settings into account.
  89AC_DEFUN([GIT_STASH_FLAGS],[
  90if test -n "$1"; then
  91   old_CPPFLAGS="$CPPFLAGS"
  92   old_LDFLAGS="$LDFLAGS"
  93   CPPFLAGS="-I$1/include $CPPFLAGS"
  94   LDFLAGS="-L$1/$lib $LDFLAGS"
  95fi
  96])
  97
  98dnl
  99dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 100dnl -----------------------------
 101dnl Restore the stashed *FLAGS values.
 102AC_DEFUN([GIT_UNSTASH_FLAGS],[
 103if test -n "$1"; then
 104   CPPFLAGS="$old_CPPFLAGS"
 105   LDFLAGS="$old_LDFLAGS"
 106fi
 107])
 108
 109## Site configuration related to programs (before tests)
 110## --with-PACKAGE[=ARG] and --without-PACKAGE
 111#
 112# Set lib to alternative name of lib directory (e.g. lib64)
 113AC_ARG_WITH([lib],
 114 [AS_HELP_STRING([--with-lib=ARG],
 115                 [ARG specifies alternative name for lib directory])],
 116 [if test "$withval" = "no" || test "$withval" = "yes"; then \
 117        AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 118else \
 119        lib=$withval; \
 120        AC_MSG_NOTICE([Setting lib to '$lib']); \
 121        GIT_CONF_APPEND_LINE(lib=$withval); \
 122fi; \
 123],[])
 124
 125if test -z "$lib"; then
 126   AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 127   lib=lib
 128fi
 129
 130AC_ARG_ENABLE([pthreads],
 131 [AS_HELP_STRING([--enable-pthreads=FLAGS],
 132  [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 133  [The default if FLAGS is not specified is to try first -pthread]
 134  [and then -lpthread.]
 135  [--without-pthreads will disable threading.])],
 136[
 137if test "x$enableval" = "xyes"; then
 138   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 139elif test "x$enableval" != "xno"; then
 140   PTHREAD_CFLAGS=$enableval
 141   AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 142else
 143   AC_MSG_NOTICE([POSIX Threads will be disabled.])
 144   NO_PTHREADS=YesPlease
 145   USER_NOPTHREAD=1
 146fi],
 147[
 148   AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 149])
 150
 151## Site configuration (override autodetection)
 152## --with-PACKAGE[=ARG] and --without-PACKAGE
 153AC_MSG_NOTICE([CHECKS for site configuration])
 154#
 155# Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 156# tests.  These tests take up a significant amount of the total test time
 157# but are not needed unless you plan to talk to SVN repos.
 158#
 159# Define PPC_SHA1 environment variable when running make to make use of
 160# a bundled SHA1 routine optimized for PowerPC.
 161#
 162# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 163# This also implies BLK_SHA1.
 164#
 165# Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 166# /foo/bar/include and /foo/bar/lib directories.
 167AC_ARG_WITH(openssl,
 168AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 169AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 170GIT_PARSE_WITH(openssl))
 171#
 172# Define NO_CURL if you do not have curl installed.  git-http-pull and
 173# git-http-push are not built, and you cannot use http:// and https://
 174# transports.
 175#
 176# Define CURLDIR=/foo/bar if your curl header and library files are in
 177# /foo/bar/include and /foo/bar/lib directories.
 178AC_ARG_WITH(curl,
 179AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 180AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 181GIT_PARSE_WITH(curl))
 182#
 183# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 184# not built, and you cannot push using http:// and https:// transports.
 185#
 186# Define EXPATDIR=/foo/bar if your expat header and library files are in
 187# /foo/bar/include and /foo/bar/lib directories.
 188AC_ARG_WITH(expat,
 189AS_HELP_STRING([--with-expat],
 190[support git-push using http:// and https:// transports via WebDAV (default is YES)])
 191AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 192GIT_PARSE_WITH(expat))
 193#
 194# Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 195# installed in /sw, but don't want GIT to link against any libraries
 196# installed there.  If defined you may specify your own (or Fink's)
 197# include directories and library directories by defining CFLAGS
 198# and LDFLAGS appropriately.
 199#
 200# Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 201# have DarwinPorts installed in /opt/local, but don't want GIT to
 202# link against any libraries installed there.  If defined you may
 203# specify your own (or DarwinPort's) include directories and
 204# library directories by defining CFLAGS and LDFLAGS appropriately.
 205#
 206# Define NO_MMAP if you want to avoid mmap.
 207#
 208# Define NO_ICONV if your libc does not properly support iconv.
 209AC_ARG_WITH(iconv,
 210AS_HELP_STRING([--without-iconv],
 211[if your architecture doesn't properly support iconv])
 212AS_HELP_STRING([--with-iconv=PATH],
 213[PATH is prefix for libiconv library and headers])
 214AS_HELP_STRING([],
 215[used only if you need linking with libiconv]),
 216GIT_PARSE_WITH(iconv))
 217
 218## --enable-FEATURE[=ARG] and --disable-FEATURE
 219#
 220# Define USE_NSEC below if you want git to care about sub-second file mtimes
 221# and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 222# it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 223# randomly break unless your underlying filesystem supports those sub-second
 224# times (my ext3 doesn't).
 225#
 226# Define USE_STDEV below if you want git to care about the underlying device
 227# change being considered an inode change from the update-index perspective.
 228
 229#
 230# Define SHELL_PATH to provide path to shell.
 231GIT_ARG_SET_PATH(shell)
 232#
 233# Define PERL_PATH to provide path to Perl.
 234GIT_ARG_SET_PATH(perl)
 235#
 236# Define ZLIB_PATH to provide path to zlib.
 237GIT_ARG_SET_PATH(zlib)
 238#
 239# Declare the with-tcltk/without-tcltk options.
 240AC_ARG_WITH(tcltk,
 241AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 242AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 243AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 244AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 245GIT_PARSE_WITH(tcltk))
 246#
 247
 248
 249## Checks for programs.
 250AC_MSG_NOTICE([CHECKS for programs])
 251#
 252AC_PROG_CC([cc gcc])
 253# which switch to pass runtime path to dynamic libraries to the linker
 254AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 255   SAVE_LDFLAGS="${LDFLAGS}"
 256   LDFLAGS="${SAVE_LDFLAGS} -R /"
 257   AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 258   LDFLAGS="${SAVE_LDFLAGS}"
 259])
 260if test "$git_cv_ld_dashr" = "yes"; then
 261   AC_SUBST(CC_LD_DYNPATH, [-R])
 262else
 263   AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 264      SAVE_LDFLAGS="${LDFLAGS}"
 265      LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 266      AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 267      LDFLAGS="${SAVE_LDFLAGS}"
 268   ])
 269   if test "$git_cv_ld_wl_rpath" = "yes"; then
 270      AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 271   else
 272      AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 273         SAVE_LDFLAGS="${LDFLAGS}"
 274         LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 275         AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 276         LDFLAGS="${SAVE_LDFLAGS}"
 277      ])
 278      if test "$git_cv_ld_rpath" = "yes"; then
 279         AC_SUBST(CC_LD_DYNPATH, [-rpath])
 280      else
 281         AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 282      fi
 283   fi
 284fi
 285#AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 286AC_CHECK_TOOLS(AR, [gar ar], :)
 287AC_CHECK_PROGS(TAR, [gtar tar])
 288# TCLTK_PATH will be set to some value if we want Tcl/Tk
 289# or will be empty otherwise.
 290if test -z "$NO_TCLTK"; then
 291  if test "$with_tcltk" = ""; then
 292  # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 293    TCLTK_PATH=wish
 294    AC_SUBST(TCLTK_PATH)
 295  elif test "$with_tcltk" = "yes"; then
 296  # Tcl/Tk check requested.
 297    AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 298  else
 299    AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 300    TCLTK_PATH="$with_tcltk"
 301    AC_SUBST(TCLTK_PATH)
 302  fi
 303fi
 304AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 305if test -n "$ASCIIDOC"; then
 306        AC_MSG_CHECKING([for asciidoc version])
 307        asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 308        case "${asciidoc_version}" in
 309        asciidoc' '8*)
 310                ASCIIDOC8=YesPlease
 311                AC_MSG_RESULT([${asciidoc_version} > 7])
 312                ;;
 313        asciidoc' '7*)
 314                ASCIIDOC8=
 315                AC_MSG_RESULT([${asciidoc_version}])
 316                ;;
 317        *)
 318                ASCIIDOC8=
 319                AC_MSG_RESULT([${asciidoc_version} (unknown)])
 320                ;;
 321        esac
 322fi
 323AC_SUBST(ASCIIDOC8)
 324
 325
 326## Checks for libraries.
 327AC_MSG_NOTICE([CHECKS for libraries])
 328#
 329# Define NO_OPENSSL environment variable if you do not have OpenSSL.
 330# Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 331
 332GIT_STASH_FLAGS($OPENSSLDIR)
 333
 334AC_CHECK_LIB([crypto], [SHA1_Init],
 335[NEEDS_SSL_WITH_CRYPTO=],
 336[AC_CHECK_LIB([ssl], [SHA1_Init],
 337 [NEEDS_SSL_WITH_CRYPTO=YesPlease],
 338 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
 339
 340GIT_UNSTASH_FLAGS($OPENSSLDIR)
 341
 342AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 343AC_SUBST(NO_OPENSSL)
 344
 345#
 346# Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 347# git-http-push are not built, and you cannot use http:// and https://
 348# transports.
 349
 350GIT_STASH_FLAGS($CURLDIR)
 351
 352AC_CHECK_LIB([curl], [curl_global_init],
 353[NO_CURL=],
 354[NO_CURL=YesPlease])
 355
 356GIT_UNSTASH_FLAGS($CURLDIR)
 357
 358AC_SUBST(NO_CURL)
 359
 360#
 361# Define NO_EXPAT if you do not have expat installed.  git-http-push is
 362# not built, and you cannot push using http:// and https:// transports.
 363
 364GIT_STASH_FLAGS($EXPATDIR)
 365
 366AC_CHECK_LIB([expat], [XML_ParserCreate],
 367[NO_EXPAT=],
 368[NO_EXPAT=YesPlease])
 369
 370GIT_UNSTASH_FLAGS($EXPATDIR)
 371
 372AC_SUBST(NO_EXPAT)
 373
 374#
 375# Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 376# some Solaris installations).
 377# Define NO_ICONV if neither libc nor libiconv support iconv.
 378
 379if test -z "$NO_ICONV"; then
 380
 381GIT_STASH_FLAGS($ICONVDIR)
 382
 383AC_DEFUN([ICONVTEST_SRC], [
 384#include <iconv.h>
 385
 386int main(void)
 387{
 388        iconv_open("", "");
 389        return 0;
 390}
 391])
 392
 393if test -n "$ICONVDIR"; then
 394   lib_order="-liconv -lc"
 395else
 396   lib_order="-lc -liconv"
 397fi
 398
 399NO_ICONV=YesPlease
 400
 401for l in $lib_order; do
 402    if test "$l" = "-liconv"; then
 403       NEEDS_LIBICONV=YesPlease
 404    else
 405       NEEDS_LIBICONV=
 406    fi
 407
 408    old_LIBS="$LIBS"
 409    LIBS="$LIBS $l"
 410    AC_MSG_CHECKING([for iconv in $l])
 411    AC_LINK_IFELSE(ICONVTEST_SRC,
 412        [AC_MSG_RESULT([yes])
 413        NO_ICONV=
 414        break],
 415        [AC_MSG_RESULT([no])])
 416    LIBS="$old_LIBS"
 417done
 418
 419#in case of break
 420LIBS="$old_LIBS"
 421
 422GIT_UNSTASH_FLAGS($ICONVDIR)
 423
 424AC_SUBST(NEEDS_LIBICONV)
 425AC_SUBST(NO_ICONV)
 426
 427if test -n "$NO_ICONV"; then
 428    NEEDS_LIBICONV=
 429fi
 430
 431fi
 432
 433#
 434# Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 435
 436GIT_STASH_FLAGS($ZLIB_PATH)
 437
 438AC_DEFUN([ZLIBTEST_SRC], [
 439#include <zlib.h>
 440
 441int main(void)
 442{
 443        deflateBound(0, 0);
 444        return 0;
 445}
 446])
 447AC_MSG_CHECKING([for deflateBound in -lz])
 448old_LIBS="$LIBS"
 449LIBS="$LIBS -lz"
 450AC_LINK_IFELSE(ZLIBTEST_SRC,
 451        [AC_MSG_RESULT([yes])],
 452        [AC_MSG_RESULT([no])
 453        NO_DEFLATE_BOUND=yes])
 454LIBS="$old_LIBS"
 455
 456GIT_UNSTASH_FLAGS($ZLIB_PATH)
 457
 458AC_SUBST(NO_DEFLATE_BOUND)
 459
 460#
 461# Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 462# Patrick Mauritz).
 463AC_CHECK_LIB([c], [socket],
 464[NEEDS_SOCKET=],
 465[NEEDS_SOCKET=YesPlease])
 466AC_SUBST(NEEDS_SOCKET)
 467test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 468
 469#
 470# Define NEEDS_RESOLV if linking with -lnsl and/or -lsocket is not enough.
 471# Notably on Solaris hstrerror resides in libresolv and on Solaris 7
 472# inet_ntop and inet_pton additionally reside there.
 473AC_CHECK_LIB([c], [hstrerror],
 474[NEEDS_RESOLV=],
 475[NEEDS_RESOLV=YesPlease])
 476AC_SUBST(NEEDS_RESOLV)
 477test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 478
 479AC_CHECK_LIB([c], [basename],
 480[NEEDS_LIBGEN=],
 481[NEEDS_LIBGEN=YesPlease])
 482AC_SUBST(NEEDS_LIBGEN)
 483test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 484
 485## Checks for header files.
 486AC_MSG_NOTICE([CHECKS for header files])
 487#
 488# Define NO_SYS_SELECT_H if you don't have sys/select.h.
 489AC_CHECK_HEADER([sys/select.h],
 490[NO_SYS_SELECT_H=],
 491[NO_SYS_SELECT_H=UnfortunatelyYes])
 492AC_SUBST(NO_SYS_SELECT_H)
 493#
 494# Define OLD_ICONV if your library has an old iconv(), where the second
 495# (input buffer pointer) parameter is declared with type (const char **).
 496AC_DEFUN([OLDICONVTEST_SRC], [[
 497#include <iconv.h>
 498
 499extern size_t iconv(iconv_t cd,
 500                    char **inbuf, size_t *inbytesleft,
 501                    char **outbuf, size_t *outbytesleft);
 502
 503int main(void)
 504{
 505        return 0;
 506}
 507]])
 508
 509GIT_STASH_FLAGS($ICONVDIR)
 510
 511AC_MSG_CHECKING([for old iconv()])
 512AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 513        [AC_MSG_RESULT([no])],
 514        [AC_MSG_RESULT([yes])
 515        OLD_ICONV=UnfortunatelyYes])
 516
 517GIT_UNSTASH_FLAGS($ICONVDIR)
 518
 519AC_SUBST(OLD_ICONV)
 520
 521## Checks for typedefs, structures, and compiler characteristics.
 522AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 523#
 524# Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 525AC_CHECK_MEMBER(struct dirent.d_ino,
 526[NO_D_INO_IN_DIRENT=],
 527[NO_D_INO_IN_DIRENT=YesPlease],
 528[#include <dirent.h>])
 529AC_SUBST(NO_D_INO_IN_DIRENT)
 530#
 531# Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 532# d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 533AC_CHECK_MEMBER(struct dirent.d_type,
 534[NO_D_TYPE_IN_DIRENT=],
 535[NO_D_TYPE_IN_DIRENT=YesPlease],
 536[#include <dirent.h>])
 537AC_SUBST(NO_D_TYPE_IN_DIRENT)
 538#
 539# Define NO_SOCKADDR_STORAGE if your platform does not have struct
 540# sockaddr_storage.
 541AC_CHECK_TYPE(struct sockaddr_storage,
 542[NO_SOCKADDR_STORAGE=],
 543[NO_SOCKADDR_STORAGE=YesPlease],[
 544#include <sys/types.h>
 545#include <sys/socket.h>
 546])
 547AC_SUBST(NO_SOCKADDR_STORAGE)
 548#
 549# Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 550AC_CHECK_TYPE([struct addrinfo],[
 551 GIT_CHECK_FUNC([getaddrinfo],
 552  [NO_IPV6=],
 553  [NO_IPV6=YesPlease])
 554],[NO_IPV6=YesPlease],[
 555#include <sys/types.h>
 556#include <sys/socket.h>
 557#include <netdb.h>
 558])
 559AC_SUBST(NO_IPV6)
 560#
 561# Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 562# do not support the 'size specifiers' introduced by C99, namely ll, hh,
 563# j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 564# some C compilers supported these specifiers prior to C99 as an extension.
 565AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 566 [ac_cv_c_c99_format],
 567[# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 568AC_RUN_IFELSE(
 569        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 570                [[char buf[64];
 571                if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 572                  return 1;
 573                else if (strcmp(buf, "12345"))
 574                  return 2;]])],
 575        [ac_cv_c_c99_format=yes],
 576        [ac_cv_c_c99_format=no])
 577])
 578if test $ac_cv_c_c99_format = no; then
 579        NO_C99_FORMAT=YesPlease
 580else
 581        NO_C99_FORMAT=
 582fi
 583AC_SUBST(NO_C99_FORMAT)
 584#
 585# Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 586# when attempting to read from an fopen'ed directory.
 587AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 588 [ac_cv_fread_reads_directories],
 589[
 590AC_RUN_IFELSE(
 591        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 592                [[char c;
 593                FILE *f = fopen(".", "r");
 594                return f && fread(&c, 1, 1, f)]])],
 595        [ac_cv_fread_reads_directories=no],
 596        [ac_cv_fread_reads_directories=yes])
 597])
 598if test $ac_cv_fread_reads_directories = yes; then
 599        FREAD_READS_DIRECTORIES=UnfortunatelyYes
 600else
 601        FREAD_READS_DIRECTORIES=
 602fi
 603AC_SUBST(FREAD_READS_DIRECTORIES)
 604#
 605# Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 606# or vsnprintf() return -1 instead of number of characters which would
 607# have been written to the final string if enough space had been available.
 608AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 609 [ac_cv_snprintf_returns_bogus],
 610[
 611AC_RUN_IFELSE(
 612        [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 613                #include "stdarg.h"
 614
 615                int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 616                {
 617                  int ret;
 618                  va_list ap;
 619                  va_start(ap, format);
 620                  ret = vsnprintf(str, maxsize, format, ap);
 621                  va_end(ap);
 622                  return ret;
 623                }],
 624                [[char buf[6];
 625                  if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 626                      || strcmp(buf, "12")) return 1;
 627                  if (snprintf(buf, 3, "%s", "12345") != 5
 628                      || strcmp(buf, "12")) return 1]])],
 629        [ac_cv_snprintf_returns_bogus=no],
 630        [ac_cv_snprintf_returns_bogus=yes])
 631])
 632if test $ac_cv_snprintf_returns_bogus = yes; then
 633        SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 634else
 635        SNPRINTF_RETURNS_BOGUS=
 636fi
 637AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 638
 639
 640## Checks for library functions.
 641## (in default C library and libraries checked by AC_CHECK_LIB)
 642AC_MSG_NOTICE([CHECKS for library functions])
 643#
 644# Define NO_LIBGEN_H if you don't have libgen.h.
 645AC_CHECK_HEADER([libgen.h],
 646[NO_LIBGEN_H=],
 647[NO_LIBGEN_H=YesPlease])
 648AC_SUBST(NO_LIBGEN_H)
 649#
 650# Define NO_STRCASESTR if you don't have strcasestr.
 651GIT_CHECK_FUNC(strcasestr,
 652[NO_STRCASESTR=],
 653[NO_STRCASESTR=YesPlease])
 654AC_SUBST(NO_STRCASESTR)
 655#
 656# Define NO_MEMMEM if you don't have memmem.
 657GIT_CHECK_FUNC(memmem,
 658[NO_MEMMEM=],
 659[NO_MEMMEM=YesPlease])
 660AC_SUBST(NO_MEMMEM)
 661#
 662# Define NO_STRLCPY if you don't have strlcpy.
 663GIT_CHECK_FUNC(strlcpy,
 664[NO_STRLCPY=],
 665[NO_STRLCPY=YesPlease])
 666AC_SUBST(NO_STRLCPY)
 667#
 668# Define NO_UINTMAX_T if your platform does not have uintmax_t
 669AC_CHECK_TYPE(uintmax_t,
 670[NO_UINTMAX_T=],
 671[NO_UINTMAX_T=YesPlease],[
 672#include <inttypes.h>
 673])
 674AC_SUBST(NO_UINTMAX_T)
 675#
 676# Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 677GIT_CHECK_FUNC(strtoumax,
 678[NO_STRTOUMAX=],
 679[NO_STRTOUMAX=YesPlease])
 680AC_SUBST(NO_STRTOUMAX)
 681#
 682# Define NO_SETENV if you don't have setenv in the C library.
 683GIT_CHECK_FUNC(setenv,
 684[NO_SETENV=],
 685[NO_SETENV=YesPlease])
 686AC_SUBST(NO_SETENV)
 687#
 688# Define NO_UNSETENV if you don't have unsetenv in the C library.
 689GIT_CHECK_FUNC(unsetenv,
 690[NO_UNSETENV=],
 691[NO_UNSETENV=YesPlease])
 692AC_SUBST(NO_UNSETENV)
 693#
 694# Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 695GIT_CHECK_FUNC(mkdtemp,
 696[NO_MKDTEMP=],
 697[NO_MKDTEMP=YesPlease])
 698AC_SUBST(NO_MKDTEMP)
 699#
 700# Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 701GIT_CHECK_FUNC(mkstemps,
 702[NO_MKSTEMPS=],
 703[NO_MKSTEMPS=YesPlease])
 704AC_SUBST(NO_MKSTEMPS)
 705#
 706#
 707# Define NO_MMAP if you want to avoid mmap.
 708#
 709# Define NO_ICONV if your libc does not properly support iconv.
 710
 711
 712## Other checks.
 713# Define USE_PIC if you need the main git objects to be built with -fPIC
 714# in order to build and link perl/Git.so.  x86-64 seems to need this.
 715#
 716# Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 717# Enable it on Windows.  By default, symrefs are still used.
 718#
 719# Define NO_PTHREADS if we do not have pthreads
 720#
 721# Define PTHREAD_LIBS to the linker flag used for Pthread support and define
 722# THREADED_DELTA_SEARCH if Pthreads are available.
 723AC_DEFUN([PTHREADTEST_SRC], [
 724#include <pthread.h>
 725
 726int main(void)
 727{
 728        pthread_mutex_t test_mutex;
 729        return (0);
 730}
 731])
 732
 733dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 734dnl   [[#include <pthread.h>]],
 735dnl   [[pthread_mutex_t test_mutex;]]
 736dnl )])
 737
 738NO_PTHREADS=UnfortunatelyYes
 739THREADED_DELTA_SEARCH=
 740PTHREAD_LIBS=
 741
 742if test -n "$USER_NOPTHREAD"; then
 743   AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 744# handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 745# -D_REENTRANT' or some such.
 746elif test -z "$PTHREAD_CFLAGS"; then
 747  for opt in -pthread -lpthread; do
 748     old_CFLAGS="$CFLAGS"
 749     CFLAGS="$opt $CFLAGS"
 750     AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 751     AC_LINK_IFELSE(PTHREADTEST_SRC,
 752        [AC_MSG_RESULT([yes])
 753                NO_PTHREADS=
 754                PTHREAD_LIBS="$opt"
 755                THREADED_DELTA_SEARCH=YesPlease
 756                break
 757        ],
 758        [AC_MSG_RESULT([no])])
 759      CFLAGS="$old_CFLAGS"
 760  done
 761else
 762  old_CFLAGS="$CFLAGS"
 763  CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 764  AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 765  AC_LINK_IFELSE(PTHREADTEST_SRC,
 766        [AC_MSG_RESULT([yes])
 767                NO_PTHREADS=
 768                PTHREAD_LIBS="$PTHREAD_CFLAGS"
 769                THREADED_DELTA_SEARCH=YesPlease
 770        ],
 771        [AC_MSG_RESULT([no])])
 772
 773  CFLAGS="$old_CFLAGS"
 774fi
 775
 776CFLAGS="$old_CFLAGS"
 777
 778AC_SUBST(PTHREAD_LIBS)
 779AC_SUBST(NO_PTHREADS)
 780AC_SUBST(THREADED_DELTA_SEARCH)
 781
 782## Output files
 783AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 784AC_OUTPUT
 785
 786
 787## Cleanup
 788rm -f "${config_append}"