Andrew's git / gitweb.git / git-svnimport.perl
?
git-svnimport.perlon commit rev-list --objects: use full pathname to help hashing. (e646de0)
   1#!/usr/bin/perl -w
   2
   3# This tool is copyright (c) 2005, Matthias Urlichs.
   4# It is released under the Gnu Public License, version 2.
   5#
   6# The basic idea is to pull and analyze SVN changes.
   7#
   8# Checking out the files is done by a single long-running SVN connection.
   9#
  10# The head revision is on branch "origin" by default.
  11# You can change that with the '-o' option.
  12
  13require 5.008; # for shell-safe open("-|",LIST)
  14use strict;
  15use warnings;
  16use Getopt::Std;
  17use File::Spec;
  18use File::Temp qw(tempfile);
  19use File::Path qw(mkpath);
  20use File::Basename qw(basename dirname);
  21use Time::Local;
  22use IO::Pipe;
  23use POSIX qw(strftime dup2);
  24use IPC::Open2;
  25use SVN::Core;
  26use SVN::Ra;
  27
  28die "Need SVN:Core 1.2.1 or better" if $SVN::Core::VERSION lt "1.2.1";
  29
  30$SIG{'PIPE'}="IGNORE";
  31$ENV{'TZ'}="UTC";
  32
  33our($opt_h,$opt_o,$opt_v,$opt_u,$opt_C,$opt_i,$opt_m,$opt_M,$opt_t,$opt_T,$opt_b,$opt_r,$opt_s,$opt_l,$opt_d,$opt_D);
  34
  35sub usage() {
  36        print STDERR <<END;
  37Usage: ${\basename $0}     # fetch/update GIT from SVN
  38       [-o branch-for-HEAD] [-h] [-v] [-l max_rev]
  39       [-C GIT_repository] [-t tagname] [-T trunkname] [-b branchname]
  40       [-d|-D] [-i] [-u] [-r] [-s start_chg] [-m] [-M regex] [SVN_URL]
  41END
  42        exit(1);
  43}
  44
  45getopts("b:C:dDhil:mM:o:rs:t:T:uv") or usage();
  46usage if $opt_h;
  47
  48my $tag_name = $opt_t || "tags";
  49my $trunk_name = $opt_T || "trunk";
  50my $branch_name = $opt_b || "branches";
  51
  52@ARGV == 1 or @ARGV == 2 or usage();
  53
  54$opt_o ||= "origin";
  55$opt_s ||= 1;
  56my $git_tree = $opt_C;
  57$git_tree ||= ".";
  58
  59my $svn_url = $ARGV[0];
  60my $svn_dir = $ARGV[1];
  61
  62our @mergerx = ();
  63if ($opt_m) {
  64        @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
  65}
  66if ($opt_M) {
  67        push (@mergerx, qr/$opt_M/);
  68}
  69
  70select(STDERR); $|=1; select(STDOUT);
  71
  72
  73package SVNconn;
  74# Basic SVN connection.
  75# We're only interested in connecting and downloading, so ...
  76
  77use File::Spec;
  78use File::Temp qw(tempfile);
  79use POSIX qw(strftime dup2);
  80
  81sub new {
  82        my($what,$repo) = @_;
  83        $what=ref($what) if ref($what);
  84
  85        my $self = {};
  86        $self->{'buffer'} = "";
  87        bless($self,$what);
  88
  89        $repo =~ s#/+$##;
  90        $self->{'fullrep'} = $repo;
  91        $self->conn();
  92
  93        return $self;
  94}
  95
  96sub conn {
  97        my $self = shift;
  98        my $repo = $self->{'fullrep'};
  99        my $auth = SVN::Core::auth_open ([SVN::Client::get_simple_provider,
 100                          SVN::Client::get_ssl_server_trust_file_provider,
 101                          SVN::Client::get_username_provider]);
 102        my $s = SVN::Ra->new(url => $repo, auth => $auth);
 103        die "SVN connection to $repo: $!\n" unless defined $s;
 104        $self->{'svn'} = $s;
 105        $self->{'repo'} = $repo;
 106        $self->{'maxrev'} = $s->get_latest_revnum();
 107}
 108
 109sub file {
 110        my($self,$path,$rev) = @_;
 111
 112        my ($fh, $name) = tempfile('gitsvn.XXXXXX',
 113                    DIR => File::Spec->tmpdir(), UNLINK => 1);
 114
 115        print "... $rev $path ...\n" if $opt_v;
 116        my $pool = SVN::Pool->new();
 117        eval { $self->{'svn'}->get_file($path,$rev,$fh,$pool); };
 118        $pool->clear;
 119        if($@) {
 120                return undef if $@ =~ /Attempted to get checksum/;
 121                die $@;
 122        }
 123        close ($fh);
 124
 125        return $name;
 126}
 127
 128package main;
 129use URI;
 130
 131our $svn = $svn_url;
 132$svn .= "/$svn_dir" if defined $svn_dir;
 133my $svn2 = SVNconn->new($svn);
 134$svn = SVNconn->new($svn);
 135
 136my $lwp_ua;
 137if($opt_d or $opt_D) {
 138        $svn_url = URI->new($svn_url)->canonical;
 139        if($opt_D) {
 140                $svn_dir =~ s#/*$#/#;
 141        } else {
 142                $svn_dir = "";
 143        }
 144        if ($svn_url->scheme eq "http") {
 145                use LWP::UserAgent;
 146                $lwp_ua = LWP::UserAgent->new(keep_alive => 1, requests_redirectable => []);
 147        } else {
 148                print STDERR "Warning: not HTTP; turning off direct file access\n";
 149                $opt_d=0;
 150        }
 151}
 152
 153sub pdate($) {
 154        my($d) = @_;
 155        $d =~ m#(\d\d\d\d)-(\d\d)-(\d\d)T(\d\d):(\d\d):(\d\d)#
 156                or die "Unparseable date: $d\n";
 157        my $y=$1; $y-=1900 if $y>1900;
 158        return timegm($6||0,$5,$4,$3,$2-1,$y);
 159}
 160
 161sub getwd() {
 162        my $pwd = `pwd`;
 163        chomp $pwd;
 164        return $pwd;
 165}
 166
 167
 168sub get_headref($$) {
 169    my $name    = shift;
 170    my $git_dir = shift;
 171    my $sha;
 172
 173    if (open(C,"$git_dir/refs/heads/$name")) {
 174        chomp($sha = <C>);
 175        close(C);
 176        length($sha) == 40
 177            or die "Cannot get head id for $name ($sha): $!\n";
 178    }
 179    return $sha;
 180}
 181
 182
 183-d $git_tree
 184        or mkdir($git_tree,0777)
 185        or die "Could not create $git_tree: $!";
 186chdir($git_tree);
 187
 188my $orig_branch = "";
 189my $forward_master = 0;
 190my %branches;
 191
 192my $git_dir = $ENV{"GIT_DIR"} || ".git";
 193$git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 194$ENV{"GIT_DIR"} = $git_dir;
 195my $orig_git_index;
 196$orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 197my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 198                                    DIR => File::Spec->tmpdir());
 199close ($git_ih);
 200$ENV{GIT_INDEX_FILE} = $git_index;
 201my $maxnum = 0;
 202my $last_rev = "";
 203my $last_branch;
 204my $current_rev = $opt_s || 1;
 205unless(-d $git_dir) {
 206        system("git-init-db");
 207        die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 208        system("git-read-tree");
 209        die "Cannot init an empty tree: $?\n" if $?;
 210
 211        $last_branch = $opt_o;
 212        $orig_branch = "";
 213} else {
 214        -f "$git_dir/refs/heads/$opt_o"
 215                or die "Branch '$opt_o' does not exist.\n".
 216                       "Either use the correct '-o branch' option,\n".
 217                       "or import to a new repository.\n";
 218
 219        -f "$git_dir/svn2git"
 220                or die "'$git_dir/svn2git' does not exist.\n".
 221                       "You need that file for incremental imports.\n";
 222        open(F, "git-symbolic-ref HEAD |") or
 223                die "Cannot run git-symbolic-ref: $!\n";
 224        chomp ($last_branch = <F>);
 225        $last_branch = basename($last_branch);
 226        close(F);
 227        unless($last_branch) {
 228                warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 229                $last_branch = "master";
 230        }
 231        $orig_branch = $last_branch;
 232        $last_rev = get_headref($orig_branch, $git_dir);
 233        if (-f "$git_dir/SVN2GIT_HEAD") {
 234                die <<EOM;
 235SVN2GIT_HEAD exists.
 236Make sure your working directory corresponds to HEAD and remove SVN2GIT_HEAD.
 237You may need to run
 238
 239    git-read-tree -m -u SVN2GIT_HEAD HEAD
 240EOM
 241        }
 242        system('cp', "$git_dir/HEAD", "$git_dir/SVN2GIT_HEAD");
 243
 244        $forward_master =
 245            $opt_o ne 'master' && -f "$git_dir/refs/heads/master" &&
 246            system('cmp', '-s', "$git_dir/refs/heads/master",
 247                                "$git_dir/refs/heads/$opt_o") == 0;
 248
 249        # populate index
 250        system('git-read-tree', $last_rev);
 251        die "read-tree failed: $?\n" if $?;
 252
 253        # Get the last import timestamps
 254        open my $B,"<", "$git_dir/svn2git";
 255        while(<$B>) {
 256                chomp;
 257                my($num,$branch,$ref) = split;
 258                $branches{$branch}{$num} = $ref;
 259                $branches{$branch}{"LAST"} = $ref;
 260                $current_rev = $num+1 if $current_rev <= $num;
 261        }
 262        close($B);
 263}
 264-d $git_dir
 265        or die "Could not create git subdir ($git_dir).\n";
 266
 267open BRANCHES,">>", "$git_dir/svn2git";
 268
 269sub node_kind($$$) {
 270        my ($branch, $path, $revision) = @_;
 271        my $pool=SVN::Pool->new;
 272        my $kind = $svn->{'svn'}->check_path(revert_split_path($branch,$path),$revision,$pool);
 273        $pool->clear;
 274        return $kind;
 275}
 276
 277sub revert_split_path($$) {
 278        my($branch,$path) = @_;
 279
 280        my $svnpath;
 281        $path = "" if $path eq "/"; # this should not happen, but ...
 282        if($branch eq "/") {
 283                $svnpath = "$trunk_name/$path";
 284        } elsif($branch =~ m#^/#) {
 285                $svnpath = "$tag_name$branch/$path";
 286        } else {
 287                $svnpath = "$branch_name/$branch/$path";
 288        }
 289
 290        $svnpath =~ s#/+$##;
 291        return $svnpath;
 292}
 293
 294sub get_file($$$) {
 295        my($rev,$branch,$path) = @_;
 296
 297        my $svnpath = revert_split_path($branch,$path);
 298
 299        # now get it
 300        my $name;
 301        if($opt_d) {
 302                my($req,$res);
 303
 304                # /svn/!svn/bc/2/django/trunk/django-docs/build.py
 305                my $url=$svn_url->clone();
 306                $url->path($url->path."/!svn/bc/$rev/$svn_dir$svnpath");
 307                print "... $path...\n" if $opt_v;
 308                $req = HTTP::Request->new(GET => $url);
 309                $res = $lwp_ua->request($req);
 310                if ($res->is_success) {
 311                        my $fh;
 312                        ($fh, $name) = tempfile('gitsvn.XXXXXX',
 313                        DIR => File::Spec->tmpdir(), UNLINK => 1);
 314                        print $fh $res->content;
 315                        close($fh) or die "Could not write $name: $!\n";
 316                } else {
 317                        return undef if $res->code == 301; # directory?
 318                        die $res->status_line." at $url\n";
 319                }
 320        } else {
 321                $name = $svn->file("$svnpath",$rev);
 322                return undef unless defined $name;
 323        }
 324
 325        open my $F, '-|', "git-hash-object", "-w", $name
 326                or die "Cannot create object: $!\n";
 327        my $sha = <$F>;
 328        chomp $sha;
 329        close $F;
 330        unlink $name;
 331        my $mode = "0644"; # SV does not seem to store any file modes
 332        return [$mode, $sha, $path];
 333}
 334
 335sub split_path($$) {
 336        my($rev,$path) = @_;
 337        my $branch;
 338
 339        if($path =~ s#^/\Q$tag_name\E/([^/]+)/?##) {
 340                $branch = "/$1";
 341        } elsif($path =~ s#^/\Q$trunk_name\E/?##) {
 342                $branch = "/";
 343        } elsif($path =~ s#^/\Q$branch_name\E/([^/]+)/?##) {
 344                $branch = $1;
 345        } else {
 346                my %no_error = (
 347                        "/" => 1,
 348                        "/$tag_name" => 1,
 349                        "/$branch_name" => 1
 350                );
 351                print STDERR "$rev: Unrecognized path: $path\n" unless (defined $no_error{$path});
 352                return ()
 353        }
 354        $path = "/" if $path eq "";
 355        return ($branch,$path);
 356}
 357
 358sub branch_rev($$) {
 359
 360        my ($srcbranch,$uptorev) = @_;
 361
 362        my $bbranches = $branches{$srcbranch};
 363        my @revs = reverse sort { ($a eq 'LAST' ? 0 : $a) <=> ($b eq 'LAST' ? 0 : $b) } keys %$bbranches;
 364        my $therev;
 365        foreach my $arev(@revs) {
 366                next if  ($arev eq 'LAST');
 367                if ($arev <= $uptorev) {
 368                        $therev = $arev;
 369                        last;
 370                }
 371        }
 372        return $therev;
 373}
 374
 375sub copy_path($$$$$$$$) {
 376        # Somebody copied a whole subdirectory.
 377        # We need to find the index entries from the old version which the
 378        # SVN log entry points to, and add them to the new place.
 379
 380        my($newrev,$newbranch,$path,$oldpath,$rev,$node_kind,$new,$parents) = @_;
 381
 382        my($srcbranch,$srcpath) = split_path($rev,$oldpath);
 383        unless(defined $srcbranch) {
 384                print "Path not found when copying from $oldpath @ $rev\n";
 385                return;
 386        }
 387        my $therev = branch_rev($srcbranch, $rev);
 388        my $gitrev = $branches{$srcbranch}{$therev};
 389        unless($gitrev) {
 390                print STDERR "$newrev:$newbranch: could not find $oldpath \@ $rev\n";
 391                return;
 392        }
 393        if ($srcbranch ne $newbranch) {
 394                push(@$parents, $branches{$srcbranch}{'LAST'});
 395        }
 396        print "$newrev:$newbranch:$path: copying from $srcbranch:$srcpath @ $rev\n" if $opt_v;
 397        if ($node_kind eq $SVN::Node::dir) {
 398                        $srcpath =~ s#/*$#/#;
 399        }
 400        
 401        open my $f,"-|","git-ls-tree","-r","-z",$gitrev,$srcpath;
 402        local $/ = "\0";
 403        while(<$f>) {
 404                chomp;
 405                my($m,$p) = split(/\t/,$_,2);
 406                my($mode,$type,$sha1) = split(/ /,$m);
 407                next if $type ne "blob";
 408                if ($node_kind eq $SVN::Node::dir) {
 409                        $p = $path . substr($p,length($srcpath)-1);
 410                } else {
 411                        $p = $path;
 412                }
 413                push(@$new,[$mode,$sha1,$p]);   
 414        }
 415        close($f) or
 416                print STDERR "$newrev:$newbranch: could not list files in $oldpath \@ $rev\n";
 417}
 418
 419sub commit {
 420        my($branch, $changed_paths, $revision, $author, $date, $message) = @_;
 421        my($author_name,$author_email,$dest);
 422        my(@old,@new,@parents);
 423
 424        if (not defined $author) {
 425                $author_name = $author_email = "unknown";
 426        } elsif ($author =~ /^(.*?)\s+<(.*)>$/) {
 427                ($author_name, $author_email) = ($1, $2);
 428        } else {
 429                $author =~ s/^<(.*)>$/$1/;
 430                $author_name = $author_email = $author;
 431        }
 432        $date = pdate($date);
 433
 434        my $tag;
 435        my $parent;
 436        if($branch eq "/") { # trunk
 437                $parent = $opt_o;
 438        } elsif($branch =~ m#^/(.+)#) { # tag
 439                $tag = 1;
 440                $parent = $1;
 441        } else { # "normal" branch
 442                # nothing to do
 443                $parent = $branch;
 444        }
 445        $dest = $parent;
 446
 447        my $prev = $changed_paths->{"/"};
 448        if($prev and $prev->[0] eq "A") {
 449                delete $changed_paths->{"/"};
 450                my $oldpath = $prev->[1];
 451                my $rev;
 452                if(defined $oldpath) {
 453                        my $p;
 454                        ($parent,$p) = split_path($revision,$oldpath);
 455                        if($parent eq "/") {
 456                                $parent = $opt_o;
 457                        } else {
 458                                $parent =~ s#^/##; # if it's a tag
 459                        }
 460                } else {
 461                        $parent = undef;
 462                }
 463        }
 464
 465        my $rev;
 466        if($revision > $opt_s and defined $parent) {
 467                open(H,"git-rev-parse --verify $parent |");
 468                $rev = <H>;
 469                close(H) or do {
 470                        print STDERR "$revision: cannot find commit '$parent'!\n";
 471                        return;
 472                };
 473                chop $rev;
 474                if(length($rev) != 40) {
 475                        print STDERR "$revision: cannot find commit '$parent'!\n";
 476                        return;
 477                }
 478                $rev = $branches{($parent eq $opt_o) ? "/" : $parent}{"LAST"};
 479                if($revision != $opt_s and not $rev) {
 480                        print STDERR "$revision: do not know ancestor for '$parent'!\n";
 481                        return;
 482                }
 483        } else {
 484                $rev = undef;
 485        }
 486
 487#       if($prev and $prev->[0] eq "A") {
 488#               if(not $tag) {
 489#                       unless(open(H,"> $git_dir/refs/heads/$branch")) {
 490#                               print STDERR "$revision: Could not create branch $branch: $!\n";
 491#                               $state=11;
 492#                               next;
 493#                       }
 494#                       print H "$rev\n"
 495#                               or die "Could not write branch $branch: $!";
 496#                       close(H)
 497#                               or die "Could not write branch $branch: $!";
 498#               }
 499#       }
 500        if(not defined $rev) {
 501                unlink($git_index);
 502        } elsif ($rev ne $last_rev) {
 503                print "Switching from $last_rev to $rev ($branch)\n" if $opt_v;
 504                system("git-read-tree", $rev);
 505                die "read-tree failed for $rev: $?\n" if $?;
 506                $last_rev = $rev;
 507        }
 508
 509        push (@parents, $rev) if defined $rev;
 510
 511        my $cid;
 512        if($tag and not %$changed_paths) {
 513                $cid = $rev;
 514        } else {
 515                my @paths = sort keys %$changed_paths;
 516                foreach my $path(@paths) {
 517                        my $action = $changed_paths->{$path};
 518
 519                        if ($action->[0] eq "R") {
 520                                # refer to a file/tree in an earlier commit
 521                                push(@old,$path); # remove any old stuff
 522                        }
 523                        if(($action->[0] eq "A") || ($action->[0] eq "R")) {
 524                                my $node_kind = node_kind($branch,$path,$revision);
 525                                if($action->[1]) {
 526                                        copy_path($revision,$branch,$path,$action->[1],$action->[2],$node_kind,\@new,\@parents);
 527                                } elsif ($node_kind eq $SVN::Node::file) {
 528                                        my $f = get_file($revision,$branch,$path);
 529                                        if ($f) {
 530                                                push(@new,$f) if $f;
 531                                        } else {
 532                                                my $opath = $action->[3];
 533                                                print STDERR "$revision: $branch: could not fetch '$opath'\n";
 534                                        }
 535                                }
 536                        } elsif ($action->[0] eq "D") {
 537                                push(@old,$path);
 538                        } elsif ($action->[0] eq "M") {
 539                                my $node_kind = node_kind($branch,$path,$revision);
 540                                if ($node_kind eq $SVN::Node::file) {
 541                                        my $f = get_file($revision,$branch,$path);
 542                                        push(@new,$f) if $f;
 543                                }
 544                        } else {
 545                                die "$revision: unknown action '".$action->[0]."' for $path\n";
 546                        }
 547                }
 548
 549                while(@old) {
 550                        my @o1;
 551                        if(@old > 55) {
 552                                @o1 = splice(@old,0,50);
 553                        } else {
 554                                @o1 = @old;
 555                                @old = ();
 556                        }
 557                        open my $F, "-|", "git-ls-files", "-z", @o1 or die $!;
 558                        @o1 = ();
 559                        local $/ = "\0";
 560                        while(<$F>) {
 561                                chomp;
 562                                push(@o1,$_);
 563                        }
 564                        close($F);
 565
 566                        while(@o1) {
 567                                my @o2;
 568                                if(@o1 > 55) {
 569                                        @o2 = splice(@o1,0,50);
 570                                } else {
 571                                        @o2 = @o1;
 572                                        @o1 = ();
 573                                }
 574                                system("git-update-index","--force-remove","--",@o2);
 575                                die "Cannot remove files: $?\n" if $?;
 576                        }
 577                }
 578                while(@new) {
 579                        my @n2;
 580                        if(@new > 12) {
 581                                @n2 = splice(@new,0,10);
 582                        } else {
 583                                @n2 = @new;
 584                                @new = ();
 585                        }
 586                        system("git-update-index","--add",
 587                                (map { ('--cacheinfo', @$_) } @n2));
 588                        die "Cannot add files: $?\n" if $?;
 589                }
 590
 591                my $pid = open(C,"-|");
 592                die "Cannot fork: $!" unless defined $pid;
 593                unless($pid) {
 594                        exec("git-write-tree");
 595                        die "Cannot exec git-write-tree: $!\n";
 596                }
 597                chomp(my $tree = <C>);
 598                length($tree) == 40
 599                        or die "Cannot get tree id ($tree): $!\n";
 600                close(C)
 601                        or die "Error running git-write-tree: $?\n";
 602                print "Tree ID $tree\n" if $opt_v;
 603
 604                my $pr = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 605                my $pw = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 606                $pid = fork();
 607                die "Fork: $!\n" unless defined $pid;
 608                unless($pid) {
 609                        $pr->writer();
 610                        $pw->reader();
 611                        open(OUT,">&STDOUT");
 612                        dup2($pw->fileno(),0);
 613                        dup2($pr->fileno(),1);
 614                        $pr->close();
 615                        $pw->close();
 616
 617                        my @par = ();
 618
 619                        # loose detection of merges
 620                        # based on the commit msg
 621                        foreach my $rx (@mergerx) {
 622                                if ($message =~ $rx) {
 623                                        my $mparent = $1;
 624                                        if ($mparent eq 'HEAD') { $mparent = $opt_o };
 625                                        if ( -e "$git_dir/refs/heads/$mparent") {
 626                                                $mparent = get_headref($mparent, $git_dir);
 627                                                push (@parents, $mparent);
 628                                                print OUT "Merge parent branch: $mparent\n" if $opt_v;
 629                                        }
 630                                }
 631                        }
 632                        my %seen_parents = ();
 633                        my @unique_parents = grep { ! $seen_parents{$_} ++ } @parents;
 634                        foreach my $bparent (@unique_parents) {
 635                                push @par, '-p', $bparent;
 636                                print OUT "Merge parent branch: $bparent\n" if $opt_v;
 637                        }
 638
 639                        exec("env",
 640                                "GIT_AUTHOR_NAME=$author_name",
 641                                "GIT_AUTHOR_EMAIL=$author_email",
 642                                "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 643                                "GIT_COMMITTER_NAME=$author_name",
 644                                "GIT_COMMITTER_EMAIL=$author_email",
 645                                "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 646                                "git-commit-tree", $tree,@par);
 647                        die "Cannot exec git-commit-tree: $!\n";
 648                }
 649                $pw->writer();
 650                $pr->reader();
 651
 652                $message =~ s/[\s\n]+\z//;
 653                $message = "r$revision: $message" if $opt_r;
 654
 655                print $pw "$message\n"
 656                        or die "Error writing to git-commit-tree: $!\n";
 657                $pw->close();
 658
 659                print "Committed change $revision:$branch ".strftime("%Y-%m-%d %H:%M:%S",gmtime($date)).")\n" if $opt_v;
 660                chomp($cid = <$pr>);
 661                length($cid) == 40
 662                        or die "Cannot get commit id ($cid): $!\n";
 663                print "Commit ID $cid\n" if $opt_v;
 664                $pr->close();
 665
 666                waitpid($pid,0);
 667                die "Error running git-commit-tree: $?\n" if $?;
 668        }
 669
 670        if (not defined $cid) {
 671                $cid = $branches{"/"}{"LAST"};
 672        }
 673
 674        if(not defined $dest) {
 675                print "... no known parent\n" if $opt_v;
 676        } elsif(not $tag) {
 677                print "Writing to refs/heads/$dest\n" if $opt_v;
 678                open(C,">$git_dir/refs/heads/$dest") and
 679                print C ("$cid\n") and
 680                close(C)
 681                        or die "Cannot write branch $dest for update: $!\n";
 682        }
 683
 684        if($tag) {
 685                my($in, $out) = ('','');
 686                $last_rev = "-" if %$changed_paths;
 687                # the tag was 'complex', i.e. did not refer to a "real" revision
 688
 689                $dest =~ tr/_/\./ if $opt_u;
 690                $branch = $dest;
 691
 692                my $pid = open2($in, $out, 'git-mktag');
 693                print $out ("object $cid\n".
 694                    "type commit\n".
 695                    "tag $dest\n".
 696                    "tagger $author_name <$author_email>\n") and
 697                close($out)
 698                    or die "Cannot create tag object $dest: $!\n";
 699
 700                my $tagobj = <$in>;
 701                chomp $tagobj;
 702
 703                if ( !close($in) or waitpid($pid, 0) != $pid or
 704                                $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 705                        die "Cannot create tag object $dest: $!\n";
 706                }
 707
 708                open(C,">$git_dir/refs/tags/$dest") and
 709                print C ("$tagobj\n") and
 710                close(C)
 711                        or die "Cannot create tag $branch: $!\n";
 712
 713                print "Created tag '$dest' on '$branch'\n" if $opt_v;
 714        }
 715        $branches{$branch}{"LAST"} = $cid;
 716        $branches{$branch}{$revision} = $cid;
 717        $last_rev = $cid;
 718        print BRANCHES "$revision $branch $cid\n";
 719        print "DONE: $revision $dest $cid\n" if $opt_v;
 720}
 721
 722sub commit_all {
 723        # Recursive use of the SVN connection does not work
 724        local $svn = $svn2;
 725
 726        my ($changed_paths, $revision, $author, $date, $message, $pool) = @_;
 727        my %p;
 728        while(my($path,$action) = each %$changed_paths) {
 729                $p{$path} = [ $action->action,$action->copyfrom_path, $action->copyfrom_rev, $path ];
 730        }
 731        $changed_paths = \%p;
 732
 733        my %done;
 734        my @col;
 735        my $pref;
 736        my $branch;
 737
 738        while(my($path,$action) = each %$changed_paths) {
 739                ($branch,$path) = split_path($revision,$path);
 740                next if not defined $branch;
 741                $done{$branch}{$path} = $action;
 742        }
 743        while(($branch,$changed_paths) = each %done) {
 744                commit($branch, $changed_paths, $revision, $author, $date, $message);
 745        }
 746}
 747
 748$opt_l = $svn->{'maxrev'} if not defined $opt_l or $opt_l > $svn->{'maxrev'};
 749
 750if ($svn->{'maxrev'} < $current_rev) {
 751    print "Up to date: no new revisions to fetch!\n" if $opt_v;
 752    unlink("$git_dir/SVN2GIT_HEAD");
 753    exit;
 754}
 755
 756print "Fetching from $current_rev to $opt_l ...\n" if $opt_v;
 757
 758my $pool=SVN::Pool->new;
 759$svn->{'svn'}->get_log("/",$current_rev,$opt_l,0,1,1,\&commit_all,$pool);
 760$pool->clear;
 761
 762
 763unlink($git_index);
 764
 765if (defined $orig_git_index) {
 766        $ENV{GIT_INDEX_FILE} = $orig_git_index;
 767} else {
 768        delete $ENV{GIT_INDEX_FILE};
 769}
 770
 771# Now switch back to the branch we were in before all of this happened
 772if($orig_branch) {
 773        print "DONE\n" if $opt_v and (not defined $opt_l or $opt_l > 0);
 774        system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 775                if $forward_master;
 776        unless ($opt_i) {
 777                system('git-read-tree', '-m', '-u', 'SVN2GIT_HEAD', 'HEAD');
 778                die "read-tree failed: $?\n" if $?;
 779        }
 780} else {
 781        $orig_branch = "master";
 782        print "DONE; creating $orig_branch branch\n" if $opt_v and (not defined $opt_l or $opt_l > 0);
 783        system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 784                unless -f "$git_dir/refs/heads/master";
 785        system('git-update-ref', 'HEAD', "$orig_branch");
 786        unless ($opt_i) {
 787                system('git checkout');
 788                die "checkout failed: $?\n" if $?;
 789        }
 790}
 791unlink("$git_dir/SVN2GIT_HEAD");
 792close(BRANCHES);