Andrew's git / gitweb.git / lib/blame.tcl
?
lib / blame.tclon commit git-gui: Space the commit group continuation out in blame view (ddc1fa8)
   1# git-gui blame viewer
   2# Copyright (C) 2006, 2007 Shawn Pearce
   3
   4class blame {
   5
   6field commit  ; # input commit to blame
   7field path    ; # input filename to view in $commit
   8
   9field w
  10field w_line
  11field w_cgrp
  12field w_load
  13field w_file
  14field w_cmit
  15field status
  16
  17field highlight_line   -1 ; # current line selected
  18field highlight_commit {} ; # sha1 of commit selected
  19
  20field total_lines       0  ; # total length of file
  21field blame_lines       0  ; # number of lines computed
  22field commit_count      0  ; # number of commits in $commit_list
  23field commit_list      {}  ; # list of commit sha1 in receipt order
  24field order                ; # array commit -> receipt order
  25field header               ; # array commit,key -> header field
  26field line_commit          ; # array line -> sha1 commit
  27field line_file            ; # array line -> file name
  28
  29field r_commit      ; # commit currently being parsed
  30field r_orig_line   ; # original line number
  31field r_final_line  ; # final line number
  32field r_line_count  ; # lines in this region
  33
  34field tooltip_wm     {} ; # Current tooltip toplevel, if open
  35field tooltip_timer  {} ; # Current timer event for our tooltip
  36field tooltip_commit {} ; # Commit in tooltip
  37field tooltip_text   {} ; # Text in current tooltip
  38
  39variable active_color #98e1a0
  40variable group_colors {
  41        #cbcbcb
  42        #e1e1e1
  43}
  44
  45constructor new {i_commit i_path} {
  46        variable active_color
  47        global cursor_ptr
  48
  49        set commit $i_commit
  50        set path   $i_path
  51
  52        make_toplevel top w
  53        wm title $top "[appname] ([reponame]): File Viewer"
  54        set status "Loading $commit:$path..."
  55
  56        label $w.path -text "$commit:$path" \
  57                -anchor w \
  58                -justify left \
  59                -borderwidth 1 \
  60                -relief sunken \
  61                -font font_uibold
  62        pack $w.path -side top -fill x
  63
  64        frame $w.out
  65        set w_load $w.out.loaded_t
  66        text $w_load \
  67                -background white -borderwidth 0 \
  68                -state disabled \
  69                -wrap none \
  70                -height 40 \
  71                -width 1 \
  72                -font font_diff
  73        $w_load tag conf annotated -background grey
  74
  75        set w_line $w.out.linenumber_t
  76        text $w_line \
  77                -background white -borderwidth 0 \
  78                -state disabled \
  79                -wrap none \
  80                -height 40 \
  81                -width 5 \
  82                -font font_diff
  83        $w_line tag conf linenumber -justify right
  84
  85        set w_cgrp $w.out.commit_t
  86        text $w_cgrp \
  87                -background white -borderwidth 0 \
  88                -state disabled \
  89                -wrap none \
  90                -height 40 \
  91                -width 4 \
  92                -font font_diff
  93
  94        set w_file $w.out.file_t
  95        text $w_file \
  96                -background white -borderwidth 0 \
  97                -state disabled \
  98                -wrap none \
  99                -height 40 \
 100                -width 80 \
 101                -xscrollcommand [list $w.out.sbx set] \
 102                -font font_diff
 103
 104        scrollbar $w.out.sbx -orient h -command [list $w_file xview]
 105        scrollbar $w.out.sby -orient v \
 106                -command [list scrollbar2many [list \
 107                $w_load \
 108                $w_line \
 109                $w_cgrp \
 110                $w_file \
 111                ] yview]
 112        grid \
 113                $w_cgrp \
 114                $w_line \
 115                $w_load \
 116                $w_file \
 117                $w.out.sby \
 118                -sticky nsew
 119        grid conf $w.out.sbx -column 3 -sticky we
 120        grid columnconfigure $w.out 3 -weight 1
 121        grid rowconfigure $w.out 0 -weight 1
 122        pack $w.out -fill both -expand 1
 123
 124        label $w.status \
 125                -textvariable @status \
 126                -anchor w \
 127                -justify left \
 128                -borderwidth 1 \
 129                -relief sunken
 130        pack $w.status -side bottom -fill x
 131
 132        frame $w.cm
 133        set w_cmit $w.cm.t
 134        text $w_cmit \
 135                -background white -borderwidth 0 \
 136                -state disabled \
 137                -wrap none \
 138                -height 10 \
 139                -width 80 \
 140                -xscrollcommand [list $w.cm.sbx set] \
 141                -yscrollcommand [list $w.cm.sby set] \
 142                -font font_diff
 143        $w_cmit tag conf header_key \
 144                -tabs {3c} \
 145                -background $active_color \
 146                -font font_uibold
 147        $w_cmit tag conf header_val \
 148                -background $active_color \
 149                -font font_ui
 150        $w_cmit tag raise sel
 151        scrollbar $w.cm.sbx -orient h -command [list $w_cmit xview]
 152        scrollbar $w.cm.sby -orient v -command [list $w_cmit yview]
 153        pack $w.cm.sby -side right -fill y
 154        pack $w.cm.sbx -side bottom -fill x
 155        pack $w_cmit -expand 1 -fill both
 156        pack $w.cm -side bottom -fill x
 157
 158        menu $w.ctxm -tearoff 0
 159        $w.ctxm add command \
 160                -label "Copy Commit" \
 161                -command [cb _copycommit]
 162
 163        foreach i [list \
 164                $w_cgrp \
 165                $w_load \
 166                $w_line \
 167                $w_file] {
 168                $i conf -cursor $cursor_ptr
 169                $i conf -yscrollcommand \
 170                        [list many2scrollbar [list \
 171                        $w_cgrp \
 172                        $w_load \
 173                        $w_line \
 174                        $w_file \
 175                        ] yview $w.out.sby]
 176                bind $i <Button-1> "
 177                        [cb _hide_tooltip]
 178                        [cb _click $i @%x,%y]
 179                        focus $i
 180                "
 181                bind $i <Any-Motion>  [cb _show_tooltip $i @%x,%y]
 182                bind $i <Any-Enter>   [cb _hide_tooltip]
 183                bind $i <Any-Leave>   [cb _hide_tooltip]
 184                bind_button3 $i "
 185                        [cb _hide_tooltip]
 186                        set cursorX %x
 187                        set cursorY %y
 188                        set cursorW %W
 189                        tk_popup $w.ctxm %X %Y
 190                "
 191        }
 192
 193        foreach i [list \
 194                $w_cgrp \
 195                $w_load \
 196                $w_line \
 197                $w_file \
 198                $w_cmit] {
 199                bind $i <Key-Up>        {catch {%W yview scroll -1 units};break}
 200                bind $i <Key-Down>      {catch {%W yview scroll  1 units};break}
 201                bind $i <Key-Left>      {catch {%W xview scroll -1 units};break}
 202                bind $i <Key-Right>     {catch {%W xview scroll  1 units};break}
 203                bind $i <Key-k>         {catch {%W yview scroll -1 units};break}
 204                bind $i <Key-j>         {catch {%W yview scroll  1 units};break}
 205                bind $i <Key-h>         {catch {%W xview scroll -1 units};break}
 206                bind $i <Key-l>         {catch {%W xview scroll  1 units};break}
 207                bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
 208                bind $i <Control-Key-f> {catch {%W yview scroll  1 pages};break}
 209        }
 210
 211        bind $w_cmit <Button-1> [list focus $w_cmit]
 212        bind $top <Visibility> [list focus $top]
 213        bind $top <Destroy> [list delete_this $this]
 214
 215        if {$commit eq {}} {
 216                set fd [open $path r]
 217        } else {
 218                set cmd [list git cat-file blob "$commit:$path"]
 219                set fd [open "| $cmd" r]
 220        }
 221        fconfigure $fd -blocking 0 -translation lf -encoding binary
 222        fileevent $fd readable [cb _read_file $fd]
 223}
 224
 225method _read_file {fd} {
 226        $w_load conf -state normal
 227        $w_cgrp conf -state normal
 228        $w_line conf -state normal
 229        $w_file conf -state normal
 230        while {[gets $fd line] >= 0} {
 231                regsub "\r\$" $line {} line
 232                incr total_lines
 233
 234                if {$total_lines > 1} {
 235                        $w_load insert end "\n"
 236                        $w_cgrp insert end "\n"
 237                        $w_line insert end "\n"
 238                        $w_file insert end "\n"
 239                }
 240
 241                $w_line insert end "$total_lines" linenumber
 242                $w_file insert end "$line"
 243        }
 244        $w_load conf -state disabled
 245        $w_cgrp conf -state disabled
 246        $w_line conf -state disabled
 247        $w_file conf -state disabled
 248
 249        if {[eof $fd]} {
 250                close $fd
 251                _status $this
 252                set cmd [list git blame -M -C --incremental]
 253                if {$commit eq {}} {
 254                        lappend cmd --contents $path
 255                } else {
 256                        lappend cmd $commit
 257                }
 258                lappend cmd -- $path
 259                set fd [open "| $cmd" r]
 260                fconfigure $fd -blocking 0 -translation lf -encoding binary
 261                fileevent $fd readable [cb _read_blame $fd]
 262        }
 263} ifdeleted { catch {close $fd} }
 264
 265method _read_blame {fd} {
 266        variable group_colors
 267
 268        $w_cgrp conf -state normal
 269        while {[gets $fd line] >= 0} {
 270                if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
 271                        cmit original_line final_line line_count]} {
 272                        set r_commit     $cmit
 273                        set r_orig_line  $original_line
 274                        set r_final_line $final_line
 275                        set r_line_count $line_count
 276
 277                        if {[catch {set g $order($cmit)}]} {
 278                                set bg [lindex $group_colors 0]
 279                                set group_colors [lrange $group_colors 1 end]
 280                                lappend group_colors $bg
 281
 282                                $w_cgrp tag conf g$cmit -background $bg
 283                                $w_line tag conf g$cmit -background $bg
 284                                $w_file tag conf g$cmit -background $bg
 285
 286                                set order($cmit) $commit_count
 287                                incr commit_count
 288                                lappend commit_list $cmit
 289                        }
 290                } elseif {[string match {filename *} $line]} {
 291                        set file [string range $line 9 end]
 292                        set n    $r_line_count
 293                        set lno  $r_final_line
 294                        set cmit $r_commit
 295
 296                        if {[regexp {^0{40}$} $cmit]} {
 297                                set abbr work
 298                        } else {
 299                                set abbr [string range $cmit 0 4]
 300                        }
 301
 302                        if {![catch {set ncmit $line_commit([expr {$lno - 1}])}]} {
 303                                if {$ncmit eq $cmit} {
 304                                        set abbr { |}
 305                                }
 306                        }
 307
 308                        while {$n > 0} {
 309                                set lno_e "$lno.0 lineend + 1c"
 310                                if {[catch {set g g$line_commit($lno)}]} {
 311                                        $w_load tag add annotated $lno.0 $lno_e
 312                                } else {
 313                                        $w_cgrp tag remove g$g $lno.0 $lno_e
 314                                        $w_line tag remove g$g $lno.0 $lno_e
 315                                        $w_file tag remove g$g $lno.0 $lno_e
 316
 317                                        $w_cgrp tag remove a$g $lno.0 $lno_e
 318                                        $w_line tag remove a$g $lno.0 $lno_e
 319                                        $w_file tag remove a$g $lno.0 $lno_e
 320                                }
 321
 322                                set line_commit($lno) $cmit
 323                                set line_file($lno)   $file
 324
 325                                $w_cgrp delete $lno.0 "$lno.0 lineend"
 326                                $w_cgrp insert $lno.0 $abbr
 327                                set abbr { |}
 328
 329                                $w_cgrp tag add g$cmit $lno.0 $lno_e
 330                                $w_line tag add g$cmit $lno.0 $lno_e
 331                                $w_file tag add g$cmit $lno.0 $lno_e
 332
 333                                $w_cgrp tag add a$cmit $lno.0 $lno_e
 334                                $w_line tag add a$cmit $lno.0 $lno_e
 335                                $w_file tag add a$cmit $lno.0 $lno_e
 336
 337                                if {$highlight_line == -1} {
 338                                        if {[lindex [$w_file yview] 0] == 0} {
 339                                                $w_file see $lno.0
 340                                                _showcommit $this $lno
 341                                        }
 342                                } elseif {$highlight_line == $lno} {
 343                                        _showcommit $this $lno
 344                                }
 345
 346                                incr n -1
 347                                incr lno
 348                                incr blame_lines
 349                        }
 350
 351                        if {![catch {set ncmit $line_commit($lno)}]} {
 352                                if {$ncmit eq $cmit} {
 353                                        $w_cgrp delete $lno.0 "$lno.0 lineend + 1c"
 354                                        $w_cgrp insert $lno.0 " |\n"
 355                                }
 356                        }
 357                } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
 358                        set header($r_commit,$key) $data
 359                }
 360        }
 361        $w_cgrp conf -state disabled
 362
 363        if {[eof $fd]} {
 364                close $fd
 365                set status {Annotation complete.}
 366        } else {
 367                _status $this
 368        }
 369} ifdeleted { catch {close $fd} }
 370
 371method _status {} {
 372        set have  $blame_lines
 373        set total $total_lines
 374        set pdone 0
 375        if {$total} {set pdone [expr {100 * $have / $total}]}
 376
 377        set status [format \
 378                "Loading annotations... %i of %i lines annotated (%2i%%)" \
 379                $have $total $pdone]
 380}
 381
 382method _click {cur_w pos} {
 383        set lno [lindex [split [$cur_w index $pos] .] 0]
 384        if {$lno eq {}} return
 385        _showcommit $this $lno
 386}
 387
 388method _showcommit {lno} {
 389        global repo_config
 390        variable active_color
 391
 392        if {$highlight_commit ne {}} {
 393                set cmit $highlight_commit
 394                $w_cgrp tag conf a$cmit -background {}
 395                $w_line tag conf a$cmit -background {}
 396                $w_file tag conf a$cmit -background {}
 397        }
 398
 399        $w_cmit conf -state normal
 400        $w_cmit delete 0.0 end
 401        if {[catch {set cmit $line_commit($lno)}]} {
 402                set cmit {}
 403                $w_cmit insert end "Loading annotation..."
 404        } else {
 405                $w_cgrp tag conf a$cmit -background $active_color
 406                $w_line tag conf a$cmit -background $active_color
 407                $w_file tag conf a$cmit -background $active_color
 408
 409                set author_name {}
 410                set author_email {}
 411                set author_time {}
 412                catch {set author_name $header($cmit,author)}
 413                catch {set author_email $header($cmit,author-mail)}
 414                catch {set author_time [clock format \
 415                        $header($cmit,author-time) \
 416                        -format {%Y-%m-%d %H:%M:%S}
 417                ]}
 418
 419                set committer_name {}
 420                set committer_email {}
 421                set committer_time {}
 422                catch {set committer_name $header($cmit,committer)}
 423                catch {set committer_email $header($cmit,committer-mail)}
 424                catch {set committer_time [clock format \
 425                        $header($cmit,committer-time) \
 426                        -format {%Y-%m-%d %H:%M:%S}
 427                ]}
 428
 429                if {[catch {set msg $header($cmit,message)}]} {
 430                        set msg {}
 431                        catch {
 432                                set fd [open "| git cat-file commit $cmit" r]
 433                                fconfigure $fd -encoding binary -translation lf
 434                                if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
 435                                        set enc utf-8
 436                                }
 437                                while {[gets $fd line] > 0} {
 438                                        if {[string match {encoding *} $line]} {
 439                                                set enc [string tolower [string range $line 9 end]]
 440                                        }
 441                                }
 442                                set msg [encoding convertfrom $enc [read $fd]]
 443                                set msg [string trim $msg]
 444                                close $fd
 445
 446                                set author_name [encoding convertfrom $enc $author_name]
 447                                set committer_name [encoding convertfrom $enc $committer_name]
 448
 449                                set header($cmit,author) $author_name
 450                                set header($cmit,committer) $committer_name
 451                        }
 452                        set header($cmit,message) $msg
 453                }
 454
 455                $w_cmit insert end "commit $cmit\n" header_key
 456                $w_cmit insert end "Author:\t" header_key
 457                $w_cmit insert end "$author_name $author_email" header_val
 458                $w_cmit insert end "$author_time\n" header_val
 459
 460                $w_cmit insert end "Committer:\t" header_key
 461                $w_cmit insert end "$committer_name $committer_email" header_val
 462                $w_cmit insert end "$committer_time\n" header_val
 463
 464                if {$line_file($lno) ne $path} {
 465                        $w_cmit insert end "Original File:\t" header_key
 466                        $w_cmit insert end "[escape_path $line_file($lno)]\n" header_val
 467                }
 468
 469                $w_cmit insert end "\n$msg"
 470        }
 471        $w_cmit conf -state disabled
 472
 473        set highlight_line $lno
 474        set highlight_commit $cmit
 475
 476        if {$highlight_commit eq $tooltip_commit} {
 477                _hide_tooltip $this
 478        }
 479}
 480
 481method _copycommit {} {
 482        set pos @$::cursorX,$::cursorY
 483        set lno [lindex [split [$::cursorW index $pos] .] 0]
 484        if {![catch {set commit $line_commit($lno)}]} {
 485                clipboard clear
 486                clipboard append \
 487                        -format STRING \
 488                        -type STRING \
 489                        -- $commit
 490        }
 491}
 492
 493method _show_tooltip {cur_w pos} {
 494        set lno [lindex [split [$cur_w index $pos] .] 0]
 495        if {[catch {set cmit $line_commit($lno)}]} {
 496                _hide_tooltip $this
 497                return
 498        }
 499
 500        if {$cmit eq $highlight_commit} {
 501                _hide_tooltip $this
 502                return
 503        }
 504
 505        if {$cmit eq $tooltip_commit} {
 506                _position_tooltip $this
 507        } elseif {$tooltip_wm ne {}} {
 508                _open_tooltip $this $cur_w
 509        } elseif {$tooltip_timer eq {}} {
 510                set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
 511        }
 512}
 513
 514method _open_tooltip {cur_w} {
 515        set tooltip_timer {}
 516        set pos_x [winfo pointerx $cur_w]
 517        set pos_y [winfo pointery $cur_w]
 518        if {[winfo containing $pos_x $pos_y] ne $cur_w} {
 519                _hide_tooltip $this
 520                return
 521        }
 522
 523        set pos @[join [list \
 524                [expr {$pos_x - [winfo rootx $cur_w]}] \
 525                [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
 526        set lno [lindex [split [$cur_w index $pos] .] 0]
 527        set cmit $line_commit($lno)
 528
 529        set author_name {}
 530        set author_email {}
 531        set author_time {}
 532        catch {set author_name $header($cmit,author)}
 533        catch {set author_email $header($cmit,author-mail)}
 534        catch {set author_time [clock format \
 535                $header($cmit,author-time) \
 536                -format {%Y-%m-%d %H:%M:%S}
 537        ]}
 538
 539        set committer_name {}
 540        set committer_email {}
 541        set committer_time {}
 542        catch {set committer_name $header($cmit,committer)}
 543        catch {set committer_email $header($cmit,committer-mail)}
 544        catch {set committer_time [clock format \
 545                $header($cmit,committer-time) \
 546                -format {%Y-%m-%d %H:%M:%S}
 547        ]}
 548
 549        set summary {}
 550        catch {set summary $header($cmit,summary)}
 551
 552        set tooltip_commit $cmit
 553        set tooltip_text "commit $cmit
 554$author_name $author_email  $author_time
 555$summary"
 556
 557        if {$tooltip_wm ne "$cur_w.tooltip"} {
 558                _hide_tooltip $this
 559
 560                set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
 561                wm overrideredirect $tooltip_wm 1
 562                wm transient $tooltip_wm [winfo toplevel $cur_w]
 563                pack [label $tooltip_wm.label \
 564                        -background lightyellow \
 565                        -foreground black \
 566                        -textvariable @tooltip_text \
 567                        -justify left]
 568        }
 569        _position_tooltip $this
 570}
 571
 572method _position_tooltip {} {
 573        set req_w [winfo reqwidth  $tooltip_wm.label]
 574        set req_h [winfo reqheight $tooltip_wm.label]
 575        set pos_x [expr {[winfo pointerx .] +  5}]
 576        set pos_y [expr {[winfo pointery .] + 10}]
 577
 578        set g "${req_w}x${req_h}"
 579        if {$pos_x >= 0} {append g +}
 580        append g $pos_x
 581        if {$pos_y >= 0} {append g +}
 582        append g $pos_y
 583
 584        wm geometry $tooltip_wm $g
 585        raise $tooltip_wm
 586}
 587
 588method _hide_tooltip {} {
 589        if {$tooltip_wm ne {}} {
 590                destroy $tooltip_wm
 591                set tooltip_wm {}
 592                set tooltip_commit {}
 593        }
 594        if {$tooltip_timer ne {}} {
 595                after cancel $tooltip_timer
 596                set tooltip_timer {}
 597        }
 598}
 599
 600}